code.delx.au - gnu-emacs/blob - lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 86, 92, 94, 95, 96, 97, 1998, 1999 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file parses the command line and gets Emacs running.  Options on
  28 ;; the command line are handled in precedence order.  The order is the
  29 ;; one in the list below; first described means first handled.  Options
  30 ;; within each category (delimited by a bar) are handled in the order
  31 ;; encountered on the command line.
  32
  33 ;; -------------------------
  34 ;; -version                  Print Emacs version to stderr, then exit
  35 ;; --version                 successfully right away.
  36 ;;                           This option is handled by emacs.c
  37 ;; -------------------------
  38 ;; -help                     Print a short usage description and exit
  39 ;; --help                    successfully right away.
  40 ;;                           This option is handled by emacs.c
  41 ;; -------------------------
  42 ;; -nl                       Do not use shared memory (for systems that
  43 ;; -no-shared-memory         support this) for the dumped Emacs data.
  44 ;;                           This option is handled by emacs.c
  45 ;;
  46 ;; -map                      For VMS.
  47 ;; --map-data                This option is handled by emacs.c
  48 ;; -------------------------
  49 ;; -t FILE                   Use FILE as the name of the terminal.
  50 ;; --terminal FILE           Using this implies "-nw" also.
  51 ;;                           This option is handled by emacs.c
  52 ;; -------------------------
  53 ;; -d DISPNAME               Use DISPNAME as the name of the X-windows
  54 ;; -display DISPNAME         display for the initial frame.
  55 ;; --display DISPNAME        This option is handled by emacs.c
  56 ;; -------------------------
  57 ;; -nw                       Do not use a windows system (but use the
  58 ;; --no-windows              terminal instead.)
  59 ;;                           This option is handled by emacs.c
  60 ;; -------------------------
  61 ;; -batch                    Execute noninteractively (messages go to stdout,
  62 ;; --batch                   variable noninteractive set to t)
  63 ;;                           This option is handled by emacs.c
  64 ;; -------------------------
  65 ;; -q                        Do not load user's init file and do not load
  66 ;; -no-init-file             "default.el".  Regardless of this switch,
  67 ;; --no-init-file            "site-start" is still loaded.
  68 ;; -------------------------
  69 ;; -no-site-file             Do not load "site-start.el".  (This is the ONLY
  70 ;; --no-site-file            way to prevent loading that file.)
  71 ;; -------------------------
  72 ;; -u USER                   Load USER's init file instead of the init
  73 ;; -user USER                file belonging to the user starting Emacs.
  74 ;; --user USER
  75 ;; -------------------------
  76 ;; -debug-init               Don't catch errors in init files; let the
  77 ;; --debug-init              debugger run.
  78 ;; -------------------------
  79 ;; -i ICONTYPE               Set type of icon using when Emacs is
  80 ;; -itype ICONTYPE           iconified under X-windows.
  81 ;; --icon-type ICONTYPE      This option is passed on to term/x-win.el
  82 ;;
  83 ;; -iconic                   Start Emacs iconified under X-windows.
  84 ;; --iconic                  This option is passed on to term/x-win.el
  85 ;; -------------------------
  86 ;; Various X-windows options for colors/fonts/geometry/title etc.
  87 ;; These options are passed on to term/x-win.el which see.  Certain
  88 ;; of these are also found in term/pc-win.el
  89 ;; -------------------------
  90 ;; FILE                      Visit FILE.
  91 ;;
  92 ;; -L DIRNAME                Add DIRNAME to load-path
  93 ;; -directory DIRNAME
  94 ;; --directory DIRNAME
  95 ;;
  96 ;; -l FILE                   Load and execute the Emacs lisp code
  97 ;; -load FILE                in FILE.
  98 ;; --load FILE
  99 ;;
 100 ;; -f FUNC                   Execute Emacs lisp function FUNC with
 101 ;; -funcall FUNC             no arguments.  The "-e" form is outdated
 102 ;; --funcall FUNC            and should not be used.  (It's a typo
 103 ;; -e FUNC                   promoted to a feature.)
 104 ;;
 105 ;; -eval FORM                Execute Emacs lisp form FORM.
 106 ;; --eval FORM
 107 ;;
 108 ;; -insert FILE              Insert the contents of FILE into buffer.
 109 ;; --insert FILE
 110 ;; -------------------------
 111 ;; -kill                     Kill (exit) Emacs right away.
 112 ;; --kill
 113 ;; -------------------------
 114
 115 ;;; Code:
 116
 117 (setq top-level '(normal-top-level))
 118
 119 (defvar command-line-processed nil
 120   "Non-nil once command line has been processed")
 121
 122 (defgroup initialization nil
 123   "Emacs start-up procedure"
 124   :group 'internal)
 125
 126 (defcustom inhibit-startup-message nil
 127   "*Non-nil inhibits the initial startup message.
 128 This is for use in your personal init file, once you are familiar
 129 with the contents of the startup message."
 130   :type 'boolean
 131   :group 'initialization)
 132
 133 (defcustom inhibit-startup-echo-area-message nil
 134   "*Non-nil inhibits the initial startup echo area message.
 135 Setting this variable takes effect
 136 only if you do it with the customization buffer
 137 or if your `.emacs' file contains a line of this form:
 138  (setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\")
 139 If your `.emacs' file is byte-compiled, use the following form instead:
 140  (eval '(setq inhibit-startup-echo-area-message \"YOUR-USER-NAME\"))
 141 Thus, someone else using a copy of your `.emacs' file will see
 142 the startup message unless he personally acts to inhibit it."
 143   :type '(choice (const :tag "Don't inhibit")
 144                  (string :tag "Enter your user name, to inhibit"))
 145   :group 'initialization)
 146
 147 (defcustom inhibit-default-init nil
 148   "*Non-nil inhibits loading the `default' library."
 149   :type 'boolean
 150   :group 'initialization)
 151
 152 (defvar command-switch-alist nil
 153   "Alist of command-line switches.
 154 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
 155 HANDLER-FUNCTION receives switch name as sole arg;
 156 remaining command-line args are in the variable `command-line-args-left'.")
 157
 158 (defvar command-line-args-left nil
 159   "List of command-line args not yet processed.")
 160
 161 (defvar command-line-functions nil    ;; lrs 7/31/89
 162   "List of functions to process unrecognized command-line arguments.
 163 Each function should access the dynamically bound variables
 164 `argi' (the current argument) and `command-line-args-left' (the remaining
 165 arguments).  The function should return non-nil only if it recognizes and
 166 processes `argi'.  If it does so, it may consume successive arguments by
 167 altering `command-line-args-left' to remove them.")
 168
 169 (defvar command-line-default-directory nil
 170   "Default directory to use for command line arguments.
 171 This is normally copied from `default-directory' when Emacs starts.")
 172
 173 ;;; This is here, rather than in x-win.el, so that we can ignore these
 174 ;;; options when we are not using X.
 175 (defvar command-line-x-option-alist
 176   '(("-bw" 1 x-handle-numeric-switch border-width)
 177     ("-d" 1 x-handle-display)
 178     ("-display" 1 x-handle-display)
 179     ("-name" 1 x-handle-name-switch)
 180     ("-title" 1 x-handle-switch title)
 181     ("-T" 1 x-handle-switch title)
 182     ("-r" 0 x-handle-switch reverse t)
 183     ("-rv" 0 x-handle-switch reverse t)
 184     ("-reverse" 0 x-handle-switch reverse t)
 185     ("-reverse-video" 0 x-handle-switch reverse t)
 186     ("-fn" 1 x-handle-switch font)
 187     ("-font" 1 x-handle-switch font)
 188     ("-ib" 1 x-handle-numeric-switch internal-border-width)
 189     ("-g" 1 x-handle-geometry)
 190     ("-geometry" 1 x-handle-geometry)
 191     ("-fg" 1 x-handle-switch foreground-color)
 192     ("-foreground" 1 x-handle-switch foreground-color)
 193     ("-bg" 1 x-handle-switch background-color)
 194     ("-background" 1 x-handle-switch background-color)
 195     ("-ms" 1 x-handle-switch mouse-color)
 196     ("-itype" 0 x-handle-switch icon-type t)
 197     ("-i" 0 x-handle-switch icon-type t)
 198     ("-iconic" 0 x-handle-iconic)
 199     ("-xrm" 1 x-handle-xrm-switch)
 200     ("-cr" 1 x-handle-switch cursor-color)
 201     ("-vb" 0 x-handle-switch vertical-scroll-bars t)
 202     ("-hb" 0 x-handle-switch horizontal-scroll-bars t)
 203     ("-bd" 1 x-handle-switch)
 204     ("--border-width" 1 x-handle-numeric-switch border-width)
 205     ("--display" 1 x-handle-display)
 206     ("--name" 1 x-handle-name-switch)
 207     ("--title" 1 x-handle-switch title)
 208     ("--reverse-video" 0 x-handle-switch reverse t)
 209     ("--font" 1 x-handle-switch font)
 210     ("--internal-border" 1 x-handle-numeric-switch internal-border-width)
 211     ("--geometry" 1 x-handle-geometry)
 212     ("--foreground-color" 1 x-handle-switch foreground-color)
 213     ("--background-color" 1 x-handle-switch background-color)
 214     ("--mouse-color" 1 x-handle-switch mouse-color)
 215     ("--icon-type" 0 x-handle-switch icon-type t)
 216     ("--iconic" 0 x-handle-iconic)
 217     ("--xrm" 1 x-handle-xrm-switch)
 218     ("--cursor-color" 1 x-handle-switch cursor-color)
 219     ("--vertical-scroll-bars" 0 x-handle-switch vertical-scroll-bars t)
 220     ("--border-color" 1 x-handle-switch border-width))
 221   "Alist of X Windows options.
 222 Each element has the form
 223   (NAME NUMARGS HANDLER FRAME-PARAM VALUE)
 224 where NAME is the option name string, NUMARGS is the number of arguments
 225 that the option accepts, HANDLER is a function to call to handle the option.
 226 FRAME-PARAM (optional) is the frame parameter this option specifies,
 227 and VALUE is the value which is given to that frame parameter
 228 \(most options use the argument for this, so VALUE is not present).")
 229
 230 (defvar before-init-hook nil
 231   "Normal hook run after handling urgent options but before loading init files.")
 232
 233 (defvar after-init-hook nil
 234   "Normal hook run after loading the init files, `~/.emacs' and `default.el'.
 235 There is no `condition-case' around the running of these functions;
 236 therefore, if you set `debug-on-error' non-nil in `.emacs',
 237 an error in one of these functions will invoke the debugger.")
 238
 239 (defvar emacs-startup-hook nil
 240   "Normal hook run after loading init files and handling the command line.")
 241
 242 (defvar term-setup-hook nil
 243   "Normal hook run after loading terminal-specific Lisp code.
 244 It also follows `emacs-startup-hook'.  This hook exists for users to set,
 245 so as to override the definitions made by the terminal-specific file.
 246 Emacs never sets this variable itself.")
 247
 248 (defvar keyboard-type nil
 249   "The brand of keyboard you are using.
 250 This variable is used to define
 251 the proper function and keypad keys for use under X.  It is used in a
 252 fashion analogous to the environment variable TERM.")
 253
 254 (defvar window-setup-hook nil
 255   "Normal hook run to initialize window system display.
 256 Emacs runs this hook after processing the command line arguments and loading
 257 the user's init file.")
 258
 259 (defcustom initial-major-mode 'lisp-interaction-mode
 260   "Major mode command symbol to use for the initial *scratch* buffer."
 261   :type 'function
 262   :group 'initialization)
 263
 264 (defcustom init-file-user nil
 265   "Identity of user whose `.emacs' file is or was read.
 266 The value is nil if `-q' or `--no-init-file' was specified,
 267 meaning do not load any init file.
 268
 269 Otherwise, the value may be the null string, meaning use the init file
 270 for the user that originally logged in, or it may be a
 271 string containing a user's name meaning use that person's init file.
 272
 273 In either of the latter cases, `(concat \"~\" init-file-user \"/\")'
 274 evaluates to the name of the directory where the `.emacs' file was
 275 looked for.
 276
 277 Setting `init-file-user' does not prevent Emacs from loading
 278 `site-start.el'.  The only way to do that is to use `--no-site-file'."
 279   :type '(choice (const :tag "none" nil) string)
 280   :group 'initialization)
 281
 282 (defcustom site-run-file "site-start"
 283   "File containing site-wide run-time initializations.
 284 This file is loaded at run-time before `~/.emacs'.  It contains inits
 285 that need to be in place for the entire site, but which, due to their
 286 higher incidence of change, don't make sense to load into emacs'
 287 dumped image.  Thus, the run-time load order is: 1. file described in
 288 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.
 289
 290 Don't use the `site-start.el' file for things some users may not like.
 291 Put them in `default.el' instead, so that users can more easily
 292 override them.  Users can prevent loading `default.el' with the `-q'
 293 option or by setting `inhibit-default-init' in their own init files,
 294 but inhibiting `site-start.el' requires `--no-site-file', which
 295 is less convenient."
 296   :type '(choice (const :tag "none" nil) string)
 297   :group 'initialization)
 298
 299 (defconst iso-8859-n-locale-regexp "8859[-_]?\\([1-49]\\)"
 300   "Regexp that specifies when to enable an ISO 8859-N character set.
 301 We do that if this regexp matches the locale name
 302 specified by the LC_ALL, LC_CTYPE and LANG environment variables.
 303 The paren group in the regexp should match the specific character
 304 set number, N.")
 305
 306 (defcustom mail-host-address nil
 307   "*Name of this machine, for purposes of naming users."
 308   :type '(choice (const nil) string)
 309   :group 'mail)
 310
 311 (defcustom user-mail-address nil
 312   "*Full mailing address of this user.
 313 This is initialized based on `mail-host-address',
 314 after your init file is read, in case it sets `mail-host-address'."
 315   :type 'string
 316   :group 'mail)
 317
 318 (defcustom auto-save-list-file-prefix
 319   (if (eq system-type 'ms-dos)
 320       "~/_s"  ; MS-DOS cannot have initial dot, and allows only 8.3 names
 321     "~/.saves-")
 322   "Prefix for generating `auto-save-list-file-name'.
 323 This is used after reading your `.emacs' file to initialize
 324 `auto-save-list-file-name', by appending Emacs's pid and the system name,
 325 if you have not already set `auto-save-list-file-name' yourself.
 326 Set this to nil if you want to prevent `auto-save-list-file-name'
 327 from being initialized."
 328   :type '(choice (const :tag "Don't record a session's auto save list" nil)
 329                  string)
 330   :group 'auto-save)
 331
 332 (defvar locale-translation-file-name
 333   (let ((files '("/usr/lib/X11/locale/locale.alias" ; e.g. X11R6.4
 334                  "/usr/X11R6/lib/X11/locale/locale.alias" ; e.g. RedHat 4.2
 335                  "/usr/openwin/lib/locale/locale.alias" ; e.g. Solaris 2.6
 336                  ;;
 337                  ;; The following name appears after the X-related names above,
 338                  ;; since the X-related names are what X actually uses.
 339                  "/usr/share/locale/locale.alias" ; GNU/Linux sans X
 340                  )))
 341     (while (and files (not (file-exists-p (car files))))
 342       (setq files (cdr files)))
 343     (car files))
 344   "*File name for the system's file of locale-name aliases, or nil if none.")
 345
 346 (defvar init-file-debug nil)
 347
 348 (defvar init-file-had-error nil)
 349
 350 (defun normal-top-level-add-subdirs-to-load-path ()
 351   "Add all subdirectories of current directory to `load-path'.
 352 More precisely, this uses only the subdirectories whose names
 353 start with letters or digits; it excludes any subdirectory named `RCS'
 354 or `CVS', and any subdirectory that contains a file named `.nosearch'."
 355   (let (dirs
 356         (pending (list default-directory)))
 357     ;; This loop does a breadth-first tree walk on DIR's subtree,
 358     ;; putting each subdir into DIRS as its contents are examined.
 359     (while pending
 360       (setq dirs (cons (car pending) dirs))
 361       (setq pending (cdr pending))
 362       (let ((contents (directory-files (car dirs)))
 363             (default-directory (car dirs)))
 364         (while contents
 365           (unless (member (car contents) '("." ".." "RCS" "CVS"))
 366             (when (and (string-match "\\`[a-zA-Z0-9]" (car contents))
 367                        (file-directory-p (car contents)))
 368               (let ((expanded (expand-file-name (car contents))))
 369                 (unless (file-exists-p (expand-file-name ".nosearch"
 370                                                          expanded))
 371                   (setq pending (nconc pending (list expanded)))))))
 372           (setq contents (cdr contents)))))
 373     (normal-top-level-add-to-load-path (cdr (nreverse dirs)))))
 374
 375 ;; This function is called from a subdirs.el file.
 376 ;; It assumes that default-directory is the directory
 377 ;; in which the subdirs.el file exists,
 378 ;; and it adds to load-path the subdirs of that directory
 379 ;; as specified in DIRS.  Normally the elements of DIRS are relative.
 380 (defun normal-top-level-add-to-load-path (dirs)
 381   (let ((tail load-path)
 382         (thisdir (directory-file-name default-directory)))
 383     (while (and tail
 384                 (not (equal thisdir (car tail)))
 385                 (not (and (memq system-type '(ms-dos windows-nt))
 386                           (equal (downcase thisdir) (downcase (car tail))))))
 387       (setq tail (cdr tail)))
 388     (setcdr tail (append (mapcar 'expand-file-name dirs) (cdr tail)))))
 389
 390 (defun normal-top-level ()
 391   (if command-line-processed
 392       (message "Back to top level.")
 393     (setq command-line-processed t)
 394     ;; Give *Messages* the same default-directory as *scratch*,
 395     ;; just to keep things predictable.
 396     (let ((dir default-directory))
 397       (save-excursion
 398         (set-buffer (get-buffer "*Messages*"))
 399         (setq default-directory dir)))
 400     ;; For root, preserve owner and group when editing files.
 401     (if (equal (user-uid) 0)
 402         (setq backup-by-copying-when-mismatch t))
 403     ;; Look in each dir in load-path for a subdirs.el file.
 404     ;; If we find one, load it, which will add the appropriate subdirs
 405     ;; of that dir into load-path,
 406     (let ((tail load-path)
 407           new)
 408       (while tail
 409         (setq new (cons (car tail) new))
 410         (let ((default-directory (car tail)))
 411           (load (expand-file-name "subdirs.el" (car tail)) t t t))
 412         (setq tail (cdr tail))))
 413     (if (not (eq system-type 'vax-vms))
 414         (progn
 415           ;; If the PWD environment variable isn't accurate, delete it.
 416           (let ((pwd (getenv "PWD")))
 417             (and (stringp pwd)
 418                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 419                  ;; describes the directory linked to, not FOO itself.
 420                  (or (equal (file-attributes
 421                              (concat (file-name-as-directory pwd) "."))
 422                             (file-attributes
 423                              (concat (file-name-as-directory default-directory)
 424                                      ".")))
 425                      (setq process-environment
 426                            (delete (concat "PWD=" pwd)
 427                                    process-environment)))))))
 428     (setq default-directory (abbreviate-file-name default-directory))
 429     (let ((menubar-bindings-done nil))
 430       (unwind-protect
 431           (command-line)
 432         ;; Do this again, in case .emacs defined more abbreviations.
 433         (setq default-directory (abbreviate-file-name default-directory))
 434         ;; Specify the file for recording all the auto save files of this session.
 435         ;; This is used by recover-session.
 436         (or auto-save-list-file-name
 437             (and auto-save-list-file-prefix
 438                  (setq auto-save-list-file-name
 439                        ;; Under MS-DOS our PID is almost always reused between
 440                        ;; Emacs invocations.  We need something more unique.
 441                        (if (eq system-type 'ms-dos)
 442                            (concat
 443                             (make-temp-name
 444                              (expand-file-name auto-save-list-file-prefix))
 445                             "~")
 446
 447                          (expand-file-name (format "%s%d-%s~"
 448                                                    auto-save-list-file-prefix
 449                                                    (emacs-pid)
 450                                                    (system-name)))))))
 451         (run-hooks 'emacs-startup-hook)
 452         (and term-setup-hook
 453              (run-hooks 'term-setup-hook))
 454         ;; Modify the initial frame based on what .emacs puts into
 455         ;; ...-frame-alist.
 456         (if (fboundp 'frame-notice-user-settings)
 457             (frame-notice-user-settings))
 458         ;; Now we know the user's default font, so add it to the menu.
 459         (if (fboundp 'font-menu-add-default)
 460             (font-menu-add-default))
 461         (and window-setup-hook
 462              (run-hooks 'window-setup-hook))
 463         (or menubar-bindings-done
 464             (if (memq window-system '(x w32))
 465                 (precompute-menubar-bindings)))))))
 466
 467 ;; Precompute the keyboard equivalents in the menu bar items.
 468 (defun precompute-menubar-bindings ()
 469   (let ((submap (lookup-key global-map [menu-bar])))
 470     (while submap
 471       (and (consp (car submap))
 472            (symbolp (car (car submap)))
 473            (stringp (car-safe (cdr (car submap))))
 474            (keymapp (cdr (cdr (car submap))))
 475            (progn
 476              (x-popup-menu nil (cdr (cdr (car submap))))
 477              (if purify-flag
 478                  (garbage-collect))))
 479       (setq submap (cdr submap))))
 480   (setq define-key-rebound-commands t))
 481
 482 (defun command-line ()
 483   (setq command-line-default-directory default-directory)
 484
 485   ;; Choose a reasonable location for temporary files.
 486   (setq temporary-file-directory
 487         (file-name-as-directory
 488          (cond ((memq system-type '(ms-dos windows-nt))
 489                 (or (getenv "TEMP") (getenv "TMPDIR") (getenv "TMP") "c:/temp"))
 490                ((memq system-type '(vax-vms axp-vms))
 491                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "SYS$SCRATCH:"))
 492                (t
 493                 (or (getenv "TMPDIR") (getenv "TMP") (getenv "TEMP") "/tmp")))))
 494
 495   ;; See if we should import version-control from the environment variable.
 496   (let ((vc (getenv "VERSION_CONTROL")))
 497     (cond ((eq vc nil))                 ;don't do anything if not set
 498           ((or (string= vc "t")
 499                (string= vc "numbered"))
 500            (setq version-control t))
 501           ((or (string= vc "nil")
 502                (string= vc "existing"))
 503            (setq version-control nil))
 504           ((or (string= vc "never")
 505                (string= vc "simple"))
 506            (setq version-control 'never))))
 507
 508   (let ((ctype
 509          ;; Use the first of these three envvars that has a nonempty value.
 510          (or (let ((string (getenv "LC_ALL")))
 511                (and (not (equal string "")) string))
 512              (let ((string (getenv "LC_CTYPE")))
 513                (and (not (equal string "")) string))
 514              (let ((string (getenv "LANG")))
 515                (and (not (equal string "")) string)))))
 516     ;; Translate "swedish" into "sv_SE.ISO-8859-1", and so on,
 517     ;; using the translation file that GNU/Linux systems have.
 518     (and ctype
 519          locale-translation-file-name
 520          (not (string-match iso-8859-n-locale-regexp ctype))
 521          (with-temp-buffer
 522            (insert-file-contents locale-translation-file-name)
 523            (if (re-search-forward
 524                 (concat "^" (regexp-quote ctype) ":?[ \t]+") nil t)
 525                (setq ctype (buffer-substring (point)
 526                                              (progn (end-of-line) (point)))))))
 527     ;; Now see if the locale specifies an ISO 8859 character set.
 528     (when (and ctype
 529                (string-match iso-8859-n-locale-regexp ctype))
 530       (let (charset (which (match-string 1 ctype)))
 531         (if (equal "9" which)
 532             (setq which "5"))
 533         (setq charset (concat "latin-" which))
 534         (when (string-match "latin-[12345]" charset)
 535           ;; Set up for this character set.
 536           ;; This is now the right way to do it
 537           ;; for both unibyte and multibyte modes.
 538           (set-language-environment charset)
 539           (unless (or noninteractive (eq window-system 'x))
 540             ;; Send those codes literally to a non-X terminal.
 541             (when default-enable-multibyte-characters
 542               ;; If this is nil, we are using single-byte characters,
 543               ;; so the terminal coding system is irrelevant.
 544               (set-terminal-coding-system
 545                (intern (downcase charset)))))
 546           (standard-display-european-internal)))))
 547
 548   ;;! This has been commented out; I currently find the behavior when
 549   ;;! split-window-keep-point is nil disturbing, but if I can get used
 550   ;;! to it, then it would be better to eliminate the option.
 551   ;;! ;; Choose a good default value for split-window-keep-point.
 552   ;;! (setq split-window-keep-point (> baud-rate 2400))
 553
 554   ;; Read window system's init file if using a window system.
 555   (condition-case error
 556       (if (and window-system (not noninteractive))
 557           (load (concat term-file-prefix
 558                         (symbol-name window-system)
 559                         "-win")
 560                 ;; Every window system should have a startup file;
 561                 ;; barf if we can't find it.
 562                 nil t))
 563     ;; If we can't read it, print the error message and exit.
 564     (error
 565      (princ
 566       (if (eq (car error) 'error)
 567           (apply 'concat (cdr error))
 568         (if (memq 'file-error (get (car error) 'error-conditions))
 569             (format "%s: %s"
 570                      (nth 1 error)
 571                      (mapconcat '(lambda (obj) (prin1-to-string obj t))
 572                                 (cdr (cdr error)) ", "))
 573           (format "%s: %s"
 574                    (get (car error) 'error-message)
 575                    (mapconcat '(lambda (obj) (prin1-to-string obj t))
 576                               (cdr error) ", "))))
 577       'external-debugging-output)
 578      (setq window-system nil)
 579      (kill-emacs)))
 580
 581   (let ((done nil)
 582         (args (cdr command-line-args)))
 583
 584     ;; Figure out which user's init file to load,
 585     ;; either from the environment or from the options.
 586     (setq init-file-user (if noninteractive nil (user-login-name)))
 587     ;; If user has not done su, use current $HOME to find .emacs.
 588     (and init-file-user (string= init-file-user (user-real-login-name))
 589          (setq init-file-user ""))
 590
 591     ;; Process the command-line args, and delete the arguments
 592     ;; processed.  This is consistent with the way main in emacs.c
 593     ;; does things.
 594     (while (and (not done) args)
 595       (let ((longopts '(("--no-init-file") ("--no-site-file") ("--user")
 596                         ("--debug-init") ("--iconic") ("--icon-type")))
 597             (argi (car args))
 598             (argval nil))
 599         ;; Handle --OPTION=VALUE format.
 600         (if (and (string-match "\\`--" argi)
 601                  (string-match "=" argi))
 602             (setq argval (substring argi (match-end 0))
 603                   argi (substring argi 0 (match-beginning 0))))
 604         (or (equal argi "--")
 605             (let ((completion (try-completion argi longopts)))
 606               (if (eq completion t)
 607                   (setq argi (substring argi 1))
 608                 (if (stringp completion)
 609                     (let ((elt (assoc completion longopts)))
 610                       (or elt
 611                           (error "Option `%s' is ambiguous" argi))
 612                       (setq argi (substring (car elt) 1)))
 613                   (setq argval nil)))))
 614         (cond
 615          ((or (string-equal argi "-q")
 616               (string-equal argi "-no-init-file"))
 617           (setq init-file-user nil
 618                 args (cdr args)))
 619          ((or (string-equal argi "-u")
 620               (string-equal argi "-user"))
 621           (or argval
 622               (setq args (cdr args)
 623                     argval (car args)))
 624           (setq init-file-user argval
 625                 argval nil
 626                 args (cdr args)))
 627          ((string-equal argi "-no-site-file")
 628           (setq site-run-file nil
 629                 args (cdr args)))
 630          ((string-equal argi "-debug-init")
 631           (setq init-file-debug t
 632                 args (cdr args)))
 633          ((string-equal argi "-iconic")
 634           (setq initial-frame-alist
 635                 (cons '(visibility . icon) initial-frame-alist))
 636           (setq args (cdr args)))
 637          ((or (string-equal argi "-icon-type")
 638               (string-equal argi "-i")
 639               (string-equal argi "-itype"))
 640           (setq default-frame-alist
 641                 (cons '(icon-type . t) default-frame-alist))
 642           (setq args (cdr args)))
 643          (t (setq done t)))
 644         ;; Was argval set but not used?
 645         (and argval
 646              (error "Option `%s' doesn't allow an argument" argi))))
 647
 648     ;; Re-attach the program name to the front of the arg list.
 649     (and command-line-args (setcdr command-line-args args)))
 650
 651   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 652   (if (fboundp 'frame-initialize)
 653       (frame-initialize))
 654   ;; If frame was created with a menu bar, set menu-bar-mode on.
 655   (if (or (not (memq window-system '(x w32)))
 656           (> (cdr (assq 'menu-bar-lines (frame-parameters))) 0))
 657       (menu-bar-mode t))
 658
 659   (run-hooks 'before-init-hook)
 660
 661   ;; Run the site-start library if it exists.  The point of this file is
 662   ;; that it is run before .emacs.  There is no point in doing this after
 663   ;; .emacs; that is useless.
 664   (if site-run-file
 665       (load site-run-file t t))
 666
 667   ;; Register available input methods by loading LEIM list file.
 668   (load "leim-list.el" 'noerror 'nomessage 'nosuffix)
 669
 670   ;; Sites should not disable this.  Only individuals should disable
 671   ;; the startup message.
 672   (setq inhibit-startup-message nil)
 673
 674   ;; Load that user's init file, or the default one, or none.
 675   (let (debug-on-error-from-init-file
 676         debug-on-error-should-be-set
 677         (debug-on-error-initial
 678          (if (eq init-file-debug t) 'startup init-file-debug))
 679         (orig-enable-multibyte default-enable-multibyte-characters))
 680     (let ((debug-on-error debug-on-error-initial)
 681           ;; This function actually reads the init files.
 682           (inner
 683            (function
 684             (lambda ()
 685               (if init-file-user
 686                   (progn
 687                     (setq user-init-file
 688                           (cond
 689                            ((eq system-type 'ms-dos)
 690                             (concat "~" init-file-user "/_emacs"))
 691                            ((eq system-type 'windows-nt)
 692                             (if (directory-files "~" nil "^\.emacs\\(\.elc?\\)?$")
 693                                 "~/.emacs"
 694                               "~/_emacs"))
 695                            ((eq system-type 'vax-vms)
 696                             "sys$login:.emacs")
 697                            (t
 698                             (concat "~" init-file-user "/.emacs"))))
 699                     (load user-init-file t t)
 700                     (or inhibit-default-init
 701                         (let ((inhibit-startup-message nil))
 702                           ;; Users are supposed to be told their rights.
 703                           ;; (Plus how to get help and how to undo.)
 704                           ;; Don't you dare turn this off for anyone
 705                           ;; except yourself.
 706                           (load "default" t t)))))))))
 707       (if init-file-debug
 708           ;; Do this without a condition-case if the user wants to debug.
 709           (funcall inner)
 710         (condition-case error
 711             (progn
 712               (funcall inner)
 713               (setq init-file-had-error nil))
 714           (error (message "Error in init file: %s%s%s"
 715                           (get (car error) 'error-message)
 716                           (if (cdr error) ": " "")
 717                           (mapconcat 'prin1-to-string (cdr error) ", "))
 718                  (setq init-file-had-error t))))
 719       ;; If we can tell that the init file altered debug-on-error,
 720       ;; arrange to preserve the value that it set up.
 721       (or (eq debug-on-error debug-on-error-initial)
 722           (setq debug-on-error-should-be-set t
 723                 debug-on-error-from-init-file debug-on-error)))
 724     (if debug-on-error-should-be-set
 725         (setq debug-on-error debug-on-error-from-init-file))
 726     (unless (or default-enable-multibyte-characters
 727                 (eq orig-enable-multibyte default-enable-multibyte-characters))
 728       ;; Init file changed to unibyte.  Reset existing multibyte
 729       ;; buffers (probably *scratch*, *Messages*, *Minibuff-0*).
 730       ;; Arguably this should only be done if they're free of
 731       ;; multibyte characters.
 732       (mapcar (lambda (buffer)
 733                 (with-current-buffer buffer
 734                   (if enable-multibyte-characters
 735                       (set-buffer-multibyte nil))))
 736               (buffer-list))
 737       ;; Also re-set the language environment in case it was
 738       ;; originally done before unibyte was set and is sensitive to
 739       ;; unibyte (display table, terminal coding system &c).
 740       (set-language-environment current-language-environment)))
 741
 742   ;; Do this here in case the init file sets mail-host-address.
 743   (or user-mail-address
 744       (setq user-mail-address (concat (user-login-name) "@"
 745                                       (or mail-host-address
 746                                           (system-name)))))
 747
 748   (run-hooks 'after-init-hook)
 749
 750   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 751   (if (get-buffer "*scratch*")
 752       (save-excursion
 753         (set-buffer "*scratch*")
 754         (if (eq major-mode 'fundamental-mode)
 755             (funcall initial-major-mode))))
 756   ;; Load library for our terminal type.
 757   ;; User init file can set term-file-prefix to nil to prevent this.
 758   (and term-file-prefix (not noninteractive) (not window-system)
 759        (let ((term (getenv "TERM"))
 760              hyphend)
 761          (while (and term
 762                      (not (load (concat term-file-prefix term) t t)))
 763            ;; Strip off last hyphen and what follows, then try again
 764            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 765                (setq term (substring term 0 hyphend))
 766              (setq term nil)))))
 767
 768   ;; Process the remaining args.
 769   (command-line-1 (cdr command-line-args))
 770
 771   ;; If -batch, terminate after processing the command options.
 772   (if noninteractive (kill-emacs t)))
 773
 774 (defcustom initial-scratch-message "\
 775 This buffer is for notes you don't want to save, and for Lisp evaluation.
 776 If you want to create a file, visit that file with C-x C-f,
 777 then enter the text in that file's own buffer.
 778
 779 "
 780   "Initial message displayed in *scratch* buffer at startup.
 781 If this is nil, no message will be displayed."
 782   :type 'string)
 783
 784 (defun command-line-1 (command-line-args-left)
 785   (or noninteractive (input-pending-p) init-file-had-error
 786       (and inhibit-startup-echo-area-message
 787            user-init-file
 788            (or (and (get 'inhibit-startup-echo-area-message 'saved-value)
 789                     (equal inhibit-startup-echo-area-message
 790                            (if (string= init-file-user "")
 791                                (user-login-name)
 792                              init-file-user)))
 793                ;; Wasn't set with custom; see if .emacs has a setq.
 794                (let ((buffer (get-buffer-create " *temp*")))
 795                  (prog1
 796                      (condition-case nil
 797                          (save-excursion
 798                            (set-buffer buffer)
 799                            (insert-file-contents user-init-file)
 800                            (re-search-forward
 801                             (concat
 802                              "([ \t\n]*setq[ \t\n]+"
 803                              "inhibit-startup-echo-area-message[ \t\n]+"
 804                              (regexp-quote
 805                               (prin1-to-string
 806                                (if (string= init-file-user "")
 807                                    (user-login-name)
 808                                  init-file-user)))
 809                              "[ \t\n]*)")
 810                             nil t))
 811                        (error nil))
 812                    (kill-buffer buffer)))))
 813       (message (if (eq (key-binding "\C-h\C-p") 'describe-project)
 814                    "For information about the GNU Project and its goals, type C-h C-p."
 815                  (substitute-command-keys
 816                   "For information about the GNU Project and its goals, type \\[describe-project]."))))
 817   (if (null command-line-args-left)
 818       (cond ((and (not inhibit-startup-message) (not noninteractive)
 819                   ;; Don't clobber a non-scratch buffer if init file
 820                   ;; has selected it.
 821                   (string= (buffer-name) "*scratch*"))
 822              ;; If there are no switches to process, we might as well
 823              ;; run this hook now, and there may be some need to do it
 824              ;; before doing any output.
 825              (and term-setup-hook
 826                   (run-hooks 'term-setup-hook))
 827              ;; Don't let the hook be run twice.
 828              (setq term-setup-hook nil)
 829
 830              ;; It's important to notice the user settings before we
 831              ;; display the startup message; otherwise, the settings
 832              ;; won't take effect until the user gives the first
 833              ;; keystroke, and that's distracting.
 834              (if (fboundp 'frame-notice-user-settings)
 835                  (frame-notice-user-settings))
 836
 837              (and window-setup-hook
 838                   (run-hooks 'window-setup-hook))
 839              (setq window-setup-hook nil)
 840              ;; Do this now to avoid an annoying delay if the user
 841              ;; clicks the menu bar during the sit-for.
 842              (if (memq window-system '(x w32))
 843                  (precompute-menubar-bindings))
 844              (setq menubar-bindings-done t)
 845              (when (= (buffer-size) 0)
 846                (let ((buffer-undo-list t))
 847                  (unwind-protect
 848                      (when (not (input-pending-p))
 849                        (goto-char (point-max))
 850                        ;; The convention for this piece of code is that
 851                        ;; each piece of output starts with one or two newlines
 852                        ;; and does not end with any newlines.
 853                        (insert "Welcome to GNU Emacs")
 854                        (if (eq system-type 'gnu/linux)
 855                            (insert ", one component of a Linux-based GNU system."))
 856                        (insert "\n")
 857                        (if (assq 'display (frame-parameters))
 858                            (progn
 859                              (insert "\
 860 The menu bar and scroll bar are sufficient for basic editing with the mouse.
 861
 862 Useful Files menu items:
 863 Exit Emacs              (or type Control-x followed by Control-c)
 864 Recover Session         recover files you were editing before a crash
 865
 866 Important Help menu items:
 867 Emacs Tutorial          Learn-by-doing tutorial for using Emacs efficiently.
 868 \(Non)Warranty          GNU Emacs comes with ABSOLUTELY NO WARRANTY
 869 Copying Conditions      Conditions for redistributing and changing Emacs.
 870 Getting New Versions    How to obtain the latest version of Emacs.
 871 ")
 872                              (insert "\n\n" (emacs-version)
 873                                      "
 874 Copyright (C) 1998 Free Software Foundation, Inc."))
 875                          ;; If keys have their default meanings,
 876                          ;; use precomputed string to save lots of time.
 877                          (if (and (eq (key-binding "\C-h") 'help-command)
 878                                   (eq (key-binding "\C-xu") 'advertised-undo)
 879                                   (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
 880                                   (eq (key-binding "\C-ht") 'help-with-tutorial)
 881                                   (eq (key-binding "\C-hi") 'info)
 882                                   (eq (key-binding "\C-h\C-n") 'view-emacs-news))
 883                              (insert "
 884 Get help           C-h  (Hold down CTRL and press h)
 885 Undo changes       C-x u       Exit Emacs               C-x C-c
 886 Get a tutorial     C-h t       Use Info to read docs    C-h i")
 887                            (insert (substitute-command-keys
 888                                     (format "\n
 889 Get help           %s
 890 Undo changes       \\[advertised-undo]
 891 Exit Emacs         \\[save-buffers-kill-emacs]
 892 Get a tutorial     \\[help-with-tutorial]
 893 Use Info to read docs   \\[info]"
 894                                             (let ((where (where-is-internal
 895                                                           'help-command nil t)))
 896                                               (if where
 897                                                   (key-description where)
 898                                                 "M-x help"))))))
 899                          ;; Say how to use the menu bar
 900                          ;; if that is not with the mouse.
 901                          (if (and (eq (key-binding "\M-`") 'tmm-menubar)
 902                                   (eq (key-binding [f10]) 'tmm-menubar))
 903                              (insert "
 904 Activate menubar   F10  or  ESC `  or   M-`")
 905                            (insert (substitute-command-keys "
 906 Activate menubar     \\[tmm-menubar]")))
 907
 908                        ;; Windows and MSDOS (currently) do not count as
 909                        ;; window systems, but do have mouse support.
 910                          (if window-system
 911                              (insert "
 912 Mode-specific menu   C-mouse-3 (third button, with CTRL)"))
 913                          ;; Many users seem to have problems with these.
 914                          (insert "
 915 \(`C-' means use the CTRL key.  `M-' means use the Meta (or Alt) key.
 916 If you have no Meta key, you may instead type ESC followed by the character.)")
 917                          (and auto-save-list-file-prefix
 918                               (directory-files
 919                                (file-name-directory auto-save-list-file-prefix)
 920                                nil
 921                                (concat "\\`"
 922                                        (regexp-quote (file-name-nondirectory
 923                                                       auto-save-list-file-prefix)))
 924                                t)
 925                               (insert "\n\nIf an Emacs session crashed recently, "
 926                                       "type M-x recover-session RET\nto recover"
 927                                       " the files you were editing."))
 928
 929                          (insert "\n\n" (emacs-version)
 930                                  "
 931 Copyright (C) 1998 Free Software Foundation, Inc.")
 932                          (if (and (eq (key-binding "\C-h\C-c") 'describe-copying)
 933                                   (eq (key-binding "\C-h\C-d") 'describe-distribution)
 934                                   (eq (key-binding "\C-h\C-w") 'describe-no-warranty))
 935                              (insert
 936                               "\n
 937 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
 938 You may give out copies of Emacs; type C-h C-c to see the conditions.
 939 Type C-h C-d for information on getting the latest version.")
 940                            (insert (substitute-command-keys
 941                                     "\n
 942 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
 943 You may give out copies of Emacs; type \\[describe-copying] to see the conditions.
 944 Type \\[describe-distribution] for information on getting the latest version."))))
 945                        (goto-char (point-min))
 946
 947                        (set-buffer-modified-p nil)
 948                        (sit-for 120))
 949                    (with-current-buffer (get-buffer "*scratch*")
 950                      (erase-buffer)
 951                      (and initial-scratch-message
 952                           (insert initial-scratch-message))
 953                      (set-buffer-modified-p nil)))))))
 954     ;; Delay 2 seconds after the init file error message
 955     ;; was displayed, so user can read it.
 956     (if init-file-had-error
 957         (sit-for 2))
 958     (let ((dir command-line-default-directory)
 959           (file-count 0)
 960           first-file-buffer
 961           tem
 962           just-files  ;; t if this follows the magic -- option.
 963           ;; This includes our standard options' long versions
 964           ;; and long versions of what's on command-switch-alist.
 965           (longopts
 966            (append '(("--funcall") ("--load") ("--insert") ("--kill")
 967                      ("--directory") ("--eval") ("--find-file") ("--visit"))
 968                    (mapcar '(lambda (elt)
 969                               (list (concat "-" (car elt))))
 970                            command-switch-alist)))
 971           (line 0))
 972
 973       ;; Add the long X options to longopts.
 974       (setq tem command-line-x-option-alist)
 975       (while tem
 976         (if (string-match "^--" (car (car tem)))
 977             (setq longopts (cons (list (car (car tem))) longopts)))
 978         (setq tem (cdr tem)))
 979
 980       ;; Loop, processing options.
 981       (while (and command-line-args-left)
 982         (let* ((argi (car command-line-args-left))
 983                (orig-argi argi)
 984                argval completion
 985                ;; List of directories specified in -L/--directory,
 986                ;; in reverse of the order specified.
 987                extra-load-path
 988                (initial-load-path load-path))
 989           (setq command-line-args-left (cdr command-line-args-left))
 990
 991           ;; Do preliminary decoding of the option.
 992           (if just-files
 993               ;; After --, don't look for options; treat all args as files.
 994               (setq argi "")
 995             ;; Convert long options to ordinary options
 996             ;; and separate out an attached option argument into argval.
 997             (if (string-match "^--[^=]*=" argi)
 998                 (setq argval (substring argi (match-end 0))
 999                       argi (substring argi 0 (1- (match-end 0)))))
1000             (if (equal argi "--")
1001                 (setq completion nil)
1002               (setq completion (try-completion argi longopts)))
1003             (if (eq completion t)
1004                 (setq argi (substring argi 1))
1005               (if (stringp completion)
1006                   (let ((elt (assoc completion longopts)))
1007                     (or elt
1008                         (error "Option `%s' is ambiguous" argi))
1009                     (setq argi (substring (car elt) 1)))
1010                 (setq argval nil argi orig-argi))))
1011
1012           ;; Execute the option.
1013           (cond ((setq tem (assoc argi command-switch-alist))
1014                  (if argval
1015                      (let ((command-line-args-left
1016                             (cons argval command-line-args-left)))
1017                        (funcall (cdr tem) argi))
1018                    (funcall (cdr tem) argi)))
1019                 ((or (string-equal argi "-f")  ;what the manual claims
1020                      (string-equal argi "-funcall")
1021                      (string-equal argi "-e")) ; what the source used to say
1022                  (if argval
1023                      (setq tem (intern argval))
1024                    (setq tem (intern (car command-line-args-left)))
1025                    (setq command-line-args-left (cdr command-line-args-left)))
1026                  (if (arrayp (symbol-function tem))
1027                      (command-execute tem)
1028                    (funcall tem)))
1029                 ((string-equal argi "-eval")
1030                  (if argval
1031                      (setq tem argval)
1032                    (setq tem (car command-line-args-left))
1033                    (setq command-line-args-left (cdr command-line-args-left)))
1034                  (eval (read tem)))
1035                 ;; Set the default directory as specified in -L.
1036                 ((or (string-equal argi "-L")
1037                      (string-equal argi "-directory"))
1038                  (if argval
1039                      (setq tem argval)
1040                    (setq tem (car command-line-args-left)
1041                          command-line-args-left (cdr command-line-args-left)))
1042                  (setq tem (command-line-normalize-file-name tem))
1043                  (setq extra-load-path
1044                        (cons (expand-file-name tem) extra-load-path))
1045                  (setq load-path (append (nreverse extra-load-path)
1046                                          initial-load-path)))
1047                 ((or (string-equal argi "-l")
1048                      (string-equal argi "-load"))
1049                  (if argval
1050                      (setq tem argval)
1051                    (setq tem (car command-line-args-left)
1052                          command-line-args-left (cdr command-line-args-left)))
1053                  (let ((file (command-line-normalize-file-name tem)))
1054                    ;; Take file from default dir if it exists there;
1055                    ;; otherwise let `load' search for it.
1056                    (if (file-exists-p (expand-file-name file))
1057                        (setq file (expand-file-name file)))
1058                    (load file nil t)))
1059                 ((string-equal argi "-insert")
1060                  (if argval
1061                      (setq tem argval)
1062                    (setq tem (car command-line-args-left)
1063                          command-line-args-left (cdr command-line-args-left)))
1064                  (or (stringp tem)
1065                      (error "File name omitted from `-insert' option"))
1066                  (insert-file-contents (command-line-normalize-file-name tem)))
1067                 ((string-equal argi "-kill")
1068                  (kill-emacs t))
1069                 ((string-match "^\\+[0-9]+\\'" argi)
1070                  (setq line (string-to-int argi)))
1071                 ((setq tem (assoc argi command-line-x-option-alist))
1072                  ;; Ignore X-windows options and their args if not using X.
1073                  (setq command-line-args-left
1074                        (nthcdr (nth 1 tem) command-line-args-left)))
1075                 ((or (string-equal argi "-find-file")
1076                      (string-equal argi "-visit"))
1077                  ;; An explicit option to specify visiting a file.
1078                  (setq file-count (1+ file-count))
1079                  (let ((file
1080                         (expand-file-name
1081                          (command-line-normalize-file-name orig-argi)
1082                          dir)))
1083                    (if (= file-count 1)
1084                        (setq first-file-buffer (find-file file))
1085                      (find-file-other-window file)))
1086                  (or (zerop line)
1087                      (goto-line line))
1088                  (setq line 0))
1089                 ((equal argi "--")
1090                  (setq just-files t))
1091                 (t
1092                  ;; We have almost exhausted our options. See if the
1093                  ;; user has made any other command-line options available
1094                  (let ((hooks command-line-functions);; lrs 7/31/89
1095                        (did-hook nil))
1096                    (while (and hooks
1097                                (not (setq did-hook (funcall (car hooks)))))
1098                      (setq hooks (cdr hooks)))
1099                    (if (not did-hook)
1100                        ;; Ok, presume that the argument is a file name
1101                        (progn
1102                          (if (string-match "\\`-" argi)
1103                              (error "Unknown option `%s'" argi))
1104                          (setq file-count (1+ file-count))
1105                          (let ((file
1106                                 (expand-file-name
1107                                  (command-line-normalize-file-name orig-argi)
1108                                  dir)))
1109                            (if (= file-count 1)
1110                                (setq first-file-buffer (find-file file))
1111                              (find-file-other-window file)))
1112                          (or (zerop line)
1113                              (goto-line line))
1114                          (setq line 0))))))))
1115       ;; If 3 or more files visited, and not all visible,
1116       ;; show user what they all are.
1117       (and (> file-count 2)
1118            (not noninteractive)
1119            (or (get-buffer-window first-file-buffer)
1120                (progn (other-window 1)
1121                       (buffer-menu)))))))
1122
1123 (defun command-line-normalize-file-name (file)
1124   "Collapse multiple slashes to one, to handle non-Emacs file names."
1125   (save-match-data
1126     ;; Use arg 1 so that we don't collapse // at the start of the file name.
1127     ;; That is significant on some systems.
1128     ;; However, /// at the beginning is supposed to mean just /, not //.
1129     (if (string-match "^///+" file)
1130         (setq file (replace-match "/" t t file)))
1131     (while (string-match "//+" file 1)
1132       (setq file (replace-match "/" t t file)))
1133     file))
1134
1135 ;;; startup.el ends here