code.delx.au - gnu-emacs/blob - lisp/arc-mode.el

   1 ;;; arc-mode.el --- simple editing of archives
   2
   3 ;; Copyright (C) 1995, 1997, 1998, 2002, 2003, 2004,
   4 ;;   2005, 2006 Free Software Foundation, Inc.
   5
   6 ;; Author: Morten Welinder <terra@gnu.org>
   7 ;; Keywords: archives msdog editing major-mode
   8 ;; Favourite-brand-of-beer: None, I hate beer.
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; NAMING: "arc" is short for "archive" and does not refer specifically
  30 ;; to files whose name end in ".arc"
  31 ;;
  32 ;; This code does not decode any files internally, although it does
  33 ;; understand the directory level of the archives.  For this reason,
  34 ;; you should expect this code to need more fiddling than tar-mode.el
  35 ;; (although it at present has fewer bugs :-)  In particular, I have
  36 ;; not tested this under Ms-Dog myself.
  37 ;; -------------------------------------
  38 ;; INTERACTION: arc-mode.el should play together with
  39 ;;
  40 ;; * ange-ftp.el: Remote archives (i.e., ones that ange-ftp has brought
  41 ;;                to you) are handled by doing all updates on a local
  42 ;;                copy.  When you make changes to a remote file the
  43 ;;                changes will first take effect when the archive buffer
  44 ;;                is saved.  You will be warned about this.
  45 ;;
  46 ;; * dos-fns.el:  (Part of Emacs 19).  You get automatic ^M^J <--> ^J
  47 ;;                conversion.
  48 ;;
  49 ;; arc-mode.el does not work well with crypt++.el; for the archives as
  50 ;; such this could be fixed (but wouldn't be useful) by declaring such
  51 ;; archives to be "remote".  For the members this is a general Emacs
  52 ;; problem that 19.29's file formats may fix.
  53 ;; -------------------------------------
  54 ;; ARCHIVE TYPES: Currently only the archives below are handled, but the
  55 ;; structure for handling just about anything is in place.
  56 ;;
  57 ;;                        Arc     Lzh     Zip     Zoo
  58 ;;                        --------------------------------
  59 ;; View listing           Intern  Intern  Intern  Intern
  60 ;; Extract member         Y       Y       Y       Y
  61 ;; Save changed member    Y       Y       Y       Y
  62 ;; Add new member         N       N       N       N
  63 ;; Delete member          Y       Y       Y       Y
  64 ;; Rename member          Y       Y       N       N
  65 ;; Chmod                  -       Y       Y       -
  66 ;; Chown                  -       Y       -       -
  67 ;; Chgrp                  -       Y       -       -
  68 ;;
  69 ;; Special thanks to Bill Brodie <wbrodie@panix.com> for very useful tips
  70 ;; on the first released version of this package.
  71 ;;
  72 ;; This code is partly based on tar-mode.el from Emacs.
  73 ;; -------------------------------------
  74 ;; ARCHIVE STRUCTURES:
  75 ;; (This is mostly for myself.)
  76 ;;
  77 ;; ARC         A series of (header,file).  No interactions among members.
  78 ;;
  79 ;; LZH         A series of (header,file).  Headers are checksummed.  No
  80 ;;             interaction among members.
  81 ;;             Headers come in three flavours called level 0, 1 and 2 headers.
  82 ;;             Level 2 header is free of DOS specific restrictions and most
  83 ;;             prevalently used.  Also level 1 and 2 headers consist of base
  84 ;;             and extension headers.  For more details see
  85 ;;             http://homepage1.nifty.com/dangan/en/Content/Program/Java/jLHA/Notes/Notes.html
  86 ;;             http://www.osirusoft.com/joejared/lzhformat.html
  87 ;;
  88 ;; ZIP         A series of (lheader,fil) followed by a "central directory"
  89 ;;             which is a series of (cheader) followed by an end-of-
  90 ;;             central-dir record possibly followed by junk.  The e-o-c-d
  91 ;;             links to c-d.  cheaders link to lheaders which are basically
  92 ;;             cut-down versions of the cheaders.
  93 ;;
  94 ;; ZOO         An archive header followed by a series of (header,file).
  95 ;;             Each member header points to the next.  The archive is
  96 ;;             terminated by a bogus header with a zero next link.
  97 ;; -------------------------------------
  98 ;; HOOKS: `foo' means one of the supported archive types.
  99 ;;
 100 ;; archive-mode-hook
 101 ;; archive-foo-mode-hook
 102 ;; archive-extract-hooks
 103
 104 ;;; Code:
 105
 106 ;; -------------------------------------------------------------------------
 107 ;; Section: Configuration.
 108
 109 (defgroup archive nil
 110   "Simple editing of archives."
 111   :group 'data)
 112
 113 (defgroup archive-arc nil
 114   "ARC-specific options to archive."
 115   :group 'archive)
 116
 117 (defgroup archive-lzh nil
 118   "LZH-specific options to archive."
 119   :group 'archive)
 120
 121 (defgroup archive-zip nil
 122   "ZIP-specific options to archive."
 123   :group 'archive)
 124
 125 (defgroup archive-zoo nil
 126   "ZOO-specific options to archive."
 127   :group 'archive)
 128
 129 (defcustom archive-tmpdir
 130   ;; make-temp-name is safe here because we use this name
 131   ;; to create a directory.
 132   (make-temp-name
 133    (expand-file-name (if (eq system-type 'ms-dos) "ar" "archive.tmp")
 134                      temporary-file-directory))
 135   "Directory for temporary files made by `arc-mode.el'."
 136   :type 'directory
 137   :group 'archive)
 138
 139 (defcustom archive-remote-regexp "^/[^/:]*[^/:.]:"
 140   "*Regexp recognizing archive files names that are not local.
 141 A non-local file is one whose file name is not proper outside Emacs.
 142 A local copy of the archive will be used when updating."
 143   :type 'regexp
 144   :group 'archive)
 145
 146 (defcustom archive-extract-hooks nil
 147   "*Hooks to run when an archive member has been extracted."
 148   :type 'hook
 149   :group 'archive)
 150 ;; ------------------------------
 151 ;; Arc archive configuration
 152
 153 ;; We always go via a local file since there seems to be no reliable way
 154 ;; to extract to stdout without junk getting added.
 155 (defcustom archive-arc-extract
 156   '("arc" "x")
 157   "*Program and its options to run in order to extract an arc file member.
 158 Extraction should happen to the current directory.  Archive and member
 159 name will be added."
 160   :type '(list (string :tag "Program")
 161                 (repeat :tag "Options"
 162                         :inline t
 163                         (string :format "%v")))
 164   :group 'archive-arc)
 165
 166 (defcustom archive-arc-expunge
 167   '("arc" "d")
 168   "*Program and its options to run in order to delete arc file members.
 169 Archive and member names will be added."
 170   :type '(list (string :tag "Program")
 171                 (repeat :tag "Options"
 172                         :inline t
 173                         (string :format "%v")))
 174   :group 'archive-arc)
 175
 176 (defcustom archive-arc-write-file-member
 177   '("arc" "u")
 178   "*Program and its options to run in order to update an arc file member.
 179 Archive and member name will be added."
 180   :type '(list (string :tag "Program")
 181                 (repeat :tag "Options"
 182                         :inline t
 183                         (string :format "%v")))
 184   :group 'archive-arc)
 185 ;; ------------------------------
 186 ;; Lzh archive configuration
 187
 188 (defcustom archive-lzh-extract
 189   '("lha" "pq")
 190   "*Program and its options to run in order to extract an lzh file member.
 191 Extraction should happen to standard output.  Archive and member name will
 192 be added."
 193   :type '(list (string :tag "Program")
 194                 (repeat :tag "Options"
 195                         :inline t
 196                         (string :format "%v")))
 197   :group 'archive-lzh)
 198
 199 (defcustom archive-lzh-expunge
 200   '("lha" "d")
 201   "*Program and its options to run in order to delete lzh file members.
 202 Archive and member names will be added."
 203   :type '(list (string :tag "Program")
 204                 (repeat :tag "Options"
 205                         :inline t
 206                         (string :format "%v")))
 207   :group 'archive-lzh)
 208
 209 (defcustom archive-lzh-write-file-member
 210   '("lha" "a")
 211   "*Program and its options to run in order to update an lzh file member.
 212 Archive and member name will be added."
 213   :type '(list (string :tag "Program")
 214                 (repeat :tag "Options"
 215                         :inline t
 216                         (string :format "%v")))
 217   :group 'archive-lzh)
 218 ;; ------------------------------
 219 ;; Zip archive configuration
 220
 221 (defcustom archive-zip-extract
 222   (if (and (not (executable-find "unzip"))
 223            (executable-find "pkunzip"))
 224       '("pkunzip" "-e" "-o-")
 225     '("unzip" "-qq" "-c"))
 226   "*Program and its options to run in order to extract a zip file member.
 227 Extraction should happen to standard output.  Archive and member name will
 228 be added."
 229   :type '(list (string :tag "Program")
 230                 (repeat :tag "Options"
 231                         :inline t
 232                         (string :format "%v")))
 233   :group 'archive-zip)
 234
 235 ;; For several reasons the latter behaviour is not desirable in general.
 236 ;; (1) It uses more disk space.  (2) Error checking is worse or non-
 237 ;; existent.  (3) It tends to do funny things with other systems' file
 238 ;; names.
 239
 240 (defcustom archive-zip-expunge
 241   (if (and (not (executable-find "zip"))
 242            (executable-find "pkzip"))
 243       '("pkzip" "-d")
 244     '("zip" "-d" "-q"))
 245   "*Program and its options to run in order to delete zip file members.
 246 Archive and member names will be added."
 247   :type '(list (string :tag "Program")
 248                 (repeat :tag "Options"
 249                         :inline t
 250                         (string :format "%v")))
 251   :group 'archive-zip)
 252
 253 (defcustom archive-zip-update
 254   (if (and (not (executable-find "zip"))
 255            (executable-find "pkzip"))
 256       '("pkzip" "-u" "-P")
 257     '("zip" "-q"))
 258   "*Program and its options to run in order to update a zip file member.
 259 Options should ensure that specified directory will be put into the zip
 260 file.  Archive and member name will be added."
 261   :type '(list (string :tag "Program")
 262                 (repeat :tag "Options"
 263                         :inline t
 264                         (string :format "%v")))
 265   :group 'archive-zip)
 266
 267 (defcustom archive-zip-update-case
 268   (if (and (not (executable-find "zip"))
 269            (executable-find "pkzip"))
 270       '("pkzip" "-u" "-P")
 271     '("zip" "-q" "-k"))
 272   "*Program and its options to run in order to update a case fiddled zip member.
 273 Options should ensure that specified directory will be put into the zip file.
 274 Archive and member name will be added."
 275   :type '(list (string :tag "Program")
 276                 (repeat :tag "Options"
 277                         :inline t
 278                         (string :format "%v")))
 279   :group 'archive-zip)
 280
 281 (defcustom archive-zip-case-fiddle t
 282   "*If non-nil then zip file members may be down-cased.
 283 This case fiddling will only happen for members created by a system
 284 that uses caseless file names."
 285   :type 'boolean
 286   :group 'archive-zip)
 287 ;; ------------------------------
 288 ;; Zoo archive configuration
 289
 290 (defcustom archive-zoo-extract
 291   '("zoo" "xpq")
 292   "*Program and its options to run in order to extract a zoo file member.
 293 Extraction should happen to standard output.  Archive and member name will
 294 be added."
 295   :type '(list (string :tag "Program")
 296                 (repeat :tag "Options"
 297                         :inline t
 298                         (string :format "%v")))
 299   :group 'archive-zoo)
 300
 301 (defcustom archive-zoo-expunge
 302   '("zoo" "DqPP")
 303   "*Program and its options to run in order to delete zoo file members.
 304 Archive and member names will be added."
 305   :type '(list (string :tag "Program")
 306                 (repeat :tag "Options"
 307                         :inline t
 308                         (string :format "%v")))
 309   :group 'archive-zoo)
 310
 311 (defcustom archive-zoo-write-file-member
 312   '("zoo" "a")
 313   "*Program and its options to run in order to update a zoo file member.
 314 Archive and member name will be added."
 315   :type '(list (string :tag "Program")
 316                 (repeat :tag "Options"
 317                         :inline t
 318                         (string :format "%v")))
 319   :group 'archive-zoo)
 320 ;; -------------------------------------------------------------------------
 321 ;; Section: Variables
 322
 323 (defvar archive-subtype nil "Symbol describing archive type.")
 324 (defvar archive-file-list-start nil "Position of first contents line.")
 325 (defvar archive-file-list-end nil "Position just after last contents line.")
 326 (defvar archive-proper-file-start nil "Position of real archive's start.")
 327 (defvar archive-read-only nil "Non-nil if the archive is read-only on disk.")
 328 (defvar archive-local-name nil "Name of local copy of remote archive.")
 329 (defvar archive-mode-map
 330   (let ((map (make-keymap)))
 331     (suppress-keymap map)
 332     (define-key map " " 'archive-next-line)
 333     (define-key map "a" 'archive-alternate-display)
 334     ;;(define-key map "c" 'archive-copy)
 335     (define-key map "d" 'archive-flag-deleted)
 336     (define-key map "\C-d" 'archive-flag-deleted)
 337     (define-key map "e" 'archive-extract)
 338     (define-key map "f" 'archive-extract)
 339     (define-key map "\C-m" 'archive-extract)
 340     (define-key map "g" 'revert-buffer)
 341     (define-key map "h" 'describe-mode)
 342     (define-key map "m" 'archive-mark)
 343     (define-key map "n" 'archive-next-line)
 344     (define-key map "\C-n" 'archive-next-line)
 345     (define-key map [down] 'archive-next-line)
 346     (define-key map "o" 'archive-extract-other-window)
 347     (define-key map "p" 'archive-previous-line)
 348     (define-key map "q" 'quit-window)
 349     (define-key map "\C-p" 'archive-previous-line)
 350     (define-key map [up] 'archive-previous-line)
 351     (define-key map "r" 'archive-rename-entry)
 352     (define-key map "u" 'archive-unflag)
 353     (define-key map "\M-\C-?" 'archive-unmark-all-files)
 354     (define-key map "v" 'archive-view)
 355     (define-key map "x" 'archive-expunge)
 356     (define-key map "\177" 'archive-unflag-backwards)
 357     (define-key map "E" 'archive-extract-other-window)
 358     (define-key map "M" 'archive-chmod-entry)
 359     (define-key map "G" 'archive-chgrp-entry)
 360     (define-key map "O" 'archive-chown-entry)
 361
 362     (if (fboundp 'command-remapping)
 363         (progn
 364           (define-key map [remap advertised-undo] 'archive-undo)
 365           (define-key map [remap undo] 'archive-undo))
 366       (substitute-key-definition 'advertised-undo 'archive-undo map global-map)
 367       (substitute-key-definition 'undo 'archive-undo map global-map))
 368
 369     (define-key map
 370       (if (featurep 'xemacs) 'button2 [mouse-2]) 'archive-extract)
 371
 372     (if (featurep 'xemacs)
 373         ()                              ; out of luck
 374
 375       (define-key map [menu-bar immediate]
 376         (cons "Immediate" (make-sparse-keymap "Immediate")))
 377       (define-key map [menu-bar immediate alternate]
 378         '(menu-item "Alternate Display" archive-alternate-display
 379           :enable (boundp (archive-name "alternate-display"))
 380           :help "Toggle alternate file info display"))
 381       (define-key map [menu-bar immediate view]
 382         '(menu-item "View This File" archive-view
 383           :help "Display file at cursor in View Mode"))
 384       (define-key map [menu-bar immediate display]
 385         '(menu-item "Display in Other Window" archive-display-other-window
 386           :help "Display file at cursor in another window"))
 387       (define-key map [menu-bar immediate find-file-other-window]
 388         '(menu-item "Find in Other Window" archive-extract-other-window
 389           :help "Edit file at cursor in another window"))
 390       (define-key map [menu-bar immediate find-file]
 391         '(menu-item "Find This File" archive-extract
 392           :help "Extract file at cursor and edit it"))
 393
 394       (define-key map [menu-bar mark]
 395         (cons "Mark" (make-sparse-keymap "Mark")))
 396       (define-key map [menu-bar mark unmark-all]
 397         '(menu-item "Unmark All" archive-unmark-all-files
 398           :help "Unmark all marked files"))
 399       (define-key map [menu-bar mark deletion]
 400         '(menu-item "Flag" archive-flag-deleted
 401           :help "Flag file at cursor for deletion"))
 402       (define-key map [menu-bar mark unmark]
 403         '(menu-item "Unflag" archive-unflag
 404           :help "Unmark file at cursor"))
 405       (define-key map [menu-bar mark mark]
 406         '(menu-item "Mark" archive-mark
 407           :help "Mark file at cursor"))
 408
 409       (define-key map [menu-bar operate]
 410         (cons "Operate" (make-sparse-keymap "Operate")))
 411       (define-key map [menu-bar operate chown]
 412         '(menu-item "Change Owner..." archive-chown-entry
 413           :enable (fboundp (archive-name "chown-entry"))
 414           :help "Change owner of marked files"))
 415       (define-key map [menu-bar operate chgrp]
 416         '(menu-item "Change Group..." archive-chgrp-entry
 417           :enable (fboundp (archive-name "chgrp-entry"))
 418           :help "Change group ownership of marked files"))
 419       (define-key map [menu-bar operate chmod]
 420         '(menu-item "Change Mode..." archive-chmod-entry
 421           :enable (fboundp (archive-name "chmod-entry"))
 422           :help "Change mode (permissions) of marked files"))
 423       (define-key map [menu-bar operate rename]
 424         '(menu-item "Rename to..." archive-rename-entry
 425           :enable (fboundp (archive-name "rename-entry"))
 426           :help "Rename marked files"))
 427       ;;(define-key map [menu-bar operate copy]
 428       ;;  '(menu-item "Copy to..." archive-copy))
 429       (define-key map [menu-bar operate expunge]
 430         '(menu-item "Expunge Marked Files" archive-expunge
 431           :help "Delete all flagged files from archive"))
 432       map))
 433   "Local keymap for archive mode listings.")
 434 (defvar archive-file-name-indent nil "Column where file names start.")
 435
 436 (defvar archive-remote nil "Non-nil if the archive is outside file system.")
 437 (make-variable-buffer-local 'archive-remote)
 438 (put 'archive-remote 'permanent-local t)
 439
 440 (defvar archive-member-coding-system nil "Coding-system of archive member.")
 441 (make-variable-buffer-local 'archive-member-coding-system)
 442
 443 (defvar archive-alternate-display nil
 444   "Non-nil when alternate information is shown.")
 445 (make-variable-buffer-local 'archive-alternate-display)
 446 (put 'archive-alternate-display 'permanent-local t)
 447
 448 (defvar archive-superior-buffer nil "In archive members, points to archive.")
 449 (put 'archive-superior-buffer 'permanent-local t)
 450
 451 (defvar archive-subfile-mode nil "Non-nil in archive member buffers.")
 452 (make-variable-buffer-local 'archive-subfile-mode)
 453 (put 'archive-subfile-mode 'permanent-local t)
 454
 455 (defvar archive-files nil
 456   "Vector of file descriptors.
 457 Each descriptor is a vector of the form
 458  [EXT-FILE-NAME INT-FILE-NAME CASE-FIDDLED MODE ...]")
 459 (make-variable-buffer-local 'archive-files)
 460
 461 ;; -------------------------------------------------------------------------
 462 ;; Section: Support functions.
 463
 464 (defsubst archive-name (suffix)
 465   (intern (concat "archive-" (symbol-name archive-subtype) "-" suffix)))
 466
 467 (defun archive-l-e (str &optional len)
 468   "Convert little endian string/vector STR to integer.
 469 Alternatively, STR may be a buffer position in the current buffer
 470 in which case a second argument, length LEN, should be supplied."
 471   (if (stringp str)
 472       (setq len (length str))
 473     (setq str (buffer-substring str (+ str len))))
 474   (let ((result 0)
 475         (i 0))
 476     (while (< i len)
 477       (setq i (1+ i)
 478             result (+ (ash result 8) (aref str (- len i)))))
 479     result))
 480
 481 (defun archive-int-to-mode (mode)
 482   "Turn an integer like 0700 (i.e., 448) into a mode string like -rwx------."
 483   ;; FIXME: merge with tar-grind-file-mode.
 484   (string
 485     (if (zerop (logand  8192 mode))
 486         (if (zerop (logand 16384 mode)) ?- ?d)
 487       ?c) ; completeness
 488     (if (zerop (logand   256 mode)) ?- ?r)
 489     (if (zerop (logand   128 mode)) ?- ?w)
 490     (if (zerop (logand    64 mode))
 491         (if (zerop (logand  1024 mode)) ?- ?S)
 492       (if (zerop (logand  1024 mode)) ?x ?s))
 493     (if (zerop (logand    32 mode)) ?- ?r)
 494     (if (zerop (logand    16 mode)) ?- ?w)
 495     (if (zerop (logand     8 mode))
 496         (if (zerop (logand  2048 mode)) ?- ?S)
 497       (if (zerop (logand  2048 mode)) ?x ?s))
 498     (if (zerop (logand     4 mode)) ?- ?r)
 499     (if (zerop (logand     2 mode)) ?- ?w)
 500     (if (zerop (logand     1 mode)) ?- ?x)))
 501
 502 (defun archive-calc-mode (oldmode newmode &optional error)
 503   "From the integer OLDMODE and the string NEWMODE calculate a new file mode.
 504 NEWMODE may be an octal number including a leading zero in which case it
 505 will become the new mode.\n
 506 NEWMODE may also be a relative specification like \"og-rwx\" in which case
 507 OLDMODE will be modified accordingly just like chmod(2) would have done.\n
 508 If optional third argument ERROR is non-nil an error will be signaled if
 509 the mode is invalid.  If ERROR is nil then nil will be returned."
 510   (cond ((string-match "^0[0-7]*$" newmode)
 511          (let ((result 0)
 512                (len (length newmode))
 513                (i 1))
 514            (while (< i len)
 515              (setq result (+ (lsh result 3) (aref newmode i) (- ?0))
 516                    i (1+ i)))
 517            (logior (logand oldmode 65024) result)))
 518         ((string-match "^\\([agou]+\\)\\([---+=]\\)\\([rwxst]+\\)$" newmode)
 519          (let ((who 0)
 520                (result oldmode)
 521                (op (aref newmode (match-beginning 2)))
 522                (bits 0)
 523                (i (match-beginning 3)))
 524            (while (< i (match-end 3))
 525              (let ((rwx (aref newmode i)))
 526                (setq bits (logior bits (cond ((= rwx ?r)  292)
 527                                              ((= rwx ?w)  146)
 528                                              ((= rwx ?x)   73)
 529                                              ((= rwx ?s) 3072)
 530                                              ((= rwx ?t)  512)))
 531                      i (1+ i))))
 532            (while (< who (match-end 1))
 533              (let* ((whoc (aref newmode who))
 534                     (whomask (cond ((= whoc ?a) 4095)
 535                                    ((= whoc ?u) 1472)
 536                                    ((= whoc ?g) 2104)
 537                                    ((= whoc ?o)    7))))
 538                (if (= op ?=)
 539                    (setq result (logand result (lognot whomask))))
 540                (if (= op ?-)
 541                    (setq result (logand result (lognot (logand whomask bits))))
 542                  (setq result (logior result (logand whomask bits)))))
 543              (setq who (1+ who)))
 544            result))
 545         (t
 546          (if error
 547              (error "Invalid mode specification: %s" newmode)))))
 548
 549 (defun archive-dosdate (date)
 550   "Stringify dos packed DATE record."
 551   (let ((year (+ 1980 (logand (ash date -9) 127)))
 552         (month (logand (ash date -5) 15))
 553         (day (logand date 31)))
 554     (if (or (> month 12) (< month 1))
 555         ""
 556       (format "%2d-%s-%d"
 557               day
 558               (aref ["Jan" "Feb" "Mar" "Apr" "May" "Jun"
 559                      "Jul" "Aug" "Sep" "Oct" "Nov" "Dec"] (1- month))
 560               year))))
 561
 562 (defun archive-dostime (time)
 563   "Stringify dos packed TIME record."
 564   (let ((hour (logand (ash time -11) 31))
 565         (minute (logand (ash time -5) 63))
 566         (second (* 2 (logand time 31)))) ; 2 seconds resolution
 567     (format "%02d:%02d:%02d" hour minute second)))
 568
 569 (defun archive-unixdate (low high)
 570   "Stringify Unix (LOW HIGH) date."
 571   (let ((str (current-time-string (cons high low))))
 572     (format "%s-%s-%s"
 573             (substring str 8 10)
 574             (substring str 4 7)
 575             (substring str 20 24))))
 576
 577 (defun archive-unixtime (low high)
 578   "Stringify Unix (LOW HIGH) time."
 579   (let ((str (current-time-string (cons high low))))
 580     (substring str 11 19)))
 581
 582 (defun archive-get-lineno ()
 583   (if (>= (point) archive-file-list-start)
 584       (count-lines archive-file-list-start
 585                    (save-excursion (beginning-of-line) (point)))
 586     0))
 587
 588 (defun archive-get-descr (&optional noerror)
 589   "Return the descriptor vector for file at point.
 590 Does not signal an error if optional argument NOERROR is non-nil."
 591   (let ((no (archive-get-lineno)))
 592     (if (and (>= (point) archive-file-list-start)
 593              (< no (length archive-files)))
 594         (let ((item (aref archive-files no)))
 595           (if (vectorp item)
 596               item
 597             (if (not noerror)
 598                 (error "Entry is not a regular member of the archive"))))
 599       (if (not noerror)
 600           (error "Line does not describe a member of the archive")))))
 601 ;; -------------------------------------------------------------------------
 602 ;; Section: the mode definition
 603
 604 ;;;###autoload
 605 (defun archive-mode (&optional force)
 606   "Major mode for viewing an archive file in a dired-like way.
 607 You can move around using the usual cursor motion commands.
 608 Letters no longer insert themselves.
 609 Type `e' to pull a file out of the archive and into its own buffer;
 610 or click mouse-2 on the file's line in the archive mode buffer.
 611
 612 If you edit a sub-file of this archive (as with the `e' command) and
 613 save it, the contents of that buffer will be saved back into the
 614 archive.
 615
 616 \\{archive-mode-map}"
 617   ;; This is not interactive because you shouldn't be turning this
 618   ;; mode on and off.  You can corrupt things that way.
 619   (if (zerop (buffer-size))
 620       ;; At present we cannot create archives from scratch
 621       (funcall default-major-mode)
 622     (if (and (not force) archive-files) nil
 623       (let* ((type (archive-find-type))
 624              (typename (capitalize (symbol-name type))))
 625         (kill-all-local-variables)
 626         (make-local-variable 'archive-subtype)
 627         (setq archive-subtype type)
 628
 629         ;; Buffer contains treated image of file before the file contents
 630         (make-local-variable 'revert-buffer-function)
 631         (setq revert-buffer-function 'archive-mode-revert)
 632         (auto-save-mode 0)
 633
 634         ;; Remote archives are not written by a hook.
 635         (if archive-remote nil
 636           (add-hook 'write-contents-functions 'archive-write-file nil t))
 637
 638         (make-local-variable 'require-final-newline)
 639         (setq require-final-newline nil)
 640         (make-local-variable 'local-enable-local-variables)
 641         (setq local-enable-local-variables nil)
 642
 643         ;; Prevent loss of data when saving the file.
 644         (make-local-variable 'file-precious-flag)
 645         (setq file-precious-flag t)
 646
 647         (make-local-variable 'archive-read-only)
 648         ;; Archives which are inside other archives and whose
 649         ;; names are invalid for this OS, can't be written.
 650         (setq archive-read-only
 651               (or (not (file-writable-p (buffer-file-name)))
 652                   (and archive-subfile-mode
 653                        (string-match file-name-invalid-regexp
 654                                      (aref archive-subfile-mode 0)))))
 655
 656         ;; Should we use a local copy when accessing from outside Emacs?
 657         (make-local-variable 'archive-local-name)
 658
 659         ;; An archive can contain another archive whose name is invalid
 660         ;; on local filesystem.  Treat such archives as remote.
 661         (or archive-remote
 662             (setq archive-remote
 663                   (or (string-match archive-remote-regexp (buffer-file-name))
 664                       (string-match file-name-invalid-regexp
 665                                     (buffer-file-name)))))
 666
 667         (setq major-mode 'archive-mode)
 668         (setq mode-name (concat typename "-Archive"))
 669         ;; Run archive-foo-mode-hook and archive-mode-hook
 670         (run-mode-hooks (archive-name "mode-hook") 'archive-mode-hook)
 671         (use-local-map archive-mode-map))
 672
 673       (make-local-variable 'archive-proper-file-start)
 674       (make-local-variable 'archive-file-list-start)
 675       (make-local-variable 'archive-file-list-end)
 676       (make-local-variable 'archive-file-name-indent)
 677       (archive-summarize nil)
 678       (setq buffer-read-only t))))
 679
 680 ;; Archive mode is suitable only for specially formatted data.
 681 (put 'archive-mode 'mode-class 'special)
 682
 683 (let ((item1 '(archive-subfile-mode " Archive")))
 684   (or (member item1 minor-mode-alist)
 685       (setq minor-mode-alist (cons item1 minor-mode-alist))))
 686 ;; -------------------------------------------------------------------------
 687 (defun archive-find-type ()
 688   (widen)
 689   (goto-char (point-min))
 690   ;; The funny [] here make it unlikely that the .elc file will be treated
 691   ;; as an archive by other software.
 692   (let (case-fold-search)
 693     (cond ((looking-at "[P]K\003\004") 'zip)
 694           ((looking-at "..-l[hz][0-9ds]-") 'lzh)
 695           ((looking-at "....................[\334]\247\304\375") 'zoo)
 696           ((and (looking-at "\C-z")     ; signature too simple, IMHO
 697                 (string-match "\\.[aA][rR][cC]$"
 698                               (or buffer-file-name (buffer-name))))
 699            'arc)
 700           (t (error "Buffer format not recognized")))))
 701 ;; -------------------------------------------------------------------------
 702 (defun archive-summarize (&optional shut-up)
 703   "Parse the contents of the archive file in the current buffer.
 704 Place a dired-like listing on the front;
 705 then narrow to it, so that only that listing
 706 is visible (and the real data of the buffer is hidden).
 707 Optional argument SHUT-UP, if non-nil, means don't print messages
 708 when parsing the archive."
 709   (widen)
 710   (set-buffer-multibyte nil)
 711   (let ((inhibit-read-only t))
 712     (or shut-up
 713         (message "Parsing archive file..."))
 714     (buffer-disable-undo (current-buffer))
 715     (setq archive-files (funcall (archive-name "summarize")))
 716     (or shut-up
 717         (message "Parsing archive file...done."))
 718     (setq archive-proper-file-start (point-marker))
 719     (narrow-to-region (point-min) (point))
 720     (set-buffer-modified-p nil)
 721     (buffer-enable-undo))
 722   (goto-char archive-file-list-start)
 723   (archive-next-line 0))
 724
 725 (defun archive-resummarize ()
 726   "Recreate the contents listing of an archive."
 727   (let ((modified (buffer-modified-p))
 728         (no (archive-get-lineno))
 729         (inhibit-read-only t))
 730     (widen)
 731     (delete-region (point-min) archive-proper-file-start)
 732     (archive-summarize t)
 733     (restore-buffer-modified-p modified)
 734     (goto-char archive-file-list-start)
 735     (archive-next-line no)))
 736
 737 (defun archive-summarize-files (files)
 738   "Insert a description of a list of files annotated with proper mouse face."
 739   (setq archive-file-list-start (point-marker))
 740   (setq archive-file-name-indent (if files (aref (car files) 1) 0))
 741   ;; We don't want to do an insert for each element since that takes too
 742   ;; long when the archive -- which has to be moved in memory -- is large.
 743   (insert
 744    (apply
 745     (function concat)
 746     (mapcar
 747      (lambda (fil)
 748        ;; Using `concat' here copies the text also, so we can add
 749        ;; properties without problems.
 750        (let ((text (concat (aref fil 0) "\n")))
 751          (if (featurep 'xemacs)
 752              ()                         ; out of luck
 753            (add-text-properties
 754             (aref fil 1) (aref fil 2)
 755             '(mouse-face highlight
 756               help-echo "mouse-2: extract this file into a buffer")
 757             text))
 758          text))
 759      files)))
 760   (setq archive-file-list-end (point-marker)))
 761
 762 (defun archive-alternate-display ()
 763   "Toggle alternative display.
 764 To avoid very long lines archive mode does not show all information.
 765 This function changes the set of information shown for each files."
 766   (interactive)
 767   (setq archive-alternate-display (not archive-alternate-display))
 768   (archive-resummarize))
 769 ;; -------------------------------------------------------------------------
 770 ;; Section: Local archive copy handling
 771
 772 (defun archive-unique-fname (fname dir)
 773   "Make sure a file FNAME can be created uniquely in directory DIR.
 774
 775 If FNAME can be uniquely created in DIR, it is returned unaltered.
 776 If FNAME is something our underlying filesystem can't grok, or if another
 777 file by that name already exists in DIR, a unique new name is generated
 778 using `make-temp-file', and the generated name is returned."
 779   (let ((fullname (expand-file-name fname dir))
 780         (alien (string-match file-name-invalid-regexp fname)))
 781     (if (or alien (file-exists-p fullname))
 782         (make-temp-file
 783          (expand-file-name
 784           (if (if (fboundp 'msdos-long-file-names)
 785                   (not (msdos-long-file-names)))
 786               "am"
 787             "arc-mode.")
 788           dir))
 789       fullname)))
 790
 791 (defun archive-maybe-copy (archive)
 792   (let ((coding-system-for-write 'no-conversion))
 793     (if archive-remote
 794         (let ((start (point-max))
 795               ;; Sometimes ARCHIVE is invalid while its actual name, as
 796               ;; recorded in its parent archive, is not.  For example, an
 797               ;; archive bar.zip inside another archive foo.zip gets a name
 798               ;; "foo.zip:bar.zip", which is invalid on DOS/Windows.
 799               ;; So use the actual name if available.
 800               (archive-name
 801                (or (and archive-subfile-mode (aref archive-subfile-mode 0))
 802                    archive)))
 803           (setq archive-local-name
 804                 (archive-unique-fname archive-name archive-tmpdir))
 805           ;; Maked sure all the leading directories in
 806           ;; archive-local-name exist under archive-tmpdir, so that
 807           ;; the directory structure recorded in the archive is
 808           ;; reconstructed in the temporary directory.
 809           (make-directory (file-name-directory archive-local-name) t)
 810           (save-restriction
 811             (widen)
 812             (write-region start (point-max) archive-local-name nil 'nomessage))
 813           archive-local-name)
 814       (if (buffer-modified-p) (save-buffer))
 815       archive)))
 816
 817 (defun archive-maybe-update (unchanged)
 818   (if archive-remote
 819       (let ((name archive-local-name)
 820             (modified (buffer-modified-p))
 821             (coding-system-for-read 'no-conversion)
 822             (lno (archive-get-lineno))
 823             (inhibit-read-only t))
 824         (if unchanged nil
 825           (setq archive-files nil)
 826           (erase-buffer)
 827           (insert-file-contents name)
 828           (archive-mode t)
 829           (goto-char archive-file-list-start)
 830           (archive-next-line lno))
 831         (archive-delete-local name)
 832         (if (not unchanged)
 833             (message
 834              "Buffer `%s' must be saved for changes to take effect"
 835              (buffer-name (current-buffer))))
 836         (set-buffer-modified-p (or modified (not unchanged))))))
 837
 838 (defun archive-delete-local (name)
 839   "Delete file NAME and its parents up to and including `archive-tmpdir'."
 840   (let ((again t)
 841         (top (directory-file-name (file-name-as-directory archive-tmpdir))))
 842     (condition-case nil
 843         (delete-file name)
 844       (error nil))
 845     (while again
 846       (setq name (directory-file-name (file-name-directory name)))
 847       (condition-case nil
 848           (delete-directory name)
 849         (error nil))
 850       (if (string= name top) (setq again nil)))))
 851 ;; -------------------------------------------------------------------------
 852 ;; Section: Member extraction
 853
 854 (defun archive-file-name-handler (op &rest args)
 855   (or (eq op 'file-exists-p)
 856       (let ((file-name-handler-alist nil))
 857         (apply op args))))
 858
 859 (defun archive-set-buffer-as-visiting-file (filename)
 860   "Set the current buffer as if it were visiting FILENAME."
 861   (save-excursion
 862     (goto-char (point-min))
 863     (let ((coding
 864            (or coding-system-for-read
 865                (and set-auto-coding-function
 866                     (save-excursion
 867                       (funcall set-auto-coding-function
 868                                filename (- (point-max) (point-min)))))
 869                ;; dos-w32.el defines find-operation-coding-system for
 870                ;; DOS/Windows systems which preserves the coding-system
 871                ;; of existing files.  We want it to act here as if the
 872                ;; extracted file existed.
 873                (let ((file-name-handler-alist
 874                       '(("" . archive-file-name-handler))))
 875                  (car (find-operation-coding-system 'insert-file-contents
 876                                                     filename t))))))
 877       (if (and (not coding-system-for-read)
 878                (not enable-multibyte-characters))
 879           (setq coding
 880                 (coding-system-change-text-conversion coding 'raw-text)))
 881       (if (and coding
 882                (not (eq coding 'no-conversion)))
 883           (decode-coding-region (point-min) (point-max) coding)
 884         (setq last-coding-system-used coding))
 885       (set-buffer-modified-p nil)
 886       (kill-local-variable 'buffer-file-coding-system)
 887       (after-insert-file-set-coding (- (point-max) (point-min))))))
 888
 889 (define-obsolete-function-alias 'archive-mouse-extract 'archive-extract "22.1")
 890
 891 (defun archive-extract (&optional other-window-p event)
 892   "In archive mode, extract this entry of the archive into its own buffer."
 893   (interactive (list nil last-input-event))
 894   (if event (posn-set-point (event-end event)))
 895   (let* ((view-p (eq other-window-p 'view))
 896          (descr (archive-get-descr))
 897          (ename (aref descr 0))
 898          (iname (aref descr 1))
 899          (archive-buffer (current-buffer))
 900          (arcdir default-directory)
 901          (archive (buffer-file-name))
 902          (arcname (file-name-nondirectory archive))
 903          (bufname (concat (file-name-nondirectory iname) " (" arcname ")"))
 904          (extractor (archive-name "extract"))
 905          ;; Members with file names which aren't valid for the
 906          ;; underlying filesystem, are treated as read-only.
 907          (read-only-p (or archive-read-only
 908                           view-p
 909                           (string-match file-name-invalid-regexp ename)))
 910          (arcfilename (expand-file-name (concat arcname ":" iname)))
 911          (buffer (get-buffer bufname))
 912          (just-created nil))
 913       (if (and buffer
 914                (string= (buffer-file-name buffer) arcfilename))
 915           nil
 916         (setq archive (archive-maybe-copy archive))
 917         (setq bufname (generate-new-buffer-name bufname))
 918         (setq buffer (get-buffer-create bufname))
 919         (setq just-created t)
 920         (with-current-buffer buffer
 921           (setq buffer-file-name arcfilename)
 922           (setq buffer-file-truename
 923                 (abbreviate-file-name buffer-file-name))
 924           ;; Set the default-directory to the dir of the superior buffer.
 925           (setq default-directory arcdir)
 926           (make-local-variable 'archive-superior-buffer)
 927           (setq archive-superior-buffer archive-buffer)
 928           (add-hook 'write-file-functions 'archive-write-file-member nil t)
 929           (setq archive-subfile-mode descr)
 930           (if (and
 931                (null
 932                 (let (;; We may have to encode file name arguement for
 933                       ;; external programs.
 934                       (coding-system-for-write
 935                        (and enable-multibyte-characters
 936                             file-name-coding-system))
 937                       ;; We read an archive member by no-conversion at
 938                       ;; first, then decode appropriately by calling
 939                       ;; archive-set-buffer-as-visiting-file later.
 940                       (coding-system-for-read 'no-conversion))
 941                   (condition-case err
 942                       (if (fboundp extractor)
 943                           (funcall extractor archive ename)
 944                         (archive-*-extract archive ename
 945                                            (symbol-value extractor)))
 946                     (error
 947                      (ding (message "%s" (error-message-string err)))
 948                      nil))))
 949                just-created)
 950               (progn
 951                 (set-buffer-modified-p nil)
 952                 (kill-buffer buffer))
 953             (archive-set-buffer-as-visiting-file ename)
 954             (goto-char (point-min))
 955             (rename-buffer bufname)
 956             (setq buffer-read-only read-only-p)
 957             (setq buffer-undo-list nil)
 958             (set-buffer-modified-p nil)
 959             (setq buffer-saved-size (buffer-size))
 960             (normal-mode)
 961             ;; Just in case an archive occurs inside another archive.
 962             (when (derived-mode-p 'archive-mode)
 963               (setq archive-remote t)
 964               (if read-only-p (setq archive-read-only t))
 965               ;; We will write out the archive ourselves if it is
 966               ;; part of another archive.
 967               (remove-hook 'write-contents-functions 'archive-write-file t))
 968             (run-hooks 'archive-extract-hooks)
 969             (if archive-read-only
 970                 (message "Note: altering this archive is not implemented."))))
 971         (archive-maybe-update t))
 972       (or (not (buffer-name buffer))
 973           (cond
 974            (view-p (view-buffer buffer (and just-created 'kill-buffer)))
 975            ((eq other-window-p 'display) (display-buffer buffer))
 976            (other-window-p (switch-to-buffer-other-window buffer))
 977            (t (switch-to-buffer buffer))))))
 978
 979 (defun archive-*-extract (archive name command)
 980   (let* ((default-directory (file-name-as-directory archive-tmpdir))
 981          (tmpfile (expand-file-name (file-name-nondirectory name)
 982                                     default-directory))
 983          exit-status success)
 984     (make-directory (directory-file-name default-directory) t)
 985     (setq exit-status
 986           (apply 'call-process
 987                  (car command)
 988                  nil
 989                  nil
 990                  nil
 991                  (append (cdr command) (list archive name))))
 992     (cond ((and (numberp exit-status) (= exit-status 0))
 993            (if (not (file-exists-p tmpfile))
 994                (ding (message "`%s': no such file or directory" tmpfile))
 995              (insert-file-contents tmpfile)
 996              (setq success t)))
 997           ((numberp exit-status)
 998            (ding
 999             (message "`%s' exited with status %d" (car command) exit-status)))
1000           ((stringp exit-status)
1001            (ding (message "`%s' aborted: %s" (car command) exit-status)))
1002           (t
1003            (ding (message "`%s' failed" (car command)))))
1004     (archive-delete-local tmpfile)
1005     success))
1006
1007 (defun archive-extract-by-stdout (archive name command)
1008   (apply 'call-process
1009          (car command)
1010          nil
1011          t
1012          nil
1013          (append (cdr command) (list archive name))))
1014
1015 (defun archive-extract-other-window ()
1016   "In archive mode, find this member in another window."
1017   (interactive)
1018   (archive-extract t))
1019
1020 (defun archive-display-other-window ()
1021   "In archive mode, display this member in another window."
1022   (interactive)
1023   (archive-extract 'display))
1024
1025 (defun archive-view ()
1026   "In archive mode, view the member on this line."
1027   (interactive)
1028   (archive-extract 'view))
1029
1030 (defun archive-add-new-member (arcbuf name)
1031   "Add current buffer to the archive in ARCBUF naming it NAME."
1032   (interactive
1033    (list (get-buffer
1034           (read-buffer "Buffer containing archive: "
1035                        ;; Find first archive buffer and suggest that
1036                        (let ((bufs (buffer-list)))
1037                          (while (and bufs
1038                                      (not (with-current-buffer (car bufs)
1039                                             (derived-mode-p 'archive-mode))))
1040                            (setq bufs (cdr bufs)))
1041                          (if bufs
1042                              (car bufs)
1043                            (error "There are no archive buffers")))
1044                        t))
1045          (read-string "File name in archive: "
1046                       (if buffer-file-name
1047                           (file-name-nondirectory buffer-file-name)
1048                         ""))))
1049   (with-current-buffer arcbuf
1050     (or (eq major-mode 'archive-mode)
1051         (error "Buffer is not an archive buffer"))
1052     (if archive-read-only
1053         (error "Archive is read-only")))
1054   (if (eq arcbuf (current-buffer))
1055       (error "An archive buffer cannot be added to itself"))
1056   (if (string= name "")
1057       (error "Archive members may not be given empty names"))
1058   (let ((func (with-current-buffer arcbuf
1059                 (archive-name "add-new-member")))
1060         (membuf (current-buffer)))
1061     (if (fboundp func)
1062         (with-current-buffer arcbuf
1063           (funcall func buffer-file-name membuf name))
1064       (error "Adding a new member is not supported for this archive type"))))
1065 ;; -------------------------------------------------------------------------
1066 ;; Section: IO stuff
1067
1068 (defun archive-write-file-member ()
1069   (save-excursion
1070     (save-restriction
1071       (message "Updating archive...")
1072       (widen)
1073       (let ((writer  (with-current-buffer archive-superior-buffer
1074                        (archive-name "write-file-member")))
1075             (archive (with-current-buffer archive-superior-buffer
1076                        (archive-maybe-copy (buffer-file-name)))))
1077         (if (fboundp writer)
1078             (funcall writer archive archive-subfile-mode)
1079           (archive-*-write-file-member archive
1080                                        archive-subfile-mode
1081                                        (symbol-value writer)))
1082         (set-buffer-modified-p nil)
1083         (message "Updating archive...done"))
1084       (set-buffer archive-superior-buffer)
1085       (if (not archive-remote) (revert-buffer) (archive-maybe-update nil))))
1086   ;; Restore the value of last-coding-system-used, so that basic-save-buffer
1087   ;; won't reset the coding-system of this archive member.
1088   (if (local-variable-p 'archive-member-coding-system)
1089       (setq last-coding-system-used archive-member-coding-system))
1090   t)
1091
1092 (defun archive-*-write-file-member (archive descr command)
1093   (let* ((ename (aref descr 0))
1094          (tmpfile (expand-file-name ename archive-tmpdir))
1095          (top (directory-file-name (file-name-as-directory archive-tmpdir)))
1096          (default-directory (file-name-as-directory top)))
1097     (unwind-protect
1098         (progn
1099           (make-directory (file-name-directory tmpfile) t)
1100           ;; If the member is itself an archive, write it without
1101           ;; the dired-like listing we created.
1102           (if (eq major-mode 'archive-mode)
1103               (archive-write-file tmpfile)
1104             (write-region (point-min) (point-max) tmpfile nil 'nomessage))
1105           ;; basic-save-buffer needs last-coding-system-used to have
1106           ;; the value used to write the file, so save it before any
1107           ;; further processing clobbers it (we restore it in
1108           ;; archive-write-file-member, above).
1109           (setq archive-member-coding-system last-coding-system-used)
1110           (if (aref descr 3)
1111               ;; Set the file modes, but make sure we can read it.
1112               (set-file-modes tmpfile (logior ?\400 (aref descr 3))))
1113           (if enable-multibyte-characters
1114               (setq ename
1115                     (encode-coding-string ename file-name-coding-system)))
1116           (let ((exitcode (apply 'call-process
1117                                  (car command)
1118                                  nil
1119                                  nil
1120                                  nil
1121                                  (append (cdr command) (list archive ename)))))
1122             (if (equal exitcode 0)
1123                 nil
1124               (error "Updating was unsuccessful (%S)" exitcode))))
1125       (archive-delete-local tmpfile))))
1126
1127 (defun archive-write-file (&optional file)
1128   (save-excursion
1129     (let ((coding-system-for-write 'no-conversion))
1130       (write-region archive-proper-file-start (point-max)
1131                     (or file buffer-file-name) nil t)
1132       (set-buffer-modified-p nil))
1133     t))
1134 ;; -------------------------------------------------------------------------
1135 ;; Section: Marking and unmarking.
1136
1137 (defun archive-flag-deleted (p &optional type)
1138   "In archive mode, mark this member to be deleted from the archive.
1139 With a prefix argument, mark that many files."
1140   (interactive "p")
1141   (or type (setq type ?D))
1142   (beginning-of-line)
1143   (let ((sign (if (>= p 0) +1 -1))
1144         (modified (buffer-modified-p))
1145         (inhibit-read-only t))
1146     (while (not (zerop p))
1147       (if (archive-get-descr t)
1148           (progn
1149             (delete-char 1)
1150             (insert type)))
1151       (forward-line sign)
1152       (setq p (- p sign)))
1153     (restore-buffer-modified-p modified))
1154   (archive-next-line 0))
1155
1156 (defun archive-unflag (p)
1157   "In archive mode, un-mark this member if it is marked to be deleted.
1158 With a prefix argument, un-mark that many files forward."
1159   (interactive "p")
1160   (archive-flag-deleted p ?\s))
1161
1162 (defun archive-unflag-backwards (p)
1163   "In archive mode, un-mark this member if it is marked to be deleted.
1164 With a prefix argument, un-mark that many members backward."
1165   (interactive "p")
1166   (archive-flag-deleted (- p) ?\s))
1167
1168 (defun archive-unmark-all-files ()
1169   "Remove all marks."
1170   (interactive)
1171   (let ((modified (buffer-modified-p))
1172         (inhibit-read-only t))
1173     (save-excursion
1174       (goto-char archive-file-list-start)
1175       (while (< (point) archive-file-list-end)
1176         (or (= (following-char) ?\s)
1177             (progn (delete-char 1) (insert ?\s)))
1178         (forward-line 1)))
1179     (restore-buffer-modified-p modified)))
1180
1181 (defun archive-mark (p)
1182   "In archive mode, mark this member for group operations.
1183 With a prefix argument, mark that many members.
1184 Use \\[archive-unmark-all-files] to remove all marks."
1185   (interactive "p")
1186   (archive-flag-deleted p ?*))
1187
1188 (defun archive-get-marked (mark &optional default)
1189   (let (files)
1190     (save-excursion
1191       (goto-char archive-file-list-start)
1192       (while (< (point) archive-file-list-end)
1193         (if (= (following-char) mark)
1194             (setq files (cons (archive-get-descr) files)))
1195         (forward-line 1)))
1196     (or (nreverse files)
1197         (and default
1198              (list (archive-get-descr))))))
1199 ;; -------------------------------------------------------------------------
1200 ;; Section: Operate
1201
1202 (defun archive-next-line (p)
1203   (interactive "p")
1204   (forward-line p)
1205   (or (eobp)
1206       (forward-char archive-file-name-indent)))
1207
1208 (defun archive-previous-line (p)
1209   (interactive "p")
1210   (archive-next-line (- p)))
1211
1212 (defun archive-chmod-entry (new-mode)
1213   "Change the protection bits associated with all marked or this member.
1214 The new protection bits can either be specified as an octal number or
1215 as a relative change like \"g+rw\" as for chmod(2)."
1216   (interactive "sNew mode (octal or relative): ")
1217   (if archive-read-only (error "Archive is read-only"))
1218   (let ((func (archive-name "chmod-entry")))
1219     (if (fboundp func)
1220         (progn
1221           (funcall func new-mode (archive-get-marked ?* t))
1222           (archive-resummarize))
1223       (error "Setting mode bits is not supported for this archive type"))))
1224
1225 (defun archive-chown-entry (new-uid)
1226   "Change the owner of all marked or this member."
1227   (interactive "nNew uid: ")
1228   (if archive-read-only (error "Archive is read-only"))
1229   (let ((func (archive-name "chown-entry")))
1230     (if (fboundp func)
1231         (progn
1232           (funcall func new-uid (archive-get-marked ?* t))
1233           (archive-resummarize))
1234       (error "Setting owner is not supported for this archive type"))))
1235
1236 (defun archive-chgrp-entry (new-gid)
1237   "Change the group of all marked or this member."
1238   (interactive "nNew gid: ")
1239   (if archive-read-only (error "Archive is read-only"))
1240   (let ((func (archive-name "chgrp-entry")))
1241     (if (fboundp func)
1242         (progn
1243           (funcall func new-gid (archive-get-marked ?* t))
1244           (archive-resummarize))
1245       (error "Setting group is not supported for this archive type"))))
1246
1247 (defun archive-expunge ()
1248   "Do the flagged deletions."
1249   (interactive)
1250   (let (files)
1251     (save-excursion
1252       (goto-char archive-file-list-start)
1253       (while (< (point) archive-file-list-end)
1254         (if (= (following-char) ?D)
1255             (setq files (cons (aref (archive-get-descr) 0) files)))
1256         (forward-line 1)))
1257     (setq files (nreverse files))
1258     (and files
1259          (or (not archive-read-only)
1260              (error "Archive is read-only"))
1261          (or (yes-or-no-p (format "Really delete %d member%s? "
1262                                   (length files)
1263                                   (if (null (cdr files)) "" "s")))
1264              (error "Operation aborted"))
1265          (let ((archive (archive-maybe-copy (buffer-file-name)))
1266                (expunger (archive-name "expunge")))
1267            (if (fboundp expunger)
1268                (funcall expunger archive files)
1269              (archive-*-expunge archive files (symbol-value expunger)))
1270            (archive-maybe-update nil)
1271            (if archive-remote
1272                (archive-resummarize)
1273              (revert-buffer))))))
1274
1275 (defun archive-*-expunge (archive files command)
1276   (apply 'call-process
1277          (car command)
1278          nil
1279          nil
1280          nil
1281          (append (cdr command) (cons archive files))))
1282
1283 (defun archive-rename-entry (newname)
1284   "Change the name associated with this entry in the archive file."
1285   (interactive "sNew name: ")
1286   (if archive-read-only (error "Archive is read-only"))
1287   (if (string= newname "")
1288       (error "Archive members may not be given empty names"))
1289   (let ((func (archive-name "rename-entry"))
1290         (descr (archive-get-descr)))
1291     (if (fboundp func)
1292         (progn
1293           (funcall func
1294                    (if enable-multibyte-characters
1295                        (encode-coding-string newname file-name-coding-system)
1296                      newname)
1297                    descr)
1298           (archive-resummarize))
1299       (error "Renaming is not supported for this archive type"))))
1300
1301 ;; Revert the buffer and recompute the dired-like listing.
1302 (defun archive-mode-revert (&optional no-auto-save no-confirm)
1303   (let ((no (archive-get-lineno)))
1304     (setq archive-files nil)
1305     (let ((revert-buffer-function nil)
1306           (coding-system-for-read 'no-conversion))
1307       (set-buffer-multibyte nil)
1308       (revert-buffer t t))
1309     (archive-mode)
1310     (goto-char archive-file-list-start)
1311     (archive-next-line no)))
1312
1313 (defun archive-undo ()
1314   "Undo in an archive buffer.
1315 This doesn't recover lost files, it just undoes changes in the buffer itself."
1316   (interactive)
1317   (let ((inhibit-read-only t))
1318     (undo)))
1319 ;; -------------------------------------------------------------------------
1320 ;; Section: Arc Archives
1321
1322 (defun archive-arc-summarize ()
1323   (let ((p 1)
1324         (totalsize 0)
1325         (maxlen 8)
1326         files
1327         visual)
1328     (while (and (< (+ p 29) (point-max))
1329                 (= (char-after p) ?\C-z)
1330                 (> (char-after (1+ p)) 0))
1331       (let* ((namefld (buffer-substring (+ p 2) (+ p 2 13)))
1332              (fnlen   (or (string-match "\0" namefld) 13))
1333              (efnname (substring namefld 0 fnlen))
1334              (csize   (archive-l-e (+ p 15) 4))
1335              (moddate (archive-l-e (+ p 19) 2))
1336              (modtime (archive-l-e (+ p 21) 2))
1337              (ucsize  (archive-l-e (+ p 25) 4))
1338              (fiddle  (string= efnname (upcase efnname)))
1339              (ifnname (if fiddle (downcase efnname) efnname))
1340              (text    (format "  %8d  %-11s  %-8s  %s"
1341                               ucsize
1342                               (archive-dosdate moddate)
1343                               (archive-dostime modtime)
1344                               ifnname)))
1345         (setq maxlen (max maxlen fnlen)
1346               totalsize (+ totalsize ucsize)
1347               visual (cons (vector text
1348                                    (- (length text) (length ifnname))
1349                                    (length text))
1350                            visual)
1351               files (cons (vector efnname ifnname fiddle nil (1- p))
1352                           files)
1353               p (+ p 29 csize))))
1354     (goto-char (point-min))
1355     (let ((dash (concat "- --------  -----------  --------  "
1356                         (make-string maxlen ?-)
1357                         "\n")))
1358       (insert "M   Length  Date         Time      File\n"
1359               dash)
1360       (archive-summarize-files (nreverse visual))
1361       (insert dash
1362               (format "  %8d                         %d file%s"
1363                       totalsize
1364                       (length files)
1365                       (if (= 1 (length files)) "" "s"))
1366               "\n"))
1367     (apply 'vector (nreverse files))))
1368
1369 (defun archive-arc-rename-entry (newname descr)
1370   (if (string-match "[:\\\\/]" newname)
1371       (error "File names in arc files must not contain a directory component"))
1372   (if (> (length newname) 12)
1373       (error "File names in arc files are limited to 12 characters"))
1374   (let ((name (concat newname (substring "\0\0\0\0\0\0\0\0\0\0\0\0\0"
1375                                          (length newname))))
1376         (inhibit-read-only t))
1377     (save-restriction
1378       (save-excursion
1379         (widen)
1380         (set-buffer-multibyte nil)
1381         (goto-char (+ archive-proper-file-start (aref descr 4) 2))
1382         (delete-char 13)
1383         (insert name)))))
1384 ;; -------------------------------------------------------------------------
1385 ;; Section: Lzh Archives
1386
1387 (defun archive-lzh-summarize ()
1388   (let ((p 1)
1389         (totalsize 0)
1390         (maxlen 8)
1391         files
1392         visual)
1393     (while (progn (goto-char p)         ;beginning of a base header.
1394                   (looking-at "\\(.\\|\n\\)\\(.\\|\n\\)-l[hz][0-9ds]-"))
1395       (let* ((hsize   (char-after p))   ;size of the base header (level 0 and 1)
1396              (csize   (archive-l-e (+ p 7) 4)) ;size of a compressed file to follow (level 0 and 2),
1397                                         ;size of extended headers + the compressed file to follow (level 1).
1398              (ucsize  (archive-l-e (+ p 11) 4)) ;size of an uncompressed file.
1399              (time1   (archive-l-e (+ p 15) 2)) ;date/time (MSDOS format in level 0, 1 headers
1400              (time2   (archive-l-e (+ p 17) 2)) ;and UNIX format in level 2 header.)
1401              (hdrlvl  (char-after (+ p 20))) ;header level
1402              thsize             ;total header size (base + extensions)
1403              fnlen efnname fiddle ifnname width p2
1404              neh        ;beginning of next extension header (level 1 and 2)
1405              mode modestr uid gid text dir prname
1406              gname uname modtime moddate)
1407         (if (= hdrlvl 3) (error "can't handle lzh level 3 header type"))
1408         (when (or (= hdrlvl 0) (= hdrlvl 1))
1409           (setq fnlen   (char-after (+ p 21))) ;filename length
1410           (setq efnname (let ((str (buffer-substring (+ p 22) (+ p 22 fnlen)))) ;filename from offset 22
1411                         (if file-name-coding-system
1412                             (decode-coding-string str file-name-coding-system)
1413                           (string-as-multibyte str))))
1414           (setq p2      (+ p 22 fnlen))) ;
1415         (if (= hdrlvl 1)
1416             (setq neh (+ p2 3))         ;specific to level 1 header
1417           (if (= hdrlvl 2)
1418               (setq neh (+ p 24))))     ;specific to level 2 header
1419         (if neh         ;if level 1 or 2 we expect extension headers to follow
1420             (let* ((ehsize (archive-l-e neh 2)) ;size of the extension header
1421                    (etype (char-after (+ neh 2)))) ;extension type
1422               (while (not (= ehsize 0))
1423                   (cond
1424                  ((= etype 1)   ;file name
1425                   (let ((i (+ neh 3)))
1426                     (while (< i (+ neh ehsize))
1427                       (setq efnname (concat efnname (char-to-string (char-after i))))
1428                       (setq i (1+ i)))))
1429                  ((= etype 2)   ;directory name
1430                   (let ((i (+ neh 3)))
1431                     (while (< i (+ neh ehsize))
1432                                     (setq dir (concat dir
1433                                                        (if (= (char-after i)
1434                                                               255)
1435                                                            "/"
1436                                                          (char-to-string
1437                                                           (char-after i)))))
1438                                     (setq i (1+ i)))))
1439                  ((= etype 80)          ;Unix file permission
1440                   (setq mode (archive-l-e (+ neh 3) 2)))
1441                  ((= etype 81)          ;UNIX file group/user ID
1442                   (progn (setq uid (archive-l-e (+ neh 3) 2))
1443                          (setq gid (archive-l-e (+ neh 5) 2))))
1444                  ((= etype 82)          ;UNIX file group name
1445                   (let ((i (+ neh 3)))
1446                     (while (< i (+ neh ehsize))
1447                       (setq gname (concat gname (char-to-string (char-after i))))
1448                       (setq i (1+ i)))))
1449                  ((= etype 83)          ;UNIX file user name
1450                   (let ((i (+ neh 3)))
1451                     (while (< i (+ neh ehsize))
1452                       (setq uname (concat uname (char-to-string (char-after i))))
1453                       (setq i (1+ i)))))
1454                    )
1455                 (setq neh (+ neh ehsize))
1456                 (setq ehsize (archive-l-e neh 2))
1457                 (setq etype (char-after (+ neh 2))))
1458               ;;get total header size for level 1 and 2 headers
1459               (setq thsize (- neh p))))
1460         (if (= hdrlvl 0)  ;total header size
1461             (setq thsize hsize))
1462         (setq fiddle  (if efnname (string= efnname (upcase efnname))))
1463         (setq ifnname (if fiddle (downcase efnname) efnname))
1464         (setq prname (if dir (concat dir ifnname) ifnname))
1465         (setq width (if prname (string-width prname) 0))
1466         (setq modestr (if mode (archive-int-to-mode mode) "??????????"))
1467         (setq moddate (if (= hdrlvl 2)
1468                           (archive-unixdate time1 time2) ;level 2 header in UNIX format
1469                         (archive-dosdate time2))) ;level 0 and 1 header in DOS format
1470         (setq modtime (if (= hdrlvl 2)
1471                           (archive-unixtime time1 time2)
1472                         (archive-dostime time1)))
1473         (setq text    (if archive-alternate-display
1474                           (format "  %8d  %5S  %5S  %s"
1475                                   ucsize
1476                                   (or uid "?")
1477                                   (or gid "?")
1478                                   ifnname)
1479                         (format "  %10s  %8d  %-11s  %-8s  %s"
1480                                 modestr
1481                                 ucsize
1482                                 moddate
1483                                 modtime
1484                                 prname)))
1485         (setq maxlen (max maxlen width)
1486               totalsize (+ totalsize ucsize)
1487               visual (cons (vector text
1488                                    (- (length text) (length prname))
1489                                    (length text))
1490                            visual)
1491               files (cons (vector prname ifnname fiddle mode (1- p))
1492                           files))
1493         (cond ((= hdrlvl 1)
1494                (setq p (+ p hsize 2 csize)))
1495               ((or (= hdrlvl 2) (= hdrlvl 0))
1496                (setq p (+ p thsize 2 csize))))
1497         ))
1498     (goto-char (point-min))
1499     (set-buffer-multibyte default-enable-multibyte-characters)
1500     (let ((dash (concat (if archive-alternate-display
1501                             "- --------  -----  -----  "
1502                           "- ----------  --------  -----------  --------  ")
1503                         (make-string maxlen ?-)
1504                         "\n"))
1505           (header (if archive-alternate-display
1506                        "M   Length    Uid    Gid  File\n"
1507                     "M   Filemode    Length  Date         Time      File\n"))
1508           (sumline (if archive-alternate-display
1509                        "  %8d                %d file%s"
1510                      "              %8d                         %d file%s")))
1511       (insert header dash)
1512       (archive-summarize-files (nreverse visual))
1513       (insert dash
1514               (format sumline
1515                       totalsize
1516                       (length files)
1517                       (if (= 1 (length files)) "" "s"))
1518               "\n"))
1519     (apply 'vector (nreverse files))))
1520
1521 (defconst archive-lzh-alternate-display t)
1522
1523 (defun archive-lzh-extract (archive name)
1524   (archive-extract-by-stdout archive name archive-lzh-extract))
1525
1526 (defun archive-lzh-resum (p count)
1527   (let ((sum 0))
1528     (while (> count 0)
1529       (setq count (1- count)
1530             sum (+ sum (char-after p))
1531             p (1+ p)))
1532     (logand sum 255)))
1533
1534 (defun archive-lzh-rename-entry (newname descr)
1535   (save-restriction
1536     (save-excursion
1537       (widen)
1538       (set-buffer-multibyte nil)
1539       (let* ((p        (+ archive-proper-file-start (aref descr 4)))
1540              (oldhsize (char-after p))
1541              (oldfnlen (char-after (+ p 21)))
1542              (newfnlen (length newname))
1543              (newhsize (+ oldhsize newfnlen (- oldfnlen)))
1544              (inhibit-read-only t))
1545         (if (> newhsize 255)
1546             (error "The file name is too long"))
1547         (goto-char (+ p 21))
1548         (delete-char (1+ oldfnlen))
1549         (insert newfnlen newname)
1550         (goto-char p)
1551         (delete-char 2)
1552         (insert newhsize (archive-lzh-resum p newhsize))))))
1553
1554 (defun archive-lzh-ogm (newval files errtxt ofs)
1555   (save-excursion
1556     (save-restriction
1557       (widen)
1558       (set-buffer-multibyte nil)
1559       (dolist (fil files)
1560         (let* ((p (+ archive-proper-file-start (aref fil 4)))
1561                (hsize   (char-after p))
1562                (fnlen   (char-after (+ p 21)))
1563                (p2      (+ p 22 fnlen))
1564                (creator (if (>= (- hsize fnlen) 24) (char-after (+ p2 2)) 0))
1565                (inhibit-read-only t))
1566           (if (= creator ?U)
1567               (progn
1568                 (or (numberp newval)
1569                     (setq newval (funcall newval (archive-l-e (+ p2 ofs) 2))))
1570                 (goto-char (+ p2 ofs))
1571                 (delete-char 2)
1572                 (insert (logand newval 255) (lsh newval -8))
1573                 (goto-char (1+ p))
1574                 (delete-char 1)
1575                 (insert (archive-lzh-resum (1+ p) hsize)))
1576             (message "Member %s does not have %s field"
1577                      (aref fil 1) errtxt)))))))
1578
1579 (defun archive-lzh-chown-entry (newuid files)
1580   (archive-lzh-ogm newuid files "an uid" 10))
1581
1582 (defun archive-lzh-chgrp-entry (newgid files)
1583   (archive-lzh-ogm newgid files "a gid" 12))
1584
1585 (defun archive-lzh-chmod-entry (newmode files)
1586   (archive-lzh-ogm
1587    ;; This should work even though newmode will be dynamically accessed.
1588    (lambda (old) (archive-calc-mode old newmode t))
1589    files "a unix-style mode" 8))
1590 ;; -------------------------------------------------------------------------
1591 ;; Section: Zip Archives
1592
1593 (defun archive-zip-summarize ()
1594   (goto-char (- (point-max) (- 22 18)))
1595   (search-backward-regexp "[P]K\005\006")
1596   (let ((p (+ (point-min) (archive-l-e (+ (point) 16) 4)))
1597         (maxlen 8)
1598         (totalsize 0)
1599         files
1600         visual)
1601     (while (string= "PK\001\002" (buffer-substring p (+ p 4)))
1602       (let* ((creator (char-after (+ p 5)))
1603              ;; (method  (archive-l-e (+ p 10) 2))
1604              (modtime (archive-l-e (+ p 12) 2))
1605              (moddate (archive-l-e (+ p 14) 2))
1606              (ucsize  (archive-l-e (+ p 24) 4))
1607              (fnlen   (archive-l-e (+ p 28) 2))
1608              (exlen   (archive-l-e (+ p 30) 2))
1609              (fclen   (archive-l-e (+ p 32) 2))
1610              (lheader (archive-l-e (+ p 42) 4))
1611              (efnname (let ((str (buffer-substring (+ p 46) (+ p 46 fnlen))))
1612                         (if file-name-coding-system
1613                             (decode-coding-string str file-name-coding-system)
1614                           (string-as-multibyte str))))
1615              (isdir   (and (= ucsize 0)
1616                            (string= (file-name-nondirectory efnname) "")))
1617              (mode    (cond ((memq creator '(2 3)) ; Unix + VMS
1618                              (archive-l-e (+ p 40) 2))
1619                             ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1620                              (logior ?\444
1621                                      (if isdir (logior 16384 ?\111) 0)
1622                                      (if (zerop
1623                                           (logand 1 (char-after (+ p 38))))
1624                                          ?\222 0)))
1625                             (t nil)))
1626              (modestr (if mode (archive-int-to-mode mode) "??????????"))
1627              (fiddle  (and archive-zip-case-fiddle
1628                            (not (not (memq creator '(0 2 4 5 9))))
1629                            (string= (upcase efnname) efnname)))
1630              (ifnname (if fiddle (downcase efnname) efnname))
1631              (width (string-width ifnname))
1632              (text    (format "  %10s  %8d  %-11s  %-8s  %s"
1633                               modestr
1634                               ucsize
1635                               (archive-dosdate moddate)
1636                               (archive-dostime modtime)
1637                               ifnname)))
1638         (setq maxlen (max maxlen width)
1639               totalsize (+ totalsize ucsize)
1640               visual (cons (vector text
1641                                    (- (length text) (length ifnname))
1642                                    (length text))
1643                            visual)
1644               files (cons (if isdir
1645                               nil
1646                             (vector efnname ifnname fiddle mode
1647                                     (list (1- p) lheader)))
1648                           files)
1649               p (+ p 46 fnlen exlen fclen))))
1650     (goto-char (point-min))
1651     (let ((dash (concat "- ----------  --------  -----------  --------  "
1652                         (make-string maxlen ?-)
1653                         "\n")))
1654       (insert "M Filemode      Length  Date         Time      File\n"
1655               dash)
1656       (archive-summarize-files (nreverse visual))
1657       (insert dash
1658               (format "              %8d                         %d file%s"
1659                       totalsize
1660                       (length files)
1661                       (if (= 1 (length files)) "" "s"))
1662               "\n"))
1663     (apply 'vector (nreverse files))))
1664
1665 (defun archive-zip-extract (archive name)
1666   (if (equal (car archive-zip-extract) "pkzip")
1667       (archive-*-extract archive name archive-zip-extract)
1668     (archive-extract-by-stdout archive name archive-zip-extract)))
1669
1670 (defun archive-zip-write-file-member (archive descr)
1671   (archive-*-write-file-member
1672    archive
1673    descr
1674    (if (aref descr 2) archive-zip-update-case archive-zip-update)))
1675
1676 (defun archive-zip-chmod-entry (newmode files)
1677   (save-restriction
1678     (save-excursion
1679       (widen)
1680       (set-buffer-multibyte nil)
1681       (dolist (fil files)
1682         (let* ((p (+ archive-proper-file-start (car (aref fil 4))))
1683                (creator (char-after (+ p 5)))
1684                (oldmode (aref fil 3))
1685                (newval  (archive-calc-mode oldmode newmode t))
1686                (inhibit-read-only t))
1687           (cond ((memq creator '(2 3)) ; Unix + VMS
1688                  (goto-char (+ p 40))
1689                  (delete-char 2)
1690                  (insert (logand newval 255) (lsh newval -8)))
1691                 ((memq creator '(0 5 6 7 10 11 15)) ; Dos etc.
1692                  (goto-char (+ p 38))
1693                  (insert (logior (logand (char-after (point)) 254)
1694                                  (logand (logxor 1 (lsh newval -7)) 1)))
1695                  (delete-char 1))
1696                 (t (message "Don't know how to change mode for this member"))))
1697         ))))
1698 ;; -------------------------------------------------------------------------
1699 ;; Section: Zoo Archives
1700
1701 (defun archive-zoo-summarize ()
1702   (let ((p (1+ (archive-l-e 25 4)))
1703         (maxlen 8)
1704         (totalsize 0)
1705         files
1706         visual)
1707     (while (and (string= "\334\247\304\375" (buffer-substring p (+ p 4)))
1708                 (> (archive-l-e (+ p 6) 4) 0))
1709       (let* ((next    (1+ (archive-l-e (+ p 6) 4)))
1710              (moddate (archive-l-e (+ p 14) 2))
1711              (modtime (archive-l-e (+ p 16) 2))
1712              (ucsize  (archive-l-e (+ p 20) 4))
1713              (namefld (buffer-substring (+ p 38) (+ p 38 13)))
1714              (dirtype (char-after (+ p 4)))
1715              (lfnlen  (if (= dirtype 2) (char-after (+ p 56)) 0))
1716              (ldirlen (if (= dirtype 2) (char-after (+ p 57)) 0))
1717              (fnlen   (or (string-match "\0" namefld) 13))
1718              (efnname (let ((str
1719                              (concat
1720                               (if (> ldirlen 0)
1721                                   (concat (buffer-substring
1722                                            (+ p 58 lfnlen)
1723                                            (+ p 58 lfnlen ldirlen -1))
1724                                           "/")
1725                                 "")
1726                               (if (> lfnlen 0)
1727                                   (buffer-substring (+ p 58)
1728                                                     (+ p 58 lfnlen -1))
1729                                 (substring namefld 0 fnlen)))))
1730                         (if file-name-coding-system
1731                             (decode-coding-string str file-name-coding-system)
1732                           (string-as-multibyte str))))
1733              (fiddle  (and (= lfnlen 0) (string= efnname (upcase efnname))))
1734              (ifnname (if fiddle (downcase efnname) efnname))
1735              (width (string-width ifnname))
1736              (text    (format "  %8d  %-11s  %-8s  %s"
1737                               ucsize
1738                               (archive-dosdate moddate)
1739                               (archive-dostime modtime)
1740                               ifnname)))
1741         (setq maxlen (max maxlen width)
1742               totalsize (+ totalsize ucsize)
1743               visual (cons (vector text
1744                                    (- (length text) (length ifnname))
1745                                    (length text))
1746                            visual)
1747               files (cons (vector efnname ifnname fiddle nil (1- p))
1748                           files)
1749               p next)))
1750     (goto-char (point-min))
1751     (let ((dash (concat "- --------  -----------  --------  "
1752                         (make-string maxlen ?-)
1753                         "\n")))
1754       (insert "M   Length  Date         Time      File\n"
1755               dash)
1756       (archive-summarize-files (nreverse visual))
1757       (insert dash
1758               (format "  %8d                         %d file%s"
1759                       totalsize
1760                       (length files)
1761                       (if (= 1 (length files)) "" "s"))
1762               "\n"))
1763     (apply 'vector (nreverse files))))
1764
1765 (defun archive-zoo-extract (archive name)
1766   (archive-extract-by-stdout archive name archive-zoo-extract))
1767 ;; -------------------------------------------------------------------------
1768 ;; This line was a mistake; it is kept now for compatibility.
1769 ;; rms  15 Oct 98
1770 (provide 'archive-mode)
1771
1772 (provide 'arc-mode)
1773
1774 ;; arch-tag: e5966a01-35ec-4f27-8095-a043a79b457b
1775 ;;; arc-mode.el ends here