code.delx.au - gnu-emacs/blob - lisp/font-lock.el

   1 ;; Electric Font Lock Mode
   2 ;; Copyright (C) 1992, 1993 Free Software Foundation, Inc.
   3
   4 ;; Author: jwz, then rms
   5 ;; Maintainer: FSF
   6 ;; Keywords: languages, faces
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24
  25 ;;; Commentary:
  26
  27 ;; Font-lock-mode is a minor mode that causes your comments to be
  28 ;; displayed in one face, strings in another, reserved words in another,
  29 ;; documentation strings in another, and so on.
  30 ;;
  31 ;; Comments will be displayed in `font-lock-comment-face'.
  32 ;; Strings will be displayed in `font-lock-string-face'.
  33 ;; Doc strings will be displayed in `font-lock-doc-string-face'.
  34 ;; Function and variable names (in their defining forms) will be
  35 ;;  displayed in `font-lock-function-name-face'.
  36 ;; Reserved words will be displayed in `font-lock-keyword-face'.
  37 ;;
  38 ;; To make the text you type be fontified, use M-x font-lock-mode.
  39 ;; When this minor mode is on, the fonts of the current line are
  40 ;; updated with every insertion or deletion.
  41 ;;
  42 ;; To define new reserved words or other patterns to highlight, use
  43 ;; the `font-lock-keywords' variable.  This should be mode-local.
  44 ;;
  45 ;; To turn this on automatically, add this to your .emacs file:
  46 ;;
  47 ;;      (setq emacs-lisp-mode-hook '(lambda () (font-lock-mode 1)))
  48 ;;
  49 ;; On a Sparc2, the initial fontification takes about 12 seconds for a 120k
  50 ;; file of C code, using the default configuration.  You can speed this up
  51 ;; substantially by removing some of the patterns that are highlighted by
  52 ;; default.  Fontifying Lisp code is significantly faster, because Lisp has a
  53 ;; more regular syntax than C, so the expressions don't have to be as hairy.
  54
  55 ;;; Code:
  56
  57 (or window-system
  58     (error "Can't fontify on an ASCII terminal"))
  59
  60 (or (internal-find-face 'underline)
  61     (copy-face 'default 'underline))
  62 (set-face-underline-p 'underline t)
  63
  64 (defvar font-lock-comment-face
  65   'italic
  66   "Face to use for comments.")
  67
  68 (defvar font-lock-doc-string-face
  69   'italic
  70   "Face to use for documentation strings.")
  71
  72 (defvar font-lock-string-face
  73   'underline
  74   "Face to use for string constants.")
  75
  76 (defvar font-lock-function-name-face
  77   'bold-italic
  78   "Face to use for function names.")
  79
  80 (defvar font-lock-keyword-face
  81   'bold
  82   "Face to use for keywords.")
  83
  84 (defvar font-lock-type-face
  85   'italic
  86   "Face to use for data types.")
  87
  88 (make-variable-buffer-local 'font-lock-keywords)
  89 (defvar font-lock-keywords nil
  90   "*The keywords to highlight.
  91 If this is a list, then elements may be of the forms:
  92
  93   \"string\"                      ; A regexp to highlight in the
  94                                   ;  `font-lock-keyword-face'.
  95   (\"string\" . N)                ; Highlight subexpression N of the regexp.
  96   (\"string\" . face-name)        ; Use the named face
  97   (\"string\" N face-name)        ; Both of the above
  98   (\"string\" N face-name t)      ; This allows highlighting to override
  99                                   ;  already-highlighted regions.
 100   (\"string\" N face-name keep)   ; This allows highlighting to occur
 101                                   ; even if some parts of what STRING matches
 102                                   ; are already highlighted--but does not alter
 103                                   ; the existing highlighting of those parts.
 104
 105 These regular expressions should not match text which spans lines.
 106 While \\[font-lock-fontify-buffer] handles multi-line patterns correctly,
 107 updating when you edit the buffer does not,
 108 since it considers text one line at a time.
 109
 110 Be careful composing regexps for this list; the wrong pattern can dramatically
 111 slow things down!")
 112
 113 (defvar font-lock-keywords-case-fold-search nil
 114   "*Non-nil means the patterns in `font-lock-keywords' are case-insensitive.")
 115
 116 (defvar font-lock-verbose t
 117   "*Non-nil means `font-lock-fontify-buffer' should print status messages.")
 118
 119 ;;;###autoload
 120 (defvar font-lock-mode-hook nil
 121   "Function or functions to run on entry to Font Lock mode.")
 122
 123 ;;; These variables record, for each buffer,
 124 ;;; the parse state at a particular position, always the start of a line.
 125 ;;; This is used to make font-lock-fontify-region faster.
 126 (defvar font-lock-cache-position nil)
 127 (defvar font-lock-cache-state nil)
 128 (make-variable-buffer-local 'font-lock-cache-position)
 129 (make-variable-buffer-local 'font-lock-cache-state)
 130
 131 (defun font-lock-fontify-region (start end)
 132   "Put proper face on each string and comment between START and END."
 133   (save-excursion
 134     (goto-char start)
 135     (beginning-of-line)
 136     (setq end (min end (point-max)))
 137     (let ((buffer-read-only nil)
 138           state startline prev prevstate
 139           (modified (buffer-modified-p)))
 140       ;; Find the state at the line-beginning before START.
 141       (setq startline (point))
 142       (if (eq (point) font-lock-cache-position)
 143           (setq state font-lock-cache-state)
 144         ;; Find outermost containing sexp.
 145         (beginning-of-defun)
 146         ;; Find the state at STARTLINE.
 147         (while (< (point) startline)
 148           (setq state (parse-partial-sexp (point) startline 0)))
 149         (setq font-lock-cache-state state
 150               font-lock-cache-position (point)))
 151       ;; Now find the state precisely at START.
 152       (setq state (parse-partial-sexp (point) start nil nil state))
 153       ;; If the region starts inside a string, show the extent of it.
 154       (if (nth 3 state)
 155           (let ((beg (point)))
 156             (while (and (re-search-forward "\\s\"" end 'move)
 157                         (nth 3 (parse-partial-sexp beg (point)
 158                                                    nil nil state))))
 159             (put-text-property beg (point) 'face font-lock-string-face)
 160             (setq state (parse-partial-sexp beg (point) nil nil state))))
 161       ;; Likewise for a comment.
 162       (if (or (nth 4 state) (nth 7 state))
 163           (let ((beg (point)))
 164             (while (and (re-search-forward (if comment-end
 165                                                (concat "\\s>\\|"
 166                                                        (regexp-quote comment-end))
 167                                              "\\s>")
 168                                            end 'move)
 169                         (nth 3 (parse-partial-sexp beg (point)
 170                                                    nil nil state))))
 171             (put-text-property beg (point) 'face font-lock-comment-face)
 172             (setq state (parse-partial-sexp beg (point) nil nil state))))
 173       ;; Find each interesting place between here and END.
 174       (while (and (< (point) end)
 175                   (setq prev (point) prevstate state)
 176                   (re-search-forward (if comment-start-skip
 177                                          (concat "\\s\"\\|" comment-start-skip)
 178                                        "\\s\"")
 179                                      end t)
 180                   ;; Clear out the fonts of what we skip over.
 181                   (progn (remove-text-properties prev (point) '(face nil)) t)
 182                   ;; Verify the state at that place
 183                   ;; so we don't get fooled by \" or \;.
 184                   (setq state (parse-partial-sexp prev (point)
 185                                                   nil nil state)))
 186         (let ((here (point)))
 187           (if (or (nth 4 state) (nth 7 state))
 188               ;; We found a real comment start.
 189               (let ((beg (match-beginning 0)))
 190                 (goto-char beg)
 191                 (save-restriction
 192                   (narrow-to-region (point-min) end)
 193                   (condition-case nil
 194                       (progn
 195                         (forward-comment 1)
 196                         ;; forward-comment skips all whitespace,
 197                         ;; so go back to the real end of the comment.
 198                         (skip-chars-backward " \t"))
 199                     (error (goto-char end))))
 200                 (put-text-property beg (point) 'face font-lock-comment-face)
 201                 (setq state (parse-partial-sexp here (point) nil nil state)))
 202             (if (nth 3 state)
 203                 (let ((beg (match-beginning 0)))
 204                   (while (and (re-search-forward "\\s\"" end 'move)
 205                               (nth 3 (parse-partial-sexp here (point)
 206                                                          nil nil state))))
 207                   (put-text-property beg (point) 'face font-lock-string-face)
 208                   (setq state (parse-partial-sexp here (point) nil nil state))))
 209               ))
 210         ;; Make sure PREV is non-nil after the loop
 211         ;; only if it was set on the very last iteration.
 212         (setq prev nil))
 213       (and prev
 214            (remove-text-properties prev end '(face nil)))
 215       (set-buffer-modified-p modified))))
 216
 217 ;; This code used to be used to show a string on reaching the end of it.
 218 ;; It is probably not needed due to later changes to handle strings
 219 ;; starting before the region in question.
 220 ;;          (if (and (null (nth 3 state))
 221 ;;                   (eq (char-syntax (preceding-char)) ?\")
 222 ;;                   (save-excursion
 223 ;;                     (nth 3 (parse-partial-sexp prev (1- (point))
 224 ;;                                                nil nil prevstate))))
 225 ;;              ;; We found the end of a string.
 226 ;;              (save-excursion
 227 ;;                (setq foo2 (point))
 228 ;;                (let ((ept (point)))
 229 ;;                  (forward-sexp -1)
 230 ;;                  ;; Highlight the string when we see the end.
 231 ;;                  ;; Doing it at the start leads to trouble:
 232 ;;                  ;; either it fails to handle multiline strings
 233 ;;                  ;; or it can run away when an unmatched " is inserted.
 234 ;;                  (put-text-property (point) ept 'face
 235 ;;                                     (if (= (car state) 1)
 236 ;;                                         font-lock-doc-string-face
 237 ;;                                       font-lock-string-face)))))
 238
 239 (defun font-lock-unfontify-region (beg end)
 240   (let ((modified (buffer-modified-p))
 241         (buffer-read-only nil))
 242     (remove-text-properties beg end '(face nil))
 243     (set-buffer-modified-p modified)))
 244
 245 ;; Called when any modification is made to buffer text.
 246 (defun font-lock-after-change-function (beg end old-len)
 247   (save-excursion
 248     (save-match-data
 249       (goto-char beg)
 250       ;; Discard the cache info if text before it has changed.
 251       (and font-lock-cache-position
 252            (> font-lock-cache-position beg)
 253            (setq font-lock-cache-position nil))
 254       ;; Rescan till end of line.  yes!
 255       (goto-char end)
 256       (end-of-line)
 257       (setq end (point))
 258       (goto-char beg)
 259       (beginning-of-line)
 260       (setq beg (point))
 261       ;; First scan for strings and comments.
 262       ;; Must scan from line start in case of
 263       ;; inserting space into `intfoo () {}'.
 264       (font-lock-fontify-region beg (1+ end))
 265       ;; Now scan for keywords.
 266       (font-lock-hack-keywords beg end))))
 267 \f
 268 ;;; Fontifying arbitrary patterns
 269
 270 (defsubst font-lock-any-properties-p (start end)
 271   (or (get-text-property start 'face)
 272       (let ((next (next-single-property-change start 'face)))
 273         (and next (< next end)))))
 274
 275 (defun font-lock-hack-keywords (start end &optional loudly)
 276   (goto-char start)
 277   (let ((case-fold-search font-lock-keywords-case-fold-search)
 278         (rest font-lock-keywords)
 279         (count 0)
 280         (buffer-read-only nil)
 281         (modified (buffer-modified-p))
 282         first str match face s e allow-overlap-p)
 283     (while rest
 284       (setq first (car rest) rest (cdr rest))
 285       (goto-char start)
 286       (cond ((consp first)
 287              (setq str (car first))
 288              (cond ((consp (cdr first))
 289                     (setq match (nth 1 first)
 290                           face (eval (nth 2 first))
 291                           allow-overlap-p (nth 3 first)))
 292                    ((symbolp (cdr first))
 293                     (setq match 0 allow-overlap-p nil
 294                           face (eval (cdr first))))
 295                    (t
 296                     (setq match (cdr first)
 297                           allow-overlap-p nil
 298                           face font-lock-keyword-face))))
 299             (t
 300              (setq str first match 0 allow-overlap-p nil
 301                    face font-lock-keyword-face)))
 302       ;(message "regexp: %s" str)
 303       (while (re-search-forward str end t)
 304         (setq s (match-beginning match)
 305               e (match-end match))
 306         (or s (error "expression did not match subexpression %d" match))
 307         ;; don't fontify this keyword if we're already in some other context.
 308         (or (if allow-overlap-p nil (font-lock-any-properties-p s e))
 309             (if (not (memq allow-overlap-p '(t nil)))
 310                 (save-excursion
 311                   (goto-char s)
 312                   (save-restriction
 313                     (narrow-to-region s e)
 314                     (while (not (eobp))
 315                       (let ((next (next-single-property-change (point) 'face)))
 316                         (if (or (null next) (> next (point-max)))
 317                             (setq next (point-max)))
 318                         (if (not (get-text-property (point) 'face))
 319                             (put-text-property (point) next 'face face))
 320                         (goto-char next)))))
 321               (put-text-property s e 'face face))))
 322       (if loudly (message "Fontifying %s... (regexps...%s)"
 323                           (buffer-name)
 324                           (make-string (setq count (1+ count)) ?.))))
 325     (set-buffer-modified-p modified)))
 326 \f
 327 ;; The user level functions
 328
 329 (defvar font-lock-mode nil) ; for modeline
 330 (or (assq 'font-lock-mode minor-mode-alist)
 331     (setq minor-mode-alist
 332           (append minor-mode-alist
 333                   '((font-lock-mode " Font")))))
 334
 335 (defvar font-lock-fontified nil) ; whether we have hacked this buffer
 336 (put 'font-lock-fontified 'permanent-local t)
 337
 338 ;;;###autoload
 339 (defun font-lock-mode (&optional arg)
 340   "Toggle Font Lock mode.
 341 With arg, turn Font Lock mode on if and only if arg is positive.
 342
 343 When Font Lock mode is enabled, text is fontified as you type it:
 344
 345  - comments are displayed in `font-lock-comment-face';
 346      (That is a variable whose value should be a face name.)
 347  - strings are displayed in `font-lock-string-face';
 348  - documentation strings are displayed in `font-lock-doc-string-face';
 349  - function and variable names in their defining forms are displayed
 350    in `font-lock-function-name-face';
 351  - and certain other expressions are displayed in other faces
 352    according to the value of the variable `font-lock-keywords'.
 353
 354 When you turn Font Lock mode on/off, the buffer is fontified/defontified.
 355 To fontify a buffer without having newly typed text become fontified, you
 356 can use \\[font-lock-fontify-buffer]."
 357   (interactive "P")
 358   (let ((on-p (if (null arg)
 359                   (not font-lock-mode)
 360                 (> (prefix-numeric-value arg) 0))))
 361     (if (equal (buffer-name) " *Compiler Input*") ; hack for bytecomp...
 362         (setq on-p nil))
 363     (or (memq after-change-function
 364               '(nil font-lock-after-change-function))
 365         (error "after-change-function is %s" after-change-function))
 366     (set (make-local-variable 'after-change-function)
 367          (if on-p 'font-lock-after-change-function nil))
 368     (set (make-local-variable 'font-lock-mode) on-p)
 369     (cond (on-p
 370            (font-lock-set-defaults)
 371            (make-local-variable 'before-revert-hook)
 372            (make-local-variable 'after-revert-hook)
 373            ;; If buffer is reverted, must clean up the state.
 374            (add-hook 'before-revert-hook 'font-lock-revert-setup)
 375            (add-hook 'after-revert-hook 'font-lock-revert-cleanup)
 376            (run-hooks 'font-lock-mode-hook)
 377            (or font-lock-fontified (font-lock-fontify-buffer)))
 378           (font-lock-fontified
 379            (setq font-lock-fontified nil)
 380            (remove-hook 'before-revert-hook 'font-lock-revert-setup)
 381            (remove-hook 'after-revert-hook 'font-lock-revert-cleanup)
 382            (font-lock-unfontify-region (point-min) (point-max))))
 383     (force-mode-line-update)))
 384
 385 ;; If the buffer is about to be reverted, it won't be fontified.
 386 (defun font-lock-revert-setup ()
 387   (setq font-lock-fontified nil))
 388
 389 ;; If the buffer has just been reverted, we might not even be in font-lock
 390 ;; mode anymore, and if we are, the buffer may or may not have already been
 391 ;; refontified.  Refontify here if it looks like we need to.
 392 (defun font-lock-revert-cleanup ()
 393   (and font-lock-mode
 394        (not font-lock-fontified)
 395        (font-lock-mode 1)))
 396
 397 (defun font-lock-fontify-buffer ()
 398   "Fontify the current buffer the way `font-lock-mode' would:
 399
 400  - comments are displayed in `font-lock-comment-face';
 401  - strings are displayed in `font-lock-string-face';
 402  - documentation strings are displayed in `font-lock-doc-string-face';
 403  - function and variable names in their defining forms are displayed
 404    in `font-lock-function-name-face';
 405  - and certain other expressions are displayed in other faces
 406    according to the value of the variable `font-lock-keywords'.
 407
 408 This can take a while for large buffers."
 409   (interactive)
 410   (let ((was-on font-lock-mode)
 411         (font-lock-verbose (or font-lock-verbose (interactive-p))))
 412     (if font-lock-verbose (message "Fontifying %s..." (buffer-name)))
 413     ;; Turn it on to run hooks and get the right font-lock-keywords.
 414     (or was-on (font-lock-set-defaults))
 415     (font-lock-unfontify-region (point-min) (point-max))
 416     (if font-lock-verbose (message "Fontifying %s... (syntactically...)"
 417                                    (buffer-name)))
 418 ;;    (buffer-syntactic-context-flush-cache)
 419     (save-excursion
 420       (font-lock-fontify-region (point-min) (point-max))
 421       (if font-lock-verbose (message "Fontifying %s... (regexps...)"
 422                                      (buffer-name)))
 423       (font-lock-hack-keywords (point-min) (point-max) font-lock-verbose))
 424     (set (make-local-variable 'font-lock-fontified) t)
 425     (if font-lock-verbose (message "Fontifying %s... done." (buffer-name)))
 426     ))
 427
 428 \f
 429 ;;; Various mode-specific information.
 430
 431 (defun font-lock-set-defaults ()
 432   "Set `font-lock-keywords' to something appropriate for this mode."
 433   (if (not font-lock-keywords)          ; if not already set.
 434       (setq font-lock-keywords
 435             (cond ((eq major-mode 'lisp-mode)       lisp-font-lock-keywords)
 436                   ((eq major-mode 'emacs-lisp-mode) lisp-font-lock-keywords)
 437                   ((eq major-mode 'c-mode)          c-font-lock-keywords)
 438                   ((eq major-mode 'c++-c-mode)      c-font-lock-keywords)
 439                   ((eq major-mode 'c++-mode)        c++-font-lock-keywords)
 440                   ((eq major-mode 'perl-mode)       perl-font-lock-keywords)
 441                   ((eq major-mode 'tex-mode)        tex-font-lock-keywords)
 442                   ((eq major-mode 'texinfo-mode)    texi-font-lock-keywords)
 443                   ((eq major-mode 'shell-mode)      shell-font-lock-keywords)
 444                   ((eq major-mode 'dired-mode)      dired-font-lock-keywords)
 445                   (t nil)))))
 446
 447 (defconst lisp-font-lock-keywords-1
 448  '(;;
 449    ;; highlight defining forms.  This doesn't work too nicely for
 450    ;; (defun (setf foo) ...) but it does work for (defvar foo) which
 451    ;; is more important.
 452    ("^(def[-a-z]+\\s +\\([^ \t\n\)]+\\)" 1 font-lock-function-name-face)
 453    ;;
 454    ;; highlight CL keywords
 455    ("\\s :\\(\\(\\sw\\|\\s_\\)+\\)\\>" . 1)
 456    ;;
 457    ;; this is highlights things like (def* (setf foo) (bar baz)), but may
 458    ;; be slower (I haven't really thought about it)
 459 ;   ("^(def[-a-z]+\\s +\\(\\s(\\S)*\\s)\\|\\S(\\S *\\)"
 460 ;    1 font-lock-function-name-face)
 461    )
 462  "For consideration as a value of `lisp-font-lock-keywords'.
 463 This does fairly subdued highlighting.")
 464
 465 (defconst lisp-font-lock-keywords-2
 466   (append
 467    lisp-font-lock-keywords-1
 468    '(;;
 469      ;; Highlight control structures
 470      ("(\\(cond\\|if\\|when\\|unless\\|[ec]?\\(type\\)?case\\)[ \t\n]" . 1)
 471      ("(\\(while\\|do\\|let\\*?\\|flet\\|labels\\|prog[nv12*]?\\)[ \t\n]" . 1)
 472      ("(\\(catch\\|\\throw\\|block\\|return\\|return-from\\)[ \t\n]" . 1)
 473      ("(\\(save-restriction\\|save-window-restriction\\)[ \t\n]" . 1)
 474      ("(\\(save-excursion\\|unwind-protect\\|condition-case\\)[ \t\n]" . 1)
 475      ;;
 476      ;; highlight function names in emacs-lisp docstrings (in the syntax
 477      ;; that substitute-command-keys understands.)
 478      ("\\\\\\\\\\[\\([^]\\\n]+\\)]" 1 font-lock-keyword-face t)
 479      ;;
 480      ;; highlight words inside `' which tend to be function names
 481      ("`\\([-a-zA-Z0-9_][-a-zA-Z0-9_][-a-zA-Z0-9_.]+\\)'"
 482       1 font-lock-keyword-face t)
 483      ))
 484  "For consideration as a value of `lisp-font-lock-keywords'.
 485 This does a lot more highlighting.")
 486
 487 ;; default to the gaudier variety?
 488 ;(defvar lisp-font-lock-keywords lisp-font-lock-keywords-2
 489 ;  "Additional expressions to highlight in Lisp modes.")
 490 (defvar lisp-font-lock-keywords lisp-font-lock-keywords-1
 491   "Additional expressions to highlight in Lisp modes.")
 492
 493
 494 (defconst c-font-lock-keywords-1 nil
 495  "For consideration as a value of `c-font-lock-keywords'.
 496 This does fairly subdued highlighting.")
 497
 498 (defconst c-font-lock-keywords-2 nil
 499  "For consideration as a value of `c-font-lock-keywords'.
 500 This does a lot more highlighting.")
 501
 502 (defconst c++-font-lock-keywords-1 nil
 503  "For consideration as a value of `c++-font-lock-keywords'.
 504 This does fairly subdued highlighting.")
 505
 506 (defconst c++-font-lock-keywords-2 nil
 507  "For consideration as a value of `c++-font-lock-keywords'.
 508 This does a lot more highlighting.")
 509
 510 (let* ((storage "auto\\|extern\\|register\\|static\\|typedef")
 511        (struct "struct\\|union\\|enum")
 512        (prefixes "signed\\|unsigned\\|short\\|long")
 513        (types (concat prefixes "\\|int\\|char\\|float\\|double\\|void"))
 514        (ctoken "[a-zA-Z0-9_:~*]+")
 515        (c++-things (concat
 516                     "const\\|class\\|protected:\\|private:\\|public:\\|inline\\|"
 517                     "new\\|delete")))
 518  (setq c-font-lock-keywords-1
 519   (list
 520    ;; fontify preprocessor directives as comments.
 521    '("^#[ \t]*[a-z]+" . font-lock-comment-face)
 522    ;;
 523    ;; fontify names being defined.
 524    '("^#[ \t]*\\(define\\|undef\\)[ \t]+\\(\\(\\sw\\|\\s_\\)+\\)" 2
 525      font-lock-function-name-face)
 526    ;;
 527    ;; fontify other preprocessor lines.
 528    '("^#[ \t]*\\(if\\|elif\\|else\\|endif\\)[ \t]+\\([^\n]+\\)"
 529      2 font-lock-function-name-face keep)
 530    '("^#[ \t]*\\(ifn?def\\)[ \t]+\\([^ \t\n]+\\)"
 531      2 font-lock-function-name-face t)
 532    ;;
 533    ;; fontify the filename in #include <...>
 534    ;; don't need to do this for #include "..." because those were
 535    ;; already fontified as strings by the syntactic pass.
 536    '("^#[ \t]*include[ \t]+\\(<[^>\"\n]+>\\)" 1 font-lock-string-face)
 537    ;;
 538    ;; fontify the names of functions being defined.
 539    (list (concat
 540           "^\\(" ctoken "[ \t]+\\)?"    ; type specs; there can be no
 541           "\\(" ctoken "[ \t]+\\)?"     ; more than 3 tokens, right?
 542           "\\(" ctoken "[ \t]+\\)?"
 543           "\\([*&]+[ \t]*\\)?"          ; pointer
 544           "\\(" ctoken "\\)[ \t]*(")            ; name
 545     5 'font-lock-function-name-face)
 546    ;;
 547    ;;
 548    ;; Fontify structure names (in structure definition form).
 549    (list (concat "^\\(" storage "\\)?[ \t]*\\<\\(" struct "\\)"
 550           "[ \t]+\\(" ctoken "\\)[ \t]*\\(\{\\|$\\)")
 551     3 'font-lock-function-name-face)
 552    ;;
 553    ;; Fontify declarations of simple identifiers (including typedefs).
 554    ;; (Should this be in c-font-lock-keywords-2 instead?)
 555    (list (concat "^[ \t]*\\(\\(" storage "\\)[ \t]+\\)?\\(\\(\\(" prefixes
 556           "\\)\\>[ \t]*\\)*\\(" types "\\)\\)[ \t]+\\(" ctoken
 557           "\\)[ \t]*[=;]")
 558     7 'font-lock-function-name-face 'keep)
 559    ;;
 560    ;; And likewise for structs
 561    (list (concat "^[ \t]*\\(\\(" storage "\\)[ \t]+\\)?\\(" struct
 562           "\\)[ \t]+" ctoken "[ \t]+\\(" ctoken "\\);")
 563     4 'font-lock-function-name-face 'keep)
 564    ;;
 565    ;; Fontify case clauses.  This is fast because its anchored on the left.
 566    '("case[ \t]+\\(\\(\\sw\\|\\s_\\)+\\):". 1)
 567    '("\\<\\(default\\):". 1)
 568    ))
 569
 570  (setq c-font-lock-keywords-2
 571   (append c-font-lock-keywords-1
 572    (list
 573     ;;
 574     ;; fontify all storage classes and type specifiers
 575     (cons (concat "\\<\\(" storage "\\)\\>") 'font-lock-type-face)
 576     (cons (concat "\\<\\(" types "\\)\\>") 'font-lock-type-face)
 577     (cons (concat "\\<\\(\\(\\(" prefixes "\\)\\>[ \t]*\\)*\\(" types
 578            "\\)\\)\\>")
 579      'font-lock-type-face)
 580     (list (concat "\\<\\(" struct "\\)[ \t]+" ctoken)
 581      0 'font-lock-type-face 'keep)
 582     ;;
 583     ;; fontify all builtin tokens
 584     (cons (concat
 585            "[ \t]\\("
 586            (mapconcat 'identity
 587             '("for" "while" "do" "return" "goto" "case" "break" "switch"
 588               "if" "else" "default" "continue" "default")
 589             "\\|")
 590            "\\)[ \t\n(){};,]")
 591      1)
 592     ;;
 593     ;; fontify case targets and goto-tags.  This is slow because the
 594     ;; expression is anchored on the right.
 595     "\\(\\(\\sw\\|\\s_\\)+\\):"
 596     ;;
 597     ;; Fontify variables declared with structures, or typedef names.
 598     '("}[ \t*]*\\(\\(\\sw\\|\\s_\\)+\\)[ \t]*[,;]"
 599       1 font-lock-function-name-face)
 600     ;;
 601     ;; Fontify global variables without a type.
 602 ;    '("^\\([_a-zA-Z0-9:~*]+\\)[ \t]*[[;={]" 1 font-lock-function-name-face)
 603     )))
 604
 605  (setq c++-font-lock-keywords-1
 606        (cons
 607         (concat "\\(" c++-things "\\)[ \t\n]")
 608         c-font-lock-keywords-1))
 609  (setq c++-font-lock-keywords-2
 610        (cons
 611         (cons (concat "\\<\\(" c++-things "\\)\\>") 'font-lock-type-face)
 612         c-font-lock-keywords-2))
 613  )
 614
 615 ; default to the gaudier variety?
 616 (defvar c-font-lock-keywords c-font-lock-keywords-1
 617   "Additional expressions to highlight in C mode.")
 618
 619 (defvar c++-font-lock-keywords c++-font-lock-keywords-1
 620   "Additional expressions to highlight in C++ mode.")
 621
 622
 623 (defvar perl-font-lock-keywords
 624   (list
 625    (cons (concat "[ \n\t{]*\\("
 626                  (mapconcat 'identity
 627                             '("if" "until" "while" "elsif" "else" "unless" "for"
 628                               "foreach" "continue" "exit" "die" "last" "goto" "next"
 629                               "redo" "return" "local" "exec")
 630                             "\\|")
 631                  "\\)[ \n\t;(]") 1)
 632    (mapconcat 'identity
 633               '("#endif" "#else" "#ifdef" "#ifndef" "#if" "#include"
 634                 "#define" "#undef")
 635               "\\|")
 636    '("^[ \n\t]*sub[ \t]+\\([^ \t{]+\\)[ \t]*[{]" 1 font-lock-function-name-face)
 637    '("[ \n\t{]*\\(eval\\)[ \n\t(;]" 1 font-lock-function-name-face)
 638    '("\\(--- .* ---\\|=== .* ===\\)" . font-lock-doc-string-face)
 639    )
 640   "Additional expressions to highlight in Perl mode.")
 641
 642 (defvar tex-font-lock-keywords
 643   (list
 644    '("\\(\\\\\\w+\\)" 1 font-lock-keyword-face t)
 645    '("{\\\\em\\([^}]+\\)}" 1 font-lock-comment-face t)
 646    '("{\\\\bf\\([^}]+\\)}" 1 font-lock-keyword-face t)
 647    '("^[ \t\n]*\\\\def[\\\\@]\\(\\w+\\)" 1 font-lock-function-name-face t)
 648    '("\\\\\\(begin\\|end\\){\\([a-zA-Z0-9\\*]+\\)}"
 649      2 font-lock-function-name-face t)
 650    '("[^\\\\]\\$\\([^$]*\\)\\$" 1 font-lock-string-face t)
 651 ;   '("\\$\\([^$]*\\)\\$" 1 font-lock-string-face t)
 652    )
 653   "Additional expressions to highlight in TeX mode.")
 654
 655 (defvar texi-font-lock-keywords
 656   (list
 657    "@\\(@\\|[^}\t \n{]+\\)"                                     ;commands
 658    '("^\\(@c\\|@comment\\)[ \t].*$" . font-lock-comment-face)   ;comments
 659    '("^\\(*.*\\)[\t ]*$" 1 font-lock-function-name-face t)      ;menu items
 660    '("@\\(emph\\|strong\\|b\\|i\\){\\([^}]+\\)" 2 font-lock-comment-face t)
 661    '("@\\(file\\|kbd\\|key\\){\\([^}]+\\)" 2 font-lock-string-face t)
 662    '("@\\(samp\\|code\\|var\\){\\([^}]+\\)" 2 font-lock-function-name-face t)
 663    '("@\\(xref\\|pxref\\){\\([^}]+\\)" 2 font-lock-keyword-face t)
 664    '("@end *\\([a-zA-Z0-9]+\\)[ \t]*$" 1 font-lock-function-name-face t)
 665    '("@item \\(.*\\)$" 1 font-lock-function-name-face t)
 666    '("\\$\\([^$]*\\)\\$" 1 font-lock-string-face t)
 667    )
 668   "Additional expressions to highlight in TeXinfo mode.")
 669
 670 (defvar shell-font-lock-keywords
 671   (list (cons shell-prompt-pattern 'font-lock-keyword-face)
 672         (list (concat shell-prompt-pattern "\\([^ \t]+\\)")
 673               1 'font-lock-function-name-face)
 674         '("[ \t]\\([+-][^ \t\n]+\\)" 1 font-lock-comment-face)
 675         '("^[^ \t]+:.*$" . font-lock-string-face)
 676         '("^\\[[1-9][0-9]*\\]" . font-lock-string-face))
 677   "Additional expressions to highlight in Shell mode.")
 678
 679 (defvar dired-font-lock-keywords
 680   '(;; Put directory headers in italics.
 681     ("^  \\(/.+\\)$" 1 font-lock-type-face)
 682     ;; Put symlinks in bold italics.
 683     ("\\([^ ]+\\) -> [^ ]+$" . font-lock-function-name-face)
 684     ;; Put marks in bold.
 685     ("^\\([^ ]\\).*$" 1 font-lock-keyword-face t)
 686     ;; Put files that are subdirectories in bold.
 687     ("^..d.* \\([^ ]+\\)$" 1 font-lock-keyword-face))
 688   "Additional expressions to highlight in Dired mode.")
 689
 690 (provide 'font-lock)
 691
 692 ;;; font-lock.el ends here