code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 357
 358 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 359  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 360  [ case "${withval}" in
 361     y | ye | yes )      val=yes ;;
 362     n | no )            val=no  ;;
 363     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 364     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 365     g | gf | gfi | gfil | gfile )       val=gfile ;;
 366     w | w3 | w32 )      val=w32 ;;
 367     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 368 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 369 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 370 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 371     ;;
 372    esac
 373    with_file_notification=$val
 374  ],
 375  [with_file_notification=$with_features])
 376
 377 OPTION_DEFAULT_OFF([xwidgets],
 378   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 379
 380 ## For the times when you want to build Emacs but don't have
 381 ## a suitable makeinfo, and can live without the manuals.
 382 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 383 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 384
 385 ## This might be a 'configure' arg.
 386 AC_SUBST([ACLOCAL_PATH])
 387
 388 ## Makefile.in needs the cache file name.
 389 AC_SUBST(cache_file)
 390
 391 ## This is an option because I do not know if all info/man support
 392 ## compressed files, nor how to test if they do so.
 393 OPTION_DEFAULT_ON([compress-install],
 394   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 395 make GZIP_PROG= install])
 396
 397 AC_ARG_WITH(gameuser,dnl
 398 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 399                 [user for shared game score files.
 400                 An argument prefixed by ':' specifies a group instead.])])
 401 gameuser=
 402 gamegroup=
 403 # We don't test if we can actually chown/chgrp here, because configure
 404 # may run without root privileges.  lib-src/Makefile.in will handle
 405 # any errors due to missing user/group gracefully.
 406 case ${with_gameuser} in
 407   no) ;;
 408   "" | yes) gamegroup=games ;;
 409   :*) gamegroup=${with_gameuser#:} ;;
 410   *) gameuser=${with_gameuser} ;;
 411 esac
 412
 413 AC_ARG_WITH([gnustep-conf],dnl
 414 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 415    [name of GNUstep configuration file to use on systems where the command
 416     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 417     /etc/GNUstep/GNUstep.conf])])
 418 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 419   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 420 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 421      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 422
 423 AC_ARG_ENABLE(ns-self-contained,
 424 [AS_HELP_STRING([--disable-ns-self-contained],
 425                 [disable self contained build under NeXTstep])],
 426    EN_NS_SELF_CONTAINED=$enableval,
 427    EN_NS_SELF_CONTAINED=yes)
 428
 429 locallisppathset=no
 430 AC_ARG_ENABLE(locallisppath,
 431 [AS_HELP_STRING([--enable-locallisppath=PATH],
 432                 [directories Emacs should search for lisp files specific
 433                  to this site])],
 434 if test "${enableval}" = "no"; then
 435   locallisppath=
 436 elif test "${enableval}" != "yes"; then
 437   locallisppath=${enableval} locallisppathset=yes
 438 fi)
 439
 440 AC_ARG_ENABLE(checking,
 441 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 442                 [enable expensive run-time checks.  With LIST,
 443                  enable only specific categories of checks.
 444                  Categories are: all,yes,no.
 445                  Flags are: stringbytes, stringoverrun, stringfreelist,
 446                  xmallocoverrun, conslist, glyphs])],
 447 [ac_checking_flags="${enableval}"],[])
 448 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 449 for check in $ac_checking_flags
 450 do
 451         case $check in
 452         # these set all the flags to specific states
 453         yes)            ac_enable_checking=1 ;;
 454         no)             ac_enable_checking= ;
 455                         ac_gc_check_stringbytes= ;
 456                         ac_gc_check_string_overrun= ;
 457                         ac_gc_check_string_free_list= ;
 458                         ac_xmalloc_overrun= ;
 459                         ac_gc_check_cons_list= ;
 460                         ac_glyphs_debug= ;;
 461         all)            ac_enable_checking=1 ;
 462                         ac_gc_check_stringbytes=1 ;
 463                         ac_gc_check_string_overrun=1 ;
 464                         ac_gc_check_string_free_list=1 ;
 465                         ac_xmalloc_overrun=1 ;
 466                         ac_gc_check_cons_list=1 ;
 467                         ac_glyphs_debug=1 ;;
 468         # these enable particular checks
 469         stringbytes)    ac_gc_check_stringbytes=1 ;;
 470         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 471         stringfreelist) ac_gc_check_string_free_list=1 ;;
 472         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 473         conslist)       ac_gc_check_cons_list=1 ;;
 474         glyphs)         ac_glyphs_debug=1 ;;
 475         *)      AC_MSG_ERROR(unknown check category $check) ;;
 476         esac
 477 done
 478 IFS="$ac_save_IFS"
 479
 480 if test x$ac_enable_checking != x ; then
 481   AC_DEFINE(ENABLE_CHECKING, 1,
 482 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 483 fi
 484 if test x$ac_gc_check_stringbytes != x ; then
 485   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 486 [Define this temporarily to hunt a bug.  If defined, the size of
 487    strings is redundantly recorded in sdata structures so that it can
 488    be compared to the sizes recorded in Lisp strings.])
 489 fi
 490 if test x$ac_gc_check_string_overrun != x ; then
 491   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 492 [Define this to check for short string overrun.])
 493 fi
 494 if test x$ac_gc_check_string_free_list != x ; then
 495   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 496 [Define this to check the string free list.])
 497 fi
 498 if test x$ac_xmalloc_overrun != x ; then
 499   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 500 [Define this to check for malloc buffer overrun.])
 501 fi
 502 if test x$ac_gc_check_cons_list != x ; then
 503   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 504 [Define this to check for errors in cons list.])
 505 fi
 506 if test x$ac_glyphs_debug != x ; then
 507   AC_DEFINE(GLYPH_DEBUG, 1,
 508 [Define this to enable glyphs debugging code.])
 509 fi
 510
 511 AC_ARG_ENABLE(check-lisp-object-type,
 512 [AS_HELP_STRING([--enable-check-lisp-object-type],
 513                 [enable compile time checks for the Lisp_Object data type.
 514                 This is useful for development for catching certain types of bugs.])],
 515 if test "${enableval}" != "no"; then
 516    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 517    [Define this to enable compile time checks for the Lisp_Object data type.])
 518 fi)
 519
 520
 521 dnl The name of this option is unfortunate.  It predates, and has no
 522 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 523 dnl Actually, it stops it working.
 524 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 525 AC_ARG_ENABLE(profiling,
 526 [AS_HELP_STRING([--enable-profiling],
 527                 [build emacs with low-level, gprof profiling support.
 528                 Mainly useful for debugging Emacs itself.  May not work on
 529                 all platforms.  Stops profiler.el working.])],
 530 [ac_enable_profiling="${enableval}"],[])
 531 if test x$ac_enable_profiling != x ; then
 532    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 533 else
 534    PROFILING_CFLAGS=
 535 fi
 536 AC_SUBST(PROFILING_CFLAGS)
 537
 538 AC_ARG_ENABLE(autodepend,
 539 [AS_HELP_STRING([--enable-autodepend],
 540                 [automatically generate dependencies to .h-files.
 541                  Requires gcc, enabled if found.])],
 542 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 543
 544 AC_ARG_ENABLE(gtk-deprecation-warnings,
 545 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 546                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 547 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 548
 549 AC_ARG_ENABLE(deterministic-dump,
 550 [AS_HELP_STRING([--enable-deterministic-dump],
 551                 [Make dumping deterministic by removing system-specific
 552                 information from the dump, such as host names and
 553                 timestamps.])])
 554 if test "x${enableval}" = xno ; then
 555    AC_DEFINE(DETERMINISTIC_DUMP, false,
 556    [Set this to true to make dumping deterministic.])
 557 else
 558    AC_DEFINE(DETERMINISTIC_DUMP, true,
 559    [Set this to true to make dumping deterministic.])
 560 fi
 561
 562 dnl This used to use changequote, but, apart from 'changequote is evil'
 563 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 564 dnl the great gob of text.  Thus it's not processed for possible expansion.
 565 dnl Just make sure the brackets remain balanced.
 566 dnl
 567 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 568 dnl indicated by comments.
 569 dnl quotation begins
 570 [
 571
 572 ### If you add support for a new configuration, add code to this
 573 ### switch statement to recognize your configuration name and select
 574 ### the appropriate opsys.
 575
 576 ### As far as handling version numbers on operating systems is
 577 ### concerned, make sure things will fail in a fixable way.  If
 578 ### /etc/MACHINES doesn't say anything about version numbers, be
 579 ### prepared to handle anything reasonably.  If version numbers
 580 ### matter, be sure /etc/MACHINES says something about it.
 581
 582 opsys='' unported=no
 583 case "${canonical}" in
 584
 585   ## GNU/Linux and similar ports
 586   *-*-linux* )
 587     opsys=gnu-linux
 588   ;;
 589
 590   ## FreeBSD ports
 591   *-*-freebsd* )
 592     opsys=freebsd
 593   ;;
 594
 595   ## DragonFly ports
 596   *-*-dragonfly* )
 597     opsys=dragonfly
 598   ;;
 599
 600   ## FreeBSD kernel + glibc based userland
 601   *-*-kfreebsd*gnu* )
 602     opsys=gnu-kfreebsd
 603   ;;
 604
 605   ## NetBSD ports
 606   *-*-netbsd* )
 607     opsys=netbsd
 608   ;;
 609
 610   ## OpenBSD ports
 611   *-*-openbsd* | *-*-mirbsd* )
 612     opsys=openbsd
 613   ;;
 614
 615   ## Apple Darwin / Mac OS X
 616   *-apple-darwin* )
 617     case "${canonical}" in
 618       *-apple-darwin[0-9].*) unported=yes ;;
 619       i[3456]86-* | x86_64-* )  ;;
 620       * )            unported=yes ;;
 621     esac
 622     opsys=darwin
 623     ## Use fink packages if available.
 624     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 625 ##    if test -d /sw/include && test -d /sw/lib; then
 626 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 627 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 628 ##    fi
 629   ;;
 630
 631   ## Chromium Native Client
 632   *-nacl )
 633     opsys=nacl
 634   ;;
 635
 636   ## Cygwin ports
 637   *-*-cygwin )
 638     opsys=cygwin
 639   ;;
 640
 641   ## HP 9000 series 700 and 800, running HP/UX
 642   hppa*-hp-hpux10.2* )
 643     opsys=hpux10-20
 644   ;;
 645   hppa*-hp-hpux1[1-9]* )
 646     opsys=hpux11
 647     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 648   ;;
 649
 650   ## IBM machines
 651   rs6000-ibm-aix4.[23]* )
 652     opsys=aix4-2
 653   ;;
 654   powerpc-ibm-aix4.[23]*  )
 655     opsys=aix4-2
 656   ;;
 657   rs6000-ibm-aix[56]* )
 658     opsys=aix4-2
 659   ;;
 660   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 661     opsys=aix4-2
 662   ;;
 663
 664   ## Silicon Graphics machines
 665   ## Iris 4D
 666   mips-sgi-irix6.5 )
 667     opsys=irix6-5
 668     # Without defining _LANGUAGE_C, things get masked out in the headers
 669     # so that, for instance, grepping for 'free' in stdlib.h fails and
 670     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 671     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 672   ;;
 673
 674   ## Suns
 675   *-sun-solaris* \
 676     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 677     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 678     case "${canonical}" in
 679       i[3456]86-*-* )   ;;
 680       amd64-*-*|x86_64-*-*) ;;
 681       sparc* )          ;;
 682       * )               unported=yes ;;
 683     esac
 684     case "${canonical}" in
 685       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 686                 opsys=sol2-10
 687                 emacs_check_sunpro_c=yes
 688                 ;;
 689       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 690       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 691       *-sunos5.6* | *-solaris2.6* )
 692                 opsys=sol2-6
 693                 RANLIB="ar -ts"
 694                 ;;
 695       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 696       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 697                 opsys=sol2-6
 698                 emacs_check_sunpro_c=yes
 699                 ;;
 700     esac
 701     ## Watch out for a compiler that we know will not work.
 702     case "${canonical}" in
 703      *-solaris* | *-sunos5* )
 704                 if [ "x$CC" = x/usr/ucb/cc ]; then
 705                   ## /usr/ucb/cc doesn't work;
 706                   ## we should find some other compiler that does work.
 707                   unset CC
 708                 fi
 709                 ;;
 710       *) ;;
 711     esac
 712   ;;
 713
 714   ## Intel 386 machines where we don't care about the manufacturer.
 715   i[3456]86-*-* )
 716     case "${canonical}" in
 717       *-darwin* )               opsys=darwin ;;
 718       *-mingw* )
 719                 opsys=mingw32
 720                 # MinGW overrides and adds some system headers in nt/inc.
 721                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 722                 ;;
 723       *-sysv4.2uw* )            opsys=unixware ;;
 724       *-sysv5uw* )              opsys=unixware ;;
 725       *-sysv5OpenUNIX* )        opsys=unixware ;;
 726       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 727     esac
 728   ;;
 729
 730   # MinGW64
 731   x86_64-*-* )
 732     case "${canonical}" in
 733       *-mingw* )
 734                 opsys=mingw32
 735                 # MinGW overrides and adds some system headers in nt/inc.
 736                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 737                 ;;
 738       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 739     esac
 740   ;;
 741
 742   * )
 743     unported=yes
 744   ;;
 745 esac
 746
 747 ### If the code above didn't choose an operating system, just choose
 748 ### an operating system based on the configuration name.  You really
 749 ### only want to use this when you have no idea what the right
 750 ### operating system is; if you know what operating systems a machine
 751 ### runs, it's cleaner to make it explicit in the case statement
 752 ### above.
 753 if test x"${opsys}" = x; then
 754   case "${canonical}" in
 755     *-gnu* )                            opsys=gnu ;;
 756     * )
 757       unported=yes
 758     ;;
 759   esac
 760 fi
 761
 762 ]
 763 dnl quotation ends
 764
 765 if test $unported = yes; then
 766   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 767 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 768 Check 'etc/MACHINES' for recognized configuration names.])
 769 fi
 770
 771 #### Choose a compiler.
 772
 773 dnl Don't bother to test for C89.
 774 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 775
 776 dnl Sets GCC=yes if using gcc.
 777 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 778 if test -n "$XCRUN"; then
 779   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 780   test -n "$AR" && export AR
 781 fi
 782
 783 dnl Emacs needs C99 or later.
 784 gl_PROG_CC_C99
 785
 786 AM_PROG_CC_C_O
 787
 788 if test x$GCC = xyes; then
 789   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 790 else
 791   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 792 fi
 793
 794 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 795 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 796 dnl that clash with MinGW.
 797 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 798
 799 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 800 AC_DEFUN([gl_CRYPTO_CHECK])
 801 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 802 # as we don't use them.
 803 AC_DEFUN([gl_FCNTL_O_FLAGS])
 804 # Avoid gnulib's test for pthread_sigmask.
 805 funcs=
 806 for func in $ac_func_list; do
 807   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 808 done
 809 ac_func_list=$funcs
 810 # Use the system putenv even if it lacks GNU features, as we don't need them,
 811 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 812 AC_CHECK_FUNCS_ONCE([putenv])
 813 AC_DEFUN([gl_FUNC_PUTENV],
 814   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 815
 816 # Initialize gnulib right after choosing the compiler.
 817 dnl Amongst other things, this sets AR and ARFLAGS.
 818 gl_EARLY
 819
 820 if test "$ac_test_CFLAGS" != set; then
 821   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 822   # if -g3 works and the user does not specify CFLAGS.
 823   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 824   case $CFLAGS in
 825     '-g')
 826       emacs_g3_CFLAGS='-g3';;
 827     '-g -O2')
 828       emacs_g3_CFLAGS='-g3 -O2';;
 829     *)
 830       emacs_g3_CFLAGS='';;
 831   esac
 832   if test -n "$emacs_g3_CFLAGS"; then
 833     emacs_save_CFLAGS=$CFLAGS
 834     CFLAGS=$emacs_g3_CFLAGS
 835     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 836       [emacs_cv_prog_cc_g3],
 837       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 838          [emacs_cv_prog_cc_g3=yes],
 839          [emacs_cv_prog_cc_g3=no])])
 840     if test $emacs_cv_prog_cc_g3 != yes; then
 841       CFLAGS=$emacs_save_CFLAGS
 842     fi
 843     if test $opsys = mingw32; then
 844       CFLAGS="$CFLAGS -gdwarf-2"
 845     fi
 846   fi
 847
 848   case $CFLAGS in
 849     *-O*) ;;
 850     *)
 851       # No optimization flag was inferred for this non-GCC compiler.
 852       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 853       emacs_save_CFLAGS=$CFLAGS
 854       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 855       CFLAGS=${CFLAGS}-O
 856       AC_CACHE_CHECK([whether $CC accepts -O],
 857         [emacs_cv_prog_cc_o],
 858         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 859            [emacs_cv_prog_cc_o=yes],
 860            [emacs_cv_prog_cc_o=no])])
 861       if test $emacs_cv_prog_cc_o != yes; then
 862         CFLAGS=$emacs_save_CFLAGS
 863       fi ;;
 864   esac
 865 fi
 866
 867 AC_ARG_ENABLE([gcc-warnings],
 868   [AS_HELP_STRING([--enable-gcc-warnings],
 869                   [turn on lots of GCC warnings/errors. This is intended for
 870                    developers, and may generate false alarms when used
 871                    with older or non-GNU development tools.])],
 872   [case $enableval in
 873      yes|no) ;;
 874      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 875    esac
 876    gl_gcc_warnings=$enableval],
 877   [gl_gcc_warnings=no]
 878 )
 879
 880 # clang is unduly picky about some things.
 881 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 882   [AC_COMPILE_IFELSE(
 883      [AC_LANG_PROGRAM([[
 884           #ifndef __clang__
 885             error "not clang";
 886           #endif
 887         ]])],
 888      [emacs_cv_clang=yes],
 889      [emacs_cv_clang=no])])
 890
 891 # When compiling with GCC, prefer -isystem to -I when including system
 892 # include files, to avoid generating useless diagnostics for the files.
 893 if test "$gl_gcc_warnings" != yes; then
 894   isystem='-I'
 895   if test "$emacs_cv_clang" = yes
 896   then
 897      # Turn off some warnings if supported.
 898      gl_WARN_ADD([-Wno-switch])
 899      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 900      gl_WARN_ADD([-Wno-pointer-sign])
 901      gl_WARN_ADD([-Wno-string-plus-int])
 902      gl_WARN_ADD([-Wno-unknown-attributes])
 903   fi
 904 else
 905   isystem='-isystem '
 906
 907   # This, $nw, is the list of warnings we disable.
 908   nw=
 909
 910   case $with_x_toolkit in
 911     lucid | athena | motif)
 912        # Old toolkits mishandle 'const'.
 913        nw="$nw -Wwrite-strings"
 914        ;;
 915     *)
 916        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 917        ;;
 918   esac
 919   AC_SUBST([WERROR_CFLAGS])
 920
 921   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 922   nw="$nw -Woverlength-strings"     # Not a problem these days
 923   nw="$nw -Wformat-nonliteral"      # we do this a lot
 924   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 925   nw="$nw -Wswitch-default"         # Too many warnings for now
 926   nw="$nw -Winline"                 # OK to ignore 'inline'
 927   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 928                                     # signed overflow has undefined behavior
 929   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 930   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 931   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 932
 933   # Emacs doesn't care about shadowing; see
 934   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 935   nw="$nw -Wshadow"
 936
 937   # Emacs's use of alloca inhibits protecting the stack.
 938   nw="$nw -Wstack-protector"
 939
 940   # Emacs's use of partly-const functions such as Fgnutls_available_p
 941   # make this option problematic.
 942   nw="$nw -Wsuggest-attribute=const"
 943
 944   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 945   # option problematic.
 946   nw="$nw -Wsuggest-attribute=pure"
 947
 948   # This part is merely for shortening the command line,
 949   # since -Wall implies -Wswitch.
 950   nw="$nw -Wswitch"
 951
 952   # This part is merely for shortening the command line,
 953   # since -Wno-FOO needs to be added below regardless.
 954   nw="$nw -Wmissing-field-initializers"
 955   nw="$nw -Wtype-limits"
 956   nw="$nw -Wunused-parameter"
 957
 958   if test $emacs_cv_clang = yes; then
 959     nw="$nw -Wcast-align"
 960   fi
 961
 962   gl_MANYWARN_ALL_GCC([ws])
 963   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 964   for w in $ws; do
 965     gl_WARN_ADD([$w])
 966   done
 967   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 968   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 969   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 970   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 971   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 972   gl_WARN_ADD([-Wno-format-nonliteral])
 973
 974   # More things that clang is unduly picky about.
 975   if test $emacs_cv_clang = yes; then
 976     gl_WARN_ADD([-Wno-format-extra-args])
 977     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 978     gl_WARN_ADD([-Wno-unused-command-line-argument])
 979     gl_WARN_ADD([-Wno-unused-value])
 980   fi
 981
 982   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 983   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 984   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 985   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 986       without upsetting glibc 2.15+. */
 987    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 988         && defined __OPTIMIZE__ && __OPTIMIZE__)
 989    # define _FORTIFY_SOURCE 2
 990    #endif
 991   ])
 992
 993   # We use a slightly smaller set of warning options for lib/.
 994   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 995   nw=
 996   nw="$nw -Wunused-macros"
 997
 998   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 999   AC_SUBST([GNULIB_WARN_CFLAGS])
