code.delx.au - gnu-emacs/blob - lisp/progmodes/octave-mod.el

   1 ;;; octave-mod.el --- editing Octave source files under Emacs
   2
   3 ;; Copyright (C) 1997, 2001, 2002, 2003, 2004, 2005, 2006
   4 ;; Free Software Foundation, Inc.
   5
   6 ;; Author: Kurt Hornik <Kurt.Hornik@wu-wien.ac.at>
   7 ;; Author: John Eaton <jwe@bevo.che.wisc.edu>
   8 ;; Maintainer: Kurt Hornik <Kurt.Hornik@wu-wien.ac.at>
   9 ;; Keywords: languages
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides Emacs support for Octave.
  31 ;; It defines Octave mode, a major mode for editing
  32 ;; Octave code.
  33
  34 ;; The file octave-hlp.el provides `octave-help', a facility for looking up
  35 ;; documentation on a symbol in the Octave info files.
  36
  37 ;; The file octave-inf.el contains code for interacting with an inferior
  38 ;; Octave process using comint.
  39
  40 ;; See the documentation of `octave-mode', `octave-help' and
  41 ;; `run-octave' for further information on usage and customization.
  42
  43 ;;; Code:
  44 (require 'custom)
  45
  46 (defgroup octave nil
  47   "Major mode for editing Octave source files."
  48   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
  49   :group 'languages)
  50
  51 (defvar inferior-octave-output-list nil)
  52 (defvar inferior-octave-output-string nil)
  53 (defvar inferior-octave-receive-in-progress nil)
  54
  55 (defconst octave-maintainer-address
  56   "Kurt Hornik <Kurt.Hornik@wu-wien.ac.at>, bug-gnu-emacs@gnu.org"
  57   "Current maintainer of the Emacs Octave package.")
  58
  59 (defvar octave-abbrev-table nil
  60   "Abbrev table for Octave's reserved words.
  61 Used in `octave-mode' and inferior-octave-mode buffers.
  62 All Octave abbrevs start with a grave accent (`).")
  63 (unless octave-abbrev-table
  64   (let ((ac abbrevs-changed))
  65     (define-abbrev-table 'octave-abbrev-table ())
  66     (define-abbrev octave-abbrev-table "`a" "all_va_args" nil 0 t)
  67     (define-abbrev octave-abbrev-table "`b" "break" nil 0 t)
  68     (define-abbrev octave-abbrev-table "`cs" "case" nil 0 t)
  69     (define-abbrev octave-abbrev-table "`ca" "catch" nil 0 t)
  70     (define-abbrev octave-abbrev-table "`c" "continue" nil 0 t)
  71     (define-abbrev octave-abbrev-table "`el" "else" nil 0 t)
  72     (define-abbrev octave-abbrev-table "`eli" "elseif" nil 0 t)
  73     (define-abbrev octave-abbrev-table "`et" "end_try_catch" nil 0 t)
  74     (define-abbrev octave-abbrev-table "`eu" "end_unwind_protect" nil 0 t)
  75     (define-abbrev octave-abbrev-table "`ef" "endfor" nil 0 t)
  76     (define-abbrev octave-abbrev-table "`efu" "endfunction" nil 0 t)
  77     (define-abbrev octave-abbrev-table "`ei" "endif" nil 0 t)
  78     (define-abbrev octave-abbrev-table "`es" "endswitch" nil 0 t)
  79     (define-abbrev octave-abbrev-table "`ew" "endwhile" nil 0 t)
  80     (define-abbrev octave-abbrev-table "`f" "for" nil 0 t)
  81     (define-abbrev octave-abbrev-table "`fu" "function" nil 0 t)
  82     (define-abbrev octave-abbrev-table "`gl" "global" nil 0 t)
  83     (define-abbrev octave-abbrev-table "`gp" "gplot" nil 0 t)
  84     (define-abbrev octave-abbrev-table "`gs" "gsplot" nil 0 t)
  85     (define-abbrev octave-abbrev-table "`if" "if ()" nil 0 t)
  86     (define-abbrev octave-abbrev-table "`o" "otherwise" nil 0 t)
  87     (define-abbrev octave-abbrev-table "`rp" "replot" nil 0 t)
  88     (define-abbrev octave-abbrev-table "`r" "return" nil 0 t)
  89     (define-abbrev octave-abbrev-table "`s" "switch" nil 0 t)
  90     (define-abbrev octave-abbrev-table "`t" "try" nil 0 t)
  91     (define-abbrev octave-abbrev-table "`up" "unwind_protect" nil 0 t)
  92     (define-abbrev octave-abbrev-table "`upc" "unwind_protect_cleanup" nil 0 t)
  93     (define-abbrev octave-abbrev-table "`w" "while ()" nil 0 t)
  94     (setq abbrevs-changed ac)))
  95
  96 (defvar octave-comment-char ?#
  97   "Character to start an Octave comment.")
  98 (defvar octave-comment-start
  99   (string octave-comment-char ?\ )
 100   "String to insert to start a new Octave in-line comment.")
 101 (defvar octave-comment-start-skip "\\s<+\\s-*"
 102   "Regexp to match the start of an Octave comment up to its body.")
 103
 104 (defvar octave-begin-keywords
 105   '("for" "function" "if" "switch" "try" "unwind_protect" "while"))
 106 (defvar octave-else-keywords
 107   '("case" "catch" "else" "elseif" "otherwise" "unwind_protect_cleanup"))
 108 (defvar octave-end-keywords
 109   '("end" "endfor" "endfunction" "endif" "endswitch" "end_try_catch"
 110     "end_unwind_protect" "endwhile"))
 111
 112 (defvar octave-reserved-words
 113   (append octave-begin-keywords
 114           octave-else-keywords
 115           octave-end-keywords
 116           '("all_va_args" "break" "continue" "global" "gplot" "gsplot"
 117             "replot" "return"))
 118   "Reserved words in Octave.")
 119
 120 (defvar octave-text-functions
 121   '("casesen" "cd" "chdir" "clear" "diary" "dir" "document" "echo"
 122     "edit_history" "format" "gset" "gshow" "help" "history" "hold"
 123     "load" "ls" "more" "run_history" "save" "set" "show" "type"
 124     "which" "who" "whos")
 125   "Text functions in Octave (these names are also reserved).")
 126
 127 (defvar octave-variables
 128   '("EDITOR" "EXEC_PATH" "F_DUPFD" "F_GETFD" "F_GETFL" "F_SETFD"
 129     "F_SETFL" "I" "IMAGEPATH" "INFO_FILE" "INFO_PROGRAM" "Inf" "J"
 130     "LOADPATH" "NaN" "OCTAVE_VERSION" "O_APPEND" "O_CREAT" "O_EXCL"
 131     "O_NONBLOCK" "O_RDONLY" "O_RDWR" "O_TRUNC" "O_WRONLY" "PAGER" "PS1"
 132     "PS2" "PS4" "PWD" "SEEK_CUR" "SEEK_END" "SEEK_SET" "__F_DUPFD__"
 133     "__F_GETFD__" "__F_GETFL__" "__F_SETFD__" "__F_SETFL__" "__I__"
 134     "__Inf__" "__J__" "__NaN__" "__OCTAVE_VERSION__" "__O_APPEND__"
 135     "__O_CREAT__" "__O_EXCL__" "__O_NONBLOCK__" "__O_RDONLY__"
 136     "__O_RDWR__" "__O_TRUNC__" "__O_WRONLY__" "__PWD__" "__SEEK_CUR__"
 137     "__SEEK_END__" "__SEEK_SET__" "__argv__" "__e__" "__eps__"
 138     "__error_text__" "__i__" "__inf__" "__j__" "__nan__" "__pi__"
 139     "__program_invocation_name__" "__program_name__" "__realmax__"
 140     "__realmin__" "__stderr__" "__stdin__" "__stdout__" "ans" "argv"
 141     "automatic_replot" "beep_on_error" "completion_append_char"
 142     "default_return_value" "default_save_format"
 143     "define_all_return_values" "do_fortran_indexing" "e"
 144     "echo_executing_commands" "empty_list_elements_ok" "eps"
 145     "error_text" "gnuplot_binary" "gnuplot_has_multiplot" "history_file"
 146     "history_size" "ignore_function_time_stamp" "implicit_str_to_num_ok"
 147     "inf" "nan" "nargin" "ok_to_lose_imaginary_part"
 148     "output_max_field_width" "output_precision"
 149     "page_output_immediately" "page_screen_output" "pi"
 150     "prefer_column_vectors" "prefer_zero_one_indexing"
 151     "print_answer_id_name" "print_empty_dimensions"
 152     "program_invocation_name" "program_name" "propagate_empty_matrices"
 153     "realmax" "realmin" "resize_on_range_error"
 154     "return_last_computed_value" "save_precision" "saving_history"
 155     "silent_functions" "split_long_rows" "stderr" "stdin" "stdout"
 156     "string_fill_char" "struct_levels_to_print"
 157     "suppress_verbose_help_message" "treat_neg_dim_as_zero"
 158     "warn_assign_as_truth_value" "warn_comma_in_global_decl"
 159     "warn_divide_by_zero" "warn_function_name_clash"
 160     "warn_missing_semicolon" "whitespace_in_literal_matrix")
 161   "Builtin variables in Octave.")
 162
 163 (defvar octave-function-header-regexp
 164   (concat "^\\s-*\\<\\(function\\)\\>"
 165           "\\([^=;\n]*=[ \t]*\\|[ \t]*\\)\\(\\w+\\)\\>")
 166   "Regexp to match an Octave function header.
 167 The string `function' and its name are given by the first and third
 168 parenthetical grouping.")
 169
 170 (defvar octave-font-lock-keywords
 171   (list
 172    ;; Fontify all builtin keywords.
 173    (cons (concat "\\<\\("
 174                  (mapconcat 'identity octave-reserved-words "\\|")
 175                  (mapconcat 'identity octave-text-functions "\\|")
 176                  "\\)\\>")
 177          'font-lock-keyword-face)
 178    ;; Fontify all builtin operators.
 179    (cons "\\(&\\||\\|<=\\|>=\\|==\\|<\\|>\\|!=\\|!\\)"
 180          (if (boundp 'font-lock-builtin-face)
 181              'font-lock-builtin-face
 182            'font-lock-preprocessor-face))
 183    ;; Fontify all builtin variables.
 184    (cons (concat "\\<\\("
 185                  (mapconcat 'identity octave-variables "\\|")
 186                  "\\)\\>")
 187          'font-lock-variable-name-face)
 188    ;; Fontify all function declarations.
 189    (list octave-function-header-regexp
 190          '(1 font-lock-keyword-face)
 191          '(3 font-lock-function-name-face nil t)))
 192   "Additional Octave expressions to highlight.")
 193
 194 (defcustom inferior-octave-buffer "*Inferior Octave*"
 195   "*Name of buffer for running an inferior Octave process."
 196   :type 'string
 197   :group 'octave-inferior)
 198
 199 (defvar inferior-octave-process nil)
 200 \f
 201 (defvar octave-mode-map nil
 202   "Keymap used in Octave mode.")
 203 (if octave-mode-map
 204     ()
 205   (let ((map (make-sparse-keymap)))
 206     (define-key map "`" 'octave-abbrev-start)
 207     (define-key map ";" 'octave-electric-semi)
 208     (define-key map " " 'octave-electric-space)
 209     (define-key map "\n" 'octave-reindent-then-newline-and-indent)
 210     (define-key map "\t" 'indent-according-to-mode)
 211     (define-key map "\e;" 'octave-indent-for-comment)
 212     (define-key map "\e\n" 'octave-indent-new-comment-line)
 213     (define-key map "\e\t" 'octave-complete-symbol)
 214     (define-key map "\M-\C-a" 'octave-beginning-of-defun)
 215     (define-key map "\M-\C-e" 'octave-end-of-defun)
 216     (define-key map "\M-\C-h" 'octave-mark-defun)
 217     (define-key map "\M-\C-q" 'octave-indent-defun)
 218     (define-key map "\C-c;" 'octave-comment-region)
 219     (define-key map "\C-c:" 'octave-uncomment-region)
 220     (define-key map "\C-c\C-b" 'octave-submit-bug-report)
 221     (define-key map "\C-c\C-p" 'octave-previous-code-line)
 222     (define-key map "\C-c\C-n" 'octave-next-code-line)
 223     (define-key map "\C-c\C-a" 'octave-beginning-of-line)
 224     (define-key map "\C-c\C-e" 'octave-end-of-line)
 225     (define-key map "\C-c\M-\C-n" 'octave-forward-block)
 226     (define-key map "\C-c\M-\C-p" 'octave-backward-block)
 227     (define-key map "\C-c\M-\C-u" 'octave-backward-up-block)
 228     (define-key map "\C-c\M-\C-d" 'octave-down-block)
 229     (define-key map "\C-c\M-\C-h" 'octave-mark-block)
 230     (define-key map "\C-c]" 'octave-close-block)
 231     (define-key map "\C-c\C-f" 'octave-insert-defun)
 232     (define-key map "\C-c\C-h" 'octave-help)
 233     (define-key map "\C-c\C-il" 'octave-send-line)
 234     (define-key map "\C-c\C-ib" 'octave-send-block)
 235     (define-key map "\C-c\C-if" 'octave-send-defun)
 236     (define-key map "\C-c\C-ir" 'octave-send-region)
 237     (define-key map "\C-c\C-is" 'octave-show-process-buffer)
 238     (define-key map "\C-c\C-ih" 'octave-hide-process-buffer)
 239     (define-key map "\C-c\C-ik" 'octave-kill-process)
 240     (define-key map "\C-c\C-i\C-l" 'octave-send-line)
 241     (define-key map "\C-c\C-i\C-b" 'octave-send-block)
 242     (define-key map "\C-c\C-i\C-f" 'octave-send-defun)
 243     (define-key map "\C-c\C-i\C-r" 'octave-send-region)
 244     (define-key map "\C-c\C-i\C-s" 'octave-show-process-buffer)
 245     (define-key map "\C-c\C-i\C-h" 'octave-hide-process-buffer)
 246     (define-key map "\C-c\C-i\C-k" 'octave-kill-process)
 247     (setq octave-mode-map map)))
 248
 249 (defvar octave-mode-menu
 250   (list "Octave"
 251         (list "Lines"
 252               ["Previous Code Line"     octave-previous-code-line t]
 253               ["Next Code Line"         octave-next-code-line t]
 254               ["Begin of Continuation"  octave-beginning-of-line t]
 255               ["End of Continuation"    octave-end-of-line t]
 256               ["Split Line at Point"    octave-indent-new-comment-line t])
 257         (list "Blocks"
 258               ["Next Block"             octave-forward-block t]
 259               ["Previous Block"         octave-backward-block t]
 260               ["Down Block"             octave-down-block t]
 261               ["Up Block"               octave-backward-up-block t]
 262               ["Mark Block"             octave-mark-block t]
 263               ["Close Block"            octave-close-block t])
 264         (list "Functions"
 265               ["Begin of Function"      octave-beginning-of-defun t]
 266               ["End of Function"        octave-end-of-defun t]
 267               ["Mark Function"          octave-mark-defun t]
 268               ["Indent Function"        octave-indent-defun t]
 269               ["Insert Function"        octave-insert-defun t])
 270         "-"
 271         (list "Debug"
 272               ["Send Current Line"      octave-send-line t]
 273               ["Send Current Block"     octave-send-block t]
 274               ["Send Current Function"  octave-send-defun t]
 275               ["Send Region"            octave-send-region t]
 276               ["Show Process Buffer"    octave-show-process-buffer t]
 277               ["Hide Process Buffer"    octave-hide-process-buffer t]
 278               ["Kill Process"           octave-kill-process t])
 279         "-"
 280         ["Indent Line"                  indent-according-to-mode t]
 281         ["Complete Symbol"              octave-complete-symbol t]
 282         "-"
 283         ["Toggle Abbrev Mode"           abbrev-mode t]
 284         ["Toggle Auto-Fill Mode"        auto-fill-mode t]
 285         "-"
 286         ["Submit Bug Report"            octave-submit-bug-report t]
 287         "-"
 288         ["Describe Octave Mode"         octave-describe-major-mode t]
 289         ["Lookup Octave Index"          octave-help t])
 290   "Menu for Octave mode.")
 291
 292 (defvar octave-mode-syntax-table
 293   (let ((table (make-syntax-table)))
 294     (modify-syntax-entry ?\r " "  table)
 295     (modify-syntax-entry ?+ "."   table)
 296     (modify-syntax-entry ?- "."   table)
 297     (modify-syntax-entry ?= "."   table)
 298     (modify-syntax-entry ?* "."   table)
 299     (modify-syntax-entry ?/ "."   table)
 300     (modify-syntax-entry ?> "."   table)
 301     (modify-syntax-entry ?< "."   table)
 302     (modify-syntax-entry ?& "."   table)
 303     (modify-syntax-entry ?| "."   table)
 304     (modify-syntax-entry ?! "."   table)
 305     (modify-syntax-entry ?\\ "\\" table)
 306     (modify-syntax-entry ?\' "."  table)
 307     (modify-syntax-entry ?\` "w"  table)
 308     (modify-syntax-entry ?\" "\"" table)
 309     (modify-syntax-entry ?. "w"   table)
 310     (modify-syntax-entry ?_ "w"   table)
 311     (modify-syntax-entry ?\% "<"  table)
 312     (modify-syntax-entry ?\# "<"  table)
 313     (modify-syntax-entry ?\n ">"  table)
 314     table)
 315   "Syntax table in use in `octave-mode' buffers.")
 316
 317 (defcustom octave-auto-indent nil
 318   "*Non-nil means indent line after a semicolon or space in Octave mode."
 319   :type 'boolean
 320   :group 'octave)
 321
 322 (defcustom octave-auto-newline nil
 323   "*Non-nil means automatically newline after a semicolon in Octave mode."
 324   :type 'boolean
 325   :group 'octave)
 326
 327 (defcustom octave-blink-matching-block t
 328   "*Control the blinking of matching Octave block keywords.
 329 Non-nil means show matching begin of block when inserting a space,
 330 newline or semicolon after an else or end keyword."
 331   :type 'boolean
 332   :group 'octave)
 333 (defcustom octave-block-offset 2
 334   "*Extra indentation applied to statements in Octave block structures."
 335   :type 'integer
 336   :group 'octave)
 337
 338 (defvar octave-block-begin-regexp
 339   (concat "\\<\\("
 340           (mapconcat 'identity octave-begin-keywords "\\|")
 341           "\\)\\>"))
 342 (defvar octave-block-else-regexp
 343   (concat "\\<\\("
 344           (mapconcat 'identity octave-else-keywords "\\|")
 345           "\\)\\>"))
 346 (defvar octave-block-end-regexp
 347   (concat "\\<\\("
 348           (mapconcat 'identity octave-end-keywords "\\|")
 349           "\\)\\>"))
 350 (defvar octave-block-begin-or-end-regexp
 351   (concat octave-block-begin-regexp "\\|" octave-block-end-regexp))
 352 (defvar octave-block-else-or-end-regexp
 353   (concat octave-block-else-regexp "\\|" octave-block-end-regexp))
 354 (defvar octave-block-match-alist
 355   '(("for" . ("end" "endfor"))
 356     ("function" . ("end" "endfunction"))
 357     ("if" . ("else" "elseif" "end" "endif"))
 358     ("switch" . ("case" "otherwise" "end" "endswitch"))
 359     ("try" . ("catch" "end" "end_try_catch"))
 360     ("unwind_protect" . ("unwind_protect_cleanup" "end"
 361                          "end_unwind_protect"))
 362     ("while" . ("end" "endwhile")))
 363   "Alist with Octave's matching block keywords.
 364 Has Octave's begin keywords as keys and a list of the matching else or
 365 end keywords as associated values.")
 366
 367 (defvar octave-block-comment-start
 368   (concat (make-string 2 octave-comment-char) " ")
 369   "String to insert to start a new Octave comment on an empty line.")
 370
 371 (defcustom octave-continuation-offset 4
 372   "*Extra indentation applied to Octave continuation lines."
 373   :type 'integer
 374   :group 'octave)
 375 (defvar octave-continuation-regexp
 376   "[^#%\n]*\\(\\\\\\|\\.\\.\\.\\)\\s-*\\(\\s<.*\\)?$")
 377 (defcustom octave-continuation-string "\\"
 378   "*Character string used for Octave continuation lines.  Normally \\."
 379   :type 'string
 380   :group 'octave)
 381
 382 (defvar octave-completion-alist nil
 383   "Alist of Octave symbols for completion in Octave mode.
 384 Each element looks like (VAR . VAR), where the car and cdr are the same
 385 symbol (an Octave command or variable name).
 386 Currently, only builtin variables can be completed.")
 387
 388 (defvar octave-mode-imenu-generic-expression
 389   (list
 390    ;; Functions
 391    (list nil octave-function-header-regexp 3))
 392   "Imenu expression for Octave mode.  See `imenu-generic-expression'.")
 393
 394 (defcustom octave-mode-startup-message t
 395   "*nil means do not display the Octave mode startup message."
 396   :type 'boolean
 397   :group 'octave)
 398
 399 (defcustom octave-mode-hook nil
 400   "*Hook to be run when Octave mode is started."
 401   :type 'hook
 402   :group 'octave)
 403
 404 (defcustom octave-send-show-buffer t
 405   "*Non-nil means display `inferior-octave-buffer' after sending to it."
 406   :type 'boolean
 407   :group 'octave)
 408 (defcustom octave-send-line-auto-forward t
 409   "*Control auto-forward after sending to the inferior Octave process.
 410 Non-nil means always go to the next Octave code line after sending."
 411   :type 'boolean
 412   :group 'octave)
 413 (defcustom octave-send-echo-input t
 414   "*Non-nil means echo input sent to the inferior Octave process."
 415   :type 'boolean
 416   :group 'octave)
 417
 418 \f
 419 ;;;###autoload
 420 (defun octave-mode ()
 421   "Major mode for editing Octave code.
 422
 423 This mode makes it easier to write Octave code by helping with
 424 indentation, doing some of the typing for you (with Abbrev mode) and by
 425 showing keywords, comments, strings, etc. in different faces (with
 426 Font Lock mode on terminals that support it).
 427
 428 Octave itself is a high-level language, primarily intended for numerical
 429 computations.  It provides a convenient command line interface for
 430 solving linear and nonlinear problems numerically.  Function definitions
 431 can also be stored in files, and it can be used in a batch mode (which
 432 is why you need this mode!).
 433
 434 The latest released version of Octave is always available via anonymous
 435 ftp from bevo.che.wisc.edu in the directory `/pub/octave'.  Complete
 436 source and binaries for several popular systems are available.
 437
 438 Type \\[list-abbrevs] to display the built-in abbrevs for Octave keywords.
 439
 440 Keybindings
 441 ===========
 442
 443 \\{octave-mode-map}
 444
 445 Variables you can use to customize Octave mode
 446 ==============================================
 447
 448 octave-auto-indent
 449   Non-nil means indent current line after a semicolon or space.
 450   Default is nil.
 451
 452 octave-auto-newline
 453   Non-nil means auto-insert a newline and indent after a semicolon.
 454   Default is nil.
 455
 456 octave-blink-matching-block
 457   Non-nil means show matching begin of block when inserting a space,
 458   newline or semicolon after an else or end keyword.  Default is t.
 459
 460 octave-block-offset
 461   Extra indentation applied to statements in block structures.
 462   Default is 2.
 463
 464 octave-continuation-offset
 465   Extra indentation applied to Octave continuation lines.
 466   Default is 4.
 467
 468 octave-continuation-string
 469   String used for Octave continuation lines.
 470   Default is a backslash.
 471
 472 octave-mode-startup-message
 473   nil means do not display the Octave mode startup message.
 474   Default is t.
 475
 476 octave-send-echo-input
 477   Non-nil means always display `inferior-octave-buffer' after sending a
 478   command to the inferior Octave process.
 479
 480 octave-send-line-auto-forward
 481   Non-nil means always go to the next unsent line of Octave code after
 482   sending a line to the inferior Octave process.
 483
 484 octave-send-echo-input
 485   Non-nil means echo input sent to the inferior Octave process.
 486
 487 Turning on Octave mode runs the hook `octave-mode-hook'.
 488
 489 To begin using this mode for all `.m' files that you edit, add the
 490 following lines to your `.emacs' file:
 491
 492   (autoload 'octave-mode \"octave-mod\" nil t)
 493   (setq auto-mode-alist
 494         (cons '(\"\\\\.m$\" . octave-mode) auto-mode-alist))
 495
 496 To automatically turn on the abbrev, auto-fill and font-lock features,
 497 add the following lines to your `.emacs' file as well:
 498
 499   (add-hook 'octave-mode-hook
 500             (lambda ()
 501               (abbrev-mode 1)
 502               (auto-fill-mode 1)
 503               (if (eq window-system 'x)
 504                   (font-lock-mode 1))))
 505
 506 To submit a problem report, enter \\[octave-submit-bug-report] from \
 507 an Octave mode buffer.
 508 This automatically sets up a mail buffer with version information
 509 already added.  You just need to add a description of the problem,
 510 including a reproducible test case and send the message."
 511   (interactive)
 512   (kill-all-local-variables)
 513
 514   (use-local-map octave-mode-map)
 515   (setq major-mode 'octave-mode)
 516   (setq mode-name "Octave")
 517   (setq local-abbrev-table octave-abbrev-table)
 518   (set-syntax-table octave-mode-syntax-table)
 519
 520   (make-local-variable 'indent-line-function)
 521   (setq indent-line-function 'octave-indent-line)
 522
 523   (make-local-variable 'comment-start)
 524   (setq comment-start octave-comment-start)
 525   (make-local-variable 'comment-end)
 526   (setq comment-end "")
 527   (make-local-variable 'comment-column)
 528   (setq comment-column 32)
 529   (make-local-variable 'comment-start-skip)
 530   (setq comment-start-skip "\\s<+\\s-*")
 531   (make-local-variable 'comment-indent-function)
 532   (setq comment-indent-function 'octave-comment-indent)
 533
 534   (make-local-variable 'parse-sexp-ignore-comments)
 535   (setq parse-sexp-ignore-comments t)
 536   (make-local-variable 'paragraph-start)
 537   (setq paragraph-start (concat "\\s-*$\\|" page-delimiter))
 538   (make-local-variable 'paragraph-separate)
 539   (setq paragraph-separate paragraph-start)
 540   (make-local-variable 'paragraph-ignore-fill-prefix)
 541   (setq paragraph-ignore-fill-prefix t)
 542   (make-local-variable 'fill-paragraph-function)
 543   (setq fill-paragraph-function 'octave-fill-paragraph)
 544   (make-local-variable 'adaptive-fill-regexp)
 545   (setq adaptive-fill-regexp nil)
 546   (make-local-variable 'fill-column)
 547   (setq fill-column 72)
 548   (make-local-variable 'normal-auto-fill-function)
 549   (setq normal-auto-fill-function 'octave-auto-fill)
 550
 551   (make-local-variable 'font-lock-defaults)
 552   (setq font-lock-defaults '(octave-font-lock-keywords nil nil))
 553
 554   (make-local-variable 'imenu-generic-expression)
 555   (setq imenu-generic-expression octave-mode-imenu-generic-expression
 556         imenu-case-fold-search nil)
 557
 558   (octave-add-octave-menu)
 559   (octave-initialize-completions)
 560   (run-mode-hooks 'octave-mode-hook))
 561 \f
 562 ;;; Miscellaneous useful functions
 563 (defun octave-describe-major-mode ()
 564   "Describe the current major mode."
 565   (interactive)
 566   (describe-function major-mode))
 567
 568 (defsubst octave-in-comment-p ()
 569   "Returns t if point is inside an Octave comment, nil otherwise."
 570   (interactive)
 571   (save-excursion
 572     (nth 4 (parse-partial-sexp (line-beginning-position) (point)))))
 573
 574 (defsubst octave-in-string-p ()
 575   "Returns t if point is inside an Octave string, nil otherwise."
 576   (interactive)
 577   (save-excursion
 578     (nth 3 (parse-partial-sexp (line-beginning-position) (point)))))
 579
 580 (defsubst octave-not-in-string-or-comment-p ()
 581   "Returns t iff point is not inside an Octave string or comment."
 582   (let ((pps (parse-partial-sexp (line-beginning-position) (point))))
 583     (not (or (nth 3 pps) (nth 4 pps)))))
 584
 585 (defun octave-in-block-p ()
 586   "Returns t if point is inside an Octave block, nil otherwise.
 587 The block is taken to start at the first letter of the begin keyword and
 588 to end after the end keyword."
 589   (let ((pos (point)))
 590     (save-excursion
 591       (condition-case nil
 592           (progn
 593             (skip-syntax-forward "w")
 594             (octave-up-block -1)
 595             (octave-forward-block)
 596             t)
 597         (error nil))
 598       (< pos (point)))))
 599
 600 (defun octave-in-defun-p ()
 601   "Returns t iff point is inside an Octave function declaration.
 602 The function is taken to start at the `f' of `function' and to end after
 603 the end keyword."
 604   (let ((pos (point)))
 605     (save-excursion
 606       (or (and (looking-at "\\<function\\>")
 607                (octave-not-in-string-or-comment-p))
 608           (and (octave-beginning-of-defun)
 609                (condition-case nil
 610                    (progn
 611                      (octave-forward-block)
 612                      t)
 613                  (error nil))
 614                (< pos (point)))))))
 615
 616 (defun octave-maybe-insert-continuation-string ()
 617   (if (or (octave-in-comment-p)
 618           (save-excursion
 619             (beginning-of-line)
 620             (looking-at octave-continuation-regexp)))
 621       nil
 622     (delete-horizontal-space)
 623     (insert (concat " " octave-continuation-string))))
 624
 625 (defvar octave-xemacs-p
 626   (string-match "XEmacs\\|Lucid" emacs-version))
 627
 628 ;;; Comments
 629 (defun octave-comment-region (beg end &optional arg)
 630   "Comment or uncomment each line in the region as Octave code.
 631 See `comment-region'."
 632   (interactive "r\nP")
 633   (let ((comment-start (char-to-string octave-comment-char)))
 634     (comment-region beg end arg)))
 635
 636 (defun octave-uncomment-region (beg end &optional arg)
 637   "Uncomment each line in the region as Octave code."
 638   (interactive "r\nP")
 639   (or arg (setq arg 1))
 640   (octave-comment-region beg end (- arg)))
 641
 642 \f
 643 ;;; Indentation
 644 (defun calculate-octave-indent ()
 645   "Return appropriate indentation for current line as Octave code.
 646 Returns an integer (the column to indent to) unless the line is a
 647 comment line with fixed goal golumn.  In that case, returns a list whose
 648 car is the column to indent to, and whose cdr is the current indentation
 649 level."
 650   (let ((is-continuation-line
 651          (save-excursion
 652            (if (zerop (octave-previous-code-line))
 653                (looking-at octave-continuation-regexp))))
 654         (icol 0))
 655     (save-excursion
 656       (beginning-of-line)
 657       ;; If we can move backward out one level of parentheses, take 1
 658       ;; plus the indentation of that parenthesis.  Otherwise, go back
 659       ;; to the beginning of the previous code line, and compute the
 660       ;; offset this line gives.
 661       (if (condition-case nil
 662               (progn
 663                 (up-list -1)
 664                 t)
 665             (error nil))
 666           (setq icol (+ 1 (current-column)))
 667         (if (zerop (octave-previous-code-line))
 668             (progn
 669               (octave-beginning-of-line)
 670               (back-to-indentation)
 671               (setq icol (current-column))
 672               (let ((bot (point))
 673                     (eol (line-end-position)))
 674                 (while (< (point) eol)
 675                   (if (octave-not-in-string-or-comment-p)
 676                       (cond
 677                        ((looking-at "\\<switch\\>")
 678                         (setq icol (+ icol (* 2 octave-block-offset))))
 679                        ((looking-at octave-block-begin-regexp)
 680                         (setq icol (+ icol octave-block-offset)))
 681                        ((looking-at octave-block-else-regexp)
 682                         (if (= bot (point))
 683                             (setq icol (+ icol octave-block-offset))))
 684                        ((looking-at octave-block-end-regexp)
 685                         (if (not (= bot (point)))
 686                             (setq icol (- icol
 687                                           (octave-block-end-offset)))))))
 688                   (forward-char)))
 689               (if is-continuation-line
 690                   (setq icol (+ icol octave-continuation-offset)))))))
 691     (save-excursion
 692       (back-to-indentation)
 693       (cond
 694        ((and (looking-at octave-block-else-regexp)
 695              (octave-not-in-string-or-comment-p))
 696         (setq icol (- icol octave-block-offset)))
 697        ((and (looking-at octave-block-end-regexp)
 698              (octave-not-in-string-or-comment-p))
 699         (setq icol (- icol (octave-block-end-offset))))
 700        ((or (looking-at "\\s<\\s<\\s<\\S<")
 701             (octave-before-magic-comment-p))
 702         (setq icol (list 0 icol)))
 703        ((looking-at "\\s<\\S<")
 704         (setq icol (list comment-column icol)))))
 705     icol))
 706
 707 (defun octave-block-end-offset ()
 708   (save-excursion
 709     (octave-backward-up-block 1)
 710     (* octave-block-offset
 711        (if (string-match (match-string 0) "switch") 2 1))))
 712
 713 (defun octave-before-magic-comment-p ()
 714   (save-excursion
 715     (beginning-of-line)
 716     (and (bobp) (looking-at "\\s-*#!"))))
 717
 718 (defun octave-comment-indent ()
 719   (if (or (looking-at "\\s<\\s<\\s<")
 720           (octave-before-magic-comment-p))
 721       0
 722     (if (looking-at "\\s<\\s<")
 723         (calculate-octave-indent)
 724       (skip-syntax-backward " ")
 725       (max (if (bolp) 0 (+ 1 (current-column)))
 726            comment-column))))
 727
 728 (defun octave-indent-for-comment ()
 729   "Maybe insert and indent an Octave comment.
 730 If there is no comment already on this line, create a code-level comment
 731 \(started by two comment characters) if the line is empty, or an in-line
 732 comment (started by one comment character) otherwise.
 733 Point is left after the start of the comment which is properly aligned."
 734   (interactive)
 735   (beginning-of-line)
 736   (if (looking-at "^\\s-*$")
 737       (insert octave-block-comment-start)
 738     (indent-for-comment))
 739   (indent-according-to-mode))
 740
 741 (defun octave-indent-line (&optional arg)
 742   "Indent current line as Octave code.
 743 With optional ARG, use this as offset unless this line is a comment with
 744 fixed goal column."
 745   (interactive)
 746   (or arg (setq arg 0))
 747   (let ((icol (calculate-octave-indent))
 748         (relpos (- (current-column) (current-indentation))))
 749     (if (listp icol)
 750         (setq icol (car icol))
 751       (setq icol (+ icol arg)))
 752     (if (< icol 0)
 753         (error "Unmatched end keyword")
 754       (indent-line-to icol)
 755       (if (> relpos 0)
 756           (move-to-column (+ icol relpos))))))
 757
 758 (defun octave-indent-new-comment-line ()
 759   "Break Octave line at point, continuing comment if within one.
 760 If within code, insert `octave-continuation-string' before breaking the
 761 line.  If within a string, signal an error.
 762 The new line is properly indented."
 763   (interactive)
 764   (delete-horizontal-space)
 765   (cond
 766    ((octave-in-comment-p)
 767     (indent-new-comment-line))
 768    ((octave-in-string-p)
 769     (error "Cannot split a code line inside a string"))
 770    (t
 771     (insert (concat " " octave-continuation-string))
 772     (octave-reindent-then-newline-and-indent))))
 773
 774 (defun octave-indent-defun ()
 775   "Properly indents the Octave function which contains point."
 776   (interactive)
 777   (save-excursion
 778     (octave-mark-defun)
 779     (message "Indenting function...")
 780     (indent-region (point) (mark) nil))
 781   (message "Indenting function...done."))
 782
 783 \f
 784 ;;; Motion
 785 (defun octave-next-code-line (&optional arg)
 786   "Move ARG lines of Octave code forward (backward if ARG is negative).
 787 Skips past all empty and comment lines.  Default for ARG is 1.
 788
 789 On success, return 0.  Otherwise, go as far as possible and return -1."
 790   (interactive "p")
 791   (or arg (setq arg 1))
 792   (beginning-of-line)
 793   (let ((n 0)
 794         (inc (if (> arg 0) 1 -1)))
 795     (while (and (/= arg 0) (= n 0))
 796       (setq n (forward-line inc))
 797       (while (and (= n 0)
 798                   (looking-at "\\s-*\\($\\|\\s<\\)"))
 799         (setq n (forward-line inc)))
 800       (setq arg (- arg inc)))
 801     n))
 802
 803 (defun octave-previous-code-line (&optional arg)
 804   "Move ARG lines of Octave code backward (forward if ARG is negative).
 805 Skips past all empty and comment lines.  Default for ARG is 1.
 806
 807 On success, return 0.  Otherwise, go as far as possible and return -1."
 808   (interactive "p")
 809   (or arg (setq arg 1))
 810   (octave-next-code-line (- arg)))
 811
 812 (defun octave-beginning-of-line ()
 813   "Move point to beginning of current Octave line.
 814 If on an empty or comment line, go to the beginning of that line.
 815 Otherwise, move backward to the beginning of the first Octave code line
 816 which is not inside a continuation statement, i.e., which does not
 817 follow a code line ending in `...' or `\\', or is inside an open
 818 parenthesis list."
 819   (interactive)
 820   (beginning-of-line)
 821   (if (not (looking-at "\\s-*\\($\\|\\s<\\)"))
 822       (while (or (condition-case nil
 823                      (progn
 824                        (up-list -1)
 825                        (beginning-of-line)
 826                        t)
 827                    (error nil))
 828                  (and (or (looking-at "\\s-*\\($\\|\\s<\\)")
 829                           (save-excursion
 830                             (if (zerop (octave-previous-code-line))
 831                                 (looking-at octave-continuation-regexp))))
 832                       (zerop (forward-line -1)))))))
 833
 834 (defun octave-end-of-line ()
 835   "Move point to end of current Octave line.
 836 If on an empty or comment line, go to the end of that line.
 837 Otherwise, move forward to the end of the first Octave code line which
 838 does not end in `...' or `\\' or is inside an open parenthesis list."
 839   (interactive)
 840   (end-of-line)
 841   (if (save-excursion
 842         (beginning-of-line)
 843         (looking-at "\\s-*\\($\\|\\s<\\)"))
 844       ()
 845     (while (or (condition-case nil
 846                    (progn
 847                      (up-list 1)
 848                      (end-of-line)
 849                      t)
 850                  (error nil))
 851                (and (save-excursion
 852                       (beginning-of-line)
 853                       (or (looking-at "\\s-*\\($\\|\\s<\\)")
 854                           (looking-at octave-continuation-regexp)))
 855                     (zerop (forward-line 1)))))
 856     (end-of-line)))
 857
 858 (defun octave-scan-blocks (from count depth)
 859   "Scan from character number FROM by COUNT Octave begin-end blocks.
 860 Returns the character number of the position thus found.
 861
 862 If DEPTH is nonzero, block depth begins counting from that value.
 863 Only places where the depth in blocks becomes zero are candidates for
 864 stopping; COUNT such places are counted.
 865
 866 If the beginning or end of the buffer is reached and the depth is wrong,
 867 an error is signaled."
 868   (let ((min-depth (if (> depth 0) 0 depth))
 869         (inc (if (> count 0) 1 -1)))
 870     (save-excursion
 871       (while (/= count 0)
 872         (catch 'foo
 873           (while (or (re-search-forward
 874                       octave-block-begin-or-end-regexp nil 'move inc)
 875                      (if (/= depth 0)
 876                          (error "Unbalanced block")))
 877             (if (octave-not-in-string-or-comment-p)
 878                 (progn
 879                   (cond
 880                    ((match-end 1)
 881                     (setq depth (+ depth inc)))
 882                    ((match-end 2)
 883                     (setq depth (- depth inc))))
 884                   (if (< depth min-depth)
 885                       (error "Containing expression ends prematurely"))
 886                   (if (= depth 0)
 887                       (throw 'foo nil))))))
 888         (setq count (- count inc)))
 889       (point))))
 890
 891 (defun octave-forward-block (&optional arg)
 892   "Move forward across one balanced Octave begin-end block.
 893 With argument, do it that many times.
 894 Negative arg -N means move backward across N blocks."
 895   (interactive "p")
 896   (or arg (setq arg 1))
 897   (goto-char (or (octave-scan-blocks (point) arg 0) (buffer-end arg))))
 898
 899 (defun octave-backward-block (&optional arg)
 900   "Move backward across one balanced Octave begin-end block.
 901 With argument, do it that many times.
 902 Negative arg -N means move forward across N blocks."
 903   (interactive "p")
 904   (or arg (setq arg 1))
 905   (octave-forward-block (- arg)))
 906
 907 (defun octave-down-block (arg)
 908   "Move forward down one begin-end block level of Octave code.
 909 With argument, do this that many times.
 910 A negative argument means move backward but still go down a level.
 911 In Lisp programs, an argument is required."
 912   (interactive "p")
 913   (let ((inc (if (> arg 0) 1 -1)))
 914     (while (/= arg 0)
 915       (goto-char (or (octave-scan-blocks (point) inc -1)
 916                      (buffer-end arg)))
 917       (setq arg (- arg inc)))))
 918
 919 (defun octave-backward-up-block (arg)
 920   "Move backward out of one begin-end block level of Octave code.
 921 With argument, do this that many times.
 922 A negative argument means move forward but still to a less deep spot.
 923 In Lisp programs, an argument is required."
 924   (interactive "p")
 925   (octave-up-block (- arg)))
 926
 927 (defun octave-up-block (arg)
 928   "Move forward out of one begin-end block level of Octave code.
 929 With argument, do this that many times.
 930 A negative argument means move backward but still to a less deep spot.
 931 In Lisp programs, an argument is required."
 932   (interactive "p")
 933   (let ((inc (if (> arg 0) 1 -1)))
 934     (while (/= arg 0)
 935       (goto-char (or (octave-scan-blocks (point) inc 1)
 936                      (buffer-end arg)))
 937       (setq arg (- arg inc)))))
 938
 939 (defun octave-mark-block ()
 940   "Put point at the beginning of this Octave block, mark at the end.
 941 The block marked is the one that contains point or follows point."
 942   (interactive)
 943   (let ((pos (point)))
 944     (if (or (and (octave-in-block-p)
 945                  (skip-syntax-forward "w"))
 946             (condition-case nil
 947                 (progn
 948                   (octave-down-block 1)
 949                   (octave-in-block-p))
 950               (error nil)))
 951         (progn
 952           (octave-up-block -1)
 953           (push-mark (point))
 954           (octave-forward-block)
 955           (exchange-point-and-mark))
 956       (goto-char pos)
 957       (message "No block to mark found"))))
 958
 959 (defun octave-close-block ()
 960   "Close the current Octave block on a separate line.
 961 An error is signaled if no block to close is found."
 962   (interactive)
 963   (let (bb-keyword)
 964     (condition-case nil
 965         (progn
 966           (save-excursion
 967             (octave-backward-up-block 1)
 968             (setq bb-keyword (buffer-substring-no-properties
 969                               (match-beginning 1) (match-end 1))))
 970           (if (save-excursion
 971                 (beginning-of-line)
 972                 (looking-at "^\\s-*$"))
 973               (indent-according-to-mode)
 974             (octave-reindent-then-newline-and-indent))
 975           (insert (car (reverse
 976                         (assoc bb-keyword
 977                                octave-block-match-alist))))
 978           (octave-reindent-then-newline-and-indent)
 979           t)
 980       (error (message "No block to close found")))))
 981
 982 (defun octave-blink-matching-block-open ()
 983   "Blink the matching Octave begin block keyword.
 984 If point is right after an Octave else or end type block keyword, move
 985 cursor momentarily to the corresponding begin keyword.
 986 Signal an error if the keywords are incompatible."
 987   (interactive)
 988   (let (bb-keyword bb-arg eb-keyword pos eol)
 989     (if (and (octave-not-in-string-or-comment-p)
 990              (looking-at "\\>")
 991              (save-excursion
 992                (skip-syntax-backward "w")
 993                (looking-at octave-block-else-or-end-regexp)))
 994         (save-excursion
 995           (cond
 996            ((match-end 1)
 997             (setq eb-keyword
 998                   (buffer-substring-no-properties
 999                    (match-beginning 1) (match-end 1)))
1000             (octave-backward-up-block 1))
1001            ((match-end 2)
1002             (setq eb-keyword
1003                   (buffer-substring-no-properties
1004                    (match-beginning 2) (match-end 2)))
1005             (octave-backward-block)))
1006           (setq pos (match-end 0)
1007                 bb-keyword
1008                 (buffer-substring-no-properties
1009                  (match-beginning 0) pos)
1010                 pos (+ pos 1)
1011                 eol (line-end-position)
1012                 bb-arg
1013                 (save-excursion
1014                   (save-restriction
1015                     (goto-char pos)
1016                     (while (and (skip-syntax-forward "^<" eol)
1017                                 (octave-in-string-p)
1018                                 (not (forward-char 1))))
1019                     (skip-syntax-backward " ")
1020                     (buffer-substring-no-properties pos (point)))))
1021           (if (member eb-keyword
1022                       (cdr (assoc bb-keyword octave-block-match-alist)))
1023               (progn
1024                 (message "Matches `%s %s'" bb-keyword bb-arg)
1025                 (if (pos-visible-in-window-p)
1026                     (sit-for blink-matching-delay)))
1027             (error "Block keywords `%s' and `%s' do not match"
1028                    bb-keyword eb-keyword))))))
1029
1030 (defun octave-beginning-of-defun (&optional arg)
1031   "Move backward to the beginning of an Octave function.
1032 With positive ARG, do it that many times.  Negative argument -N means
1033 move forward to Nth following beginning of a function.
1034 Returns t unless search stops at the beginning or end of the buffer."
1035   (interactive "p")
1036   (let* ((arg (or arg 1))
1037          (inc (if (> arg 0) 1 -1))
1038          (found))
1039     (and (not (eobp))
1040          (not (and (> arg 0) (looking-at "\\<function\\>")))
1041          (skip-syntax-forward "w"))
1042     (while (and (/= arg 0)
1043                 (setq found
1044                       (re-search-backward "\\<function\\>" nil 'move inc)))
1045       (if (octave-not-in-string-or-comment-p)
1046           (setq arg (- arg inc))))
1047     (if found
1048         (progn
1049           (and (< inc 0) (goto-char (match-beginning 0)))
1050           t))))
1051
1052 (defun octave-end-of-defun (&optional arg)
1053   "Move forward to the end of an Octave function.
1054 With positive ARG, do it that many times.  Negative argument -N means
1055 move back to Nth preceding end of a function.
1056
1057 An end of a function occurs right after the end keyword matching the
1058 `function' keyword that starts the function."
1059   (interactive "p")
1060   (or arg (setq arg 1))
1061   (and (< arg 0) (skip-syntax-backward "w"))
1062   (and (> arg 0) (skip-syntax-forward "w"))
1063   (if (octave-in-defun-p)
1064       (setq arg (- arg 1)))
1065   (if (= arg 0) (setq arg -1))
1066   (if (octave-beginning-of-defun (- arg))
1067       (octave-forward-block)))
1068
1069 (defun octave-mark-defun ()
1070   "Put point at the beginning of this Octave function, mark at its end.
1071 The function marked is the one containing point or following point."
1072   (interactive)
1073   (let ((pos (point)))
1074     (if (or (octave-in-defun-p)
1075             (and (octave-beginning-of-defun -1)
1076                  (octave-in-defun-p)))
1077         (progn
1078           (skip-syntax-forward "w")
1079           (octave-beginning-of-defun)
1080           (push-mark (point))
1081           (octave-end-of-defun)
1082           (exchange-point-and-mark))
1083       (goto-char pos)
1084       (message "No function to mark found"))))
1085
1086 \f
1087 ;;; Filling
1088 (defun octave-auto-fill ()
1089   "Perform auto-fill in Octave mode.
1090 Returns nil if no feasible place to break the line could be found, and t
1091 otherwise."
1092   (let (fc give-up)
1093     (if (or (null (setq fc (current-fill-column)))
1094             (save-excursion
1095               (beginning-of-line)
1096               (and auto-fill-inhibit-regexp
1097                    (looking-at auto-fill-inhibit-regexp))))
1098         nil                             ; Can't do anything
1099       (if (and (not (octave-in-comment-p))
1100                (> (current-column) fc))
1101           (setq fc (- fc (+ (length octave-continuation-string) 1))))
1102       (while (and (not give-up) (> (current-column) fc))
1103         (let* ((opoint (point))
1104                (fpoint
1105                 (save-excursion
1106                   (move-to-column (+ fc 1))
1107                   (skip-chars-backward "^ \t\n")
1108                   ;; If we're at the beginning of the line, break after
1109                   ;; the first word
1110                   (if (bolp)
1111                       (re-search-forward "[ \t]" opoint t))
1112                   ;; If we're in a comment line, don't break after the
1113                   ;; comment chars
1114                   (if (save-excursion
1115                         (skip-syntax-backward " <")
1116                         (bolp))
1117                       (re-search-forward "[ \t]" (line-end-position)
1118                                          'move))
1119                   ;; If we're not in a comment line and just ahead the
1120                   ;; continuation string, don't break here.
1121                   (if (and (not (octave-in-comment-p))
1122                            (looking-at
1123                             (concat "\\s-*"
1124                                     (regexp-quote
1125                                      octave-continuation-string)
1126                                     "\\s-*$")))
1127                       (end-of-line))
1128                   (skip-chars-backward " \t")
1129                   (point))))
1130           (if (save-excursion
1131                 (goto-char fpoint)
1132                 (not (or (bolp) (eolp))))
1133               (let ((prev-column (current-column)))
1134                 (if (save-excursion
1135                       (skip-chars-backward " \t")
1136                       (= (point) fpoint))
1137                     (progn
1138                       (octave-maybe-insert-continuation-string)
1139                       (indent-new-comment-line t))
1140                   (save-excursion
1141                     (goto-char fpoint)
1142                     (octave-maybe-insert-continuation-string)
1143                     (indent-new-comment-line t)))
1144                 (if (>= (current-column) prev-column)
1145                     (setq give-up t)))
1146             (setq give-up t))))
1147       (not give-up))))
1148
1149 (defun octave-fill-paragraph (&optional arg)
1150  "Fill paragraph of Octave code, handling Octave comments."
1151  (interactive "P")
1152  (save-excursion
1153    (let ((end (progn (forward-paragraph) (point)))
1154          (beg (progn
1155                 (forward-paragraph -1)
1156                 (skip-chars-forward " \t\n")
1157                 (beginning-of-line)
1158                 (point)))
1159          (cfc (current-fill-column))
1160          (ind (calculate-octave-indent))
1161          comment-prefix)
1162      (save-restriction
1163        (goto-char beg)
1164        (narrow-to-region beg end)
1165        (if (listp ind) (setq ind (nth 1 ind)))
1166        (while (not (eobp))
1167          (condition-case nil
1168              (octave-indent-line ind)
1169            (error nil))
1170          (if (and (> ind 0)
1171                   (not
1172                    (save-excursion
1173                      (beginning-of-line)
1174                      (looking-at "^\\s-*\\($\\|\\s<+\\)"))))
1175              (setq ind 0))
1176          (move-to-column cfc)
1177          ;; First check whether we need to combine non-empty comment lines
1178          (if (and (< (current-column) cfc)
1179                   (octave-in-comment-p)
1180                   (not (save-excursion
1181                          (beginning-of-line)
1182                          (looking-at "^\\s-*\\s<+\\s-*$"))))
1183              ;; This is a nonempty comment line which does not extend
1184              ;; past the fill column.  If it is followed by a nonempty
1185              ;; comment line with the same comment prefix, try to
1186              ;; combine them, and repeat this until either we reach the
1187              ;; fill-column or there is nothing more to combine.
1188              (progn
1189                ;; Get the comment prefix
1190                (save-excursion
1191                  (beginning-of-line)
1192                  (while (and (re-search-forward "\\s<+")
1193                              (not (octave-in-comment-p))))
1194                  (setq comment-prefix (match-string 0)))
1195                ;; And keep combining ...
1196                (while (and (< (current-column) cfc)
1197                            (save-excursion
1198                              (forward-line 1)
1199                              (and (looking-at
1200                                    (concat "^\\s-*"
1201                                            comment-prefix
1202                                            "\\S<"))
1203                                   (not (looking-at
1204                                         (concat "^\\s-*"
1205                                                 comment-prefix
1206                                                 "\\s-*$"))))))
1207                  (delete-char 1)
1208                  (re-search-forward comment-prefix)
1209                  (delete-region (match-beginning 0) (match-end 0))
1210                  (fixup-whitespace)
1211                  (move-to-column cfc))))
1212          ;; We might also try to combine continued code lines>  Perhaps
1213          ;; some other time ...
1214          (skip-chars-forward "^ \t\n")
1215          (delete-horizontal-space)
1216          (if (or (< (current-column) cfc)
1217                  (and (= (current-column) cfc) (eolp)))
1218              (forward-line 1)
1219            (if (not (eolp)) (insert " "))
1220            (or (octave-auto-fill)
1221                (forward-line 1)))))
1222      t)))
1223
1224 \f
1225 ;;; Completions
1226 (defun octave-initialize-completions ()
1227   "Create an alist for Octave completions."
1228   (if octave-completion-alist
1229       ()
1230     (setq octave-completion-alist
1231           (mapcar '(lambda (var) (cons var var))
1232                   (append octave-reserved-words
1233                           octave-text-functions
1234                           octave-variables)))))
1235
1236 (defun octave-complete-symbol ()
1237   "Perform completion on Octave symbol preceding point.
1238 Compare that symbol against Octave's reserved words and builtin
1239 variables."
1240   ;; This code taken from lisp-complete-symbol
1241   (interactive)
1242   (let* ((end (point))
1243          (beg (save-excursion (backward-sexp 1) (point)))
1244          (string (buffer-substring-no-properties beg end))
1245          (completion (try-completion string octave-completion-alist)))
1246     (cond ((eq completion t))           ; ???
1247           ((null completion)
1248            (message "Can't find completion for \"%s\"" string)
1249            (ding))
1250           ((not (string= string completion))
1251            (delete-region beg end)
1252            (insert completion))
1253           (t
1254            (let ((list (all-completions string octave-completion-alist))
1255                  (conf (current-window-configuration)))
1256              ;; Taken from comint.el
1257              (message "Making completion list...")
1258              (with-output-to-temp-buffer "*Completions*"
1259                (display-completion-list list string))
1260              (message "Hit space to flush")
1261              (let (key first)
1262                (if (save-excursion
1263                      (set-buffer (get-buffer "*Completions*"))
1264                      (setq key (read-key-sequence nil)
1265                            first (aref key 0))
1266                      (and (consp first) (consp (event-start first))
1267                           (eq (window-buffer (posn-window (event-start
1268                                                            first)))
1269                               (get-buffer "*Completions*"))
1270                           (eq (key-binding key) 'mouse-choose-completion)))
1271                    (progn
1272                      (mouse-choose-completion first)
1273                      (set-window-configuration conf))
1274                  (if (eq first ?\ )
1275                      (set-window-configuration conf)
1276                    (setq unread-command-events
1277                          (listify-key-sequence key))))))))))
1278
1279 \f
1280 ;;; Electric characters && friends
1281 (defun octave-reindent-then-newline-and-indent ()
1282   "Reindent current Octave line, insert newline, and indent the new line.
1283 If Abbrev mode is on, expand abbrevs first."
1284   (interactive)
1285   (if abbrev-mode (expand-abbrev))
1286   (if octave-blink-matching-block
1287       (octave-blink-matching-block-open))
1288   (save-excursion
1289     (delete-region (point) (progn (skip-chars-backward " \t") (point)))
1290     (indent-according-to-mode))
1291   (insert "\n")
1292   (indent-according-to-mode))
1293
1294 (defun octave-electric-semi ()
1295   "Insert a semicolon in Octave mode.
1296 Maybe expand abbrevs and blink matching block open keywords.
1297 Reindent the line of `octave-auto-indent' is non-nil.
1298 Insert a newline if `octave-auto-newline' is non-nil."
1299   (interactive)
1300   (if (not (octave-not-in-string-or-comment-p))
1301       (insert ";")
1302     (if abbrev-mode (expand-abbrev))
1303     (if octave-blink-matching-block
1304         (octave-blink-matching-block-open))
1305     (if octave-auto-indent
1306         (indent-according-to-mode))
1307     (insert ";")
1308     (if octave-auto-newline
1309         (newline-and-indent))))
1310
1311 (defun octave-electric-space ()
1312   "Insert a space in Octave mode.
1313 Maybe expand abbrevs and blink matching block open keywords.
1314 Reindent the line of `octave-auto-indent' is non-nil."
1315   (interactive)
1316   (setq last-command-char ? )
1317   (if (and octave-auto-indent
1318            (not (octave-not-in-string-or-comment-p)))
1319       (progn
1320         (indent-according-to-mode)
1321         (self-insert-command 1))
1322     (if abbrev-mode (expand-abbrev))
1323     (if octave-blink-matching-block
1324         (octave-blink-matching-block-open))
1325     (if (and octave-auto-indent
1326              (save-excursion
1327                (skip-syntax-backward " ")
1328                (not (bolp))))
1329         (indent-according-to-mode))
1330     (self-insert-command 1)))
1331
1332 (defun octave-abbrev-start ()
1333   "Start entering an Octave abbreviation.
1334 If Abbrev mode is turned on, typing ` (grave accent) followed by ? or
1335 \\[help-command] lists all Octave abbrevs.  Any other key combination is
1336 executed normally.
1337 Note that all Octave mode abbrevs start with a grave accent."
1338   (interactive)
1339   (if (not abbrev-mode)
1340       (self-insert-command 1)
1341     (let (c)
1342       (insert last-command-char)
1343       (if (if octave-xemacs-p
1344               (or (eq (event-to-character (setq c (next-event))) ??)
1345                   (eq (event-to-character c) help-char))
1346             (or (eq (setq c (read-event)) ??)
1347                 (eq c help-char)))
1348           (let ((abbrev-table-name-list '(octave-abbrev-table)))
1349             (list-abbrevs))
1350         (setq unread-command-events (list c))))))
1351
1352 (defun octave-insert-defun (name args vals)
1353   "Insert an Octave function skeleton.
1354 Prompt for the function's name, arguments and return values (to be
1355 entered without parens)."
1356   (interactive
1357    (list
1358     (read-from-minibuffer "Function name: "
1359                           (substring (buffer-name) 0 -2))
1360     (read-from-minibuffer "Arguments: ")
1361     (read-from-minibuffer "Return values: ")))
1362   (let ((string (format "%s %s (%s)"
1363                         (cond
1364                          ((string-equal vals "")
1365                           vals)
1366                          ((string-match "[ ,]" vals)
1367                           (concat " [" vals "] ="))
1368                          (t
1369                           (concat " " vals " =")))
1370                         name
1371                         args))
1372         (prefix octave-block-comment-start))
1373     (if (not (bobp)) (newline))
1374     (insert "function" string)
1375     (indent-according-to-mode)
1376     (newline 2)
1377     (insert prefix "usage: " string)
1378     (reindent-then-newline-and-indent)
1379     (insert prefix)
1380     (reindent-then-newline-and-indent)
1381     (insert prefix)
1382     (indent-according-to-mode)
1383     (save-excursion
1384       (newline 2)
1385       (insert "endfunction")
1386       (indent-according-to-mode))))
1387
1388 \f
1389 ;;; Menu
1390 (defun octave-add-octave-menu ()
1391   "Adds the `Octave' menu to the menu bar in Octave mode."
1392   (require 'easymenu)
1393   (easy-menu-define octave-mode-menu-map octave-mode-map
1394                     "Menu keymap for Octave mode." octave-mode-menu)
1395   (easy-menu-add octave-mode-menu-map octave-mode-map))
1396
1397 \f
1398 ;;; Communication with the inferior Octave process
1399 (defun octave-kill-process ()
1400   "Kill inferior Octave process and its buffer."
1401   (interactive)
1402   (if inferior-octave-process
1403       (progn
1404         (process-send-string inferior-octave-process "quit;\n")
1405         (accept-process-output inferior-octave-process)))
1406   (if inferior-octave-buffer
1407       (kill-buffer inferior-octave-buffer)))
1408
1409 (defun octave-show-process-buffer ()
1410   "Make sure that `inferior-octave-buffer' is displayed."
1411   (interactive)
1412   (if (get-buffer inferior-octave-buffer)
1413       (display-buffer inferior-octave-buffer)
1414     (message "No buffer named %s" inferior-octave-buffer)))
1415
1416 (defun octave-hide-process-buffer ()
1417   "Delete all windows that display `inferior-octave-buffer'."
1418   (interactive)
1419   (if (get-buffer inferior-octave-buffer)
1420       (delete-windows-on inferior-octave-buffer)
1421     (message "No buffer named %s" inferior-octave-buffer)))
1422
1423 (defun octave-send-region (beg end)
1424   "Send current region to the inferior Octave process."
1425   (interactive "r")
1426   (inferior-octave t)
1427   (let ((proc inferior-octave-process)
1428         (string (buffer-substring-no-properties beg end))
1429         line)
1430     (save-excursion
1431       (set-buffer inferior-octave-buffer)
1432       (setq inferior-octave-output-list nil)
1433       (while (not (string-equal string ""))
1434         (if (string-match "\n" string)
1435             (setq line (substring string 0 (match-beginning 0))
1436                   string (substring string (match-end 0)))
1437           (setq line string string ""))
1438         (setq inferior-octave-receive-in-progress t)
1439         (inferior-octave-send-list-and-digest (list (concat line "\n")))
1440         (while inferior-octave-receive-in-progress
1441           (accept-process-output proc))
1442         (insert-before-markers
1443          (mapconcat 'identity
1444                     (append
1445                      (if octave-send-echo-input (list line) (list ""))
1446                      (mapcar 'inferior-octave-strip-ctrl-g
1447                              inferior-octave-output-list)
1448                      (list inferior-octave-output-string))
1449                     "\n")))))
1450   (if octave-send-show-buffer
1451       (display-buffer inferior-octave-buffer)))
1452
1453 (defun octave-send-block ()
1454   "Send current Octave block to the inferior Octave process."
1455   (interactive)
1456   (save-excursion
1457     (octave-mark-block)
1458     (octave-send-region (point) (mark))))
1459
1460 (defun octave-send-defun ()
1461   "Send current Octave function to the inferior Octave process."
1462   (interactive)
1463   (save-excursion
1464     (octave-mark-defun)
1465     (octave-send-region (point) (mark))))
1466
1467 (defun octave-send-line (&optional arg)
1468   "Send current Octave code line to the inferior Octave process.
1469 With positive prefix ARG, send that many lines.
1470 If `octave-send-line-auto-forward' is non-nil, go to the next unsent
1471 code line."
1472   (interactive "P")
1473   (or arg (setq arg 1))
1474   (if (> arg 0)
1475       (let (beg end)
1476         (beginning-of-line)
1477         (setq beg (point))
1478         (octave-next-code-line (- arg 1))
1479         (end-of-line)
1480         (setq end (point))
1481         (if octave-send-line-auto-forward
1482             (octave-next-code-line 1))
1483         (octave-send-region beg end))))
1484
1485 (defun octave-eval-print-last-sexp ()
1486   "Evaluate Octave sexp before point and print value into current buffer."
1487   (interactive)
1488   (inferior-octave t)
1489   (let ((standard-output (current-buffer))
1490         (print-escape-newlines nil)
1491         (opoint (point)))
1492     (terpri)
1493     (prin1
1494      (save-excursion
1495        (forward-sexp -1)
1496        (inferior-octave-send-list-and-digest
1497         (list (concat (buffer-substring-no-properties (point) opoint)
1498                       "\n")))
1499        (mapconcat 'identity inferior-octave-output-list "\n")))
1500     (terpri)))
1501 \f
1502 ;;; Bug reporting
1503 (defun octave-submit-bug-report ()
1504   "Submit a bug report on the Emacs Octave package via mail."
1505   (interactive)
1506   (require 'reporter)
1507   (and
1508    (y-or-n-p "Do you want to submit a bug report? ")
1509    (reporter-submit-bug-report
1510     octave-maintainer-address
1511     (concat "Emacs version " emacs-version)
1512     (list
1513      'octave-auto-indent
1514      'octave-auto-newline
1515      'octave-blink-matching-block
1516      'octave-block-offset
1517      'octave-comment-char
1518      'octave-continuation-offset
1519      'octave-continuation-string
1520      'octave-help-files
1521      'octave-mode-startup-message
1522      'octave-send-echo-input
1523      'octave-send-line-auto-forward
1524      'octave-send-show-buffer))))
1525
1526 ;;; provide ourself
1527
1528 (provide 'octave-mod)
1529
1530 ;;; arch-tag: 05f1ce09-be87-4c00-803e-4919ffa26c23
1531 ;;; octave-mod.el ends here