code.delx.au - gnu-emacs/blob - lisp/uniquify.el

   1 ;;; uniquify.el --- unique buffer names dependent on file name
   2
   3 ;; Copyright (c) 1989, 1995, 1996, 1997, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Dick King <king@reasoning.com>
   6 ;; Maintainer: FSF
   7 ;; Keywords: files
   8 ;; Created: 15 May 86
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Emacs's standard method for making buffer names unique adds <2>, <3>,
  30 ;; etc. to the end of (all but one of) the buffers.  This file replaces
  31 ;; that behavior, for buffers visiting files and dired buffers, with a
  32 ;; uniquification that adds parts of the file name until the buffer names
  33 ;; are unique.  For instance, buffers visiting /u/mernst/tmp/Makefile and
  34 ;; /usr/projects/zaphod/Makefile would be named Makefile|tmp and
  35 ;; Makefile|zaphod, respectively (instead of Makefile and Makefile<2>).
  36 ;; Other buffer name styles are also available.
  37
  38 ;; To use this file, do (require 'uniquify)
  39 ;; and set uniquify-buffer-name-style to one of its non-nil alternative values.
  40
  41 ;; For other options, see "User-visible variables", below.
  42
  43 ;; A version of uniquify.el that works under Emacs 18, Emacs 19, XEmacs,
  44 ;; and InfoDock is available from the maintainer.
  45
  46 ;;; Change Log:
  47
  48 ;; Originally by Dick King <king@reasoning.com> 15 May 86
  49 ;; Converted for Emacs 18 by Stephen Gildea <gildea@stop.mail-abuse.org>
  50 ;; Make uniquify-min-dir-content 0 truly non-invasive.  gildea 23 May 89
  51 ;; Some cleanup.  uniquify-min-dir-content default 0.  gildea 01 Jun 89
  52 ;; Don't rename to "".  Michael Ernst <mernst@theory.lcs.mit.edu> 15 Jun 94
  53 ;; Add kill-buffer-hook.  Kenneth Manheimer <ken.manheimer@nist.gov> 09 May 95
  54 ;; Add advice for rename-buffer and create-file-buffer, handle dired buffers,
  55 ;;  kill-buffer-rationalize-buffer-names-p, documentation.  mernst 24 May 95
  56 ;; Remove free variables, fix typos.  mernst 5 Jun 95
  57 ;; Efficiently support Emacs 19.27 & earlier.  ken.manheimer, mernst 10 Jun 95
  58 ;; Rename user options to "uniquify-...", add uniquify-reverse-dir-content-p,
  59 ;;  add uniquify-ask-about-buffer-names-p.  king, mernst 13 Jun 95
  60 ;; Prefix functions by "uniquify-..."; rename mnemonic-buffer-names to
  61 ;;  uniquify-buffer-name-style; add 'forward and 'post-forward-angle-brackets
  62 ;;  styles; remove uniquify-reverse-dir-content-p; add
  63 ;;  uniquify-trailing-separator-p.  mernst 4 Aug 95
  64 ;; Don't call expand-file-name on nil.  mernst 7 Jan 96
  65 ;; Check whether list-buffers-directory is bound.  mernst 11 Oct 96
  66 ;; Ignore non-file non-dired buffers. Colin Rafferty <craffert@ml.com> 3 Mar 97
  67 ;; Use last component, not "", for file name of directories.  mernst 27 Jun 97
  68 ;; Use directory-file-name; code cleanup.  mernst 6 Sep 97
  69 ;; Add uniquify-ignore-buffers-re.
  70 ;;  Andre Srinivasan <andre@visigenic.com> 9 Sep 97
  71 ;; Add uniquify-list-buffers-directory-modes
  72 ;;   Stefan Monnier <monnier@cs.yale.edu> 17 Nov 2000
  73 ;; Algorithm and data structure changed to reduce consing with lots of buffers
  74 ;;   Francesco Potortì <pot@gnu.org> (ideas by rms and monnier) 2001-07-18
  75
  76 ;; Valuable feedback was provided by
  77 ;; Paul Smith <psmith@baynetworks.com>,
  78 ;; Alastair Burt <burt@dfki.uni-kl.de>,
  79 ;; Bob Weiner <weiner@footloose.sps.mot.com>,
  80 ;; Albert L. Ting <alt@vlibs.com>,
  81 ;; gyro@reasoning.com,
  82 ;; Bryan O'Sullivan <bos@eng.sun.com>.
  83
  84
  85 ;;; Code:
  86
  87 (provide 'uniquify)
  88 (eval-when-compile (require 'cl))
  89
  90 ;;; User-visible variables
  91
  92 (defgroup uniquify nil
  93   "Unique buffer names dependent on file name"
  94   :group 'applications)
  95
  96
  97 (defcustom uniquify-buffer-name-style nil
  98   "*If non-nil, buffer names are uniquified with parts of directory name.
  99 The value determines the buffer name style and is one of `forward',
 100 `reverse', `post-forward', or `post-forward-angle-brackets'.
 101 For example, files `/foo/bar/mumble/name' and `/baz/quux/mumble/name'
 102 would have the following buffer names in the various styles:
 103   forward        bar/mumble/name  quux/mumble/name
 104   reverse        name\\mumble\\bar  name\\mumble\\quux
 105   post-forward   name|bar/mumble  name|quux/mumble
 106   post-forward-angle-brackets   name<bar/mumble>  name<quux/mumble>
 107   nil            name  name<2>"
 108   :type '(radio (const forward)
 109                 (const reverse)
 110                 (const post-forward)
 111                 (const post-forward-angle-brackets)
 112                 (const :tag "standard Emacs behavior (nil)" nil))
 113   :require 'uniquify
 114   :group 'uniquify)
 115
 116 (defcustom uniquify-after-kill-buffer-p nil
 117   "*If non-nil, rerationalize buffer names after a buffer has been killed.
 118 This can be dangerous if Emacs Lisp code is keeping track of buffers by their
 119 names (rather than keeping pointers to the buffers themselves)."
 120   :type 'boolean
 121   :group 'uniquify)
 122
 123 (defcustom uniquify-ask-about-buffer-names-p nil
 124   "*If non-nil, permit user to choose names for buffers with same base file.
 125 If the user chooses to name a buffer, uniquification is preempted and no
 126 other buffer names are changed."
 127   :type 'boolean
 128   :group 'uniquify)
 129
 130 (defcustom uniquify-ignore-buffers-re nil
 131   "*Regular expression matching buffer names that should not be uniquified.
 132 For instance, set this to \"^draft-[0-9]+$\" to avoid having uniquify rename
 133 draft buffers even if `uniquify-after-kill-buffer-p' is non-nil and the
 134 visited file name isn't the same as that of the buffer."
 135   :type '(choice (const :tag "Uniquify all buffers" nil) regexp)
 136   :group 'uniquify)
 137
 138 (defcustom uniquify-min-dir-content 0
 139   "*Minimum number of directory name components included in buffer name."
 140   :type 'integer
 141   :group 'uniquify)
 142
 143 (defcustom uniquify-separator nil
 144   "*String separator for buffer name components.
 145 When `uniquify-buffer-name-style' is `post-forward', separates
 146 base file name from directory part in buffer names (default \"|\").
 147 When `uniquify-buffer-name-style' is `reverse', separates all
 148 file name components (default \"\\\")."
 149   :type '(choice (const nil) string)
 150   :group 'uniquify)
 151
 152 (defcustom uniquify-trailing-separator-p nil
 153   "*If non-nil, add a file name separator to dired buffer names.
 154 If `uniquify-buffer-name-style' is `forward', add the separator at the end;
 155 if it is `reverse', add the separator at the beginning; otherwise, this
 156 variable is ignored."
 157   :type 'boolean
 158   :group 'uniquify)
 159
 160 (defvar uniquify-list-buffers-directory-modes '(dired-mode cvs-mode)
 161   "List of modes for which uniquify should obey `list-buffers-directory'.
 162 That means that when `buffer-file-name' is set to nil, `list-buffers-directory'
 163 contains the name of the directory which the buffer is visiting.")
 164
 165 ;;; Utilities
 166
 167 ;; For directories, return the last component, not the empty string.
 168 (defun uniquify-file-name-nondirectory (file-name)
 169   (file-name-nondirectory (directory-file-name file-name)))
 170
 171 ;; uniquify-fix-list data structure
 172 (defsubst uniquify-ref-base (x) (aref x 0))
 173 (defsubst uniquify-ref-filename (x) (aref x 1))
 174 (defsubst uniquify-ref-buffer (x) (aref x 2))
 175 (defsubst uniquify-ref-proposed (x) (aref x 3))
 176 (defsubst uniquify-set-proposed (x p) (aset x 3 p))
 177
 178 ;; Internal variables used free
 179 (defvar uniquify-non-file-buffer-names nil)
 180 (defvar uniquify-possibly-resolvable nil)
 181
 182 ;;; Main entry point.
 183
 184 (defun uniquify-rationalize-file-buffer-names (&optional newbuffile newbuf)
 185   "Make file buffer names unique by adding segments from file name.
 186 If `uniquify-min-dir-content' > 0, always pulls that many
 187 file name elements.  Arguments cause only a subset of buffers to be renamed."
 188   (interactive)
 189   (let (fix-list
 190         uniquify-non-file-buffer-names
 191         (newbuffile-nd (and newbuffile
 192                             (uniquify-file-name-nondirectory newbuffile))))
 193     (dolist (buffer (buffer-list))
 194       (let ((bufname (buffer-name buffer))
 195             bfn rawname proposed)
 196         (if (and (not (and uniquify-ignore-buffers-re
 197                            (string-match uniquify-ignore-buffers-re
 198                                          bufname)))
 199                  (setq bfn (if (eq buffer newbuf)
 200                                (when newbuffile
 201                                  (expand-file-name
 202                                   (if (file-directory-p newbuffile)
 203                                       (directory-file-name newbuffile)
 204                                     newbuffile)))
 205                              (uniquify-buffer-file-name buffer)))
 206                  (setq rawname (uniquify-file-name-nondirectory bfn))
 207                  (or (not newbuffile)
 208                      (equal rawname newbuffile-nd))
 209                  (setq proposed (uniquify-get-proposed-name
 210                                  rawname bfn uniquify-min-dir-content)))
 211             (push (vector rawname bfn buffer proposed) fix-list)
 212           (push bufname uniquify-non-file-buffer-names))))
 213     ;; selects buffers whose names may need changing, and others that
 214     ;; may conflict, then bring conflicting names together
 215     (uniquify-rationalize-a-list fix-list uniquify-min-dir-content)))
 216
 217 ;; uniquify's version of buffer-file-name; result never contains trailing slash
 218 (defun uniquify-buffer-file-name (buffer)
 219   "Return name of file BUFFER is visiting, or nil if none.
 220 Works on ordinary file-visiting buffers and buffers whose mode is mentioned
 221 in `uniquify-list-buffers-directory-modes', otherwise returns nil."
 222   (or (buffer-file-name buffer)
 223       (with-current-buffer buffer
 224         (and
 225          (memq major-mode uniquify-list-buffers-directory-modes)
 226          (if (boundp 'list-buffers-directory) ; XEmacs mightn't define this
 227              (and list-buffers-directory
 228                   (directory-file-name list-buffers-directory))
 229            ;; don't use default-directory if dired-directory is nil
 230            (and dired-directory
 231                 (expand-file-name
 232                  (directory-file-name
 233                   (if (consp dired-directory)
 234                       (car dired-directory)
 235                     dired-directory)))))))))
 236
 237 (defun uniquify-item-greaterp (item1 item2)
 238   (string-lessp (uniquify-ref-proposed item2)
 239                 (uniquify-ref-proposed item1)))
 240
 241 (defun uniquify-rationalize-a-list (fix-list depth)
 242   (let (conflicting-sublist     ; all elements have the same proposed name
 243         (old-proposed "")
 244         proposed)
 245     (dolist (item (sort fix-list 'uniquify-item-greaterp))
 246       (setq proposed (uniquify-ref-proposed item))
 247       (unless (equal proposed old-proposed)
 248         (uniquify-rationalize-conflicting-sublist conflicting-sublist
 249                                                   old-proposed depth)
 250         (setq conflicting-sublist nil))
 251       (push item conflicting-sublist)
 252       (setq old-proposed proposed))
 253     (uniquify-rationalize-conflicting-sublist conflicting-sublist
 254                                               old-proposed depth)))
 255
 256 (defun uniquify-get-proposed-name (base filename depth)
 257   (assert (equal base (uniquify-file-name-nondirectory filename)))
 258   (assert (equal (directory-file-name filename) filename))
 259
 260   ;; Distinguish directories by adding extra separator.
 261   (if (and uniquify-trailing-separator-p
 262            (file-directory-p filename)
 263            (not (string-equal base "")))
 264       (cond ((eq uniquify-buffer-name-style 'forward)
 265              (setq base (file-name-as-directory base)))
 266             ;; (setq base (concat base "/")))
 267             ((eq uniquify-buffer-name-style 'reverse)
 268              (setq base (concat (or uniquify-separator "\\") base)))))
 269
 270   (let ((extra-string nil)
 271         (n depth))
 272     (while (and (> n 0) filename
 273                 (setq filename (file-name-directory filename))
 274                 (setq filename (directory-file-name filename)))
 275       (let ((file (file-name-nondirectory filename)))
 276         (setq n (1- n))
 277         (push (if (zerop (length file)) ;nil or "".
 278                   (prog1 "" (setq filename nil)) ;Could be `filename' iso "".
 279                 file)
 280               extra-string)))
 281     (when (zerop n)
 282       (if (and filename extra-string
 283                (setq filename (file-name-directory filename))
 284                (equal filename
 285                       (file-name-directory (directory-file-name filename))))
 286           ;; We're just before the root.  Let's add the leading / already.
 287           ;; With "/a/b"+"/c/d/b" this leads to "/a/b" and "d/b" but with
 288           ;; "/a/b"+"/c/a/b" this leads to "/a/b" and "a/b".
 289           (push "" extra-string))
 290       (setq uniquify-possibly-resolvable t))
 291
 292     (cond
 293      ((null extra-string) base)
 294      ((string-equal base "") ;Happens for dired buffers on the root directory.
 295       (mapconcat 'identity extra-string (string directory-sep-char)))
 296      ((eq uniquify-buffer-name-style 'reverse)
 297       (let ((dirsep (string directory-sep-char)))
 298         (mapconcat 'identity
 299                    (cons base (nreverse extra-string))
 300                    (or uniquify-separator "\\"))))
 301      ((eq uniquify-buffer-name-style 'forward)
 302       (mapconcat 'identity (nconc extra-string (list base))
 303                  (string directory-sep-char)))
 304      ((eq uniquify-buffer-name-style 'post-forward)
 305       (concat base (or uniquify-separator "|")
 306               (mapconcat 'identity extra-string (string directory-sep-char))))
 307      ((eq uniquify-buffer-name-style 'post-forward-angle-brackets)
 308       (concat base "<" (mapconcat 'identity extra-string
 309                                   (string directory-sep-char)) ">"))
 310      (t (error "Bad value for uniquify-buffer-name-style: %s"
 311                uniquify-buffer-name-style)))))
 312
 313
 314 ;; Deal with conflicting-sublist, all of whose elements have identical
 315 ;; "base" components.
 316 (defun uniquify-rationalize-conflicting-sublist (conf-list old-name depth)
 317   (when conf-list
 318     (if (or (cdr conf-list)
 319             (member old-name uniquify-non-file-buffer-names))
 320         (when uniquify-possibly-resolvable
 321           (setq uniquify-possibly-resolvable nil
 322                 depth (1+ depth))
 323           (dolist (item conf-list)
 324             (uniquify-set-proposed item (uniquify-get-proposed-name
 325                                          (uniquify-ref-base item)
 326                                          (uniquify-ref-filename item)
 327                                          depth)))
 328           (uniquify-rationalize-a-list conf-list depth))
 329       (unless (string= old-name "")
 330         (uniquify-rename-buffer (car conf-list) old-name)))))
 331
 332
 333 (defun uniquify-rename-buffer (item newname)
 334   (let ((buffer (uniquify-ref-buffer item)))
 335     (unless (equal newname (buffer-name buffer))
 336       (let ((unset (current-buffer))
 337             ;; avoid hooks on rename-buffer
 338             (uniquify-buffer-name-style nil))
 339         (set-buffer buffer)
 340         (rename-buffer newname)
 341         (set-buffer unset)))))
 342
 343 ;;; Hooks from the rest of Emacs
 344
 345 ;; The logical place to put all this code is in generate-new-buffer-name.
 346 ;; It's written in C, so we would add a generate-new-buffer-name-function
 347 ;; which, if non-nil, would be called instead of the C.  One problem with
 348 ;; that is that generate-new-buffer-name takes a potential buffer name as
 349 ;; its argument -- not other information, such as what file the buffer will
 350 ;; visit.
 351
 352 ;; The below solution works because generate-new-buffer-name is called
 353 ;; only by rename-buffer (which, as of 19.29, is never called from C) and
 354 ;; generate-new-buffer, which is called only by Lisp functions
 355 ;; create-file-buffer and rename-uniquely.  Rename-uniquely generally
 356 ;; isn't used for buffers visiting files, so it's sufficient to hook
 357 ;; rename-buffer and create-file-buffer.  (Setting find-file-hooks isn't
 358 ;; sufficient.)
 359
 360 (defadvice rename-buffer (after rename-buffer-uniquify activate)
 361   "Uniquify buffer names with parts of directory name."
 362   (if (and uniquify-buffer-name-style
 363            ;; UNIQUE argument
 364            (ad-get-arg 1))
 365       (progn
 366         (if uniquify-after-kill-buffer-p
 367             ;; call with no argument; rationalize vs. old name as well as new
 368             (uniquify-rationalize-file-buffer-names)
 369           ;; call with argument: rationalize vs. new name only
 370           (uniquify-rationalize-file-buffer-names
 371            (uniquify-buffer-file-name (current-buffer)) (current-buffer)))
 372         (setq ad-return-value (buffer-name (current-buffer))))))
 373
 374 (defadvice create-file-buffer (after create-file-buffer-uniquify activate)
 375   "Uniquify buffer names with parts of directory name."
 376   (if uniquify-buffer-name-style
 377       (uniquify-rationalize-file-buffer-names (ad-get-arg 0) ad-return-value)))
 378
 379 ;; Buffer deletion
 380 ;; Rerationalize after a buffer is killed, to reduce coinciding buffer names.
 381 ;; This mechanism uses `kill-buffer-hook', which runs *before* deletion.
 382 ;; That means that the kill-buffer-hook function cannot just delete the
 383 ;; buffer -- it has to set something to do the rationalization *later*.
 384 ;; It actually puts another function on `post-command-hook'.  This other
 385 ;; function runs the rationalization and then removes itself from the hook.
 386 ;; Is there a better way to accomplish this?
 387 ;; (This ought to set some global variables so the work is done only for
 388 ;; buffers with names similar to the deleted buffer.  -MDE)
 389
 390 (defun delay-uniquify-rationalize-file-buffer-names ()
 391   "Add `delayed-uniquify-rationalize-file-buffer-names' to `post-command-hook'.
 392 For use on, eg, `kill-buffer-hook', to rationalize *after* buffer deletion."
 393   (if (and uniquify-buffer-name-style
 394            uniquify-after-kill-buffer-p)
 395       (add-hook 'post-command-hook
 396                 'delayed-uniquify-rationalize-file-buffer-names)))
 397
 398 (defun delayed-uniquify-rationalize-file-buffer-names ()
 399   "Rerationalize buffer names and remove self from `post-command-hook'.
 400 See also `delay-rationalize-file-buffer-names' for hook setter."
 401   (uniquify-rationalize-file-buffer-names)
 402   (remove-hook 'post-command-hook
 403                'delayed-uniquify-rationalize-file-buffer-names))
 404
 405 (add-hook 'kill-buffer-hook 'delay-uniquify-rationalize-file-buffer-names)
 406
 407 ;;; uniquify.el ends here