code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2013 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.3.50)
  26
  27 dnl This is the documented way to record the args passed to configure,
  28 dnl rather than $ac_configure_args.
  29 emacs_config_options="$@"
  30 ## Add some environment variables, if they were passed via the environment
  31 ## rather than on the command-line.
  32 for var in CFLAGS CPPFLAGS LDFLAGS; do
  33     case "$emacs_config_options" in
  34       *$var=*) continue ;;
  35     esac
  36     eval val="\$${var}"
  37     test x"$val" = x && continue
  38     emacs_config_options="${emacs_config_options}${emacs_config_options:+ }$var=\"$val\""
  39 done
  40
  41 AC_CONFIG_HEADER(src/config.h:src/config.in)
  42 AC_CONFIG_SRCDIR(src/lisp.h)
  43 AC_CONFIG_AUX_DIR(build-aux)
  44 dnl Fairly arbitrary, older versions might work too.
  45 AM_INIT_AUTOMAKE(1.11)
  46
  47 dnl Support for --program-prefix, --program-suffix and
  48 dnl --program-transform-name options
  49 AC_ARG_PROGRAM
  50
  51 dnl It is important that variables on the RHS not be expanded here,
  52 dnl hence the single quotes.  This is per the GNU coding standards, see
  53 dnl (autoconf) Installation Directory Variables
  54 dnl See also epaths.h below.
  55 lispdir='${datadir}/emacs/${version}/lisp'
  56 leimdir='${datadir}/emacs/${version}/leim'
  57 standardlisppath='${lispdir}:${leimdir}'
  58 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  59 '${datadir}/emacs/site-lisp'
  60 lisppath='${locallisppath}:${standardlisppath}'
  61 etcdir='${datadir}/emacs/${version}/etc'
  62 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  63 docdir='${datadir}/emacs/${version}/etc'
  64 gamedir='${localstatedir}/games/emacs'
  65
  66 dnl Special option to disable the most of other options.
  67 AC_ARG_WITH(all,
  68 [AS_HELP_STRING([--without-all],
  69                 [omit almost all features and build
  70                 small executable with minimal dependencies])],
  71   with_features=$withval,
  72   with_features=yes)
  73
  74 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  75 dnl Create a new --with option that defaults to being disabled.
  76 dnl NAME is the base name of the option.  The shell variable with_NAME
  77 dnl   will be set to either the user's value (if the option is
  78 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  79 dnl   option is not specified).  Note that the shell variable name is
  80 dnl   constructed as autoconf does, by replacing non-alphanumeric
  81 dnl   characters with "_".
  82 dnl HELP-STRING is the help text for the option.
  83 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  84   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  85     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  86 ])dnl
  87
  88 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  89 dnl Create a new --with option that defaults to $enable_features.
  90 dnl NAME is the base name of the option.  The shell variable with_NAME
  91 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  92 dnl   'yes' (if the option is not specified).  Note that the shell
  93 dnl   variable name is constructed as autoconf does, by replacing
  94 dnl   non-alphanumeric characters with "_".
  95 dnl HELP-STRING is the help text for the option.
  96 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  97   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  98    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
  99 ])dnl
 100
 101 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 102 if test "$with_pop" = yes; then
 103    AC_DEFINE(MAIL_USE_POP)
 104 fi
 105 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 106
 107 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 108 if test "$with_kerberos" != no; then
 109    AC_DEFINE(KERBEROS)
 110 fi
 111 AH_TEMPLATE(KERBEROS,
 112             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 113
 114 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 115 if test "${with_kerberos5}" != no; then
 116   if test "${with_kerberos}" = no; then
 117     with_kerberos=yes
 118     AC_DEFINE(KERBEROS)
 119   fi
 120   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 121 fi
 122
 123 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 124 dnl FIXME hesiod support may not be present, so it seems like an error
 125 dnl to define, or at least use, this unconditionally.
 126 if test "$with_hesiod" != no; then
 127   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 128 fi
 129
 130 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 131 if test "$with_mmdf" != no; then
 132    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 133 fi
 134
 135 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 136 if test "$with_mail_unlink" != no; then
 137    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 138 fi
 139
 140 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 141     [string giving default POP mail host])],
 142     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 143
 144 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 145
 146 dnl FIXME currently it is not the last.
 147 dnl This should be the last --with option, because --with-x is
 148 dnl added later on when we find the file name of X, and it's best to
 149 dnl keep them together visually.
 150 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 151  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 152 [         case "${withval}" in
 153             y | ye | yes )      val=gtk ;;
 154             n | no )            val=no  ;;
 155             l | lu | luc | luci | lucid )       val=lucid ;;
 156             a | at | ath | athe | athen | athena )      val=athena ;;
 157             m | mo | mot | moti | motif )       val=motif ;;
 158             g | gt | gtk  )     val=gtk ;;
 159             gtk2  )     val=gtk2 ;;
 160             gtk3  )     val=gtk3 ;;
 161             * )
 162 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 163 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 164 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 165 `athena' and `lucid' are synonyms.])
 166             ;;
 167           esac
 168           with_x_toolkit=$val
 169 ])
 170
 171 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 172 if test "$with_wide_int" = yes; then
 173   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 174 fi
 175
 176 dnl _ON results in a '--without' option in the --help output, so
 177 dnl the help text should refer to "don't compile", etc.
 178 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 179 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 180 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 181 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 182 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 183 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 184 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 185 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 186
 187 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 188 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 189 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 190
 191 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 192 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 193 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 194 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 195 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI])
 196
 197 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 198 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 199 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 200 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 201 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 202 OPTION_DEFAULT_ON([acl],[don't compile with ACL support])
 203 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 204 OPTION_DEFAULT_ON([inotify],[don't compile with inotify (file-watch) support])
 205
 206 OPTION_DEFAULT_OFF([xwidgets],[enable use of some gtk widgets it Emacs buffers])
 207
 208 ## For the times when you want to build Emacs but don't have
 209 ## a suitable makeinfo, and can live without the manuals.
 210 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 211 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 212
 213 ## Makefile.in needs the cache file name.
 214 AC_SUBST(cache_file)
 215
 216 ## This is an option because I do not know if all info/man support
 217 ## compressed files, nor how to test if they do so.
 218 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 219 if test $with_compress_info = yes; then
 220    GZIP_INFO=yes
 221 else
 222    GZIP_INFO=
 223 fi
 224 AC_SUBST(GZIP_INFO)
 225
 226 AC_ARG_WITH([pkg-config-prog],dnl
 227 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 228                   [file name of pkg-config for finding GTK and librsvg])])
 229 if test "X${with_pkg_config_prog}" != X; then
 230    if test "${with_pkg_config_prog}" != yes; then
 231       PKG_CONFIG="${with_pkg_config_prog}"
 232    fi
 233 fi
 234
 235 CRT_DIR=
 236 AC_ARG_WITH([crt-dir],dnl
 237 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 238 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 239 CRT_DIR="${with_crt_dir}"
 240
 241 AC_ARG_WITH(gameuser,dnl
 242 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 243 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 244   && gameuser="${with_gameuser}"
 245 test "X$gameuser" = X && gameuser=games
 246
 247 AC_ARG_WITH([gnustep-conf],dnl
 248 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 249    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 250 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 251   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 252 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 253      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 254
 255 AC_ARG_ENABLE(ns-self-contained,
 256 [AS_HELP_STRING([--disable-ns-self-contained],
 257                 [disable self contained build under NeXTstep])],
 258    EN_NS_SELF_CONTAINED=$enableval,
 259    EN_NS_SELF_CONTAINED=yes)
 260
 261 AC_ARG_ENABLE(locallisppath,
 262 [AS_HELP_STRING([--enable-locallisppath=PATH],
 263                 [directories Emacs should search for lisp files specific
 264                  to this site])],
 265 if test "${enableval}" = "no"; then
 266   locallisppath=
 267 elif test "${enableval}" != "yes"; then
 268   locallisppath=${enableval}
 269 fi)
 270
 271 AC_ARG_ENABLE(checking,
 272 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 273                 [enable expensive run-time checks.  With LIST,
 274                  enable only specific categories of checks.
 275                  Categories are: all,yes,no.
 276                  Flags are: stringbytes, stringoverrun, stringfreelist,
 277                  xmallocoverrun, conslist, glyphs])],
 278 [ac_checking_flags="${enableval}"],[])
 279 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 280 for check in $ac_checking_flags
 281 do
 282         case $check in
 283         # these set all the flags to specific states
 284         yes)            ac_enable_checking=1 ;;
 285         no)             ac_enable_checking= ;
 286                         ac_gc_check_stringbytes= ;
 287                         ac_gc_check_string_overrun= ;
 288                         ac_gc_check_string_free_list= ;
 289                         ac_xmalloc_overrun= ;
 290                         ac_gc_check_cons_list= ;
 291                         ac_glyphs_debug= ;;
 292         all)            ac_enable_checking=1 ;
 293                         ac_gc_check_stringbytes=1 ;
 294                         ac_gc_check_string_overrun=1 ;
 295                         ac_gc_check_string_free_list=1 ;
 296                         ac_xmalloc_overrun=1 ;
 297                         ac_gc_check_cons_list=1 ;
 298                         ac_glyphs_debug=1 ;;
 299         # these enable particular checks
 300         stringbytes)    ac_gc_check_stringbytes=1 ;;
 301         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 302         stringfreelist) ac_gc_check_string_free_list=1 ;;
 303         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 304         conslist)       ac_gc_check_cons_list=1 ;;
 305         glyphs)         ac_glyphs_debug=1 ;;
 306         *)      AC_MSG_ERROR(unknown check category $check) ;;
 307         esac
 308 done
 309 IFS="$ac_save_IFS"
 310
 311 if test x$ac_enable_checking != x ; then
 312   AC_DEFINE(ENABLE_CHECKING, 1,
 313 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 314 fi
 315 if test x$ac_gc_check_stringbytes != x ; then
 316   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 317 [Define this temporarily to hunt a bug.  If defined, the size of
 318    strings is redundantly recorded in sdata structures so that it can
 319    be compared to the sizes recorded in Lisp strings.])
 320 fi
 321 if test x$ac_gc_check_string_overrun != x ; then
 322   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 323 [Define this to check for short string overrun.])
 324 fi
 325 if test x$ac_gc_check_string_free_list != x ; then
 326   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 327 [Define this to check the string free list.])
 328 fi
 329 if test x$ac_xmalloc_overrun != x ; then
 330   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 331 [Define this to check for malloc buffer overrun.])
 332 fi
 333 if test x$ac_gc_check_cons_list != x ; then
 334   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 335 [Define this to check for errors in cons list.])
 336 fi
 337 if test x$ac_glyphs_debug != x ; then
 338   AC_DEFINE(GLYPH_DEBUG, 1,
 339 [Define this to enable glyphs debugging code.])
 340 fi
 341
 342 AC_ARG_ENABLE(check-lisp-object-type,
 343 [AS_HELP_STRING([--enable-check-lisp-object-type],
 344                 [enable compile time checks for the Lisp_Object data type.
 345                 This is useful for development for catching certain types of bugs.])],
 346 if test "${enableval}" != "no"; then
 347    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 348    [Define this to enable compile time checks for the Lisp_Object data type.])
 349 fi)
 350
 351
 352 dnl The name of this option is unfortunate.  It predates, and has no
 353 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 354 dnl Actually, it stops it working.
 355 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 356 AC_ARG_ENABLE(profiling,
 357 [AS_HELP_STRING([--enable-profiling],
 358                 [build emacs with low-level, gprof profiling support.
 359                 Mainly useful for debugging Emacs itself.  May not work on
 360                 all platforms.  Stops profiler.el working.])],
 361 [ac_enable_profiling="${enableval}"],[])
 362 if test x$ac_enable_profiling != x ; then
 363    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 364 else
 365    PROFILING_CFLAGS=
 366 fi
 367 AC_SUBST(PROFILING_CFLAGS)
 368
 369 AC_ARG_ENABLE(autodepend,
 370 [AS_HELP_STRING([--enable-autodepend],
 371                 [automatically generate dependencies to .h-files.
 372                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 373                  found])],
 374 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 375
 376 AC_ARG_ENABLE(gtk-deprecation-warnings,
 377 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 378                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 379 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 380
 381 #### Make srcdir absolute, if it isn't already.  It's important to
 382 #### avoid running the file name through pwd unnecessarily, since pwd can
 383 #### give you automounter prefixes, which can go away.  We do all this
 384 #### so Emacs can find its files when run uninstalled.
 385 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 386 unset CDPATH
 387 case "${srcdir}" in
 388   /* ) ;;
 389   . )
 390     ## We may be able to use the $PWD environment variable to make this
 391     ## absolute.  But sometimes PWD is inaccurate.
 392     ## Note: we used to use $PWD at the end instead of `pwd`,
 393     ## but that tested only for a well-formed and valid PWD,
 394     ## it did not object when PWD was well-formed and valid but just wrong.
 395     if test ".$PWD" != "." && test ".`(cd "$PWD" ; sh -c pwd)`" = ".`pwd`"  ;
 396     then
 397       srcdir="$PWD"
 398     else
 399       srcdir=`(cd "$srcdir"; pwd)`
 400     fi
 401   ;;
 402   *  ) srcdir=`(cd "$srcdir"; pwd)` ;;
 403 esac
 404
 405 ### Canonicalize the configuration name.
 406
 407 AC_CANONICAL_HOST
 408 canonical=$host
 409 configuration=${host_alias-${build_alias-$host}}
 410
 411 dnl This used to use changequote, but, apart from `changequote is evil'
 412 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 413 dnl the great gob of text.  Thus it's not processed for possible expansion.
 414 dnl Just make sure the brackets remain balanced.
 415 dnl
 416 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 417 dnl indicated by comments.
 418 dnl quotation begins
 419 [
 420
 421 ### If you add support for a new configuration, add code to this
 422 ### switch statement to recognize your configuration name and select
 423 ### the appropriate operating system file.
 424
 425 ### You would hope that you could choose an s/*.h
 426 ### file based on the operating system portion.  However, it turns out
 427 ### that each s/*.h file is pretty manufacturer-specific.
 428 ### So we basically have to have a special case for each
 429 ### configuration name.
 430 ###
 431 ### As far as handling version numbers on operating systems is
 432 ### concerned, make sure things will fail in a fixable way.  If
 433 ### /etc/MACHINES doesn't say anything about version numbers, be
 434 ### prepared to handle anything reasonably.  If version numbers
 435 ### matter, be sure /etc/MACHINES says something about it.
 436
 437 opsys='' unported=no
 438 case "${canonical}" in
 439
 440   ## GNU/Linux and similar ports
 441   *-*-linux* )
 442     opsys=gnu-linux
 443   ;;
 444
 445   ## FreeBSD ports
 446   *-*-freebsd* )
 447     opsys=freebsd
 448   ;;
 449
 450   ## FreeBSD kernel + glibc based userland
 451   *-*-kfreebsd*gnu* )
 452     opsys=gnu-kfreebsd
 453   ;;
 454
 455   ## NetBSD ports
 456   *-*-netbsd* )
 457     opsys=netbsd
 458   ;;
 459
 460   ## OpenBSD ports
 461   *-*-openbsd* )
 462     opsys=openbsd
 463   ;;
 464
 465   ## Apple Darwin / Mac OS X
 466   *-apple-darwin* )
 467     case "${canonical}" in
 468       i[3456]86-* )  ;;
 469       powerpc-* )    ;;
 470       x86_64-* )     ;;
 471       * )            unported=yes ;;
 472     esac
 473     opsys=darwin
 474     ## Use fink packages if available.
 475     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 476 ##    if test -d /sw/include && test -d /sw/lib; then
 477 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 478 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 479 ##    fi
 480   ;;
 481
 482   ## HP 9000 series 700 and 800, running HP/UX
 483   hppa*-hp-hpux10.2* )
 484     opsys=hpux10-20
 485   ;;
 486   hppa*-hp-hpux1[1-9]* )
 487     opsys=hpux11
 488     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 489   ;;
 490
 491   ## IBM machines
 492   rs6000-ibm-aix4.[23]* )
 493     opsys=aix4-2
 494   ;;
 495   powerpc-ibm-aix4.[23]*  )
 496     opsys=aix4-2
 497   ;;
 498   rs6000-ibm-aix[56]* )
 499     opsys=aix4-2
 500   ;;
 501   powerpc-ibm-aix[56]*  )
 502     opsys=aix4-2
 503   ;;
 504
 505   ## Silicon Graphics machines
 506   ## Iris 4D
 507   mips-sgi-irix6.5 )
 508     opsys=irix6-5
 509     # Without defining _LANGUAGE_C, things get masked out in the headers
 510     # so that, for instance, grepping for `free' in stdlib.h fails and
 511     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 512     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 513   ;;
 514
 515   ## Suns
 516   *-sun-solaris* \
 517     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 518     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 519     case "${canonical}" in
 520       i[3456]86-*-* )   ;;
 521       amd64-*-*|x86_64-*-*) ;;
 522       sparc* )          ;;
 523       * )               unported=yes ;;
 524     esac
 525     case "${canonical}" in
 526       *-sunos5.6* | *-solaris2.6* )
 527                 opsys=sol2-6
 528                 RANLIB="ar -ts"
 529                 ;;
 530       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 531                 opsys=sol2-6
 532                 emacs_check_sunpro_c=yes
 533                 ;;
 534       *-sunos5* | *-solaris* )
 535                 opsys=sol2-10
 536                 emacs_check_sunpro_c=yes
 537                 ;;
 538     esac
 539     ## Watch out for a compiler that we know will not work.
 540     case "${canonical}" in
 541      *-solaris* | *-sunos5* )
 542                 if [ "x$CC" = x/usr/ucb/cc ]; then
 543                   ## /usr/ucb/cc doesn't work;
 544                   ## we should find some other compiler that does work.
 545                   unset CC
 546                 fi
 547                 ;;
 548       *) ;;
 549     esac
 550   ;;
 551
 552   ## Intel 386 machines where we don't care about the manufacturer.
 553   i[3456]86-*-* )
 554     case "${canonical}" in
 555       *-cygwin )                opsys=cygwin ;;
 556       *-darwin* )               opsys=darwin ;;
 557       *-sysv4.2uw* )            opsys=unixware ;;
 558       *-sysv5uw* )              opsys=unixware ;;
 559       *-sysv5OpenUNIX* )        opsys=unixware ;;
 560       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 561     esac
 562   ;;
 563
 564   * )
 565     unported=yes
 566   ;;
 567 esac
 568
 569 ### If the code above didn't choose an operating system, just choose
 570 ### an operating system based on the configuration name.  You really
 571 ### only want to use this when you have no idea what the right
 572 ### operating system is; if you know what operating systems a machine
 573 ### runs, it's cleaner to make it explicit in the case statement
 574 ### above.
 575 if test x"${opsys}" = x; then
 576   case "${canonical}" in
 577     *-gnu* )                            opsys=gnu ;;
 578     * )
 579       unported=yes
 580     ;;
 581   esac
 582 fi
 583
 584 ]
 585 dnl quotation ends
 586
 587 if test $unported = yes; then
 588   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 589 Check `etc/MACHINES' for recognized configuration names.])
 590 fi
 591
 592
 593 #### Choose a compiler.
 594
 595 dnl Sets GCC=yes if using gcc.
 596 AC_PROG_CC
 597 AM_PROG_CC_C_O
 598
 599 if test x$GCC = xyes; then
 600   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 601 else
 602   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 603 fi
 604
 605 # Avoid gnulib's tests for O_NOATIME and O_NOFOLLOW, as we don't use them.
 606 AC_DEFUN([gl_FCNTL_O_FLAGS])
 607 # Avoid gnulib's threadlib module, as we do threads our own way.
 608 AC_DEFUN([gl_THREADLIB])
 609
 610 # Initialize gnulib right after choosing the compiler.
 611 dnl Amongst other things, this sets AR and ARFLAGS.
 612 gl_EARLY
 613
 614 # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 615 # if -g3 works and the user does not specify CFLAGS.
 616 # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 617 if test "$ac_test_CFLAGS" != set; then
 618   case $CFLAGS in
 619     '-g')
 620       emacs_g3_CFLAGS='-g3';;
 621     '-g -O2')
 622       emacs_g3_CFLAGS='-g3 -O2';;
 623     *)
 624       emacs_g3_CFLAGS='';;
 625   esac
 626   if test -n "$emacs_g3_CFLAGS"; then
 627     emacs_save_CFLAGS=$CFLAGS
 628     CFLAGS=$emacs_g3_CFLAGS
 629     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 630       [emacs_cv_prog_cc_g3],
 631       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 632          [emacs_cv_prog_cc_g3=yes],
 633          [emacs_cv_prog_cc_g3=no])])
 634     if test $emacs_cv_prog_cc_g3 = yes; then
 635       CFLAGS=$emacs_g3_CFLAGS
 636     else
 637       CFLAGS=$emacs_save_CFLAGS
 638     fi
 639   fi
 640 fi
 641
 642 AC_ARG_ENABLE([gcc-warnings],
 643   [AS_HELP_STRING([--enable-gcc-warnings],
 644                   [turn on lots of GCC warnings/errors. This is intended for
 645                    developers, and may generate false alarms when used
 646                    with older or non-GNU development tools.])],
 647   [case $enableval in
 648      yes|no) ;;
 649      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 650    esac
 651    gl_gcc_warnings=$enableval],
 652   [gl_gcc_warnings=no]
 653 )
 654
 655 AC_ARG_ENABLE(link-time-optimization,
 656 [AS_HELP_STRING([--enable-link-time-optimization],
 657                 [build emacs with link-time optimization.
 658                  This is supported only for GCC since 4.5.0.])],
 659 if test "${enableval}" != "no"; then
 660    AC_MSG_CHECKING([whether link-time optimization is supported])
 661    ac_lto_supported=no
 662    if test x$GCC = xyes; then
 663       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 664       if test x$CPUS != x; then
 665          LTO="-flto=$CPUS"
 666       else
 667          LTO="-flto"
 668       fi
 669       old_CFLAGS=$CFLAGS
 670       CFLAGS="$CFLAGS $LTO"
 671       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 672         [ac_lto_supported=yes], [ac_lto_supported=no])
 673       CFLAGS="$old_CFLAGS"
 674    fi
 675    AC_MSG_RESULT([$ac_lto_supported])
 676    if test "$ac_lto_supported" = "yes"; then
 677       CFLAGS="$CFLAGS $LTO"
 678    fi
 679 fi)
 680
 681 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 682 # ------------------------------------------------
 683 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 684 # Otherwise, run RUN-IF-NOT-FOUND.
 685 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 686   [AC_PREPROC_IFELSE(
 687     [AC_LANG_PROGRAM(
 688       [[
 689 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 690 /* ok */
 691 #else
 692 # error "your version of gcc is older than $1.$2"
 693 #endif
 694       ]]),
 695     ], [$3], [$4])
 696   ]
 697 )
 698
 699 # When compiling with GCC, prefer -isystem to -I when including system
 700 # include files, to avoid generating useless diagnostics for the files.
 701 if test "$gl_gcc_warnings" != yes; then
 702   isystem='-I'
 703 else
 704   isystem='-isystem '
 705
 706   # This, $nw, is the list of warnings we disable.
 707   nw=
 708
 709   case $with_x_toolkit in
 710     lucid | athena | motif)
 711        # Old toolkits mishandle 'const'.
 712        nw="$nw -Wwrite-strings"
 713        ;;
 714     *)
 715        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 716        ;;
 717   esac
 718   AC_SUBST([WERROR_CFLAGS])
 719
 720   nw="$nw -Waggregate-return"       # anachronistic
 721   nw="$nw -Wlong-long"              # C90 is anachronistic
 722   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 723   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 724   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 725   nw="$nw -Wcast-qual"              # Too many warnings for now
 726   nw="$nw -Wconversion"             # Too many warnings for now
 727   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 728   nw="$nw -Wsign-conversion"        # Too many warnings for now
 729   nw="$nw -Woverlength-strings"     # Not a problem these days
 730   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 731   nw="$nw -Wunreachable-code"       # so buggy that it's now silently ignored
 732   nw="$nw -Wpadded"                 # Our structs are not padded
 733   nw="$nw -Wredundant-decls"        # we regularly (re)declare functions
 734   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 735   nw="$nw -Wformat-nonliteral"      # we do this a lot
 736   nw="$nw -Wvla"                    # warnings in gettext.h
 737   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 738   nw="$nw -Wswitch-enum"            # Too many warnings for now
 739   nw="$nw -Wswitch-default"         # Too many warnings for now
 740   nw="$nw -Wfloat-equal"            # warns about high-quality code
 741   nw="$nw -Winline"                 # OK to ignore 'inline'
 742   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 743   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 744                                     # signed overflow has undefined behavior
 745   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 746   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 747
 748   # Emacs doesn't care about shadowing; see
 749   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 750   nw="$nw -Wshadow"
 751
 752   # Emacs's use of alloca inhibits protecting the stack.
 753   nw="$nw -Wstack-protector"
 754
 755   # The following line should be removable at some point.
 756   nw="$nw -Wsuggest-attribute=pure"
 757
 758   gl_MANYWARN_ALL_GCC([ws])
 759   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 760   for w in $ws; do
 761     gl_WARN_ADD([$w])
 762   done
 763   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 764   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 765   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 766   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 767   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 768   gl_WARN_ADD([-Wno-format-nonliteral])
 769
 770   # In spite of excluding -Wlogical-op above, it is enabled, as of
 771   # gcc 4.5.0 20090517.
 772   gl_WARN_ADD([-Wno-logical-op])
 773
 774   gl_WARN_ADD([-fdiagnostics-show-option])
 775   gl_WARN_ADD([-funit-at-a-time])
 776
 777   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 778   AH_VERBATIM([FORTIFY_SOURCE],
 779   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 780       without upsetting glibc 2.15+. */
 781    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 782    # define _FORTIFY_SOURCE 2
 783    #endif
 784   ])
 785   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 786
 787   # We use a slightly smaller set of warning options for lib/.
 788   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 789   nw=
 790   nw="$nw -Wunused-macros"
 791
 792   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 793   AC_SUBST([GNULIB_WARN_CFLAGS])
 794 fi
 795
 796
 797
 798 dnl Some other nice autoconf tests.
 799 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 800 dnl AC_PROG_INSTALL
 801 dnl AC_PROG_MKDIR_P
 802 dnl if test "x$RANLIB" = x; then
 803 dnl   AC_PROG_RANLIB
 804 dnl fi
 805 AC_PROG_LN_S
 806
 807 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 808   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 809 dnl Don't use GZIP, which is used by gzip for additional parameters.
 810 AC_PATH_PROG(GZIP_PROG, gzip)
 811
 812 if test $opsys = gnu-linux; then
 813   AC_PATH_PROG(PAXCTL, paxctl,,
 814     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 815   if test "X$PAXCTL" != X; then
 816     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 817     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 818       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 819       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 820   fi
 821 fi
 822
 823 ## Need makeinfo >= 4.7 (?) to build the manuals.
 824 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 825 dnl By this stage, configure has already checked for egrep and set EGREP,
 826 dnl or exited with an error if no egrep was found.
 827 if test "$MAKEINFO" != "no"; then
 828   case `
 829     $MAKEINFO --version 2> /dev/null |
 830     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
 831   ` in
 832     '') MAKEINFO=no;;
 833   esac
 834 fi
 835
 836 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 837 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 838 ## therefore in the category of "special tools" not normally required, which
 839 ## configure does not have to check for (eg autoconf itself).
 840 ## In a Bazaar checkout on the other hand, the manuals are not included.
 841 ## So makeinfo is a requirement to build from Bazaar, and configure
 842 ## should test for it as it does for any other build requirement.
 843 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 844 ## with pre-built manuals, from a Bazaar checkout.
 845 HAVE_MAKEINFO=yes
 846
 847 if test "$MAKEINFO" = "no"; then
 848   MAKEINFO=makeinfo
 849   if test "x${with_makeinfo}" = "xno"; then
 850     HAVE_MAKEINFO=no
 851   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
 852     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 853 source tree does not seem to have pre-built manuals in the `info' directory.
 854 Either install a suitable version of makeinfo, or re-run configure
 855 with the `--without-makeinfo' option to build without the manuals.] )
 856   fi
 857 fi
 858 AC_SUBST(HAVE_MAKEINFO)
 859
 860 dnl Just so that there is only a single place we need to edit.
 861 INFO_EXT=.info
 862 INFO_OPTS=--no-split
 863 AC_SUBST(INFO_EXT)
 864 AC_SUBST(INFO_OPTS)
 865
 866 dnl Add our options to ac_link now, after it is set up.
 867
 868 if test x$GCC = xyes; then
 869   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 870     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 871 else
 872   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 873     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 874 fi
 875
 876 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 877 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 878 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 879 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 880 dnl if not built to support GNU ld.
 881
 882 late_LDFLAGS=$LDFLAGS
 883 if test x$GCC = xyes; then
 884   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 885 else
 886   LDFLAGS="$LDFLAGS -znocombreloc"
 887 fi
 888
 889 AC_MSG_CHECKING([for -znocombreloc])
 890 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 891   [AC_MSG_RESULT(yes)],
 892   LDFLAGS=$late_LDFLAGS
 893   [AC_MSG_RESULT(no)])
 894
 895
 896 dnl The function dump-emacs will not be defined and temacs will do
 897 dnl (load "loadup") automatically unless told otherwise.
 898 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 899 case "$opsys" in
 900   your-opsys-here) CANNOT_DUMP=yes ;;
 901 esac
 902
 903 test "$CANNOT_DUMP" = "yes" && \
 904   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 905
 906 AC_SUBST(CANNOT_DUMP)
 907
 908
 909 UNEXEC_OBJ=unexelf.o
 910 case "$opsys" in
 911   # MSDOS uses unexcoff.o
 912   # MSWindows uses unexw32.o
 913   aix4-2)
 914    UNEXEC_OBJ=unexaix.o
 915    ;;
 916   cygwin)
 917    UNEXEC_OBJ=unexcw.o
 918    ;;
 919   darwin)
 920    UNEXEC_OBJ=unexmacosx.o
 921    ;;
 922   hpux10-20 | hpux11)
 923    UNEXEC_OBJ=unexhp9k800.o
 924    ;;
 925   sol2-10)
 926    # Use the Solaris dldump() function, called from unexsol.c, to dump
 927    # emacs, instead of the generic ELF dump code found in unexelf.c.
 928    # The resulting binary has a complete symbol table, and is better
 929    # for debugging and other observability tools (debuggers, pstack, etc).
 930    #
 931    # If you encounter a problem using dldump(), please consider sending
 932    # a message to the OpenSolaris tools-linking mailing list:
 933    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 934    #
 935    # It is likely that dldump() works with older Solaris too, but this has
 936    # not been tested, so for now this change is for Solaris 10 or newer.
 937    UNEXEC_OBJ=unexsol.o
 938    ;;
 939 esac
 940
 941 LD_SWITCH_SYSTEM=
 942 case "$opsys" in
 943   freebsd)
 944    ## Let `ld' find image libs and similar things in /usr/local/lib.
 945    ## The system compiler, GCC, has apparently been modified to not
 946    ## look there, contrary to what a stock GCC would do.
 947 ### It's not our place to do this.  See bug#10313#17.
 948 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 949       :
 950    ;;
 951
 952   gnu-linux)
 953    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 954    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 955    ;;
 956
 957   netbsd)
 958 ### It's not our place to do this.  See bug#10313#17.
 959 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 960       :
 961    ;;
 962
 963   openbsd)
 964    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 965    ## otherwise Emacs dumps core on elf systems.
 966    LD_SWITCH_SYSTEM="-Z"
 967    ;;
 968 esac
 969 AC_SUBST(LD_SWITCH_SYSTEM)
 970
 971 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 972
 973 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 974 ## which has not been defined yet.  When this was handled with cpp,
 975 ## it was expanded to null when configure sourced the s/*.h file.
 976 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 977 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 978 ## (or somesuch), but because it is supposed to go at the _front_
 979 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 980 ## Compare with the gnu-linux case below, which added to the end
 981 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 982 ## LD_SWITCH_SYSTEM_TEMACS.
 983 case "$opsys" in
 984   netbsd|openbsd)
 985    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 986 esac
 987
 988
 989 C_SWITCH_MACHINE=
 990 case $canonical in
 991  alpha*)
 992   AC_CHECK_DECL([__ELF__])
 993   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 994     ## With ELF, make sure that all common symbols get allocated to in the
 995     ## data section.  Otherwise, the dump of temacs may miss variables in
 996     ## the shared library that have been initialized.  For example, with
 997     ## GNU libc, __malloc_initialized would normally be resolved to the
 998     ## shared library's .bss section, which is fatal.
 999     if test "x$GCC" = "xyes"; then
