code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158
 159 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 160 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 161 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 162
 163 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 164 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 165 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 166 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 167
 168 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 169 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 170 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 171 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH([gnustep-conf],dnl
 204 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 205 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 206   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 207 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 208      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 209
 210 AC_ARG_ENABLE(ns-self-contained,
 211 [AS_HELP_STRING([--disable-ns-self-contained],
 212                 [disable self contained build under NeXTstep])],
 213    EN_NS_SELF_CONTAINED=$enableval,
 214    EN_NS_SELF_CONTAINED=yes)
 215
 216 AC_ARG_ENABLE(asserts,
 217 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 218       USE_XASSERTS=$enableval,
 219       USE_XASSERTS=no)
 220
 221 AC_ARG_ENABLE(maintainer-mode,
 222 [AS_HELP_STRING([--enable-maintainer-mode],
 223                 [enable make rules and dependencies not useful (and sometimes
 224                  confusing) to the casual installer])],
 225       USE_MAINTAINER_MODE=$enableval,
 226       USE_MAINTAINER_MODE=no)
 227 if test $USE_MAINTAINER_MODE = yes; then
 228   MAINT=
 229 else
 230   MAINT=#
 231 fi
 232 AC_SUBST(MAINT)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;;
 264         all)            ac_enable_checking=1 ;
 265                         ac_gc_check_stringbytes=1 ;
 266                         ac_gc_check_string_overrun=1 ;
 267                         ac_gc_check_string_free_list=1 ;
 268                         ac_xmalloc_overrun=1 ;
 269                         ac_gc_check_cons_list=1 ;;
 270         # these enable particular checks
 271         stringbytes)    ac_gc_check_stringbytes=1 ;;
 272         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 273         stringfreelist) ac_gc_check_string_free_list=1 ;;
 274         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 275         conslist)       ac_gc_check_cons_list=1 ;;
 276         *)      AC_MSG_ERROR(unknown check category $check) ;;
 277         esac
 278 done
 279 IFS="$ac_save_IFS"
 280
 281 if test x$ac_enable_checking != x ; then
 282   AC_DEFINE(ENABLE_CHECKING, 1,
 283 [Enable expensive run-time checking of data types?])
 284 fi
 285 if test x$ac_gc_check_stringbytes != x ; then
 286   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 287 [Define this temporarily to hunt a bug.  If defined, the size of
 288    strings is redundantly recorded in sdata structures so that it can
 289    be compared to the sizes recorded in Lisp strings.])
 290 fi
 291 if test x$ac_gc_check_stringoverrun != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 293 [Define this to check for short string overrun.])
 294 fi
 295 if test x$ac_gc_check_string_free_list != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 297 [Define this to check the string free list.])
 298 fi
 299 if test x$ac_xmalloc_overrun != x ; then
 300   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 301 [Define this to check for malloc buffer overrun.])
 302 fi
 303 if test x$ac_gc_check_cons_list != x ; then
 304   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 305 [Define this to check for errors in cons list.])
 306 fi
 307
 308 AC_ARG_ENABLE(use-lisp-union-type,
 309 [AS_HELP_STRING([--enable-use-lisp-union-type],
 310                 [use a union for the Lisp_Object data type.
 311                 This is only useful for development for catching certain types of bugs.])],
 312 if test "${enableval}" != "no"; then
 313    AC_DEFINE(USE_LISP_UNION_TYPE, 1,
 314    [Define this to use a lisp union for the Lisp_Object data type.])
 315 fi)
 316
 317
 318 AC_ARG_ENABLE(profiling,
 319 [AS_HELP_STRING([--enable-profiling],
 320                 [build emacs with profiling support.
 321                  This might not work on all platforms])],
 322 [ac_enable_profiling="${enableval}"],[])
 323 if test x$ac_enable_profiling != x ; then
 324    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 325    PROFILING_LDFLAGS="-pg"
 326 else
 327    PROFILING_CFLAGS=
 328    PROFILING_LDFLAGS=
 329 fi
 330
 331 AC_ARG_ENABLE(autodepend,
 332 [AS_HELP_STRING([--enable-autodepend],
 333                 [automatically generate dependencies to .h-files.
 334                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 335                  found])],
 336 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 337
 338 #### Make srcdir absolute, if it isn't already.  It's important to
 339 #### avoid running the path through pwd unnecessarily, since pwd can
 340 #### give you automounter prefixes, which can go away.  We do all this
 341 #### so Emacs can find its files when run uninstalled.
 342 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 343 unset CDPATH
 344 case "${srcdir}" in
 345   /* ) ;;
 346   . )
 347     ## We may be able to use the $PWD environment variable to make this
 348     ## absolute.  But sometimes PWD is inaccurate.
 349     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 350     ## but that tested only for a well-formed and valid PWD,
 351     ## it did not object when PWD was well-formed and valid but just wrong.
 352     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 353     then
 354       srcdir="$PWD"
 355     else
 356       srcdir="`(cd ${srcdir}; pwd)`"
 357     fi
 358   ;;
 359   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 360 esac
 361
 362 #### Check if the source directory already has a configured system in it.
 363 if test `pwd` != `(cd ${srcdir} && pwd)` \
 364    && test -f "${srcdir}/src/config.h" ; then
 365   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 366    as a build directory right now; it has been configured in its own
 367    right.  To configure in another directory as well, you MUST
 368    use GNU make.  If you do not have GNU make, then you must
 369    now do `make distclean' in ${srcdir},
 370    and then run $0 again.]])
 371 fi
 372
 373 #### Given the configuration name, set machfile and opsysfile to the
 374 #### names of the m/*.h and s/*.h files we should use.
 375
 376 ### Canonicalize the configuration name.
 377
 378 AC_CANONICAL_HOST
 379 canonical=$host
 380 configuration=${host_alias-${build_alias-$host}}
 381
 382 dnl This used to use changequote, but, apart from `changequote is evil'
 383 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 384 dnl the great gob of text.  Thus it's not processed for possible expansion.
 385 dnl Just make sure the brackets remain balanced.
 386 dnl
 387 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 388 dnl indicated by comments.
 389 dnl quotation begins
 390 [
 391
 392 ### If you add support for a new configuration, add code to this
 393 ### switch statement to recognize your configuration name and select
 394 ### the appropriate operating system and machine description files.
 395
 396 ### You would hope that you could choose an m/*.h file pretty much
 397 ### based on the machine portion of the configuration name, and an s/*.h
 398 ### file based on the operating system portion.  However, it turns out
 399 ### that each m/*.h file is pretty manufacturer-specific - for
 400 ### example mips.h is MIPS
 401 ### So we basically have to have a special case for each
 402 ### configuration name.
 403 ###
 404 ### As far as handling version numbers on operating systems is
 405 ### concerned, make sure things will fail in a fixable way.  If
 406 ### /etc/MACHINES doesn't say anything about version numbers, be
 407 ### prepared to handle anything reasonably.  If version numbers
 408 ### matter, be sure /etc/MACHINES says something about it.
 409
 410 machine='' opsys='' unported=no
 411 case "${canonical}" in
 412
 413   ## FreeBSD ports
 414   *-*-freebsd* )
 415     opsys=freebsd
 416     case "${canonical}" in
 417       alpha*)           machine=alpha ;;
 418       amd64-*|x86_64-*) machine=amdx86-64 ;;
 419       arm*)             machine=arm ;;
 420       ia64-*)           machine=ia64 ;;
 421       i[3456]86-*)      machine=intel386 ;;
 422       powerpc-*)        machine=macppc ;;
 423       sparc-*)          machine=sparc ;;
 424       sparc64-*)        machine=sparc ;;
 425     esac
 426   ;;
 427
 428   ## FreeBSD kernel + glibc based userland
 429   *-*-kfreebsd*gnu* )
 430     opsys=gnu-kfreebsd
 431     case "${canonical}" in
 432       alpha*)           machine=alpha ;;
 433       amd64-*|x86_64-*) machine=amdx86-64 ;;
 434       ia64-*)           machine=ia64 ;;
 435       i[3456]86-*)      machine=intel386 ;;
 436       powerpc-*)        machine=macppc ;;
 437       sparc-*)          machine=sparc ;;
 438       sparc64-*)        machine=sparc ;;
 439     esac
 440   ;;
 441
 442   ## NetBSD ports
 443   *-*-netbsd* )
 444     opsys=netbsd
 445     case "${canonical}" in
 446       alpha*)      machine=alpha ;;
 447       x86_64-*)    machine=amdx86-64 ;;
 448       arm-*)       machine=arm ;;
 449       hppa-*)      machine=hp800 ;;
 450       i[3456]86-*) machine=intel386 ;;
 451       m68k-*)      machine=m68k ;;
 452       powerpc-*)   machine=macppc ;;
 453       mips-*)      machine=mips ;;
 454       mipse[bl]-*) machine=mips ;;
 455       sparc*-)     machine=sparc ;;
 456       vax-*)       machine=vax ;;
 457     esac
 458   ;;
 459
 460   ## OpenBSD ports
 461   *-*-openbsd* )
 462     opsys=openbsd
 463     case "${canonical}" in
 464       alpha*)    machine=alpha ;;
 465       x86_64-*)  machine=amdx86-64 ;;
 466       arm-*)     machine=arm ;;
 467       hppa-*)    machine=hp800 ;;
 468       i386-*)    machine=intel386 ;;
 469       powerpc-*) machine=macppc ;;
 470       sparc*)    machine=sparc ;;
 471       vax-*)     machine=vax ;;
 472     esac
 473   ;;
 474
 475   alpha*-*-linux-gnu* )
 476     machine=alpha opsys=gnu-linux
 477   ;;
 478
 479   arm*-*-linux-gnu* )
 480     machine=arm opsys=gnu-linux
 481   ;;
 482
 483   ## Apple Darwin / Mac OS X
 484   *-apple-darwin* )
 485     case "${canonical}" in
 486       i[3456]86-* )  machine=intel386 ;;
 487       powerpc-* )    machine=macppc ;;
 488       x86_64-* )     machine=amdx86-64 ;;
 489       * )            unported=yes ;;
 490     esac
 491     opsys=darwin
 492     # Define CPP as follows to make autoconf work correctly.
 493     CPP="${CC-cc} -E -no-cpp-precomp"
 494     # Use fink packages if available.
 495     if test -d /sw/include && test -d /sw/lib; then
 496       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 497       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 498       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 499     fi
 500   ;;
 501
 502   ## HP 9000 series 700 and 800, running HP/UX
 503   hppa*-hp-hpux10.2* )
 504     machine=hp800 opsys=hpux10-20
 505   ;;
 506   hppa*-hp-hpux1[1-9]* )
 507     machine=hp800 opsys=hpux11
 508     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 509   ;;
 510
 511   hppa*-*-linux-gnu* )
 512     machine=hp800 opsys=gnu-linux
 513   ;;
 514
 515   ## IBM machines
 516   s390-*-linux-gnu* )
 517     machine=ibms390 opsys=gnu-linux
 518   ;;
 519   s390x-*-linux-gnu* )
 520     machine=ibms390x opsys=gnu-linux
 521   ;;
 522   rs6000-ibm-aix4.[23]* )
 523     machine=ibmrs6000 opsys=aix4-2
 524   ;;
 525   powerpc-ibm-aix4.[23]*  )
 526     machine=ibmrs6000 opsys=aix4-2
 527   ;;
 528   rs6000-ibm-aix[56]* )
 529     machine=ibmrs6000 opsys=aix4-2
 530   ;;
 531   powerpc-ibm-aix[56]*  )
 532     machine=ibmrs6000 opsys=aix4-2
 533   ;;
 534
 535   ## Macintosh PowerPC
 536   powerpc*-*-linux-gnu* )
 537     machine=macppc opsys=gnu-linux
 538   ;;
 539
 540   ## Silicon Graphics machines
 541   ## Iris 4D
 542   mips-sgi-irix6.5 )
 543     machine=iris4d opsys=irix6-5
 544     # Without defining _LANGUAGE_C, things get masked out in the headers
 545     # so that, for instance, grepping for `free' in stdlib.h fails and
 546     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 547     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 548     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 549   ;;
 550
 551   ## Suns
 552   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 553     machine=sparc opsys=gnu-linux
 554   ;;
 555
 556   *-sun-solaris* \
 557     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 558     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 559     case "${canonical}" in
 560       i[3456]86-*-* )     machine=intel386 ;;
 561       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 562       sparc* )          machine=sparc ;;
 563       * )               unported=yes ;;
 564     esac
 565     case "${canonical}" in
 566       *-sunos5.6* | *-solaris2.6* )
 567                 opsys=sol2-6
 568                 NON_GNU_CPP=/usr/ccs/lib/cpp
 569                 RANLIB="ar -ts"
 570                 ;;
 571       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 572                 opsys=sol2-6
 573                 emacs_check_sunpro_c=yes
 574                 NON_GNU_CPP=/usr/ccs/lib/cpp
 575                 ;;
 576       *-sunos5* | *-solaris* )
 577                 opsys=sol2-10
 578                 emacs_check_sunpro_c=yes
 579                 NON_GNU_CPP=/usr/ccs/lib/cpp
 580                 ;;
 581     esac
 582     ## Watch out for a compiler that we know will not work.
 583     case "${canonical}" in
 584      *-solaris* | *-sunos5* )
 585                 if [ "x$CC" = x/usr/ucb/cc ]; then
 586                   ## /usr/ucb/cc doesn't work;
 587                   ## we should find some other compiler that does work.
 588                   unset CC
 589                 fi
 590                 ;;
 591       *) ;;
 592     esac
 593   ;;
 594
 595   ## IA-64
 596   ia64*-*-linux* )
 597     machine=ia64 opsys=gnu-linux
 598   ;;
 599
 600   ## Intel 386 machines where we don't care about the manufacturer.
 601   i[3456]86-*-* )
 602     machine=intel386
 603     case "${canonical}" in
 604       *-cygwin )                opsys=cygwin ;;
 605       *-darwin* )               opsys=darwin
 606                                 CPP="${CC-cc} -E -no-cpp-precomp"
 607                                 ;;
 608       *-linux-gnu* )            opsys=gnu-linux ;;
 609       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 610       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 611       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 612       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 613     esac
 614   ;;
 615
 616   ## m68k Linux-based GNU system
 617   m68k-*-linux-gnu* )
 618     machine=m68k opsys=gnu-linux
 619   ;;
 620
 621   ## Mips Linux-based GNU system
 622   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 623     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 624     machine=mips opsys=gnu-linux
 625   ;;
 626
 627   ## AMD x86-64 Linux-based GNU system
 628   x86_64-*-linux-gnu* )
 629     machine=amdx86-64 opsys=gnu-linux
 630   ;;
 631
 632   ## Tensilica Xtensa Linux-based GNU system
 633   xtensa*-*-linux-gnu* )
 634     machine=xtensa opsys=gnu-linux
 635     ;;
 636
 637   ## SuperH Linux-based GNU system
 638   sh[34]*-*-linux-gnu* )
 639     machine=sh3 opsys=gnu-linux
 640   ;;
 641
 642   * )
 643     unported=yes
 644   ;;
 645 esac
 646
 647 ### If the code above didn't choose an operating system, just choose
 648 ### an operating system based on the configuration name.  You really
 649 ### only want to use this when you have no idea what the right
 650 ### operating system is; if you know what operating systems a machine
 651 ### runs, it's cleaner to make it explicit in the case statement
 652 ### above.
 653 if test x"${opsys}" = x; then
 654   case "${canonical}" in
 655     *-gnu* )                            opsys=gnu ;;
 656     * )
 657       unported=yes
 658     ;;
 659   esac
 660 fi
 661
 662 ]
 663 dnl quotation ends
 664
 665 if test $unported = yes; then
 666   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 667 Check `etc/MACHINES' for recognized configuration names.])
 668 fi
 669
 670 machfile="m/${machine}.h"
 671 opsysfile="s/${opsys}.h"
 672
 673
 674 #### Choose a compiler.
 675 test -n "$CC" && cc_specified=yes
 676
 677 # Save the value of CFLAGS that the user specified.
 678 SPECIFIED_CFLAGS="$CFLAGS"
 679
 680 dnl Sets GCC=yes if using gcc.
 681 AC_PROG_CC
 682
 683 # On Suns, sometimes $CPP names a directory.
 684 if test -n "$CPP" && test -d "$CPP"; then
 685   CPP=
 686 fi
 687
 688 ## If not using gcc, and on Solaris, and no CPP specified, see if
 689 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 690 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 691  test x"$CPP" = x; then
 692   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 693   AC_CACHE_VAL(emacs_cv_sunpro_c,
 694   [AC_TRY_LINK([],
 695 [#ifndef __SUNPRO_C
 696 fail;
 697 #endif
 698 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 699   AC_MSG_RESULT($emacs_cv_sunpro_c)
 700
 701   if test x"$emacs_cv_sunpro_c" = xyes; then
 702     NON_GNU_CPP="$CC -E -Xs"
 703   fi
 704 fi
 705
 706 #### Some systems specify a CPP to use unless we are using GCC.
 707 #### Now that we know whether we are using GCC, we can decide whether
 708 #### to use that one.
 709 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 710 then
 711   CPP="$NON_GNU_CPP"
 712 fi
 713
 714 #### Some systems specify a CC to use unless we are using GCC.
 715 #### Now that we know whether we are using GCC, we can decide whether
 716 #### to use that one.
 717 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 718   test x$cc_specified != xyes
 719 then
 720   CC="$NON_GNU_CC"
 721 fi
 722
 723 if test x$GCC = xyes; then
 724   C_OPTIMIZE_SWITCH=-O2
 725   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 726 else
 727   C_OPTIMIZE_SWITCH=-O
 728   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 729 fi
 730
 731 dnl checks for Unix variants
 732 AC_USE_SYSTEM_EXTENSIONS
 733
 734 ### Use -Wno-pointer-sign if the compiler supports it
 735 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 736 SAVE_CFLAGS="$CFLAGS"
 737 CFLAGS="$CFLAGS -Wno-pointer-sign"
 738 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 739 if test $has_option = yes; then
 740    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 741 fi
 742 AC_MSG_RESULT($has_option)
 743 CFLAGS="$SAVE_CFLAGS"
 744 unset has_option
 745 unset SAVE_CFLAGS
 746
 747 ### Use -Wdeclaration-after-statement if the compiler supports it
 748 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 749 SAVE_CFLAGS="$CFLAGS"
 750 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 751 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 752 if test $has_option = yes; then
 753    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 754 fi
 755 AC_MSG_RESULT($has_option)
 756 CFLAGS="$SAVE_CFLAGS"
 757 unset has_option
 758 unset SAVE_CFLAGS
 759
 760 #### Some other nice autoconf tests.
 761
 762 dnl checks for programs
 763 AC_PROG_CPP
 764 AC_PROG_INSTALL
 765 if test "x$RANLIB" = x; then
 766   AC_PROG_RANLIB
 767 fi
 768
 769 ## Although we're running on an amd64 kernel, we're actually compiling for
 770 ## the x86 architecture.  The user should probably have provided an
 771 ## explicit --build to `configure', but if everything else than the kernel
 772 ## is running in i386 mode, we can help them out.
 773 if test "$machine" = "amdx86-64"; then
 774   AC_CHECK_DECL([i386])
 775   if test "$ac_cv_have_decl_i386" = "yes"; then
 776     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 777     machine=intel386
 778     machfile="m/${machine}.h"
 779   fi
 780 fi
 781
 782 AC_PATH_PROG(INSTALL_INFO, install-info)
 783 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 784 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 785 dnl Don't use GZIP, which is used by gzip for additional parameters.
 786 AC_PATH_PROG(GZIP_PROG, gzip)
 787
 788
 789 ## Need makeinfo >= 4.6 (?) to build the manuals.
 790 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 791 dnl By this stage, configure has already checked for egrep and set EGREP,
 792 dnl or exited with an error if no egrep was found.
 793 if test "$MAKEINFO" != "no" && \
 794   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 795    MAKEINFO=no
 796 fi
 797
 798 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 799 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 800 ## therefore in the category of "special tools" not normally required, which
 801 ## configure does not have to check for (eg autoconf itself).
 802 ## In a Bazaar checkout on the other hand, the manuals are not included.
 803 ## So makeinfo is a requirement to build from Bazaar, and configure
 804 ## should test for it as it does for any other build requirement.
 805 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 806 ## with pre-built manuals, from a Bazaar checkout.
 807 if test "$MAKEINFO" = "no"; then
 808   if test "x${with_makeinfo}" = "xno"; then
 809     MAKEINFO=off
 810   elif test ! -e $srcdir/info/emacs; then
 811     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 812 source tree does not seem to have pre-built manuals in the `info' directory.
 813 Either install a suitable version of makeinfo, or re-run configure
 814 with the `--without-makeinfo' option to build without the manuals.] )
 815   fi
 816 fi
 817
 818 dnl Add our options to ac_link now, after it is set up.
 819
 820 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 821 then
 822   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 823 fi
 824
 825 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 826 then
 827   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 828 fi
 829
 830 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 831 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 832 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 833 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 834 dnl if not built to support GNU ld.
 835
 836 late_LDFLAGS=$LDFLAGS
 837 if test "$GCC" = yes; then
 838   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 839 else
 840   LDFLAGS="$LDFLAGS -znocombreloc"
 841 fi
 842
 843 AC_MSG_CHECKING([for -znocombreloc])
 844 AC_LINK_IFELSE([main(){return 0;}],
 845   [AC_MSG_RESULT(yes)],
 846   LDFLAGS=$late_LDFLAGS
 847   [AC_MSG_RESULT(no)])
 848
 849 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 850
 851
 852 # The value of CPP is a quoted variable reference, so we need to do this
 853 # to get its actual value...
 854 CPP=`eval "echo $CPP"`
 855
 856
 857 ### First figure out CFLAGS (which we use for running the compiler here)
 858 ### and REAL_CFLAGS (which we use for real compilation).
 859 ### The two are the same except when using GCC where we might use
 860 ### extra warning and profiling flags.
 861
 862 ### If the CFLAGS env var is specified, we use that value
 863 ### instead of the default.
 864
 865 dnl Note AC_PROG_CC sets CFLAGS to -g -O2 for gcc anyway.
 866 if test "x$SPECIFIED_CFLAGS" = x; then
 867   CFLAGS="-g $C_OPTIMIZE_SWITCH"
 868   if test x$GCC = xyes; then
 869     REAL_CFLAGS="$CFLAGS $C_WARNINGS_SWITCH $PROFILING_CFLAGS"
 870   else
 871     REAL_CFLAGS="$CFLAGS"
 872   fi
 873 else
 874   REAL_CFLAGS="$CFLAGS"
 875 fi
 876
 877
 878 dnl Not used by any currently supported platform.
 879 dnl The function dump-emacs will not be defined and temacs will do
 880 dnl (load "loadup") automatically unless told otherwise.
 881 CANNOT_DUMP=no
 882 case "$opsys" in
 883   your-opsys-here)
 884    CANNOT_DUMP=yes
 885    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 886   ;;
 887 esac
 888 AC_SUBST(CANNOT_DUMP)
 889
 890
 891 UNEXEC_OBJ=unexelf.o
 892 case "$opsys" in
 893   # MSDOS uses unexec.o
 894   # MSWindows uses unexw32.o
 895   aix4-2)
 896    UNEXEC_OBJ=unexaix.o
 897    ;;
 898   cygwin)
 899    UNEXEC_OBJ=unexcw.o
 900    ;;
 901   darwin)
 902    UNEXEC_OBJ=unexmacosx.o
 903    ;;
 904   hpux10-20 | hpux11)
 905    UNEXEC_OBJ=unexhp9k800.o
 906    ;;
 907   sol2-10)
 908    # Use the Solaris dldump() function, called from unexsol.c, to dump
 909    # emacs, instead of the generic ELF dump code found in unexelf.c.
 910    # The resulting binary has a complete symbol table, and is better
 911    # for debugging and other observability tools (debuggers, pstack, etc).
 912    #
 913    # If you encounter a problem using dldump(), please consider sending
 914    # a message to the OpenSolaris tools-linking mailing list:
 915    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 916    #
 917    # It is likely that dldump() works with older Solaris too, but this has
 918    # not been tested, so for now this change is for Solaris 10 or newer.
 919    UNEXEC_OBJ=unexsol.o
 920    ;;
 921 esac
 922
 923 LD_SWITCH_SYSTEM=
 924 case "$opsys" in
 925   freebsd)
 926    ## Let `ld' find image libs and similar things in /usr/local/lib.
 927    ## The system compiler, GCC, has apparently been modified to not
 928    ## look there, contrary to what a stock GCC would do.
 929    LD_SWITCH_SYSTEM=-L/usr/local/lib
 930    ;;
 931
 932   gnu-linux)
 933    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 934    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 935    ;;
 936
 937   netbsd)
 938    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 939    ;;
 940
 941   openbsd)
 942    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 943    ## otherwise Emacs dumps core on elf systems.
 944    LD_SWITCH_SYSTEM="-Z"
 945    ;;
 946 esac
 947 AC_SUBST(LD_SWITCH_SYSTEM)
 948
 949 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 950
 951 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 952 ## which has not been defined yet.  When this was handled with cpp,
 953 ## it was expanded to null when configure sourced the s/*.h file.
 954 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 955 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 956 ## (or somesuch), but because it is supposed to go at the _front_
 957 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 958 ## Compare with the gnu-linux case below, which added to the end
 959 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 960 ## LD_SWITCH_SYSTEM_TEMACS.
 961 case "$opsys" in
 962   netbsd|openbsd)
 963    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 964    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 965 esac
 966
 967
 968 C_SWITCH_MACHINE=
 969 if test "$machine" = "alpha"; then
 970   AC_CHECK_DECL([__ELF__])
 971   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 972     ## With ELF, make sure that all common symbols get allocated to in the
 973     ## data section.  Otherwise, the dump of temacs may miss variables in
 974     ## the shared library that have been initialized.  For example, with
 975     ## GNU libc, __malloc_initialized would normally be resolved to the
 976     ## shared library's .bss section, which is fatal.
 977     if test "x$GCC" = "xyes"; then
 978       C_SWITCH_MACHINE="-fno-common"
 979     else
 980       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 981     fi
 982   else
 983     UNEXEC_OBJ=unexalpha.o
 984   fi
 985 fi
 986 AC_SUBST(C_SWITCH_MACHINE)
 987
 988 AC_SUBST(UNEXEC_OBJ)
 989
 990 C_SWITCH_SYSTEM=
 991 ## Some programs in src produce warnings saying certain subprograms
 992 ## are too complex and need a MAXMEM value greater than 2000 for
 993 ## additional optimization.  --nils@exp-math.uni-essen.de
 994 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 995   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 996 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 997 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 998 AC_SUBST(C_SWITCH_SYSTEM)
 999
1000
1001 LIBS_SYSTEM=
1002 case "$opsys" in
1003   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1004   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1005
1006   freebsd) LIBS_SYSTEM="-lutil" ;;
1007
1008   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1009
1010   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1011
1012   ## Motif needs -lgen.
1013   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1014 esac
1015 AC_SUBST(LIBS_SYSTEM)
1016
1017
1018 ### Make sure subsequent tests use flags consistent with the build flags.
1019
1020 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1021   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1022 else
1023   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1024 fi
1025
1026 dnl For AC_FUNC_GETLOADAVG, at least:
1027 AC_CONFIG_LIBOBJ_DIR(src)
1028
1029 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1030 AC_SYS_LARGEFILE
1031
1032
1033 ## If user specified a crt-dir, use that unconditionally.
1034 if test "X$CRT_DIR" = "X"; then
1035
1036   case "$canonical" in
1037     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1038     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1039     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1040     ## For anything else (eg /usr/lib32), it is up the user to specify
1041     ## the location (bug#5655).
1042     ## Test for crtn.o, not just the directory, because sometimes the
1043     ## directory exists but does not have the relevant files (bug#1287).
1044     ## FIXME better to test for binary compatibility somehow.
1045     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1046     ;;
1047
1048     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1049   esac
1050
1051   case "$opsys" in
1052     hpux10-20) CRT_DIR=/lib ;;
1053   esac
1054
1055   ## Default is /usr/lib.
1056   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1057
1058 else
1059
1060   ## Some platforms don't use any of these files, so it is not
1061   ## appropriate to put this test outside the if block.
1062   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1063     AC_MSG_ERROR([crt*.o not found in specified location.])
1064
1065 fi
1066
1067 AC_SUBST(CRT_DIR)
1068
1069 LIB_MATH=-lm
1070 LIB_STANDARD=
1071 START_FILES=
1072
1073 case $opsys in
1074   cygwin )
1075     LIB_MATH=
1076     START_FILES='ecrt0.o'
1077     ;;
1078   darwin )
1079     ## Adding -lm confuses the dynamic linker, so omit it.
1080     LIB_MATH=
1081     START_FILES='pre-crt0.o'
1082     ;;
1083   freebsd )
1084     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1085     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1086     ;;
1087   gnu-linux | gnu-kfreebsd )
1088     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1089     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1090     ;;
1091   hpux10-20 | hpux11 )
1092     LIB_STANDARD=-lc
1093     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1094     ;;
1095   netbsd | openbsd )
1096     if test -f $CRT_DIR/crti.o; then
1097         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1098         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1099     else
1100         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1101         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1102     fi
1103     ;;
1104 esac
1105
1106 AC_SUBST(LIB_MATH)
1107 AC_SUBST(START_FILES)
1108
1109 dnl This function definition taken from Gnome 2.0
1110 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1111 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1112 dnl also defines GSTUFF_PKG_ERRORS on error
1113 AC_DEFUN([PKG_CHECK_MODULES], [
1114   succeeded=no
1115
1116   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1117
1118   if test "$PKG_CONFIG" = "no" ; then
1119      ifelse([$4], , [AC_MSG_ERROR([
1120       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1121   else
1122      PKG_CONFIG_MIN_VERSION=0.9.0
1123      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1124         AC_MSG_CHECKING(for $2)
1125
1126         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1127             AC_MSG_RESULT(yes)
1128             succeeded=yes
1129
1130             AC_MSG_CHECKING($1_CFLAGS)
1131             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1132             AC_MSG_RESULT($$1_CFLAGS)
1133
1134             AC_MSG_CHECKING($1_LIBS)
1135             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1136             AC_MSG_RESULT($$1_LIBS)
1137         else
1138             AC_MSG_RESULT(no)
1139             $1_CFLAGS=""
1140             $1_LIBS=""
1141             ## If we have a custom action on failure, don't print errors, but
1142             ## do set a variable so people can do so.
1143             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1144             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1145         fi
1146
1147         AC_SUBST($1_CFLAGS)
1148         AC_SUBST($1_LIBS)
1149      else
1150         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1151         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1152      fi
1153   fi
1154
1155   if test $succeeded = yes; then
1156      ifelse([$3], , :, [$3])
1157   else
1158      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1159   fi
1160 ])
1161
1162
1163 if test "${with_sound}" != "no"; then
1164   # Sound support for GNU/Linux and the free BSDs.
1165   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1166     have_sound_header=yes)
1167   # Emulation library used on NetBSD.
1168   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1169   AC_SUBST(LIBSOUND)
1170
1171   ALSA_REQUIRED=1.0.0
1172   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1173   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1174   if test $HAVE_ALSA = yes; then
1175     SAVE_CFLAGS="$CFLAGS"
1176     SAVE_LDFLAGS="$LDFLAGS"
1177     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1178     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1179     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1180                     emacs_alsa_normal=yes,
1181                     emacs_alsa_normal=no)
1182     if test "$emacs_alsa_normal" != yes; then
1183       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1184                      [snd_lib_error_set_handler (0);],
1185                      emacs_alsa_subdir=yes,
1186                      emacs_alsa_subdir=no)
1187       if test "$emacs_alsa_subdir" != yes; then
1188         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1189       fi
1190       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1191     fi
1192
1193     CFLAGS="$SAVE_CFLAGS"
1194     LDFLAGS="$SAVE_LDFLAGS"
1195     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1196     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1197     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1198   fi
1199
1200   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1201   dnl compiles only on the specified platforms.  For others, it
1202   dnl probably doesn't make sense to try.
1203   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1204      case "$opsys" in
1205        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1206        gnu-linux|freebsd|netbsd)
1207          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1208          ;;
1209      esac
1210   fi
1211
1212   AC_SUBST(CFLAGS_SOUND)
1213 fi
1214
1215 dnl checks for header files
1216 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1217   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1218   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1219   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1220   sys/utsname.h pwd.h utmp.h)
1221
1222 AC_MSG_CHECKING(if personality LINUX32 can be set)
1223 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1224                emacs_cv_personality_linux32=yes,
1225                emacs_cv_personality_linux32=no)
1226 AC_MSG_RESULT($emacs_cv_personality_linux32)
1227
1228 if test $emacs_cv_personality_linux32 = yes; then
1229   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1230             [Define to 1 if personality LINUX32 can be set.])
1231 fi
1232
1233 dnl On Solaris 8 there's a compilation warning for term.h because
1234 dnl it doesn't define `bool'.
1235 AC_CHECK_HEADERS(term.h, , , -)
1236 AC_HEADER_STDC
1237 AC_HEADER_TIME
1238 AC_CHECK_DECLS([sys_siglist])
1239 if test $ac_cv_have_decl_sys_siglist != yes; then
1240   # For Tru64, at least:
1241   AC_CHECK_DECLS([__sys_siglist])
1242   if test $ac_cv_have_decl___sys_siglist = yes; then
1243     AC_DEFINE(sys_siglist, __sys_siglist,
1244               [Define to any substitute for sys_siglist.])
1245   fi
1246 fi
1247 AC_HEADER_SYS_WAIT
1248
1249 dnl Some systems have utime.h but don't declare the struct anyplace.
1250 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1251 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1252 #include <sys/time.h>
1253 #include <time.h>
1254 #else
1255 #ifdef HAVE_SYS_TIME_H
1256 #include <sys/time.h>
1257 #else
1258 #include <time.h>
1259 #endif
1260 #endif
1261 #ifdef HAVE_UTIME_H
1262 #include <utime.h>
1263 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1264   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1265 if test $emacs_cv_struct_utimbuf = yes; then
1266   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1267 fi
1268
1269 dnl checks for typedefs
1270 AC_TYPE_SIGNAL
1271
1272 dnl Check for speed_t typedef.
1273 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1274   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1275     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1276 if test $emacs_cv_speed_t = yes; then
1277   AC_DEFINE(HAVE_SPEED_T, 1,
1278            [Define to 1 if `speed_t' is declared by <termios.h>.])
1279 fi
1280
1281 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1282 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1283 #include <sys/time.h>
1284 #include <time.h>
1285 #else
1286 #ifdef HAVE_SYS_TIME_H
1287 #include <sys/time.h>
1288 #else
1289 #include <time.h>
1290 #endif
1291 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1292   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1293 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1294 if test $emacs_cv_struct_timeval = yes; then
1295   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1296 fi
1297
1298 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1299 AC_TRY_COMPILE([#include <math.h>],
1300 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1301   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1302 HAVE_EXCEPTION=$emacs_cv_struct_exception
1303 if test $emacs_cv_struct_exception != yes; then
1304   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1305 fi
1306
1307 AC_CHECK_HEADERS(sys/socket.h)
1308 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1309 #if HAVE_SYS_SOCKET_H
1310 #include <sys/socket.h>
1311 #endif])
1312
1313 dnl checks for structure members
1314 AC_STRUCT_TM
1315 AC_STRUCT_TIMEZONE
1316 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1317                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1318                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1319                 [#include <time.h>])
1320 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1321                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1322                   struct ifreq.ifr_addr], , ,
1323                  [AC_INCLUDES_DEFAULT
1324 #if HAVE_SYS_SOCKET_H
1325 #include <sys/socket.h>
1326 #endif
1327 #if HAVE_NET_IF_H
1328 #include <net/if.h>
1329 #endif])
1330
1331 dnl checks for compiler characteristics
1332
1333 dnl Testing __STDC__ to determine prototype support isn't good enough.
1334 dnl DEC C, for instance, doesn't define it with default options, and
1335 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1336 dnl and void *.
1337 AC_C_PROTOTYPES
1338 AC_C_VOLATILE
1339 AC_C_CONST
1340 dnl This isn't useful because we can't turn on use of `inline' unless
1341 dnl the compiler groks `extern inline'.
1342 dnl AC_C_INLINE
1343 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1344   [AC_TRY_COMPILE(, [void * foo;],
1345                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1346 if test $emacs_cv_void_star = yes; then
1347   AC_DEFINE(POINTER_TYPE, void)
1348 else
1349   AC_DEFINE(POINTER_TYPE, char)
1350 fi
1351 AH_TEMPLATE(POINTER_TYPE,
1352             [Define as `void' if your compiler accepts `void *'; otherwise
1353              define as `char'.])dnl
1354
1355
1356
1357 dnl This could be used for targets which can have both byte sexes.
1358 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1359 dnl AC_C_BIGENDIAN
1360
1361 dnl check for Make feature
1362 AC_PROG_MAKE_SET
1363
1364 DEPFLAGS=
1365 MKDEPDIR=":"
1366 deps_frag=deps.mk
1367 dnl check for GNU Make if we have GCC and autodepend is on.
1368 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1369    AC_MSG_CHECKING([whether we are using GNU Make])
1370    HAVE_GNU_MAKE=no
1371    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1372    if test "x$testval" != x; then
1373       HAVE_GNU_MAKE=yes
1374    else
1375       ac_enable_autodepend=no
1376    fi
1377    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1378    if test $HAVE_GNU_MAKE = yes; then
1379       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1380       SAVE_CFLAGS="$CFLAGS"
1381       CFLAGS="$CFLAGS -MMD -MF deps.d"
1382       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1383       CFLAGS="$SAVE_CFLAGS"
1384       test -f deps.d || ac_enable_autodepend=no
1385       rm -rf deps.d
1386       AC_MSG_RESULT([$ac_enable_autodepend])
1387    fi
1388    if test $ac_enable_autodepend = yes; then
1389       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1390       ## In parallel builds, another make might create depdir between
1391       ## the first test and mkdir, so stick another test on the end.
1392       ## Or use mkinstalldirs?  mkdir -p is not portable.
1393       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1394       deps_frag=autodeps.mk
1395    fi
1396 fi
1397 deps_frag=$srcdir/src/$deps_frag
1398 AC_SUBST(MKDEPDIR)
1399 AC_SUBST(DEPFLAGS)
1400 AC_SUBST_FILE(deps_frag)
1401
1402
1403 dnl checks for operating system services
1404 AC_SYS_LONG_FILE_NAMES
1405
1406 #### Choose a window system.
1407
1408 AC_PATH_X
1409 if test "$no_x" = yes; then
1410   window_system=none
1411 else
1412   window_system=x11
1413 fi
1414
1415 ## Workaround for bug in autoconf <= 2.62.
1416 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1417 ## No need to do anything special for these standard directories.
1418 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1419
1420    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1421
1422 fi
1423
1424 LD_SWITCH_X_SITE_AUX=
1425 LD_SWITCH_X_SITE_AUX_RPATH=
1426 if test "${x_libraries}" != NONE; then
1427   if test -n "${x_libraries}"; then
1428     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1429     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1430     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1431   fi
1432   x_default_search_path=""
1433   x_search_path=${x_libraries}
1434   if test -z "${x_search_path}"; then
1435     x_search_path=/usr/lib
1436   fi
1437   for x_library in `echo ${x_search_path}: | \
1438                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1439     x_search_path="\
1440 ${x_library}/X11/%L/%T/%N%C%S:\
1441 ${x_library}/X11/%l/%T/%N%C%S:\
1442 ${x_library}/X11/%T/%N%C%S:\
1443 ${x_library}/X11/%L/%T/%N%S:\
1444 ${x_library}/X11/%l/%T/%N%S:\
1445 ${x_library}/X11/%T/%N%S"
1446     if test x"${x_default_search_path}" = x; then
1447       x_default_search_path=${x_search_path}
1448     else
1449       x_default_search_path="${x_search_path}:${x_default_search_path}"
1450     fi
1451   done
1452 fi
1453 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1454 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1455
1456 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1457   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1458 fi
1459
1460 if test x"${x_includes}" = x; then
1461   bitmapdir=/usr/include/X11/bitmaps
1462 else
1463   # accumulate include directories that have X11 bitmap subdirectories
1464   bmd_acc="dummyval"
1465   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1466     if test -d "${bmd}/X11/bitmaps"; then
1467       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1468     fi
1469     if test -d "${bmd}/bitmaps"; then
1470       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1471     fi
1472   done
1473   if test ${bmd_acc} != "dummyval"; then
1474     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1475   fi
1476 fi
1477
1478 HAVE_NS=no
1479 NS_IMPL_COCOA=no
1480 NS_IMPL_GNUSTEP=no
1481 tmp_CPPFLAGS="$CPPFLAGS"
1482 tmp_CFLAGS="$CFLAGS"
1483 CPPFLAGS="$CPPFLAGS -x objective-c"
1484 CFLAGS="$CFLAGS -x objective-c"
1485 TEMACS_LDFLAGS2="\${LDFLAGS}"
1486 dnl I don't think it's especially important, but src/Makefile.in
1487 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1488 dnl trailing "/" to it, so now we do it here.
1489 if test "${with_ns}" != no; then
1490   if test "${opsys}" = darwin; then
1491      NS_IMPL_COCOA=yes
1492      ns_appdir=`pwd`/nextstep/Emacs.app/
1493      ns_appbindir=${ns_appdir}Contents/MacOS/
1494      ns_appresdir=${ns_appdir}Contents/Resources
1495      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1496   elif test -f $GNUSTEP_CONFIG_FILE; then
1497      NS_IMPL_GNUSTEP=yes
1498      ns_appdir=`pwd`/nextstep/Emacs.app/
1499      ns_appbindir=${ns_appdir}
1500      ns_appresdir=${ns_appdir}Resources
1501      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1502      dnl FIXME sourcing this several times in subshells seems inefficient.
1503      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1504      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1505      dnl I seemed to need these as well with GNUstep-startup 0.25.
1506      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1507      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1508      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1509        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1510      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1511        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1512      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1513      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1514      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1515      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1516      LIB_STANDARD=
1517      START_FILES=
1518      TEMACS_LDFLAGS2=
1519   fi
1520   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1521                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1522   files are missing or cannot be compiled.])])
1523   NS_HAVE_NSINTEGER=yes
1524   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1525                                      [NSInteger i;])],
1526                     ns_have_nsinteger=yes,
1527                     ns_have_nsinteger=no)
1528   if test $ns_have_nsinteger = no; then
1529     NS_HAVE_NSINTEGER=no
1530   fi
1531 fi
1532 AC_SUBST(TEMACS_LDFLAGS2)
1533
1534 ns_frag=/dev/null
1535 NS_OBJ=
1536 NS_SUPPORT=
1537 if test "${HAVE_NS}" = yes; then
1538   window_system=nextstep
1539   with_xft=no
1540   # set up packaging dirs
1541   exec_prefix=${ns_appbindir}
1542   libexecdir=${ns_appbindir}/libexec
1543   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1544      prefix=${ns_appresdir}
1545   fi
1546   ns_frag=$srcdir/src/ns.mk
1547   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1548   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1549 fi
1550 CFLAGS="$tmp_CFLAGS"
1551 CPPFLAGS="$tmp_CPPFLAGS"
1552 AC_SUBST(NS_OBJ)
1553 AC_SUBST(NS_SUPPORT)
1554 AC_SUBST(LIB_STANDARD)
1555 AC_SUBST_FILE(ns_frag)
1556
1557 case "${window_system}" in
1558   x11 )
1559     HAVE_X_WINDOWS=yes
1560     HAVE_X11=yes
1561     case "${with_x_toolkit}" in
1562       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1563       motif ) USE_X_TOOLKIT=MOTIF ;;
1564       gtk ) with_gtk=yes
1565 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1566 dnl USE_X_TOOLKIT is set.
1567             USE_X_TOOLKIT=none ;;
1568       gtk3 ) with_gtk3=yes
1569              USE_X_TOOLKIT=none ;;
1570       no ) USE_X_TOOLKIT=none ;;
1571 dnl If user did not say whether to use a toolkit, make this decision later:
1572 dnl use the toolkit if we have gtk, or X11R5 or newer.
1573       * ) USE_X_TOOLKIT=maybe ;;
1574     esac
1575   ;;
1576   nextstep | none )
1577     HAVE_X_WINDOWS=no
1578     HAVE_X11=no
1579     USE_X_TOOLKIT=none
1580   ;;
1581 esac
1582
1583 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1584    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1585    if test "$HAVE_XSERVER" = true ||
1586       test -n "$DISPLAY" ||
1587       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1588         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1589 were found.  You should install the relevant development files for X
1590 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1591 sure you have development files for image handling, i.e.
1592 tiff, gif, jpeg, png and xpm.
1593 If you are sure you want Emacs compiled without X window support, pass
1594   --without-x
1595 to configure.])
1596    fi
1597 fi
1598
1599 ### If we're using X11, we should use the X menu package.
1600 HAVE_MENUS=no
1601 case ${HAVE_X11} in
1602   yes ) HAVE_MENUS=yes ;;
1603 esac
1604
1605 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1606 # Assume not, until told otherwise.
1607 GNU_MALLOC=yes
1608 doug_lea_malloc=yes
1609 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1610 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1611 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1612                emacs_cv_var___after_morecore_hook,
1613 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1614   emacs_cv_var___after_morecore_hook=yes,
1615   emacs_cv_var___after_morecore_hook=no)])
1616 if test $emacs_cv_var___after_morecore_hook = no; then
1617   doug_lea_malloc=no
1618 fi
1619
1620
1621 dnl See comments in aix4-2.h about maybe using system malloc there.
1622 system_malloc=no
1623 case "$opsys" in
1624   ## darwin ld insists on the use of malloc routines in the System framework.
1625   darwin|sol2-10) system_malloc=yes ;;
1626 esac
1627
1628 if test "${system_malloc}" = "yes"; then
1629   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1630   GNU_MALLOC=no
1631   GNU_MALLOC_reason="
1632     (The GNU allocators don't work with this system configuration.)"
1633   GMALLOC_OBJ=
1634   VMLIMIT_OBJ=
1635 else
1636   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1637   VMLIMIT_OBJ=vm-limit.o
1638 fi
1639 AC_SUBST(GMALLOC_OBJ)
1640 AC_SUBST(VMLIMIT_OBJ)
1641
1642 if test "$doug_lea_malloc" = "yes" ; then
1643   if test "$GNU_MALLOC" = yes ; then
1644     GNU_MALLOC_reason="
1645       (Using Doug Lea's new malloc from the GNU C Library.)"
1646   fi
1647   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1648             [Define to 1 if you are using the GNU C Library.])
1649
1650   ## Use mmap directly for allocating larger buffers.
1651   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1652   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1653   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1654   case "$opsys" in
1655     gnu*) REL_ALLOC=no ;;
1656   esac
1657 fi
1658
1659 if test x"${REL_ALLOC}" = x; then
1660   REL_ALLOC=${GNU_MALLOC}
1661 fi
1662
1663 use_mmap_for_buffers=no
1664 case "$opsys" in
1665   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1666 esac
1667
1668 AC_FUNC_MMAP
1669 if test $use_mmap_for_buffers = yes; then
1670   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1671   REL_ALLOC=no
1672 fi
1673
1674 LIBS="$LIBS_SYSTEM $LIBS"
1675
1676 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1677 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1678 AC_CHECK_LIB(dnet, dnet_ntoa)
1679 dnl This causes -lresolv to get used in subsequent tests,
1680 dnl which causes failures on some systems such as HPUX 9.
1681 dnl AC_CHECK_LIB(resolv, gethostbyname)
1682
1683 dnl FIXME replace main with a function we actually want from this library.
1684 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1685
1686 AC_CHECK_LIB(pthreads, cma_open)
1687
1688 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1689 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1690 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1691 ## added to LIBS in configure would never contain the pthreads part,
1692 ## but the value used in Makefiles might.  FIXME?
1693 ##
1694 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1695 ## be harmless on older versions of X where it happens to exist.
1696 test "$opsys" = "aix4-2" && \
1697   test $ac_cv_lib_pthreads_cma_open = yes && \
1698   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1699
1700 dnl Check for need for bigtoc support on IBM AIX
1701
1702 case ${host_os} in
1703 aix*)
1704   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1705     case $GCC in
1706     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1707     *) gdb_cv_bigtoc=-bbigtoc ;;
1708     esac
1709
1710     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1711     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1712   ])
1713   ;;
1714 esac
1715
1716 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1717 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1718 # REAL_CPPFLAGS later on.
1719
1720 REAL_CPPFLAGS="$CPPFLAGS"
1721
1722 if test "${HAVE_X11}" = "yes"; then
1723   DEFS="$C_SWITCH_X_SITE $DEFS"
1724   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1725   LIBS="-lX11 $LIBS"
1726   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1727   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1728
1729   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1730   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1731   # but it's more convenient here to set LD_RUN_PATH
1732   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1733   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1734     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1735     export LD_RUN_PATH
1736   fi
1737
1738   if test "${opsys}" = "gnu-linux"; then
1739     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1740     AC_TRY_LINK([],
1741      [XOpenDisplay ("foo");],
1742      [xlinux_first_failure=no],
1743      [xlinux_first_failure=yes])
1744     if test "${xlinux_first_failure}" = "yes"; then
1745       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1746       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1747       OLD_CPPFLAGS="$CPPFLAGS"
1748       OLD_LIBS="$LIBS"
1749       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1750       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1751       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1752       LIBS="$LIBS -b i486-linuxaout"
1753       AC_TRY_LINK([],
1754        [XOpenDisplay ("foo");],
1755        [xlinux_second_failure=no],
1756        [xlinux_second_failure=yes])
1757       if test "${xlinux_second_failure}" = "yes"; then
1758         # If we get the same failure with -b, there is no use adding -b.
1759         # So take it out.  This plays safe.
1760         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1761         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1762         CPPFLAGS="$OLD_CPPFLAGS"
1763         LIBS="$OLD_LIBS"
1764         AC_MSG_RESULT(no)
1765       else
1766         AC_MSG_RESULT(yes)
1767       fi
1768     else
1769       AC_MSG_RESULT(no)
1770     fi
1771   fi
1772
1773   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1774   # header files included from there.
1775   AC_MSG_CHECKING(for Xkb)
1776   AC_TRY_LINK([#include <X11/Xlib.h>
1777 #include <X11/XKBlib.h>],
1778         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1779         emacs_xkb=yes, emacs_xkb=no)
1780   AC_MSG_RESULT($emacs_xkb)
1781   if test $emacs_xkb = yes; then
1782     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1783   fi
1784
1785   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1786 XScreenNumberOfScreen XSetWMProtocols)
1787 fi
1788
1789 if test "${window_system}" = "x11"; then
1790   AC_MSG_CHECKING(X11 version 6)
1791   AC_CACHE_VAL(emacs_cv_x11_version_6,
1792   [AC_TRY_LINK([#include <X11/Xlib.h>],
1793 [#if XlibSpecificationRelease < 6
1794 fail;
1795 #endif
1796 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1797   if test $emacs_cv_x11_version_6 = yes; then
1798     AC_MSG_RESULT(6 or newer)
1799     AC_DEFINE(HAVE_X11R6, 1,
1800               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1801     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1802     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1803     ## XIM support.
1804     case "$opsys" in
1805       sol2-*) : ;;
1806       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1807            [Define if you have usable X11R6-style XIM support.])
1808          ;;
1809     esac
1810   else
1811     AC_MSG_RESULT(before 6)
1812   fi
1813 fi
1814
1815
1816 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1817 HAVE_RSVG=no
1818 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1819   if test "${with_rsvg}" != "no"; then
1820     RSVG_REQUIRED=2.11.0
1821     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1822
1823     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1824     AC_SUBST(RSVG_CFLAGS)
1825     AC_SUBST(RSVG_LIBS)
1826
1827     if test ".${RSVG_CFLAGS}" != "."; then
1828       HAVE_RSVG=yes
1829       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1830       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1831       LIBS="$RSVG_LIBS $LIBS"
1832     fi
1833   fi
1834 fi
1835
1836
1837 HAVE_GTK=no
1838 if test "${with_gtk3}" = "yes"; then
1839   GLIB_REQUIRED=2.6
1840   GTK_REQUIRED=2.90
1841   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1842
1843   dnl Checks for libraries.
1844   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1845   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1846      AC_MSG_ERROR($GTK_PKG_ERRORS)
1847   fi
1848 fi
1849
1850 if test "$pkg_check_gtk" != "yes"; then
1851   HAVE_GTK=no
1852 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1853   GLIB_REQUIRED=2.6
1854   GTK_REQUIRED=2.6
1855   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1856
1857   dnl Checks for libraries.
1858   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1859   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1860      AC_MSG_ERROR($GTK_PKG_ERRORS)
1861   fi
1862 fi
1863 fi
1864
1865 GTK_OBJ=
1866 if test x"$pkg_check_gtk" = xyes; then
1867
1868   AC_SUBST(GTK_CFLAGS)
1869   AC_SUBST(GTK_LIBS)
1870   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1871   CFLAGS="$CFLAGS $GTK_CFLAGS"
1872   LIBS="$GTK_LIBS $LIBS"
1873   dnl Try to compile a simple GTK program.
1874   GTK_COMPILES=no
1875   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1876   if test "${GTK_COMPILES}" != "yes"; then
1877     if test "$USE_X_TOOLKIT" != "maybe"; then
1878       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1879     fi
1880   else
1881     HAVE_GTK=yes
1882     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1883     GTK_OBJ=gtkutil.o
1884     USE_X_TOOLKIT=none
1885     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1886       :
1887     else
1888       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1889        closing open displays.  This is no problem if you just use
1890        one display, but if you use more than one and close one of them
1891        Emacs may crash.]])
1892       sleep 3
1893     fi
1894   fi
1895
1896 fi
1897 AC_SUBST(GTK_OBJ)
1898
1899
1900 if test "${HAVE_GTK}" = "yes"; then
1901
1902   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1903   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1904   if test "$with_toolkit_scroll_bars" != no; then
1905     with_toolkit_scroll_bars=yes
1906   fi
1907
1908   dnl  Check if we have the old file selection dialog declared and
1909   dnl  in the link library.  In 2.x it may be in the library,
1910   dnl  but not declared if deprecated featured has been selected out.
1911   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1912   HAVE_GTK_FILE_SELECTION=no
1913   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1914                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1915 #include <gtk/gtk.h>])
1916   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1917     AC_CHECK_FUNCS(gtk_file_selection_new)
1918   fi
1919
1920   dnl Check if pthreads are available.  Emacs only needs this when using
1921   dnl gtk_file_chooser under Gnome.
1922     HAVE_GTK_AND_PTHREAD=no
1923     AC_CHECK_HEADERS(pthread.h)
1924     if test "$ac_cv_header_pthread_h"; then
1925       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1926     fi
1927     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1928       case "${canonical}" in
1929         *-hpux*) ;;
1930         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1931       esac
1932       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1933                [Define to 1 if you have GTK and pthread (-lpthread).])
1934     fi
1935
1936   dnl Check for functions introduced in 2.14 and later.
1937   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1938                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1939                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1940                  gtk_orientable_set_orientation)
1941
1942 fi
1943
1944 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1945 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1946 dnl also not configured.
1947 HAVE_DBUS=no
1948 DBUS_OBJ=
1949 if test "${with_dbus}" = "yes"; then
1950    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1951    if test "$HAVE_DBUS" = yes; then
1952      LIBS="$LIBS $DBUS_LIBS"
1953      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1954      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1955      DBUS_OBJ=dbusbind.o
1956    fi
1957 fi
1958 AC_SUBST(DBUS_OBJ)
1959
1960 dnl GConf has been tested under GNU/Linux only.
1961 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1962 HAVE_GCONF=no
1963 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1964    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1965    if test "$HAVE_GCONF" = yes; then
1966       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1967    fi
1968 fi
1969
1970 dnl SELinux is available for GNU/Linux only.
1971 HAVE_LIBSELINUX=no
1972 LIBSELINUX_LIBS=
1973 if test "${with_selinux}" = "yes"; then
1974    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1975    if test "$HAVE_LIBSELINUX" = yes; then
1976       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1977       LIBSELINUX_LIBS=-lselinux
1978    fi
1979 fi
1980 AC_SUBST(LIBSELINUX_LIBS)
1981
1982 dnl Do not put whitespace before the #include statements below.
1983 dnl Older compilers (eg sunos4 cc) choke on it.
1984 HAVE_XAW3D=no
1985 LUCID_LIBW=
1986 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1987   if test "$with_xaw3d" != no; then
1988     AC_MSG_CHECKING(for xaw3d)
1989     AC_CACHE_VAL(emacs_cv_xaw3d,
1990     [AC_TRY_LINK([
1991 #include <X11/Intrinsic.h>
1992 #include <X11/Xaw3d/Simple.h>],
1993       [],
1994       emacs_cv_xaw3d=yes,
1995       emacs_cv_xaw3d=no)])
1996   else
1997     emacs_cv_xaw3d=no
1998   fi
1999   if test $emacs_cv_xaw3d = yes; then
2000     AC_MSG_RESULT([yes; using Lucid toolkit])
2001     USE_X_TOOLKIT=LUCID
2002     HAVE_XAW3D=yes
2003     LUCID_LIBW=-lXaw3d
2004     AC_DEFINE(HAVE_XAW3D, 1,
2005               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2006   else
2007     AC_MSG_RESULT(no)
2008     AC_MSG_CHECKING(for libXaw)
2009     AC_CACHE_VAL(emacs_cv_xaw,
2010     [AC_TRY_LINK([
2011 #include <X11/Intrinsic.h>
2012 #include <X11/Xaw/Simple.h>],
2013       [],
2014       emacs_cv_xaw=yes,
2015       emacs_cv_xaw=no)])
2016     if test $emacs_cv_xaw = yes; then
2017       AC_MSG_RESULT([yes; using Lucid toolkit])
2018       USE_X_TOOLKIT=LUCID
2019       LUCID_LIBW=-lXaw
2020     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2021       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2022     else
2023       AC_MSG_RESULT([no; do not use toolkit by default])
2024       USE_X_TOOLKIT=none
2025     fi
2026   fi
2027 fi
2028
2029 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2030
2031 LIBXTR6=
2032 if test "${USE_X_TOOLKIT}" != "none"; then
2033   AC_MSG_CHECKING(X11 toolkit version)
2034   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2035   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2036 [#if XtSpecificationRelease < 6
2037 fail;
2038 #endif
2039 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2040   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2041   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2042     AC_MSG_RESULT(6 or newer)
2043     AC_DEFINE(HAVE_X11XTR6, 1,
2044               [Define to 1 if you have the X11R6 or newer version of Xt.])
2045     LIBXTR6="-lSM -lICE"
2046     case "$opsys" in
2047       ## Use libw.a along with X11R6 Xt.
2048       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2049     esac
2050   else
2051     AC_MSG_RESULT(before 6)
2052   fi
2053
2054 dnl If using toolkit, check whether libXmu.a exists.
2055 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2056   OLDLIBS="$LIBS"
2057   if test x$HAVE_X11XTR6 = xyes; then
2058     LIBS="-lXt -lSM -lICE $LIBS"
2059   else
2060     LIBS="-lXt $LIBS"
2061   fi
2062   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2063   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2064 fi
2065 AC_SUBST(LIBXTR6)
2066
2067 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2068 dnl Why not just test for libxmu in the normal way?
2069 LIBXMU=-lXmu
2070 case "$machine" in
2071   ## These machines don't supply Xmu.
2072   hpux* | aix4-2 )
2073     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2074     ;;
2075 esac
2076 AC_SUBST(LIBXMU)
2077
2078 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2079 if test "${HAVE_X11}" = "yes"; then
2080   if test "${USE_X_TOOLKIT}" != "none"; then
2081     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2082   fi
2083 fi
2084
2085 LIBXP=
2086 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2087   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2088   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2089     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2090 int x = 5;
2091 #else
2092 Motif version prior to 2.1.
2093 #endif],
2094     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2095   if test $emacs_cv_motif_version_2_1 = yes; then
2096     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2097   else
2098     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2099     # We put this in CFLAGS temporarily to precede other -I options
2100     # that might be in CFLAGS temporarily.
2101     # We put this in CPPFLAGS where it precedes the other -I options.
2102     OLD_CPPFLAGS=$CPPFLAGS
2103     OLD_CFLAGS=$CFLAGS
2104     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2105     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2106     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2107       [int x = 5;],
2108       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2109     if test $emacs_cv_lesstif = yes; then
2110       # Make sure this -I option remains in CPPFLAGS after it is set
2111       # back to REAL_CPPFLAGS.
2112       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2113       # have those other -I options anyway.  Ultimately, having this
2114       # directory ultimately in CPPFLAGS will be enough.
2115       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2116       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2117     else
2118       CFLAGS=$OLD_CFLAGS
2119       CPPFLAGS=$OLD_CPPFLAGS
2120     fi
2121   fi
2122 fi
2123
2124 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2125 dnl using Motif or Xaw3d is available, and unless
2126 dnl --with-toolkit-scroll-bars=no was specified.
2127
2128 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2129             [Define to 1 if we should use toolkit scroll bars.])dnl
2130 USE_TOOLKIT_SCROLL_BARS=no
2131 if test "${with_toolkit_scroll_bars}" != "no"; then
2132   if test "${USE_X_TOOLKIT}" != "none"; then
2133     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2134       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2135       HAVE_XAW3D=no
2136       USE_TOOLKIT_SCROLL_BARS=yes
2137     elif test "${HAVE_XAW3D}" = "yes"; then
2138       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2139       USE_TOOLKIT_SCROLL_BARS=yes
2140     fi
2141   elif test "${HAVE_GTK}" = "yes"; then
2142     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2143     USE_TOOLKIT_SCROLL_BARS=yes
2144   elif test "${HAVE_NS}" = "yes"; then
2145     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2146     USE_TOOLKIT_SCROLL_BARS=yes
2147   fi
2148 fi
2149
2150 dnl See if XIM is available.
2151 AC_TRY_COMPILE([
2152           #include <X11/Xlib.h>
2153           #include <X11/Xresource.h>],
2154          [XIMProc  callback;],
2155          [HAVE_XIM=yes
2156          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2157          HAVE_XIM=no)
2158
2159 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2160
2161 if test "${with_xim}" != "no"; then
2162   AC_DEFINE(USE_XIM, 1,
2163             [Define to 1 if we should use XIM, if it is available.])
2164 fi
2165
2166
2167 if test "${HAVE_XIM}" != "no"; then
2168   late_CFLAGS=$CFLAGS
2169   if test "$GCC" = yes; then
2170     CFLAGS="$CFLAGS --pedantic-errors"
2171   fi
2172   AC_TRY_COMPILE([
2173 #include <X11/Xlib.h>
2174 #include <X11/Xresource.h>],
2175 [Display *display;
2176 XrmDatabase db;
2177 char *res_name;
2178 char *res_class;
2179 XIMProc  callback;
2180 XPointer *client_data;
2181 #ifndef __GNUC__
2182 /* If we're not using GCC, it's probably not XFree86, and this is
2183    probably right, but we can't use something like --pedantic-errors.  */
2184 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2185                                            char*, XIMProc, XPointer*);
2186 #endif
2187 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2188    client_data);],
2189     [emacs_cv_arg6_star=yes])
2190   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2191          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2192 either XPointer or XPointer*.])dnl
2193   if test "$emacs_cv_arg6_star" = yes; then
2194     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2195   else
2196     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2197   fi
2198   CFLAGS=$late_CFLAGS
2199 fi
2200
2201 ### Start of font-backend (under any platform) section.
2202 # (nothing here yet -- this is a placeholder)
2203 ### End of font-backend (under any platform) section.
2204
2205 ### Start of font-backend (under X11) section.
2206 if test "${HAVE_X11}" = "yes"; then
2207    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2208
2209    ## Use -lXft if available, unless `--with-xft=no'.
2210    HAVE_XFT=maybe
2211     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2212       with_xft="no";
2213     fi
2214     if test "x${with_xft}" != "xno"; then
2215
2216       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2217       ## Because xftfont.c uses XRenderQueryExtension, we also
2218       ## need to link to -lXrender.
2219       HAVE_XRENDER=no
2220       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2221       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2222         OLD_CPPFLAGS="$CPPFLAGS"
2223         OLD_CFLAGS="$CFLAGS"
2224         OLD_LIBS="$LIBS"
2225         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2226         CFLAGS="$CFLAGS $XFT_CFLAGS"
2227         XFT_LIBS="-lXrender $XFT_LIBS"
2228         LIBS="$XFT_LIBS $LIBS"
2229         AC_CHECK_HEADER(X11/Xft/Xft.h,
2230           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2231
2232         if test "${HAVE_XFT}" = "yes"; then
2233           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2234             AC_SUBST(XFT_LIBS)
2235           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2236         else
2237           CPPFLAGS="$OLD_CPPFLAGS"
2238           CFLAGS="$OLD_CFLAGS"
2239           LIBS="$OLD_LIBS"
2240         fi                        # "${HAVE_XFT}" = "yes"
2241       fi                          # "$HAVE_XFT" != no
2242     fi                            # "x${with_xft}" != "xno"
2243
2244     dnl For the "Does Emacs use" message at the end.
2245     if test "$HAVE_XFT" != "yes"; then
2246        HAVE_XFT=no
2247     fi
2248
2249
2250     HAVE_FREETYPE=no
2251     ## We used to allow building with FreeType and without Xft.
2252     ## However, the ftx font backend driver is not in good shape.
2253     if test "${HAVE_XFT}" = "yes"; then
2254       dnl As we use Xft, we anyway use freetype.
2255       dnl There's no need for additional CFLAGS and LIBS.
2256       HAVE_FREETYPE=yes
2257       FONTCONFIG_CFLAGS=
2258       FONTCONFIG_LIBS=
2259     fi
2260
2261     HAVE_LIBOTF=no
2262     if test "${HAVE_FREETYPE}" = "yes"; then
2263       AC_DEFINE(HAVE_FREETYPE, 1,
2264                 [Define to 1 if using the freetype and fontconfig libraries.])
2265       if test "${with_libotf}" != "no"; then
2266         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2267                           HAVE_LIBOTF=no)
2268         if test "$HAVE_LIBOTF" = "yes"; then
2269           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2270           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2271                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2272                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2273           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2274             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2275                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2276           fi
2277         fi
2278       fi
2279     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2280     dnl Does the new font backend require it, or can it work without it?
2281     fi
2282
2283     HAVE_M17N_FLT=no
2284     if test "${HAVE_LIBOTF}" = yes; then
2285       if test "${with_m17n_flt}" != "no"; then
2286         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2287         if test "$HAVE_M17N_FLT" = "yes"; then
2288           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2289         fi
2290       fi
2291     fi
2292 else
2293     HAVE_XFT=no
2294     HAVE_FREETYPE=no
2295     HAVE_LIBOTF=no
2296     HAVE_M17N_FLT=no
2297 fi
2298
2299 ### End of font-backend (under X11) section.
2300
2301 AC_SUBST(FREETYPE_CFLAGS)
2302 AC_SUBST(FREETYPE_LIBS)
2303 AC_SUBST(FONTCONFIG_CFLAGS)
2304 AC_SUBST(FONTCONFIG_LIBS)
2305 AC_SUBST(LIBOTF_CFLAGS)
2306 AC_SUBST(LIBOTF_LIBS)
2307 AC_SUBST(M17N_FLT_CFLAGS)
2308 AC_SUBST(M17N_FLT_LIBS)
2309
2310 ### Use -lXpm if available, unless `--with-xpm=no'.
2311 HAVE_XPM=no
2312 LIBXPM=
2313 if test "${HAVE_X11}" = "yes"; then
2314   if test "${with_xpm}" != "no"; then
2315     AC_CHECK_HEADER(X11/xpm.h,
2316       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2317     if test "${HAVE_XPM}" = "yes"; then
2318       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2319       AC_EGREP_CPP(no_return_alloc_pixels,
2320       [#include "X11/xpm.h"
2321 #ifndef XpmReturnAllocPixels
2322 no_return_alloc_pixels
2323 #endif
2324       ], HAVE_XPM=no, HAVE_XPM=yes)
2325
2326       if test "${HAVE_XPM}" = "yes"; then
2327         AC_MSG_RESULT(yes)
2328       else
2329         AC_MSG_RESULT(no)
2330       fi
2331     fi
2332   fi
2333
2334   if test "${HAVE_XPM}" = "yes"; then
2335     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2336     LIBXPM=-lXpm
2337   fi
2338 fi
2339 AC_SUBST(LIBXPM)
2340
2341 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2342 HAVE_JPEG=no
2343 LIBJPEG=
2344 if test "${HAVE_X11}" = "yes"; then
2345   if test "${with_jpeg}" != "no"; then
2346     dnl Checking for jpeglib.h can lose because of a redefinition of
2347     dnl  HAVE_STDLIB_H.
2348     AC_CHECK_HEADER(jerror.h,
2349       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2350   fi
2351
2352   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2353   if test "${HAVE_JPEG}" = "yes"; then
2354     AC_DEFINE(HAVE_JPEG)
2355     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2356         [#include <jpeglib.h>
2357          version=JPEG_LIB_VERSION
2358 ],
2359         [AC_DEFINE(HAVE_JPEG)],
2360         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2361         HAVE_JPEG=no])
2362   fi
2363   if test "${HAVE_JPEG}" = "yes"; then
2364     LIBJPEG=-ljpeg
2365   fi
2366 fi
2367 AC_SUBST(LIBJPEG)
2368
2369 ### Use -lpng if available, unless `--with-png=no'.
2370 HAVE_PNG=no
2371 LIBPNG=
2372 if test "${HAVE_X11}" = "yes"; then
2373   if test "${with_png}" != "no"; then
2374     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2375     # in /usr/include/libpng.
2376     AC_CHECK_HEADERS(png.h libpng/png.h)
2377     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2378       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2379     fi
2380   fi
2381
2382   if test "${HAVE_PNG}" = "yes"; then
2383     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2384     LIBPNG="-lpng -lz -lm"
2385   fi
2386 fi
2387 AC_SUBST(LIBPNG)
2388
2389 ### Use -ltiff if available, unless `--with-tiff=no'.
2390 HAVE_TIFF=no
2391 LIBTIFF=
2392 if test "${HAVE_X11}" = "yes"; then
2393   if test "${with_tiff}" != "no"; then
2394     AC_CHECK_HEADER(tiffio.h,
2395       [tifflibs="-lz -lm"
2396       # At least one tiff package requires the jpeg library.
2397       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2398       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2399   fi
2400
2401   if test "${HAVE_TIFF}" = "yes"; then
2402     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2403     dnl FIXME -lz -lm, as per libpng?
2404     LIBTIFF=-ltiff
2405   fi
2406 fi
2407 AC_SUBST(LIBTIFF)
2408
2409 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2410 HAVE_GIF=no
2411 LIBGIF=
2412 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2413   AC_CHECK_HEADER(gif_lib.h,
2414 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2415 # Earlier versions can crash Emacs.
2416     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2417
2418   if test "$HAVE_GIF" = yes; then
2419     LIBGIF=-lgif
2420   elif test "$HAVE_GIF" = maybe; then
2421 # If gif_lib.h but no libgif, try libungif.
2422     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2423     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2424   fi
2425
2426   if test "${HAVE_GIF}" = "yes"; then
2427     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2428   fi
2429 fi
2430 AC_SUBST(LIBGIF)
2431
2432 dnl Check for required libraries.
2433 if test "${HAVE_X11}" = "yes"; then
2434   MISSING=""
2435   WITH_NO=""
2436   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2437     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2438   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2439     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2440   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2441     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2442   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2443     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2444   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2445     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2446
2447   if test "X${MISSING}" != X; then
2448     AC_MSG_ERROR([The following required libraries were not found:
2449     $MISSING
2450 Maybe some development libraries/packages are missing?
2451 If you don't want to link with them give
2452     $WITH_NO
2453 as options to configure])
2454   fi
2455 fi
2456
2457 ### Use -lgpm if available, unless `--with-gpm=no'.
2458 HAVE_GPM=no
2459 LIBGPM=
2460 MOUSE_SUPPORT=
2461 if test "${with_gpm}" != "no"; then
2462   AC_CHECK_HEADER(gpm.h,
2463     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2464
2465   if test "${HAVE_GPM}" = "yes"; then
2466     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2467     LIBGPM=-lgpm
2468     ## May be reset below.
2469     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2470   fi
2471 fi
2472 AC_SUBST(LIBGPM)
2473
2474 dnl Check for malloc/malloc.h on darwin
2475 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2476
2477 C_SWITCH_X_SYSTEM=
2478 ### Use NeXTstep API to implement GUI.
2479 if test "${HAVE_NS}" = "yes"; then
2480   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2481   if test "${NS_IMPL_COCOA}" = "yes"; then
2482     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2483     GNU_OBJC_CFLAGS=
2484   fi
2485   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2486     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2487     # See also .m.o rule in Makefile.in */
2488     # FIXME: are all these flags really needed?  Document here why.  */
2489     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2490     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2491   fi
2492   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2493     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2494   fi
2495   # We also have mouse menus.
2496   HAVE_MENUS=yes
2497   OTHER_FILES=ns-app
2498 fi
2499
2500
2501 ### Use session management (-lSM -lICE) if available
2502 HAVE_X_SM=no
2503 LIBXSM=
2504 if test "${HAVE_X11}" = "yes"; then
2505   AC_CHECK_HEADER(X11/SM/SMlib.h,
2506     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2507
2508   if test "${HAVE_X_SM}" = "yes"; then
2509     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2510     LIBXSM="-lSM -lICE"
2511     case "$LIBS" in
2512       *-lSM*) ;;
2513       *)      LIBS="$LIBXSM $LIBS" ;;
2514     esac
2515   fi
2516 fi
2517 AC_SUBST(LIBXSM)
2518
2519 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2520 AC_CACHE_CHECK(whether netdb declares h_errno,
2521                emacs_cv_netdb_declares_h_errno,
2522 [AC_TRY_LINK([#include <netdb.h>],
2523   [return h_errno;],
2524   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2525 if test $emacs_cv_netdb_declares_h_errno = yes; then
2526   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2527 fi
2528
2529 AC_FUNC_ALLOCA
2530
2531 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2532 dnl FIXME is there an autoconf test that does the right thing, without
2533 dnl needing to call A_M_E afterwards?
2534 if test x"$ac_cv_func_alloca_works" != xyes; then
2535    AC_MSG_ERROR( [a system implementation of alloca is required] )
2536 fi
2537
2538 # fmod, logb, and frexp are found in -lm on most systems.
2539 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2540 AC_CHECK_LIB(m, sqrt)
2541
2542 # Check for mail-locking functions in a "mail" library.  Probably this should
2543 # have the same check as for liblockfile below.
2544 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2545 if test $have_mail = yes; then
2546   LIBS_MAIL=-lmail
2547   LIBS="$LIBS_MAIL $LIBS"
2548   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2549 else
2550   LIBS_MAIL=
2551 fi
2552 dnl Debian, at least:
2553 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2554 if test $have_lockfile = yes; then
2555    LIBS_MAIL=-llockfile
2556    LIBS="$LIBS_MAIL $LIBS"
2557    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2558 else
2559 # If we have the shared liblockfile, assume we must use it for mail
2560 # locking (e.g. Debian).  If we couldn't link against liblockfile
2561 # (no liblockfile.a installed), ensure that we don't need to.
2562   dnl This works for files generally, not just executables.
2563   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2564   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2565                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2566   if test $ac_cv_prog_liblockfile = yes; then
2567     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2568 This probably means that movemail could lose mail.
2569 There may be a `development' package to install containing liblockfile.])
2570   fi
2571 fi
2572 AC_CHECK_FUNCS(touchlock)
2573 AC_CHECK_HEADERS(maillock.h)
2574 AC_SUBST(LIBS_MAIL)
2575
2576 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2577 ## interlock access to the mail spool.  The alternative is a lock file named
2578 ## /usr/spool/mail/$USER.lock.
2579 mail_lock=no
2580 case "$opsys" in
2581   aix4-2) mail_lock="lockf" ;;
2582
2583   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2584
2585   ## On GNU/Linux systems, both methods are used by various mail programs.
2586   ## I assume most people are using newer mailers that have heard of flock.
2587   ## Change this if you need to.
2588   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2589   ## configure gets the right answers, and that means *NOT* using flock.
2590   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2591   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2592   ## Debian maintainer hasn't provided a clean fix for Emacs.
2593   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2594   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2595   ## correct logic.  -- fx
2596   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2597   ## liblockfile is a Free Software replacement for libmail, used on
2598   ## Debian systems and elsewhere. -rfr.
2599   gnu-*)
2600     mail_lock="flock"
2601     if test $have_mail = yes || test $have_lockfile = yes; then
2602       test $ac_cv_header_maillock_h = yes && mail_lock=no
2603     fi
2604     ;;
2605 esac
2606
2607 BLESSMAIL_TARGET=
2608 case "$mail_lock" in
2609   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2610
2611   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2612
2613   *) BLESSMAIL_TARGET="need-blessmail" ;;
2614 esac
2615 AC_SUBST(BLESSMAIL_TARGET)
2616
2617
2618 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2619 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2620 random lrand48 logb frexp fmod rint cbrt ftime setsid \
2621 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2622 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2623 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2624 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2625 gai_strerror mkstemp getline getdelim mremap memmove fsync sync \
2626 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2627 cfmakeraw cfsetspeed isnan copysign)
2628
2629 AC_CHECK_HEADERS(sys/un.h)
2630
2631 AC_FUNC_MKTIME
2632 if test "$ac_cv_func_working_mktime" = no; then
2633   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2634 fi
2635
2636 AC_FUNC_GETLOADAVG
2637
2638 AC_FUNC_FSEEKO
2639
2640 # Configure getopt.
2641 m4_include([m4/getopt.m4])
2642 gl_GETOPT_IFELSE([
2643   gl_GETOPT_SUBSTITUTE_HEADER
2644   gl_PREREQ_GETOPT
2645   GETOPTOBJS='getopt.o getopt1.o'
2646 ])
2647 AC_SUBST(GETOPTOBJS)
2648
2649 AC_FUNC_GETPGRP
2650
2651 AC_FUNC_STRFTIME
2652
2653 # UNIX98 PTYs.
2654 AC_CHECK_FUNCS(grantpt)
2655
2656 # PTY-related GNU extensions.
2657 AC_CHECK_FUNCS(getpt)
2658
2659 # Check this now, so that we will NOT find the above functions in ncurses.
2660 # That is because we have not set up to link ncurses in lib-src.
2661 # It's better to believe a function is not available
2662 # than to expect to find it in ncurses.
2663 # Also we need tputs and friends to be able to build at all.
2664 have_tputs_et_al=true
2665 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2666 if test "$have_tputs_et_al" != true; then
2667   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2668 Maybe some development libraries/packages are missing?  Try installing
2669 libncurses-dev(el), libterminfo-dev(el) or similar.])
2670 fi
2671 # Must define this when any termcap library is found.
2672 AC_DEFINE(HAVE_LIBNCURSES, 1,
2673           [Define to 1 if you have the `ncurses' library (-lncurses).])
2674 ## FIXME This was the cpp logic, but I am not sure it is right.
2675 ## The above test has not necessarily found libncurses.
2676 HAVE_LIBNCURSES=yes
2677
2678 ## Use terminfo instead of termcap?
2679 ## Note only system files NOT using terminfo are:
2680 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2681 ## darwin|gnu without ncurses.
2682 TERMINFO=no
2683 LIBS_TERMCAP=
2684 case "$opsys" in
2685   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2686   ## hpux10-20: Use the system provided termcap(3) library.
2687   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2688   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2689   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2690
2691   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2692   ##  The ncurses library has been moved out of the System framework in
2693   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2694   ##  option to use it.
2695   darwin|gnu*)
2696     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2697     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2698       TERMINFO=yes
2699       LIBS_TERMCAP="-lncurses"
2700     fi
2701     ;;
2702
2703   freebsd)
2704     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2705     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2706     [AC_TRY_LINK([#include <osreldate.h>],
2707 [#if __FreeBSD_version < 400000
2708 fail;
2709 #endif
2710 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2711
2712     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2713
2714     if test $emacs_cv_freebsd_terminfo = yes; then
2715       TERMINFO=yes
2716       LIBS_TERMCAP="-lncurses"
2717     else
2718       LIBS_TERMCAP="-ltermcap"
2719     fi
2720     ;;
2721
2722   netbsd)
2723     if test $ac_cv_search_tputs = -lterminfo; then
2724       TERMINFO=yes
2725       LIBS_TERMCAP="-lterminfo"
2726     else
2727       LIBS_TERMCAP="-ltermcap"
2728     fi
2729     ;;
2730
2731 esac
2732
2733 case "$opsys" in
2734   ## hpux: Make sure we get select from libc rather than from libcurses
2735   ##  because libcurses on HPUX 10.10 has a broken version of select.
2736   ##  We used to use -lc -lcurses, but this may be cleaner.
2737   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2738
2739   openbsd) LIBS_TERMCAP="-lncurses" ;;
2740
2741   ## Must use system termcap, if we use any termcap.  It does special things.
2742   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2743 esac
2744
2745 TERMCAP_OBJ=tparam.o
2746 if test $TERMINFO = yes; then
2747   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2748
2749   ## Default used to be -ltermcap.  Add a case above if need something else.
2750   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2751
2752   TERMCAP_OBJ=terminfo.o
2753 fi
2754 AC_SUBST(LIBS_TERMCAP)
2755 AC_SUBST(TERMCAP_OBJ)
2756
2757
2758 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2759 resolv=no
2760 AC_TRY_LINK([#include <netinet/in.h>
2761 #include <arpa/nameser.h>
2762 #include <resolv.h>],
2763     [return res_init();],
2764     have_res_init=yes, have_res_init=no)
2765 if test "$have_res_init" = no; then
2766   OLIBS="$LIBS"
2767   LIBS="$LIBS -lresolv"
2768   AC_MSG_CHECKING(for res_init with -lresolv)
2769   AC_TRY_LINK([#include <netinet/in.h>
2770 #include <arpa/nameser.h>
2771 #include <resolv.h>],
2772     [return res_init();],
2773     have_res_init=yes, have_res_init=no)
2774   AC_MSG_RESULT($have_res_init)
2775   if test "$have_res_init" = yes ; then
2776     resolv=yes
2777   fi
2778   LIBS="$OLIBS"
2779 fi
2780
2781 if test "$have_res_init" = yes; then
2782   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2783 fi
2784
2785 # Do we need the Hesiod library to provide the support routines?
2786 LIBHESIOD=
2787 if test "$with_hesiod" != no ; then
2788   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2789   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2790      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2791                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2792   if test "$resolv" = yes ; then
2793     RESOLVLIB=-lresolv
2794   else
2795     RESOLVLIB=
2796   fi
2797   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2798         hesiod=yes, :, $RESOLVLIB)])
2799
2800   if test x"$hesiod" = xyes; then
2801     AC_DEFINE(HAVE_LIBHESIOD, 1,
2802               [Define to 1 if you have the hesiod library (-lhesiod).])
2803     LIBHESIOD=-lhesiod
2804   fi
2805 fi
2806 AC_SUBST(LIBHESIOD)
2807
2808 # Do we need libresolv (due to res_init or Hesiod)?
2809 if test "$resolv" = yes ; then
2810   AC_DEFINE(HAVE_LIBRESOLV, 1,
2811             [Define to 1 if you have the resolv library (-lresolv).])
2812   LIBRESOLV=-lresolv
2813 else
2814   LIBRESOLV=
2815 fi
2816 AC_SUBST(LIBRESOLV)
2817
2818 # These tell us which Kerberos-related libraries to use.
2819 COM_ERRLIB=
2820 CRYPTOLIB=
2821 KRB5LIB=
2822 DESLIB=
2823 KRB4LIB=
2824
2825 if test "${with_kerberos}" != no; then
2826   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2827   if test $have_com_err = yes; then
2828     COM_ERRLIB=-lcom_err
2829     LIBS="$COM_ERRLIB $LIBS"
2830     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2831   fi
2832   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2833   if test $have_crypto = yes; then
2834     CRYPTOLIB=-lcrypto
2835     LIBS="$CRYPTOLIB $LIBS"
2836     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2837   fi
2838   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2839   if test $have_k5crypto = yes; then
2840     CRYPTOLIB=-lk5crypto
2841     LIBS="$CRYPTOLIB $LIBS"
2842     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2843   fi
2844   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2845   if test $have_krb5=yes; then
2846     KRB5LIB=-lkrb5
2847     LIBS="$KRB5LIB $LIBS"
2848     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2849   fi
2850   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2851   if test "${with_kerberos5}" = no; then
2852     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2853     if test $have_des425 = yes; then
2854       DESLIB=-ldes425
2855       LIBS="$DESLIB $LIBS"
2856       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2857     else
2858       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2859       if test $have_des = yes; then
2860         DESLIB=-ldes
2861         LIBS="$DESLIB $LIBS"
2862         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2863       fi
2864     fi
2865     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2866     if test $have_krb4 = yes; then
2867       KRB4LIB=-lkrb4
2868       LIBS="$KRB4LIB $LIBS"
2869       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2870     else
2871       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2872       if test $have_krb = yes; then
2873         KRB4LIB=-lkrb
2874         LIBS="$KRB4LIB $LIBS"
2875         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2876       fi
2877     fi
2878   fi
2879
2880   if test "${with_kerberos5}" != no; then
2881     AC_CHECK_HEADERS(krb5.h,
2882       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2883                         [#include <krb5.h>])])
2884   else
2885     AC_CHECK_HEADERS(des.h,,
2886                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2887                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2888     AC_CHECK_HEADERS(krb.h,,
2889                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2890                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2891   fi
2892   AC_CHECK_HEADERS(com_err.h)
2893 fi
2894
2895 AC_SUBST(COM_ERRLIB)
2896 AC_SUBST(CRYPTOLIB)
2897 AC_SUBST(KRB5LIB)
2898 AC_SUBST(DESLIB)
2899 AC_SUBST(KRB4LIB)
2900
2901 # Solaris requires -lintl if you want strerror (which calls dgettext)
2902 # to return localized messages.
2903 AC_CHECK_LIB(intl, dgettext)
2904
2905 AC_MSG_CHECKING(whether localtime caches TZ)
2906 AC_CACHE_VAL(emacs_cv_localtime_cache,
2907 [if test x$ac_cv_func_tzset = xyes; then
2908 AC_TRY_RUN([#include <time.h>
2909 extern char **environ;
2910 unset_TZ ()
2911 {
2912   char **from, **to;
2913   for (to = from = environ; (*to = *from); from++)
2914     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2915       to++;
2916 }
2917 char TZ_GMT0[] = "TZ=GMT0";
2918 char TZ_PST8[] = "TZ=PST8";
2919 main()
2920 {
2921   time_t now = time ((time_t *) 0);
2922   int hour_GMT0, hour_unset;
2923   if (putenv (TZ_GMT0) != 0)
2924     exit (1);
2925   hour_GMT0 = localtime (&now)->tm_hour;
2926   unset_TZ ();
2927   hour_unset = localtime (&now)->tm_hour;
2928   if (putenv (TZ_PST8) != 0)
2929     exit (1);
2930   if (localtime (&now)->tm_hour == hour_GMT0)
2931     exit (1);
2932   unset_TZ ();
2933   if (localtime (&now)->tm_hour != hour_unset)
2934     exit (1);
2935   exit (0);
2936 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2937 [# If we have tzset, assume the worst when cross-compiling.
2938 emacs_cv_localtime_cache=yes])
2939 else
2940         # If we lack tzset, report that localtime does not cache TZ,
2941         # since we can't invalidate the cache if we don't have tzset.
2942         emacs_cv_localtime_cache=no
2943 fi])dnl
2944 AC_MSG_RESULT($emacs_cv_localtime_cache)
2945 if test $emacs_cv_localtime_cache = yes; then
2946   AC_DEFINE(LOCALTIME_CACHE, 1,
2947             [Define to 1 if localtime caches TZ.])
2948 fi
2949
2950 if test "x$HAVE_TIMEVAL" = xyes; then
2951   AC_CHECK_FUNCS(gettimeofday)
2952   if test $ac_cv_func_gettimeofday = yes; then
2953     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2954                    emacs_cv_gettimeofday_two_arguments,
2955     [AC_TRY_COMPILE([
2956 #ifdef TIME_WITH_SYS_TIME
2957 #include <sys/time.h>
2958 #include <time.h>
2959 #else
2960 #ifdef HAVE_SYS_TIME_H
2961 #include <sys/time.h>
2962 #else
2963 #include <time.h>
2964 #endif
2965 #endif],
2966       [struct timeval time;
2967        gettimeofday (&time, 0);],
2968       emacs_cv_gettimeofday_two_arguments=yes,
2969       emacs_cv_gettimeofday_two_arguments=no)])
2970     if test $emacs_cv_gettimeofday_two_arguments = no; then
2971       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2972                 [Define to 1 if gettimeofday accepts only one argument.])
2973     fi
2974   fi
2975 fi
2976
2977 ok_so_far=yes
2978 AC_CHECK_FUNC(socket, , ok_so_far=no)
2979 if test $ok_so_far = yes; then
2980   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2981 fi
2982 if test $ok_so_far = yes; then
2983   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2984 fi
2985 if test $ok_so_far = yes; then
2986 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2987   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2988             [Define to 1 if you have inet sockets.])
2989 fi
2990
2991 AC_CHECK_HEADERS(sys/ioctl.h)
2992
2993 if test -f /usr/lpp/X11/bin/smt.exp; then
2994   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2995             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2996 fi
2997
2998 AC_MSG_CHECKING(whether system supports dynamic ptys)
2999 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3000   AC_MSG_RESULT(yes)
3001   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3002 else
3003   AC_MSG_RESULT(no)
3004 fi
3005
3006 AC_FUNC_FORK
3007
3008 dnl Adapted from Haible's version.
3009 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3010   [AC_TRY_LINK([#include <langinfo.h>],
3011     [char* cs = nl_langinfo(CODESET);],
3012     emacs_cv_langinfo_codeset=yes,
3013     emacs_cv_langinfo_codeset=no)
3014   ])
3015 if test $emacs_cv_langinfo_codeset = yes; then
3016   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3017     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3018 fi
3019
3020 AC_CHECK_TYPES(size_t)
3021
3022 AC_TYPE_MBSTATE_T
3023
3024 dnl Restrict could probably be used effectively other than in regex.c.
3025 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3026   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3027                   emacs_cv_c_restrict=yes,
3028                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3029                                   emacs_cv_c_restrict=__restrict,
3030                                   emacs_cv_c_restrict=no)])])
3031 case "$emacs_cv_c_restrict" in
3032   yes) emacs_restrict=restrict;;
3033   no) emacs_restrict="";;
3034   *) emacs_restrict="$emacs_cv_c_restrict";;
3035 esac
3036 if test "$emacs_restrict" != __restrict; then
3037   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3038     [Define to compiler's equivalent of C99 restrict keyword.
3039      Don't define if equivalent is `__restrict'.])
3040 fi
3041
3042 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3043   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3044                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3045 if test "$emacs_cv_c_restrict_arr" = yes; then
3046   AC_DEFINE(__restrict_arr, __restrict,
3047     [Define to compiler's equivalent of C99 restrict keyword in array
3048      declarations.  Define as empty for no equivalent.])
3049 fi
3050
3051 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3052 dnl how the tty code is related to POSIX and/or other versions of termios.
3053 dnl The following looks like a useful start.
3054 dnl
3055 dnl AC_SYS_POSIX_TERMIOS
3056 dnl if test $ac_cv_sys_posix_termios = yes; then
3057 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3058 dnl                                and macros for terminal control.])
3059 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3060 dnl fi
3061
3062 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3063
3064 # Set up the CFLAGS for real compilation, so we can substitute it.
3065 CFLAGS="$REAL_CFLAGS"
3066 CPPFLAGS="$REAL_CPPFLAGS"
3067
3068 ## Hack to detect a buggy GCC version.
3069 if test "x$GCC" = xyes \
3070    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3071    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3072    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3073    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3074 fi
3075
3076 #### Find out which version of Emacs this is.
3077 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3078          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3079 if test x"${version}" = x; then
3080   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3081 fi
3082 if test x"${version}" != x"$PACKAGE_VERSION"; then
3083   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3084 fi
3085
3086 ### Specify what sort of things we'll be editing into Makefile and config.h.
3087 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3088 AC_SUBST(version)
3089 AC_SUBST(configuration)
3090 ## Unused?
3091 AC_SUBST(canonical)
3092 AC_SUBST(srcdir)
3093 AC_SUBST(prefix)
3094 AC_SUBST(exec_prefix)
3095 AC_SUBST(bindir)
3096 AC_SUBST(datadir)
3097 AC_SUBST(sharedstatedir)
3098 AC_SUBST(libexecdir)
3099 AC_SUBST(mandir)
3100 AC_SUBST(infodir)
3101 AC_SUBST(lispdir)
3102 AC_SUBST(locallisppath)
3103 AC_SUBST(lisppath)
3104 AC_SUBST(x_default_search_path)
3105 AC_SUBST(etcdir)
3106 AC_SUBST(archlibdir)
3107 AC_SUBST(docdir)
3108 AC_SUBST(bitmapdir)
3109 AC_SUBST(gamedir)
3110 AC_SUBST(gameuser)
3111 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3112 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3113 ## end of LIBX_BASE, but nothing ever set it.
3114 AC_SUBST(LD_SWITCH_X_SITE)
3115 AC_SUBST(C_SWITCH_X_SITE)
3116 AC_SUBST(C_SWITCH_X_SYSTEM)
3117 AC_SUBST(CFLAGS)
3118 ## Used in lwlib/Makefile.in.
3119 AC_SUBST(X_TOOLKIT_TYPE)
3120 AC_SUBST(machfile)
3121 AC_SUBST(opsysfile)
3122 AC_SUBST(GETLOADAVG_LIBS)
3123 AC_SUBST(ns_appdir)
3124 AC_SUBST(ns_appbindir)
3125 AC_SUBST(ns_appresdir)
3126 AC_SUBST(ns_appsrc)
3127 AC_SUBST(GNU_OBJC_CFLAGS)
3128 AC_SUBST(OTHER_FILES)
3129
3130 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3131                    [Define to the canonical Emacs configuration name.])
3132 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3133                    [Define to the options passed to configure.])
3134 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3135                    [Define to the used machine dependent file.])
3136 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3137                    [Define to the used os dependent file.])
3138
3139 XMENU_OBJ=
3140 XOBJ=
3141 FONT_OBJ=
3142 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3143   AC_DEFINE(HAVE_X_WINDOWS, 1,
3144             [Define to 1 if you want to use the X window system.])
3145   XMENU_OBJ=xmenu.o
3146   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3147   FONT_OBJ=xfont.o
3148   if test "$HAVE_XFT" = "yes"; then
3149     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3150   elif test "$HAVE_FREETYPE" = "yes"; then
3151     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3152   fi
3153   AC_SUBST(FONT_OBJ)
3154 fi
3155 AC_SUBST(XMENU_OBJ)
3156 AC_SUBST(XOBJ)
3157 AC_SUBST(FONT_OBJ)
3158
3159 WIDGET_OBJ=
3160 MOTIF_LIBW=
3161 if test "${USE_X_TOOLKIT}" != "none" ; then
3162   WIDGET_OBJ=widget.o
3163   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3164   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3165     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3166   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3167     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3168     MOTIF_LIBW=-lXm
3169     case "$opsys" in
3170       gnu-linux)
3171         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3172         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3173         ;;
3174
3175       unixware)
3176         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3177         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3178         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3179         ;;
3180
3181       aix4-2)
3182         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3183         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3184         ;;
3185     esac
3186     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3187   fi
3188 fi
3189 AC_SUBST(WIDGET_OBJ)
3190
3191 TOOLKIT_LIBW=
3192 case "$USE_X_TOOLKIT" in
3193   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3194   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3195   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3196 esac
3197 AC_SUBST(TOOLKIT_LIBW)
3198
3199 if test "$USE_X_TOOLKIT" = "none"; then
3200   LIBXT_OTHER="\$(LIBXSM)"
3201   OLDXMENU_TARGET="really-oldXMenu"
3202 else
3203   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3204   OLDXMENU_TARGET="really-lwlib"
3205 fi
3206 AC_SUBST(LIBXT_OTHER)
3207
3208 ## The X Menu stuff is present in the X10 distribution, but missing
3209 ## from X11.  If we have X10, just use the installed library;
3210 ## otherwise, use our own copy.
3211 if test "${HAVE_X11}" = "yes" ; then
3212   AC_DEFINE(HAVE_X11, 1,
3213             [Define to 1 if you want to use version 11 of X windows.
3214              Otherwise, Emacs expects to use version 10.])
3215
3216   if test "$USE_X_TOOLKIT" = "none"; then
3217     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3218   else
3219     OLDXMENU="\${lwlibdir}liblw.a"
3220   fi
3221   LIBXMENU="\$(OLDXMENU)"
3222   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3223   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3224 else
3225   ## For a syntactically valid Makefile; not actually used for anything.
3226   ## See comments in src/Makefile.in.
3227   OLDXMENU=nothing
3228   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3229   if test "${HAVE_X_WINDOWS}" = "yes"; then
3230     LIBXMENU="-lXMenu"
3231   else
3232     LIBXMENU=
3233   fi
3234   LIBX_OTHER=
3235   OLDXMENU_DEPS=
3236 fi
3237
3238 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3239   OLDXMENU_TARGET=
3240   OLDXMENU=nothing
3241   LIBXMENU=
3242   OLDXMENU_DEPS=
3243 fi
3244
3245 AC_SUBST(OLDXMENU_TARGET)
3246 AC_SUBST(OLDXMENU)
3247 AC_SUBST(LIBXMENU)
3248 AC_SUBST(LIBX_OTHER)
3249 AC_SUBST(OLDXMENU_DEPS)
3250
3251 if test "${HAVE_MENUS}" = "yes" ; then
3252   AC_DEFINE(HAVE_MENUS, 1,
3253             [Define to 1 if you have mouse menus.
3254              (This is automatic if you use X, but the option to specify it remains.)
3255              It is also defined with other window systems that support xmenu.c.])
3256 fi
3257
3258 if test "${GNU_MALLOC}" = "yes" ; then
3259   AC_DEFINE(GNU_MALLOC, 1,
3260             [Define to 1 if you want to use the GNU memory allocator.])
3261 fi
3262
3263 RALLOC_OBJ=
3264 if test "${REL_ALLOC}" = "yes" ; then
3265   AC_DEFINE(REL_ALLOC, 1,
3266             [Define REL_ALLOC if you want to use the relocating allocator for
3267              buffer space.])
3268
3269   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3270 fi
3271 AC_SUBST(RALLOC_OBJ)
3272
3273 if test "$opsys" = "cygwin"; then
3274   CYGWIN_OBJ="sheap.o"
3275   ## Cygwin differs because of its unexec().
3276   PRE_ALLOC_OBJ=
3277   POST_ALLOC_OBJ=lastfile.o
3278 else
3279   CYGWIN_OBJ=
3280   PRE_ALLOC_OBJ=lastfile.o
3281   POST_ALLOC_OBJ=
3282 fi
3283 AC_SUBST(CYGWIN_OBJ)
3284 AC_SUBST(PRE_ALLOC_OBJ)
3285 AC_SUBST(POST_ALLOC_OBJ)
3286
3287
3288 case "$opsys" in
3289   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3290
3291   darwin)
3292    ## The -headerpad option tells ld (see man page) to leave room at the
3293    ## end of the header for adding load commands.  Needed for dumping.
3294    ## 0x690 is the total size of 30 segment load commands (at 56
3295    ## each); under Cocoa 31 commands are required.
3296    if test "$HAVE_NS" = "yes"; then
3297      libs_nsgui="-framework AppKit"
3298      headerpad_extra=6C8
3299    else
3300      libs_nsgui=
3301      headerpad_extra=690
3302    fi
3303    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3304
3305    ## This is here because src/Makefile.in did some extra fiddling around
3306    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3307    ##   #ifndef LD_SWITCH_SYSTEM
3308    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3309    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3310    ## not using gcc, darwin system not on an alpha (ie darwin, since
3311    ## darwin + alpha does not occur).
3312    ## Because this was done in src/Makefile.in, the resulting part of
3313    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3314    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3315    ## rather than LD_SWITCH_SYSTEM.
3316    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3317      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3318    ;;
3319
3320   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3321   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3322   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3323   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3324   ## had different values in configure (in ac_link) and src/Makefile.in.
3325   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3326   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3327
3328   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3329 esac
3330
3331 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3332   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3333 fi
3334
3335 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3336
3337
3338 LINKER=
3339 ORDINARY_LINK=
3340 case "$opsys" in
3341   ## gnu: GNU needs its own crt0.
3342   aix4-2|darwin|gnu|usg5-4|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3343
3344   cygwin) LINKER="\$(CC)" ;;
3345
3346   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3347   ## library search parth, i.e. it won't search /usr/lib for libc and
3348   ## friends.  Using -nostartfiles instead avoids this problem, and
3349   ## will also work on earlier NetBSD releases.
3350   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3351
3352   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3353   ##   MkLinux/LinuxPPC needs this.
3354   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3355   gnu-*)
3356     case "$machine" in
3357       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3358     esac
3359     ;;
3360 esac
3361
3362
3363 PRE_EDIT_LDFLAGS=
3364 POST_EDIT_LDFLAGS=
3365 if test "x$ORDINARY_LINK" = "xyes"; then
3366
3367   LINKER="\$(CC)"
3368   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3369
3370 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3371 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3372 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3373
3374   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3375   ## places that are difficult to figure out at make time.  Fortunately,
3376   ## these same versions allow you to pass arbitrary flags on to the
3377   ## linker, so there is no reason not to use it as a linker.
3378   ##
3379   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3380   ## searching for libraries in its internal directories, so we have to
3381   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3382   LINKER="\$(CC) -nostdlib"
3383   ## GCC passes any argument prefixed with -Xlinker directly to the linker.
3384   ## See prefix-args.c for an explanation of why we do not do this with the
3385   ## shell''s ``for'' construct.  Note that sane people do not have '.' in
3386   ## their paths, so we must use ./prefix-args.
3387   ## TODO either make prefix-args check ORDINARY_LINK internally,
3388   ## or remove it altogether (bug#6184), removing the need for this hack.
3389   PRE_EDIT_LDFLAGS='`./prefix-args -Xlinker'
3390   POST_EDIT_LDFLAGS='`'
3391 fi
3392 AC_SUBST(PRE_EDIT_LDFLAGS)
3393 AC_SUBST(POST_EDIT_LDFLAGS)
3394
3395 test "x$LINKER" = "x" && LINKER=ld
3396 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3397 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3398
3399 AC_SUBST(LINKER)
3400
3401
3402 ## FIXME? The logic here is not precisely the same as that above.
3403 ## There is no check here for a pre-defined LINKER.
3404 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3405 LIB_GCC=
3406 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3407
3408   case "$opsys" in
3409     ## cygwin: don't link against static libgcc.
3410     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3411
3412     gnu-*)
3413       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3414       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3415       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3416       if test "$machine" = "arm"; then
3417         LIB_GCC="-lgcc_s"
3418       else
3419         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3420         ## immediately undefine it again and redefine it to empty.
3421         ## Was the C_SWITCH_X_SITE part really necessary?
3422 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3423         LIB_GCC=
3424       fi
3425       ;;
3426
3427     ## Ask GCC where to find libgcc.a.
3428     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3429   esac
3430 fi                              dnl if $GCC
3431 AC_SUBST(LIB_GCC)
3432
3433
3434 TOOLTIP_SUPPORT=
3435 WINDOW_SUPPORT=
3436 ## If we're using X11/GNUstep, define some consequences.
3437 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3438   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3439   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3440   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3441   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3442
3443   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3444   test "$HAVE_X_WINDOWS" = "yes" && \
3445     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3446
3447 fi
3448 AC_SUBST(MOUSE_SUPPORT)
3449 AC_SUBST(TOOLTIP_SUPPORT)
3450 AC_SUBST(WINDOW_SUPPORT)
3451
3452
3453 AH_TOP([/* GNU Emacs site configuration template file.
3454    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3455      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3456
3457 This file is part of GNU Emacs.
3458
3459 GNU Emacs is free software: you can redistribute it and/or modify
3460 it under the terms of the GNU General Public License as published by
3461 the Free Software Foundation, either version 3 of the License, or
3462 (at your option) any later version.
3463
3464 GNU Emacs is distributed in the hope that it will be useful,
3465 but WITHOUT ANY WARRANTY; without even the implied warranty of
3466 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3467 GNU General Public License for more details.
3468
3469 You should have received a copy of the GNU General Public License
3470 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3471
3472
3473 /* No code in Emacs #includes config.h twice, but some bits of code
3474    intended to work with other packages as well (like gmalloc.c)
3475    think they can include it as many times as they like.  */
3476 #ifndef EMACS_CONFIG_H
3477 #define EMACS_CONFIG_H
3478 ])dnl
3479
3480 AH_BOTTOM([
3481 /* Define AMPERSAND_FULL_NAME if you use the convention
3482    that & in the full name stands for the login id.  */
3483 /* Turned on June 1996 supposing nobody will mind it.  */
3484 #define AMPERSAND_FULL_NAME
3485
3486 /* If using GNU, then support inline function declarations.  */
3487 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3488    generally, because even if non-gcc compilers accept `inline', they
3489    may reject `extern inline'.  */
3490 #if defined (__GNUC__) && defined (OPTIMIZE)
3491 #define INLINE __inline__
3492 #else
3493 #define INLINE
3494 #endif
3495
3496 /* `subprocesses' should be defined if you want to
3497    have code for asynchronous subprocesses
3498    (as used in M-x compile and M-x shell).
3499    Only MSDOS does not support this (it overrides
3500    this in its config_opsysfile below).  */
3501
3502 #define subprocesses
3503
3504 /* Include the os and machine dependent files.  */
3505 #include config_opsysfile
3506 #include config_machfile
3507
3508 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3509   (There is probably a better place to do this, but right now the Cocoa
3510    side does this in s/darwin.h and we cannot
3511    parallel this exactly since GNUstep is multi-OS.  */
3512 #ifdef HAVE_NS
3513 # ifdef NS_IMPL_GNUSTEP
3514 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3515 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3516 #  define SYSTEM_PURESIZE_EXTRA 30000
3517 # endif /* NS_IMPL_GNUSTEP */
3518 #endif /* HAVE_NS */
3519
3520 /* SIGTYPE is the macro we actually use.  */
3521 #ifndef SIGTYPE
3522 #define SIGTYPE RETSIGTYPE
3523 #endif
3524
3525 #ifdef emacs /* Don't do this for lib-src.  */
3526 /* Tell regex.c to use a type compatible with Emacs.  */
3527 #define RE_TRANSLATE_TYPE Lisp_Object
3528 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3529 #ifdef make_number
3530 /* If make_number is a macro, use it.  */
3531 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3532 #else
3533 /* If make_number is a function, avoid it.  */
3534 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3535 #endif
3536 #endif
3537
3538 /* Avoid link-time collision with system mktime if we will use our own.  */
3539 #if ! HAVE_MKTIME || BROKEN_MKTIME
3540 #define mktime emacs_mktime
3541 #endif
3542
3543 #define my_strftime nstrftime   /* for strftime.c */
3544
3545 /* These default definitions are good for almost all machines.
3546    The exceptions override them in m/MACHINE.h.  */
3547
3548 #ifndef BITS_PER_CHAR
3549 #define BITS_PER_CHAR 8
3550 #endif
3551
3552 #ifndef BITS_PER_SHORT
3553 #define BITS_PER_SHORT 16
3554 #endif
3555
3556 /* Note that lisp.h uses this in a preprocessor conditional, so it
3557    would not work to use sizeof.  That being so, we do all of them
3558    without sizeof, for uniformity's sake.  */
3559 #ifndef BITS_PER_INT
3560 #define BITS_PER_INT 32
3561 #endif
3562
3563 #ifndef BITS_PER_LONG
3564 #ifdef _LP64
3565 #define BITS_PER_LONG 64
3566 #else
3567 #define BITS_PER_LONG 32
3568 #endif
3569 #endif
3570
3571 /* Define if the compiler supports function prototypes.  It may do so but
3572    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3573 #undef PROTOTYPES
3574
3575 #ifdef HAVE_STRING_H
3576 #include <string.h>
3577 #endif
3578
3579 #ifdef HAVE_STDLIB_H
3580 #include <stdlib.h>
3581 #endif
3582
3583 #ifdef HAVE_ALLOCA_H
3584 # include <alloca.h>
3585 #elif defined __GNUC__
3586 # define alloca __builtin_alloca
3587 #elif defined _AIX
3588 # define alloca __alloca
3589 #else
3590 # include <stddef.h>
3591 # ifdef  __cplusplus
3592 extern "C"
3593 # endif
3594 void *alloca (size_t);
3595 #endif
3596
3597 #ifndef HAVE_SIZE_T
3598 typedef unsigned size_t;
3599 #endif
3600
3601 #if defined __GNUC__ && (__GNUC__ > 2 \
3602                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3603 #define NO_RETURN       __attribute__ ((__noreturn__))
3604 #else
3605 #define NO_RETURN       /* nothing */
3606 #endif
3607
3608 /* These won't be used automatically yet.  We also need to know, at least,
3609    that the stack is continuous.  */
3610 #ifdef __GNUC__
3611 #  ifndef GC_SETJMP_WORKS
3612   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3613 #    define GC_SETJMP_WORKS 1
3614 #  endif
3615 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3616 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3617 #  endif
3618 #endif
3619
3620 #endif /* EMACS_CONFIG_H */
3621
3622 /*
3623 Local Variables:
3624 mode: c
3625 End:
3626 */
3627 ])dnl
3628
3629 #### Report on what we decided to do.
3630 #### Report GTK as a toolkit, even if it doesn't use Xt.
3631 #### It makes printing result more understandable as using GTK sets
3632 #### toolkit_scroll_bars to yes by default.
3633 if test "${HAVE_GTK}" = "yes"; then
3634   USE_X_TOOLKIT=GTK
3635 fi
3636
3637 echo "
3638 Configured for \`${canonical}'.
3639
3640   Where should the build process find the source code?    ${srcdir}
3641   What operating system and machine description files should Emacs use?
3642         \`${opsysfile}' and \`${machfile}'
3643   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3644   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3645   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3646   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3647   What window system should Emacs use?                    ${window_system}
3648   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3649
3650 if test -n "${x_includes}"; then
3651 echo "  Where do we find X Windows header files?                ${x_includes}"
3652 else
3653 echo "  Where do we find X Windows header files?                Standard dirs"
3654 fi
3655 if test -n "${x_libraries}"; then
3656 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3657 else
3658 echo "  Where do we find X Windows libraries?                   Standard dirs"
3659 fi
3660
3661 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3662 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3663 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3664 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3665 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3666 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3667 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3668 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3669 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3670 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3671 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3672
3673 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3674 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3675 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3676 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3677
3678 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3679 echo
3680
3681 if test $USE_XASSERTS = yes; then
3682    echo "  Compiling with asserts turned on."
3683    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3684 fi
3685
3686 echo
3687
3688 if test "$HAVE_NS" = "yes"; then
3689    echo
3690    echo "You must run \"make install\" in order to test the built application.
3691 The installed application will go to nextstep/Emacs.app and can be
3692 run or moved from there."
3693    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3694       echo "The application will be fully self-contained."
3695     else
3696       echo "The lisp resources for the application will be installed under ${prefix}.
3697 You may need to run \"make install\" with sudo.  The application will fail
3698 to run if these resources are not installed."
3699    fi
3700    echo
3701 fi
3702
3703 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3704   echo "D-Bus integration has been tested for GNU/Linux only."
3705   echo
3706 fi
3707
3708
3709 # Remove any trailing slashes in these variables.
3710 [test "${prefix}" != NONE &&
3711   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3712 test "${exec_prefix}" != NONE &&
3713   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3714
3715 dnl You might wonder (I did) why epaths.h is generated by running make,
3716 dnl rather than just letting configure generate it from epaths.in.
3717 dnl One reason is that the various paths are not fully expanded (see above);
3718 dnl eg gamedir=${prefix}/var/games/emacs.
3719 dnl Secondly, the GNU Coding standards require that one should be able
3720 dnl to run `make prefix=/some/where/else' and override the values set
3721 dnl by configure.  This also explains the `move-if-change' test and
3722 dnl the use of force in the `epaths-force' rule in Makefile.in.
3723 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3724         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3725         doc/lispref/Makefile src/Makefile \
3726         lwlib/Makefile lisp/Makefile leim/Makefile, [
3727
3728 ### Make the necessary directories, if they don't exist.
3729 for dir in etc lisp ; do
3730   test -d ${dir} || mkdir ${dir}
3731 done
3732
3733 echo creating src/epaths.h
3734 ${MAKE-make} epaths-force
3735
3736 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3737   echo creating src/.gdbinit
3738   echo source $srcdir/src/.gdbinit > src/.gdbinit
3739 fi
3740
3741 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3742
3743 m4_if(dnl       Do not change this comment
3744    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3745 )dnl