code.delx.au - gnu-emacs/blob - lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 1986, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ; These are processed only at the beginning of the argument list.
  27 ; -batch                execute noninteractively (messages go to stdout,
  28 ;                        variable noninteractive set to t)
  29 ;                        This option must be the first in the arglist.
  30 ;                        Processed by `main' in emacs.c -- never seen by lisp
  31 ; -t file               Specify to use file rather than stdin/stdout
  32 ;                        as the terminal.
  33 ;                        This option must be the first in the arglist.
  34 ;                        Processed by `main' in emacs.c -- never seen by lisp
  35 ; -nw                   Inhibit the use of any window-system-specific display
  36 ;                        code; use the current virtual terminal.
  37 ;                        This option must be the first in the arglist.
  38 ;                        Processed by `main' in emacs.c -- never seen by lisp
  39 ; -q                    load no init file
  40 ; -no-init-file         same
  41 ; -u user               load user's init file
  42 ; -user user            same
  43 ; -debug-init           Don't catch errors in init file; let debugger run.
  44
  45 ; These are processed in the order encountered.
  46 ; -f function           execute function
  47 ; -funcall function     same
  48 ; -l file               load file
  49 ; -load file            same
  50 ; -insert file          same
  51 ; file                  visit file
  52 ; -kill                 kill (exit) emacs
  53
  54 ;;; Code:
  55
  56 (setq top-level '(normal-top-level))
  57
  58 (defvar command-line-processed nil "t once command line has been processed")
  59
  60 (defconst inhibit-startup-message nil
  61   "*Non-nil inhibits the initial startup messages.
  62 This is for use in your personal init file, once you are familiar
  63 with the contents of the startup message.")
  64
  65 (defconst inhibit-default-init nil
  66   "*Non-nil inhibits loading the `default' library.")
  67
  68 (defconst command-switch-alist nil
  69   "Alist of command-line switches.
  70 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
  71 HANDLER-FUNCTION receives switch name as sole arg;
  72 remaining command-line args are in the variable `command-line-args-left'.")
  73
  74 (defvar command-line-functions nil    ;; lrs 7/31/89
  75   "List of functions to process unrecognized command-line arguments.
  76 Each function should access the dynamically bound variables
  77 argi (the current argument) and command-line-args-left (the remaining
  78 arguments).  The function should return non-nil only if it recognizes and
  79 processes argi.  If it does so, it may consume successive arguments by
  80 altering command-line-args-left to remove them.")
  81
  82 (defvar before-init-hook nil
  83   "Functions to call after handling urgent options but before loading init file.
  84 The frame system uses this to open frames to display messages while
  85 Emacs loads the user's initialization file.")
  86
  87 (defvar after-init-hook nil
  88   "Functions to call after loading the init file (`~/.emacs').
  89 The call is not protected by a condition-case, so you can set `debug-on-error'
  90 in `.emacs', and put all the actual code on `after-init-hook'.")
  91
  92 (defvar term-setup-hook nil
  93   "Functions to be called after loading terminal-specific lisp code.
  94 See `run-hooks'.  This variable exists for users to set,
  95 so as to override the definitions made by the terminal-specific file.
  96 Emacs never sets this variable itself.")
  97
  98 (defvar keyboard-type nil
  99   "The brand of keyboard you are using.  This variable is used to define
 100 the proper function and keypad keys for use under X.  It is used in a
 101 fashion analogous to the environment value TERM.")
 102
 103 (defvar window-setup-hook nil
 104   "Function called to initialize window system display.
 105 Emacs calls this after processing the command line arguments and loading
 106 the user's init file.
 107
 108 Users should not set this variable; use term-setup-hook instead.")
 109
 110 (defconst initial-major-mode 'lisp-interaction-mode
 111   "Major mode command symbol to use for the initial *scratch* buffer.")
 112
 113 (defvar init-file-user nil
 114   "Identity of user whose `.emacs' file is or was read.
 115 The value may be the null string or a string containing a user's name.
 116 If the value is a null string, it means that the init file was taken from
 117 the user that originally logged in.
 118
 119 In all cases, `(concat \"~\" init-file-user \"/\")' evaluates to the
 120 directory name of the directory where the `.emacs' file was looked for.")
 121
 122 (defvar init-file-debug nil)
 123
 124 (defun normal-top-level ()
 125   (if command-line-processed
 126       (message "Back to top level.")
 127     (setq command-line-processed t)
 128     (if (not (eq system-type 'vax-vms))
 129         (progn
 130           ;; If the PWD environment variable isn't accurate, delete it.
 131           (let ((pwd (getenv "PWD")))
 132             (and (stringp pwd)
 133                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 134                  ;; describes the directory linked to, not FOO itself.
 135                  (or (equal (file-attributes
 136                              (concat (file-name-as-directory pwd) "."))
 137                             (file-attributes
 138                              (concat (file-name-as-directory default-directory)
 139                                      ".")))
 140                      (setq process-environment
 141                            (delete (concat "PWD=" pwd)
 142                                    process-environment)))))))
 143     (setq default-directory (abbreviate-file-name default-directory))
 144     (unwind-protect
 145         (command-line)
 146       (run-hooks 'emacs-startup-hook)
 147       (and term-setup-hook
 148            (run-hooks 'term-setup-hook))
 149       (if (fboundp 'frame-notice-user-settings)
 150           (frame-notice-user-settings))
 151       (and window-setup-hook
 152            (run-hooks 'window-setup-hook)))))
 153
 154 (defun command-line ()
 155   ;; See if we should import version-control from the environment variable.
 156   (let ((vc (getenv "VERSION_CONTROL")))
 157     (cond ((eq vc nil))                 ;don't do anything if not set
 158           ((or (string= vc "t")
 159                (string= vc "numbered"))
 160            (setq version-control t))
 161           ((or (string= vc "nil")
 162                (string= vc "existing"))
 163            (setq version-control nil))
 164           ((or (string= vc "never")
 165                (string= vc "simple"))
 166            (setq version-control 'never))))
 167
 168   ;;! This has been commented out; I currently find the behavior when
 169   ;;! split-window-keep-point is nil disturbing, but if I can get used
 170   ;;! to it, then it would be better to eliminate the option.
 171   ;;! ;; Choose a good default value for split-window-keep-point.
 172   ;;! (setq split-window-keep-point (> baud-rate 2400))
 173
 174   ;; Read window system's init file if using a window system.
 175   (if (and window-system (not noninteractive))
 176       (load (concat term-file-prefix
 177                     (symbol-name window-system)
 178                     "-win")
 179             ;; Every window system should have a startup file;
 180             ;; barf if we can't find it.
 181             nil t))
 182
 183   (let ((done nil)
 184         (args (cdr command-line-args)))
 185
 186     ;; Figure out which user's init file to load,
 187     ;; either from the environment or from the options.
 188     (setq init-file-user (if noninteractive nil (user-login-name)))
 189     ;; If user has not done su, use current $HOME to find .emacs.
 190     (and init-file-user (string= init-file-user (user-real-login-name))
 191          (setq init-file-user ""))
 192
 193     ;; Process the command-line args, and delete the arguments
 194     ;; processed.  This is consistent with the way main in emacs.c
 195     ;; does things.
 196     (while (and (not done) args)
 197       (let ((argi (car args)))
 198         (cond
 199          ((or (string-equal argi "-q")
 200               (string-equal argi "-no-init-file"))
 201           (setq init-file-user nil
 202                 args (cdr args)))
 203          ((or (string-equal argi "-u")
 204               (string-equal argi "-user"))
 205           (setq args (cdr args)
 206                 init-file-user (car args)
 207                 args (cdr args)))
 208          ((string-equal argi "-debug-init")
 209           (setq init-file-debug t
 210                 args (cdr args)))
 211          (t (setq done t)))))
 212
 213     ;; Re-attach the program name to the front of the arg list.
 214     (setcdr command-line-args args))
 215
 216   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 217   (if (fboundp 'frame-initialize)
 218       (frame-initialize))
 219   (if (fboundp 'face-initialize)
 220       (face-initialize))
 221
 222   (run-hooks 'before-init-hook)
 223
 224   ;; Run the site-start library if it exists.  The point of this file is
 225   ;; that it is run before .emacs.  There is no point in doing this after
 226   ;; .emacs; that is useless.
 227   (load "site-start" t t)
 228
 229   ;; Load that user's init file, or the default one, or none.
 230   (let ((debug-on-error init-file-debug)
 231         ;; This function actually reads the init files.
 232         (inner
 233          (function
 234           (lambda ()
 235             (if init-file-user
 236                 (progn (load (if (eq system-type 'vax-vms)
 237                                  "sys$login:.emacs"
 238                                (concat "~" init-file-user "/.emacs"))
 239                              t t t)
 240                        (or inhibit-default-init
 241                            (let ((inhibit-startup-message nil))
 242                              ;; Users are supposed to be told their rights.
 243                              ;; (Plus how to get help and how to undo.)
 244                              ;; Don't you dare turn this off for anyone
 245                              ;; except yourself.
 246                              (load "default" t t)))))))))
 247     (if init-file-debug
 248         ;; Do this without a condition-case if the user wants to debug.
 249         (funcall inner)
 250       (condition-case error
 251           (funcall inner)
 252         (error (message "Error in init file: %s%s%s"
 253                         (get (car error) 'error-message)
 254                         (if (cdr error) ": ")
 255                         (mapconcat 'prin1-to-string (cdr error) ", "))))))
 256
 257   (run-hooks 'after-init-hook)
 258
 259   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 260   (if (get-buffer "*scratch*")
 261       (save-excursion
 262         (set-buffer "*scratch*")
 263         (if (eq major-mode 'fundamental-mode)
 264             (funcall initial-major-mode))))
 265   ;; Load library for our terminal type.
 266   ;; User init file can set term-file-prefix to nil to prevent this.
 267   (and term-file-prefix (not noninteractive) (not window-system)
 268        (let ((term (getenv "TERM"))
 269              hyphend)
 270          (while (and term
 271                      (not (load (concat term-file-prefix term) t t)))
 272            ;; Strip off last hyphen and what follows, then try again
 273            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 274                (setq term (substring term 0 hyphend))
 275              (setq term nil)))))
 276
 277   ;; Process the remaining args.
 278   (command-line-1 (cdr command-line-args))
 279
 280   ;; If -batch, terminate after processing the command options.
 281   (if noninteractive (kill-emacs t)))
 282
 283 (defun command-line-1 (command-line-args-left)
 284   (if (null command-line-args-left)
 285       (cond ((and (not inhibit-startup-message) (not noninteractive)
 286                   ;; Don't clobber a non-scratch buffer if init file
 287                   ;; has selected it.
 288                   (string= (buffer-name) "*scratch*")
 289                   (not (input-pending-p)))
 290              ;; If there are no switches to process, we might as well
 291              ;; run this hook now, and there may be some need to do it
 292              ;; before doing any output.
 293              (and term-setup-hook
 294                   (run-hooks 'term-setup-hook))
 295              ;; Don't let the hook be run twice.
 296              (setq term-setup-hook nil)
 297
 298              ;; It's important to notice the user settings before we
 299              ;; display the startup message; otherwise, the settings
 300              ;; won't take effect until the user gives the first
 301              ;; keystroke, and that's distracting.
 302              (if (fboundp 'frame-notice-user-settings)
 303                  (frame-notice-user-settings))
 304
 305              (and window-setup-hook
 306                   (run-hooks 'window-setup-hook))
 307              (setq window-setup-hook nil)
 308              (unwind-protect
 309                  (progn
 310                    (insert (emacs-version)
 311                            "
 312 Copyright (C) 1993 Free Software Foundation, Inc.\n\n")
 313                    ;; If keys have their default meanings,
 314                    ;; use precomputed string to save lots of time.
 315                    (if (and (eq (key-binding "\C-h") 'help-command)
 316                             (eq (key-binding "\C-xu") 'advertised-undo)
 317                             (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
 318                             (eq (key-binding "\C-h\C-c") 'describe-copying)
 319                             (eq (key-binding "\C-h\C-d") 'describe-distribution)
 320                             (eq (key-binding "\C-h\C-w") 'describe-no-warranty)
 321                             (eq (key-binding "\C-ht") 'help-with-tutorial))
 322                        (insert
 323        "Type C-h for help; C-x u to undo changes.  (`C-' means use CTRL key.)
 324 To kill the Emacs job, type C-x C-c.
 325 Type C-h t for a tutorial on using Emacs.
 326 Type C-h i to enter Info, which you can use to read GNU documentation.
 327
 328 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
 329 You may give out copies of Emacs; type C-h C-c to see the conditions.
 330 Type C-h C-d for information on getting the latest version.")
 331                      (insert (substitute-command-keys
 332        "Type \\[help-command] for help; \\[advertised-undo] to undo changes.  (`C-' means use CTRL key.)
 333 To kill the Emacs job, type \\[save-buffers-kill-emacs].
 334 Type \\[help-with-tutorial] for a tutorial on using Emacs.
 335 Type \\[info] to enter Info, which you can use to read GNU documentation.
 336
 337 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
 338 You may give out copies of Emacs; type \\[describe-copying] to see the conditions.
 339 Type \\[describe-distribution] for information on getting the latest version.")))
 340                    (set-buffer-modified-p nil)
 341                    (sit-for 120))
 342                (save-excursion
 343                  ;; In case the Emacs server has already selected
 344                  ;; another buffer, erase the one our message is in.
 345                  (set-buffer (get-buffer "*scratch*"))
 346                  (erase-buffer)
 347                  (set-buffer-modified-p nil)))))
 348     (let ((dir default-directory)
 349           (file-count 0)
 350           first-file-buffer
 351           (line 0))
 352       (while command-line-args-left
 353         (let ((argi (car command-line-args-left))
 354               tem)
 355           (setq command-line-args-left (cdr command-line-args-left))
 356           (cond ((setq tem (assoc argi command-switch-alist))
 357                  (funcall (cdr tem) argi))
 358                 ((or (string-equal argi "-f")  ;what the manual claims
 359                      (string-equal argi "-funcall")
 360                      (string-equal argi "-e")) ; what the source used to say
 361                  (setq tem (intern (car command-line-args-left)))
 362                  (setq command-line-args-left (cdr command-line-args-left))
 363                  (funcall tem))
 364                 ((or (string-equal argi "-l")
 365                      (string-equal argi "-load"))
 366                  (let ((file (car command-line-args-left)))
 367                    ;; Take file from default dir if it exists there;
 368                    ;; otherwise let `load' search for it.
 369                    (if (file-exists-p (expand-file-name file))
 370                        (setq file (expand-file-name file)))
 371                    (load file nil t))
 372                  (setq command-line-args-left (cdr command-line-args-left)))
 373                 ((string-equal argi "-insert")
 374                  (or (stringp (car command-line-args-left))
 375                      (error "filename omitted from `-insert' option"))
 376                  (insert-file-contents (car command-line-args-left))
 377                  (setq command-line-args-left (cdr command-line-args-left)))
 378                 ((string-equal argi "-kill")
 379                  (kill-emacs t))
 380                 ((string-match "^\\+[0-9]+\\'" argi)
 381                  (setq line (string-to-int argi)))
 382                 (t
 383                  ;; We have almost exhausted our options. See if the
 384                  ;; user has made any other command-line options available
 385                  (let ((hooks command-line-functions);; lrs 7/31/89
 386                        (did-hook nil))
 387                    (while (and hooks
 388                                (not (setq did-hook (funcall (car hooks)))))
 389                      (setq hooks (cdr hooks)))
 390                    (if (not did-hook)
 391                        ;; Ok, presume that the argument is a file name
 392                        (progn
 393                          (setq file-count (1+ file-count))
 394                          (cond ((= file-count 1)
 395                                 (setq first-file-buffer
 396                                       (find-file (expand-file-name argi dir))))
 397                                (t
 398                                 (find-file-other-window (expand-file-name argi dir))))
 399                          (or (zerop line)
 400                              (goto-line line))
 401                          (setq line 0))))))))
 402       ;; If 3 or more files visited, and not all visible,
 403       ;; show user what they all are.
 404       (if (> file-count 2)
 405           (or (get-buffer-window first-file-buffer)
 406               (progn (other-window 1)
 407                      (buffer-menu)))))))
 408
 409 ;;; startup.el ends here