code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_ON([libsystemd],[don't compile with libsystemd support])
 334 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 335 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 336 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 337
 338 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 339 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 340 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 341
 342 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 343 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 344 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 345 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 346 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 347 On by default on Mac OS X.])],[],[with_ns=maybe])
 348 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 349
 350 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 351 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 352 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 353 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 354 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 355 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 356 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 357 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 358
 359 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 360  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 361  [ case "${withval}" in
 362     y | ye | yes )      val=yes ;;
 363     n | no )            val=no  ;;
 364     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 365     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 366     g | gf | gfi | gfil | gfile )       val=gfile ;;
 367     w | w3 | w32 )      val=w32 ;;
 368     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 369 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 370 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 371 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 372     ;;
 373    esac
 374    with_file_notification=$val
 375  ],
 376  [with_file_notification=$with_features])
 377
 378 OPTION_DEFAULT_OFF([xwidgets],
 379   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 380
 381 ## For the times when you want to build Emacs but don't have
 382 ## a suitable makeinfo, and can live without the manuals.
 383 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 384 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 385
 386 ## This might be a 'configure' arg.
 387 AC_SUBST([ACLOCAL_PATH])
 388
 389 ## Makefile.in needs the cache file name.
 390 AC_SUBST(cache_file)
 391
 392 ## This is an option because I do not know if all info/man support
 393 ## compressed files, nor how to test if they do so.
 394 OPTION_DEFAULT_ON([compress-install],
 395   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 396 make GZIP_PROG= install])
 397
 398 AC_ARG_WITH(gameuser,dnl
 399 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 400                 [user for shared game score files.
 401                 An argument prefixed by ':' specifies a group instead.])])
 402 gameuser=
 403 gamegroup=
 404 # We don't test if we can actually chown/chgrp here, because configure
 405 # may run without root privileges.  lib-src/Makefile.in will handle
 406 # any errors due to missing user/group gracefully.
 407 case ${with_gameuser} in
 408   no) ;;
 409   "" | yes) gamegroup=games ;;
 410   :*) gamegroup=${with_gameuser#:} ;;
 411   *) gameuser=${with_gameuser} ;;
 412 esac
 413
 414 AC_ARG_WITH([gnustep-conf],dnl
 415 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 416    [name of GNUstep configuration file to use on systems where the command
 417     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 418     /etc/GNUstep/GNUstep.conf])])
 419 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 420   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 421 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 422      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 423
 424 AC_ARG_ENABLE(ns-self-contained,
 425 [AS_HELP_STRING([--disable-ns-self-contained],
 426                 [disable self contained build under NeXTstep])],
 427    EN_NS_SELF_CONTAINED=$enableval,
 428    EN_NS_SELF_CONTAINED=yes)
 429
 430 locallisppathset=no
 431 AC_ARG_ENABLE(locallisppath,
 432 [AS_HELP_STRING([--enable-locallisppath=PATH],
 433                 [directories Emacs should search for lisp files specific
 434                  to this site])],
 435 if test "${enableval}" = "no"; then
 436   locallisppath=
 437 elif test "${enableval}" != "yes"; then
 438   locallisppath=${enableval} locallisppathset=yes
 439 fi)
 440
 441 AC_ARG_ENABLE(checking,
 442 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 443                 [enable expensive run-time checks.  With LIST,
 444                  enable only specific categories of checks.
 445                  Categories are: all,yes,no.
 446                  Flags are: stringbytes, stringoverrun, stringfreelist,
 447                  xmallocoverrun, conslist, glyphs])],
 448 [ac_checking_flags="${enableval}"],[])
 449 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 450 for check in $ac_checking_flags
 451 do
 452         case $check in
 453         # these set all the flags to specific states
 454         yes)            ac_enable_checking=1 ;;
 455         no)             ac_enable_checking= ;
 456                         ac_gc_check_stringbytes= ;
 457                         ac_gc_check_string_overrun= ;
 458                         ac_gc_check_string_free_list= ;
 459                         ac_xmalloc_overrun= ;
 460                         ac_gc_check_cons_list= ;
 461                         ac_glyphs_debug= ;;
 462         all)            ac_enable_checking=1 ;
 463                         ac_gc_check_stringbytes=1 ;
 464                         ac_gc_check_string_overrun=1 ;
 465                         ac_gc_check_string_free_list=1 ;
 466                         ac_xmalloc_overrun=1 ;
 467                         ac_gc_check_cons_list=1 ;
 468                         ac_glyphs_debug=1 ;;
 469         # these enable particular checks
 470         stringbytes)    ac_gc_check_stringbytes=1 ;;
 471         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 472         stringfreelist) ac_gc_check_string_free_list=1 ;;
 473         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 474         conslist)       ac_gc_check_cons_list=1 ;;
 475         glyphs)         ac_glyphs_debug=1 ;;
 476         *)      AC_MSG_ERROR(unknown check category $check) ;;
 477         esac
 478 done
 479 IFS="$ac_save_IFS"
 480
 481 if test x$ac_enable_checking != x ; then
 482   AC_DEFINE(ENABLE_CHECKING, 1,
 483 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 484 fi
 485 if test x$ac_gc_check_stringbytes != x ; then
 486   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 487 [Define this temporarily to hunt a bug.  If defined, the size of
 488    strings is redundantly recorded in sdata structures so that it can
 489    be compared to the sizes recorded in Lisp strings.])
 490 fi
 491 if test x$ac_gc_check_string_overrun != x ; then
 492   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 493 [Define this to check for short string overrun.])
 494 fi
 495 if test x$ac_gc_check_string_free_list != x ; then
 496   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 497 [Define this to check the string free list.])
 498 fi
 499 if test x$ac_xmalloc_overrun != x ; then
 500   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 501 [Define this to check for malloc buffer overrun.])
 502 fi
 503 if test x$ac_gc_check_cons_list != x ; then
 504   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 505 [Define this to check for errors in cons list.])
 506 fi
 507 if test x$ac_glyphs_debug != x ; then
 508   AC_DEFINE(GLYPH_DEBUG, 1,
 509 [Define this to enable glyphs debugging code.])
 510 fi
 511
 512 AC_ARG_ENABLE(check-lisp-object-type,
 513 [AS_HELP_STRING([--enable-check-lisp-object-type],
 514                 [enable compile time checks for the Lisp_Object data type.
 515                 This is useful for development for catching certain types of bugs.])],
 516 if test "${enableval}" != "no"; then
 517    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 518    [Define this to enable compile time checks for the Lisp_Object data type.])
 519 fi)
 520
 521
 522 dnl The name of this option is unfortunate.  It predates, and has no
 523 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 524 dnl Actually, it stops it working.
 525 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 526 AC_ARG_ENABLE(profiling,
 527 [AS_HELP_STRING([--enable-profiling],
 528                 [build emacs with low-level, gprof profiling support.
 529                 Mainly useful for debugging Emacs itself.  May not work on
 530                 all platforms.  Stops profiler.el working.])],
 531 [ac_enable_profiling="${enableval}"],[])
 532 if test x$ac_enable_profiling != x ; then
 533    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 534 else
 535    PROFILING_CFLAGS=
 536 fi
 537 AC_SUBST(PROFILING_CFLAGS)
 538
 539 AC_ARG_ENABLE(autodepend,
 540 [AS_HELP_STRING([--enable-autodepend],
 541                 [automatically generate dependencies to .h-files.
 542                  Requires gcc, enabled if found.])],
 543 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 544
 545 AC_ARG_ENABLE(gtk-deprecation-warnings,
 546 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 547                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 548 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 549
 550 BUILD_DETAILS=
 551 AC_ARG_ENABLE([build-details],
 552   [AS_HELP_STRING([--disable-build-details],
 553                   [Make the build more deterministic by omitting host
 554                    names, time stamps, etc. from the output.])],
 555   [test "$enableval" = no && BUILD_DETAILS=--no-build-details])
 556 AC_SUBST([BUILD_DETAILS])
 557
 558 dnl This used to use changequote, but, apart from 'changequote is evil'
 559 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 560 dnl the great gob of text.  Thus it's not processed for possible expansion.
 561 dnl Just make sure the brackets remain balanced.
 562 dnl
 563 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 564 dnl indicated by comments.
 565 dnl quotation begins
 566 [
 567
 568 ### If you add support for a new configuration, add code to this
 569 ### switch statement to recognize your configuration name and select
 570 ### the appropriate opsys.
 571
 572 ### As far as handling version numbers on operating systems is
 573 ### concerned, make sure things will fail in a fixable way.  If
 574 ### /etc/MACHINES doesn't say anything about version numbers, be
 575 ### prepared to handle anything reasonably.  If version numbers
 576 ### matter, be sure /etc/MACHINES says something about it.
 577
 578 opsys='' unported=no
 579 case "${canonical}" in
 580
 581   ## GNU/Linux and similar ports
 582   *-*-linux* )
 583     opsys=gnu-linux
 584   ;;
 585
 586   ## FreeBSD ports
 587   *-*-freebsd* )
 588     opsys=freebsd
 589   ;;
 590
 591   ## DragonFly ports
 592   *-*-dragonfly* )
 593     opsys=dragonfly
 594   ;;
 595
 596   ## FreeBSD kernel + glibc based userland
 597   *-*-kfreebsd*gnu* )
 598     opsys=gnu-kfreebsd
 599   ;;
 600
 601   ## NetBSD ports
 602   *-*-netbsd* )
 603     opsys=netbsd
 604   ;;
 605
 606   ## OpenBSD ports
 607   *-*-openbsd* | *-*-mirbsd* )
 608     opsys=openbsd
 609   ;;
 610
 611   ## Apple Darwin / Mac OS X
 612   *-apple-darwin* )
 613     case "${canonical}" in
 614       *-apple-darwin[0-9].*) unported=yes ;;
 615       i[3456]86-* | x86_64-* )  ;;
 616       * )            unported=yes ;;
 617     esac
 618     opsys=darwin
 619     ## FIXME: Find a way to use Fink if available (Bug#11507).
 620   ;;
 621
 622   ## Chromium Native Client
 623   *-nacl )
 624     opsys=nacl
 625   ;;
 626
 627   ## Cygwin ports
 628   *-*-cygwin )
 629     opsys=cygwin
 630   ;;
 631
 632   ## HP 9000 series 700 and 800, running HP/UX
 633   hppa*-hp-hpux10.2* )
 634     opsys=hpux10-20
 635   ;;
 636   hppa*-hp-hpux1[1-9]* )
 637     opsys=hpux11
 638     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 639   ;;
 640
 641   ## IBM machines
 642   rs6000-ibm-aix4.[23]* )
 643     opsys=aix4-2
 644   ;;
 645   powerpc-ibm-aix4.[23]*  )
 646     opsys=aix4-2
 647   ;;
 648   rs6000-ibm-aix[56]* )
 649     opsys=aix4-2
 650   ;;
 651   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 652     opsys=aix4-2
 653   ;;
 654
 655   ## Suns
 656   *-sun-solaris* \
 657     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 658     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 659     case "${canonical}" in
 660       i[3456]86-*-* )   ;;
 661       amd64-*-*|x86_64-*-*) ;;
 662       sparc* )          ;;
 663       * )               unported=yes ;;
 664     esac
 665     case "${canonical}" in
 666       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 667                 opsys=sol2-10
 668                 emacs_check_sunpro_c=yes
 669                 ;;
 670       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 671       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 672       *-sunos5.6* | *-solaris2.6* )
 673                 opsys=sol2-6
 674                 RANLIB="ar -ts"
 675                 ;;
 676       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 677       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 678                 opsys=sol2-6
 679                 emacs_check_sunpro_c=yes
 680                 ;;
 681     esac
 682     ## Watch out for a compiler that we know will not work.
 683     case "${canonical}" in
 684      *-solaris* | *-sunos5* )
 685                 if [ "x$CC" = x/usr/ucb/cc ]; then
 686                   ## /usr/ucb/cc doesn't work;
 687                   ## we should find some other compiler that does work.
 688                   unset CC
 689                 fi
 690                 ;;
 691       *) ;;
 692     esac
 693   ;;
 694
 695   ## Intel 386 machines where we don't care about the manufacturer.
 696   i[3456]86-*-* )
 697     case "${canonical}" in
 698       *-darwin* )               opsys=darwin ;;
 699       *-mingw* )
 700                 opsys=mingw32
 701                 # MinGW overrides and adds some system headers in nt/inc.
 702                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 703                 ;;
 704       *-sysv4.2uw* )            opsys=unixware ;;
 705       *-sysv5uw* )              opsys=unixware ;;
 706       *-sysv5OpenUNIX* )        opsys=unixware ;;
 707       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 708     esac
 709   ;;
 710
 711   # MinGW64
 712   x86_64-*-* )
 713     case "${canonical}" in
 714       *-mingw* )
 715                 opsys=mingw32
 716                 # MinGW overrides and adds some system headers in nt/inc.
 717                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 718                 ;;
 719       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 720     esac
 721   ;;
 722
 723   * )
 724     unported=yes
 725   ;;
 726 esac
 727
 728 ### If the code above didn't choose an operating system, just choose
 729 ### an operating system based on the configuration name.  You really
 730 ### only want to use this when you have no idea what the right
 731 ### operating system is; if you know what operating systems a machine
 732 ### runs, it's cleaner to make it explicit in the case statement
 733 ### above.
 734 if test x"${opsys}" = x; then
 735   case "${canonical}" in
 736     *-gnu* )                            opsys=gnu ;;
 737     * )
 738       unported=yes
 739     ;;
 740   esac
 741 fi
 742
 743 ]
 744 dnl quotation ends
 745
 746 if test $unported = yes; then
 747   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 748 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 749 Check 'etc/MACHINES' for recognized configuration names.])
 750 fi
 751
 752 #### Choose a compiler.
 753
 754 dnl Don't bother to test for C89.
 755 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 756
 757 dnl Sets GCC=yes if using gcc.
 758 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 759 if test -n "$XCRUN"; then
 760   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 761   test -n "$AR" && export AR
 762 fi
 763
 764 dnl Emacs needs C99 or later.
 765 gl_PROG_CC_C99
 766
 767 AM_PROG_CC_C_O
 768
 769 if test x$GCC = xyes; then
 770   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 771 fi
 772
 773 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 774 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 775 dnl that clash with MinGW.
 776 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 777
 778 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 779 AC_DEFUN([gl_CRYPTO_CHECK])
 780 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 781 # as we don't use them.
 782 AC_DEFUN([gl_FCNTL_O_FLAGS])
 783 # Avoid gnulib's test for pthread_sigmask.
 784 funcs=
 785 for func in $ac_func_list; do
 786   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 787 done
 788 ac_func_list=$funcs
 789 # Use the system putenv even if it lacks GNU features, as we don't need them,
 790 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 791 AC_CHECK_FUNCS_ONCE([putenv])
 792 AC_DEFUN([gl_FUNC_PUTENV],
 793   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 794
 795 # Initialize gnulib right after choosing the compiler.
 796 dnl Amongst other things, this sets AR and ARFLAGS.
 797 gl_EARLY
 798
 799 if test "$ac_test_CFLAGS" != set; then
 800   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 801   # if -g3 works and the user does not specify CFLAGS.
 802   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 803   case $CFLAGS in
 804     '-g')
 805       emacs_g3_CFLAGS='-g3';;
 806     '-g -O2')
 807       emacs_g3_CFLAGS='-g3 -O2';;
 808     *)
 809       emacs_g3_CFLAGS='';;
 810   esac
 811   if test -n "$emacs_g3_CFLAGS"; then
 812     emacs_save_CFLAGS=$CFLAGS
 813     CFLAGS=$emacs_g3_CFLAGS
 814     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 815       [emacs_cv_prog_cc_g3],
 816       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 817          [emacs_cv_prog_cc_g3=yes],
 818          [emacs_cv_prog_cc_g3=no])])
 819     if test $emacs_cv_prog_cc_g3 != yes; then
 820       CFLAGS=$emacs_save_CFLAGS
 821     fi
 822     if test $opsys = mingw32; then
 823       CFLAGS="$CFLAGS -gdwarf-2"
 824     fi
 825   fi
 826
 827   case $CFLAGS in
 828     *-O*) ;;
 829     *)
 830       # No optimization flag was inferred for this non-GCC compiler.
 831       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 832       emacs_save_CFLAGS=$CFLAGS
 833       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 834       CFLAGS=${CFLAGS}-O
 835       AC_CACHE_CHECK([whether $CC accepts -O],
 836         [emacs_cv_prog_cc_o],
 837         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 838            [emacs_cv_prog_cc_o=yes],
 839            [emacs_cv_prog_cc_o=no])])
 840       if test $emacs_cv_prog_cc_o != yes; then
 841         CFLAGS=$emacs_save_CFLAGS
 842       fi ;;
 843   esac
 844 fi
 845
 846 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 847 # ---------------------------------------------------------------------------
 848 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 849 # Otherwise, run RUN-IF-NOT-FOUND.
 850 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 851   [AC_PREPROC_IFELSE(
 852     [AC_LANG_PROGRAM(
 853       [[
 854 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 855 /* ok */
 856 #else
 857 # error "your version of gcc is older than $1.$2"
 858 #endif
 859       ]]),
 860     ], [$3], [$4])
 861   ]
 862 )
 863
 864 AC_ARG_ENABLE([gcc-warnings],
 865   [AS_HELP_STRING([--enable-gcc-warnings@<:@=TYPE@:>@],
 866                   [control generation of GCC warnings.  The TYPE 'yes'
 867                    means to fail if any warnings are issued; 'warn-only'
 868                    means issue warnings without failing (default for
 869                    developer builds); 'no' means disable warnings
 870                    (default for non-developer builds).])],
 871   [case $enableval in
 872      yes|no|warn-only) ;;
 873      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 874    esac
 875    gl_gcc_warnings=$enableval],
 876   [# By default, use 'warn-only' if it looks like the invoker of 'configure'
 877    # is a developer as opposed to a builder.  This is most likely true
 878    # if GCC is recent enough and there is a .git directory or file;
 879    # however, if there is also a .tarball-version file it is probably
 880    # just a release imported into Git for patch management.
 881    gl_gcc_warnings=no
 882    test -e "$srcdir"/.git && test ! -f "$srcdir"/.tarball-version &&
 883      gl_GCC_VERSION_IFELSE([5], [3], [gl_gcc_warnings=warn-only])]
 884 )
 885
 886 # clang is unduly picky about some things.
 887 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 888   [AC_COMPILE_IFELSE(
 889      [AC_LANG_PROGRAM([[
 890           #ifndef __clang__
 891             error "not clang";
 892           #endif
 893         ]])],
 894      [emacs_cv_clang=yes],
 895      [emacs_cv_clang=no])])
 896
 897 # When compiling with GCC, prefer -isystem to -I when including system
 898 # include files, to avoid generating useless diagnostics for the files.
 899 AS_IF([test $gl_gcc_warnings = no],
 900  [
 901   isystem='-I'
 902   AS_IF([test "$emacs_cv_clang" = yes],
 903    [
 904      # Turn off some warnings if supported.
 905      gl_WARN_ADD([-Wno-switch])
 906      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 907      gl_WARN_ADD([-Wno-pointer-sign])
 908      gl_WARN_ADD([-Wno-string-plus-int])
 909      gl_WARN_ADD([-Wno-unknown-attributes])
 910    ])
 911  ],[
 912   isystem='-isystem '
 913
 914   # This, $nw, is the list of warnings we disable.
 915   nw=
 916
 917   case $with_x_toolkit in
 918     lucid | athena | motif)
 919        # Old toolkits mishandle 'const'.
 920        nw="$nw -Wwrite-strings"
 921        ;;
 922   esac
 923   AS_IF([test $gl_gcc_warnings = yes],
 924     [gl_WARN_ADD([-Werror], [WERROR_CFLAGS])])
 925   AC_SUBST([WERROR_CFLAGS])
 926
 927   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 928   nw="$nw -Woverlength-strings"     # Not a problem these days
 929   nw="$nw -Wformat-nonliteral"      # we do this a lot
 930   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 931   nw="$nw -Wswitch-default"         # Too many warnings for now
 932   nw="$nw -Winline"                 # OK to ignore 'inline'
 933   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 934                                     # signed overflow has undefined behavior
 935   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 936   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 937   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 938
 939   # Emacs doesn't care about shadowing; see
 940   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 941   nw="$nw -Wshadow"
 942
 943   # Emacs's use of alloca inhibits protecting the stack.
 944   nw="$nw -Wstack-protector"
 945
 946   # Emacs's use of partly-const functions such as Fgnutls_available_p
 947   # make this option problematic.
 948   nw="$nw -Wsuggest-attribute=const"
 949
 950   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 951   # option problematic.
 952   nw="$nw -Wsuggest-attribute=pure"
 953
 954   # This part is merely for shortening the command line,
 955   # since -Wall implies -Wswitch.
 956   nw="$nw -Wswitch"
 957
 958   # This part is merely for shortening the command line,
 959   # since -Wno-FOO needs to be added below regardless.
 960   nw="$nw -Wmissing-field-initializers"
 961   nw="$nw -Wtype-limits"
 962   nw="$nw -Wunused-parameter"
 963
 964   if test $emacs_cv_clang = yes; then
 965     nw="$nw -Wcast-align"
 966   fi
 967
 968   gl_MANYWARN_ALL_GCC([ws])
 969   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 970   for w in $ws; do
 971     gl_WARN_ADD([$w])
 972   done
 973   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 974   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 975   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 976   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 977   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 978   gl_WARN_ADD([-Wno-format-nonliteral])
 979
 980   # More things that clang is unduly picky about.
 981   if test $emacs_cv_clang = yes; then
 982     gl_WARN_ADD([-Wno-format-extra-args])
 983     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 984     gl_WARN_ADD([-Wno-unused-command-line-argument])
 985     gl_WARN_ADD([-Wno-unused-value])
 986   fi
 987
 988   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 989   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 990   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 991   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 992       without upsetting glibc 2.15+. */
 993    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 994         && defined __OPTIMIZE__ && __OPTIMIZE__)
 995    # define _FORTIFY_SOURCE 2
 996    #endif
 997   ])
 998
 999   # We use a slightly smaller set of warning options for lib/.
