code.delx.au - gnu-emacs/blob - lisp/abbrev.el

   1 ;;; abbrev.el --- abbrev mode commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: abbrev convenience
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This facility is documented in the Emacs Manual.
  28
  29 ;;; Code:
  30
  31 (defcustom only-global-abbrevs nil
  32   "Non-nil means user plans to use global abbrevs only.
  33 This makes the commands that normally define mode-specific abbrevs
  34 define global abbrevs instead."
  35   :type 'boolean
  36   :group 'abbrev-mode
  37   :group 'convenience)
  38
  39 (defun abbrev-mode (&optional arg)
  40   "Toggle Abbrev mode in the current buffer.
  41 With argument ARG, turn abbrev mode on iff ARG is positive.
  42 In Abbrev mode, inserting an abbreviation causes it to expand
  43 and be replaced by its expansion."
  44   (interactive "P")
  45   (setq abbrev-mode
  46         (if (null arg) (not abbrev-mode)
  47           (> (prefix-numeric-value arg) 0)))
  48   (force-mode-line-update))
  49
  50 (defcustom abbrev-mode nil
  51   "Enable or disable Abbrev mode.
  52 Non-nil means automatically expand abbrevs as they are inserted.
  53
  54 Setting this variable with `setq' changes it for the current buffer.
  55 Changing it with \\[customize] sets the default value.
  56 Interactively, use the command `abbrev-mode'
  57 to enable or disable Abbrev mode in the current buffer."
  58   :type 'boolean
  59   :group 'abbrev-mode)
  60
  61 \f
  62 (defvar edit-abbrevs-map
  63   (let ((map (make-sparse-keymap)))
  64     (define-key map "\C-x\C-s" 'edit-abbrevs-redefine)
  65     (define-key map "\C-c\C-c" 'edit-abbrevs-redefine)
  66     map)
  67   "Keymap used in `edit-abbrevs'.")
  68
  69 (defun kill-all-abbrevs ()
  70   "Undefine all defined abbrevs."
  71   (interactive)
  72   (let ((tables abbrev-table-name-list))
  73     (while tables
  74       (clear-abbrev-table (symbol-value (car tables)))
  75       (setq tables (cdr tables)))))
  76
  77 (defun copy-abbrev-table (table)
  78   "Make a new abbrev-table with the same abbrevs as TABLE."
  79   (let ((new-table (make-abbrev-table)))
  80     (mapatoms
  81      (lambda (symbol)
  82        (define-abbrev new-table
  83          (symbol-name symbol)
  84          (symbol-value symbol)
  85          (symbol-function symbol)))
  86      table)
  87     new-table))
  88
  89 (defun insert-abbrevs ()
  90   "Insert after point a description of all defined abbrevs.
  91 Mark is set after the inserted text."
  92   (interactive)
  93   (push-mark
  94    (save-excursion
  95     (let ((tables abbrev-table-name-list))
  96       (while tables
  97         (insert-abbrev-table-description (car tables) t)
  98         (setq tables (cdr tables))))
  99     (point))))
 100
 101 (defun list-abbrevs (&optional local)
 102   "Display a list of defined abbrevs.
 103 If LOCAL is non-nil, interactively when invoked with a
 104 prefix arg, display only local, i.e. mode-specific, abbrevs.
 105 Otherwise display all abbrevs."
 106   (interactive "P")
 107   (display-buffer (prepare-abbrev-list-buffer local)))
 108
 109 (defun abbrev-table-name (table)
 110   "Value is the name of abbrev table TABLE."
 111   (let ((tables abbrev-table-name-list)
 112         found)
 113     (while (and (not found) tables)
 114       (when (eq (symbol-value (car tables)) table)
 115         (setq found (car tables)))
 116       (setq tables (cdr tables)))
 117     found))
 118
 119 (defun prepare-abbrev-list-buffer (&optional local)
 120   (save-excursion
 121     (let ((table local-abbrev-table))
 122       (set-buffer (get-buffer-create "*Abbrevs*"))
 123       (erase-buffer)
 124       (if local
 125           (insert-abbrev-table-description (abbrev-table-name table) t)
 126         (dolist (table abbrev-table-name-list)
 127           (insert-abbrev-table-description table t)))
 128       (goto-char (point-min))
 129       (set-buffer-modified-p nil)
 130       (edit-abbrevs-mode)
 131       (current-buffer))))
 132
 133 (defun edit-abbrevs-mode ()
 134   "Major mode for editing the list of abbrev definitions.
 135 \\{edit-abbrevs-map}"
 136   (interactive)
 137   (setq major-mode 'edit-abbrevs-mode)
 138   (setq mode-name "Edit-Abbrevs")
 139   (use-local-map edit-abbrevs-map))
 140
 141 (defun edit-abbrevs ()
 142   "Alter abbrev definitions by editing a list of them.
 143 Selects a buffer containing a list of abbrev definitions.
 144 You can edit them and type \\<edit-abbrevs-map>\\[edit-abbrevs-redefine] to redefine abbrevs
 145 according to your editing.
 146 Buffer contains a header line for each abbrev table,
 147  which is the abbrev table name in parentheses.
 148 This is followed by one line per abbrev in that table:
 149 NAME   USECOUNT   EXPANSION   HOOK
 150 where NAME and EXPANSION are strings with quotes,
 151 USECOUNT is an integer, and HOOK is any valid function
 152 or may be omitted (it is usually omitted)."
 153   (interactive)
 154   (switch-to-buffer (prepare-abbrev-list-buffer)))
 155
 156 (defun edit-abbrevs-redefine ()
 157   "Redefine abbrevs according to current buffer contents."
 158   (interactive)
 159   (define-abbrevs t)
 160   (set-buffer-modified-p nil))
 161
 162 (defun define-abbrevs (&optional arg)
 163   "Define abbrevs according to current visible buffer contents.
 164 See documentation of `edit-abbrevs' for info on the format of the
 165 text you must have in the buffer.
 166 With argument, eliminate all abbrev definitions except
 167 the ones defined from the buffer now."
 168   (interactive "P")
 169   (if arg (kill-all-abbrevs))
 170   (save-excursion
 171    (goto-char (point-min))
 172    (while (and (not (eobp)) (re-search-forward "^(" nil t))
 173      (let* ((buf (current-buffer))
 174             (table (read buf))
 175             abbrevs name hook exp count sys)
 176        (forward-line 1)
 177        (while (progn (forward-line 1)
 178                      (not (eolp)))
 179          (setq name (read buf) count (read buf))
 180          (if (equal count '(sys))
 181              (setq sys t count (read buf)))
 182          (setq exp (read buf))
 183          (skip-chars-backward " \t\n\f")
 184          (setq hook (if (not (eolp)) (read buf)))
 185          (skip-chars-backward " \t\n\f")
 186          (setq abbrevs (cons (list name exp hook count sys) abbrevs)))
 187        (define-abbrev-table table abbrevs)))))
 188
 189 (defun read-abbrev-file (&optional file quietly)
 190   "Read abbrev definitions from file written with `write-abbrev-file'.
 191 Optional argument FILE is the name of the file to read;
 192 it defaults to the value of `abbrev-file-name'.
 193 Optional second argument QUIETLY non-nil means don't display a message."
 194   (interactive "fRead abbrev file: ")
 195   (load (if (and file (> (length file) 0)) file abbrev-file-name)
 196         nil quietly)
 197   (setq abbrevs-changed nil))
 198
 199 (defun quietly-read-abbrev-file (&optional file)
 200   "Read abbrev definitions from file written with `write-abbrev-file'.
 201 Optional argument FILE is the name of the file to read;
 202 it defaults to the value of `abbrev-file-name'.
 203 Does not display any message."
 204   ;(interactive "fRead abbrev file: ")
 205   (read-abbrev-file file t))
 206
 207 (defun write-abbrev-file (&optional file)
 208   "Write all user-level abbrev definitions to a file of Lisp code.
 209 This does not include system abbrevs; it includes only the abbrev tables
 210 listed in listed in `abbrev-table-name-list'.
 211 The file written can be loaded in another session to define the same abbrevs.
 212 The argument FILE is the file name to write.  If omitted or nil, the file
 213 specified in `abbrev-file-name' is used."
 214   (interactive
 215    (list
 216     (read-file-name "Write abbrev file: "
 217                     (file-name-directory (expand-file-name abbrev-file-name))
 218                     abbrev-file-name)))
 219   (or (and file (> (length file) 0))
 220       (setq file abbrev-file-name))
 221   (let ((coding-system-for-write 'emacs-mule))
 222     (with-temp-file file
 223       (insert ";;-*-coding: emacs-mule;-*-\n")
 224       (dolist (table abbrev-table-name-list)
 225         (insert-abbrev-table-description table nil)))))
 226 \f
 227 (defun add-mode-abbrev (arg)
 228   "Define mode-specific abbrev for last word(s) before point.
 229 Argument is how many words before point form the expansion;
 230 or zero means the region is the expansion.
 231 A negative argument means to undefine the specified abbrev.
 232 Reads the abbreviation in the minibuffer.
 233
 234 Don't use this function in a Lisp program; use `define-abbrev' instead."
 235   (interactive "p")
 236   (add-abbrev
 237    (if only-global-abbrevs
 238        global-abbrev-table
 239      (or local-abbrev-table
 240          (error "No per-mode abbrev table")))
 241    "Mode" arg))
 242
 243 (defun add-global-abbrev (arg)
 244   "Define global (all modes) abbrev for last word(s) before point.
 245 The prefix argument specifies the number of words before point that form the
 246 expansion; or zero means the region is the expansion.
 247 A negative argument means to undefine the specified abbrev.
 248 This command uses the minibuffer to read the abbreviation.
 249
 250 Don't use this function in a Lisp program; use `define-abbrev' instead."
 251   (interactive "p")
 252   (add-abbrev global-abbrev-table "Global" arg))
 253
 254 (defun add-abbrev (table type arg)
 255   (let ((exp (and (>= arg 0)
 256                   (buffer-substring-no-properties
 257                    (point)
 258                    (if (= arg 0) (mark)
 259                      (save-excursion (forward-word (- arg)) (point))))))
 260         name)
 261     (setq name
 262           (read-string (format (if exp "%s abbrev for \"%s\": "
 263                                  "Undefine %s abbrev: ")
 264                                type exp)))
 265     (set-text-properties 0 (length name) nil name)
 266     (if (or (null exp)
 267             (not (abbrev-expansion name table))
 268             (y-or-n-p (format "%s expands to \"%s\"; redefine? "
 269                               name (abbrev-expansion name table))))
 270         (define-abbrev table (downcase name) exp))))
 271
 272 (defun inverse-add-mode-abbrev (arg)
 273   "Define last word before point as a mode-specific abbrev.
 274 With prefix argument N, defines the Nth word before point.
 275 This command uses the minibuffer to read the expansion.
 276 Expands the abbreviation after defining it."
 277   (interactive "p")
 278   (inverse-add-abbrev
 279    (if only-global-abbrevs
 280        global-abbrev-table
 281      (or local-abbrev-table
 282          (error "No per-mode abbrev table")))
 283    "Mode" arg))
 284
 285 (defun inverse-add-global-abbrev (arg)
 286   "Define last word before point as a global (mode-independent) abbrev.
 287 With prefix argument N, defines the Nth word before point.
 288 This command uses the minibuffer to read the expansion.
 289 Expands the abbreviation after defining it."
 290   (interactive "p")
 291   (inverse-add-abbrev global-abbrev-table "Global" arg))
 292
 293 (defun inverse-add-abbrev (table type arg)
 294   (let (name exp start end)
 295     (save-excursion
 296       (forward-word (1+ (- arg)))
 297       (setq end (point))
 298       (backward-word 1)
 299       (setq start (point)
 300             name (buffer-substring-no-properties start end)))
 301
 302     (setq exp (read-string (format "%s expansion for \"%s\": " type name)
 303                            nil nil nil t))
 304     (when (or (not (abbrev-expansion name table))
 305               (y-or-n-p (format "%s expands to \"%s\"; redefine? "
 306                                 name (abbrev-expansion name table))))
 307       (define-abbrev table (downcase name) exp)
 308       (save-excursion
 309         (goto-char end)
 310         (expand-abbrev)))))
 311
 312 (defun abbrev-prefix-mark (&optional arg)
 313   "Mark current point as the beginning of an abbrev.
 314 Abbrev to be expanded starts here rather than at beginning of word.
 315 This way, you can expand an abbrev with a prefix: insert the prefix,
 316 use this command, then insert the abbrev.  This command inserts a
 317 temporary hyphen after the prefix \(until the intended abbrev
 318 expansion occurs).
 319 If the prefix is itself an abbrev, this command expands it, unless
 320 ARG is non-nil.  Interactively, ARG is the prefix argument."
 321   (interactive "P")
 322   (or arg (expand-abbrev))
 323   (setq abbrev-start-location (point-marker)
 324         abbrev-start-location-buffer (current-buffer))
 325   (insert "-"))
 326
 327 (defun expand-region-abbrevs (start end &optional noquery)
 328   "For abbrev occurrence in the region, offer to expand it.
 329 The user is asked to type y or n for each occurrence.
 330 A prefix argument means don't query; expand all abbrevs.
 331 If called from a Lisp program, arguments are START END &optional NOQUERY."
 332   (interactive "r\nP")
 333   (save-excursion
 334     (goto-char start)
 335     (let ((lim (- (point-max) end))
 336           pnt string)
 337       (while (and (not (eobp))
 338                   (progn (forward-word 1)
 339                          (<= (setq pnt (point)) (- (point-max) lim))))
 340         (if (abbrev-expansion
 341              (setq string
 342                    (buffer-substring-no-properties
 343                     (save-excursion (forward-word -1) (point))
 344                     pnt)))
 345             (if (or noquery (y-or-n-p (format "Expand `%s'? " string)))
 346                 (expand-abbrev)))))))
 347
 348 ;;; arch-tag: dbd6f3ae-dfe3-40ba-b00f-f9e3ff960df5
 349 ;;; abbrev.el ends here