1000       C_SWITCH_MACHINE="-fno-common"
1001     else
1002       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
1003     fi
1004   else
1005     UNEXEC_OBJ=unexalpha.o
1006   fi
1007   ;;
1008 esac
1009 AC_SUBST(C_SWITCH_MACHINE)
1010
1011 AC_SUBST(UNEXEC_OBJ)
1012
1013 C_SWITCH_SYSTEM=
1014 ## Some programs in src produce warnings saying certain subprograms
1015 ## are too complex and need a MAXMEM value greater than 2000 for
1016 ## additional optimization.  --nils@exp-math.uni-essen.de
1017 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1018   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1019 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1020 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1021 AC_SUBST(C_SWITCH_SYSTEM)
1022
1023
1024 LIBS_SYSTEM=
1025 case "$opsys" in
1026   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1027   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1028
1029   freebsd) LIBS_SYSTEM="-lutil" ;;
1030
1031   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1032
1033   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1034
1035   ## Motif needs -lgen.
1036   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1037 esac
1038 AC_SUBST(LIBS_SYSTEM)
1039
1040
1041 ### Make sure subsequent tests use flags consistent with the build flags.
1042
1043 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1044   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1045 else
1046   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1047 fi
1048
1049 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1050 AC_DEFUN([AC_TYPE_SIZE_T])
1051 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1052 AC_DEFUN([AC_TYPE_UID_T])
1053
1054
1055 LIB_MATH=-lm
1056 LIB_STANDARD=
1057 START_FILES=
1058 dnl Current possibilities handled by sed (aix4-2 -> aix,
1059 dnl gnu-linux -> gnu/linux, etc.):
1060 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1061 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1062 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1063
1064 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
1065 case $opsys in
1066   cygwin )
1067     LIB_MATH=
1068     START_FILES='pre-crt0.o'
1069     ;;
1070   darwin )
1071     ## Adding -lm confuses the dynamic linker, so omit it.
1072     LIB_MATH=
1073     START_FILES='pre-crt0.o'
1074     ;;
1075   freebsd )
1076     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1077     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1078     SYSTEM_TYPE=berkeley-unix
1079     ;;
1080   gnu-linux | gnu-kfreebsd )
1081     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1082     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1083     ;;
1084   hpux10-20 | hpux11 )
1085     LIB_STANDARD=-lc
1086     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1087     ;;
1088   dnl NB this may be adjusted below.
1089   netbsd | openbsd )
1090     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1091     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1092     SYSTEM_TYPE=berkeley-unix
1093     ;;
1094
1095   sol2* | unixware )
1096     SYSTEM_TYPE=usg-unix-v
1097     ;;
1098
1099 esac
1100
1101 AC_SUBST(LIB_MATH)
1102 AC_SUBST(START_FILES)
1103 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1104   [The type of system you are compiling for; sets `system-type'.])
1105
1106 dnl Not all platforms use crtn.o files.  Check if the current one does.
1107 crt_files=
1108
1109 for file in x $LIB_STANDARD $START_FILES; do
1110   case "$file" in
1111     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1112   esac
1113 done
1114
1115 if test "x$crt_files" != x; then
1116
1117   ## If user specified a crt-dir, use that unconditionally.
1118   crt_gcc=no
1119
1120   if test "X$CRT_DIR" = "X"; then
1121
1122     CRT_DIR=/usr/lib            # default
1123
1124     case "$canonical" in
1125       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1126       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1127       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1128       ## For anything else (eg /usr/lib32), it is up the user to specify
1129       ## the location (bug#5655).
1130       ## Test for crtn.o, not just the directory, because sometimes the
1131       ## directory exists but does not have the relevant files (bug#1287).
1132       ## FIXME better to test for binary compatibility somehow.
1133       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1134       ;;
1135
1136       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1137     esac
1138
1139     case "$opsys" in
1140       hpux10-20) CRT_DIR=/lib ;;
1141     esac
1142
1143     test "x${GCC}" = xyes && crt_gcc=yes
1144
1145   fi                            # CRT_DIR = ""
1146
1147   crt_missing=
1148
1149   for file in $crt_files; do
1150
1151     ## If we're using gcc, try to determine it automatically by asking
1152     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1153     ## system-dependent default from above.]
1154     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1155
1156        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1157        case "$crt_file" in
1158          */*)
1159            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1160            ;;
1161        esac
1162     fi
1163
1164     dnl We expect all the files to be in a single directory, so after the
1165     dnl first there is no point asking gcc.
1166     crt_gcc=no
1167
1168     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1169   done                          # $crt_files
1170
1171   test "x$crt_missing" = x || \
1172     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1173 Try using the --with-crt-dir option.])
1174
1175 fi                              # crt_files != ""
1176
1177 AC_SUBST(CRT_DIR)
1178
1179 case $opsys in
1180   netbsd | openbsd )
1181     if test -f $CRT_DIR/crti.o; then
1182
1183         test -f $CRT_DIR/crtn.o || \
1184           AC_MSG_ERROR([Required file not found: crtn.o])
1185
1186         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1187         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1188     fi
1189     ;;
1190 esac
1191
1192
1193 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1194 pre_PKG_CONFIG_LIBS=$LIBS
1195
1196 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1197
1198 dnl This function definition taken from Gnome 2.0
1199 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1200 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1201 dnl also defines GSTUFF_PKG_ERRORS on error
1202 AC_DEFUN([PKG_CHECK_MODULES], [
1203   succeeded=no
1204
1205   if test "$PKG_CONFIG" = "no" ; then
1206      ifelse([$4], , [AC_MSG_ERROR([
1207       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1208   else
1209      PKG_CONFIG_MIN_VERSION=0.9.0
1210      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1211         AC_MSG_CHECKING(for $2)
1212
1213         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1214            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1215            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1216             edit_cflags="
1217               s,///*,/,g
1218               s/^/ /
1219               s/ -I/ $isystem/g
1220               s/^ //
1221             "
1222             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1223             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1224             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1225             succeeded=yes
1226         else
1227             AC_MSG_RESULT(no)
1228             $1_CFLAGS=""
1229             $1_LIBS=""
1230             ## If we have a custom action on failure, don't print errors, but
1231             ## do set a variable so people can do so.  Do it in a subshell
1232             ## to capture any diagnostics in invoking pkg-config.
1233             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1234             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1235         fi
1236
1237         AC_SUBST($1_CFLAGS)
1238         AC_SUBST($1_LIBS)
1239      else
1240         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1241         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1242      fi
1243   fi
1244
1245   if test $succeeded = yes; then
1246      ifelse([$3], , :, [$3])
1247   else
1248      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1249   fi
1250 ])
1251
1252
1253 if test "${with_sound}" != "no"; then
1254   # Sound support for GNU/Linux and the free BSDs.
1255   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1256     have_sound_header=yes)
1257   # Emulation library used on NetBSD.
1258   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1259   AC_SUBST(LIBSOUND)
1260
1261   ALSA_REQUIRED=1.0.0
1262   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1263   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1264   if test $HAVE_ALSA = yes; then
1265     SAVE_CFLAGS="$CFLAGS"
1266     SAVE_LIBS="$LIBS"
1267     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1268     LIBS="$ALSA_LIBS $LIBS"
1269     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1270                     emacs_alsa_normal=yes,
1271                     emacs_alsa_normal=no)
1272     if test "$emacs_alsa_normal" != yes; then
1273       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1274                      [[snd_lib_error_set_handler (0);]])],
1275                      emacs_alsa_subdir=yes,
1276                      emacs_alsa_subdir=no)
1277       if test "$emacs_alsa_subdir" != yes; then
1278         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1279       fi
1280       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1281     fi
1282
1283     CFLAGS="$SAVE_CFLAGS"
1284     LIBS="$SAVE_LIBS"
1285     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1286     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1287     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1288   fi
1289
1290   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1291   dnl compiles only on the specified platforms.  For others, it
1292   dnl probably doesn't make sense to try.
1293   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1294      case "$opsys" in
1295        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1296        gnu-linux|freebsd|netbsd)
1297          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1298          ;;
1299      esac
1300   fi
1301
1302   AC_SUBST(CFLAGS_SOUND)
1303 fi
1304
1305 dnl checks for header files
1306 AC_CHECK_HEADERS_ONCE(
1307   linux/version.h sys/systeminfo.h
1308   coff.h pty.h
1309   sys/vlimit.h sys/resource.h
1310   sys/utsname.h pwd.h utmp.h util.h)
1311
1312 AC_MSG_CHECKING(if personality LINUX32 can be set)
1313 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1314                emacs_cv_personality_linux32=yes,
1315                emacs_cv_personality_linux32=no)
1316 AC_MSG_RESULT($emacs_cv_personality_linux32)
1317
1318 if test $emacs_cv_personality_linux32 = yes; then
1319   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1320             [Define to 1 if personality LINUX32 can be set.])
1321 fi
1322
1323 dnl On Solaris 8 there's a compilation warning for term.h because
1324 dnl it doesn't define `bool'.
1325 AC_CHECK_HEADERS(term.h, , , -)
1326 AC_HEADER_TIME
1327 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1328                                       ]])
1329 if test $ac_cv_have_decl_sys_siglist != yes; then
1330   # For Tru64, at least:
1331   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1332                                           ]])
1333   if test $ac_cv_have_decl___sys_siglist = yes; then
1334     AC_DEFINE(sys_siglist, __sys_siglist,
1335               [Define to any substitute for sys_siglist.])
1336   fi
1337 fi
1338 AC_HEADER_SYS_WAIT
1339
1340 dnl Check for speed_t typedef.
1341 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1342   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1343     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1344 if test $emacs_cv_speed_t = yes; then
1345   AC_DEFINE(HAVE_SPEED_T, 1,
1346            [Define to 1 if `speed_t' is declared by <termios.h>.])
1347 fi
1348
1349 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1350 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1351 #if HAVE_SYS_SOCKET_H
1352 #include <sys/socket.h>
1353 #endif])
1354 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1355 #if HAVE_SYS_SOCKET_H
1356 #include <sys/socket.h>
1357 #endif])
1358 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1359 #if HAVE_SYS_SOCKET_H
1360 #include <sys/socket.h>
1361 #endif])
1362
1363 dnl checks for structure members
1364 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1365                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1366                   struct ifreq.ifr_addr,
1367                   struct ifreq.ifr_addr.sa_len], , ,
1368                  [AC_INCLUDES_DEFAULT
1369 #if HAVE_SYS_SOCKET_H
1370 #include <sys/socket.h>
1371 #endif
1372 #if HAVE_NET_IF_H
1373 #include <net/if.h>
1374 #endif])
1375
1376 dnl Check for endianness.
1377 dnl AC_C_BIGENDIAN is done by gnulib.
1378
1379 dnl check for Make feature
1380 dnl AC_PROG_MAKE_SET is done by Automake.
1381
1382 DEPFLAGS=
1383 MKDEPDIR=":"
1384 deps_frag=deps.mk
1385 dnl check for GNU Make if we have GCC and autodepend is on.
1386 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1387    AC_MSG_CHECKING([whether we are using GNU Make])
1388    HAVE_GNU_MAKE=no
1389    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1390    if test "x$testval" != x; then
1391       HAVE_GNU_MAKE=yes
1392    else
1393       ac_enable_autodepend=no
1394    fi
1395    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1396    if test $HAVE_GNU_MAKE = yes; then
1397       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1398       SAVE_CFLAGS="$CFLAGS"
1399       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1400       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1401       CFLAGS="$SAVE_CFLAGS"
1402       test -f deps.d || ac_enable_autodepend=no
1403       rm -rf deps.d
1404       AC_MSG_RESULT([$ac_enable_autodepend])
1405    fi
1406    if test $ac_enable_autodepend = yes; then
1407       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1408       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1409       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1410       deps_frag=autodeps.mk
1411    fi
1412 fi
1413 deps_frag=$srcdir/src/$deps_frag
1414 AC_SUBST(MKDEPDIR)
1415 AC_SUBST(DEPFLAGS)
1416 AC_SUBST_FILE(deps_frag)
1417
1418
1419 lisp_frag=$srcdir/src/lisp.mk
1420 AC_SUBST_FILE(lisp_frag)
1421
1422
1423 dnl checks for operating system services
1424 AC_SYS_LONG_FILE_NAMES
1425
1426 #### Choose a window system.
1427
1428 ## We leave window_system equal to none if
1429 ## we end up building without one.  Any new window system should
1430 ## set window_system to an appropriate value and add objects to
1431 ## window-system-specific substs.
1432
1433 window_system=none
1434 AC_PATH_X
1435 if test "$no_x" != yes; then
1436   window_system=x11
1437 fi
1438
1439 LD_SWITCH_X_SITE_RPATH=
1440 if test "${x_libraries}" != NONE; then
1441   if test -n "${x_libraries}"; then
1442     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1443     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1444   fi
1445   x_default_search_path=""
1446   x_search_path=${x_libraries}
1447   if test -z "${x_search_path}"; then
1448     x_search_path=/usr/lib
1449   fi
1450   for x_library in `echo ${x_search_path}: | \
1451                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1452     x_search_path="\
1453 ${x_library}/X11/%L/%T/%N%C%S:\
1454 ${x_library}/X11/%l/%T/%N%C%S:\
1455 ${x_library}/X11/%T/%N%C%S:\
1456 ${x_library}/X11/%L/%T/%N%S:\
1457 ${x_library}/X11/%l/%T/%N%S:\
1458 ${x_library}/X11/%T/%N%S"
1459     if test x"${x_default_search_path}" = x; then
1460       x_default_search_path=${x_search_path}
1461     else
1462       x_default_search_path="${x_search_path}:${x_default_search_path}"
1463     fi
1464   done
1465 fi
1466 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1467
1468 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1469   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1470 fi
1471
1472 if test x"${x_includes}" = x; then
1473   bitmapdir=/usr/include/X11/bitmaps
1474 else
1475   # accumulate include directories that have X11 bitmap subdirectories
1476   bmd_acc="dummyval"
1477   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1478     if test -d "${bmd}/X11/bitmaps"; then
1479       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1480     fi
1481     if test -d "${bmd}/bitmaps"; then
1482       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1483     fi
1484   done
1485   if test ${bmd_acc} != "dummyval"; then
1486     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1487   fi
1488 fi
1489
1490 HAVE_NS=no
1491 NS_IMPL_COCOA=no
1492 NS_IMPL_GNUSTEP=no
1493 tmp_CPPFLAGS="$CPPFLAGS"
1494 tmp_CFLAGS="$CFLAGS"
1495 CPPFLAGS="$CPPFLAGS -x objective-c"
1496 CFLAGS="$CFLAGS -x objective-c"
1497 GNU_OBJC_CFLAGS=
1498 LIBS_GNUSTEP=
1499 if test "${with_ns}" != no; then
1500   if test "${opsys}" = darwin; then
1501      NS_IMPL_COCOA=yes
1502      ns_appdir=`pwd`/nextstep/Emacs.app
1503      ns_appbindir=${ns_appdir}/Contents/MacOS
1504      ns_appresdir=${ns_appdir}/Contents/Resources
1505      ns_appsrc=Cocoa/Emacs.base
1506   elif test -f $GNUSTEP_CONFIG_FILE; then
1507      NS_IMPL_GNUSTEP=yes
1508      ns_appdir=`pwd`/nextstep/Emacs.app
1509      ns_appbindir=${ns_appdir}
1510      ns_appresdir=${ns_appdir}/Resources
1511      ns_appsrc=GNUstep/Emacs.base
1512      dnl FIXME sourcing this several times in subshells seems inefficient.
1513      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1514      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1515      dnl I seemed to need these as well with GNUstep-startup 0.25.
1516      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1517      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1518      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1519        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1520      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1521        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1522      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1523      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1524      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1525      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1526      LIB_STANDARD=
1527      START_FILES=
1528      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1529      dnl If they had chosen to either define it or not, we could have
1530      dnl just used AC_CHECK_DECL here.
1531      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1532        emacs_cv_objc_exceptions,
1533 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1534 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1535 1;
1536 #else
1537 fail;
1538 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1539      if test $emacs_cv_objc_exceptions = yes; then
1540        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1541        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1542          [Define if GNUstep uses ObjC exceptions.])
1543        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1544      fi
1545   fi
1546
1547   dnl This is only used while we test the NS headers, it gets reset below.
1548   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1549
1550   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1551                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1552   files are missing or cannot be compiled.])])
1553
1554   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1555                                      [
1556 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1557 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1558  ; /* OK */
1559 #else
1560 #error "OSX 10.4 or newer required"
1561 #endif
1562 #endif
1563                     ])],
1564                     ns_osx_have_104=yes,
1565                     ns_osx_have_104=no)
1566   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1567                                      [NSInteger i;])],
1568                     ns_have_nsinteger=yes,
1569                     ns_have_nsinteger=no)
1570   if test $ns_osx_have_104 = no; then
1571      AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1572   fi
1573   if test $ns_have_nsinteger = yes; then
1574     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1575   fi
1576 fi
1577
1578 AC_SUBST(LIBS_GNUSTEP)
1579
1580 INSTALL_ARCH_INDEP_EXTRA=install-etc
1581 ns_self_contained=no
1582 NS_OBJ=
1583 NS_OBJC_OBJ=
1584 if test "${HAVE_NS}" = yes; then
1585   if test "$with_toolkit_scroll_bars" = "no"; then
1586     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1587   fi
1588
1589   window_system=nextstep
1590   # set up packaging dirs
1591   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1592      ns_self_contained=yes
1593      prefix=${ns_appresdir}
1594      exec_prefix=${ns_appbindir}
1595      dnl This one isn't really used, only archlibdir is.
1596      libexecdir="\${ns_appbindir}/libexec"
1597      archlibdir="\${ns_appbindir}/libexec"
1598      docdir="\${ns_appresdir}/etc"
1599      etcdir="\${ns_appresdir}/etc"
1600      dnl FIXME maybe set datarootdir instead.
1601      dnl That would also get applications, icons, man.
1602      infodir="\${ns_appresdir}/info"
1603      mandir="\${ns_appresdir}/man"
1604      lispdir="\${ns_appresdir}/lisp"
1605      leimdir="\${ns_appresdir}/leim"
1606      INSTALL_ARCH_INDEP_EXTRA=
1607   fi
1608   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1609 fi
1610 CFLAGS="$tmp_CFLAGS"
1611 CPPFLAGS="$tmp_CPPFLAGS"
1612 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1613 AC_SUBST(ns_self_contained)
1614 AC_SUBST(NS_OBJ)
1615 AC_SUBST(NS_OBJC_OBJ)
1616 AC_SUBST(LIB_STANDARD)
1617
1618 HAVE_W32=no
1619 W32_OBJ=
1620 W32_LIBS=
1621 W32_RES=
1622 W32_RES_LINK=
1623 if test "${with_w32}" != no; then
1624   if test "${opsys}" != "cygwin"; then
1625     AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin.])
1626   fi
1627   AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1628                   [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1629                   cannot be found.])])
1630   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1631   AC_CHECK_TOOL(WINDRES, [windres],
1632                 [AC_MSG_ERROR([No resource compiler found.])])
1633   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1634   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1635   W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1636   W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1637   W32_RES="emacs.res"
1638   # Tell the linker that emacs.res is an object (which we compile from
1639   # the rc file), not a linker script.
1640   W32_RES_LINK="-Wl,-bpe-i386 -Wl,emacs.res"
1641 fi
1642 AC_SUBST(W32_OBJ)
1643 AC_SUBST(W32_LIBS)
1644 AC_SUBST(W32_RES)
1645 AC_SUBST(W32_RES_LINK)
1646
1647 if test "${HAVE_W32}" = "yes"; then
1648   window_system=w32
1649   with_xft=no
1650 fi
1651
1652 ## $window_system is now set to the window system we will
1653 ## ultimately use.
1654
1655 term_header=
1656 HAVE_X_WINDOWS=no
1657 HAVE_X11=no
1658 USE_X_TOOLKIT=none
1659
1660 case "${window_system}" in
1661   x11 )
1662     HAVE_X_WINDOWS=yes
1663     HAVE_X11=yes
1664     term_header=xterm.h
1665     case "${with_x_toolkit}" in
1666       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1667       motif ) USE_X_TOOLKIT=MOTIF ;;
1668       gtk ) with_gtk=yes
1669             term_header=gtkutil.h
1670 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1671 dnl USE_X_TOOLKIT is set.
1672             USE_X_TOOLKIT=none ;;
1673       gtk2 ) with_gtk2=yes
1674              term_header=gtkutil.h
1675              USE_X_TOOLKIT=none ;;
1676       gtk3 ) with_gtk3=yes
1677              term_header=gtkutil.h
1678              USE_X_TOOLKIT=none ;;
1679       no ) USE_X_TOOLKIT=none ;;
1680 dnl If user did not say whether to use a toolkit, make this decision later:
1681 dnl use the toolkit if we have gtk, or X11R5 or newer.
1682       * ) USE_X_TOOLKIT=maybe ;;
1683     esac
1684   ;;
1685   nextstep )
1686     term_header=nsterm.h
1687   ;;
1688   w32 )
1689     term_header=w32term.h
1690   ;;
1691 esac
1692
1693 if test -n "${term_header}"; then
1694     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
1695         [Define to the header for the built-in window system.])
1696 fi
1697
1698 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1699    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1700    if test "$HAVE_XSERVER" = true ||
1701       test -n "$DISPLAY" ||
1702       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1703         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1704 were found.  You should install the relevant development files for X
1705 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1706 sure you have development files for image handling, i.e.
1707 tiff, gif, jpeg, png and xpm.
1708 If you are sure you want Emacs compiled without X window support, pass
1709   --without-x
1710 to configure.])
1711    fi
1712 fi
1713
1714 ### If we're using X11, we should use the X menu package.
1715 HAVE_MENUS=no
1716 case ${HAVE_X11} in
1717   yes ) HAVE_MENUS=yes ;;
1718 esac
1719
1720 # Does the opsystem file prohibit the use of the GNU malloc?
1721 # Assume not, until told otherwise.
1722 GNU_MALLOC=yes
1723
1724 AC_CACHE_CHECK(
1725   [whether malloc is Doug Lea style],
1726   [emacs_cv_var_doug_lea_malloc],
1727   [AC_LINK_IFELSE(
1728      [AC_LANG_PROGRAM(
1729         [[#include <malloc.h>
1730           static void hook (void) {}]],
1731         [[malloc_set_state (malloc_get_state ());
1732           __after_morecore_hook = hook;
1733           __malloc_initialize_hook = hook;]])],
1734      [emacs_cv_var_doug_lea_malloc=yes],
1735      [emacs_cv_var_doug_lea_malloc=no])])
1736 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1737
1738
1739 dnl See comments in aix4-2.h about maybe using system malloc there.
1740 system_malloc=no
1741 case "$opsys" in
1742   ## darwin ld insists on the use of malloc routines in the System framework.
1743   darwin|sol2-10) system_malloc=yes ;;
1744 esac
1745
1746 if test "${system_malloc}" = "yes"; then
1747   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1748   GNU_MALLOC=no
1749   GNU_MALLOC_reason="
1750     (The GNU allocators don't work with this system configuration.)"
1751   GMALLOC_OBJ=
1752   VMLIMIT_OBJ=
1753 else
1754   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1755   VMLIMIT_OBJ=vm-limit.o
1756 fi
1757 AC_SUBST(GMALLOC_OBJ)
1758 AC_SUBST(VMLIMIT_OBJ)
1759
1760 if test "$doug_lea_malloc" = "yes" ; then
1761   if test "$GNU_MALLOC" = yes ; then
1762     GNU_MALLOC_reason="
1763       (Using Doug Lea's new malloc from the GNU C Library.)"
1764   fi
1765   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1766             [Define to 1 if you are using the GNU C Library.])
1767
1768   ## Use mmap directly for allocating larger buffers.
1769   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1770   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1771   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1772   case "$opsys" in
1773     gnu*) REL_ALLOC=no ;;
1774   esac
1775 fi
1776
1777 if test x"${REL_ALLOC}" = x; then
1778   REL_ALLOC=${GNU_MALLOC}
1779 fi
1780
1781 use_mmap_for_buffers=no
1782 case "$opsys" in
1783   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1784 esac
1785
1786 AC_FUNC_MMAP
1787 if test $use_mmap_for_buffers = yes; then
1788   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1789   REL_ALLOC=no
1790 fi
1791
1792 LIBS="$LIBS_SYSTEM $LIBS"
1793
1794 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1795 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1796 AC_CHECK_LIB(dnet, dnet_ntoa)
1797 dnl This causes -lresolv to get used in subsequent tests,
1798 dnl which causes failures on some systems such as HPUX 9.
1799 dnl AC_CHECK_LIB(resolv, gethostbyname)
1800
1801 dnl FIXME replace main with a function we actually want from this library.
1802 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1803
1804 dnl Check if pthreads is available.
1805 LIB_PTHREAD=
1806 AC_CHECK_HEADERS_ONCE(pthread.h)
1807 if test "$ac_cv_header_pthread_h"; then
1808   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1809   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1810   dnl testing for pthread_self if Emacs uses gmalloc.c.
1811   if test "$GMALLOC_OBJ" = gmalloc.o; then
1812     emacs_pthread_function=pthread_atfork
1813   else
1814     emacs_pthread_function=pthread_self
1815   fi
1816   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1817 fi
1818 if test "$HAVE_PTHREAD" = yes; then
1819   case "${canonical}" in
1820     *-hpux*) ;;
1821     *) LIB_PTHREAD="-lpthread"
1822        LIBS="$LIB_PTHREAD $LIBS" ;;
1823   esac
1824   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1825 fi
1826 AC_SUBST([LIB_PTHREAD])
1827
1828 AC_CHECK_LIB(pthreads, cma_open)
1829
1830 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1831 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1832 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1833 ## added to LIBS in configure would never contain the pthreads part,
1834 ## but the value used in Makefiles might.  FIXME?
1835 ##
1836 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1837 ## be harmless on older versions of X where it happens to exist.
1838 test "$opsys" = "aix4-2" && \
1839   test $ac_cv_lib_pthreads_cma_open = yes && \
1840   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1841
1842 dnl Check for need for bigtoc support on IBM AIX
1843
1844 case ${host_os} in
1845 aix*)
1846   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1847     case $GCC in
1848     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1849     *) gdb_cv_bigtoc=-bbigtoc ;;
1850     esac
1851
1852     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1853     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1854   ])
1855   ;;
1856 esac
1857
1858 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1859 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1860 # REAL_CPPFLAGS later on.
1861
1862 REAL_CFLAGS="$CFLAGS"
1863 REAL_CPPFLAGS="$CPPFLAGS"
1864
1865 if test "${HAVE_X11}" = "yes"; then
1866   DEFS="$C_SWITCH_X_SITE $DEFS"
1867   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1868   LIBS="-lX11 $LIBS"
1869   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1870   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1871
1872   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1873   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1874   # but it's more convenient here to set LD_RUN_PATH since this
1875   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1876   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1877     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1878     export LD_RUN_PATH
1879   fi
1880
1881   if test "${opsys}" = "gnu-linux"; then
1882     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1883     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1884      [[XOpenDisplay ("foo");]])],
1885      [xgnu_linux_first_failure=no],
1886      [xgnu_linux_first_failure=yes])
1887     if test "${xgnu_linux_first_failure}" = "yes"; then
1888       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1889       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1890       OLD_CPPFLAGS="$CPPFLAGS"
1891       OLD_LIBS="$LIBS"
1892       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1893       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1894       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1895       LIBS="$LIBS -b i486-linuxaout"
1896       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1897        [[XOpenDisplay ("foo");]])],
1898        [xgnu_linux_second_failure=no],
1899        [xgnu_linux_second_failure=yes])
1900       if test "${xgnu_linux_second_failure}" = "yes"; then
1901         # If we get the same failure with -b, there is no use adding -b.
1902         # So take it out.  This plays safe.
1903         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1904         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1905         CPPFLAGS="$OLD_CPPFLAGS"
1906         LIBS="$OLD_LIBS"
1907         AC_MSG_RESULT(no)
1908       else
1909         AC_MSG_RESULT(yes)
1910       fi
1911     else
1912       AC_MSG_RESULT(no)
1913     fi
1914   fi
1915
1916   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1917   # header files included from there.
1918   AC_MSG_CHECKING(for Xkb)
1919   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1920 #include <X11/XKBlib.h>]],
1921         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1922         emacs_xkb=yes, emacs_xkb=no)
1923   AC_MSG_RESULT($emacs_xkb)
1924   if test $emacs_xkb = yes; then
1925     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1926   fi
1927
1928   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1929 XScreenNumberOfScreen)
1930 fi
1931
1932 if test "${window_system}" = "x11"; then
1933   AC_MSG_CHECKING(X11 version 6)
1934   AC_CACHE_VAL(emacs_cv_x11_version_6,
1935   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1936 [[#if XlibSpecificationRelease < 6
1937 fail;
1938 #endif
1939 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1940   if test $emacs_cv_x11_version_6 = yes; then
1941     AC_MSG_RESULT(6 or newer)
1942     AC_DEFINE(HAVE_X11R6, 1,
1943               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1944     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1945     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1946     ## XIM support.
1947     case "$opsys" in
1948       sol2-*) : ;;
1949       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1950            [Define if you have usable X11R6-style XIM support.])
1951          ;;
1952     esac
1953   else
1954     AC_MSG_RESULT(before 6)
1955   fi
1956 fi
1957
1958
1959 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1960 HAVE_RSVG=no
1961 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1962   if test "${with_rsvg}" != "no"; then
1963     RSVG_REQUIRED=2.11.0
1964     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1965
1966     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1967     AC_SUBST(RSVG_CFLAGS)
1968     AC_SUBST(RSVG_LIBS)
1969
1970     if test $HAVE_RSVG = yes; then
1971       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1972       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1973       LIBS="$RSVG_LIBS $LIBS"
1974     fi
1975   fi
1976 fi
1977
1978 HAVE_IMAGEMAGICK=no
1979 if test "${HAVE_X11}" = "yes"; then
1980   if test "${with_imagemagick}" != "no"; then
1981     ## 6.2.8 is the earliest version known to work, but earlier versions
1982     ## might work - let us know if you find one.
1983     ## 6.0.7 does not work.  See bug#7955.
1984     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1985     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1986     AC_SUBST(IMAGEMAGICK_CFLAGS)
1987     AC_SUBST(IMAGEMAGICK_LIBS)
1988
1989     if test $HAVE_IMAGEMAGICK = yes; then
1990       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1991       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1992       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1993       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1994     fi
1995   fi
1996 fi
1997
1998
1999 HAVE_GTK=no
2000 GTK_OBJ=
2001 check_gtk2=no
2002 gtk3_pkg_errors=
2003 if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2004   GLIB_REQUIRED=2.28
2005   GTK_REQUIRED=3.0
2006   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2007
2008   dnl Checks for libraries.
2009   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2010   if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2011      AC_MSG_ERROR($GTK_PKG_ERRORS)
2012   fi
2013   if test "$pkg_check_gtk" = "yes"; then
2014      AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2015      GTK_OBJ=emacsgtkfixed.o
2016      term_header=gtkutil.h
2017      USE_GTK_TOOLKIT="GTK3"
2018      if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2019          GTK_CFLAGS="$GTK_CFLAGS -DGDK_DISABLE_DEPRECATION_WARNINGS"
2020      fi
2021   else
2022      check_gtk2=yes
2023      gtk3_pkg_errors="$GTK_PKG_ERRORS "
2024   fi
2025 fi
2026
2027 if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2028   GLIB_REQUIRED=2.10
2029   GTK_REQUIRED=2.10
2030   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2031
2032   dnl Checks for libraries.
2033   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2034   if test "$pkg_check_gtk" = "no" &&
2035      { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2036   then
2037     AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2038   fi
2039   test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2040 fi
2041
2042 if test x"$pkg_check_gtk" = xyes; then
2043
2044   AC_SUBST(GTK_CFLAGS)
2045   AC_SUBST(GTK_LIBS)
2046   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2047   CFLAGS="$CFLAGS $GTK_CFLAGS"
2048   LIBS="$GTK_LIBS $LIBS"
2049   dnl Try to compile a simple GTK program.
2050   GTK_COMPILES=no
2051   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
2052   if test "${GTK_COMPILES}" != "yes"; then
2053     if test "$USE_X_TOOLKIT" != "maybe"; then
2054       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2055     fi
2056   else
2057     HAVE_GTK=yes
2058     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2059     GTK_OBJ="gtkutil.o $GTK_OBJ"
2060     USE_X_TOOLKIT=none
2061     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2062       :
2063     else
2064       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2065        closing open displays.  This is no problem if you just use
2066        one display, but if you use more than one and close one of them
2067        Emacs may crash.]])
2068       sleep 3
2069     fi
2070   fi
2071
2072 fi
2073 AC_SUBST(GTK_OBJ)
2074
2075
2076 if test "${HAVE_GTK}" = "yes"; then
2077
2078   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2079   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2080   if test "$with_toolkit_scroll_bars" != no; then
2081     with_toolkit_scroll_bars=yes
2082   fi
2083
2084   dnl  Check if we have the old file selection dialog declared and
2085   dnl  in the link library.  In 2.x it may be in the library,
2086   dnl  but not declared if deprecated featured has been selected out.
2087   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2088   HAVE_GTK_FILE_SELECTION=no
2089   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2090                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2091 #include <gtk/gtk.h>])
2092   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2093     AC_CHECK_FUNCS(gtk_file_selection_new)
2094   fi
2095
2096   dnl Same as above for gtk_handle_box.
2097   HAVE_GTK_HANDLE_BOX=no
2098   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2099                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2100 #include <gtk/gtk.h>])
2101   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2102     AC_CHECK_FUNCS(gtk_handle_box_new)
2103   fi
2104
2105   dnl Same as above for gtk_tearoff_menu_item.
2106   HAVE_GTK_TEAROFF_MENU_ITEM=no
2107   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2108                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2109 #include <gtk/gtk.h>])
2110   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2111     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2112   fi
2113
2114   dnl Check for functions introduced in 2.14 and later.
2115   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2116                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2117                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2118                  gtk_orientable_set_orientation \
2119                  gtk_window_set_has_resize_grip)
2120
2121  term_header=gtkutil.h
2122 fi
2123
2124
2125 HAVE_XWIDGETS=no
2126 HAVE_WEBKIT=no
2127 HAVE_GOOCANVAS=no
2128 HAVE_CLUTTER=no
2129 HAVE_GIR=no
2130
2131 if test "${with_xwidgets}" != "no"; then
2132    echo "xwidgets enabled, checking webkit, and others"
2133    HAVE_XWIDGETS=yes
2134    AC_DEFINE(HAVE_XWIDGETS, 1, [Define to 1 if you have xwidgets support.])
2135 #xwidgets
2136 #TODO
2137 # - enable only if gtk/gtk3 enabled
2138 # - webkit, goocanvas, clutter
2139 # - only webkit_osr is good so remove plain webkit laterish
2140
2141 #webkit version for gtk3.
2142   WEBKIT_REQUIRED=1.4.0
2143   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2144
2145   if test "${with_gtk3}" = "yes"; then
2146     PKG_CHECK_MODULES(WEBKIT, $WEBKIT_MODULES, HAVE_WEBKIT=yes, HAVE_WEBKIT=no)
2147     if test $HAVE_WEBKIT = yes; then
2148         AC_DEFINE(HAVE_WEBKIT_OSR, 1, [Define to 1 if you have webkit_osr support.])
2149     fi
2150   fi
2151
2152   if test "${with_xwdemo}"  = "yes"; then
2153 #clutter and goocanvas are just proof of concept so disable for now
2154   CLUTTER_REQUIRED=1.0.0
2155   CLUTTER_MODULES="clutter-gtk-1.0 >= $CLUTTER_REQUIRED"
2156
2157   PKG_CHECK_MODULES(CLUTTER, $CLUTTER_MODULES, HAVE_CLUTTER=yes, HAVE_CLUTTER=no)
2158   if test $HAVE_CLUTTER = yes;  then
2159      AC_DEFINE(HAVE_CLUTTER, 1, [Define to 1 if you have clutter support.])
2160   fi
2161
2162
2163   GOOCANVAS_REQUIRED=1.4.0
2164   GOOCANVAS_MODULES="goocanvasgtk-3.0 >= $GOOCANVAS_REQUIRED"
2165
2166   PKG_CHECK_MODULES(GOOCANVAS, $GOOCANVAS_MODULES, HAVE_GOOCANVAS=yes, HAVE_GOOCANVAS=no)
2167   if test $HAVE_GOOCANVAS = yes; then
2168      AC_DEFINE(HAVE_GOOCANVAS, 1, [Define to 1 if you have goocanvas support.])
2169   fi
2170   fi
2171
2172   GIR_REQUIRED=1.32.1
2173   GIR_MODULES="gobject-introspection-1.0 >= $GIR_REQUIRED"
2174   PKG_CHECK_MODULES(GIR, $GIR_MODULES, HAVE_GIR=yes, HAVE_GIR=no)
2175   if test $HAVE_GIR = yes; then
2176      AC_DEFINE(HAVE_GIR, 1, [Define to 1 if you have GIR support.])
2177   fi
2178
2179
2180 fi
2181
2182
2183 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2184 dnl other platforms.
2185 HAVE_DBUS=no
2186 DBUS_OBJ=
2187 if test "${with_dbus}" = "yes"; then
2188    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2189    if test "$HAVE_DBUS" = yes; then
2190      LIBS="$LIBS $DBUS_LIBS"
2191      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2192      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2193      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2194      dnl D-Bus 1.5.12.
2195      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2196                     dbus_type_is_valid \
2197                     dbus_validate_bus_name \
2198                     dbus_validate_path \
2199                     dbus_validate_interface \
2200                     dbus_validate_member)
2201      DBUS_OBJ=dbusbind.o
2202    fi
2203 fi
2204 AC_SUBST(DBUS_OBJ)
2205
2206 dnl GSettings has been tested under GNU/Linux only.
2207 HAVE_GSETTINGS=no
2208 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2209    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2210    if test "$HAVE_GSETTINGS" = "yes"; then
2211       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2212       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2213       SETTINGS_LIBS="$GSETTINGS_LIBS"
2214    fi
2215 fi
2216
2217 dnl GConf has been tested under GNU/Linux only.
2218 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2219 HAVE_GCONF=no
2220 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2221    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2222    if test "$HAVE_GCONF" = yes; then
2223       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2224       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2225       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2226       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2227    fi
2228 fi
2229
2230 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2231     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2232     if test "$HAVE_GOBJECT" = "yes"; then
2233        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2234        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2235     fi
2236     SAVE_CFLAGS="$CFLAGS"
2237     SAVE_LIBS="$LIBS"
2238     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2239     LIBS="$SETTINGS_LIBS $LIBS"
2240     AC_CHECK_FUNCS([g_type_init])
2241     CFLAGS="$SAVE_CFLAGS"
2242     LIBS="$SAVE_LIBS"
2243 fi
2244 AC_SUBST(SETTINGS_CFLAGS)
2245 AC_SUBST(SETTINGS_LIBS)
2246
2247
2248 dnl SELinux is available for GNU/Linux only.
2249 HAVE_LIBSELINUX=no
2250 LIBSELINUX_LIBS=
2251 if test "${with_selinux}" = "yes"; then
2252    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2253    if test "$HAVE_LIBSELINUX" = yes; then
2254       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2255       LIBSELINUX_LIBS=-lselinux
2256    fi
2257 fi
2258 AC_SUBST(LIBSELINUX_LIBS)
2259
2260 HAVE_GNUTLS=no
2261 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2262 if test "${with_gnutls}" = "yes" ; then
2263   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2264   if test "${HAVE_GNUTLS}" = "yes"; then
2265     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2266   fi
2267
2268   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2269   LIBS="$LIBGNUTLS_LIBS $LIBS"
2270   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2271
2272   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2273     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2274   fi
2275 fi
2276
2277 AC_SUBST(LIBGNUTLS_LIBS)
2278 AC_SUBST(LIBGNUTLS_CFLAGS)
2279
2280 dnl inotify is only available on GNU/Linux.
2281 if test "${with_inotify}" = "yes"; then
2282    AC_CHECK_HEADERS(sys/inotify.h)
2283    if test "$ac_cv_header_sys_inotify_h" = yes ; then
2284      AC_CHECK_FUNC(inotify_init1)
2285    fi
2286 fi
2287 if test "$ac_cv_func_inotify_init1" = yes; then
2288   AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2289 fi
2290
2291 dnl POSIX ACL support: provided by libacl on GNU/Linux, by libc on FreeBSD.
2292 HAVE_POSIX_ACL=no
2293 LIBACL_LIBS=
2294 if test "${with_acl}" = "yes"; then
2295   AC_CHECK_LIB([acl], [acl_set_file], HAVE_POSIX_ACL=yes, HAVE_POSIX_ACL=no)
2296   if test "$HAVE_POSIX_ACL" = yes; then
2297     AC_DEFINE(HAVE_POSIX_ACL, 1, [Define to 1 if using POSIX ACL support.])
2298     LIBACL_LIBS=-lacl
2299   else
2300     AC_CHECK_FUNC(acl_set_file, HAVE_POSIX_ACL=yes, HAVE_POSIX_ACL=no)
2301     if test "$HAVE_POSIX_ACL" = yes; then
2302       AC_DEFINE(HAVE_POSIX_ACL, 1, [Define to 1 if using POSIX ACL support.])
2303     fi
2304  fi
2305 fi
2306 AC_SUBST(LIBACL_LIBS)
2307
2308 dnl Do not put whitespace before the #include statements below.
2309 dnl Older compilers (eg sunos4 cc) choke on it.
2310 HAVE_XAW3D=no
2311 LUCID_LIBW=
2312 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2313   if test "$with_xaw3d" != no; then
2314     AC_CACHE_VAL(emacs_cv_xaw3d,
2315     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2316 #include <X11/Intrinsic.h>
2317 #include <X11/Xaw3d/Simple.h>]],
2318       [[]])],
2319       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2320                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2321       emacs_cv_xaw3d=no)])
2322   else
2323     emacs_cv_xaw3d=no
2324   fi
2325   if test $emacs_cv_xaw3d = yes; then
2326     AC_MSG_CHECKING(for xaw3d)
2327     AC_MSG_RESULT([yes; using Lucid toolkit])
2328     USE_X_TOOLKIT=LUCID
2329     HAVE_XAW3D=yes
2330     LUCID_LIBW=-lXaw3d
2331     AC_DEFINE(HAVE_XAW3D, 1,
2332               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2333   else
2334     AC_MSG_CHECKING(for xaw3d)
2335     AC_MSG_RESULT(no)
2336     AC_MSG_CHECKING(for libXaw)
2337     AC_CACHE_VAL(emacs_cv_xaw,
2338     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2339 #include <X11/Intrinsic.h>
2340 #include <X11/Xaw/Simple.h>]],
2341       [[]])],
2342       emacs_cv_xaw=yes,
2343       emacs_cv_xaw=no)])
2344     if test $emacs_cv_xaw = yes; then
2345       AC_MSG_RESULT([yes; using Lucid toolkit])
2346       USE_X_TOOLKIT=LUCID
2347       LUCID_LIBW=-lXaw
2348     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2349       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2350     else
2351       AC_MSG_ERROR([No X toolkit could be found.
2352 If you are sure you want Emacs compiled without an X toolkit, pass
2353   --with-x-toolkit=no
2354 to configure.  Otherwise, install the development libraries for the toolkit
2355 that you want to use (e.g. Gtk+) and re-run configure.])
2356     fi
2357   fi
2358 fi
2359
2360 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2361
2362 LIBXTR6=
2363 if test "${USE_X_TOOLKIT}" != "none"; then
2364   AC_MSG_CHECKING(X11 toolkit version)
2365   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2366   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2367 [[#if XtSpecificationRelease < 6
2368 fail;
2369 #endif
2370 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2371   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2372   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2373     AC_MSG_RESULT(6 or newer)
2374     AC_DEFINE(HAVE_X11XTR6, 1,
2375               [Define to 1 if you have the X11R6 or newer version of Xt.])
2376     LIBXTR6="-lSM -lICE"
2377     case "$opsys" in
2378       ## Use libw.a along with X11R6 Xt.
2379       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2380     esac
2381   else
2382     AC_MSG_RESULT(before 6)
2383   fi
2384
2385 dnl If using toolkit, check whether libXmu.a exists.
2386 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2387   OLDLIBS="$LIBS"
2388   if test x$HAVE_X11XTR6 = xyes; then
2389     LIBS="-lXt -lSM -lICE $LIBS"
2390   else
2391     LIBS="-lXt $LIBS"
2392   fi
2393   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2394   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2395   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2396 fi
2397 AC_SUBST(LIBXTR6)
2398
2399 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2400 dnl Why not just test for libxmu in the normal way?
2401 LIBXMU=-lXmu
2402 case $opsys in
2403   ## These systems don't supply Xmu.
2404   hpux* | aix4-2 )
2405     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2406     ;;
2407 esac
2408 AC_SUBST(LIBXMU)
2409
2410 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2411 if test "${HAVE_X11}" = "yes"; then
2412   if test "${USE_X_TOOLKIT}" != "none"; then
2413     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2414   fi
2415 fi
2416
2417 LIBXP=
2418 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2419   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2420   if test -d /usr/include/openmotif; then
2421     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2422     emacs_cv_openmotif=yes
2423     case "$canonical" in
2424       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2425       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2426       ;;
2427       *)
2428       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2429     esac
2430   else
2431     emacs_cv_openmotif=no
2432   fi
2433   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2434   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2435     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2436 int x = 5;
2437 #else
2438 Motif version prior to 2.1.
2439 #endif]])],
2440     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2441   if test $emacs_cv_motif_version_2_1 = yes; then
2442     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2443     if test x$emacs_cv_openmotif = xyes; then
2444       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2445     fi
2446   else
2447     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2448     # We put this in CFLAGS temporarily to precede other -I options
2449     # that might be in CFLAGS temporarily.
2450     # We put this in CPPFLAGS where it precedes the other -I options.
2451     OLD_CPPFLAGS=$CPPFLAGS
2452     OLD_CFLAGS=$CFLAGS
2453     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2454     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2455     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2456       [[int x = 5;]])],
2457       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2458     if test $emacs_cv_lesstif = yes; then
2459       # Make sure this -I option remains in CPPFLAGS after it is set
2460       # back to REAL_CPPFLAGS.
2461       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2462       # have those other -I options anyway.  Ultimately, having this
2463       # directory ultimately in CPPFLAGS will be enough.
2464       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2465       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2466     else
2467       CFLAGS=$OLD_CFLAGS
2468       CPPFLAGS=$OLD_CPPFLAGS
2469     fi
2470   fi
2471   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2472     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2473 fi
2474
2475 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2476 dnl using Motif or Xaw3d is available, and unless
2477 dnl --with-toolkit-scroll-bars=no was specified.
2478
2479 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2480             [Define to 1 if we should use toolkit scroll bars.])dnl
2481 USE_TOOLKIT_SCROLL_BARS=no
2482 if test "${with_toolkit_scroll_bars}" != "no"; then
2483   if test "${USE_X_TOOLKIT}" != "none"; then
2484     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2485       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2486       HAVE_XAW3D=no
2487       USE_TOOLKIT_SCROLL_BARS=yes
2488     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2489       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2490       USE_TOOLKIT_SCROLL_BARS=yes
2491     fi
2492   elif test "${HAVE_GTK}" = "yes"; then
2493     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2494     USE_TOOLKIT_SCROLL_BARS=yes
2495   elif test "${HAVE_NS}" = "yes"; then
2496     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2497     USE_TOOLKIT_SCROLL_BARS=yes
2498   elif test "${HAVE_W32}" = "yes"; then
2499     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2500     USE_TOOLKIT_SCROLL_BARS=yes
2501   fi
2502 fi
2503
2504 dnl See if XIM is available.
2505 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2506           #include <X11/Xlib.h>
2507           #include <X11/Xresource.h>]],
2508          [[XIMProc  callback;]])],
2509          [HAVE_XIM=yes
2510          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2511          HAVE_XIM=no)
2512
2513 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2514
2515 if test "${with_xim}" != "no"; then
2516   AC_DEFINE(USE_XIM, 1,
2517             [Define to 1 if we should use XIM, if it is available.])
2518 fi
2519
2520
2521 if test "${HAVE_XIM}" != "no"; then
2522   late_CFLAGS=$CFLAGS
2523   if test "$GCC" = yes; then
2524     CFLAGS="$CFLAGS --pedantic-errors"
2525   fi
2526   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2527 #include <X11/Xlib.h>
2528 #include <X11/Xresource.h>]],
2529 [[Display *display;
2530 XrmDatabase db;
2531 char *res_name;
2532 char *res_class;
2533 XIMProc  callback;
2534 XPointer *client_data;
2535 #ifndef __GNUC__
2536 /* If we're not using GCC, it's probably not XFree86, and this is
2537    probably right, but we can't use something like --pedantic-errors.  */
2538 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2539                                            char*, XIMProc, XPointer*);
2540 #endif
2541 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2542    client_data);]])],
2543     [emacs_cv_arg6_star=yes])
2544   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2545          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2546 either XPointer or XPointer*.])dnl
2547   if test "$emacs_cv_arg6_star" = yes; then
2548     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2549   else
2550     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2551   fi
2552   CFLAGS=$late_CFLAGS
2553 fi
2554
2555 ### Start of font-backend (under any platform) section.
2556 # (nothing here yet -- this is a placeholder)
2557 ### End of font-backend (under any platform) section.
2558
2559 ### Start of font-backend (under X11) section.
2560 if test "${HAVE_X11}" = "yes"; then
2561    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2562
2563    ## Use -lXft if available, unless `--with-xft=no'.
2564    HAVE_XFT=maybe
2565     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2566       with_xft="no";
2567     fi
2568     if test "x${with_xft}" != "xno"; then
2569
2570       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2571       ## Because xftfont.c uses XRenderQueryExtension, we also
2572       ## need to link to -lXrender.
2573       HAVE_XRENDER=no
2574       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2575       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2576         OLD_CPPFLAGS="$CPPFLAGS"
2577         OLD_CFLAGS="$CFLAGS"
2578         OLD_LIBS="$LIBS"
2579         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2580         CFLAGS="$CFLAGS $XFT_CFLAGS"
2581         XFT_LIBS="-lXrender $XFT_LIBS"
2582         LIBS="$XFT_LIBS $LIBS"
2583         AC_CHECK_HEADER(X11/Xft/Xft.h,
2584           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2585
2586         if test "${HAVE_XFT}" = "yes"; then
2587           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2588             AC_SUBST(XFT_LIBS)
2589           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2590         else
2591           CPPFLAGS="$OLD_CPPFLAGS"
2592           CFLAGS="$OLD_CFLAGS"
2593           LIBS="$OLD_LIBS"
2594         fi                        # "${HAVE_XFT}" = "yes"
2595       fi                          # "$HAVE_XFT" != no
2596     fi                            # "x${with_xft}" != "xno"
2597
2598     ## We used to allow building with FreeType and without Xft.
2599     ## However, the ftx font backend driver is not in good shape.
2600     if test "$HAVE_XFT" != "yes"; then
2601        dnl For the "Does Emacs use" message at the end.
2602        HAVE_XFT=no
2603        HAVE_FREETYPE=no
2604     else
2605        dnl Strict linkers fail with
2606        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2607        dnl if -lfreetype is not specified.
2608        dnl The following is needed to set FREETYPE_LIBS.
2609        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2610                          HAVE_FREETYPE=no)
2611
2612        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2613     fi
2614
2615     HAVE_LIBOTF=no
2616     if test "${HAVE_FREETYPE}" = "yes"; then
2617       AC_DEFINE(HAVE_FREETYPE, 1,
2618                 [Define to 1 if using the freetype and fontconfig libraries.])
2619       if test "${with_libotf}" != "no"; then
2620         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2621                           HAVE_LIBOTF=no)
2622         if test "$HAVE_LIBOTF" = "yes"; then
2623           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2624           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2625                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2626                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2627           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2628             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2629                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2630           fi
2631         fi
2632       fi
2633     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2634     dnl Does the new font backend require it, or can it work without it?
2635     fi
2636
2637     HAVE_M17N_FLT=no
2638     if test "${HAVE_LIBOTF}" = yes; then
2639       if test "${with_m17n_flt}" != "no"; then
2640         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2641         if test "$HAVE_M17N_FLT" = "yes"; then
2642           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2643         fi
2644       fi
2645     fi
2646 else
2647     HAVE_XFT=no
2648     HAVE_FREETYPE=no
2649     HAVE_LIBOTF=no
2650     HAVE_M17N_FLT=no
2651 fi
2652
2653 ### End of font-backend (under X11) section.
2654
2655 AC_SUBST(FREETYPE_CFLAGS)
2656 AC_SUBST(FREETYPE_LIBS)
2657 AC_SUBST(FONTCONFIG_CFLAGS)
2658 AC_SUBST(FONTCONFIG_LIBS)
2659 AC_SUBST(LIBOTF_CFLAGS)
2660 AC_SUBST(LIBOTF_LIBS)
2661 AC_SUBST(M17N_FLT_CFLAGS)
2662 AC_SUBST(M17N_FLT_LIBS)
2663
2664 ### Use -lXpm if available, unless `--with-xpm=no'.
2665 HAVE_XPM=no
2666 LIBXPM=
2667
2668 if test "${HAVE_W32}" = "yes"; then
2669   if test "${with_xpm}" != "no"; then
2670     SAVE_CPPFLAGS="$CPPFLAGS"
2671     SAVE_LDFLAGS="$LDFLAGS"
2672     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2673     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2674     AC_CHECK_HEADER(X11/xpm.h,
2675       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2676     if test "${HAVE_XPM}" = "yes"; then
2677       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2678       AC_EGREP_CPP(no_return_alloc_pixels,
2679       [#include "X11/xpm.h"
2680 #ifndef XpmReturnAllocPixels
2681 no_return_alloc_pixels
2682 #endif
2683       ], HAVE_XPM=no, HAVE_XPM=yes)
2684
2685       if test "${HAVE_XPM}" = "yes"; then
2686         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2687         AC_MSG_RESULT(yes)
2688       else
2689         AC_MSG_RESULT(no)
2690         CPPFLAGS="$SAVE_CPPFLAGS"
2691         LDFLAGS="$SAVE_LDFLAGS"
2692       fi
2693     fi
2694   fi
2695
2696   if test "${HAVE_XPM}" = "yes"; then
2697     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2698     LIBXPM=-lXpm
2699   fi
2700 fi
2701
2702 if test "${HAVE_X11}" = "yes"; then
2703   if test "${with_xpm}" != "no"; then
2704     AC_CHECK_HEADER(X11/xpm.h,
2705       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2706     if test "${HAVE_XPM}" = "yes"; then
2707       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2708       AC_EGREP_CPP(no_return_alloc_pixels,
2709       [#include "X11/xpm.h"
2710 #ifndef XpmReturnAllocPixels
2711 no_return_alloc_pixels
2712 #endif
2713       ], HAVE_XPM=no, HAVE_XPM=yes)
2714
2715       if test "${HAVE_XPM}" = "yes"; then
2716         AC_MSG_RESULT(yes)
2717       else
2718         AC_MSG_RESULT(no)
2719       fi
2720     fi
2721   fi
2722
2723   if test "${HAVE_XPM}" = "yes"; then
2724     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2725     LIBXPM=-lXpm
2726   fi
2727 fi
2728
2729 AC_SUBST(LIBXPM)
2730
2731 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2732 HAVE_JPEG=no
2733 LIBJPEG=
2734 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2735   if test "${with_jpeg}" != "no"; then
2736     dnl Checking for jpeglib.h can lose because of a redefinition of
2737     dnl  HAVE_STDLIB_H.
2738     AC_CHECK_HEADER(jerror.h,
2739       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2740   fi
2741
2742   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2743   if test "${HAVE_JPEG}" = "yes"; then
2744     AC_DEFINE(HAVE_JPEG)
2745     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2746         [#include <jpeglib.h>
2747          version=JPEG_LIB_VERSION
2748 ],
2749         [AC_DEFINE(HAVE_JPEG)],
2750         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2751         HAVE_JPEG=no])
2752   fi
2753   if test "${HAVE_JPEG}" = "yes"; then
2754     LIBJPEG=-ljpeg
2755   fi
2756 fi
2757 AC_SUBST(LIBJPEG)
2758
2759 ### Use -lpng if available, unless `--with-png=no'.
2760 HAVE_PNG=no
2761 LIBPNG=
2762 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2763   if test "${with_png}" != "no"; then
2764     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2765     # in /usr/include/libpng.
2766     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2767     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2768       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2769     fi
2770   fi
2771
2772   if test "${HAVE_PNG}" = "yes"; then
2773     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2774     LIBPNG="-lpng -lz -lm"
2775
2776     AC_CHECK_DECL(png_longjmp,
2777       [],
2778       [AC_DEFINE(PNG_DEPSTRUCT, [],
2779          [Define to empty to suppress deprecation warnings when building
2780           with --enable-gcc-warnings and with libpng versions before 1.5,
2781           which lack png_longjmp.])],
2782       [[#ifdef HAVE_LIBPNG_PNG_H
2783         # include <libpng/png.h>
2784         #else
2785         # include <png.h>
2786         #endif
2787       ]])
2788   fi
2789 fi
2790 AC_SUBST(LIBPNG)
2791
2792 ### Use -ltiff if available, unless `--with-tiff=no'.
2793 HAVE_TIFF=no
2794 LIBTIFF=
2795 if test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2796   if test "${with_tiff}" != "no"; then
2797     AC_CHECK_HEADER(tiffio.h,
2798       [tifflibs="-lz -lm"
2799       # At least one tiff package requires the jpeg library.
2800       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2801       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2802   fi
2803
2804   if test "${HAVE_TIFF}" = "yes"; then
2805     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2806     dnl FIXME -lz -lm, as per libpng?
2807     LIBTIFF=-ltiff
2808   fi
2809 fi
2810 AC_SUBST(LIBTIFF)
2811
2812 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2813 HAVE_GIF=no
2814 LIBGIF=
2815 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
2816         || test "${HAVE_W32}" = "yes"; then
2817   AC_CHECK_HEADER(gif_lib.h,
2818 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2819 # Earlier versions can crash Emacs.
2820     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2821
2822   if test "$HAVE_GIF" = yes; then
2823     LIBGIF=-lgif
2824   elif test "$HAVE_GIF" = maybe; then
2825 # If gif_lib.h but no libgif, try libungif.
2826     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2827     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2828   fi
2829
2830   if test "${HAVE_GIF}" = "yes"; then
2831     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2832   fi
2833 fi
2834 AC_SUBST(LIBGIF)
2835
2836 dnl Check for required libraries.
2837 if test "${HAVE_X11}" = "yes"; then
2838   MISSING=""
2839   WITH_NO=""
2840   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2841     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2842   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2843     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2844   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2845     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2846   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2847     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2848   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2849     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2850
2851   if test "X${MISSING}" != X; then
2852     AC_MSG_ERROR([The following required libraries were not found:
2853     $MISSING
2854 Maybe some development libraries/packages are missing?
2855 If you don't want to link with them give
2856     $WITH_NO
2857 as options to configure])
2858   fi
2859 fi
2860
2861 ### Use -lgpm if available, unless `--with-gpm=no'.
2862 HAVE_GPM=no
2863 LIBGPM=
2864 if test "${with_gpm}" != "no"; then
2865   AC_CHECK_HEADER(gpm.h,
2866     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2867
2868   if test "${HAVE_GPM}" = "yes"; then
2869     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2870     LIBGPM=-lgpm
2871   fi
2872 fi
2873 AC_SUBST(LIBGPM)
2874
2875 dnl Check for malloc/malloc.h on darwin
2876 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2877
2878 GNUSTEP_CFLAGS=
2879 ### Use NeXTstep API to implement GUI.
2880 if test "${HAVE_NS}" = "yes"; then
2881   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2882   if test "${NS_IMPL_COCOA}" = "yes"; then
2883     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2884   fi
2885   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2886     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2887     # See also .m.o rule in Makefile.in */
2888     # FIXME: are all these flags really needed?  Document here why.  */
2889     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2890     ## Extra CFLAGS applied to src/*.m files.
2891     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2892   fi
2893   # We also have mouse menus.
2894   HAVE_MENUS=yes
2895   OTHER_FILES=ns-app
2896 fi
2897
2898 if test "${HAVE_W32}" = "yes"; then
2899   HAVE_MENUS=yes
2900 fi
2901
2902 ### Use session management (-lSM -lICE) if available
2903 HAVE_X_SM=no
2904 LIBXSM=
2905 if test "${HAVE_X11}" = "yes"; then
2906   AC_CHECK_HEADER(X11/SM/SMlib.h,
2907     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2908
2909   if test "${HAVE_X_SM}" = "yes"; then
2910     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2911     LIBXSM="-lSM -lICE"
2912     case "$LIBS" in
2913       *-lSM*) ;;
2914       *)      LIBS="$LIBXSM $LIBS" ;;
2915     esac
2916   fi
2917 fi
2918 AC_SUBST(LIBXSM)
2919
2920 ### Use libxml (-lxml2) if available
2921 HAVE_LIBXML2=no
2922 if test "${with_xml2}" != "no"; then
2923   ### I'm not sure what the version number should be, so I just guessed.
2924   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2925   if test "${HAVE_LIBXML2}" = "yes"; then
2926     LIBS="$LIBXML2_LIBS $LIBS"
2927     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2928     if test "${HAVE_LIBXML2}" = "yes"; then
2929       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2930     else
2931       LIBXML2_LIBS=""
2932       LIBXML2_CFLAGS=""
2933     fi
2934   fi
2935 fi
2936 AC_SUBST(LIBXML2_LIBS)
2937 AC_SUBST(LIBXML2_CFLAGS)
2938
2939 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2940 AC_CACHE_CHECK(whether netdb declares h_errno,
2941                emacs_cv_netdb_declares_h_errno,
2942 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2943   [[return h_errno;]])],
2944   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2945 if test $emacs_cv_netdb_declares_h_errno = yes; then
2946   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2947 fi
2948
2949 # sqrt and other floating-point functions such as fmod and frexp
2950 # are found in -lm on most systems.
2951 AC_CHECK_LIB(m, sqrt)
2952
2953 # Check for mail-locking functions in a "mail" library.  Probably this should
2954 # have the same check as for liblockfile below.
2955 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2956 if test $have_mail = yes; then
2957   LIBS_MAIL=-lmail
2958   LIBS="$LIBS_MAIL $LIBS"
2959   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2960 else
2961   LIBS_MAIL=
2962 fi
2963 dnl Debian, at least:
2964 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2965 if test $have_lockfile = yes; then
2966    LIBS_MAIL=-llockfile
2967    LIBS="$LIBS_MAIL $LIBS"
2968    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2969 else
2970 # If we have the shared liblockfile, assume we must use it for mail
2971 # locking (e.g. Debian).  If we couldn't link against liblockfile
2972 # (no liblockfile.a installed), ensure that we don't need to.
2973   dnl This works for files generally, not just executables.
2974   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2975   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2976                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2977   if test $ac_cv_prog_liblockfile = yes; then
2978     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2979 This probably means that movemail could lose mail.
2980 There may be a `development' package to install containing liblockfile.])
2981   fi
2982 fi
2983 AC_CHECK_HEADERS_ONCE(maillock.h)
2984 AC_SUBST(LIBS_MAIL)
2985
2986 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2987 ## interlock access to the mail spool.  The alternative is a lock file named
2988 ## /usr/spool/mail/$USER.lock.
2989 mail_lock=no
2990 case "$opsys" in
2991   aix4-2) mail_lock="lockf" ;;
2992
2993   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2994
2995   ## On GNU/Linux systems, both methods are used by various mail programs.
2996   ## I assume most people are using newer mailers that have heard of flock.
2997   ## Change this if you need to.
2998   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2999   ## configure gets the right answers, and that means *NOT* using flock.
3000   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3001   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3002   ## Debian maintainer hasn't provided a clean fix for Emacs.
3003   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3004   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3005   ## correct logic.  -- fx
3006   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3007   ## liblockfile is a Free Software replacement for libmail, used on
3008   ## Debian systems and elsewhere. -rfr.
3009   gnu-*)
3010     mail_lock="flock"
3011     if test $have_mail = yes || test $have_lockfile = yes; then
3012       test $ac_cv_header_maillock_h = yes && mail_lock=no
3013     fi
3014     ;;
3015 esac
3016
3017 BLESSMAIL_TARGET=
3018 case "$mail_lock" in
3019   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3020
3021   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3022
3023   *) BLESSMAIL_TARGET="need-blessmail" ;;
3024 esac
3025 AC_SUBST(BLESSMAIL_TARGET)
3026
3027
3028 AC_CHECK_FUNCS(gethostname \
3029 getrusage get_current_dir_name \
3030 lrand48 \
3031 select getpagesize setlocale \
3032 utimes getrlimit setrlimit shutdown getaddrinfo \
3033 strsignal setitimer \
3034 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3035 gai_strerror mkstemp getline getdelim fsync sync \
3036 difftime posix_memalign \
3037 getpwent endpwent getgrent endgrent \
3038 touchlock \
3039 cfmakeraw cfsetspeed copysign __executable_start)
3040
3041 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
3042 ## has a broken `rint' in some library versions including math library
3043 ## version number A.09.05.
3044 ## You can fix the math library by installing patch number PHSS_4630.
3045 ## But we can fix it more reliably for Emacs by just not using rint.
3046 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
3047 case $opsys in
3048    hpux*) : ;;
3049    *) AC_CHECK_FUNCS(random rint) ;;
3050 esac
3051
3052 dnl Cannot use AC_CHECK_FUNCS
3053 AC_CACHE_CHECK([for __builtin_unwind_init],
3054                emacs_cv_func___builtin_unwind_init,
3055 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3056                 emacs_cv_func___builtin_unwind_init=yes,
3057                 emacs_cv_func___builtin_unwind_init=no)])
3058 if test $emacs_cv_func___builtin_unwind_init = yes; then
3059   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3060             [Define to 1 if you have the `__builtin_unwind_init' function.])
3061 fi
3062
3063 AC_CHECK_HEADERS_ONCE(sys/un.h)
3064
3065 AC_FUNC_FSEEKO
3066
3067 # UNIX98 PTYs.
3068 AC_CHECK_FUNCS(grantpt)
3069
3070 # PTY-related GNU extensions.
3071 AC_CHECK_FUNCS(getpt posix_openpt)
3072
3073 # Check this now, so that we will NOT find the above functions in ncurses.
3074 # That is because we have not set up to link ncurses in lib-src.
3075 # It's better to believe a function is not available
3076 # than to expect to find it in ncurses.
3077 # Also we need tputs and friends to be able to build at all.
3078 AC_MSG_CHECKING([for library containing tputs])
3079 # Run a test program that contains a call to tputs, a call that is
3080 # never executed.  This tests whether a pre-'main' dynamic linker
3081 # works with the library.  It's too much trouble to actually call
3082 # tputs in the test program, due to portability hassles.  When
3083 # cross-compiling, assume the test program will run if it links.
3084 AC_DEFUN([tputs_link_source], [
3085   AC_LANG_SOURCE(
3086      [[extern void tputs (const char *, int, int (*)(int));
3087        int main (int argc, char **argv)
3088        {
3089           if (argc == 10000)
3090             tputs (argv[0], 0, 0);
3091           return 0;
3092        }]])
3093 ])
3094 # Maybe curses should be tried earlier?
3095 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3096 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3097   OLIBS=$LIBS
3098   if test -z "$tputs_library"; then
3099     LIBS_TERMCAP=
3100     msg='none required'
3101   else
3102     LIBS_TERMCAP=-l$tputs_library
3103     msg=$LIBS_TERMCAP
3104     LIBS="$LIBS_TERMCAP $LIBS"
3105   fi
3106   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3107     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3108   LIBS=$OLIBS
3109   if test "X$msg" != Xno; then
3110     break
3111   fi
3112 done
3113 AC_MSG_RESULT([$msg])
3114 if test "X$msg" = Xno; then
3115   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3116 The following libraries were tried (in order):
3117   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3118 Please try installing whichever of these libraries is most appropriate
3119 for your system, together with its header files.
3120 For example, a libncurses-dev(el) or similar package.])
3121 fi
3122
3123 ## Use termcap instead of terminfo?
3124 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3125 TERMINFO=yes
3126 ## FIXME?  In the cases below where we unconditionally set
3127 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3128 ## if that was found above to have tputs.
3129 ## Should we use the gnu* logic everywhere?
3130 case "$opsys" in
3131   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3132   ##  The ncurses library has been moved out of the System framework in
3133   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3134   ##  option to use it.
3135   darwin) LIBS_TERMCAP="-lncurses" ;;
3136
3137   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3138
3139   freebsd)
3140     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3141     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3142     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3143 [[#if __FreeBSD_version < 400000
3144 fail;
3145 #endif
3146 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3147
3148     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3149
3150     if test $emacs_cv_freebsd_terminfo = yes; then
3151       LIBS_TERMCAP="-lncurses"
3152     else
3153       TERMINFO=no
3154       LIBS_TERMCAP="-ltermcap"
3155     fi
3156     ;;
3157
3158   netbsd)
3159     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3160       TERMINFO=no
3161       LIBS_TERMCAP="-ltermcap"
3162     fi
3163     ;;
3164
3165   openbsd) LIBS_TERMCAP="-lncurses" ;;
3166
3167   ## hpux: Make sure we get select from libc rather than from libcurses
3168   ##  because libcurses on HPUX 10.10 has a broken version of select.
3169   ##  We used to use -lc -lcurses, but this may be cleaner.
3170   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3171   # set that way, now it uses the default).  Isn't this a contradiction?
3172   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3173
3174 esac
3175
3176 TERMCAP_OBJ=tparam.o
3177 if test $TERMINFO = yes; then
3178   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3179   TERMCAP_OBJ=terminfo.o
3180 fi
3181 AC_SUBST(LIBS_TERMCAP)
3182 AC_SUBST(TERMCAP_OBJ)
3183
3184
3185 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3186 # On Darwin, res_init appears not to be useful: see bug#562 and
3187 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3188 resolv=no
3189
3190 if test $opsys != darwin; then
3191
3192   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3193 #include <arpa/nameser.h>
3194 #include <resolv.h>]],
3195     [[return res_init();]])],
3196     have_res_init=yes, have_res_init=no)
3197   if test "$have_res_init" = no; then
3198     OLIBS="$LIBS"
3199     LIBS="$LIBS -lresolv"
3200     AC_MSG_CHECKING(for res_init with -lresolv)
3201     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3202 #include <arpa/nameser.h>
3203 #include <resolv.h>]],
3204       [[return res_init();]])],
3205       have_res_init=yes, have_res_init=no)
3206     AC_MSG_RESULT($have_res_init)
3207     if test "$have_res_init" = yes ; then
3208       resolv=yes
3209     fi
3210     LIBS="$OLIBS"
3211   fi
3212
3213   if test "$have_res_init" = yes; then
3214     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3215   fi
3216 fi                              dnl !darwin
3217
3218 # Do we need the Hesiod library to provide the support routines?
3219 dnl FIXME?  Should we be skipping this on Darwin too?
3220 LIBHESIOD=
3221 if test "$with_hesiod" != no ; then
3222   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3223   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3224      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3225                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3226   if test "$resolv" = yes ; then
3227     RESOLVLIB=-lresolv
3228   else
3229     RESOLVLIB=
3230   fi
3231   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3232         hesiod=yes, :, $RESOLVLIB)])
3233
3234   if test x"$hesiod" = xyes; then
3235     AC_DEFINE(HAVE_LIBHESIOD, 1,
3236               [Define to 1 if you have the hesiod library (-lhesiod).])
3237     LIBHESIOD=-lhesiod
3238   fi
3239 fi
3240 AC_SUBST(LIBHESIOD)
3241
3242 # Do we need libresolv (due to res_init or Hesiod)?
3243 if test "$resolv" = yes && test $opsys != darwin; then
3244   AC_DEFINE(HAVE_LIBRESOLV, 1,
3245             [Define to 1 if you have the resolv library (-lresolv).])
3246   LIBRESOLV=-lresolv
3247 else
3248   LIBRESOLV=
3249 fi
3250 AC_SUBST(LIBRESOLV)
3251
3252 # These tell us which Kerberos-related libraries to use.
3253 COM_ERRLIB=
3254 CRYPTOLIB=
3255 KRB5LIB=
3256 DESLIB=
3257 KRB4LIB=
3258
3259 if test "${with_kerberos}" != no; then
3260   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3261   if test $have_com_err = yes; then
3262     COM_ERRLIB=-lcom_err
3263     LIBS="$COM_ERRLIB $LIBS"
3264     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3265   fi
3266   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3267   if test $have_crypto = yes; then
3268     CRYPTOLIB=-lcrypto
3269     LIBS="$CRYPTOLIB $LIBS"
3270     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3271   fi
3272   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3273   if test $have_k5crypto = yes; then
3274     CRYPTOLIB=-lk5crypto
3275     LIBS="$CRYPTOLIB $LIBS"
3276     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3277   fi
3278   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3279   if test $have_krb5=yes; then
3280     KRB5LIB=-lkrb5
3281     LIBS="$KRB5LIB $LIBS"
3282     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3283   fi
3284   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3285   if test "${with_kerberos5}" = no; then
3286     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3287     if test $have_des425 = yes; then
3288       DESLIB=-ldes425
3289       LIBS="$DESLIB $LIBS"
3290       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3291     else
3292       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3293       if test $have_des = yes; then
3294         DESLIB=-ldes
3295         LIBS="$DESLIB $LIBS"
3296         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3297       fi
3298     fi
3299     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3300     if test $have_krb4 = yes; then
3301       KRB4LIB=-lkrb4
3302       LIBS="$KRB4LIB $LIBS"
3303       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3304     else
3305       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3306       if test $have_krb = yes; then
3307         KRB4LIB=-lkrb
3308         LIBS="$KRB4LIB $LIBS"
3309         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3310       fi
3311     fi
3312   fi
3313
3314   if test "${with_kerberos5}" != no; then
3315     AC_CHECK_HEADERS(krb5.h,
3316       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3317                         [#include <krb5.h>])])
3318   else
3319     AC_CHECK_HEADERS(des.h,,
3320                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3321                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3322     AC_CHECK_HEADERS(krb.h,,
3323                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3324                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3325   fi
3326   AC_CHECK_HEADERS(com_err.h)
3327 fi
3328
3329 AC_SUBST(COM_ERRLIB)
3330 AC_SUBST(CRYPTOLIB)
3331 AC_SUBST(KRB5LIB)
3332 AC_SUBST(DESLIB)
3333 AC_SUBST(KRB4LIB)
3334
3335 AC_CHECK_FUNCS_ONCE(tzset)
3336 AC_MSG_CHECKING(whether localtime caches TZ)
3337 AC_CACHE_VAL(emacs_cv_localtime_cache,
3338 [if test x$ac_cv_func_tzset = xyes; then
3339 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3340 char TZ_GMT0[] = "TZ=GMT0";
3341 char TZ_PST8[] = "TZ=PST8";
3342 main()
3343 {
3344   time_t now = time ((time_t *) 0);
3345   int hour_GMT0, hour_unset;
3346   if (putenv (TZ_GMT0) != 0)
3347     exit (1);
3348   hour_GMT0 = localtime (&now)->tm_hour;
3349   unsetenv("TZ");
3350   hour_unset = localtime (&now)->tm_hour;
3351   if (putenv (TZ_PST8) != 0)
3352     exit (1);
3353   if (localtime (&now)->tm_hour == hour_GMT0)
3354     exit (1);
3355   unsetenv("TZ");
3356   if (localtime (&now)->tm_hour != hour_unset)
3357     exit (1);
3358   exit (0);
3359 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3360 [# If we have tzset, assume the worst when cross-compiling.
3361 emacs_cv_localtime_cache=yes])
3362 else
3363         # If we lack tzset, report that localtime does not cache TZ,
3364         # since we can't invalidate the cache if we don't have tzset.
3365         emacs_cv_localtime_cache=no
3366 fi])dnl
3367 AC_MSG_RESULT($emacs_cv_localtime_cache)
3368 if test $emacs_cv_localtime_cache = yes; then
3369   AC_DEFINE(LOCALTIME_CACHE, 1,
3370             [Define to 1 if localtime caches TZ.])
3371 fi
3372
3373 ok_so_far=yes
3374 AC_CHECK_FUNC(socket, , ok_so_far=no)
3375 if test $ok_so_far = yes; then
3376   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3377 fi
3378 if test $ok_so_far = yes; then
3379   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3380 fi
3381 if test $ok_so_far = yes; then
3382 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3383   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3384             [Define to 1 if you have inet sockets.])
3385 fi
3386
3387 if test -f /usr/lpp/X11/bin/smt.exp; then
3388   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3389             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3390 fi
3391
3392 AC_MSG_CHECKING(whether system supports dynamic ptys)
3393 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3394   AC_MSG_RESULT(yes)
3395   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3396 else
3397   AC_MSG_RESULT(no)
3398 fi
3399
3400 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3401 dnl This can be removed once we assume Autoconf 2.70.
3402 case $canonical in
3403   *-solaris2.4 | *-solaris2.4.*)
3404     dnl Disable the Autoconf-generated vfork test.
3405     : ${ac_cv_func_vfork_works=no};;
3406 esac
3407
3408 AC_FUNC_FORK
3409
3410 AC_CHECK_FUNCS(snprintf)
3411
3412 dnl Adapted from Haible's version.
3413 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3414   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3415     [[char* cs = nl_langinfo(CODESET);]])],
3416     emacs_cv_langinfo_codeset=yes,
3417     emacs_cv_langinfo_codeset=no)
3418   ])
3419 if test $emacs_cv_langinfo_codeset = yes; then
3420   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3421     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3422 fi
3423
3424 AC_TYPE_MBSTATE_T
3425
3426 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3427   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3428                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3429 if test "$emacs_cv_c_restrict_arr" = yes; then
3430   AC_DEFINE(__restrict_arr, __restrict,
3431     [Define to compiler's equivalent of C99 restrict keyword in array
3432      declarations.  Define as empty for no equivalent.])
3433 fi
3434
3435 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3436 dnl how the tty code is related to POSIX and/or other versions of termios.
3437 dnl The following looks like a useful start.
3438 dnl
3439 dnl AC_SYS_POSIX_TERMIOS
3440 dnl if test $ac_cv_sys_posix_termios = yes; then
3441 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3442 dnl                                and macros for terminal control.])
3443 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3444 dnl fi
3445
3446 dnl Turned on June 1996 supposing nobody will mind it.
3447 AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3448   in the full name stands for the login id.])
3449
3450 dnl Every platform that uses configure (ie every non-MS platform)
3451 dnl supports this.  There is a create-lockfiles option you can
3452 dnl customize if you do not want the lock files to be written.
3453 dnl So it is not clear that this #define still needs to exist.
3454 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3455   so that Emacs can tell instantly when you try to modify a file that
3456   someone else has modified in his/her Emacs.])
3457
3458 dnl Everybody supports this, except MS.
3459 dnl Seems like the kind of thing we should be testing for, though.
3460 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3461 AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3462
3463 dnl Everybody supports this, except MS-DOS.
3464 dnl Seems like the kind of thing we should be testing for, though.
3465 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3466 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3467   4.2-compatible sockets.])
3468
3469 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3470
3471 AC_DEFINE(NULL_DEVICE, ["/dev/null"], [Name of the file to open to get
3472   a null file, or a data sink.])
3473
3474 AC_DEFINE(SEPCHAR, [':'], [Character that separates PATH elements.])
3475
3476 dnl Everybody supports this, except MS-DOS.
3477 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3478
3479 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3480
3481
3482 AC_DEFINE(DIRECTORY_SEP, ['/'],
3483   [Character that separates directories in a file name.])
3484
3485 dnl Only used on MS platforms.
3486 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3487
3488 AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3489   [Returns true if character is a device separator.])
3490
3491 AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3492   [Returns true if character is a directory separator.])
3493
3494 dnl On MS, this also accepts IS_DEVICE_SEP.
3495 AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3496   [Returns true if character is any form of separator.])
3497
3498
3499 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3500
3501 case $opsys in
3502   aix4-2)
3503     dnl Unfortunately without libXmu we cannot support EditRes.
3504     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3505       AC_DEFINE(NO_EDITRES, 1)
3506     fi
3507     ;;
3508
3509   hpux*)
3510     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3511     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3512     AC_DEFINE(NO_EDITRES, 1)
3513     ;;
3514 esac
3515
3516
3517 case $opsys in
3518   irix6-5 | sol2* | unixware )
3519     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3520     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3521     dnl need the constant to dimension an array.  So wire in the appropriate
3522     dnl value here.
3523     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3524     ;;
3525 esac
3526
3527 emacs_broken_SIGIO=no
3528
3529 case $opsys in
3530   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3531   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3532   hpux* | irix6-5 | openbsd | sol2* | unixware )
3533     emacs_broken_SIGIO=yes
3534     ;;
3535
3536   aix4-2)
3537     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3538     dnl the way this system works, libc functions that return malloced
3539     dnl memory use the libc malloc implementation. Calling xfree or
3540     dnl xrealloc on the results of such functions results in a crash.
3541     dnl
3542     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3543     dnl but that does not currently work on this system.
3544     dnl
3545     dnl It is possible to completely override the malloc implementation on
3546     dnl AIX, but that involves putting the malloc functions in a shared
3547     dnl library and setting the MALLOCTYPE environment variable to point to
3548     dnl that shared library.
3549     dnl
3550     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3551     dnl to avoid a crash just use the Emacs implementation for that function.
3552     dnl
3553     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3554     dnl of this file, so that we do not check for get_current_dir_name
3555     dnl on AIX.  But that might be fragile if something else ends
3556     dnl up testing for get_current_dir_name as a dependency.
3557     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3558       get_current_dir_name should not be used.])
3559     ;;
3560
3561   freebsd)
3562     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3563     dnl writes/reads on a PTY, read(2) returns bogus data:
3564     dnl
3565     dnl write(2)  1022 bytes
3566     dnl write(2)   954 bytes, get EAGAIN
3567     dnl read(2)   1024 bytes in process_read_output
3568     dnl read(2)     11 bytes in process_read_output
3569     dnl
3570     dnl That is, read(2) returns more bytes than have ever been written
3571     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3572     dnl successfully after processing (for example with CRs added if the
3573     dnl terminal is set up that way which it is here).  The same bytes will
3574     dnl be seen again in a later read(2), without the CRs.
3575     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3576       work around an issue when reading from a PTY.])
3577     ;;
3578 esac
3579
3580 case $opsys in
3581   gnu-* | sol2-10 )
3582     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3583     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3584   ;;
3585 esac
3586
3587 case $opsys in
3588   darwin | freebsd | netbsd | openbsd )
3589     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3590       close a pty to make it a controlling terminal (it is already a
3591       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3592   ;;
3593 esac
3594
3595 dnl FIXME Surely we can test for this rather than hard-code it.
3596 case $opsys in
3597   netbsd | openbsd) sound_device="/dev/audio" ;;
3598   *) sound_device="/dev/dsp" ;;
3599 esac
3600
3601 dnl Used in sound.c
3602 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3603   [Name of the default sound device.])
3604
3605
3606 dnl Emacs can read input using SIGIO and buffering characters itself,
3607 dnl or using CBREAK mode and making C-g cause SIGINT.
3608 dnl The choice is controlled by the variable interrupt_input.
3609 dnl
3610 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3611 dnl
3612 dnl Emacs uses the presence of the USABLE_SIGIO macro
3613 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3614 dnl INTERRUPT_INPUT to decide whether to use it by default.
3615 dnl
3616 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3617 dnl CBREAK mode has two disadvantages
3618 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3619 dnl I hear that in system V this problem does not exist.
3620 dnl 2) Control-G causes output to be discarded.
3621 dnl I do not know whether this can be fixed in system V.
3622 dnl
3623 dnl Another method of doing input is planned but not implemented.
3624 dnl It would have Emacs fork off a separate process
3625 dnl to read the input and send it to the true Emacs process
3626 dnl through a pipe.
3627 case $opsys in
3628   darwin | gnu-linux | gnu-kfreebsd )
3629     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3630   ;;
3631 esac
3632
3633
3634 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3635 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3636 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3637 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3638 dnl taking float or double parameters.
3639 case $opsys in
3640   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3641     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3642       file defines `NeedWidePrototypes' as `NO'.])
3643   ;;
3644 esac
3645
3646
3647 dnl Used in process.c, this must be a loop, even if it only runs once.
3648 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3649 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3650 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3651 dnl trying suffixes 0-16.
3652 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3653   first PTY, if PTYs are supported.])
3654 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3655 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3656   end of a PTY, if non-standard.])
3657 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3658   end of a PTY, if non-standard.])
3659
3660 case $opsys in
3661   aix4-2 )
3662     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3663     dnl You allocate a pty by opening /dev/ptc to get the master side.
3664     dnl To get the name of the slave side, you just ttyname() the master side.
3665     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3666     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3667     ;;
3668
3669   cygwin )
3670     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3671     dnl multi-line AC_DEFINEs are hard. :(
3672     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (0)])
3673     AC_DEFINE(PTY_NAME_SPRINTF, [])
3674     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3675     ;;
3676
3677   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
3678   darwin )
3679     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3680     dnl Not used, because PTY_ITERATION is defined.
3681     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3682     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3683     dnl But we don't have to block SIGCHLD because it is blocked in the
3684     dnl implementation of grantpt.
3685     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3686     AC_DEFINE(PTY_NAME_SPRINTF, [])
3687     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3688     ;;
3689
3690   gnu | openbsd )
3691     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3692     ;;
3693
3694   gnu-linux | gnu-kfreebsd | freebsd | netbsd )
3695     dnl if HAVE_GRANTPT
3696     if test "x$ac_cv_func_grantpt" = xyes; then
3697       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3698       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3699       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3700       dnl to prevent sigchld_handler from intercepting the child's death.
3701       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3702       dnl if HAVE_POSIX_OPENPT
3703       if test "x$ac_cv_func_posix_openpt" = xyes; then
3704         AC_DEFINE(PTY_OPEN, [fd = posix_openpt (O_RDWR | O_NOCTTY)])
3705         AC_DEFINE(PTY_NAME_SPRINTF, [])
3706       dnl if HAVE_GETPT
3707       elif test "x$ac_cv_func_getpt" = xyes; then
3708         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3709         AC_DEFINE(PTY_NAME_SPRINTF, [])
3710       else
3711         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3712       fi
3713     else
3714       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3715     fi
3716     ;;
3717
3718   hpux*)
3719     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3720     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3721     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3722     ;;
3723
3724   irix6-5 )
3725     dnl It looks like this cannot be right, because it is not a loop.
3726     dnl However, process.c actually does this:
3727     dnl # ifndef __sgi
3728     dnl   continue;
3729     dnl # else
3730     dnl   return -1;
3731     dnl # endif
3732     dnl which presumably makes it OK, since irix == sgi (?).
3733     dnl FIXME it seems like this special treatment is unnecessary?
3734     dnl Why can't irix use a single-trip loop like eg cygwin?
3735     AC_DEFINE(PTY_ITERATION, [])
3736     dnl Not used, because PTY_ITERATION is defined.
3737     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
3738     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
3739     dnl No need to get the pty name at all.
3740     AC_DEFINE(PTY_NAME_SPRINTF, [])
3741     dnl No need to use sprintf to get the tty name--we get that from _getpty.
3742     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3743     ;;
3744
3745   sol2* )
3746     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
3747     dnl from intercepting that death.  If any child but grantpt's should die
3748     dnl within, it should be caught after sigrelse(2).
3749     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3750     ;;
3751
3752   unixware )
3753     dnl Comments are as per sol2*.
3754     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3755     ;;
3756 esac
3757
3758
3759 case $opsys in
3760   sol2* | unixware )
3761     dnl This change means that we don't loop through allocate_pty too
3762     dnl many times in the (rare) event of a failure.
3763     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
3764     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3765     dnl Push various streams modules onto a PTY channel.  Used in process.c.
3766     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
3767     ;;
3768 esac
3769
3770
3771 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
3772 "typing" a signal character on the pty.])
3773
3774 case $opsys in
3775   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
3776   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
3777   aix4-2 | cygwin | gnu | irix6-5 | freebsd | netbsd | openbsd | darwin )
3778     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3779     ;;
3780
3781   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
3782   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
3783   gnu-linux | gnu-kfreebsd )
3784
3785     AC_MSG_CHECKING([for signals via characters])
3786     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3787 #include <linux/version.h>
3788 #if LINUX_VERSION_CODE < 0x20400
3789 # error "Linux version too old"
3790 #endif
3791       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
3792
3793     AC_MSG_RESULT([$emacs_signals_via_chars])
3794     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
3795     ;;
3796 esac
3797
3798
3799 dnl Used in vm-limit.c
3800 AH_TEMPLATE(DATA_START, [Address of the start of the data segment.])
3801 dnl Used in lisp.h, emacs.c, mem-limits.h
3802 dnl NEWS.18 describes this as "a number which contains
3803 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
3804 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
3805 stored in a Lisp_Object.])
3806 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
3807
3808 case $opsys in
3809   gnu)
3810     dnl libc defines data_start.
3811     AC_DEFINE(DATA_START, [({ extern int data_start; (char *) &data_start; })])
3812     ;;
3813
3814   hpux*)
3815     dnl The data segment on this machine always starts at address 0x40000000.
3816     AC_DEFINE(DATA_START, [0x40000000])
3817     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
3818     ;;
3819   irix6-5)
3820     AC_DEFINE(DATA_START, [0x10000000])
3821     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
3822     ;;
3823 esac
3824
3825
3826 AH_TEMPLATE(TAB3, [Undocumented.])
3827
3828 case $opsys in
3829   darwin) AC_DEFINE(TAB3, OXTABS) ;;
3830
3831   gnu | freebsd | netbsd | openbsd )
3832     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
3833     AC_DEFINE(TAB3, OXTABS)
3834     ;;
3835
3836   gnu-linux | gnu-kfreebsd )
3837     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3838 #ifndef __ia64__
3839 # error "not ia64"
3840 #endif
3841       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
3842         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
3843         [Mark a secondary stack, like the register stack on the ia64.]), [])
3844     ;;
3845
3846   hpux*)
3847     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
3848       run_time_remap; for HPUX.])
3849     ;;
3850 esac
3851
3852
3853 dnl This won't be used automatically yet.  We also need to know, at least,
3854 dnl that the stack is continuous.
3855 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
3856   registers relevant for conservative garbage collection in the jmp_buf.])
3857
3858
3859 case $opsys in
3860   dnl Not all the architectures are tested, but there are Debian packages
3861   dnl for SCM and/or Guile on them, so the technique must work.  See also
3862   dnl comments in alloc.c concerning setjmp and gcc.
3863   dnl Fixme: it's probably safe to just use the GCC conditional below.
3864   gnu-linux | gnu-kfreebsd )
3865     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3866 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
3867   || defined __alpha__ || defined __mips__ || defined __s390__ \
3868   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
3869   || defined __ia64__ || defined __sh__
3870 /* ok */
3871 #else
3872 # error "setjmp not known to work on this arch"
3873 #endif
3874     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
3875     ;;
3876 esac
3877
3878
3879 if test x$GCC = xyes; then
3880    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
3881    AC_DEFINE(GC_SETJMP_WORKS, 1)
3882 else
3883   case $opsys in
3884     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
3885     freebsd | netbsd | openbsd | irix6-5 | sol2* )
3886       AC_DEFINE(GC_SETJMP_WORKS, 1)
3887       ;;
3888   esac
3889 fi                              dnl GCC?
3890
3891 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
3892   [AC_LINK_IFELSE(
3893      [AC_LANG_PROGRAM(
3894        [[#include <setjmp.h>
3895        ]],
3896        [[jmp_buf j;
3897          if (! _setjmp (j))
3898            _longjmp (j, 1);]])],
3899      [emacs_cv_func__setjmp=yes],
3900      [emacs_cv_func__setjmp=no])])
3901 if test $emacs_cv_func__setjmp = yes; then
3902   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
3903 else
3904   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
3905     [AC_LINK_IFELSE(
3906        [AC_LANG_PROGRAM(
3907          [[#include <setjmp.h>
3908          ]],
3909          [[sigjmp_buf j;
3910            if (! sigsetjmp (j, 1))
3911              siglongjmp (j, 1);]])],
3912        [emacs_cv_func_sigsetjmp=yes],
3913        [emacs_cv_func_sigsetjmp=no])])
3914   if test $emacs_cv_func_sigsetjmp = yes; then
3915     AC_DEFINE([HAVE_SIGSETJMP], 1,
3916       [Define to 1 if sigsetjmp and siglongjmp work.
3917        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
3918   fi
3919 fi
3920
3921 case $opsys in
3922   sol2* | unixware )
3923     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
3924     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
3925     dnl and this is all we need.
3926     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
3927     ;;
3928 esac
3929
3930
3931 case $opsys in
3932   hpux* | sol2* )
3933     dnl Used in xfaces.c.
3934     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
3935       some systems, where it requires time.h.])
3936     ;;
3937 esac
3938
3939
3940 dnl Define symbols to identify the version of Unix this is.
3941 dnl Define all the symbols that apply correctly.
3942 AH_TEMPLATE(BSD_SYSTEM, [Define if the system is compatible with BSD 4.2.])
3943 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
3944 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
3945 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
3946 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
3947 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
3948
3949 case $opsys in
3950   aix4-2)
3951     AC_DEFINE(USG, [])
3952     AC_DEFINE(USG5, [])
3953     dnl This symbol should be defined on AIX Version 3  ???????
3954     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3955 #ifndef _AIX
3956 # error "_AIX not defined"
3957 #endif
3958     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
3959     ;;
3960
3961   cygwin)
3962     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
3963     ;;
3964
3965   darwin)
3966     dnl BSD4_3 and BSD4_4 are already defined in sys/param.h.
3967     AC_DEFINE(BSD_SYSTEM, [])
3968     dnl More specific than the above two.  We cannot use __APPLE__ as this
3969     dnl may not be defined on non-OSX Darwin, and we cannot define DARWIN
3970     dnl here because Panther and lower CoreFoundation.h uses DARWIN to
3971     dnl distinguish OS X from pure Darwin.
3972     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
3973     ;;
3974
3975   freebsd)
3976     dnl Hack to avoid calling AC_PREPROC_IFELSE multiple times.
3977     dnl Would not be needed with autoconf >= 2.67, where the
3978     dnl preprocessed output is accessible in "conftest.i".
3979     AC_DEFINE(BSD_SYSTEM_AHB, 1, [Define if AH_BOTTOM should change BSD_SYSTEM.])
3980     ;;
3981
3982   gnu | netbsd | openbsd )
3983     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
3984 #ifndef BSD_SYSTEM
3985 # error "BSD_SYSTEM not defined"
3986 #endif
3987     ]], [[]])], [], AC_DEFINE(BSD_SYSTEM, 43) )
3988     ;;
3989
3990   gnu-linux | gnu-kfreebsd )
3991     AC_DEFINE(USG, [])
3992     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
3993     ;;
3994
3995   hpux*)
3996     AC_DEFINE(USG, [])
3997     AC_DEFINE(USG5, [])
3998     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
3999     ;;
4000
4001   irix6-5)
4002     AC_DEFINE(USG, [])
4003     AC_DEFINE(USG5, [])
4004     AC_DEFINE(USG5_4, [])
4005     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4006     ;;
4007
4008   sol2*)
4009     AC_DEFINE(USG, [])
4010     AC_DEFINE(USG5, [])
4011     AC_DEFINE(USG5_4, [])
4012     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4013     ;;
4014
4015   unixware)
4016     AC_DEFINE(USG, [])
4017     AC_DEFINE(USG5, [])
4018     AC_DEFINE(USG5_4, [])
4019     ;;
4020 esac
4021
4022 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4023   [case $opsys in
4024      aix4-2)
4025        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4026        emacs_cv_usable_FIONREAD=no
4027        ;;
4028
4029      *)
4030        AC_COMPILE_IFELSE(
4031          [AC_LANG_PROGRAM([[#include <sys/types.h>
4032                             #include <sys/ioctl.h>
4033                             #ifdef USG5_4
4034                             # include <sys/filio.h>
4035                             #endif
4036                           ]],
4037                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4038          [emacs_cv_usable_FIONREAD=yes],
4039          [emacs_cv_usable_FIONREAD=no])
4040        ;;
4041    esac])
4042 if test $emacs_cv_usable_FIONREAD = yes; then
4043   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4044
4045   if test $emacs_broken_SIGIO = no; then
4046     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4047       [AC_COMPILE_IFELSE(
4048          [AC_LANG_PROGRAM([[#include <fcntl.h>
4049                             #include <signal.h>
4050                           ]],
4051                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4052          [emacs_cv_usable_SIGIO=yes],
4053          [emacs_cv_usable_SIGIO=no])],
4054       [emacs_cv_usable_SIGIO=yes],
4055       [emacs_cv_usable_SIGIO=no])
4056     if test $emacs_cv_usable_SIGIO = yes; then
4057       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4058     fi
4059   fi
4060 fi
4061
4062
4063 case $opsys in
4064   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
4065   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
4066   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
4067   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
4068   cygwin)
4069     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4070       G_SLICE environment variable to "always-malloc" at startup, if
4071       using GTK.])
4072     ;;
4073
4074   hpux11)
4075     dnl It works to open the pty's tty in the parent (Emacs), then
4076     dnl close and reopen it in the child.
4077     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4078       works to open a pty's tty in the parent process, then close and
4079       reopen it in the child.])
4080     ;;
4081
4082   irix6-5)
4083     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4084       use VSUSP instead of VSWTCH.])
4085     ;;
4086
4087   sol2-10)
4088     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4089       on Solaris.])
4090     ;;
4091 esac
4092
4093 # Set up the CFLAGS for real compilation, so we can substitute it.
4094 CFLAGS="$REAL_CFLAGS"
4095 CPPFLAGS="$REAL_CPPFLAGS"
4096
4097 ## Hack to detect a buggy GCC version.
4098 if test "x$GCC" = xyes \
4099    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4100    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4101    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4102    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4103 fi
4104
4105 version=$PACKAGE_VERSION
4106
4107 copyright="Copyright (C) 2013 Free Software Foundation, Inc."
4108 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4109   [Short copyright string for this version of Emacs.])
4110 AC_SUBST(copyright)
4111
4112 ### Specify what sort of things we'll be editing into Makefile and config.h.
4113 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4114 AC_SUBST(version)
4115 AC_SUBST(configuration)
4116 ## Unused?
4117 AC_SUBST(canonical)
4118 AC_SUBST(srcdir)
4119 AC_SUBST(prefix)
4120 AC_SUBST(exec_prefix)
4121 AC_SUBST(bindir)
4122 AC_SUBST(datadir)
4123 AC_SUBST(sharedstatedir)
4124 AC_SUBST(libexecdir)
4125 AC_SUBST(mandir)
4126 AC_SUBST(infodir)
4127 AC_SUBST(lispdir)
4128 AC_SUBST(leimdir)
4129 AC_SUBST(standardlisppath)
4130 AC_SUBST(locallisppath)
4131 AC_SUBST(lisppath)
4132 AC_SUBST(x_default_search_path)
4133 AC_SUBST(etcdir)
4134 AC_SUBST(archlibdir)
4135 AC_SUBST(docdir)
4136 AC_SUBST(bitmapdir)
4137 AC_SUBST(gamedir)
4138 AC_SUBST(gameuser)
4139 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4140 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4141 ## end of LIBX_BASE, but nothing ever set it.
4142 AC_SUBST(LD_SWITCH_X_SITE)
4143 AC_SUBST(C_SWITCH_X_SITE)
4144 AC_SUBST(GNUSTEP_CFLAGS)
4145 AC_SUBST(CFLAGS)
4146 ## Used in lwlib/Makefile.in.
4147 AC_SUBST(X_TOOLKIT_TYPE)
4148 AC_SUBST(ns_appdir)
4149 AC_SUBST(ns_appbindir)
4150 AC_SUBST(ns_appresdir)
4151 AC_SUBST(ns_appsrc)
4152 AC_SUBST(GNU_OBJC_CFLAGS)
4153 AC_SUBST(OTHER_FILES)
4154
4155 if test -n "${term_header}"; then
4156     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4157         [Define to the header for the built-in window system.])
4158 fi
4159
4160 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4161                    [Define to the canonical Emacs configuration name.])
4162 dnl Replace any embedded " characters (bug#13274).
4163 emacs_config_options=`echo "$emacs_config_options " | sed -e 's/--no-create //' -e 's/--no-recursion //' -e 's/ *$//' -e "s/\"/'/g"`
4164 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4165                    [Define to the options passed to configure.])
4166 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4167   define this to include extra configuration information.])
4168
4169 XMENU_OBJ=
4170 XOBJ=
4171 FONT_OBJ=
4172 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4173   AC_DEFINE(HAVE_X_WINDOWS, 1,
4174             [Define to 1 if you want to use the X window system.])
4175   XMENU_OBJ=xmenu.o
4176   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o xgselect.o"
4177   FONT_OBJ=xfont.o
4178   if test "$HAVE_XFT" = "yes"; then
4179     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4180   elif test "$HAVE_FREETYPE" = "yes"; then
4181     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4182   fi
4183   AC_SUBST(FONT_OBJ)
4184 fi
4185 AC_SUBST(XMENU_OBJ)
4186 AC_SUBST(XOBJ)
4187 AC_SUBST(FONT_OBJ)
4188
4189 WIDGET_OBJ=
4190 MOTIF_LIBW=
4191 if test "${USE_X_TOOLKIT}" != "none" ; then
4192   WIDGET_OBJ=widget.o
4193   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4194   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4195     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4196   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4197     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4198     MOTIF_LIBW=-lXm
4199     case "$opsys" in
4200       gnu-linux)
4201         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4202         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4203         ;;
4204
4205       unixware)
4206         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4207         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4208         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4209         ;;
4210
4211       aix4-2)
4212         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4213         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4214         ;;
4215     esac
4216     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4217   fi
4218 fi
4219 AC_SUBST(WIDGET_OBJ)
4220
4221 TOOLKIT_LIBW=
4222 case "$USE_X_TOOLKIT" in
4223   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4224   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4225   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS -lXcomposite" ;;
4226 esac
4227 AC_SUBST(TOOLKIT_LIBW)
4228
4229 if test "$USE_X_TOOLKIT" = "none"; then
4230   LIBXT_OTHER="\$(LIBXSM)"
4231   OLDXMENU_TARGET="really-oldXMenu"
4232 else
4233   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4234   OLDXMENU_TARGET="really-lwlib"
4235 fi
4236 AC_SUBST(LIBXT_OTHER)
4237
4238 ## The X Menu stuff is present in the X10 distribution, but missing
4239 ## from X11.  If we have X10, just use the installed library;
4240 ## otherwise, use our own copy.
4241 if test "${HAVE_X11}" = "yes" ; then
4242   AC_DEFINE(HAVE_X11, 1,
4243             [Define to 1 if you want to use version 11 of X windows.
4244              Otherwise, Emacs expects to use version 10.])
4245
4246   if test "$USE_X_TOOLKIT" = "none"; then
4247     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4248   else
4249     OLDXMENU="\${lwlibdir}/liblw.a"
4250   fi
4251   LIBXMENU="\$(OLDXMENU)"
4252   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4253   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4254 else
4255   ## For a syntactically valid Makefile; not actually used for anything.
4256   ## See comments in src/Makefile.in.
4257   OLDXMENU=nothing
4258   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4259   if test "${HAVE_X_WINDOWS}" = "yes"; then
4260     LIBXMENU="-lXMenu"
4261   else
4262     LIBXMENU=
4263   fi
4264   LIBX_OTHER=
4265   OLDXMENU_DEPS=
4266 fi
4267
4268 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4269   OLDXMENU_TARGET=
4270   OLDXMENU=nothing
4271   LIBXMENU=
4272   OLDXMENU_DEPS=
4273 fi
4274
4275 AC_SUBST(OLDXMENU_TARGET)
4276 AC_SUBST(OLDXMENU)
4277 AC_SUBST(LIBXMENU)
4278 AC_SUBST(LIBX_OTHER)
4279 AC_SUBST(OLDXMENU_DEPS)
4280
4281 if test "${HAVE_MENUS}" = "yes" ; then
4282   AC_DEFINE(HAVE_MENUS, 1,
4283             [Define to 1 if you have mouse menus.
4284              (This is automatic if you use X, but the option to specify it remains.)
4285              It is also defined with other window systems that support xmenu.c.])
4286 fi
4287
4288 if test "${GNU_MALLOC}" = "yes" ; then
4289   AC_DEFINE(GNU_MALLOC, 1,
4290             [Define to 1 if you want to use the GNU memory allocator.])
4291 fi
4292
4293 RALLOC_OBJ=
4294 if test "${REL_ALLOC}" = "yes" ; then
4295   AC_DEFINE(REL_ALLOC, 1,
4296             [Define REL_ALLOC if you want to use the relocating allocator for
4297              buffer space.])
4298
4299   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4300 fi
4301 AC_SUBST(RALLOC_OBJ)
4302
4303 if test "$opsys" = "cygwin"; then
4304   CYGWIN_OBJ="sheap.o cygw32.o"
4305   ## Cygwin differs because of its unexec().
4306   PRE_ALLOC_OBJ=
4307   POST_ALLOC_OBJ=lastfile.o
4308 else
4309   CYGWIN_OBJ=
4310   PRE_ALLOC_OBJ=lastfile.o
4311   POST_ALLOC_OBJ=
4312 fi
4313 AC_SUBST(CYGWIN_OBJ)
4314 AC_SUBST(PRE_ALLOC_OBJ)
4315 AC_SUBST(POST_ALLOC_OBJ)
4316
4317 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4318 # it temporarily reverts them to their pre-pkg-config values,
4319 # because gnulib needs to work with both src (which uses the
4320 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4321 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4322 # and it therefore needs to run in an environment where LIBS does not
4323 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4324 # for some package unrelated to lib-src.
4325 SAVE_CFLAGS=$CFLAGS
4326 SAVE_LIBS=$LIBS
4327 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4328 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4329 gl_ASSERT_NO_GNULIB_POSIXCHECK
4330 gl_ASSERT_NO_GNULIB_TESTS
4331 gl_INIT
4332 CFLAGS=$SAVE_CFLAGS
4333 LIBS=$SAVE_LIBS
4334
4335 case "$opsys" in
4336   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4337
4338   darwin)
4339    ## The -headerpad option tells ld (see man page) to leave room at the
4340    ## end of the header for adding load commands.  Needed for dumping.
4341    ## 0x690 is the total size of 30 segment load commands (at 56
4342    ## each); under Cocoa 31 commands are required.
4343    if test "$HAVE_NS" = "yes"; then
4344      libs_nsgui="-framework AppKit"
4345      headerpad_extra=6C8
4346    else
4347      libs_nsgui=
4348      headerpad_extra=690
4349    fi
4350    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4351
4352    ## This is here because src/Makefile.in did some extra fiddling around
4353    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
4354    ##   #ifndef LD_SWITCH_SYSTEM
4355    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
4356    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
4357    ## not using gcc, darwin.
4358    ## Because this was done in src/Makefile.in, the resulting part of
4359    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
4360    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
4361    ## rather than LD_SWITCH_SYSTEM.
4362    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4363      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4364    ;;
4365
4366   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4367   ## find X at run-time.
4368   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4369   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4370   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4371   ## had different values in configure (in ac_link) and src/Makefile.in.
4372   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4373   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4374
4375   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4376 esac
4377
4378 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4379
4380
4381 LD_FIRSTFLAG=
4382 ORDINARY_LINK=
4383 case "$opsys" in
4384   ## gnu: GNU needs its own crt0.
4385   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
4386
4387   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
4388   ## library search parth, i.e. it won't search /usr/lib for libc and
4389   ## friends.  Using -nostartfiles instead avoids this problem, and
4390   ## will also work on earlier NetBSD releases.
4391   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
4392
4393   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
4394   ##   MkLinux/LinuxPPC needs this.
4395   ## s390x-* only supports opsys = gnu-linux so it can be added here.
4396   gnu-*)
4397     case "$canonical" in
4398       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
4399     esac
4400     ;;
4401 esac
4402
4403
4404 if test "x$ORDINARY_LINK" = "xyes"; then
4405
4406   LD_FIRSTFLAG=""
4407   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
4408
4409 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
4410 ## freebsd, gnu-* not on powerpc*|s390x*.
4411 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
4412
4413   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
4414   ## places that are difficult to figure out at make time.  Fortunately,
4415   ## these same versions allow you to pass arbitrary flags on to the
4416   ## linker, so there is no reason not to use it as a linker.
4417   ##
4418   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
4419   ## searching for libraries in its internal directories, so we have to
4420   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
4421   LD_FIRSTFLAG="-nostdlib"
4422 fi
4423
4424 ## FIXME? What setting of EDIT_LDFLAGS should this have?
4425 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
4426
4427 AC_SUBST(LD_FIRSTFLAG)
4428
4429
4430 ## FIXME? The logic here is not precisely the same as that above.
4431 ## There is no check here for a pre-defined LD_FIRSTFLAG.
4432 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
4433 LIB_GCC=
4434 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
4435
4436   case "$opsys" in
4437     freebsd|netbsd|openbsd) LIB_GCC= ;;
4438
4439     gnu-*)
4440       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
4441       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
4442       case $host_cpu in
4443       arm*)
4444         LIB_GCC="-lgcc_s"
4445         ;;
4446       *)
4447         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
4448         ## immediately undefine it again and redefine it to empty.
4449         ## Was the C_SWITCH_X_SITE part really necessary?
4450 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
4451         LIB_GCC=
4452         ;;
4453       esac
4454       ;;
4455
4456     ## Ask GCC where to find libgcc.a.
4457     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
4458   esac
4459 fi                              dnl if $GCC
4460 AC_SUBST(LIB_GCC)
4461
4462 ## Common for all window systems
4463 if test "$window_system" != "none"; then
4464   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4465   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4466 fi
4467
4468 AC_SUBST(WINDOW_SYSTEM_OBJ)
4469
4470 AH_TOP([/* GNU Emacs site configuration template file.
4471
4472 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2013
4473   Free Software Foundation, Inc.
4474
4475 This file is part of GNU Emacs.
4476
4477 GNU Emacs is free software: you can redistribute it and/or modify
4478 it under the terms of the GNU General Public License as published by
4479 the Free Software Foundation, either version 3 of the License, or
4480 (at your option) any later version.
4481
4482 GNU Emacs is distributed in the hope that it will be useful,
4483 but WITHOUT ANY WARRANTY; without even the implied warranty of
4484 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4485 GNU General Public License for more details.
4486
4487 You should have received a copy of the GNU General Public License
4488 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4489
4490
4491 /* No code in Emacs #includes config.h twice, but some bits of code
4492    intended to work with other packages as well (like gmalloc.c)
4493    think they can include it as many times as they like.  */
4494 #ifndef EMACS_CONFIG_H
4495 #define EMACS_CONFIG_H
4496 ])dnl
4497
4498 AH_BOTTOM([#include <conf_post.h>
4499
4500 #endif /* EMACS_CONFIG_H */
4501
4502 /*
4503 Local Variables:
4504 mode: c
4505 End:
4506 */
4507 ])dnl
4508
4509 #### Report on what we decided to do.
4510 #### Report GTK as a toolkit, even if it doesn't use Xt.
4511 #### It makes printing result more understandable as using GTK sets
4512 #### toolkit_scroll_bars to yes by default.
4513 if test "${HAVE_GTK}" = "yes"; then
4514   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4515 fi
4516
4517 echo "
4518 Configured for \`${canonical}'.
4519
4520   Where should the build process find the source code?    ${srcdir}
4521   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4522   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4523   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4524   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4525   What window system should Emacs use?                    ${window_system}
4526   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4527
4528 if test -n "${x_includes}"; then
4529 echo "  Where do we find X Windows header files?                ${x_includes}"
4530 else
4531 echo "  Where do we find X Windows header files?                Standard dirs"
4532 fi
4533 if test -n "${x_libraries}"; then
4534 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4535 else
4536 echo "  Where do we find X Windows libraries?                   Standard dirs"
4537 fi
4538
4539 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4540 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4541 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4542 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4543 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4544 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4545 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4546 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4547
4548 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4549 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4550 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4551 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4552 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4553 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4554 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4555
4556 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4557 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4558 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4559 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4560
4561 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4562
4563 echo "  Does Emacs support Xwidgets?                            ${HAVE_XWIDGETS}"
4564 echo "       Does xwidgets support webkit(requires gtk3)?       ${HAVE_WEBKIT}"
4565 echo "       Does xwidgets support gobject introspection?       ${HAVE_GIR}"
4566 echo "       Does xwidgets support clutter(demo code)?          ${HAVE_CLUTTER}"
4567 echo "       Does xwidgets support goocanvas(demo code)?        ${HAVE_GOOCANVAS}"
4568 echo
4569
4570 if test -n "${EMACSDATA}"; then
4571    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4572 fi
4573 if test -n "${EMACSDOC}"; then
4574    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4575 fi
4576
4577 echo
4578
4579 if test "$HAVE_NS" = "yes"; then
4580    echo
4581    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4582 The installed application will go to nextstep/Emacs.app and can be
4583 run or moved from there."
4584    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4585       echo "The application will be fully self-contained."
4586     else
4587       echo "The lisp resources for the application will be installed under ${prefix}.
4588 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4589 to run if these resources are not installed."
4590    fi
4591    echo
4592 fi
4593
4594 if test "${opsys}" = "cygwin"; then
4595   case `uname -r` in
4596     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4597            echo
4598            ;;
4599   esac
4600 fi
4601
4602 # Remove any trailing slashes in these variables.
4603 [test "${prefix}" != NONE &&
4604   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4605 test "${exec_prefix}" != NONE &&
4606   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4607
4608 if test "$HAVE_NS" = "yes"; then
4609   if test "$NS_IMPL_GNUSTEP" = yes; then
4610     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
4611       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
4612   else
4613     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
4614       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
4615   fi
4616 fi
4617
4618 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4619 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4620 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4621 dnl (else you get "no `Makefile.am' found for any configure output").
4622 dnl This will work, but you get a config.status that is not quite right
4623 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4624 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4625 dnl it seems better to just live with the duplication.
4626 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile"
4627
4628 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4629        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4630        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4631        leim/Makefile nextstep/Makefile])
4632
4633 dnl test/ is not present in release tarfiles.
4634 opt_makefile=test/automated/Makefile
4635
4636 if test -f "$srcdir/$opt_makefile.in"; then
4637   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4638   dnl Again, it's best not to use a variable.  Though you can add
4639   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4640   AC_CONFIG_FILES([test/automated/Makefile])
4641 fi
4642
4643
4644 dnl admin/ may or may not be present.
4645 opt_makefile=admin/unidata/Makefile
4646
4647 if test -f "$srcdir/$opt_makefile.in"; then
4648   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4649   AC_CONFIG_FILES([admin/unidata/Makefile])
4650 fi
4651
4652
4653 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4654
4655 AC_SUBST(SUBDIR_MAKEFILES_IN)
4656
4657 dnl Make the necessary directories, if they don't exist.
4658 AC_CONFIG_COMMANDS([mkdirs], [
4659 for dir in etc lisp ; do
4660   test -d ${dir} || mkdir ${dir}
4661 done
4662 ])
4663
4664 dnl You might wonder (I did) why epaths.h is generated by running make,
4665 dnl rather than just letting configure generate it from epaths.in.
4666 dnl One reason is that the various paths are not fully expanded (see above);
4667 dnl eg gamedir=${prefix}/var/games/emacs.
4668 dnl Secondly, the GNU Coding standards require that one should be able
4669 dnl to run `make prefix=/some/where/else' and override the values set
4670 dnl by configure.  This also explains the `move-if-change' test and
4671 dnl the use of force in the `epaths-force' rule in Makefile.in.
4672 AC_CONFIG_COMMANDS([epaths], [
4673 echo creating src/epaths.h
4674 ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4675 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
4676
4677 AC_CONFIG_COMMANDS([gdbinit], [
4678 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
4679   echo creating src/.gdbinit
4680   echo "source $srcdir/src/.gdbinit" > src/.gdbinit
4681 fi
4682 ])
4683
4684 AC_OUTPUT