code.delx.au - gnu-emacs/blob - lisp/gnus/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2
   3 ;; Copyright (C) 1995-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile (require 'cl))
  28
  29 (require 'gnus)
  30 (require 'gnus-start)
  31 (require 'gnus-spec)
  32 (require 'gnus-group)
  33 (require 'gnus-int)
  34 (require 'gnus-range)
  35
  36 (autoload 'gnus-group-make-nnir-group "nnir")
  37
  38 (defcustom gnus-server-mode-hook nil
  39   "Hook run in `gnus-server-mode' buffers."
  40   :group 'gnus-server
  41   :type 'hook)
  42
  43 (defcustom gnus-server-exit-hook nil
  44   "Hook run when exiting the server buffer."
  45   :group 'gnus-server
  46   :type 'hook)
  47
  48 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a%c\n"
  49   "Format of server lines.
  50 It works along the same lines as a normal formatting string,
  51 with some simple extensions.
  52
  53 The following specs are understood:
  54
  55 %h back end
  56 %n name
  57 %w address
  58 %s status
  59 %a agent covered
  60
  61 General format specifiers can also be used.
  62 See Info node `(gnus)Formatting Variables'."
  63   :link '(custom-manual "(gnus)Formatting Variables")
  64   :group 'gnus-server-visual
  65   :type 'string)
  66
  67 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  68   "The format specification for the server mode line."
  69   :group 'gnus-server-visual
  70   :type 'string)
  71
  72 (defcustom gnus-server-browse-in-group-buffer nil
  73   "Whether server browsing should take place in the group buffer.
  74 If nil, a faster, but more primitive, buffer is used instead."
  75   :version "22.1"
  76   :group 'gnus-server-visual
  77   :type 'boolean)
  78
  79 ;;; Internal variables.
  80
  81 (defvar gnus-tmp-how)
  82 (defvar gnus-tmp-name)
  83 (defvar gnus-tmp-where)
  84 (defvar gnus-tmp-status)
  85 (defvar gnus-tmp-agent)
  86 (defvar gnus-tmp-cloud)
  87 (defvar gnus-tmp-news-server)
  88 (defvar gnus-tmp-news-method)
  89 (defvar gnus-tmp-user-defined)
  90
  91 (defvar gnus-inserted-opened-servers nil)
  92
  93 (defvar gnus-server-line-format-alist
  94   `((?h gnus-tmp-how ?s)
  95     (?n gnus-tmp-name ?s)
  96     (?w gnus-tmp-where ?s)
  97     (?s gnus-tmp-status ?s)
  98     (?a gnus-tmp-agent ?s)
  99     (?c gnus-tmp-cloud ?s)))
 100
 101 (defvar gnus-server-mode-line-format-alist
 102   `((?S gnus-tmp-news-server ?s)
 103     (?M gnus-tmp-news-method ?s)
 104     (?u gnus-tmp-user-defined ?s)))
 105
 106 (defvar gnus-server-line-format-spec nil)
 107 (defvar gnus-server-mode-line-format-spec nil)
 108 (defvar gnus-server-killed-servers nil)
 109
 110 (defvar gnus-server-mode-map)
 111
 112 (defvar gnus-server-menu-hook nil
 113   "*Hook run after the creation of the server mode menu.")
 114
 115 (defun gnus-server-make-menu-bar ()
 116   (gnus-turn-off-edit-menu 'server)
 117   (unless (boundp 'gnus-server-server-menu)
 118     (easy-menu-define
 119      gnus-server-server-menu gnus-server-mode-map ""
 120      '("Server"
 121        ["Add..." gnus-server-add-server t]
 122        ["Browse" gnus-server-read-server t]
 123        ["Scan" gnus-server-scan-server t]
 124        ["List" gnus-server-list-servers t]
 125        ["Kill" gnus-server-kill-server t]
 126        ["Yank" gnus-server-yank-server t]
 127        ["Copy" gnus-server-copy-server t]
 128        ["Show" gnus-server-show-server t]
 129        ["Edit" gnus-server-edit-server t]
 130        ["Regenerate" gnus-server-regenerate-server t]
 131        ["Compact" gnus-server-compact-server t]
 132        ["Exit" gnus-server-exit t]))
 133
 134     (easy-menu-define
 135      gnus-server-connections-menu gnus-server-mode-map ""
 136      '("Connections"
 137        ["Open" gnus-server-open-server t]
 138        ["Close" gnus-server-close-server t]
 139        ["Offline" gnus-server-offline-server t]
 140        ["Deny" gnus-server-deny-server t]
 141        ["Toggle Cloud" gnus-server-toggle-cloud-server t]
 142        "---"
 143        ["Open All" gnus-server-open-all-servers t]
 144        ["Close All" gnus-server-close-all-servers t]
 145        ["Reset All" gnus-server-remove-denials t]))
 146
 147     (gnus-run-hooks 'gnus-server-menu-hook)))
 148
 149 (defvar gnus-server-mode-map nil)
 150 (put 'gnus-server-mode 'mode-class 'special)
 151
 152 (unless gnus-server-mode-map
 153   (setq gnus-server-mode-map (make-sparse-keymap))
 154   (suppress-keymap gnus-server-mode-map)
 155
 156   (gnus-define-keys gnus-server-mode-map
 157     " " gnus-server-read-server-in-server-buffer
 158     "\r" gnus-server-read-server
 159     [mouse-2] gnus-server-pick-server
 160     "q" gnus-server-exit
 161     "l" gnus-server-list-servers
 162     "k" gnus-server-kill-server
 163     "y" gnus-server-yank-server
 164     "c" gnus-server-copy-server
 165     "a" gnus-server-add-server
 166     "e" gnus-server-edit-server
 167     "S" gnus-server-show-server
 168     "s" gnus-server-scan-server
 169
 170     "O" gnus-server-open-server
 171     "\M-o" gnus-server-open-all-servers
 172     "C" gnus-server-close-server
 173     "\M-c" gnus-server-close-all-servers
 174     "D" gnus-server-deny-server
 175     "L" gnus-server-offline-server
 176     "R" gnus-server-remove-denials
 177
 178     "n" next-line
 179     "p" previous-line
 180
 181     "g" gnus-server-regenerate-server
 182
 183     "G" gnus-group-make-nnir-group
 184
 185     "z" gnus-server-compact-server
 186
 187     "i" gnus-server-toggle-cloud-server
 188
 189     "\C-c\C-i" gnus-info-find-node
 190     "\C-c\C-b" gnus-bug))
 191
 192 (defface gnus-server-agent
 193   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 194     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 195     (t (:bold t)))
 196   "Face used for displaying AGENTIZED servers"
 197   :group 'gnus-server-visual)
 198 ;; backward-compatibility alias
 199 (put 'gnus-server-agent-face 'face-alias 'gnus-server-agent)
 200 (put 'gnus-server-agent-face 'obsolete-face "22.1")
 201
 202 (defface gnus-server-cloud
 203   '((((class color) (background light)) (:foreground "ForestGreen" :bold t))
 204     (((class color) (background dark)) (:foreground "PaleGreen" :bold t))
 205     (t (:bold t)))
 206   "Face used for displaying AGENTIZED servers"
 207   :group 'gnus-server-visual)
 208
 209 (defface gnus-server-opened
 210   '((((class color) (background light)) (:foreground "Green3" :bold t))
 211     (((class color) (background dark)) (:foreground "Green1" :bold t))
 212     (t (:bold t)))
 213   "Face used for displaying OPENED servers"
 214   :group 'gnus-server-visual)
 215 ;; backward-compatibility alias
 216 (put 'gnus-server-opened-face 'face-alias 'gnus-server-opened)
 217 (put 'gnus-server-opened-face 'obsolete-face "22.1")
 218
 219 (defface gnus-server-closed
 220   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 221     (((class color) (background dark))
 222      (:foreground "LightBlue" :italic t))
 223     (t (:italic t)))
 224   "Face used for displaying CLOSED servers"
 225   :group 'gnus-server-visual)
 226 ;; backward-compatibility alias
 227 (put 'gnus-server-closed-face 'face-alias 'gnus-server-closed)
 228 (put 'gnus-server-closed-face 'obsolete-face "22.1")
 229
 230 (defface gnus-server-denied
 231   '((((class color) (background light)) (:foreground "Red" :bold t))
 232     (((class color) (background dark)) (:foreground "Pink" :bold t))
 233     (t (:inverse-video t :bold t)))
 234   "Face used for displaying DENIED servers"
 235   :group 'gnus-server-visual)
 236 ;; backward-compatibility alias
 237 (put 'gnus-server-denied-face 'face-alias 'gnus-server-denied)
 238 (put 'gnus-server-denied-face 'obsolete-face "22.1")
 239
 240 (defface gnus-server-offline
 241   '((((class color) (background light)) (:foreground "Orange" :bold t))
 242     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 243     (t (:inverse-video t :bold t)))
 244   "Face used for displaying OFFLINE servers"
 245   :group 'gnus-server-visual)
 246 ;; backward-compatibility alias
 247 (put 'gnus-server-offline-face 'face-alias 'gnus-server-offline)
 248 (put 'gnus-server-offline-face 'obsolete-face "22.1")
 249
 250 (defvar gnus-server-font-lock-keywords
 251   '(("(\\(agent\\))" 1 'gnus-server-agent)
 252     ("(\\(cloud\\))" 1 'gnus-server-cloud)
 253     ("(\\(opened\\))" 1 'gnus-server-opened)
 254     ("(\\(closed\\))" 1 'gnus-server-closed)
 255     ("(\\(offline\\))" 1 'gnus-server-offline)
 256     ("(\\(denied\\))" 1 'gnus-server-denied)))
 257
 258 (defun gnus-server-mode ()
 259   "Major mode for listing and editing servers.
 260
 261 All normal editing commands are switched off.
 262 \\<gnus-server-mode-map>
 263 For more in-depth information on this mode, read the manual
 264 \(`\\[gnus-info-find-node]').
 265
 266 The following commands are available:
 267
 268 \\{gnus-server-mode-map}"
 269   ;; FIXME: Use define-derived-mode.
 270   (interactive)
 271   (when (gnus-visual-p 'server-menu 'menu)
 272     (gnus-server-make-menu-bar))
 273   (kill-all-local-variables)
 274   (gnus-simplify-mode-line)
 275   (setq major-mode 'gnus-server-mode)
 276   (setq mode-name "Server")
 277   (gnus-set-default-directory)
 278   (setq mode-line-process nil)
 279   (use-local-map gnus-server-mode-map)
 280   (buffer-disable-undo)
 281   (setq truncate-lines t)
 282   (setq buffer-read-only t)
 283   (set (make-local-variable 'font-lock-defaults)
 284        '(gnus-server-font-lock-keywords t))
 285   (gnus-run-mode-hooks 'gnus-server-mode-hook))
 286
 287 (defun gnus-server-insert-server-line (name method)
 288   (let* ((gnus-tmp-name name)
 289          (gnus-tmp-how (car method))
 290          (gnus-tmp-where (nth 1 method))
 291          (elem (assoc method gnus-opened-servers))
 292          (gnus-tmp-status
 293           (cond
 294            ((eq (nth 1 elem) 'denied) "(denied)")
 295            ((eq (nth 1 elem) 'offline) "(offline)")
 296            (t
 297             (condition-case nil
 298                 (if (or (gnus-server-opened method)
 299                         (eq (nth 1 elem) 'ok))
 300                     "(opened)"
 301                   "(closed)")
 302               ((error) "(error)")))))
 303          (gnus-tmp-agent (if (and gnus-agent
 304                                   (gnus-agent-method-p method))
 305                              " (agent)"
 306                            ""))
 307          (gnus-tmp-cloud (if (gnus-cloud-server-p gnus-tmp-name)
 308                              " (cloud)"
 309                            "")))
 310     (beginning-of-line)
 311     (add-text-properties
 312      (point)
 313      (prog1 (1+ (point))
 314        ;; Insert the text.
 315        (eval gnus-server-line-format-spec))
 316      (list 'gnus-server (intern gnus-tmp-name)
 317            'gnus-named-server (intern (gnus-method-to-server method t))))))
 318
 319 (defun gnus-enter-server-buffer ()
 320   "Set up the server buffer."
 321   (gnus-server-setup-buffer)
 322   (gnus-configure-windows 'server)
 323   ;; Usually `gnus-configure-windows' will finish with the
 324   ;; `gnus-server-buffer' selected as the current buffer, but not always (I
 325   ;; bumped into it when starting from a dedicated *Group* frame, and
 326   ;; gnus-configure-windows opened *Server* into its own dedicated frame).
 327   (with-current-buffer (get-buffer gnus-server-buffer)
 328     (gnus-server-prepare)))
 329
 330 (defun gnus-server-setup-buffer ()
 331   "Initialize the server buffer."
 332   (unless (get-buffer gnus-server-buffer)
 333     (with-current-buffer (gnus-get-buffer-create gnus-server-buffer)
 334       (gnus-server-mode))))
 335
 336 (defun gnus-server-prepare ()
 337   (gnus-set-format 'server-mode)
 338   (gnus-set-format 'server t)
 339   (let ((alist gnus-server-alist)
 340         (buffer-read-only nil)
 341         done server op-ser)
 342     (erase-buffer)
 343     (setq gnus-inserted-opened-servers nil)
 344     ;; First we do the real list of servers.
 345     (while alist
 346       (unless (member (cdar alist) done)
 347         (push (cdar alist) done)
 348         (setq server (pop alist))
 349         (when (and server (car server) (cdr server))
 350           (gnus-server-insert-server-line (car server) (cdr server))))
 351       (when (member (cdar alist) done)
 352         (pop alist)))
 353     ;; Then we insert the list of servers that have been opened in
 354     ;; this session.
 355     (dolist (open gnus-opened-servers)
 356       (when (and (not (member (car open) done))
 357                  ;; Just ignore ephemeral servers.
 358                  (not (gnus-method-ephemeral-p (car open))))
 359         (push (car open) done)
 360         (gnus-server-insert-server-line
 361          (setq op-ser (format "%s:%s" (caar open) (nth 1 (car open))))
 362          (car open))
 363         (push (list op-ser (car open)) gnus-inserted-opened-servers))))
 364   (goto-char (point-min))
 365   (gnus-server-position-point))
 366
 367 (defun gnus-server-server-name ()
 368   (let ((server (get-text-property (point-at-bol) 'gnus-server)))
 369     (and server (symbol-name server))))
 370
 371 (defun gnus-server-named-server ()
 372   "Return a server name that matches one of the names returned by
 373 `gnus-method-to-server'."
 374   (let ((server (get-text-property (point-at-bol) 'gnus-named-server)))
 375     (and server (symbol-name server))))
 376
 377 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 378
 379 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 380
 381 (defun gnus-server-update-server (server)
 382   (with-current-buffer gnus-server-buffer
 383     (let* ((buffer-read-only nil)
 384            (entry (assoc server gnus-server-alist))
 385            (oentry (assoc (gnus-server-to-method server)
 386                           gnus-opened-servers)))
 387       (when entry
 388         (gnus-dribble-enter
 389          (concat "(gnus-server-set-info \"" server "\" '"
 390                  (gnus-prin1-to-string (cdr entry)) ")\n")
 391          (concat "^(gnus-server-set-info \"" (regexp-quote server) "\"")))
 392       (when (or entry oentry)
 393         ;; Buffer may be narrowed.
 394         (save-restriction
 395           (widen)
 396           (when (gnus-server-goto-server server)
 397             (gnus-delete-line))
 398           (if entry
 399               (gnus-server-insert-server-line (car entry) (cdr entry))
 400             (gnus-server-insert-server-line
 401              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 402              (car oentry)))
 403           (gnus-server-position-point))))))
 404
 405 (defun gnus-server-set-info (server info)
 406   ;; Enter a select method into the virtual server alist.
 407   (when (and server info)
 408     (gnus-dribble-enter
 409      (concat "(gnus-server-set-info \"" server "\" '"
 410              (gnus-prin1-to-string info) ")")
 411      (concat "^(gnus-server-set-info \"" (regexp-quote server) "\""))
 412     (let* ((server (nth 1 info))
 413            (entry (assoc server gnus-server-alist))
 414            (cached (assoc server gnus-server-method-cache)))
 415       (if cached
 416           (setq gnus-server-method-cache
 417                 (delq cached gnus-server-method-cache)))
 418       (if entry
 419           (progn
 420             ;; Remove the server from `gnus-opened-servers' since
 421             ;; it has never been opened with the new `info' yet.
 422             (gnus-opened-servers-remove (cdr entry))
 423             ;; Don't make a new Lisp object.
 424             (setcar (cdr entry) (car info))
 425             (setcdr (cdr entry) (cdr info)))
 426         (setq gnus-server-alist
 427               (nconc gnus-server-alist (list (cons server info))))))))
 428
 429 ;;; Interactive server functions.
 430
 431 (defun gnus-server-kill-server (server)
 432   "Kill the server on the current line."
 433   (interactive (list (gnus-server-server-name)))
 434   (unless (gnus-server-goto-server server)
 435     (if server (error "No such server: %s" server)
 436       (error "No server on the current line")))
 437   (unless (assoc server gnus-server-alist)
 438     (error "Read-only server %s" server))
 439   (gnus-dribble-touch)
 440   (let ((buffer-read-only nil))
 441     (gnus-delete-line))
 442   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 443   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 444                                 gnus-server-alist))
 445   (let ((groups (gnus-groups-from-server server)))
 446     (when (and groups
 447                (gnus-yes-or-no-p
 448                 (format "Kill all %s groups from this server? "
 449                         (length groups))))
 450       (dolist (group groups)
 451         (setq gnus-newsrc-alist
 452               (delq (assoc group gnus-newsrc-alist)
 453                     gnus-newsrc-alist))
 454         (when gnus-group-change-level-function
 455           (funcall gnus-group-change-level-function
 456                    group gnus-level-killed 3)))))
 457   (gnus-server-position-point))
 458
 459 (defun gnus-server-yank-server ()
 460   "Yank the previously killed server."
 461   (interactive)
 462   (unless gnus-server-killed-servers
 463     (error "No killed servers to be yanked"))
 464   (let ((alist gnus-server-alist)
 465         (server (gnus-server-server-name))
 466         (killed (car gnus-server-killed-servers)))
 467     (if (not server)
 468         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 469       (if (string= server (caar gnus-server-alist))
 470           (push killed gnus-server-alist)
 471         (while (and (cdr alist)
 472                     (not (string= server (caadr alist))))
 473           (setq alist (cdr alist)))
 474         (if alist
 475             (setcdr alist (cons killed (cdr alist)))
 476           (setq gnus-server-alist (list killed)))))
 477     (gnus-server-update-server (car killed))
 478     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 479     (gnus-server-position-point)))
 480
 481 (defun gnus-server-exit ()
 482   "Return to the group buffer."
 483   (interactive)
 484   (gnus-run-hooks 'gnus-server-exit-hook)
 485   (gnus-kill-buffer (current-buffer))
 486   (gnus-configure-windows 'group t))
 487
 488 (defun gnus-server-list-servers ()
 489   "List all available servers."
 490   (interactive)
 491   (let ((cur (gnus-server-server-name)))
 492     (gnus-server-prepare)
 493     (if cur (gnus-server-goto-server cur)
 494       (goto-char (point-max))
 495       (forward-line -1))
 496     (gnus-server-position-point)))
 497
 498 (defun gnus-server-set-status (method status)
 499   "Make METHOD have STATUS."
 500   (let ((entry (assoc method gnus-opened-servers)))
 501     (if entry
 502         (setcar (cdr entry) status)
 503       (push (list method status) gnus-opened-servers))))
 504
 505 (defun gnus-opened-servers-remove (method)
 506   "Remove METHOD from the list of opened servers."
 507   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 508                                   gnus-opened-servers)))
 509
 510 (defun gnus-server-open-server (server)
 511   "Force an open of SERVER."
 512   (interactive (list (gnus-server-server-name)))
 513   (let ((method (gnus-server-to-method server)))
 514     (unless method
 515       (error "No such server: %s" server))
 516     (gnus-server-set-status method 'ok)
 517     (prog1
 518         (gnus-open-server method)
 519       (gnus-server-update-server server)
 520       (gnus-server-position-point))))
 521
 522 (defun gnus-server-open-all-servers ()
 523   "Open all servers."
 524   (interactive)
 525   (dolist (server gnus-inserted-opened-servers)
 526     (gnus-server-open-server (car server))))
 527
 528 (defun gnus-server-close-server (server)
 529   "Close SERVER."
 530   (interactive (list (gnus-server-server-name)))
 531   (let ((method (gnus-server-to-method server)))
 532     (unless method
 533       (error "No such server: %s" server))
 534     (gnus-server-set-status method 'closed)
 535     (prog1
 536         (gnus-close-server method)
 537       (gnus-server-update-server server)
 538       (gnus-server-position-point))))
 539
 540 (defun gnus-server-offline-server (server)
 541   "Set SERVER to offline."
 542   (interactive (list (gnus-server-server-name)))
 543   (let ((method (gnus-server-to-method server)))
 544     (unless method
 545       (error "No such server: %s" server))
 546     (prog1
 547         (gnus-close-server method)
 548       (gnus-server-set-status method 'offline)
 549       (gnus-server-update-server server)
 550       (gnus-server-position-point))))
 551
 552 (defun gnus-server-close-all-servers ()
 553   "Close all servers."
 554   (interactive)
 555   (dolist (server gnus-inserted-opened-servers)
 556     (gnus-server-close-server (car server)))
 557   (dolist (server gnus-server-alist)
 558     (gnus-server-close-server (car server))))
 559
 560 (defun gnus-server-deny-server (server)
 561   "Make sure SERVER will never be attempted opened."
 562   (interactive (list (gnus-server-server-name)))
 563   (let ((method (gnus-server-to-method server)))
 564     (unless method
 565       (error "No such server: %s" server))
 566     (gnus-server-set-status method 'denied))
 567   (gnus-server-update-server server)
 568   (gnus-server-position-point)
 569   t)
 570
 571 (defun gnus-server-remove-denials ()
 572   "Make all denied servers into closed servers."
 573   (interactive)
 574   (dolist (server gnus-opened-servers)
 575     (when (eq (nth 1 server) 'denied)
 576       (setcar (nthcdr 1 server) 'closed)))
 577   (gnus-server-list-servers))
 578
 579 (defun gnus-server-copy-server (from to)
 580   "Copy a server definition to a new name."
 581   (interactive
 582    (list
 583     (or (gnus-server-server-name)
 584         (error "No server on the current line"))
 585     (read-string "Copy to: ")))
 586   (unless from
 587     (error "No server on current line"))
 588   (unless (and to (not (string= to "")))
 589     (error "No name to copy to"))
 590   (when (assoc to gnus-server-alist)
 591     (error "%s already exists" to))
 592   (unless (gnus-server-to-method from)
 593     (error "%s: no such server" from))
 594   (let ((to-entry (cons from (gnus-copy-sequence
 595                               (gnus-server-to-method from)))))
 596     (setcar to-entry to)
 597     (setcar (nthcdr 2 to-entry) to)
 598     (push to-entry gnus-server-killed-servers)
 599     (gnus-server-yank-server)))
 600
 601 (defun gnus-server-add-server (how where)
 602   (interactive
 603    (list (intern (gnus-completing-read "Server method"
 604                                        (mapcar 'car gnus-valid-select-methods)
 605                                        t))
 606          (read-string "Server name: ")))
 607   (when (assq where gnus-server-alist)
 608     (error "Server with that name already defined"))
 609   (push (list where how where) gnus-server-killed-servers)
 610   (gnus-server-yank-server))
 611
 612 (defun gnus-server-goto-server (server)
 613   "Jump to a server line."
 614   (interactive
 615    (list (gnus-completing-read "Goto server" (mapcar 'car gnus-server-alist) t)))
 616   (let ((to (text-property-any (point-min) (point-max)
 617                                'gnus-server (intern server))))
 618     (when to
 619       (goto-char to)
 620       (gnus-server-position-point))))
 621
 622 (defun gnus-server-edit-server (server)
 623   "Edit the server on the current line."
 624   (interactive (list (gnus-server-server-name)))
 625   (unless server
 626     (error "No server on current line"))
 627   (unless (assoc server gnus-server-alist)
 628     (error "This server can't be edited"))
 629   (let ((info (cdr (assoc server gnus-server-alist))))
 630     (gnus-close-server info)
 631     (gnus-edit-form
 632      info "Editing the server."
 633      `(lambda (form)
 634         (gnus-server-set-info ,server form)
 635         (gnus-server-list-servers)
 636         (gnus-server-position-point))
 637      'edit-server)))
 638
 639 (defun gnus-server-show-server (server)
 640   "Show the definition of the server on the current line."
 641   (interactive (list (gnus-server-server-name)))
 642   (unless server
 643     (error "No server on current line"))
 644   (let ((info (gnus-server-to-method server)))
 645     (gnus-edit-form
 646      info "Showing the server."
 647      `(lambda (form)
 648         (gnus-server-position-point))
 649      'edit-server)))
 650
 651 (defun gnus-server-scan-server (server)
 652   "Request a scan from the current server."
 653   (interactive (list (gnus-server-server-name)))
 654   (let ((method (gnus-server-to-method server)))
 655     (if (not (gnus-get-function method 'request-scan))
 656         (error "Server %s can't scan" (car method))
 657       (gnus-message 3 "Scanning %s..." server)
 658       (gnus-request-scan nil method)
 659       (gnus-message 3 "Scanning %s...done" server))))
 660
 661 (defun gnus-server-read-server-in-server-buffer (server)
 662   "Browse a server in server buffer."
 663   (interactive (list (gnus-server-server-name)))
 664   (let (gnus-server-browse-in-group-buffer)
 665     (gnus-server-read-server server)))
 666
 667 (defun gnus-server-read-server (server)
 668   "Browse a server."
 669   (interactive (list (gnus-server-server-name)))
 670   (let ((buf (current-buffer)))
 671     (prog1
 672         (gnus-browse-foreign-server server buf)
 673       (with-current-buffer buf
 674         (gnus-server-update-server (gnus-server-server-name))
 675         (gnus-server-position-point)))))
 676
 677 (defun gnus-server-pick-server (e)
 678   (interactive "e")
 679   (mouse-set-point e)
 680   (gnus-server-read-server (gnus-server-server-name)))
 681
 682 \f
 683 ;;;
 684 ;;; Browse Server Mode
 685 ;;;
 686
 687 (defvar gnus-browse-menu-hook nil
 688   "*Hook run after the creation of the browse mode menu.")
 689
 690 (defcustom gnus-browse-subscribe-newsgroup-method
 691   'gnus-subscribe-alphabetically
 692   "Function(s) called when subscribing groups in the Browse Server Buffer
 693 A few pre-made functions are supplied: `gnus-subscribe-randomly'
 694 inserts new groups at the beginning of the list of groups;
 695 `gnus-subscribe-alphabetically' inserts new groups in strict
 696 alphabetic order; `gnus-subscribe-hierarchically' inserts new groups
 697 in hierarchical newsgroup order; `gnus-subscribe-interactively' asks
 698 for your decision; `gnus-subscribe-killed' kills all new groups;
 699 `gnus-subscribe-zombies' will make all new groups into zombies;
 700 `gnus-subscribe-topics' will enter groups into the topics that
 701 claim them."
 702   :version "24.1"
 703   :group 'gnus-server
 704   :type '(radio (function-item gnus-subscribe-randomly)
 705                 (function-item gnus-subscribe-alphabetically)
 706                 (function-item gnus-subscribe-hierarchically)
 707                 (function-item gnus-subscribe-interactively)
 708                 (function-item gnus-subscribe-killed)
 709                 (function-item gnus-subscribe-zombies)
 710                 (function-item gnus-subscribe-topics)
 711                 function
 712                 (repeat function)))
 713
 714 (defvar gnus-browse-mode-hook nil)
 715 (defvar gnus-browse-mode-map nil)
 716 (put 'gnus-browse-mode 'mode-class 'special)
 717
 718 (unless gnus-browse-mode-map
 719   (setq gnus-browse-mode-map (make-keymap))
 720   (suppress-keymap gnus-browse-mode-map)
 721
 722   (gnus-define-keys
 723       gnus-browse-mode-map
 724     " " gnus-browse-read-group
 725     "=" gnus-browse-select-group
 726     "n" gnus-browse-next-group
 727     "p" gnus-browse-prev-group
 728     "\177" gnus-browse-prev-group
 729     [delete] gnus-browse-prev-group
 730     "N" gnus-browse-next-group
 731     "P" gnus-browse-prev-group
 732     "\M-n" gnus-browse-next-group
 733     "\M-p" gnus-browse-prev-group
 734     "\r" gnus-browse-select-group
 735     "u" gnus-browse-unsubscribe-current-group
 736     "l" gnus-browse-exit
 737     "L" gnus-browse-exit
 738     "q" gnus-browse-exit
 739     "Q" gnus-browse-exit
 740     "d" gnus-browse-describe-group
 741     [delete] gnus-browse-delete-group
 742     "\C-c\C-c" gnus-browse-exit
 743     "?" gnus-browse-describe-briefly
 744
 745     "\C-c\C-i" gnus-info-find-node
 746     "\C-c\C-b" gnus-bug))
 747
 748 (defun gnus-browse-make-menu-bar ()
 749   (gnus-turn-off-edit-menu 'browse)
 750   (unless (boundp 'gnus-browse-menu)
 751     (easy-menu-define
 752      gnus-browse-menu gnus-browse-mode-map ""
 753      '("Browse"
 754        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 755        ["Read" gnus-browse-read-group t]
 756        ["Select" gnus-browse-select-group t]
 757        ["Describe" gnus-browse-describe-group t]
 758        ["Next" gnus-browse-next-group t]
 759        ["Prev" gnus-browse-prev-group t]
 760        ["Exit" gnus-browse-exit t]))
 761     (gnus-run-hooks 'gnus-browse-menu-hook)))
 762
 763 (defvar gnus-browse-current-method nil)
 764 (defvar gnus-browse-return-buffer nil)
 765
 766 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 767
 768 (defun gnus-browse-foreign-server (server &optional return-buffer)
 769   "Browse the server SERVER."
 770   (setq gnus-browse-current-method (gnus-server-to-method server))
 771   (setq gnus-browse-return-buffer return-buffer)
 772   (let* ((method gnus-browse-current-method)
 773          (orig-select-method gnus-select-method)
 774          (gnus-select-method method)
 775          groups group)
 776     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 777     (cond
 778      ((not (gnus-check-server method))
 779       (gnus-message
 780        1 "Unable to contact server %s: %s" (nth 1 method)
 781        (gnus-status-message method))
 782       nil)
 783      ((not
 784        (prog2
 785            (gnus-message 6 "Reading active file...")
 786            (gnus-request-list method)
 787          (gnus-message 6 "Reading active file...done")))
 788       (gnus-message
 789        1 "Couldn't request list: %s" (gnus-status-message method))
 790       nil)
 791      (t
 792       (with-current-buffer nntp-server-buffer
 793         (let ((cur (current-buffer)))
 794           (goto-char (point-min))
 795          (unless (or (null gnus-ignored-newsgroups)
 796                      (string= gnus-ignored-newsgroups ""))
 797             (delete-matching-lines gnus-ignored-newsgroups))
 798           ;; We treat NNTP as a special case to avoid problems with
 799           ;; garbage group names like `"foo' that appear in some badly
 800           ;; managed active files. -jh.
 801           (if (eq (car method) 'nntp)
 802               (while (not (eobp))
 803                 (ignore-errors
 804                   (push (cons
 805                          (string-as-unibyte
 806                           (buffer-substring
 807                            (point)
 808                            (progn
 809                              (skip-chars-forward "^ \t")
 810                              (point))))
 811                          (let ((last (read cur)))
 812                            (cons (read cur) last)))
 813                         groups))
 814                 (forward-line))
 815             (while (not (eobp))
 816               (ignore-errors
 817                 (push (cons
 818                        (string-as-unibyte
 819                         (if (eq (char-after) ?\")
 820                             (read cur)
 821                           (let ((p (point)) (name ""))
 822                             (skip-chars-forward "^ \t\\\\")
 823                             (setq name (buffer-substring p (point)))
 824                             (while (eq (char-after) ?\\)
 825                               (setq p (1+ (point)))
 826                               (forward-char 2)
 827                               (skip-chars-forward "^ \t\\\\")
 828                               (setq name (concat name (buffer-substring
 829                                                        p (point)))))
 830                             name)))
 831                        (let ((last (read cur)))
 832                          (cons (read cur) last)))
 833                       groups))
 834               (forward-line)))))
 835       (setq groups (sort groups
 836                          (lambda (l1 l2)
 837                            (string< (car l1) (car l2)))))
 838       (if gnus-server-browse-in-group-buffer
 839           (let* ((gnus-select-method orig-select-method)
 840                  (gnus-group-listed-groups
 841                   (mapcar (lambda (group)
 842                             (let ((name
 843                                    (gnus-group-prefixed-name
 844                                     (car group) method)))
 845                               (gnus-set-active name (cdr group))
 846                               name))
 847                           groups)))
 848             (gnus-configure-windows 'group)
 849             (funcall gnus-group-prepare-function
 850                      gnus-level-killed 'ignore 1 'ignore))
 851         (gnus-get-buffer-create gnus-browse-buffer)
 852         (gnus-configure-windows 'browse)
 853         (buffer-disable-undo)
 854         (let ((buffer-read-only nil))
 855           (erase-buffer))
 856         (gnus-browse-mode)
 857         (setq mode-line-buffer-identification
 858               (list
 859                (format
 860                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 861         (let ((buffer-read-only nil)
 862               name
 863               (prefix (let ((gnus-select-method orig-select-method))
 864                         (gnus-group-prefixed-name "" method))))
 865           (while (setq group (pop groups))
 866             (add-text-properties
 867              (point)
 868              (prog1 (1+ (point))
 869                (insert
 870                 (format "%c%7d: %s\n"
 871                         (let ((level
 872                                (if (string= prefix "")
 873                                    (gnus-group-level (setq name (car group)))
 874                                  (gnus-group-level
 875                                   (concat prefix (setq name (car group)))))))
 876                           (cond
 877                            ((<= level gnus-level-subscribed) ? )
 878                            ((<= level gnus-level-unsubscribed) ?U)
 879                            ((= level gnus-level-zombie) ?Z)
 880                            (t ?K)))
 881                         (max 0 (- (1+ (cddr group)) (cadr group)))
 882                         ;; Don't decode if name is ASCII
 883                         (if (eq (detect-coding-string name t) 'undecided)
 884                             name
 885                           (decode-coding-string
 886                            name
 887                            (inline (gnus-group-name-charset method name)))))))
 888              (list 'gnus-group name)
 889              )))
 890         (switch-to-buffer (current-buffer)))
 891       (goto-char (point-min))
 892       (gnus-group-position-point)
 893       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 894       t))))
 895
 896 (define-derived-mode gnus-browse-mode fundamental-mode "Browse Server"
 897   "Major mode for browsing a foreign server.
 898
 899 All normal editing commands are switched off.
 900
 901 \\<gnus-browse-mode-map>
 902 The only things you can do in this buffer is
 903
 904 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 905 The group will be inserted into the group buffer upon exit from this
 906 buffer.
 907
 908 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 909
 910 3) `\\[gnus-browse-exit]' to return to the group buffer."
 911   (when (gnus-visual-p 'browse-menu 'menu)
 912     (gnus-browse-make-menu-bar))
 913   (gnus-simplify-mode-line)
 914   (setq mode-line-process nil)
 915   (buffer-disable-undo)
 916   (setq truncate-lines t)
 917   (gnus-set-default-directory)
 918   (setq buffer-read-only t))
 919
 920 (defun gnus-browse-read-group (&optional no-article number)
 921   "Enter the group at the current line.
 922 If NUMBER, fetch this number of articles."
 923   (interactive "P")
 924   (let ((group (gnus-browse-group-name)))
 925     (if (or (not (gnus-get-info group))
 926             (gnus-ephemeral-group-p group))
 927         (unless (gnus-group-read-ephemeral-group
 928                  group gnus-browse-current-method nil
 929                  (cons (current-buffer) 'browse)
 930                  nil nil nil number)
 931           (error "Couldn't enter %s" group))
 932       (unless (gnus-group-read-group nil no-article group)
 933         (error "Couldn't enter %s" group)))))
 934
 935 (defun gnus-browse-select-group (&optional number)
 936   "Select the current group.
 937 If NUMBER, fetch this number of articles."
 938   (interactive "P")
 939   (gnus-browse-read-group 'no number))
 940
 941 (defun gnus-browse-next-group (n)
 942   "Go to the next group."
 943   (interactive "p")
 944   (prog1
 945       (forward-line n)
 946     (gnus-group-position-point)))
 947
 948 (defun gnus-browse-prev-group (n)
 949   "Go to the next group."
 950   (interactive "p")
 951   (gnus-browse-next-group (- n)))
 952
 953 (defun gnus-browse-unsubscribe-current-group (arg)
 954   "(Un)subscribe to the next ARG groups.
 955 The variable `gnus-browse-subscribe-newsgroup-method' determines
 956 how new groups will be entered into the group buffer."
 957   (interactive "p")
 958   (when (eobp)
 959     (error "No group at current line"))
 960   (let ((ward (if (< arg 0) -1 1))
 961         (arg (abs arg)))
 962     (while (and (> arg 0)
 963                 (not (eobp))
 964                 (gnus-browse-unsubscribe-group)
 965                 (zerop (gnus-browse-next-group ward)))
 966       (decf arg))
 967     (gnus-group-position-point)
 968     (when (/= 0 arg)
 969       (gnus-message 7 "No more newsgroups"))
 970     arg))
 971
 972 (defun gnus-browse-group-name ()
 973   (save-excursion
 974     (beginning-of-line)
 975     (let ((name (get-text-property (point) 'gnus-group)))
 976       (when (re-search-forward ": \\(.*\\)$" (point-at-eol) t)
 977         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 978                 (or name
 979                     (match-string-no-properties 1)))))))
 980
 981 (defun gnus-browse-describe-group (group)
 982   "Describe the current group."
 983   (interactive (list (gnus-browse-group-name)))
 984   (gnus-group-describe-group nil group))
 985
 986 (defun gnus-browse-delete-group (group force)
 987   "Delete the current group.  Only meaningful with editable groups.
 988 If FORCE (the prefix) is non-nil, all the articles in the group will
 989 be deleted.  This is \"deleted\" as in \"removed forever from the face
 990 of the Earth\".  There is no undo.  The user will be prompted before
 991 doing the deletion."
 992   (interactive (list (gnus-browse-group-name)
 993                      current-prefix-arg))
 994   (gnus-group-delete-group group force))
 995
 996 (defun gnus-browse-unsubscribe-group ()
 997   "Toggle subscription of the current group in the browse buffer."
 998   (let ((sub nil)
 999         (buffer-read-only nil)
1000         group)
1001     (save-excursion
1002       (beginning-of-line)
1003       ;; If this group it killed, then we want to subscribe it.
1004       (unless (eq (char-after) ? )
1005         (setq sub t))
1006       (setq group (gnus-browse-group-name))
1007       (when (gnus-server-equal gnus-browse-current-method "native")
1008         (setq group (gnus-group-real-name group)))
1009       (if sub
1010           (progn
1011             ;; Make sure the group has been properly removed before we
1012             ;; subscribe to it.
1013             (if (gnus-ephemeral-group-p group)
1014                 (gnus-kill-ephemeral-group group))
1015             (let ((entry (gnus-group-entry group)))
1016               (if entry
1017                   ;; Just change the subscription level if it is an
1018                   ;; unsubscribed group.
1019                   (gnus-group-change-level entry
1020                                            gnus-level-default-subscribed)
1021                 ;; If it is a killed group or a zombie, feed it to the
1022                 ;; mechanism for new group subscription.
1023                 (gnus-call-subscribe-functions
1024                  gnus-browse-subscribe-newsgroup-method
1025                  group)
1026                 (gnus-request-update-group-status group 'subscribe)))
1027             (delete-char 1)
1028             (insert (let ((lvl (gnus-group-level group)))
1029                       (cond
1030                        ((< lvl gnus-level-unsubscribed) ? )
1031                        ((< lvl gnus-level-zombie) ?U)
1032                        ((< lvl gnus-level-killed) ?Z)
1033                        (t ?K)))))
1034         (gnus-group-change-level
1035          group gnus-level-unsubscribed gnus-level-default-subscribed)
1036         (delete-char 1)
1037         (insert ?U)))
1038     t))
1039
1040 (defun gnus-browse-exit ()
1041   "Quit browsing and return to the group buffer."
1042   (interactive)
1043   (when (derived-mode-p 'gnus-browse-mode)
1044     (gnus-kill-buffer (current-buffer)))
1045   ;; Insert the newly subscribed groups in the group buffer.
1046   (with-current-buffer gnus-group-buffer
1047     (gnus-group-list-groups nil))
1048   (if gnus-browse-return-buffer
1049       (gnus-configure-windows 'server 'force)
1050     (gnus-configure-windows 'group 'force)))
1051
1052 (defun gnus-browse-describe-briefly ()
1053   "Give a one line description of the group mode commands."
1054   (interactive)
1055   (gnus-message 6 "%s"
1056                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
1057
1058 (defun gnus-server-regenerate-server ()
1059   "Issue a command to the server to regenerate all its data structures."
1060   (interactive)
1061   (let ((server (gnus-server-server-name)))
1062     (unless server
1063       (error "No server on the current line"))
1064     (condition-case ()
1065         (gnus-get-function (gnus-server-to-method server)
1066                            'request-regenerate)
1067       (error
1068         (error "This back end doesn't support regeneration")))
1069     (gnus-message 5 "Requesting regeneration of %s..." server)
1070     (unless (gnus-open-server server)
1071       (error "Couldn't open server"))
1072     (if (gnus-request-regenerate server)
1073         (gnus-message 5 "Requesting regeneration of %s...done" server)
1074       (gnus-message 5 "Couldn't regenerate %s" server))))
1075
1076
1077 ;;;
1078 ;;; Server compaction. -- dvl
1079 ;;;
1080
1081 ;; #### FIXME: this function currently fails to update the Group buffer's
1082 ;; #### appearance.
1083 (defun gnus-server-compact-server ()
1084   "Issue a command to the server to compact all its groups.
1085
1086 Note: currently only implemented in nnml."
1087   (interactive)
1088   (let ((server (gnus-server-server-name)))
1089     (unless server
1090       (error "No server on the current line"))
1091     (condition-case ()
1092         (gnus-get-function (gnus-server-to-method server)
1093                            'request-compact)
1094       (error
1095        (error "This back end doesn't support compaction")))
1096     (gnus-message 5 "\
1097 Requesting compaction of %s... (this may take a long time)"
1098                   server)
1099     (unless (gnus-open-server server)
1100       (error "Couldn't open server"))
1101     (if (not (gnus-request-compact server))
1102         (gnus-message 5 "Couldn't compact %s" server)
1103       (gnus-message 5 "Requesting compaction of %s...done" server)
1104       ;; Invalidate the original article buffer which might be out of date.
1105       ;; #### NOTE: Yes, this might be a bit rude, but since compaction
1106       ;; #### will not happen very often, I think this is acceptable.
1107       (let ((original (get-buffer gnus-original-article-buffer)))
1108         (and original (gnus-kill-buffer original))))))
1109
1110 (defun gnus-server-toggle-cloud-server ()
1111   "Make the server under point be replicated in the Emacs Cloud."
1112   (interactive)
1113   (let ((server (gnus-server-server-name)))
1114     (unless server
1115       (error "No server on the current line"))
1116
1117     (unless (gnus-method-option-p server 'cloud)
1118       (error "The server under point doesn't support cloudiness"))
1119
1120     (if (gnus-cloud-server-p server)
1121         (setq gnus-cloud-covered-servers
1122               (delete server gnus-cloud-covered-servers))
1123       (push server gnus-cloud-covered-servers))
1124
1125     (gnus-server-update-server server)
1126     (gnus-message 1 (if (gnus-cloud-server-p server)
1127                         "Replication of %s in the cloud will start"
1128                       "Replication of %s in the cloud will stop")
1129                   server)))
1130
1131 (provide 'gnus-srvr)
1132
1133 ;;; gnus-srvr.el ends here