code.delx.au - gnu-emacs/blob - lisp/gnus/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36 (require 'gnus-util)
  37
  38 (defcustom gnus-post-method 'current
  39   "*Preferred method for posting USENET news.
  40
  41 If this variable is `current' (which is the default), Gnus will use
  42 the \"current\" select method when posting.  If it is `native', Gnus
  43 will use the native select method when posting.
  44
  45 This method will not be used in mail groups and the like, only in
  46 \"real\" newsgroups.
  47
  48 If not `native' nor `current', the value must be a valid method as discussed
  49 in the documentation of `gnus-select-method'.  It can also be a list of
  50 methods.  If that is the case, the user will be queried for what select
  51 method to use when posting."
  52   :group 'gnus-group-foreign
  53   :link '(custom-manual "(gnus)Posting Server")
  54   :type `(choice (const native)
  55                  (const current)
  56                  (sexp :tag "Methods" ,gnus-select-method)))
  57
  58 (defcustom gnus-outgoing-message-group nil
  59   "*All outgoing messages will be put in this group.
  60 If you want to store all your outgoing mail and articles in the group
  61 \"nnml:archive\", you set this variable to that value.  This variable
  62 can also be a list of group names.
  63
  64 If you want to have greater control over what group to put each
  65 message in, you can set this variable to a function that checks the
  66 current newsgroup name and then returns a suitable group name (or list
  67 of names)."
  68   :group 'gnus-message
  69   :type '(choice (string :tag "Group")
  70                  (function)))
  71
  72 (defcustom gnus-mailing-list-groups nil
  73   "*If non-nil a regexp matching groups that are really mailing lists.
  74 This is useful when you're reading a mailing list that has been
  75 gatewayed to a newsgroup, and you want to followup to an article in
  76 the group."
  77   :group 'gnus-message
  78   :type '(choice (regexp)
  79                  (const nil)))
  80
  81 (defcustom gnus-add-to-list nil
  82   "*If non-nil, add a `to-list' parameter automatically."
  83   :group 'gnus-message
  84   :type 'boolean)
  85
  86 (defcustom gnus-crosspost-complaint
  87   "Hi,
  88
  89 You posted the article below with the following Newsgroups header:
  90
  91 Newsgroups: %s
  92
  93 The %s group, at least, was an inappropriate recipient
  94 of this message.  Please trim your Newsgroups header to exclude this
  95 group before posting in the future.
  96
  97 Thank you.
  98
  99 "
 100   "Format string to be inserted when complaining about crossposts.
 101 The first %s will be replaced by the Newsgroups header;
 102 the second with the current group name."
 103   :group 'gnus-message
 104   :type 'string)
 105
 106 (defcustom gnus-message-setup-hook nil
 107   "Hook run after setting up a message buffer."
 108   :group 'gnus-message
 109   :type 'hook)
 110
 111 (defcustom gnus-bug-create-help-buffer t
 112   "*Should we create the *Gnus Help Bug* buffer?"
 113   :group 'gnus-message
 114   :type 'boolean)
 115
 116 (defcustom gnus-posting-styles nil
 117   "*Alist of styles to use when posting.
 118 See Info node `(gnus)Posting Styles'."
 119   :group 'gnus-message
 120   :link '(custom-manual "(gnus)Posting Styles")
 121   :type '(repeat (cons (choice (regexp)
 122                                (variable)
 123                                (list (const header)
 124                                      (string :tag "Header")
 125                                      (regexp :tag "Regexp"))
 126                                (function)
 127                                (sexp))
 128                        (repeat (list
 129                                 (choice (const signature)
 130                                         (const signature-file)
 131                                         (const organization)
 132                                         (const address)
 133                                         (const x-face-file)
 134                                         (const name)
 135                                         (const body)
 136                                         (symbol)
 137                                         (string :tag "Header"))
 138                                 (choice (string)
 139                                         (function)
 140                                         (variable)
 141                                         (sexp)))))))
 142
 143 (defcustom gnus-gcc-mark-as-read nil
 144   "If non-nil, automatically mark Gcc articles as read."
 145   :version "21.4"
 146   :group 'gnus-message
 147   :type 'boolean)
 148
 149 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 150                         'gnus-gcc-mark-as-read)
 151
 152 (defcustom gnus-gcc-externalize-attachments nil
 153   "Should local-file attachments be included as external parts in Gcc copies?
 154 If it is `all', attach files as external parts;
 155 if a regexp and matches the Gcc group name, attach files as external parts;
 156 if nil, attach files as normal parts."
 157   :version "21.4"
 158   :group 'gnus-message
 159   :type '(choice (const nil :tag "None")
 160                  (const all :tag "Any")
 161                  (string :tag "Regexp")))
 162
 163 (gnus-define-group-parameter
 164  posting-charset-alist
 165  :type list
 166  :function-document
 167  "Return the permitted unencoded charsets for posting of GROUP."
 168  :variable gnus-group-posting-charset-alist
 169  :variable-default
 170   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 171     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 172     (message-this-is-mail nil nil)
 173     (message-this-is-news nil t))
 174  :variable-document
 175   "Alist of regexps and permitted unencoded charsets for posting.
 176 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 177 TEST is either a regular expression matching the newsgroup header or a
 178 variable to query,
 179 HEADER is the charset which may be left unencoded in the header (nil
 180 means encode all charsets),
 181 BODY-LIST is a list of charsets which may be encoded using 8bit
 182 content-transfer encoding in the body, or one of the special values
 183 nil (always encode using quoted-printable) or t (always use 8bit).
 184
 185 Note that any value other than nil for HEADER infringes some RFCs, so
 186 use this option with care."
 187  :variable-group gnus-charset
 188  :variable-type
 189  '(repeat (list :tag "Permitted unencoded charsets"
 190                 (choice :tag "Where"
 191                         (regexp :tag "Group")
 192                         (const :tag "Mail message" :value message-this-is-mail)
 193                         (const :tag "News article" :value message-this-is-news))
 194                 (choice :tag "Header"
 195                         (const :tag "None" nil)
 196                         (symbol :tag "Charset"))
 197                 (choice :tag "Body"
 198                         (const :tag "Any" :value t)
 199                         (const :tag "None" :value nil)
 200                         (repeat :tag "Charsets"
 201                                 (symbol :tag "Charset")))))
 202  :parameter-type '(choice :tag "Permitted unencoded charsets"
 203                           :value nil
 204                           (repeat (symbol)))
 205  :parameter-document       "\
 206 List of charsets that are permitted to be unencoded.")
 207
 208 (defcustom gnus-debug-files
 209   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 210     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 211     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 212     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 213     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 214   "Files whose variables will be reported in `gnus-bug'."
 215   :version "21.4"
 216   :group 'gnus-message
 217   :type '(repeat (string :tag "File")))
 218
 219 (defcustom gnus-debug-exclude-variables
 220   '(mm-mime-mule-charset-alist
 221     nnmail-split-fancy message-minibuffer-local-map)
 222   "Variables that should not be reported in `gnus-bug'."
 223   :version "21.4"
 224   :group 'gnus-message
 225   :type '(repeat (symbol :tag "Variable")))
 226
 227 (defcustom gnus-discouraged-post-methods
 228   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 229   "A list of back ends that are not used in \"real\" newsgroups.
 230 This variable is used only when `gnus-post-method' is `current'."
 231   :version "21.4"
 232   :group 'gnus-group-foreign
 233   :type '(repeat (symbol :tag "Back end")))
 234
 235 (defcustom gnus-message-replysign
 236   nil
 237   "Automatically sign replies to signed messages.
 238 See also the `mml-default-sign-method' variable."
 239   :group 'gnus-message
 240   :type 'boolean)
 241
 242 (defcustom gnus-message-replyencrypt
 243   nil
 244   "Automatically encrypt replies to encrypted messages.
 245 See also the `mml-default-encrypt-method' variable."
 246   :group 'gnus-message
 247   :type 'boolean)
 248
 249 (defcustom gnus-message-replysignencrypted
 250   t
 251   "Setting this causes automatically encrypted messages to also be signed."
 252   :group 'gnus-message
 253   :type 'boolean)
 254
 255 (defcustom gnus-confirm-mail-reply-to-news nil
 256   "If non-nil, Gnus requests confirmation when replying to news.
 257 This is done because new users often reply by mistake when reading
 258 news.
 259 This can also be a function receiving the group name as the only
 260 parameter which should return non-nil iff a confirmation is needed, or
 261 a regexp, in which case a confirmation is asked for iff the group name
 262 matches the regexp."
 263   :version "21.4"
 264   :group 'gnus-message
 265   :type '(choice (const :tag "No" nil)
 266                  (const :tag "Yes" t)
 267                  (regexp :tag "Iff group matches regexp")
 268                  (function :tag "Iff function evaluates to non-nil")))
 269
 270 (defcustom gnus-confirm-treat-mail-like-news
 271   nil
 272   "If non-nil, Gnus will treat mail like news with regard to confirmation
 273 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 274 for fine-tuning this.
 275 If nil, Gnus will never ask for confirmation if replying to mail."
 276   :version "21.4"
 277   :group 'gnus-message
 278   :type 'boolean)
 279
 280 (defcustom gnus-summary-resend-default-address t
 281   "If non-nil, Gnus tries to suggest a default address to resend to.
 282 If nil, the address field will always be empty after invoking
 283 `gnus-summary-resend-message'."
 284   :version "21.4"
 285   :group 'gnus-message
 286   :type 'boolean)
 287
 288 ;;; Internal variables.
 289
 290 (defvar gnus-inhibit-posting-styles nil
 291   "Inhibit the use of posting styles.")
 292
 293 (defvar gnus-article-yanked-articles nil)
 294 (defvar gnus-message-buffer "*Mail Gnus*")
 295 (defvar gnus-article-copy nil)
 296 (defvar gnus-check-before-posting nil)
 297 (defvar gnus-last-posting-server nil)
 298 (defvar gnus-message-group-art nil)
 299
 300 (defvar gnus-msg-force-broken-reply-to nil)
 301
 302 (defconst gnus-bug-message
 303   "Sending a bug report to the Gnus Towers.
 304 ========================================
 305
 306 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 307 be sent to the Gnus Bug Exterminators.
 308
 309 The thing near the bottom of the buffer is how the environment
 310 settings will be included in the mail.  Please do not delete that.
 311 They will tell the Bug People what your environment is, so that it
 312 will be easier to locate the bugs.
 313
 314 If you have found a bug that makes Emacs go \"beep\", set
 315 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 316 and include the backtrace in your bug report.
 317
 318 Please describe the bug in annoying, painstaking detail.
 319
 320 Thank you for your help in stamping out bugs.
 321 ")
 322
 323 (eval-and-compile
 324   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 325   (autoload 'news-setup "rnewspost")
 326   (autoload 'news-reply-mode "rnewspost")
 327   (autoload 'rmail-dont-reply-to "mail-utils")
 328   (autoload 'rmail-output "rmailout"))
 329
 330 \f
 331 ;;;
 332 ;;; Gnus Posting Functions
 333 ;;;
 334
 335 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 336   "p" gnus-summary-post-news
 337   "i" gnus-summary-news-other-window
 338   "f" gnus-summary-followup
 339   "F" gnus-summary-followup-with-original
 340   "c" gnus-summary-cancel-article
 341   "s" gnus-summary-supersede-article
 342   "r" gnus-summary-reply
 343   "y" gnus-summary-yank-message
 344   "R" gnus-summary-reply-with-original
 345   "w" gnus-summary-wide-reply
 346   "W" gnus-summary-wide-reply-with-original
 347   "v" gnus-summary-very-wide-reply
 348   "V" gnus-summary-very-wide-reply-with-original
 349   "n" gnus-summary-followup-to-mail
 350   "N" gnus-summary-followup-to-mail-with-original
 351   "m" gnus-summary-mail-other-window
 352   "u" gnus-uu-post-news
 353   "\M-c" gnus-summary-mail-crosspost-complaint
 354   "Br" gnus-summary-reply-broken-reply-to
 355   "BR" gnus-summary-reply-broken-reply-to-with-original
 356   "om" gnus-summary-mail-forward
 357   "op" gnus-summary-post-forward
 358   "Om" gnus-uu-digest-mail-forward
 359   "Op" gnus-uu-digest-post-forward)
 360
 361 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 362   "b" gnus-summary-resend-bounced-mail
 363   ;; "c" gnus-summary-send-draft
 364   "r" gnus-summary-resend-message
 365   "e" gnus-summary-resend-message-edit)
 366
 367 ;;; Internal functions.
 368
 369 (defun gnus-inews-make-draft ()
 370   `(lambda ()
 371      (gnus-inews-make-draft-meta-information
 372       ,gnus-newsgroup-name ',gnus-article-reply)))
 373
 374 (defvar gnus-article-reply nil)
 375 (defmacro gnus-setup-message (config &rest forms)
 376   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 377         (buffer (make-symbol "gnus-setup-message-buffer"))
 378         (article (make-symbol "gnus-setup-message-article"))
 379         (yanked (make-symbol "gnus-setup-yanked-articles"))
 380         (group (make-symbol "gnus-setup-message-group")))
 381     `(let ((,winconf (current-window-configuration))
 382            (,buffer (buffer-name (current-buffer)))
 383            (,article gnus-article-reply)
 384            (,yanked gnus-article-yanked-articles)
 385            (,group gnus-newsgroup-name)
 386            (message-header-setup-hook
 387             (copy-sequence message-header-setup-hook))
 388            (mbl mml-buffer-list)
 389            (message-mode-hook (copy-sequence message-mode-hook)))
 390        (setq mml-buffer-list nil)
 391        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 392        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 393        ;; #### FIXME: for a reason that I did not manage to identify yet,
 394        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 395        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 396        ;; After evaluation of @forms below, it gets the value we actually want
 397        ;; to override, and the posting styles are used. For that reason, I've
 398        ;; added an optional argument to `gnus-configure-posting-styles' to
 399        ;; make sure that the correct value for the group name is used. -- drv
 400        (add-hook 'message-mode-hook
 401                  (if (memq ,config '(reply-yank reply))
 402                      (lambda ()
 403                        (gnus-configure-posting-styles ,group))
 404                    (lambda ()
 405                      ;; There may be an old " *gnus article copy*" buffer.
 406                      (let (gnus-article-copy)
 407                        (gnus-configure-posting-styles ,group)))))
 408        (gnus-pull ',(intern gnus-draft-meta-information-header)
 409                   message-required-headers)
 410        (when (and ,group
 411                   (not (string= ,group "")))
 412          (push (cons
 413                 (intern gnus-draft-meta-information-header)
 414                 (gnus-inews-make-draft))
 415                message-required-headers))
 416        (unwind-protect
 417            (progn
 418              ,@forms)
 419          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 420                                       ,yanked)
 421          (setq gnus-message-buffer (current-buffer))
 422          (set (make-local-variable 'gnus-message-group-art)
 423               (cons ,group ,article))
 424          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 425          (gnus-run-hooks 'gnus-message-setup-hook)
 426          (if (eq major-mode 'message-mode)
 427              (let ((mbl1 mml-buffer-list))
 428                (setq mml-buffer-list mbl)  ;; Global value
 429                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 430                (gnus-make-local-hook 'kill-buffer-hook)
 431                (gnus-make-local-hook 'change-major-mode-hook)
 432                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 433                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 434            (mml-destroy-buffers)
 435            (setq mml-buffer-list mbl)))
 436        (message-hide-headers)
 437        (gnus-add-buffer)
 438        (gnus-configure-windows ,config t)
 439        (run-hooks 'post-command-hook)
 440        (set-buffer-modified-p nil))))
 441
 442 (defun gnus-inews-make-draft-meta-information (group article)
 443   (concat "(\"" group "\" "
 444           (if article (number-to-string
 445                        (if (listp article)
 446                            (car article)
 447                          article)) "\"\"")
 448           ")"))
 449
 450 ;;;###autoload
 451 (defun gnus-msg-mail (&optional to subject other-headers continue
 452                                 switch-action yank-action send-actions)
 453   "Start editing a mail message to be sent.
 454 Like `message-mail', but with Gnus paraphernalia, particularly the
 455 Gcc: header for archiving purposes."
 456   (interactive)
 457   (let ((buf (current-buffer))
 458         mail-buf)
 459     (gnus-setup-message 'message
 460       (message-mail to subject other-headers continue
 461                     nil yank-action send-actions))
 462     (when switch-action
 463       (setq mail-buf (current-buffer))
 464       (switch-to-buffer buf)
 465       (apply switch-action mail-buf nil)))
 466   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 467   t)
 468
 469 (defvar save-selected-window-window)
 470
 471 ;;;###autoload
 472 (defun gnus-button-mailto (address)
 473   "Mail to ADDRESS."
 474   (set-buffer (gnus-copy-article-buffer))
 475   (gnus-setup-message 'message
 476     (message-reply address))
 477   (and (boundp 'save-selected-window-window)
 478        (not (window-live-p save-selected-window-window))
 479        (setq save-selected-window-window (selected-window))))
 480
 481 ;;;###autoload
 482 (defun gnus-button-reply (&optional to-address wide)
 483   "Like `message-reply'."
 484   (interactive)
 485   (gnus-setup-message 'message
 486     (message-reply to-address wide))
 487   (and (boundp 'save-selected-window-window)
 488        (not (window-live-p save-selected-window-window))
 489        (setq save-selected-window-window (selected-window))))
 490
 491 ;;;###autoload
 492 (define-mail-user-agent 'gnus-user-agent
 493   'gnus-msg-mail 'message-send-and-exit
 494   'message-kill-buffer 'message-send-hook)
 495
 496 (defun gnus-setup-posting-charset (group)
 497   (let ((alist gnus-group-posting-charset-alist)
 498         (group (or group ""))
 499         elem)
 500     (when group
 501       (catch 'found
 502         (while (setq elem (pop alist))
 503           (when (or (and (stringp (car elem))
 504                          (string-match (car elem) group))
 505                     (and (functionp (car elem))
 506                          (funcall (car elem) group))
 507                     (and (symbolp (car elem))
 508                          (symbol-value (car elem))))
 509             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 510
 511 (defun gnus-inews-add-send-actions (winconf buffer article
 512                                             &optional config yanked)
 513   (gnus-make-local-hook 'message-sent-hook)
 514   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 515                                  'gnus-inews-do-gcc) nil t)
 516   (when gnus-agent
 517     (gnus-make-local-hook 'message-header-hook)
 518     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 519   (setq message-post-method
 520         `(lambda (arg)
 521            (gnus-post-method arg ,gnus-newsgroup-name)))
 522   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 523   (message-add-action
 524    `(when (gnus-buffer-exists-p ,buffer)
 525       (set-window-configuration ,winconf))
 526    'exit 'postpone 'kill)
 527   (let ((to-be-marked (cond
 528                        (yanked
 529                         (mapcar
 530                          (lambda (x) (if (listp x) (car x) x)) yanked))
 531                        (article (if (listp article) article (list article)))
 532                        (t nil))))
 533     (message-add-action
 534      `(when (gnus-buffer-exists-p ,buffer)
 535         (save-excursion
 536           (set-buffer ,buffer)
 537           ,(when to-be-marked
 538              (if (eq config 'forward)
 539                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 540                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 541      'send)))
 542
 543 (put 'gnus-setup-message 'lisp-indent-function 1)
 544 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 545
 546 ;;; Post news commands of Gnus group mode and summary mode
 547
 548 (defun gnus-group-mail (&optional arg)
 549   "Start composing a mail.
 550 If ARG, use the group under the point to find a posting style.
 551 If ARG is 1, prompt for a group name to find the posting style."
 552   (interactive "P")
 553   ;; We can't `let' gnus-newsgroup-name here, since that leads
 554   ;; to local variables leaking.
 555   (let ((group gnus-newsgroup-name)
 556         ;; make sure last viewed article doesn't affect posting styles:
 557         (gnus-article-copy)
 558         (buffer (current-buffer)))
 559     (unwind-protect
 560         (progn
 561           (setq gnus-newsgroup-name
 562                 (if arg
 563                     (if (= 1 (prefix-numeric-value arg))
 564                         (completing-read "Use posting style of group: "
 565                                          gnus-active-hashtb nil
 566                                          (gnus-read-active-file-p))
 567                       (gnus-group-group-name))
 568                   ""))
 569           ;; #### see comment in gnus-setup-message -- drv
 570           (gnus-setup-message 'message (message-mail)))
 571       (save-excursion
 572         (set-buffer buffer)
 573         (setq gnus-newsgroup-name group)))))
 574
 575 (defun gnus-group-news (&optional arg)
 576   "Start composing a news.
 577 If ARG, post to group under point.
 578 If ARG is 1, prompt for group name to post to.
 579
 580 This function prepares a news even when using mail groups.  This is useful
 581 for posting messages to mail groups without actually sending them over the
 582 network.  The corresponding back end must have a 'request-post method."
 583   (interactive "P")
 584   ;; We can't `let' gnus-newsgroup-name here, since that leads
 585   ;; to local variables leaking.
 586   (let ((group gnus-newsgroup-name)
 587         ;; make sure last viewed article doesn't affect posting styles:
 588         (gnus-article-copy)
 589         (buffer (current-buffer)))
 590     (unwind-protect
 591         (progn
 592           (setq gnus-newsgroup-name
 593                 (if arg
 594                     (if (= 1 (prefix-numeric-value arg))
 595                         (completing-read "Use group: "
 596                                          gnus-active-hashtb nil
 597                                          (gnus-read-active-file-p))
 598                       (gnus-group-group-name))
 599                   ""))
 600           ;; #### see comment in gnus-setup-message -- drv
 601           (gnus-setup-message 'message
 602             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 603       (save-excursion
 604         (set-buffer buffer)
 605         (setq gnus-newsgroup-name group)))))
 606
 607 (defun gnus-group-post-news (&optional arg)
 608   "Start composing a message (a news by default).
 609 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 610 Depending on the selected group, the message might be either a mail or
 611 a news."
 612   (interactive "P")
 613   ;; Bind this variable here to make message mode hooks work ok.
 614   (let ((gnus-newsgroup-name
 615          (if arg
 616              (if (= 1 (prefix-numeric-value arg))
 617                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 618                                   (gnus-read-active-file-p))
 619                (gnus-group-group-name))
 620            ""))
 621         ;; make sure last viewed article doesn't affect posting styles:
 622         (gnus-article-copy))
 623     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 624                     (string= gnus-newsgroup-name ""))))
 625
 626 (defun gnus-summary-mail-other-window (&optional arg)
 627   "Start composing a mail in another window.
 628 Use the posting of the current group by default.
 629 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 630 posting style."
 631   (interactive "P")
 632   ;; We can't `let' gnus-newsgroup-name here, since that leads
 633   ;; to local variables leaking.
 634   (let ((group gnus-newsgroup-name)
 635         ;; make sure last viewed article doesn't affect posting styles:
 636         (gnus-article-copy)
 637         (buffer (current-buffer)))
 638     (unwind-protect
 639         (progn
 640           (setq gnus-newsgroup-name
 641                 (if arg
 642                     (if (= 1 (prefix-numeric-value arg))
 643                         (completing-read "Use group: "
 644                                          gnus-active-hashtb nil
 645                                          (gnus-read-active-file-p))
 646                       "")
 647                   gnus-newsgroup-name))
 648           ;; #### see comment in gnus-setup-message -- drv
 649           (gnus-setup-message 'message (message-mail)))
 650       (save-excursion
 651         (set-buffer buffer)
 652         (setq gnus-newsgroup-name group)))))
 653
 654 (defun gnus-summary-news-other-window (&optional arg)
 655   "Start composing a news in another window.
 656 Post to the current group by default.
 657 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 658
 659 This function prepares a news even when using mail groups.  This is useful
 660 for posting messages to mail groups without actually sending them over the
 661 network.  The corresponding back end must have a 'request-post method."
 662   (interactive "P")
 663   ;; We can't `let' gnus-newsgroup-name here, since that leads
 664   ;; to local variables leaking.
 665   (let ((group gnus-newsgroup-name)
 666         ;; make sure last viewed article doesn't affect posting styles:
 667         (gnus-article-copy)
 668         (buffer (current-buffer)))
 669     (unwind-protect
 670         (progn
 671           (setq gnus-newsgroup-name
 672                 (if arg
 673                     (if (= 1 (prefix-numeric-value arg))
 674                         (completing-read "Use group: "
 675                                          gnus-active-hashtb nil
 676                                          (gnus-read-active-file-p))
 677                       "")
 678                   gnus-newsgroup-name))
 679           ;; #### see comment in gnus-setup-message -- drv
 680           (gnus-setup-message 'message
 681             (progn
 682               (message-news (gnus-group-real-name gnus-newsgroup-name))
 683               (set (make-local-variable 'gnus-discouraged-post-methods)
 684                    (delq
 685                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 686                     (copy-sequence gnus-discouraged-post-methods))))))
 687       (save-excursion
 688         (set-buffer buffer)
 689         (setq gnus-newsgroup-name group)))))
 690
 691 (defun gnus-summary-post-news (&optional arg)
 692   "Start composing a message.  Post to the current group by default.
 693 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 694 Depending on the selected group, the message might be either a mail or
 695 a news."
 696   (interactive "P")
 697   ;; Bind this variable here to make message mode hooks work ok.
 698   (let ((gnus-newsgroup-name
 699          (if arg
 700              (if (= 1 (prefix-numeric-value arg))
 701                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 702                                   (gnus-read-active-file-p))
 703                "")
 704            gnus-newsgroup-name))
 705         ;; make sure last viewed article doesn't affect posting styles:
 706         (gnus-article-copy))
 707     (gnus-post-news 'post gnus-newsgroup-name)))
 708
 709
 710 (defun gnus-summary-followup (yank &optional force-news)
 711   "Compose a followup to an article.
 712 If prefix argument YANK is non-nil, the original article is yanked
 713 automatically.
 714 YANK is a list of elements, where the car of each element is the
 715 article number, and the cdr is the string to be yanked."
 716   (interactive
 717    (list (and current-prefix-arg
 718               (gnus-summary-work-articles 1))))
 719   (when yank
 720     (gnus-summary-goto-subject
 721      (if (listp (car yank))
 722          (caar yank)
 723        (car yank))))
 724   (save-window-excursion
 725     (gnus-summary-select-article))
 726   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 727         (gnus-newsgroup-name gnus-newsgroup-name))
 728     ;; Send a followup.
 729     (gnus-post-news nil gnus-newsgroup-name
 730                     headers gnus-article-buffer
 731                     yank nil force-news)
 732     (gnus-summary-handle-replysign)))
 733
 734 (defun gnus-summary-followup-with-original (n &optional force-news)
 735   "Compose a followup to an article and include the original article.
 736 The text in the region will be yanked.  If the region isn't
 737 active, the entire article will be yanked."
 738   (interactive "P")
 739   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 740
 741 (defun gnus-summary-followup-to-mail (&optional arg)
 742   "Followup to the current mail message via news."
 743   (interactive
 744    (list (and current-prefix-arg
 745               (gnus-summary-work-articles 1))))
 746   (gnus-summary-followup arg t))
 747
 748 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 749   "Followup to the current mail message via news."
 750   (interactive "P")
 751   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 752
 753 (defun gnus-inews-yank-articles (articles)
 754   (let (beg article yank-string)
 755     (message-goto-body)
 756     (while (setq article (pop articles))
 757       (when (listp article)
 758         (setq yank-string (nth 1 article)
 759               article (nth 0 article)))
 760       (save-window-excursion
 761         (set-buffer gnus-summary-buffer)
 762         (gnus-summary-select-article nil nil nil article)
 763         (gnus-summary-remove-process-mark article))
 764       (gnus-copy-article-buffer nil yank-string)
 765       (let ((message-reply-buffer gnus-article-copy)
 766             (message-reply-headers
 767              ;; The headers are decoded.
 768              (with-current-buffer gnus-article-copy
 769                (save-restriction
 770                  (nnheader-narrow-to-headers)
 771                  (nnheader-parse-naked-head)))))
 772         (message-yank-original)
 773         (setq beg (or beg (mark t))))
 774       (when articles
 775         (insert "\n")))
 776     (push-mark)
 777     (goto-char beg)))
 778
 779 (defun gnus-summary-cancel-article (&optional n symp)
 780   "Cancel an article you posted.
 781 Uses the process-prefix convention.  If given the symbolic
 782 prefix `a', cancel using the standard posting method; if not
 783 post using the current select method."
 784   (interactive (gnus-interactive "P\ny"))
 785   (let ((articles (gnus-summary-work-articles n))
 786         (message-post-method
 787          `(lambda (arg)
 788             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
 789         article)
 790     (while (setq article (pop articles))
 791       (when (gnus-summary-select-article t nil nil article)
 792         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 793                 (message-cancel-news))
 794           (gnus-summary-mark-as-read article gnus-canceled-mark)
 795           (gnus-cache-remove-article 1))
 796         (gnus-article-hide-headers-if-wanted))
 797       (gnus-summary-remove-process-mark article))))
 798
 799 (defun gnus-summary-supersede-article ()
 800   "Compose an article that will supersede a previous article.
 801 This is done simply by taking the old article and adding a Supersedes
 802 header line with the old Message-ID."
 803   (interactive)
 804   (let ((article (gnus-summary-article-number)))
 805     (gnus-setup-message 'reply-yank
 806       (gnus-summary-select-article t)
 807       (set-buffer gnus-original-article-buffer)
 808       (message-supersede)
 809       (push
 810        `((lambda ()
 811            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 812              (save-excursion
 813                (set-buffer ,gnus-summary-buffer)
 814                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 815                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 816        message-send-actions))))
 817
 818 \f
 819
 820 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 821   ;; make a copy of the article buffer with all text properties removed
 822   ;; this copy is in the buffer gnus-article-copy.
 823   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 824   ;; this buffer should be passed to all mail/news reply/post routines.
 825   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 826   (save-excursion
 827     (set-buffer gnus-article-copy)
 828     (mm-enable-multibyte))
 829   (let ((article-buffer (or article-buffer gnus-article-buffer))
 830         end beg)
 831     (if (not (and (get-buffer article-buffer)
 832                   (gnus-buffer-exists-p article-buffer)))
 833         (error "Can't find any article buffer")
 834       (save-excursion
 835         (set-buffer article-buffer)
 836         (let ((gnus-newsgroup-charset (or gnus-article-charset
 837                                           gnus-newsgroup-charset))
 838               (gnus-newsgroup-ignored-charsets
 839                (or gnus-article-ignored-charsets
 840                    gnus-newsgroup-ignored-charsets)))
 841           (save-restriction
 842             ;; Copy over the (displayed) article buffer, delete
 843             ;; hidden text and remove text properties.
 844             (widen)
 845             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 846             (set-buffer gnus-article-copy)
 847             (when yank-string
 848               (message-goto-body)
 849               (delete-region (point) (point-max))
 850               (insert yank-string))
 851             (gnus-article-delete-text-of-type 'annotation)
 852             (gnus-remove-text-with-property 'gnus-prev)
 853             (gnus-remove-text-with-property 'gnus-next)
 854             (gnus-remove-text-with-property 'gnus-decoration)
 855             (insert
 856              (prog1
 857                  (buffer-substring-no-properties (point-min) (point-max))
 858                (erase-buffer)))
 859             ;; Find the original headers.
 860             (set-buffer gnus-original-article-buffer)
 861             (goto-char (point-min))
 862             (while (looking-at message-unix-mail-delimiter)
 863               (forward-line 1))
 864             (let ((mail-header-separator ""))
 865               (setq beg (point)
 866                     end (or (message-goto-body)
 867                             ;; There may be just a header.
 868                             (point-max))))
 869             ;; Delete the headers from the displayed articles.
 870             (set-buffer gnus-article-copy)
 871             (let ((mail-header-separator ""))
 872               (delete-region (goto-char (point-min))
 873                              (or (message-goto-body) (point-max))))
 874             ;; Insert the original article headers.
 875             (insert-buffer-substring gnus-original-article-buffer beg end)
 876             ;; Decode charsets.
 877             (let ((gnus-article-decode-hook
 878                    (delq 'article-decode-charset
 879                          (copy-sequence gnus-article-decode-hook))))
 880               (run-hooks 'gnus-article-decode-hook)))))
 881       gnus-article-copy)))
 882
 883 (defun gnus-post-news (post &optional group header article-buffer yank subject
 884                             force-news)
 885   (when article-buffer
 886     (gnus-copy-article-buffer))
 887   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 888         (gnus-article-yanked-articles yank)
 889         (add-to-list gnus-add-to-list))
 890     (gnus-setup-message (cond (yank 'reply-yank)
 891                               (article-buffer 'reply)
 892                               (t 'message))
 893       (let* ((group (or group gnus-newsgroup-name))
 894              (charset (gnus-group-name-charset nil group))
 895              (pgroup group)
 896              to-address to-group mailing-list to-list
 897              newsgroup-p)
 898         (when group
 899           (setq to-address (gnus-parameter-to-address group)
 900                 to-group (gnus-group-find-parameter group 'to-group)
 901                 to-list (gnus-parameter-to-list group)
 902                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 903                 mailing-list (when gnus-mailing-list-groups
 904                                (string-match gnus-mailing-list-groups group))
 905                 group (gnus-group-name-decode (gnus-group-real-name group)
 906                                               charset)))
 907         (if (or (and to-group
 908                      (gnus-news-group-p to-group))
 909                 newsgroup-p
 910                 force-news
 911                 (and (gnus-news-group-p
 912                       (or pgroup gnus-newsgroup-name)
 913                       (or header gnus-current-article))
 914                      (not mailing-list)
 915                      (not to-list)
 916                      (not to-address)))
 917             ;; This is news.
 918             (if post
 919                 (message-news
 920                  (or to-group
 921                      (and (not (gnus-virtual-group-p pgroup)) group)))
 922               (set-buffer gnus-article-copy)
 923               (gnus-msg-treat-broken-reply-to)
 924               (message-followup (if (or newsgroup-p force-news)
 925                                     (if (save-restriction
 926                                           (article-narrow-to-head)
 927                                           (message-fetch-field "newsgroups"))
 928                                         nil
 929                                       "")
 930                                   to-group)))
 931           ;; The is mail.
 932           (if post
 933               (progn
 934                 (message-mail (or to-address to-list))
 935                 ;; Arrange for mail groups that have no `to-address' to
 936                 ;; get that when the user sends off the mail.
 937                 (when (and (not to-list)
 938                            (not to-address)
 939                            add-to-list)
 940                   (push (list 'gnus-inews-add-to-address pgroup)
 941                         message-send-actions)))
 942             (set-buffer gnus-article-copy)
 943             (gnus-msg-treat-broken-reply-to)
 944             (message-wide-reply to-address)))
 945         (when yank
 946           (gnus-inews-yank-articles yank))))))
 947
 948 (defun gnus-msg-treat-broken-reply-to (&optional force)
 949   "Remove the Reply-to header if broken-reply-to."
 950   (when (or force
 951             (gnus-group-find-parameter
 952              gnus-newsgroup-name 'broken-reply-to))
 953     (save-restriction
 954       (message-narrow-to-head)
 955       (message-remove-header "reply-to"))))
 956
 957 (defun gnus-post-method (arg group &optional silent)
 958   "Return the posting method based on GROUP and ARG.
 959 If SILENT, don't prompt the user."
 960   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 961                               gnus-post-method))
 962         (group-method (gnus-find-method-for-group group)))
 963     (cond
 964      ;; If the group-method is nil (which shouldn't happen) we use
 965      ;; the default method.
 966      ((null group-method)
 967       (or (and (listp gnus-post-method) ;If not current/native/nil
 968                (not (listp (car gnus-post-method))) ; and not a list of methods
 969                gnus-post-method)        ;then use it.
 970           gnus-select-method
 971           message-post-method))
 972      ;; We want the inverse of the default
 973      ((and arg (not (eq arg 0)))
 974       (if (eq gnus-post-method 'current)
 975           gnus-select-method
 976         group-method))
 977      ;; We query the user for a post method.
 978      ((or arg
 979           (and (listp gnus-post-method)
 980                (listp (car gnus-post-method))))
 981       (let* ((methods
 982               ;; Collect all methods we know about.
 983               (append
 984                (when (listp gnus-post-method)
 985                  (if (listp (car gnus-post-method))
 986                      gnus-post-method
 987                    (list gnus-post-method)))
 988                gnus-secondary-select-methods
 989                (mapcar 'cdr gnus-server-alist)
 990                (mapcar 'car gnus-opened-servers)
 991                (list gnus-select-method)
 992                (list group-method)))
 993              method-alist post-methods method)
 994         ;; Weed out all mail methods.
 995         (while methods
 996           (setq method (gnus-server-get-method "" (pop methods)))
 997           (when (and (or (gnus-method-option-p method 'post)
 998                          (gnus-method-option-p method 'post-mail))
 999                      (not (member method post-methods)))
1000             (push method post-methods)))
1001         ;; Create a name-method alist.
1002         (setq method-alist
1003               (mapcar
1004                (lambda (m)
1005                  (if (equal (cadr m) "")
1006                      (list (symbol-name (car m)) m)
1007                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1008                post-methods))
1009         ;; Query the user.
1010         (cadr
1011          (assoc
1012           (setq gnus-last-posting-server
1013                 (if (and silent
1014                          gnus-last-posting-server)
1015                     ;; Just use the last value.
1016                     gnus-last-posting-server
1017                   (completing-read
1018                    "Posting method: " method-alist nil t
1019                    (cons (or gnus-last-posting-server "") 0))))
1020           method-alist))))
1021      ;; Override normal method.
1022      ((and (eq gnus-post-method 'current)
1023            (not (memq (car group-method) gnus-discouraged-post-methods))
1024            (gnus-get-function group-method 'request-post t))
1025       (assert (not arg))
1026       group-method)
1027      ;; Use gnus-post-method.
1028      ((listp gnus-post-method)          ;A method...
1029       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1030       gnus-post-method)
1031      ;; Use the normal select method (nil or native).
1032      (t gnus-select-method))))
1033
1034 \f
1035
1036 (defun gnus-extended-version ()
1037   "Stringified Gnus version and Emacs version.
1038 See the variable `gnus-user-agent'."
1039   (interactive)
1040   (let* ((float-output-format nil)
1041          (gnus-v
1042           (concat "Gnus/"
1043                   (prin1-to-string (gnus-continuum-version gnus-version) t)
1044                   " (" gnus-version ")"))
1045          (emacs-v (gnus-emacs-version)))
1046     (if (stringp gnus-user-agent)
1047         gnus-user-agent
1048       (concat gnus-v
1049               (when emacs-v
1050                 (concat " " emacs-v))))))
1051
1052 \f
1053 ;;;
1054 ;;; Gnus Mail Functions
1055 ;;;
1056
1057 ;;; Mail reply commands of Gnus summary mode
1058
1059 (defun gnus-summary-reply (&optional yank wide very-wide)
1060   "Start composing a mail reply to the current message.
1061 If prefix argument YANK is non-nil, the original article is yanked
1062 automatically.
1063 If WIDE, make a wide reply.
1064 If VERY-WIDE, make a very wide reply."
1065   (interactive
1066    (list (and current-prefix-arg
1067               (gnus-summary-work-articles 1))))
1068   ;; Allow user to require confirmation before replying by mail to the
1069   ;; author of a news article (or mail message).
1070   (when (or
1071             (not (or (gnus-news-group-p gnus-newsgroup-name)
1072                      gnus-confirm-treat-mail-like-news))
1073             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1074                         (string-match gnus-confirm-mail-reply-to-news
1075                                       gnus-newsgroup-name))
1076                        ((functionp gnus-confirm-mail-reply-to-news)
1077                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1078                        (t gnus-confirm-mail-reply-to-news)))
1079             (y-or-n-p "Really reply by mail to article author? "))
1080     (let* ((article
1081             (if (listp (car yank))
1082                 (caar yank)
1083               (car yank)))
1084            (gnus-article-reply (or article (gnus-summary-article-number)))
1085            (gnus-article-yanked-articles yank)
1086            (headers ""))
1087       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1088       (when yank
1089         (gnus-summary-goto-subject article))
1090       (gnus-setup-message (if yank 'reply-yank 'reply)
1091         (if (not very-wide)
1092             (gnus-summary-select-article)
1093           (dolist (article very-wide)
1094             (gnus-summary-select-article nil nil nil article)
1095             (save-excursion
1096               (set-buffer (gnus-copy-article-buffer))
1097               (gnus-msg-treat-broken-reply-to)
1098               (save-restriction
1099                 (message-narrow-to-head)
1100                 (setq headers (concat headers (buffer-string)))))))
1101         (set-buffer (gnus-copy-article-buffer))
1102         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1103         (save-restriction
1104           (message-narrow-to-head)
1105           (when very-wide
1106             (erase-buffer)
1107             (insert headers))
1108           (goto-char (point-max)))
1109         (mml-quote-region (point) (point-max))
1110         (message-reply nil wide)
1111         (when yank
1112           (gnus-inews-yank-articles yank))
1113         (gnus-summary-handle-replysign)))))
1114
1115 (defun gnus-summary-handle-replysign ()
1116   "Check the various replysign variables and take action accordingly."
1117   (when (or gnus-message-replysign gnus-message-replyencrypt)
1118     (let (signed encrypted)
1119       (save-excursion
1120         (set-buffer gnus-article-buffer)
1121         (setq signed (memq 'signed gnus-article-wash-types))
1122         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1123       (cond ((and gnus-message-replyencrypt encrypted)
1124              (mml-secure-message mml-default-encrypt-method
1125                                  (if gnus-message-replysignencrypted
1126                                      'signencrypt
1127                                    'encrypt)))
1128             ((and gnus-message-replysign signed)
1129              (mml-secure-message mml-default-sign-method 'sign))))))
1130
1131 (defun gnus-summary-reply-with-original (n &optional wide)
1132   "Start composing a reply mail to the current message.
1133 The original article will be yanked."
1134   (interactive "P")
1135   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1136
1137 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1138   "Like `gnus-summary-reply' except removing reply-to field.
1139 If prefix argument YANK is non-nil, the original article is yanked
1140 automatically.
1141 If WIDE, make a wide reply.
1142 If VERY-WIDE, make a very wide reply."
1143   (interactive
1144    (list (and current-prefix-arg
1145               (gnus-summary-work-articles 1))))
1146   (let ((gnus-msg-force-broken-reply-to t))
1147     (gnus-summary-reply yank wide very-wide)))
1148
1149 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1150   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1151 The original article will be yanked."
1152   (interactive "P")
1153   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1154
1155 (defun gnus-summary-wide-reply (&optional yank)
1156   "Start composing a wide reply mail to the current message.
1157 If prefix argument YANK is non-nil, the original article is yanked
1158 automatically."
1159   (interactive
1160    (list (and current-prefix-arg
1161               (gnus-summary-work-articles 1))))
1162   (gnus-summary-reply yank t))
1163
1164 (defun gnus-summary-wide-reply-with-original (n)
1165   "Start composing a wide reply mail to the current message.
1166 The original article will be yanked.
1167 Uses the process/prefix convention."
1168   (interactive "P")
1169   (gnus-summary-reply-with-original n t))
1170
1171 (defun gnus-summary-very-wide-reply (&optional yank)
1172   "Start composing a very wide reply mail to the current message.
1173 If prefix argument YANK is non-nil, the original article is yanked
1174 automatically."
1175   (interactive
1176    (list (and current-prefix-arg
1177               (gnus-summary-work-articles 1))))
1178   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1179
1180 (defun gnus-summary-very-wide-reply-with-original (n)
1181   "Start composing a very wide reply mail to the current message.
1182 The original article will be yanked."
1183   (interactive "P")
1184   (gnus-summary-reply
1185    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1186
1187 (defun gnus-summary-mail-forward (&optional arg post)
1188   "Forward the current message(s) to another user.
1189 If process marks exist, forward all marked messages;
1190 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1191 if ARG is 1, decode the message and forward directly inline;
1192 if ARG is 2, forward message as an rfc822 MIME section;
1193 if ARG is 3, decode message and forward as an rfc822 MIME section;
1194 if ARG is 4, forward message directly inline;
1195 otherwise, use flipped `message-forward-as-mime'.
1196 If POST, post instead of mail.
1197 For the `inline' alternatives, also see the variable
1198 `message-forward-ignored-headers'."
1199   (interactive "P")
1200   (if (cdr (gnus-summary-work-articles nil))
1201       ;; Process marks are given.
1202       (gnus-uu-digest-mail-forward arg post)
1203     ;; No process marks.
1204     (let ((message-forward-as-mime message-forward-as-mime)
1205           (message-forward-show-mml message-forward-show-mml))
1206       (cond
1207        ((null arg))
1208        ((eq arg 1)
1209         (setq message-forward-as-mime nil
1210               message-forward-show-mml t))
1211        ((eq arg 2)
1212         (setq message-forward-as-mime t
1213               message-forward-show-mml nil))
1214        ((eq arg 3)
1215         (setq message-forward-as-mime t
1216               message-forward-show-mml t))
1217        ((eq arg 4)
1218         (setq message-forward-as-mime nil
1219               message-forward-show-mml nil))
1220        (t
1221         (setq message-forward-as-mime (not message-forward-as-mime))))
1222       (let* ((gnus-article-reply (gnus-summary-article-number))
1223              (gnus-article-yanked-articles (list gnus-article-reply)))
1224         (gnus-setup-message 'forward
1225           (gnus-summary-select-article)
1226           (let ((mail-parse-charset
1227                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1228                           (with-current-buffer gnus-article-buffer
1229                             gnus-article-charset))
1230                      gnus-newsgroup-charset))
1231                 (mail-parse-ignored-charsets
1232                  gnus-newsgroup-ignored-charsets))
1233             (set-buffer gnus-original-article-buffer)
1234             (message-forward post)))))))
1235
1236 (defun gnus-summary-resend-message (address n)
1237   "Resend the current article to ADDRESS."
1238   (interactive
1239    (list (message-read-from-minibuffer
1240           "Resend message(s) to: "
1241           (when (and gnus-summary-resend-default-address
1242                      (gnus-buffer-live-p gnus-original-article-buffer))
1243             ;; If some other article is currently selected, the
1244             ;; initial-contents is wrong. Whatever, it is just the
1245             ;; initial-contents.
1246             (with-current-buffer gnus-original-article-buffer
1247               (nnmail-fetch-field "to"))))
1248          current-prefix-arg))
1249   (let ((articles (gnus-summary-work-articles n))
1250         article)
1251     (while (setq article (pop articles))
1252       (gnus-summary-select-article nil nil nil article)
1253       (save-excursion
1254         (set-buffer gnus-original-article-buffer)
1255         (message-resend address))
1256       (gnus-summary-mark-article-as-forwarded article))))
1257
1258 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1259 (defun gnus-summary-resend-message-edit ()
1260   "Resend an article that has already been sent.
1261 A new buffer will be created to allow the user to modify body and
1262 contents of the message, and then, everything will happen as when
1263 composing a new message."
1264   (interactive)
1265   (let ((article (gnus-summary-article-number)))
1266     (gnus-setup-message 'reply-yank
1267       (gnus-summary-select-article t)
1268       (set-buffer gnus-original-article-buffer)
1269       (let ((cur (current-buffer))
1270             (to (message-fetch-field "to")))
1271         ;; Get a normal message buffer.
1272         (message-pop-to-buffer (message-buffer-name "Resend" to))
1273         (insert-buffer-substring cur)
1274         (mime-to-mml)
1275         (message-narrow-to-head-1)
1276         ;; Gnus will generate a new one when sending.
1277         (message-remove-header "Message-ID")
1278         (message-remove-header message-ignored-resent-headers t)
1279         ;; Remove unwanted headers.
1280         (goto-char (point-max))
1281         (insert mail-header-separator)
1282         (goto-char (point-min))
1283         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1284           (forward-char 1))
1285         (widen)))))
1286
1287 (defun gnus-summary-post-forward (&optional arg)
1288   "Forward the current article to a newsgroup.
1289 See `gnus-summary-mail-forward' for ARG."
1290   (interactive "P")
1291   (gnus-summary-mail-forward arg t))
1292
1293 (defvar gnus-nastygram-message
1294   "The following article was inappropriately posted to %s.\n\n"
1295   "Format string to insert in nastygrams.
1296 The current group name will be inserted at \"%s\".")
1297
1298 (defun gnus-summary-mail-nastygram (n)
1299   "Send a nastygram to the author of the current article."
1300   (interactive "P")
1301   (when (or gnus-expert-user
1302             (gnus-y-or-n-p
1303              "Really send a nastygram to the author of the current article? "))
1304     (let ((group gnus-newsgroup-name))
1305       (gnus-summary-reply-with-original n)
1306       (set-buffer gnus-message-buffer)
1307       (message-goto-body)
1308       (insert (format gnus-nastygram-message group))
1309       (message-send-and-exit))))
1310
1311 (defun gnus-summary-mail-crosspost-complaint (n)
1312   "Send a complaint about crossposting to the current article(s)."
1313   (interactive "P")
1314   (let ((articles (gnus-summary-work-articles n))
1315         article)
1316     (while (setq article (pop articles))
1317       (set-buffer gnus-summary-buffer)
1318       (gnus-summary-goto-subject article)
1319       (let ((group (gnus-group-real-name gnus-newsgroup-name))
1320             newsgroups followup-to)
1321         (gnus-summary-select-article)
1322         (set-buffer gnus-original-article-buffer)
1323         (if (and (<= (length (message-tokenize-header
1324                               (setq newsgroups
1325                                     (mail-fetch-field "newsgroups"))
1326                               ", "))
1327                      1)
1328                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
1329                      (not (member group (message-tokenize-header
1330                                          followup-to ", ")))))
1331             (if followup-to
1332                 (gnus-message 1 "Followup-to restricted")
1333               (gnus-message 1 "Not a crossposted article"))
1334           (set-buffer gnus-summary-buffer)
1335           (gnus-summary-reply-with-original 1)
1336           (set-buffer gnus-message-buffer)
1337           (message-goto-body)
1338           (insert (format gnus-crosspost-complaint newsgroups group))
1339           (message-goto-subject)
1340           (re-search-forward " *$")
1341           (replace-match " (crosspost notification)" t t)
1342           (gnus-deactivate-mark)
1343           (when (gnus-y-or-n-p "Send this complaint? ")
1344             (message-send-and-exit)))))))
1345
1346 (defun gnus-mail-parse-comma-list ()
1347   (let (accumulated
1348         beg)
1349     (skip-chars-forward " ")
1350     (while (not (eobp))
1351       (setq beg (point))
1352       (skip-chars-forward "^,")
1353       (while (zerop
1354               (save-excursion
1355                 (save-restriction
1356                   (let ((i 0))
1357                     (narrow-to-region beg (point))
1358                     (goto-char beg)
1359                     (logand (progn
1360                               (while (search-forward "\"" nil t)
1361                                 (incf i))
1362                               (if (zerop i) 2 i))
1363                             2)))))
1364         (skip-chars-forward ",")
1365         (skip-chars-forward "^,"))
1366       (skip-chars-backward " ")
1367       (push (buffer-substring beg (point))
1368             accumulated)
1369       (skip-chars-forward "^,")
1370       (skip-chars-forward ", "))
1371     accumulated))
1372
1373 (defun gnus-inews-add-to-address (group)
1374   (let ((to-address (mail-fetch-field "to")))
1375     (when (and to-address
1376                (gnus-alive-p))
1377       ;; This mail group doesn't have a `to-list', so we add one
1378       ;; here.  Magic!
1379       (when (gnus-y-or-n-p
1380              (format "Do you want to add this as `to-list': %s? " to-address))
1381         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1382
1383 (defun gnus-put-message ()
1384   "Put the current message in some group and return to Gnus."
1385   (interactive)
1386   (let ((reply gnus-article-reply)
1387         (winconf gnus-prev-winconf)
1388         (group gnus-newsgroup-name))
1389     (unless (and group
1390                  (not (gnus-group-read-only-p group)))
1391       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1392
1393     (when (gnus-gethash group gnus-newsrc-hashtb)
1394       (error "No such group: %s" group))
1395     (save-excursion
1396       (save-restriction
1397         (widen)
1398         (message-narrow-to-headers)
1399         (let ((gnus-deletable-headers nil))
1400           (message-generate-headers
1401            (if (message-news-p)
1402                message-required-news-headers
1403              message-required-mail-headers)))
1404         (goto-char (point-max))
1405         (if (string-match " " group)
1406             (insert "Gcc: \"" group "\"\n")
1407           (insert "Gcc: " group "\n"))
1408         (widen)))
1409     (gnus-inews-do-gcc)
1410     (when (and (get-buffer gnus-group-buffer)
1411                (gnus-buffer-exists-p (car-safe reply))
1412                (cdr reply))
1413       (set-buffer (car reply))
1414       (gnus-summary-mark-article-as-replied (cdr reply)))
1415     (when winconf
1416       (set-window-configuration winconf))))
1417
1418 (defun gnus-article-mail (yank)
1419   "Send a reply to the address near point.
1420 If YANK is non-nil, include the original article."
1421   (interactive "P")
1422   (let ((address
1423          (buffer-substring
1424           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1425           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1426     (when address
1427       (gnus-msg-mail address)
1428       (when yank
1429         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1430
1431 (defvar nntp-server-type)
1432 (defun gnus-bug ()
1433   "Send a bug report to the Gnus maintainers."
1434   (interactive)
1435   (unless (gnus-alive-p)
1436     (error "Gnus has been shut down"))
1437   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1438     (unless (message-mail-user-agent)
1439       (delete-other-windows)
1440       (when gnus-bug-create-help-buffer
1441         (switch-to-buffer "*Gnus Help Bug*")
1442         (erase-buffer)
1443         (insert gnus-bug-message)
1444         (goto-char (point-min)))
1445       (message-pop-to-buffer "*Gnus Bug*"))
1446     (let ((message-this-is-mail t))
1447       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1448     (when gnus-bug-create-help-buffer
1449       (push `(gnus-bug-kill-buffer) message-send-actions))
1450     (goto-char (point-min))
1451     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1452     (forward-line 1)
1453     (insert (gnus-version) "\n"
1454             (emacs-version) "\n")
1455     (when (and (boundp 'nntp-server-type)
1456                (stringp nntp-server-type))
1457       (insert nntp-server-type))
1458     (insert "\n\n\n\n\n")
1459     (let (text)
1460       (save-excursion
1461         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1462         (erase-buffer)
1463         (gnus-debug)
1464         (setq text (buffer-string)))
1465       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1466     (goto-char (point-min))
1467     (search-forward "Subject: " nil t)
1468     (message "")))
1469
1470 (defun gnus-bug-kill-buffer ()
1471   (when (get-buffer "*Gnus Help Bug*")
1472     (kill-buffer "*Gnus Help Bug*")))
1473
1474 (defun gnus-summary-yank-message (buffer n)
1475   "Yank the current article into a composed message."
1476   (interactive
1477    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1478          current-prefix-arg))
1479   (gnus-summary-iterate n
1480     (let ((gnus-inhibit-treatment t))
1481       (gnus-summary-select-article))
1482     (save-excursion
1483       (set-buffer buffer)
1484       (message-yank-buffer gnus-article-buffer))))
1485
1486 (defun gnus-debug ()
1487   "Attempts to go through the Gnus source file and report what variables have been changed.
1488 The source file has to be in the Emacs load path."
1489   (interactive)
1490   (let ((files gnus-debug-files)
1491         (point (point))
1492         file expr olist sym)
1493     (gnus-message 4 "Please wait while we snoop your variables...")
1494     (sit-for 0)
1495     ;; Go through all the files looking for non-default values for variables.
1496     (save-excursion
1497       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1498       (while files
1499         (erase-buffer)
1500         (when (and (setq file (locate-library (pop files)))
1501                    (file-exists-p file))
1502           (insert-file-contents file)
1503           (goto-char (point-min))
1504           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1505               (gnus-message 4 "Malformed sources in file %s" file)
1506             (narrow-to-region (point-min) (point))
1507             (goto-char (point-min))
1508             (while (setq expr (ignore-errors (read (current-buffer))))
1509               (ignore-errors
1510                 (and (or (eq (car expr) 'defvar)
1511                          (eq (car expr) 'defcustom))
1512                      (stringp (nth 3 expr))
1513                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1514                      (or (not (boundp (nth 1 expr)))
1515                          (not (equal (eval (nth 2 expr))
1516                                      (symbol-value (nth 1 expr)))))
1517                      (push (nth 1 expr) olist)))))))
1518       (kill-buffer (current-buffer)))
1519     (when (setq olist (nreverse olist))
1520       (insert "------------------ Environment follows ------------------\n\n"))
1521     (while olist
1522       (if (boundp (car olist))
1523           (ignore-errors
1524            (gnus-pp
1525             `(setq ,(car olist)
1526                    ,(if (or (consp (setq sym (symbol-value (car olist))))
1527                             (and (symbolp sym)
1528                                  (not (or (eq sym nil)
1529                                           (eq sym t)))))
1530                         (list 'quote (symbol-value (car olist)))
1531                       (symbol-value (car olist))))))
1532         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1533       (setq olist (cdr olist)))
1534     (insert "\n\n")
1535     ;; Remove any control chars - they seem to cause trouble for some
1536     ;; mailers.  (Byte-compiled output from the stuff above.)
1537     (goto-char point)
1538     (while (re-search-forward (mm-string-as-multibyte
1539                                "[\000-\010\013-\037\200-\237]") nil t)
1540       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1541                      t t))))
1542
1543 ;;; Treatment of rejected articles.
1544 ;;; Bounced mail.
1545
1546 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1547   "Re-mail the current message.
1548 This only makes sense if the current message is a bounce message that
1549 contains some mail you have written which has been bounced back to
1550 you.
1551 If FETCH, try to fetch the article that this is a reply to, if indeed
1552 this is a reply."
1553   (interactive "P")
1554   (gnus-summary-select-article t)
1555   (set-buffer gnus-original-article-buffer)
1556   (gnus-setup-message 'compose-bounce
1557     (let* ((references (mail-fetch-field "references"))
1558            (parent (and references (gnus-parent-id references))))
1559       (message-bounce)
1560       ;; If there are references, we fetch the article we answered to.
1561       (and fetch parent
1562            (gnus-summary-refer-article parent)
1563            (gnus-summary-show-all-headers)))))
1564
1565 ;;; Gcc handling.
1566
1567 (defun gnus-inews-group-method (group)
1568   (cond
1569    ;; If the group doesn't exist, we assume
1570    ;; it's an archive group...
1571    ((and (null (gnus-get-info group))
1572          (eq (car (gnus-server-to-method gnus-message-archive-method))
1573              (car (gnus-server-to-method (gnus-group-method group)))))
1574     gnus-message-archive-method)
1575    ;; Use the method.
1576    ((gnus-info-method (gnus-get-info group))
1577     (gnus-info-method (gnus-get-info group)))
1578    ;; Find the method.
1579    (t (gnus-server-to-method (gnus-group-method group)))))
1580
1581 ;; Do Gcc handling, which copied the message over to some group.
1582 (defun gnus-inews-do-gcc (&optional gcc)
1583   (interactive)
1584   (save-excursion
1585     (save-restriction
1586       (message-narrow-to-headers)
1587       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1588             (cur (current-buffer))
1589             groups group method group-art
1590             mml-externalize-attachments)
1591         (when gcc
1592           (message-remove-header "gcc")
1593           (widen)
1594           (setq groups (message-unquote-tokens
1595                         (message-tokenize-header gcc " ,")))
1596           ;; Copy the article over to some group(s).
1597           (while (setq group (pop groups))
1598             (unless (gnus-check-server
1599                      (setq method (gnus-inews-group-method group)))
1600               (error "Can't open server %s" (if (stringp method) method
1601                                               (car method))))
1602             (unless (gnus-request-group group nil method)
1603               (gnus-request-create-group group method))
1604             (setq mml-externalize-attachments
1605                   (if (stringp gnus-gcc-externalize-attachments)
1606                       (string-match gnus-gcc-externalize-attachments group)
1607                     gnus-gcc-externalize-attachments))
1608             (save-excursion
1609               (nnheader-set-temp-buffer " *acc*")
1610               (insert-buffer-substring cur)
1611               (message-encode-message-body)
1612               (save-restriction
1613                 (message-narrow-to-headers)
1614                 (let* ((mail-parse-charset message-default-charset)
1615                        (newsgroups-field (save-restriction
1616                                            (message-narrow-to-headers-or-head)
1617                                            (message-fetch-field "Newsgroups")))
1618                        (followup-field (save-restriction
1619                                          (message-narrow-to-headers-or-head)
1620                                          (message-fetch-field "Followup-To")))
1621                        ;; BUG: We really need to get the charset for
1622                        ;; each name in the Newsgroups and Followup-To
1623                        ;; lines to allow crossposting between group
1624                        ;; namess with incompatible character sets.
1625                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1626                        (group-field-charset
1627                         (gnus-group-name-charset
1628                          method (or newsgroups-field "")))
1629                        (followup-field-charset
1630                         (gnus-group-name-charset
1631                          method (or followup-field "")))
1632                        (rfc2047-header-encoding-alist
1633                         (append
1634                          (when group-field-charset
1635                            (list (cons "Newsgroups" group-field-charset)))
1636                          (when followup-field-charset
1637                            (list (cons "Followup-To" followup-field-charset)))
1638                          rfc2047-header-encoding-alist)))
1639                   (mail-encode-encoded-word-buffer)))
1640               (goto-char (point-min))
1641               (when (re-search-forward
1642                      (concat "^" (regexp-quote mail-header-separator) "$")
1643                      nil t)
1644                 (replace-match "" t t ))
1645               (unless (setq group-art
1646                             (gnus-request-accept-article group method t t))
1647                 (gnus-message 1 "Couldn't store article in group %s: %s"
1648                               group (gnus-status-message method))
1649                 (sit-for 2))
1650               (when (and group-art
1651                          ;; FIXME: Should gcc-mark-as-read work when
1652                          ;; Gnus is not running?
1653                          (gnus-alive-p)
1654                          (or gnus-gcc-mark-as-read
1655                              (and
1656                               (boundp 'gnus-inews-mark-gcc-as-read)
1657                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1658                 (gnus-group-mark-article-read group (cdr group-art)))
1659               (kill-buffer (current-buffer)))))))))
1660
1661 (defun gnus-inews-insert-gcc ()
1662   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1663   (save-excursion
1664     (save-restriction
1665       (message-narrow-to-headers)
1666       (let* ((group gnus-outgoing-message-group)
1667              (gcc (cond
1668                    ((functionp group)
1669                     (funcall group))
1670                    ((or (stringp group) (list group))
1671                     group))))
1672         (when gcc
1673           (insert "Gcc: "
1674                   (if (stringp gcc)
1675                       (if (string-match " " gcc)
1676                           (concat "\"" gcc "\"")
1677                         gcc)
1678                     (mapconcat (lambda (group)
1679                                  (if (string-match " " group)
1680                                      (concat "\"" group "\"")
1681                                    group))
1682                                gcc " "))
1683                   "\n"))))))
1684
1685 (defun gnus-inews-insert-archive-gcc (&optional group)
1686   "Insert the Gcc to say where the article is to be archived."
1687   (let* ((var gnus-message-archive-group)
1688          (group (or group gnus-newsgroup-name ""))
1689          (gcc-self-val
1690           (and gnus-newsgroup-name
1691                (not (equal gnus-newsgroup-name ""))
1692                (gnus-group-find-parameter
1693                 gnus-newsgroup-name 'gcc-self)))
1694          result
1695          (groups
1696           (cond
1697            ((null gnus-message-archive-method)
1698             ;; Ignore.
1699             nil)
1700            ((stringp var)
1701             ;; Just a single group.
1702             (list var))
1703            ((null var)
1704             ;; We don't want this.
1705             nil)
1706            ((and (listp var) (stringp (car var)))
1707             ;; A list of groups.
1708             var)
1709            ((functionp var)
1710             ;; A function.
1711             (funcall var group))
1712            (t
1713             ;; An alist of regexps/functions/forms.
1714             (while (and var
1715                         (not
1716                          (setq result
1717                                (cond
1718                                 ((stringp (caar var))
1719                                  ;; Regexp.
1720                                  (when (string-match (caar var) group)
1721                                    (cdar var)))
1722                                 ((functionp (car var))
1723                                  ;; Function.
1724                                  (funcall (car var) group))
1725                                 (t
1726                                  (eval (car var)))))))
1727               (setq var (cdr var)))
1728             result)))
1729          name)
1730     (when (or groups gcc-self-val)
1731       (when (stringp groups)
1732         (setq groups (list groups)))
1733       (save-excursion
1734         (save-restriction
1735           (message-narrow-to-headers)
1736           (goto-char (point-max))
1737           (insert "Gcc: ")
1738           (if gcc-self-val
1739               ;; Use the `gcc-self' param value instead.
1740               (progn
1741                 (insert
1742                  (if (stringp gcc-self-val)
1743                      (if (string-match " " gcc-self-val)
1744                          (concat "\"" gcc-self-val "\"")
1745                        gcc-self-val)
1746                    ;; In nndoc groups, we use the parent group name
1747                    ;; instead of the current group.
1748                    (let ((group (or (gnus-group-find-parameter
1749                                      gnus-newsgroup-name 'parent-group)
1750                                     group)))
1751                      (if (string-match " " group)
1752                          (concat "\"" group "\"")
1753                        group))))
1754                 (if (not (eq gcc-self-val 'none))
1755                     (insert "\n")
1756                   (gnus-delete-line)))
1757             ;; Use the list of groups.
1758             (while (setq name (pop groups))
1759               (let ((str (if (string-match ":" name)
1760                              name
1761                            (gnus-group-prefixed-name
1762                             name gnus-message-archive-method))))
1763                 (insert (if (string-match " " str)
1764                             (concat "\"" str "\"")
1765                           str)))
1766               (when groups
1767                 (insert " ")))
1768             (insert "\n")))))))
1769
1770 (defun gnus-mailing-list-followup-to ()
1771   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1772   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1773         (list-post (gnus-fetch-original-field "list-post")))
1774     (when (and list-post
1775                (string-match "mailto:\\([^>]+\\)" list-post))
1776       (setq list-post (match-string 1 list-post)))
1777     (or list-post
1778         x-been-there)))
1779
1780 ;;; Posting styles.
1781
1782 (defun gnus-configure-posting-styles (&optional group-name)
1783   "Configure posting styles according to `gnus-posting-styles'."
1784   (unless gnus-inhibit-posting-styles
1785     (let ((group (or group-name gnus-newsgroup-name ""))
1786           (styles gnus-posting-styles)
1787           style match attribute value v results
1788           filep name address element)
1789       ;; If the group has a posting-style parameter, add it at the end with a
1790       ;; regexp matching everything, to be sure it takes precedence over all
1791       ;; the others.
1792       (when gnus-newsgroup-name
1793         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1794           (when tmp-style
1795             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1796       ;; Go through all styles and look for matches.
1797       (dolist (style styles)
1798         (setq match (pop style))
1799         (goto-char (point-min))
1800         (when (cond
1801                ((stringp match)
1802                 ;; Regexp string match on the group name.
1803                 (string-match match group))
1804                ((eq match 'header)
1805                 ;; Obsolete format of header match.
1806                 (and (gnus-buffer-live-p gnus-article-copy)
1807                      (with-current-buffer gnus-article-copy
1808                        (save-restriction
1809                          (nnheader-narrow-to-headers)
1810                          (let ((header (message-fetch-field (pop style))))
1811                            (and header
1812                                 (string-match (pop style) header)))))))
1813                ((or (symbolp match)
1814                     (functionp match))
1815                 (cond
1816                  ((functionp match)
1817                   ;; Function to be called.
1818                   (funcall match))
1819                  ((boundp match)
1820                   ;; Variable to be checked.
1821                   (symbol-value match))))
1822                ((listp match)
1823                 (cond
1824                  ((eq (car match) 'header)
1825                   ;; New format of header match.
1826                   (and (gnus-buffer-live-p gnus-article-copy)
1827                        (with-current-buffer gnus-article-copy
1828                          (save-restriction
1829                            (nnheader-narrow-to-headers)
1830                            (let ((header (message-fetch-field (nth 1 match))))
1831                              (and header
1832                                   (string-match (nth 2 match) header)))))))
1833                  (t
1834                   ;; This is a form to be evaled.
1835                   (eval match)))))
1836           ;; We have a match, so we set the variables.
1837           (dolist (attribute style)
1838             (setq element (pop attribute)
1839                   filep nil)
1840             (setq value
1841                   (cond
1842                    ((eq (car attribute) :file)
1843                     (setq filep t)
1844                     (cadr attribute))
1845                    ((eq (car attribute) :value)
1846                     (cadr attribute))
1847                    (t
1848                     (car attribute))))
1849             ;; We get the value.
1850             (setq v
1851                   (cond
1852                    ((stringp value)
1853                     value)
1854                    ((or (symbolp value)
1855                         (functionp value))
1856                     (cond ((functionp value)
1857                            (funcall value))
1858                           ((boundp value)
1859                            (symbol-value value))))
1860                    ((listp value)
1861                     (eval value))))
1862             ;; Translate obsolescent value.
1863             (cond
1864              ((eq element 'signature-file)
1865               (setq element 'signature
1866                     filep t))
1867              ((eq element 'x-face-file)
1868               (setq element 'x-face
1869                     filep t)))
1870             ;; Get the contents of file elems.
1871             (when (and filep v)
1872               (setq v (with-temp-buffer
1873                         (insert-file-contents v)
1874                         (buffer-substring
1875                          (point-min)
1876                          (progn
1877                            (goto-char (point-max))
1878                            (if (zerop (skip-chars-backward "\n"))
1879                                (point)
1880                              (1+ (point))))))))
1881             (setq results (delq (assoc element results) results))
1882             (push (cons element v) results))))
1883       ;; Now we have all the styles, so we insert them.
1884       (setq name (assq 'name results)
1885             address (assq 'address results))
1886       (setq results (delq name (delq address results)))
1887       (gnus-make-local-hook 'message-setup-hook)
1888       (setq results (sort results (lambda (x y)
1889                                     (string-lessp (car x) (car y)))))
1890       (dolist (result results)
1891         (add-hook 'message-setup-hook
1892                   (cond
1893                    ((eq 'eval (car result))
1894                     'ignore)
1895                    ((eq 'body (car result))
1896                     `(lambda ()
1897                        (save-excursion
1898                          (message-goto-body)
1899                          (insert ,(cdr result)))))
1900                    ((eq 'signature (car result))
1901                     (set (make-local-variable 'message-signature) nil)
1902                     (set (make-local-variable 'message-signature-file) nil)
1903                     (if (not (cdr result))
1904                         'ignore
1905                       `(lambda ()
1906                          (save-excursion
1907                            (let ((message-signature ,(cdr result)))
1908                              (when message-signature
1909                                (message-insert-signature)))))))
1910                    (t
1911                     (let ((header
1912                            (if (symbolp (car result))
1913                                (capitalize (symbol-name (car result)))
1914                              (car result))))
1915                       `(lambda ()
1916                          (save-excursion
1917                            (message-remove-header ,header)
1918                            (let ((value ,(cdr result)))
1919                              (when value
1920                                (message-goto-eoh)
1921                                (insert ,header ": " value)
1922                                (unless (bolp)
1923                                  (insert "\n")))))))))
1924                   nil 'local))
1925       (when (or name address)
1926         (add-hook 'message-setup-hook
1927                   `(lambda ()
1928                      (set (make-local-variable 'user-mail-address)
1929                           ,(or (cdr address) user-mail-address))
1930                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1931                            (user-mail-address
1932                             ,(or (cdr address) user-mail-address)))
1933                        (save-excursion
1934                          (message-remove-header "From")
1935                          (message-goto-eoh)
1936                          (insert "From: " (message-make-from) "\n"))))
1937                   nil 'local)))))
1938
1939 ;;; Allow redefinition of functions.
1940
1941 (gnus-ems-redefine)
1942
1943 (provide 'gnus-msg)
1944
1945 ;;; arch-tag: 9f22b2f5-1c0a-49de-916e-4c88e984852b
1946 ;;; gnus-msg.el ends here