code.delx.au - gnu-emacs/blob - lisp/mail/pmailedit.el

   1 ;;; pmailedit.el --- "PMAIL edit mode"  Edit the current message
   2
   3 ;; Copyright (C) 1985, 1994, 2001, 2002, 2003, 2004, 2005, 2006,
   4 ;;   2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: mail
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;;; Code:
  27
  28 (eval-when-compile
  29   (require 'pmail)
  30   (require 'pmailsum))
  31
  32 (defcustom pmail-edit-mode-hook nil
  33   "List of functions to call when editing an PMAIL message."
  34   :type 'hook
  35   :version "21.1"
  36   :group 'pmail-edit)
  37
  38 (defvar pmail-old-text)
  39
  40 (defvar pmail-edit-map nil)
  41 (if pmail-edit-map
  42     nil
  43   ;; Make a keymap that inherits text-mode-map.
  44   (setq pmail-edit-map (make-sparse-keymap))
  45   (set-keymap-parent pmail-edit-map text-mode-map)
  46   (define-key pmail-edit-map "\C-c\C-c" 'pmail-cease-edit)
  47   (define-key pmail-edit-map "\C-c\C-]" 'pmail-abort-edit))
  48
  49 ;; Pmail Edit mode is suitable only for specially formatted data.
  50 (put 'pmail-edit-mode 'mode-class 'special)
  51
  52 (declare-function pmail-summary-disable "" ())
  53 (declare-function pmail-summary-enable "pmailsum" ())
  54
  55 (defun pmail-edit-mode ()
  56   "Major mode for editing the contents of an PMAIL message.
  57 The editing commands are the same as in Text mode, together with two commands
  58 to return to regular PMAIL:
  59   *  \\[pmail-abort-edit] cancels the changes
  60      you have made and returns to PMAIL
  61   *  \\[pmail-cease-edit] makes them permanent.
  62 This functions runs the normal hook `pmail-edit-mode-hook'.
  63 \\{pmail-edit-map}"
  64   (delay-mode-hooks (text-mode))
  65   (use-local-map pmail-edit-map)
  66   (setq major-mode 'pmail-edit-mode)
  67   (setq mode-name "PMAIL Edit")
  68   (if (boundp 'mode-line-modified)
  69       (setq mode-line-modified (default-value 'mode-line-modified))
  70     (setq mode-line-format (default-value 'mode-line-format)))
  71   (if (pmail-summary-exists)
  72       (save-excursion
  73         (set-buffer pmail-summary-buffer)
  74         (pmail-summary-disable)))
  75   (run-mode-hooks 'pmail-edit-mode-hook))
  76
  77 (defvar pmail-old-pruned nil)
  78 (put 'pmail-old-pruned 'permanent-local t)
  79
  80 (defvar pmail-edit-saved-coding-system nil)
  81 (put 'pmail-edit-saved-coding-system 'permanent-local t)
  82
  83 ;;;###autoload
  84 (defun pmail-edit-current-message ()
  85   "Edit the contents of this message."
  86   (interactive)
  87   (if (= pmail-total-messages 0)
  88       (error "No messages in this file"))
  89   (make-local-variable 'pmail-old-pruned)
  90   (setq pmail-old-pruned (eq pmail-header-style 'normal))
  91   (make-local-variable 'pmail-edit-saved-coding-system)
  92   (setq pmail-edit-saved-coding-system save-buffer-coding-system)
  93   (pmail-edit-mode)
  94   ;; As the local value of save-buffer-coding-system is deleted by
  95   ;; pmail-edit-mode, we restore the original value.
  96   (make-local-variable 'save-buffer-coding-system)
  97   (setq save-buffer-coding-system pmail-edit-saved-coding-system)
  98   (make-local-variable 'pmail-old-text)
  99   (setq pmail-old-text (buffer-substring (point-min) (point-max)))
 100   (setq buffer-read-only nil)
 101   (force-mode-line-update)
 102   (if (and (eq (key-binding "\C-c\C-c") 'pmail-cease-edit)
 103            (eq (key-binding "\C-c\C-]") 'pmail-abort-edit))
 104       (message "Editing: Type C-c C-c to return to Pmail, C-c C-] to abort")
 105     (message "%s" (substitute-command-keys
 106                    "Editing: Type \\[pmail-cease-edit] to return to Pmail, \\[pmail-abort-edit] to abort"))))
 107
 108 (defun pmail-cease-edit ()
 109   "Finish editing message; switch back to Pmail proper."
 110   (interactive)
 111   (if (pmail-summary-exists)
 112       (save-excursion
 113         (set-buffer pmail-summary-buffer)
 114         (pmail-summary-enable)))
 115   ;; Make sure buffer ends with a blank line.
 116   (save-excursion
 117     (goto-char (point-max))
 118     (if (/= (preceding-char) ?\n)
 119         (insert "\n"))
 120     (unless (looking-back "\n\n")
 121       (insert "\n"))
 122     ;; Adjust the marker that points to the end of this message.
 123     (set-marker (aref pmail-message-vector (1+ pmail-current-message))
 124                 (point)))
 125   (let ((old pmail-old-text))
 126     (force-mode-line-update)
 127     (kill-all-local-variables)
 128     (pmail-mode-1)
 129     (if (boundp 'tool-bar-map)
 130         (set (make-local-variable 'tool-bar-map) pmail-tool-bar-map))
 131     (pmail-variables)
 132     ;; As the local value of save-buffer-coding-system is changed by
 133     ;; pmail-variables, we restore the original value.
 134     (setq save-buffer-coding-system pmail-edit-saved-coding-system)
 135     (unless (and (= (length old) (- (point-max) (point-min)))
 136                  (string= old (buffer-substring (point-min) (point-max))))
 137       (setq old nil)
 138       (pmail-set-attribute pmail-edited-attr-index t)
 139       (if (boundp 'pmail-summary-vector)
 140           (progn
 141             (aset pmail-summary-vector (1- pmail-current-message) nil)
 142             (save-excursion
 143               (pmail-widen-to-current-msgbeg
 144                 (function (lambda ()
 145                             (forward-line 2)
 146                             (if (looking-at "Summary-line: ")
 147                                 (let ((buffer-read-only nil))
 148                                   (delete-region (point)
 149                                                  (progn (forward-line 1)
 150                                                         (point))))))))))))
 151     (save-excursion
 152       (pmail-show-message)
 153       (pmail-toggle-header (if pmail-old-pruned 1 0))))
 154   (run-hooks 'pmail-mode-hook))
 155
 156 (defun pmail-abort-edit ()
 157   "Abort edit of current message; restore original contents."
 158   (interactive)
 159   (delete-region (point-min) (point-max))
 160   (insert pmail-old-text)
 161   (pmail-cease-edit)
 162   (pmail-highlight-headers))
 163
 164 (provide 'pmailedit)
 165
 166 ;; Local Variables:
 167 ;; change-log-default-name: "ChangeLog.pmail"
 168 ;; End:
 169
 170 ;; arch-tag: 9524f335-12cc-4e95-9e9b-3208dc30550b
 171 ;;; pmailedit.el ends here