code.delx.au - gnu-emacs/blob - lisp/gnus/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   4
   5 ;; Author: Teodor Zlatanov <tzz@lifelogs.com>
   6 ;; Keywords: network
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  28 ;;; breaks are used for grouping declarations and documentation relating to
  29 ;;; each particular aspect.
  30
  31 ;;; Code:
  32 (require 'gnus)
  33 (require 'gnus-sum)
  34
  35 (eval-and-compile
  36   (autoload 'mm-url-insert "mm-url"))
  37
  38 (defgroup spam-report nil
  39   "Spam reporting configuration."
  40   :group 'mail
  41   :group 'news)
  42
  43 (defcustom spam-report-gmane-regex nil
  44   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  45 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  46 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  47 instead."
  48   :type '(radio (const nil)
  49                 (regexp :value "^nntp\+.*:gmane\."))
  50   :group 'spam-report)
  51
  52 (defcustom spam-report-gmane-spam-header
  53   "^X-Report-Spam: http://\\([^/]+\\)\\(.*\\)$"
  54   "String matching Gmane spam-reporting header.  Two match groups are needed."
  55   :type 'regexp
  56   :group 'spam-report)
  57
  58 (defcustom spam-report-gmane-use-article-number t
  59   "Whether the article number (faster!) or the header should be used."
  60   :type 'boolean
  61   :group 'spam-report)
  62
  63 (defcustom spam-report-url-ping-function
  64   'spam-report-url-ping-plain
  65   "Function to use for url ping spam reporting.
  66 The function must accept the arguments `host' and `report'."
  67   :type '(choice
  68           (const :tag "Connect directly"
  69                  spam-report-url-ping-plain)
  70           (const :tag "Use the external program specified in `mm-url-program'"
  71                  spam-report-url-ping-mm-url)
  72           (const :tag "Store request URLs in `spam-report-requests-file'"
  73                  spam-report-url-to-file)
  74           (function :tag "User defined function" nil))
  75   :group 'spam-report)
  76
  77 (defcustom spam-report-requests-file
  78   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  79   ;; Is there a convention for the extension of such a file?
  80   ;; Should we use `spam-directory'?
  81   "File where spam report request are stored."
  82   :type 'file
  83   :group 'spam-report)
  84
  85 (defvar spam-report-url-ping-temp-agent-function nil
  86   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  87 This variable will store the value of `spam-report-url-ping-function' from
  88 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  89 undo that change.")
  90
  91 (defun spam-report-gmane (&rest articles)
  92   "Report an article as spam through Gmane"
  93   (dolist (article articles)
  94     (when (and gnus-newsgroup-name
  95                (or (null spam-report-gmane-regex)
  96                    (string-match spam-report-gmane-regex gnus-newsgroup-name)))
  97       (gnus-message 6 "Reporting spam article %d to spam.gmane.org..." article)
  98       (if spam-report-gmane-use-article-number
  99           (spam-report-url-ping
 100            "spam.gmane.org"
 101            (format "/%s:%d"
 102                    (gnus-group-real-name gnus-newsgroup-name)
 103                    article))
 104         (with-current-buffer nntp-server-buffer
 105           (gnus-request-head article gnus-newsgroup-name)
 106           (goto-char (point-min))
 107           (if (re-search-forward spam-report-gmane-spam-header nil t)
 108               (let* ((host (match-string 1))
 109                      (report (match-string 2))
 110                      (url (format "http://%s%s" host report)))
 111                 (gnus-message 7 "Reporting spam through URL %s..." url)
 112                 (spam-report-url-ping host report))
 113             (gnus-message 3 "Could not find X-Report-Spam in article %d..."
 114                           article)))))))
 115
 116 (defun spam-report-url-ping (host report)
 117   "Ping a host through HTTP, addressing a specific GET resource using
 118 the function specified by `spam-report-url-ping-function'."
 119   (funcall spam-report-url-ping-function host report))
 120
 121 (defun spam-report-url-ping-plain (host report)
 122   "Ping a host through HTTP, addressing a specific GET resource."
 123   (let ((tcp-connection))
 124     (with-temp-buffer
 125       (or (setq tcp-connection
 126                 (open-network-stream
 127                  "URL ping"
 128                  (buffer-name)
 129                  host
 130                  80))
 131           (error "Could not open connection to %s" host))
 132       (set-marker (process-mark tcp-connection) (point-min))
 133       (process-send-string
 134        tcp-connection
 135        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 136                report (gnus-emacs-version) host)))))
 137
 138 ;;;###autoload
 139 (defun spam-report-process-queue (&optional file keep)
 140   "Report all queued requests from `spam-report-requests-file'.
 141
 142 If FILE is given, use it instead of `spam-report-requests-file'.
 143 If KEEP is t, leave old requests in the file.  If KEEP is the
 144 symbol `ask', query before flushing the queue file."
 145   (interactive
 146    (list (read-file-name
 147           "File: "
 148           (file-name-directory spam-report-requests-file)
 149           spam-report-requests-file
 150           nil
 151           (file-name-nondirectory spam-report-requests-file))
 152          current-prefix-arg))
 153   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 154       (error (concat "Cannot process requests when "
 155                      "`spam-report-url-ping-function' is "
 156                      "`spam-report-url-to-file'."))
 157     (gnus-message 7 "Processing requests using `%s'."
 158                   spam-report-url-ping-function))
 159   (or file (setq file spam-report-requests-file))
 160   (save-excursion
 161     (set-buffer (find-file-noselect file))
 162     (goto-char (point-min))
 163     (while (and (not (eobp))
 164                 (re-search-forward
 165                  "http://\\([^/]+\\)\\(/.*\\) *$" (gnus-point-at-eol) t))
 166       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 167       (forward-line 1))
 168     (if (or (eq keep nil)
 169             (and (eq keep 'ask)
 170                  (y-or-n-p
 171                   (format
 172                    "Flush requests from `%s'? " (current-buffer)))))
 173         (progn
 174           (gnus-message 7 "Flushing request file `%s'"
 175                         spam-report-requests-file)
 176           (erase-buffer)
 177           (save-buffer)
 178           (kill-buffer (current-buffer)))
 179       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 180
 181 ;;;###autoload
 182 (defun spam-report-url-ping-mm-url (host report)
 183   "Ping a host through HTTP, addressing a specific GET resource. Use
 184 the external program specified in `mm-url-program' to connect to
 185 server."
 186   (with-temp-buffer
 187     (let ((url (format "http://%s%s" host report)))
 188       (mm-url-insert url t))))
 189
 190 ;;;###autoload
 191 (defun spam-report-url-to-file (host report)
 192   "Collect spam report requests in `spam-report-requests-file'.
 193 Customize `spam-report-url-ping-function' to use this function."
 194   (let ((url (format "http://%s%s" host report))
 195         (file spam-report-requests-file))
 196     (gnus-make-directory (file-name-directory file))
 197     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 198     (with-temp-buffer
 199       (insert url)
 200       (newline)
 201       (append-to-file (point-min) (point-max) file))))
 202
 203 ;;;###autoload
 204 (defun spam-report-agentize ()
 205   "Add spam-report support to the Agent.
 206 Spam reports will be queued with \\[spam-report-url-to-file] when
 207 the Agent is unplugged, and will be submitted in a batch when the
 208 Agent is plugged."
 209   (interactive)
 210   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 211   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 212
 213 ;;;###autoload
 214 (defun spam-report-deagentize ()
 215   "Remove spam-report support from the Agent.
 216 Spam reports will be queued with the method used when
 217 \\[spam-report-agentize] was run."
 218   (interactive)
 219   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 220   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 221
 222 (defun spam-report-plug-agent ()
 223   "Adjust spam report settings for plugged state.
 224 Process queued spam reports."
 225   ;; Process the queue, unless the user only wanted to report to a file
 226   ;; anyway.
 227   (unless (equal spam-report-url-ping-temp-agent-function
 228                  'spam-report-url-to-file)
 229     (spam-report-process-queue))
 230   ;; Set the reporting function, if we have memorized something otherwise,
 231   ;; stick with plain URL reporting.
 232   (setq spam-report-url-ping-function
 233         (or spam-report-url-ping-temp-agent-function
 234             'spam-report-url-ping-plain)))
 235
 236 (defun spam-report-unplug-agent ()
 237   "Restore spam report settings for unplugged state."
 238   ;; save the old value
 239   (setq spam-report-url-ping-temp-agent-function
 240         spam-report-url-ping-function)
 241   ;; store all reports to file
 242   (setq spam-report-url-ping-function
 243         'spam-report-url-to-file))
 244
 245 (provide 'spam-report)
 246
 247 ;;; arch-tag: f6683295-ec89-4ab5-8803-8cc842293022
 248 ;;; spam-report.el ends here.