code.delx.au - gnu-emacs/blob - lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Introduction:
  30 ;;
  31 ;; Whenever a file that Emacs is editing has been changed by another
  32 ;; program the user normally has to execute the command `revert-buffer'
  33 ;; to load the new content of the file into Emacs.
  34 ;;
  35 ;; This package contains two minor modes: Global Auto-Revert Mode and
  36 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  37 ;; whenever the corresponding files have been changed on disk.
  38 ;;
  39 ;; Auto-Revert Mode can be activated for individual buffers.
  40 ;; Global Auto-Revert Mode applies to all file buffers.
  41 ;;
  42 ;; Both modes operate by checking the time stamp of all files at
  43 ;; intervals of `auto-revert-interval'.  The default is every five
  44 ;; seconds.  The check is aborted whenever the user actually uses
  45 ;; Emacs.  You should never even notice that this package is active
  46 ;; (except that your buffers will be reverted, of course).
  47
  48 ;; Usage:
  49 ;;
  50 ;; Go to the appropriate buffer and press:
  51 ;;   M-x auto-revert-mode RET
  52 ;;
  53 ;; To activate Global Auto-Revert Mode, press:
  54 ;;   M-x global-auto-revert-mode RET
  55 ;;
  56 ;; To activate Global Auto-Revert Mode every time Emacs is started
  57 ;; customise the option `global-auto-revert-mode' or the following
  58 ;; line could be added to your ~/.emacs:
  59 ;;   (global-auto-revert-mode 1)
  60 ;;
  61 ;; The function `turn-on-auto-revert-mode' could be added to any major
  62 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  63 ;; mode.  For example, the following line will activate Auto-Revert
  64 ;; Mode in all C mode buffers:
  65 ;;
  66 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  67
  68 ;;; Code:
  69
  70 ;; Dependencies:
  71
  72 (require 'timer)
  73 (autoload 'dired-get-filename "dired")
  74 (autoload 'vc-workfile-version "vc-hooks")
  75 (autoload 'vc-mode-line        "vc-hooks")
  76
  77 (eval-when-compile
  78   (defvar dired-directory)
  79   (defvar vc-mode)
  80   (require 'cl))
  81
  82
  83 ;; Custom Group:
  84 ;;
  85 ;; The two modes will be placed next to Auto Save Mode under the
  86 ;; Files group under Emacs.
  87
  88 (defgroup auto-revert nil
  89   "Revert individual buffers when files on disk change.
  90
  91 Auto-Revert Mode can be activated for individual buffer.
  92 Global Auto-Revert Mode applies to all buffers."
  93   :group 'files
  94   :group 'convenience)
  95
  96
  97 ;; Variables:
  98
  99 ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
 100 ;;;###autoload
 101 (defvar auto-revert-mode nil
 102   "*Non-nil when Auto-Revert Mode is active.
 103 Never set this variable directly, use the command `auto-revert-mode' instead.")
 104 (put 'auto-revert-mode 'permanent-local t)
 105
 106 (defvar auto-revert-timer nil
 107   "Timer used by Auto-Revert Mode.")
 108
 109 (defcustom auto-revert-interval 5
 110   "Time, in seconds, between Auto-Revert Mode file checks.
 111 The value may be an integer or floating point number.
 112
 113 If a timer is already active, there are two ways to make sure
 114 that the new value will take effect immediately.  You can set
 115 this variable through Custom or you can call the command
 116 `auto-revert-set-timer' after setting the variable.  Otherwise,
 117 the new value will take effect the first time Auto Revert Mode
 118 calls `auto-revert-set-timer' for internal reasons or in your
 119 next editing session."
 120   :group 'auto-revert
 121   :type 'number
 122   :set (lambda (variable value)
 123          (set-default variable value)
 124          (and (boundp 'auto-revert-timer)
 125               auto-revert-timer
 126               (auto-revert-set-timer))))
 127
 128 (defcustom auto-revert-stop-on-user-input t
 129   "When non-nil Auto-Revert Mode stops checking files on user input."
 130   :group 'auto-revert
 131   :type 'boolean)
 132
 133 (defcustom auto-revert-verbose t
 134   "When nil, Auto-Revert Mode will not generate any messages.
 135 When non-nil, a message is generated whenever a file is reverted."
 136   :group 'auto-revert
 137   :type 'boolean)
 138
 139 (defcustom auto-revert-mode-text " ARev"
 140   "String to display in the mode line when Auto-Revert Mode is active.
 141
 142 \(When the string is not empty, make sure that it has a leading space.)"
 143   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 144   :group 'auto-revert
 145   :type 'string)
 146
 147 (defcustom auto-revert-mode-hook nil
 148   "Functions to run when Auto-Revert Mode is activated."
 149   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 150   :group 'auto-revert
 151   :type 'hook)
 152
 153 (defcustom global-auto-revert-mode-text ""
 154   "String to display when Global Auto-Revert Mode is active.
 155
 156 The default is nothing since when this mode is active this text doesn't
 157 vary over time, or between buffers.  Hence mode line text
 158 would only waste precious space."
 159   :group 'auto-revert
 160   :type 'string)
 161
 162 (defcustom global-auto-revert-mode-hook nil
 163   "Hook called when Global Auto-Revert Mode is activated."
 164   :group 'auto-revert
 165   :type 'hook)
 166
 167 (defcustom global-auto-revert-non-file-buffers nil
 168   "When nil only file buffers are reverted by Global Auto-Revert Mode.
 169
 170 When non-nil, both file buffers and buffers with a custom
 171 `revert-buffer-function' and a `buffer-stale-function' are
 172 reverted by Global Auto-Revert Mode.
 173
 174 Use this option with care since it could lead to excessive reverts.
 175 Note also that for some non-file buffers the check whether the
 176 buffer needs updating may be imperfect, due to efficiency
 177 considerations, and may not take all information listed in the
 178 buffer into account.  Hence, a non-nil value for this option does
 179 not necessarily make manual updates useless for non-file buffers."
 180   :group 'auto-revert
 181   :type 'boolean)
 182
 183 (defcustom global-auto-revert-ignore-modes '()
 184   "List of major modes Global Auto-Revert Mode should not check."
 185   :group 'auto-revert
 186   :type '(repeat sexp))
 187
 188 (defcustom auto-revert-load-hook nil
 189   "Functions to run when Auto-Revert Mode is first loaded."
 190   :tag "Load Hook"
 191   :group 'auto-revert
 192   :type 'hook)
 193
 194 (defvar global-auto-revert-ignore-buffer nil
 195   "*When non-nil, Global Auto-Revert Mode will not revert this buffer.
 196
 197 This variable becomes buffer local when set in any fashion.")
 198 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 199
 200 ;; Internal variables:
 201
 202 (defvar auto-revert-buffer-list '()
 203   "List of buffers in Auto-Revert Mode.
 204
 205 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 206 buffers to this list.
 207
 208 The timer function `auto-revert-buffers' is responsible for purging
 209 the list of old buffers.")
 210
 211 (defvar auto-revert-remaining-buffers '()
 212   "Buffers not checked when user input stopped execution.")
 213
 214
 215 ;; Functions:
 216
 217 ;;;###autoload
 218 (define-minor-mode auto-revert-mode
 219   "Toggle reverting buffer when file on disk changes.
 220
 221 With arg, turn Auto Revert mode on if and only if arg is positive.
 222 This is a minor mode that affects only the current buffer.
 223 Use `global-auto-revert-mode' to automatically revert all buffers."
 224   nil auto-revert-mode-text nil
 225   (if auto-revert-mode
 226       (if (not (memq (current-buffer) auto-revert-buffer-list))
 227           (push (current-buffer) auto-revert-buffer-list))
 228     (setq auto-revert-buffer-list
 229           (delq (current-buffer) auto-revert-buffer-list)))
 230   (auto-revert-set-timer)
 231   (when auto-revert-mode
 232     (auto-revert-buffers)))
 233
 234
 235 ;;;###autoload
 236 (defun turn-on-auto-revert-mode ()
 237   "Turn on Auto-Revert Mode.
 238
 239 This function is designed to be added to hooks, for example:
 240   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 241   (auto-revert-mode 1))
 242
 243
 244 ;;;###autoload
 245 (define-minor-mode global-auto-revert-mode
 246   "Revert any buffer when file on disk changes.
 247
 248 With arg, turn Auto Revert mode on globally if and only if arg is positive.
 249 This is a minor mode that affects all buffers.
 250 Use `auto-revert-mode' to revert a particular buffer."
 251   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 252   (auto-revert-set-timer)
 253   (when global-auto-revert-mode
 254     (auto-revert-buffers)))
 255
 256
 257 (defun auto-revert-set-timer ()
 258   "Restart or cancel the timer used by Auto-Revert Mode.
 259 If such a timer is active, cancel it.  Start a new timer if
 260 Global Auto-Revert Mode is active or if Auto-Revert Mode is active
 261 in some buffer.  Restarting the timer ensures that Auto-Revert Mode
 262 will use an up-to-date value of `auto-revert-interval'"
 263   (interactive)
 264   (if (timerp auto-revert-timer)
 265       (cancel-timer auto-revert-timer))
 266   (setq auto-revert-timer
 267         (if (or global-auto-revert-mode auto-revert-buffer-list)
 268             (run-with-timer auto-revert-interval
 269                             auto-revert-interval
 270                             'auto-revert-buffers)
 271           nil)))
 272
 273 (defun auto-revert-active-p ()
 274   "Check if auto-revert is active (in current buffer or globally)."
 275   (or auto-revert-mode
 276       (and
 277        global-auto-revert-mode
 278        (not global-auto-revert-ignore-buffer)
 279        (not (memq major-mode
 280                   global-auto-revert-ignore-modes)))))
 281
 282 (defun auto-revert-vc-cvs-file-version (file)
 283   "Get version of FILE by reading control file on disk."
 284   (let* ((control "CVS/Entries")
 285          (name    (file-name-nondirectory file))
 286          (path    (format "%s/%s"
 287                           (file-name-directory file)
 288                           control)))
 289     (when (file-exists-p path)
 290       (with-temp-buffer
 291         (insert-file-contents-literally path)
 292         (goto-char (point-min))
 293         (when (re-search-forward
 294                ;; /file.txt/1.3/Mon Sep 15 18:43:20 2003//
 295                (format "%s/\\([.0-9]+\\)" (regexp-quote name))
 296                nil t)
 297           (match-string 1))))))
 298
 299 (defun auto-revert-vc-buffer-p ()
 300   "Check if buffer is version controlled."
 301   (and (boundp 'vc-mode)
 302        (string-match "[0-9]" (or vc-mode ""))))
 303
 304 (defun auto-revert-handler-vc ()
 305   "Check if version controlled buffer needs revert."
 306   ;; [Emacs 1]
 307   ;; 1. File is saved     (*)
 308   ;; 2. checkin is done 1.1 -> 1.2
 309   ;; 3. VC reverts, so that updated version number is shown in mode line
 310   ;;
 311   ;; Suppose the same file has been opened in another Emacs and
 312   ;; autorevert.el is on.
 313   ;;
 314   ;; [Emacs 2]
 315   ;; 1. Step (1) is detected and buffer is reverted.
 316   ;; 2. But check in does not always change the file in dis, but possibly only
 317   ;;    control files like CVS/Entries
 318   ;; 3. The buffer is not reverted to update VC version line.
 319   ;;    Incorrect version number 1.1 is shown in this Emacs
 320   ;;
 321   (when (featurep 'vc)
 322     (let* ((file           (buffer-file-name))
 323            (backend        (vc-backend (buffer-file-name)))
 324            (version-buffer (vc-workfile-version file)))
 325       (when (stringp version-buffer)
 326         (cond
 327          ((eq backend 'CVS)
 328           (let ((version-file
 329                  (auto-revert-vc-cvs-file-version (buffer-file-name))))
 330             (and (stringp version-file)
 331                  (not (string-match version-file version-buffer)))))
 332          ((eq backend 'RCS)
 333           ;; TODO:
 334           ))))))
 335
 336 (defun auto-revert-handler ()
 337   "Revert current buffer, if appropriate.
 338 This is an internal function used by Auto-Revert Mode."
 339   (unless (buffer-modified-p)
 340     (let (revert)
 341       (cond
 342        ((auto-revert-vc-buffer-p)
 343         (when (auto-revert-handler-vc)
 344           (setq revert 'vc)))
 345        ((or (and (buffer-file-name)
 346                  (file-readable-p (buffer-file-name))
 347                  (not (verify-visited-file-modtime (current-buffer))))
 348             (and (or auto-revert-mode global-auto-revert-non-file-buffers)
 349                  revert-buffer-function
 350                  (boundp 'buffer-stale-function)
 351                  (functionp buffer-stale-function)
 352                  (funcall buffer-stale-function t)))
 353         (setq revert t)))
 354       (when revert
 355         (when auto-revert-verbose
 356           (message "Reverting buffer `%s'." (buffer-name)))
 357         (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)
 358         ;; `preserve-modes' avoids changing the (minor) modes.  But we
 359         ;; do want to reset the mode for VC, so we do it explicitly.
 360         (vc-find-file-hook)
 361         (if (eq revert 'vc)
 362             (vc-mode-line buffer-file-name))))))
 363
 364 (defun auto-revert-buffers ()
 365   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 366
 367 Should `global-auto-revert-mode' be active all file buffers are checked.
 368
 369 Should `auto-revert-mode' be active in some buffers, those buffers
 370 are checked.
 371
 372 Non-file buffers that have a custom `revert-buffer-function' and
 373 a `buffer-stale-function' are reverted either when Auto-Revert
 374 Mode is active in that buffer, or when the variable
 375 `global-auto-revert-non-file-buffers' is non-nil and Global
 376 Auto-Revert Mode is active.
 377
 378 This function stops whenever there is user input.  The buffers not
 379 checked are stored in the variable `auto-revert-remaining-buffers'.
 380
 381 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 382 are checked first the next time this function is called.
 383
 384 This function is also responsible for removing buffers no longer in
 385 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 386 the timer when no buffers need to be checked."
 387   (let ((bufs (if global-auto-revert-mode
 388                   (buffer-list)
 389                 auto-revert-buffer-list))
 390         (remaining '())
 391         (new '()))
 392     ;; Partition `bufs' into two halves depending on whether or not
 393     ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 394     ;; halves are then re-joined with the "remaining" buffers at the
 395     ;; head of the list.
 396     (dolist (buf auto-revert-remaining-buffers)
 397       (if (memq buf bufs)
 398           (push buf remaining)))
 399     (dolist (buf bufs)
 400       (if (not (memq buf remaining))
 401           (push buf new)))
 402     (setq bufs (nreverse (nconc new remaining)))
 403     (while (and bufs
 404                 (not (and auto-revert-stop-on-user-input
 405                           (input-pending-p))))
 406       (let ((buf (car bufs)))
 407         (if (buffer-name buf)           ; Buffer still alive?
 408             (with-current-buffer buf
 409               ;; Test if someone has turned off Auto-Revert Mode in a
 410               ;; non-standard way, for example by changing major mode.
 411               (if (and (not auto-revert-mode)
 412                        (memq buf auto-revert-buffer-list))
 413                   (setq auto-revert-buffer-list
 414                         (delq buf auto-revert-buffer-list)))
 415               (when (auto-revert-active-p) (auto-revert-handler)))
 416           ;; Remove dead buffer from `auto-revert-buffer-list'.
 417           (setq auto-revert-buffer-list
 418                 (delq buf auto-revert-buffer-list))))
 419       (setq bufs (cdr bufs)))
 420     (setq auto-revert-remaining-buffers bufs)
 421     ;; Check if we should cancel the timer.
 422     (when (and (not global-auto-revert-mode)
 423                (null auto-revert-buffer-list))
 424       (cancel-timer auto-revert-timer)
 425       (setq auto-revert-timer nil))))
 426
 427
 428 ;; The end:
 429 (provide 'autorevert)
 430
 431 (run-hooks 'auto-revert-load-hook)
 432
 433 ;;; arch-tag: f6bcb07b-4841-477e-9e44-b18678e58876
 434 ;;; autorevert.el ends here