code.delx.au - gnu-emacs/blob - lisp/international/mule-util.el

   1 ;;; mule-util.el --- Utility functions for mulitilingual environment (mule)
   2
   3 ;; Copyright (C) 1995 Electrotechnical Laboratory, JAPAN.
   4 ;; Licensed to the Free Software Foundation.
   5
   6 ;; Keywords: mule, multilingual
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Code:
  26
  27 ;;; String manipulations while paying attention to multibyte
  28 ;;; characters.
  29
  30 ;;;###autoload
  31 (defun string-to-sequence (string type)
  32   "Convert STRING to a sequence of TYPE which contains characters in STRING.
  33 TYPE should be `list' or `vector'."
  34   (or (eq type 'list) (eq type 'vector)
  35       (error "Invalid type: %s" type))
  36   (let* ((len (length string))
  37          (i 0)
  38          l ch)
  39     (while (< i len)
  40       (setq ch (if enable-multibyte-characters
  41                    (sref string i) (aref string i)))
  42       (setq l (cons ch l))
  43       (setq i (+ i (char-bytes ch))))
  44     (setq l (nreverse l))
  45     (if (eq type 'list)
  46         l
  47       (vconcat l))))
  48
  49 ;;;###autoload
  50 (defsubst string-to-list (string)
  51   "Return a list of characters in STRING."
  52   (string-to-sequence string 'list))
  53
  54 ;;;###autoload
  55 (defsubst string-to-vector (string)
  56   "Return a vector of characters in STRING."
  57   (string-to-sequence string 'vector))
  58
  59 ;;;###autoload
  60 (defun store-substring (string idx obj)
  61   "Embed OBJ (string or character) at index IDX of STRING."
  62   (let* ((str (cond ((stringp obj) obj)
  63                     ((integerp obj) (char-to-string obj))
  64                     (t (error
  65                         "Invalid argument (should be string or character): %s"
  66                         obj))))
  67          (string-len (length string))
  68          (len (length str))
  69          (i 0))
  70     (while (and (< i len) (< idx string-len))
  71       (aset string idx (aref str i))
  72       (setq idx (1+ idx) i (1+ i)))
  73     string))
  74
  75 ;;;###autoload
  76 (defun truncate-string-to-width (str end-column &optional start-column padding)
  77   "Truncate string STR to end at column END-COLUMN.
  78 The optional 2nd arg START-COLUMN, if non-nil, specifies
  79 the starting column; that means to return the characters occupying
  80 columns START-COLUMN ... END-COLUMN of STR.
  81
  82 The optional 3rd arg PADDING, if non-nil, specifies a padding character
  83 to add at the end of the result if STR doesn't reach column END-COLUMN,
  84 or if END-COLUMN comes in the middle of a character in STR.
  85 PADDING is also added at the beginning of the result
  86 if column START-COLUMN appears in the middle of a character in STR.
  87
  88 If PADDING is nil, no padding is added in these cases, so
  89 the resulting string may be narrower than END-COLUMN."
  90   (or start-column
  91       (setq start-column 0))
  92   (let ((len (length str))
  93         (idx 0)
  94         (column 0)
  95         (head-padding "") (tail-padding "")
  96         ch last-column last-idx from-idx)
  97     (condition-case nil
  98         (while (< column start-column)
  99           (setq ch (sref str idx)
 100                 column (+ column (char-width ch))
 101                 idx (+ idx (char-bytes ch))))
 102       (args-out-of-range (setq idx len)))
 103     (if (< column start-column)
 104         (if padding (make-string end-column padding) "")
 105       (if (and padding (> column start-column))
 106           (setq head-padding (make-string (- column start-column) ?\ )))
 107       (setq from-idx idx)
 108       (if (< end-column column)
 109           (setq idx from-idx)
 110         (condition-case nil
 111             (while (< column end-column)
 112               (setq last-column column
 113                     last-idx idx
 114                     ch (sref str idx)
 115                     column (+ column (char-width ch))
 116                     idx (+ idx (char-bytes ch))))
 117           (args-out-of-range (setq idx len)))
 118         (if (> column end-column)
 119             (setq column last-column idx last-idx))
 120         (if (and padding (< column end-column))
 121             (setq tail-padding (make-string (- end-column column) padding))))
 122       (setq str (substring str from-idx idx))
 123       (if padding
 124           (concat head-padding str tail-padding)
 125         str))))
 126
 127 ;;; For backward compatiblity ...
 128 ;;;###autoload
 129 (defalias 'truncate-string 'truncate-string-to-width)
 130 (make-obsolete 'truncate-string 'truncate-string-to-width)
 131 \f
 132 ;;; Nested alist handler.  Nested alist is alist whose elements are
 133 ;;; also nested alist.
 134
 135 ;;;###autoload
 136 (defsubst nested-alist-p (obj)
 137   "Return t if OBJ is a nesetd alist.
 138
 139 Nested alist is a list of the form (ENTRY . BRANCHES), where ENTRY is
 140 any Lisp object, and BRANCHES is a list of cons cells of the form
 141 (KEY-ELEMENT . NESTED-ALIST).
 142
 143 You can use a nested alist to store any Lisp object (ENTRY) for a key
 144 sequence KEYSEQ, where KEYSEQ is a sequence of KEY-ELEMENT.  KEYSEQ
 145 can be a string, a vector, or a list."
 146   (and obj (listp obj) (listp (cdr obj))))
 147
 148 ;;;###autoload
 149 (defun set-nested-alist (keyseq entry alist &optional len branches)
 150   "Set ENTRY for KEYSEQ in a nested alist ALIST.
 151 Optional 4th arg LEN non-nil means the firlst LEN elements in KEYSEQ
 152  is considered.
 153 Optional argument BRANCHES if non-nil is branches for a keyseq
 154 longer than KEYSEQ.
 155 See the documentation of `nested-alist-p' for more detail."
 156   (or (nested-alist-p alist)
 157       (error "Invalid arguement %s" alist))
 158   (let ((islist (listp keyseq))
 159         (len (or len (length keyseq)))
 160         (i 0)
 161         key-elt slot)
 162     (while (< i len)
 163       (if (null (nested-alist-p alist))
 164           (error "Keyseq %s is too long for this nested alist" keyseq))
 165       (setq key-elt (if islist (nth i keyseq) (aref keyseq i)))
 166       (setq slot (assoc key-elt (cdr alist)))
 167       (if (null slot)
 168           (progn
 169             (setq slot (cons key-elt (list t)))
 170             (setcdr alist (cons slot (cdr alist)))))
 171       (setq alist (cdr slot))
 172       (setq i (1+ i)))
 173     (setcar alist entry)
 174     (if branches
 175         (if (cdr alist)
 176             (error "Can't set branches for keyseq %s" keyseq)
 177           (setcdr alist branches)))))
 178
 179 ;;;###autoload
 180 (defun lookup-nested-alist (keyseq alist &optional len start nil-for-too-long)
 181   "Look up key sequence KEYSEQ in nested alist ALIST.  Return the definition.
 182 Optional 1st argument LEN specifies the length of KEYSEQ.
 183 Optional 2nd argument START specifies index of the starting key.
 184 The returned value is normally a nested alist of which
 185 car part is the entry for KEYSEQ.
 186 If ALIST is not deep enough for KEYSEQ, return number which is
 187  how many key elements at the front of KEYSEQ it takes
 188  to reach a leaf in ALIST.
 189 Optional 3rd argument NIL-FOR-TOO-LONG non-nil means return nil
 190  even if ALIST is not deep enough."
 191   (or (nested-alist-p alist)
 192       (error "invalid arguement %s" alist))
 193   (or len
 194       (setq len (length keyseq)))
 195   (let ((i (or start 0)))
 196     (if (catch 'lookup-nested-alist-tag
 197           (if (listp keyseq)
 198               (while (< i len)
 199                 (if (setq alist (cdr (assoc (nth i keyseq) (cdr alist))))
 200                     (setq i (1+ i))
 201                   (throw 'lookup-nested-alist-tag t))))
 202           (while (< i len)
 203             (if (setq alist (cdr (assoc (aref keyseq i) (cdr alist))))
 204                 (setq i (1+ i))
 205               (throw 'lookup-nested-alist-tag t))))
 206         ;; KEYSEQ is too long.
 207         (if nil-for-too-long nil i)
 208       alist)))
 209
 210 \f
 211 ;; Coding system related functions.
 212
 213 ;;;###autoload
 214 (defun coding-system-eol-type-mnemonic (coding-system)
 215   "Return mnemonic letter of eol-type of CODING-SYSTEM."
 216   (let ((eol-type (coding-system-eol-type coding-system)))
 217     (cond ((vectorp eol-type) eol-mnemonic-undecided)
 218           ((eq eol-type 0) eol-mnemonic-unix)
 219           ((eq eol-type 1) eol-mnemonic-unix)
 220           ((eq eol-type 2) eol-mnemonic-unix)
 221           (t ?-))))
 222
 223 ;;;###autoload
 224 (defun coding-system-post-read-conversion (coding-system)
 225   "Return the value of CODING-SYSTEM's post-read-conversion property."
 226   (coding-system-get coding-system 'post-read-conversion))
 227
 228 ;;;###autoload
 229 (defun coding-system-pre-write-conversion (coding-system)
 230   "Return the value of CODING-SYSTEM's pre-write-conversion property."
 231   (coding-system-get coding-system 'pre-write-conversion))
 232
 233 ;;;###autoload
 234 (defun coding-system-unification-table-for-decode (coding-system)
 235   "Return the value of CODING-SYSTEM's unification-table-for-decode property."
 236   (coding-system-get coding-system 'character-unification-table-for-decode))
 237
 238 ;;;###autoload
 239 (defun coding-system-unification-table-for-encode (coding-system)
 240   "Return the value of CODING-SYSTEM's unification-table-for-encode property."
 241   (coding-system-get coding-system 'character-unification-table-for-encode))
 242
 243 (defun coding-system-lessp (x y)
 244   (cond ((eq x 'no-conversion) t)
 245         ((eq y 'no-conversion) nil)
 246         ((eq x 'emacs-mule) t)
 247         ((eq y 'emacs-mule) nil)
 248         ((eq x 'undecided) t)
 249         ((eq y 'undecided) nil)
 250         (t (let ((c1 (coding-system-mnemonic x))
 251                  (c2 (coding-system-mnemonic y)))
 252              (or (< (downcase c1) (downcase c2))
 253                  (and (not (> (downcase c1) (downcase c2)))
 254                       (< c1 c2)))))))
 255
 256 ;;;###autoload
 257 (defun coding-system-list (&optional base-only)
 258   "Return a list of all existing coding systems.
 259 If optional arg BASE-ONLY is non-nil, only base coding systems are listed."
 260   (let* ((codings (sort (copy-sequence coding-system-list)
 261                         'coding-system-lessp))
 262          (tail (cons nil codings)))
 263     ;; Remove subsidiary coding systems (eol variants) and alias
 264     ;; coding systems (if necessary).
 265     (while (cdr tail)
 266       (let* ((coding (car (cdr tail)))
 267              (aliases (coding-system-get coding 'alias-coding-systems)))
 268         (if (or
 269              ;; CODING is an eol varinant if not in ALIASES.
 270              (not (memq coding aliases))
 271              ;; CODING is an alias if it is not car of ALISES.
 272              (and base-only (not (eq coding (car aliases)))))
 273             (setcdr tail (cdr (cdr tail)))
 274           (setq tail (cdr tail)))))
 275     codings))
 276
 277 ;;;###autoload
 278 (defun coding-system-equal (coding-system-1 coding-system-2)
 279   "Return t if and only if CODING-SYSTEM-1 and CODING-SYSTEM-2 are identical.
 280 Two coding systems are identical if two symbols are equal
 281 or one is an alias of the other."
 282   (or (eq coding-system-1 coding-system-2)
 283       (and (equal (coding-system-spec coding-system-1)
 284                   (coding-system-spec coding-system-2))
 285            (let ((eol-type-1 (coding-system-eol-type coding-system-1))
 286                  (eol-type-2 (coding-system-eol-type coding-system-2)))
 287              (or (eq eol-type-1 eol-type-2)
 288                  (and (vectorp eol-type-1) (vectorp eol-type-2)))))))
 289
 290 ;;;###autoload
 291 (defun find-safe-coding-system (from to)
 292   "Return a list of proper coding systems to encode a text between FROM and TO.
 293 All coding systems in the list can safely encode any multibyte characters
 294 in the region.
 295
 296 If the region contains no multibyte charcters, the returned list
 297 contains a single element `undecided'.
 298
 299 Kludgy feature: if FROM is a string, then that string is the target
 300 for finding proper coding systems, and TO is ignored."
 301   (let ((found (if (stringp from)
 302                    (find-charset-string from)
 303                  (find-charset-region from to)))
 304         (l coding-system-list)
 305         codings coding safe)
 306     (if (and (= (length found) 1)
 307              (eq 'ascii (car found)))
 308         '(undecided)
 309       (while l
 310         (setq coding (car l) l (cdr l))
 311         (if (and (eq coding (coding-system-base coding))
 312                  (setq safe (coding-system-get coding 'safe-charsets))
 313                  (or (eq safe t)
 314                      (catch 'tag
 315                        (mapcar (function (lambda (x)
 316                                            (if (not (memq x safe))
 317                                                (throw 'tag nil))))
 318                                found))))
 319             (setq codings (cons coding codings))))
 320       codings)))
 321
 322 \f
 323 ;;; Composite charcater manipulations.
 324
 325 ;;;###autoload
 326 (defun compose-region (start end)
 327   "Compose all characters in the current region into one composite character.
 328 When called from a program, expects two arguments,
 329 positions (integers or markers) specifying the region."
 330   (interactive "r")
 331   (save-excursion
 332     (let ((str (buffer-substring start end)))
 333       (goto-char start)
 334       (delete-region start end)
 335       (insert (compose-string str)))))
 336
 337 ;;;###autoload
 338 (defun decompose-region (start end)
 339   "Decompose all composite characters in the current region.
 340 Composite characters are broken up into individual components.
 341 When called from a program, expects two arguments,
 342 positions (integers or markers) specifying the region."
 343   (interactive "r")
 344   (save-restriction
 345     (narrow-to-region start end)
 346     (goto-char (point-min))
 347     (let ((enable-multibyte-characters nil)
 348           ;; This matches the whole bytes of single composite character.
 349           (re-cmpchar "\200[\240-\377]+")
 350           p ch str)
 351       (while (re-search-forward re-cmpchar nil t)
 352         (setq str (buffer-substring (match-beginning 0) (match-end 0)))
 353         (delete-region (match-beginning 0) (match-end 0))
 354         (insert (decompose-composite-char (string-to-char str)))))))
 355
 356 ;;;###autoload
 357 (defun decompose-string (string)
 358   "Decompose all composite characters in STRING."
 359   (let* ((l (string-to-list string))
 360          (tail l)
 361          ch)
 362     (while tail
 363       (setq ch (car tail))
 364       (setcar tail (if (cmpcharp ch) (decompose-composite-char ch)
 365                      (char-to-string ch)))
 366       (setq tail (cdr tail)))
 367     (apply 'concat l)))
 368
 369 ;;;###autoload
 370 (defconst reference-point-alist
 371   '((tl . 0) (tc . 1) (tr . 2)
 372     (ml . 3) (mc . 4) (mr . 5)
 373     (bl . 6) (bc . 7) (br . 8)
 374     (top-left . 0) (top-center . 1) (top-right . 2)
 375     (mid-left . 3) (mid-center . 4) (mid-right . 5)
 376     (bottom-left . 6) (bottom-center . 7) (bottom-right . 8)
 377     (0 . 0) (1 . 1) (2 . 2)
 378     (3 . 3) (4 . 4) (5 . 5)
 379     (6 . 6) (7 . 7) (8 . 8))
 380   "Alist of reference point symbols vs reference point codes.
 381 A reference point symbol is to be used to specify a composition rule
 382 while making a composite character by the function `compose-chars'
 383 (which see).
 384
 385 Meanings of reference point codes are as follows:
 386
 387     0----1----2 <-- ascent      0:tl or top-left
 388     |         |                 1:tc or top-center
 389     |         |                 2:tr or top-right
 390     |         |                 3:ml or mid-left
 391     |    4 <--+---- center      4:mc or mid-center
 392     |         |                 5:mr or mid-right
 393 --- 3         5 <-- baseline    6:bl or bottom-left
 394     |         |                 7:bc or bottom-center
 395     6----7----8 <-- descent     8:br or bottom-right
 396
 397 Reference point symbols are to be used to specify composition rule of
 398 the form \(GLOBAL-REF-POINT . NEW-REF-POINT), where GLOBAL-REF-POINT
 399 is a reference point in the overall glyphs already composed, and
 400 NEW-REF-POINT is a reference point in the new glyph to be added.
 401
 402 For instance, if GLOBAL-REF-POINT is 8 and NEW-REF-POINT is 1, the
 403 overall glyph is updated as follows:
 404
 405     +-------+--+ <--- new ascent
 406     |       |  |
 407     | global|  |
 408     | glyph |  |
 409 --- |       |  | <--- baseline (doesn't change)
 410     +----+--+--+
 411     |    | new |
 412     |    |glyph|
 413     +----+-----+ <--- new descent
 414 ")
 415
 416 ;; Return a string for char CH to be embedded in multibyte form of
 417 ;; composite character.
 418 (defun compose-chars-component (ch)
 419   (if (< ch 128)
 420       (format "\240%c" (+ ch 128))
 421     (let ((str (char-to-string ch)))
 422       (if (cmpcharp ch)
 423           (substring str (if (= (aref str 1) ?\xFF) 2 1))
 424         (aset str 0 (+ (aref str 0) ?\x20))
 425         str))))
 426
 427 ;; Return a string for composition rule RULE to be embedded in
 428 ;; multibyte form of composite character.
 429 (defsubst compose-chars-rule (rule)
 430   (char-to-string (+ ?\xA0
 431                      (* (cdr (assq (car rule) reference-point-alist)) 9)
 432                      (cdr (assq (cdr rule) reference-point-alist)))))
 433
 434 ;;;###autoload
 435 (defun compose-chars (first-component &rest args)
 436   "Return one char string composed from the arguments.
 437 Each argument is a character (including a composite chararacter)
 438 or a composition rule.
 439 A composition rule has the form \(GLOBAL-REF-POINT . NEW-REF-POINT).
 440 See the documentation of `reference-point-alist' for more detail."
 441   (if (= (length args) 0)
 442       (char-to-string first-component)
 443     (let* ((with-rule (consp (car args)))
 444            (str (if with-rule (concat (vector leading-code-composition ?\xFF))
 445                   (char-to-string leading-code-composition))))
 446       (setq str (concat str (compose-chars-component first-component)))
 447       (while args
 448         (if with-rule
 449             (progn
 450               (if (not (consp (car args)))
 451                   (error "Invalid composition rule: %s" (car args)))
 452               (setq str (concat str (compose-chars-rule (car args))
 453                                 (compose-chars-component (car (cdr args))))
 454                     args (cdr (cdr args))))
 455           (setq str (concat str (compose-chars-component (car args)))
 456                 args (cdr args))))
 457       str)))
 458
 459 ;;;###autoload
 460 (defun decompose-composite-char (char &optional type with-composition-rule)
 461   "Convert composite character CHAR to a string containing components of CHAR.
 462 Optional 1st arg TYPE specifies the type of sequence returned.
 463 It should be `string' (default), `list', or `vector'.
 464 Optional 2nd arg WITH-COMPOSITION-RULE non-nil means the returned
 465 sequence contains embedded composition rules if any.  In this case, the
 466 order of elements in the sequence is the same as arguments for
 467 `compose-chars' to create CHAR.
 468 If TYPE is omitted or is `string', composition rules are omitted
 469 even if WITH-COMPOSITION-RULE is t."
 470   (or type
 471       (setq type 'string))
 472   (let* ((len (composite-char-component-count char))
 473          (i (1- len))
 474          l)
 475     (setq with-composition-rule (and with-composition-rule
 476                                     (not (eq type 'string))
 477                                     (composite-char-composition-rule-p char)))
 478     (while (> i 0)
 479       (setq l (cons (composite-char-component char i) l))
 480       (if  with-composition-rule
 481           (let ((rule (- (composite-char-composition-rule char i) ?\xA0)))
 482             (setq l (cons (cons (/ rule 9) (% rule 9)) l))))
 483       (setq i (1- i)))
 484     (setq l (cons (composite-char-component char 0) l))
 485     (cond ((eq type 'string)
 486            (apply 'concat-chars l))
 487           ((eq type 'list)
 488            l)
 489           (t                            ; i.e. TYPE is vector
 490            (vconcat l)))))
 491
 492 ;;; mule-util.el ends here