code.delx.au - gnu-emacs/blob - lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs
   2
   3 ;; Copyright (C) 1985, 86, 87, 92, 94, 96, 1997, 2000, 2001, 2002
   4 ;;  Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package supplies the string and regular-expression replace functions
  28 ;; documented in the Emacs user's manual.
  29
  30 ;;; Code:
  31
  32 (defcustom case-replace t
  33   "*Non-nil means `query-replace' should preserve case in replacements."
  34   :type 'boolean
  35   :group 'matching)
  36
  37 (defvar query-replace-history nil)
  38
  39 (defvar query-replace-interactive nil
  40   "Non-nil means `query-replace' uses the last search string.
  41 That becomes the \"string to replace\".")
  42
  43 (defcustom query-replace-from-history-variable 'query-replace-history
  44   "History list to use for the FROM argument of `query-replace' commands.
  45 The value of this variable should be a symbol; that symbol
  46 is used as a variable to hold a history list for the strings
  47 or patterns to be replaced."
  48   :group 'matching
  49   :type 'symbol
  50   :version "20.3")
  51
  52 (defcustom query-replace-to-history-variable 'query-replace-history
  53   "History list to use for the TO argument of `query-replace' commands.
  54 The value of this variable should be a symbol; that symbol
  55 is used as a variable to hold a history list for replacement
  56 strings or patterns."
  57   :group 'matching
  58   :type 'symbol
  59   :version "20.3")
  60
  61 (defcustom query-replace-skip-read-only nil
  62   "*Non-nil means `query-replace' and friends ignore read-only matches."
  63   :type 'boolean
  64   :group 'matching
  65   :version "21.4")
  66
  67 (defun query-replace-read-args (string regexp-flag &optional noerror)
  68   (unless noerror
  69     (barf-if-buffer-read-only))
  70   (let (from to)
  71     (if query-replace-interactive
  72         (setq from (car (if regexp-flag regexp-search-ring search-ring)))
  73       (setq from (read-from-minibuffer (format "%s: " string)
  74                                        nil nil nil
  75                                        query-replace-from-history-variable
  76                                        nil t))
  77       ;; Warn if user types \n or \t, but don't reject the input.
  78       (if (string-match "\\\\[nt]" from)
  79           (let ((match (match-string 0 from)))
  80             (cond
  81              ((string= match "\\n")
  82               (message "Note: `\\n' here doesn't match a newline; to do that, type C-q C-j instead"))
  83              ((string= match "\\t")
  84               (message "Note: `\\t' here doesn't match a tab; to do that, just type TAB")))
  85             (sit-for 2))))
  86
  87     (setq to (read-from-minibuffer (format "%s %s with: " string from)
  88                                    nil nil nil
  89                                    query-replace-to-history-variable from t))
  90     (if (and transient-mark-mode mark-active)
  91         (list from to current-prefix-arg (region-beginning) (region-end))
  92       (list from to current-prefix-arg nil nil))))
  93
  94 (defun query-replace (from-string to-string &optional delimited start end)
  95   "Replace some occurrences of FROM-STRING with TO-STRING.
  96 As each match is found, the user must type a character saying
  97 what to do with it.  For directions, type \\[help-command] at that time.
  98
  99 In Transient Mark mode, if the mark is active, operate on the contents
 100 of the region.  Otherwise, operate from point to the end of the buffer.
 101
 102 If `query-replace-interactive' is non-nil, the last incremental search
 103 string is used as FROM-STRING--you don't have to specify it with the
 104 minibuffer.
 105
 106 Replacement transfers the case of the old text to the new text,
 107 if `case-replace' and `case-fold-search'
 108 are non-nil and FROM-STRING has no uppercase letters.
 109 \(Preserving case means that if the string matched is all caps, or capitalized,
 110 then its replacement is upcased or capitalized.)
 111
 112 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 113 only matches surrounded by word boundaries.
 114 Fourth and fifth arg START and END specify the region to operate on.
 115
 116 To customize possible responses, change the \"bindings\" in `query-replace-map'."
 117   (interactive (query-replace-read-args "Query replace" nil))
 118   (perform-replace from-string to-string t nil delimited nil nil start end))
 119
 120 (define-key esc-map "%" 'query-replace)
 121
 122 (defun query-replace-regexp (regexp to-string &optional delimited start end)
 123   "Replace some things after point matching REGEXP with TO-STRING.
 124 As each match is found, the user must type a character saying
 125 what to do with it.  For directions, type \\[help-command] at that time.
 126
 127 In Transient Mark mode, if the mark is active, operate on the contents
 128 of the region.  Otherwise, operate from point to the end of the buffer.
 129
 130 If `query-replace-interactive' is non-nil, the last incremental search
 131 regexp is used as REGEXP--you don't have to specify it with the
 132 minibuffer.
 133
 134 Preserves case in each replacement if `case-replace' and `case-fold-search'
 135 are non-nil and REGEXP has no uppercase letters.
 136
 137 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 138 only matches surrounded by word boundaries.
 139 Fourth and fifth arg START and END specify the region to operate on.
 140
 141 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 142 and `\\=\\N' (where N is a digit) stands for
 143  whatever what matched the Nth `\\(...\\)' in REGEXP."
 144   (interactive (query-replace-read-args "Query replace regexp" t))
 145   (perform-replace regexp to-string t t delimited nil nil start end))
 146 (define-key esc-map [?\C-%] 'query-replace-regexp)
 147
 148 (defun query-replace-regexp-eval (regexp to-expr &optional delimited start end)
 149   "Replace some things after point matching REGEXP with the result of TO-EXPR.
 150 As each match is found, the user must type a character saying
 151 what to do with it.  For directions, type \\[help-command] at that time.
 152
 153 TO-EXPR is a Lisp expression evaluated to compute each replacement.  It may
 154 reference `replace-count' to get the number of replacements already made.
 155 If the result of TO-EXPR is not a string, it is converted to one using
 156 `prin1-to-string' with the NOESCAPE argument (which see).
 157
 158 For convenience, when entering TO-EXPR interactively, you can use `\\&' or
 159 `\\0' to stand for whatever matched the whole of REGEXP, and `\\N' (where
 160 N is a digit) to stand for whatever matched the Nth `\\(...\\)' in REGEXP.
 161 Use `\\#&' or `\\#N' if you want a number instead of a string.
 162
 163 In Transient Mark mode, if the mark is active, operate on the contents
 164 of the region.  Otherwise, operate from point to the end of the buffer.
 165
 166 If `query-replace-interactive' is non-nil, the last incremental search
 167 regexp is used as REGEXP--you don't have to specify it with the
 168 minibuffer.
 169
 170 Preserves case in each replacement if `case-replace' and `case-fold-search'
 171 are non-nil and REGEXP has no uppercase letters.
 172
 173 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 174 only matches that are surrounded by word boundaries.
 175 Fourth and fifth arg START and END specify the region to operate on."
 176   (interactive
 177    (let (from to start end)
 178      (when (and transient-mark-mode mark-active)
 179        (setq start (region-beginning)
 180              end (region-end)))
 181      (if query-replace-interactive
 182          (setq from (car regexp-search-ring))
 183        (setq from (read-from-minibuffer "Query replace regexp: "
 184                                         nil nil nil
 185                                         query-replace-from-history-variable
 186                                         nil t)))
 187      (setq to (list (read-from-minibuffer
 188                      (format "Query replace regexp %s with eval: " from)
 189                      nil nil t query-replace-to-history-variable from t)))
 190      ;; We make TO a list because replace-match-string-symbols requires one,
 191      ;; and the user might enter a single token.
 192      (replace-match-string-symbols to)
 193      (list from (car to) current-prefix-arg start end)))
 194   (perform-replace regexp (cons 'replace-eval-replacement to-expr)
 195                    t t delimited nil nil start end))
 196
 197 (defun map-query-replace-regexp (regexp to-strings &optional n start end)
 198   "Replace some matches for REGEXP with various strings, in rotation.
 199 The second argument TO-STRINGS contains the replacement strings,
 200 separated by spaces.  Third arg DELIMITED (prefix arg if interactive),
 201 if non-nil, means replace only matches surrounded by word boundaries.
 202 This command works like `query-replace-regexp' except that each
 203 successive replacement uses the next successive replacement string,
 204 wrapping around from the last such string to the first.
 205
 206 In Transient Mark mode, if the mark is active, operate on the contents
 207 of the region.  Otherwise, operate from point to the end of the buffer.
 208
 209 Non-interactively, TO-STRINGS may be a list of replacement strings.
 210
 211 If `query-replace-interactive' is non-nil, the last incremental search
 212 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 213
 214 A prefix argument N says to use each replacement string N times
 215 before rotating to the next.
 216 Fourth and fifth arg START and END specify the region to operate on."
 217   (interactive
 218    (let (from to start end)
 219      (when (and transient-mark-mode mark-active)
 220        (setq start (region-beginning)
 221              end (region-end)))
 222      (setq from (if query-replace-interactive
 223                     (car regexp-search-ring)
 224                   (read-from-minibuffer "Map query replace (regexp): "
 225                                         nil nil nil
 226                                         'query-replace-history nil t)))
 227      (setq to (read-from-minibuffer
 228                (format "Query replace %s with (space-separated strings): "
 229                        from)
 230                nil nil nil
 231                'query-replace-history from t))
 232      (list from to start end current-prefix-arg)))
 233   (let (replacements)
 234     (if (listp to-strings)
 235         (setq replacements to-strings)
 236       (while (/= (length to-strings) 0)
 237         (if (string-match " " to-strings)
 238             (setq replacements
 239                   (append replacements
 240                           (list (substring to-strings 0
 241                                            (string-match " " to-strings))))
 242                   to-strings (substring to-strings
 243                                        (1+ (string-match " " to-strings))))
 244           (setq replacements (append replacements (list to-strings))
 245                 to-strings ""))))
 246     (perform-replace regexp replacements t t nil n nil start end)))
 247
 248 (defun replace-string (from-string to-string &optional delimited start end)
 249   "Replace occurrences of FROM-STRING with TO-STRING.
 250 Preserve case in each match if `case-replace' and `case-fold-search'
 251 are non-nil and FROM-STRING has no uppercase letters.
 252 \(Preserving case means that if the string matched is all caps, or capitalized,
 253 then its replacement is upcased or capitalized.)
 254
 255 In Transient Mark mode, if the mark is active, operate on the contents
 256 of the region.  Otherwise, operate from point to the end of the buffer.
 257
 258 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 259 only matches surrounded by word boundaries.
 260 Fourth and fifth arg START and END specify the region to operate on.
 261
 262 If `query-replace-interactive' is non-nil, the last incremental search
 263 string is used as FROM-STRING--you don't have to specify it with the
 264 minibuffer.
 265
 266 This function is usually the wrong thing to use in a Lisp program.
 267 What you probably want is a loop like this:
 268   (while (search-forward FROM-STRING nil t)
 269     (replace-match TO-STRING nil t))
 270 which will run faster and will not set the mark or print anything.
 271 \(You may need a more complex loop if FROM-STRING can match the null string
 272 and TO-STRING is also null.)"
 273   (interactive (query-replace-read-args "Replace string" nil))
 274   (perform-replace from-string to-string nil nil delimited nil nil start end))
 275
 276 (defun replace-regexp (regexp to-string &optional delimited start end)
 277   "Replace things after point matching REGEXP with TO-STRING.
 278 Preserve case in each match if `case-replace' and `case-fold-search'
 279 are non-nil and REGEXP has no uppercase letters.
 280
 281 In Transient Mark mode, if the mark is active, operate on the contents
 282 of the region.  Otherwise, operate from point to the end of the buffer.
 283
 284 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 285 only matches surrounded by word boundaries.
 286 Fourth and fifth arg START and END specify the region to operate on.
 287
 288 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 289 and `\\=\\N' (where N is a digit) stands for
 290  whatever what matched the Nth `\\(...\\)' in REGEXP.
 291
 292 If `query-replace-interactive' is non-nil, the last incremental search
 293 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 294
 295 This function is usually the wrong thing to use in a Lisp program.
 296 What you probably want is a loop like this:
 297   (while (re-search-forward REGEXP nil t)
 298     (replace-match TO-STRING nil nil))
 299 which will run faster and will not set the mark or print anything."
 300   (interactive (query-replace-read-args "Replace regexp" t))
 301   (perform-replace regexp to-string nil t delimited nil nil start end))
 302
 303 \f
 304 (defvar regexp-history nil
 305   "History list for some commands that read regular expressions.")
 306
 307
 308 (defalias 'delete-non-matching-lines 'keep-lines)
 309 (defalias 'delete-matching-lines 'flush-lines)
 310 (defalias 'count-matches 'how-many)
 311
 312
 313 (defun keep-lines-read-args (prompt)
 314   "Read arguments for `keep-lines' and friends.
 315 Prompt for a regexp with PROMPT.
 316 Value is a list, (REGEXP)."
 317   (list (read-from-minibuffer prompt nil nil nil
 318                               'regexp-history nil t)))
 319
 320 (defun keep-lines (regexp &optional rstart rend)
 321   "Delete all lines except those containing matches for REGEXP.
 322 A match split across lines preserves all the lines it lies in.
 323 Applies to all lines after point.
 324
 325 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 326 the matching is case-sensitive.
 327
 328 Second and third arg RSTART and REND specify the region to operate on.
 329
 330 Interactively, in Transient Mark mode when the mark is active, operate
 331 on the contents of the region.  Otherwise, operate from point to the
 332 end of the buffer."
 333
 334   (interactive
 335    (progn
 336      (barf-if-buffer-read-only)
 337      (keep-lines-read-args "Keep lines (containing match for regexp): ")))
 338   (if rstart
 339       (progn
 340         (goto-char (min rstart rend))
 341         (setq rend (copy-marker (max rstart rend))))
 342     (if (and transient-mark-mode mark-active)
 343         (setq rstart (region-beginning)
 344               rend (copy-marker (region-end)))
 345       (setq rstart (point)
 346             rend (point-max-marker)))
 347     (goto-char rstart))
 348   (save-excursion
 349     (or (bolp) (forward-line 1))
 350     (let ((start (point))
 351           (case-fold-search  (and case-fold-search
 352                                   (isearch-no-upper-case-p regexp t))))
 353       (while (< (point) rend)
 354         ;; Start is first char not preserved by previous match.
 355         (if (not (re-search-forward regexp rend 'move))
 356             (delete-region start rend)
 357           (let ((end (save-excursion (goto-char (match-beginning 0))
 358                                      (beginning-of-line)
 359                                      (point))))
 360             ;; Now end is first char preserved by the new match.
 361             (if (< start end)
 362                 (delete-region start end))))
 363
 364         (setq start (save-excursion (forward-line 1) (point)))
 365         ;; If the match was empty, avoid matching again at same place.
 366         (and (< (point) rend)
 367              (= (match-beginning 0) (match-end 0))
 368              (forward-char 1))))))
 369
 370
 371 (defun flush-lines (regexp &optional rstart rend)
 372   "Delete lines containing matches for REGEXP.
 373 If a match is split across lines, all the lines it lies in are deleted.
 374 Applies to lines after point.
 375
 376 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 377 the matching is case-sensitive.
 378
 379 Second and third arg RSTART and REND specify the region to operate on.
 380
 381 Interactively, in Transient Mark mode when the mark is active, operate
 382 on the contents of the region.  Otherwise, operate from point to the
 383 end of the buffer."
 384
 385   (interactive
 386    (progn
 387      (barf-if-buffer-read-only)
 388      (keep-lines-read-args "Flush lines (containing match for regexp): ")))
 389   (if rstart
 390       (progn
 391         (goto-char (min rstart rend))
 392         (setq rend (copy-marker (max rstart rend))))
 393     (if (and transient-mark-mode mark-active)
 394         (setq rstart (region-beginning)
 395               rend (copy-marker (region-end)))
 396       (setq rstart (point)
 397             rend (point-max-marker)))
 398     (goto-char rstart))
 399   (let ((case-fold-search (and case-fold-search
 400                                (isearch-no-upper-case-p regexp t))))
 401     (save-excursion
 402       (while (and (< (point) rend)
 403                   (re-search-forward regexp rend t))
 404         (delete-region (save-excursion (goto-char (match-beginning 0))
 405                                        (beginning-of-line)
 406                                        (point))
 407                        (progn (forward-line 1) (point)))))))
 408
 409
 410 (defun how-many (regexp &optional rstart rend)
 411   "Print number of matches for REGEXP following point.
 412
 413 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 414 the matching is case-sensitive.
 415
 416 Second and third arg RSTART and REND specify the region to operate on.
 417
 418 Interactively, in Transient Mark mode when the mark is active, operate
 419 on the contents of the region.  Otherwise, operate from point to the
 420 end of the buffer."
 421
 422   (interactive
 423    (keep-lines-read-args "How many matches for (regexp): "))
 424   (save-excursion
 425     (if rstart
 426         (goto-char (min rstart rend))
 427       (if (and transient-mark-mode mark-active)
 428           (setq rstart (region-beginning)
 429                 rend (copy-marker (region-end)))
 430         (setq rstart (point)
 431               rend (point-max-marker)))
 432       (goto-char rstart))
 433     (let ((count 0)
 434           opoint
 435           (case-fold-search (and case-fold-search
 436                                  (isearch-no-upper-case-p regexp t))))
 437       (while (and (< (point) rend)
 438                   (progn (setq opoint (point))
 439                          (re-search-forward regexp rend t)))
 440         (if (= opoint (point))
 441             (forward-char 1)
 442           (setq count (1+ count))))
 443       (message "%d occurrences" count))))
 444
 445 \f
 446 (defvar occur-mode-map
 447   (let ((map (make-sparse-keymap)))
 448     (define-key map [mouse-2] 'occur-mode-mouse-goto)
 449     (define-key map "\C-c\C-c" 'occur-mode-goto-occurrence)
 450     (define-key map "\C-m" 'occur-mode-goto-occurrence)
 451     (define-key map "o" 'occur-mode-goto-occurrence-other-window)
 452     (define-key map "\C-o" 'occur-mode-display-occurrence)
 453     (define-key map "\M-n" 'occur-next)
 454     (define-key map "\M-p" 'occur-prev)
 455     (define-key map "r" 'occur-rename-buffer)
 456     (define-key map "c" 'clone-buffer)
 457     (define-key map "g" 'revert-buffer)
 458     (define-key map "q" 'quit-window)
 459     (define-key map "z" 'kill-this-buffer)
 460     map)
 461   "Keymap for `occur-mode'.")
 462
 463 (defvar occur-revert-arguments nil
 464   "Arguments to pass to `occur-1' to revert an Occur mode buffer.
 465 See `occur-revert-function'.")
 466
 467 (defcustom occur-mode-hook '(turn-on-font-lock)
 468   "Hooks run when `occur' is called."
 469   :type 'hook
 470   :group 'matching)
 471
 472 (put 'occur-mode 'mode-class 'special)
 473 (defun occur-mode ()
 474   "Major mode for output from \\[occur].
 475 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 476 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 477 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 478
 479 \\{occur-mode-map}"
 480   (kill-all-local-variables)
 481   (use-local-map occur-mode-map)
 482   (setq major-mode 'occur-mode)
 483   (setq mode-name "Occur")
 484   (set (make-local-variable 'revert-buffer-function) 'occur-revert-function)
 485   (make-local-variable 'occur-revert-arguments)
 486   (run-hooks 'occur-mode-hook))
 487
 488 (defun occur-revert-function (ignore1 ignore2)
 489   "Handle `revert-buffer' for Occur mode buffers."
 490   (apply 'occur-1 (append occur-revert-arguments (list (buffer-name)))))
 491
 492 (defun occur-mode-mouse-goto (event)
 493   "In Occur mode, go to the occurrence whose line you click on."
 494   (interactive "e")
 495   (let (pos)
 496     (save-excursion
 497       (set-buffer (window-buffer (posn-window (event-end event))))
 498       (save-excursion
 499         (goto-char (posn-point (event-end event)))
 500         (setq pos (occur-mode-find-occurrence))))
 501     (pop-to-buffer (marker-buffer pos))
 502     (goto-char pos)))
 503
 504 (defun occur-mode-find-occurrence ()
 505   (let ((pos (get-text-property (point) 'occur-target)))
 506     (unless pos
 507       (error "No occurrence on this line"))
 508     (unless (buffer-live-p (marker-buffer pos))
 509       (error "Buffer for this occurrence was killed"))
 510     pos))
 511
 512 (defun occur-mode-goto-occurrence ()
 513   "Go to the occurrence the current line describes."
 514   (interactive)
 515   (let ((pos (occur-mode-find-occurrence)))
 516     (pop-to-buffer (marker-buffer pos))
 517     (goto-char pos)))
 518
 519 (defun occur-mode-goto-occurrence-other-window ()
 520   "Go to the occurrence the current line describes, in another window."
 521   (interactive)
 522   (let ((pos (occur-mode-find-occurrence)))
 523     (switch-to-buffer-other-window (marker-buffer pos))
 524     (goto-char pos)))
 525
 526 (defun occur-mode-display-occurrence ()
 527   "Display in another window the occurrence the current line describes."
 528   (interactive)
 529   (let ((pos (occur-mode-find-occurrence))
 530         window
 531         ;; Bind these to ensure `display-buffer' puts it in another window.
 532         same-window-buffer-names
 533         same-window-regexps)
 534     (setq window (display-buffer (marker-buffer pos)))
 535     ;; This is the way to set point in the proper window.
 536     (save-selected-window
 537       (select-window window)
 538       (goto-char pos))))
 539
 540 (defun occur-next (&optional n)
 541   "Move to the Nth (default 1) next match in an Occur mode buffer."
 542   (interactive "p")
 543   (if (not n) (setq n 1))
 544   (let ((r))
 545     (while (> n 0)
 546       (if (get-text-property (point) 'occur-point)
 547           (forward-char 1))
 548       (setq r (next-single-property-change (point) 'occur-point))
 549       (if r
 550           (goto-char r)
 551         (error "No more matches"))
 552       (setq n (1- n)))))
 553
 554 (defun occur-prev (&optional n)
 555   "Move to the Nth (default 1) previous match in an Occur mode buffer."
 556   (interactive "p")
 557   (if (not n) (setq n 1))
 558   (let ((r))
 559     (while (> n 0)
 560
 561       (setq r (get-text-property (point) 'occur-point))
 562       (if r (forward-char -1))
 563
 564       (setq r (previous-single-property-change (point) 'occur-point))
 565       (if r
 566           (goto-char (- r 1))
 567         (error "No earlier matches"))
 568
 569       (setq n (1- n)))))
 570 \f
 571 (defcustom list-matching-lines-default-context-lines 0
 572   "*Default number of context lines included around `list-matching-lines' matches.
 573 A negative number means to include that many lines before the match.
 574 A positive number means to include that many lines both before and after."
 575   :type 'integer
 576   :group 'matching)
 577
 578 (defalias 'list-matching-lines 'occur)
 579
 580 (defcustom list-matching-lines-face 'bold
 581   "*Face used by \\[list-matching-lines] to show the text that matches.
 582 If the value is nil, don't highlight the matching portions specially."
 583   :type 'face
 584   :group 'matching)
 585
 586 (defcustom list-matching-lines-buffer-name-face 'underline
 587   "*Face used by \\[list-matching-lines] to show the names of buffers.
 588 If the value is nil, don't highlight the buffer names specially."
 589   :type 'face
 590   :group 'matching)
 591
 592 (defun occur-accumulate-lines (count &optional no-props)
 593   (save-excursion
 594     (let ((forwardp (> count 0))
 595           (result nil))
 596       (while (not (or (zerop count)
 597                       (if forwardp
 598                           (eobp)
 599                         (bobp))))
 600         (setq count (+ count (if forwardp -1 1)))
 601         (push
 602          (funcall (if no-props
 603                       #'buffer-substring-no-properties
 604                     #'buffer-substring)
 605           (line-beginning-position)
 606           (line-end-position))
 607          result)
 608         (forward-line (if forwardp 1 -1)))
 609       (nreverse result))))
 610
 611 (defun occur-read-primary-args ()
 612   (list (let* ((default (car regexp-history))
 613                (input
 614                 (read-from-minibuffer
 615                  (if default
 616                      (format "List lines matching regexp (default `%s'): "
 617                              default)
 618                    "List lines matching regexp: ")
 619                  nil
 620                  nil
 621                  nil
 622                  'regexp-history)))
 623           (if (equal input "")
 624               default
 625             input))
 626         (when current-prefix-arg
 627           (prefix-numeric-value current-prefix-arg))))
 628
 629 (defun occur-rename-buffer (&optional unique-p)
 630   "Rename the current *Occur* buffer to *Occur: original-buffer-name*.
 631 Here `original-buffer-name' is the buffer name were occur was originally run.
 632 When given the prefix argument, the renaming will not clobber the existing
 633 buffer(s) of that name, but use `generate-new-buffer-name' instead.
 634 You can add this to `occur-mode-hook' if you always want a separate *Occur*
 635 buffer for each buffer where you invoke `occur'."
 636   (interactive "P")
 637   (with-current-buffer
 638       (if (eq major-mode 'occur-mode) (current-buffer) (get-buffer "*Occur*"))
 639     (rename-buffer (concat "*Occur: "
 640                            (mapconcat #'buffer-name
 641                                       (car (cddr occur-revert-arguments)) "/")
 642                            "*")
 643                    unique-p)))
 644
 645 (defun occur (regexp &optional nlines)
 646   "Show all lines in the current buffer containing a match for REGEXP.
 647
 648 If a match spreads across multiple lines, all those lines are shown.
 649
 650 Each line is displayed with NLINES lines before and after, or -NLINES
 651 before if NLINES is negative.
 652 NLINES defaults to `list-matching-lines-default-context-lines'.
 653 Interactively it is the prefix arg.
 654
 655 The lines are shown in a buffer named `*Occur*'.
 656 It serves as a menu to find any of the occurrences in this buffer.
 657 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
 658
 659 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 660 the matching is case-sensitive."
 661   (interactive (occur-read-primary-args))
 662   (occur-1 regexp nlines (list (current-buffer))))
 663
 664 (defun multi-occur (bufs regexp &optional nlines)
 665   "Show all lines in buffers BUFS containing a match for REGEXP.
 666 This function acts on multiple buffers; otherwise, it is exactly like
 667 `occur'."
 668   (interactive
 669    (cons
 670     (let ((bufs (list (read-buffer "First buffer to search: "
 671                                    (current-buffer) t)))
 672           (buf nil))
 673       (while (not (string-equal
 674                    (setq buf (read-buffer "Next buffer to search (RET to end): "
 675                                           nil t))
 676                    ""))
 677         (push buf bufs))
 678       (nreverse (mapcar #'get-buffer bufs)))
 679     (occur-read-primary-args)))
 680   (occur-1 regexp nlines bufs))
 681
 682 (defun multi-occur-by-filename-regexp (bufregexp regexp &optional nlines)
 683   "Show all lines matching REGEXP in buffers named by BUFREGEXP.
 684 See also `multi-occur'."
 685   (interactive
 686    (cons
 687     (let* ((default (car regexp-history))
 688            (input
 689             (read-from-minibuffer
 690              "List lines in buffers whose filename matches regexp: "
 691              nil
 692              nil
 693              nil
 694              'regexp-history)))
 695       (if (equal input "")
 696           default
 697         input))
 698     (occur-read-primary-args)))
 699   (when bufregexp
 700     (occur-1 regexp nlines
 701              (delq nil
 702                    (mapcar (lambda (buf)
 703                              (when (and (buffer-file-name buf)
 704                                         (string-match bufregexp
 705                                                       (buffer-file-name buf)))
 706                                buf))
 707                            (buffer-list))))))
 708
 709 (defun occur-1 (regexp nlines bufs &optional buf-name)
 710   (unless buf-name
 711     (setq buf-name "*Occur*"))
 712   (let ((occur-buf (get-buffer-create buf-name))
 713         (made-temp-buf nil)
 714         (active-bufs (delq nil (mapcar #'(lambda (buf)
 715                                            (when (buffer-live-p buf) buf))
 716                                        bufs))))
 717     ;; Handle the case where one of the buffers we're searching is the
 718     ;; *Occur* buffer itself.
 719     (when (memq occur-buf bufs)
 720       (setq occur-buf (with-current-buffer occur-buf
 721                         (clone-buffer "*Occur-temp*"))
 722             made-temp-buf t))
 723     (with-current-buffer occur-buf
 724       (setq buffer-read-only nil)
 725       (occur-mode)
 726       (erase-buffer)
 727       (let ((count (occur-engine
 728                     regexp active-bufs occur-buf
 729                     (or nlines list-matching-lines-default-context-lines)
 730                     (and case-fold-search
 731                          (isearch-no-upper-case-p regexp t))
 732                     list-matching-lines-buffer-name-face
 733                     nil list-matching-lines-face nil)))
 734         (let* ((bufcount (length active-bufs))
 735                (diff (- (length bufs) bufcount)))
 736           (message "Searched %d buffer%s%s; %s match%s for `%s'"
 737                    bufcount (if (= bufcount 1) "" "s")
 738                    (if (zerop diff) "" (format " (%d killed)" diff))
 739                    (if (zerop count) "no" (format "%d" count))
 740                    (if (= count 1) "" "es")
 741                    regexp))
 742         ;; If we had to make a temporary buffer, make it the *Occur*
 743         ;; buffer now.
 744         (when made-temp-buf
 745           (with-current-buffer (get-buffer buf-name)
 746             (kill-buffer (current-buffer)))
 747           (rename-buffer buf-name))
 748         (setq occur-revert-arguments (list regexp nlines bufs)
 749               buffer-read-only t)
 750         (if (> count 0)
 751             (display-buffer occur-buf)
 752           (kill-buffer occur-buf))))))
 753
 754 (defun occur-engine-add-prefix (lines)
 755   (mapcar
 756    #'(lambda (line)
 757        (concat "      :" line "\n"))
 758    lines))
 759
 760 (defun occur-engine (regexp buffers out-buf nlines case-fold-search
 761                             title-face prefix-face match-face keep-props)
 762   (with-current-buffer out-buf
 763     (setq buffer-read-only nil)
 764     (let ((globalcount 0))
 765       ;; Map over all the buffers
 766       (dolist (buf buffers)
 767         (when (buffer-live-p buf)
 768           (let ((matches 0)     ;; count of matched lines
 769                 (lines 1)       ;; line count
 770                 (matchbeg 0)
 771                 (matchend 0)
 772                 (origpt nil)
 773                 (begpt nil)
 774                 (endpt nil)
 775                 (marker nil)
 776                 (curstring "")
 777                 (headerpt (with-current-buffer out-buf (point))))
 778             (save-excursion
 779               (set-buffer buf)
 780               (save-excursion
 781                 (goto-char (point-min)) ;; begin searching in the buffer
 782                 (while (not (eobp))
 783                   (setq origpt (point))
 784                   (when (setq endpt (re-search-forward regexp nil t))
 785                     (setq matches (1+ matches)) ;; increment match count
 786                     (setq matchbeg (match-beginning 0)
 787                           matchend (match-end 0))
 788                     (setq begpt (save-excursion
 789                                   (goto-char matchbeg)
 790                                   (line-beginning-position)))
 791                     (setq lines (+ lines (1- (count-lines origpt endpt))))
 792                     (setq marker (make-marker))
 793                     (set-marker marker matchbeg)
 794                     (setq curstring (buffer-substring begpt
 795                                                       (line-end-position)))
 796                     ;; Depropertize the string, and maybe
 797                     ;; highlight the matches
 798                     (let ((len (length curstring))
 799                           (start 0))
 800                       (unless keep-props
 801                         (set-text-properties 0 len nil curstring))
 802                       (while (and (< start len)
 803                                   (string-match regexp curstring start))
 804                         (add-text-properties (match-beginning 0)
 805                                              (match-end 0)
 806                                              (append
 807                                               `(occur-match t)
 808                                               (when match-face
 809                                                 `(font-lock-face ,match-face)))
 810                                              curstring)
 811                         (setq start (match-end 0))))
 812                     ;; Generate the string to insert for this match
 813                     (let* ((out-line
 814                             (concat
 815                              (apply #'propertize (format "%6d:" lines)
 816                                     (append
 817                                      (when prefix-face
 818                                        `(font-lock-face prefix-face))
 819                                      '(occur-prefix t)))
 820                              curstring
 821                              "\n"))
 822                            (data
 823                             (if (= nlines 0)
 824                                 ;; The simple display style
 825                                 out-line
 826                               ;; The complex multi-line display
 827                               ;; style.  Generate a list of lines,
 828                               ;; concatenate them all together.
 829                               (apply #'concat
 830                                      (nconc
 831                                       (occur-engine-add-prefix (nreverse (cdr (occur-accumulate-lines (- (1+ nlines)) keep-props))))
 832                                       (list out-line)
 833                                       (occur-engine-add-prefix (cdr (occur-accumulate-lines (1+ nlines) keep-props))))))))
 834                       ;; Actually insert the match display data
 835                       (with-current-buffer out-buf
 836                         (let ((beg (point))
 837                               (end (progn (insert data) (point))))
 838                           (unless (= nlines 0)
 839                             (insert "-------\n"))
 840                           (add-text-properties
 841                            beg end
 842                            `(occur-target ,marker help-echo "mouse-2: go to this occurrence"))
 843                           ;; We don't put `mouse-face' on the newline,
 844                           ;; because that loses.
 845                           (add-text-properties beg (1- end) '(mouse-face highlight)))))
 846                     (goto-char endpt))
 847                   (if endpt
 848                       (progn
 849                         (setq lines (1+ lines))
 850                         ;; On to the next match...
 851                         (forward-line 1))
 852                     (goto-char (point-max))))))
 853             (when (not (zerop matches)) ;; is the count zero?
 854               (setq globalcount (+ globalcount matches))
 855               (with-current-buffer out-buf
 856                 (goto-char headerpt)
 857                 (let ((beg (point))
 858                       end)
 859                   (insert (format "%d lines matching \"%s\" in buffer: %s\n"
 860                                   matches regexp (buffer-name buf)))
 861                   (setq end (point))
 862                   (add-text-properties beg end
 863                                        (append
 864                                         (when title-face
 865                                           `(font-lock-face ,title-face))
 866                                         `(occur-title ,buf))))
 867                 (goto-char (point-min)))))))
 868       ;; Return the number of matches
 869       globalcount)))
 870
 871 \f
 872 ;; It would be nice to use \\[...], but there is no reasonable way
 873 ;; to make that display both SPC and Y.
 874 (defconst query-replace-help
 875   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
 876 RET or `q' to exit, Period to replace one match and exit,
 877 Comma to replace but not move point immediately,
 878 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
 879 C-w to delete match and recursive edit,
 880 C-l to clear the screen, redisplay, and offer same replacement again,
 881 ! to replace all remaining matches with no more questions,
 882 ^ to move point back to previous match,
 883 E to edit the replacement string"
 884   "Help message while in `query-replace'.")
 885
 886 (defvar query-replace-map (make-sparse-keymap)
 887   "Keymap that defines the responses to questions in `query-replace'.
 888 The \"bindings\" in this map are not commands; they are answers.
 889 The valid answers include `act', `skip', `act-and-show',
 890 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
 891 `automatic', `backup', `exit-prefix', and `help'.")
 892
 893 (define-key query-replace-map " " 'act)
 894 (define-key query-replace-map "\d" 'skip)
 895 (define-key query-replace-map [delete] 'skip)
 896 (define-key query-replace-map [backspace] 'skip)
 897 (define-key query-replace-map "y" 'act)
 898 (define-key query-replace-map "n" 'skip)
 899 (define-key query-replace-map "Y" 'act)
 900 (define-key query-replace-map "N" 'skip)
 901 (define-key query-replace-map "e" 'edit-replacement)
 902 (define-key query-replace-map "E" 'edit-replacement)
 903 (define-key query-replace-map "," 'act-and-show)
 904 (define-key query-replace-map "q" 'exit)
 905 (define-key query-replace-map "\r" 'exit)
 906 (define-key query-replace-map [return] 'exit)
 907 (define-key query-replace-map "." 'act-and-exit)
 908 (define-key query-replace-map "\C-r" 'edit)
 909 (define-key query-replace-map "\C-w" 'delete-and-edit)
 910 (define-key query-replace-map "\C-l" 'recenter)
 911 (define-key query-replace-map "!" 'automatic)
 912 (define-key query-replace-map "^" 'backup)
 913 (define-key query-replace-map "\C-h" 'help)
 914 (define-key query-replace-map [f1] 'help)
 915 (define-key query-replace-map [help] 'help)
 916 (define-key query-replace-map "?" 'help)
 917 (define-key query-replace-map "\C-g" 'quit)
 918 (define-key query-replace-map "\C-]" 'quit)
 919 (define-key query-replace-map "\e" 'exit-prefix)
 920 (define-key query-replace-map [escape] 'exit-prefix)
 921
 922 (defun replace-match-string-symbols (n)
 923   "Process a list (and any sub-lists), expanding certain symbols.
 924 Symbol  Expands To
 925 N     (match-string N)           (where N is a string of digits)
 926 #N    (string-to-number (match-string N))
 927 &     (match-string 0)
 928 #&    (string-to-number (match-string 0))
 929
 930 Note that these symbols must be preceeded by a backslash in order to
 931 type them."
 932   (while n
 933     (cond
 934      ((consp (car n))
 935       (replace-match-string-symbols (car n))) ;Process sub-list
 936      ((symbolp (car n))
 937       (let ((name (symbol-name (car n))))
 938         (cond
 939          ((string-match "^[0-9]+$" name)
 940           (setcar n (list 'match-string (string-to-number name))))
 941          ((string-match "^#[0-9]+$" name)
 942           (setcar n (list 'string-to-number
 943                           (list 'match-string
 944                                 (string-to-number (substring name 1))))))
 945          ((string= "&" name)
 946           (setcar n '(match-string 0)))
 947          ((string= "#&" name)
 948           (setcar n '(string-to-number (match-string 0))))))))
 949     (setq n (cdr n))))
 950
 951 (defun replace-eval-replacement (expression replace-count)
 952   (let ((replacement (eval expression)))
 953     (if (stringp replacement)
 954         replacement
 955       (prin1-to-string replacement t))))
 956
 957 (defun replace-loop-through-replacements (data replace-count)
 958   ;; DATA is a vector contaning the following values:
 959   ;;   0 next-rotate-count
 960   ;;   1 repeat-count
 961   ;;   2 next-replacement
 962   ;;   3 replacements
 963   (if (= (aref data 0) replace-count)
 964       (progn
 965         (aset data 0 (+ replace-count (aref data 1)))
 966         (let ((next (cdr (aref data 2))))
 967           (aset data 2 (if (consp next) next (aref data 3))))))
 968   (car (aref data 2)))
 969
 970 (defun perform-replace (from-string replacements
 971                         query-flag regexp-flag delimited-flag
 972                         &optional repeat-count map start end)
 973   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
 974 Don't use this in your own program unless you want to query and set the mark
 975 just as `query-replace' does.  Instead, write a simple loop like this:
 976
 977   (while (re-search-forward \"foo[ \\t]+bar\" nil t)
 978     (replace-match \"foobar\" nil nil))
 979
 980 which will run faster and probably do exactly what you want.  Please
 981 see the documentation of `replace-match' to find out how to simulate
 982 `case-replace'.
 983
 984 This function returns nil if and only if there were no matches to
 985 make, or the user didn't cancel the call."
 986   (or map (setq map query-replace-map))
 987   (and query-flag minibuffer-auto-raise
 988        (raise-frame (window-frame (minibuffer-window))))
 989   (let ((nocasify (not (and case-fold-search case-replace
 990                             (string-equal from-string
 991                                           (downcase from-string)))))
 992         (case-fold-search (and case-fold-search
 993                                (string-equal from-string
 994                                              (downcase from-string))))
 995         (literal (not regexp-flag))
 996         (search-function (if regexp-flag 're-search-forward 'search-forward))
 997         (search-string from-string)
 998         (real-match-data nil)           ; the match data for the current match
 999         (next-replacement nil)
1000         (keep-going t)
1001         (stack nil)
1002         (replace-count 0)
1003         (nonempty-match nil)
1004
1005         ;; If non-nil, it is marker saying where in the buffer to stop.
1006         (limit nil)
1007
1008         ;; Data for the next match.  If a cons, it has the same format as
1009         ;; (match-data); otherwise it is t if a match is possible at point.
1010         (match-again t)
1011
1012         (message
1013          (if query-flag
1014              (substitute-command-keys
1015               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
1016
1017     ;; If region is active, in Transient Mark mode, operate on region.
1018     (when start
1019       (setq limit (copy-marker (max start end)))
1020       (goto-char (min start end))
1021       (deactivate-mark))
1022
1023     ;; REPLACEMENTS is either a string, a list of strings, or a cons cell
1024     ;; containing a function and its first argument.  The function is
1025     ;; called to generate each replacement like this:
1026     ;;   (funcall (car replacements) (cdr replacements) replace-count)
1027     ;; It must return a string.
1028     (cond
1029      ((stringp replacements)
1030       (setq next-replacement replacements
1031             replacements     nil))
1032      ((stringp (car replacements)) ; If it isn't a string, it must be a cons
1033       (or repeat-count (setq repeat-count 1))
1034       (setq replacements (cons 'replace-loop-through-replacements
1035                                (vector repeat-count repeat-count
1036                                        replacements replacements)))))
1037
1038     (if delimited-flag
1039         (setq search-function 're-search-forward
1040               search-string (concat "\\b"
1041                                     (if regexp-flag from-string
1042                                       (regexp-quote from-string))
1043                                     "\\b")))
1044     (push-mark)
1045     (undo-boundary)
1046     (unwind-protect
1047         ;; Loop finding occurrences that perhaps should be replaced.
1048         (while (and keep-going
1049                     (not (eobp))
1050                     ;; Use the next match if it is already known;
1051                     ;; otherwise, search for a match after moving forward
1052                     ;; one char if progress is required.
1053                     (setq real-match-data
1054                           (if (consp match-again)
1055                               (progn (goto-char (nth 1 match-again))
1056                                      match-again)
1057                             (and (or match-again
1058                                      ;; MATCH-AGAIN non-nil means we
1059                                      ;; accept an adjacent match.  If
1060                                      ;; we don't, move one char to the
1061                                      ;; right.  This takes us a
1062                                      ;; character too far at the end,
1063                                      ;; but this is undone after the
1064                                      ;; while-loop.
1065                                      (progn (forward-char 1) (not (eobp))))
1066                                  (funcall search-function search-string limit t)
1067                                  ;; For speed, use only integers and
1068                                  ;; reuse the list used last time.
1069                                  (match-data t real-match-data)))))
1070           ;; Optionally ignore matches that have a read-only property.
1071           (unless (and query-replace-skip-read-only
1072                        (text-property-not-all
1073                         (match-beginning 0) (match-end 0)
1074                         'read-only nil))
1075
1076             ;; Record whether the match is nonempty, to avoid an infinite loop
1077             ;; repeatedly matching the same empty string.
1078             (setq nonempty-match
1079                   (/= (nth 0 real-match-data) (nth 1 real-match-data)))
1080
1081             ;; If the match is empty, record that the next one can't be
1082             ;; adjacent.
1083
1084             ;; Otherwise, if matching a regular expression, do the next
1085             ;; match now, since the replacement for this match may
1086             ;; affect whether the next match is adjacent to this one.
1087             ;; If that match is empty, don't use it.
1088             (setq match-again
1089                   (and nonempty-match
1090                        (or (not regexp-flag)
1091                            (and (looking-at search-string)
1092                                 (let ((match (match-data)))
1093                                   (and (/= (nth 0 match) (nth 1 match))
1094                                        match))))))
1095
1096             ;; Calculate the replacement string, if necessary.
1097             (when replacements
1098               (set-match-data real-match-data)
1099               (setq next-replacement
1100                     (funcall (car replacements) (cdr replacements)
1101                              replace-count)))
1102             (if (not query-flag)
1103                 (let ((inhibit-read-only query-replace-skip-read-only))
1104                   (set-match-data real-match-data)
1105                   (replace-match next-replacement nocasify literal)
1106                   (setq replace-count (1+ replace-count)))
1107               (undo-boundary)
1108               (let (done replaced key def)
1109                 ;; Loop reading commands until one of them sets done,
1110                 ;; which means it has finished handling this occurrence.
1111                 (while (not done)
1112                   (set-match-data real-match-data)
1113                   (replace-highlight (match-beginning 0) (match-end 0))
1114                   ;; Bind message-log-max so we don't fill up the message log
1115                   ;; with a bunch of identical messages.
1116                   (let ((message-log-max nil))
1117                     (message message from-string next-replacement))
1118                   (setq key (read-event))
1119                   ;; Necessary in case something happens during read-event
1120                   ;; that clobbers the match data.
1121                   (set-match-data real-match-data)
1122                   (setq key (vector key))
1123                   (setq def (lookup-key map key))
1124                   ;; Restore the match data while we process the command.
1125                   (cond ((eq def 'help)
1126                          (with-output-to-temp-buffer "*Help*"
1127                            (princ
1128                             (concat "Query replacing "
1129                                     (if regexp-flag "regexp " "")
1130                                     from-string " with "
1131                                     next-replacement ".\n\n"
1132                                     (substitute-command-keys
1133                                      query-replace-help)))
1134                            (with-current-buffer standard-output
1135                              (help-mode))))
1136                         ((eq def 'exit)
1137                          (setq keep-going nil)
1138                          (setq done t))
1139                         ((eq def 'backup)
1140                          (if stack
1141                              (let ((elt (pop stack)))
1142                                (goto-char (car elt))
1143                                (setq replaced (eq t (cdr elt)))
1144                                (or replaced
1145                                    (set-match-data (cdr elt))))
1146                            (message "No previous match")
1147                            (ding 'no-terminate)
1148                            (sit-for 1)))
1149                         ((eq def 'act)
1150                          (or replaced
1151                              (progn
1152                                (replace-match next-replacement nocasify literal)
1153                                (setq replace-count (1+ replace-count))))
1154                          (setq done t replaced t))
1155                         ((eq def 'act-and-exit)
1156                          (or replaced
1157                              (progn
1158                                (replace-match next-replacement nocasify literal)
1159                                (setq replace-count (1+ replace-count))))
1160                          (setq keep-going nil)
1161                          (setq done t replaced t))
1162                         ((eq def 'act-and-show)
1163                          (if (not replaced)
1164                              (progn
1165                                (replace-match next-replacement nocasify literal)
1166                                (setq replace-count (1+ replace-count))
1167                                (setq replaced t))))
1168                         ((eq def 'automatic)
1169                          (or replaced
1170                              (progn
1171                                (replace-match next-replacement nocasify literal)
1172                                (setq replace-count (1+ replace-count))))
1173                          (setq done t query-flag nil replaced t))
1174                         ((eq def 'skip)
1175                          (setq done t))
1176                         ((eq def 'recenter)
1177                          (recenter nil))
1178                         ((eq def 'edit)
1179                          (let ((opos (point-marker)))
1180                            (goto-char (match-beginning 0))
1181                            (save-excursion
1182                              (funcall search-function search-string limit t)
1183                              (setq real-match-data (match-data)))
1184                            (save-excursion
1185                              (save-window-excursion
1186                                (recursive-edit)))
1187                            (goto-char opos))
1188                          (set-match-data real-match-data)
1189                          ;; Before we make the replacement,
1190                          ;; decide whether the search string
1191                          ;; can match again just after this match.
1192                          (if (and regexp-flag nonempty-match)
1193                              (setq match-again (and (looking-at search-string)
1194                                                     (match-data)))))
1195
1196                         ;; Edit replacement.
1197                         ((eq def 'edit-replacement)
1198                          (setq next-replacement
1199                                (read-input "Edit replacement string: "
1200                                            next-replacement))
1201                          (or replaced
1202                              (replace-match next-replacement nocasify literal))
1203                          (setq done t))
1204
1205                         ((eq def 'delete-and-edit)
1206                          (delete-region (match-beginning 0) (match-end 0))
1207                          (set-match-data
1208                           (prog1 (match-data)
1209                             (save-excursion (recursive-edit))))
1210                          (setq replaced t))
1211                         ;; Note: we do not need to treat `exit-prefix'
1212                         ;; specially here, since we reread
1213                         ;; any unrecognized character.
1214                         (t
1215                          (setq this-command 'mode-exited)
1216                          (setq keep-going nil)
1217                          (setq unread-command-events
1218                                (append (listify-key-sequence key)
1219                                        unread-command-events))
1220                          (setq done t))))
1221                 ;; Record previous position for ^ when we move on.
1222                 ;; Change markers to numbers in the match data
1223                 ;; since lots of markers slow down editing.
1224                 (setq stack
1225                       (cons (cons (point)
1226                                   (or replaced (match-data t)))
1227                             stack))))))
1228
1229       ;; The code preventing adjacent regexp matches in the condition
1230       ;; of the while-loop above will haven taken us one character
1231       ;; beyond the last replacement.  Undo that.
1232       (when (and regexp-flag (not match-again) (> replace-count 0))
1233         (backward-char 1))
1234
1235       (replace-dehighlight))
1236     (or unread-command-events
1237         (message "Replaced %d occurrence%s"
1238                  replace-count
1239                  (if (= replace-count 1) "" "s")))
1240     (and keep-going stack)))
1241
1242 (defcustom query-replace-highlight t
1243   "*Non-nil means to highlight words during query replacement."
1244   :type 'boolean
1245   :group 'matching)
1246
1247 (defvar replace-overlay nil)
1248
1249 (defun replace-dehighlight ()
1250   (and replace-overlay
1251        (progn
1252          (delete-overlay replace-overlay)
1253          (setq replace-overlay nil))))
1254
1255 (defun replace-highlight (start end)
1256   (and query-replace-highlight
1257        (progn
1258          (or replace-overlay
1259              (progn
1260                (setq replace-overlay (make-overlay start end))
1261                (overlay-put replace-overlay 'face
1262                             (if (facep 'query-replace)
1263                                 'query-replace 'region))))
1264          (move-overlay replace-overlay start end (current-buffer)))))
1265
1266 ;;; replace.el ends here