code.delx.au - gnu-emacs/blob - lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.ai.mit.edu>
   6 ;; Keywords: mouse
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; For those who are annoyed by the mouse pointer obscuring text,
  28 ;; this mode moves the mouse pointer - either just a little out of
  29 ;; the way, or all the way to the corner of the frame.
  30 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  31 ;; To set up permanently, put the following in your .emacs:
  32 ;;
  33 ;; (if window-system (mouse-avoidance-mode 'animate))
  34 ;;
  35 ;; The 'animate can be 'jump or 'banish or 'exile or 'protean if you prefer.
  36 ;; See the documentation for function `mouse-avoidance-mode' for
  37 ;; details of the different modes.
  38 ;;
  39 ;; For added silliness, make the animatee animate...
  40 ;; put something similar to the following into your .emacs:
  41 ;;
  42 ;; (if window-system
  43 ;;     (mouse-avoidance-set-pointer-shape
  44 ;;           (eval (nth (random 4)
  45 ;;                      '(x-pointer-man x-pointer-spider
  46 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  47 ;;
  48 ;; For completely random pointer shape, replace the setq above with:
  49 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  50 ;;
  51 ;; Bugs / Warnings / To-Do:
  52 ;;
  53 ;; - Using this code does slow emacs down.  "banish" mode shouldn't
  54 ;;   be too bad, and on my workstation even "animate" is reasonable.
  55 ;;
  56 ;; - It ought to find out where any overlapping frames are and avoid them,
  57 ;;   rather than always raising the frame.
  58
  59 ;; Credits:
  60 ;; This code was helped by all those who contributed suggestions,
  61 ;;   fixes, and additions
  62 ;; Joe Harrington (and his advisor), for the original inspiration.
  63 ;; Ken Manheimer, for dreaming up the Protean mode.
  64 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  65 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  66 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  67
  68 ;;; Code:
  69
  70 (provide 'avoid)
  71
  72 (defgroup avoid nil
  73   "Make mouse pointer stay out of the way of editing."
  74   :prefix "mouse-avoidance-"
  75   :group 'mouse)
  76
  77
  78 (defvar mouse-avoidance-mode nil
  79   "Value is t or a symbol if the mouse pointer should avoid the cursor.
  80 See function `mouse-avoidance-mode' for possible values.  Changing this
  81 variable is NOT the recommended way to change modes; use that function
  82 instead.")
  83
  84 (defcustom mouse-avoidance-nudge-dist 15
  85   "*Average distance that mouse will be moved when approached by cursor.
  86 Only applies in mouse-avoidance-mode `jump' and its derivatives.
  87 For best results make this larger than `mouse-avoidance-threshold'."
  88   :type 'integer
  89   :group 'avoid)
  90
  91 (defcustom mouse-avoidance-nudge-var 10
  92   "*Variability of `mouse-avoidance-nudge-dist' (which see)."
  93   :type 'integer
  94   :group 'avoid)
  95
  96 (defcustom mouse-avoidance-animation-delay .01
  97   "Delay between animation steps, in seconds."
  98   :type 'number
  99   :group 'avoid)
 100
 101 (defcustom mouse-avoidance-threshold 5
 102   "*Mouse-pointer's flight distance.
 103 If the cursor gets closer than this, the mouse pointer will move away.
 104 Only applies in mouse-avoidance-modes `animate' and `jump'."
 105   :type 'integer
 106   :group 'avoid)
 107
 108 ;; Internal variables
 109 (defvar mouse-avoidance-state nil)
 110 (defvar mouse-avoidance-pointer-shapes nil)
 111 (defvar mouse-avoidance-n-pointer-shapes 0)
 112 (defvar mouse-avoidance-old-pointer-shape nil)
 113
 114 ;; This timer is used to run something when Emacs is idle.
 115 (defvar mouse-avoidance-timer nil)
 116
 117 ;;; Functions:
 118
 119 (defsubst mouse-avoidance-set-pointer-shape (shape)
 120   "Set the shape of the mouse pointer to SHAPE."
 121   (setq x-pointer-shape shape)
 122   (set-mouse-color nil))
 123
 124 (defun mouse-avoidance-point-position ()
 125   "Return the position of point as (FRAME X . Y).
 126 Analogous to mouse-position."
 127   (let* ((w (selected-window))
 128          (edges (window-edges w))
 129          (list
 130           (compute-motion (max (window-start w) (point-min))   ; start pos
 131                           ;; window-start can be < point-min if the
 132                           ;; latter has changed since the last redisplay
 133                           '(0 . 0)                             ; start XY
 134                           (point)                              ; stop pos
 135                           (cons (window-width) (window-height)); stop XY: none
 136                           (1- (window-width))                  ; width
 137                           (cons (window-hscroll w) 0)          ; 0 may not be right?
 138                           (selected-window))))
 139     ;; compute-motion returns (pos HPOS VPOS prevhpos contin)
 140     ;; we want:               (frame hpos . vpos)
 141     (cons (selected-frame)
 142           (cons (+ (car edges)       (car (cdr list)))
 143                 (+ (car (cdr edges)) (car (cdr (cdr list))))))))
 144
 145 ;(defun mouse-avoidance-point-position-test ()
 146 ;  (interactive)
 147 ;  (message (format "point=%s mouse=%s"
 148 ;                  (cdr (mouse-avoidance-point-position))
 149 ;                  (cdr (mouse-position)))))
 150
 151 (defun mouse-avoidance-set-mouse-position (pos)
 152   ;; Carefully set mouse position to given position (X . Y)
 153   ;; Ideally, should check if X,Y is in the current frame, and if not,
 154   ;; leave the mouse where it was.  However, this is currently
 155   ;; difficult to do, so we just raise the frame to avoid frame switches.
 156   ;; Returns t if it moved the mouse.
 157   (let ((f (selected-frame)))
 158     (raise-frame f)
 159     (set-mouse-position f (car pos) (cdr pos))
 160     t))
 161
 162 (defun mouse-avoidance-too-close-p (mouse)
 163   ;;  Return t if mouse pointer and point cursor are too close.
 164   ;; Acceptable distance is defined by mouse-avoidance-threshold.
 165   (let ((point (mouse-avoidance-point-position)))
 166     (and (eq (car mouse) (car point))
 167          (car (cdr mouse))
 168          (< (abs (- (car (cdr mouse)) (car (cdr point))))
 169             mouse-avoidance-threshold)
 170          (< (abs (- (cdr (cdr mouse)) (cdr (cdr point))))
 171             mouse-avoidance-threshold))))
 172
 173 (defun mouse-avoidance-banish-destination ()
 174   "The position to which mouse-avoidance-mode `banish' moves the mouse.
 175 You can redefine this if you want the mouse banished to a different corner."
 176  (cons (1- (frame-width))
 177        0))
 178
 179 (defun mouse-avoidance-banish-mouse ()
 180   ;; Put the mouse pointer in the upper-right corner of the current frame.
 181   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 182
 183 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 184   ;; Decide how far to move in either dimension.
 185   ;; Args are the CURRENT location, the desired DELTA for
 186   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 187   ;; in distance allowed, and the MIN and MAX possible window positions.
 188   ;; Returns something as close to DELTA as possible within the constraints.
 189   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 190         (R1                  (+ (- dist)    var ))
 191         (L2                  (+    dist  (- var)))
 192         (R2 (min (- max cur) (+    dist     var))))
 193     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 194     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 195     (cond ((and L1 (< delta L1)) L1)
 196           ((and R1 (< delta R1)) delta)
 197           ((and R1 (< delta 0)) R1)
 198           ((and L2 (< delta L2)) L2)
 199           ((and R2 (< delta R2)) delta)
 200           (R2)
 201           ((or R1 L2))
 202           (t 0))))
 203
 204 (defun mouse-avoidance-nudge-mouse ()
 205   ;; Push the mouse a little way away, possibly animating the move
 206   ;; For these modes, state keeps track of the total offset that we've
 207   ;; accumulated, and tries to keep it close to zero.
 208   (let* ((cur (mouse-position))
 209          (cur-frame (car cur))
 210          (cur-pos (cdr cur))
 211          (deltax (mouse-avoidance-delta
 212                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 213                                    (car mouse-avoidance-state))
 214                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 215                   0 (frame-width)))
 216          (deltay (mouse-avoidance-delta
 217                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 218                                    (cdr mouse-avoidance-state))
 219                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 220                   0 (frame-height))))
 221     (setq mouse-avoidance-state
 222           (cons (+ (car mouse-avoidance-state) deltax)
 223                 (+ (cdr mouse-avoidance-state) deltay)))
 224     (if (or (eq mouse-avoidance-mode 'animate)
 225             (eq mouse-avoidance-mode 'proteus))
 226         (let ((i 0.0))
 227           (while (<= i 1)
 228             (mouse-avoidance-set-mouse-position
 229              (cons (+ (car cur-pos) (round (* i deltax)))
 230                    (+ (cdr cur-pos) (round (* i deltay)))))
 231             (setq i (+ i (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 232             (if (eq mouse-avoidance-mode 'proteus)
 233                 (mouse-avoidance-set-pointer-shape
 234                  (mouse-avoidance-random-shape)))
 235             (sit-for mouse-avoidance-animation-delay)))
 236       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 237                                                 (+ (cdr (cdr cur)) deltay))))))
 238
 239 (defun mouse-avoidance-random-shape ()
 240   "Return a random cursor shape.
 241 This assumes that any variable whose name begins with x-pointer- and
 242 has an integer value is a valid cursor shape.  You might want to
 243 redefine this function to suit your own tastes."
 244   (if (null mouse-avoidance-pointer-shapes)
 245       (progn
 246         (setq mouse-avoidance-pointer-shapes
 247               (mapcar '(lambda (x) (symbol-value (intern x)))
 248                       (all-completions "x-pointer-" obarray
 249                                        '(lambda (x)
 250                                           (and (boundp x)
 251                                                (integerp (symbol-value x)))))))
 252         (setq mouse-avoidance-n-pointer-shapes
 253               (length mouse-avoidance-pointer-shapes))))
 254   (nth (random mouse-avoidance-n-pointer-shapes)
 255        mouse-avoidance-pointer-shapes))
 256
 257 (defun mouse-avoidance-banish-hook ()
 258   (if (and (not executing-kbd-macro)    ; don't check inside macro
 259            (mouse-avoidance-kbd-command (this-command-keys)))
 260       (mouse-avoidance-banish-mouse)))
 261
 262 (defun mouse-avoidance-exile-hook ()
 263   ;; For exile mode, the state is nil when the mouse is in its normal
 264   ;; position, and set to the old mouse-position when the mouse is in exile.
 265   (if (and (not executing-kbd-macro)
 266            (mouse-avoidance-kbd-command (this-command-keys)))
 267       (let ((mp (mouse-position)))
 268         (cond ((and (not mouse-avoidance-state)
 269                     (mouse-avoidance-too-close-p mp))
 270                (setq mouse-avoidance-state mp)
 271                (mouse-avoidance-banish-mouse))
 272               ((and mouse-avoidance-state
 273                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 274                (if (and (eq (car mp) (selected-frame))
 275                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 276                    (mouse-avoidance-set-mouse-position
 277                     ;; move back only if user has not moved mouse
 278                     (cdr mouse-avoidance-state)))
 279                ;; but clear state anyway, to be ready for another move
 280                (setq mouse-avoidance-state nil))))))
 281
 282 (defun mouse-avoidance-fancy-hook ()
 283   ;; Used for the "fancy" modes, ie jump et al.
 284   (if (and (not executing-kbd-macro)    ; don't check inside macro
 285            (mouse-avoidance-kbd-command (this-command-keys))
 286            (mouse-avoidance-too-close-p (mouse-position)))
 287       (let ((old-pos (mouse-position)))
 288         (mouse-avoidance-nudge-mouse)
 289         (if (not (eq (selected-frame) (car old-pos)))
 290             ;; This should never happen.
 291             (apply 'set-mouse-position old-pos)))))
 292
 293 (defun mouse-avoidance-kbd-command (key)
 294   "Return t if the KEYSEQENCE is composed of keyboard events only.
 295 Return nil if there are any lists in the key sequence."
 296   (cond ((null key) nil)                ; Null event seems to be
 297                                         ; returned occasionally.
 298         ((not (vectorp key)) t)         ; Strings are keyboard events.
 299         ((catch 'done
 300            (let ((i 0)
 301                  (l (length key)))
 302              (while (< i l)
 303                (if (listp (aref key i))
 304                    (throw 'done nil))
 305                (setq i (1+ i))))
 306            t))))
 307
 308 ;;;###autoload
 309 (defun mouse-avoidance-mode (&optional mode)
 310   "Set cursor avoidance mode to MODE.
 311 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 312 `cat-and-mouse', `proteus', or `none'.
 313
 314 If MODE is nil, toggle mouse avoidance between `none` and `banish'
 315 modes.  Positive numbers and symbols other than the above are treated
 316 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 317
 318 Effects of the different modes:
 319  * banish: Move the mouse to the upper-right corner on any keypress.
 320  * exile: Move the mouse to the corner only if the cursor gets too close,
 321      and allow it to return once the cursor is out of the way.
 322  * jump: If the cursor gets too close to the mouse, displace the mouse
 323      a random distance & direction.
 324  * animate: As `jump', but shows steps along the way for illusion of motion.
 325  * cat-and-mouse: Same as `animate'.
 326  * proteus: As `animate', but changes the shape of the mouse pointer too.
 327
 328 Whenever the mouse is moved, the frame is also raised.
 329
 330 \(see `mouse-avoidance-threshold' for definition of \"too close\",
 331 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 332 definition of \"random distance\".)"
 333   (interactive
 334    (list (intern (completing-read
 335                   "Select cursor avoidance technique (SPACE for list): "
 336                   '(("banish") ("exile") ("jump") ("animate")
 337                     ("cat-and-mouse") ("proteus") ("none"))
 338                   nil t))))
 339   (if (eq mode 'cat-and-mouse)
 340       (setq mode 'animate))
 341   (if mouse-avoidance-timer
 342       (cancel-timer mouse-avoidance-timer))
 343   (setq mouse-avoidance-timer nil)
 344
 345   ;; Restore pointer shape if necessary
 346   (if (eq mouse-avoidance-mode 'proteus)
 347       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 348
 349   ;; Do additional setup depending on version of mode requested
 350   (cond ((eq mode 'none)
 351          (setq mouse-avoidance-mode nil))
 352         ((or (eq mode 'jump)
 353              (eq mode 'animate)
 354              (eq mode 'proteus))
 355          (setq mouse-avoidance-timer
 356                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy-hook))
 357          (setq mouse-avoidance-mode mode
 358                mouse-avoidance-state (cons 0 0)
 359                mouse-avoidance-old-pointer-shape x-pointer-shape))
 360         ((eq mode 'exile)
 361          (setq mouse-avoidance-timer
 362                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile-hook))
 363          (setq mouse-avoidance-mode mode
 364                mouse-avoidance-state nil))
 365         ((or (eq mode 'banish)
 366              (eq mode t)
 367              (and (null mode) (null mouse-avoidance-mode))
 368              (and mode (> (prefix-numeric-value mode) 0)))
 369          (setq mouse-avoidance-timer
 370                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish-hook))
 371          (setq mouse-avoidance-mode 'banish))
 372         (t (setq mouse-avoidance-mode nil)))
 373   (force-mode-line-update))
 374
 375 ;; Most people who use avoid mode leave it on all the time, so it's not
 376 ;; very informative to announce it in the mode line.
 377 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 378 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 379 ;;                               minor-mode-alist)))
 380
 381 ;;; End of avoid.el