]> code.delx.au - gnu-emacs/blob - configure.in
delx.au / code / gnu-emacs / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
Initial revision
[gnu-emacs] / configure.in
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996 Free Software Foundation, Inc.
7 dnl
8 dnl This file is part of GNU Emacs.
9 dnl
10 dnl GNU Emacs is free software; you can redistribute it and/or modify
11 dnl it under the terms of the GNU General Public License as published by
12 dnl the Free Software Foundation; either version 2, or (at your option)
13 dnl any later version.
14 dnl
15 dnl GNU Emacs is distributed in the hope that it will be useful,
16 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 dnl GNU General Public License for more details.
19 dnl
20 dnl You should have received a copy of the GNU General Public License
21 dnl along with GNU Emacs; see the file COPYING. If not, write to the
22 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
23 dnl Boston, MA 02111-1307, USA.
24
25 AC_PREREQ(2.8)dnl
26 AC_INIT(src/lisp.h)
27 AC_CONFIG_HEADER(src/config.h:src/config.in)
28
29 lispdir='${datadir}/emacs/${version}/lisp'
30 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
31 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
32 lisppath='${locallisppath}:${lispdir}'
33 etcdir='${datadir}/emacs/${version}/etc'
34 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
35 docdir='${datadir}/emacs/${version}/etc'
36
37 AC_ARG_WITH(gcc,
38 [ --with-gcc use GCC to compile Emacs])
39 AC_ARG_WITH(pop,
40 [ --with-pop support POP for mail retrieval],
41 [AC_DEFINE(MAIL_USE_POP)])
42 AC_ARG_WITH(kerberos,
43 [ --with-kerberos support Kerberos-authenticated POP],
44 [AC_DEFINE(KERBEROS)])
45 AC_ARG_WITH(kerberos5,
46 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
47 [if test "${with_kerberos5+set}" = set; then
48 if test "${with_kerberos+set}" != set; then
49 with_kerberos=yes
50 AC_DEFINE(KERBEROS)
51 fi
52 fi
53 AC_DEFINE(KERBEROS5)])
54 AC_ARG_WITH(hesiod,
55 [ --with-hesiod support Hesiod to get the POP server host],
56 [AC_DEFINE(HESIOD)])
57 dnl This should be the last --with option, because --with-x is
58 dnl added later on when we find the path of X, and it's best to
59 dnl keep them together visually.
60 AC_ARG_WITH(x-toolkit,
61 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif/no)],
62 [ case "${withval}" in
63 y | ye | yes ) val=athena ;;
64 n | no ) val=no ;;
65 l | lu | luc | luci | lucid ) val=lucid ;;
66 a | at | ath | athe | athen | athena ) val=athena ;;
67 m | mo | mot | moti | motif ) val=motif ;;
68 dnl These don't currently work.
69 dnl o | op | ope | open | open- | open-l | open-lo \
70 dnl | open-loo | open-look ) val=open-look ;;
71 * )
72 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
73 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
74 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
75 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
76 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
77 ;;
78 esac
79 with_x_toolkit=$val
80 ])
81
82 #### Make srcdir absolute, if it isn't already. It's important to
83 #### avoid running the path through pwd unnecessary, since pwd can
84 #### give you automounter prefixes, which can go away. We do all this
85 #### so Emacs can find its files when run uninstalled.
86 case "${srcdir}" in
87 /* ) ;;
88 . )
89 ## We may be able to use the $PWD environment variable to make this
90 ## absolute. But sometimes PWD is inaccurate.
91 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
92 CDPATH=
93 if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`" ;
94 then
95 srcdir="$PWD"
96 else
97 srcdir="`(cd ${srcdir}; pwd)`"
98 fi
99 ;;
100 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
101 esac
102
103 #### Check if the source directory already has a configured system in it.
104 if test `pwd` != `(cd ${srcdir} && pwd)` \
105 && test -f "${srcdir}/src/config.h" ; then
106 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
107 as a build directory right now; it has been configured in its own
108 right. To configure in another directory as well, you MUST
109 use GNU make. If you do not have GNU make, then you must
110 now do \`make distclean' in ${srcdir},
111 and then run $0 again.])
112
113 changequote(, )dnl
114 extrasub='/^VPATH[ ]*=/c\
115 changequote([, ])dnl
116 vpath %.c $(srcdir)\
117 vpath %.h $(srcdir)\
118 vpath %.y $(srcdir)\
119 vpath %.l $(srcdir)\
120 vpath %.s $(srcdir)\
121 vpath %.in $(srcdir)\
122 vpath %.texi $(srcdir)'
123 fi
124
125 #### Given the configuration name, set machfile and opsysfile to the
126 #### names of the m/*.h and s/*.h files we should use.
127
128 ### Canonicalize the configuration name.
129
130 AC_CANONICAL_HOST
131 canonical=$host
132 configuration=$host_alias
133
134 changequote(, )dnl
135
136 ### If you add support for a new configuration, add code to this
137 ### switch statement to recognize your configuration name and select
138 ### the appropriate operating system and machine description files.
139
140 ### You would hope that you could choose an m/*.h file pretty much
141 ### based on the machine portion of the configuration name, and an s-
142 ### file based on the operating system portion. However, it turns out
143 ### that each m/*.h file is pretty manufacturer-specific - for
144 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
145 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
146 ### machines. So we basically have to have a special case for each
147 ### configuration name.
148 ###
149 ### As far as handling version numbers on operating systems is
150 ### concerned, make sure things will fail in a fixable way. If
151 ### /etc/MACHINES doesn't say anything about version numbers, be
152 ### prepared to handle anything reasonably. If version numbers
153 ### matter, be sure /etc/MACHINES says something about it.
154 ###
155 ### Eric Raymond says we should accept strings like "sysvr4" to mean
156 ### "System V Release 4"; he writes, "The old convention encouraged
157 ### confusion between `system' and `release' levels'."
158
159 machine='' opsys='' unported=no
160 case "${canonical}" in
161
162 ## NetBSD ports
163 *-*-netbsd* )
164 opsys=netbsd
165 case "${canonical}" in
166 alpha*-*-netbsd*) machine=alpha ;;
167 i[3456]86-*-netbsd*) machine=intel386 ;;
168 m68k-*-netbsd*)
169 # This is somewhat bogus.
170 machine=hp9000s300 ;;
171 mips-*-netbsd*) machine=pmax ;;
172 ns32k-*-netbsd*) machine=ns32000 ;;
173 sparc-*-netbsd*) machine=sparc ;;
174 vax-*-netbsd*) machine=vax ;;
175 esac
176 ;;
177
178 ## OpenBSD ports
179 *-*-openbsd* )
180 opsys=openbsd
181 case "${canonical}" in
182 alpha*-*-openbsd*) machine=alpha ;;
183 i386-*-openbsd*) machine=intel386 ;;
184 m68k-*-openbsd*) machine=hp9000s300 ;;
185 mipsel-*-openbsd*) machine=pmax ;;
186 ns32k-*-openbsd*) machine=ns32000 ;;
187 sparc-*-openbsd*) machine=sparc ;;
188 vax-*-netbsd*) machine=vax ;;
189 esac
190 ;;
191
192 ## Acorn RISCiX:
193 arm-acorn-riscix1.1* )
194 machine=acorn opsys=riscix1-1
195 ;;
196 arm-acorn-riscix1.2* | arm-acorn-riscix )
197 ## This name is riscix12 instead of riscix1.2
198 ## to avoid a file name conflict on MSDOS.
199 machine=acorn opsys=riscix12
200 ;;
201
202 ## BSDI ports
203 *-*-bsdi* )
204 opsys=bsdi
205 case "${canonical}" in
206 i[345]86-*-bsdi*) machine=intel386 ;;
207 sparc-*-bsdi*) machine=sparc ;;
208 powerpc-*-bsdi*) machine=powerpc ;;
209 esac
210 case "${canonical}" in
211 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
212 *-*-bsdi2.0* ) opsys=bsdos2 ;;
213 *-*-bsdi2* ) opsys=bsdos2-1 ;;
214 *-*-bsdi3* ) opsys=bsdos3 ;;
215 esac
216 ;;
217
218 ## Alliant machines
219 ## Strictly speaking, we need the version of the alliant operating
220 ## system to choose the right machine file, but currently the
221 ## configuration name doesn't tell us enough to choose the right
222 ## one; we need to give alliants their own operating system name to
223 ## do this right. When someone cares, they can help us.
224 fx80-alliant-* )
225 machine=alliant4 opsys=bsd4-2
226 ;;
227 i860-alliant-* )
228 machine=alliant-2800 opsys=bsd4-3
229 ;;
230
231 ## Alpha (DEC) machines.
232 alpha*-dec-osf* )
233 machine=alpha opsys=osf1
234 # This is needed to find X11R6.1 libraries for certain tests.
235 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
236 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
237 ;;
238
239 alpha*-*-linux-gnu* )
240 machine=alpha opsys=gnu-linux
241 ;;
242
243 ## Altos 3068
244 m68*-altos-sysv* )
245 machine=altos opsys=usg5-2
246 ;;
247
248 ## Amdahl UTS
249 580-amdahl-sysv* )
250 machine=amdahl opsys=usg5-2-2
251 ;;
252
253 ## Apollo, Domain/OS
254 m68*-apollo-* )
255 machine=apollo opsys=bsd4-3
256 ;;
257
258 ## AT&T 3b2, 3b5, 3b15, 3b20
259 we32k-att-sysv* )
260 machine=att3b opsys=usg5-2-2
261 ;;
262
263 ## AT&T 3b1 - The Mighty Unix PC!
264 m68*-att-sysv* )
265 machine=7300 opsys=usg5-2-2
266 ;;
267
268 ## Bull dpx20
269 rs6000-bull-bosx* )
270 machine=ibmrs6000 opsys=aix3-2
271 ;;
272
273 ## Bull dpx2
274 m68*-bull-sysv3* )
275 machine=dpx2 opsys=usg5-3
276 ;;
277
278 ## Bull sps7
279 m68*-bull-sysv2* )
280 machine=sps7 opsys=usg5-2
281 ;;
282
283 ## CCI 5/32, 6/32 -- see "Tahoe".
284
285 ## Celerity
286 ## I don't know what configuration name to use for this; config.sub
287 ## doesn't seem to know anything about it. Hey, Celerity users, get
288 ## in touch with us!
289 celerity-celerity-bsd* )
290 machine=celerity opsys=bsd4-2
291 ;;
292
293 ## Clipper
294 ## What operating systems does this chip run that Emacs has been
295 ## tested on?
296 clipper-* )
297 machine=clipper
298 ## We'll use the catch-all code at the bottom to guess the
299 ## operating system.
300 ;;
301
302 ## Convex
303 *-convex-bsd* | *-convex-convexos* )
304 machine=convex opsys=bsd4-3
305 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
306 NON_GNU_CPP="cc -E -P"
307 ;;
308
309 ## Cubix QBx/386
310 i[3456]86-cubix-sysv* )
311 machine=intel386 opsys=usg5-3
312 ;;
313
314 ## Cydra 5
315 cydra*-cydrome-sysv* )
316 machine=cydra5 opsys=usg5-3
317 ;;
318
319 ## Data General AViiON Machines
320 ## DG changed naming conventions with the release of 5.4.4.10, they
321 ## dropped the initial 5.4 but left the intervening R. Because of the
322 ## R this shouldn't conflict with older versions of the OS (which I
323 ## think were named like dgux4.*). In addition, DG new AViiONs series
324 ## uses either Motorola M88k or Intel Pentium CPUs.
325 i586-dg-dguxR4.* | m88k-dg-dguxR4.* | m88k-dg-dgux4* )
326 machine=aviion opsys=dgux4
327 ;;
328 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
329 ## This name is dgux5-4-3 instead of dgux5-4r3
330 ## to avoid a file name conflict on MSDOS.
331 machine=aviion opsys=dgux5-4-3
332 ;;
333 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
334 machine=aviion opsys=dgux5-4r2
335 ;;
336 m88k-dg-dgux* )
337 machine=aviion opsys=dgux
338 ;;
339
340 ## DECstations
341 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
342 machine=pmax opsys=bsd4-2
343 ;;
344 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
345 machine=pmax opsys=bsd4-3
346 ;;
347 mips-dec-ultrix* )
348 machine=pmax opsys=ultrix4-3
349 ;;
350 mips-dec-osf* )
351 machine=pmax opsys=osf1
352 ;;
353 mips-dec-mach_bsd4.3* )
354 machine=pmax opsys=mach-bsd4-3
355 ;;
356
357 ## Motorola Delta machines
358 m68k-motorola-sysv* | m68000-motorola-sysv* )
359 machine=delta opsys=usg5-3
360 if test -z "`type gnucc | grep 'not found'`"
361 then
362 if test -s /etc/167config
363 then CC="gnucc -m68040"
364 else CC="gnucc -m68881"
365 fi
366 else
367 if test -z "`type gcc | grep 'not found'`"
368 then CC=gcc
369 else CC=cc
370 fi
371 fi
372 ;;
373 m88k-motorola-sysv4* )
374 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
375 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
376 # I hope there are not other 4.0 versions for this machine
377 # which really need usg5-4 instead.
378 machine=delta88k opsys=usg5-4-2
379 ;;
380 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
381 machine=delta88k opsys=usg5-3
382 ;;
383
384 ## Dual machines
385 m68*-dual-sysv* )
386 machine=dual opsys=usg5-2
387 ;;
388 m68*-dual-uniplus* )
389 machine=dual opsys=unipl5-2
390 ;;
391
392 ## Elxsi 6400
393 elxsi-elxsi-sysv* )
394 machine=elxsi opsys=usg5-2
395 ;;
396
397 ## Encore machines
398 ns16k-encore-bsd* )
399 machine=ns16000 opsys=umax
400 ;;
401
402 ## The GEC 93 - apparently, this port isn't really finished yet.
403
404 ## Gould Power Node and NP1
405 pn-gould-bsd4.2* )
406 machine=gould opsys=bsd4-2
407 ;;
408 pn-gould-bsd4.3* )
409 machine=gould opsys=bsd4-3
410 ;;
411 np1-gould-bsd* )
412 machine=gould-np1 opsys=bsd4-3
413 ;;
414
415 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
416 ## as far as Emacs is concerned).
417 m88k-harris-cxux* )
418 # Build needs to be different on 7.0 and later releases
419 case "`uname -r`" in
420 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
421 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
422 esac
423 NON_GNU_CPP="/lib/cpp"
424 ;;
425 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
426 m68k-harris-cxux* )
427 machine=nh3000 opsys=cxux
428 ;;
429 ## Harris power pc NightHawk running Power UNIX (Series 6000)
430 powerpc-harris-powerunix )
431 machine=nh6000 opsys=powerunix
432 NON_GNU_CPP="cc -Xo -E -P"
433 ;;
434 ## SR2001/SR2201 running HI-UX/MPP
435 hppa1.1-hitachi-hiuxmpp* )
436 machine=sr2k opsys=hiuxmpp
437 ;;
438 ## Honeywell XPS100
439 xps*-honeywell-sysv* )
440 machine=xps100 opsys=usg5-2
441 ;;
442
443 ## HP 9000 series 200 or 300
444 m68*-hp-bsd* )
445 machine=hp9000s300 opsys=bsd4-3
446 ;;
447 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
448 m68*-hp-hpux* )
449 case "`uname -r`" in
450 ## Someone's system reports A.B8.05 for this.
451 ## I wonder what other possibilities there are.
452 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
453 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
454 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
455 *.10.* ) machine=hp9000s300 opsys=hpux9shr ;;
456 *) machine=hp9000s300 opsys=hpux ;;
457 esac
458 ;;
459
460 ## HP 9000 series 700 and 800, running HP/UX
461 hppa*-hp-hpux7* )
462 machine=hp800 opsys=hpux
463 ;;
464 hppa*-hp-hpux8* )
465 machine=hp800 opsys=hpux8
466 ;;
467 hppa*-hp-hpux9shr* )
468 machine=hp800 opsys=hpux9shr
469 ;;
470 hppa*-hp-hpux9* )
471 machine=hp800 opsys=hpux9
472 ;;
473 hppa*-hp-hpux10* )
474 machine=hp800 opsys=hpux10
475 ;;
476
477 ## HP 9000 series 700 and 800, running HP/UX
478 hppa*-hp-hpux* )
479 ## Cross-compilation? Nah!
480 case "`uname -r`" in
481 ## Someone's system reports A.B8.05 for this.
482 ## I wonder what other possibilities there are.
483 *.B8.* ) machine=hp800 opsys=hpux8 ;;
484 *.08.* ) machine=hp800 opsys=hpux8 ;;
485 *.09.* ) machine=hp800 opsys=hpux9 ;;
486 *) machine=hp800 opsys=hpux ;;
487 esac
488 ;;
489 hppa*-*-nextstep* )
490 machine=hp800 opsys=nextstep
491 ;;
492
493 ## Orion machines
494 orion-orion-bsd* )
495 machine=orion opsys=bsd4-2
496 ;;
497 clipper-orion-bsd* )
498 machine=orion105 opsys=bsd4-2
499 ;;
500
501 ## IBM machines
502 i[3456]86-ibm-aix1.1* )
503 machine=ibmps2-aix opsys=usg5-2-2
504 ;;
505 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
506 machine=ibmps2-aix opsys=usg5-3
507 ;;
508 i370-ibm-aix*)
509 machine=ibm370aix opsys=usg5-3
510 ;;
511 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
512 machine=ibmrs6000 opsys=aix3-1
513 ;;
514 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
515 machine=ibmrs6000 opsys=aix3-2-5
516 ;;
517 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
518 machine=ibmrs6000 opsys=aix4-1
519 ;;
520 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
521 machine=ibmrs6000 opsys=aix4-2
522 ;;
523 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
524 machine=ibmrs6000 opsys=aix4
525 ;;
526 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
527 machine=ibmrs6000 opsys=aix4-1
528 ;;
529 rs6000-ibm-aix* | powerpc-ibm-aix* )
530 machine=ibmrs6000 opsys=aix3-2
531 ;;
532 romp-ibm-bsd4.3* )
533 machine=ibmrt opsys=bsd4-3
534 ;;
535 romp-ibm-bsd4.2* )
536 machine=ibmrt opsys=bsd4-2
537 ;;
538 romp-ibm-aos4.3* )
539 machine=ibmrt opsys=bsd4-3
540 ;;
541 romp-ibm-aos4.2* )
542 machine=ibmrt opsys=bsd4-2
543 ;;
544 romp-ibm-aos* )
545 machine=ibmrt opsys=bsd4-3
546 ;;
547 romp-ibm-bsd* )
548 machine=ibmrt opsys=bsd4-3
549 ;;
550 romp-ibm-aix* )
551 machine=ibmrt-aix opsys=usg5-2-2
552 ;;
553
554 ## Integrated Solutions `Optimum V'
555 m68*-isi-bsd4.2* )
556 machine=isi-ov opsys=bsd4-2
557 ;;
558 m68*-isi-bsd4.3* )
559 machine=isi-ov opsys=bsd4-3
560 ;;
561
562 ## Intel 386 machines where we do care about the manufacturer
563 i[3456]86-intsys-sysv* )
564 machine=is386 opsys=usg5-2-2
565 ;;
566
567 ## Prime EXL
568 i[3456]86-prime-sysv* )
569 machine=i386 opsys=usg5-3
570 ;;
571
572 ## Sequent Symmetry running Dynix
573 i[3456]86-sequent-bsd* )
574 machine=symmetry opsys=bsd4-3
575 ;;
576
577 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
578 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
579 machine=sequent-ptx opsys=ptx4
580 NON_GNU_CPP=/lib/cpp
581 ;;
582
583 ## Sequent Symmetry running DYNIX/ptx
584 ## Use the old cpp rather than the newer ANSI one.
585 i[3456]86-sequent-ptx* )
586 machine=sequent-ptx opsys=ptx
587 NON_GNU_CPP="/lib/cpp"
588 ;;
589
590 ## ncr machine running svr4.3.
591 i[3456]86-ncr-sysv4.3 )
592 machine=ncr386 opsys=usg5-4-3
593 ;;
594
595 ## Unspecified sysv on an ncr machine defaults to svr4.2.
596 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
597 i[3456]86-ncr-sysv* )
598 machine=ncr386 opsys=usg5-4-2
599 ;;
600
601 ## Intel Paragon OSF/1
602 i860-intel-osf1* )
603 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
604 ;;
605
606 ## Intel 860
607 i860-*-sysv4* )
608 machine=i860 opsys=usg5-4
609 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
610 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
611 ;;
612
613 ## Masscomp machines
614 m68*-masscomp-rtu* )
615 machine=masscomp opsys=rtu
616 ;;
617
618 ## Megatest machines
619 m68*-megatest-bsd* )
620 machine=mega68 opsys=bsd4-2
621 ;;
622
623 ## Workstations sold by MIPS
624 ## This is not necessarily all workstations using the MIPS processor -
625 ## Irises are produced by SGI, and DECstations by DEC.
626
627 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
628 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
629 ## it gives for choosing between the alternatives seems to be "Use
630 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
631 ## the BSD world." I'll assume that these are instructions for
632 ## handling two odd situations, and that every other situation
633 ## should use mips.h and usg5-2-2, they being listed first.
634 mips-mips-usg* )
635 machine=mips4
636 ## Fall through to the general code at the bottom to decide on the OS.
637 ;;
638 mips-mips-riscos4* )
639 machine=mips4 opsys=bsd4-3
640 NON_GNU_CC="cc -systype bsd43"
641 NON_GNU_CPP="cc -systype bsd43 -E"
642 ;;
643 mips-mips-riscos5* )
644 machine=mips4 opsys=riscos5
645 NON_GNU_CC="cc -systype bsd43"
646 NON_GNU_CPP="cc -systype bsd43 -E"
647 ;;
648 mips-mips-bsd* )
649 machine=mips opsys=bsd4-3
650 ;;
651 mips-mips-* )
652 machine=mips opsys=usg5-2-2
653 ;;
654
655 ## NeXT
656 m68*-next-* | m68k-*-nextstep* )
657 machine=m68k opsys=nextstep
658 ;;
659
660 ## The complete machine from National Semiconductor
661 ns32k-ns-genix* )
662 machine=ns32000 opsys=usg5-2
663 ;;
664
665 ## NCR machines
666 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
667 machine=tower32 opsys=usg5-2-2
668 ;;
669 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
670 machine=tower32v3 opsys=usg5-3
671 ;;
672
673 ## Nixdorf Targon 31
674 m68*-nixdorf-sysv* )
675 machine=targon31 opsys=usg5-2-2
676 ;;
677
678 ## Nu (TI or LMI)
679 m68*-nu-sysv* )
680 machine=nu opsys=usg5-2
681 ;;
682
683 ## Plexus
684 m68*-plexus-sysv* )
685 machine=plexus opsys=usg5-2
686 ;;
687
688 ## PowerPC reference platform
689 powerpcle-*-solaris2* )
690 machine=prep
691 opsys=sol2-5
692 ;;
693
694 ## Pyramid machines
695 ## I don't really have any idea what sort of processor the Pyramid has,
696 ## so I'm assuming it is its own architecture.
697 pyramid-pyramid-bsd* )
698 machine=pyramid opsys=bsd4-2
699 ;;
700
701 ## Sequent Balance
702 ns32k-sequent-bsd4.2* )
703 machine=sequent opsys=bsd4-2
704 ;;
705 ns32k-sequent-bsd4.3* )
706 machine=sequent opsys=bsd4-3
707 ;;
708
709 ## Siemens Nixdorf
710 mips-siemens-sysv* | mips-sni-sysv*)
711 machine=mips-siemens opsys=usg5-4
712 NON_GNU_CC=/usr/ccs/bin/cc
713 NON_GNU_CPP=/usr/ccs/lib/cpp
714 ;;
715
716 ## Silicon Graphics machines
717 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
718 m68*-sgi-iris3.5* )
719 machine=irist opsys=iris3-5
720 ;;
721 m68*-sgi-iris3.6* | m68*-sgi-iris*)
722 machine=irist opsys=iris3-6
723 ;;
724 ## Iris 4D
725 mips-sgi-irix3* )
726 machine=iris4d opsys=irix3-3
727 ;;
728 mips-sgi-irix4* )
729 machine=iris4d opsys=irix4-0
730 ;;
731 mips-sgi-irix6* )
732 machine=iris4d opsys=irix6-0
733 NON_GNU_CPP=/lib/cpp
734 NON_GCC_TEST_OPTIONS=-32
735 ;;
736 mips-sgi-irix5.[01]* )
737 machine=iris4d opsys=irix5-0
738 ;;
739 mips-sgi-irix5* | mips-sgi-irix* )
740 machine=iris4d opsys=irix5-2
741 ;;
742
743 ## SONY machines
744 m68*-sony-bsd4.2* )
745 machine=news opsys=bsd4-2
746 ;;
747 m68*-sony-bsd4.3* )
748 machine=news opsys=bsd4-3
749 ;;
750 m68*-sony-newsos3* | m68*-sony-news3*)
751 machine=news opsys=bsd4-3
752 ;;
753 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
754 machine=news-risc opsys=bsd4-3
755 ;;
756 mips-sony-newsos6* )
757 machine=news-r6 opsys=newsos6
758 ;;
759 mips-sony-news* )
760 machine=news-risc opsys=newsos5
761 ;;
762
763 ## Stride
764 m68*-stride-sysv* )
765 machine=stride opsys=usg5-2
766 ;;
767
768 ## Suns
769 sparc-*-linux-gnu* )
770 machine=sparc opsys=gnu-linux
771 ;;
772
773 *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
774 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
775 | rs6000-*-solaris2*)
776 case "${canonical}" in
777 m68*-sunos1* ) machine=sun1 ;;
778 m68*-sunos2* ) machine=sun2 ;;
779 m68* ) machine=sun3 ;;
780 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
781 i[3456]86-*-* ) machine=intel386 ;;
782 powerpcle* ) machine=powerpcle ;;
783 powerpc* | rs6000* ) machine=ibmrs6000 ;;
784 sparc* ) machine=sparc ;;
785 * ) unported=yes ;;
786 esac
787 case "${canonical}" in
788 ## The Sun386 didn't get past 4.0.
789 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
790 *-sunos4.0* ) opsys=sunos4-0 ;;
791 *-sunos4.1.[3-9]*noshare )
792 ## This name is sunos413 instead of sunos4-1-3
793 ## to avoid a file name conflict on MSDOS.
794 opsys=sunos413
795 NON_GNU_CPP=/usr/lib/cpp
796 NON_GCC_TEST_OPTIONS=-Bstatic
797 GCC_TEST_OPTIONS=-static
798 ;;
799 *-sunos4.1.[3-9]* | *-sunos4shr*)
800 opsys=sunos4shr
801 NON_GNU_CPP=/usr/lib/cpp
802 ;;
803 *-sunos4* | *-sunos )
804 opsys=sunos4-1
805 NON_GCC_TEST_OPTIONS=-Bstatic
806 GCC_TEST_OPTIONS=-static
807 ;;
808 *-sunos5.3* | *-solaris2.3* )
809 opsys=sol2-3
810 NON_GNU_CPP=/usr/ccs/lib/cpp
811 ;;
812 *-sunos5.4* | *-solaris2.4* )
813 opsys=sol2-4
814 NON_GNU_CPP=/usr/ccs/lib/cpp
815 RANLIB="ar -ts"
816 ;;
817 *-sunos5.5* | *-solaris2.5* )
818 opsys=sol2-5
819 NON_GNU_CPP=/usr/ccs/lib/cpp
820 RANLIB="ar -ts"
821 ;;
822 *-sunos5* | *-solaris* )
823 opsys=sol2-4
824 NON_GNU_CPP=/usr/ccs/lib/cpp
825 ;;
826 * ) opsys=bsd4-2 ;;
827 esac
828 ## Watch out for a compiler that we know will not work.
829 case "${canonical}" in
830 *-solaris* | *-sunos5* )
831 if [ "x$CC" = x/usr/ucb/cc ]; then
832 ## /usr/ucb/cc doesn't work;
833 ## we should find some other compiler that does work.
834 unset CC
835 fi
836 ;;
837 *) ;;
838 esac
839 ;;
840 sparc-*-nextstep* )
841 machine=sparc opsys=nextstep
842 ;;
843
844 ## Tadpole 68k
845 m68*-tadpole-sysv* )
846 machine=tad68k opsys=usg5-3
847 ;;
848
849 ## Tahoe machines
850 tahoe-tahoe-bsd4.2* )
851 machine=tahoe opsys=bsd4-2
852 ;;
853 tahoe-tahoe-bsd4.3* )
854 machine=tahoe opsys=bsd4-3
855 ;;
856
857 ## Tandem Integrity S2
858 mips-tandem-sysv* )
859 machine=tandem-s2 opsys=usg5-3
860 ;;
861
862 ## Tektronix XD88
863 m88k-tektronix-sysv3* )
864 machine=tekxd88 opsys=usg5-3
865 ;;
866
867 ## Tektronix 16000 box (6130?)
868 ns16k-tektronix-bsd* )
869 machine=ns16000 opsys=bsd4-2
870 ;;
871 ## Tektronix 4300
872 ## src/m/tek4300.h hints that this is a m68k machine.
873 m68*-tektronix-bsd* )
874 machine=tek4300 opsys=bsd4-3
875 ;;
876
877 ## Titan P2 or P3
878 ## We seem to have lost the machine-description file titan.h!
879 titan-titan-sysv* )
880 machine=titan opsys=usg5-3
881 ;;
882
883 ## Ustation E30 (SS5E)
884 m68*-unisys-uniplus* )
885 machine=ustation opsystem=unipl5-2
886 ;;
887
888 ## Vaxen.
889 vax-dec-* )
890 machine=vax
891 case "${canonical}" in
892 *-bsd4.1* ) opsys=bsd4-1 ;;
893 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
894 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
895 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
896 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
897 *-vms* ) opsys=vms ;;
898 * ) unported=yes
899 esac
900 ;;
901
902 ## Whitechapel MG1
903 ns16k-whitechapel-* )
904 machine=mg1
905 ## We don't know what sort of OS runs on these; we'll let the
906 ## operating system guessing code below try.
907 ;;
908
909 ## Wicat
910 m68*-wicat-sysv* )
911 machine=wicat opsys=usg5-2
912 ;;
913
914 ## Intel 386 machines where we don't care about the manufacturer
915 i[3456]86-*-* )
916 machine=intel386
917 case "${canonical}" in
918 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
919 *-isc2.2* ) opsys=isc2-2 ;;
920 *-isc4.0* ) opsys=isc4-0 ;;
921 *-isc4.* ) opsys=isc4-1
922 GCC_TEST_OPTIONS=-posix
923 NON_GCC_TEST_OPTIONS=-Xp
924 ;;
925 *-isc* ) opsys=isc3-0 ;;
926 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
927 *-esix* ) opsys=esix ;;
928 *-xenix* ) opsys=xenix ;;
929 *-linux-gnu* ) opsys=gnu-linux ;;
930 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
931 *-sco3.2v5* ) opsys=sco5
932 NON_GNU_CPP=/lib/cpp
933 # Prevent -belf from being passed to $CPP.
934 # /lib/cpp does not accept it.
935 OVERRIDE_CPPFLAGS=" "
936 ;;
937 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
938 *-386bsd* ) opsys=386bsd ;;
939 *-freebsd* ) opsys=freebsd ;;
940 *-nextstep* ) opsys=nextstep ;;
941 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
942 esac
943 ;;
944
945 ## m68k Linux-based GNU system
946 m68k-*-linux-gnu* )
947 machine=m68k opsys=gnu-linux
948 ;;
949
950 ## Mips Linux-based GNU system
951 mips-*-linux-gnu* )
952 machine=mips opsys=gnu-linux
953 ;;
954
955 * )
956 unported=yes
957 ;;
958 esac
959
960 ### If the code above didn't choose an operating system, just choose
961 ### an operating system based on the configuration name. You really
962 ### only want to use this when you have no idea what the right
963 ### operating system is; if you know what operating systems a machine
964 ### runs, it's cleaner to make it explicit in the case statement
965 ### above.
966 if test x"${opsys}" = x; then
967 case "${canonical}" in
968 *-gnu* ) opsys=gnu ;;
969 *-bsd4.[01] ) opsys=bsd4-1 ;;
970 *-bsd4.2 ) opsys=bsd4-2 ;;
971 *-bsd4.3 ) opsys=bsd4-3 ;;
972 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
973 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
974 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
975 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
976 *-sysv4.2uw* ) opsys=unixware ;;
977 *-sysv4.1* | *-sysvr4.1* )
978 NON_GNU_CPP=/usr/lib/cpp
979 opsys=usg5-4 ;;
980 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
981 if [ x$NON_GNU_CPP = x ]; then
982 if [ -f /usr/ccs/lib/cpp ]; then
983 NON_GNU_CPP=/usr/ccs/lib/cpp
984 else
985 NON_GNU_CPP=/lib/cpp
986 fi
987 fi
988 opsys=usg5-4-2 ;;
989 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
990 * )
991 unported=yes
992 ;;
993 esac
994 fi
995
996 if test "x$RANLIB" = x; then
997 RANLIB=ranlib
998 fi
999
1000 changequote([, ])dnl
1001
1002 if test $unported = yes; then
1003 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1004 Check \`etc/MACHINES' for recognized configuration names.])
1005 fi
1006
1007 machfile="m/${machine}.h"
1008 opsysfile="s/${opsys}.h"
1009
1010
1011 #### Choose a compiler.
1012 test -n "$CC" && cc_specified=yes
1013
1014 # Save the value of CFLAGS that the user specified.
1015 SPECIFIED_CFLAGS="$CFLAGS"
1016
1017 case ${with_gcc} in
1018 "yes" ) CC="gcc" GCC=yes ;;
1019 "no" ) : ${CC=cc} ;;
1020 * ) AC_PROG_CC
1021 esac
1022
1023 # On Suns, sometimes $CPP names a directory.
1024 if test -n "$CPP" && test -d "$CPP"; then
1025 CPP=
1026 fi
1027
1028 #### Some systems specify a CPP to use unless we are using GCC.
1029 #### Now that we know whether we are using GCC, we can decide whether
1030 #### to use that one.
1031 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1032 then
1033 CPP="$NON_GNU_CPP"
1034 fi
1035
1036 #### Some systems specify a CC to use unless we are using GCC.
1037 #### Now that we know whether we are using GCC, we can decide whether
1038 #### to use that one.
1039 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1040 test x$cc_specified != xyes
1041 then
1042 CC="$NON_GNU_CC"
1043 fi
1044
1045 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1046 then
1047 CC="$CC $GCC_TEST_OPTIONS"
1048 fi
1049
1050 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1051 then
1052 CC="$CC $NON_GCC_TEST_OPTIONS"
1053 fi
1054
1055 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1056 then
1057 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1058 fi
1059
1060 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1061 then
1062 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1063 fi
1064
1065 #### Some other nice autoconf tests. If you add a test here which
1066 #### should make an entry in src/config.h, don't forget to add an
1067 #### #undef clause to src/config.h.in for autoconf to modify.
1068
1069 dnl checks for programs
1070 AC_PROG_LN_S
1071 AC_PROG_CPP
1072 AC_PROG_INSTALL
1073 AC_PROG_YACC
1074
1075 dnl checks for Unix variants
1076 AC_AIX
1077
1078 dnl checks for header files
1079 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h linux/version.h sys/systeminfo.h termios.h limits.h)
1080 AC_HEADER_STDC
1081 AC_HEADER_TIME
1082 AC_DECL_SYS_SIGLIST
1083
1084 dnl Some systems have utime.h but don't declare the struct anyplace.
1085 AC_MSG_CHECKING(for struct utimbuf)
1086 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1087 #include <sys/time.h>
1088 #include <time.h>
1089 #else
1090 #ifdef HAVE_SYS_TIME_H
1091 #include <sys/time.h>
1092 #else
1093 #include <time.h>
1094 #endif
1095 #endif
1096 #ifdef HAVE_UTIME_H
1097 #include <utime.h>
1098 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1099 [AC_MSG_RESULT(yes)
1100 AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
1101 AC_MSG_RESULT(no))
1102
1103 dnl checks for typedefs
1104 AC_TYPE_SIGNAL
1105
1106 AC_MSG_CHECKING(for struct timeval)
1107 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1108 #include <sys/time.h>
1109 #include <time.h>
1110 #else
1111 #ifdef HAVE_SYS_TIME_H
1112 #include <sys/time.h>
1113 #else
1114 #include <time.h>
1115 #endif
1116 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1117 [AC_MSG_RESULT(yes)
1118 HAVE_TIMEVAL=yes
1119 AC_DEFINE(HAVE_TIMEVAL)],
1120 [AC_MSG_RESULT(no)
1121 HAVE_TIMEVAL=no])
1122
1123 dnl checks for structure members
1124 AC_STRUCT_TM
1125 AC_STRUCT_TIMEZONE
1126
1127 dnl checks for compiler characteristics
1128 AC_C_CONST
1129
1130 dnl check for Make feature
1131 AC_PROG_MAKE_SET
1132
1133 dnl checks for operating system services
1134 AC_SYS_LONG_FILE_NAMES
1135
1136 #### Choose a window system.
1137
1138 AC_PATH_X
1139 if test "$no_x" = yes; then
1140 window_system=none
1141 else
1142 window_system=x11
1143 fi
1144
1145 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1146 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1147 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1148 x_default_search_path=""
1149 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1150 x_search_path="${x_library}/X11/%L/%T/%N%C%S:\
1151 ${x_library}/X11/%L/%T/%N%C%S:${x_libary}/X11/%l/%T/%N%C%S:\
1152 ${x_library}/X11/%T/%N%C%S:${x_library}/X11/%L/%T/%N%S:\
1153 ${x_library}/X11/%l/%T/%N%S:${x_library}/X11/%T/%N%S"
1154 if test x"${x_default_search_path}" = x; then
1155 x_default_search_path=${x_search_path}
1156 else
1157 x_default_search_path="${x_search_path}:${x_default_search_path}"
1158 fi
1159 done
1160 fi
1161 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1162 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1163 fi
1164
1165 if test x"${x_includes}" = x; then
1166 bitmapdir=/usr/include/X11/bitmaps
1167 else
1168 # accumulate include directories that have X11 bitmap subdirectories
1169 bmd_acc="dummyval"
1170 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1171 if test -d "${bmd}/X11/bitmaps"; then
1172 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1173 elif test -d "${bmd}/bitmaps"; then
1174 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1175 fi
1176 done
1177 if test ${bmd_acc} != "dummyval"; then
1178 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1179 fi
1180 fi
1181
1182 case "${window_system}" in
1183 x11 )
1184 HAVE_X_WINDOWS=yes
1185 HAVE_X11=yes
1186 case "${with_x_toolkit}" in
1187 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1188 motif ) USE_X_TOOLKIT=MOTIF ;;
1189 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1190 no ) USE_X_TOOLKIT=none ;;
1191 dnl If user did not say whether to use a toolkit,
1192 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1193 * ) USE_X_TOOLKIT=maybe ;;
1194 esac
1195 ;;
1196 none )
1197 HAVE_X_WINDOWS=no
1198 HAVE_X11=no
1199 USE_X_TOOLKIT=none
1200 ;;
1201 esac
1202
1203 ### If we're using X11, we should use the X menu package.
1204 HAVE_MENUS=no
1205 case ${HAVE_X11} in
1206 yes ) HAVE_MENUS=yes ;;
1207 esac
1208
1209 if test "${opsys}" = "hpux9"; then
1210 case "${x_libraries}" in
1211 *X11R4* )
1212 opsysfile="s/hpux9-x11r4.h"
1213 ;;
1214 esac
1215 fi
1216
1217 if test "${opsys}" = "hpux9shr"; then
1218 case "${x_libraries}" in
1219 *X11R4* )
1220 opsysfile="s/hpux9shxr4.h"
1221 ;;
1222 esac
1223 fi
1224
1225 #### Extract some information from the operating system and machine files.
1226
1227 AC_CHECKING([the machine- and system-dependent files to find out
1228 - which libraries the lib-src programs will want, and
1229 - whether the GNU malloc routines are usable])
1230
1231 ### First figure out CFLAGS (which we use for running the compiler here)
1232 ### and REAL_CFLAGS (which we use for real compilation).
1233 ### The two are the same except on a few systems, where they are made
1234 ### different to work around various lossages. For example,
1235 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1236 ### as implying static linking.
1237
1238 ### If the CFLAGS env var is specified, we use that value
1239 ### instead of the default.
1240
1241 ### It's not important that this name contain the PID; you can't run
1242 ### two configures in the same directory and have anything work
1243 ### anyway.
1244 tempcname="conftest.c"
1245
1246 echo '
1247 #include "'${srcdir}'/src/'${opsysfile}'"
1248 #include "'${srcdir}'/src/'${machfile}'"
1249 #ifndef LIBS_MACHINE
1250 #define LIBS_MACHINE
1251 #endif
1252 #ifndef LIBS_SYSTEM
1253 #define LIBS_SYSTEM
1254 #endif
1255 #ifndef C_SWITCH_SYSTEM
1256 #define C_SWITCH_SYSTEM
1257 #endif
1258 #ifndef C_SWITCH_MACHINE
1259 #define C_SWITCH_MACHINE
1260 #endif
1261 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1262 configure___ c_switch_system=C_SWITCH_SYSTEM
1263 configure___ c_switch_machine=C_SWITCH_MACHINE
1264
1265 #ifndef LIB_X11_LIB
1266 #define LIB_X11_LIB -lX11
1267 #endif
1268
1269 #ifndef LIBX11_MACHINE
1270 #define LIBX11_MACHINE
1271 #endif
1272
1273 #ifndef LIBX11_SYSTEM
1274 #define LIBX11_SYSTEM
1275 #endif
1276 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1277
1278 #ifdef UNEXEC
1279 configure___ unexec=UNEXEC
1280 #else
1281 configure___ unexec=unexec.o
1282 #endif
1283
1284 #ifdef SYSTEM_MALLOC
1285 configure___ system_malloc=yes
1286 #else
1287 configure___ system_malloc=no
1288 #endif
1289
1290 #ifndef C_DEBUG_SWITCH
1291 #define C_DEBUG_SWITCH -g
1292 #endif
1293
1294 #ifndef C_OPTIMIZE_SWITCH
1295 #define C_OPTIMIZE_SWITCH -O
1296 #endif
1297
1298 #ifndef LD_SWITCH_MACHINE
1299 #define LD_SWITCH_MACHINE
1300 #endif
1301
1302 #ifndef LD_SWITCH_SYSTEM
1303 #define LD_SWITCH_SYSTEM
1304 #endif
1305
1306 #ifndef LD_SWITCH_X_SITE_AUX
1307 #define LD_SWITCH_X_SITE_AUX
1308 #endif
1309
1310 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1311 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1312
1313 #ifdef THIS_IS_CONFIGURE
1314
1315 /* Get the CFLAGS for tests in configure. */
1316 #ifdef __GNUC__
1317 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1318 #else
1319 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1320 #endif
1321
1322 #else /* not THIS_IS_CONFIGURE */
1323
1324 /* Get the CFLAGS for real compilation. */
1325 #ifdef __GNUC__
1326 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1327 #else
1328 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1329 #endif
1330
1331 #endif /* not THIS_IS_CONFIGURE */
1332 ' > ${tempcname}
1333
1334 # The value of CPP is a quoted variable reference, so we need to do this
1335 # to get its actual value...
1336 CPP=`eval "echo $CPP"`
1337 changequote(, )dnl
1338 eval `${CPP} -Isrc ${tempcname} \
1339 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1340 if test "x$SPECIFIED_CFLAGS" = x; then
1341 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1342 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1343 else
1344 REAL_CFLAGS="$CFLAGS"
1345 fi
1346 changequote([, ])dnl
1347 rm ${tempcname}
1348
1349 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1350
1351 ### Compute the unexec source name from the object name.
1352 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1353
1354 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1355 # Assume not, until told otherwise.
1356 GNU_MALLOC=yes
1357 doug_lea_malloc=yes
1358 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1359 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1360 AC_MSG_CHECKING(whether __after_morecore_hook exists)
1361 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1362 [AC_MSG_RESULT(yes)],
1363 [AC_MSG_RESULT(no)
1364 doug_lea_malloc=no])
1365 if test "${system_malloc}" = "yes"; then
1366 GNU_MALLOC=no
1367 GNU_MALLOC_reason="
1368 (The GNU allocators don't work with this system configuration.)"
1369 fi
1370 if test "$doug_lea_malloc" = "yes" ; then
1371 if test "$GNU_MALLOC" = yes ; then
1372 GNU_MALLOC_reason="
1373 (Using Doug Lea's new malloc from the GNU C Library.)"
1374 fi
1375 AC_DEFINE(DOUG_LEA_MALLOC)
1376 fi
1377
1378 if test x"${REL_ALLOC}" = x; then
1379 REL_ALLOC=${GNU_MALLOC}
1380 fi
1381
1382 LISP_FLOAT_TYPE=yes
1383
1384
1385 #### Add the libraries to LIBS and check for some functions.
1386
1387 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1388 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1389 else
1390 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1391 fi
1392
1393 LIBS="$libsrc_libs $LIBS"
1394
1395 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1396 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1397 AC_CHECK_LIB(dnet, dnet_ntoa)
1398 dnl This causes -lresolv to get used in subsequent tests,
1399 dnl which causes failures on some systems such as HPUX 9.
1400 dnl AC_CHECK_LIB(resolv, gethostbyname)
1401
1402 dnl FIXME replace main with a function we actually want from this library.
1403 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1404
1405 AC_CHECK_LIB(pthreads, cma_open)
1406
1407 AC_MSG_CHECKING(for XFree86)
1408 if test -d /usr/X386/include; then
1409 HAVE_XFREE386=yes
1410 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1411 else
1412 HAVE_XFREE386=no
1413 fi
1414 AC_MSG_RESULT($HAVE_XFREE386)
1415
1416 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1417 # for the tests that follow. We set it back to REAL_CFLAGS later on.
1418
1419 if test "${HAVE_X11}" = "yes"; then
1420 DEFS="$C_SWITCH_X_SITE $DEFS"
1421 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1422 LIBS="$LIBX $LIBS"
1423 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1424
1425 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1426 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1427 # but it's more convenient here to set LD_RUN_PATH
1428 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1429 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1430 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1431 export LD_RUN_PATH
1432 fi
1433
1434 if test "${opsys}" = "gnu-linux"; then
1435 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1436 AC_TRY_LINK([],
1437 [XOpenDisplay ("foo");],
1438 [xlinux_first_failure=no],
1439 [xlinux_first_failure=yes])
1440 if test "${xlinux_first_failure}" = "yes"; then
1441 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1442 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1443 OLD_CPPFLAGS="$CPPFLAGS"
1444 OLD_LIBS="$LIBS"
1445 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1446 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1447 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1448 LIBS="$LIBS -b i486-linuxaout"
1449 AC_TRY_LINK([],
1450 [XOpenDisplay ("foo");],
1451 [xlinux_second_failure=no],
1452 [xlinux_second_failure=yes])
1453 if test "${xlinux_second_failure}" = "yes"; then
1454 # If we get the same failure with -b, there is no use adding -b.
1455 # So take it out. This plays safe.
1456 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1457 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1458 CPPFLAGS="$OLD_CPPFLAGS"
1459 LIBS="$OLD_LIBS"
1460 AC_MSG_RESULT(no)
1461 else
1462 AC_MSG_RESULT(yes)
1463 fi
1464 else
1465 AC_MSG_RESULT(no)
1466 fi
1467 fi
1468
1469 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1470 XScreenNumberOfScreen XSetWMProtocols)
1471 fi
1472
1473 if test "${window_system}" = "x11"; then
1474 AC_MSG_CHECKING(X11 version 6)
1475 AC_TRY_LINK([#include <X11/Xlib.h>],
1476 [#if XlibSpecificationRelease < 6
1477 fail;
1478 #endif
1479 ], [AC_MSG_RESULT(6 or newer)
1480 AC_DEFINE(HAVE_X11R6)],
1481 [AC_MSG_RESULT(before 6)])
1482 fi
1483
1484 if test "${window_system}" = "x11"; then
1485 AC_MSG_CHECKING(X11 version 5)
1486 AC_TRY_LINK([#include <X11/Xlib.h>],
1487 [#if XlibSpecificationRelease < 5
1488 fail;
1489 #endif
1490 ], [AC_MSG_RESULT(5 or newer)
1491 HAVE_X11R5=yes
1492 AC_DEFINE(HAVE_X11R5)],
1493 [
1494 HAVE_X11R5=no
1495 AC_MSG_RESULT(before 5)])
1496 fi
1497
1498 dnl Do not put whitespace before the #include statements below.
1499 dnl Older compilers (eg sunos4 cc) choke on it.
1500 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1501 if test x"${HAVE_X11R5}" = xyes; then
1502 AC_MSG_CHECKING(X11 version 5 with Xaw)
1503 AC_TRY_LINK([
1504 #include <X11/Intrinsic.h>
1505 #include <X11/Xaw/Simple.h>],
1506 [],
1507 [AC_MSG_RESULT(5 or newer, with Xaw; use toolkit by default)
1508 USE_X_TOOLKIT=LUCID],
1509 [AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1510 USE_X_TOOLKIT=none])
1511 else
1512 USE_X_TOOLKIT=none
1513 fi
1514 fi
1515
1516 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1517
1518 if test "${USE_X_TOOLKIT}" != "none"; then
1519 AC_MSG_CHECKING(X11 toolkit version)
1520 AC_TRY_LINK([#include <X11/Intrinsic.h>],
1521 [#if XtSpecificationRelease < 6
1522 fail;
1523 #endif
1524 ], [AC_MSG_RESULT(6 or newer)
1525 HAVE_X11XTR6=yes
1526 AC_DEFINE(HAVE_X11XTR6)],
1527 [AC_MSG_RESULT(before 6)
1528 HAVE_X11XTR6=no])
1529
1530 dnl If using toolkit, check whether libXmu.a exists.
1531 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1532 OLDLIBS="$LIBS"
1533 if test x$HAVE_X11XTR6 = xyes; then
1534 LIBS="-lXt -lSM -lICE $LIBS"
1535 else
1536 LIBS="-lXt $LIBS"
1537 fi
1538 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1539 LIBS="$OLDLIBS"
1540 fi
1541
1542 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1543 AC_MSG_CHECKING(for Motif version 2.1)
1544 AC_TRY_COMPILE([#include <Xm/Xm.h>],
1545 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1546 int x = 5;
1547 #else
1548 Motif version prior to 2.1.
1549 #endif],
1550 [AC_MSG_RESULT(yes)
1551 HAVE_MOTIF_2_1=yes
1552 AC_DEFINE(HAVE_MOTIF_2_1)],
1553 [AC_MSG_RESULT(no)
1554 HAVE_MOTIF_2_1=no])
1555 fi
1556
1557 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1558 AC_MSG_CHECKING(whether netdb declares h_errno)
1559 AC_TRY_LINK([#include <netdb.h>],
1560 [return h_errno;],
1561 [AC_MSG_RESULT(yes)
1562 AC_DEFINE(HAVE_H_ERRNO)],
1563 [AC_MSG_RESULT(no)])
1564
1565 AC_FUNC_ALLOCA
1566
1567 # fmod, logb, and frexp are found in -lm on most systems.
1568 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1569 AC_CHECK_LIB(m, sqrt)
1570
1571 # Check for mail-locking functions in a "mail" library
1572 AC_CHECK_LIB(mail, maillock,
1573 AC_DEFINE(HAVE_LIBMAIL)
1574 AC_CHECK_FUNCS(touchlock)
1575 AC_CHECK_HEADERS(maillock.h))
1576
1577 AC_CHECK_FUNCS(gettimeofday gethostname getdomainname dup2 \
1578 rename closedir mkdir rmdir sysinfo \
1579 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
1580 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
1581 utimes setrlimit setpgid getcwd shutdown strftime)
1582
1583 # Check this now, so that we will NOT find the above functions in ncurses.
1584 # That is because we have not set up to link ncurses in lib-src.
1585 # It's better to believe a function is not available
1586 # than to expect to find it in ncurses.
1587 AC_CHECK_LIB(ncurses, tparm)
1588
1589 # These tell us which Kerberos-related libraries to use.
1590 if test "${with_kerberos+set}" = set; then
1591 AC_CHECK_LIB(com_err, com_err)
1592 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
1593 AC_CHECK_LIB(krb5, krb5_init_context)
1594 if test "${with_kerberos5+set}" != set; then
1595 AC_CHECK_LIB(des, des_cbc_encrypt,,
1596 AC_CHECK_LIB(des425, des_cbc_encrypt))
1597 AC_CHECK_LIB(krb, krb_get_cred,,
1598 AC_CHECK_LIB(krb4, krb_get_cred))
1599 fi
1600
1601 if test "${with_kerberos5+set}" = set; then
1602 AC_CHECK_HEADERS(krb5.h)
1603 else
1604 AC_CHECK_HEADERS(des.h,,
1605 AC_CHECK_HEADERS(kerberosIV/des.h,,
1606 AC_CHECK_HEADERS(kerberos/des.h)))
1607 AC_CHECK_HEADERS(krb.h,,
1608 AC_CHECK_HEADERS(kerberosIV/krb.h,,
1609 AC_CHECK_HEADERS(kerberos/krb.h)))
1610 fi
1611 AC_CHECK_HEADERS(com_err.h)
1612 fi
1613
1614 # Solaris requires -lintl if you want strerror (which calls dgettext)
1615 # to return localized messages.
1616 AC_CHECK_LIB(intl, dgettext)
1617
1618 AC_MSG_CHECKING(whether localtime caches TZ)
1619 AC_CACHE_VAL(emacs_cv_localtime_cache,
1620 [if test x$ac_cv_func_tzset = xyes; then
1621 AC_TRY_RUN([#include <time.h>
1622 #if STDC_HEADERS
1623 # include <stdlib.h>
1624 #endif
1625 extern char **environ;
1626 unset_TZ ()
1627 {
1628 char **from, **to;
1629 for (to = from = environ; (*to = *from); from++)
1630 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1631 to++;
1632 }
1633 char TZ_GMT0[] = "TZ=GMT0";
1634 char TZ_PST8[] = "TZ=PST8";
1635 main()
1636 {
1637 time_t now = time ((time_t *) 0);
1638 int hour_GMT0, hour_unset;
1639 if (putenv (TZ_GMT0) != 0)
1640 exit (1);
1641 hour_GMT0 = localtime (&now)->tm_hour;
1642 unset_TZ ();
1643 hour_unset = localtime (&now)->tm_hour;
1644 if (putenv (TZ_PST8) != 0)
1645 exit (1);
1646 if (localtime (&now)->tm_hour == hour_GMT0)
1647 exit (1);
1648 unset_TZ ();
1649 if (localtime (&now)->tm_hour != hour_unset)
1650 exit (1);
1651 exit (0);
1652 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
1653 [# If we have tzset, assume the worst when cross-compiling.
1654 emacs_cv_localtime_cache=yes])
1655 else
1656 # If we lack tzset, report that localtime does not cache TZ,
1657 # since we can't invalidate the cache if we don't have tzset.
1658 emacs_cv_localtime_cache=no
1659 fi])dnl
1660 AC_MSG_RESULT($emacs_cv_localtime_cache)
1661 if test $emacs_cv_localtime_cache = yes; then
1662 AC_DEFINE(LOCALTIME_CACHE)
1663 fi
1664
1665 if test "x$HAVE_TIMEVAL" = xyes; then
1666 AC_MSG_CHECKING(whether gettimeofday can accept two arguments)
1667 AC_TRY_LINK([
1668 #ifdef TIME_WITH_SYS_TIME
1669 #include <sys/time.h>
1670 #include <time.h>
1671 #else
1672 #ifdef HAVE_SYS_TIME_H
1673 #include <sys/time.h>
1674 #else
1675 #include <time.h>
1676 #endif
1677 #endif
1678 ],
1679 [
1680 struct timeval time;
1681 struct timezone dummy;
1682 gettimeofday (&time, &dummy);
1683 ],
1684 [AC_MSG_RESULT(yes)],
1685 [AC_MSG_RESULT(no)
1686 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)])
1687 fi
1688
1689 ok_so_far=yes
1690 AC_CHECK_FUNC(socket, , ok_so_far=no)
1691 if test $ok_so_far = yes; then
1692 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1693 fi
1694 if test $ok_so_far = yes; then
1695 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1696 fi
1697 if test $ok_so_far = yes; then
1698 AC_DEFINE(HAVE_INET_SOCKETS)
1699 fi
1700
1701 if test -f /usr/lpp/X11/bin/smt.exp; then
1702 AC_DEFINE(HAVE_AIX_SMT_EXP)
1703 fi
1704
1705 # Set up the CFLAGS for real compilation, so we can substitute it.
1706 CFLAGS="$REAL_CFLAGS"
1707
1708 changequote(, )dnl
1709 #### Find out which version of Emacs this is.
1710 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
1711 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1712 changequote([, ])dnl
1713 if test x"${version}" = x; then
1714 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1715 fi
1716
1717 ### Specify what sort of things we'll be editing into Makefile and config.h.
1718 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1719 AC_SUBST(version)
1720 AC_SUBST(configuration)
1721 AC_SUBST(canonical)
1722 AC_SUBST(srcdir)
1723 AC_SUBST(prefix)
1724 AC_SUBST(exec_prefix)
1725 AC_SUBST(bindir)
1726 AC_SUBST(datadir)
1727 AC_SUBST(sharedstatedir)
1728 AC_SUBST(libexecdir)
1729 AC_SUBST(mandir)
1730 AC_SUBST(infodir)
1731 AC_SUBST(lispdir)
1732 AC_SUBST(locallisppath)
1733 AC_SUBST(lisppath)
1734 AC_SUBST(x_default_search_path)
1735 AC_SUBST(etcdir)
1736 AC_SUBST(archlibdir)
1737 AC_SUBST(docdir)
1738 AC_SUBST(bitmapdir)
1739 AC_SUBST(c_switch_system)
1740 AC_SUBST(c_switch_machine)
1741 AC_SUBST(LD_SWITCH_X_SITE)
1742 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1743 AC_SUBST(C_SWITCH_X_SITE)
1744 AC_SUBST(CFLAGS)
1745 AC_SUBST(X_TOOLKIT_TYPE)
1746 AC_SUBST(machfile)
1747 AC_SUBST(opsysfile)
1748 AC_SUBST(RANLIB)
1749
1750 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}")
1751 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1752 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}")
1753 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1754 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1755 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1756 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE})
1757 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC})
1758
1759 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1760 AC_DEFINE(HAVE_X_WINDOWS)
1761 fi
1762 if test "${USE_X_TOOLKIT}" != "none" ; then
1763 AC_DEFINE(USE_X_TOOLKIT)
1764 fi
1765 if test "${HAVE_X11}" = "yes" ; then
1766 AC_DEFINE(HAVE_X11)
1767 fi
1768 if test "${HAVE_XFREE386}" = "yes" ; then
1769 AC_DEFINE(HAVE_XFREE386)
1770 fi
1771 if test "${HAVE_MENUS}" = "yes" ; then
1772 AC_DEFINE(HAVE_MENUS)
1773 fi
1774 if test "${GNU_MALLOC}" = "yes" ; then
1775 AC_DEFINE(GNU_MALLOC)
1776 fi
1777 if test "${REL_ALLOC}" = "yes" ; then
1778 AC_DEFINE(REL_ALLOC)
1779 fi
1780 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1781 AC_DEFINE(LISP_FLOAT_TYPE)
1782 fi
1783
1784 #### Report on what we decided to do.
1785 echo "
1786 Configured for \`${canonical}'.
1787
1788 Where should the build process find the source code? ${srcdir}
1789 What operating system and machine description files should Emacs use?
1790 \`${opsysfile}' and \`${machfile}'
1791 What compiler should emacs be built with? ${CC} ${CFLAGS}
1792 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
1793 Should Emacs use the relocating allocator for buffers? ${REL_ALLOC}
1794 What window system should Emacs use? ${window_system}
1795 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
1796
1797 if test -n "${x_includes}"; then
1798 echo " Where do we find X Windows header files? ${x_includes}"
1799 else
1800 echo " Where do we find X Windows header files? Standard dirs"
1801 fi
1802 if test -n "${x_libraries}"; then
1803 echo " Where do we find X Windows libraries? ${x_libraries}"
1804 else
1805 echo " Where do we find X Windows libraries? Standard dirs"
1806 fi
1807
1808 echo
1809
1810 # Remove any trailing slashes in these variables.
1811 changequote(, )dnl
1812 test "${prefix}" != NONE &&
1813 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1814 test "${exec_prefix}" != NONE &&
1815 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1816 changequote([, ])dnl
1817
1818 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
1819 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
1820 leim/Makefile, [
1821
1822 ### Make the necessary directories, if they don't exist.
1823 for dir in cpp etc lisp ; do
1824 test -d ${dir} || mkdir ${dir}
1825 done
1826
1827 # Build src/Makefile from ${srcdir}/src/Makefile.c
1828 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
1829 # This must be done after src/config.h is built, since we rely on that file.
1830
1831 changequote(, )dnl The horror, the horror.
1832 # Now get this: Some word that is part of the ${srcdir} directory name
1833 # or the ${configuration} value might, just might, happen to be an
1834 # identifier like `sun4' or `i386' or something, and be predefined by
1835 # the C preprocessor to some helpful value like 1, or maybe the empty
1836 # string. Needless to say consequent macro substitutions are less
1837 # than conducive to the makefile finding the correct directory.
1838 undefs="`echo $top_srcdir $configuration $canonical |
1839 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
1840 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1841 `"
1842 changequote([, ])dnl
1843
1844 echo creating src/paths.h
1845 make paths-force
1846
1847 echo creating lib-src/Makefile
1848 ( cd lib-src
1849 rm -f junk.c junk1.c junk2.c
1850 sed -e '/start of cpp stuff/q' \
1851 < Makefile.c > junk1.c
1852 sed -e '1,/start of cpp stuff/d'\
1853 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1854 < Makefile.c > junk.c
1855 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1856 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
1857 cat junk1.c junk2.c > Makefile.new
1858 rm -f junk.c junk1.c junk2.c
1859 chmod 444 Makefile.new
1860 mv -f Makefile.new Makefile
1861 )
1862
1863 echo creating src/Makefile
1864 ( cd src
1865 rm -f junk.c junk1.c junk2.c
1866 sed -e '/start of cpp stuff/q' \
1867 < Makefile.c > junk1.c
1868 sed -e '1,/start of cpp stuff/d'\
1869 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1870 < Makefile.c > junk.c
1871 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1872 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
1873 cat junk1.c junk2.c > Makefile.new
1874 rm -f junk.c junk1.c junk2.c
1875 chmod 444 Makefile.new
1876 mv -f Makefile.new Makefile
1877 )
1878
1879 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
1880 echo creating src/.gdbinit
1881 echo source $top_srcdir/src/.gdbinit > src/.gdbinit
1882 fi
1883
1884 # This is how we know whether to re-run configure in certain cases.
1885 touch src/config.stamp
1886
1887 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])