code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 150 if test "$with_wide_int" = yes; then
 151   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 152 fi
 153
 154 dnl _ON results in a '--without' option in the --help output, so
 155 dnl the help text should refer to "don't compile", etc.
 156 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 157 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 158 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 159 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 160 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 161 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 162 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 163 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 164
 165 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 166 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 167 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 168
 169 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 170 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 171 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 172 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 173
 174 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 175 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 176 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 177 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 178 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 179 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 180
 181 ## For the times when you want to build Emacs but don't have
 182 ## a suitable makeinfo, and can live without the manuals.
 183 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 184 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 185
 186 ## Makefile.in needs the cache file name.
 187 AC_SUBST(cache_file)
 188
 189 ## This is an option because I do not know if all info/man support
 190 ## compressed files, nor how to test if they do so.
 191 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 192 if test $with_compress_info = yes; then
 193    GZIP_INFO=yes
 194 else
 195    GZIP_INFO=
 196 fi
 197 AC_SUBST(GZIP_INFO)
 198
 199 AC_ARG_WITH([pkg-config-prog],dnl
 200 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 201                   [path to pkg-config for finding GTK and librsvg])])
 202 if test "X${with_pkg_config_prog}" != X; then
 203    if test "${with_pkg_config_prog}" != yes; then
 204       PKG_CONFIG="${with_pkg_config_prog}"
 205    fi
 206 fi
 207
 208 CRT_DIR=
 209 AC_ARG_WITH([crt-dir],dnl
 210 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 211 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 212 CRT_DIR="${with_crt_dir}"
 213
 214 AC_ARG_WITH(gameuser,dnl
 215 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 216 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 217   && gameuser="${with_gameuser}"
 218 test "X$gameuser" = X && gameuser=games
 219
 220 AC_ARG_WITH([gnustep-conf],dnl
 221 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 222 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 223   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 224 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 225      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 226
 227 AC_ARG_ENABLE(ns-self-contained,
 228 [AS_HELP_STRING([--disable-ns-self-contained],
 229                 [disable self contained build under NeXTstep])],
 230    EN_NS_SELF_CONTAINED=$enableval,
 231    EN_NS_SELF_CONTAINED=yes)
 232
 233 AC_ARG_ENABLE(asserts,
 234 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 235       USE_XASSERTS=$enableval,
 236       USE_XASSERTS=no)
 237
 238 AC_ARG_ENABLE(locallisppath,
 239 [AS_HELP_STRING([--enable-locallisppath=PATH],
 240                 [directories Emacs should search for lisp files specific
 241                  to this site])],
 242 if test "${enableval}" = "no"; then
 243   locallisppath=
 244 elif test "${enableval}" != "yes"; then
 245   locallisppath=${enableval}
 246 fi)
 247
 248 AC_ARG_ENABLE(checking,
 249 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 250                 [enable expensive run-time checks.  With LIST,
 251                  enable only specific categories of checks.
 252                  Categories are: all,yes,no.
 253                  Flags are: stringbytes, stringoverrun, stringfreelist,
 254                  xmallocoverrun, conslist, glyphs])],
 255 [ac_checking_flags="${enableval}"],[])
 256 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 257 for check in $ac_checking_flags
 258 do
 259         case $check in
 260         # these set all the flags to specific states
 261         yes)            ac_enable_checking=1 ;;
 262         no)             ac_enable_checking= ;
 263                         ac_gc_check_stringbytes= ;
 264                         ac_gc_check_string_overrun= ;
 265                         ac_gc_check_string_free_list= ;
 266                         ac_xmalloc_overrun= ;
 267                         ac_gc_check_cons_list= ;
 268                         ac_check_glyphs= ;;
 269         all)            ac_enable_checking=1 ;
 270                         ac_gc_check_stringbytes=1 ;
 271                         ac_gc_check_string_overrun=1 ;
 272                         ac_gc_check_string_free_list=1 ;
 273                         ac_xmalloc_overrun=1 ;
 274                         ac_gc_check_cons_list=1 ;
 275                         ac_check_glyphs=1 ;;
 276         # these enable particular checks
 277         stringbytes)    ac_gc_check_stringbytes=1 ;;
 278         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 279         stringfreelist) ac_gc_check_string_free_list=1 ;;
 280         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 281         conslist)       ac_gc_check_cons_list=1 ;;
 282         glyphs)         ac_check_glyphs=1 ;;
 283         *)      AC_MSG_ERROR(unknown check category $check) ;;
 284         esac
 285 done
 286 IFS="$ac_save_IFS"
 287
 288 if test x$ac_enable_checking != x ; then
 289   AC_DEFINE(ENABLE_CHECKING, 1,
 290 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 291 fi
 292 if test x$ac_gc_check_stringbytes != x ; then
 293   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 294 [Define this temporarily to hunt a bug.  If defined, the size of
 295    strings is redundantly recorded in sdata structures so that it can
 296    be compared to the sizes recorded in Lisp strings.])
 297 fi
 298 if test x$ac_gc_check_string_overrun != x ; then
 299   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 300 [Define this to check for short string overrun.])
 301 fi
 302 if test x$ac_gc_check_string_free_list != x ; then
 303   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 304 [Define this to check the string free list.])
 305 fi
 306 if test x$ac_xmalloc_overrun != x ; then
 307   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 308 [Define this to check for malloc buffer overrun.])
 309 fi
 310 if test x$ac_gc_check_cons_list != x ; then
 311   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 312 [Define this to check for errors in cons list.])
 313 fi
 314 if test x$ac_check_glyphs != x ; then
 315   AC_DEFINE(GLYPH_DEBUG, 1,
 316 [Define this to enable glyphs debugging code.])
 317 fi
 318
 319 AC_ARG_ENABLE(check-lisp-object-type,
 320 [AS_HELP_STRING([--enable-check-lisp-object-type],
 321                 [enable compile time checks for the Lisp_Object data type.
 322                 This is useful for development for catching certain types of bugs.])],
 323 if test "${enableval}" != "no"; then
 324    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 325    [Define this to enable compile time checks for the Lisp_Object data type.])
 326 fi)
 327
 328
 329 AC_ARG_ENABLE(profiling,
 330 [AS_HELP_STRING([--enable-profiling],
 331                 [build emacs with profiling support.
 332                  This might not work on all platforms])],
 333 [ac_enable_profiling="${enableval}"],[])
 334 if test x$ac_enable_profiling != x ; then
 335    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 336 else
 337    PROFILING_CFLAGS=
 338 fi
 339 AC_SUBST(PROFILING_CFLAGS)
 340
 341 AC_ARG_ENABLE(autodepend,
 342 [AS_HELP_STRING([--enable-autodepend],
 343                 [automatically generate dependencies to .h-files.
 344                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 345                  found])],
 346 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 347
 348 #### Make srcdir absolute, if it isn't already.  It's important to
 349 #### avoid running the path through pwd unnecessarily, since pwd can
 350 #### give you automounter prefixes, which can go away.  We do all this
 351 #### so Emacs can find its files when run uninstalled.
 352 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 353 unset CDPATH
 354 case "${srcdir}" in
 355   /* ) ;;
 356   . )
 357     ## We may be able to use the $PWD environment variable to make this
 358     ## absolute.  But sometimes PWD is inaccurate.
 359     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 360     ## but that tested only for a well-formed and valid PWD,
 361     ## it did not object when PWD was well-formed and valid but just wrong.
 362     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 363     then
 364       srcdir="$PWD"
 365     else
 366       srcdir="`(cd ${srcdir}; pwd)`"
 367     fi
 368   ;;
 369   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 370 esac
 371
 372 #### Given the configuration name, set opsysfile to the
 373 #### name of s/*.h file we should use.
 374
 375 ### Canonicalize the configuration name.
 376
 377 AC_CANONICAL_HOST
 378 canonical=$host
 379 configuration=${host_alias-${build_alias-$host}}
 380
 381 dnl This used to use changequote, but, apart from `changequote is evil'
 382 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 383 dnl the great gob of text.  Thus it's not processed for possible expansion.
 384 dnl Just make sure the brackets remain balanced.
 385 dnl
 386 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 387 dnl indicated by comments.
 388 dnl quotation begins
 389 [
 390
 391 ### If you add support for a new configuration, add code to this
 392 ### switch statement to recognize your configuration name and select
 393 ### the appropriate operating system file.
 394
 395 ### You would hope that you could choose an s/*.h
 396 ### file based on the operating system portion.  However, it turns out
 397 ### that each s/*.h file is pretty manufacturer-specific.
 398 ### So we basically have to have a special case for each
 399 ### configuration name.
 400 ###
 401 ### As far as handling version numbers on operating systems is
 402 ### concerned, make sure things will fail in a fixable way.  If
 403 ### /etc/MACHINES doesn't say anything about version numbers, be
 404 ### prepared to handle anything reasonably.  If version numbers
 405 ### matter, be sure /etc/MACHINES says something about it.
 406
 407 opsys='' unported=no
 408 case "${canonical}" in
 409
 410   ## GNU/Linux and similar ports
 411   *-*-linux* )
 412     opsys=gnu-linux
 413   ;;
 414
 415   ## FreeBSD ports
 416   *-*-freebsd* )
 417     opsys=freebsd
 418   ;;
 419
 420   ## FreeBSD kernel + glibc based userland
 421   *-*-kfreebsd*gnu* )
 422     opsys=gnu-kfreebsd
 423   ;;
 424
 425   ## NetBSD ports
 426   *-*-netbsd* )
 427     opsys=netbsd
 428   ;;
 429
 430   ## OpenBSD ports
 431   *-*-openbsd* )
 432     opsys=openbsd
 433   ;;
 434
 435   ## Apple Darwin / Mac OS X
 436   *-apple-darwin* )
 437     case "${canonical}" in
 438       i[3456]86-* )  ;;
 439       powerpc-* )    ;;
 440       x86_64-* )     ;;
 441       * )            unported=yes ;;
 442     esac
 443     opsys=darwin
 444     ## Use fink packages if available.
 445     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 446 ##    if test -d /sw/include && test -d /sw/lib; then
 447 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 448 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 449 ##    fi
 450   ;;
 451
 452   ## HP 9000 series 700 and 800, running HP/UX
 453   hppa*-hp-hpux10.2* )
 454     opsys=hpux10-20
 455   ;;
 456   hppa*-hp-hpux1[1-9]* )
 457     opsys=hpux11
 458     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 459   ;;
 460
 461   ## IBM machines
 462   rs6000-ibm-aix4.[23]* )
 463     opsys=aix4-2
 464   ;;
 465   powerpc-ibm-aix4.[23]*  )
 466     opsys=aix4-2
 467   ;;
 468   rs6000-ibm-aix[56]* )
 469     opsys=aix4-2
 470   ;;
 471   powerpc-ibm-aix[56]*  )
 472     opsys=aix4-2
 473   ;;
 474
 475   ## Silicon Graphics machines
 476   ## Iris 4D
 477   mips-sgi-irix6.5 )
 478     opsys=irix6-5
 479     # Without defining _LANGUAGE_C, things get masked out in the headers
 480     # so that, for instance, grepping for `free' in stdlib.h fails and
 481     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 482     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 483   ;;
 484
 485   ## Suns
 486   *-sun-solaris* \
 487     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 488     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 489     case "${canonical}" in
 490       i[3456]86-*-* )   ;;
 491       amd64-*-*|x86_64-*-*) ;;
 492       sparc* )          ;;
 493       * )               unported=yes ;;
 494     esac
 495     case "${canonical}" in
 496       *-sunos5.6* | *-solaris2.6* )
 497                 opsys=sol2-6
 498                 RANLIB="ar -ts"
 499                 ;;
 500       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 501                 opsys=sol2-6
 502                 emacs_check_sunpro_c=yes
 503                 ;;
 504       *-sunos5* | *-solaris* )
 505                 opsys=sol2-10
 506                 emacs_check_sunpro_c=yes
 507                 ;;
 508     esac
 509     ## Watch out for a compiler that we know will not work.
 510     case "${canonical}" in
 511      *-solaris* | *-sunos5* )
 512                 if [ "x$CC" = x/usr/ucb/cc ]; then
 513                   ## /usr/ucb/cc doesn't work;
 514                   ## we should find some other compiler that does work.
 515                   unset CC
 516                 fi
 517                 ;;
 518       *) ;;
 519     esac
 520   ;;
 521
 522   ## Intel 386 machines where we don't care about the manufacturer.
 523   i[3456]86-*-* )
 524     case "${canonical}" in
 525       *-cygwin )                opsys=cygwin ;;
 526       *-darwin* )               opsys=darwin ;;
 527       *-sysv4.2uw* )            opsys=unixware ;;
 528       *-sysv5uw* )              opsys=unixware ;;
 529       *-sysv5OpenUNIX* )        opsys=unixware ;;
 530       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 531     esac
 532   ;;
 533
 534   * )
 535     unported=yes
 536   ;;
 537 esac
 538
 539 ### If the code above didn't choose an operating system, just choose
 540 ### an operating system based on the configuration name.  You really
 541 ### only want to use this when you have no idea what the right
 542 ### operating system is; if you know what operating systems a machine
 543 ### runs, it's cleaner to make it explicit in the case statement
 544 ### above.
 545 if test x"${opsys}" = x; then
 546   case "${canonical}" in
 547     *-gnu* )                            opsys=gnu ;;
 548     * )
 549       unported=yes
 550     ;;
 551   esac
 552 fi
 553
 554 ]
 555 dnl quotation ends
 556
 557 if test $unported = yes; then
 558   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 559 Check `etc/MACHINES' for recognized configuration names.])
 560 fi
 561
 562 opsysfile="s/${opsys}.h"
 563
 564
 565 #### Choose a compiler.
 566
 567 dnl Sets GCC=yes if using gcc.
 568 AC_PROG_CC
 569 AM_PROG_CC_C_O
 570
 571 if test x$GCC = xyes; then
 572   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 573 else
 574   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 575 fi
 576
 577 # Initialize gnulib right after choosing the compiler.
 578 gl_EARLY
 579
 580 AC_ARG_ENABLE([gcc-warnings],
 581   [AS_HELP_STRING([--enable-gcc-warnings],
 582                   [turn on lots of GCC warnings (for developers)])],
 583   [case $enableval in
 584      yes|no) ;;
 585      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 586    esac
 587    gl_gcc_warnings=$enableval],
 588   [gl_gcc_warnings=no]
 589 )
 590
 591 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 592 # ------------------------------------------------
 593 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 594 # Otherwise, run RUN-IF-NOT-FOUND.
 595 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 596   [AC_PREPROC_IFELSE(
 597     [AC_LANG_PROGRAM(
 598       [[
 599 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 600 /* ok */
 601 #else
 602 # error "your version of gcc is older than $1.$2"
 603 #endif
 604       ]]),
 605     ], [$3], [$4])
 606   ]
 607 )
 608
 609 # When compiling with GCC, prefer -isystem to -I when including system
 610 # include files, to avoid generating useless diagnostics for the files.
 611 if test "$gl_gcc_warnings" != yes; then
 612   isystem='-I'
 613 else
 614   isystem='-isystem '
 615
 616   # This, $nw, is the list of warnings we disable.
 617   nw=
 618
 619   case $with_x_toolkit in
 620     lucid | athena | motif)
 621        # Old toolkits mishandle 'const'.
 622        nw="$nw -Wwrite-strings"
 623        ;;
 624     *)
 625        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 626        ;;
 627   esac
 628   AC_SUBST([WERROR_CFLAGS])
 629
 630   nw="$nw -Waggregate-return"       # anachronistic
 631   nw="$nw -Wlong-long"              # C90 is anachronistic
 632   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 633   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 634   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 635   nw="$nw -Wcast-qual"              # Too many warnings for now
 636   nw="$nw -Wconversion"             # Too many warnings for now
 637   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 638   nw="$nw -Wsign-conversion"        # Too many warnings for now
 639   nw="$nw -Woverlength-strings"     # Not a problem these days
 640   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 641   nw="$nw -Wpadded"                 # Our structs are not padded
 642   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 643   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 644   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 645   nw="$nw -Wvla"                    # warnings in gettext.h
 646   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 647   nw="$nw -Wswitch-enum"            # Too many warnings for now
 648   nw="$nw -Wswitch-default"         # Too many warnings for now
 649   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 650   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 651
 652   # Emacs doesn't care about shadowing; see
 653   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 654   nw="$nw -Wshadow"
 655
 656   # The following lines should be removable at some point.
 657   nw="$nw -Wstack-protector"
 658   nw="$nw -Wstrict-overflow"
 659   nw="$nw -Wsuggest-attribute=const"
 660   nw="$nw -Wsuggest-attribute=pure"
 661
 662   gl_MANYWARN_ALL_GCC([ws])
 663   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 664   for w in $ws; do
 665     gl_WARN_ADD([$w])
 666   done
 667   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 668   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 669   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 670   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 671   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 672   gl_WARN_ADD([-Wno-format-nonliteral])
 673
 674   # In spite of excluding -Wlogical-op above, it is enabled, as of
 675   # gcc 4.5.0 20090517.
 676   gl_WARN_ADD([-Wno-logical-op])
 677
 678   gl_WARN_ADD([-fdiagnostics-show-option])
 679   gl_WARN_ADD([-funit-at-a-time])
 680
 681   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 682   AC_DEFINE([_FORTIFY_SOURCE], [2],
 683     [enable compile-time and run-time bounds-checking, and some warnings])
 684   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 685
 686   # We use a slightly smaller set of warning options for lib/.
 687   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 688   nw=
 689   nw="$nw -Wunused-macros"
 690
 691   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 692   AC_SUBST([GNULIB_WARN_CFLAGS])
 693 fi
 694
 695
 696
 697 dnl Some other nice autoconf tests.
 698 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 699 dnl AC_PROG_INSTALL
 700 dnl AC_PROG_MKDIR_P
 701 dnl if test "x$RANLIB" = x; then
 702 dnl   AC_PROG_RANLIB
 703 dnl fi
 704
 705 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 706   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 707 dnl Don't use GZIP, which is used by gzip for additional parameters.
 708 AC_PATH_PROG(GZIP_PROG, gzip)
 709
 710 if test $opsys = gnu-linux; then
 711   AC_PATH_PROG(PAXCTL, paxctl,,
 712     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 713 fi
 714
 715 ## Need makeinfo >= 4.7 (?) to build the manuals.
 716 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 717 dnl By this stage, configure has already checked for egrep and set EGREP,
 718 dnl or exited with an error if no egrep was found.
 719 if test "$MAKEINFO" != "no" && \
 720   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 721    MAKEINFO=no
 722 fi
 723
 724 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 725 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 726 ## therefore in the category of "special tools" not normally required, which
 727 ## configure does not have to check for (eg autoconf itself).
 728 ## In a Bazaar checkout on the other hand, the manuals are not included.
 729 ## So makeinfo is a requirement to build from Bazaar, and configure
 730 ## should test for it as it does for any other build requirement.
 731 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 732 ## with pre-built manuals, from a Bazaar checkout.
 733 HAVE_MAKEINFO=yes
 734
 735 if test "$MAKEINFO" = "no"; then
 736   MAKEINFO=makeinfo
 737   if test "x${with_makeinfo}" = "xno"; then
 738     HAVE_MAKEINFO=no
 739   elif test ! -e $srcdir/info/emacs; then
 740     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 741 source tree does not seem to have pre-built manuals in the `info' directory.
 742 Either install a suitable version of makeinfo, or re-run configure
 743 with the `--without-makeinfo' option to build without the manuals.] )
 744   fi
 745 fi
 746 AC_SUBST(HAVE_MAKEINFO)
 747
 748 dnl Just so that there is only a single place we need to edit.
 749 INFO_EXT=.info
 750 INFO_OPTS=--no-split
 751 AC_SUBST(INFO_EXT)
 752 AC_SUBST(INFO_OPTS)
 753
 754 dnl Add our options to ac_link now, after it is set up.
 755
 756 if test x$GCC = xyes; then
 757   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 758     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 759 else
 760   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 761     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 762 fi
 763
 764 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 765 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 766 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 767 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 768 dnl if not built to support GNU ld.
 769
 770 late_LDFLAGS=$LDFLAGS
 771 if test x$GCC = xyes; then
 772   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 773 else
 774   LDFLAGS="$LDFLAGS -znocombreloc"
 775 fi
 776
 777 AC_MSG_CHECKING([for -znocombreloc])
 778 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 779   [AC_MSG_RESULT(yes)],
 780   LDFLAGS=$late_LDFLAGS
 781   [AC_MSG_RESULT(no)])
 782
 783
 784 dnl The function dump-emacs will not be defined and temacs will do
 785 dnl (load "loadup") automatically unless told otherwise.
 786 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 787 case "$opsys" in
 788   your-opsys-here) CANNOT_DUMP=yes ;;
 789 esac
 790
 791 test "$CANNOT_DUMP" = "yes" && \
 792   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 793
 794 AC_SUBST(CANNOT_DUMP)
 795
 796
 797 UNEXEC_OBJ=unexelf.o
 798 case "$opsys" in
 799   # MSDOS uses unexcoff.o
 800   # MSWindows uses unexw32.o
 801   aix4-2)
 802    UNEXEC_OBJ=unexaix.o
 803    ;;
 804   cygwin)
 805    UNEXEC_OBJ=unexcw.o
 806    ;;
 807   darwin)
 808    UNEXEC_OBJ=unexmacosx.o
 809    ;;
 810   hpux10-20 | hpux11)
 811    UNEXEC_OBJ=unexhp9k800.o
 812    ;;
 813   sol2-10)
 814    # Use the Solaris dldump() function, called from unexsol.c, to dump
 815    # emacs, instead of the generic ELF dump code found in unexelf.c.
 816    # The resulting binary has a complete symbol table, and is better
 817    # for debugging and other observability tools (debuggers, pstack, etc).
 818    #
 819    # If you encounter a problem using dldump(), please consider sending
 820    # a message to the OpenSolaris tools-linking mailing list:
 821    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 822    #
 823    # It is likely that dldump() works with older Solaris too, but this has
 824    # not been tested, so for now this change is for Solaris 10 or newer.
 825    UNEXEC_OBJ=unexsol.o
 826    ;;
 827 esac
 828
 829 LD_SWITCH_SYSTEM=
 830 case "$opsys" in
 831   freebsd)
 832    ## Let `ld' find image libs and similar things in /usr/local/lib.
 833    ## The system compiler, GCC, has apparently been modified to not
 834    ## look there, contrary to what a stock GCC would do.
 835 ### It's not our place to do this.  See bug#10313#17.
 836 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 837       :
 838    ;;
 839
 840   gnu-linux)
 841    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 842    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 843    ;;
 844
 845   netbsd)
 846 ### It's not our place to do this.  See bug#10313#17.
 847 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 848       :
 849    ;;
 850
 851   openbsd)
 852    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 853    ## otherwise Emacs dumps core on elf systems.
 854    LD_SWITCH_SYSTEM="-Z"
 855    ;;
 856 esac
 857 AC_SUBST(LD_SWITCH_SYSTEM)
 858
 859 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 860
 861 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 862 ## which has not been defined yet.  When this was handled with cpp,
 863 ## it was expanded to null when configure sourced the s/*.h file.
 864 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 865 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 866 ## (or somesuch), but because it is supposed to go at the _front_
 867 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 868 ## Compare with the gnu-linux case below, which added to the end
 869 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 870 ## LD_SWITCH_SYSTEM_TEMACS.
 871 case "$opsys" in
 872   netbsd|openbsd)
 873    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 874 esac
 875
 876
 877 C_SWITCH_MACHINE=
 878 case $canonical in
 879  alpha*)
 880   AC_CHECK_DECL([__ELF__])
 881   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 882     ## With ELF, make sure that all common symbols get allocated to in the
 883     ## data section.  Otherwise, the dump of temacs may miss variables in
 884     ## the shared library that have been initialized.  For example, with
 885     ## GNU libc, __malloc_initialized would normally be resolved to the
 886     ## shared library's .bss section, which is fatal.
 887     if test "x$GCC" = "xyes"; then
 888       C_SWITCH_MACHINE="-fno-common"
 889     else
 890       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 891     fi
 892   else
 893     UNEXEC_OBJ=unexalpha.o
 894   fi
 895   ;;
 896 esac
 897 AC_SUBST(C_SWITCH_MACHINE)
 898
 899 AC_SUBST(UNEXEC_OBJ)
 900
 901 C_SWITCH_SYSTEM=
 902 ## Some programs in src produce warnings saying certain subprograms
 903 ## are too complex and need a MAXMEM value greater than 2000 for
 904 ## additional optimization.  --nils@exp-math.uni-essen.de
 905 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 906   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 907 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 908 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 909 AC_SUBST(C_SWITCH_SYSTEM)
 910
 911
 912 LIBS_SYSTEM=
 913 case "$opsys" in
 914   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 915   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 916
 917   freebsd) LIBS_SYSTEM="-lutil" ;;
 918
 919   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 920
 921   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 922
 923   ## Motif needs -lgen.
 924   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 925 esac
 926 AC_SUBST(LIBS_SYSTEM)
 927
 928
 929 ### Make sure subsequent tests use flags consistent with the build flags.
 930
 931 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 932   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 933 else
 934   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 935 fi
 936
 937 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 938 AC_DEFUN([AC_TYPE_SIZE_T])
 939 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 940 AC_DEFUN([AC_TYPE_UID_T])
 941
 942
 943 LIB_MATH=-lm
 944 LIB_STANDARD=
 945 START_FILES=
 946 dnl Current possibilities handled by sed (aix4-2 -> aix,
 947 dnl gnu-linux -> gnu/linux, etc.):
 948 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 949 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 950 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 951
 952 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 953 case $opsys in
 954   cygwin )
 955     LIB_MATH=
 956     START_FILES='pre-crt0.o'
 957     ;;
 958   darwin )
 959     ## Adding -lm confuses the dynamic linker, so omit it.
 960     LIB_MATH=
 961     START_FILES='pre-crt0.o'
 962     ;;
 963   freebsd )
 964     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 965     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 966     SYSTEM_TYPE=berkeley-unix
 967     ;;
 968   gnu-linux | gnu-kfreebsd )
 969     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 970     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 971     ;;
 972   hpux10-20 | hpux11 )
 973     LIB_STANDARD=-lc
 974     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
 975     ;;
 976   dnl NB this may be adjusted below.
 977   netbsd | openbsd )
 978     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
 979     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
 980     SYSTEM_TYPE=berkeley-unix
 981     ;;
 982
 983   sol2* | unixware )
 984     SYSTEM_TYPE=usg-unix-v
 985     ;;
 986
 987 esac
 988
 989 AC_SUBST(LIB_MATH)
 990 AC_SUBST(START_FILES)
 991 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
 992   [The type of system you are compiling for; sets `system-type'.])
 993
 994 dnl Not all platforms use crtn.o files.  Check if the current one does.
 995 crt_files=
 996
 997 for file in x $LIB_STANDARD $START_FILES; do
 998   case "$file" in
 999     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
1000   esac
1001 done
1002
1003 if test "x$crt_files" != x; then
1004
1005   ## If user specified a crt-dir, use that unconditionally.
1006   crt_gcc=no
1007
1008   if test "X$CRT_DIR" = "X"; then
1009
1010     CRT_DIR=/usr/lib            # default
1011
1012     case "$canonical" in
1013       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1014       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1015       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1016       ## For anything else (eg /usr/lib32), it is up the user to specify
1017       ## the location (bug#5655).
1018       ## Test for crtn.o, not just the directory, because sometimes the
1019       ## directory exists but does not have the relevant files (bug#1287).
1020       ## FIXME better to test for binary compatibility somehow.
1021       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1022       ;;
1023
1024       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1025     esac
1026
1027     case "$opsys" in
1028       hpux10-20) CRT_DIR=/lib ;;
1029     esac
1030
1031     test "x${GCC}" = xyes && crt_gcc=yes
1032
1033   fi                            # CRT_DIR = ""
1034
1035   crt_missing=
1036
1037   for file in $crt_files; do
1038
1039     ## If we're using gcc, try to determine it automatically by asking
1040     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1041     ## system-dependent default from above.]
1042     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1043
1044        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1045        case "$crt_file" in
1046          */*)
1047            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1048            ;;
1049        esac
1050     fi
1051
1052     dnl We expect all the files to be in a single directory, so after the
1053     dnl first there is no point asking gcc.
1054     crt_gcc=no
1055
1056     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1057   done                          # $crt_files
1058
1059   test "x$crt_missing" = x || \
1060     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1061 Try using the --with-crt-dir option.])
1062
1063 fi                              # crt_files != ""
1064
1065 AC_SUBST(CRT_DIR)
1066
1067 case $opsys in
1068   netbsd | openbsd )
1069     if test -f $CRT_DIR/crti.o; then
1070
1071         test -f $CRT_DIR/crtn.o || \
1072           AC_MSG_ERROR([Required file not found: crtn.o])
1073
1074         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1075         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1076     fi
1077     ;;
1078 esac
1079
1080
1081 # Configure gnulib before invoking PKG_CHECK_MODULES, as the latter might
1082 # for example add -lrt to RSVG_LIBS, which would then cause gnulib to
1083 # incorrectly conclude that -lrt is not needed to link clock_gettime.
1084 gl_ASSERT_NO_GNULIB_POSIXCHECK
1085 gl_ASSERT_NO_GNULIB_TESTS
1086 gl_INIT
1087
1088 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1089
1090 dnl This function definition taken from Gnome 2.0
1091 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1092 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1093 dnl also defines GSTUFF_PKG_ERRORS on error
1094 AC_DEFUN([PKG_CHECK_MODULES], [
1095   succeeded=no
1096
1097   if test "$PKG_CONFIG" = "no" ; then
1098      ifelse([$4], , [AC_MSG_ERROR([
1099       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1100   else
1101      PKG_CONFIG_MIN_VERSION=0.9.0
1102      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1103         AC_MSG_CHECKING(for $2)
1104
1105         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1106            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1107            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1108             edit_cflags="
1109               s,///*,/,g
1110               s/^/ /
1111               s/ -I/ $isystem/g
1112               s/^ //
1113             "
1114             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1115             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1116             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1117             succeeded=yes
1118         else
1119             AC_MSG_RESULT(no)
1120             $1_CFLAGS=""
1121             $1_LIBS=""
1122             ## If we have a custom action on failure, don't print errors, but
1123             ## do set a variable so people can do so.
1124             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1125             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1126         fi
1127
1128         AC_SUBST($1_CFLAGS)
1129         AC_SUBST($1_LIBS)
1130      else
1131         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1132         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1133      fi
1134   fi
1135
1136   if test $succeeded = yes; then
1137      ifelse([$3], , :, [$3])
1138   else
1139      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1140   fi
1141 ])
1142
1143
1144 if test "${with_sound}" != "no"; then
1145   # Sound support for GNU/Linux and the free BSDs.
1146   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1147     have_sound_header=yes)
1148   # Emulation library used on NetBSD.
1149   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1150   AC_SUBST(LIBSOUND)
1151
1152   ALSA_REQUIRED=1.0.0
1153   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1154   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1155   if test $HAVE_ALSA = yes; then
1156     SAVE_CFLAGS="$CFLAGS"
1157     SAVE_LIBS="$LIBS"
1158     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1159     LIBS="$ALSA_LIBS $LIBS"
1160     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1161                     emacs_alsa_normal=yes,
1162                     emacs_alsa_normal=no)
1163     if test "$emacs_alsa_normal" != yes; then
1164       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1165                      [[snd_lib_error_set_handler (0);]])],
1166                      emacs_alsa_subdir=yes,
1167                      emacs_alsa_subdir=no)
1168       if test "$emacs_alsa_subdir" != yes; then
1169         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1170       fi
1171       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1172     fi
1173
1174     CFLAGS="$SAVE_CFLAGS"
1175     LIBS="$SAVE_LIBS"
1176     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1177     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1178     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1179   fi
1180
1181   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1182   dnl compiles only on the specified platforms.  For others, it
1183   dnl probably doesn't make sense to try.
1184   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1185      case "$opsys" in
1186        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1187        gnu-linux|freebsd|netbsd)
1188          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1189          ;;
1190      esac
1191   fi
1192
1193   AC_SUBST(CFLAGS_SOUND)
1194 fi
1195
1196 dnl checks for header files
1197 AC_CHECK_HEADERS_ONCE(
1198   linux/version.h sys/systeminfo.h
1199   stdio_ext.h fcntl.h coff.h pty.h
1200   sys/vlimit.h sys/resource.h
1201   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1202
1203 AC_MSG_CHECKING(if personality LINUX32 can be set)
1204 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1205                emacs_cv_personality_linux32=yes,
1206                emacs_cv_personality_linux32=no)
1207 AC_MSG_RESULT($emacs_cv_personality_linux32)
1208
1209 if test $emacs_cv_personality_linux32 = yes; then
1210   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1211             [Define to 1 if personality LINUX32 can be set.])
1212 fi
1213
1214 dnl On Solaris 8 there's a compilation warning for term.h because
1215 dnl it doesn't define `bool'.
1216 AC_CHECK_HEADERS(term.h, , , -)
1217 AC_HEADER_TIME
1218 AC_CHECK_DECLS([sys_siglist])
1219 if test $ac_cv_have_decl_sys_siglist != yes; then
1220   # For Tru64, at least:
1221   AC_CHECK_DECLS([__sys_siglist])
1222   if test $ac_cv_have_decl___sys_siglist = yes; then
1223     AC_DEFINE(sys_siglist, __sys_siglist,
1224               [Define to any substitute for sys_siglist.])
1225   fi
1226 fi
1227 AC_HEADER_SYS_WAIT
1228
1229 dnl Check for speed_t typedef.
1230 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1231   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1232     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1233 if test $emacs_cv_speed_t = yes; then
1234   AC_DEFINE(HAVE_SPEED_T, 1,
1235            [Define to 1 if `speed_t' is declared by <termios.h>.])
1236 fi
1237
1238 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1239 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1240 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1241   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1242 HAVE_EXCEPTION=$emacs_cv_struct_exception
1243 if test $emacs_cv_struct_exception != yes; then
1244   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1245 fi
1246
1247 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1248 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1249 #if HAVE_SYS_SOCKET_H
1250 #include <sys/socket.h>
1251 #endif])
1252 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1253 #if HAVE_SYS_SOCKET_H
1254 #include <sys/socket.h>
1255 #endif])
1256 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1257 #if HAVE_SYS_SOCKET_H
1258 #include <sys/socket.h>
1259 #endif])
1260
1261 dnl checks for structure members
1262 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1263                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1264                   struct ifreq.ifr_addr,
1265                   struct ifreq.ifr_addr.sa_len], , ,
1266                  [AC_INCLUDES_DEFAULT
1267 #if HAVE_SYS_SOCKET_H
1268 #include <sys/socket.h>
1269 #endif
1270 #if HAVE_NET_IF_H
1271 #include <net/if.h>
1272 #endif])
1273
1274 dnl Check for endianness.
1275 dnl AC_C_BIGENDIAN is done by gnulib.
1276
1277 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1278   [emacs_cv_attribute_aligned],
1279   [AC_COMPILE_IFELSE(
1280      [AC_LANG_PROGRAM(
1281         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1282         [[]])],
1283      [emacs_cv_attribute_aligned=yes],
1284      [emacs_cv_attribute_aligned=no])])
1285 if test $emacs_cv_attribute_aligned = yes; then
1286   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1287     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1288 fi
1289
1290 dnl check for Make feature
1291 dnl AC_PROG_MAKE_SET is done by Automake.
1292
1293 DEPFLAGS=
1294 MKDEPDIR=":"
1295 deps_frag=deps.mk
1296 dnl check for GNU Make if we have GCC and autodepend is on.
1297 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1298    AC_MSG_CHECKING([whether we are using GNU Make])
1299    HAVE_GNU_MAKE=no
1300    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1301    if test "x$testval" != x; then
1302       HAVE_GNU_MAKE=yes
1303    else
1304       ac_enable_autodepend=no
1305    fi
1306    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1307    if test $HAVE_GNU_MAKE = yes; then
1308       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1309       SAVE_CFLAGS="$CFLAGS"
1310       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1311       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1312       CFLAGS="$SAVE_CFLAGS"
1313       test -f deps.d || ac_enable_autodepend=no
1314       rm -rf deps.d
1315       AC_MSG_RESULT([$ac_enable_autodepend])
1316    fi
1317    if test $ac_enable_autodepend = yes; then
1318       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1319       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1320       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1321       deps_frag=autodeps.mk
1322    fi
1323 fi
1324 deps_frag=$srcdir/src/$deps_frag
1325 AC_SUBST(MKDEPDIR)
1326 AC_SUBST(DEPFLAGS)
1327 AC_SUBST_FILE(deps_frag)
1328
1329
1330 lisp_frag=$srcdir/src/lisp.mk
1331 AC_SUBST_FILE(lisp_frag)
1332
1333
1334 dnl checks for operating system services
1335 AC_SYS_LONG_FILE_NAMES
1336
1337 #### Choose a window system.
1338
1339 AC_PATH_X
1340 if test "$no_x" = yes; then
1341   window_system=none
1342 else
1343   window_system=x11
1344 fi
1345
1346 LD_SWITCH_X_SITE_RPATH=
1347 if test "${x_libraries}" != NONE; then
1348   if test -n "${x_libraries}"; then
1349     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1350     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1351   fi
1352   x_default_search_path=""
1353   x_search_path=${x_libraries}
1354   if test -z "${x_search_path}"; then
1355     x_search_path=/usr/lib
1356   fi
1357   for x_library in `echo ${x_search_path}: | \
1358                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1359     x_search_path="\
1360 ${x_library}/X11/%L/%T/%N%C%S:\
1361 ${x_library}/X11/%l/%T/%N%C%S:\
1362 ${x_library}/X11/%T/%N%C%S:\
1363 ${x_library}/X11/%L/%T/%N%S:\
1364 ${x_library}/X11/%l/%T/%N%S:\
1365 ${x_library}/X11/%T/%N%S"
1366     if test x"${x_default_search_path}" = x; then
1367       x_default_search_path=${x_search_path}
1368     else
1369       x_default_search_path="${x_search_path}:${x_default_search_path}"
1370     fi
1371   done
1372 fi
1373 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1374
1375 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1376   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1377 fi
1378
1379 if test x"${x_includes}" = x; then
1380   bitmapdir=/usr/include/X11/bitmaps
1381 else
1382   # accumulate include directories that have X11 bitmap subdirectories
1383   bmd_acc="dummyval"
1384   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1385     if test -d "${bmd}/X11/bitmaps"; then
1386       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1387     fi
1388     if test -d "${bmd}/bitmaps"; then
1389       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1390     fi
1391   done
1392   if test ${bmd_acc} != "dummyval"; then
1393     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1394   fi
1395 fi
1396
1397 HAVE_NS=no
1398 NS_IMPL_COCOA=no
1399 NS_IMPL_GNUSTEP=no
1400 tmp_CPPFLAGS="$CPPFLAGS"
1401 tmp_CFLAGS="$CFLAGS"
1402 CPPFLAGS="$CPPFLAGS -x objective-c"
1403 CFLAGS="$CFLAGS -x objective-c"
1404 TEMACS_LDFLAGS2="\${LDFLAGS}"
1405 GNU_OBJC_CFLAGS=
1406 if test "${with_ns}" != no; then
1407   if test "${opsys}" = darwin; then
1408      NS_IMPL_COCOA=yes
1409      ns_appdir=`pwd`/nextstep/Emacs.app
1410      ns_appbindir=${ns_appdir}/Contents/MacOS
1411      ns_appresdir=${ns_appdir}/Contents/Resources
1412      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1413   elif test -f $GNUSTEP_CONFIG_FILE; then
1414      NS_IMPL_GNUSTEP=yes
1415      ns_appdir=`pwd`/nextstep/Emacs.app
1416      ns_appbindir=${ns_appdir}
1417      ns_appresdir=${ns_appdir}/Resources
1418      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1419      dnl FIXME sourcing this several times in subshells seems inefficient.
1420      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1421      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1422      dnl I seemed to need these as well with GNUstep-startup 0.25.
1423      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1424      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1425      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1426        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1427      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1428        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1429      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1430      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1431      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1432      LIB_STANDARD=
1433      START_FILES=
1434      TEMACS_LDFLAGS2=
1435      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1436      dnl If they had chosen to either define it or not, we could have
1437      dnl just used AC_CHECK_DECL here.
1438      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1439        emacs_cv_objc_exceptions,
1440 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1441 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1442 1;
1443 #else
1444 fail;
1445 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1446      if test $emacs_cv_objc_exceptions = yes; then
1447        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1448        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1449          [Define if GNUstep uses ObjC exceptions.])
1450        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1451      fi
1452   fi
1453
1454   dnl This is only used while we test the NS headers, it gets reset below.
1455   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1456
1457   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1458                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1459   files are missing or cannot be compiled.])])
1460   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1461                                      [NSInteger i;])],
1462                     ns_have_nsinteger=yes,
1463                     ns_have_nsinteger=no)
1464   if test $ns_have_nsinteger = yes; then
1465     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1466   fi
1467 fi
1468 AC_SUBST(TEMACS_LDFLAGS2)
1469
1470 INSTALL_ARCH_INDEP_EXTRA=install-etc
1471 ns_self_contained=no
1472 ns_frag=/dev/null
1473 NS_OBJ=
1474 NS_OBJC_OBJ=
1475 if test "${HAVE_NS}" = yes; then
1476   if test "$with_toolkit_scroll_bars" = "no"; then
1477     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1478   fi
1479
1480   window_system=nextstep
1481   with_xft=no
1482   # set up packaging dirs
1483   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1484      ns_self_contained=yes
1485      prefix=${ns_appresdir}
1486      exec_prefix=${ns_appbindir}
1487      dnl This one isn't really used, only archlibdir is.
1488      libexecdir="\${ns_appbindir}/libexec"
1489      archlibdir="\${ns_appbindir}/libexec"
1490      docdir="\${ns_appresdir}/etc"
1491      etcdir="\${ns_appresdir}/etc"
1492      dnl FIXME maybe set datarootdir instead.
1493      dnl That would also get applications, icons, man.
1494      infodir="\${ns_appresdir}/info"
1495      mandir="\${ns_appresdir}/man"
1496      lispdir="\${ns_appresdir}/lisp"
1497      leimdir="\${ns_appresdir}/leim"
1498      INSTALL_ARCH_INDEP_EXTRA=
1499   fi
1500   ns_frag=$srcdir/src/ns.mk
1501   NS_OBJ="fontset.o fringe.o image.o"
1502   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1503 fi
1504 CFLAGS="$tmp_CFLAGS"
1505 CPPFLAGS="$tmp_CPPFLAGS"
1506 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1507 AC_SUBST(ns_self_contained)
1508 AC_SUBST(NS_OBJ)
1509 AC_SUBST(NS_OBJC_OBJ)
1510 AC_SUBST(LIB_STANDARD)
1511 AC_SUBST_FILE(ns_frag)
1512
1513 case "${window_system}" in
1514   x11 )
1515     HAVE_X_WINDOWS=yes
1516     HAVE_X11=yes
1517     case "${with_x_toolkit}" in
1518       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1519       motif ) USE_X_TOOLKIT=MOTIF ;;
1520       gtk ) with_gtk=yes
1521 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1522 dnl USE_X_TOOLKIT is set.
1523             USE_X_TOOLKIT=none ;;
1524       gtk3 ) with_gtk3=yes
1525              USE_X_TOOLKIT=none ;;
1526       no ) USE_X_TOOLKIT=none ;;
1527 dnl If user did not say whether to use a toolkit, make this decision later:
1528 dnl use the toolkit if we have gtk, or X11R5 or newer.
1529       * ) USE_X_TOOLKIT=maybe ;;
1530     esac
1531   ;;
1532   nextstep | none )
1533     HAVE_X_WINDOWS=no
1534     HAVE_X11=no
1535     USE_X_TOOLKIT=none
1536   ;;
1537 esac
1538
1539 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1540    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1541    if test "$HAVE_XSERVER" = true ||
1542       test -n "$DISPLAY" ||
1543       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1544         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1545 were found.  You should install the relevant development files for X
1546 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1547 sure you have development files for image handling, i.e.
1548 tiff, gif, jpeg, png and xpm.
1549 If you are sure you want Emacs compiled without X window support, pass
1550   --without-x
1551 to configure.])
1552    fi
1553 fi
1554
1555 ### If we're using X11, we should use the X menu package.
1556 HAVE_MENUS=no
1557 case ${HAVE_X11} in
1558   yes ) HAVE_MENUS=yes ;;
1559 esac
1560
1561 # Does the opsystem file prohibit the use of the GNU malloc?
1562 # Assume not, until told otherwise.
1563 GNU_MALLOC=yes
1564
1565 AC_CACHE_CHECK(
1566   [whether malloc is Doug Lea style],
1567   [emacs_cv_var_doug_lea_malloc],
1568   [AC_LINK_IFELSE(
1569      [AC_LANG_PROGRAM(
1570         [[#include <malloc.h>
1571           static void hook (void) {}]],
1572         [[malloc_set_state (malloc_get_state ());
1573           __after_morecore_hook = hook;
1574           __malloc_initialize_hook = hook;]])],
1575      [emacs_cv_var_doug_lea_malloc=yes],
1576      [emacs_cv_var_doug_lea_malloc=no])])
1577 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1578
1579
1580 dnl See comments in aix4-2.h about maybe using system malloc there.
1581 system_malloc=no
1582 case "$opsys" in
1583   ## darwin ld insists on the use of malloc routines in the System framework.
1584   darwin|sol2-10) system_malloc=yes ;;
1585 esac
1586
1587 if test "${system_malloc}" = "yes"; then
1588   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1589   GNU_MALLOC=no
1590   GNU_MALLOC_reason="
1591     (The GNU allocators don't work with this system configuration.)"
1592   GMALLOC_OBJ=
1593   VMLIMIT_OBJ=
1594 else
1595   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1596   VMLIMIT_OBJ=vm-limit.o
1597 fi
1598 AC_SUBST(GMALLOC_OBJ)
1599 AC_SUBST(VMLIMIT_OBJ)
1600
1601 if test "$doug_lea_malloc" = "yes" ; then
1602   if test "$GNU_MALLOC" = yes ; then
1603     GNU_MALLOC_reason="
1604       (Using Doug Lea's new malloc from the GNU C Library.)"
1605   fi
1606   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1607             [Define to 1 if you are using the GNU C Library.])
1608
1609   ## Use mmap directly for allocating larger buffers.
1610   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1611   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1612   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1613   case "$opsys" in
1614     gnu*) REL_ALLOC=no ;;
1615   esac
1616 fi
1617
1618 if test x"${REL_ALLOC}" = x; then
1619   REL_ALLOC=${GNU_MALLOC}
1620 fi
1621
1622 use_mmap_for_buffers=no
1623 case "$opsys" in
1624   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1625 esac
1626
1627 AC_FUNC_MMAP
1628 if test $use_mmap_for_buffers = yes; then
1629   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1630   REL_ALLOC=no
1631 fi
1632
1633 LIBS="$LIBS_SYSTEM $LIBS"
1634
1635 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1636 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1637 AC_CHECK_LIB(dnet, dnet_ntoa)
1638 dnl This causes -lresolv to get used in subsequent tests,
1639 dnl which causes failures on some systems such as HPUX 9.
1640 dnl AC_CHECK_LIB(resolv, gethostbyname)
1641
1642 dnl FIXME replace main with a function we actually want from this library.
1643 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1644
1645 dnl Check if pthreads is available.
1646 LIB_PTHREAD=
1647 AC_CHECK_HEADERS_ONCE(pthread.h)
1648 if test "$ac_cv_header_pthread_h"; then
1649   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1650   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1651   dnl testing for pthread_self if Emacs uses gmalloc.c.
1652   if test "$GMALLOC_OBJ" = gmalloc.o; then
1653     emacs_pthread_function=pthread_atfork
1654   else
1655     emacs_pthread_function=pthread_self
1656   fi
1657   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1658 fi
1659 if test "$HAVE_PTHREAD" = yes; then
1660   case "${canonical}" in
1661     *-hpux*) ;;
1662     *) LIB_PTHREAD="-lpthread"
1663        LIBS="$LIB_PTHREAD $LIBS" ;;
1664   esac
1665   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1666 fi
1667 AC_SUBST([LIB_PTHREAD])
1668
1669 AC_CHECK_LIB(pthreads, cma_open)
1670
1671 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1672 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1673 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1674 ## added to LIBS in configure would never contain the pthreads part,
1675 ## but the value used in Makefiles might.  FIXME?
1676 ##
1677 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1678 ## be harmless on older versions of X where it happens to exist.
1679 test "$opsys" = "aix4-2" && \
1680   test $ac_cv_lib_pthreads_cma_open = yes && \
1681   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1682
1683 dnl Check for need for bigtoc support on IBM AIX
1684
1685 case ${host_os} in
1686 aix*)
1687   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1688     case $GCC in
1689     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1690     *) gdb_cv_bigtoc=-bbigtoc ;;
1691     esac
1692
1693     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1694     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1695   ])
1696   ;;
1697 esac
1698
1699 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1700 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1701 # REAL_CPPFLAGS later on.
1702
1703 REAL_CFLAGS="$CFLAGS"
1704 REAL_CPPFLAGS="$CPPFLAGS"
1705
1706 if test "${HAVE_X11}" = "yes"; then
1707   DEFS="$C_SWITCH_X_SITE $DEFS"
1708   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1709   LIBS="-lX11 $LIBS"
1710   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1711   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1712
1713   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1714   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1715   # but it's more convenient here to set LD_RUN_PATH since this
1716   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1717   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1718     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1719     export LD_RUN_PATH
1720   fi
1721
1722   if test "${opsys}" = "gnu-linux"; then
1723     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1724     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1725      [[XOpenDisplay ("foo");]])],
1726      [xgnu_linux_first_failure=no],
1727      [xgnu_linux_first_failure=yes])
1728     if test "${xgnu_linux_first_failure}" = "yes"; then
1729       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1730       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1731       OLD_CPPFLAGS="$CPPFLAGS"
1732       OLD_LIBS="$LIBS"
1733       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1734       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1735       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1736       LIBS="$LIBS -b i486-linuxaout"
1737       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1738        [[XOpenDisplay ("foo");]])],
1739        [xgnu_linux_second_failure=no],
1740        [xgnu_linux_second_failure=yes])
1741       if test "${xgnu_linux_second_failure}" = "yes"; then
1742         # If we get the same failure with -b, there is no use adding -b.
1743         # So take it out.  This plays safe.
1744         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1745         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1746         CPPFLAGS="$OLD_CPPFLAGS"
1747         LIBS="$OLD_LIBS"
1748         AC_MSG_RESULT(no)
1749       else
1750         AC_MSG_RESULT(yes)
1751       fi
1752     else
1753       AC_MSG_RESULT(no)
1754     fi
1755   fi
1756
1757   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1758   # header files included from there.
1759   AC_MSG_CHECKING(for Xkb)
1760   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1761 #include <X11/XKBlib.h>]],
1762         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1763         emacs_xkb=yes, emacs_xkb=no)
1764   AC_MSG_RESULT($emacs_xkb)
1765   if test $emacs_xkb = yes; then
1766     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1767   fi
1768
1769   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1770 XScreenNumberOfScreen)
1771 fi
1772
1773 if test "${window_system}" = "x11"; then
1774   AC_MSG_CHECKING(X11 version 6)
1775   AC_CACHE_VAL(emacs_cv_x11_version_6,
1776   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1777 [[#if XlibSpecificationRelease < 6
1778 fail;
1779 #endif
1780 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1781   if test $emacs_cv_x11_version_6 = yes; then
1782     AC_MSG_RESULT(6 or newer)
1783     AC_DEFINE(HAVE_X11R6, 1,
1784               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1785     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1786     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1787     ## XIM support.
1788     case "$opsys" in
1789       sol2-*) : ;;
1790       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1791            [Define if you have usable X11R6-style XIM support.])
1792          ;;
1793     esac
1794   else
1795     AC_MSG_RESULT(before 6)
1796   fi
1797 fi
1798
1799
1800 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1801 HAVE_RSVG=no
1802 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1803   if test "${with_rsvg}" != "no"; then
1804     RSVG_REQUIRED=2.11.0
1805     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1806
1807     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1808     AC_SUBST(RSVG_CFLAGS)
1809     AC_SUBST(RSVG_LIBS)
1810
1811     if test $HAVE_RSVG = yes; then
1812       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1813       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1814       LIBS="$RSVG_LIBS $LIBS"
1815     fi
1816   fi
1817 fi
1818
1819 HAVE_IMAGEMAGICK=no
1820 if test "${HAVE_X11}" = "yes"; then
1821   if test "${with_imagemagick}" != "no"; then
1822     ## 6.2.8 is the earliest version known to work, but earlier versions
1823     ## might work - let us know if you find one.
1824     ## 6.0.7 does not work.  See bug#7955.
1825     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1826     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1827     AC_SUBST(IMAGEMAGICK_CFLAGS)
1828     AC_SUBST(IMAGEMAGICK_LIBS)
1829
1830     if test $HAVE_IMAGEMAGICK = yes; then
1831       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1832       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1833       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1834       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1835     fi
1836   fi
1837 fi
1838
1839
1840 HAVE_GTK=no
1841 GTK_OBJ=
1842 if test "${with_gtk3}" = "yes"; then
1843   GLIB_REQUIRED=2.28
1844   GTK_REQUIRED=3.0
1845   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1846
1847   dnl Checks for libraries.
1848   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1849   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1850      AC_MSG_ERROR($GTK_PKG_ERRORS)
1851   fi
1852   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1853   GTK_OBJ=emacsgtkfixed.o
1854 fi
1855
1856 if test "$pkg_check_gtk" != "yes"; then
1857   HAVE_GTK=no
1858 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1859   GLIB_REQUIRED=2.10
1860   GTK_REQUIRED=2.10
1861   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1862
1863   dnl Checks for libraries.
1864   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1865   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1866      AC_MSG_ERROR($GTK_PKG_ERRORS)
1867   fi
1868 fi
1869 fi
1870
1871 if test x"$pkg_check_gtk" = xyes; then
1872
1873   AC_SUBST(GTK_CFLAGS)
1874   AC_SUBST(GTK_LIBS)
1875   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1876   CFLAGS="$CFLAGS $GTK_CFLAGS"
1877   LIBS="$GTK_LIBS $LIBS"
1878   dnl Try to compile a simple GTK program.
1879   GTK_COMPILES=no
1880   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1881   if test "${GTK_COMPILES}" != "yes"; then
1882     if test "$USE_X_TOOLKIT" != "maybe"; then
1883       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1884     fi
1885   else
1886     HAVE_GTK=yes
1887     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1888     GTK_OBJ="gtkutil.o $GTK_OBJ"
1889     USE_X_TOOLKIT=none
1890     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1891       :
1892     else
1893       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1894        closing open displays.  This is no problem if you just use
1895        one display, but if you use more than one and close one of them
1896        Emacs may crash.]])
1897       sleep 3
1898     fi
1899   fi
1900
1901 fi
1902 AC_SUBST(GTK_OBJ)
1903
1904
1905 if test "${HAVE_GTK}" = "yes"; then
1906
1907   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1908   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1909   if test "$with_toolkit_scroll_bars" != no; then
1910     with_toolkit_scroll_bars=yes
1911   fi
1912
1913   dnl  Check if we have the old file selection dialog declared and
1914   dnl  in the link library.  In 2.x it may be in the library,
1915   dnl  but not declared if deprecated featured has been selected out.
1916   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1917   HAVE_GTK_FILE_SELECTION=no
1918   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1919                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1920 #include <gtk/gtk.h>])
1921   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1922     AC_CHECK_FUNCS(gtk_file_selection_new)
1923   fi
1924
1925
1926   dnl Check for functions introduced in 2.14 and later.
1927   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1928                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1929                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1930                  gtk_orientable_set_orientation \
1931                  gtk_window_set_has_resize_grip)
1932 fi
1933
1934 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1935 dnl other platforms.
1936 HAVE_DBUS=no
1937 DBUS_OBJ=
1938 if test "${with_dbus}" = "yes"; then
1939    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1940    if test "$HAVE_DBUS" = yes; then
1941      LIBS="$LIBS $DBUS_LIBS"
1942      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1943      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1944      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1945      dnl D-Bus 1.5.12.
1946      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1947                     dbus_type_is_valid \
1948                     dbus_validate_bus_name \
1949                     dbus_validate_path \
1950                     dbus_validate_interface \
1951                     dbus_validate_member)
1952      DBUS_OBJ=dbusbind.o
1953    fi
1954 fi
1955 AC_SUBST(DBUS_OBJ)
1956
1957 dnl GSettings has been tested under GNU/Linux only.
1958 HAVE_GSETTINGS=no
1959 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1960    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1961    if test "$HAVE_GSETTINGS" = "yes"; then
1962       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1963       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1964       SETTINGS_LIBS="$GSETTINGS_LIBS"
1965    fi
1966 fi
1967
1968 dnl GConf has been tested under GNU/Linux only.
1969 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1970 HAVE_GCONF=no
1971 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1972    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1973    if test "$HAVE_GCONF" = yes; then
1974       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1975       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1976       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
1977       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
1978    fi
1979 fi
1980
1981 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
1982     SAVE_CFLAGS="$CFLAGS"
1983     SAVE_LIBS="$LIBS"
1984     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
1985     LIBS="$SETTINGS_LIBS $LIBS"
1986     AC_CHECK_FUNCS([g_type_init])
1987     CFLAGS="$SAVE_CFLAGS"
1988     LIBS="$SAVE_LIBS"
1989 fi
1990 AC_SUBST(SETTINGS_CFLAGS)
1991 AC_SUBST(SETTINGS_LIBS)
1992
1993
1994 dnl SELinux is available for GNU/Linux only.
1995 HAVE_LIBSELINUX=no
1996 LIBSELINUX_LIBS=
1997 if test "${with_selinux}" = "yes"; then
1998    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1999    if test "$HAVE_LIBSELINUX" = yes; then
2000       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2001       LIBSELINUX_LIBS=-lselinux
2002    fi
2003 fi
2004 AC_SUBST(LIBSELINUX_LIBS)
2005
2006 HAVE_GNUTLS=no
2007 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2008 if test "${with_gnutls}" = "yes" ; then
2009   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2010   if test "${HAVE_GNUTLS}" = "yes"; then
2011     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2012   fi
2013
2014   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2015   LIBS="$LIBGNUTLS_LIBS $LIBS"
2016   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2017
2018   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2019     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2020   fi
2021 fi
2022
2023 AC_SUBST(LIBGNUTLS_LIBS)
2024 AC_SUBST(LIBGNUTLS_CFLAGS)
2025
2026 dnl Do not put whitespace before the #include statements below.
2027 dnl Older compilers (eg sunos4 cc) choke on it.
2028 HAVE_XAW3D=no
2029 LUCID_LIBW=
2030 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2031   if test "$with_xaw3d" != no; then
2032     AC_MSG_CHECKING(for xaw3d)
2033     AC_CACHE_VAL(emacs_cv_xaw3d,
2034     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2035 #include <X11/Intrinsic.h>
2036 #include <X11/Xaw3d/Simple.h>]],
2037       [[]])],
2038       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2039                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2040       emacs_cv_xaw3d=no)])
2041   else
2042     emacs_cv_xaw3d=no
2043   fi
2044   if test $emacs_cv_xaw3d = yes; then
2045     AC_MSG_RESULT([yes; using Lucid toolkit])
2046     USE_X_TOOLKIT=LUCID
2047     HAVE_XAW3D=yes
2048     LUCID_LIBW=-lXaw3d
2049     AC_DEFINE(HAVE_XAW3D, 1,
2050               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2051   else
2052     AC_MSG_RESULT(no)
2053     AC_MSG_CHECKING(for libXaw)
2054     AC_CACHE_VAL(emacs_cv_xaw,
2055     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2056 #include <X11/Intrinsic.h>
2057 #include <X11/Xaw/Simple.h>]],
2058       [[]])],
2059       emacs_cv_xaw=yes,
2060       emacs_cv_xaw=no)])
2061     if test $emacs_cv_xaw = yes; then
2062       AC_MSG_RESULT([yes; using Lucid toolkit])
2063       USE_X_TOOLKIT=LUCID
2064       LUCID_LIBW=-lXaw
2065     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2066       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2067     else
2068       AC_MSG_ERROR([No X toolkit could be found.
2069 If you are sure you want Emacs compiled without an X toolkit, pass
2070   --with-x-toolkit=no
2071 to configure.  Otherwise, install the development libraries for the toolkit
2072 that you want to use (e.g. Gtk+) and re-run configure.])
2073     fi
2074   fi
2075 fi
2076
2077 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2078
2079 LIBXTR6=
2080 if test "${USE_X_TOOLKIT}" != "none"; then
2081   AC_MSG_CHECKING(X11 toolkit version)
2082   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2083   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2084 [[#if XtSpecificationRelease < 6
2085 fail;
2086 #endif
2087 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2088   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2089   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2090     AC_MSG_RESULT(6 or newer)
2091     AC_DEFINE(HAVE_X11XTR6, 1,
2092               [Define to 1 if you have the X11R6 or newer version of Xt.])
2093     LIBXTR6="-lSM -lICE"
2094     case "$opsys" in
2095       ## Use libw.a along with X11R6 Xt.
2096       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2097     esac
2098   else
2099     AC_MSG_RESULT(before 6)
2100   fi
2101
2102 dnl If using toolkit, check whether libXmu.a exists.
2103 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2104   OLDLIBS="$LIBS"
2105   if test x$HAVE_X11XTR6 = xyes; then
2106     LIBS="-lXt -lSM -lICE $LIBS"
2107   else
2108     LIBS="-lXt $LIBS"
2109   fi
2110   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2111   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2112 fi
2113 AC_SUBST(LIBXTR6)
2114
2115 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2116 dnl Why not just test for libxmu in the normal way?
2117 LIBXMU=-lXmu
2118 case $opsys in
2119   ## These systems don't supply Xmu.
2120   hpux* | aix4-2 )
2121     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2122     ;;
2123 esac
2124 AC_SUBST(LIBXMU)
2125
2126 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2127 if test "${HAVE_X11}" = "yes"; then
2128   if test "${USE_X_TOOLKIT}" != "none"; then
2129     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2130   fi
2131 fi
2132
2133 LIBXP=
2134 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2135   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2136   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2137     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2138 int x = 5;
2139 #else
2140 Motif version prior to 2.1.
2141 #endif]])],
2142     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2143   if test $emacs_cv_motif_version_2_1 = yes; then
2144     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2145   else
2146     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2147     # We put this in CFLAGS temporarily to precede other -I options
2148     # that might be in CFLAGS temporarily.
2149     # We put this in CPPFLAGS where it precedes the other -I options.
2150     OLD_CPPFLAGS=$CPPFLAGS
2151     OLD_CFLAGS=$CFLAGS
2152     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2153     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2154     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2155       [[int x = 5;]])],
2156       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2157     if test $emacs_cv_lesstif = yes; then
2158       # Make sure this -I option remains in CPPFLAGS after it is set
2159       # back to REAL_CPPFLAGS.
2160       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2161       # have those other -I options anyway.  Ultimately, having this
2162       # directory ultimately in CPPFLAGS will be enough.
2163       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2164       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2165     else
2166       CFLAGS=$OLD_CFLAGS
2167       CPPFLAGS=$OLD_CPPFLAGS
2168     fi
2169   fi
2170   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2171     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2172 fi
2173
2174 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2175 dnl using Motif or Xaw3d is available, and unless
2176 dnl --with-toolkit-scroll-bars=no was specified.
2177
2178 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2179             [Define to 1 if we should use toolkit scroll bars.])dnl
2180 USE_TOOLKIT_SCROLL_BARS=no
2181 if test "${with_toolkit_scroll_bars}" != "no"; then
2182   if test "${USE_X_TOOLKIT}" != "none"; then
2183     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2184       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2185       HAVE_XAW3D=no
2186       USE_TOOLKIT_SCROLL_BARS=yes
2187     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2188       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2189       USE_TOOLKIT_SCROLL_BARS=yes
2190     fi
2191   elif test "${HAVE_GTK}" = "yes"; then
2192     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2193     USE_TOOLKIT_SCROLL_BARS=yes
2194   elif test "${HAVE_NS}" = "yes"; then
2195     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2196     USE_TOOLKIT_SCROLL_BARS=yes
2197   fi
2198 fi
2199
2200 dnl See if XIM is available.
2201 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2202           #include <X11/Xlib.h>
2203           #include <X11/Xresource.h>]],
2204          [[XIMProc  callback;]])],
2205          [HAVE_XIM=yes
2206          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2207          HAVE_XIM=no)
2208
2209 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2210
2211 if test "${with_xim}" != "no"; then
2212   AC_DEFINE(USE_XIM, 1,
2213             [Define to 1 if we should use XIM, if it is available.])
2214 fi
2215
2216
2217 if test "${HAVE_XIM}" != "no"; then
2218   late_CFLAGS=$CFLAGS
2219   if test "$GCC" = yes; then
2220     CFLAGS="$CFLAGS --pedantic-errors"
2221   fi
2222   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2223 #include <X11/Xlib.h>
2224 #include <X11/Xresource.h>]],
2225 [[Display *display;
2226 XrmDatabase db;
2227 char *res_name;
2228 char *res_class;
2229 XIMProc  callback;
2230 XPointer *client_data;
2231 #ifndef __GNUC__
2232 /* If we're not using GCC, it's probably not XFree86, and this is
2233    probably right, but we can't use something like --pedantic-errors.  */
2234 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2235                                            char*, XIMProc, XPointer*);
2236 #endif
2237 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2238    client_data);]])],
2239     [emacs_cv_arg6_star=yes])
2240   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2241          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2242 either XPointer or XPointer*.])dnl
2243   if test "$emacs_cv_arg6_star" = yes; then
2244     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2245   else
2246     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2247   fi
2248   CFLAGS=$late_CFLAGS
2249 fi
2250
2251 ### Start of font-backend (under any platform) section.
2252 # (nothing here yet -- this is a placeholder)
2253 ### End of font-backend (under any platform) section.
2254
2255 ### Start of font-backend (under X11) section.
2256 if test "${HAVE_X11}" = "yes"; then
2257    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2258
2259    ## Use -lXft if available, unless `--with-xft=no'.
2260    HAVE_XFT=maybe
2261     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2262       with_xft="no";
2263     fi
2264     if test "x${with_xft}" != "xno"; then
2265
2266       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2267       ## Because xftfont.c uses XRenderQueryExtension, we also
2268       ## need to link to -lXrender.
2269       HAVE_XRENDER=no
2270       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2271       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2272         OLD_CPPFLAGS="$CPPFLAGS"
2273         OLD_CFLAGS="$CFLAGS"
2274         OLD_LIBS="$LIBS"
2275         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2276         CFLAGS="$CFLAGS $XFT_CFLAGS"
2277         XFT_LIBS="-lXrender $XFT_LIBS"
2278         LIBS="$XFT_LIBS $LIBS"
2279         AC_CHECK_HEADER(X11/Xft/Xft.h,
2280           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2281
2282         if test "${HAVE_XFT}" = "yes"; then
2283           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2284             AC_SUBST(XFT_LIBS)
2285           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2286         else
2287           CPPFLAGS="$OLD_CPPFLAGS"
2288           CFLAGS="$OLD_CFLAGS"
2289           LIBS="$OLD_LIBS"
2290         fi                        # "${HAVE_XFT}" = "yes"
2291       fi                          # "$HAVE_XFT" != no
2292     fi                            # "x${with_xft}" != "xno"
2293
2294     ## We used to allow building with FreeType and without Xft.
2295     ## However, the ftx font backend driver is not in good shape.
2296     if test "$HAVE_XFT" != "yes"; then
2297        dnl For the "Does Emacs use" message at the end.
2298        HAVE_XFT=no
2299        HAVE_FREETYPE=no
2300     else
2301        dnl Strict linkers fail with
2302        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2303        dnl if -lfreetype is not specified.
2304        dnl The following is needed to set FREETYPE_LIBS.
2305        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2306                          HAVE_FREETYPE=no)
2307
2308        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2309     fi
2310
2311     HAVE_LIBOTF=no
2312     if test "${HAVE_FREETYPE}" = "yes"; then
2313       AC_DEFINE(HAVE_FREETYPE, 1,
2314                 [Define to 1 if using the freetype and fontconfig libraries.])
2315       if test "${with_libotf}" != "no"; then
2316         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2317                           HAVE_LIBOTF=no)
2318         if test "$HAVE_LIBOTF" = "yes"; then
2319           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2320           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2321                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2322                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2323           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2324             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2325                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2326           fi
2327         fi
2328       fi
2329     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2330     dnl Does the new font backend require it, or can it work without it?
2331     fi
2332
2333     HAVE_M17N_FLT=no
2334     if test "${HAVE_LIBOTF}" = yes; then
2335       if test "${with_m17n_flt}" != "no"; then
2336         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2337         if test "$HAVE_M17N_FLT" = "yes"; then
2338           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2339         fi
2340       fi
2341     fi
2342 else
2343     HAVE_XFT=no
2344     HAVE_FREETYPE=no
2345     HAVE_LIBOTF=no
2346     HAVE_M17N_FLT=no
2347 fi
2348
2349 ### End of font-backend (under X11) section.
2350
2351 AC_SUBST(FREETYPE_CFLAGS)
2352 AC_SUBST(FREETYPE_LIBS)
2353 AC_SUBST(FONTCONFIG_CFLAGS)
2354 AC_SUBST(FONTCONFIG_LIBS)
2355 AC_SUBST(LIBOTF_CFLAGS)
2356 AC_SUBST(LIBOTF_LIBS)
2357 AC_SUBST(M17N_FLT_CFLAGS)
2358 AC_SUBST(M17N_FLT_LIBS)
2359
2360 ### Use -lXpm if available, unless `--with-xpm=no'.
2361 HAVE_XPM=no
2362 LIBXPM=
2363 if test "${HAVE_X11}" = "yes"; then
2364   if test "${with_xpm}" != "no"; then
2365     AC_CHECK_HEADER(X11/xpm.h,
2366       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2367     if test "${HAVE_XPM}" = "yes"; then
2368       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2369       AC_EGREP_CPP(no_return_alloc_pixels,
2370       [#include "X11/xpm.h"
2371 #ifndef XpmReturnAllocPixels
2372 no_return_alloc_pixels
2373 #endif
2374       ], HAVE_XPM=no, HAVE_XPM=yes)
2375
2376       if test "${HAVE_XPM}" = "yes"; then
2377         AC_MSG_RESULT(yes)
2378       else
2379         AC_MSG_RESULT(no)
2380       fi
2381     fi
2382   fi
2383
2384   if test "${HAVE_XPM}" = "yes"; then
2385     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2386     LIBXPM=-lXpm
2387   fi
2388 fi
2389 AC_SUBST(LIBXPM)
2390
2391 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2392 HAVE_JPEG=no
2393 LIBJPEG=
2394 if test "${HAVE_X11}" = "yes"; then
2395   if test "${with_jpeg}" != "no"; then
2396     dnl Checking for jpeglib.h can lose because of a redefinition of
2397     dnl  HAVE_STDLIB_H.
2398     AC_CHECK_HEADER(jerror.h,
2399       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2400   fi
2401
2402   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2403   if test "${HAVE_JPEG}" = "yes"; then
2404     AC_DEFINE(HAVE_JPEG)
2405     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2406         [#include <jpeglib.h>
2407          version=JPEG_LIB_VERSION
2408 ],
2409         [AC_DEFINE(HAVE_JPEG)],
2410         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2411         HAVE_JPEG=no])
2412   fi
2413   if test "${HAVE_JPEG}" = "yes"; then
2414     LIBJPEG=-ljpeg
2415   fi
2416 fi
2417 AC_SUBST(LIBJPEG)
2418
2419 ### Use -lpng if available, unless `--with-png=no'.
2420 HAVE_PNG=no
2421 LIBPNG=
2422 if test "${HAVE_X11}" = "yes"; then
2423   if test "${with_png}" != "no"; then
2424     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2425     # in /usr/include/libpng.
2426     AC_CHECK_HEADERS(png.h libpng/png.h)
2427     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2428       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2429     fi
2430   fi
2431
2432   if test "${HAVE_PNG}" = "yes"; then
2433     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2434     LIBPNG="-lpng -lz -lm"
2435   fi
2436 fi
2437 AC_SUBST(LIBPNG)
2438
2439 ### Use -ltiff if available, unless `--with-tiff=no'.
2440 HAVE_TIFF=no
2441 LIBTIFF=
2442 if test "${HAVE_X11}" = "yes"; then
2443   if test "${with_tiff}" != "no"; then
2444     AC_CHECK_HEADER(tiffio.h,
2445       [tifflibs="-lz -lm"
2446       # At least one tiff package requires the jpeg library.
2447       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2448       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2449   fi
2450
2451   if test "${HAVE_TIFF}" = "yes"; then
2452     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2453     dnl FIXME -lz -lm, as per libpng?
2454     LIBTIFF=-ltiff
2455   fi
2456 fi
2457 AC_SUBST(LIBTIFF)
2458
2459 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2460 HAVE_GIF=no
2461 LIBGIF=
2462 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2463   AC_CHECK_HEADER(gif_lib.h,
2464 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2465 # Earlier versions can crash Emacs.
2466     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2467
2468   if test "$HAVE_GIF" = yes; then
2469     LIBGIF=-lgif
2470   elif test "$HAVE_GIF" = maybe; then
2471 # If gif_lib.h but no libgif, try libungif.
2472     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2473     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2474   fi
2475
2476   if test "${HAVE_GIF}" = "yes"; then
2477     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2478   fi
2479 fi
2480 AC_SUBST(LIBGIF)
2481
2482 dnl Check for required libraries.
2483 if test "${HAVE_X11}" = "yes"; then
2484   MISSING=""
2485   WITH_NO=""
2486   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2487     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2488   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2489     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2490   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2491     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2492   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2493     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2494   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2495     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2496
2497   if test "X${MISSING}" != X; then
2498     AC_MSG_ERROR([The following required libraries were not found:
2499     $MISSING
2500 Maybe some development libraries/packages are missing?
2501 If you don't want to link with them give
2502     $WITH_NO
2503 as options to configure])
2504   fi
2505 fi
2506
2507 ### Use -lgpm if available, unless `--with-gpm=no'.
2508 HAVE_GPM=no
2509 LIBGPM=
2510 if test "${with_gpm}" != "no"; then
2511   AC_CHECK_HEADER(gpm.h,
2512     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2513
2514   if test "${HAVE_GPM}" = "yes"; then
2515     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2516     LIBGPM=-lgpm
2517   fi
2518 fi
2519 AC_SUBST(LIBGPM)
2520
2521 dnl Check for malloc/malloc.h on darwin
2522 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2523
2524 GNUSTEP_CFLAGS=
2525 ### Use NeXTstep API to implement GUI.
2526 if test "${HAVE_NS}" = "yes"; then
2527   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2528   if test "${NS_IMPL_COCOA}" = "yes"; then
2529     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2530   fi
2531   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2532     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2533     # See also .m.o rule in Makefile.in */
2534     # FIXME: are all these flags really needed?  Document here why.  */
2535     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2536     ## Extra CFLAGS applied to src/*.m files.
2537     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2538   fi
2539   # We also have mouse menus.
2540   HAVE_MENUS=yes
2541   OTHER_FILES=ns-app
2542 fi
2543
2544
2545 ### Use session management (-lSM -lICE) if available
2546 HAVE_X_SM=no
2547 LIBXSM=
2548 if test "${HAVE_X11}" = "yes"; then
2549   AC_CHECK_HEADER(X11/SM/SMlib.h,
2550     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2551
2552   if test "${HAVE_X_SM}" = "yes"; then
2553     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2554     LIBXSM="-lSM -lICE"
2555     case "$LIBS" in
2556       *-lSM*) ;;
2557       *)      LIBS="$LIBXSM $LIBS" ;;
2558     esac
2559   fi
2560 fi
2561 AC_SUBST(LIBXSM)
2562
2563 ### Use libxml (-lxml2) if available
2564 HAVE_LIBXML2=no
2565 if test "${with_xml2}" != "no"; then
2566   ### I'm not sure what the version number should be, so I just guessed.
2567   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2568   if test "${HAVE_LIBXML2}" = "yes"; then
2569     LIBS="$LIBXML2_LIBS $LIBS"
2570     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2571     if test "${HAVE_LIBXML2}" = "yes"; then
2572       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2573     else
2574       LIBXML2_LIBS=""
2575       LIBXML2_CFLAGS=""
2576     fi
2577   fi
2578 fi
2579 AC_SUBST(LIBXML2_LIBS)
2580 AC_SUBST(LIBXML2_CFLAGS)
2581
2582 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2583 AC_CACHE_CHECK(whether netdb declares h_errno,
2584                emacs_cv_netdb_declares_h_errno,
2585 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2586   [[return h_errno;]])],
2587   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2588 if test $emacs_cv_netdb_declares_h_errno = yes; then
2589   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2590 fi
2591
2592 # fmod, logb, and frexp are found in -lm on most systems.
2593 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2594 AC_CHECK_LIB(m, sqrt)
2595
2596 # Check for mail-locking functions in a "mail" library.  Probably this should
2597 # have the same check as for liblockfile below.
2598 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2599 if test $have_mail = yes; then
2600   LIBS_MAIL=-lmail
2601   LIBS="$LIBS_MAIL $LIBS"
2602   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2603 else
2604   LIBS_MAIL=
2605 fi
2606 dnl Debian, at least:
2607 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2608 if test $have_lockfile = yes; then
2609    LIBS_MAIL=-llockfile
2610    LIBS="$LIBS_MAIL $LIBS"
2611    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2612 else
2613 # If we have the shared liblockfile, assume we must use it for mail
2614 # locking (e.g. Debian).  If we couldn't link against liblockfile
2615 # (no liblockfile.a installed), ensure that we don't need to.
2616   dnl This works for files generally, not just executables.
2617   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2618   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2619                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2620   if test $ac_cv_prog_liblockfile = yes; then
2621     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2622 This probably means that movemail could lose mail.
2623 There may be a `development' package to install containing liblockfile.])
2624   fi
2625 fi
2626 AC_CHECK_HEADERS_ONCE(maillock.h)
2627 AC_SUBST(LIBS_MAIL)
2628
2629 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2630 ## interlock access to the mail spool.  The alternative is a lock file named
2631 ## /usr/spool/mail/$USER.lock.
2632 mail_lock=no
2633 case "$opsys" in
2634   aix4-2) mail_lock="lockf" ;;
2635
2636   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2637
2638   ## On GNU/Linux systems, both methods are used by various mail programs.
2639   ## I assume most people are using newer mailers that have heard of flock.
2640   ## Change this if you need to.
2641   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2642   ## configure gets the right answers, and that means *NOT* using flock.
2643   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2644   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2645   ## Debian maintainer hasn't provided a clean fix for Emacs.
2646   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2647   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2648   ## correct logic.  -- fx
2649   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2650   ## liblockfile is a Free Software replacement for libmail, used on
2651   ## Debian systems and elsewhere. -rfr.
2652   gnu-*)
2653     mail_lock="flock"
2654     if test $have_mail = yes || test $have_lockfile = yes; then
2655       test $ac_cv_header_maillock_h = yes && mail_lock=no
2656     fi
2657     ;;
2658 esac
2659
2660 BLESSMAIL_TARGET=
2661 case "$mail_lock" in
2662   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2663
2664   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2665
2666   *) BLESSMAIL_TARGET="need-blessmail" ;;
2667 esac
2668 AC_SUBST(BLESSMAIL_TARGET)
2669
2670
2671 AC_CHECK_FUNCS(gethostname \
2672 rename closedir mkdir rmdir getrusage get_current_dir_name \
2673 random lrand48 logb frexp fmod rint cbrt setsid \
2674 strerror fpathconf select euidaccess getpagesize setlocale \
2675 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2676 __fpending strsignal setitimer \
2677 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2678 gai_strerror mkstemp getline getdelim fsync sync \
2679 difftime posix_memalign \
2680 getpwent endpwent getgrent endgrent \
2681 touchlock \
2682 strcasecmp strncasecmp \
2683 cfmakeraw cfsetspeed copysign __executable_start)
2684
2685 dnl Cannot use AC_CHECK_FUNCS
2686 AC_CACHE_CHECK([for __builtin_unwind_init],
2687                emacs_cv_func___builtin_unwind_init,
2688 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2689                 emacs_cv_func___builtin_unwind_init=yes,
2690                 emacs_cv_func___builtin_unwind_init=no)])
2691 if test $emacs_cv_func___builtin_unwind_init = yes; then
2692   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2693             [Define to 1 if you have the `__builtin_unwind_init' function.])
2694 fi
2695
2696 AC_CHECK_HEADERS_ONCE(sys/un.h)
2697
2698 AC_FUNC_FSEEKO
2699
2700 AC_FUNC_GETPGRP
2701
2702 # UNIX98 PTYs.
2703 AC_CHECK_FUNCS(grantpt)
2704
2705 # PTY-related GNU extensions.
2706 AC_CHECK_FUNCS(getpt)
2707
2708 # Check this now, so that we will NOT find the above functions in ncurses.
2709 # That is because we have not set up to link ncurses in lib-src.
2710 # It's better to believe a function is not available
2711 # than to expect to find it in ncurses.
2712 # Also we need tputs and friends to be able to build at all.
2713 AC_MSG_CHECKING([for library containing tputs])
2714 # Run a test program that contains a call to tputs, a call that is
2715 # never executed.  This tests whether a pre-'main' dynamic linker
2716 # works with the library.  It's too much trouble to actually call
2717 # tputs in the test program, due to portability hassles.  When
2718 # cross-compiling, assume the test program will run if it links.
2719 AC_DEFUN([tputs_link_source], [
2720   AC_LANG_SOURCE(
2721      [[extern void tputs (const char *, int, int (*)(int));
2722        int main (int argc, char **argv)
2723        {
2724           if (argc == 10000)
2725             tputs (argv[0], 0, 0);
2726           return 0;
2727        }]])
2728 ])
2729 # Maybe curses should be tried earlier?
2730 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2731 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2732   OLIBS=$LIBS
2733   if test -z "$tputs_library"; then
2734     LIBS_TERMCAP=
2735     msg='none required'
2736   else
2737     LIBS_TERMCAP=-l$tputs_library
2738     msg=$LIBS_TERMCAP
2739     LIBS="$LIBS_TERMCAP $LIBS"
2740   fi
2741   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2742     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2743   LIBS=$OLIBS
2744   if test "X$msg" != Xno; then
2745     break
2746   fi
2747 done
2748 AC_MSG_RESULT([$msg])
2749 if test "X$msg" = Xno; then
2750   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2751 The following libraries were tried (in order):
2752   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2753 Please try installing whichever of these libraries is most appropriate
2754 for your system, together with its header files.
2755 For example, a libncurses-dev(el) or similar package.])
2756 fi
2757
2758 ## Use termcap instead of terminfo?
2759 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2760 TERMINFO=yes
2761 ## FIXME?  In the cases below where we unconditionally set
2762 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2763 ## if that was found above to have tputs.
2764 ## Should we use the gnu* logic everywhere?
2765 case "$opsys" in
2766   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2767   ##  The ncurses library has been moved out of the System framework in
2768   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2769   ##  option to use it.
2770   darwin) LIBS_TERMCAP="-lncurses" ;;
2771
2772   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2773
2774   freebsd)
2775     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2776     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2777     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2778 [[#if __FreeBSD_version < 400000
2779 fail;
2780 #endif
2781 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2782
2783     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2784
2785     if test $emacs_cv_freebsd_terminfo = yes; then
2786       LIBS_TERMCAP="-lncurses"
2787     else
2788       TERMINFO=no
2789       LIBS_TERMCAP="-ltermcap"
2790     fi
2791     ;;
2792
2793   netbsd)
2794     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2795       TERMINFO=no
2796       LIBS_TERMCAP="-ltermcap"
2797     fi
2798     ;;
2799
2800   openbsd) LIBS_TERMCAP="-lncurses" ;;
2801
2802   ## hpux: Make sure we get select from libc rather than from libcurses
2803   ##  because libcurses on HPUX 10.10 has a broken version of select.
2804   ##  We used to use -lc -lcurses, but this may be cleaner.
2805   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2806   # set that way, now it uses the default).  Isn't this a contradiction?
2807   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2808
2809 esac
2810
2811 TERMCAP_OBJ=tparam.o
2812 if test $TERMINFO = yes; then
2813   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2814   TERMCAP_OBJ=terminfo.o
2815 fi
2816 AC_SUBST(LIBS_TERMCAP)
2817 AC_SUBST(TERMCAP_OBJ)
2818
2819
2820 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2821 resolv=no
2822 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2823 #include <arpa/nameser.h>
2824 #include <resolv.h>]],
2825     [[return res_init();]])],
2826     have_res_init=yes, have_res_init=no)
2827 if test "$have_res_init" = no; then
2828   OLIBS="$LIBS"
2829   LIBS="$LIBS -lresolv"
2830   AC_MSG_CHECKING(for res_init with -lresolv)
2831   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2832 #include <arpa/nameser.h>
2833 #include <resolv.h>]],
2834     [[return res_init();]])],
2835     have_res_init=yes, have_res_init=no)
2836   AC_MSG_RESULT($have_res_init)
2837   if test "$have_res_init" = yes ; then
2838     resolv=yes
2839   fi
2840   LIBS="$OLIBS"
2841 fi
2842
2843 if test "$have_res_init" = yes; then
2844   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2845 fi
2846
2847 # Do we need the Hesiod library to provide the support routines?
2848 LIBHESIOD=
2849 if test "$with_hesiod" != no ; then
2850   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2851   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2852      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2853                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2854   if test "$resolv" = yes ; then
2855     RESOLVLIB=-lresolv
2856   else
2857     RESOLVLIB=
2858   fi
2859   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2860         hesiod=yes, :, $RESOLVLIB)])
2861
2862   if test x"$hesiod" = xyes; then
2863     AC_DEFINE(HAVE_LIBHESIOD, 1,
2864               [Define to 1 if you have the hesiod library (-lhesiod).])
2865     LIBHESIOD=-lhesiod
2866   fi
2867 fi
2868 AC_SUBST(LIBHESIOD)
2869
2870 # Do we need libresolv (due to res_init or Hesiod)?
2871 if test "$resolv" = yes ; then
2872   AC_DEFINE(HAVE_LIBRESOLV, 1,
2873             [Define to 1 if you have the resolv library (-lresolv).])
2874   LIBRESOLV=-lresolv
2875 else
2876   LIBRESOLV=
2877 fi
2878 AC_SUBST(LIBRESOLV)
2879
2880 # These tell us which Kerberos-related libraries to use.
2881 COM_ERRLIB=
2882 CRYPTOLIB=
2883 KRB5LIB=
2884 DESLIB=
2885 KRB4LIB=
2886
2887 if test "${with_kerberos}" != no; then
2888   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2889   if test $have_com_err = yes; then
2890     COM_ERRLIB=-lcom_err
2891     LIBS="$COM_ERRLIB $LIBS"
2892     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2893   fi
2894   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2895   if test $have_crypto = yes; then
2896     CRYPTOLIB=-lcrypto
2897     LIBS="$CRYPTOLIB $LIBS"
2898     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2899   fi
2900   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2901   if test $have_k5crypto = yes; then
2902     CRYPTOLIB=-lk5crypto
2903     LIBS="$CRYPTOLIB $LIBS"
2904     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2905   fi
2906   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2907   if test $have_krb5=yes; then
2908     KRB5LIB=-lkrb5
2909     LIBS="$KRB5LIB $LIBS"
2910     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2911   fi
2912   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2913   if test "${with_kerberos5}" = no; then
2914     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2915     if test $have_des425 = yes; then
2916       DESLIB=-ldes425
2917       LIBS="$DESLIB $LIBS"
2918       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2919     else
2920       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2921       if test $have_des = yes; then
2922         DESLIB=-ldes
2923         LIBS="$DESLIB $LIBS"
2924         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2925       fi
2926     fi
2927     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2928     if test $have_krb4 = yes; then
2929       KRB4LIB=-lkrb4
2930       LIBS="$KRB4LIB $LIBS"
2931       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2932     else
2933       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2934       if test $have_krb = yes; then
2935         KRB4LIB=-lkrb
2936         LIBS="$KRB4LIB $LIBS"
2937         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2938       fi
2939     fi
2940   fi
2941
2942   if test "${with_kerberos5}" != no; then
2943     AC_CHECK_HEADERS(krb5.h,
2944       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2945                         [#include <krb5.h>])])
2946   else
2947     AC_CHECK_HEADERS(des.h,,
2948                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2949                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2950     AC_CHECK_HEADERS(krb.h,,
2951                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2952                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2953   fi
2954   AC_CHECK_HEADERS(com_err.h)
2955 fi
2956
2957 AC_SUBST(COM_ERRLIB)
2958 AC_SUBST(CRYPTOLIB)
2959 AC_SUBST(KRB5LIB)
2960 AC_SUBST(DESLIB)
2961 AC_SUBST(KRB4LIB)
2962
2963 AC_CHECK_FUNCS(tzset)
2964 AC_MSG_CHECKING(whether localtime caches TZ)
2965 AC_CACHE_VAL(emacs_cv_localtime_cache,
2966 [if test x$ac_cv_func_tzset = xyes; then
2967 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2968 char TZ_GMT0[] = "TZ=GMT0";
2969 char TZ_PST8[] = "TZ=PST8";
2970 main()
2971 {
2972   time_t now = time ((time_t *) 0);
2973   int hour_GMT0, hour_unset;
2974   if (putenv (TZ_GMT0) != 0)
2975     exit (1);
2976   hour_GMT0 = localtime (&now)->tm_hour;
2977   unsetenv("TZ");
2978   hour_unset = localtime (&now)->tm_hour;
2979   if (putenv (TZ_PST8) != 0)
2980     exit (1);
2981   if (localtime (&now)->tm_hour == hour_GMT0)
2982     exit (1);
2983   unsetenv("TZ");
2984   if (localtime (&now)->tm_hour != hour_unset)
2985     exit (1);
2986   exit (0);
2987 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2988 [# If we have tzset, assume the worst when cross-compiling.
2989 emacs_cv_localtime_cache=yes])
2990 else
2991         # If we lack tzset, report that localtime does not cache TZ,
2992         # since we can't invalidate the cache if we don't have tzset.
2993         emacs_cv_localtime_cache=no
2994 fi])dnl
2995 AC_MSG_RESULT($emacs_cv_localtime_cache)
2996 if test $emacs_cv_localtime_cache = yes; then
2997   AC_DEFINE(LOCALTIME_CACHE, 1,
2998             [Define to 1 if localtime caches TZ.])
2999 fi
3000
3001 ok_so_far=yes
3002 AC_CHECK_FUNC(socket, , ok_so_far=no)
3003 if test $ok_so_far = yes; then
3004   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3005 fi
3006 if test $ok_so_far = yes; then
3007   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3008 fi
3009 if test $ok_so_far = yes; then
3010 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3011   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3012             [Define to 1 if you have inet sockets.])
3013 fi
3014
3015 if test -f /usr/lpp/X11/bin/smt.exp; then
3016   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3017             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3018 fi
3019
3020 AC_MSG_CHECKING(whether system supports dynamic ptys)
3021 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3022   AC_MSG_RESULT(yes)
3023   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3024 else
3025   AC_MSG_RESULT(no)
3026 fi
3027
3028 AC_FUNC_FORK
3029
3030 AC_CHECK_FUNCS(snprintf)
3031
3032 dnl Adapted from Haible's version.
3033 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3034   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3035     [[char* cs = nl_langinfo(CODESET);]])],
3036     emacs_cv_langinfo_codeset=yes,
3037     emacs_cv_langinfo_codeset=no)
3038   ])
3039 if test $emacs_cv_langinfo_codeset = yes; then
3040   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3041     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3042 fi
3043
3044 AC_TYPE_MBSTATE_T
3045
3046 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3047   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3048                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3049 if test "$emacs_cv_c_restrict_arr" = yes; then
3050   AC_DEFINE(__restrict_arr, __restrict,
3051     [Define to compiler's equivalent of C99 restrict keyword in array
3052      declarations.  Define as empty for no equivalent.])
3053 fi
3054
3055 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3056 dnl how the tty code is related to POSIX and/or other versions of termios.
3057 dnl The following looks like a useful start.
3058 dnl
3059 dnl AC_SYS_POSIX_TERMIOS
3060 dnl if test $ac_cv_sys_posix_termios = yes; then
3061 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3062 dnl                                and macros for terminal control.])
3063 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3064 dnl fi
3065
3066 case $opsys in
3067   darwin | gnu | hpux* | *bsd )
3068     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3069   ;;
3070 esac
3071
3072 dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3073 dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3074 case $opsys in
3075   hpux* | irix6-5 | openbsd | sol2* | unixware )
3076     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3077   ;;
3078 esac
3079
3080 case $opsys in
3081   gnu-* | sol2-10 )
3082     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3083     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3084   ;;
3085 esac
3086
3087 case $opsys in
3088    gnu-kfreebsd) opsysfile="s/gnu-linux.h" ;;
3089
3090    hpux11)
3091      dnl SA_RESTART resets the timeout of `select', so don't use it.
3092      AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should not
3093        be used.])
3094      dnl It works to open the pty's tty in the parent (Emacs), then
3095      dnl close and reopen it in the child.
3096      AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3097        works to open a pty's tty in the parent process, then close and
3098        reopen it in the child.])
3099
3100      opsysfile="s/hpux10-20.h"
3101    ;;
3102
3103    openbsd) opsysfile="s/netbsd.h" ;;
3104
3105    sol2-10)
3106      AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3107        on Solaris.])
3108      opsysfile="s/sol2-6.h"
3109    ;;
3110 esac
3111
3112 # Set up the CFLAGS for real compilation, so we can substitute it.
3113 CFLAGS="$REAL_CFLAGS"
3114 CPPFLAGS="$REAL_CPPFLAGS"
3115
3116 ## Hack to detect a buggy GCC version.
3117 if test "x$GCC" = xyes \
3118    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3119    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3120    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3121    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3122 fi
3123
3124 version=$PACKAGE_VERSION
3125
3126 ### Specify what sort of things we'll be editing into Makefile and config.h.
3127 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3128 AC_SUBST(version)
3129 AC_SUBST(configuration)
3130 ## Unused?
3131 AC_SUBST(canonical)
3132 AC_SUBST(srcdir)
3133 AC_SUBST(prefix)
3134 AC_SUBST(exec_prefix)
3135 AC_SUBST(bindir)
3136 AC_SUBST(datadir)
3137 AC_SUBST(sharedstatedir)
3138 AC_SUBST(libexecdir)
3139 AC_SUBST(mandir)
3140 AC_SUBST(infodir)
3141 AC_SUBST(lispdir)
3142 AC_SUBST(leimdir)
3143 AC_SUBST(locallisppath)
3144 AC_SUBST(lisppath)
3145 AC_SUBST(x_default_search_path)
3146 AC_SUBST(etcdir)
3147 AC_SUBST(archlibdir)
3148 AC_SUBST(docdir)
3149 AC_SUBST(bitmapdir)
3150 AC_SUBST(gamedir)
3151 AC_SUBST(gameuser)
3152 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3153 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3154 ## end of LIBX_BASE, but nothing ever set it.
3155 AC_SUBST(LD_SWITCH_X_SITE)
3156 AC_SUBST(C_SWITCH_X_SITE)
3157 AC_SUBST(GNUSTEP_CFLAGS)
3158 AC_SUBST(CFLAGS)
3159 ## Used in lwlib/Makefile.in.
3160 AC_SUBST(X_TOOLKIT_TYPE)
3161 if test -n "${opsysfile}"; then
3162   S_FILE="\$(srcdir)/${opsysfile}"
3163 else
3164   S_FILE=
3165 fi
3166 AC_SUBST(S_FILE)
3167 AC_SUBST(ns_appdir)
3168 AC_SUBST(ns_appbindir)
3169 AC_SUBST(ns_appresdir)
3170 AC_SUBST(ns_appsrc)
3171 AC_SUBST(GNU_OBJC_CFLAGS)
3172 AC_SUBST(OTHER_FILES)
3173
3174 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3175                    [Define to the canonical Emacs configuration name.])
3176 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3177                    [Define to the options passed to configure.])
3178 if test -n "$opsysfile"; then
3179   AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3180                      [Define to the used os dependent file.])
3181 fi
3182
3183 XMENU_OBJ=
3184 XOBJ=
3185 FONT_OBJ=
3186 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3187   AC_DEFINE(HAVE_X_WINDOWS, 1,
3188             [Define to 1 if you want to use the X window system.])
3189   XMENU_OBJ=xmenu.o
3190   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3191   FONT_OBJ=xfont.o
3192   if test "$HAVE_XFT" = "yes"; then
3193     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3194   elif test "$HAVE_FREETYPE" = "yes"; then
3195     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3196   fi
3197   AC_SUBST(FONT_OBJ)
3198 fi
3199 AC_SUBST(XMENU_OBJ)
3200 AC_SUBST(XOBJ)
3201 AC_SUBST(FONT_OBJ)
3202
3203 WIDGET_OBJ=
3204 MOTIF_LIBW=
3205 if test "${USE_X_TOOLKIT}" != "none" ; then
3206   WIDGET_OBJ=widget.o
3207   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3208   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3209     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3210   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3211     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3212     MOTIF_LIBW=-lXm
3213     case "$opsys" in
3214       gnu-linux)
3215         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3216         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3217         ;;
3218
3219       unixware)
3220         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3221         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3222         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3223         ;;
3224
3225       aix4-2)
3226         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3227         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3228         ;;
3229     esac
3230     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3231   fi
3232 fi
3233 AC_SUBST(WIDGET_OBJ)
3234
3235 TOOLKIT_LIBW=
3236 case "$USE_X_TOOLKIT" in
3237   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3238   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3239   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3240 esac
3241 AC_SUBST(TOOLKIT_LIBW)
3242
3243 if test "$USE_X_TOOLKIT" = "none"; then
3244   LIBXT_OTHER="\$(LIBXSM)"
3245   OLDXMENU_TARGET="really-oldXMenu"
3246 else
3247   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3248   OLDXMENU_TARGET="really-lwlib"
3249 fi
3250 AC_SUBST(LIBXT_OTHER)
3251
3252 ## The X Menu stuff is present in the X10 distribution, but missing
3253 ## from X11.  If we have X10, just use the installed library;
3254 ## otherwise, use our own copy.
3255 if test "${HAVE_X11}" = "yes" ; then
3256   AC_DEFINE(HAVE_X11, 1,
3257             [Define to 1 if you want to use version 11 of X windows.
3258              Otherwise, Emacs expects to use version 10.])
3259
3260   if test "$USE_X_TOOLKIT" = "none"; then
3261     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3262   else
3263     OLDXMENU="\${lwlibdir}/liblw.a"
3264   fi
3265   LIBXMENU="\$(OLDXMENU)"
3266   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3267   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3268 else
3269   ## For a syntactically valid Makefile; not actually used for anything.
3270   ## See comments in src/Makefile.in.
3271   OLDXMENU=nothing
3272   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3273   if test "${HAVE_X_WINDOWS}" = "yes"; then
3274     LIBXMENU="-lXMenu"
3275   else
3276     LIBXMENU=
3277   fi
3278   LIBX_OTHER=
3279   OLDXMENU_DEPS=
3280 fi
3281
3282 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3283   OLDXMENU_TARGET=
3284   OLDXMENU=nothing
3285   LIBXMENU=
3286   OLDXMENU_DEPS=
3287 fi
3288
3289 AC_SUBST(OLDXMENU_TARGET)
3290 AC_SUBST(OLDXMENU)
3291 AC_SUBST(LIBXMENU)
3292 AC_SUBST(LIBX_OTHER)
3293 AC_SUBST(OLDXMENU_DEPS)
3294
3295 if test "${HAVE_MENUS}" = "yes" ; then
3296   AC_DEFINE(HAVE_MENUS, 1,
3297             [Define to 1 if you have mouse menus.
3298              (This is automatic if you use X, but the option to specify it remains.)
3299              It is also defined with other window systems that support xmenu.c.])
3300 fi
3301
3302 if test "${GNU_MALLOC}" = "yes" ; then
3303   AC_DEFINE(GNU_MALLOC, 1,
3304             [Define to 1 if you want to use the GNU memory allocator.])
3305 fi
3306
3307 RALLOC_OBJ=
3308 if test "${REL_ALLOC}" = "yes" ; then
3309   AC_DEFINE(REL_ALLOC, 1,
3310             [Define REL_ALLOC if you want to use the relocating allocator for
3311              buffer space.])
3312
3313   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3314 fi
3315 AC_SUBST(RALLOC_OBJ)
3316
3317 if test "$opsys" = "cygwin"; then
3318   CYGWIN_OBJ="sheap.o"
3319   ## Cygwin differs because of its unexec().
3320   PRE_ALLOC_OBJ=
3321   POST_ALLOC_OBJ=lastfile.o
3322 else
3323   CYGWIN_OBJ=
3324   PRE_ALLOC_OBJ=lastfile.o
3325   POST_ALLOC_OBJ=
3326 fi
3327 AC_SUBST(CYGWIN_OBJ)
3328 AC_SUBST(PRE_ALLOC_OBJ)
3329 AC_SUBST(POST_ALLOC_OBJ)
3330
3331 case "$opsys" in
3332   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3333
3334   darwin)
3335    ## The -headerpad option tells ld (see man page) to leave room at the
3336    ## end of the header for adding load commands.  Needed for dumping.
3337    ## 0x690 is the total size of 30 segment load commands (at 56
3338    ## each); under Cocoa 31 commands are required.
3339    if test "$HAVE_NS" = "yes"; then
3340      libs_nsgui="-framework AppKit"
3341      headerpad_extra=6C8
3342    else
3343      libs_nsgui=
3344      headerpad_extra=690
3345    fi
3346    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3347
3348    ## This is here because src/Makefile.in did some extra fiddling around
3349    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3350    ##   #ifndef LD_SWITCH_SYSTEM
3351    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3352    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3353    ## not using gcc, darwin.
3354    ## Because this was done in src/Makefile.in, the resulting part of
3355    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3356    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3357    ## rather than LD_SWITCH_SYSTEM.
3358    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3359      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3360    ;;
3361
3362   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3363   ## find X at run-time.
3364   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3365   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3366   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3367   ## had different values in configure (in ac_link) and src/Makefile.in.
3368   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3369   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3370
3371   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3372 esac
3373
3374 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3375   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3376 fi
3377
3378 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3379
3380
3381 LD_FIRSTFLAG=
3382 ORDINARY_LINK=
3383 case "$opsys" in
3384   ## gnu: GNU needs its own crt0.
3385   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3386
3387   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3388   ## library search parth, i.e. it won't search /usr/lib for libc and
3389   ## friends.  Using -nostartfiles instead avoids this problem, and
3390   ## will also work on earlier NetBSD releases.
3391   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3392
3393   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3394   ##   MkLinux/LinuxPPC needs this.
3395   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3396   gnu-*)
3397     case "$canonical" in
3398       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3399     esac
3400     ;;
3401 esac
3402
3403
3404 if test "x$ORDINARY_LINK" = "xyes"; then
3405
3406   LD_FIRSTFLAG=""
3407   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3408
3409 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3410 ## freebsd, gnu-* not on powerpc*|s390x*.
3411 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3412
3413   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3414   ## places that are difficult to figure out at make time.  Fortunately,
3415   ## these same versions allow you to pass arbitrary flags on to the
3416   ## linker, so there is no reason not to use it as a linker.
3417   ##
3418   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3419   ## searching for libraries in its internal directories, so we have to
3420   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3421   LD_FIRSTFLAG="-nostdlib"
3422 fi
3423
3424 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3425 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3426
3427 AC_SUBST(LD_FIRSTFLAG)
3428
3429
3430 ## FIXME? The logic here is not precisely the same as that above.
3431 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3432 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3433 LIB_GCC=
3434 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3435
3436   case "$opsys" in
3437     freebsd|netbsd|openbsd) LIB_GCC= ;;
3438
3439     gnu-*)
3440       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3441       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3442       case $host_cpu in
3443       arm*)
3444         LIB_GCC="-lgcc_s"
3445         ;;
3446       *)
3447         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3448         ## immediately undefine it again and redefine it to empty.
3449         ## Was the C_SWITCH_X_SITE part really necessary?
3450 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3451         LIB_GCC=
3452         ;;
3453       esac
3454       ;;
3455
3456     ## Ask GCC where to find libgcc.a.
3457     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3458   esac
3459 fi                              dnl if $GCC
3460 AC_SUBST(LIB_GCC)
3461
3462
3463 ## If we're using X11/GNUstep, define some consequences.
3464 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3465   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3466   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3467 fi
3468
3469
3470 AH_TOP([/* GNU Emacs site configuration template file.
3471
3472 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3473   Free Software Foundation, Inc.
3474
3475 This file is part of GNU Emacs.
3476
3477 GNU Emacs is free software: you can redistribute it and/or modify
3478 it under the terms of the GNU General Public License as published by
3479 the Free Software Foundation, either version 3 of the License, or
3480 (at your option) any later version.
3481
3482 GNU Emacs is distributed in the hope that it will be useful,
3483 but WITHOUT ANY WARRANTY; without even the implied warranty of
3484 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3485 GNU General Public License for more details.
3486
3487 You should have received a copy of the GNU General Public License
3488 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3489
3490
3491 /* No code in Emacs #includes config.h twice, but some bits of code
3492    intended to work with other packages as well (like gmalloc.c)
3493    think they can include it as many times as they like.  */
3494 #ifndef EMACS_CONFIG_H
3495 #define EMACS_CONFIG_H
3496 ])dnl
3497
3498 AH_BOTTOM([
3499 /* On AIX 3 this must be included before any other include file.  */
3500 #include <alloca.h>
3501 #if ! HAVE_ALLOCA
3502 # error "alloca not available on this machine"
3503 #endif
3504
3505 /* Define AMPERSAND_FULL_NAME if you use the convention
3506    that & in the full name stands for the login id.  */
3507 /* Turned on June 1996 supposing nobody will mind it.  */
3508 #define AMPERSAND_FULL_NAME
3509
3510 /* `subprocesses' should be defined if you want to
3511    have code for asynchronous subprocesses
3512    (as used in M-x compile and M-x shell).
3513    Only MSDOS does not support this (it overrides
3514    this in its config_opsysfile below).  */
3515
3516 #define subprocesses
3517
3518 /* Include the os dependent file.  */
3519 #ifdef config_opsysfile
3520 # include config_opsysfile
3521 #endif
3522
3523 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3524    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3525   (There is probably a better place to do this, but right now the
3526    Cocoa side does this in s/darwin.h and we cannot parallel this
3527    exactly since GNUstep is multi-OS.  */
3528 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3529 #  define SYSTEM_PURESIZE_EXTRA 30000
3530 #endif
3531
3532 #ifdef emacs /* Don't do this for lib-src.  */
3533 /* Tell regex.c to use a type compatible with Emacs.  */
3534 #define RE_TRANSLATE_TYPE Lisp_Object
3535 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3536 #ifdef make_number
3537 /* If make_number is a macro, use it.  */
3538 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3539 #else
3540 /* If make_number is a function, avoid it.  */
3541 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3542 #endif
3543 #endif
3544
3545 #include <string.h>
3546 #include <stdlib.h>
3547
3548 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3549 #define NO_INLINE __attribute__((noinline))
3550 #else
3551 #define NO_INLINE
3552 #endif
3553
3554 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3555 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3556 #else
3557 #define EXTERNALLY_VISIBLE
3558 #endif
3559
3560 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3561 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3562 #else
3563 # define ATTRIBUTE_FORMAT(spec) /* empty */
3564 #endif
3565
3566 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3567 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3568    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3569 #else
3570 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3571    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3572 #endif
3573
3574 /* Some versions of GNU/Linux define noinline in their headers.  */
3575 #ifdef noinline
3576 #undef noinline
3577 #endif
3578
3579 /* These won't be used automatically yet.  We also need to know, at least,
3580    that the stack is continuous.  */
3581 #ifdef __GNUC__
3582 #  ifndef GC_SETJMP_WORKS
3583   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3584 #    define GC_SETJMP_WORKS 1
3585 #  endif
3586 #endif
3587
3588 #endif /* EMACS_CONFIG_H */
3589
3590 /*
3591 Local Variables:
3592 mode: c
3593 End:
3594 */
3595 ])dnl
3596
3597 #### Report on what we decided to do.
3598 #### Report GTK as a toolkit, even if it doesn't use Xt.
3599 #### It makes printing result more understandable as using GTK sets
3600 #### toolkit_scroll_bars to yes by default.
3601 if test "${HAVE_GTK}" = "yes"; then
3602   USE_X_TOOLKIT=GTK
3603 fi
3604
3605 echo "
3606 Configured for \`${canonical}'.
3607
3608   Where should the build process find the source code?    ${srcdir}
3609   What operating system file should Emacs use?            ${opsysfile-none}
3610   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3611   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3612   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3613   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3614   What window system should Emacs use?                    ${window_system}
3615   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3616
3617 if test -n "${x_includes}"; then
3618 echo "  Where do we find X Windows header files?                ${x_includes}"
3619 else
3620 echo "  Where do we find X Windows header files?                Standard dirs"
3621 fi
3622 if test -n "${x_libraries}"; then
3623 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3624 else
3625 echo "  Where do we find X Windows libraries?                   Standard dirs"
3626 fi
3627
3628 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3629 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3630 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3631 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3632 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3633 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3634 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3635 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3636
3637 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3638 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3639 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3640 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3641 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3642 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3643 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3644
3645 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3646 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3647 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3648 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3649
3650 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3651 echo
3652
3653 if test -n "${EMACSDATA}"; then
3654    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3655 fi
3656 if test -n "${EMACSDOC}"; then
3657    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3658 fi
3659
3660 if test $USE_XASSERTS = yes; then
3661    echo "  Compiling with asserts turned on."
3662    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3663 fi
3664
3665 echo
3666
3667 if test "$HAVE_NS" = "yes"; then
3668    echo
3669    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3670 The installed application will go to nextstep/Emacs.app and can be
3671 run or moved from there."
3672    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3673       echo "The application will be fully self-contained."
3674     else
3675       echo "The lisp resources for the application will be installed under ${prefix}.
3676 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3677 to run if these resources are not installed."
3678    fi
3679    echo
3680 fi
3681
3682 if test "${opsys}" = "cygwin"; then
3683   case `uname -r` in
3684     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3685            echo
3686            ;;
3687   esac
3688 fi
3689
3690 # Remove any trailing slashes in these variables.
3691 [test "${prefix}" != NONE &&
3692   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3693 test "${exec_prefix}" != NONE &&
3694   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3695
3696 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3697 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3698 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3699 dnl (else you get "no `Makefile.am' found for any configure output").
3700 dnl This will work, but you get a config.status that is not quite right
3701 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3702 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3703 dnl it seems better to just live with the duplication.
3704 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3705
3706 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3707        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3708        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3709        leim/Makefile])
3710
3711 dnl test/ is not present in release tarfiles.
3712 opt_makefile=test/automated/Makefile
3713
3714 if test -f $srcdir/${opt_makefile}.in; then
3715   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3716   dnl Again, it's best not to use a variable.  Though you can add
3717   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3718   AC_CONFIG_FILES([test/automated/Makefile])
3719 fi
3720
3721
3722 dnl admin/ may or may not be present.
3723 opt_makefile=admin/unidata/Makefile
3724
3725 if test -f $srcdir/${opt_makefile}.in; then
3726   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3727   AC_CONFIG_FILES([admin/unidata/Makefile])
3728 fi
3729
3730
3731 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3732
3733 AC_SUBST(SUBDIR_MAKEFILES_IN)
3734
3735 dnl Make the necessary directories, if they don't exist.
3736 AC_CONFIG_COMMANDS([mkdirs], [
3737 for dir in etc lisp ; do
3738   test -d ${dir} || mkdir ${dir}
3739 done
3740 ])
3741
3742 dnl You might wonder (I did) why epaths.h is generated by running make,
3743 dnl rather than just letting configure generate it from epaths.in.
3744 dnl One reason is that the various paths are not fully expanded (see above);
3745 dnl eg gamedir=${prefix}/var/games/emacs.
3746 dnl Secondly, the GNU Coding standards require that one should be able
3747 dnl to run `make prefix=/some/where/else' and override the values set
3748 dnl by configure.  This also explains the `move-if-change' test and
3749 dnl the use of force in the `epaths-force' rule in Makefile.in.
3750 AC_CONFIG_COMMANDS([epaths], [
3751 echo creating src/epaths.h
3752 ${MAKE-make} epaths-force
3753 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3754
3755 AC_CONFIG_COMMANDS([gdbinit], [
3756 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3757   echo creating src/.gdbinit
3758   echo source $srcdir/src/.gdbinit > src/.gdbinit
3759 fi
3760 ])
3761
3762 AC_OUTPUT
3763
3764 dnl configure.in ends here