1000 fi
1001
1002 edit_cflags="
1003   s,///*,/,g
1004   s/^/ /
1005   s/ -I/ $isystem/g
1006   s/^ //
1007 "
1008
1009 AC_ARG_ENABLE(link-time-optimization,
1010 [AS_HELP_STRING([--enable-link-time-optimization],
1011                 [build emacs with link-time optimization.
1012                  This requires GCC 4.5.0 or later, or clang.
1013                  (Note that clang support is experimental - see INSTALL.)
1014                  It also makes Emacs harder to debug, and when we tried it
1015                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1016                  recommended for typical use.])],
1017 if test "${enableval}" != "no"; then
1018    ac_lto_supported=no
1019    if test $emacs_cv_clang = yes; then
1020       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1021       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1022       if test -x "$GOLD_PLUGIN"; then
1023          LTO="-flto"
1024       fi
1025    elif test x$GCC = xyes; then
1026       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1027       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1028       if test x$CPUS != x; then
1029          LTO="-flto=$CPUS"
1030       else
1031          LTO="-flto"
1032       fi
1033    else
1034       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1035    fi
1036    if test -z "$LTO"; then
1037       ac_lto_supported=no
1038    else
1039       old_CFLAGS=$CFLAGS
1040       CFLAGS="$CFLAGS $LTO"
1041       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1042          [ac_lto_supported=yes], [ac_lto_supported=no])
1043          CFLAGS="$old_CFLAGS"
1044    fi
1045    AC_MSG_RESULT([$ac_lto_supported])
1046    if test "$ac_lto_supported" = "yes"; then
1047       CFLAGS="$CFLAGS $LTO"
1048       if test x$emacs_cv_clang = xyes; then
1049          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1050          # WARNING: 'ar --plugin ...' doesn't work without
1051          # command, so plugin name is appended to ARFLAGS.
1052          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1053          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1054       else
1055         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1056         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1057         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1058         dnl dump core on Fedora 20, so play it safe for now.
1059         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1060           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1061       fi
1062    fi
1063 fi)
1064
1065 dnl Prefer silent make output.  For verbose output, use
1066 dnl 'configure --disable-silent-rules' or 'make V=1' .
1067 AM_SILENT_RULES([yes])
1068 dnl Port to Automake 1.11.
1069 dnl This section can be removed once we assume Automake 1.14 or later.
1070 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1071 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1072 AC_SUBST([AM_V])
1073 AM_SUBST_NOTMAKE([AM_V])
1074 AC_SUBST([AM_DEFAULT_V])
1075 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1076 AC_SUBST([AM_DEFAULT_VERBOSITY])
1077
1078 dnl Some other nice autoconf tests.
1079 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1080 dnl AC_PROG_INSTALL
1081 dnl AC_PROG_MKDIR_P
1082 dnl if test "x$RANLIB" = x; then
1083 dnl   AC_PROG_RANLIB
1084 dnl fi
1085
1086
1087 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1088 dnl can be made to directories.  This is not relevant for our usage, and
1089 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1090 dnl hosted on AFS, both examples where simple links work, but links to
1091 dnl directories fail.  We use a cut-down version instead.
1092 dnl AC_PROG_LN_S
1093
1094 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1095 rm -f conf$$ conf$$.file
1096
1097 LN_S_FILEONLY='cp -p'
1098
1099 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1100 dnl random program in the current directory.
1101 if (echo >conf$$.file) 2>/dev/null; then
1102   if ln -s conf$$.file conf$$ 2>/dev/null; then
1103     if test "$opsys" = "mingw32"; then
1104       LN_S_FILEONLY='/bin/ln -s'
1105     else
1106       LN_S_FILEONLY='ln -s'
1107     fi
1108   elif ln conf$$.file conf$$ 2>/dev/null; then
1109     if test "$opsys" = "mingw32"; then
1110       LN_S_FILEONLY=/bin/ln
1111     else
1112       LN_S_FILEONLY=ln
1113     fi
1114   fi
1115 fi
1116
1117 rm -f conf$$ conf$$.file
1118
1119 if test "$LN_S_FILEONLY" = "ln -s"; then
1120    AC_MSG_RESULT([yes])
1121 else
1122    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1123 fi
1124
1125 AC_SUBST(LN_S_FILEONLY)
1126
1127
1128 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1129 dnl doesn't support links to directories, as in "ln file dir".  But that
1130 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1131 dnl executables at "make install" time.
1132 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1133 dnl for more details.
1134 if test "$opsys" = "mingw32"; then
1135   LN_S="/bin/ln"
1136 fi
1137
1138 dnl On some Debian versions, "install-info" prints irritating messages
1139 dnl "This is not dpkg install-info anymore, but GNU install-info"
1140 dnl if called via an absolute file name.
1141 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1142 dnl Sadly some people may have an old ginstall-info installed on
1143 dnl non-Debian systems, so we can't use this.
1144 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1145 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1146
1147 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1148   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1149 dnl Don't use GZIP, which is used by gzip for additional parameters.
1150 AC_PATH_PROG(GZIP_PROG, gzip)
1151
1152 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1153    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1154
1155 if test $opsys = gnu-linux; then
1156   AC_PATH_PROG(PAXCTL, paxctl,,
1157     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1158   if test "X$PAXCTL" != X; then
1159     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1160     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1161       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1162       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1163   fi
1164
1165   if test "${SETFATTR+set}" != set; then
1166     AC_CACHE_CHECK([for setfattr],
1167       [emacs_cv_prog_setfattr],
1168       [touch conftest.tmp
1169        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1170          emacs_cv_prog_setfattr=yes
1171        else
1172          emacs_cv_prog_setfattr=no
1173        fi])
1174     if test "$emacs_cv_prog_setfattr" = yes; then
1175       SETFATTR=setfattr
1176     else
1177       SETFATTR=
1178     fi
1179     rm -f conftest.tmp
1180     AC_SUBST([SETFATTR])
1181   fi
1182 fi
1183
1184 ## Need makeinfo >= 4.7 (?) to build the manuals.
1185 if test "$MAKEINFO" != "no"; then
1186   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1187     MAKEINFO=makeinfo
1188   fi
1189   case `($MAKEINFO --version) 2>/dev/null` in
1190     *' (GNU texinfo) '4.[[7-9]]* | \
1191     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1192     *' (GNU texinfo) '[[5-9]]* | \
1193     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1194     *) MAKEINFO=no;;
1195   esac
1196 fi
1197
1198 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1199 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1200 ## therefore in the category of "special tools" not normally required, which
1201 ## configure does not have to check for (eg autoconf itself).
1202 ## In a repository checkout on the other hand, the manuals are not included.
1203 ## So makeinfo is a requirement to build from the repository, and configure
1204 ## should test for it as it does for any other build requirement.
1205 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1206 ## with pre-built manuals, from a repository checkout.
1207 HAVE_MAKEINFO=yes
1208
1209 if test "$MAKEINFO" = "no"; then
1210   MAKEINFO=makeinfo
1211   if test "x${with_makeinfo}" = "xno"; then
1212     HAVE_MAKEINFO=no
1213   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1214     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1215 source tree does not seem to have pre-built manuals in the 'info' directory.
1216 Either install a suitable version of makeinfo, or re-run configure
1217 with the '--without-makeinfo' option to build without the manuals.] )
1218   fi
1219 fi
1220 AC_SUBST(HAVE_MAKEINFO)
1221
1222 if test $opsys = mingw32; then
1223    DOCMISC_W32=efaq-w32
1224 else
1225    DOCMISC_W32=
1226 fi
1227 AC_SUBST(DOCMISC_W32)
1228
1229 dnl Add our options to ac_link now, after it is set up.
1230
1231 if test x$GCC = xyes; then
1232   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1233     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1234 else
1235   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1236     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1237 fi
1238
1239 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1240 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1241 dnl (Don't use '-z nocombreloc' as -z takes no arg on Irix.)
1242 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1243 dnl if not built to support GNU ld.
1244
1245 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1246 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1247 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1248 dnl   Eg "make LDFLAGS=... all" could run into problems,
1249 dnl   http://bugs.debian.org/684788
1250 dnl * unnecessary, since temacs is the only thing that actually needs it.
1251 dnl   Indeed this is where it was originally, prior to:
1252 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1253 late_LDFLAGS="$LDFLAGS"
1254 if test x$GCC = xyes; then
1255   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1256 else
1257   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1258 fi
1259
1260 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1261
1262 AC_MSG_CHECKING([for -znocombreloc])
1263 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1264   [AC_MSG_RESULT(yes)],
1265   LDFLAGS_NOCOMBRELOC=
1266   [AC_MSG_RESULT(no)])
1267
1268 LDFLAGS="$late_LDFLAGS"
1269
1270 AC_CACHE_CHECK([whether addresses are sanitized],
1271   [emacs_cv_sanitize_address],
1272   [AC_COMPILE_IFELSE(
1273      [AC_LANG_PROGRAM(
1274         [[#ifndef __has_feature
1275           #define __has_feature(f) 0
1276           #endif
1277           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1278           #else
1279            error "Addresses are not sanitized.";
1280           #endif
1281         ]])],
1282      [emacs_cv_sanitize_address=yes],
1283      [emacs_cv_sanitize_address=no])])
1284
1285 dnl The function dump-emacs will not be defined and temacs will do
1286 dnl (load "loadup") automatically unless told otherwise.
1287 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1288 case "$opsys" in
1289   nacl) CANNOT_DUMP=yes ;;
1290 esac
1291
1292 if test "$CANNOT_DUMP" = "yes"; then
1293   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1294 elif test "$emacs_cv_sanitize_address" = yes; then
1295   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1296 fi
1297
1298 AC_SUBST(CANNOT_DUMP)
1299
1300
1301 UNEXEC_OBJ=unexelf.o
1302 case "$opsys" in
1303   # MSDOS uses unexcoff.o
1304   aix4-2)
1305    UNEXEC_OBJ=unexaix.o
1306    ;;
1307   cygwin)
1308    UNEXEC_OBJ=unexcw.o
1309    ;;
1310   darwin)
1311    UNEXEC_OBJ=unexmacosx.o
1312    ;;
1313   hpux10-20 | hpux11)
1314    UNEXEC_OBJ=unexhp9k800.o
1315    ;;
1316   mingw32)
1317    UNEXEC_OBJ=unexw32.o
1318    ;;
1319   sol2-10)
1320    # Use the Solaris dldump() function, called from unexsol.c, to dump
1321    # emacs, instead of the generic ELF dump code found in unexelf.c.
1322    # The resulting binary has a complete symbol table, and is better
1323    # for debugging and other observability tools (debuggers, pstack, etc).
1324    #
1325    # If you encounter a problem using dldump(), please consider sending
1326    # a message to the OpenSolaris tools-linking mailing list:
1327    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1328    #
1329    # It is likely that dldump() works with older Solaris too, but this has
1330    # not been tested, so for now this change is for Solaris 10 or newer.
1331    UNEXEC_OBJ=unexsol.o
1332    ;;
1333 esac
1334
1335 LD_SWITCH_SYSTEM=
1336 case "$opsys" in
1337   freebsd|dragonfly)
1338    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1339    ## The system compiler, GCC, has apparently been modified to not
1340    ## look there, contrary to what a stock GCC would do.
1341 ### It's not our place to do this.  See bug#10313#17.
1342 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1343       :
1344    ;;
1345
1346   gnu-linux)
1347    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1348    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1349    ;;
1350
1351   netbsd)
1352 ### It's not our place to do this.  See bug#10313#17.
1353 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1354       :
1355    ;;
1356
1357   openbsd)
1358    ## Han Boetes <han@boetes.org> says this is necessary,
1359    ## otherwise Emacs dumps core on elf systems.
1360    LD_SWITCH_SYSTEM="-Z"
1361    ;;
1362 esac
1363 AC_SUBST(LD_SWITCH_SYSTEM)
1364
1365 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1366
1367 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1368 ## which has not been defined yet.  When this was handled with cpp,
1369 ## it was expanded to null when configure sourced the s/*.h file.
1370 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1371 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1372 ## (or somesuch), but because it is supposed to go at the _front_
1373 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1374 ## Compare with the gnu-linux case below, which added to the end
1375 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1376 ## LD_SWITCH_SYSTEM_TEMACS.
1377 case "$opsys" in
1378   netbsd|openbsd)
1379    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1380 esac
1381
1382
1383 C_SWITCH_MACHINE=
1384 case $canonical in
1385  alpha*)
1386   AC_CHECK_DECL([__ELF__])
1387   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1388     ## With ELF, make sure that all common symbols get allocated to in the
1389     ## data section.  Otherwise, the dump of temacs may miss variables in
1390     ## the shared library that have been initialized.  For example, with
1391     ## GNU libc, __malloc_initialized would normally be resolved to the
1392     ## shared library's .bss section, which is fatal.
1393     if test "x$GCC" = "xyes"; then
1394       C_SWITCH_MACHINE="-fno-common"
1395     else
1396       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1397     fi
1398   else
1399       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1400       dnl albeit under the mistaken assumption that said file
1401       dnl was no longer used.
1402       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1403   fi
1404   ;;
1405 esac
1406 AC_SUBST(C_SWITCH_MACHINE)
1407
1408 AC_SUBST(UNEXEC_OBJ)
1409
1410 C_SWITCH_SYSTEM=
1411 ## Some programs in src produce warnings saying certain subprograms
1412 ## are too complex and need a MAXMEM value greater than 2000 for
1413 ## additional optimization.  --nils@exp-math.uni-essen.de
1414 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1415   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1416 if test "$opsys" = "mingw32"; then
1417   case "$canonical" in
1418     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1419     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1420   esac
1421 fi
1422 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1423 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1424 AC_SUBST(C_SWITCH_SYSTEM)
1425
1426
1427 LIBS_SYSTEM=
1428 case "$opsys" in
1429   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1430   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1431
1432   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1433
1434   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1435
1436   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1437
1438   ## Motif needs -lgen.
1439   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1440 esac
1441
1442 AC_SUBST(LIBS_SYSTEM)
1443
1444 ### Make sure subsequent tests use flags consistent with the build flags.
1445
1446 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1447   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1448 else
1449   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1450 fi
1451
1452 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1453 AC_DEFUN([AC_TYPE_SIZE_T])
1454 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1455 AC_DEFUN([AC_TYPE_UID_T])
1456
1457 # sqrt and other floating-point functions such as fmod and frexp
1458 # are found in -lm on many systems.
1459 OLD_LIBS=$LIBS
1460 AC_SEARCH_LIBS([sqrt], [m])
1461 if test "X$LIBS" = "X$OLD_LIBS"; then
1462   LIB_MATH=
1463 else
1464   LIB_MATH=$ac_cv_search_sqrt
1465 fi
1466 LIBS=$OLD_LIBS
1467
1468 dnl Current possibilities handled by sed (aix4-2 -> aix,
1469 dnl gnu-linux -> gnu/linux, etc.):
1470 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1471 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1472 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1473
1474 case $opsys in
1475   cygwin )
1476     LIB_MATH=
1477     ;;
1478   darwin )
1479     ## Adding -lm confuses the dynamic linker, so omit it.
1480     LIB_MATH=
1481     ;;
1482   freebsd | dragonfly )
1483     SYSTEM_TYPE=berkeley-unix
1484     ;;
1485   gnu-linux | gnu-kfreebsd )
1486     ;;
1487   hpux10-20 | hpux11 )
1488     ;;
1489   mingw32 )
1490     LIB_MATH=
1491     SYSTEM_TYPE=windows-nt
1492     ;;
1493   dnl NB this may be adjusted below.
1494   netbsd | openbsd )
1495     SYSTEM_TYPE=berkeley-unix
1496     ;;
1497
1498   sol2* | unixware )
1499     SYSTEM_TYPE=usg-unix-v
1500     ;;
1501
1502 esac
1503
1504 AC_SUBST(LIB_MATH)
1505 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1506   [The type of system you are compiling for; sets 'system-type'.])
1507
1508
1509 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1510 pre_PKG_CONFIG_LIBS=$LIBS
1511
1512 PKG_PROG_PKG_CONFIG(0.9.0)
1513
1514 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1515 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1516 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1517 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1518 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1519 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1520 dnl actions.
1521 AC_DEFUN([EMACS_CHECK_MODULES],
1522   [PKG_CHECK_MODULES([$1], [$2],
1523      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1524       m4_default([$3], [HAVE_$1=yes])],
1525      [m4_default([$4], [HAVE_$1=no])])])
1526
1527 HAVE_SOUND=no
1528 if test "${with_sound}" != "no"; then
1529   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1530   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1531     have_sound_header=yes, [], [
1532     #ifdef __MINGW32__
1533     #define WIN32_LEAN_AND_MEAN
1534     #include <windows.h>
1535     #endif
1536     ])
1537   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1538     AC_MSG_ERROR([OSS sound support requested but not found.])
1539
1540   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1541     # Emulation library used on NetBSD.
1542     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1543     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1544       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1545     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1546     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1547   fi
1548   AC_SUBST(LIBSOUND)
1549
1550   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1551     ALSA_REQUIRED=1.0.0
1552     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1553     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1554     if test $HAVE_ALSA = yes; then
1555       SAVE_CFLAGS="$CFLAGS"
1556       SAVE_LIBS="$LIBS"
1557       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1558       LIBS="$ALSA_LIBS $LIBS"
1559       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1560                       emacs_alsa_normal=yes,
1561                     emacs_alsa_normal=no)
1562       if test "$emacs_alsa_normal" != yes; then
1563         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1564                        [[snd_lib_error_set_handler (0);]])],
1565                        emacs_alsa_subdir=yes,
1566                      emacs_alsa_subdir=no)
1567         if test "$emacs_alsa_subdir" != yes; then
1568           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1569         fi
1570         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1571       fi
1572
1573       CFLAGS="$SAVE_CFLAGS"
1574       LIBS="$SAVE_LIBS"
1575       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1576       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1577       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1578     elif test "${with_sound}" = "alsa"; then
1579       AC_MSG_ERROR([ALSA sound support requested but not found.])
1580     fi
1581   fi                            dnl with_sound = alsa|yes
1582
1583   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1584   dnl compiles only on the specified platforms.  For others, it
1585   dnl probably doesn't make sense to try.
1586   dnl FIXME So surely we should bypass this whole section if not using
1587   dnl one of these platforms?
1588   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1589      case "$opsys" in
1590        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1591        dnl Adjust the --with-sound help text if you change this.
1592        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1593          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1594          HAVE_SOUND=yes
1595          ;;
1596      esac
1597   fi
1598
1599   AC_SUBST(CFLAGS_SOUND)
1600 fi
1601
1602 dnl checks for header files
1603 AC_CHECK_HEADERS_ONCE(
1604   malloc.h
1605   sys/systeminfo.h
1606   sys/sysinfo.h
1607   coff.h pty.h
1608   sys/resource.h
1609   sys/utsname.h pwd.h utmp.h util.h)
1610
1611 AC_MSG_CHECKING(if personality LINUX32 can be set)
1612 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1613                emacs_cv_personality_linux32=yes,
1614                emacs_cv_personality_linux32=no)
1615 AC_MSG_RESULT($emacs_cv_personality_linux32)
1616
1617 if test $emacs_cv_personality_linux32 = yes; then
1618   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1619             [Define to 1 if personality LINUX32 can be set.])
1620 fi
1621
1622 # Note that Solaris has sys/sysinfo.h which defines struct
1623 # sysinfo as well.  To make sure that we're using GNU/Linux
1624 # sysinfo, we explicitly set one of its fields.
1625 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1626   AC_MSG_CHECKING([if Linux sysinfo may be used])
1627   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1628                                      [[struct sysinfo si;
1629                                        si.totalram = 0;
1630                                        sysinfo (&si)]])],
1631     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1632   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1633   if test $emacs_cv_linux_sysinfo = yes; then
1634     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1635     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1636                                        [[struct sysinfo si; return si.mem_unit]])],
1637       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1638                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1639   fi
1640 fi
1641
1642 dnl On Solaris 8 there's a compilation warning for term.h because
1643 dnl it doesn't define 'bool'.
1644 AC_CHECK_HEADERS(term.h, , , -)
1645 AC_HEADER_TIME
1646 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1647                                       ]])
1648 if test $ac_cv_have_decl_sys_siglist != yes; then
1649   # For Tru64, at least:
1650   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1651                                           ]])
1652 fi
1653 AC_HEADER_SYS_WAIT
1654
1655 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1656 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1657 #if HAVE_SYS_SOCKET_H
1658 #include <sys/socket.h>
1659 #endif])
1660 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1661 #if HAVE_SYS_SOCKET_H
1662 #include <sys/socket.h>
1663 #endif])
1664 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1665 #if HAVE_SYS_SOCKET_H
1666 #include <sys/socket.h>
1667 #endif])
1668
1669 dnl checks for structure members
1670 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1671                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1672                   struct ifreq.ifr_addr,
1673                   struct ifreq.ifr_addr.sa_len], , ,
1674                  [AC_INCLUDES_DEFAULT
1675 #if HAVE_SYS_SOCKET_H
1676 #include <sys/socket.h>
1677 #endif
1678 #if HAVE_NET_IF_H
1679 #include <net/if.h>
1680 #endif])
1681
1682 dnl Check for endianness.
1683 dnl AC_C_BIGENDIAN is done by gnulib.
1684
1685 dnl check for Make feature
1686
1687 AUTO_DEPEND=no
1688 dnl check if we have GCC and autodepend is on.
1689 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1690    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1691    SAVE_CFLAGS="$CFLAGS"
1692    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1693    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1694    CFLAGS="$SAVE_CFLAGS"
1695    test -f deps.d || ac_enable_autodepend=no
1696    rm -rf deps.d
1697    AC_MSG_RESULT([$ac_enable_autodepend])
1698    if test $ac_enable_autodepend = yes; then
1699       AUTO_DEPEND=yes
1700    fi
1701 fi
1702 AC_SUBST(AUTO_DEPEND)
1703
1704 dnl checks for operating system services
1705 AC_SYS_LONG_FILE_NAMES
1706
1707 #### Choose a window system.
1708
1709 ## We leave window_system equal to none if
1710 ## we end up building without one.  Any new window system should
1711 ## set window_system to an appropriate value and add objects to
1712 ## window-system-specific substs.
1713
1714 window_system=none
1715 AC_PATH_X
1716 if test "$no_x" != yes; then
1717   window_system=x11
1718 fi
1719
1720 LD_SWITCH_X_SITE_RPATH=
1721 if test "${x_libraries}" != NONE; then
1722   if test -n "${x_libraries}"; then
1723     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1724     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1725       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1726     `
1727   fi
1728   x_default_search_path=""
1729   x_search_path=${x_libraries}
1730   if test -z "${x_search_path}"; then
1731     x_search_path=/usr/lib
1732   fi
1733   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1734                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1735     x_search_path="\
1736 ${x_library}/X11/%L/%T/%N%C%S:\
1737 ${x_library}/X11/%l/%T/%N%C%S:\
1738 ${x_library}/X11/%T/%N%C%S:\
1739 ${x_library}/X11/%L/%T/%N%S:\
1740 ${x_library}/X11/%l/%T/%N%S:\
1741 ${x_library}/X11/%T/%N%S"
1742     if test x"${x_default_search_path}" = x; then
1743       x_default_search_path=${x_search_path}
1744     else
1745       x_default_search_path="${x_search_path}:${x_default_search_path}"
1746     fi
1747   done
1748 fi
1749 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1750
1751 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1752   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1753 fi
1754
1755 if test x"${x_includes}" = x; then
1756   bitmapdir=/usr/include/X11/bitmaps
1757 else
1758   # accumulate include directories that have X11 bitmap subdirectories
1759   bmd_acc=
1760   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1761     if test -d "${bmd}/X11/bitmaps"; then
1762       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1763     fi
1764     if test -d "${bmd}/bitmaps"; then
1765       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1766     fi
1767   done
1768   bitmapdir=${bmd_acc#:}
1769 fi
1770
1771 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1772 HAVE_NS=no
1773 NS_GNUSTEP_CONFIG=no
1774 NS_IMPL_COCOA=no
1775 NS_IMPL_GNUSTEP=no
1776 tmp_CPPFLAGS="$CPPFLAGS"
1777 tmp_CFLAGS="$CFLAGS"
1778 CPPFLAGS="$CPPFLAGS -x objective-c"
1779 CFLAGS="$CFLAGS -x objective-c"
1780 GNU_OBJC_CFLAGS=
1781 LIBS_GNUSTEP=
1782 if test "${with_ns}" != no; then
1783   if test "${opsys}" = darwin; then
1784      NS_IMPL_COCOA=yes
1785      ns_appdir=`pwd`/nextstep/Emacs.app
1786      ns_appbindir=${ns_appdir}/Contents/MacOS
1787      ns_appresdir=${ns_appdir}/Contents/Resources
1788      ns_appsrc=Cocoa/Emacs.base
1789      ns_fontfile=macfont.o
1790   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1791      NS_IMPL_GNUSTEP=yes
1792      NS_GNUSTEP_CONFIG=yes
1793      GNU_OBJC_CFLAGS=$flags
1794      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1795   elif test -f $GNUSTEP_CONFIG_FILE; then
1796      NS_IMPL_GNUSTEP=yes
1797      dnl FIXME sourcing this several times in subshells seems inefficient.
1798      GNUSTEP_SYSTEM_HEADERS=$(
1799        . $GNUSTEP_CONFIG_FILE
1800        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1801      )
1802      GNUSTEP_SYSTEM_LIBRARIES=$(
1803        . $GNUSTEP_CONFIG_FILE
1804        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1805      )
1806      dnl I seemed to need these as well with GNUstep-startup 0.25.
1807      GNUSTEP_LOCAL_HEADERS=$(
1808        . $GNUSTEP_CONFIG_FILE
1809        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1810      )
1811      GNUSTEP_LOCAL_LIBRARIES=$(
1812        . $GNUSTEP_CONFIG_FILE
1813        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1814      )
1815      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1816        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1817      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1818        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1819      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1820      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1821      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1822      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1823      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1824      dnl If they had chosen to either define it or not, we could have
1825      dnl just used AC_CHECK_DECL here.
1826      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1827        emacs_cv_objc_exceptions,
1828 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1829 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1830 1;
1831 #else
1832 fail;
1833 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1834      if test $emacs_cv_objc_exceptions = yes; then
1835        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1836        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1837          [Define if GNUstep uses ObjC exceptions.])
1838        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1839      fi
1840   fi
1841   if test $NS_IMPL_GNUSTEP = yes; then
1842      ns_appdir=`pwd`/nextstep/Emacs.app
1843      ns_appbindir=${ns_appdir}
1844      ns_appresdir=${ns_appdir}/Resources
1845      ns_appsrc=GNUstep/Emacs.base
1846      ns_fontfile=nsfont.o
1847   fi
1848
1849   dnl This is only used while we test the NS headers, it gets reset below.
1850   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1851   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1852
1853   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1854                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1855 are required for a Nextstep build are missing or cannot be compiled.
1856 Either fix this, or re-configure with the option '--without-ns'.])])
1857
1858   macfont_file=""
1859   if test "${NS_IMPL_COCOA}" = "yes"; then
1860     AC_MSG_CHECKING([for OSX 10.6 or newer])
1861     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1862                                      [
1863 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1864 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1865  ; /* OK */
1866 #else
1867  error "OSX 10.6 or newer required";
1868 #endif
1869 #endif
1870                     ])],
1871                     ns_osx_have_106=yes,
1872                     ns_osx_have_106=no)
1873     AC_MSG_RESULT([$ns_osx_have_106])
1874
1875     if test $ns_osx_have_106 = no; then
1876        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1877     fi
1878   fi
1879 fi
1880
1881 AC_SUBST(LIBS_GNUSTEP)
1882
1883 INSTALL_ARCH_INDEP_EXTRA=install-etc
1884 ns_self_contained=no
1885 NS_OBJ=
1886 NS_OBJC_OBJ=
1887 if test "${HAVE_NS}" = yes; then
1888   if test "$with_toolkit_scroll_bars" = "no"; then
1889     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1890   fi
1891
1892   window_system=nextstep
1893   # set up packaging dirs
1894   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1895      ns_self_contained=yes
1896      prefix=${ns_appresdir}
1897      exec_prefix=${ns_appbindir}
1898      dnl This one isn't really used, only archlibdir is.
1899      libexecdir="\${ns_appbindir}/libexec"
1900      archlibdir="\${ns_appbindir}/libexec"
1901      etcdocdir="\${ns_appresdir}/etc"
1902      etcdir="\${ns_appresdir}/etc"
1903      dnl FIXME maybe set datarootdir instead.
1904      dnl That would also get applications, icons, man.
1905      infodir="\${ns_appresdir}/info"
1906      mandir="\${ns_appresdir}/man"
1907      lispdir="\${ns_appresdir}/lisp"
1908      test "$locallisppathset" = no && locallisppath=""
1909      INSTALL_ARCH_INDEP_EXTRA=
1910   fi
1911
1912   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1913 fi
1914 CFLAGS="$tmp_CFLAGS"
1915 CPPFLAGS="$tmp_CPPFLAGS"
1916 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1917 AC_SUBST(ns_self_contained)
1918 AC_SUBST(NS_OBJ)
1919 AC_SUBST(NS_OBJC_OBJ)
1920
1921 HAVE_W32=no
1922 W32_OBJ=
1923 W32_LIBS=
1924 EMACSRES=
1925 CLIENTRES=
1926 CLIENTW=
1927 W32_RES_LINK=
1928 EMACS_MANIFEST=
1929 UPDATE_MANIFEST=
1930 if test "${with_w32}" != no; then
1931   case "${opsys}" in
1932     cygwin)
1933       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1934              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1935                    cannot be found.])])
1936     ;;
1937     mingw32)
1938     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1939     ;;
1940     *)
1941       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1942     ;;
1943   esac
1944 fi
1945
1946 if test "${opsys}" = "mingw32"; then
1947   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1948   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1949      #include <windows.h>
1950      #include <usp10.h>]],
1951    [[PIMAGE_NT_HEADERS pHeader;
1952      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1953    [emacs_cv_w32api=yes
1954     HAVE_W32=yes],
1955    emacs_cv_w32api=no)
1956   AC_MSG_RESULT($emacs_cv_w32api)
1957   if test "${emacs_cv_w32api}" = "no"; then
1958     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1959   fi
1960 fi
1961
1962 FIRSTFILE_OBJ=
1963 NTDIR=
1964 LIBS_ECLIENT=
1965 LIB_WSOCK32=
1966 NTLIB=
1967 CM_OBJ="cm.o"
1968 XARGS_LIMIT=
1969 if test "${HAVE_W32}" = "yes"; then
1970   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1971   if test "$with_toolkit_scroll_bars" = "no"; then
1972     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1973   fi
1974   AC_CHECK_TOOL(WINDRES, [windres],
1975                 [AC_MSG_ERROR([No resource compiler found.])])
1976   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1977   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1978   EMACSRES="emacs.res"
1979   case "$canonical" in
1980     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1981     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1982   esac
1983   dnl Construct something of the form "24,4,0,0" with 4 components.
1984   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1985
1986   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1987   AC_SUBST(comma_version)
1988   AC_SUBST(comma_space_version)
1989   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1990   if test "${opsys}" = "cygwin"; then
1991     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1992     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1993     # Tell the linker that emacs.res is an object (which we compile from
1994     # the rc file), not a linker script.
1995     W32_RES_LINK="-Wl,emacs.res"
1996   else
1997     UPDATE_MANIFEST=update-game-score.exe.manifest
1998     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1999     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
2000     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
2001     W32_RES_LINK="\$(EMACSRES)"
2002     CLIENTRES="emacsclient.res"
2003     CLIENTW="emacsclientw\$(EXEEXT)"
2004     FIRSTFILE_OBJ=firstfile.o
2005     NTDIR=nt
2006     CM_OBJ=
2007     LIBS_ECLIENT="-lcomctl32"
2008     LIB_WSOCK32="-lwsock32"
2009     NTLIB="ntlib.$ac_objext"
2010     XARGS_LIMIT="-s 10000"
2011   fi
2012 fi
2013 AC_SUBST(W32_OBJ)
2014 AC_SUBST(W32_LIBS)
2015 AC_SUBST(EMACSRES)
2016 AC_SUBST(EMACS_MANIFEST)
2017 AC_SUBST(UPDATE_MANIFEST)
2018 AC_SUBST(CLIENTRES)
2019 AC_SUBST(CLIENTW)
2020 AC_SUBST(W32_RES_LINK)
2021 AC_SUBST(FIRSTFILE_OBJ)
2022 AC_SUBST(NTDIR)
2023 AC_SUBST(CM_OBJ)
2024 AC_SUBST(LIBS_ECLIENT)
2025 AC_SUBST(LIB_WSOCK32)
2026 AC_SUBST(NTLIB)
2027 AC_SUBST(XARGS_LIMIT)
2028
2029 if test "${HAVE_W32}" = "yes"; then
2030   window_system=w32
2031   with_xft=no
2032 fi
2033
2034 ## $window_system is now set to the window system we will
2035 ## ultimately use.
2036
2037 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2038    # Too many warnings for now.
2039    nw=
2040    nw="$nw -Wsuggest-attribute=noreturn"
2041    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2042
2043    gl_WARN_ADD([-Wno-unused-variable])
2044    gl_WARN_ADD([-Wno-unused-but-set-variable])
2045    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2046 fi
2047
2048 term_header=
2049 HAVE_X_WINDOWS=no
2050 HAVE_X11=no
2051 USE_X_TOOLKIT=none
2052
2053 case "${window_system}" in
2054   x11 )
2055     HAVE_X_WINDOWS=yes
2056     HAVE_X11=yes
2057     term_header=xterm.h
2058     case "${with_x_toolkit}" in
2059       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2060       motif ) USE_X_TOOLKIT=MOTIF ;;
2061       gtk ) with_gtk=yes
2062             term_header=gtkutil.h
2063 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2064 dnl USE_X_TOOLKIT is set.
2065             USE_X_TOOLKIT=none ;;
2066       gtk2 ) with_gtk2=yes
2067              term_header=gtkutil.h
2068              USE_X_TOOLKIT=none ;;
2069       gtk3 ) with_gtk3=yes
2070              term_header=gtkutil.h
2071              USE_X_TOOLKIT=none ;;
2072       no ) USE_X_TOOLKIT=none ;;
2073 dnl If user did not say whether to use a toolkit, make this decision later:
2074 dnl use the toolkit if we have gtk, or X11R5 or newer.
2075       * ) USE_X_TOOLKIT=maybe ;;
2076     esac
2077   ;;
2078   nextstep )
2079     term_header=nsterm.h
2080   ;;
2081   w32 )
2082     term_header=w32term.h
2083   ;;
2084 esac
2085
2086 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2087    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2088    if test "$HAVE_XSERVER" = true ||
2089       test -n "$DISPLAY" ||
2090       {
2091         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2092         test "$emacs_libX11" != '/usr/lib/libX11.*'
2093       }
2094    then
2095         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2096 were found.  You should install the relevant development files for X
2097 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2098 sure you have development files for image handling, i.e.
2099 tiff, gif, jpeg, png and xpm.
2100 If you are sure you want Emacs compiled without X window support, pass
2101   --without-x
2102 to configure.])
2103    fi
2104 fi
2105
2106 # Does the opsystem file prohibit the use of the GNU malloc?
2107 # Assume not, until told otherwise.
2108 GNU_MALLOC=yes
2109
2110 AC_CACHE_CHECK(
2111   [whether malloc is Doug Lea style],
2112   [emacs_cv_var_doug_lea_malloc],
2113   [emacs_cv_var_doug_lea_malloc=no
2114    dnl Hooks do not work with address sanitization.
2115    if test "$emacs_cv_sanitize_address" != yes; then
2116      AC_LINK_IFELSE(
2117        [AC_LANG_PROGRAM(
2118           [[#include <malloc.h>
2119             static void hook (void) {}]],
2120           [[malloc_set_state (malloc_get_state ());
2121             __after_morecore_hook = hook;
2122             __malloc_initialize_hook = hook;]])],
2123        [emacs_cv_var_doug_lea_malloc=yes])
2124    fi])
2125 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2126
2127 system_malloc=$emacs_cv_sanitize_address
2128
2129 hybrid_malloc=
2130
2131 case "$opsys" in
2132   ## darwin ld insists on the use of malloc routines in the System framework.
2133   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2134   cygwin) hybrid_malloc=yes;;
2135 esac
2136
2137 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2138    && test "${UNEXEC_OBJ}" = unexelf.o; then
2139   hybrid_malloc=yes
2140 fi
2141
2142 GMALLOC_OBJ=
2143 HYBRID_MALLOC=
2144 if test "${system_malloc}" = "yes"; then
2145   AC_DEFINE([SYSTEM_MALLOC], 1,
2146     [Define to 1 to use the system memory allocator, even if it is not
2147      Doug Lea style.])
2148   GNU_MALLOC=no
2149   GNU_MALLOC_reason="
2150     (The GNU allocators don't work with this system configuration.)"
2151   VMLIMIT_OBJ=
2152 elif test "$hybrid_malloc" = yes; then
2153   AC_DEFINE(HYBRID_MALLOC, 1,
2154     [Define to use gmalloc before dumping and the system malloc after.])
2155   HYBRID_MALLOC=1
2156   GNU_MALLOC=
2157   GNU_MALLOC_reason="only before dumping"
2158   GMALLOC_OBJ=gmalloc.o
2159   VMLIMIT_OBJ=
2160 else
2161   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2162   VMLIMIT_OBJ=vm-limit.o
2163
2164   AC_CHECK_HEADERS([sys/vlimit.h])
2165   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2166     [AC_LINK_IFELSE(
2167        [AC_LANG_PROGRAM(
2168          [[extern char data_start[]; char ch;]],
2169          [[return data_start < &ch;]])],
2170        [emacs_cv_data_start=yes],
2171        [emacs_cv_data_start=no])])
2172   if test $emacs_cv_data_start = yes; then
2173     AC_DEFINE([HAVE_DATA_START], 1,
2174       [Define to 1 if data_start is the address of the start
2175        of the main data segment.])
2176   fi
2177 fi
2178 AC_SUBST([HYBRID_MALLOC])
2179 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2180 AC_SUBST(GMALLOC_OBJ)
2181 AC_SUBST(VMLIMIT_OBJ)
2182
2183 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2184   if test "$GNU_MALLOC" = yes ; then
2185     GNU_MALLOC_reason="
2186       (Using Doug Lea's new malloc from the GNU C Library.)"
2187   fi
2188   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2189     [Define to 1 if the system memory allocator is Doug Lea style,
2190      with malloc hooks and malloc_set_state.])
2191
2192   ## Use mmap directly for allocating larger buffers.
2193   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2194   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2195   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2196   case "$opsys" in
2197     mingw32|gnu*) REL_ALLOC=no ;;
2198   esac
2199 fi
2200
2201 if test x"${REL_ALLOC}" = x; then
2202   REL_ALLOC=${GNU_MALLOC}
2203 fi
2204
2205 use_mmap_for_buffers=no
2206 case "$opsys" in
2207   cygwin|mingw32|irix6-5) use_mmap_for_buffers=yes ;;
2208 esac
2209
2210 AC_FUNC_MMAP
2211 if test $use_mmap_for_buffers = yes; then
2212   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2213   REL_ALLOC=no
2214 fi
2215
2216 LIBS="$LIBS_SYSTEM $LIBS"
2217
2218 dnl FIXME replace main with a function we actually want from this library.
2219 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2220
2221 dnl Check for the POSIX thread library.
2222 LIB_PTHREAD=
2223 AC_CHECK_HEADERS_ONCE(pthread.h)
2224 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2225   AC_CACHE_CHECK([for pthread library],
2226     [emacs_cv_pthread_lib],
2227     [emacs_cv_pthread_lib=no
2228      OLD_LIBS=$LIBS
2229      for emacs_pthread_lib in 'none needed' -lpthread; do
2230        case $emacs_pthread_lib in
2231          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2232        esac
2233        AC_LINK_IFELSE(
2234          [AC_LANG_PROGRAM(
2235             [[#include <pthread.h>
2236               #include <signal.h>
2237               sigset_t old_mask, new_mask;
2238               void noop (void) {}]],
2239             [[pthread_t th = pthread_self ();
2240               int status = 0;
2241               status += pthread_create (&th, 0, 0, 0);
2242               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2243               status += pthread_kill (th, 0);
2244               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2245                      || defined DOUG_LEA_MALLOC)
2246               /* Test for pthread_atfork only if gmalloc uses it,
2247                  as older-style hosts like MirBSD 10 lack it.  */
2248               status += pthread_atfork (noop, noop, noop);
2249               #endif
2250               return status;]])],
2251          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2252        LIBS=$OLD_LIBS
2253        if test "$emacs_cv_pthread_lib" != no; then
2254          break
2255        fi
2256      done])
2257   if test "$emacs_cv_pthread_lib" != no; then
2258     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2259     case $emacs_cv_pthread_lib in
2260       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2261     esac
2262     ac_cv_func_pthread_sigmask=yes
2263     # Some systems optimize for single-threaded programs by default, and
2264     # need special flags to disable these optimizations. For example, the
2265     # definition of 'errno' in <errno.h>.
2266     case $opsys in
2267       hpux* | sol*)
2268         AC_DEFINE([_REENTRANT], 1,
2269           [Define to 1 if your system requires this in multithreaded code.]);;
2270       aix4-2)
2271         AC_DEFINE([_THREAD_SAFE], 1,
2272           [Define to 1 if your system requires this in multithreaded code.]);;
2273     esac
2274   fi
2275 fi
2276 AC_SUBST([LIB_PTHREAD])
2277
2278 dnl Check for need for bigtoc support on IBM AIX
2279
2280 case ${host_os} in
2281 aix*)
2282   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2283     case $GCC in
2284     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2285     *) gdb_cv_bigtoc=-bbigtoc ;;
2286     esac
2287
2288     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2289     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2290   ])
2291   ;;
2292 esac
2293
2294 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2295 # is for the tests that follow.  We set them back later on.
2296
2297 REAL_CFLAGS="$CFLAGS"
2298 REAL_CPPFLAGS="$CPPFLAGS"
2299 REAL_LIBS="$LIBS"
2300
2301 if test "${HAVE_X11}" = "yes"; then
2302   DEFS="$C_SWITCH_X_SITE $DEFS"
2303   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2304   LIBS="-lX11 $LIBS"
2305   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2306   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2307
2308   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2309   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2310   # but it's more convenient here to set LD_RUN_PATH since this
2311   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2312   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2313     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2314     export LD_RUN_PATH
2315   fi
2316
2317   if test "${opsys}" = "gnu-linux"; then
2318     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2319     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2320      [[XOpenDisplay ("foo");]])],
2321      [xgnu_linux_first_failure=no],
2322      [xgnu_linux_first_failure=yes])
2323     if test "${xgnu_linux_first_failure}" = "yes"; then
2324       OLD_CPPFLAGS="$CPPFLAGS"
2325       OLD_LIBS="$LIBS"
2326       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2327       LIBS="$LIBS -b i486-linuxaout"
2328       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2329        [[XOpenDisplay ("foo");]])],
2330        [xgnu_linux_second_failure=no],
2331        [xgnu_linux_second_failure=yes])
2332       if test "${xgnu_linux_second_failure}" = "yes"; then
2333         # If we get the same failure with -b, there is no use adding -b.
2334         # So leave it out.  This plays safe.
2335         AC_MSG_RESULT(no)
2336       else
2337         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2338         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2339         AC_MSG_RESULT(yes)
2340       fi
2341       CPPFLAGS=$OLD_CPPFLAGS
2342       LIBS=$OLD_LIBS
2343     else
2344       AC_MSG_RESULT(no)
2345     fi
2346   fi
2347
2348   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2349   # header files included from there.
2350   AC_MSG_CHECKING(for Xkb)
2351   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2352 #include <X11/XKBlib.h>]],
2353         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2354         emacs_xkb=yes, emacs_xkb=no)
2355   AC_MSG_RESULT($emacs_xkb)
2356   if test $emacs_xkb = yes; then
2357     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2358   fi
2359
2360   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2361 XScreenNumberOfScreen)
2362 fi
2363
2364 if test "${window_system}" = "x11"; then
2365   AC_MSG_CHECKING(X11 version 6)
2366   AC_CACHE_VAL(emacs_cv_x11_version_6,
2367   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2368 [[#if XlibSpecificationRelease < 6
2369 fail;
2370 #endif
2371 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2372   if test $emacs_cv_x11_version_6 = yes; then
2373     AC_MSG_RESULT(6 or newer)
2374     AC_DEFINE(HAVE_X11R6, 1,
2375               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2376     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2377     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2378     ## XIM support.
2379     case "$opsys" in
2380       sol2-*) : ;;
2381       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2382            [Define if you have usable X11R6-style XIM support.])
2383          ;;
2384     esac
2385   else
2386     AC_MSG_RESULT(before 6)
2387   fi
2388 fi
2389
2390
2391 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2392 HAVE_RSVG=no
2393 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2394   if test "${with_rsvg}" != "no"; then
2395     RSVG_REQUIRED=2.11.0
2396     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2397
2398     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2399     AC_SUBST(RSVG_CFLAGS)
2400     AC_SUBST(RSVG_LIBS)
2401
2402     if test $HAVE_RSVG = yes; then
2403       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2404       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2405       # Windows loads librsvg dynamically
2406       if test "${opsys}" = "mingw32"; then
2407         RSVG_LIBS=
2408       fi
2409     fi
2410   fi
2411 fi
2412
2413 HAVE_IMAGEMAGICK=no
2414 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2415   if test "${with_imagemagick}" != "no"; then
2416     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2417     ## 6.8.2 makes Emacs crash; see Bug#13867.
2418     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2419     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2420     AC_SUBST(IMAGEMAGICK_CFLAGS)
2421     AC_SUBST(IMAGEMAGICK_LIBS)
2422
2423     if test $HAVE_IMAGEMAGICK = yes; then
2424       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2425       OLD_CFLAGS=$CFLAGS
2426       OLD_LIBS=$LIBS
2427       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2428       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2429       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2430       CFLAGS=$OLD_CFLAGS
2431       LIBS=$OLD_LIBS
2432     fi
2433   fi
2434 fi
2435
2436 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2437 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2438   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2439 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2440   GETADDRINFO_A_LIBS="-lanl"
2441   AC_SUBST(GETADDRINFO_A_LIBS)
2442 fi
2443
2444 HAVE_GTK=no
2445 GTK_OBJ=
2446 gtk_term_header=$term_header
2447 check_gtk2=no
2448 gtk3_pkg_errors=
2449 if test "${opsys}" != "mingw32"; then
2450   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2451     GLIB_REQUIRED=2.28
2452     GTK_REQUIRED=3.0
2453     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2454
2455     dnl Checks for libraries.
2456     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2457       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2458     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2459        AC_MSG_ERROR($GTK_PKG_ERRORS)
2460     fi
2461     if test "$pkg_check_gtk" = "yes"; then
2462        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2463        GTK_OBJ=emacsgtkfixed.o
2464        gtk_term_header=gtkutil.h
2465        USE_GTK_TOOLKIT="GTK3"
2466        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2467          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2468            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2469          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2470            [Define to 1 to disable Glib deprecation warnings.])
2471        fi
2472     else
2473        check_gtk2=yes
2474        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2475     fi
2476   fi
2477
2478   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2479     GLIB_REQUIRED=2.10
2480     GTK_REQUIRED=2.10
2481     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2482
2483     dnl Checks for libraries.
2484     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2485       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2486     if test "$pkg_check_gtk" = "no" &&
2487        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2488     then
2489       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2490     fi
2491     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2492   fi
2493 fi
2494
2495 OLD_CFLAGS=$CFLAGS
2496 OLD_LIBS=$LIBS
2497
2498 if test x"$pkg_check_gtk" = xyes; then
2499
2500   AC_SUBST(GTK_LIBS)
2501   CFLAGS="$CFLAGS $GTK_CFLAGS"
2502   LIBS="$GTK_LIBS $LIBS"
2503   dnl Try to compile a simple GTK program.
2504   AC_MSG_CHECKING([whether GTK compiles])
2505   GTK_COMPILES=no
2506   AC_LINK_IFELSE(
2507     [AC_LANG_PROGRAM(
2508        [[/* Check the Gtk and Glib APIs.  */
2509          #include <gtk/gtk.h>
2510          #include <glib-object.h>
2511          static void
2512          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2513          {}
2514        ]],
2515        [[
2516          GtkSettings *gs = 0;
2517          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2518             strict C prohibits this.  Use gtk_main_iteration to test that the
2519             libraries are there.  */
2520          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2521                                     0, 0, 0, G_CALLBACK (callback), 0))
2522            gtk_main_iteration ();
2523        ]])],
2524     [GTK_COMPILES=yes])
2525   AC_MSG_RESULT([$GTK_COMPILES])
2526   if test "${GTK_COMPILES}" != "yes"; then
2527     GTK_OBJ=
2528     if test "$USE_X_TOOLKIT" != "maybe"; then
2529       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2530     fi
2531   else
2532     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2533     HAVE_GTK=yes
2534     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2535     GTK_OBJ="gtkutil.o $GTK_OBJ"
2536     term_header=$gtk_term_header
2537     USE_X_TOOLKIT=none
2538     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2539        closing open displays.  This is no problem if you just use
2540        one display, but if you use more than one and close one of them
2541        Emacs may crash.
2542        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2543     sleep 3
2544   fi
2545
2546 fi
2547 AC_SUBST(GTK_OBJ)
2548
2549
2550 if test "${HAVE_GTK}" = "yes"; then
2551
2552   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2553   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2554   if test "$with_toolkit_scroll_bars" != no; then
2555     with_toolkit_scroll_bars=yes
2556   fi
2557
2558   dnl  Check if we have the old file selection dialog declared and
2559   dnl  in the link library.  In 2.x it may be in the library,
2560   dnl  but not declared if deprecated featured has been selected out.
2561   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2562   HAVE_GTK_FILE_SELECTION=no
2563   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2564                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2565 #include <gtk/gtk.h>])
2566   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2567     AC_CHECK_FUNCS(gtk_file_selection_new)
2568   fi
2569
2570   dnl Same as above for gtk_handle_box.
2571   HAVE_GTK_HANDLE_BOX=no
2572   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2573                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2574 #include <gtk/gtk.h>])
2575   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2576     AC_CHECK_FUNCS(gtk_handle_box_new)
2577   fi
2578
2579   dnl Same as above for gtk_tearoff_menu_item.
2580   HAVE_GTK_TEAROFF_MENU_ITEM=no
2581   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2582                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2583 #include <gtk/gtk.h>])
2584   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2585     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2586   fi
2587
2588   dnl Check for functions introduced in 2.14 and later.
2589   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2590                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2591                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2592                  gtk_orientable_set_orientation \
2593                  gtk_window_set_has_resize_grip)
2594
2595  term_header=gtkutil.h
2596 fi
2597
2598
2599 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2600 HAVE_XWIDGETS=no
2601 XWIDGETS_OBJ=
2602 if test "$with_xwidgets" != "no"; then
2603   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2604     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2605
2606   WEBKIT_REQUIRED=1.4.0
2607   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2608   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2609   HAVE_XWIDGETS=$HAVE_WEBKIT
2610   test $HAVE_XWIDGETS = yes ||
2611     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2612
2613   XWIDGETS_OBJ=xwidget.o
2614   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2615 fi
2616 AC_SUBST(XWIDGETS_OBJ)
2617
2618 CFLAGS=$OLD_CFLAGS
2619 LIBS=$OLD_LIBS
2620
2621 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2622 dnl other platforms.
2623 HAVE_DBUS=no
2624 DBUS_OBJ=
2625 if test "${with_dbus}" = "yes"; then
2626    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2627    if test "$HAVE_DBUS" = yes; then
2628      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2629      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2630      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2631      dnl D-Bus 1.5.12.
2632      OLD_LIBS=$LIBS
2633      LIBS="$LIBS $DBUS_LIBS"
2634      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2635                     dbus_type_is_valid \
2636                     dbus_validate_bus_name \
2637                     dbus_validate_path \
2638                     dbus_validate_interface \
2639                     dbus_validate_member)
2640      LIBS=$OLD_LIBS
2641      DBUS_OBJ=dbusbind.o
2642    fi
2643 fi
2644 AC_SUBST(DBUS_CFLAGS)
2645 AC_SUBST(DBUS_LIBS)
2646 AC_SUBST(DBUS_OBJ)
2647
2648 dnl GSettings has been tested under GNU/Linux only.
2649 HAVE_GSETTINGS=no
2650 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2651    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2652    if test "$HAVE_GSETTINGS" = "yes"; then
2653       old_CFLAGS=$CFLAGS
2654       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2655       old_LIBS=$LIBS
2656       LIBS="$LIBS $GSETTINGS_LIBS"
2657       AC_MSG_CHECKING([whether GSettings is in gio])
2658       AC_LINK_IFELSE(
2659          [AC_LANG_PROGRAM(
2660              [[/* Check that gsettings really is present.  */
2661              #include <glib-object.h>
2662              #include <gio/gio.h>
2663              ]],
2664              [[
2665                GSettings *settings;
2666                GVariant *val = g_settings_get_value (settings, "");
2667              ]])],
2668          [], HAVE_GSETTINGS=no)
2669       AC_MSG_RESULT([$HAVE_GSETTINGS])
2670
2671       if test "$HAVE_GSETTINGS" = "yes"; then
2672         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2673         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2674         SETTINGS_LIBS="$GSETTINGS_LIBS"
2675       fi
2676       CFLAGS=$old_CFLAGS
2677       LIBS=$old_LIBS
2678    fi
2679 fi
2680
2681 dnl GConf has been tested under GNU/Linux only.
2682 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2683 HAVE_GCONF=no
2684 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2685    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2686    if test "$HAVE_GCONF" = yes; then
2687       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2688       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2689       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2690       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2691    fi
2692 fi
2693
2694 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2695     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2696     if test "$HAVE_GOBJECT" = "yes"; then
2697        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2698        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2699     fi
2700     SAVE_CFLAGS="$CFLAGS"
2701     SAVE_LIBS="$LIBS"
2702     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2703     LIBS="$SETTINGS_LIBS $LIBS"
2704     CFLAGS="$SAVE_CFLAGS"
2705     LIBS="$SAVE_LIBS"
2706 fi
2707 AC_SUBST(SETTINGS_CFLAGS)
2708 AC_SUBST(SETTINGS_LIBS)
2709
2710
2711 dnl SELinux is available for GNU/Linux only.
2712 HAVE_LIBSELINUX=no
2713 LIBSELINUX_LIBS=
2714 if test "${with_selinux}" = "yes"; then
2715    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2716    if test "$HAVE_LIBSELINUX" = yes; then
2717       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2718       LIBSELINUX_LIBS=-lselinux
2719    fi
2720 fi
2721 AC_SUBST(LIBSELINUX_LIBS)
2722
2723 HAVE_GNUTLS=no
2724 if test "${with_gnutls}" = "yes" ; then
2725   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2726     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2727   if test "${HAVE_GNUTLS}" = "yes"; then
2728     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2729     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2730       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2731   fi
2732
2733   # Windows loads GnuTLS dynamically
2734   if test "${opsys}" = "mingw32"; then
2735     LIBGNUTLS_LIBS=
2736   fi
2737 fi
2738
2739 AC_SUBST(LIBGNUTLS_LIBS)
2740 AC_SUBST(LIBGNUTLS_CFLAGS)
2741
2742 NOTIFY_OBJ=
2743 NOTIFY_SUMMARY=no
2744
2745 dnl MS Windows native file monitor is available for mingw32 only.
2746 case $with_file_notification,$opsys in
2747   w32,cygwin)
2748     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2749     this is only supported on MS-Windows native and MinGW32 builds.
2750     Consider using gfile instead.])
2751     ;;
2752   w32,* | yes,mingw32)
2753     AC_CHECK_HEADER(windows.h)
2754     if test "$ac_cv_header_windows_h" = yes ; then
2755        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2756        NOTIFY_OBJ=w32notify.o
2757        NOTIFY_SUMMARY="yes (w32)"
2758     fi ;;
2759 esac
2760
2761 dnl inotify is available only on GNU/Linux.
2762 case $with_file_notification,$NOTIFY_OBJ in
2763   inotify, | yes,)
2764     AC_CHECK_HEADER(sys/inotify.h)
2765     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2766         AC_CHECK_FUNC(inotify_init1)
2767         if test "$ac_cv_func_inotify_init1" = yes; then
2768           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2769           NOTIFY_OBJ=inotify.o
2770           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2771        fi
2772     fi ;;
2773 esac
2774
2775 dnl kqueue is available on BSD-like systems.
2776 case $with_file_notification,$NOTIFY_OBJ in
2777   kqueue,* | yes,)
2778     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2779     if test "$HAVE_KQUEUE" = "yes"; then
2780        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2781        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2782        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2783        NOTIFY_LIBS=$KQUEUE_LIBS
2784        NOTIFY_OBJ=kqueue.o
2785        NOTIFY_SUMMARY="yes -lkqueue"
2786     else
2787        AC_SEARCH_LIBS(kqueue, [])
2788        if test "$ac_cv_search_kqueue" != no; then
2789          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2790          NOTIFY_OBJ=kqueue.o
2791          NOTIFY_SUMMARY="yes (kqueue)"
2792        fi
2793     fi ;;
2794 esac
2795
2796 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2797 dnl has been added in glib 2.24.  It has been tested under
2798 dnl GNU/Linux only.
2799 case $with_file_notification,$NOTIFY_OBJ in
2800   gfile,* | yes,)
2801     if test "${HAVE_NS}" = yes; then
2802        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2803 Consider kqueue instead.])
2804     else
2805        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2806        if test "$HAVE_GFILENOTIFY" = "yes"; then
2807           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2808           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2809           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2810           NOTIFY_OBJ=gfilenotify.o
2811           NOTIFY_SUMMARY="yes -lgio (gfile)"
2812        fi
2813     fi ;;
2814 esac
2815
2816 case $with_file_notification,$NOTIFY_OBJ in
2817   yes,* | no,* | *,?*) ;;
2818   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2819 esac
2820
2821 if test -n "$NOTIFY_OBJ"; then
2822    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2823 fi
2824 AC_SUBST(NOTIFY_CFLAGS)
2825 AC_SUBST(NOTIFY_LIBS)
2826 AC_SUBST(NOTIFY_OBJ)
2827
2828 dnl Do not put whitespace before the #include statements below.
2829 dnl Older compilers (eg sunos4 cc) choke on it.
2830 HAVE_XAW3D=no
2831 LUCID_LIBW=
2832 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2833   if test "$with_xaw3d" != no; then
2834     AC_CACHE_VAL(emacs_cv_xaw3d,
2835     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2836 #include <X11/Intrinsic.h>
2837 #include <X11/Xaw3d/Simple.h>]],
2838       [[]])],
2839       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2840                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2841       emacs_cv_xaw3d=no)])
2842   else
2843     emacs_cv_xaw3d=no
2844   fi
2845   if test $emacs_cv_xaw3d = yes; then
2846     AC_MSG_CHECKING(for xaw3d)
2847     AC_MSG_RESULT([yes; using Lucid toolkit])
2848     USE_X_TOOLKIT=LUCID
2849     HAVE_XAW3D=yes
2850     LUCID_LIBW=-lXaw3d
2851     AC_DEFINE(HAVE_XAW3D, 1,
2852               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2853   else
2854     AC_MSG_CHECKING(for xaw3d)
2855     AC_MSG_RESULT(no)
2856     AC_MSG_CHECKING(for libXaw)
2857     AC_CACHE_VAL(emacs_cv_xaw,
2858     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2859 #include <X11/Intrinsic.h>
2860 #include <X11/Xaw/Simple.h>]],
2861       [[]])],
2862       emacs_cv_xaw=yes,
2863       emacs_cv_xaw=no)])
2864     if test $emacs_cv_xaw = yes; then
2865       AC_MSG_RESULT([yes; using Lucid toolkit])
2866       USE_X_TOOLKIT=LUCID
2867       LUCID_LIBW=-lXaw
2868     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2869       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2870     else
2871       AC_MSG_ERROR([No X toolkit could be found.
2872 If you are sure you want Emacs compiled without an X toolkit, pass
2873   --with-x-toolkit=no
2874 to configure.  Otherwise, install the development libraries for the toolkit
2875 that you want to use (e.g. Gtk+) and re-run configure.])
2876     fi
2877   fi
2878 fi
2879
2880 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2881
2882 LIBXTR6=
2883 LIBXMU=
2884 if test "${USE_X_TOOLKIT}" != "none"; then
2885   AC_MSG_CHECKING(X11 toolkit version)
2886   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2887   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2888 [[#if XtSpecificationRelease < 6
2889 fail;
2890 #endif
2891 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2892   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2893   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2894     AC_MSG_RESULT(6 or newer)
2895     AC_DEFINE(HAVE_X11XTR6, 1,
2896               [Define to 1 if you have the X11R6 or newer version of Xt.])
2897     LIBXTR6="-lSM -lICE"
2898     case "$opsys" in
2899       ## Use libw.a along with X11R6 Xt.
2900       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2901     esac
2902   else
2903     AC_MSG_RESULT(before 6)
2904   fi
2905
2906 dnl If using toolkit, check whether libXmu.a exists.
2907 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2908   OLDLIBS="$LIBS"
2909   if test x$HAVE_X11XTR6 = xyes; then
2910     OTHERLIBS='-lXt -lSM -lICE'
2911   else
2912     OTHERLIBS='-lXt'
2913   fi
2914   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2915   if test "X$LIBS" != "X$OLDLIBS"; then
2916     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2917   fi
2918   LIBS=$OLDLIBS
2919   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2920 fi
2921 AC_SUBST(LIBXTR6)
2922 AC_SUBST(LIBXMU)
2923
2924 LIBXP=
2925 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2926   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2927   if test -d /usr/include/openmotif; then
2928     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2929     emacs_cv_openmotif=yes
2930     case "$canonical" in
2931       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2932       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2933       ;;
2934       *)
2935       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2936     esac
2937   else
2938     emacs_cv_openmotif=no
2939   fi
2940   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2941   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2942     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2943 int x = 5;
2944 #else
2945 Motif version prior to 2.1.
2946 #endif]])],
2947     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2948   if test $emacs_cv_motif_version_2_1 = yes; then
2949     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2950     if test x$emacs_cv_openmotif = xyes; then
2951       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2952     fi
2953   else
2954     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2955     # We put this in CFLAGS temporarily to precede other -I options
2956     # that might be in CFLAGS temporarily.
2957     # We put this in CPPFLAGS where it precedes the other -I options.
2958     OLD_CPPFLAGS=$CPPFLAGS
2959     OLD_CFLAGS=$CFLAGS
2960     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2961     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2962     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2963       [[int x = 5;]])],
2964       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2965     if test $emacs_cv_lesstif = yes; then
2966       # Make sure this -I option remains in CPPFLAGS after it is set
2967       # back to REAL_CPPFLAGS.
2968       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2969       # have those other -I options anyway.  Ultimately, having this
2970       # directory ultimately in CPPFLAGS will be enough.
2971       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2972       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2973     else
2974       CFLAGS=$OLD_CFLAGS
2975       CPPFLAGS=$OLD_CPPFLAGS
2976     fi
2977   fi
2978   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2979     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2980 fi
2981
2982 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2983 dnl using Motif or Xaw3d is available, and unless
2984 dnl --with-toolkit-scroll-bars=no was specified.
2985
2986 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2987             [Define to 1 if we should use toolkit scroll bars.])dnl
2988 USE_TOOLKIT_SCROLL_BARS=no
2989 if test "${with_toolkit_scroll_bars}" != "no"; then
2990   if test "${USE_X_TOOLKIT}" != "none"; then
2991     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2992       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2993       HAVE_XAW3D=no
2994       USE_TOOLKIT_SCROLL_BARS=yes
2995     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2996       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2997       USE_TOOLKIT_SCROLL_BARS=yes
2998     fi
2999   elif test "${HAVE_GTK}" = "yes"; then
3000     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3001     USE_TOOLKIT_SCROLL_BARS=yes
3002   elif test "${HAVE_NS}" = "yes"; then
3003     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3004     USE_TOOLKIT_SCROLL_BARS=yes
3005   elif test "${HAVE_W32}" = "yes"; then
3006     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3007     USE_TOOLKIT_SCROLL_BARS=yes
3008   fi
3009 fi
3010
3011 dnl See if XIM is available.
3012 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3013           #include <X11/Xlib.h>
3014           #include <X11/Xresource.h>]],
3015          [[XIMProc  callback;]])],
3016          [HAVE_XIM=yes
3017          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
3018          HAVE_XIM=no)
3019
3020 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3021
3022 if test "${with_xim}" != "no"; then
3023   AC_DEFINE(USE_XIM, 1,
3024             [Define to 1 if we should use XIM, if it is available.])
3025 fi
3026
3027
3028 if test "${HAVE_XIM}" != "no"; then
3029   late_CFLAGS=$CFLAGS
3030   if test "$GCC" = yes; then
3031     CFLAGS="$CFLAGS --pedantic-errors"
3032   fi
3033   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3034 #include <X11/Xlib.h>
3035 #include <X11/Xresource.h>]],
3036 [[Display *display;
3037 XrmDatabase db;
3038 char *res_name;
3039 char *res_class;
3040 XIMProc  callback;
3041 XPointer *client_data;
3042 #ifndef __GNUC__
3043 /* If we're not using GCC, it's probably not XFree86, and this is
3044    probably right, but we can't use something like --pedantic-errors.  */
3045 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3046                                            char*, XIMProc, XPointer*);
3047 #endif
3048 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3049    client_data);]])],
3050     [emacs_cv_arg6_star=yes])
3051   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3052          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3053 either XPointer or XPointer*.])dnl
3054   if test "$emacs_cv_arg6_star" = yes; then
3055     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3056   else
3057     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3058   fi
3059   CFLAGS=$late_CFLAGS
3060 fi
3061
3062 ### Start of font-backend (under any platform) section.
3063 # (nothing here yet -- this is a placeholder)
3064 ### End of font-backend (under any platform) section.
3065
3066 ### Start of font-backend (under X11) section.
3067 if test "${HAVE_X11}" = "yes"; then
3068     ## Use -lXft if available, unless '--with-xft=no'.
3069     HAVE_XFT=maybe
3070     if test "x${with_x}" = "xno"; then
3071       with_xft="no";
3072     fi
3073
3074     if test "$with_xft" != no; then
3075       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3076       with_xft=$HAVE_FONTCONFIG
3077     fi
3078
3079     if test "x${with_xft}" != "xno"; then
3080
3081       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3082       ## Because xftfont.c uses XRenderQueryExtension, we also
3083       ## need to link to -lXrender.
3084       HAVE_XRENDER=no
3085       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3086       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3087         OLD_CPPFLAGS="$CPPFLAGS"
3088         OLD_CFLAGS="$CFLAGS"
3089         OLD_LIBS="$LIBS"
3090         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3091         CFLAGS="$CFLAGS $XFT_CFLAGS"
3092         XFT_LIBS="-lXrender $XFT_LIBS"
3093         LIBS="$XFT_LIBS $LIBS"
3094         AC_CHECK_HEADER(X11/Xft/Xft.h,
3095           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3096           [[#include <X11/X.h>]])
3097
3098         if test "${HAVE_XFT}" = "yes"; then
3099           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3100             AC_SUBST(XFT_LIBS)
3101           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3102         fi                        # "${HAVE_XFT}" = "yes"
3103         CPPFLAGS=$OLD_CPPFLAGS
3104         CFLAGS=$OLD_CFLAGS
3105         LIBS=$OLD_LIBS
3106       fi                          # "$HAVE_XFT" != no
3107     fi                            # "x${with_xft}" != "xno"
3108
3109     ## We used to allow building with FreeType and without Xft.
3110     ## However, the ftx font backend driver is not in good shape.
3111     if test "$HAVE_XFT" != "yes"; then
3112        dnl For the "Does Emacs use" message at the end.
3113        HAVE_XFT=no
3114        HAVE_FREETYPE=no
3115     else
3116        dnl Strict linkers fail with
3117        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3118        dnl if -lfreetype is not specified.
3119        dnl The following is needed to set FREETYPE_LIBS.
3120        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3121
3122        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3123     fi
3124
3125     HAVE_LIBOTF=no
3126     if test "${HAVE_FREETYPE}" = "yes"; then
3127       AC_DEFINE(HAVE_FREETYPE, 1,
3128                 [Define to 1 if using the freetype and fontconfig libraries.])
3129       if test "${with_libotf}" != "no"; then
3130         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3131         if test "$HAVE_LIBOTF" = "yes"; then
3132           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3133           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3134                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3135                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3136           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3137             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3138                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3139           fi
3140         fi
3141       fi
3142     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3143     dnl Does the new font backend require it, or can it work without it?
3144     fi
3145
3146     HAVE_M17N_FLT=no
3147     if test "${HAVE_LIBOTF}" = yes; then
3148       if test "${with_m17n_flt}" != "no"; then
3149         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3150         if test "$HAVE_M17N_FLT" = "yes"; then
3151           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3152         fi
3153       fi
3154     fi
3155 else
3156     HAVE_XFT=no
3157     HAVE_FREETYPE=no
3158     HAVE_LIBOTF=no
3159     HAVE_M17N_FLT=no
3160 fi
3161
3162 ### End of font-backend (under X11) section.
3163
3164 AC_SUBST(FREETYPE_CFLAGS)
3165 AC_SUBST(FREETYPE_LIBS)
3166 AC_SUBST(FONTCONFIG_CFLAGS)
3167 AC_SUBST(FONTCONFIG_LIBS)
3168 AC_SUBST(LIBOTF_CFLAGS)
3169 AC_SUBST(LIBOTF_LIBS)
3170 AC_SUBST(M17N_FLT_CFLAGS)
3171 AC_SUBST(M17N_FLT_LIBS)
3172
3173 HAVE_CAIRO=no
3174 if test "${HAVE_X11}" = "yes"; then
3175   if test "${with_cairo}" != "no"; then
3176     CAIRO_REQUIRED=1.12.0
3177     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3178     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3179     if test $HAVE_CAIRO = yes; then
3180       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3181     else
3182       AC_MSG_ERROR([cairo requested but not found.])
3183     fi
3184
3185     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3186     LIBS="$LIBS $CAIRO_LIBS"
3187     AC_SUBST(CAIRO_CFLAGS)
3188     AC_SUBST(CAIRO_LIBS)
3189   fi
3190 fi
3191
3192 if test "${HAVE_X11}" = "yes"; then
3193   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3194     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3195   if test "${HAVE_XCB}" = "yes"; then
3196     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3197     if test "${HAVE_X11_XCB}" = "yes"; then
3198       AC_DEFINE(USE_XCB, 1,
3199 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3200    X11/XCB programming.])
3201       XCB_LIBS="-lX11-xcb -lxcb"
3202       AC_SUBST(XCB_LIBS)
3203     fi
3204   fi
3205 fi
3206
3207 ### Use -lXpm if available, unless '--with-xpm=no'.
3208 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3209 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3210 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3211 ### LDFLAGS) accordingly.
3212 HAVE_XPM=no
3213 LIBXPM=
3214 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3215   if test "${with_xpm}" != "no"; then
3216     SAVE_CPPFLAGS="$CPPFLAGS"
3217     SAVE_LDFLAGS="$LDFLAGS"
3218     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3219     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3220     AC_CHECK_HEADER(X11/xpm.h,
3221       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3222     if test "${HAVE_XPM}" = "yes"; then
3223       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3224       AC_EGREP_CPP(no_return_alloc_pixels,
3225       [#include "X11/xpm.h"
3226 #ifndef XpmReturnAllocPixels
3227 no_return_alloc_pixels
3228 #endif
3229       ], HAVE_XPM=no, HAVE_XPM=yes)
3230
3231       if test "${HAVE_XPM}" = "yes"; then
3232         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3233         AC_MSG_RESULT(yes)
3234       else
3235         AC_MSG_RESULT(no)
3236         CPPFLAGS="$SAVE_CPPFLAGS"
3237         LDFLAGS="$SAVE_LDFLAGS"
3238       fi
3239     fi
3240   fi
3241
3242   if test "${HAVE_XPM}" = "yes"; then
3243     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3244     LIBXPM=-lXpm
3245   fi
3246 fi
3247
3248 if test "${HAVE_X11}" = "yes"; then
3249   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3250   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3251
3252   if test "${with_xpm}" != "no"; then
3253     AC_CHECK_HEADER(X11/xpm.h,
3254       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3255     if test "${HAVE_XPM}" = "yes"; then
3256       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3257       AC_EGREP_CPP(no_return_alloc_pixels,
3258       [#include "X11/xpm.h"
3259 #ifndef XpmReturnAllocPixels
3260 no_return_alloc_pixels
3261 #endif
3262       ], HAVE_XPM=no, HAVE_XPM=yes)
3263
3264       if test "${HAVE_XPM}" = "yes"; then
3265         AC_MSG_RESULT(yes)
3266       else
3267         AC_MSG_RESULT(no)
3268       fi
3269     fi
3270   fi
3271
3272   if test "${HAVE_XPM}" = "yes"; then
3273     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3274     LIBXPM=-lXpm
3275   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3276     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3277     LIBXPM=-lXpm
3278   fi
3279 fi
3280
3281 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3282 ### slightly different requirements wrt image libraries (it doesn't
3283 ### use -lXpm because it loads the xpm shared library dynamically at
3284 ### run time).
3285 if test "${opsys}" = "mingw32"; then
3286   if test "${with_xpm}" != "no"; then
3287     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3288 #define FOR_MSW 1])
3289   fi
3290
3291   if test "${HAVE_XPM}" = "yes"; then
3292     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3293   fi
3294 fi
3295
3296 AC_SUBST(LIBXPM)
3297
3298 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3299 HAVE_JPEG=no
3300 LIBJPEG=
3301 if test "${with_jpeg}" != "no"; then
3302   AC_CACHE_CHECK([for jpeglib 6b or later],
3303     [emacs_cv_jpeglib],
3304     [OLD_LIBS=$LIBS
3305      for emacs_cv_jpeglib in yes -ljpeg no; do
3306        case $emacs_cv_jpeglib in
3307          yes) ;;
3308          no) break;;
3309          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3310        esac
3311        AC_LINK_IFELSE(
3312          [AC_LANG_PROGRAM(
3313             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3314               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3315               #include <jpeglib.h>
3316               #include <jerror.h>
3317               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3318               struct jpeg_decompress_struct cinfo;
3319             ]],
3320             [[
3321               jpeg_create_decompress (&cinfo);
3322               WARNMS (&cinfo, JWRN_JPEG_EOF);
3323               jpeg_destroy_decompress (&cinfo);
3324             ]])],
3325          [emacs_link_ok=yes],
3326          [emacs_link_ok=no])
3327        LIBS=$OLD_LIBS
3328        test $emacs_link_ok = yes && break
3329      done])
3330   if test "$emacs_cv_jpeglib" != no; then
3331     HAVE_JPEG=yes
3332     AC_DEFINE([HAVE_JPEG], 1,
3333       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3334     ### mingw32 doesn't use -ljpeg, since it loads the library
3335     ### dynamically when needed, and doesn't want a run-time
3336     ### dependency on the jpeglib DLL.
3337     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3338     && LIBJPEG=$emacs_cv_jpeglib
3339   fi
3340 fi
3341 AC_SUBST(LIBJPEG)
3342
3343 HAVE_ZLIB=no
3344 LIBZ=
3345 if test "${with_zlib}" != "no"; then
3346   OLIBS=$LIBS
3347   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3348   LIBS=$OLIBS
3349   case $ac_cv_search_inflateEnd in
3350     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3351   esac
3352 fi
3353 if test "${HAVE_ZLIB}" = "yes"; then
3354   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3355   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3356   if test "${opsys}" = "mingw32"; then
3357      LIBZ=
3358   fi
3359 fi
3360 AC_SUBST(LIBZ)
3361
3362 ### Dynamic modules support
3363 LIBMODULES=
3364 HAVE_MODULES=no
3365 MODULES_OBJ=
3366 MODULES_SUFFIX=
3367 if test "${with_modules}" != "no"; then
3368   if test "$opsys" = "gnu-linux"; then
3369     LIBMODULES="-ldl"
3370     MODULES_SUFFIX=".so"
3371     HAVE_MODULES=yes
3372   elif test "$opsys" = "cygwin"; then
3373     MODULES_SUFFIX=".dll"
3374     HAVE_MODULES=yes
3375   elif test "$opsys" = "darwin"; then
3376     MODULES_SUFFIX=".so"
3377     HAVE_MODULES=yes
3378   elif test "$opsys" = "mingw32"; then
3379     MODULES_SUFFIX=".dll"
3380     HAVE_MODULES=yes
3381   else
3382     # BSD system have dlopen in the libc
3383     AC_CHECK_FUNC(dlopen, [MODULES_SUFFIX=".so"]
3384                           [HAVE_MODULES=yes], [])
3385   fi
3386
3387   if test "${HAVE_MODULES}" = no; then
3388     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3389   else
3390     SAVE_LIBS=$LIBS
3391     LIBS="$LIBS $LIBMODULES"
3392     AC_CHECK_FUNCS([dladdr dlfunc])
3393     LIBS=$SAVE_LIBS
3394   fi
3395 fi
3396
3397 if test "${HAVE_MODULES}" = yes; then
3398    MODULES_OBJ="dynlib.o emacs-module.o"
3399    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3400    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3401      [System extension for dynamic libraries])
3402 fi
3403 AC_SUBST(MODULES_OBJ)
3404 AC_SUBST(LIBMODULES)
3405
3406 ### Use -lpng if available, unless '--with-png=no'.
3407 HAVE_PNG=no
3408 LIBPNG=
3409 PNG_CFLAGS=
3410 if test "${NS_IMPL_COCOA}" = yes; then
3411   : # Nothing to do
3412 elif test "${with_png}" != no; then
3413   # mingw32 loads the library dynamically.
3414   if test "$opsys" = mingw32; then
3415     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3416   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3417     AC_MSG_CHECKING([for png])
3418     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3419     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3420       # libpng-config does not work; configure by hand.
3421       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3422       # in /usr/include/libpng.
3423       if test -r /usr/include/libpng/png.h &&
3424          test ! -r /usr/include/png.h; then
3425         png_cflags=-I/usr/include/libpng
3426       else
3427         png_cflags=
3428       fi
3429       png_libs='-lpng'
3430     }
3431     SAVE_CFLAGS=$CFLAGS
3432     SAVE_LIBS=$LIBS
3433     CFLAGS="$CFLAGS $png_cflags"
3434     LIBS="$png_libs -lz -lm $LIBS"
3435     AC_LINK_IFELSE(
3436       [AC_LANG_PROGRAM([[#include <png.h>]],
3437          [[return !png_get_channels (0, 0);]])],
3438       [HAVE_PNG=yes
3439        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3440        LIBPNG=$png_libs
3441        # $LIBPNG requires explicit -lz in some cases.
3442        # We don't know what those cases are, exactly, so play it safe and
3443        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3444        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3445          LIBPNG="$LIBPNG -lz"
3446        fi])
3447     CFLAGS=$SAVE_CFLAGS
3448     LIBS=$SAVE_LIBS
3449     AC_MSG_RESULT([$HAVE_PNG])
3450   fi
3451 fi
3452 if test $HAVE_PNG = yes; then
3453   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3454
3455   SAVE_CFLAGS=$CFLAGS
3456   CFLAGS="$CFLAGS $PNG_CFLAGS"
3457   AC_CHECK_DECL([png_longjmp],
3458     [],
3459     [AC_DEFINE([PNG_DEPSTRUCT], [],
3460        [Define to empty to suppress deprecation warnings when building
3461         with --enable-gcc-warnings and with libpng versions before 1.5,
3462         which lack png_longjmp.])],
3463     [[#include <png.h>
3464     ]])
3465   CFLAGS=$SAVE_CFLAGS
3466 fi
3467 AC_SUBST(LIBPNG)
3468 AC_SUBST(PNG_CFLAGS)
3469
3470 ### Use -ltiff if available, unless '--with-tiff=no'.
3471 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3472 HAVE_TIFF=no
3473 LIBTIFF=
3474 if test "${opsys}" = "mingw32"; then
3475   if test "${with_tiff}" != "no"; then
3476     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3477   fi
3478   if test "${HAVE_TIFF}" = "yes"; then
3479     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3480   fi
3481 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3482   if test "${with_tiff}" != "no"; then
3483     AC_CHECK_HEADER(tiffio.h,
3484       [tifflibs="-lz -lm"
3485       # At least one tiff package requires the jpeg library.
3486       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3487       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3488   fi
3489
3490   if test "${HAVE_TIFF}" = "yes"; then
3491     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3492     dnl FIXME -lz -lm, as per libpng?
3493     LIBTIFF=-ltiff
3494   fi
3495 fi
3496 AC_SUBST(LIBTIFF)
3497
3498 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3499 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3500 HAVE_GIF=no
3501 LIBGIF=
3502 if test "${opsys}" = "mingw32"; then
3503   if test "${with_gif}" != "no"; then
3504     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3505   fi
3506   if test "${HAVE_GIF}" = "yes"; then
3507     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3508   fi
3509 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3510         || test "${HAVE_W32}" = "yes"; then
3511   AC_CHECK_HEADER(gif_lib.h,
3512 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3513 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3514     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3515         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3516
3517   if test "$HAVE_GIF" = yes; then
3518     LIBGIF=-lgif
3519   elif test "$HAVE_GIF" = maybe; then
3520 # If gif_lib.h but no libgif, try libungif.
3521     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3522     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3523   fi
3524
3525   if test "${HAVE_GIF}" = "yes"; then
3526     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3527   fi
3528 fi
3529 AC_SUBST(LIBGIF)
3530
3531 dnl Check for required libraries.
3532 if test "${HAVE_X11}" = "yes"; then
3533   MISSING=""
3534   WITH_NO=""
3535   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3536     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3537   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3538     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3539   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3540     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3541   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3542     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3543   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3544     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3545
3546   if test "X${MISSING}" != X; then
3547     AC_MSG_ERROR([The following required libraries were not found:
3548     $MISSING
3549 Maybe some development libraries/packages are missing?
3550 If you don't want to link with them give
3551     $WITH_NO
3552 as options to configure])
3553   fi
3554 fi
3555
3556 ### Use -lgpm if available, unless '--with-gpm=no'.
3557 HAVE_GPM=no
3558 LIBGPM=
3559 if test "${with_gpm}" != "no"; then
3560   AC_CHECK_HEADER(gpm.h,
3561     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3562
3563   if test "${HAVE_GPM}" = "yes"; then
3564     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3565     LIBGPM=-lgpm
3566   fi
3567 fi
3568 AC_SUBST(LIBGPM)
3569
3570 dnl Check for malloc/malloc.h on darwin
3571 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3572
3573 GNUSTEP_CFLAGS=
3574 ### Use NeXTstep API to implement GUI.
3575 if test "${HAVE_NS}" = "yes"; then
3576   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3577   if test "${NS_IMPL_COCOA}" = "yes"; then
3578     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3579   fi
3580   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3581     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3582     if test $NS_GNUSTEP_CONFIG != yes; then
3583       # See also .m.o rule in src/Makefile.in.  */
3584       # FIXME: are all these flags really needed?  Document here why.  */
3585       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3586       ## Extra CFLAGS applied to src/*.m files.
3587       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3588     fi
3589   fi
3590   OTHER_FILES=ns-app
3591 fi
3592
3593 ### Use session management (-lSM -lICE) if available
3594 HAVE_X_SM=no
3595 LIBXSM=
3596 if test "${HAVE_X11}" = "yes"; then
3597   AC_CHECK_HEADER(X11/SM/SMlib.h,
3598     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3599
3600   if test "${HAVE_X_SM}" = "yes"; then
3601     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3602     LIBXSM="-lSM -lICE"
3603   fi
3604 fi
3605 AC_SUBST(LIBXSM)
3606
3607 ### Use XRandr (-lXrandr) if available
3608 HAVE_XRANDR=no
3609 if test "${HAVE_X11}" = "yes"; then
3610   XRANDR_REQUIRED=1.2.2
3611   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3612   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3613   if test $HAVE_XRANDR = no; then
3614     # Test old way in case pkg-config doesn't have it (older machines).
3615     # Include Xrender.h by hand to work around bug in older Xrandr.h
3616     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3617     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3618       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3619       [], [AC_INCLUDES_DEFAULT
3620 #include <X11/extensions/Xrender.h>])
3621     if test $HAVE_XRANDR = yes; then
3622       XRANDR_LIBS=-lXrandr
3623     fi
3624   fi
3625   if test $HAVE_XRANDR = yes; then
3626     SAVE_CFLAGS="$CFLAGS"
3627     SAVE_LIBS="$LIBS"
3628     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3629     LIBS="$XRANDR_LIBS $LIBS"
3630     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3631     CFLAGS="$SAVE_CFLAGS"
3632     LIBS="$SAVE_LIBS"
3633
3634     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3635   fi
3636 fi
3637 AC_SUBST(XRANDR_CFLAGS)
3638 AC_SUBST(XRANDR_LIBS)
3639
3640 ### Use Xinerama (-lXinerama) if available
3641 HAVE_XINERAMA=no
3642 if test "${HAVE_X11}" = "yes"; then
3643   XINERAMA_REQUIRED=1.0.2
3644   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3645   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3646   if test $HAVE_XINERAMA = no; then
3647     # Test old way in case pkg-config doesn't have it (older machines).
3648     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3649       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3650     if test $HAVE_XINERAMA = yes; then
3651       XINERAMA_LIBS=-lXinerama
3652     fi
3653   fi
3654   if test $HAVE_XINERAMA = yes; then
3655     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3656   fi
3657 fi
3658 AC_SUBST(XINERAMA_CFLAGS)
3659 AC_SUBST(XINERAMA_LIBS)
3660
3661 ### Use Xfixes (-lXfixes) if available
3662 HAVE_XFIXES=no
3663 if test "${HAVE_X11}" = "yes"; then
3664   XFIXES_REQUIRED=4.0.0
3665   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3666   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3667   if test $HAVE_XFIXES = no; then
3668     # Test old way in case pkg-config doesn't have it (older machines).
3669     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3670       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3671     if test $HAVE_XFIXES = yes; then
3672       XFIXES_LIBS=-lXfixes
3673     fi
3674   fi
3675   if test $HAVE_XFIXES = yes; then
3676     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3677   fi
3678 fi
3679 AC_SUBST(XFIXES_CFLAGS)
3680 AC_SUBST(XFIXES_LIBS)
3681
3682 ### Use libxml (-lxml2) if available
3683 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3684 HAVE_LIBXML2=no
3685 if test "${with_xml2}" != "no"; then
3686   ### I'm not sure what the version number should be, so I just guessed.
3687   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3688   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3689   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3690     SAVE_CPPFLAGS="$CPPFLAGS"
3691     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3692       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3693       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3694       case $xcsdkdir in
3695         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3696         xcsdkdir="" ;;
3697       esac
3698     fi
3699     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3700     AC_CHECK_HEADER(libxml/HTMLparser.h,
3701       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3702                      [#include <libxml/HTMLparser.h>])])
3703     CPPFLAGS="$SAVE_CPPFLAGS"
3704     if test "${HAVE_LIBXML2}" = "yes"; then
3705       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3706       LIBXML2_LIBS="-lxml2"
3707     fi
3708   fi
3709   if test "${HAVE_LIBXML2}" = "yes"; then
3710     if test "${opsys}" != "mingw32"; then
3711       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3712         [$LIBXML2_LIBS])
3713     else
3714       LIBXML2_LIBS=""
3715     fi
3716     if test "${HAVE_LIBXML2}" = "yes"; then
3717       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3718     else
3719       LIBXML2_LIBS=""
3720       LIBXML2_CFLAGS=""
3721     fi
3722   fi
3723 fi
3724 AC_SUBST(LIBXML2_LIBS)
3725 AC_SUBST(LIBXML2_CFLAGS)
3726
3727 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3728 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3729 if test "${opsys}" = "mingw32"; then
3730   emacs_cv_netdb_declares_h_errno=yes
3731 fi
3732 AC_CACHE_CHECK(whether netdb declares h_errno,
3733                emacs_cv_netdb_declares_h_errno,
3734 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3735   [[return h_errno;]])],
3736   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3737 if test $emacs_cv_netdb_declares_h_errno = yes; then
3738   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3739 fi
3740
3741 # Check for mail-locking functions in a "mail" library.  Probably this should
3742 # have the same check as for liblockfile below.
3743 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3744 if test $have_mail = yes; then
3745   LIBS_MAIL=-lmail
3746   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3747
3748   OLD_LIBS=$LIBS
3749   LIBS="$LIBS_MAIL $LIBS"
3750   AC_CHECK_FUNCS(touchlock)
3751   LIBS=$OLD_LIBS
3752 else
3753   LIBS_MAIL=
3754 fi
3755 dnl Debian, at least:
3756 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3757 if test $have_lockfile = yes; then
3758    LIBS_MAIL=-llockfile
3759    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3760 else
3761 # If we have the shared liblockfile, assume we must use it for mail
3762 # locking (e.g. Debian).  If we couldn't link against liblockfile
3763 # (no liblockfile.a installed), ensure that we don't need to.
3764   dnl This works for files generally, not just executables.
3765   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3766   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3767                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3768   if test $ac_cv_prog_liblockfile = yes; then
3769     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3770 This probably means that movemail could lose mail.
3771 There may be a 'development' package to install containing liblockfile.])
3772   fi
3773 fi
3774 AC_CHECK_HEADERS_ONCE(maillock.h)
3775 AC_SUBST(LIBS_MAIL)
3776
3777 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3778 ## interlock access to the mail spool.  The alternative is a lock file named
3779 ## /usr/spool/mail/$USER.lock.
3780 mail_lock=no
3781 case "$opsys" in
3782   aix4-2) mail_lock="lockf" ;;
3783
3784   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3785
3786   ## On GNU/Linux systems, both methods are used by various mail programs.
3787   ## I assume most people are using newer mailers that have heard of flock.
3788   ## Change this if you need to.
3789   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3790   ## configure gets the right answers, and that means *NOT* using flock.
3791   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3792   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3793   ## Debian maintainer hasn't provided a clean fix for Emacs.
3794   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3795   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3796   ## correct logic.  -- fx
3797   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3798   ## liblockfile is a Free Software replacement for libmail, used on
3799   ## Debian systems and elsewhere. -rfr.
3800   gnu-*)
3801     mail_lock="flock"
3802     if test $have_mail = yes || test $have_lockfile = yes; then
3803       test $ac_cv_header_maillock_h = yes && mail_lock=no
3804     fi
3805     ;;
3806
3807   mingw32)
3808     mail_lock="none-needed" ;;
3809 esac
3810
3811 BLESSMAIL_TARGET=
3812 case "$mail_lock" in
3813   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3814
3815   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3816
3817   none-needed) ;;
3818
3819   *) BLESSMAIL_TARGET="need-blessmail" ;;
3820 esac
3821 AC_SUBST(BLESSMAIL_TARGET)
3822
3823 OLD_LIBS=$LIBS
3824 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3825 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3826 getrusage get_current_dir_name \
3827 lrand48 random rint \
3828 select getpagesize setlocale newlocale \
3829 getrlimit setrlimit shutdown getaddrinfo \
3830 pthread_sigmask strsignal setitimer \
3831 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3832 gai_strerror sync \
3833 getpwent endpwent getgrent endgrent \
3834 cfmakeraw cfsetspeed copysign __executable_start log2)
3835 LIBS=$OLD_LIBS
3836
3837 dnl No need to check for posix_memalign if aligned_alloc works.
3838 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3839 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3840
3841 dnl Cannot use AC_CHECK_FUNCS
3842 AC_CACHE_CHECK([for __builtin_unwind_init],
3843                emacs_cv_func___builtin_unwind_init,
3844 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3845                 emacs_cv_func___builtin_unwind_init=yes,
3846                 emacs_cv_func___builtin_unwind_init=no)])
3847 if test $emacs_cv_func___builtin_unwind_init = yes; then
3848   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3849             [Define to 1 if you have the '__builtin_unwind_init' function.])
3850 fi
3851
3852 AC_CHECK_HEADERS_ONCE(sys/un.h)
3853
3854 AC_FUNC_FSEEKO
3855
3856 # UNIX98 PTYs.
3857 AC_CHECK_FUNCS(grantpt)
3858
3859 # PTY-related GNU extensions.
3860 AC_CHECK_FUNCS(getpt posix_openpt)
3861
3862 # Check this now, so that we will NOT find the above functions in ncurses.
3863 # That is because we have not set up to link ncurses in lib-src.
3864 # It's better to believe a function is not available
3865 # than to expect to find it in ncurses.
3866 # Also we need tputs and friends to be able to build at all.
3867 AC_MSG_CHECKING([for library containing tputs])
3868 # Run a test program that contains a call to tputs, a call that is
3869 # never executed.  This tests whether a pre-'main' dynamic linker
3870 # works with the library.  It's too much trouble to actually call
3871 # tputs in the test program, due to portability hassles.  When
3872 # cross-compiling, assume the test program will run if it links.
3873 AC_DEFUN([tputs_link_source], [
3874   AC_LANG_SOURCE(
3875      [[extern void tputs (const char *, int, int (*)(int));
3876        int main (int argc, char **argv)
3877        {
3878           if (argc == 10000)
3879             tputs (argv[0], 0, 0);
3880           return 0;
3881        }]])
3882 ])
3883 if test "${opsys}" = "mingw32"; then
3884   msg='none required'
3885 else
3886   # Maybe curses should be tried earlier?
3887   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3888   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3889     OLIBS=$LIBS
3890     if test -z "$tputs_library"; then
3891       LIBS_TERMCAP=
3892       msg='none required'
3893     else
3894       LIBS_TERMCAP=-l$tputs_library
3895       msg=$LIBS_TERMCAP
3896       LIBS="$LIBS_TERMCAP $LIBS"
3897     fi
3898     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3899       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3900     LIBS=$OLIBS
3901     if test "X$msg" != Xno; then
3902       break
3903     fi
3904   done
3905 fi
3906 AC_MSG_RESULT([$msg])
3907 if test "X$msg" = Xno; then
3908   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3909 The following libraries were tried (in order):
3910   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3911 Please try installing whichever of these libraries is most appropriate
3912 for your system, together with its header files.
3913 For example, a libncurses-dev(el) or similar package.])
3914 fi
3915
3916 ## Use termcap instead of terminfo?
3917 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3918 TERMINFO=yes
3919 ## FIXME?  In the cases below where we unconditionally set
3920 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3921 ## if that was found above to have tputs.
3922 ## Should we use the gnu* logic everywhere?
3923 case "$opsys" in
3924   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3925   ##  The ncurses library has been moved out of the System framework in
3926   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3927   ##  option to use it.
3928   darwin) LIBS_TERMCAP="-lncurses" ;;
3929
3930   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3931
3932   freebsd)
3933     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3934     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3935     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3936 [[#if __FreeBSD_version < 400000
3937 fail;
3938 #endif
3939 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3940
3941     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3942
3943     if test $emacs_cv_freebsd_terminfo = yes; then
3944       LIBS_TERMCAP="-lncurses"
3945     else
3946       TERMINFO=no
3947       LIBS_TERMCAP="-ltermcap"
3948     fi
3949     ;;
3950
3951   mingw32)
3952     TERMINFO=no
3953     LIBS_TERMCAP=
3954     ;;
3955
3956   netbsd)
3957     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3958       TERMINFO=no
3959       LIBS_TERMCAP="-ltermcap"
3960     fi
3961     ;;
3962
3963   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3964
3965   ## hpux: Make sure we get select from libc rather than from libcurses
3966   ##  because libcurses on HPUX 10.10 has a broken version of select.
3967   ##  We used to use -lc -lcurses, but this may be cleaner.
3968   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3969   # set that way, now it uses the default).  Isn't this a contradiction?
3970   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3971
3972 esac
3973
3974 TERMCAP_OBJ=tparam.o
3975 if test $TERMINFO = yes; then
3976   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3977   TERMCAP_OBJ=terminfo.o
3978 fi
3979 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3980   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3981 fi
3982 AC_SUBST(LIBS_TERMCAP)
3983 AC_SUBST(TERMCAP_OBJ)
3984
3985 # GNU/Linux-specific timer functions.
3986 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3987   [AC_COMPILE_IFELSE(
3988      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3989                       ]],
3990                       [[timerfd_create (CLOCK_REALTIME,
3991                                         TFD_CLOEXEC | TFD_NONBLOCK);
3992                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3993      [emacs_cv_have_timerfd=yes],
3994      [emacs_cv_have_timerfd=no])])
3995 if test "$emacs_cv_have_timerfd" = yes; then
3996   AC_DEFINE([HAVE_TIMERFD], 1,
3997     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3998 fi
3999
4000 # Alternate stack for signal handlers.
4001 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
4002                [emacs_cv_alternate_stack],
4003   [AC_COMPILE_IFELSE(
4004      [AC_LANG_PROGRAM([[#include <signal.h>
4005                       ]],
4006                       [[stack_t ss;
4007                         struct sigaction sa;
4008                         ss.ss_sp = malloc (SIGSTKSZ);
4009                         ss.ss_size = SIGSTKSZ;
4010                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
4011                         sigaltstack (&ss, 0);
4012                         sigaction (SIGSEGV, &sa, 0);]])],
4013      [emacs_cv_alternate_stack=yes],
4014      [emacs_cv_alternate_stack=no])])
4015
4016 # Do we need the Hesiod library to provide the support routines?
4017 dnl FIXME?  Should we be skipping this on Darwin too?
4018 LIBHESIOD=
4019 LIBRESOLV=
4020 if test "$with_hesiod" != no ; then
4021   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4022   resolv=no
4023   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4024      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4025                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4026   if test "$resolv" = yes ; then
4027     RESOLVLIB=-lresolv
4028   else
4029     RESOLVLIB=
4030   fi
4031   hesiod=no
4032   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4033         hesiod=yes, :, $RESOLVLIB)])
4034
4035   if test x"$hesiod" = xyes; then
4036     LIBHESIOD=-lhesiod
4037     LIBRESOLV=$RESOLVLIB
4038   fi
4039 fi
4040 AC_SUBST(LIBHESIOD)
4041 AC_SUBST(LIBRESOLV)
4042
4043 # These tell us which Kerberos-related libraries to use.
4044 COM_ERRLIB=
4045 CRYPTOLIB=
4046 KRB5LIB=
4047 DESLIB=
4048 KRB4LIB=
4049
4050 if test "${with_kerberos}" != no; then
4051   OLD_LIBS=$LIBS
4052   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4053   if test $have_com_err = yes; then
4054     COM_ERRLIB=-lcom_err
4055     LIBS="$COM_ERRLIB $LIBS"
4056   fi
4057   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4058   if test $have_crypto = yes; then
4059     CRYPTOLIB=-lcrypto
4060     LIBS="$CRYPTOLIB $LIBS"
4061   fi
4062   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4063   if test $have_k5crypto = yes; then
4064     CRYPTOLIB=-lk5crypto
4065     LIBS="$CRYPTOLIB $LIBS"
4066   fi
4067   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4068   if test $have_krb5=yes; then
4069     KRB5LIB=-lkrb5
4070     LIBS="$KRB5LIB $LIBS"
4071   fi
4072   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4073   if test "${with_kerberos5}" = no; then
4074     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4075     if test $have_des425 = yes; then
4076       DESLIB=-ldes425
4077       LIBS="$DESLIB $LIBS"
4078     else
4079       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4080       if test $have_des = yes; then
4081         DESLIB=-ldes
4082         LIBS="$DESLIB $LIBS"
4083       fi
4084     fi
4085     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4086     if test $have_krb4 = yes; then
4087       KRB4LIB=-lkrb4
4088       LIBS="$KRB4LIB $LIBS"
4089     else
4090       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4091       if test $have_krb = yes; then
4092         KRB4LIB=-lkrb
4093         LIBS="$KRB4LIB $LIBS"
4094       fi
4095     fi
4096   fi
4097
4098   if test "${with_kerberos5}" != no; then
4099     AC_CHECK_HEADERS(krb5.h,
4100       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4101                         [#include <krb5.h>])])
4102   else
4103     AC_CHECK_HEADERS(krb.h,,
4104                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4105                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4106   fi
4107   AC_CHECK_HEADERS(com_err.h)
4108   LIBS=$OLD_LIBS
4109 fi
4110
4111 AC_SUBST(COM_ERRLIB)
4112 AC_SUBST(CRYPTOLIB)
4113 AC_SUBST(KRB5LIB)
4114 AC_SUBST(DESLIB)
4115 AC_SUBST(KRB4LIB)
4116
4117 AC_CHECK_HEADERS(valgrind/valgrind.h)
4118
4119 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4120
4121 AC_CHECK_FUNCS_ONCE(tzset)
4122
4123 ok_so_far=yes
4124 AC_CHECK_FUNC(socket, , ok_so_far=no)
4125 if test $ok_so_far = yes; then
4126   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4127 fi
4128 if test $ok_so_far = yes; then
4129   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4130 fi
4131 if test $ok_so_far = yes; then
4132 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4133   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4134             [Define to 1 if you have inet sockets.])
4135 fi
4136
4137 AC_FUNC_FORK
4138
4139 AC_CHECK_FUNCS(snprintf)
4140
4141 dnl Check for glib.  This differs from other library checks in that
4142 dnl Emacs need not link to glib unless some other library is already
4143 dnl linking to glib.  Although glib provides no facilities that Emacs
4144 dnl needs for its own purposes, when glib is present Emacs needs to
4145 dnl use primitives like g_main_context_query to avoid clashing with
4146 dnl glib at a low level.
4147 dnl
4148 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4149 XGSELOBJ=
4150 OLDCFLAGS="$CFLAGS"
4151 OLDLIBS="$LIBS"
4152 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4153 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4154 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4155 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4156 AC_MSG_CHECKING([whether GLib is linked in])
4157 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4158         [[#include <glib.h>
4159         ]],
4160         [[g_print ("Hello world");]])],
4161      [links_glib=yes],
4162      [links_glib=no])
4163 AC_MSG_RESULT([$links_glib])
4164 if test "${links_glib}" = "yes"; then
4165   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4166   if test "$HAVE_NS" = no;then
4167     XGSELOBJ=xgselect.o
4168   fi
4169 fi
4170 CFLAGS="$OLDCFLAGS"
4171 LIBS="$OLDLIBS"
4172 AC_SUBST(XGSELOBJ)
4173
4174 dnl Adapted from Haible's version.
4175 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4176   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4177     [[char* cs = nl_langinfo(CODESET);]])],
4178     emacs_cv_langinfo_codeset=yes,
4179     emacs_cv_langinfo_codeset=no)
4180   ])
4181 if test $emacs_cv_langinfo_codeset = yes; then
4182   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4183     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4184 fi
4185
4186 AC_TYPE_MBSTATE_T
4187
4188 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4189 dnl how the tty code is related to POSIX and/or other versions of termios.
4190 dnl The following looks like a useful start.
4191 dnl
4192 dnl AC_SYS_POSIX_TERMIOS
4193 dnl if test $ac_cv_sys_posix_termios = yes; then
4194 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4195 dnl                                and macros for terminal control.])
4196 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4197 dnl fi
4198
4199 dnl Turned on June 1996 supposing nobody will mind it.
4200 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4201 if test "${opsys}" != "mingw32"; then
4202    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4203      in the full name stands for the login id.])
4204 fi
4205
4206 dnl Everybody supports this, except MS.
4207 dnl Seems like the kind of thing we should be testing for, though.
4208 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4209 if test "${opsys}" != "mingw32"; then
4210   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4211 fi
4212
4213 dnl Everybody supports this, except MS-DOS.
4214 dnl Seems like the kind of thing we should be testing for, though.
4215 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4216 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4217   4.2-compatible sockets.])
4218
4219 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4220
4221 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4222   a null file, or a data sink.])
4223 if test "${opsys}" = "mingw32"; then
4224   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4225 else
4226   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4227 fi
4228
4229 if test "${opsys}" = "mingw32"; then
4230   SEPCHAR=';'
4231 else
4232   SEPCHAR=':'
4233 fi
4234 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4235 dnl This is for MinGW, and is used in test/Makefile.in.
4236 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4237 dnl decides that a command-line argument to be passed to a MinGW program
4238 dnl is a PATH-style list of directories.  But that heuristics plays it
4239 dnl safe, and only does the replacement when it is _absolutely_ sure it
4240 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4241 dnl which breaks in-tree builds.  So we do this manually instead.
4242 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4243 dnl be computed as ':' in MSYS Bash.
4244 AC_SUBST(SEPCHAR)
4245
4246 dnl Everybody supports this, except MS-DOS.
4247 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4248
4249 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4250
4251
4252 AC_DEFINE(DIRECTORY_SEP, ['/'],
4253   [Character that separates directories in a file name.])
4254
4255 if test "${opsys}" = "mingw32"; then
4256   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4257     [Returns true if character is a device separator.])
4258
4259   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4260     [Returns true if character is a directory separator.])
4261
4262   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4263     [Returns true if character is any form of separator.])
4264 else
4265   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4266     [Returns true if character is a device separator.])
4267
4268   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4269     [Returns true if character is a directory separator.])
4270
4271   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4272     [Returns true if character is any form of separator.])
4273 fi
4274
4275 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4276
4277 case $opsys in
4278   aix4-2)
4279     dnl Unfortunately without libXmu we cannot support EditRes.
4280     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4281       AC_DEFINE(NO_EDITRES, 1)
4282     fi
4283     ;;
4284
4285   hpux*)
4286     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4287     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4288     AC_DEFINE(NO_EDITRES, 1)
4289     ;;
4290 esac
4291
4292
4293 case $opsys in
4294   irix6-5 | sol2* | unixware )
4295     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4296     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4297     dnl need the constant to dimension an array.  So wire in the appropriate
4298     dnl value here.
4299     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4300     ;;
4301 esac
4302
4303 emacs_broken_SIGIO=no
4304
4305 case $opsys in
4306   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4307   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4308   hpux* | irix6-5 | nacl | openbsd | sol2* | unixware )
4309     emacs_broken_SIGIO=yes
4310     ;;
4311
4312   aix4-2)
4313     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4314     dnl the way this system works, libc functions that return malloced
4315     dnl memory use the libc malloc implementation. Calling xfree or
4316     dnl xrealloc on the results of such functions results in a crash.
4317     dnl
4318     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4319     dnl but that does not currently work on this system.
4320     dnl
4321     dnl It is possible to completely override the malloc implementation on
4322     dnl AIX, but that involves putting the malloc functions in a shared
4323     dnl library and setting the MALLOCTYPE environment variable to point to
4324     dnl that shared library.
4325     dnl
4326     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4327     dnl to avoid a crash just use the Emacs implementation for that function.
4328     dnl
4329     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4330     dnl of this file, so that we do not check for get_current_dir_name
4331     dnl on AIX.  But that might be fragile if something else ends
4332     dnl up testing for get_current_dir_name as a dependency.
4333     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4334       get_current_dir_name should not be used.])
4335     ;;
4336
4337   freebsd)
4338     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4339     dnl writes/reads on a PTY, read(2) returns bogus data:
4340     dnl
4341     dnl write(2)  1022 bytes
4342     dnl write(2)   954 bytes, get EAGAIN
4343     dnl read(2)   1024 bytes in process_read_output
4344     dnl read(2)     11 bytes in process_read_output
4345     dnl
4346     dnl That is, read(2) returns more bytes than have ever been written
4347     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4348     dnl successfully after processing (for example with CRs added if the
4349     dnl terminal is set up that way which it is here).  The same bytes will
4350     dnl be seen again in a later read(2), without the CRs.
4351     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4352       work around an issue when reading from a PTY.])
4353     ;;
4354 esac
4355
4356 case $opsys in
4357   gnu-* | sol2-10 )
4358     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4359     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4360   ;;
4361 esac
4362
4363 case $opsys in
4364   darwin | dragonfly | freebsd | netbsd | openbsd )
4365     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4366       close a pty to make it a controlling terminal (it is already a
4367       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4368   ;;
4369 esac
4370
4371 dnl FIXME Surely we can test for this rather than hard-code it.
4372 case $opsys in
4373   netbsd | openbsd) sound_device="/dev/audio" ;;
4374   *) sound_device="/dev/dsp" ;;
4375 esac
4376
4377 dnl Used in sound.c
4378 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4379   [Name of the default sound device.])
4380
4381
4382 dnl Emacs can read input using SIGIO and buffering characters itself,
4383 dnl or using CBREAK mode and making C-g cause SIGINT.
4384 dnl The choice is controlled by the variable interrupt_input.
4385 dnl
4386 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4387 dnl
4388 dnl Emacs uses the presence of the USABLE_SIGIO macro
4389 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4390 dnl INTERRUPT_INPUT to decide whether to use it by default.
4391 dnl
4392 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4393 dnl CBREAK mode has two disadvantages
4394 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4395 dnl I hear that in system V this problem does not exist.
4396 dnl 2) Control-G causes output to be discarded.
4397 dnl I do not know whether this can be fixed in system V.
4398 dnl
4399 dnl Another method of doing input is planned but not implemented.
4400 dnl It would have Emacs fork off a separate process
4401 dnl to read the input and send it to the true Emacs process
4402 dnl through a pipe.
4403 case $opsys in
4404   darwin | gnu-linux | gnu-kfreebsd )
4405     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4406   ;;
4407 esac
4408
4409
4410 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4411 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4412 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4413 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4414 dnl taking float or double parameters.
4415 case $opsys in
4416   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
4417     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4418       file defines 'NeedWidePrototypes' as 'NO'.])
4419   ;;
4420 esac
4421
4422
4423 dnl Used in process.c, this must be a loop, even if it only runs once.
4424 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
4425 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4426 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4427 dnl trying suffixes 0-16.
4428 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4429   first PTY, if PTYs are supported.])
4430 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4431 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4432   end of a PTY, if non-standard.])
4433 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4434   end of a PTY, if non-standard.])
4435
4436 case $opsys in
4437   aix4-2 )
4438     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4439     dnl You allocate a pty by opening /dev/ptc to get the master side.
4440     dnl To get the name of the slave side, you just ttyname() the master side.
4441     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4442     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4443     ;;
4444
4445   cygwin )
4446     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4447     dnl multi-line AC_DEFINEs are hard. :(
4448     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4449     AC_DEFINE(PTY_NAME_SPRINTF, [])
4450     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4451     ;;
4452
4453   gnu | openbsd )
4454     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4455     ;;
4456
4457   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4458     dnl if HAVE_GRANTPT
4459     if test "x$ac_cv_func_grantpt" = xyes; then
4460       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4461       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4462       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4463       dnl to prevent sigchld_handler from intercepting the child's death.
4464       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4465       dnl if HAVE_POSIX_OPENPT
4466       if test "x$ac_cv_func_posix_openpt" = xyes; then
4467         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4468         AC_DEFINE(PTY_NAME_SPRINTF, [])
4469       dnl if HAVE_GETPT
4470       elif test "x$ac_cv_func_getpt" = xyes; then
4471         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4472         AC_DEFINE(PTY_NAME_SPRINTF, [])
4473       else
4474         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4475       fi
4476     else
4477       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4478     fi
4479     ;;
4480
4481   hpux*)
4482     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4483     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4484     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4485     ;;
4486
4487   irix6-5 )
4488     dnl It looks like this cannot be right, because it is not a loop.
4489     dnl However, process.c actually does this:
4490     dnl # ifndef __sgi
4491     dnl   continue;
4492     dnl # else
4493     dnl   return -1;
4494     dnl # endif
4495     dnl which presumably makes it OK, since irix == sgi (?).
4496     dnl FIXME it seems like this special treatment is unnecessary?
4497     dnl Why can't irix use a single-trip loop like eg cygwin?
4498     AC_DEFINE(PTY_ITERATION, [])
4499     dnl Not used, because PTY_ITERATION is defined.
4500     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4501     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4502     dnl No need to get the pty name at all.
4503     AC_DEFINE(PTY_NAME_SPRINTF, [])
4504     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4505     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4506     ;;
4507
4508   sol2* )
4509     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4510     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4511     dnl from intercepting that death.  If any child but grantpt's should die
4512     dnl within, it should be caught after sigrelse(2).
4513     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4514     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4515     ;;
4516
4517   unixware )
4518     dnl Comments are as per sol2*.
4519     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4520     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4521     ;;
4522 esac
4523
4524
4525 case $opsys in
4526   sol2* | unixware )
4527     dnl This change means that we don't loop through allocate_pty too
4528     dnl many times in the (rare) event of a failure.
4529     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4530     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4531     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4532     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4533     ;;
4534 esac
4535
4536
4537 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4538 "typing" a signal character on the pty.])
4539
4540 case $opsys in
4541   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4542   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4543   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4544     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4545     ;;
4546
4547   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4548   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4549   gnu-linux | gnu-kfreebsd )
4550
4551     AC_MSG_CHECKING([for signals via characters])
4552     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4553 #include <linux/version.h>
4554 #if LINUX_VERSION_CODE < 0x20400
4555 # error "Linux version too old"
4556 #endif
4557       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4558
4559     AC_MSG_RESULT([$emacs_signals_via_chars])
4560     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4561     ;;
4562 esac
4563
4564
4565 AH_TEMPLATE(TAB3, [Undocumented.])
4566
4567 case $opsys in
4568   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4569
4570   gnu | dragonfly | freebsd | netbsd | openbsd )
4571     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4572     AC_DEFINE(TAB3, OXTABS)
4573     ;;
4574
4575   gnu-linux | gnu-kfreebsd )
4576     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4577 #ifndef __ia64__
4578 # error "not ia64"
4579 #endif
4580       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4581         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4582         [Mark a secondary stack, like the register stack on the ia64.]), [])
4583     ;;
4584
4585   hpux*)
4586     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4587       run_time_remap; for HPUX.])
4588     ;;
4589 esac
4590
4591
4592 dnl This won't be used automatically yet.  We also need to know, at least,
4593 dnl that the stack is continuous.
4594 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4595   registers relevant for conservative garbage collection in the jmp_buf.])
4596
4597
4598 case $opsys in
4599   dnl Not all the architectures are tested, but there are Debian packages
4600   dnl for SCM and/or Guile on them, so the technique must work.  See also
4601   dnl comments in alloc.c concerning setjmp and gcc.
4602   dnl Fixme: it's probably safe to just use the GCC conditional below.
4603   gnu-linux | gnu-kfreebsd )
4604     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4605 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4606   || defined __alpha__ || defined __mips__ || defined __s390__ \
4607   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4608   || defined __ia64__ || defined __sh__
4609 /* ok */
4610 #else
4611 # error "setjmp not known to work on this arch"
4612 #endif
4613     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4614     ;;
4615 esac
4616
4617
4618 if test x$GCC = xyes; then
4619    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4620    AC_DEFINE(GC_SETJMP_WORKS, 1)
4621 else
4622   case $opsys in
4623     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4624     aix* | dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4625       AC_DEFINE(GC_SETJMP_WORKS, 1)
4626       ;;
4627   esac
4628 fi                              dnl GCC?
4629
4630 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4631 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4632   [AC_LINK_IFELSE(
4633      [AC_LANG_PROGRAM(
4634        [[#include <setjmp.h>
4635          #ifdef __MINGW32__
4636          # define _longjmp longjmp
4637          #endif
4638        ]],
4639        [[jmp_buf j;
4640          if (! _setjmp (j))
4641            _longjmp (j, 1);]])],
4642      [emacs_cv_func__setjmp=yes],
4643      [emacs_cv_func__setjmp=no])])
4644 if test $emacs_cv_func__setjmp = yes; then
4645   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4646 fi
4647
4648 # We need to preserve signal mask to handle C stack overflows.
4649 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4650   [AC_LINK_IFELSE(
4651      [AC_LANG_PROGRAM(
4652        [[#include <setjmp.h>
4653        ]],
4654        [[sigjmp_buf j;
4655          if (! sigsetjmp (j, 1))
4656            siglongjmp (j, 1);]])],
4657      [emacs_cv_func_sigsetjmp=yes],
4658      [emacs_cv_func_sigsetjmp=no])])
4659 if test $emacs_cv_func_sigsetjmp = yes; then
4660   AC_DEFINE([HAVE_SIGSETJMP], 1,
4661     [Define to 1 if sigsetjmp and siglongjmp work.])
4662 fi
4663
4664 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4665   yes,yes,* | *,*,mingw32)
4666     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4667       [Define to 1 if C stack overflow can be handled in some cases.]);;
4668 esac
4669
4670 case $opsys in
4671   sol2* | unixware )
4672     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4673     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4674     dnl and this is all we need.
4675     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4676     ;;
4677 esac
4678
4679
4680 case $opsys in
4681   hpux* | sol2* )
4682     dnl Used in xfaces.c.
4683     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4684       some systems, where it requires time.h.])
4685     ;;
4686 esac
4687
4688
4689 dnl Define symbols to identify the version of Unix this is.
4690 dnl Define all the symbols that apply correctly.
4691 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4692 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4693 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4694 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4695
4696 case $opsys in
4697   aix4-2)
4698     AC_DEFINE(USG, [])
4699     dnl This symbol should be defined on AIX Version 3  ???????
4700     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4701 #ifndef _AIX
4702 # error "_AIX not defined"
4703 #endif
4704     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4705     ;;
4706
4707   cygwin)
4708     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4709     ;;
4710
4711   darwin)
4712     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4713     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4714     dnl distinguish OS X from pure Darwin.
4715     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4716     ;;
4717
4718   gnu-linux | gnu-kfreebsd )
4719     AC_DEFINE(USG, [])
4720     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4721     ;;
4722
4723   hpux*)
4724     AC_DEFINE(USG, [])
4725     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4726     ;;
4727
4728   irix6-5)
4729     AC_DEFINE(USG, [])
4730     AC_DEFINE(USG5_4, [])
4731     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4732     ;;
4733
4734   mingw32)
4735     AC_DEFINE(DOS_NT, [])
4736     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4737     if test "x$ac_enable_checking" != "x" ; then
4738       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4739     fi
4740     ;;
4741
4742   sol2*)
4743     AC_DEFINE(USG, [])
4744     AC_DEFINE(USG5_4, [])
4745     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4746     ;;
4747
4748   unixware)
4749     AC_DEFINE(USG, [])
4750     AC_DEFINE(USG5_4, [])
4751     ;;
4752 esac
4753
4754 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4755   [case $opsys in
4756      aix4-2 | nacl)
4757        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4758        emacs_cv_usable_FIONREAD=no
4759        ;;
4760
4761      mingw32)
4762        emacs_cv_usable_FIONREAD=yes
4763        ;;
4764
4765      *)
4766        AC_COMPILE_IFELSE(
4767          [AC_LANG_PROGRAM([[#include <sys/types.h>
4768                             #include <sys/ioctl.h>
4769                             #ifdef USG5_4
4770                             # include <sys/filio.h>
4771                             #endif
4772                           ]],
4773                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4774          [emacs_cv_usable_FIONREAD=yes],
4775          [emacs_cv_usable_FIONREAD=no])
4776        ;;
4777    esac])
4778 if test $emacs_cv_usable_FIONREAD = yes; then
4779   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4780
4781   if test $emacs_broken_SIGIO = no; then
4782     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4783       [AC_COMPILE_IFELSE(
4784          [AC_LANG_PROGRAM([[#include <fcntl.h>
4785                             #include <signal.h>
4786                           ]],
4787                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4788          [emacs_cv_usable_SIGIO=yes],
4789          [emacs_cv_usable_SIGIO=no])],
4790       [emacs_cv_usable_SIGIO=yes],
4791       [emacs_cv_usable_SIGIO=no])
4792     if test $emacs_cv_usable_SIGIO = yes; then
4793       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4794     fi
4795   fi
4796 fi
4797
4798 case $opsys in
4799   hpux11)
4800     dnl It works to open the pty's tty in the parent (Emacs), then
4801     dnl close and reopen it in the child.
4802     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4803       works to open a pty's tty in the parent process, then close and
4804       reopen it in the child.])
4805     ;;
4806
4807   irix6-5)
4808     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4809       use VSUSP instead of VSWTCH.])
4810     ;;
4811
4812   sol2-10)
4813     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4814       on Solaris.])
4815     ;;
4816 esac
4817
4818 # Set up the CFLAGS for real compilation, so we can substitute it.
4819 CFLAGS="$REAL_CFLAGS"
4820 CPPFLAGS="$REAL_CPPFLAGS"
4821 LIBS="$REAL_LIBS"
4822
4823 ## Hack to detect a buggy GCC version.
4824 if test "$GCC" = yes && \
4825    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4826   case $CFLAGS in
4827     *-fno-optimize-sibling-calls*) ;;
4828     *-O@<:@23@:>@*)
4829       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4830   esac
4831 fi
4832
4833 version=$PACKAGE_VERSION
4834
4835 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4836 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4837   [Short copyright string for this version of Emacs.])
4838 AC_SUBST(copyright)
4839
4840 ### Specify what sort of things we'll be editing into Makefile and config.h.
4841 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4842 AC_SUBST(version)
4843 AC_SUBST(configuration)
4844 ## Unused?
4845 AC_SUBST(canonical)
4846 AC_SUBST(srcdir)
4847 AC_SUBST(prefix)
4848 AC_SUBST(exec_prefix)
4849 AC_SUBST(bindir)
4850 AC_SUBST(datadir)
4851 AC_SUBST(sharedstatedir)
4852 AC_SUBST(libexecdir)
4853 AC_SUBST(mandir)
4854 AC_SUBST(infodir)
4855 AC_SUBST(lispdir)
4856 AC_SUBST(standardlisppath)
4857 AC_SUBST(locallisppath)
4858 AC_SUBST(lisppath)
4859 AC_SUBST(x_default_search_path)
4860 AC_SUBST(etcdir)
4861 AC_SUBST(archlibdir)
4862 AC_SUBST(etcdocdir)
4863 AC_SUBST(bitmapdir)
4864 AC_SUBST(gamedir)
4865 AC_SUBST(gameuser)
4866 AC_SUBST(gamegroup)
4867 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4868 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4869 ## end of LIBX_BASE, but nothing ever set it.
4870 AC_SUBST(LD_SWITCH_X_SITE)
4871 AC_SUBST(C_SWITCH_X_SITE)
4872 AC_SUBST(GNUSTEP_CFLAGS)
4873 AC_SUBST(CFLAGS)
4874 ## Used in lwlib/Makefile.in.
4875 AC_SUBST(X_TOOLKIT_TYPE)
4876 AC_SUBST(ns_appdir)
4877 AC_SUBST(ns_appbindir)
4878 AC_SUBST(ns_appresdir)
4879 AC_SUBST(ns_appsrc)
4880 AC_SUBST(GNU_OBJC_CFLAGS)
4881 AC_SUBST(OTHER_FILES)
4882
4883 if test -n "${term_header}"; then
4884     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4885         [Define to the header for the built-in window system.])
4886 fi
4887
4888 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4889                    [Define to the canonical Emacs configuration name.])
4890 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4891                    [Define to the options passed to configure.])
4892 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4893   define this to include extra configuration information.])
4894
4895 case $opsys in
4896   mingw32)
4897     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4898     ;;
4899 esac
4900
4901 XMENU_OBJ=
4902 XOBJ=
4903 FONT_OBJ=
4904 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4905   AC_DEFINE(HAVE_X_WINDOWS, 1,
4906             [Define to 1 if you want to use the X window system.])
4907   XMENU_OBJ=xmenu.o
4908   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4909   FONT_OBJ=xfont.o
4910   if test "$HAVE_CAIRO" = "yes"; then
4911     FONT_OBJ="ftfont.o ftcrfont.o"
4912   elif test "$HAVE_XFT" = "yes"; then
4913     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4914   elif test "$HAVE_FREETYPE" = "yes"; then
4915     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4916   fi
4917   AC_SUBST(FONT_OBJ)
4918 fi
4919 AC_SUBST(XMENU_OBJ)
4920 AC_SUBST(XOBJ)
4921 AC_SUBST(FONT_OBJ)
4922
4923 WIDGET_OBJ=
4924 MOTIF_LIBW=
4925 if test "${USE_X_TOOLKIT}" != "none" ; then
4926   WIDGET_OBJ=widget.o
4927   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4928   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4929     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4930   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4931     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4932     MOTIF_LIBW=-lXm
4933     case "$opsys" in
4934       gnu-linux)
4935         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4936         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4937         ;;
4938
4939       unixware)
4940         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4941         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4942         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4943         ;;
4944
4945       aix4-2)
4946         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4947         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4948         ;;
4949     esac
4950     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4951   fi
4952 fi
4953 AC_SUBST(WIDGET_OBJ)
4954
4955 TOOLKIT_LIBW=
4956 case "$USE_X_TOOLKIT" in
4957   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4958   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4959   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4960 esac
4961 if test "$HAVE_XWIDGETS" = "yes"; then
4962   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4963 fi
4964 AC_SUBST(TOOLKIT_LIBW)
4965
4966 if test "${opsys}" != "mingw32"; then
4967   if test "$USE_X_TOOLKIT" = "none"; then
4968     LIBXT_OTHER="\$(LIBXSM)"
4969   else
4970     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4971   fi
4972 fi
4973 AC_SUBST(LIBXT_OTHER)
4974
4975 if test "${HAVE_X11}" = "yes" ; then
4976   AC_DEFINE(HAVE_X11, 1,
4977             [Define to 1 if you want to use version 11 of X windows.])
4978   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4979 else
4980   LIBX_OTHER=
4981 fi
4982 AC_SUBST(LIBX_OTHER)
4983
4984 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4985   LIBXMENU=
4986 elif test "$USE_X_TOOLKIT" = none; then
4987   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4988 else
4989   LIBXMENU='$(lwlibdir)/liblw.a'
4990 fi
4991 AC_SUBST(LIBXMENU)
4992
4993 AC_CACHE_CHECK([for struct alignment],
4994   [emacs_cv_struct_alignment],
4995   [AC_COMPILE_IFELSE(
4996      [AC_LANG_PROGRAM([[#include <stddef.h>
4997                         struct __attribute__ ((aligned (8))) s { char c; };
4998                         struct t { char c; struct s s; };
4999                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
5000                       ]])],
5001      [emacs_cv_struct_alignment=yes],
5002      [emacs_cv_struct_alignment=no])])
5003 if test "$emacs_cv_struct_alignment" = yes; then
5004   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
5005     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
5006      structure to an N-byte boundary.])
5007 fi
5008
5009 if test "${GNU_MALLOC}" = "yes" ; then
5010   AC_DEFINE(GNU_MALLOC, 1,
5011             [Define to 1 if you want to use the GNU memory allocator.])
5012 fi
5013
5014 RALLOC_OBJ=
5015 if test "${REL_ALLOC}" = "yes" ; then
5016   AC_DEFINE(REL_ALLOC, 1,
5017             [Define REL_ALLOC if you want to use the relocating allocator for
5018              buffer space.])
5019
5020   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
5021 fi
5022 AC_SUBST(RALLOC_OBJ)
5023
5024 if test "$opsys" = "cygwin"; then
5025   CYGWIN_OBJ="cygw32.o"
5026   ## Cygwin differs because of its unexec().
5027   PRE_ALLOC_OBJ=
5028   POST_ALLOC_OBJ=lastfile.o
5029 elif test "$opsys" = "mingw32"; then
5030   CYGWIN_OBJ=
5031   PRE_ALLOC_OBJ=
5032   POST_ALLOC_OBJ=lastfile.o
5033 else
5034   CYGWIN_OBJ=
5035   PRE_ALLOC_OBJ=lastfile.o
5036   POST_ALLOC_OBJ=
5037 fi
5038 AC_SUBST(CYGWIN_OBJ)
5039 AC_SUBST(PRE_ALLOC_OBJ)
5040 AC_SUBST(POST_ALLOC_OBJ)
5041
5042 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
5043 dnl verbatim defined above.  The tricky name is apropos, as this hack
5044 dnl makes Fortify go sour!
5045 AH_VERBATIM([FORTIFY_SOUR],
5046 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
5047    The workaround disables some useful run-time checking, so it
5048    should be conditional to the platforms with the performance bug.
5049    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
5050 #if defined __APPLE__ && defined __GNUC__
5051 # ifndef _DONT_USE_CTYPE_INLINE_
5052 #  define _DONT_USE_CTYPE_INLINE_
5053 # endif
5054 # ifndef _FORTIFY_SOURCE
5055 #  define _FORTIFY_SOURCE 0
5056 # endif
5057 #endif
5058 ])
5059
5060 # If user asks to omit features, disable optional features that gnulib
5061 # might otherwise enable.
5062 if test "$with_features" = no && test "$enable_acl" != yes; then
5063   enable_acl=no
5064 fi
5065
5066 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5067 # it temporarily reverts them to their pre-pkg-config values,
5068 # because gnulib needs to work with both src (which uses the
5069 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5070 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5071 # and it therefore needs to run in an environment where LIBS does not
5072 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5073 # for some package unrelated to lib-src.
5074 SAVE_CFLAGS=$CFLAGS
5075 SAVE_LIBS=$LIBS
5076 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5077 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5078 gl_ASSERT_NO_GNULIB_POSIXCHECK
5079 gl_ASSERT_NO_GNULIB_TESTS
5080 gl_INIT
5081 CFLAGS=$SAVE_CFLAGS
5082 LIBS=$SAVE_LIBS
5083
5084 if test "${opsys}" = "mingw32"; then
5085   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5086   # Remove unneeded switches from the value of CC that goes to Makefiles
5087   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5088 fi
5089
5090 case "$opsys" in
5091   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5092
5093   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5094
5095   darwin)
5096    ## The -headerpad option tells ld (see man page) to leave room at the
5097    ## end of the header for adding load commands.  Needed for dumping.
5098    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5099    ## architecture (where they are 78 bytes each). The actual number of
5100    ## load commands added is not consistent but normally ranges from
5101    ## about 14 to about 34. Setting it high gets us plenty of slop and
5102    ## only costs about 1.5K of wasted binary space.
5103    headerpad_extra=1000
5104    if test "$HAVE_NS" = "yes"; then
5105      libs_nsgui="-framework AppKit"
5106      if test "$NS_IMPL_COCOA" = "yes"; then
5107         libs_nsgui="$libs_nsgui -framework IOKit"
5108      fi
5109    else
5110      libs_nsgui=
5111    fi
5112    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5113
5114    ## This is here because src/Makefile.in did some extra fiddling around
5115    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5116    ## LD_SWITCH_SYSTEM_TEMACS instead,
5117    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5118      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5119    ;;
5120
5121   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5122   ## find X at run-time.
5123   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5124   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5125   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5126   ## had different values in configure (in ac_link) and src/Makefile.in.
5127   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5128   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5129
5130   mingw32)
5131    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5132    case "$canonical" in
5133      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5134      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5135    esac
5136    ;;
5137
5138   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5139 esac
5140
5141 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5142 # with "hardened" GCC configurations for some reason (Bug#18784).
5143 # We don't know why -nopie works, but not segfaulting is better than
5144 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5145 # clang keeps warning that it does not understand -nopie, and pre-4.6
5146 # GCC has a similar problem (Bug#20338).
5147 AC_CACHE_CHECK([whether $CC accepts -nopie],
5148   [emacs_cv_prog_cc_nopie],
5149   [emacs_save_c_werror_flag=$ac_c_werror_flag
5150    emacs_save_LDFLAGS=$LDFLAGS
5151    ac_c_werror_flag=yes
5152    LDFLAGS="$LDFLAGS -nopie"
5153    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5154      [emacs_cv_prog_cc_nopie=yes],
5155      [emacs_cv_prog_cc_nopie=no])
5156    ac_c_werror_flag=$emacs_save_c_werror_flag
5157    LDFLAGS=$emacs_save_LDFLAGS])
5158 if test "$emacs_cv_prog_cc_nopie" = yes; then
5159   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5160 fi
5161
5162 if test x$ac_enable_profiling != x ; then
5163   case $opsys in
5164     *freebsd | gnu-linux) ;;
5165     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5166   esac
5167 fi
5168
5169 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5170
5171 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5172
5173 ## Common for all window systems
5174 if test "$window_system" != "none"; then
5175   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5176   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5177   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5178 fi
5179
5180 AC_SUBST(WINDOW_SYSTEM_OBJ)
5181
5182 AH_TOP([/* GNU Emacs site configuration template file.
5183
5184 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5185   Free Software Foundation, Inc.
5186
5187 This file is part of GNU Emacs.
5188
5189 GNU Emacs is free software: you can redistribute it and/or modify
5190 it under the terms of the GNU General Public License as published by
5191 the Free Software Foundation, either version 3 of the License, or
5192 (at your option) any later version.
5193
5194 GNU Emacs is distributed in the hope that it will be useful,
5195 but WITHOUT ANY WARRANTY; without even the implied warranty of
5196 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5197 GNU General Public License for more details.
5198
5199 You should have received a copy of the GNU General Public License
5200 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5201
5202
5203 /* No code in Emacs #includes config.h twice, but some bits of code
5204    intended to work with other packages as well (like gmalloc.c)
5205    think they can include it as many times as they like.  */
5206 #ifndef EMACS_CONFIG_H
5207 #define EMACS_CONFIG_H
5208 ])dnl
5209
5210 AH_BOTTOM([#include <conf_post.h>
5211
5212 #endif /* EMACS_CONFIG_H */
5213
5214 /*
5215 Local Variables:
5216 mode: c
5217 End:
5218 */
5219 ])dnl
5220
5221 #### Report on what we decided to do.
5222 #### Report GTK as a toolkit, even if it doesn't use Xt.
5223 #### It makes printing result more understandable as using GTK sets
5224 #### toolkit_scroll_bars to yes by default.
5225 if test "${HAVE_GTK}" = "yes"; then
5226   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5227 fi
5228
5229 if test $USE_ACL -ne 0; then
5230   ACL_SUMMARY="yes $LIB_ACL"
5231 else
5232   ACL_SUMMARY=no
5233 fi
5234
5235 emacs_standard_dirs='Standard dirs'
5236 AS_ECHO(["
5237 Configured for '${canonical}'.
5238
5239   Where should the build process find the source code?    ${srcdir}
5240   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5241   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5242   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5243   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5244   What window system should Emacs use?                    ${window_system}
5245   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5246   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5247   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5248
5249 optsep=
5250 emacs_config_features=
5251 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5252   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5253   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5254   XWIDGETS; do
5255
5256     case $opt in
5257       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5258       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5259       *) eval val=\${HAVE_$opt} ;;
5260     esac
5261     case x$val in
5262       xno|xnone|x) continue ;;
5263     esac
5264     case $opt in
5265       X_TOOLKIT)
5266         case $val in
5267           GTK*|LUCID|MOTIF) opt=$val ;;
5268           *) continue ;;
5269         esac
5270       ;;
5271     esac
5272     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5273     optsep=' '
5274 done
5275 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5276   [Summary of some of the main features enabled by configure.])
5277
5278 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5279   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5280   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5281   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5282   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5283   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5284   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5285   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5286   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5287   Does Emacs support sound?                               ${HAVE_SOUND}
5288   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5289   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5290   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5291   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5292   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5293   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5294   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5295   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5296   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5297   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5298   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5299   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5300   Does Emacs use -lxft?                                   ${HAVE_XFT}
5301   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5302   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5303   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5304   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5305 "])
5306
5307 if test -n "${EMACSDATA}"; then
5308    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5309 fi
5310 if test -n "${EMACSDOC}"; then
5311    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5312 fi
5313
5314 echo
5315
5316 if test "$HAVE_NS" = "yes"; then
5317    echo
5318    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5319 The installed application will go to nextstep/Emacs.app and can be
5320 run or moved from there."])
5321    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5322       echo "The application will be fully self-contained."
5323     else
5324       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5325 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5326 to run if these resources are not installed."])
5327    fi
5328    echo
5329 fi
5330
5331 if test "${opsys}" = "cygwin"; then
5332   case `uname -r` in
5333     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5334            echo
5335            ;;
5336   esac
5337 fi
5338
5339 # Remove any trailing slashes in these variables.
5340 case $prefix in
5341   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5342 esac
5343 case $exec_prefix in
5344   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5345 esac
5346
5347 if test "$HAVE_NS" = "yes"; then
5348   if test "$NS_IMPL_GNUSTEP" = yes; then
5349     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5350       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5351     ns_check_file=Resources/Info-gnustep.plist
5352   else
5353     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5354       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5355     ns_check_file=Contents/Info.plist
5356   fi
5357   AC_SUBST(ns_check_file)
5358 fi
5359
5360 dnl config.status treats $srcdir specially, so I think this is ok...
5361 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5362
5363 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5364 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5365 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5366 dnl (else you get "no 'Makefile.am' found for any configure output").
5367 dnl This will work, but you get a config.status that is not quite right
5368 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5369 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5370 dnl it seems better to just live with the duplication.
5371 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5372
5373 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5374        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5375        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5376        leim/Makefile nextstep/Makefile nt/Makefile])
5377
5378 dnl test/ is not present in release tarfiles.
5379 opt_makefile=test/Makefile
5380
5381 if test -f "$srcdir/$opt_makefile.in"; then
5382   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5383   dnl Again, it's best not to use a variable.  Though you can add
5384   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5385   AC_CONFIG_FILES([test/Makefile])
5386 fi
5387
5388
5389 dnl The admin/ directory used to be excluded from tarfiles.
5390 if test -d $srcdir/admin; then
5391   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5392   AC_CONFIG_FILES([admin/charsets/Makefile])
5393   AC_CONFIG_FILES([admin/unidata/Makefile])
5394   AC_CONFIG_FILES([admin/grammars/Makefile])
5395 fi                              dnl -d admin
5396
5397
5398 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5399
5400 AC_SUBST(SUBDIR_MAKEFILES_IN)
5401
5402 dnl You might wonder (I did) why epaths.h is generated by running make,
5403 dnl rather than just letting configure generate it from epaths.in.
5404 dnl One reason is that the various paths are not fully expanded (see above);
5405 dnl eg gamedir=${prefix}/var/games/emacs.
5406 dnl Secondly, the GNU Coding standards require that one should be able
5407 dnl to run 'make prefix=/some/where/else' and override the values set
5408 dnl by configure.  This also explains the 'move-if-change' test and
5409 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5410 AC_CONFIG_COMMANDS([src/epaths.h], [
5411 if test "${opsys}" = "mingw32"; then
5412   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5413 else
5414   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5415 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5416 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5417
5418 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5419 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5420 dnl or a symlink?
5421 AC_CONFIG_COMMANDS([src/.gdbinit], [
5422 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5423   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5424 fi
5425 ])
5426
5427 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5428 dnl See comments for etc-refcards-emacsver.tex.
5429 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5430 dnl it is not quite the same.  But we are generating in $srcdir.
5431 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5432 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5433 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5434 ])
5435
5436 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5437 dnl then a directory etc/refcards is created in the build directory,
5438 dnl which is probably harmless, but confusing (in out-of-tree builds).
5439 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5440 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5441 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5442 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5443 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5444 ])
5445
5446 AC_OUTPUT
5447
5448 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])