code.delx.au - gnu-emacs/blob - lisp/progmodes/executable.el

   1 ;;; executable.el --- base functionality for executable interpreter scripts
   2
   3 ;; Copyright (C) 1994, 1995, 1996 by Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel.Pfeiffer@Informatik.START.dbp.de, fax (+49 69) 7588-2389
   6 ;; Keywords: languages, unix
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; executable.el is used by certain major modes to insert a suitable
  28 ;; #! line at the beginning of the file, if the file does not already
  29 ;; have one.
  30
  31 ;; Unless it has a magic number, a Unix file with executable mode is passed to
  32 ;; a new instance of the running shell (or to a Bourne shell if a csh is
  33 ;; running and the file starts with `:').  Only a shell can start such a file,
  34 ;; exec() cannot, which is why it is important to have a magic number in every
  35 ;; executable script.  Such a magic number is made up by the characters `#!'
  36 ;; the filename of an interpreter (in COFF, ELF or somesuch format) and one
  37 ;; optional argument.
  38
  39 ;; This library is for certain major modes like sh-, awk-, perl-, tcl- or
  40 ;; makefile-mode to insert or update a suitable #! line at the beginning of
  41 ;; the file, if the file does not already have one and the file is not a
  42 ;; default file of that interpreter (like .profile or makefile).  It also
  43 ;; makes the file executable if it wasn't, as soon as it's saved.
  44
  45 ;; It also allows debugging scripts, with an adaptation of compile, as far
  46 ;; as interpreters give out meaningful error messages.
  47
  48 ;; Modes that use this should nconc `executable-map' to the end of their own
  49 ;; keymap and `executable-font-lock-keywords' to the end of their own font
  50 ;; lock keywords.  Their mode-setting commands should call
  51 ;; `executable-set-magic'.
  52
  53 ;;; Code:
  54
  55 (defvar executable-insert t
  56   "*Non-nil means offer to add a magic number to a file.
  57 This takes effect when you switch to certain major modes,
  58 including Shell-script mode (`sh-mode').
  59 When you type \\[executable-set-magic], it always offers to add or
  60 update the magic number.")
  61
  62 (defvar executable-query 'function
  63   "*If non-nil, ask user before changing an existing magic number.
  64 When this is `function', only ask when called non-interactively.")
  65
  66
  67 (defvar executable-magicless-file-regexp "/[Mm]akefile$\\|/\\.\\(z?profile\\|bash_profile\\|z?login\\|bash_login\\|z?logout\\|bash_logout\\|.+shrc\\|esrc\\|rcrc\\|[kz]shenv\\)$"
  68   "*On files with this kind of name no magic is inserted or changed.")
  69
  70
  71 (defvar executable-prefix "#! "
  72   "*Interpreter magic number prefix inserted when there was no magic number.")
  73
  74
  75
  76 (defvar executable-chmod 73
  77   "*After saving, if the file is not executable, set this mode.
  78 This mode passed to `set-file-modes' is taken absolutely when negative, or
  79 relative to the files existing modes.  Do nothing if this is nil.
  80 Typical values are 73 (+x) or -493 (rwxr-xr-x).")
  81
  82
  83 (defvar executable-command nil)
  84
  85 (defvar executable-self-display "tail"
  86   "*Command you use with argument `+2' to make text files self-display.
  87 Note that the like of `more' doesn't work too well under Emacs  \\[shell].")
  88
  89
  90 (defvar executable-font-lock-keywords
  91   '(("\\`#!.*/\\([^ \t\n]+\\)" 1 font-lock-keyword-face t))
  92   "*Rules for highlighting executable scripts' magic number.
  93 This can be included in `font-lock-keywords' by modes that call `executable'.")
  94
  95
  96 (defvar executable-error-regexp-alist
  97   '(;; /bin/xyz: syntax error at line 14: `(' unexpected
  98     ;; /bin/xyz[5]: syntax error at line 8 : ``' unmatched
  99     ("^\\(.*[^[/]\\)\\(\\[[0-9]+\\]\\)?: .* error .* line \\([0-9]+\\)" 1 3)
 100     ;; /bin/xyz[27]: ehco:  not found
 101     ("^\\(.*[^/]\\)\\[\\([0-9]+\\)\\]: .*: " 1 2)
 102     ;; /bin/xyz: syntax error near unexpected token `)'
 103     ;; /bin/xyz: /bin/xyz: line 2: `)'
 104     ("^\\(.*[^/]\\): [^0-9\n]+\n\\1: \\1: line \\([0-9]+\\):" 1 2)
 105     ;; /usr/bin/awk: syntax error at line 5 of file /bin/xyz
 106     (" error .* line \\([0-9]+\\) of file \\(.+\\)$" 2 1)
 107     ;; /usr/bin/awk: calling undefined function toto
 108     ;;  input record number 3, file awktestdata
 109     ;;  source line 4 of file /bin/xyz
 110     ("^[^ ].+\n\\( .+\n\\)* line \\([0-9]+\\) of file \\(.+\\)$" 3 2)
 111     ;; makefile:1: *** target pattern contains no `%'.  Stop.
 112     ("^\\(.+\\):\\([0-9]+\\): " 1 2))
 113   "Alist of regexps used to match script errors.
 114 See `compilation-error-regexp-alist'.")
 115
 116 ;; The C function openp slightly modified would do the trick fine
 117 (defun executable-find (command)
 118   "Search for COMMAND in exec-path and return the absolute file name.
 119 Return nil if COMMAND is not found anywhere in `exec-path'."
 120   (let ((list exec-path)
 121         file)
 122     (while list
 123       (setq list (if (and (setq file (expand-file-name command (car list)))
 124                           (file-executable-p file)
 125                           (not (file-directory-p file)))
 126                      nil
 127                    (setq file nil)
 128                    (cdr list))))
 129     file))
 130
 131
 132 (defun executable-chmod ()
 133   "This gets called after saving a file to assure that it be executable.
 134 You can set the absolute or relative mode in variable `executable-chmod' for
 135 non-executable files."
 136   (and executable-chmod
 137        buffer-file-name
 138        (or (file-executable-p buffer-file-name)
 139            (set-file-modes buffer-file-name
 140                            (if (< executable-chmod 0)
 141                                (- executable-chmod)
 142                              (logior executable-chmod
 143                                      (file-modes buffer-file-name)))))))
 144
 145
 146 (defun executable-interpret (command)
 147   "Run script with user-specified args, and collect output in a buffer.
 148 While script runs asynchronously, you can use the \\[next-error] command
 149 to find the next error."
 150   (interactive (list (read-string "Run script: "
 151                                   (or executable-command
 152                                       buffer-file-name))))
 153   (require 'compile)
 154   (save-some-buffers (not compilation-ask-about-save))
 155   (make-local-variable 'executable-command)
 156   (compile-internal (setq executable-command command)
 157                     "No more errors." "Interpretation"
 158                     ;; Give it a simpler regexp to match.
 159                     nil executable-error-regexp-alist))
 160
 161
 162
 163 ;;;###autoload
 164 (defun executable-set-magic (interpreter &optional argument
 165                                          no-query-flag insert-flag)
 166   "Set this buffer's interpreter to INTERPRETER with optional ARGUMENT.
 167 The variables `executable-magicless-file-regexp', `executable-prefix',
 168 `executable-insert', `executable-query' and `executable-chmod' control
 169 when and how magic numbers are inserted or replaced and scripts made
 170 executable."
 171   (interactive
 172    (let* ((name (read-string "Name or file name of interpreter: "))
 173           (arg (read-string (format "Argument for %s: " name))))
 174      (list name arg (eq executable-query 'function) t)))
 175   (setq interpreter (if (file-name-absolute-p interpreter)
 176                         interpreter
 177                       (or (executable-find interpreter)
 178                           (error "Interpreter %s not recognized" interpreter)))
 179         argument (concat interpreter
 180                          (and argument (string< "" argument) " ")
 181                          argument))
 182   (or buffer-read-only
 183       (if buffer-file-name
 184           (string-match executable-magicless-file-regexp
 185                         buffer-file-name))
 186       (not (or insert-flag executable-insert))
 187       (> (point-min) 1)
 188       (save-excursion
 189         (let ((point (point-marker))
 190               (buffer-modified-p (buffer-modified-p)))
 191           (goto-char (point-min))
 192           (make-local-hook 'after-save-hook)
 193           (add-hook 'after-save-hook 'executable-chmod nil t)
 194           (if (looking-at "#![ \t]*\\(.*\\)$")
 195               (and (goto-char (match-beginning 1))
 196                    ;; If the line ends in a space,
 197                    ;; don't offer to change it.
 198                    (not (= (char-after (1- (match-end 1))) ?\ ))
 199                    (not (string= argument
 200                                  (buffer-substring (point) (match-end 1))))
 201                    (if (or (not executable-query) no-query-flag
 202                            (save-window-excursion
 203                              ;; Make buffer visible before question.
 204                              (switch-to-buffer (current-buffer))
 205                              (y-or-n-p (concat "Replace magic number by `"
 206                                                executable-prefix argument "'? "))))
 207                        (progn
 208                          (replace-match argument t t nil 1)
 209                          (message "Magic number changed to `%s'"
 210                                   (concat executable-prefix argument)))))
 211             (insert executable-prefix argument ?\n)
 212             (message "Magic number changed to `%s'"
 213                      (concat executable-prefix argument)))
 214 ;;;       (or insert-flag
 215 ;;;           (eq executable-insert t)
 216 ;;;           (set-buffer-modified-p buffer-modified-p))
 217           )))
 218   interpreter)
 219
 220
 221
 222 ;;;###autoload
 223 (defun executable-self-display ()
 224   "Turn a text file into a self-displaying Un*x command.
 225 The magic number of such a command displays all lines but itself."
 226   (interactive)
 227   (if (eq this-command 'executable-self-display)
 228       (setq this-command 'executable-set-magic))
 229   (executable-set-magic executable-self-display "+2"))
 230
 231
 232
 233 (provide 'executable)
 234
 235 ;; executable.el ends here