1000   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
1001   nw=
1002   nw="$nw -Wunused-macros"
1003
1004   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
1005   AC_SUBST([GNULIB_WARN_CFLAGS])
1006  ])
1007
1008 edit_cflags="
1009   s,///*,/,g
1010   s/^/ /
1011   s/ -I/ $isystem/g
1012   s/^ //
1013 "
1014
1015 AC_ARG_ENABLE(link-time-optimization,
1016 [AS_HELP_STRING([--enable-link-time-optimization],
1017                 [build emacs with link-time optimization.
1018                  This requires GCC 4.5.0 or later, or clang.
1019                  (Note that clang support is experimental - see INSTALL.)
1020                  It also makes Emacs harder to debug, and when we tried it
1021                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
1022                  recommended for typical use.])],
1023 if test "${enableval}" != "no"; then
1024    ac_lto_supported=no
1025    if test $emacs_cv_clang = yes; then
1026       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
1027       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1028       if test -x "$GOLD_PLUGIN"; then
1029          LTO="-flto"
1030       fi
1031    elif test x$GCC = xyes; then
1032       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1033       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1034       if test x$CPUS != x; then
1035          LTO="-flto=$CPUS"
1036       else
1037          LTO="-flto"
1038       fi
1039    else
1040       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1041    fi
1042    if test -z "$LTO"; then
1043       ac_lto_supported=no
1044    else
1045       old_CFLAGS=$CFLAGS
1046       CFLAGS="$CFLAGS $LTO"
1047       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1048          [ac_lto_supported=yes], [ac_lto_supported=no])
1049          CFLAGS="$old_CFLAGS"
1050    fi
1051    AC_MSG_RESULT([$ac_lto_supported])
1052    if test "$ac_lto_supported" = "yes"; then
1053       CFLAGS="$CFLAGS $LTO"
1054       if test x$emacs_cv_clang = xyes; then
1055          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1056          # WARNING: 'ar --plugin ...' doesn't work without
1057          # command, so plugin name is appended to ARFLAGS.
1058          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1059          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1060       else
1061         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1062         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1063         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1064         dnl dump core on Fedora 20, so play it safe for now.
1065         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1066           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1067       fi
1068    fi
1069 fi)
1070
1071 dnl Prefer silent make output.  For verbose output, use
1072 dnl 'configure --disable-silent-rules' or 'make V=1' .
1073 AM_SILENT_RULES([yes])
1074 dnl Port to Automake 1.11.
1075 dnl This section can be removed once we assume Automake 1.14 or later.
1076 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1077 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1078 AC_SUBST([AM_V])
1079 AM_SUBST_NOTMAKE([AM_V])
1080 AC_SUBST([AM_DEFAULT_V])
1081 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1082 AC_SUBST([AM_DEFAULT_VERBOSITY])
1083
1084 dnl Some other nice autoconf tests.
1085 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1086 dnl AC_PROG_INSTALL
1087 dnl AC_PROG_MKDIR_P
1088 dnl if test "x$RANLIB" = x; then
1089 dnl   AC_PROG_RANLIB
1090 dnl fi
1091
1092
1093 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1094 dnl can be made to directories.  This is not relevant for our usage, and
1095 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1096 dnl hosted on AFS, both examples where simple links work, but links to
1097 dnl directories fail.  We use a cut-down version instead.
1098 dnl AC_PROG_LN_S
1099
1100 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1101 rm -f conf$$ conf$$.file
1102
1103 LN_S_FILEONLY='cp -p'
1104
1105 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1106 dnl random program in the current directory.
1107 if (echo >conf$$.file) 2>/dev/null; then
1108   if ln -s conf$$.file conf$$ 2>/dev/null; then
1109     if test "$opsys" = "mingw32"; then
1110       LN_S_FILEONLY='/bin/ln -s'
1111     else
1112       LN_S_FILEONLY='ln -s'
1113     fi
1114   elif ln conf$$.file conf$$ 2>/dev/null; then
1115     if test "$opsys" = "mingw32"; then
1116       LN_S_FILEONLY=/bin/ln
1117     else
1118       LN_S_FILEONLY=ln
1119     fi
1120   fi
1121 fi
1122
1123 rm -f conf$$ conf$$.file
1124
1125 if test "$LN_S_FILEONLY" = "ln -s"; then
1126    AC_MSG_RESULT([yes])
1127 else
1128    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1129 fi
1130
1131 AC_SUBST(LN_S_FILEONLY)
1132
1133
1134 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1135 dnl doesn't support links to directories, as in "ln file dir".  But that
1136 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1137 dnl executables at "make install" time.
1138 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1139 dnl for more details.
1140 if test "$opsys" = "mingw32"; then
1141   LN_S="/bin/ln"
1142 fi
1143
1144 dnl On some Debian versions, "install-info" prints irritating messages
1145 dnl "This is not dpkg install-info anymore, but GNU install-info"
1146 dnl if called via an absolute file name.
1147 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1148 dnl Sadly some people may have an old ginstall-info installed on
1149 dnl non-Debian systems, so we can't use this.
1150 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1151 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1152
1153 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1154   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1155 dnl Don't use GZIP, which is used by gzip for additional parameters.
1156 AC_PATH_PROG(GZIP_PROG, gzip)
1157
1158 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1159    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1160
1161 if test $opsys = gnu-linux; then
1162   AC_PATH_PROG(PAXCTL, paxctl,,
1163     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1164   if test "X$PAXCTL" != X; then
1165     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1166     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1167       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1168       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1169   fi
1170
1171   if test "${SETFATTR+set}" != set; then
1172     AC_CACHE_CHECK([for setfattr],
1173       [emacs_cv_prog_setfattr],
1174       [touch conftest.tmp
1175        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1176          emacs_cv_prog_setfattr=yes
1177        else
1178          emacs_cv_prog_setfattr=no
1179        fi])
1180     if test "$emacs_cv_prog_setfattr" = yes; then
1181       SETFATTR=setfattr
1182     else
1183       SETFATTR=
1184     fi
1185     rm -f conftest.tmp
1186     AC_SUBST([SETFATTR])
1187   fi
1188 fi
1189
1190 ## Need makeinfo >= 4.7 (?) to build the manuals.
1191 if test "$MAKEINFO" != "no"; then
1192   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1193     MAKEINFO=makeinfo
1194   fi
1195   case `($MAKEINFO --version) 2>/dev/null` in
1196     *' (GNU texinfo) '4.[[7-9]]* | \
1197     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1198     *' (GNU texinfo) '[[5-9]]* | \
1199     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1200     *) MAKEINFO=no;;
1201   esac
1202 fi
1203
1204 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1205 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1206 ## therefore in the category of "special tools" not normally required, which
1207 ## configure does not have to check for (eg autoconf itself).
1208 ## In a repository checkout on the other hand, the manuals are not included.
1209 ## So makeinfo is a requirement to build from the repository, and configure
1210 ## should test for it as it does for any other build requirement.
1211 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1212 ## with pre-built manuals, from a repository checkout.
1213 HAVE_MAKEINFO=yes
1214
1215 if test "$MAKEINFO" = "no"; then
1216   MAKEINFO=makeinfo
1217   if test "x${with_makeinfo}" = "xno"; then
1218     HAVE_MAKEINFO=no
1219   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1220     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1221 source tree does not seem to have pre-built manuals in the 'info' directory.
1222 Either install a suitable version of makeinfo, or re-run configure
1223 with the '--without-makeinfo' option to build without the manuals.] )
1224   fi
1225 fi
1226 AC_SUBST(HAVE_MAKEINFO)
1227
1228 if test $opsys = mingw32; then
1229    DOCMISC_W32=efaq-w32
1230 else
1231    DOCMISC_W32=
1232 fi
1233 AC_SUBST(DOCMISC_W32)
1234
1235 dnl Add our options to ac_link now, after it is set up.
1236
1237 if test x$GCC = xyes; then
1238   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1239     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1240 else
1241   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1242     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1243 fi
1244
1245 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1246 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1247 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1248 dnl if not built to support GNU ld.
1249
1250 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1251 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1252 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1253 dnl   Eg "make LDFLAGS=... all" could run into problems,
1254 dnl   http://bugs.debian.org/684788
1255 dnl * unnecessary, since temacs is the only thing that actually needs it.
1256 dnl   Indeed this is where it was originally, prior to:
1257 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1258 late_LDFLAGS="$LDFLAGS"
1259 if test x$GCC = xyes; then
1260   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1261 else
1262   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1263 fi
1264
1265 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1266
1267 AC_MSG_CHECKING([for -znocombreloc])
1268 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1269   [AC_MSG_RESULT(yes)],
1270   LDFLAGS_NOCOMBRELOC=
1271   [AC_MSG_RESULT(no)])
1272
1273 LDFLAGS="$late_LDFLAGS"
1274
1275 AC_CACHE_CHECK([whether addresses are sanitized],
1276   [emacs_cv_sanitize_address],
1277   [AC_COMPILE_IFELSE(
1278      [AC_LANG_PROGRAM(
1279         [[#ifndef __has_feature
1280           #define __has_feature(f) 0
1281           #endif
1282           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1283           #else
1284            error "Addresses are not sanitized.";
1285           #endif
1286         ]])],
1287      [emacs_cv_sanitize_address=yes],
1288      [emacs_cv_sanitize_address=no])])
1289
1290 dnl The function dump-emacs will not be defined and temacs will do
1291 dnl (load "loadup") automatically unless told otherwise.
1292 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1293 case "$opsys" in
1294   nacl) CANNOT_DUMP=yes ;;
1295 esac
1296
1297 if test "$CANNOT_DUMP" = "yes"; then
1298   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1299 elif test "$emacs_cv_sanitize_address" = yes; then
1300   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1301 fi
1302
1303 AC_SUBST(CANNOT_DUMP)
1304
1305
1306 UNEXEC_OBJ=unexelf.o
1307 case "$opsys" in
1308   # MSDOS uses unexcoff.o
1309   aix4-2)
1310    UNEXEC_OBJ=unexaix.o
1311    ;;
1312   cygwin)
1313    UNEXEC_OBJ=unexcw.o
1314    ;;
1315   darwin)
1316    UNEXEC_OBJ=unexmacosx.o
1317    ;;
1318   hpux10-20 | hpux11)
1319    UNEXEC_OBJ=unexhp9k800.o
1320    ;;
1321   mingw32)
1322    UNEXEC_OBJ=unexw32.o
1323    ;;
1324   sol2-10)
1325    # Use the Solaris dldump() function, called from unexsol.c, to dump
1326    # emacs, instead of the generic ELF dump code found in unexelf.c.
1327    # The resulting binary has a complete symbol table, and is better
1328    # for debugging and other observability tools (debuggers, pstack, etc).
1329    #
1330    # If you encounter a problem using dldump(), please consider sending
1331    # a message to the OpenSolaris tools-linking mailing list:
1332    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1333    #
1334    # It is likely that dldump() works with older Solaris too, but this has
1335    # not been tested, so for now this change is for Solaris 10 or newer.
1336    UNEXEC_OBJ=unexsol.o
1337    ;;
1338 esac
1339
1340 LD_SWITCH_SYSTEM=
1341 case "$opsys" in
1342   freebsd|dragonfly)
1343    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1344    ## The system compiler, GCC, has apparently been modified to not
1345    ## look there, contrary to what a stock GCC would do.
1346 ### It's not our place to do this.  See bug#10313#17.
1347 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1348       :
1349    ;;
1350
1351   gnu-linux)
1352    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1353    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1354    ;;
1355
1356   netbsd)
1357 ### It's not our place to do this.  See bug#10313#17.
1358 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1359       :
1360    ;;
1361
1362   openbsd)
1363    ## Han Boetes <han@boetes.org> says this is necessary,
1364    ## otherwise Emacs dumps core on elf systems.
1365    LD_SWITCH_SYSTEM="-Z"
1366    ;;
1367 esac
1368 AC_SUBST(LD_SWITCH_SYSTEM)
1369
1370 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1371
1372 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1373 ## which has not been defined yet.  When this was handled with cpp,
1374 ## it was expanded to null when configure sourced the s/*.h file.
1375 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1376 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1377 ## (or somesuch), but because it is supposed to go at the _front_
1378 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1379 ## Compare with the gnu-linux case below, which added to the end
1380 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1381 ## LD_SWITCH_SYSTEM_TEMACS.
1382 case "$opsys" in
1383   netbsd|openbsd)
1384    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1385 esac
1386
1387
1388 C_SWITCH_MACHINE=
1389 case $canonical in
1390  alpha*)
1391   AC_CHECK_DECL([__ELF__])
1392   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1393     ## With ELF, make sure that all common symbols get allocated to in the
1394     ## data section.  Otherwise, the dump of temacs may miss variables in
1395     ## the shared library that have been initialized.  For example, with
1396     ## GNU libc, __malloc_initialized would normally be resolved to the
1397     ## shared library's .bss section, which is fatal.
1398     if test "x$GCC" = "xyes"; then
1399       C_SWITCH_MACHINE="-fno-common"
1400     else
1401       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1402     fi
1403   else
1404       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1405       dnl albeit under the mistaken assumption that said file
1406       dnl was no longer used.
1407       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1408   fi
1409   ;;
1410 esac
1411 AC_SUBST(C_SWITCH_MACHINE)
1412
1413 AC_SUBST(UNEXEC_OBJ)
1414
1415 C_SWITCH_SYSTEM=
1416 ## Some programs in src produce warnings saying certain subprograms
1417 ## are too complex and need a MAXMEM value greater than 2000 for
1418 ## additional optimization.  --nils@exp-math.uni-essen.de
1419 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1420   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1421 if test "$opsys" = "mingw32"; then
1422   case "$canonical" in
1423     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1424     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1425   esac
1426 fi
1427 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1428 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1429 AC_SUBST(C_SWITCH_SYSTEM)
1430
1431
1432 LIBS_SYSTEM=
1433 case "$opsys" in
1434   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1435   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1436
1437   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1438
1439   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1440
1441   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1442
1443   ## Motif needs -lgen.
1444   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1445 esac
1446
1447 AC_SUBST(LIBS_SYSTEM)
1448
1449 ### Make sure subsequent tests use flags consistent with the build flags.
1450
1451 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1452   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1453 else
1454   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1455 fi
1456
1457 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1458 AC_DEFUN([AC_TYPE_SIZE_T])
1459 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1460 AC_DEFUN([AC_TYPE_UID_T])
1461
1462 # sqrt and other floating-point functions such as fmod and frexp
1463 # are found in -lm on many systems.
1464 OLD_LIBS=$LIBS
1465 AC_SEARCH_LIBS([sqrt], [m])
1466 if test "X$LIBS" = "X$OLD_LIBS"; then
1467   LIB_MATH=
1468 else
1469   LIB_MATH=$ac_cv_search_sqrt
1470 fi
1471 LIBS=$OLD_LIBS
1472
1473 dnl Current possibilities handled by sed (aix4-2 -> aix,
1474 dnl gnu-linux -> gnu/linux, etc.):
1475 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux.
1476 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1477 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1478
1479 case $opsys in
1480   cygwin )
1481     LIB_MATH=
1482     ;;
1483   darwin )
1484     ## Adding -lm confuses the dynamic linker, so omit it.
1485     LIB_MATH=
1486     ;;
1487   freebsd | dragonfly )
1488     SYSTEM_TYPE=berkeley-unix
1489     ;;
1490   gnu-linux | gnu-kfreebsd )
1491     ;;
1492   hpux10-20 | hpux11 )
1493     ;;
1494   mingw32 )
1495     LIB_MATH=
1496     SYSTEM_TYPE=windows-nt
1497     ;;
1498   dnl NB this may be adjusted below.
1499   netbsd | openbsd )
1500     SYSTEM_TYPE=berkeley-unix
1501     ;;
1502
1503   sol2* | unixware )
1504     SYSTEM_TYPE=usg-unix-v
1505     ;;
1506
1507 esac
1508
1509 AC_SUBST(LIB_MATH)
1510 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1511   [The type of system you are compiling for; sets 'system-type'.])
1512
1513
1514 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1515 pre_PKG_CONFIG_LIBS=$LIBS
1516
1517 PKG_PROG_PKG_CONFIG(0.9.0)
1518
1519 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1520 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1521 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1522 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1523 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1524 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1525 dnl actions.
1526 AC_DEFUN([EMACS_CHECK_MODULES],
1527   [PKG_CHECK_MODULES([$1], [$2],
1528      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1529       m4_default([$3], [HAVE_$1=yes])],
1530      [m4_default([$4], [HAVE_$1=no])])])
1531
1532 HAVE_SOUND=no
1533 if test "${with_sound}" != "no"; then
1534   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1535   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1536     have_sound_header=yes, [], [
1537     #ifdef __MINGW32__
1538     #define WIN32_LEAN_AND_MEAN
1539     #include <windows.h>
1540     #endif
1541     ])
1542   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1543     AC_MSG_ERROR([OSS sound support requested but not found.])
1544
1545   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1546     # Emulation library used on NetBSD.
1547     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1548     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1549       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1550     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1551     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1552   fi
1553   AC_SUBST(LIBSOUND)
1554
1555   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1556     ALSA_REQUIRED=1.0.0
1557     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1558     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1559     if test $HAVE_ALSA = yes; then
1560       SAVE_CFLAGS="$CFLAGS"
1561       SAVE_LIBS="$LIBS"
1562       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1563       LIBS="$ALSA_LIBS $LIBS"
1564       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1565                       emacs_alsa_normal=yes,
1566                     emacs_alsa_normal=no)
1567       if test "$emacs_alsa_normal" != yes; then
1568         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1569                        [[snd_lib_error_set_handler (0);]])],
1570                        emacs_alsa_subdir=yes,
1571                      emacs_alsa_subdir=no)
1572         if test "$emacs_alsa_subdir" != yes; then
1573           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1574         fi
1575         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1576       fi
1577
1578       CFLAGS="$SAVE_CFLAGS"
1579       LIBS="$SAVE_LIBS"
1580       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1581       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1582       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1583     elif test "${with_sound}" = "alsa"; then
1584       AC_MSG_ERROR([ALSA sound support requested but not found.])
1585     fi
1586   fi                            dnl with_sound = alsa|yes
1587
1588   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1589   dnl compiles only on the specified platforms.  For others, it
1590   dnl probably doesn't make sense to try.
1591   dnl FIXME So surely we should bypass this whole section if not using
1592   dnl one of these platforms?
1593   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1594      case "$opsys" in
1595        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1596        dnl Adjust the --with-sound help text if you change this.
1597        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1598          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1599          HAVE_SOUND=yes
1600          ;;
1601      esac
1602   fi
1603
1604   AC_SUBST(CFLAGS_SOUND)
1605 fi
1606
1607 dnl checks for header files
1608 AC_CHECK_HEADERS_ONCE(
1609   malloc.h
1610   sys/systeminfo.h
1611   sys/sysinfo.h
1612   coff.h pty.h
1613   sys/resource.h
1614   sys/utsname.h pwd.h utmp.h util.h)
1615
1616 AC_MSG_CHECKING(if personality LINUX32 can be set)
1617 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1618                emacs_cv_personality_linux32=yes,
1619                emacs_cv_personality_linux32=no)
1620 AC_MSG_RESULT($emacs_cv_personality_linux32)
1621
1622 if test $emacs_cv_personality_linux32 = yes; then
1623   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1624             [Define to 1 if personality LINUX32 can be set.])
1625 fi
1626
1627 # Note that Solaris has sys/sysinfo.h which defines struct
1628 # sysinfo as well.  To make sure that we're using GNU/Linux
1629 # sysinfo, we explicitly set one of its fields.
1630 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1631   AC_MSG_CHECKING([if Linux sysinfo may be used])
1632   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1633                                      [[struct sysinfo si;
1634                                        si.totalram = 0;
1635                                        sysinfo (&si)]])],
1636     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1637   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1638   if test $emacs_cv_linux_sysinfo = yes; then
1639     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1640     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1641                                        [[struct sysinfo si; return si.mem_unit]])],
1642       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1643                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1644   fi
1645 fi
1646
1647 dnl On Solaris 8 there's a compilation warning for term.h because
1648 dnl it doesn't define 'bool'.
1649 AC_CHECK_HEADERS(term.h, , , -)
1650 AC_HEADER_TIME
1651 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1652                                       ]])
1653 if test $ac_cv_have_decl_sys_siglist != yes; then
1654   # For Tru64, at least:
1655   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1656                                           ]])
1657 fi
1658 AC_HEADER_SYS_WAIT
1659
1660 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1661 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1662 #if HAVE_SYS_SOCKET_H
1663 #include <sys/socket.h>
1664 #endif])
1665 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1666 #if HAVE_SYS_SOCKET_H
1667 #include <sys/socket.h>
1668 #endif])
1669 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1670 #if HAVE_SYS_SOCKET_H
1671 #include <sys/socket.h>
1672 #endif])
1673
1674 dnl checks for structure members
1675 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1676                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1677                   struct ifreq.ifr_addr,
1678                   struct ifreq.ifr_addr.sa_len], , ,
1679                  [AC_INCLUDES_DEFAULT
1680 #if HAVE_SYS_SOCKET_H
1681 #include <sys/socket.h>
1682 #endif
1683 #if HAVE_NET_IF_H
1684 #include <net/if.h>
1685 #endif])
1686
1687 dnl Check for endianness.
1688 dnl AC_C_BIGENDIAN is done by gnulib.
1689
1690 dnl check for Make feature
1691
1692 AUTO_DEPEND=no
1693 dnl check if we have GCC and autodepend is on.
1694 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1695    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1696    SAVE_CFLAGS="$CFLAGS"
1697    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1698    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1699    CFLAGS="$SAVE_CFLAGS"
1700    test -f deps.d || ac_enable_autodepend=no
1701    rm -rf deps.d
1702    AC_MSG_RESULT([$ac_enable_autodepend])
1703    if test $ac_enable_autodepend = yes; then
1704       AUTO_DEPEND=yes
1705    fi
1706 fi
1707 AC_SUBST(AUTO_DEPEND)
1708
1709 dnl checks for operating system services
1710 AC_SYS_LONG_FILE_NAMES
1711
1712 #### Choose a window system.
1713
1714 ## We leave window_system equal to none if
1715 ## we end up building without one.  Any new window system should
1716 ## set window_system to an appropriate value and add objects to
1717 ## window-system-specific substs.
1718
1719 window_system=none
1720 AC_PATH_X
1721 if test "$no_x" != yes; then
1722   window_system=x11
1723 fi
1724
1725 LD_SWITCH_X_SITE_RPATH=
1726 if test "${x_libraries}" != NONE; then
1727   if test -n "${x_libraries}"; then
1728     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1729     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1730       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1731     `
1732   fi
1733   x_default_search_path=""
1734   x_search_path=${x_libraries}
1735   if test -z "${x_search_path}"; then
1736     x_search_path=/usr/lib
1737   fi
1738   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1739                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1740     x_search_path="\
1741 ${x_library}/X11/%L/%T/%N%C%S:\
1742 ${x_library}/X11/%l/%T/%N%C%S:\
1743 ${x_library}/X11/%T/%N%C%S:\
1744 ${x_library}/X11/%L/%T/%N%S:\
1745 ${x_library}/X11/%l/%T/%N%S:\
1746 ${x_library}/X11/%T/%N%S"
1747     if test x"${x_default_search_path}" = x; then
1748       x_default_search_path=${x_search_path}
1749     else
1750       x_default_search_path="${x_search_path}:${x_default_search_path}"
1751     fi
1752   done
1753 fi
1754 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1755
1756 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1757   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1758 fi
1759
1760 if test x"${x_includes}" = x; then
1761   bitmapdir=/usr/include/X11/bitmaps
1762 else
1763   # accumulate include directories that have X11 bitmap subdirectories
1764   bmd_acc=
1765   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1766     if test -d "${bmd}/X11/bitmaps"; then
1767       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1768     fi
1769     if test -d "${bmd}/bitmaps"; then
1770       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1771     fi
1772   done
1773   bitmapdir=${bmd_acc#:}
1774 fi
1775
1776 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1777 HAVE_NS=no
1778 NS_GNUSTEP_CONFIG=no
1779 NS_IMPL_COCOA=no
1780 NS_IMPL_GNUSTEP=no
1781 tmp_CPPFLAGS="$CPPFLAGS"
1782 tmp_CFLAGS="$CFLAGS"
1783 CPPFLAGS="$CPPFLAGS -x objective-c"
1784 CFLAGS="$CFLAGS -x objective-c"
1785 GNU_OBJC_CFLAGS=
1786 LIBS_GNUSTEP=
1787 if test "${with_ns}" != no; then
1788   if test "${opsys}" = darwin; then
1789      NS_IMPL_COCOA=yes
1790      ns_appdir=`pwd`/nextstep/Emacs.app
1791      ns_appbindir=${ns_appdir}/Contents/MacOS
1792      ns_appresdir=${ns_appdir}/Contents/Resources
1793      ns_appsrc=Cocoa/Emacs.base
1794      ns_fontfile=macfont.o
1795   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1796      NS_IMPL_GNUSTEP=yes
1797      NS_GNUSTEP_CONFIG=yes
1798      GNU_OBJC_CFLAGS=$flags
1799      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1800   elif test -f $GNUSTEP_CONFIG_FILE; then
1801      NS_IMPL_GNUSTEP=yes
1802      dnl FIXME sourcing this several times in subshells seems inefficient.
1803      GNUSTEP_SYSTEM_HEADERS=$(
1804        . $GNUSTEP_CONFIG_FILE
1805        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1806      )
1807      GNUSTEP_SYSTEM_LIBRARIES=$(
1808        . $GNUSTEP_CONFIG_FILE
1809        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1810      )
1811      dnl I seemed to need these as well with GNUstep-startup 0.25.
1812      GNUSTEP_LOCAL_HEADERS=$(
1813        . $GNUSTEP_CONFIG_FILE
1814        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1815      )
1816      GNUSTEP_LOCAL_LIBRARIES=$(
1817        . $GNUSTEP_CONFIG_FILE
1818        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1819      )
1820      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1821        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1822      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1823        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1824      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1825      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1826      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1827      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1828      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1829      dnl If they had chosen to either define it or not, we could have
1830      dnl just used AC_CHECK_DECL here.
1831      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1832        emacs_cv_objc_exceptions,
1833 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1834 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1835 1;
1836 #else
1837 fail;
1838 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1839      if test $emacs_cv_objc_exceptions = yes; then
1840        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1841        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1842          [Define if GNUstep uses ObjC exceptions.])
1843        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1844      fi
1845   fi
1846   if test $NS_IMPL_GNUSTEP = yes; then
1847      ns_appdir=`pwd`/nextstep/Emacs.app
1848      ns_appbindir=${ns_appdir}
1849      ns_appresdir=${ns_appdir}/Resources
1850      ns_appsrc=GNUstep/Emacs.base
1851      ns_fontfile=nsfont.o
1852   fi
1853
1854   dnl This is only used while we test the NS headers, it gets reset below.
1855   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1856   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1857
1858   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1859                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1860 are required for a Nextstep build are missing or cannot be compiled.
1861 Either fix this, or re-configure with the option '--without-ns'.])])
1862
1863   macfont_file=""
1864   if test "${NS_IMPL_COCOA}" = "yes"; then
1865     AC_MSG_CHECKING([for OSX 10.6 or newer])
1866     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1867                                      [
1868 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1869 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1870  ; /* OK */
1871 #else
1872  error "OSX 10.6 or newer required";
1873 #endif
1874 #endif
1875                     ])],
1876                     ns_osx_have_106=yes,
1877                     ns_osx_have_106=no)
1878     AC_MSG_RESULT([$ns_osx_have_106])
1879
1880     if test $ns_osx_have_106 = no; then
1881        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1882     fi
1883   fi
1884 fi
1885
1886 AC_SUBST(LIBS_GNUSTEP)
1887
1888 INSTALL_ARCH_INDEP_EXTRA=install-etc
1889 ns_self_contained=no
1890 NS_OBJ=
1891 NS_OBJC_OBJ=
1892 if test "${HAVE_NS}" = yes; then
1893   if test "$with_toolkit_scroll_bars" = "no"; then
1894     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1895   fi
1896
1897   window_system=nextstep
1898   # set up packaging dirs
1899   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1900      ns_self_contained=yes
1901      prefix=${ns_appresdir}
1902      exec_prefix=${ns_appbindir}
1903      dnl This one isn't really used, only archlibdir is.
1904      libexecdir="\${ns_appbindir}/libexec"
1905      archlibdir="\${ns_appbindir}/libexec"
1906      etcdocdir="\${ns_appresdir}/etc"
1907      etcdir="\${ns_appresdir}/etc"
1908      dnl FIXME maybe set datarootdir instead.
1909      dnl That would also get applications, icons, man.
1910      infodir="\${ns_appresdir}/info"
1911      mandir="\${ns_appresdir}/man"
1912      lispdir="\${ns_appresdir}/lisp"
1913      test "$locallisppathset" = no && locallisppath=""
1914      INSTALL_ARCH_INDEP_EXTRA=
1915   fi
1916
1917   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1918 fi
1919 CFLAGS="$tmp_CFLAGS"
1920 CPPFLAGS="$tmp_CPPFLAGS"
1921 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1922 AC_SUBST(ns_self_contained)
1923 AC_SUBST(NS_OBJ)
1924 AC_SUBST(NS_OBJC_OBJ)
1925
1926 HAVE_W32=no
1927 W32_OBJ=
1928 W32_LIBS=
1929 EMACSRES=
1930 CLIENTRES=
1931 CLIENTW=
1932 W32_RES_LINK=
1933 EMACS_MANIFEST=
1934 UPDATE_MANIFEST=
1935 if test "${with_w32}" != no; then
1936   case "${opsys}" in
1937     cygwin)
1938       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1939              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1940                    cannot be found.])])
1941     ;;
1942     mingw32)
1943     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1944     ;;
1945     *)
1946       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1947     ;;
1948   esac
1949 fi
1950
1951 if test "${opsys}" = "mingw32"; then
1952   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1953   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1954      #include <windows.h>
1955      #include <usp10.h>]],
1956    [[PIMAGE_NT_HEADERS pHeader;
1957      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1958    [emacs_cv_w32api=yes
1959     HAVE_W32=yes],
1960    emacs_cv_w32api=no)
1961   AC_MSG_RESULT($emacs_cv_w32api)
1962   if test "${emacs_cv_w32api}" = "no"; then
1963     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1964   fi
1965 fi
1966
1967 FIRSTFILE_OBJ=
1968 NTDIR=
1969 LIBS_ECLIENT=
1970 LIB_WSOCK32=
1971 NTLIB=
1972 CM_OBJ="cm.o"
1973 XARGS_LIMIT=
1974 if test "${HAVE_W32}" = "yes"; then
1975   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1976   if test "$with_toolkit_scroll_bars" = "no"; then
1977     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1978   fi
1979   AC_CHECK_TOOL(WINDRES, [windres],
1980                 [AC_MSG_ERROR([No resource compiler found.])])
1981   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1982   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1983   EMACSRES="emacs.res"
1984   case "$canonical" in
1985     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1986     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1987   esac
1988   dnl Construct something of the form "24,4,0,0" with 4 components.
1989   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1990
1991   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1992   AC_SUBST(comma_version)
1993   AC_SUBST(comma_space_version)
1994   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1995   if test "${opsys}" = "cygwin"; then
1996     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1997     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1998     # Tell the linker that emacs.res is an object (which we compile from
1999     # the rc file), not a linker script.
2000     W32_RES_LINK="-Wl,emacs.res"
2001   else
2002     UPDATE_MANIFEST=update-game-score.exe.manifest
2003     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
2004     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
2005     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
2006     W32_RES_LINK="\$(EMACSRES)"
2007     CLIENTRES="emacsclient.res"
2008     CLIENTW="emacsclientw\$(EXEEXT)"
2009     FIRSTFILE_OBJ=firstfile.o
2010     NTDIR=nt
2011     CM_OBJ=
2012     LIBS_ECLIENT="-lcomctl32"
2013     LIB_WSOCK32="-lwsock32"
2014     NTLIB="ntlib.$ac_objext"
2015     XARGS_LIMIT="-s 10000"
2016   fi
2017 fi
2018 AC_SUBST(W32_OBJ)
2019 AC_SUBST(W32_LIBS)
2020 AC_SUBST(EMACSRES)
2021 AC_SUBST(EMACS_MANIFEST)
2022 AC_SUBST(UPDATE_MANIFEST)
2023 AC_SUBST(CLIENTRES)
2024 AC_SUBST(CLIENTW)
2025 AC_SUBST(W32_RES_LINK)
2026 AC_SUBST(FIRSTFILE_OBJ)
2027 AC_SUBST(NTDIR)
2028 AC_SUBST(CM_OBJ)
2029 AC_SUBST(LIBS_ECLIENT)
2030 AC_SUBST(LIB_WSOCK32)
2031 AC_SUBST(NTLIB)
2032 AC_SUBST(XARGS_LIMIT)
2033
2034 if test "${HAVE_W32}" = "yes"; then
2035   window_system=w32
2036   with_xft=no
2037 fi
2038
2039 ## $window_system is now set to the window system we will
2040 ## ultimately use.
2041
2042 term_header=
2043 HAVE_X_WINDOWS=no
2044 HAVE_X11=no
2045 USE_X_TOOLKIT=none
2046
2047 case "${window_system}" in
2048   x11 )
2049     HAVE_X_WINDOWS=yes
2050     HAVE_X11=yes
2051     term_header=xterm.h
2052     case "${with_x_toolkit}" in
2053       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2054       motif ) USE_X_TOOLKIT=MOTIF ;;
2055       gtk ) with_gtk=yes
2056             term_header=gtkutil.h
2057 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2058 dnl USE_X_TOOLKIT is set.
2059             USE_X_TOOLKIT=none ;;
2060       gtk2 ) with_gtk2=yes
2061              term_header=gtkutil.h
2062              USE_X_TOOLKIT=none ;;
2063       gtk3 ) with_gtk3=yes
2064              term_header=gtkutil.h
2065              USE_X_TOOLKIT=none ;;
2066       no ) USE_X_TOOLKIT=none ;;
2067 dnl If user did not say whether to use a toolkit, make this decision later:
2068 dnl use the toolkit if we have gtk, or X11R5 or newer.
2069       * ) USE_X_TOOLKIT=maybe ;;
2070     esac
2071   ;;
2072   nextstep )
2073     term_header=nsterm.h
2074   ;;
2075   w32 )
2076     term_header=w32term.h
2077   ;;
2078 esac
2079
2080 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2081    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2082    if test "$HAVE_XSERVER" = true ||
2083       test -n "$DISPLAY" ||
2084       {
2085         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2086         test "$emacs_libX11" != '/usr/lib/libX11.*'
2087       }
2088    then
2089         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2090 were found.  You should install the relevant development files for X
2091 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2092 sure you have development files for image handling, i.e.
2093 tiff, gif, jpeg, png and xpm.
2094 If you are sure you want Emacs compiled without X window support, pass
2095   --without-x
2096 to configure.])
2097    fi
2098 fi
2099
2100 # Does the opsystem file prohibit the use of the GNU malloc?
2101 # Assume not, until told otherwise.
2102 GNU_MALLOC=yes
2103
2104 AC_CACHE_CHECK(
2105   [whether malloc is Doug Lea style],
2106   [emacs_cv_var_doug_lea_malloc],
2107   [emacs_cv_var_doug_lea_malloc=no
2108    dnl Hooks do not work with address sanitization.
2109    if test "$emacs_cv_sanitize_address" != yes; then
2110      AC_LINK_IFELSE(
2111        [AC_LANG_PROGRAM(
2112           [[#include <malloc.h>
2113             static void hook (void) {}]],
2114           [[malloc_set_state (malloc_get_state ());
2115             __after_morecore_hook = hook;
2116             __malloc_initialize_hook = hook;]])],
2117        [emacs_cv_var_doug_lea_malloc=yes])
2118    fi])
2119 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2120
2121 system_malloc=$emacs_cv_sanitize_address
2122
2123 hybrid_malloc=
2124
2125 case "$opsys" in
2126   ## darwin ld insists on the use of malloc routines in the System framework.
2127   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2128   cygwin) hybrid_malloc=yes;;
2129 esac
2130
2131 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2132    && test "${UNEXEC_OBJ}" = unexelf.o; then
2133   hybrid_malloc=yes
2134 fi
2135
2136 GMALLOC_OBJ=
2137 HYBRID_MALLOC=
2138 if test "${system_malloc}" = "yes"; then
2139   AC_DEFINE([SYSTEM_MALLOC], 1,
2140     [Define to 1 to use the system memory allocator, even if it is not
2141      Doug Lea style.])
2142   GNU_MALLOC=no
2143   GNU_MALLOC_reason="
2144     (The GNU allocators don't work with this system configuration.)"
2145   VMLIMIT_OBJ=
2146 elif test "$hybrid_malloc" = yes; then
2147   AC_DEFINE(HYBRID_MALLOC, 1,
2148     [Define to use gmalloc before dumping and the system malloc after.])
2149   HYBRID_MALLOC=1
2150   GNU_MALLOC=
2151   GNU_MALLOC_reason="only before dumping"
2152   GMALLOC_OBJ=gmalloc.o
2153   VMLIMIT_OBJ=
2154 else
2155   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2156   VMLIMIT_OBJ=vm-limit.o
2157
2158   AC_CHECK_HEADERS([sys/vlimit.h])
2159   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2160     [AC_LINK_IFELSE(
2161        [AC_LANG_PROGRAM(
2162          [[extern char data_start[]; char ch;]],
2163          [[return data_start < &ch;]])],
2164        [emacs_cv_data_start=yes],
2165        [emacs_cv_data_start=no])])
2166   if test $emacs_cv_data_start = yes; then
2167     AC_DEFINE([HAVE_DATA_START], 1,
2168       [Define to 1 if data_start is the address of the start
2169        of the main data segment.])
2170   fi
2171 fi
2172 AC_SUBST([HYBRID_MALLOC])
2173 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2174 AC_SUBST(GMALLOC_OBJ)
2175 AC_SUBST(VMLIMIT_OBJ)
2176
2177 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2178   if test "$GNU_MALLOC" = yes ; then
2179     GNU_MALLOC_reason="
2180       (Using Doug Lea's new malloc from the GNU C Library.)"
2181   fi
2182   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2183     [Define to 1 if the system memory allocator is Doug Lea style,
2184      with malloc hooks and malloc_set_state.])
2185
2186   ## Use mmap directly for allocating larger buffers.
2187   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2188   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2189   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2190   case "$opsys" in
2191     mingw32|gnu*) REL_ALLOC=no ;;
2192   esac
2193 fi
2194
2195 if test x"${REL_ALLOC}" = x; then
2196   REL_ALLOC=${GNU_MALLOC}
2197 fi
2198
2199 use_mmap_for_buffers=no
2200 case "$opsys" in
2201   cygwin|mingw32) use_mmap_for_buffers=yes ;;
2202 esac
2203
2204 AC_FUNC_MMAP
2205 if test $use_mmap_for_buffers = yes; then
2206   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2207   REL_ALLOC=no
2208 fi
2209
2210 LIBS="$LIBS_SYSTEM $LIBS"
2211
2212 dnl FIXME replace main with a function we actually want from this library.
2213 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2214
2215 dnl Check for the POSIX thread library.
2216 LIB_PTHREAD=
2217 AC_CHECK_HEADERS_ONCE(pthread.h)
2218 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2219   AC_CACHE_CHECK([for pthread library],
2220     [emacs_cv_pthread_lib],
2221     [emacs_cv_pthread_lib=no
2222      OLD_LIBS=$LIBS
2223      for emacs_pthread_lib in 'none needed' -lpthread; do
2224        case $emacs_pthread_lib in
2225          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2226        esac
2227        AC_LINK_IFELSE(
2228          [AC_LANG_PROGRAM(
2229             [[#include <pthread.h>
2230               #include <signal.h>
2231               sigset_t old_mask, new_mask;
2232               void noop (void) {}]],
2233             [[pthread_t th = pthread_self ();
2234               int status = 0;
2235               status += pthread_create (&th, 0, 0, 0);
2236               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2237               status += pthread_kill (th, 0);
2238               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2239                      || defined DOUG_LEA_MALLOC)
2240               /* Test for pthread_atfork only if gmalloc uses it,
2241                  as older-style hosts like MirBSD 10 lack it.  */
2242               status += pthread_atfork (noop, noop, noop);
2243               #endif
2244               return status;]])],
2245          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2246        LIBS=$OLD_LIBS
2247        if test "$emacs_cv_pthread_lib" != no; then
2248          break
2249        fi
2250      done])
2251   if test "$emacs_cv_pthread_lib" != no; then
2252     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2253     case $emacs_cv_pthread_lib in
2254       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2255     esac
2256     ac_cv_func_pthread_sigmask=yes
2257     # Some systems optimize for single-threaded programs by default, and
2258     # need special flags to disable these optimizations. For example, the
2259     # definition of 'errno' in <errno.h>.
2260     case $opsys in
2261       hpux* | sol*)
2262         AC_DEFINE([_REENTRANT], 1,
2263           [Define to 1 if your system requires this in multithreaded code.]);;
2264       aix4-2)
2265         AC_DEFINE([_THREAD_SAFE], 1,
2266           [Define to 1 if your system requires this in multithreaded code.]);;
2267     esac
2268   fi
2269 fi
2270 AC_SUBST([LIB_PTHREAD])
2271
2272 dnl Check for need for bigtoc support on IBM AIX
2273
2274 case ${host_os} in
2275 aix*)
2276   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2277     case $GCC in
2278     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2279     *) gdb_cv_bigtoc=-bbigtoc ;;
2280     esac
2281
2282     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2283     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2284   ])
2285   ;;
2286 esac
2287
2288 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2289 # is for the tests that follow.  We set them back later on.
2290
2291 REAL_CFLAGS="$CFLAGS"
2292 REAL_CPPFLAGS="$CPPFLAGS"
2293 REAL_LIBS="$LIBS"
2294
2295 if test "${HAVE_X11}" = "yes"; then
2296   DEFS="$C_SWITCH_X_SITE $DEFS"
2297   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2298   LIBS="-lX11 $LIBS"
2299   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2300   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2301
2302   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2303   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2304   # but it's more convenient here to set LD_RUN_PATH since this
2305   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2306   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2307     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2308     export LD_RUN_PATH
2309   fi
2310
2311   if test "${opsys}" = "gnu-linux"; then
2312     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2313     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2314      [[XOpenDisplay ("foo");]])],
2315      [xgnu_linux_first_failure=no],
2316      [xgnu_linux_first_failure=yes])
2317     if test "${xgnu_linux_first_failure}" = "yes"; then
2318       OLD_CPPFLAGS="$CPPFLAGS"
2319       OLD_LIBS="$LIBS"
2320       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2321       LIBS="$LIBS -b i486-linuxaout"
2322       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2323        [[XOpenDisplay ("foo");]])],
2324        [xgnu_linux_second_failure=no],
2325        [xgnu_linux_second_failure=yes])
2326       if test "${xgnu_linux_second_failure}" = "yes"; then
2327         # If we get the same failure with -b, there is no use adding -b.
2328         # So leave it out.  This plays safe.
2329         AC_MSG_RESULT(no)
2330       else
2331         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2332         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2333         AC_MSG_RESULT(yes)
2334       fi
2335       CPPFLAGS=$OLD_CPPFLAGS
2336       LIBS=$OLD_LIBS
2337     else
2338       AC_MSG_RESULT(no)
2339     fi
2340   fi
2341
2342   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2343   # header files included from there.
2344   AC_MSG_CHECKING(for Xkb)
2345   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2346 #include <X11/XKBlib.h>]],
2347         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2348         emacs_xkb=yes, emacs_xkb=no)
2349   AC_MSG_RESULT($emacs_xkb)
2350   if test $emacs_xkb = yes; then
2351     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2352   fi
2353
2354   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2355 XScreenNumberOfScreen)
2356 fi
2357
2358 if test "${window_system}" = "x11"; then
2359   AC_MSG_CHECKING(X11 version 6)
2360   AC_CACHE_VAL(emacs_cv_x11_version_6,
2361   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2362 [[#if XlibSpecificationRelease < 6
2363 fail;
2364 #endif
2365 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2366   if test $emacs_cv_x11_version_6 = yes; then
2367     AC_MSG_RESULT(6 or newer)
2368     AC_DEFINE(HAVE_X11R6, 1,
2369               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2370     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2371     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2372     ## XIM support.
2373     case "$opsys" in
2374       sol2-*) : ;;
2375       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2376            [Define if you have usable X11R6-style XIM support.])
2377          ;;
2378     esac
2379   else
2380     AC_MSG_RESULT(before 6)
2381   fi
2382 fi
2383
2384
2385 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2386 HAVE_RSVG=no
2387 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2388   if test "${with_rsvg}" != "no"; then
2389     RSVG_REQUIRED=2.11.0
2390     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2391
2392     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2393     AC_SUBST(RSVG_CFLAGS)
2394     AC_SUBST(RSVG_LIBS)
2395
2396     if test $HAVE_RSVG = yes; then
2397       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2398       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2399       # Windows loads librsvg dynamically
2400       if test "${opsys}" = "mingw32"; then
2401         RSVG_LIBS=
2402       fi
2403     fi
2404   fi
2405 fi
2406
2407 HAVE_IMAGEMAGICK=no
2408 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2409   if test "${with_imagemagick}" != "no"; then
2410     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2411     ## 6.8.2 makes Emacs crash; see Bug#13867.
2412     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2413     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2414     AC_SUBST(IMAGEMAGICK_CFLAGS)
2415     AC_SUBST(IMAGEMAGICK_LIBS)
2416
2417     if test $HAVE_IMAGEMAGICK = yes; then
2418       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2419       OLD_CFLAGS=$CFLAGS
2420       OLD_LIBS=$LIBS
2421       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2422       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2423       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2424       CFLAGS=$OLD_CFLAGS
2425       LIBS=$OLD_LIBS
2426     fi
2427   fi
2428 fi
2429
2430 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2431 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2432   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2433 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2434   GETADDRINFO_A_LIBS="-lanl"
2435   AC_SUBST(GETADDRINFO_A_LIBS)
2436 fi
2437
2438 HAVE_GTK=no
2439 GTK_OBJ=
2440 gtk_term_header=$term_header
2441 check_gtk2=no
2442 gtk3_pkg_errors=
2443 if test "${opsys}" != "mingw32"; then
2444   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2445     GLIB_REQUIRED=2.28
2446     GTK_REQUIRED=3.0
2447     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2448
2449     dnl Checks for libraries.
2450     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2451       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2452     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2453        AC_MSG_ERROR($GTK_PKG_ERRORS)
2454     fi
2455     if test "$pkg_check_gtk" = "yes"; then
2456        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2457        GTK_OBJ=emacsgtkfixed.o
2458        gtk_term_header=gtkutil.h
2459        USE_GTK_TOOLKIT="GTK3"
2460        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2461          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2462            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2463          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2464            [Define to 1 to disable Glib deprecation warnings.])
2465        fi
2466     else
2467        check_gtk2=yes
2468        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2469     fi
2470   fi
2471
2472   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2473     GLIB_REQUIRED=2.10
2474     GTK_REQUIRED=2.10
2475     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2476
2477     dnl Checks for libraries.
2478     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2479       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2480     if test "$pkg_check_gtk" = "no" &&
2481        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2482     then
2483       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2484     fi
2485     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2486   fi
2487 fi
2488
2489 OLD_CFLAGS=$CFLAGS
2490 OLD_LIBS=$LIBS
2491
2492 if test x"$pkg_check_gtk" = xyes; then
2493
2494   AC_SUBST(GTK_LIBS)
2495   CFLAGS="$CFLAGS $GTK_CFLAGS"
2496   LIBS="$GTK_LIBS $LIBS"
2497   dnl Try to compile a simple GTK program.
2498   AC_MSG_CHECKING([whether GTK compiles])
2499   GTK_COMPILES=no
2500   AC_LINK_IFELSE(
2501     [AC_LANG_PROGRAM(
2502        [[/* Check the Gtk and Glib APIs.  */
2503          #include <gtk/gtk.h>
2504          #include <glib-object.h>
2505          static void
2506          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2507          {}
2508        ]],
2509        [[
2510          GtkSettings *gs = 0;
2511          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2512             strict C prohibits this.  Use gtk_main_iteration to test that the
2513             libraries are there.  */
2514          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2515                                     0, 0, 0, G_CALLBACK (callback), 0))
2516            gtk_main_iteration ();
2517        ]])],
2518     [GTK_COMPILES=yes])
2519   AC_MSG_RESULT([$GTK_COMPILES])
2520   if test "${GTK_COMPILES}" != "yes"; then
2521     GTK_OBJ=
2522     if test "$USE_X_TOOLKIT" != "maybe"; then
2523       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2524     fi
2525   else
2526     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2527     HAVE_GTK=yes
2528     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2529     GTK_OBJ="gtkutil.o $GTK_OBJ"
2530     term_header=$gtk_term_header
2531     USE_X_TOOLKIT=none
2532     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2533        closing open displays.  This is no problem if you just use
2534        one display, but if you use more than one and close one of them
2535        Emacs may crash.
2536        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2537     sleep 3
2538   fi
2539
2540 fi
2541 AC_SUBST(GTK_OBJ)
2542
2543
2544 if test "${HAVE_GTK}" = "yes"; then
2545
2546   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2547   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2548   if test "$with_toolkit_scroll_bars" != no; then
2549     with_toolkit_scroll_bars=yes
2550   fi
2551
2552   dnl  Check if we have the old file selection dialog declared and
2553   dnl  in the link library.  In 2.x it may be in the library,
2554   dnl  but not declared if deprecated featured has been selected out.
2555   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2556   HAVE_GTK_FILE_SELECTION=no
2557   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2558                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2559 #include <gtk/gtk.h>])
2560   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2561     AC_CHECK_FUNCS(gtk_file_selection_new)
2562   fi
2563
2564   dnl Same as above for gtk_handle_box.
2565   HAVE_GTK_HANDLE_BOX=no
2566   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2567                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2568 #include <gtk/gtk.h>])
2569   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2570     AC_CHECK_FUNCS(gtk_handle_box_new)
2571   fi
2572
2573   dnl Same as above for gtk_tearoff_menu_item.
2574   HAVE_GTK_TEAROFF_MENU_ITEM=no
2575   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2576                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2577 #include <gtk/gtk.h>])
2578   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2579     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2580   fi
2581
2582   dnl Check for functions introduced in 2.14 and later.
2583   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2584                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2585                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2586                  gtk_orientable_set_orientation \
2587                  gtk_window_set_has_resize_grip)
2588
2589  term_header=gtkutil.h
2590 fi
2591
2592
2593 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2594 HAVE_XWIDGETS=no
2595 XWIDGETS_OBJ=
2596 if test "$with_xwidgets" != "no"; then
2597   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2598     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2599
2600   WEBKIT_REQUIRED=1.4.0
2601   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2602   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2603   HAVE_XWIDGETS=$HAVE_WEBKIT
2604   test $HAVE_XWIDGETS = yes ||
2605     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2606
2607   XWIDGETS_OBJ=xwidget.o
2608   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2609 fi
2610 AC_SUBST(XWIDGETS_OBJ)
2611
2612 CFLAGS=$OLD_CFLAGS
2613 LIBS=$OLD_LIBS
2614
2615 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2616 dnl other platforms.
2617 HAVE_DBUS=no
2618 DBUS_OBJ=
2619 if test "${with_dbus}" = "yes"; then
2620    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2621    if test "$HAVE_DBUS" = yes; then
2622      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2623      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2624      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2625      dnl D-Bus 1.5.12.
2626      OLD_LIBS=$LIBS
2627      LIBS="$LIBS $DBUS_LIBS"
2628      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2629                     dbus_type_is_valid \
2630                     dbus_validate_bus_name \
2631                     dbus_validate_path \
2632                     dbus_validate_interface \
2633                     dbus_validate_member)
2634      LIBS=$OLD_LIBS
2635      DBUS_OBJ=dbusbind.o
2636    fi
2637 fi
2638 AC_SUBST(DBUS_CFLAGS)
2639 AC_SUBST(DBUS_LIBS)
2640 AC_SUBST(DBUS_OBJ)
2641
2642 dnl GSettings has been tested under GNU/Linux only.
2643 HAVE_GSETTINGS=no
2644 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2645    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2646    if test "$HAVE_GSETTINGS" = "yes"; then
2647       old_CFLAGS=$CFLAGS
2648       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2649       old_LIBS=$LIBS
2650       LIBS="$LIBS $GSETTINGS_LIBS"
2651       AC_MSG_CHECKING([whether GSettings is in gio])
2652       AC_LINK_IFELSE(
2653          [AC_LANG_PROGRAM(
2654              [[/* Check that gsettings really is present.  */
2655              #include <glib-object.h>
2656              #include <gio/gio.h>
2657              ]],
2658              [[
2659                GSettings *settings;
2660                GVariant *val = g_settings_get_value (settings, "");
2661              ]])],
2662          [], HAVE_GSETTINGS=no)
2663       AC_MSG_RESULT([$HAVE_GSETTINGS])
2664
2665       if test "$HAVE_GSETTINGS" = "yes"; then
2666         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2667         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2668         SETTINGS_LIBS="$GSETTINGS_LIBS"
2669       fi
2670       CFLAGS=$old_CFLAGS
2671       LIBS=$old_LIBS
2672    fi
2673 fi
2674
2675 dnl GConf has been tested under GNU/Linux only.
2676 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2677 HAVE_GCONF=no
2678 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2679    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2680    if test "$HAVE_GCONF" = yes; then
2681       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2682       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2683       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2684       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2685    fi
2686 fi
2687
2688 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2689     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2690     if test "$HAVE_GOBJECT" = "yes"; then
2691        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2692        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2693     fi
2694     SAVE_CFLAGS="$CFLAGS"
2695     SAVE_LIBS="$LIBS"
2696     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2697     LIBS="$SETTINGS_LIBS $LIBS"
2698     CFLAGS="$SAVE_CFLAGS"
2699     LIBS="$SAVE_LIBS"
2700 fi
2701 AC_SUBST(SETTINGS_CFLAGS)
2702 AC_SUBST(SETTINGS_LIBS)
2703
2704
2705 dnl SELinux is available for GNU/Linux only.
2706 HAVE_LIBSELINUX=no
2707 LIBSELINUX_LIBS=
2708 if test "${with_selinux}" = "yes"; then
2709    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2710    if test "$HAVE_LIBSELINUX" = yes; then
2711       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2712       LIBSELINUX_LIBS=-lselinux
2713    fi
2714 fi
2715 AC_SUBST(LIBSELINUX_LIBS)
2716
2717 HAVE_GNUTLS=no
2718 if test "${with_gnutls}" = "yes" ; then
2719   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2720     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2721   if test "${HAVE_GNUTLS}" = "yes"; then
2722     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2723     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2724       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2725   fi
2726
2727   # Windows loads GnuTLS dynamically
2728   if test "${opsys}" = "mingw32"; then
2729     LIBGNUTLS_LIBS=
2730   fi
2731 fi
2732
2733 AC_SUBST(LIBGNUTLS_LIBS)
2734 AC_SUBST(LIBGNUTLS_CFLAGS)
2735
2736 HAVE_LIBSYSTEMD=no
2737 if test "${with_libsystemd}" = "yes" ; then
2738   EMACS_CHECK_MODULES([LIBSYSTEMD], [libsystemd >= 226],
2739     [HAVE_LIBSYSTEMD=yes], [HAVE_LIBSYSTEMD=no])
2740   if test "${HAVE_LIBSYSTEMD}" = "yes"; then
2741     AC_DEFINE(HAVE_LIBSYSTEMD, 1, [Define if using libsystemd.])
2742   fi
2743 fi
2744
2745 AC_SUBST(LIBSYSTEMD_LIBS)
2746 AC_SUBST(LIBSYSTEMD_CFLAGS)
2747
2748 NOTIFY_OBJ=
2749 NOTIFY_SUMMARY=no
2750
2751 dnl MS Windows native file monitor is available for mingw32 only.
2752 case $with_file_notification,$opsys in
2753   w32,cygwin)
2754     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2755     this is only supported on MS-Windows native and MinGW32 builds.
2756     Consider using gfile instead.])
2757     ;;
2758   w32,* | yes,mingw32)
2759     AC_CHECK_HEADER(windows.h)
2760     if test "$ac_cv_header_windows_h" = yes ; then
2761        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2762        NOTIFY_OBJ=w32notify.o
2763        NOTIFY_SUMMARY="yes (w32)"
2764     fi ;;
2765 esac
2766
2767 dnl inotify is available only on GNU/Linux.
2768 case $with_file_notification,$NOTIFY_OBJ in
2769   inotify, | yes,)
2770     AC_CHECK_HEADER(sys/inotify.h)
2771     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2772         AC_CHECK_FUNC(inotify_init1)
2773         if test "$ac_cv_func_inotify_init1" = yes; then
2774           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2775           NOTIFY_OBJ=inotify.o
2776           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2777        fi
2778     fi ;;
2779 esac
2780
2781 dnl kqueue is available on BSD-like systems.
2782 case $with_file_notification,$NOTIFY_OBJ in
2783   kqueue,* | yes,)
2784     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2785     if test "$HAVE_KQUEUE" = "yes"; then
2786        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2787        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2788        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2789        NOTIFY_LIBS=$KQUEUE_LIBS
2790        NOTIFY_OBJ=kqueue.o
2791        NOTIFY_SUMMARY="yes -lkqueue"
2792     else
2793        AC_SEARCH_LIBS(kqueue, [])
2794        if test "$ac_cv_search_kqueue" != no; then
2795          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2796          NOTIFY_OBJ=kqueue.o
2797          NOTIFY_SUMMARY="yes (kqueue)"
2798        fi
2799     fi ;;
2800 esac
2801
2802 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2803 dnl has been added in glib 2.24.  It has been tested under
2804 dnl GNU/Linux only.
2805 case $with_file_notification,$NOTIFY_OBJ in
2806   gfile,* | yes,)
2807     if test "${HAVE_NS}" = yes; then
2808        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2809 Consider kqueue instead.])
2810     else
2811        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2812        if test "$HAVE_GFILENOTIFY" = "yes"; then
2813           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2814           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2815           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2816           NOTIFY_OBJ=gfilenotify.o
2817           NOTIFY_SUMMARY="yes -lgio (gfile)"
2818        fi
2819     fi ;;
2820 esac
2821
2822 case $with_file_notification,$NOTIFY_OBJ in
2823   yes,* | no,* | *,?*) ;;
2824   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2825 esac
2826
2827 if test -n "$NOTIFY_OBJ"; then
2828    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2829 fi
2830 AC_SUBST(NOTIFY_CFLAGS)
2831 AC_SUBST(NOTIFY_LIBS)
2832 AC_SUBST(NOTIFY_OBJ)
2833
2834 dnl Do not put whitespace before the #include statements below.
2835 dnl Older compilers (eg sunos4 cc) choke on it.
2836 HAVE_XAW3D=no
2837 LUCID_LIBW=
2838 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2839   if test "$with_xaw3d" != no; then
2840     AC_CACHE_VAL(emacs_cv_xaw3d,
2841     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2842 #include <X11/Intrinsic.h>
2843 #include <X11/Xaw3d/Simple.h>]],
2844       [[]])],
2845       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2846                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2847       emacs_cv_xaw3d=no)])
2848   else
2849     emacs_cv_xaw3d=no
2850   fi
2851   if test $emacs_cv_xaw3d = yes; then
2852     AC_MSG_CHECKING(for xaw3d)
2853     AC_MSG_RESULT([yes; using Lucid toolkit])
2854     USE_X_TOOLKIT=LUCID
2855     HAVE_XAW3D=yes
2856     LUCID_LIBW=-lXaw3d
2857     AC_DEFINE(HAVE_XAW3D, 1,
2858               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2859   else
2860     AC_MSG_CHECKING(for xaw3d)
2861     AC_MSG_RESULT(no)
2862     AC_MSG_CHECKING(for libXaw)
2863     AC_CACHE_VAL(emacs_cv_xaw,
2864     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2865 #include <X11/Intrinsic.h>
2866 #include <X11/Xaw/Simple.h>]],
2867       [[]])],
2868       emacs_cv_xaw=yes,
2869       emacs_cv_xaw=no)])
2870     if test $emacs_cv_xaw = yes; then
2871       AC_MSG_RESULT([yes; using Lucid toolkit])
2872       USE_X_TOOLKIT=LUCID
2873       LUCID_LIBW=-lXaw
2874     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2875       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2876     else
2877       AC_MSG_ERROR([No X toolkit could be found.
2878 If you are sure you want Emacs compiled without an X toolkit, pass
2879   --with-x-toolkit=no
2880 to configure.  Otherwise, install the development libraries for the toolkit
2881 that you want to use (e.g. Gtk+) and re-run configure.])
2882     fi
2883   fi
2884 fi
2885
2886 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2887
2888 LIBXTR6=
2889 LIBXMU=
2890 if test "${USE_X_TOOLKIT}" != "none"; then
2891   AC_MSG_CHECKING(X11 toolkit version)
2892   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2893   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2894 [[#if XtSpecificationRelease < 6
2895 fail;
2896 #endif
2897 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2898   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2899   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2900     AC_MSG_RESULT(6 or newer)
2901     AC_DEFINE(HAVE_X11XTR6, 1,
2902               [Define to 1 if you have the X11R6 or newer version of Xt.])
2903     LIBXTR6="-lSM -lICE"
2904     case "$opsys" in
2905       ## Use libw.a along with X11R6 Xt.
2906       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2907     esac
2908   else
2909     AC_MSG_RESULT(before 6)
2910   fi
2911
2912 dnl If using toolkit, check whether libXmu.a exists.
2913 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2914   OLDLIBS="$LIBS"
2915   if test x$HAVE_X11XTR6 = xyes; then
2916     OTHERLIBS='-lXt -lSM -lICE'
2917   else
2918     OTHERLIBS='-lXt'
2919   fi
2920   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2921   if test "X$LIBS" != "X$OLDLIBS"; then
2922     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2923   fi
2924   LIBS=$OLDLIBS
2925   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2926 fi
2927 AC_SUBST(LIBXTR6)
2928 AC_SUBST(LIBXMU)
2929
2930 LIBXP=
2931 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2932   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2933   if test -d /usr/include/openmotif; then
2934     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2935     emacs_cv_openmotif=yes
2936     case "$canonical" in
2937       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2938       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2939       ;;
2940       *)
2941       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2942     esac
2943   else
2944     emacs_cv_openmotif=no
2945   fi
2946   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2947   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2948     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2949 int x = 5;
2950 #else
2951 Motif version prior to 2.1.
2952 #endif]])],
2953     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2954   if test $emacs_cv_motif_version_2_1 = yes; then
2955     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2956     if test x$emacs_cv_openmotif = xyes; then
2957       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2958     fi
2959   else
2960     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2961     # We put this in CFLAGS temporarily to precede other -I options
2962     # that might be in CFLAGS temporarily.
2963     # We put this in CPPFLAGS where it precedes the other -I options.
2964     OLD_CPPFLAGS=$CPPFLAGS
2965     OLD_CFLAGS=$CFLAGS
2966     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2967     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2968     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2969       [[int x = 5;]])],
2970       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2971     if test $emacs_cv_lesstif = yes; then
2972       # Make sure this -I option remains in CPPFLAGS after it is set
2973       # back to REAL_CPPFLAGS.
2974       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2975       # have those other -I options anyway.  Ultimately, having this
2976       # directory ultimately in CPPFLAGS will be enough.
2977       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2978       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2979     else
2980       CFLAGS=$OLD_CFLAGS
2981       CPPFLAGS=$OLD_CPPFLAGS
2982     fi
2983   fi
2984   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2985     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2986 fi
2987
2988 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2989 dnl using Motif or Xaw3d is available, and unless
2990 dnl --with-toolkit-scroll-bars=no was specified.
2991
2992 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2993             [Define to 1 if we should use toolkit scroll bars.])dnl
2994 USE_TOOLKIT_SCROLL_BARS=no
2995 if test "${with_toolkit_scroll_bars}" != "no"; then
2996   if test "${USE_X_TOOLKIT}" != "none"; then
2997     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2998       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2999       HAVE_XAW3D=no
3000       USE_TOOLKIT_SCROLL_BARS=yes
3001     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
3002       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3003       USE_TOOLKIT_SCROLL_BARS=yes
3004     fi
3005   elif test "${HAVE_GTK}" = "yes"; then
3006     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3007     USE_TOOLKIT_SCROLL_BARS=yes
3008   elif test "${HAVE_NS}" = "yes"; then
3009     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3010     USE_TOOLKIT_SCROLL_BARS=yes
3011   elif test "${HAVE_W32}" = "yes"; then
3012     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
3013     USE_TOOLKIT_SCROLL_BARS=yes
3014   fi
3015 fi
3016
3017 dnl See if XIM is available.
3018 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3019           #include <X11/Xlib.h>
3020           #include <X11/Xresource.h>]],
3021          [[XIMProc  callback;]])],
3022          [HAVE_XIM=yes
3023          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
3024          HAVE_XIM=no)
3025
3026 dnl '--with-xim' now controls only the initial value of use_xim at run time.
3027
3028 if test "${with_xim}" != "no"; then
3029   AC_DEFINE(USE_XIM, 1,
3030             [Define to 1 if we should use XIM, if it is available.])
3031 fi
3032
3033
3034 if test "${HAVE_XIM}" != "no"; then
3035   late_CFLAGS=$CFLAGS
3036   if test "$GCC" = yes; then
3037     CFLAGS="$CFLAGS --pedantic-errors"
3038   fi
3039   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3040 #include <X11/Xlib.h>
3041 #include <X11/Xresource.h>]],
3042 [[Display *display;
3043 XrmDatabase db;
3044 char *res_name;
3045 char *res_class;
3046 XIMProc  callback;
3047 XPointer *client_data;
3048 #ifndef __GNUC__
3049 /* If we're not using GCC, it's probably not XFree86, and this is
3050    probably right, but we can't use something like --pedantic-errors.  */
3051 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3052                                            char*, XIMProc, XPointer*);
3053 #endif
3054 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3055    client_data);]])],
3056     [emacs_cv_arg6_star=yes])
3057   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3058          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3059 either XPointer or XPointer*.])dnl
3060   if test "$emacs_cv_arg6_star" = yes; then
3061     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3062   else
3063     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3064   fi
3065   CFLAGS=$late_CFLAGS
3066 fi
3067
3068 ### Start of font-backend (under any platform) section.
3069 # (nothing here yet -- this is a placeholder)
3070 ### End of font-backend (under any platform) section.
3071
3072 ### Start of font-backend (under X11) section.
3073 if test "${HAVE_X11}" = "yes"; then
3074     ## Use -lXft if available, unless '--with-xft=no'.
3075     HAVE_XFT=maybe
3076     if test "x${with_x}" = "xno"; then
3077       with_xft="no";
3078     fi
3079
3080     if test "$with_xft" != no; then
3081       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3082       with_xft=$HAVE_FONTCONFIG
3083     fi
3084
3085     if test "x${with_xft}" != "xno"; then
3086
3087       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3088       ## Because xftfont.c uses XRenderQueryExtension, we also
3089       ## need to link to -lXrender.
3090       HAVE_XRENDER=no
3091       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3092       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3093         OLD_CPPFLAGS="$CPPFLAGS"
3094         OLD_CFLAGS="$CFLAGS"
3095         OLD_LIBS="$LIBS"
3096         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3097         CFLAGS="$CFLAGS $XFT_CFLAGS"
3098         XFT_LIBS="-lXrender $XFT_LIBS"
3099         LIBS="$XFT_LIBS $LIBS"
3100         AC_CHECK_HEADER(X11/Xft/Xft.h,
3101           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3102           [[#include <X11/X.h>]])
3103
3104         if test "${HAVE_XFT}" = "yes"; then
3105           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3106             AC_SUBST(XFT_LIBS)
3107           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3108         fi                        # "${HAVE_XFT}" = "yes"
3109         CPPFLAGS=$OLD_CPPFLAGS
3110         CFLAGS=$OLD_CFLAGS
3111         LIBS=$OLD_LIBS
3112       fi                          # "$HAVE_XFT" != no
3113     fi                            # "x${with_xft}" != "xno"
3114
3115     ## We used to allow building with FreeType and without Xft.
3116     ## However, the ftx font backend driver is not in good shape.
3117     if test "$HAVE_XFT" != "yes"; then
3118        dnl For the "Does Emacs use" message at the end.
3119        HAVE_XFT=no
3120        HAVE_FREETYPE=no
3121     else
3122        dnl Strict linkers fail with
3123        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3124        dnl if -lfreetype is not specified.
3125        dnl The following is needed to set FREETYPE_LIBS.
3126        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3127
3128        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3129     fi
3130
3131     HAVE_LIBOTF=no
3132     if test "${HAVE_FREETYPE}" = "yes"; then
3133       AC_DEFINE(HAVE_FREETYPE, 1,
3134                 [Define to 1 if using the freetype and fontconfig libraries.])
3135       if test "${with_libotf}" != "no"; then
3136         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3137         if test "$HAVE_LIBOTF" = "yes"; then
3138           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3139           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3140                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3141                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3142           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3143             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3144                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3145           fi
3146         fi
3147       fi
3148     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3149     dnl Does the new font backend require it, or can it work without it?
3150     fi
3151
3152     HAVE_M17N_FLT=no
3153     if test "${HAVE_LIBOTF}" = yes; then
3154       if test "${with_m17n_flt}" != "no"; then
3155         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3156         if test "$HAVE_M17N_FLT" = "yes"; then
3157           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3158         fi
3159       fi
3160     fi
3161 else
3162     HAVE_XFT=no
3163     HAVE_FREETYPE=no
3164     HAVE_LIBOTF=no
3165     HAVE_M17N_FLT=no
3166 fi
3167
3168 ### End of font-backend (under X11) section.
3169
3170 AC_SUBST(FREETYPE_CFLAGS)
3171 AC_SUBST(FREETYPE_LIBS)
3172 AC_SUBST(FONTCONFIG_CFLAGS)
3173 AC_SUBST(FONTCONFIG_LIBS)
3174 AC_SUBST(LIBOTF_CFLAGS)
3175 AC_SUBST(LIBOTF_LIBS)
3176 AC_SUBST(M17N_FLT_CFLAGS)
3177 AC_SUBST(M17N_FLT_LIBS)
3178
3179 HAVE_CAIRO=no
3180 if test "${HAVE_X11}" = "yes"; then
3181   if test "${with_cairo}" != "no"; then
3182     CAIRO_REQUIRED=1.12.0
3183     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3184     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3185     if test $HAVE_CAIRO = yes; then
3186       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3187     else
3188       AC_MSG_ERROR([cairo requested but not found.])
3189     fi
3190
3191     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3192     LIBS="$LIBS $CAIRO_LIBS"
3193     AC_SUBST(CAIRO_CFLAGS)
3194     AC_SUBST(CAIRO_LIBS)
3195   fi
3196 fi
3197
3198 if test "${HAVE_X11}" = "yes"; then
3199   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3200     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3201   if test "${HAVE_XCB}" = "yes"; then
3202     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3203     if test "${HAVE_X11_XCB}" = "yes"; then
3204       AC_DEFINE(USE_XCB, 1,
3205 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3206    X11/XCB programming.])
3207       XCB_LIBS="-lX11-xcb -lxcb"
3208       AC_SUBST(XCB_LIBS)
3209     fi
3210   fi
3211 fi
3212
3213 ### Use -lXpm if available, unless '--with-xpm=no'.
3214 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3215 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3216 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3217 ### LDFLAGS) accordingly.
3218 HAVE_XPM=no
3219 LIBXPM=
3220 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3221   if test "${with_xpm}" != "no"; then
3222     SAVE_CPPFLAGS="$CPPFLAGS"
3223     SAVE_LDFLAGS="$LDFLAGS"
3224     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3225     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3226     AC_CHECK_HEADER(X11/xpm.h,
3227       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3228     if test "${HAVE_XPM}" = "yes"; then
3229       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3230       AC_EGREP_CPP(no_return_alloc_pixels,
3231       [#include "X11/xpm.h"
3232 #ifndef XpmReturnAllocPixels
3233 no_return_alloc_pixels
3234 #endif
3235       ], HAVE_XPM=no, HAVE_XPM=yes)
3236
3237       if test "${HAVE_XPM}" = "yes"; then
3238         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3239         AC_MSG_RESULT(yes)
3240       else
3241         AC_MSG_RESULT(no)
3242         CPPFLAGS="$SAVE_CPPFLAGS"
3243         LDFLAGS="$SAVE_LDFLAGS"
3244       fi
3245     fi
3246   fi
3247
3248   if test "${HAVE_XPM}" = "yes"; then
3249     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3250     LIBXPM=-lXpm
3251   fi
3252 fi
3253
3254 if test "${HAVE_X11}" = "yes"; then
3255   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3256   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3257
3258   if test "${with_xpm}" != "no"; then
3259     AC_CHECK_HEADER(X11/xpm.h,
3260       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3261     if test "${HAVE_XPM}" = "yes"; then
3262       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3263       AC_EGREP_CPP(no_return_alloc_pixels,
3264       [#include "X11/xpm.h"
3265 #ifndef XpmReturnAllocPixels
3266 no_return_alloc_pixels
3267 #endif
3268       ], HAVE_XPM=no, HAVE_XPM=yes)
3269
3270       if test "${HAVE_XPM}" = "yes"; then
3271         AC_MSG_RESULT(yes)
3272       else
3273         AC_MSG_RESULT(no)
3274       fi
3275     fi
3276   fi
3277
3278   if test "${HAVE_XPM}" = "yes"; then
3279     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3280     LIBXPM=-lXpm
3281   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3282     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3283     LIBXPM=-lXpm
3284   fi
3285 fi
3286
3287 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3288 ### slightly different requirements wrt image libraries (it doesn't
3289 ### use -lXpm because it loads the xpm shared library dynamically at
3290 ### run time).
3291 if test "${opsys}" = "mingw32"; then
3292   if test "${with_xpm}" != "no"; then
3293     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3294 #define FOR_MSW 1])
3295   fi
3296
3297   if test "${HAVE_XPM}" = "yes"; then
3298     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3299   fi
3300 fi
3301
3302 AC_SUBST(LIBXPM)
3303
3304 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3305 HAVE_JPEG=no
3306 LIBJPEG=
3307 if test "${with_jpeg}" != "no"; then
3308   AC_CACHE_CHECK([for jpeglib 6b or later],
3309     [emacs_cv_jpeglib],
3310     [OLD_LIBS=$LIBS
3311      for emacs_cv_jpeglib in yes -ljpeg no; do
3312        case $emacs_cv_jpeglib in
3313          yes) ;;
3314          no) break;;
3315          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3316        esac
3317        AC_LINK_IFELSE(
3318          [AC_LANG_PROGRAM(
3319             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3320               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3321               #include <jpeglib.h>
3322               #include <jerror.h>
3323               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3324               struct jpeg_decompress_struct cinfo;
3325             ]],
3326             [[
3327               jpeg_create_decompress (&cinfo);
3328               WARNMS (&cinfo, JWRN_JPEG_EOF);
3329               jpeg_destroy_decompress (&cinfo);
3330             ]])],
3331          [emacs_link_ok=yes],
3332          [emacs_link_ok=no])
3333        LIBS=$OLD_LIBS
3334        test $emacs_link_ok = yes && break
3335      done])
3336   if test "$emacs_cv_jpeglib" != no; then
3337     HAVE_JPEG=yes
3338     AC_DEFINE([HAVE_JPEG], 1,
3339       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3340     ### mingw32 doesn't use -ljpeg, since it loads the library
3341     ### dynamically when needed, and doesn't want a run-time
3342     ### dependency on the jpeglib DLL.
3343     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3344     && LIBJPEG=$emacs_cv_jpeglib
3345   fi
3346 fi
3347 AC_SUBST(LIBJPEG)
3348
3349 HAVE_ZLIB=no
3350 LIBZ=
3351 if test "${with_zlib}" != "no"; then
3352   OLIBS=$LIBS
3353   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3354   LIBS=$OLIBS
3355   case $ac_cv_search_inflateEnd in
3356     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3357   esac
3358 fi
3359 if test "${HAVE_ZLIB}" = "yes"; then
3360   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3361   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3362   if test "${opsys}" = "mingw32"; then
3363      LIBZ=
3364   fi
3365 fi
3366 AC_SUBST(LIBZ)
3367
3368 ### Dynamic modules support
3369 LIBMODULES=
3370 HAVE_MODULES=no
3371 MODULES_OBJ=
3372 MODULES_SUFFIX=
3373 if test "${with_modules}" != "no"; then
3374   if test "$opsys" = "gnu-linux"; then
3375     LIBMODULES="-ldl"
3376     MODULES_SUFFIX=".so"
3377     HAVE_MODULES=yes
3378   elif test "$opsys" = "cygwin"; then
3379     MODULES_SUFFIX=".dll"
3380     HAVE_MODULES=yes
3381   elif test "$opsys" = "darwin"; then
3382     MODULES_SUFFIX=".so"
3383     HAVE_MODULES=yes
3384   elif test "$opsys" = "mingw32"; then
3385     MODULES_SUFFIX=".dll"
3386     HAVE_MODULES=yes
3387   else
3388     # BSD system have dlopen in the libc
3389     AC_CHECK_FUNC(dlopen, [MODULES_SUFFIX=".so"]
3390                           [HAVE_MODULES=yes], [])
3391   fi
3392
3393   if test "${HAVE_MODULES}" = no; then
3394     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3395   else
3396     SAVE_LIBS=$LIBS
3397     LIBS="$LIBS $LIBMODULES"
3398     AC_CHECK_FUNCS([dladdr dlfunc])
3399     LIBS=$SAVE_LIBS
3400   fi
3401 fi
3402
3403 if test "${HAVE_MODULES}" = yes; then
3404    MODULES_OBJ="dynlib.o emacs-module.o"
3405    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3406    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3407      [System extension for dynamic libraries])
3408 fi
3409 AC_SUBST(MODULES_OBJ)
3410 AC_SUBST(LIBMODULES)
3411
3412 ### Use -lpng if available, unless '--with-png=no'.
3413 HAVE_PNG=no
3414 LIBPNG=
3415 PNG_CFLAGS=
3416 if test "${NS_IMPL_COCOA}" = yes; then
3417   : # Nothing to do
3418 elif test "${with_png}" != no; then
3419   # mingw32 loads the library dynamically.
3420   if test "$opsys" = mingw32; then
3421     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3422   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3423     AC_MSG_CHECKING([for png])
3424     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3425     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3426       # libpng-config does not work; configure by hand.
3427       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3428       # in /usr/include/libpng.
3429       if test -r /usr/include/libpng/png.h &&
3430          test ! -r /usr/include/png.h; then
3431         png_cflags=-I/usr/include/libpng
3432       else
3433         png_cflags=
3434       fi
3435       png_libs='-lpng'
3436     }
3437     SAVE_CFLAGS=$CFLAGS
3438     SAVE_LIBS=$LIBS
3439     CFLAGS="$CFLAGS $png_cflags"
3440     LIBS="$png_libs -lz -lm $LIBS"
3441     AC_LINK_IFELSE(
3442       [AC_LANG_PROGRAM([[#include <png.h>]],
3443          [[return !png_get_channels (0, 0);]])],
3444       [HAVE_PNG=yes
3445        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3446        LIBPNG=$png_libs
3447        # $LIBPNG requires explicit -lz in some cases.
3448        # We don't know what those cases are, exactly, so play it safe and
3449        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3450        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3451          LIBPNG="$LIBPNG -lz"
3452        fi])
3453     CFLAGS=$SAVE_CFLAGS
3454     LIBS=$SAVE_LIBS
3455     AC_MSG_RESULT([$HAVE_PNG])
3456   fi
3457 fi
3458 if test $HAVE_PNG = yes; then
3459   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3460
3461   SAVE_CFLAGS=$CFLAGS
3462   CFLAGS="$CFLAGS $PNG_CFLAGS"
3463   AC_CHECK_DECL([png_longjmp],
3464     [],
3465     [AC_DEFINE([PNG_DEPSTRUCT], [],
3466        [Define to empty to suppress deprecation warnings when building
3467         with --enable-gcc-warnings and with libpng versions before 1.5,
3468         which lack png_longjmp.])],
3469     [[#include <png.h>
3470     ]])
3471   CFLAGS=$SAVE_CFLAGS
3472 fi
3473 AC_SUBST(LIBPNG)
3474 AC_SUBST(PNG_CFLAGS)
3475
3476 ### Use -ltiff if available, unless '--with-tiff=no'.
3477 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3478 HAVE_TIFF=no
3479 LIBTIFF=
3480 if test "${opsys}" = "mingw32"; then
3481   if test "${with_tiff}" != "no"; then
3482     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3483   fi
3484   if test "${HAVE_TIFF}" = "yes"; then
3485     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3486   fi
3487 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3488   if test "${with_tiff}" != "no"; then
3489     AC_CHECK_HEADER(tiffio.h,
3490       [tifflibs="-lz -lm"
3491       # At least one tiff package requires the jpeg library.
3492       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3493       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3494   fi
3495
3496   if test "${HAVE_TIFF}" = "yes"; then
3497     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3498     dnl FIXME -lz -lm, as per libpng?
3499     LIBTIFF=-ltiff
3500   fi
3501 fi
3502 AC_SUBST(LIBTIFF)
3503
3504 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3505 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3506 HAVE_GIF=no
3507 LIBGIF=
3508 if test "${opsys}" = "mingw32"; then
3509   if test "${with_gif}" != "no"; then
3510     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3511   fi
3512   if test "${HAVE_GIF}" = "yes"; then
3513     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3514   fi
3515 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3516         || test "${HAVE_W32}" = "yes"; then
3517   AC_CHECK_HEADER(gif_lib.h,
3518 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3519 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3520     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3521         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3522
3523   if test "$HAVE_GIF" = yes; then
3524     LIBGIF=-lgif
3525   elif test "$HAVE_GIF" = maybe; then
3526 # If gif_lib.h but no libgif, try libungif.
3527     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3528     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3529   fi
3530
3531   if test "${HAVE_GIF}" = "yes"; then
3532     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3533   fi
3534 fi
3535 AC_SUBST(LIBGIF)
3536
3537 dnl Check for required libraries.
3538 if test "${HAVE_X11}" = "yes"; then
3539   MISSING=""
3540   WITH_NO=""
3541   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3542     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3543   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3544     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3545   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3546     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3547   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3548     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3549   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3550     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3551
3552   if test "X${MISSING}" != X; then
3553     AC_MSG_ERROR([The following required libraries were not found:
3554     $MISSING
3555 Maybe some development libraries/packages are missing?
3556 If you don't want to link with them give
3557     $WITH_NO
3558 as options to configure])
3559   fi
3560 fi
3561
3562 ### Use -lgpm if available, unless '--with-gpm=no'.
3563 HAVE_GPM=no
3564 LIBGPM=
3565 if test "${with_gpm}" != "no"; then
3566   AC_CHECK_HEADER(gpm.h,
3567     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3568
3569   if test "${HAVE_GPM}" = "yes"; then
3570     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3571     LIBGPM=-lgpm
3572   fi
3573 fi
3574 AC_SUBST(LIBGPM)
3575
3576 dnl Check for malloc/malloc.h on darwin
3577 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3578
3579 GNUSTEP_CFLAGS=
3580 ### Use NeXTstep API to implement GUI.
3581 if test "${HAVE_NS}" = "yes"; then
3582   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3583   if test "${NS_IMPL_COCOA}" = "yes"; then
3584     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3585   fi
3586   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3587     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3588     if test $NS_GNUSTEP_CONFIG != yes; then
3589       # See also .m.o rule in src/Makefile.in.  */
3590       # FIXME: are all these flags really needed?  Document here why.  */
3591       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3592       ## Extra CFLAGS applied to src/*.m files.
3593       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3594     fi
3595   fi
3596   OTHER_FILES=ns-app
3597 fi
3598
3599 ### Use session management (-lSM -lICE) if available
3600 HAVE_X_SM=no
3601 LIBXSM=
3602 if test "${HAVE_X11}" = "yes"; then
3603   AC_CHECK_HEADER(X11/SM/SMlib.h,
3604     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3605
3606   if test "${HAVE_X_SM}" = "yes"; then
3607     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3608     LIBXSM="-lSM -lICE"
3609   fi
3610 fi
3611 AC_SUBST(LIBXSM)
3612
3613 ### Use XRandr (-lXrandr) if available
3614 HAVE_XRANDR=no
3615 if test "${HAVE_X11}" = "yes"; then
3616   XRANDR_REQUIRED=1.2.2
3617   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3618   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3619   if test $HAVE_XRANDR = no; then
3620     # Test old way in case pkg-config doesn't have it (older machines).
3621     # Include Xrender.h by hand to work around bug in older Xrandr.h
3622     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3623     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3624       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3625       [], [AC_INCLUDES_DEFAULT
3626 #include <X11/extensions/Xrender.h>])
3627     if test $HAVE_XRANDR = yes; then
3628       XRANDR_LIBS=-lXrandr
3629     fi
3630   fi
3631   if test $HAVE_XRANDR = yes; then
3632     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3633   fi
3634 fi
3635 AC_SUBST(XRANDR_CFLAGS)
3636 AC_SUBST(XRANDR_LIBS)
3637
3638 ### Use Xinerama (-lXinerama) if available
3639 HAVE_XINERAMA=no
3640 if test "${HAVE_X11}" = "yes"; then
3641   XINERAMA_REQUIRED=1.0.2
3642   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3643   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3644   if test $HAVE_XINERAMA = no; then
3645     # Test old way in case pkg-config doesn't have it (older machines).
3646     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3647       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3648     if test $HAVE_XINERAMA = yes; then
3649       XINERAMA_LIBS=-lXinerama
3650     fi
3651   fi
3652   if test $HAVE_XINERAMA = yes; then
3653     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3654   fi
3655 fi
3656 AC_SUBST(XINERAMA_CFLAGS)
3657 AC_SUBST(XINERAMA_LIBS)
3658
3659 ### Use Xfixes (-lXfixes) if available
3660 HAVE_XFIXES=no
3661 if test "${HAVE_X11}" = "yes"; then
3662   XFIXES_REQUIRED=4.0.0
3663   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3664   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3665   if test $HAVE_XFIXES = no; then
3666     # Test old way in case pkg-config doesn't have it (older machines).
3667     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3668       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3669     if test $HAVE_XFIXES = yes; then
3670       XFIXES_LIBS=-lXfixes
3671     fi
3672   fi
3673   if test $HAVE_XFIXES = yes; then
3674     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3675   fi
3676 fi
3677 AC_SUBST(XFIXES_CFLAGS)
3678 AC_SUBST(XFIXES_LIBS)
3679
3680 ### Use libxml (-lxml2) if available
3681 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3682 HAVE_LIBXML2=no
3683 if test "${with_xml2}" != "no"; then
3684   ### I'm not sure what the version number should be, so I just guessed.
3685   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3686   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3687   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3688     SAVE_CPPFLAGS="$CPPFLAGS"
3689     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3690       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3691       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3692       case $xcsdkdir in
3693         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3694         xcsdkdir="" ;;
3695       esac
3696     fi
3697     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3698     AC_CHECK_HEADER(libxml/HTMLparser.h,
3699       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3700                      [#include <libxml/HTMLparser.h>])])
3701     CPPFLAGS="$SAVE_CPPFLAGS"
3702     if test "${HAVE_LIBXML2}" = "yes"; then
3703       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3704       LIBXML2_LIBS="-lxml2"
3705     fi
3706   fi
3707   if test "${HAVE_LIBXML2}" = "yes"; then
3708     if test "${opsys}" != "mingw32"; then
3709       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3710         [$LIBXML2_LIBS])
3711     else
3712       LIBXML2_LIBS=""
3713     fi
3714     if test "${HAVE_LIBXML2}" = "yes"; then
3715       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3716     else
3717       LIBXML2_LIBS=""
3718       LIBXML2_CFLAGS=""
3719     fi
3720   fi
3721 fi
3722 AC_SUBST(LIBXML2_LIBS)
3723 AC_SUBST(LIBXML2_CFLAGS)
3724
3725 # Check for mail-locking functions in a "mail" library.  Probably this should
3726 # have the same check as for liblockfile below.
3727 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3728 if test $have_mail = yes; then
3729   LIBS_MAIL=-lmail
3730   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3731
3732   OLD_LIBS=$LIBS
3733   LIBS="$LIBS_MAIL $LIBS"
3734   AC_CHECK_FUNCS(touchlock)
3735   LIBS=$OLD_LIBS
3736 else
3737   LIBS_MAIL=
3738 fi
3739 dnl Debian, at least:
3740 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3741 if test $have_lockfile = yes; then
3742    LIBS_MAIL=-llockfile
3743    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3744 else
3745 # If we have the shared liblockfile, assume we must use it for mail
3746 # locking (e.g. Debian).  If we couldn't link against liblockfile
3747 # (no liblockfile.a installed), ensure that we don't need to.
3748   dnl This works for files generally, not just executables.
3749   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3750   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3751                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3752   if test $ac_cv_prog_liblockfile = yes; then
3753     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3754 This probably means that movemail could lose mail.
3755 There may be a 'development' package to install containing liblockfile.])
3756   fi
3757 fi
3758 AC_CHECK_HEADERS_ONCE(maillock.h)
3759 AC_SUBST(LIBS_MAIL)
3760
3761 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3762 ## interlock access to the mail spool.  The alternative is a lock file named
3763 ## /usr/spool/mail/$USER.lock.
3764 mail_lock=no
3765 case "$opsys" in
3766   aix4-2) mail_lock="lockf" ;;
3767
3768   gnu|freebsd|dragonfly|netbsd|openbsd|darwin) mail_lock="flock" ;;
3769
3770   ## On GNU/Linux systems, both methods are used by various mail programs.
3771   ## I assume most people are using newer mailers that have heard of flock.
3772   ## Change this if you need to.
3773   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3774   ## configure gets the right answers, and that means *NOT* using flock.
3775   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3776   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3777   ## Debian maintainer hasn't provided a clean fix for Emacs.
3778   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3779   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3780   ## correct logic.  -- fx
3781   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3782   ## liblockfile is a Free Software replacement for libmail, used on
3783   ## Debian systems and elsewhere. -rfr.
3784   gnu-*)
3785     mail_lock="flock"
3786     if test $have_mail = yes || test $have_lockfile = yes; then
3787       test $ac_cv_header_maillock_h = yes && mail_lock=no
3788     fi
3789     ;;
3790
3791   mingw32)
3792     mail_lock="none-needed" ;;
3793 esac
3794
3795 BLESSMAIL_TARGET=
3796 case "$mail_lock" in
3797   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3798
3799   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3800
3801   none-needed) ;;
3802
3803   *) BLESSMAIL_TARGET="need-blessmail" ;;
3804 esac
3805 AC_SUBST(BLESSMAIL_TARGET)
3806
3807 OLD_LIBS=$LIBS
3808 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3809 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3810 getrusage get_current_dir_name \
3811 lrand48 random rint \
3812 select getpagesize setlocale newlocale \
3813 getrlimit setrlimit shutdown \
3814 pthread_sigmask strsignal setitimer \
3815 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3816 gai_strerror sync \
3817 getpwent endpwent getgrent endgrent \
3818 cfmakeraw cfsetspeed copysign __executable_start log2)
3819 LIBS=$OLD_LIBS
3820
3821 dnl No need to check for posix_memalign if aligned_alloc works.
3822 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3823 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3824
3825 dnl Cannot use AC_CHECK_FUNCS
3826 AC_CACHE_CHECK([for __builtin_unwind_init],
3827                emacs_cv_func___builtin_unwind_init,
3828 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3829                 emacs_cv_func___builtin_unwind_init=yes,
3830                 emacs_cv_func___builtin_unwind_init=no)])
3831 if test $emacs_cv_func___builtin_unwind_init = yes; then
3832   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3833             [Define to 1 if you have the '__builtin_unwind_init' function.])
3834 fi
3835
3836 AC_CHECK_HEADERS_ONCE(sys/un.h)
3837
3838 AC_FUNC_FSEEKO
3839
3840 # UNIX98 PTYs.
3841 AC_CHECK_FUNCS(grantpt)
3842
3843 # PTY-related GNU extensions.
3844 AC_CHECK_FUNCS(getpt posix_openpt)
3845
3846 # Check this now, so that we will NOT find the above functions in ncurses.
3847 # That is because we have not set up to link ncurses in lib-src.
3848 # It's better to believe a function is not available
3849 # than to expect to find it in ncurses.
3850 # Also we need tputs and friends to be able to build at all.
3851 AC_MSG_CHECKING([for library containing tputs])
3852 # Run a test program that contains a call to tputs, a call that is
3853 # never executed.  This tests whether a pre-'main' dynamic linker
3854 # works with the library.  It's too much trouble to actually call
3855 # tputs in the test program, due to portability hassles.  When
3856 # cross-compiling, assume the test program will run if it links.
3857 AC_DEFUN([tputs_link_source], [
3858   AC_LANG_SOURCE(
3859      [[extern void tputs (const char *, int, int (*)(int));
3860        int main (int argc, char **argv)
3861        {
3862           if (argc == 10000)
3863             tputs (argv[0], 0, 0);
3864           return 0;
3865        }]])
3866 ])
3867 if test "${opsys}" = "mingw32"; then
3868   msg='none required'
3869 else
3870   # Maybe curses should be tried earlier?
3871   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3872   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3873     OLIBS=$LIBS
3874     if test -z "$tputs_library"; then
3875       LIBS_TERMCAP=
3876       msg='none required'
3877     else
3878       LIBS_TERMCAP=-l$tputs_library
3879       msg=$LIBS_TERMCAP
3880       LIBS="$LIBS_TERMCAP $LIBS"
3881     fi
3882     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3883       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3884     LIBS=$OLIBS
3885     if test "X$msg" != Xno; then
3886       break
3887     fi
3888   done
3889 fi
3890 AC_MSG_RESULT([$msg])
3891 if test "X$msg" = Xno; then
3892   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3893 The following libraries were tried (in order):
3894   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3895 Please try installing whichever of these libraries is most appropriate
3896 for your system, together with its header files.
3897 For example, a libncurses-dev(el) or similar package.])
3898 fi
3899
3900 ## Use termcap instead of terminfo?
3901 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3902 TERMINFO=yes
3903 ## FIXME?  In the cases below where we unconditionally set
3904 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3905 ## if that was found above to have tputs.
3906 ## Should we use the gnu* logic everywhere?
3907 case "$opsys" in
3908   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3909   ##  The ncurses library has been moved out of the System framework in
3910   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3911   ##  option to use it.
3912   darwin) LIBS_TERMCAP="-lncurses" ;;
3913
3914   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3915
3916   freebsd)
3917     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3918     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3919     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3920 [[#if __FreeBSD_version < 400000
3921 fail;
3922 #endif
3923 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3924
3925     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3926
3927     if test $emacs_cv_freebsd_terminfo = yes; then
3928       LIBS_TERMCAP="-lncurses"
3929     else
3930       TERMINFO=no
3931       LIBS_TERMCAP="-ltermcap"
3932     fi
3933     ;;
3934
3935   mingw32)
3936     TERMINFO=no
3937     LIBS_TERMCAP=
3938     ;;
3939
3940   netbsd)
3941     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3942       TERMINFO=no
3943       LIBS_TERMCAP="-ltermcap"
3944     fi
3945     ;;
3946
3947   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3948
3949   ## hpux: Make sure we get select from libc rather than from libcurses
3950   ##  because libcurses on HPUX 10.10 has a broken version of select.
3951   ##  We used to use -lc -lcurses, but this may be cleaner.
3952   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3953   # set that way, now it uses the default).  Isn't this a contradiction?
3954   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3955
3956 esac
3957
3958 TERMCAP_OBJ=tparam.o
3959 if test $TERMINFO = yes; then
3960   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3961   TERMCAP_OBJ=terminfo.o
3962 fi
3963 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3964   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3965 fi
3966 AC_SUBST(LIBS_TERMCAP)
3967 AC_SUBST(TERMCAP_OBJ)
3968
3969 # GNU/Linux-specific timer functions.
3970 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3971   [AC_COMPILE_IFELSE(
3972      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3973                       ]],
3974                       [[timerfd_create (CLOCK_REALTIME,
3975                                         TFD_CLOEXEC | TFD_NONBLOCK);
3976                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3977      [emacs_cv_have_timerfd=yes],
3978      [emacs_cv_have_timerfd=no])])
3979 if test "$emacs_cv_have_timerfd" = yes; then
3980   AC_DEFINE([HAVE_TIMERFD], 1,
3981     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3982 fi
3983
3984 # Alternate stack for signal handlers.
3985 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3986                [emacs_cv_alternate_stack],
3987   [AC_COMPILE_IFELSE(
3988      [AC_LANG_PROGRAM([[#include <signal.h>
3989                       ]],
3990                       [[stack_t ss;
3991                         struct sigaction sa;
3992                         ss.ss_sp = malloc (SIGSTKSZ);
3993                         ss.ss_size = SIGSTKSZ;
3994                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3995                         sigaltstack (&ss, 0);
3996                         sigaction (SIGSEGV, &sa, 0);]])],
3997      [emacs_cv_alternate_stack=yes],
3998      [emacs_cv_alternate_stack=no])])
3999
4000 # Do we need the Hesiod library to provide the support routines?
4001 dnl FIXME?  Should we be skipping this on Darwin too?
4002 LIBHESIOD=
4003 LIBRESOLV=
4004 if test "$with_hesiod" != no ; then
4005   # Don't set $LIBS here -- see comments above.  FIXME which comments?
4006   resolv=no
4007   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4008      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4009                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4010   if test "$resolv" = yes ; then
4011     RESOLVLIB=-lresolv
4012   else
4013     RESOLVLIB=
4014   fi
4015   hesiod=no
4016   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4017         hesiod=yes, :, $RESOLVLIB)])
4018
4019   if test x"$hesiod" = xyes; then
4020     LIBHESIOD=-lhesiod
4021     LIBRESOLV=$RESOLVLIB
4022   fi
4023 fi
4024 AC_SUBST(LIBHESIOD)
4025 AC_SUBST(LIBRESOLV)
4026
4027 # These tell us which Kerberos-related libraries to use.
4028 COM_ERRLIB=
4029 CRYPTOLIB=
4030 KRB5LIB=
4031 DESLIB=
4032 KRB4LIB=
4033
4034 if test "${with_kerberos}" != no; then
4035   OLD_LIBS=$LIBS
4036   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4037   if test $have_com_err = yes; then
4038     COM_ERRLIB=-lcom_err
4039     LIBS="$COM_ERRLIB $LIBS"
4040   fi
4041   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4042   if test $have_crypto = yes; then
4043     CRYPTOLIB=-lcrypto
4044     LIBS="$CRYPTOLIB $LIBS"
4045   fi
4046   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4047   if test $have_k5crypto = yes; then
4048     CRYPTOLIB=-lk5crypto
4049     LIBS="$CRYPTOLIB $LIBS"
4050   fi
4051   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4052   if test $have_krb5=yes; then
4053     KRB5LIB=-lkrb5
4054     LIBS="$KRB5LIB $LIBS"
4055   fi
4056   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4057   if test "${with_kerberos5}" = no; then
4058     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4059     if test $have_des425 = yes; then
4060       DESLIB=-ldes425
4061       LIBS="$DESLIB $LIBS"
4062     else
4063       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4064       if test $have_des = yes; then
4065         DESLIB=-ldes
4066         LIBS="$DESLIB $LIBS"
4067       fi
4068     fi
4069     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4070     if test $have_krb4 = yes; then
4071       KRB4LIB=-lkrb4
4072       LIBS="$KRB4LIB $LIBS"
4073     else
4074       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4075       if test $have_krb = yes; then
4076         KRB4LIB=-lkrb
4077         LIBS="$KRB4LIB $LIBS"
4078       fi
4079     fi
4080   fi
4081
4082   if test "${with_kerberos5}" != no; then
4083     AC_CHECK_HEADERS(krb5.h,
4084       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4085                         [#include <krb5.h>])])
4086   else
4087     AC_CHECK_HEADERS(krb.h,,
4088                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4089                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4090   fi
4091   AC_CHECK_HEADERS(com_err.h)
4092   LIBS=$OLD_LIBS
4093 fi
4094
4095 AC_SUBST(COM_ERRLIB)
4096 AC_SUBST(CRYPTOLIB)
4097 AC_SUBST(KRB5LIB)
4098 AC_SUBST(DESLIB)
4099 AC_SUBST(KRB4LIB)
4100
4101 AC_CHECK_HEADERS(valgrind/valgrind.h)
4102
4103 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4104
4105 AC_CHECK_FUNCS_ONCE(tzset)
4106
4107 ok_so_far=yes
4108 AC_CHECK_FUNC(socket, , ok_so_far=no)
4109 if test $ok_so_far = yes; then
4110   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4111 fi
4112 if test $ok_so_far = yes; then
4113   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4114 fi
4115 if test $ok_so_far = yes; then
4116 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4117   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4118             [Define to 1 if you have inet sockets.])
4119 fi
4120
4121 AC_FUNC_FORK
4122
4123 AC_CHECK_FUNCS(snprintf)
4124
4125 dnl Check for glib.  This differs from other library checks in that
4126 dnl Emacs need not link to glib unless some other library is already
4127 dnl linking to glib.  Although glib provides no facilities that Emacs
4128 dnl needs for its own purposes, when glib is present Emacs needs to
4129 dnl use primitives like g_main_context_query to avoid clashing with
4130 dnl glib at a low level.
4131 dnl
4132 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4133 XGSELOBJ=
4134 OLDCFLAGS="$CFLAGS"
4135 OLDLIBS="$LIBS"
4136 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4137 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4138 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4139 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4140 AC_MSG_CHECKING([whether GLib is linked in])
4141 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4142         [[#include <glib.h>
4143         ]],
4144         [[g_print ("Hello world");]])],
4145      [links_glib=yes],
4146      [links_glib=no])
4147 AC_MSG_RESULT([$links_glib])
4148 if test "${links_glib}" = "yes"; then
4149   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4150   if test "$HAVE_NS" = no;then
4151     XGSELOBJ=xgselect.o
4152   fi
4153 fi
4154 CFLAGS="$OLDCFLAGS"
4155 LIBS="$OLDLIBS"
4156 AC_SUBST(XGSELOBJ)
4157
4158 dnl Adapted from Haible's version.
4159 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4160   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4161     [[char* cs = nl_langinfo(CODESET);]])],
4162     emacs_cv_langinfo_codeset=yes,
4163     emacs_cv_langinfo_codeset=no)
4164   ])
4165 if test $emacs_cv_langinfo_codeset = yes; then
4166   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4167     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4168 fi
4169
4170 AC_TYPE_MBSTATE_T
4171
4172 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4173 dnl how the tty code is related to POSIX and/or other versions of termios.
4174 dnl The following looks like a useful start.
4175 dnl
4176 dnl AC_SYS_POSIX_TERMIOS
4177 dnl if test $ac_cv_sys_posix_termios = yes; then
4178 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4179 dnl                                and macros for terminal control.])
4180 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4181 dnl fi
4182
4183 dnl Turned on June 1996 supposing nobody will mind it.
4184 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4185 if test "${opsys}" != "mingw32"; then
4186    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4187      in the full name stands for the login id.])
4188 fi
4189
4190 dnl Everybody supports this, except MS.
4191 dnl Seems like the kind of thing we should be testing for, though.
4192 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4193 if test "${opsys}" != "mingw32"; then
4194   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4195 fi
4196
4197 dnl Everybody supports this, except MS-DOS.
4198 dnl Seems like the kind of thing we should be testing for, though.
4199 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4200 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4201   4.2-compatible sockets.])
4202
4203 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4204
4205 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4206   a null file, or a data sink.])
4207 if test "${opsys}" = "mingw32"; then
4208   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4209 else
4210   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4211 fi
4212
4213 if test "${opsys}" = "mingw32"; then
4214   SEPCHAR=';'
4215 else
4216   SEPCHAR=':'
4217 fi
4218 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4219 dnl This is for MinGW, and is used in test/Makefile.in.
4220 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4221 dnl decides that a command-line argument to be passed to a MinGW program
4222 dnl is a PATH-style list of directories.  But that heuristics plays it
4223 dnl safe, and only does the replacement when it is _absolutely_ sure it
4224 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4225 dnl which breaks in-tree builds.  So we do this manually instead.
4226 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4227 dnl be computed as ':' in MSYS Bash.
4228 AC_SUBST(SEPCHAR)
4229
4230 dnl Everybody supports this, except MS-DOS.
4231 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4232
4233 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4234
4235
4236 AC_DEFINE(DIRECTORY_SEP, ['/'],
4237   [Character that separates directories in a file name.])
4238
4239 if test "${opsys}" = "mingw32"; then
4240   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4241     [Returns true if character is a device separator.])
4242
4243   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4244     [Returns true if character is a directory separator.])
4245
4246   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4247     [Returns true if character is any form of separator.])
4248 else
4249   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4250     [Returns true if character is a device separator.])
4251
4252   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4253     [Returns true if character is a directory separator.])
4254
4255   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4256     [Returns true if character is any form of separator.])
4257 fi
4258
4259 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4260
4261 case $opsys in
4262   aix4-2)
4263     dnl Unfortunately without libXmu we cannot support EditRes.
4264     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4265       AC_DEFINE(NO_EDITRES, 1)
4266     fi
4267     ;;
4268
4269   hpux*)
4270     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4271     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4272     AC_DEFINE(NO_EDITRES, 1)
4273     ;;
4274 esac
4275
4276
4277 case $opsys in
4278   sol2* | unixware )
4279     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4280     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4281     dnl need the constant to dimension an array.  So wire in the appropriate
4282     dnl value here.
4283     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4284     ;;
4285 esac
4286
4287 emacs_broken_SIGIO=no
4288
4289 case $opsys in
4290   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4291   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4292   hpux* | nacl | openbsd | sol2* | unixware )
4293     emacs_broken_SIGIO=yes
4294     ;;
4295
4296   aix4-2)
4297     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4298     dnl the way this system works, libc functions that return malloced
4299     dnl memory use the libc malloc implementation. Calling xfree or
4300     dnl xrealloc on the results of such functions results in a crash.
4301     dnl
4302     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4303     dnl but that does not currently work on this system.
4304     dnl
4305     dnl It is possible to completely override the malloc implementation on
4306     dnl AIX, but that involves putting the malloc functions in a shared
4307     dnl library and setting the MALLOCTYPE environment variable to point to
4308     dnl that shared library.
4309     dnl
4310     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4311     dnl to avoid a crash just use the Emacs implementation for that function.
4312     dnl
4313     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4314     dnl of this file, so that we do not check for get_current_dir_name
4315     dnl on AIX.  But that might be fragile if something else ends
4316     dnl up testing for get_current_dir_name as a dependency.
4317     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4318       get_current_dir_name should not be used.])
4319     ;;
4320
4321   freebsd)
4322     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4323     dnl writes/reads on a PTY, read(2) returns bogus data:
4324     dnl
4325     dnl write(2)  1022 bytes
4326     dnl write(2)   954 bytes, get EAGAIN
4327     dnl read(2)   1024 bytes in process_read_output
4328     dnl read(2)     11 bytes in process_read_output
4329     dnl
4330     dnl That is, read(2) returns more bytes than have ever been written
4331     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4332     dnl successfully after processing (for example with CRs added if the
4333     dnl terminal is set up that way which it is here).  The same bytes will
4334     dnl be seen again in a later read(2), without the CRs.
4335     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4336       work around an issue when reading from a PTY.])
4337     ;;
4338 esac
4339
4340 case $opsys in
4341   gnu-* | sol2-10 )
4342     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4343     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4344   ;;
4345 esac
4346
4347 case $opsys in
4348   darwin | dragonfly | freebsd | netbsd | openbsd )
4349     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4350       close a pty to make it a controlling terminal (it is already a
4351       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4352   ;;
4353 esac
4354
4355 dnl FIXME Surely we can test for this rather than hard-code it.
4356 case $opsys in
4357   netbsd | openbsd) sound_device="/dev/audio" ;;
4358   *) sound_device="/dev/dsp" ;;
4359 esac
4360
4361 dnl Used in sound.c
4362 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4363   [Name of the default sound device.])
4364
4365
4366 dnl Emacs can read input using SIGIO and buffering characters itself,
4367 dnl or using CBREAK mode and making C-g cause SIGINT.
4368 dnl The choice is controlled by the variable interrupt_input.
4369 dnl
4370 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4371 dnl
4372 dnl Emacs uses the presence of the USABLE_SIGIO macro
4373 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4374 dnl INTERRUPT_INPUT to decide whether to use it by default.
4375 dnl
4376 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4377 dnl CBREAK mode has two disadvantages
4378 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4379 dnl I hear that in system V this problem does not exist.
4380 dnl 2) Control-G causes output to be discarded.
4381 dnl I do not know whether this can be fixed in system V.
4382 dnl
4383 dnl Another method of doing input is planned but not implemented.
4384 dnl It would have Emacs fork off a separate process
4385 dnl to read the input and send it to the true Emacs process
4386 dnl through a pipe.
4387 case $opsys in
4388   darwin | gnu-linux | gnu-kfreebsd )
4389     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4390   ;;
4391 esac
4392
4393
4394 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4395 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4396 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4397 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4398 dnl taking float or double parameters.
4399 case $opsys in
4400   cygwin|gnu|gnu-linux|gnu-kfreebsd|freebsd|netbsd|openbsd)
4401     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4402       file defines 'NeedWidePrototypes' as 'NO'.])
4403   ;;
4404 esac
4405
4406
4407 dnl Used in process.c, this must be a loop, even if it only runs once.
4408 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4409 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4410 dnl trying suffixes 0-16.
4411 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4412   first PTY, if PTYs are supported.])
4413 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4414 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4415   end of a PTY, if non-standard.])
4416 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4417   end of a PTY, if non-standard.])
4418
4419 case $opsys in
4420   aix4-2 )
4421     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4422     dnl You allocate a pty by opening /dev/ptc to get the master side.
4423     dnl To get the name of the slave side, you just ttyname() the master side.
4424     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4425     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4426     ;;
4427
4428   cygwin )
4429     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4430     dnl multi-line AC_DEFINEs are hard. :(
4431     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4432     AC_DEFINE(PTY_NAME_SPRINTF, [])
4433     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4434     ;;
4435
4436   gnu | openbsd )
4437     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4438     ;;
4439
4440   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4441     dnl if HAVE_GRANTPT
4442     if test "x$ac_cv_func_grantpt" = xyes; then
4443       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4444       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4445       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4446       dnl to prevent sigchld_handler from intercepting the child's death.
4447       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4448       dnl if HAVE_POSIX_OPENPT
4449       if test "x$ac_cv_func_posix_openpt" = xyes; then
4450         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4451         AC_DEFINE(PTY_NAME_SPRINTF, [])
4452       dnl if HAVE_GETPT
4453       elif test "x$ac_cv_func_getpt" = xyes; then
4454         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4455         AC_DEFINE(PTY_NAME_SPRINTF, [])
4456       else
4457         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4458       fi
4459     else
4460       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4461     fi
4462     ;;
4463
4464   hpux*)
4465     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4466     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4467     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4468     ;;
4469
4470   sol2* )
4471     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4472     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4473     dnl from intercepting that death.  If any child but grantpt's should die
4474     dnl within, it should be caught after sigrelse(2).
4475     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4476     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4477     ;;
4478
4479   unixware )
4480     dnl Comments are as per sol2*.
4481     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4482     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4483     ;;
4484 esac
4485
4486
4487 case $opsys in
4488   sol2* | unixware )
4489     dnl This change means that we don't loop through allocate_pty too
4490     dnl many times in the (rare) event of a failure.
4491     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4492     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4493     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4494     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4495     ;;
4496 esac
4497
4498
4499 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4500 "typing" a signal character on the pty.])
4501
4502 case $opsys in
4503   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4504   aix4-2 | cygwin | gnu | dragonfly | freebsd | netbsd | openbsd | darwin )
4505     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4506     ;;
4507
4508   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4509   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4510   gnu-linux | gnu-kfreebsd )
4511
4512     AC_MSG_CHECKING([for signals via characters])
4513     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4514 #include <linux/version.h>
4515 #if LINUX_VERSION_CODE < 0x20400
4516 # error "Linux version too old"
4517 #endif
4518       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4519
4520     AC_MSG_RESULT([$emacs_signals_via_chars])
4521     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4522     ;;
4523 esac
4524
4525
4526 AH_TEMPLATE(TAB3, [Undocumented.])
4527
4528 case $opsys in
4529   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4530
4531   gnu | dragonfly | freebsd | netbsd | openbsd )
4532     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4533     AC_DEFINE(TAB3, OXTABS)
4534     ;;
4535
4536   gnu-linux | gnu-kfreebsd )
4537     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4538 #ifndef __ia64__
4539 # error "not ia64"
4540 #endif
4541       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4542         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4543         [Mark a secondary stack, like the register stack on the ia64.]), [])
4544     ;;
4545
4546   hpux*)
4547     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4548       run_time_remap; for HPUX.])
4549     ;;
4550 esac
4551
4552
4553 dnl This won't be used automatically yet.  We also need to know, at least,
4554 dnl that the stack is continuous.
4555 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4556   registers relevant for conservative garbage collection in the jmp_buf.])
4557
4558
4559 case $opsys in
4560   dnl Not all the architectures are tested, but there are Debian packages
4561   dnl for SCM and/or Guile on them, so the technique must work.  See also
4562   dnl comments in alloc.c concerning setjmp and gcc.
4563   dnl Fixme: it's probably safe to just use the GCC conditional below.
4564   gnu-linux | gnu-kfreebsd )
4565     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4566 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4567   || defined __alpha__ || defined __mips__ || defined __s390__ \
4568   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4569   || defined __ia64__ || defined __sh__
4570 /* ok */
4571 #else
4572 # error "setjmp not known to work on this arch"
4573 #endif
4574     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4575     ;;
4576 esac
4577
4578
4579 if test x$GCC = xyes; then
4580    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4581    AC_DEFINE(GC_SETJMP_WORKS, 1)
4582 else
4583   case $opsys in
4584     aix* | dragonfly | freebsd | netbsd | openbsd | sol2* )
4585       AC_DEFINE(GC_SETJMP_WORKS, 1)
4586       ;;
4587   esac
4588 fi                              dnl GCC?
4589
4590 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4591 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4592   [AC_LINK_IFELSE(
4593      [AC_LANG_PROGRAM(
4594        [[#include <setjmp.h>
4595          #ifdef __MINGW32__
4596          # define _longjmp longjmp
4597          #endif
4598        ]],
4599        [[jmp_buf j;
4600          if (! _setjmp (j))
4601            _longjmp (j, 1);]])],
4602      [emacs_cv_func__setjmp=yes],
4603      [emacs_cv_func__setjmp=no])])
4604 if test $emacs_cv_func__setjmp = yes; then
4605   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4606 fi
4607
4608 # We need to preserve signal mask to handle C stack overflows.
4609 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4610   [AC_LINK_IFELSE(
4611      [AC_LANG_PROGRAM(
4612        [[#include <setjmp.h>
4613        ]],
4614        [[sigjmp_buf j;
4615          if (! sigsetjmp (j, 1))
4616            siglongjmp (j, 1);]])],
4617      [emacs_cv_func_sigsetjmp=yes],
4618      [emacs_cv_func_sigsetjmp=no])])
4619 if test $emacs_cv_func_sigsetjmp = yes; then
4620   AC_DEFINE([HAVE_SIGSETJMP], 1,
4621     [Define to 1 if sigsetjmp and siglongjmp work.])
4622 fi
4623
4624 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4625   yes,yes,* | *,*,mingw32)
4626     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4627       [Define to 1 if C stack overflow can be handled in some cases.]);;
4628 esac
4629
4630 case $opsys in
4631   sol2* | unixware )
4632     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4633     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4634     dnl and this is all we need.
4635     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4636     ;;
4637 esac
4638
4639
4640 case $opsys in
4641   hpux* | sol2* )
4642     dnl Used in xfaces.c.
4643     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4644       some systems, where it requires time.h.])
4645     ;;
4646 esac
4647
4648
4649 dnl Define symbols to identify the version of Unix this is.
4650 dnl Define all the symbols that apply correctly.
4651 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4652 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4653 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4654 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4655
4656 case $opsys in
4657   aix4-2)
4658     AC_DEFINE(USG, [])
4659     dnl This symbol should be defined on AIX Version 3  ???????
4660     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4661 #ifndef _AIX
4662 # error "_AIX not defined"
4663 #endif
4664     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4665     ;;
4666
4667   cygwin)
4668     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4669     ;;
4670
4671   darwin)
4672     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4673     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4674     dnl distinguish OS X from pure Darwin.
4675     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4676     ;;
4677
4678   gnu-linux | gnu-kfreebsd )
4679     AC_DEFINE(USG, [])
4680     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4681     ;;
4682
4683   hpux*)
4684     AC_DEFINE(USG, [])
4685     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4686     ;;
4687
4688   mingw32)
4689     AC_DEFINE(DOS_NT, [])
4690     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4691     if test "x$ac_enable_checking" != "x" ; then
4692       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4693     fi
4694     ;;
4695
4696   sol2*)
4697     AC_DEFINE(USG, [])
4698     AC_DEFINE(USG5_4, [])
4699     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4700     ;;
4701
4702   unixware)
4703     AC_DEFINE(USG, [])
4704     AC_DEFINE(USG5_4, [])
4705     ;;
4706 esac
4707
4708 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4709   [case $opsys in
4710      aix4-2 | nacl)
4711        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4712        emacs_cv_usable_FIONREAD=no
4713        ;;
4714
4715      mingw32)
4716        emacs_cv_usable_FIONREAD=yes
4717        ;;
4718
4719      *)
4720        AC_COMPILE_IFELSE(
4721          [AC_LANG_PROGRAM([[#include <sys/types.h>
4722                             #include <sys/ioctl.h>
4723                             #ifdef USG5_4
4724                             # include <sys/filio.h>
4725                             #endif
4726                           ]],
4727                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4728          [emacs_cv_usable_FIONREAD=yes],
4729          [emacs_cv_usable_FIONREAD=no])
4730        ;;
4731    esac])
4732 if test $emacs_cv_usable_FIONREAD = yes; then
4733   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4734
4735   if test $emacs_broken_SIGIO = no; then
4736     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4737       [AC_COMPILE_IFELSE(
4738          [AC_LANG_PROGRAM([[#include <fcntl.h>
4739                             #include <signal.h>
4740                           ]],
4741                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4742          [emacs_cv_usable_SIGIO=yes],
4743          [emacs_cv_usable_SIGIO=no])],
4744       [emacs_cv_usable_SIGIO=yes],
4745       [emacs_cv_usable_SIGIO=no])
4746     if test $emacs_cv_usable_SIGIO = yes; then
4747       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4748     fi
4749   fi
4750 fi
4751
4752 case $opsys in
4753   hpux11)
4754     dnl It works to open the pty's tty in the parent (Emacs), then
4755     dnl close and reopen it in the child.
4756     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4757       works to open a pty's tty in the parent process, then close and
4758       reopen it in the child.])
4759     ;;
4760
4761   sol2-10)
4762     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4763       on Solaris.])
4764     ;;
4765 esac
4766
4767 # Set up the CFLAGS for real compilation, so we can substitute it.
4768 CFLAGS="$REAL_CFLAGS"
4769 CPPFLAGS="$REAL_CPPFLAGS"
4770 LIBS="$REAL_LIBS"
4771
4772 ## Hack to detect a buggy GCC version.
4773 if test "$GCC" = yes && \
4774    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4775   case $CFLAGS in
4776     *-fno-optimize-sibling-calls*) ;;
4777     *-O@<:@23@:>@*)
4778       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4779   esac
4780 fi
4781
4782 version=$PACKAGE_VERSION
4783
4784 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4785 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4786   [Short copyright string for this version of Emacs.])
4787 AC_SUBST(copyright)
4788
4789 ### Specify what sort of things we'll be editing into Makefile and config.h.
4790 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4791 AC_SUBST(version)
4792 AC_SUBST(configuration)
4793 ## Unused?
4794 AC_SUBST(canonical)
4795 AC_SUBST(srcdir)
4796 AC_SUBST(prefix)
4797 AC_SUBST(exec_prefix)
4798 AC_SUBST(bindir)
4799 AC_SUBST(datadir)
4800 AC_SUBST(sharedstatedir)
4801 AC_SUBST(libexecdir)
4802 AC_SUBST(mandir)
4803 AC_SUBST(infodir)
4804 AC_SUBST(lispdir)
4805 AC_SUBST(standardlisppath)
4806 AC_SUBST(locallisppath)
4807 AC_SUBST(lisppath)
4808 AC_SUBST(x_default_search_path)
4809 AC_SUBST(etcdir)
4810 AC_SUBST(archlibdir)
4811 AC_SUBST(etcdocdir)
4812 AC_SUBST(bitmapdir)
4813 AC_SUBST(gamedir)
4814 AC_SUBST(gameuser)
4815 AC_SUBST(gamegroup)
4816 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4817 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4818 ## end of LIBX_BASE, but nothing ever set it.
4819 AC_SUBST(LD_SWITCH_X_SITE)
4820 AC_SUBST(C_SWITCH_X_SITE)
4821 AC_SUBST(GNUSTEP_CFLAGS)
4822 AC_SUBST(CFLAGS)
4823 ## Used in lwlib/Makefile.in.
4824 AC_SUBST(X_TOOLKIT_TYPE)
4825 AC_SUBST(ns_appdir)
4826 AC_SUBST(ns_appbindir)
4827 AC_SUBST(ns_appresdir)
4828 AC_SUBST(ns_appsrc)
4829 AC_SUBST(GNU_OBJC_CFLAGS)
4830 AC_SUBST(OTHER_FILES)
4831
4832 if test -n "${term_header}"; then
4833     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4834         [Define to the header for the built-in window system.])
4835 fi
4836
4837 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4838                    [Define to the canonical Emacs configuration name.])
4839 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4840                    [Define to the options passed to configure.])
4841 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4842   define this to include extra configuration information.])
4843
4844 case $opsys in
4845   mingw32)
4846     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4847     ;;
4848 esac
4849
4850 XMENU_OBJ=
4851 XOBJ=
4852 FONT_OBJ=
4853 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4854   AC_DEFINE(HAVE_X_WINDOWS, 1,
4855             [Define to 1 if you want to use the X window system.])
4856   XMENU_OBJ=xmenu.o
4857   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4858   FONT_OBJ=xfont.o
4859   if test "$HAVE_CAIRO" = "yes"; then
4860     FONT_OBJ="ftfont.o ftcrfont.o"
4861   elif test "$HAVE_XFT" = "yes"; then
4862     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4863   elif test "$HAVE_FREETYPE" = "yes"; then
4864     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4865   fi
4866   AC_SUBST(FONT_OBJ)
4867 fi
4868 AC_SUBST(XMENU_OBJ)
4869 AC_SUBST(XOBJ)
4870 AC_SUBST(FONT_OBJ)
4871
4872 WIDGET_OBJ=
4873 MOTIF_LIBW=
4874 if test "${USE_X_TOOLKIT}" != "none" ; then
4875   WIDGET_OBJ=widget.o
4876   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4877   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4878     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4879   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4880     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4881     MOTIF_LIBW=-lXm
4882     case "$opsys" in
4883       gnu-linux)
4884         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4885         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4886         ;;
4887
4888       unixware)
4889         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4890         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4891         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4892         ;;
4893
4894       aix4-2)
4895         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4896         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4897         ;;
4898     esac
4899     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4900   fi
4901 fi
4902 AC_SUBST(WIDGET_OBJ)
4903
4904 TOOLKIT_LIBW=
4905 case "$USE_X_TOOLKIT" in
4906   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4907   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4908   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4909 esac
4910 if test "$HAVE_XWIDGETS" = "yes"; then
4911   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4912 fi
4913 AC_SUBST(TOOLKIT_LIBW)
4914
4915 if test "${opsys}" != "mingw32"; then
4916   if test "$USE_X_TOOLKIT" = "none"; then
4917     LIBXT_OTHER="\$(LIBXSM)"
4918   else
4919     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4920   fi
4921 fi
4922 AC_SUBST(LIBXT_OTHER)
4923
4924 if test "${HAVE_X11}" = "yes" ; then
4925   AC_DEFINE(HAVE_X11, 1,
4926             [Define to 1 if you want to use version 11 of X windows.])
4927   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4928 else
4929   LIBX_OTHER=
4930 fi
4931 AC_SUBST(LIBX_OTHER)
4932
4933 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4934   LIBXMENU=
4935 elif test "$USE_X_TOOLKIT" = none; then
4936   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4937 else
4938   LIBXMENU='$(lwlibdir)/liblw.a'
4939 fi
4940 AC_SUBST(LIBXMENU)
4941
4942 AC_CACHE_CHECK([for struct alignment],
4943   [emacs_cv_struct_alignment],
4944   [AC_COMPILE_IFELSE(
4945      [AC_LANG_PROGRAM([[#include <stddef.h>
4946                         struct __attribute__ ((aligned (8))) s { char c; };
4947                         struct t { char c; struct s s; };
4948                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4949                       ]])],
4950      [emacs_cv_struct_alignment=yes],
4951      [emacs_cv_struct_alignment=no])])
4952 if test "$emacs_cv_struct_alignment" = yes; then
4953   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4954     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4955      structure to an N-byte boundary.])
4956 fi
4957
4958 if test "${GNU_MALLOC}" = "yes" ; then
4959   AC_DEFINE(GNU_MALLOC, 1,
4960             [Define to 1 if you want to use the GNU memory allocator.])
4961 fi
4962
4963 RALLOC_OBJ=
4964 if test "${REL_ALLOC}" = "yes" ; then
4965   AC_DEFINE(REL_ALLOC, 1,
4966             [Define REL_ALLOC if you want to use the relocating allocator for
4967              buffer space.])
4968
4969   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4970 fi
4971 AC_SUBST(RALLOC_OBJ)
4972
4973 if test "$opsys" = "cygwin"; then
4974   CYGWIN_OBJ="cygw32.o"
4975   ## Cygwin differs because of its unexec().
4976   PRE_ALLOC_OBJ=
4977   POST_ALLOC_OBJ=lastfile.o
4978 elif test "$opsys" = "mingw32"; then
4979   CYGWIN_OBJ=
4980   PRE_ALLOC_OBJ=
4981   POST_ALLOC_OBJ=lastfile.o
4982 else
4983   CYGWIN_OBJ=
4984   PRE_ALLOC_OBJ=lastfile.o
4985   POST_ALLOC_OBJ=
4986 fi
4987 AC_SUBST(CYGWIN_OBJ)
4988 AC_SUBST(PRE_ALLOC_OBJ)
4989 AC_SUBST(POST_ALLOC_OBJ)
4990
4991 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4992 dnl verbatim defined above.  The tricky name is apropos, as this hack
4993 dnl makes Fortify go sour!
4994 AH_VERBATIM([FORTIFY_SOUR],
4995 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4996    The workaround disables some useful run-time checking, so it
4997    should be conditional to the platforms with the performance bug.
4998    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4999 #if defined __APPLE__ && defined __GNUC__
5000 # ifndef _DONT_USE_CTYPE_INLINE_
5001 #  define _DONT_USE_CTYPE_INLINE_
5002 # endif
5003 # ifndef _FORTIFY_SOURCE
5004 #  define _FORTIFY_SOURCE 0
5005 # endif
5006 #endif
5007 ])
5008
5009 # If user asks to omit features, disable optional features that gnulib
5010 # might otherwise enable.
5011 if test "$with_features" = no && test "$enable_acl" != yes; then
5012   enable_acl=no
5013 fi
5014
5015 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5016 # it temporarily reverts them to their pre-pkg-config values,
5017 # because gnulib needs to work with both src (which uses the
5018 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5019 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5020 # and it therefore needs to run in an environment where LIBS does not
5021 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5022 # for some package unrelated to lib-src.
5023 SAVE_CFLAGS=$CFLAGS
5024 SAVE_LIBS=$LIBS
5025 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5026 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5027 gl_ASSERT_NO_GNULIB_POSIXCHECK
5028 gl_ASSERT_NO_GNULIB_TESTS
5029 gl_INIT
5030 CFLAGS=$SAVE_CFLAGS
5031 LIBS=$SAVE_LIBS
5032
5033 if test "${opsys}" = "mingw32"; then
5034   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5035   # Remove unneeded switches from the value of CC that goes to Makefiles
5036   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5037 fi
5038
5039 case "$opsys" in
5040   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5041
5042   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5043
5044   darwin)
5045    ## The -headerpad option tells ld (see man page) to leave room at the
5046    ## end of the header for adding load commands.  Needed for dumping.
5047    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5048    ## architecture (where they are 78 bytes each). The actual number of
5049    ## load commands added is not consistent but normally ranges from
5050    ## about 14 to about 34. Setting it high gets us plenty of slop and
5051    ## only costs about 1.5K of wasted binary space.
5052    headerpad_extra=1000
5053    if test "$HAVE_NS" = "yes"; then
5054      libs_nsgui="-framework AppKit"
5055      if test "$NS_IMPL_COCOA" = "yes"; then
5056         libs_nsgui="$libs_nsgui -framework IOKit"
5057      fi
5058    else
5059      libs_nsgui=
5060    fi
5061    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5062
5063    ## This is here because src/Makefile.in did some extra fiddling around
5064    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5065    ## LD_SWITCH_SYSTEM_TEMACS instead,
5066    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5067      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5068    ;;
5069
5070   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5071   ## find X at run-time.
5072   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5073   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5074   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5075   ## had different values in configure (in ac_link) and src/Makefile.in.
5076   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5077   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5078
5079   mingw32)
5080    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5081    case "$canonical" in
5082      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5083      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5084    esac
5085    ;;
5086
5087   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5088 esac
5089
5090 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5091 # with "hardened" GCC configurations for some reason (Bug#18784).
5092 # We don't know why -nopie works, but not segfaulting is better than
5093 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5094 # clang keeps warning that it does not understand -nopie, and pre-4.6
5095 # GCC has a similar problem (Bug#20338).
5096 AC_CACHE_CHECK([whether $CC accepts -nopie],
5097   [emacs_cv_prog_cc_nopie],
5098   [emacs_save_c_werror_flag=$ac_c_werror_flag
5099    emacs_save_LDFLAGS=$LDFLAGS
5100    ac_c_werror_flag=yes
5101    LDFLAGS="$LDFLAGS -nopie"
5102    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5103      [emacs_cv_prog_cc_nopie=yes],
5104      [emacs_cv_prog_cc_nopie=no])
5105    ac_c_werror_flag=$emacs_save_c_werror_flag
5106    LDFLAGS=$emacs_save_LDFLAGS])
5107 if test "$emacs_cv_prog_cc_nopie" = yes; then
5108   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5109 fi
5110
5111 if test x$ac_enable_profiling != x ; then
5112   case $opsys in
5113     *freebsd | gnu-linux) ;;
5114     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5115   esac
5116 fi
5117
5118 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5119
5120 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5121
5122 ## Common for all window systems
5123 if test "$window_system" != "none"; then
5124   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5125   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5126   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5127 fi
5128
5129 AC_SUBST(WINDOW_SYSTEM_OBJ)
5130
5131 AH_TOP([/* GNU Emacs site configuration template file.
5132
5133 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5134   Free Software Foundation, Inc.
5135
5136 This file is part of GNU Emacs.
5137
5138 GNU Emacs is free software: you can redistribute it and/or modify
5139 it under the terms of the GNU General Public License as published by
5140 the Free Software Foundation, either version 3 of the License, or (at
5141 your option) any later version.
5142
5143 GNU Emacs is distributed in the hope that it will be useful,
5144 but WITHOUT ANY WARRANTY; without even the implied warranty of
5145 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5146 GNU General Public License for more details.
5147
5148 You should have received a copy of the GNU General Public License
5149 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5150
5151
5152 /* No code in Emacs #includes config.h twice, but some bits of code
5153    intended to work with other packages as well (like gmalloc.c)
5154    think they can include it as many times as they like.  */
5155 #ifndef EMACS_CONFIG_H
5156 #define EMACS_CONFIG_H
5157 ])dnl
5158
5159 AH_BOTTOM([#include <conf_post.h>
5160
5161 #endif /* EMACS_CONFIG_H */
5162
5163 /*
5164 Local Variables:
5165 mode: c
5166 End:
5167 */
5168 ])dnl
5169
5170 #### Report on what we decided to do.
5171 #### Report GTK as a toolkit, even if it doesn't use Xt.
5172 #### It makes printing result more understandable as using GTK sets
5173 #### toolkit_scroll_bars to yes by default.
5174 if test "${HAVE_GTK}" = "yes"; then
5175   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5176 fi
5177
5178 if test $USE_ACL -ne 0; then
5179   ACL_SUMMARY="yes $LIB_ACL"
5180 else
5181   ACL_SUMMARY=no
5182 fi
5183
5184 emacs_standard_dirs='Standard dirs'
5185 AS_ECHO(["
5186 Configured for '${canonical}'.
5187
5188   Where should the build process find the source code?    ${srcdir}
5189   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5190   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5191   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5192   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5193   What window system should Emacs use?                    ${window_system}
5194   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5195   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5196   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5197
5198 optsep=
5199 emacs_config_features=
5200 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5201   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5202   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5203   XWIDGETS; do
5204
5205     case $opt in
5206       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5207       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5208       *) eval val=\${HAVE_$opt} ;;
5209     esac
5210     case x$val in
5211       xno|xnone|x) continue ;;
5212     esac
5213     case $opt in
5214       X_TOOLKIT)
5215         case $val in
5216           GTK*|LUCID|MOTIF) opt=$val ;;
5217           *) continue ;;
5218         esac
5219       ;;
5220     esac
5221     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5222     optsep=' '
5223 done
5224 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5225   [Summary of some of the main features enabled by configure.])
5226
5227 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5228   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5229   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5230   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5231   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5232   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5233   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5234   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5235   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5236   Does Emacs support sound?                               ${HAVE_SOUND}
5237   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5238   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5239   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5240   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5241   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5242   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5243   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5244   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5245   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5246   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5247   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5248   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5249   Does Emacs use -lxft?                                   ${HAVE_XFT}
5250   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5251   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5252   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5253   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5254 "])
5255
5256 if test -n "${EMACSDATA}"; then
5257    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5258 fi
5259 if test -n "${EMACSDOC}"; then
5260    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5261 fi
5262
5263 echo
5264
5265 if test "$HAVE_NS" = "yes"; then
5266    echo
5267    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5268 The installed application will go to nextstep/Emacs.app and can be
5269 run or moved from there."])
5270    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5271       echo "The application will be fully self-contained."
5272     else
5273       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5274 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5275 to run if these resources are not installed."])
5276    fi
5277    echo
5278 fi
5279
5280 if test "${opsys}" = "cygwin"; then
5281   case `uname -r` in
5282     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5283            echo
5284            ;;
5285   esac
5286 fi
5287
5288 # Remove any trailing slashes in these variables.
5289 case $prefix in
5290   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5291 esac
5292 case $exec_prefix in
5293   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5294 esac
5295
5296 if test "$HAVE_NS" = "yes"; then
5297   if test "$NS_IMPL_GNUSTEP" = yes; then
5298     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5299       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5300     ns_check_file=Resources/Info-gnustep.plist
5301   else
5302     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5303       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5304     ns_check_file=Contents/Info.plist
5305   fi
5306   AC_SUBST(ns_check_file)
5307 fi
5308
5309 dnl config.status treats $srcdir specially, so I think this is ok...
5310 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5311
5312 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5313 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5314 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5315 dnl (else you get "no 'Makefile.am' found for any configure output").
5316 dnl This will work, but you get a config.status that is not quite right
5317 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5318 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5319 dnl it seems better to just live with the duplication.
5320 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5321
5322 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5323        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5324        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5325        leim/Makefile nextstep/Makefile nt/Makefile])
5326
5327 dnl test/ is not present in release tarfiles.
5328 opt_makefile=test/Makefile
5329
5330 if test -f "$srcdir/$opt_makefile.in"; then
5331   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5332   dnl Again, it's best not to use a variable.  Though you can add
5333   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5334   AC_CONFIG_FILES([test/Makefile])
5335 fi
5336
5337
5338 dnl The admin/ directory used to be excluded from tarfiles.
5339 if test -d $srcdir/admin; then
5340   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5341   AC_CONFIG_FILES([admin/charsets/Makefile])
5342   AC_CONFIG_FILES([admin/unidata/Makefile])
5343   AC_CONFIG_FILES([admin/grammars/Makefile])
5344 fi                              dnl -d admin
5345
5346
5347 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5348
5349 AC_SUBST(SUBDIR_MAKEFILES_IN)
5350
5351 dnl You might wonder (I did) why epaths.h is generated by running make,
5352 dnl rather than just letting configure generate it from epaths.in.
5353 dnl One reason is that the various paths are not fully expanded (see above);
5354 dnl eg gamedir=${prefix}/var/games/emacs.
5355 dnl Secondly, the GNU Coding standards require that one should be able
5356 dnl to run 'make prefix=/some/where/else' and override the values set
5357 dnl by configure.  This also explains the 'move-if-change' test and
5358 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5359 AC_CONFIG_COMMANDS([src/epaths.h], [
5360 if test "${opsys}" = "mingw32"; then
5361   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5362 else
5363   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5364 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5365 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5366
5367 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5368 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5369 dnl or a symlink?
5370 AC_CONFIG_COMMANDS([src/.gdbinit], [
5371 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5372   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5373 fi
5374 ])
5375
5376 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5377 dnl See comments for etc-refcards-emacsver.tex.
5378 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5379 dnl it is not quite the same.  But we are generating in $srcdir.
5380 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5381 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5382 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5383 ])
5384
5385 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5386 dnl then a directory etc/refcards is created in the build directory,
5387 dnl which is probably harmless, but confusing (in out-of-tree builds).
5388 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5389 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5390 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5391 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5392 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5393 ])
5394
5395 AC_OUTPUT
5396
5397 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])