code.delx.au - gnu-emacs/blob - lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile
  30   (require 'cl)
  31   ;; Warning suppression -- can't require x-win in batch:
  32   (autoload 'xw-defined-colors "x-win"))
  33
  34 (require 'cus-face)
  35
  36 \f
  37 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  38 ;;; Font selection.
  39 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  40
  41 (defgroup font-selection nil
  42   "Influencing face font selection."
  43   :group 'faces)
  44
  45
  46 (defcustom face-font-selection-order
  47   '(:width :height :weight :slant)
  48   "*A list specifying how face font selection chooses fonts.
  49 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  50 must appear once in the list, and the list must not contain any other
  51 elements.  Font selection tries to find a best matching font for
  52 those face attributes first that appear first in the list.  For
  53 example, if `:slant' appears before `:height', font selection first
  54 tries to find a font with a suitable slant, even if this results in
  55 a font height that isn't optimal."
  56   :tag "Font selection order."
  57   :type '(list symbol symbol symbol symbol)
  58   :group 'font-selection
  59   :set #'(lambda (symbol value)
  60            (set-default symbol value)
  61            (internal-set-font-selection-order value)))
  62
  63
  64 ;; This is defined originally in xfaces.c.
  65 (defcustom face-font-family-alternatives
  66   '(("courier" "fixed")
  67     ("helv" "helvetica" "arial" "fixed"))
  68   "*Alist of alternative font family names.
  69 Each element has the the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  70 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  71 ALTERNATIVE2 etc."
  72   :tag "Alternative font families to try."
  73   :type '(repeat (repeat string))
  74   :group 'font-selection
  75   :set #'(lambda (symbol value)
  76            (set-default symbol value)
  77            (internal-set-alternative-font-family-alist value)))
  78
  79
  80 ;; This is defined originally in xfaces.c.
  81 (defcustom face-font-registry-alternatives
  82   (if (eq system-type 'windows-nt)
  83       '(("gb2312.1980" "gb2312")
  84         ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  85         ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  86         ("muletibetan-2" "muletibetan-0"))
  87     '(("gb2312.1980" "gb2312.80&gb8565.88" "gbk*")
  88       ("jisx0208.1990" "jisx0208.1983" "jisx0208.1978")
  89       ("ksc5601.1989" "ksx1001.1992" "ksc5601.1987")
  90       ("muletibetan-2" "muletibetan-0")))
  91   "*Alist of alternative font registry names.
  92 Each element has the the form (REGISTRY ALTERNATIVE1 ALTERNATIVE2 ...).
  93 If fonts of registry REGISTRY can be loaded, font selection
  94 tries to find a best matching font among all fonts of registry
  95 REGISTRY, ALTERNATIVE1, ALTERNATIVE2, and etc."
  96   :tag "Alternative font registries to try."
  97   :type '(repeat (repeat string))
  98   :version "21.1"
  99   :group 'font-selection
 100   :set #'(lambda (symbol value)
 101            (set-default symbol value)
 102            (internal-set-alternative-font-registry-alist value)))
 103
 104
 105 \f
 106 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 107 ;;; Creation, copying.
 108 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 109
 110
 111 (defun face-list ()
 112   "Return a list of all defined face names."
 113   (mapcar #'car face-new-frame-defaults))
 114
 115
 116 ;;; ### If not frame-local initialize by what X resources?
 117
 118 (defun make-face (face &optional no-init-from-resources)
 119   "Define a new face with name FACE, a symbol.
 120 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
 121 variants of FACE from X resources.  (X resources recognized are found
 122 in the global variable `face-x-resources'.)  If FACE is already known
 123 as a face, leave it unmodified.  Value is FACE."
 124   (interactive "SMake face: ")
 125   (unless (facep face)
 126     ;; Make frame-local faces (this also makes the global one).
 127     (dolist (frame (frame-list))
 128       (internal-make-lisp-face face frame))
 129     ;; Add the face to the face menu.
 130     (when (fboundp 'facemenu-add-new-face)
 131       (facemenu-add-new-face face))
 132     ;; Define frame-local faces for all frames from X resources.
 133     (unless no-init-from-resources
 134       (make-face-x-resource-internal face)))
 135   face)
 136
 137
 138 (defun make-empty-face (face)
 139   "Define a new, empty face with name FACE.
 140 If the face already exists, it is left unmodified.  Value is FACE."
 141   (interactive "SMake empty face: ")
 142   (make-face face 'no-init-from-resources))
 143
 144
 145 (defun copy-face (old-face new-face &optional frame new-frame)
 146   "Define a face just like OLD-FACE, with name NEW-FACE.
 147
 148 If NEW-FACE already exists as a face, it is modified to be like
 149 OLD-FACE.  If it doesn't already exist, it is created.
 150
 151 If the optional argument FRAME is given as a frame,  NEW-FACE is
 152 changed on FRAME only.
 153 If FRAME is t, the frame-independent default specification for OLD-FACE
 154 is copied to NEW-FACE.
 155 If FRAME is nil, copying is done for the frame-independent defaults
 156 and for each existing frame.
 157
 158 If the optional fourth argument NEW-FRAME is given,
 159 copy the information from face OLD-FACE on frame FRAME
 160 to NEW-FACE on frame NEW-FRAME."
 161   (let ((inhibit-quit t))
 162     (if (null frame)
 163         (progn
 164           (dolist (frame (frame-list))
 165             (copy-face old-face new-face frame))
 166           (copy-face old-face new-face t))
 167       (internal-copy-lisp-face old-face new-face frame new-frame))
 168     new-face))
 169
 170
 171 \f
 172 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 173 ;;; Obsolete functions
 174 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 175
 176 ;; The functions in this section are defined because Lisp packages use
 177 ;; them, despite the prefix `internal-' suggesting that they are
 178 ;; private to the face implementation.
 179
 180 (defun internal-find-face (name &optional frame)
 181   "Retrieve the face named NAME.
 182 Return nil if there is no such face.
 183 If the optional argument FRAME is given, this gets the face NAME for
 184 that frame; otherwise, it uses the selected frame.
 185 If FRAME is the symbol t, then the global, non-frame face is returned.
 186 If NAME is already a face, it is simply returned.
 187
 188 This function is defined for compatibility with Emacs 20.2.  It
 189 should not be used anymore."
 190   (facep name))
 191 (make-obsolete 'internal-find-face 'facep "21.1")
 192
 193
 194 (defun internal-get-face (name &optional frame)
 195   "Retrieve the face named NAME; error if there is none.
 196 If the optional argument FRAME is given, this gets the face NAME for
 197 that frame; otherwise, it uses the selected frame.
 198 If FRAME is the symbol t, then the global, non-frame face is returned.
 199 If NAME is already a face, it is simply returned.
 200
 201 This function is defined for compatibility with Emacs 20.2.  It
 202 should not be used anymore."
 203   (or (facep name)
 204       (check-face name)))
 205 (make-obsolete 'internal-get-face "See `facep' and `check-face'." "21.1")
 206
 207 \f
 208 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 209 ;;; Predicates, type checks.
 210 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 211
 212 (defun facep (face)
 213   "Return non-nil if FACE is a face name."
 214   (internal-lisp-face-p face))
 215
 216
 217 (defun check-face (face)
 218   "Signal an error if FACE doesn't name a face.
 219 Value is FACE."
 220   (unless (facep face)
 221     (error "Not a face: %s" face))
 222   face)
 223
 224
 225 ;; The ID returned is not to be confused with the internally used IDs
 226 ;; of realized faces.  The ID assigned to Lisp faces is used to
 227 ;; support faces in display table entries.
 228
 229 (defun face-id (face &optional frame)
 230   "Return the interNal ID of face with name FACE.
 231 If optional argument FRAME is nil or omitted, use the selected frame."
 232   (check-face face)
 233   (get face 'face))
 234
 235
 236 (defun face-equal (face1 face2 &optional frame)
 237   "Non-nil if faces FACE1 and FACE2 are equal.
 238 Faces are considered equal if all their attributes are equal.
 239 If the optional argument FRAME is given, report on face FACE in that frame.
 240 If FRAME is t, report on the defaults for face FACE (for new frames).
 241 If FRAME is omitted or nil, use the selected frame."
 242   (internal-lisp-face-equal-p face1 face2 frame))
 243
 244
 245 (defun face-differs-from-default-p (face &optional frame)
 246   "Non-nil if FACE displays differently from the default face.
 247 If the optional argument FRAME is given, report on face FACE in that frame.
 248 If FRAME is t, report on the defaults for face FACE (for new frames).
 249 If FRAME is omitted or nil, use the selected frame.
 250 A face is considered to be ``the same'' as the default face if it is
 251 actually specified in the same way (equal attributes) or if it is
 252 fully-unspecified, and thus inherits the attributes of any face it
 253 is displayed on top of."
 254   (cond ((eq frame t) (setq frame nil))
 255         ((null frame) (setq frame (selected-frame))))
 256   (let* ((v1 (internal-lisp-face-p face frame))
 257          (n (if v1 (length v1) 0))
 258          (v2 (internal-lisp-face-p 'default frame))
 259          (i 1))
 260     (unless v1
 261       (error "Not a face: %S" face))
 262     (while (and (< i n)
 263                 (or (eq 'unspecified (aref v1 i))
 264                     (equal (aref v1 i) (aref v2 i))))
 265       (setq i (1+ i)))
 266     (< i n)))
 267
 268
 269 (defun face-nontrivial-p (face &optional frame)
 270   "True if face FACE has some non-nil attribute.
 271 If the optional argument FRAME is given, report on face FACE in that frame.
 272 If FRAME is t, report on the defaults for face FACE (for new frames).
 273 If FRAME is omitted or nil, use the selected frame."
 274   (not (internal-lisp-face-empty-p face frame)))
 275
 276
 277 \f
 278 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 279 ;;; Setting face attributes from X resources.
 280 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 281
 282 (defcustom face-x-resources
 283   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 284     (:width (".attributeWidth" . "Face.AttributeWidth"))
 285     (:height (".attributeHeight" . "Face.AttributeHeight"))
 286     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 287     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 288     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 289     (:background (".attributeBackground" . "Face.AttributeBackground"))
 290     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 291     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 292     (:box (".attributeBox" . "Face.AttributeBox"))
 293     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 294     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 295     (:stipple
 296      (".attributeStipple" . "Face.AttributeStipple")
 297      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 298     (:bold (".attributeBold" . "Face.AttributeBold"))
 299     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 300     (:font (".attributeFont" . "Face.AttributeFont"))
 301     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 302   "*List of X resources and classes for face attributes.
 303 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 304 the name of a face attribute, and each ENTRY is a cons of the form
 305 \(RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 306 X resource class for the attribute."
 307   :type '(repeat (cons symbol (repeat (cons string string))))
 308   :group 'faces)
 309
 310
 311 (defun set-face-attribute-from-resource (face attribute resource class frame)
 312   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 313 Value is the attribute value specified by the resource, or nil
 314 if not present.  This function displays a message if the resource
 315 specifies an invalid attribute."
 316   (let* ((face-name (face-name face))
 317          (value (internal-face-x-get-resource (concat face-name resource)
 318                                               class frame)))
 319     (when value
 320       (condition-case ()
 321           (internal-set-lisp-face-attribute-from-resource
 322            face attribute (downcase value) frame)
 323         (error
 324          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 325                   face-name frame attribute value))))
 326     value))
 327
 328
 329 (defun set-face-attributes-from-resources (face frame)
 330   "Set attributes of FACE from X resources for FRAME."
 331   (when (memq (framep frame) '(x w32 mac))
 332     (dolist (definition face-x-resources)
 333       (let ((attribute (car definition)))
 334         (dolist (entry (cdr definition))
 335           (set-face-attribute-from-resource face attribute (car entry)
 336                                             (cdr entry) frame))))))
 337
 338
 339 (defun make-face-x-resource-internal (face &optional frame)
 340   "Fill frame-local FACE on FRAME from X resources.
 341 FRAME nil or not specified means do it for all frames."
 342   (if (null frame)
 343       (dolist (frame (frame-list))
 344         (set-face-attributes-from-resources face frame))
 345     (set-face-attributes-from-resources face frame)))
 346
 347
 348 \f
 349 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 350 ;;; Retrieving face attributes.
 351 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 352
 353 (defun face-name (face)
 354   "Return the name of face FACE."
 355   (symbol-name (check-face face)))
 356
 357
 358 (defun face-attribute (face attribute &optional frame inherit)
 359   "Return the value of FACE's ATTRIBUTE on FRAME.
 360 If the optional argument FRAME is given, report on face FACE in that frame.
 361 If FRAME is t, report on the defaults for face FACE (for new frames).
 362 If FRAME is omitted or nil, use the selected frame.
 363
 364 If INHERIT is nil, only attributes directly defined by FACE are considered,
 365   so the return value may be `unspecified', or a relative value.
 366 If INHERIT is non-nil, FACE's definition of ATTRIBUTE is merged with the
 367   faces specified by its `:inherit' attribute; however the return value
 368   may still be `unspecified' or relative.
 369 If INHERIT is a face or a list of faces, then the result is further merged
 370   with that face (or faces), until it becomes specified and absolute.
 371
 372 To ensure that the return value is always specified and absolute, use a
 373 value of `default' for INHERIT; this will resolve any unspecified or
 374 relative values by merging with the `default' face (which is always
 375 completely specified)."
 376   (let ((value (internal-get-lisp-face-attribute face attribute frame)))
 377     (when (and inherit (face-attribute-relative-p attribute value))
 378       ;; VALUE is relative, so merge with inherited faces
 379       (let ((inh-from (face-attribute face :inherit frame)))
 380         (unless (or (null inh-from) (eq inh-from 'unspecified))
 381           (setq value
 382                 (face-attribute-merged-with attribute value inh-from frame)))))
 383     (when (and inherit
 384                (not (eq inherit t))
 385                (face-attribute-relative-p attribute value))
 386         ;; We should merge with INHERIT as well
 387       (setq value (face-attribute-merged-with attribute value inherit frame)))
 388     value))
 389
 390 (defun face-attribute-merged-with (attribute value faces &optional frame)
 391   "Merges ATTRIBUTE, initially VALUE, with faces from FACES until absolute.
 392 FACES may be either a single face or a list of faces.
 393 \[This is an internal function]"
 394   (cond ((not (face-attribute-relative-p attribute value))
 395          value)
 396         ((null faces)
 397          value)
 398         ((consp faces)
 399          (face-attribute-merged-with
 400           attribute
 401           (face-attribute-merged-with attribute value (car faces) frame)
 402           (cdr faces)
 403           frame))
 404         (t
 405          (merge-face-attribute attribute
 406                                value
 407                                (face-attribute faces attribute frame t)))))
 408
 409
 410 (defmacro face-attribute-specified-or (value &rest body)
 411   "Return VALUE, unless it's `unspecified', in which case evaluate BODY and return the result."
 412   (let ((temp (make-symbol "value")))
 413     `(let ((,temp ,value))
 414        (if (not (eq ,temp 'unspecified))
 415            ,temp
 416          ,@body))))
 417
 418 (defun face-foreground (face &optional frame inherit)
 419   "Return the foreground color name of FACE, or nil if unspecified.
 420 If the optional argument FRAME is given, report on face FACE in that frame.
 421 If FRAME is t, report on the defaults for face FACE (for new frames).
 422 If FRAME is omitted or nil, use the selected frame.
 423
 424 If INHERIT is nil, only a foreground color directly defined by FACE is
 425   considered, so the return value may be nil.
 426 If INHERIT is t, and FACE doesn't define a foreground color, then any
 427   foreground color that FACE inherits through its `:inherit' attribute
 428   is considered as well; however the return value may still be nil.
 429 If INHERIT is a face or a list of faces, then it is used to try to
 430   resolve an unspecified foreground color.
 431
 432 To ensure that a valid color is always returned, use a value of
 433 `default' for INHERIT; this will resolve any unspecified values by
 434 merging with the `default' face (which is always completely specified)."
 435   (face-attribute-specified-or (face-attribute face :foreground frame inherit)
 436                                nil))
 437
 438 (defun face-background (face &optional frame inherit)
 439   "Return the background color name of FACE, or nil if unspecified.
 440 If the optional argument FRAME is given, report on face FACE in that frame.
 441 If FRAME is t, report on the defaults for face FACE (for new frames).
 442 If FRAME is omitted or nil, use the selected frame.
 443
 444 If INHERIT is nil, only a background color directly defined by FACE is
 445   considered, so the return value may be nil.
 446 If INHERIT is t, and FACE doesn't define a background color, then any
 447   background color that FACE inherits through its `:inherit' attribute
 448   is considered as well; however the return value may still be nil.
 449 If INHERIT is a face or a list of faces, then it is used to try to
 450   resolve an unspecified background color.
 451
 452 To ensure that a valid color is always returned, use a value of
 453 `default' for INHERIT; this will resolve any unspecified values by
 454 merging with the `default' face (which is always completely specified)."
 455   (face-attribute-specified-or (face-attribute face :background frame inherit)
 456                                nil))
 457
 458 (defun face-stipple (face &optional frame inherit)
 459  "Return the stipple pixmap name of FACE, or nil if unspecified.
 460 If the optional argument FRAME is given, report on face FACE in that frame.
 461 If FRAME is t, report on the defaults for face FACE (for new frames).
 462 If FRAME is omitted or nil, use the selected frame.
 463
 464 If INHERIT is nil, only a stipple directly defined by FACE is
 465   considered, so the return value may be nil.
 466 If INHERIT is t, and FACE doesn't define a stipple, then any stipple
 467   that FACE inherits through its `:inherit' attribute is considered as
 468   well; however the return value may still be nil.
 469 If INHERIT is a face or a list of faces, then it is used to try to
 470   resolve an unspecified stipple.
 471
 472 To ensure that a valid stipple or nil is always returned, use a value of
 473 `default' for INHERIT; this will resolve any unspecified values by merging
 474 with the `default' face (which is always completely specified)."
 475   (face-attribute-specified-or (face-attribute face :stipple frame inherit)
 476                                nil))
 477
 478
 479 (defalias 'face-background-pixmap 'face-stipple)
 480
 481
 482 (defun face-underline-p (face &optional frame)
 483  "Return non-nil if FACE is underlined.
 484 If the optional argument FRAME is given, report on face FACE in that frame.
 485 If FRAME is t, report on the defaults for face FACE (for new frames).
 486 If FRAME is omitted or nil, use the selected frame."
 487  (eq (face-attribute face :underline frame) t))
 488
 489
 490 (defun face-inverse-video-p (face &optional frame)
 491  "Return non-nil if FACE is in inverse video on FRAME.
 492 If the optional argument FRAME is given, report on face FACE in that frame.
 493 If FRAME is t, report on the defaults for face FACE (for new frames).
 494 If FRAME is omitted or nil, use the selected frame."
 495  (eq (face-attribute face :inverse-video frame) t))
 496
 497
 498 (defun face-bold-p (face &optional frame)
 499   "Return non-nil if the font of FACE is bold on FRAME.
 500 If the optional argument FRAME is given, report on face FACE in that frame.
 501 If FRAME is t, report on the defaults for face FACE (for new frames).
 502 If FRAME is omitted or nil, use the selected frame.
 503 Use `face-attribute' for finer control."
 504   (let ((bold (face-attribute face :weight frame)))
 505     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 506
 507
 508 (defun face-italic-p (face &optional frame)
 509   "Return non-nil if the font of FACE is italic on FRAME.
 510 If the optional argument FRAME is given, report on face FACE in that frame.
 511 If FRAME is t, report on the defaults for face FACE (for new frames).
 512 If FRAME is omitted or nil, use the selected frame.
 513 Use `face-attribute' for finer control."
 514   (let ((italic (face-attribute face :slant frame)))
 515     (memq italic '(italic oblique))))
 516
 517
 518 \f
 519 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 520 ;;; Face documentation.
 521 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 522
 523 (defun face-documentation (face)
 524   "Get the documentation string for FACE."
 525   (get face 'face-documentation))
 526
 527
 528 (defun set-face-documentation (face string)
 529   "Set the documentation string for FACE to STRING."
 530   ;; Perhaps the text should go in DOC.
 531   (put face 'face-documentation (purecopy string)))
 532
 533
 534 (defalias 'face-doc-string 'face-documentation)
 535 (defalias 'set-face-doc-string 'set-face-documentation)
 536
 537
 538 \f
 539 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 540 ;; Setting face attributes.
 541 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 542
 543
 544 (defun set-face-attribute (face frame &rest args)
 545   "Set attributes of FACE on FRAME from ARGS.
 546
 547 FRAME nil means change attributes on all frames.  FRAME t means change
 548 the default for new frames (this is done automatically each time an
 549 attribute is changed on all frames).
 550
 551 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 552 face attribute name.  All attributes can be set to `unspecified';
 553 this fact is not further mentioned below.
 554
 555 The following attributes are recognized:
 556
 557 `:family'
 558
 559 VALUE must be a string specifying the font family, e.g. ``courier'',
 560 or a fontset alias name.  If a font family is specified, wild-cards `*'
 561 and `?' are allowed.
 562
 563 `:width'
 564
 565 VALUE specifies the relative proportionate width of the font to use.
 566 It must be one of the symbols `ultra-condensed', `extra-condensed',
 567 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 568 `extra-expanded', or `ultra-expanded'.
 569
 570 `:height'
 571
 572 VALUE must be either an integer specifying the height of the font to use
 573 in 1/10 pt, a floating point number specifying the amount by which to
 574 scale any underlying face, or a function, which is called with the old
 575 height (from the underlying face), and should return the new height.
 576
 577 `:weight'
 578
 579 VALUE specifies the weight of the font to use.  It must be one of the
 580 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 581 `semi-light', `light', `extra-light', `ultra-light'.
 582
 583 `:slant'
 584
 585 VALUE specifies the slant of the font to use.  It must be one of the
 586 symbols `italic', `oblique', `normal', `reverse-italic', or
 587 `reverse-oblique'.
 588
 589 `:foreground', `:background'
 590
 591 VALUE must be a color name, a string.
 592
 593 `:underline'
 594
 595 VALUE specifies whether characters in FACE should be underlined.  If
 596 VALUE is t, underline with foreground color of the face.  If VALUE is
 597 a string, underline with that color.  If VALUE is nil, explicitly
 598 don't underline.
 599
 600 `:overline'
 601
 602 VALUE specifies whether characters in FACE should be overlined.  If
 603 VALUE is t, overline with foreground color of the face.  If VALUE is a
 604 string, overline with that color.  If VALUE is nil, explicitly don't
 605 overline.
 606
 607 `:strike-through'
 608
 609 VALUE specifies whether characters in FACE should be drawn with a line
 610 striking through them.  If VALUE is t, use the foreground color of the
 611 face.  If VALUE is a string, strike-through with that color.  If VALUE
 612 is nil, explicitly don't strike through.
 613
 614 `:box'
 615
 616 VALUE specifies whether characters in FACE should have a box drawn
 617 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 618 VALUE is t, draw a box with lines of width 1 in the foreground color
 619 of the face.  If VALUE is a string, the string must be a color name,
 620 and the box is drawn in that color with a line width of 1.  Otherwise,
 621 VALUE must be a property list of the form `(:line-width WIDTH
 622 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 623 the property list, a default value will be used for the value, as
 624 specified below.  WIDTH specifies the width of the lines to draw; it
 625 defaults to 1.  If WIDTH is negative, the absolute value is the width
 626 of the lines, and draw top/bottom lines inside the characters area,
 627 not around it.  COLOR is the name of the color to draw in, default is
 628 the foreground color of the face for simple boxes, and the background
 629 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 630 should be draw.  If STYLE is `released-button', draw a box looking
 631 like a released 3D button.  If STYLE is `pressed-button' draw a box
 632 that appears like a pressed button.  If STYLE is nil, the default if
 633 the property list doesn't contain a style specification, draw a 2D
 634 box.
 635
 636 `:inverse-video'
 637
 638 VALUE specifies whether characters in FACE should be displayed in
 639 inverse video.  VALUE must be one of t or nil.
 640
 641 `:stipple'
 642
 643 If VALUE is a string, it must be the name of a file of pixmap data.
 644 The directories listed in the `x-bitmap-file-path' variable are
 645 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 646 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 647 is a string containing the raw bits of the bitmap.  VALUE nil means
 648 explicitly don't use a stipple pattern.
 649
 650 For convenience, attributes `:family', `:width', `:height', `:weight',
 651 and `:slant' may also be set in one step from an X font name:
 652
 653 `:font'
 654
 655 Set font-related face attributes from VALUE.  VALUE must be a valid
 656 XLFD font name.  If it is a font name pattern, the first matching font
 657 will be used.
 658
 659 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 660 be used to specify that a bold or italic font should be used.  VALUE
 661 must be t or nil in that case.  A value of `unspecified' is not allowed.
 662
 663 `:inherit'
 664
 665 VALUE is the name of a face from which to inherit attributes, or a list
 666 of face names.  Attributes from inherited faces are merged into the face
 667 like an underlying face would be, with higher priority than underlying faces."
 668   (let ((where (if (null frame) 0 frame)))
 669     (setq args (purecopy args))
 670     (while args
 671       (internal-set-lisp-face-attribute face (car args)
 672                                         (purecopy (cadr args))
 673                                         where)
 674       (setq args (cdr (cdr args))))))
 675
 676
 677 (defun make-face-bold (face &optional frame noerror)
 678   "Make the font of FACE be bold, if possible.
 679 FRAME nil or not specified means change face on all frames.
 680 Argument NOERROR is ignored and retained for compatibility.
 681 Use `set-face-attribute' for finer control of the font weight."
 682   (interactive (list (read-face-name "Make which face bold")))
 683   (set-face-attribute face frame :weight 'bold))
 684
 685
 686 (defun make-face-unbold (face &optional frame noerror)
 687   "Make the font of FACE be non-bold, if possible.
 688 FRAME nil or not specified means change face on all frames.
 689 Argument NOERROR is ignored and retained for compatibility."
 690   (interactive (list (read-face-name "Make which face non-bold")))
 691   (set-face-attribute face frame :weight 'normal))
 692
 693
 694 (defun make-face-italic (face &optional frame noerror)
 695   "Make the font of FACE be italic, if possible.
 696 FRAME nil or not specified means change face on all frames.
 697 Argument NOERROR is ignored and retained for compatibility.
 698 Use `set-face-attribute' for finer control of the font slant."
 699   (interactive (list (read-face-name "Make which face italic")))
 700   (set-face-attribute face frame :slant 'italic))
 701
 702
 703 (defun make-face-unitalic (face &optional frame noerror)
 704   "Make the font of FACE be non-italic, if possible.
 705 FRAME nil or not specified means change face on all frames.
 706 Argument NOERROR is ignored and retained for compatibility."
 707   (interactive (list (read-face-name "Make which face non-italic")))
 708   (set-face-attribute face frame :slant 'normal))
 709
 710
 711 (defun make-face-bold-italic (face &optional frame noerror)
 712   "Make the font of FACE be bold and italic, if possible.
 713 FRAME nil or not specified means change face on all frames.
 714 Argument NOERROR is ignored and retained for compatibility.
 715 Use `set-face-attribute' for finer control of font weight and slant."
 716   (interactive (list (read-face-name "Make which face bold-italic")))
 717   (set-face-attribute face frame :weight 'bold :slant 'italic))
 718
 719
 720 (defun set-face-font (face font &optional frame)
 721   "Change font-related attributes of FACE to those of FONT (a string).
 722 FRAME nil or not specified means change face on all frames.
 723 This sets the attributes `:family', `:width', `:height', `:weight',
 724 and `:slant'.  When called interactively, prompt for the face and font."
 725   (interactive (read-face-and-attribute :font))
 726   (set-face-attribute face frame :font font))
 727
 728
 729 ;; Implementation note: Emulating gray background colors with a
 730 ;; stipple pattern is now part of the face realization process, and is
 731 ;; done in C depending on the frame on which the face is realized.
 732
 733 (defun set-face-background (face color &optional frame)
 734   "Change the background color of face FACE to COLOR (a string).
 735 FRAME nil or not specified means change face on all frames.
 736 When called interactively, prompt for the face and color."
 737   (interactive (read-face-and-attribute :background))
 738   (set-face-attribute face frame :background (or color 'unspecified)))
 739
 740
 741 (defun set-face-foreground (face color &optional frame)
 742   "Change the foreground color of face FACE to COLOR (a string).
 743 FRAME nil or not specified means change face on all frames.
 744 When called interactively, prompt for the face and color."
 745   (interactive (read-face-and-attribute :foreground))
 746   (set-face-attribute face frame :foreground (or color 'unspecified)))
 747
 748
 749 (defun set-face-stipple (face stipple &optional frame)
 750   "Change the stipple pixmap of face FACE to STIPPLE.
 751 FRAME nil or not specified means change face on all frames.
 752 STIPPLE should be a string, the name of a file of pixmap data.
 753 The directories listed in the `x-bitmap-file-path' variable are searched.
 754
 755 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 756 where WIDTH and HEIGHT are the size in pixels,
 757 and DATA is a string, containing the raw bits of the bitmap."
 758   (interactive (read-face-and-attribute :stipple))
 759   (set-face-attribute face frame :stipple (or stipple 'unspecified)))
 760
 761
 762 (defun set-face-underline (face underline &optional frame)
 763   "Specify whether face FACE is underlined.
 764 UNDERLINE nil means FACE explicitly doesn't underline.
 765 UNDERLINE non-nil means FACE explicitly does underlining
 766 with the same of the foreground color.
 767 If UNDERLINE is a string, underline with the color named UNDERLINE.
 768 FRAME nil or not specified means change face on all frames.
 769 Use `set-face-attribute' to ``unspecify'' underlining."
 770   (interactive
 771    (let ((list (read-face-and-attribute :underline)))
 772      (list (car list) (eq (car (cdr list)) t))))
 773   (set-face-attribute face frame :underline underline))
 774
 775
 776 (defun set-face-underline-p (face underline-p &optional frame)
 777   "Specify whether face FACE is underlined.
 778 UNDERLINE-P nil means FACE explicitly doesn't underline.
 779 UNDERLINE-P non-nil means FACE explicitly does underlining.
 780 FRAME nil or not specified means change face on all frames.
 781 Use `set-face-attribute' to ``unspecify'' underlining."
 782   (interactive
 783    (let ((list (read-face-and-attribute :underline)))
 784      (list (car list) (eq (car (cdr list)) t))))
 785   (set-face-attribute face frame :underline underline-p))
 786
 787
 788 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 789   "Specify whether face FACE is in inverse video.
 790 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 791 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 792 FRAME nil or not specified means change face on all frames.
 793 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 794   (interactive
 795    (let ((list (read-face-and-attribute :inverse-video)))
 796      (list (car list) (eq (car (cdr list)) t))))
 797   (set-face-attribute face frame :inverse-video inverse-video-p))
 798
 799
 800 (defun set-face-bold-p (face bold-p &optional frame)
 801   "Specify whether face FACE is bold.
 802 BOLD-P non-nil means FACE should explicitly display bold.
 803 BOLD-P nil means FACE should explicitly display non-bold.
 804 FRAME nil or not specified means change face on all frames.
 805 Use `set-face-attribute' or `modify-face' for finer control."
 806   (if (null bold-p)
 807       (make-face-unbold face frame)
 808     (make-face-bold face frame)))
 809
 810
 811 (defun set-face-italic-p (face italic-p &optional frame)
 812   "Specify whether face FACE is italic.
 813 ITALIC-P non-nil means FACE should explicitly display italic.
 814 ITALIC-P nil means FACE should explicitly display non-italic.
 815 FRAME nil or not specified means change face on all frames.
 816 Use `set-face-attribute' or `modify-face' for finer control."
 817   (if (null italic-p)
 818       (make-face-unitalic face frame)
 819     (make-face-italic face frame)))
 820
 821
 822 (defalias 'set-face-background-pixmap 'set-face-stipple)
 823
 824
 825 (defun invert-face (face &optional frame)
 826   "Swap the foreground and background colors of FACE.
 827 If FRAME is omitted or nil, it means change face on all frames.
 828 If FACE specifies neither foreground nor background color,
 829 set its foreground and background to the background and foreground
 830 of the default face.  Value is FACE."
 831   (interactive (list (read-face-name "Invert face")))
 832   (let ((fg (face-attribute face :foreground frame))
 833         (bg (face-attribute face :background frame)))
 834     (if (not (and (eq fg 'unspecified) (eq bg 'unspecified)))
 835         (set-face-attribute face frame :foreground bg :background fg)
 836       (set-face-attribute face frame
 837                           :foreground
 838                           (face-attribute 'default :background frame)
 839                           :background
 840                           (face-attribute 'default :foreground frame))))
 841   face)
 842
 843 \f
 844 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 845 ;;; Interactively modifying faces.
 846 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 847
 848 (defun read-face-name (prompt)
 849   "Read and return a face symbol, prompting with PROMPT.
 850 PROMPT should not end with a blank, since this function appends one.
 851 Value is a symbol naming a known face."
 852   (let ((face-list (mapcar #'(lambda (x) (cons (symbol-name x) x))
 853                            (face-list)))
 854         (def (thing-at-point 'symbol))
 855         face)
 856     (cond ((assoc def face-list)
 857            (setq prompt (concat prompt " (default " def "): ")))
 858           (t (setq def nil)
 859              (setq prompt (concat prompt ": "))))
 860     (while (equal "" (setq face (completing-read
 861                                  prompt face-list nil t nil nil def))))
 862     (intern face)))
 863
 864
 865 (defun face-valid-attribute-values (attribute &optional frame)
 866   "Return valid values for face attribute ATTRIBUTE.
 867 The optional argument FRAME is used to determine available fonts
 868 and colors.  If it is nil or not specified, the selected frame is
 869 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 870 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 871 an integer value."
 872   (let ((valid
 873          (case attribute
 874            (:family
 875             (if window-system
 876                 (mapcar #'(lambda (x) (cons (car x) (car x)))
 877                         (x-font-family-list))
 878               ;; Only one font on TTYs.
 879               (list (cons "default" "default"))))
 880            ((:width :weight :slant :inverse-video)
 881             (mapcar #'(lambda (x) (cons (symbol-name x) x))
 882                     (internal-lisp-face-attribute-values attribute)))
 883            ((:underline :overline :strike-through :box)
 884             (if window-system
 885                 (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 886                                (internal-lisp-face-attribute-values attribute))
 887                        (mapcar #'(lambda (c) (cons c c))
 888                                (x-defined-colors frame)))
 889               (mapcar #'(lambda (x) (cons (symbol-name x) x))
 890                       (internal-lisp-face-attribute-values attribute))))
 891            ((:foreground :background)
 892             (mapcar #'(lambda (c) (cons c c))
 893                     (defined-colors frame)))
 894            ((:height)
 895             'integerp)
 896            (:stipple
 897             (and (memq window-system '(x w32 mac))
 898                  (mapcar #'list
 899                          (apply #'nconc
 900                                 (mapcar (lambda (dir)
 901                                           (and (file-readable-p dir)
 902                                                (file-directory-p dir)
 903                                                (directory-files dir)))
 904                                         x-bitmap-file-path)))))
 905            (:inherit
 906             (cons '("none" . nil)
 907                   (mapcar #'(lambda (c) (cons (symbol-name c) c))
 908                           (face-list))))
 909            (t
 910             (error "Internal error")))))
 911     (if (and (listp valid) (not (memq attribute '(:inherit))))
 912         (nconc (list (cons "unspecified" 'unspecified)) valid)
 913       valid)))
 914
 915
 916 (defvar face-attribute-name-alist
 917   '((:family . "font family")
 918     (:width . "character set width")
 919     (:height . "height in 1/10 pt")
 920     (:weight . "weight")
 921     (:slant . "slant")
 922     (:underline . "underline")
 923     (:overline . "overline")
 924     (:strike-through . "strike-through")
 925     (:box . "box")
 926     (:inverse-video . "inverse-video display")
 927     (:foreground . "foreground color")
 928     (:background . "background color")
 929     (:stipple . "background stipple")
 930     (:inherit . "inheritance"))
 931   "An alist of descriptive names for face attributes.
 932 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 933 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 934 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 935
 936
 937 (defun face-descriptive-attribute-name (attribute)
 938   "Return a descriptive name for ATTRIBUTE."
 939   (cdr (assq attribute face-attribute-name-alist)))
 940
 941
 942 (defun face-read-string (face default name &optional completion-alist)
 943   "Interactively read a face attribute string value.
 944 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 945 default string to return if no new value is entered.  NAME is a
 946 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 947 alist of valid values, if non-nil.
 948
 949 Entering nothing accepts the default string DEFAULT.
 950 Value is the new attribute value."
 951   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 952   ;; each word in a string separately).
 953   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 954   (let* ((completion-ignore-case t)
 955          (value (completing-read
 956                  (if default
 957                      (format "%s for face `%s' (default %s): "
 958                              name face default)
 959                    (format "%s for face `%s': " name face))
 960                  completion-alist)))
 961     (if (equal value "") default value)))
 962
 963
 964 (defun face-read-integer (face default name)
 965   "Interactively read an integer face attribute value.
 966 FACE is the face whose attribute is read.  DEFAULT is the default
 967 value to return if no new value is entered.  NAME is a descriptive
 968 name of the attribute for prompting.  Value is the new attribute value."
 969   (let ((new-value
 970          (face-read-string face
 971                            (format "%s" default)
 972                            name
 973                            (list (cons "unspecified" 'unspecified)))))
 974     (cond ((equal new-value "unspecified")
 975            'unspecified)
 976           ((member new-value '("unspecified-fg" "unspecified-bg"))
 977            new-value)
 978           (t
 979            (string-to-int new-value)))))
 980
 981
 982 (defun read-face-attribute (face attribute &optional frame)
 983   "Interactively read a new value for FACE's ATTRIBUTE.
 984 Optional argument FRAME nil or unspecified means read an attribute value
 985 of a global face.  Value is the new attribute value."
 986   (let* ((old-value (face-attribute face attribute frame))
 987          (attribute-name (face-descriptive-attribute-name attribute))
 988          (valid (face-valid-attribute-values attribute frame))
 989          new-value)
 990     ;; Represent complex attribute values as strings by printing them
 991     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
 992     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
 993     ;; SHADOW)'.
 994     (when (and (or (eq attribute :stipple)
 995                    (eq attribute :box))
 996                (or (consp old-value)
 997                    (vectorp old-value)))
 998       (setq old-value (prin1-to-string old-value)))
 999     (cond ((listp valid)
1000            (let ((default
1001                    (or (car (rassoc old-value valid))
1002                        (format "%s" old-value))))
1003              (setq new-value
1004                    (face-read-string face default attribute-name valid))
1005              (if (equal new-value default)
1006                  ;; Nothing changed, so don't bother with all the stuff
1007                  ;; below.  In particular, this avoids a non-tty color
1008                  ;; from being canonicalized for a tty when the user
1009                  ;; just uses the default.
1010                  (setq new-value old-value)
1011                ;; Terminal frames can support colors that don't appear
1012                ;; explicitly in VALID, using color approximation code
1013                ;; in tty-colors.el.
1014                (when (and (memq attribute '(:foreground :background))
1015                           (not (memq window-system '(x w32 mac)))
1016                           (not (member new-value
1017                                        '("unspecified"
1018                                          "unspecified-fg" "unspecified-bg"))))
1019                  (setq new-value (car (tty-color-desc new-value frame))))
1020                (when (assoc new-value valid)
1021                  (setq new-value (cdr (assoc new-value valid)))))))
1022           ((eq valid 'integerp)
1023            (setq new-value (face-read-integer face old-value attribute-name)))
1024           (t (error "Internal error")))
1025     ;; Convert stipple and box value text we read back to a list or
1026     ;; vector if it looks like one.  This makes the assumption that a
1027     ;; pixmap file name won't start with an open-paren.
1028     (when (and (or (eq attribute :stipple)
1029                    (eq attribute :box))
1030                (stringp new-value)
1031                (string-match "^[[(]" new-value))
1032       (setq new-value (read new-value)))
1033     new-value))
1034
1035
1036 (defun read-face-font (face &optional frame)
1037   "Read the name of a font for FACE on FRAME.
1038 If optional argument FRAME Is nil or omitted, use the selected frame."
1039   (let ((completion-ignore-case t))
1040     (completing-read (format "Set font attributes of face `%s' from font: " face)
1041                      (mapcar 'list (x-list-fonts "*" nil frame)))))
1042
1043
1044 (defun read-all-face-attributes (face &optional frame)
1045   "Interactively read all attributes for FACE.
1046 If optional argument FRAME Is nil or omitted, use the selected frame.
1047 Value is a property list of attribute names and new values."
1048   (let (result)
1049     (dolist (attribute face-attribute-name-alist result)
1050       (setq result (cons (car attribute)
1051                          (cons (read-face-attribute face (car attribute) frame)
1052                                result))))))
1053
1054 (defun modify-face (&optional face foreground background stipple
1055                               bold-p italic-p underline-p inverse-p frame)
1056   "Modify attributes of faces interactively.
1057 If optional argument FRAME is nil or omitted, modify the face used
1058 for newly created frame, i.e. the global face.
1059 For non-interactive use, `set-face-attribute' is preferred.
1060 When called from elisp, if FACE is nil, all arguments but FRAME are ignored
1061 and the face and its settings are obtained by querying the user."
1062   (interactive)
1063   (if face
1064       (set-face-attribute face frame
1065                           :foreground (or foreground 'unspecified)
1066                           :background (or background 'unspecified)
1067                           :stipple stipple
1068                           :bold bold-p
1069                           :italic italic-p
1070                           :underline underline-p
1071                           :inverse-video inverse-p)
1072     (setq face (read-face-name "Modify face"))
1073     (apply #'set-face-attribute face frame
1074            (read-all-face-attributes face frame))))
1075
1076 (defun read-face-and-attribute (attribute &optional frame)
1077   "Read face name and face attribute value.
1078 ATTRIBUTE is the attribute whose new value is read.
1079 FRAME nil or unspecified means read attribute value of global face.
1080 Value is a list (FACE NEW-VALUE) where FACE is the face read
1081 \(a symbol), and NEW-VALUE is value read."
1082   (cond ((eq attribute :font)
1083          (let* ((prompt "Set font-related attributes of face")
1084                 (face (read-face-name prompt))
1085                 (font (read-face-font face frame)))
1086            (list face font)))
1087         (t
1088          (let* ((attribute-name (face-descriptive-attribute-name attribute))
1089                 (prompt (format "Set %s of face" attribute-name))
1090                 (face (read-face-name prompt))
1091                 (new-value (read-face-attribute face attribute frame)))
1092            (list face new-value)))))
1093
1094
1095 \f
1096 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1097 ;;; Listing faces.
1098 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1099
1100 (defvar list-faces-sample-text
1101   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
1102   "*Text string to display as the sample text for `list-faces-display'.")
1103
1104
1105 ;; The name list-faces would be more consistent, but let's avoid a
1106 ;; conflict with Lucid, which uses that name differently.
1107
1108 (defun list-faces-display ()
1109   "List all faces, using the same sample text in each.
1110 The sample text is a string that comes from the variable
1111 `list-faces-sample-text'."
1112   (interactive)
1113   (let ((faces (sort (face-list) #'string-lessp))
1114         (face nil)
1115         (frame (selected-frame))
1116         disp-frame window face-name)
1117     (with-output-to-temp-buffer "*Faces*"
1118       (save-excursion
1119         (set-buffer standard-output)
1120         (setq truncate-lines t)
1121         (insert
1122          (substitute-command-keys
1123           (concat
1124            "Use "
1125            (if (display-mouse-p) "\\[help-follow-mouse] or ")
1126            "\\[help-follow] on a face name to customize it\n"
1127            "or on its sample text for a decription of the face.\n\n")))
1128         (setq help-xref-stack nil)
1129         (while faces
1130           (setq face (car faces))
1131           (setq faces (cdr faces))
1132           (setq face-name (symbol-name face))
1133           (insert (format "%25s " face-name))
1134           ;; Hyperlink to a customization buffer for the face.  Using
1135           ;; the help xref mechanism may not be the best way.
1136           (save-excursion
1137             (save-match-data
1138               (search-backward face-name)
1139               (help-xref-button 0 'help-customize-face face-name)))
1140           (let ((beg (point)))
1141             (insert list-faces-sample-text)
1142             ;; Hyperlink to a help buffer for the face.
1143             (save-excursion
1144               (save-match-data
1145                 (search-backward list-faces-sample-text)
1146                 (help-xref-button 0 'help-face face)))
1147             (insert "\n")
1148             (put-text-property beg (1- (point)) 'face face)
1149             ;; If the sample text has multiple lines, line up all of them.
1150             (goto-char beg)
1151             (forward-line 1)
1152             (while (not (eobp))
1153               (insert "                          ")
1154               (forward-line 1))))
1155         (goto-char (point-min)))
1156       (print-help-return-message))
1157     ;; If the *Faces* buffer appears in a different frame,
1158     ;; copy all the face definitions from FRAME,
1159     ;; so that the display will reflect the frame that was selected.
1160     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1161     (setq disp-frame (if window (window-frame window)
1162                        (car (frame-list))))
1163     (or (eq frame disp-frame)
1164         (let ((faces (face-list)))
1165           (while faces
1166             (copy-face (car faces) (car faces) frame disp-frame)
1167             (setq faces (cdr faces)))))))
1168
1169
1170 (defun describe-face (face &optional frame)
1171   "Display the properties of face FACE on FRAME.
1172 If the optional argument FRAME is given, report on face FACE in that frame.
1173 If FRAME is t, report on the defaults for face FACE (for new frames).
1174 If FRAME is omitted or nil, use the selected frame."
1175   (interactive (list (read-face-name "Describe face")))
1176   (let* ((attrs '((:family . "Family")
1177                   (:width . "Width")
1178                   (:height . "Height")
1179                   (:weight . "Weight")
1180                   (:slant . "Slant")
1181                   (:foreground . "Foreground")
1182                   (:background . "Background")
1183                   (:underline . "Underline")
1184                   (:overline . "Overline")
1185                   (:strike-through . "Strike-through")
1186                   (:box . "Box")
1187                   (:inverse-video . "Inverse")
1188                   (:stipple . "Stipple")
1189                   (:font . "Font or fontset")
1190                   (:inherit . "Inherit")))
1191         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1192                                         attrs))))
1193     (help-setup-xref (list #'describe-face face) (interactive-p))
1194     (with-output-to-temp-buffer (help-buffer)
1195       (save-excursion
1196         (set-buffer standard-output)
1197         (dolist (a attrs)
1198           (let ((attr (face-attribute face (car a) frame)))
1199             (insert (make-string (- max-width (length (cdr a))) ?\ )
1200                     (cdr a) ": " (format "%s" attr) "\n")))
1201         (insert "\nDocumentation:\n\n"
1202                 (or (face-documentation face)
1203                     "not documented as a face."))
1204         (let ((customize-label "customize"))
1205           (terpri)
1206           (terpri)
1207           (princ (concat "You can " customize-label " this face."))
1208           (with-current-buffer standard-output
1209             (save-excursion
1210               (re-search-backward
1211                (concat "\\(" customize-label "\\)") nil t)
1212               (help-xref-button 1 'help-customize-face face)))))
1213       (print-help-return-message))))
1214
1215 \f
1216 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1217 ;;; Face specifications (defface).
1218 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1219
1220 ;; Parameter FRAME Is kept for call compatibility to with previous
1221 ;; face implementation.
1222
1223 (defun face-attr-construct (face &optional frame)
1224   "Return a defface-style attribute list for FACE on FRAME.
1225 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1226 face attributes of FACE where ATTRIBUTE is the attribute name and
1227 VALUE is the specified value of that attribute."
1228   (let (result)
1229     (dolist (entry face-attribute-name-alist result)
1230       (let* ((attribute (car entry))
1231              (value (face-attribute face attribute)))
1232         (unless (eq value 'unspecified)
1233           (setq result (nconc (list attribute value) result)))))))
1234
1235
1236 (defun face-spec-set-match-display (display frame)
1237   "Non-nil if DISPLAY matches FRAME.
1238 DISPLAY is part of a spec such as can be used in `defface'.
1239 If FRAME is nil, the current FRAME is used."
1240   (let* ((conjuncts display)
1241          conjunct req options
1242          ;; t means we have succeeded against all the conjuncts in
1243          ;; DISPLAY that have been tested so far.
1244          (match t))
1245     (if (eq conjuncts t)
1246         (setq conjuncts nil))
1247     (while (and conjuncts match)
1248       (setq conjunct (car conjuncts)
1249             conjuncts (cdr conjuncts)
1250             req (car conjunct)
1251             options (cdr conjunct)
1252             match (cond ((eq req 'type)
1253                          (or (memq window-system options)
1254                              ;; FIXME: This should be revisited to use
1255                              ;; display-graphic-p, provided that the
1256                              ;; color selection depends on the number
1257                              ;; of supported colors, and all defface's
1258                              ;; are changed to look at number of colors
1259                              ;; instead of (type graphic) etc.
1260                              (and (null window-system)
1261                                   (memq 'tty options))
1262                              (and (memq 'motif options)
1263                                   (featurep 'motif))
1264                              (and (memq 'lucid options)
1265                                   (featurep 'x-toolkit)
1266                                   (not (featurep 'motif)))
1267                              (and (memq 'x-toolkit options)
1268                                   (featurep 'x-toolkit))))
1269                         ((eq req 'class)
1270                          (memq (frame-parameter frame 'display-type) options))
1271                         ((eq req 'background)
1272                          (memq (frame-parameter frame 'background-mode)
1273                                options))
1274                         (t (error "Unknown req `%S' with options `%S'"
1275                                   req options)))))
1276     match))
1277
1278
1279 (defun face-spec-choose (spec &optional frame)
1280   "Choose the proper attributes for FRAME, out of SPEC.
1281 If SPEC is nil, return nil."
1282   (unless frame
1283     (setq frame (selected-frame)))
1284   (let ((tail spec)
1285         result)
1286     (while tail
1287       (let* ((entry (pop tail))
1288              (display (car entry))
1289              (attrs (cdr entry)))
1290         (when (face-spec-set-match-display display frame)
1291           (setq result (if (listp (car attrs))
1292                            ;; Old-style entry, the attribute list is the
1293                            ;; first element.
1294                            (car attrs)
1295                          attrs)
1296                 tail nil))))
1297     result))
1298
1299
1300 (defun face-spec-reset-face (face &optional frame)
1301   "Reset all attributes of FACE on FRAME to unspecified."
1302   (let ((attrs face-attribute-name-alist))
1303     (while attrs
1304       (let ((attr-and-name (car attrs)))
1305         (set-face-attribute face frame (car attr-and-name) 'unspecified))
1306       (setq attrs (cdr attrs)))))
1307
1308
1309 (defun face-spec-set (face spec &optional frame)
1310   "Set FACE's attributes according to the first matching entry in SPEC.
1311 FRAME is the frame whose frame-local face is set.  FRAME nil means
1312 do it on all frames.  See `defface' for information about SPEC.
1313 If SPEC is nil, do nothing."
1314   (let ((attrs (face-spec-choose spec frame)))
1315     (when attrs
1316       (face-spec-reset-face face frame))
1317     (while attrs
1318       (let ((attribute (car attrs))
1319             (value (car (cdr attrs))))
1320         ;; Support some old-style attribute names and values.
1321         (case attribute
1322           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1323           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1324           ((:foreground :background)
1325            ;; Compatibility with 20.x.  Some bogus face specs seem to
1326            ;; exist containing things like `:foreground nil'.
1327            (if (null value) (setq value 'unspecified)))
1328           (t (unless (assq attribute face-x-resources)
1329                (setq attribute nil))))
1330         (when attribute
1331           (set-face-attribute face frame attribute value)))
1332       (setq attrs (cdr (cdr attrs))))))
1333
1334
1335 (defun face-attr-match-p (face attrs &optional frame)
1336   "Return t if attributes of FACE match values in plist ATTRS.
1337 Optional parameter FRAME is the frame whose definition of FACE
1338 is used.  If nil or omitted, use the selected frame."
1339   (unless frame
1340     (setq frame (selected-frame)))
1341   (let ((list face-attribute-name-alist)
1342         (match t))
1343     (while (and match (not (null list)))
1344       (let* ((attr (car (car list)))
1345              (specified-value
1346               (if (plist-member attrs attr)
1347                   (plist-get attrs attr)
1348                 'unspecified))
1349              (value-now (face-attribute face attr frame)))
1350         (setq match (equal specified-value value-now))
1351         (setq list (cdr list))))
1352     match))
1353
1354 (defun face-spec-match-p (face spec &optional frame)
1355   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1356   (face-attr-match-p face (face-spec-choose spec frame) frame))
1357
1358 (defsubst face-default-spec (face)
1359   "Return the default face-spec for FACE, ignoring any user customization.
1360 If there is no default for FACE, return nil."
1361   (get face 'face-defface-spec))
1362
1363 (defsubst face-user-default-spec (face)
1364   "Return the user's customized face-spec for FACE, or the default if none.
1365 If there is neither a user setting nor a default for FACE, return nil."
1366   (or (get face 'saved-face)
1367       (face-default-spec face)))
1368
1369 \f
1370 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1371 ;;; Frame-type independent color support.
1372 ;;; We keep the old x-* names as aliases for back-compatibility.
1373 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1374
1375 (defun defined-colors (&optional frame)
1376   "Return a list of colors supported for a particular frame.
1377 The argument FRAME specifies which frame to try.
1378 The value may be different for frames on different display types.
1379 If FRAME doesn't support colors, the value is nil."
1380   (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1381       (xw-defined-colors frame)
1382     (mapcar 'car (tty-color-alist frame))))
1383 (defalias 'x-defined-colors 'defined-colors)
1384
1385 (defun color-defined-p (color &optional frame)
1386   "Return non-nil if color COLOR is supported on frame FRAME.
1387 If FRAME is omitted or nil, use the selected frame.
1388 If COLOR is the symbol `unspecified' or one of the strings
1389 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1390   (if (member color '(unspecified "unspecified-bg" "unspecified-fg"))
1391       nil
1392     (if (member (framep (or frame (selected-frame))) '(x w32 mac))
1393         (xw-color-defined-p color frame)
1394       (numberp (tty-color-translate color frame)))))
1395 (defalias 'x-color-defined-p 'color-defined-p)
1396
1397 (defun color-values (color &optional frame)
1398   "Return a description of the color named COLOR on frame FRAME.
1399 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1400 These values appear to range from 0 65535; white is \(65535 65535 65535\).
1401 If FRAME is omitted or nil, use the selected frame.
1402 If FRAME cannot display COLOR, the value is nil.
1403 If COLOR is the symbol `unspecified' or one of the strings
1404 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1405   (if (member color '(unspecified "unspecified-fg" "unspecified-bg"))
1406       nil
1407     (if (memq (framep (or frame (selected-frame))) '(x w32 mac))
1408         (xw-color-values color frame)
1409       (tty-color-values color frame))))
1410 (defalias 'x-color-values 'color-values)
1411
1412 (defun display-color-p (&optional display)
1413   "Return t if DISPLAY supports color.
1414 The optional argument DISPLAY specifies which display to ask about.
1415 DISPLAY should be either a frame or a display name (a string).
1416 If omitted or nil, that stands for the selected frame's display."
1417   (if (memq (framep-on-display display) '(x w32 mac))
1418       (xw-display-color-p display)
1419     (tty-display-color-p display)))
1420 (defalias 'x-display-color-p 'display-color-p)
1421
1422 (defun display-grayscale-p (&optional display)
1423   "Return non-nil if frames on DISPLAY can display shades of gray."
1424   (let ((frame-type (framep-on-display display)))
1425     (cond
1426      ((memq frame-type '(x w32 mac))
1427       (x-display-grayscale-p display))
1428      (t
1429       (> (tty-color-gray-shades display) 2)))))
1430
1431 \f
1432 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1433 ;;; Background mode.
1434 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1435
1436 (defcustom frame-background-mode nil
1437   "*The brightness of the background.
1438 Set this to the symbol `dark' if your background color is dark, `light' if
1439 your background is light, or nil (default) if you want Emacs to
1440 examine the brightness for you.  Don't set this variable with `setq';
1441 this won't have the expected effect."
1442   :group 'faces
1443   :set #'(lambda (var value)
1444            (set-default var value)
1445            (mapc 'frame-set-background-mode (frame-list)))
1446   :initialize 'custom-initialize-changed
1447   :type '(choice (choice-item dark)
1448                  (choice-item light)
1449                  (choice-item :tag "default" nil)))
1450
1451
1452 (defun frame-set-background-mode (frame)
1453   "Set up display-dependent faces on FRAME.
1454 Display-dependent faces are those which have different definitions
1455 according to the `background-mode' and `display-type' frame parameters."
1456   (let* ((bg-resource
1457           (and window-system
1458                (x-get-resource ".backgroundMode" "BackgroundMode")))
1459          (bg-color (frame-parameter frame 'background-color))
1460          (bg-mode
1461           (cond (frame-background-mode)
1462                 (bg-resource
1463                  (intern (downcase bg-resource)))
1464                 ((and (null window-system) (null bg-color))
1465                  ;; No way to determine this automatically (?).
1466                  'dark)
1467                 ;; Unspecified frame background color can only happen
1468                 ;; on tty's.
1469                 ((member bg-color '(unspecified "unspecified-bg"))
1470                  'dark)
1471                 ((equal bg-color "unspecified-fg") ; inverted colors
1472                  'light)
1473                 ((>= (apply '+ (x-color-values bg-color frame))
1474                     ;; Just looking at the screen, colors whose
1475                     ;; values add up to .6 of the white total
1476                     ;; still look dark to me.
1477                     (* (apply '+ (x-color-values "white" frame)) .6))
1478                  'light)
1479                 (t 'dark)))
1480          (display-type
1481           (cond ((null window-system)
1482                  (if (tty-display-color-p frame) 'color 'mono))
1483                 ((x-display-color-p frame)
1484                  'color)
1485                 ((x-display-grayscale-p frame)
1486                  'grayscale)
1487                 (t 'mono)))
1488          (old-bg-mode
1489           (frame-parameter frame 'background-mode))
1490          (old-display-type
1491           (frame-parameter frame 'display-type)))
1492
1493     (unless (and (eq bg-mode old-bg-mode) (eq display-type old-display-type))
1494       (let ((locally-modified-faces nil))
1495         ;; Before modifying the frame parameters, we collect a list of
1496         ;; faces that don't match what their face-spec says they should
1497         ;; look like; we then avoid changing these faces below.  A
1498         ;; negative list is used on the assumption that most faces will
1499         ;; be unmodified, so we can avoid consing in the common case.
1500         (dolist (face (face-list))
1501           (when (not (face-spec-match-p face
1502                                         (face-user-default-spec face)
1503                                         (selected-frame)))
1504             (push face locally-modified-faces)))
1505         ;; Now change to the new frame parameters
1506         (modify-frame-parameters frame
1507                                  (list (cons 'background-mode bg-mode)
1508                                        (cons 'display-type display-type)))
1509         ;; For all named faces, choose face specs matching the new frame
1510         ;; parameters, unless they have been locally modified.
1511         (dolist (face (face-list))
1512           (unless (memq face locally-modified-faces)
1513             (face-spec-set face (face-user-default-spec face) frame)))))))
1514
1515 \f
1516 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1517 ;;; Frame creation.
1518 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1519
1520 (defun x-handle-named-frame-geometry (parameters)
1521   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1522 Value is the new parameter list."
1523   (let* ((name (or (cdr (assq 'name parameters))
1524                    (cdr (assq 'name default-frame-alist))))
1525          (x-resource-name name)
1526          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1527     (when res-geometry
1528       (let ((parsed (x-parse-geometry res-geometry)))
1529         ;; If the resource specifies a position, call the position
1530         ;; and size "user-specified".
1531         (when (or (assq 'top parsed)
1532                   (assq 'left parsed))
1533           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1534         ;; Put the geometry parameters at the end.  Copy
1535         ;; default-frame-alist so that they go after it.
1536         (setq parameters (append parameters default-frame-alist parsed))))
1537     parameters))
1538
1539
1540 (defun x-handle-reverse-video (frame parameters)
1541   "Handle the reverse-video frame parameter and X resource.
1542 `x-create-frame' does not handle this one."
1543   (when (cdr (or (assq 'reverse parameters)
1544                  (assq 'reverse default-frame-alist)
1545                  (let ((resource (x-get-resource "reverseVideo"
1546                                                  "ReverseVideo")))
1547                    (if resource
1548                        (cons nil (member (downcase resource)
1549                                          '("on" "true")))))))
1550       (let* ((params (frame-parameters frame))
1551              (bg (cdr (assq 'foreground-color params)))
1552              (fg (cdr (assq 'background-color params))))
1553         (modify-frame-parameters frame
1554                                  (list (cons 'foreground-color fg)
1555                                        (cons 'background-color bg)))
1556         (if (equal bg (cdr (assq 'border-color params)))
1557             (modify-frame-parameters frame
1558                                      (list (cons 'border-color fg))))
1559         (if (equal bg (cdr (assq 'mouse-color params)))
1560             (modify-frame-parameters frame
1561                                      (list (cons 'mouse-color fg))))
1562         (if (equal bg (cdr (assq 'cursor-color params)))
1563             (modify-frame-parameters frame
1564                                      (list (cons 'cursor-color fg)))))))
1565
1566
1567 (defun x-create-frame-with-faces (&optional parameters)
1568   "Create a frame from optional frame parameters PARAMETERS.
1569 Parameters not specified by PARAMETERS are taken from
1570 `default-frame-alist'.  If PARAMETERS specify a frame name,
1571 handle X geometry resources for that name.  If either PARAMETERS
1572 or `default-frame-alist' contains a `reverse' parameter, or
1573 the X resource ``reverseVideo'' is present, handle that.
1574 Value is the new frame created."
1575   (setq parameters (x-handle-named-frame-geometry parameters))
1576   (let ((visibility-spec (assq 'visibility parameters))
1577         (frame-list (frame-list))
1578         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1579         success)
1580     (unwind-protect
1581         (progn
1582           (x-handle-reverse-video frame parameters)
1583           (frame-set-background-mode frame)
1584           (face-set-after-frame-default frame)
1585           (if (or (null frame-list) (null visibility-spec))
1586               (make-frame-visible frame)
1587             (modify-frame-parameters frame (list visibility-spec)))
1588           (setq success t))
1589       (unless success
1590         (delete-frame frame)))
1591     frame))
1592
1593
1594 (defun face-set-after-frame-default (frame)
1595   "Set frame-local faces of FRAME from face specs and resources.
1596 Initialize colors of certain faces from frame parameters."
1597   (dolist (face (face-list))
1598     (when (not (equal face 'default))
1599       (face-spec-set face (face-user-default-spec face) frame)
1600       (internal-merge-in-global-face face frame)
1601       (when (and (memq window-system '(x w32 mac))
1602                  (or (not (boundp 'inhibit-default-face-x-resources))
1603                      (not (eq face 'default))))
1604         (make-face-x-resource-internal face frame))))
1605
1606   ;; Initialize attributes from frame parameters.
1607   (let ((params '((foreground-color default :foreground)
1608                   (background-color default :background)
1609                   (border-color border :background)
1610                   (cursor-color cursor :background)
1611                   (scroll-bar-foreground scroll-bar :foreground)
1612                   (scroll-bar-background scroll-bar :background)
1613                   (mouse-color mouse :background))))
1614     (dolist (param params)
1615       (let ((frame-param (frame-parameter frame (nth 0 param)))
1616             (face (nth 1 param))
1617             (attr (nth 2 param)))
1618         (when (and frame-param
1619                    ;; Don't override face attributes explicitly
1620                    ;; specified for new frames.
1621                    (eq (face-attribute face attr t) 'unspecified))
1622           (set-face-attribute face frame attr frame-param))))))
1623
1624
1625 (defun tty-handle-reverse-video (frame parameters)
1626   "Handle the reverse-video frame parameter for terminal frames."
1627   (when (cdr (or (assq 'reverse parameters)
1628                  (assq 'reverse default-frame-alist)))
1629     (let* ((params (frame-parameters frame))
1630            (bg (cdr (assq 'foreground-color params)))
1631            (fg (cdr (assq 'background-color params))))
1632       (modify-frame-parameters frame
1633                                (list (cons 'foreground-color fg)
1634                                      (cons 'background-color bg)))
1635       (if (equal bg (cdr (assq 'mouse-color params)))
1636           (modify-frame-parameters frame
1637                                    (list (cons 'mouse-color fg))))
1638       (if (equal bg (cdr (assq 'cursor-color params)))
1639           (modify-frame-parameters frame
1640                                    (list (cons 'cursor-color fg)))))))
1641
1642
1643 (defun tty-create-frame-with-faces (&optional parameters)
1644   "Create a frame from optional frame parameters PARAMETERS.
1645 Parameters not specified by PARAMETERS are taken from
1646 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1647 contains a `reverse' parameter, handle that.  Value is the new frame
1648 created."
1649   (let ((frame (make-terminal-frame parameters))
1650         success)
1651     (unwind-protect
1652         (progn
1653           (tty-handle-reverse-video frame (frame-parameters frame))
1654           (frame-set-background-mode frame)
1655           (face-set-after-frame-default frame)
1656           (setq success t))
1657       (unless success
1658         (delete-frame frame)))
1659     frame))
1660
1661
1662 ;; Called from C function init_display to initialize faces of the
1663 ;; dumped terminal frame on startup.
1664
1665 (defun tty-set-up-initial-frame-faces ()
1666   (let ((frame (selected-frame)))
1667     (frame-set-background-mode frame)
1668     (face-set-after-frame-default frame)))
1669
1670
1671
1672 \f
1673 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1674 ;;; Compatiblity with 20.2
1675 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1676
1677 ;; Update a frame's faces when we change its default font.
1678
1679 (defalias 'frame-update-faces 'ignore)
1680 (make-obsolete 'frame-update-faces "No longer necessary" "21.1")
1681
1682 ;; Update the colors of FACE, after FRAME's own colors have been
1683 ;; changed.
1684
1685 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1686 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1687
1688 \f
1689 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1690 ;;; Standard faces.
1691 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1692
1693 (defgroup basic-faces nil
1694   "The standard faces of Emacs."
1695   :group 'faces)
1696
1697
1698 (defface default
1699   '((t nil))
1700   "Basic default face."
1701   :group 'basic-faces)
1702
1703
1704 (defface mode-line
1705   '((((type x w32 mac) (class color))
1706      (:box (:line-width -1 :style released-button)
1707            :background "grey75" :foreground "black"))
1708     (t
1709      (:inverse-video t)))
1710   "Basic mode line face."
1711   :version "21.1"
1712   :group 'modeline
1713   :group 'basic-faces)
1714
1715 ;; Make `modeline' an alias for `mode-line', for compatibility.
1716 (put 'modeline 'face-alias 'mode-line)
1717
1718 (defface header-line
1719   '((((type tty))
1720      ;; This used to be `:inverse-video t', but that doesn't look very
1721      ;; good when combined with inverse-video mode-lines and multiple
1722      ;; windows.  Underlining looks better, and is more consistent with
1723      ;; the window-system face variants, which deemphasize the
1724      ;; header-line in relation to the mode-line face.  If a terminal
1725      ;; can't underline, then the header-line will end up without any
1726      ;; highlighting; this may be too confusing in general, although it
1727      ;; happens to look good with the only current use of header-lines,
1728      ;; the info browser. XXX
1729      :underline t)
1730     (((class color grayscale) (background light))
1731      :inherit mode-line
1732      :background "grey90" :foreground "grey20"
1733      :box nil)
1734     (((class color grayscale) (background dark))
1735      :inherit mode-line
1736      :background "grey20" :foreground "grey90"
1737      :box nil)
1738     (((class mono) (background light))
1739      :inherit mode-line
1740      :background "white" :foreground "black"
1741      :inverse-video nil
1742      :box nil
1743      :underline t)
1744     (((class mono) (background dark))
1745      :inherit mode-line
1746      :background "black" :foreground "white"
1747      :inverse-video nil
1748      :box nil
1749      :underline t)
1750     (t
1751      :inverse-video t))
1752   "Basic header-line face."
1753   :version "21.1"
1754   :group 'basic-faces)
1755
1756
1757 (defface tool-bar
1758   '((((type x w32 mac) (class color))
1759      (:box (:line-width 1 :style released-button)
1760            :background "grey75" :foreground "black"))
1761     (((type x) (class mono))
1762      (:box (:line-width 1 :style released-button)
1763            :background "grey" :foreground "black"))
1764     (t
1765      ()))
1766   "Basic tool-bar face."
1767   :version "21.1"
1768   :group 'basic-faces)
1769
1770
1771 (defface minibuffer-prompt '((((background dark)) (:foreground "cyan"))
1772                              (((type pc)) (:foreground "white"))
1773                              (t (:foreground "dark blue")))
1774   "Face for minibuffer prompts."
1775   :version "21.3"
1776   :group 'basic-faces)
1777
1778 (setq minibuffer-prompt-properties
1779       (append minibuffer-prompt-properties (list 'face 'minibuffer-prompt)))
1780
1781 (defface region
1782   '((((type tty) (class color))
1783      (:background "blue" :foreground "white"))
1784     (((type tty) (class mono))
1785      (:inverse-video t))
1786     (((class color) (background dark))
1787      (:background "blue3"))
1788     (((class color) (background light))
1789      (:background "lightgoldenrod2"))
1790     (t (:background "gray")))
1791   "Basic face for highlighting the region."
1792   :version "21.1"
1793   :group 'basic-faces)
1794
1795
1796 (defface fringe
1797   '((((class color) (background light))
1798        (:background "grey95"))
1799       (((class color) (background dark))
1800        (:background "grey10"))
1801       (t
1802        (:background "gray")))
1803   "Basic face for the fringes to the left and right of windows under X."
1804   :version "21.1"
1805   :group 'frames
1806   :group 'basic-faces)
1807
1808
1809 (defface scroll-bar '()
1810   "Basic face for the scroll bar colors under X."
1811   :version "21.1"
1812   :group 'frames
1813   :group 'basic-faces)
1814
1815
1816 (defface menu
1817   '((((type tty))
1818      :inverse-video t)
1819     (((type x-toolkit))
1820      )
1821     (t
1822      :inverse-video t))
1823   "Basic face for the font and colors of the menu bar and popup menus."
1824   :version "21.1"
1825   :group 'menu
1826   :group 'basic-faces)
1827
1828
1829 (defface border '()
1830   "Basic face for the frame border under X."
1831   :version "21.1"
1832   :group 'frames
1833   :group 'basic-faces)
1834
1835
1836 (defface cursor '()
1837   "Basic face for the cursor color under X."
1838   :version "21.1"
1839   :group 'cursor
1840   :group 'basic-faces)
1841
1842
1843 (defface mouse '()
1844   "Basic face for the mouse color under X."
1845   :version "21.1"
1846   :group 'mouse
1847   :group 'basic-faces)
1848
1849
1850 (defface bold '((t (:weight bold)))
1851   "Basic bold face."
1852   :group 'basic-faces)
1853
1854
1855 (defface italic '((t (:slant italic)))
1856   "Basic italic font."
1857   :group 'basic-faces)
1858
1859
1860 (defface bold-italic '((t (:weight bold :slant italic)))
1861   "Basic bold-italic face."
1862   :group 'basic-faces)
1863
1864
1865 (defface underline '((t (:underline t)))
1866   "Basic underlined face."
1867   :group 'basic-faces)
1868
1869
1870 (defface highlight
1871   '((((type tty) (class color))
1872      (:background "green"))
1873     (((class color) (background light))
1874      (:background "darkseagreen2"))
1875     (((class color) (background dark))
1876      (:background "darkolivegreen"))
1877     (t (:inverse-video t)))
1878   "Basic face for highlighting."
1879   :group 'basic-faces)
1880
1881
1882 (defface secondary-selection
1883   '((((type tty) (class color))
1884      (:background "cyan" :foreground "black"))
1885     (((class color) (background light))
1886      (:background "yellow"))
1887     (((class color) (background dark))
1888      (:background "SkyBlue4"))
1889     (t (:inverse-video t)))
1890   "Basic face for displaying the secondary selection."
1891   :group 'basic-faces)
1892
1893
1894 (defface fixed-pitch '((t (:family "courier")))
1895   "The basic fixed-pitch face."
1896   :group 'basic-faces)
1897
1898
1899 (defface variable-pitch '((t (:family "helv")))
1900   "The basic variable-pitch face."
1901   :group 'basic-faces)
1902
1903
1904 (defface trailing-whitespace
1905   '((((class color) (background light))
1906      (:background "red"))
1907     (((class color) (background dark))
1908      (:background "red"))
1909     (t (:inverse-video t)))
1910   "Basic face for highlighting trailing whitespace."
1911   :version "21.1"
1912   :group 'font-lock                     ; like `show-trailing-whitespace'
1913   :group 'basic-faces)
1914
1915
1916 \f
1917 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1918 ;;; Manipulating font names.
1919 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1920
1921 ;; This is here for compatibilty with Emacs 20.2.  For example,
1922 ;; international/fontset.el uses x-resolve-font-name.  The following
1923 ;; functions are not used in the face implementation itself.
1924
1925 (defvar x-font-regexp nil)
1926 (defvar x-font-regexp-head nil)
1927 (defvar x-font-regexp-weight nil)
1928 (defvar x-font-regexp-slant nil)
1929
1930 (defconst x-font-regexp-weight-subnum 1)
1931 (defconst x-font-regexp-slant-subnum 2)
1932 (defconst x-font-regexp-swidth-subnum 3)
1933 (defconst x-font-regexp-adstyle-subnum 4)
1934
1935 ;;; Regexps matching font names in "Host Portable Character Representation."
1936 ;;;
1937 (let ((-                "[-?]")
1938       (foundry          "[^-]+")
1939       (family           "[^-]+")
1940       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
1941 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
1942       (weight\?         "\\([^-]*\\)")                                  ; 1
1943       (slant            "\\([ior]\\)")                                  ; 2
1944 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
1945       (slant\?          "\\([^-]?\\)")                                  ; 2
1946 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
1947       (swidth           "\\([^-]*\\)")                                  ; 3
1948 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
1949       (adstyle          "\\([^-]*\\)")                                  ; 4
1950       (pixelsize        "[0-9]+")
1951       (pointsize        "[0-9][0-9]+")
1952       (resx             "[0-9][0-9]+")
1953       (resy             "[0-9][0-9]+")
1954       (spacing          "[cmp?*]")
1955       (avgwidth         "[0-9]+")
1956       (registry         "[^-]+")
1957       (encoding         "[^-]+")
1958       )
1959   (setq x-font-regexp
1960         (concat "\\`\\*?[-?*]"
1961                 foundry - family - weight\? - slant\? - swidth - adstyle -
1962                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
1963                 registry - encoding "\\*?\\'"
1964                 ))
1965   (setq x-font-regexp-head
1966         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
1967                 "\\([-*?]\\|\\'\\)"))
1968   (setq x-font-regexp-slant (concat - slant -))
1969   (setq x-font-regexp-weight (concat - weight -))
1970   nil)
1971
1972
1973 (defun x-resolve-font-name (pattern &optional face frame)
1974   "Return a font name matching PATTERN.
1975 All wildcards in PATTERN are instantiated.
1976 If PATTERN is nil, return the name of the frame's base font, which never
1977 contains wildcards.
1978 Given optional arguments FACE and FRAME, return a font which is
1979 also the same size as FACE on FRAME, or fail."
1980   (or (symbolp face)
1981       (setq face (face-name face)))
1982   (and (eq frame t)
1983        (setq frame nil))
1984   (if pattern
1985       ;; Note that x-list-fonts has code to handle a face with nil as its font.
1986       (let ((fonts (x-list-fonts pattern face frame 1)))
1987         (or fonts
1988             (if face
1989                 (if (string-match "\\*" pattern)
1990                     (if (null (face-font face))
1991                         (error "No matching fonts are the same height as the frame default font")
1992                       (error "No matching fonts are the same height as face `%s'" face))
1993                   (if (null (face-font face))
1994                       (error "Height of font `%s' doesn't match the frame default font"
1995                              pattern)
1996                     (error "Height of font `%s' doesn't match face `%s'"
1997                            pattern face)))
1998               (error "No fonts match `%s'" pattern)))
1999         (car fonts))
2000     (cdr (assq 'font (frame-parameters (selected-frame))))))
2001
2002
2003 (defun x-frob-font-weight (font which)
2004   (let ((case-fold-search t))
2005     (cond ((string-match x-font-regexp font)
2006            (concat (substring font 0
2007                               (match-beginning x-font-regexp-weight-subnum))
2008                    which
2009                    (substring font (match-end x-font-regexp-weight-subnum)
2010                               (match-beginning x-font-regexp-adstyle-subnum))
2011                    ;; Replace the ADD_STYLE_NAME field with *
2012                    ;; because the info in it may not be the same
2013                    ;; for related fonts.
2014                    "*"
2015                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2016           ((string-match x-font-regexp-head font)
2017            (concat (substring font 0 (match-beginning 1)) which
2018                    (substring font (match-end 1))))
2019           ((string-match x-font-regexp-weight font)
2020            (concat (substring font 0 (match-beginning 1)) which
2021                    (substring font (match-end 1)))))))
2022 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
2023
2024 (defun x-frob-font-slant (font which)
2025   (let ((case-fold-search t))
2026     (cond ((string-match x-font-regexp font)
2027            (concat (substring font 0
2028                               (match-beginning x-font-regexp-slant-subnum))
2029                    which
2030                    (substring font (match-end x-font-regexp-slant-subnum)
2031                               (match-beginning x-font-regexp-adstyle-subnum))
2032                    ;; Replace the ADD_STYLE_NAME field with *
2033                    ;; because the info in it may not be the same
2034                    ;; for related fonts.
2035                    "*"
2036                    (substring font (match-end x-font-regexp-adstyle-subnum))))
2037           ((string-match x-font-regexp-head font)
2038            (concat (substring font 0 (match-beginning 2)) which
2039                    (substring font (match-end 2))))
2040           ((string-match x-font-regexp-slant font)
2041            (concat (substring font 0 (match-beginning 1)) which
2042                    (substring font (match-end 1)))))))
2043 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
2044
2045 ;; These aliases are here so that we don't get warnings about obsolete
2046 ;; functions from the byte compiler.
2047 (defalias 'internal-frob-font-weight 'x-frob-font-weight)
2048 (defalias 'internal-frob-font-slant 'x-frob-font-slant)
2049
2050 (defun x-make-font-bold (font)
2051   "Given an X font specification, make a bold version of it.
2052 If that can't be done, return nil."
2053   (internal-frob-font-weight font "bold"))
2054 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
2055
2056 (defun x-make-font-demibold (font)
2057   "Given an X font specification, make a demibold version of it.
2058 If that can't be done, return nil."
2059   (internal-frob-font-weight font "demibold"))
2060 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
2061
2062 (defun x-make-font-unbold (font)
2063   "Given an X font specification, make a non-bold version of it.
2064 If that can't be done, return nil."
2065   (internal-frob-font-weight font "medium"))
2066 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
2067
2068 (defun x-make-font-italic (font)
2069   "Given an X font specification, make an italic version of it.
2070 If that can't be done, return nil."
2071   (internal-frob-font-slant font "i"))
2072 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
2073
2074 (defun x-make-font-oblique (font) ; you say tomayto...
2075   "Given an X font specification, make an oblique version of it.
2076 If that can't be done, return nil."
2077   (internal-frob-font-slant font "o"))
2078 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
2079
2080 (defun x-make-font-unitalic (font)
2081   "Given an X font specification, make a non-italic version of it.
2082 If that can't be done, return nil."
2083   (internal-frob-font-slant font "r"))
2084 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
2085
2086 (defun x-make-font-bold-italic (font)
2087   "Given an X font specification, make a bold and italic version of it.
2088 If that can't be done, return nil."
2089   (and (setq font (internal-frob-font-weight font "bold"))
2090        (internal-frob-font-slant font "i")))
2091 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
2092
2093 (provide 'faces)
2094
2095 ;;; faces.el ends here