code.delx.au - gnu-emacs/blob - lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Maintainer: FSF
   8 ;; Keywords: help, internal
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains those help commands which are complicated, and
  28 ;; which may not be used in every session.  For example
  29 ;; `describe-function' will probably be heavily used when doing elisp
  30 ;; programming, but not if just editing C files.  Simpler help commands
  31 ;; are in help.el
  32
  33 ;;; Code:
  34
  35 (require 'help-mode)
  36
  37 ;; Functions
  38
  39 ;;;###autoload
  40 (defun describe-function (function)
  41   "Display the full documentation of FUNCTION (a symbol)."
  42   (interactive
  43    (let ((fn (function-called-at-point))
  44          (enable-recursive-minibuffers t)
  45          val)
  46      (setq val (completing-read (if fn
  47                                     (format "Describe function (default %s): " fn)
  48                                   "Describe function: ")
  49                                 obarray 'fboundp t nil nil
  50                                 (and fn (symbol-name fn))))
  51      (list (if (equal val "")
  52                fn (intern val)))))
  53   (if (null function)
  54       (message "You didn't specify a function")
  55     (help-setup-xref (list #'describe-function function) (interactive-p))
  56     (save-excursion
  57       (with-help-window (help-buffer)
  58         (prin1 function)
  59         ;; Use " is " instead of a colon so that
  60         ;; it is easier to get out the function name using forward-sexp.
  61         (princ " is ")
  62         (describe-function-1 function)
  63         (with-current-buffer standard-output
  64           ;; Return the text we displayed.
  65           (buffer-string))))))
  66
  67 (defun help-split-fundoc (docstring def)
  68   "Split a function DOCSTRING into the actual doc and the usage info.
  69 Return (USAGE . DOC) or nil if there's no usage info.
  70 DEF is the function whose usage we're looking for in DOCSTRING."
  71   ;; Functions can get the calling sequence at the end of the doc string.
  72   ;; In cases where `function' has been fset to a subr we can't search for
  73   ;; function's name in the doc string so we use `fn' as the anonymous
  74   ;; function name instead.
  75   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  76     (cons (format "(%s%s"
  77                   ;; Replace `fn' with the actual function name.
  78                   (if (consp def) "anonymous" def)
  79                   (match-string 1 docstring))
  80           (substring docstring 0 (match-beginning 0)))))
  81
  82 (defun help-add-fundoc-usage (docstring arglist)
  83   "Add the usage info to DOCSTRING.
  84 If DOCSTRING already has a usage info, then just return it unchanged.
  85 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  86 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  87   (unless (stringp docstring) (setq docstring "Not documented"))
  88   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  89       docstring
  90     (concat docstring
  91             (if (string-match "\n?\n\\'" docstring)
  92                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  93               "\n\n")
  94             (if (and (stringp arglist)
  95                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  96                 (concat "(fn" (match-string 1 arglist) ")")
  97               (format "%S" (help-make-usage 'fn arglist))))))
  98
  99 (defun help-function-arglist (def)
 100   ;; Handle symbols aliased to other symbols.
 101   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 102   ;; If definition is a macro, find the function inside it.
 103   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 104   (cond
 105    ((byte-code-function-p def) (aref def 0))
 106    ((eq (car-safe def) 'lambda) (nth 1 def))
 107    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 108     "[Arg list not available until function definition is loaded.]")
 109    (t t)))
 110
 111 (defun help-make-usage (function arglist)
 112   (cons (if (symbolp function) function 'anonymous)
 113         (mapcar (lambda (arg)
 114                   (if (not (symbolp arg))
 115                       (if (and (consp arg) (symbolp (car arg)))
 116                           ;; CL style default values for optional args.
 117                           (cons (intern (upcase (symbol-name (car arg))))
 118                                 (cdr arg))
 119                         arg)
 120                     (let ((name (symbol-name arg)))
 121                       (if (string-match "\\`&" name) arg
 122                         (intern (upcase name))))))
 123                 arglist)))
 124
 125 ;; Could be this, if we make symbol-file do the work below.
 126 ;; (defun help-C-file-name (subr-or-var kind)
 127 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 128 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 129 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 130 ;;               (subr-name subr-or-var))
 131 ;;             (if (eq kind 'var) 'defvar 'defun)))
 132 ;;;###autoload
 133 (defun help-C-file-name (subr-or-var kind)
 134   "Return the name of the C file where SUBR-OR-VAR is defined.
 135 KIND should be `var' for a variable or `subr' for a subroutine."
 136   (let ((docbuf (get-buffer-create " *DOC*"))
 137         (name (if (eq 'var kind)
 138                   (concat "V" (symbol-name subr-or-var))
 139                 (concat "F" (subr-name subr-or-var)))))
 140     (with-current-buffer docbuf
 141       (goto-char (point-min))
 142       (if (eobp)
 143           (insert-file-contents-literally
 144            (expand-file-name internal-doc-file-name doc-directory)))
 145       (let ((file (catch 'loop
 146                     (while t
 147                       (let ((pnt (search-forward (concat "\1f" name "\n"))))
 148                         (re-search-backward "\1fS\\(.*\\)")
 149                         (let ((file (match-string 1)))
 150                           (if (member file build-files)
 151                               (throw 'loop file)
 152                             (goto-char pnt))))))))
 153         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 154             (setq file (replace-match ".m" t t file 1))
 155           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 156               (setq file (replace-match ".c" t t file))))
 157         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 158             (concat "src/" file)
 159           file)))))
 160
 161 (defface help-argument-name '((((supports :slant italic)) :inherit italic))
 162   "Face to highlight argument names in *Help* buffers."
 163   :group 'help)
 164
 165 (defun help-default-arg-highlight (arg)
 166   "Default function to highlight arguments in *Help* buffers.
 167 It returns ARG in face `help-argument-name'; ARG is also
 168 downcased if it displays differently than the default
 169 face (according to `face-differs-from-default-p')."
 170   (propertize (if (face-differs-from-default-p 'help-argument-name)
 171                   (downcase arg)
 172                 arg)
 173               'face 'help-argument-name))
 174
 175 (defun help-do-arg-highlight (doc args)
 176   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 177     (modify-syntax-entry ?\- "w")
 178     (dolist (arg args doc)
 179       (setq doc (replace-regexp-in-string
 180                  ;; This is heuristic, but covers all common cases
 181                  ;; except ARG1-ARG2
 182                  (concat "\\<"                   ; beginning of word
 183                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 184                          "\\("
 185                          (regexp-quote arg)
 186                          "\\)"
 187                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 188                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 189                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 190                          "\\>")                  ; end of word
 191                  (help-default-arg-highlight arg)
 192                  doc t t 1)))))
 193
 194 (defun help-highlight-arguments (usage doc &rest args)
 195   (when usage
 196     (with-temp-buffer
 197       (insert usage)
 198       (goto-char (point-min))
 199       (let ((case-fold-search nil)
 200             (next (not (or args (looking-at "\\["))))
 201             (opt nil))
 202         ;; Make a list of all arguments
 203         (skip-chars-forward "^ ")
 204         (while next
 205           (or opt (not (looking-at " &")) (setq opt t))
 206           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 207               (setq next nil)
 208             (setq args (cons (match-string 2) args))
 209             (when (and opt (string= (match-string 1) "("))
 210               ;; A pesky CL-style optional argument with default value,
 211               ;; so let's skip over it
 212               (search-backward "(")
 213               (goto-char (scan-sexps (point) 1)))))
 214         ;; Highlight aguments in the USAGE string
 215         (setq usage (help-do-arg-highlight (buffer-string) args))
 216         ;; Highlight arguments in the DOC string
 217         (setq doc (and doc (help-do-arg-highlight doc args))))))
 218   ;; Return value is like the one from help-split-fundoc, but highlighted
 219   (cons usage doc))
 220
 221 ;; The following function was compiled from the former functions
 222 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 223 ;; some excerpts from `describe-function-1' and `describe-variable'.
 224 ;; The only additional twists provided are (1) locate the defining file
 225 ;; for autoloaded functions, and (2) give preference to files in the
 226 ;; "install directory" (directories found via `load-path') rather than
 227 ;; to files in the "compile directory" (directories found by searching
 228 ;; the loaddefs.el file).  We autoload it because it's also used by
 229 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 230
 231 ;;;###autoload
 232 (defun find-lisp-object-file-name (object type)
 233   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 234 OBJECT should be a symbol associated with a function, variable, or face;
 235   alternatively, it can be a function definition.
 236 If TYPE is `variable', search for a variable definition.
 237 If TYPE is `face', search for a face definition.
 238 If TYPE is the value returned by `symbol-function' for a function symbol,
 239  search for a function definition.
 240
 241 The return value is the absolute name of a readable file where OBJECT is
 242 defined.  If several such files exist, preference is given to a file
 243 found via `load-path'.  The return value can also be `C-source', which
 244 means that OBJECT is a function or variable defined in C.  If no
 245 suitable file is found, return nil."
 246   (let* ((autoloaded (eq (car-safe type) 'autoload))
 247          (file-name (or (and autoloaded (nth 1 type))
 248                         (symbol-file
 249                          object (if (memq type (list 'defvar 'defface))
 250                                     type
 251                                   'defun)))))
 252     (cond
 253      (autoloaded
 254       ;; An autoloaded function: Locate the file since `symbol-function'
 255       ;; has only returned a bare string here.
 256       (setq file-name
 257             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 258      ((and (stringp file-name)
 259            (string-match "[.]*loaddefs.el\\'" file-name))
 260       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 261       ;; and try to extract the defining file.  The following form is
 262       ;; from `describe-function-1' and `describe-variable'.
 263       (let ((location
 264              (condition-case nil
 265                  (find-function-search-for-symbol object nil file-name)
 266                (error nil))))
 267         (when (cdr location)
 268           (with-current-buffer (car location)
 269             (goto-char (cdr location))
 270             (when (re-search-backward
 271                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 272               (setq file-name
 273                     (locate-file
 274                      (match-string-no-properties 1)
 275                      load-path nil 'readable))))))))
 276
 277     (cond
 278      ((and (not file-name) (subrp type))
 279       ;; A built-in function.  The form is from `describe-function-1'.
 280       (if (get-buffer " *DOC*")
 281           (help-C-file-name type 'subr)
 282         'C-source))
 283      ((and (not file-name) (symbolp object)
 284            (integerp (get object 'variable-documentation)))
 285       ;; A variable defined in C.  The form is from `describe-variable'.
 286       (if (get-buffer " *DOC*")
 287           (help-C-file-name object 'var)
 288         'C-source))
 289      ((not (stringp file-name))
 290       ;; If we don't have a file-name string by now, we lost.
 291       nil)
 292      ((let ((lib-name
 293              (if (string-match "[.]elc\\'" file-name)
 294                  (substring-no-properties file-name 0 -1)
 295                file-name)))
 296         ;; When the Elisp source file can be found in the install
 297         ;; directory return the name of that file - `file-name' should
 298         ;; have become an absolute file name ny now.
 299         (or (and (file-readable-p lib-name) lib-name)
 300             ;; The library might be compressed.
 301             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 302      ((let* ((lib-name (file-name-nondirectory file-name))
 303              ;; The next form is from `describe-simplify-lib-file-name'.
 304              (file-name
 305               ;; Try converting the absolute file name to a library
 306               ;; name, convert that back to a file name and see if we
 307               ;; get the original one.  If so, they are equivalent.
 308               (if (equal file-name (locate-file lib-name load-path '("")))
 309                   (if (string-match "[.]elc\\'" lib-name)
 310                       (substring-no-properties lib-name 0 -1)
 311                     lib-name)
 312                 file-name))
 313              ;; The next three forms are from `find-source-lisp-file'.
 314              (elc-file (locate-file
 315                         (concat file-name
 316                                 (if (string-match "\\.el\\'" file-name)
 317                                     "c"
 318                                   ".elc"))
 319                         load-path nil 'readable))
 320              (str (when elc-file
 321                     (with-temp-buffer
 322                       (insert-file-contents-literally elc-file nil 0 256)
 323                       (buffer-string))))
 324              (src-file (and str
 325                             (string-match ";;; from file \\(.*\\.el\\)" str)
 326                             (match-string 1 str))))
 327         (and src-file (file-readable-p src-file) src-file))))))
 328
 329 (declare-function ad-get-advice-info "advice" (function))
 330
 331 ;;;###autoload
 332 (defun describe-function-1 (function)
 333   (let* ((advised (and (symbolp function) (featurep 'advice)
 334                        (ad-get-advice-info function)))
 335          ;; If the function is advised, use the symbol that has the
 336          ;; real definition, if that symbol is already set up.
 337          (real-function
 338           (or (and advised
 339                    (let ((origname (cdr (assq 'origname advised))))
 340                      (and (fboundp origname) origname)))
 341               function))
 342          ;; Get the real definition.
 343          (def (if (symbolp real-function)
 344                   (symbol-function real-function)
 345                 function))
 346          file-name string
 347          (beg (if (commandp def) "an interactive " "a "))
 348          (pt1 (with-current-buffer (help-buffer) (point)))
 349          errtype)
 350     (setq string
 351           (cond ((or (stringp def)
 352                      (vectorp def))
 353                  "a keyboard macro")
 354                 ((subrp def)
 355                  (if (eq 'unevalled (cdr (subr-arity def)))
 356                      (concat beg "special form")
 357                    (concat beg "built-in function")))
 358                 ((byte-code-function-p def)
 359                  (concat beg "compiled Lisp function"))
 360                 ((symbolp def)
 361                  (while (and (fboundp def)
 362                              (symbolp (symbol-function def)))
 363                    (setq def (symbol-function def)))
 364                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 365                  (or (fboundp def) (setq errtype 'alias))
 366                  (format "an alias for `%s'" def))
 367                 ((eq (car-safe def) 'lambda)
 368                  (concat beg "Lisp function"))
 369                 ((eq (car-safe def) 'macro)
 370                  "a Lisp macro")
 371                 ((eq (car-safe def) 'autoload)
 372                  (format "%s autoloaded %s"
 373                          (if (commandp def) "an interactive" "an")
 374                          (if (eq (nth 4 def) 'keymap) "keymap"
 375                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 376                 ((keymapp def)
 377                  (let ((is-full nil)
 378                        (elts (cdr-safe def)))
 379                    (while elts
 380                      (if (char-table-p (car-safe elts))
 381                          (setq is-full t
 382                                elts nil))
 383                      (setq elts (cdr-safe elts)))
 384                    (if is-full
 385                        "a full keymap"
 386                      "a sparse keymap")))
 387                 (t "")))
 388     (princ string)
 389     (if (eq errtype 'alias)
 390         (princ ",\nwhich is not defined.  Please make a bug report.")
 391       (with-current-buffer standard-output
 392         (save-excursion
 393           (save-match-data
 394             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 395               (help-xref-button 1 'help-function def)))))
 396
 397       (setq file-name (find-lisp-object-file-name function def))
 398       (when file-name
 399         (princ " in `")
 400         ;; We used to add .el to the file name,
 401         ;; but that's completely wrong when the user used load-file.
 402         (princ (if (eq file-name 'C-source)
 403                    "C source code"
 404                  (file-name-nondirectory file-name)))
 405         (princ "'")
 406         ;; Make a hyperlink to the library.
 407         (with-current-buffer standard-output
 408           (save-excursion
 409             (re-search-backward "`\\([^`']+\\)'" nil t)
 410             (help-xref-button 1 'help-function-def function file-name))))
 411       (princ ".")
 412       (with-current-buffer (help-buffer)
 413         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 414                                   (point)))
 415       (terpri)(terpri)
 416       (when (commandp function)
 417         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 418               (remapped (command-remapping function)))
 419           (unless (memq remapped '(ignore undefined))
 420             (let ((keys (where-is-internal
 421                          (or remapped function) overriding-local-map nil nil))
 422                   non-modified-keys)
 423               (if (and (eq function 'self-insert-command)
 424                        (vectorp (car-safe keys))
 425                        (consp (aref (car keys) 0)))
 426                   (princ "It is bound to many ordinary text characters.\n")
 427                 ;; Which non-control non-meta keys run this command?
 428                 (dolist (key keys)
 429                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 430                       (push key non-modified-keys)))
 431                 (when remapped
 432                   (princ "It is remapped to `")
 433                   (princ (symbol-name remapped))
 434                   (princ "'"))
 435
 436                 (when keys
 437                   (princ (if remapped ", which is bound to " "It is bound to "))
 438                   ;; If lots of ordinary text characters run this command,
 439                   ;; don't mention them one by one.
 440                   (if (< (length non-modified-keys) 10)
 441                       (princ (mapconcat 'key-description keys ", "))
 442                     (dolist (key non-modified-keys)
 443                       (setq keys (delq key keys)))
 444                     (if keys
 445                         (progn
 446                           (princ (mapconcat 'key-description keys ", "))
 447                           (princ ", and many ordinary text characters"))
 448                       (princ "many ordinary text characters"))))
 449                 (when (or remapped keys non-modified-keys)
 450                   (princ ".")
 451                   (terpri)))))
 452
 453           (with-current-buffer (help-buffer)
 454             (fill-region-as-paragraph pt2 (point))
 455             (unless (looking-back "\n\n")
 456               (terpri)))))
 457       (let* ((arglist (help-function-arglist def))
 458              (doc (documentation function))
 459              (usage (help-split-fundoc doc function)))
 460         (with-current-buffer standard-output
 461           ;; If definition is a keymap, skip arglist note.
 462           (unless (keymapp function)
 463             (let* ((use (cond
 464                          (usage (setq doc (cdr usage)) (car usage))
 465                          ((listp arglist)
 466                           (format "%S" (help-make-usage function arglist)))
 467                          ((stringp arglist) arglist)
 468                          ;; Maybe the arglist is in the docstring of a symbol
 469                          ;; this one is aliased to.
 470                          ((let ((fun real-function))
 471                             (while (and (symbolp fun)
 472                                         (setq fun (symbol-function fun))
 473                                         (not (setq usage (help-split-fundoc
 474                                                           (documentation fun)
 475                                                           function)))))
 476                             usage)
 477                           (car usage))
 478                          ((or (stringp def)
 479                               (vectorp def))
 480                           (format "\nMacro: %s" (format-kbd-macro def)))
 481                          (t "[Missing arglist.  Please make a bug report.]")))
 482                    (high (help-highlight-arguments use doc)))
 483               (let ((fill-begin (point)))
 484                 (insert (car high) "\n")
 485                 (fill-region fill-begin (point)))
 486               (setq doc (cdr high))))
 487           (let* ((obsolete (and
 488                             ;; function might be a lambda construct.
 489                             (symbolp function)
 490                             (get function 'byte-obsolete-info)))
 491                  (use (car obsolete)))
 492             (when obsolete
 493               (princ "\nThis function is obsolete")
 494               (when (nth 2 obsolete)
 495                 (insert (format " since %s" (nth 2 obsolete))))
 496               (insert (cond ((stringp use) (concat ";\n" use))
 497                             (use (format ";\nuse `%s' instead." use))
 498                             (t "."))
 499                       "\n"))
 500             (insert "\n"
 501                     (or doc "Not documented."))))))))
 502
 503 \f
 504 ;; Variables
 505
 506 ;;;###autoload
 507 (defun variable-at-point (&optional any-symbol)
 508   "Return the bound variable symbol found at or before point.
 509 Return 0 if there is no such symbol.
 510 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 511   (with-syntax-table emacs-lisp-mode-syntax-table
 512     (or (condition-case ()
 513             (save-excursion
 514               (or (not (zerop (skip-syntax-backward "_w")))
 515                   (eq (char-syntax (following-char)) ?w)
 516                   (eq (char-syntax (following-char)) ?_)
 517                   (forward-sexp -1))
 518               (skip-chars-forward "'")
 519               (let ((obj (read (current-buffer))))
 520                 (and (symbolp obj) (boundp obj) obj)))
 521           (error nil))
 522         (let* ((str (find-tag-default))
 523                (sym (if str (intern-soft str))))
 524           (if (and sym (or any-symbol (boundp sym)))
 525               sym
 526             (save-match-data
 527               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 528                 (setq sym (intern-soft (match-string 1 str)))
 529                 (and (or any-symbol (boundp sym)) sym)))))
 530         0)))
 531
 532 (defun describe-variable-custom-version-info (variable)
 533   (let ((custom-version (get variable 'custom-version))
 534         (cpv (get variable 'custom-package-version))
 535         (output nil))
 536     (if custom-version
 537         (setq output
 538               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 539                       custom-version))
 540       (when cpv
 541         (let* ((package (car-safe cpv))
 542                (version (if (listp (cdr-safe cpv))
 543                             (car (cdr-safe cpv))
 544                           (cdr-safe cpv)))
 545                (pkg-versions (assq package customize-package-emacs-version-alist))
 546                (emacsv (cdr (assoc version pkg-versions))))
 547           (if (and package version)
 548               (setq output
 549                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 550                                     (if emacsv
 551                                         (format " that is part of Emacs %s" emacsv))
 552                                     ".\n")
 553                             version package))))))
 554     output))
 555
 556 ;;;###autoload
 557 (defun describe-variable (variable &optional buffer frame)
 558   "Display the full documentation of VARIABLE (a symbol).
 559 Returns the documentation as a string, also.
 560 If VARIABLE has a buffer-local value in BUFFER or FRAME
 561 \(default to the current buffer and current frame),
 562 it is displayed along with the global value."
 563   (interactive
 564    (let ((v (variable-at-point))
 565          (enable-recursive-minibuffers t)
 566          val)
 567      (setq val (completing-read (if (symbolp v)
 568                                     (format
 569                                      "Describe variable (default %s): " v)
 570                                   "Describe variable: ")
 571                                 obarray
 572                                 '(lambda (vv)
 573                                    (or (boundp vv)
 574                                        (get vv 'variable-documentation)))
 575                                 t nil nil
 576                                 (if (symbolp v) (symbol-name v))))
 577      (list (if (equal val "")
 578                v (intern val)))))
 579   (let (file-name)
 580     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 581     (unless (frame-live-p frame) (setq frame (selected-frame)))
 582     (if (not (symbolp variable))
 583         (message "You did not specify a variable")
 584       (save-excursion
 585         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 586               val val-start-pos locus)
 587           ;; Extract the value before setting up the output buffer,
 588           ;; in case `buffer' *is* the output buffer.
 589           (unless valvoid
 590             (with-selected-frame frame
 591               (with-current-buffer buffer
 592                 (setq val (symbol-value variable)
 593                       locus (variable-binding-locus variable)))))
 594           (help-setup-xref (list #'describe-variable variable buffer)
 595                            (interactive-p))
 596           (with-help-window (help-buffer)
 597             (with-current-buffer buffer
 598               (prin1 variable)
 599               (setq file-name (find-lisp-object-file-name variable 'defvar))
 600
 601               (if file-name
 602                   (progn
 603                     (princ " is a variable defined in `")
 604                     (princ (if (eq file-name 'C-source)
 605                                "C source code"
 606                              (file-name-nondirectory file-name)))
 607                     (princ "'.\n")
 608                     (with-current-buffer standard-output
 609                       (save-excursion
 610                         (re-search-backward "`\\([^`']+\\)'" nil t)
 611                         (help-xref-button 1 'help-variable-def
 612                                           variable file-name)))
 613                     (if valvoid
 614                         (princ "It is void as a variable.")
 615                       (princ "Its ")))
 616                 (if valvoid
 617                     (princ " is void as a variable.")
 618                   (princ "'s "))))
 619             (if valvoid
 620                 nil
 621               (with-current-buffer standard-output
 622                 (setq val-start-pos (point))
 623                 (princ "value is ")
 624                 (terpri)
 625                 (let ((from (point)))
 626                   (pp val)
 627                   ;; Hyperlinks in variable's value are quite frequently
 628                   ;; inappropriate e.g C-h v <RET> features <RET>
 629                   ;; (help-xref-on-pp from (point))
 630                   (if (< (point) (+ from 20))
 631                       (delete-region (1- from) from)))))
 632             (terpri)
 633
 634             (when locus
 635               (if (bufferp locus)
 636                   (princ (format "%socal in buffer %s; "
 637                                  (if (get variable 'permanent-local)
 638                                      "Permanently l" "L")
 639                                  (buffer-name)))
 640                 (princ (format "It is a frame-local variable; ")))
 641               (if (not (default-boundp variable))
 642                   (princ "globally void")
 643                 (let ((val (default-value variable)))
 644                   (with-current-buffer standard-output
 645                     (princ "global value is ")
 646                     (terpri)
 647                     ;; Fixme: pp can take an age if you happen to
 648                     ;; ask for a very large expression.  We should
 649                     ;; probably print it raw once and check it's a
 650                     ;; sensible size before prettyprinting.  -- fx
 651                     (let ((from (point)))
 652                       (pp val)
 653                       ;; See previous comment for this function.
 654                       ;; (help-xref-on-pp from (point))
 655                       (if (< (point) (+ from 20))
 656                           (delete-region (1- from) from))))))
 657               (terpri))
 658
 659             ;; If the value is large, move it to the end.
 660             (with-current-buffer standard-output
 661               (when (> (count-lines (point-min) (point-max)) 10)
 662                 ;; Note that setting the syntax table like below
 663                 ;; makes forward-sexp move over a `'s' at the end
 664                 ;; of a symbol.
 665                 (set-syntax-table emacs-lisp-mode-syntax-table)
 666                 (goto-char val-start-pos)
 667                 ;; The line below previously read as
 668                 ;; (delete-region (point) (progn (end-of-line) (point)))
 669                 ;; which suppressed display of the buffer local value for
 670                 ;; large values.
 671                 (when (looking-at "value is") (replace-match ""))
 672                 (save-excursion
 673                   (insert "\n\nValue:")
 674                   (set (make-local-variable 'help-button-cache)
 675                        (point-marker)))
 676                 (insert "value is shown ")
 677                 (insert-button "below"
 678                                'action help-button-cache
 679                                'follow-link t
 680                                'help-echo "mouse-2, RET: show value")
 681                 (insert ".\n")))
 682             (terpri)
 683
 684             (let* ((alias (condition-case nil
 685                               (indirect-variable variable)
 686                             (error variable)))
 687                    (obsolete (get variable 'byte-obsolete-variable))
 688                    (use (car obsolete))
 689                    (safe-var (get variable 'safe-local-variable))
 690                    (doc (or (documentation-property variable 'variable-documentation)
 691                             (documentation-property alias 'variable-documentation)))
 692                    (extra-line nil))
 693               ;; Add a note for variables that have been make-var-buffer-local.
 694               (when (and (local-variable-if-set-p variable)
 695                          (or (not (local-variable-p variable))
 696                              (with-temp-buffer
 697                                (local-variable-if-set-p variable))))
 698                 (setq extra-line t)
 699                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 700
 701               ;; Mention if it's an alias
 702               (unless (eq alias variable)
 703                 (setq extra-line t)
 704                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 705
 706               (when obsolete
 707                 (setq extra-line t)
 708                 (princ "  This variable is obsolete")
 709                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 710                 (princ (cond ((stringp use) (concat ";\n  " use))
 711                              (use (format ";\n  use `%s' instead." (car obsolete)))
 712                              (t ".")))
 713                 (terpri))
 714
 715               (when (member (cons variable val) file-local-variables-alist)
 716                 (setq extra-line t)
 717                 (if (member (cons variable val) dir-local-variables-alist)
 718                     (let ((file (and (buffer-file-name)
 719                                      (not (file-remote-p (buffer-file-name)))
 720                                      (dir-locals-find-file (buffer-file-name)))))
 721                       (princ "  This variable is a directory local variable")
 722                       (if file (princ (concat "\n  from the file \"" file "\"")))
 723                       (princ ".\n"))
 724                   (princ "  This variable is a file local variable.\n")))
 725
 726               (when (memq variable ignored-local-variables)
 727                 (setq extra-line t)
 728                 (princ "  This variable is ignored when used as a file local \
 729 variable.\n"))
 730
 731               ;; Can be both risky and safe, eg auto-fill-function.
 732               (when (risky-local-variable-p variable)
 733                 (setq extra-line t)
 734                 (princ "  This variable is potentially risky when used as a \
 735 file local variable.\n")
 736                 (when (assq variable safe-local-variable-values)
 737                   (princ "  However, you have added it to \
 738 `safe-local-variable-values'.\n")))
 739
 740               (when safe-var
 741                 (setq extra-line t)
 742                 (princ "  This variable is safe as a file local variable ")
 743                 (princ "if its value\n  satisfies the predicate ")
 744                 (princ (if (byte-code-function-p safe-var)
 745                            "which is byte-compiled expression.\n"
 746                          (format "`%s'.\n" safe-var))))
 747
 748               (if extra-line (terpri))
 749               (princ "Documentation:\n")
 750               (with-current-buffer standard-output
 751                 (insert (or doc "Not documented as a variable."))))
 752
 753             ;; Make a link to customize if this variable can be customized.
 754             (when (custom-variable-p variable)
 755               (let ((customize-label "customize"))
 756                 (terpri)
 757                 (terpri)
 758                 (princ (concat "You can " customize-label " this variable."))
 759                 (with-current-buffer standard-output
 760                   (save-excursion
 761                     (re-search-backward
 762                      (concat "\\(" customize-label "\\)") nil t)
 763                     (help-xref-button 1 'help-customize-variable variable))))
 764               ;; Note variable's version or package version
 765               (let ((output (describe-variable-custom-version-info variable)))
 766                 (when output
 767                   (terpri)
 768                   (terpri)
 769                   (princ output))))
 770
 771             (save-excursion
 772               (set-buffer standard-output)
 773               ;; Return the text we displayed.
 774               (buffer-string))))))))
 775
 776
 777 ;;;###autoload
 778 (defun describe-syntax (&optional buffer)
 779   "Describe the syntax specifications in the syntax table of BUFFER.
 780 The descriptions are inserted in a help buffer, which is then displayed.
 781 BUFFER defaults to the current buffer."
 782   (interactive)
 783   (setq buffer (or buffer (current-buffer)))
 784   (help-setup-xref (list #'describe-syntax buffer) (interactive-p))
 785   (with-help-window (help-buffer)
 786     (let ((table (with-current-buffer buffer (syntax-table))))
 787       (with-current-buffer standard-output
 788         (describe-vector table 'internal-describe-syntax-value)
 789         (while (setq table (char-table-parent table))
 790           (insert "\nThe parent syntax table is:")
 791           (describe-vector table 'internal-describe-syntax-value))))))
 792
 793 (defun help-describe-category-set (value)
 794   (insert (cond
 795            ((null value) "default")
 796            ((char-table-p value) "deeper char-table ...")
 797            (t (condition-case err
 798                   (category-set-mnemonics value)
 799                 (error "invalid"))))))
 800
 801 ;;;###autoload
 802 (defun describe-categories (&optional buffer)
 803   "Describe the category specifications in the current category table.
 804 The descriptions are inserted in a buffer, which is then displayed.
 805 If BUFFER is non-nil, then describe BUFFER's category table instead.
 806 BUFFER should be a buffer or a buffer name."
 807   (interactive)
 808   (setq buffer (or buffer (current-buffer)))
 809   (help-setup-xref (list #'describe-categories buffer) (interactive-p))
 810   (with-help-window (help-buffer)
 811     (let* ((table (with-current-buffer buffer (category-table)))
 812            (docs (char-table-extra-slot table 0)))
 813       (if (or (not (vectorp docs)) (/= (length docs) 95))
 814           (error "Invalid first extra slot in this category table\n"))
 815       (with-current-buffer standard-output
 816         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 817         (let ((pos (point)) (items 0) lines n)
 818           (dotimes (i 95)
 819             (if (aref docs i) (setq items (1+ items))))
 820           (setq lines (1+ (/ (1- items) 4)))
 821           (setq n 0)
 822           (dotimes (i 95)
 823             (let ((elt (aref docs i)))
 824               (when elt
 825                 (string-match ".*" elt)
 826                 (setq elt (match-string 0 elt))
 827                 (if (>= (length elt) 17)
 828                     (setq elt (concat (substring elt 0 14) "...")))
 829                 (if (< (point) (point-max))
 830                     (move-to-column (* 20 (/ n lines)) t))
 831                 (insert (+ i ?\s) ?: elt)
 832                 (if (< (point) (point-max))
 833                     (forward-line 1)
 834                   (insert "\n"))
 835                 (setq n (1+ n))
 836                 (if (= (% n lines) 0)
 837                     (goto-char pos))))))
 838         (goto-char (point-max))
 839         (insert "\n"
 840                 "character(s)\tcategory mnemonics\n"
 841                 "------------\t------------------")
 842         (describe-vector table 'help-describe-category-set)
 843         (insert "Legend of category mnemonics:\n")
 844         (dotimes (i 95)
 845           (let ((elt (aref docs i)))
 846             (when elt
 847               (if (string-match "\n" elt)
 848                   (setq elt (substring elt (match-end 0))))
 849               (insert (+ i ?\s) ": " elt "\n"))))
 850         (while (setq table (char-table-parent table))
 851           (insert "\nThe parent category table is:")
 852           (describe-vector table 'help-describe-category-set))))))
 853
 854 (provide 'help-fns)
 855
 856 ;; arch-tag: 9e10331c-ae81-4d13-965d-c4819aaab0b3
 857 ;;; help-fns.el ends here