code.delx.au - gnu-emacs/blob - lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Gerd Moellmann <gerd@acm.org>
   7 ;; Keywords: help c mouse tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl)) ; for case macro
  31
  32 \f
  33 ;;; Customizable settings
  34
  35 (defgroup tooltip nil
  36   "Customization group for the `tooltip' package."
  37   :group 'help
  38   :group 'gud
  39   :group 'mouse
  40   :group 'tools
  41   :version "21.1"
  42   :tag "Tool Tips")
  43
  44 (defcustom tooltip-delay 0.7
  45   "Seconds to wait before displaying a tooltip the first time."
  46   :tag "Delay"
  47   :type 'number
  48   :group 'tooltip)
  49
  50 (defcustom tooltip-short-delay 0.1
  51   "Seconds to wait between subsequent tooltips on different items."
  52   :tag "Short delay"
  53   :type 'number
  54   :group 'tooltip)
  55
  56 (defcustom tooltip-recent-seconds 1
  57   "Display tooltips if changing tip items within this many seconds.
  58 Do so after `tooltip-short-delay'."
  59   :tag "Recent seconds"
  60   :type 'number
  61   :group 'tooltip)
  62
  63 (defcustom tooltip-hide-delay 10
  64   "Hide tooltips automatically after this many seconds."
  65   :tag "Hide delay"
  66   :type 'number
  67   :group 'tooltip)
  68
  69 (defcustom tooltip-x-offset nil
  70   "X offset, in pixels, for the display of tooltips.
  71 The offset is relative to the position of the mouse.  It must
  72 be chosen so that the tooltip window doesn't contain the mouse
  73 when it pops up.  If the value is nil, the default offset is 5
  74 pixels.
  75
  76 If `tooltip-frame-parameters' includes the `left' parameter,
  77 the value of `tooltip-x-offset' is ignored."
  78   :tag "X offset"
  79   :type '(choice (const :tag "Default" nil)
  80                  (integer :tag "Offset" :value 1))
  81   :group 'tooltip)
  82
  83 (defcustom tooltip-y-offset nil
  84   "Y offset, in pixels, for the display of tooltips.
  85 The offset is relative to the position of the mouse.  It must
  86 be chosen so that the tooltip window doesn't contain the mouse
  87 when it pops up.  If the value is nil, the default offset is -10
  88 pixels.
  89
  90 If `tooltip-frame-parameters' includes the `top' parameter,
  91 the value of `tooltip-y-offset' is ignored."
  92   :tag "Y offset"
  93   :type '(choice (const :tag "Default" nil)
  94                  (integer :tag "Offset" :value 1))
  95   :group 'tooltip)
  96
  97 (defcustom tooltip-frame-parameters
  98   '((name . "tooltip")
  99     (internal-border-width . 5)
 100     (border-width . 1))
 101   "Frame parameters used for tooltips.
 102
 103 If `left' or `top' parameters are included, they specify the absolute
 104 position to pop up the tooltip."
 105   :type 'sexp
 106   :tag "Frame Parameters"
 107   :group 'tooltip)
 108
 109 (defface tooltip
 110   '((((class color))
 111      :background "lightyellow"
 112      :foreground "black"
 113      :inherit variable-pitch)
 114     (t
 115      :inherit variable-pitch))
 116   "Face for tooltips."
 117   :group 'tooltip)
 118
 119 (defcustom tooltip-gud-tips-p nil
 120   "*Non-nil means show tooltips in GUD sessions."
 121   :type 'boolean
 122   :tag "GUD"
 123   :group 'tooltip)
 124
 125 (defcustom tooltip-gud-modes '(gud-mode c-mode c++-mode fortran-mode)
 126   "List of modes for which to enable GUD tips."
 127   :type 'sexp
 128   :tag "GUD modes"
 129   :group 'tooltip)
 130
 131 (defcustom tooltip-gud-display
 132   '((eq (tooltip-event-buffer tooltip-gud-event)
 133         (marker-buffer overlay-arrow-position)))
 134   "List of forms determining where GUD tooltips are displayed.
 135
 136 Forms in the list are combined with AND.  The default is to display
 137 only tooltips in the buffer containing the overlay arrow."
 138   :type 'sexp
 139   :tag "GUD buffers predicate"
 140   :group 'tooltip)
 141
 142 (defcustom tooltip-use-echo-area nil
 143   "Use the echo area instead of tooltip frames.
 144 This is only relevant GUD display, since otherwise it is equivalent to
 145 turning off Tooltip mode."
 146   :type 'boolean
 147   :tag "Use echo area"
 148   :group 'tooltip)
 149
 150 \f
 151 ;;; Variables that are not customizable.
 152
 153 (defvar tooltip-hook nil
 154   "Functions to call to display tooltips.
 155 Each function is called with one argument EVENT which is a copy of
 156 the last mouse movement event that occurred.")
 157
 158 (defvar tooltip-timeout-id nil
 159   "The id of the timeout started when Emacs becomes idle.")
 160
 161 (defvar tooltip-last-mouse-motion-event nil
 162   "A copy of the last mouse motion event seen.")
 163
 164 (defvar tooltip-hide-time nil
 165   "Time when the last tooltip was hidden.")
 166
 167 \f
 168 ;;; Event accessors
 169
 170 (defun tooltip-event-buffer (event)
 171   "Return the buffer over which event EVENT occurred.
 172 This might return nil if the event did not occur over a buffer."
 173   (let ((window (posn-window (event-end event))))
 174     (and window (window-buffer window))))
 175
 176 \f
 177 ;;; Switching tooltips on/off
 178
 179 ;; We don't set track-mouse globally because this is a big redisplay
 180 ;; problem in buffers having a pre-command-hook or such installed,
 181 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
 182 ;; set-buffer prevents redisplay optimizations, so every mouse motion
 183 ;; would be accompanied by a full redisplay.
 184
 185 ;;;###autoload
 186 (define-minor-mode tooltip-mode
 187   "Toggle Tooltip display.
 188 With ARG, turn tooltip mode on if and only if ARG is positive."
 189   :global t
 190   :group 'tooltip
 191   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
 192     (error "Sorry, tooltips are not yet available on this system"))
 193   (let ((hook-fn (if tooltip-mode 'add-hook 'remove-hook)))
 194     (funcall hook-fn 'change-major-mode-hook 'tooltip-change-major-mode)
 195     (tooltip-activate-mouse-motions-if-enabled)
 196     (funcall hook-fn 'pre-command-hook 'tooltip-hide)
 197     (funcall hook-fn 'tooltip-hook 'tooltip-gud-tips)
 198     (funcall hook-fn 'tooltip-hook 'tooltip-help-tips)
 199     (setq show-help-function (if tooltip-mode 'tooltip-show-help-function nil))
 200     ;; `ignore' is the default binding for mouse movements.
 201     (define-key global-map [mouse-movement]
 202       (if tooltip-mode 'tooltip-mouse-motion 'ignore))))
 203
 204 \f
 205 ;;; Timeout for tooltip display
 206
 207 (defun tooltip-delay ()
 208   "Return the delay in seconds for the next tooltip."
 209   (let ((delay tooltip-delay)
 210         (now (float-time)))
 211     (when (and tooltip-hide-time
 212                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 213       (setq delay tooltip-short-delay))
 214     delay))
 215
 216 (defun tooltip-cancel-delayed-tip ()
 217   "Disable the tooltip timeout."
 218   (when tooltip-timeout-id
 219     (disable-timeout tooltip-timeout-id)
 220     (setq tooltip-timeout-id nil)))
 221
 222 (defun tooltip-start-delayed-tip ()
 223   "Add a one-shot timeout to call function tooltip-timeout."
 224   (setq tooltip-timeout-id
 225         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 226
 227 (defun tooltip-timeout (object)
 228   "Function called when timer with id tooltip-timeout-id fires."
 229   (run-hook-with-args-until-success 'tooltip-hook
 230                                     tooltip-last-mouse-motion-event))
 231
 232 \f
 233 ;;; Reacting on mouse movements
 234
 235 (defun tooltip-change-major-mode ()
 236   "Function added to `change-major-mode-hook' when tooltip mode is on."
 237   (add-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled))
 238
 239 (defun tooltip-activate-mouse-motions-if-enabled ()
 240   "Reconsider for all buffers whether mouse motion events are desired."
 241   (remove-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled)
 242   (dolist (buffer (buffer-list))
 243     (save-excursion
 244       (set-buffer buffer)
 245       (if (and tooltip-mode
 246                tooltip-gud-tips-p
 247                (memq major-mode tooltip-gud-modes))
 248           (tooltip-activate-mouse-motions t)
 249         (tooltip-activate-mouse-motions nil)))))
 250
 251 (defvar tooltip-mouse-motions-active nil
 252   "Locally t in a buffer if tooltip processing of mouse motion is enabled.")
 253
 254 (defun tooltip-activate-mouse-motions (activatep)
 255   "Activate/deactivate mouse motion events for the current buffer.
 256 ACTIVATEP non-nil means activate mouse motion events."
 257   (if activatep
 258       (progn
 259         (make-local-variable 'tooltip-mouse-motions-active)
 260         (setq tooltip-mouse-motions-active t)
 261         (make-local-variable 'track-mouse)
 262         (setq track-mouse t))
 263     (when tooltip-mouse-motions-active
 264       (kill-local-variable 'tooltip-mouse-motions-active)
 265       (kill-local-variable 'track-mouse))))
 266
 267 (defun tooltip-mouse-motion (event)
 268   "Command handler for mouse movement events in `global-map'."
 269   (interactive "e")
 270   (tooltip-hide)
 271   (when (car (mouse-pixel-position))
 272     (setq tooltip-last-mouse-motion-event (copy-sequence event))
 273     (tooltip-start-delayed-tip)))
 274
 275 \f
 276 ;;; Displaying tips
 277
 278 (defun tooltip-set-param (alist key value)
 279   "Change the value of KEY in alist ALIST to VALUE.
 280 If there's no association for KEY in ALIST, add one, otherwise
 281 change the existing association.  Value is the resulting alist."
 282   (let ((param (assq key alist)))
 283     (if (consp param)
 284         (setcdr param value)
 285       (push (cons key value) alist))
 286     alist))
 287
 288 (defun tooltip-show (text)
 289   "Show a tooltip window displaying TEXT.
 290
 291 Text larger than `x-max-tooltip-size' (which see) is clipped.
 292
 293 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 294 parameters, they determine the x and y position where the tooltip
 295 is displayed.  Otherwise, the tooltip pops at offsets specified by
 296 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 297 position."
 298   (if tooltip-use-echo-area
 299       (message "%s" text)
 300     (condition-case error
 301         (let ((params (copy-sequence tooltip-frame-parameters))
 302               (fg (face-attribute 'tooltip :foreground))
 303               (bg (face-attribute 'tooltip :background)))
 304           (when (stringp fg)
 305             (setq params (tooltip-set-param params 'foreground-color fg))
 306             (setq params (tooltip-set-param params 'border-color fg)))
 307           (when (stringp bg)
 308             (setq params (tooltip-set-param params 'background-color bg)))
 309           (x-show-tip (propertize text 'face 'tooltip)
 310                       (selected-frame)
 311                       params
 312                       tooltip-hide-delay
 313                       tooltip-x-offset
 314                       tooltip-y-offset))
 315       (error
 316        (message "Error while displaying tooltip: %s" error)
 317        (sit-for 1)
 318        (message "%s" text)))))
 319
 320 (defun tooltip-hide (&optional ignored-arg)
 321   "Hide a tooltip, if one is displayed.
 322 Value is non-nil if tooltip was open."
 323   (tooltip-cancel-delayed-tip)
 324   (when (x-hide-tip)
 325     (setq tooltip-hide-time (float-time))))
 326
 327 \f
 328 ;;; Debugger-related functions
 329
 330 (defun tooltip-identifier-from-point (point)
 331   "Extract the identifier at POINT, if any.
 332 Value is nil if no identifier exists at point.  Identifier extraction
 333 is based on the current syntax table."
 334   (save-excursion
 335     (goto-char point)
 336     (let ((start (progn (skip-syntax-backward "w_") (point))))
 337       (unless (looking-at "[0-9]")
 338         (skip-syntax-forward "w_")
 339         (when (> (point) start)
 340           (buffer-substring start (point)))))))
 341
 342 (defmacro tooltip-region-active-p ()
 343   "Value is non-nil if the region is currently active."
 344   (if (string-match "^GNU" (emacs-version))
 345       `(and transient-mark-mode mark-active)
 346     `(region-active-p)))
 347
 348 (defun tooltip-expr-to-print (event)
 349   "Return an expression that should be printed for EVENT.
 350 If a region is active and the mouse is inside the region, print
 351 the region.  Otherwise, figure out the identifier around the point
 352 where the mouse is."
 353   (save-excursion
 354     (set-buffer (tooltip-event-buffer event))
 355     (let ((point (posn-point (event-end event))))
 356       (if (tooltip-region-active-p)
 357           (when (and (<= (region-beginning) point) (<= point (region-end)))
 358             (buffer-substring (region-beginning) (region-end)))
 359         (tooltip-identifier-from-point point)))))
 360
 361 (defun tooltip-process-prompt-regexp (process)
 362   "Return regexp matching the prompt of PROCESS at the end of a string.
 363 The prompt is taken from the value of COMINT-PROMPT-REGEXP in the buffer
 364 of PROCESS."
 365   (let ((prompt-regexp (save-excursion
 366                          (set-buffer (process-buffer process))
 367                          comint-prompt-regexp)))
 368     ;; Most start with `^' but the one for `sdb' cannot be easily
 369     ;; stripped.  Code the prompt for `sdb' fixed here.
 370     (if (= (aref prompt-regexp 0) ?^)
 371         (setq prompt-regexp (substring prompt-regexp 1))
 372       (setq prompt-regexp "\\*"))
 373     (concat "\n*" prompt-regexp "$")))
 374
 375 (defun tooltip-strip-prompt (process output)
 376   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 377   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 378     (save-match-data
 379       (when (string-match prompt-regexp output)
 380         (setq output (substring output 0 (match-beginning 0)))))
 381     output))
 382
 383 \f
 384 ;;; Tips for `gud'
 385
 386 (defvar tooltip-gud-original-filter nil
 387   "Process filter to restore after GUD output has been received.")
 388
 389 (defvar tooltip-gud-dereference nil
 390   "Non-nil means print expressions with a `*' in front of them.
 391 For C this would dereference a pointer expression.")
 392
 393 (defvar tooltip-gud-event nil
 394   "The mouse movement event that led to a tooltip display.
 395 This event can be examined by forms in TOOLTIP-GUD-DISPLAY.")
 396
 397 (defun tooltip-gud-toggle-dereference ()
 398   "Toggle whether tooltips should show `* expr' or `expr'."
 399   (interactive)
 400   (setq tooltip-gud-dereference (not tooltip-gud-dereference))
 401   (when (interactive-p)
 402     (message "Dereferencing is now %s."
 403              (if tooltip-gud-dereference "on" "off"))))
 404
 405 ; This will only display data that comes in one chunk.
 406 ; Larger arrays (say 400 elements) are displayed in
 407 ; the tootip incompletely and spill over into the gud buffer.
 408 ; Switching the process-filter creates timing problems and
 409 ; it may be difficult to do better. gdba in gdb-ui.el
 410 ; gets round this problem.
 411 (defun tooltip-gud-process-output (process output)
 412   "Process debugger output and show it in a tooltip window."
 413   (set-process-filter process tooltip-gud-original-filter)
 414   (tooltip-show (tooltip-strip-prompt process output)))
 415
 416 (defun tooltip-gud-print-command (expr)
 417   "Return a suitable command to print the expression EXPR.
 418 If TOOLTIP-GUD-DEREFERENCE is t, also prepend a `*' to EXPR."
 419   (when tooltip-gud-dereference
 420     (setq expr (concat "*" expr)))
 421   (case gud-minor-mode
 422     ((gdb gdba) (concat "server print " expr))
 423     (dbx (concat "print " expr))
 424     (xdb (concat "p " expr))
 425     (sdb (concat expr "/"))
 426     (perldb expr)))
 427
 428 (defun tooltip-gud-tips (event)
 429   "Show tip for identifier or selection under the mouse.
 430 The mouse must either point at an identifier or inside a selected
 431 region for the tip window to be shown.  If tooltip-gud-dereference is t,
 432 add a `*' in front of the printed expression.
 433
 434 This function must return nil if it doesn't handle EVENT."
 435   (let (process)
 436     (when (and (eventp event)
 437                tooltip-gud-tips-p
 438                (boundp 'gud-comint-buffer)
 439                (setq process (get-buffer-process gud-comint-buffer))
 440                (posn-point (event-end event))
 441                (progn (setq tooltip-gud-event event)
 442                       (eval (cons 'and tooltip-gud-display))))
 443       (let ((expr (tooltip-expr-to-print event)))
 444         (when expr
 445           (let ((cmd (tooltip-gud-print-command expr)))
 446             (unless (null cmd)         ; CMD can be nil if unknown debugger
 447               (case gud-minor-mode
 448                     (gdba (gdb-enqueue-input
 449                            (list  (concat cmd "\n") 'gdb-tooltip-print)))
 450                     (t
 451                      (setq tooltip-gud-original-filter (process-filter process))
 452                        (set-process-filter process 'tooltip-gud-process-output)
 453                        (gud-basic-call cmd)))
 454                     expr)))))))
 455
 456 (defun gdb-tooltip-print ()
 457   (tooltip-show
 458    (with-current-buffer (gdb-get-buffer 'gdb-partial-output-buffer)
 459      (let ((string (buffer-string)))
 460        ;; remove newline for tooltip-use-echo-area
 461        (substring string 0 (- (length string) 1))))))
 462
 463 \f
 464 ;;; Tooltip help.
 465
 466 (defvar tooltip-help-message nil
 467   "The last help message received via `tooltip-show-help-function'.")
 468
 469 (defun tooltip-show-help-function (msg)
 470   "Function installed as `show-help-function'.
 471 MSG is either a help string to display, or nil to cancel the display."
 472   (let ((previous-help tooltip-help-message)
 473         mp pos)
 474     (if (and mouse-1-click-follows-link
 475              (stringp msg)
 476              (save-match-data
 477                (string-match "^mouse-2" msg))
 478              (setq mp (mouse-pixel-position))
 479              (consp (setq pos (cdr mp)))
 480              (car pos) (cdr pos)
 481              (setq pos (posn-at-x-y (car pos) (cdr pos) (car mp)))
 482              (windowp (posn-window pos)))
 483         (with-current-buffer (window-buffer (posn-window pos))
 484           (if (mouse-on-link-p pos)
 485               (setq msg (concat
 486                     (cond
 487                      ((eq mouse-1-click-follows-link 'double) "double-")
 488                      ((and (integerp mouse-1-click-follows-link)
 489                            (< mouse-1-click-follows-link 0)) "Long ")
 490                      (t ""))
 491                     "mouse-1" (substring msg 7))))))
 492     (setq tooltip-help-message msg)
 493     (cond ((null msg)
 494            ;; Cancel display.  This also cancels a delayed tip, if
 495            ;; there is one.
 496            (tooltip-hide))
 497           ((equal previous-help msg)
 498            ;; Same help as before (but possibly the mouse has moved).
 499            ;; Keep what we have.
 500            )
 501           (t
 502            ;; A different help.  Remove a previous tooltip, and
 503            ;; display a new one, with some delay.
 504            (tooltip-hide)
 505            (tooltip-start-delayed-tip)))))
 506
 507 (defun tooltip-help-tips (event)
 508   "Hook function to display a help tooltip.
 509 This is installed on the hook `tooltip-hook', which is run when
 510 the timer with ID `tooltip-timeout-id' fires.
 511 Value is non-nil if this function handled the tip."
 512   (when (stringp tooltip-help-message)
 513     (tooltip-show tooltip-help-message)
 514     t))
 515
 516 (provide 'tooltip)
 517
 518 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 519 ;;; tooltip.el ends here