code.delx.au - gnu-emacs/blob - lisp/org/org-id.el

   1 ;;; org-id.el --- Global identifiers for Org-mode entries
   2 ;;
   3 ;; Copyright (C) 2008-2012 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;;
   9 ;; This file is part of GNU Emacs.
  10 ;;
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  24 ;;
  25 ;;; Commentary:
  26
  27 ;; This file implements globally unique identifiers for Org-mode entries.
  28 ;; Identifiers are stored in the entry as an :ID: property.  Functions
  29 ;; are provided that create and retrieve such identifiers, and that find
  30 ;; entries based on the identifier.
  31
  32 ;; Identifiers consist of a prefix (default "Org" given by the variable
  33 ;; `org-id-prefix') and a unique part that can be created by a number
  34 ;; of different methods, see the variable `org-id-method'.
  35 ;; Org has a builtin method that uses a compact encoding of the creation
  36 ;; time of the ID, with microsecond accuracy.  This virtually
  37 ;; guarantees globally unique identifiers, even if several people are
  38 ;; creating IDs at the same time in files that will eventually be used
  39 ;; together.
  40 ;;
  41 ;; By default Org uses UUIDs as global unique identifiers.
  42 ;;
  43 ;; This file defines the following API:
  44 ;;
  45 ;; org-id-get-create
  46 ;;        Create an ID for the entry at point if it does not yet have one.
  47 ;;        Returns the ID (old or new).  This function can be used
  48 ;;        interactively, with prefix argument the creation of a new ID is
  49 ;;        forced, even if there was an old one.
  50 ;;
  51 ;; org-id-get
  52 ;;        Get the ID property of an entry.  Using appropriate arguments
  53 ;;        to the function, it can also create the ID for this entry.
  54 ;;
  55 ;; org-id-goto
  56 ;;        Command to go to a specific ID, this command can be used
  57 ;;        interactively.
  58 ;;
  59 ;; org-id-get-with-outline-path-completion
  60 ;;        Retrieve the ID of an entry, using outline path completion.
  61 ;;        This function can work for multiple files.
  62 ;;
  63 ;; org-id-get-with-outline-drilling
  64 ;;        Retrieve the ID of an entry, using outline path completion.
  65 ;;        This function only works for the current file.
  66 ;;
  67 ;; org-id-find
  68 ;;        Find the location of an entry with specific id.
  69 ;;
  70
  71 ;;; Code:
  72
  73 (require 'org)
  74
  75 (declare-function message-make-fqdn "message" ())
  76 (declare-function org-pop-to-buffer-same-window
  77                   "org-compat" (&optional buffer-or-name norecord label))
  78
  79 ;;; Customization
  80
  81 (defgroup org-id nil
  82   "Options concerning global entry identifiers in Org-mode."
  83   :tag "Org ID"
  84   :group 'org)
  85
  86 (define-obsolete-variable-alias
  87   'org-link-to-org-use-id 'org-id-link-to-org-use-id "24.3")
  88 (defcustom org-id-link-to-org-use-id nil
  89   "Non-nil means storing a link to an Org file will use entry IDs.
  90
  91 The variable can have the following values:
  92
  93 t     Create an ID if needed to make a link to the current entry.
  94
  95 create-if-interactive
  96       If `org-store-link' is called directly (interactively, as a user
  97       command), do create an ID to support the link.  But when doing the
  98       job for capture, only use the ID if it already exists.  The
  99       purpose of this setting is to avoid proliferation of unwanted
 100       IDs, just because you happen to be in an Org file when you
 101       call `org-capture' that automatically and preemptively creates a
 102       link.  If you do want to get an ID link in a capture template to
 103       an entry not having an ID, create it first by explicitly creating
 104       a link to it, using `C-c C-l' first.
 105
 106 create-if-interactive-and-no-custom-id
 107       Like create-if-interactive, but do not create an ID if there is
 108       a CUSTOM_ID property defined in the entry.
 109
 110 use-existing
 111       Use existing ID, do not create one.
 112
 113 nil   Never use an ID to make a link, instead link using a text search for
 114       the headline text."
 115   :group 'org-link-store
 116   :group 'org-id
 117   :version "24.3"
 118   :type '(choice
 119           (const :tag "Create ID to make link" t)
 120           (const :tag "Create if storing link interactively"
 121                  create-if-interactive)
 122           (const :tag "Create if storing link interactively and no CUSTOM_ID is present"
 123                  create-if-interactive-and-no-custom-id)
 124           (const :tag "Only use existing" use-existing)
 125           (const :tag "Do not use ID to create link" nil)))
 126
 127 (defcustom org-id-uuid-program "uuidgen"
 128   "The uuidgen program."
 129   :group 'org-id
 130   :type 'string)
 131
 132 (defcustom org-id-method 'uuid
 133   "The method that should be used to create new IDs.
 134
 135 An ID will consist of the optional prefix specified in `org-id-prefix',
 136 and a unique part created by the method this variable specifies.
 137
 138 Allowed values are:
 139
 140 org        Org's own internal method, using an encoding of the current time to
 141            microsecond accuracy, and optionally the current domain of the
 142            computer.  See the variable `org-id-include-domain'.
 143
 144 uuid       Create random (version 4) UUIDs.  If the program defined in
 145            `org-id-uuid-program' is available it is used to create the ID.
 146            Otherwise an internal functions is used."
 147   :group 'org-id
 148   :type '(choice
 149           (const :tag "Org's internal method" org)
 150           (const :tag "external: uuidgen" uuid)))
 151
 152 (defcustom org-id-prefix nil
 153   "The prefix for IDs.
 154
 155 This may be a string, or it can be nil to indicate that no prefix is required.
 156 When a string, the string should have no space characters as IDs are expected
 157 to have no space characters in them."
 158   :group 'org-id
 159   :type '(choice
 160           (const :tag "No prefix")
 161           (string :tag "Prefix")))
 162
 163 (defcustom org-id-include-domain nil
 164   "Non-nil means add the domain name to new IDs.
 165 This ensures global uniqueness of IDs, and is also suggested by
 166 RFC 2445 in combination with RFC 822.  This is only relevant if
 167 `org-id-method' is `org'.  When uuidgen is used, the domain will never
 168 be added.
 169 The default is to not use this because we have no really good way to get
 170 the true domain, and Org entries will normally not be shared with enough
 171 people to make this necessary."
 172   :group 'org-id
 173   :type 'boolean)
 174
 175 (defcustom org-id-track-globally t
 176   "Non-nil means track IDs through files, so that links work globally.
 177 This work by maintaining a hash table for IDs and writing this table
 178 to disk when exiting Emacs.  Because of this, it works best if you use
 179 a single Emacs process, not many.
 180
 181 When nil, IDs are not tracked.  Links to IDs will still work within
 182 a buffer, but not if the entry is located in another file.
 183 IDs can still be used if the entry with the id is in the same file as
 184 the link."
 185   :group 'org-id
 186   :type 'boolean)
 187
 188 (defcustom org-id-locations-file (convert-standard-filename
 189                                   "~/.emacs.d/.org-id-locations")
 190   "The file for remembering in which file an ID was defined.
 191 This variable is only relevant when `org-id-track-globally' is set."
 192   :group 'org-id
 193   :type 'file)
 194
 195 (defvar org-id-locations nil
 196   "List of files with IDs in those files.")
 197
 198 (defvar org-id-files nil
 199   "List of files that contain IDs.")
 200
 201 (defcustom org-id-extra-files 'org-agenda-text-search-extra-files
 202   "Files to be searched for IDs, besides the agenda files.
 203 When Org reparses files to remake the list of files and IDs it is tracking,
 204 it will normally scan the agenda files, the archives related to agenda files,
 205 any files that are listed as ID containing in the current register, and
 206 any Org-mode files currently visited by Emacs.
 207 You can list additional files here.
 208 This variable is only relevant when `org-id-track-globally' is set."
 209   :group 'org-id
 210   :type
 211   '(choice
 212     (symbol :tag "Variable")
 213     (repeat :tag "List of files"
 214             (file))))
 215
 216 (defcustom org-id-search-archives t
 217   "Non-nil means search also the archive files of agenda files for entries.
 218 This is a possibility to reduce overhead, but it means that entries moved
 219 to the archives can no longer be found by ID.
 220 This variable is only relevant when `org-id-track-globally' is set."
 221   :group 'org-id
 222   :type 'boolean)
 223
 224 ;;; The API functions
 225
 226 ;;;###autoload
 227 (defun org-id-get-create (&optional force)
 228   "Create an ID for the current entry and return it.
 229 If the entry already has an ID, just return it.
 230 With optional argument FORCE, force the creation of a new ID."
 231   (interactive "P")
 232   (when force
 233     (org-entry-put (point) "ID" nil))
 234   (org-id-get (point) 'create))
 235
 236 ;;;###autoload
 237 (defun org-id-copy ()
 238   "Copy the ID of the entry at point to the kill ring.
 239 Create an ID if necessary."
 240   (interactive)
 241   (org-kill-new (org-id-get nil 'create)))
 242
 243 ;;;###autoload
 244 (defun org-id-get (&optional pom create prefix)
 245   "Get the ID property of the entry at point-or-marker POM.
 246 If POM is nil, refer to the entry at point.
 247 If the entry does not have an ID, the function returns nil.
 248 However, when CREATE is non nil, create an ID if none is present already.
 249 PREFIX will be passed through to `org-id-new'.
 250 In any case, the ID of the entry is returned."
 251   (org-with-point-at pom
 252     (let ((id (org-entry-get nil "ID")))
 253       (cond
 254        ((and id (stringp id) (string-match "\\S-" id))
 255         id)
 256        (create
 257         (setq id (org-id-new prefix))
 258         (org-entry-put pom "ID" id)
 259         (org-id-add-location id (buffer-file-name (buffer-base-buffer)))
 260         id)))))
 261
 262 ;;;###autoload
 263 (defun org-id-get-with-outline-path-completion (&optional targets)
 264   "Use outline-path-completion to retrieve the ID of an entry.
 265 TARGETS may be a setting for `org-refile-targets' to define the eligible
 266 headlines.  When omitted, all headlines in all agenda files are
 267 eligible.
 268 It returns the ID of the entry.  If necessary, the ID is created."
 269   (let* ((org-refile-targets (or targets '((nil . (:maxlevel . 10)))))
 270          (org-refile-use-outline-path
 271           (if (caar org-refile-targets) 'file t))
 272          (org-refile-target-verify-function nil)
 273          (spos (org-refile-get-location "Entry"))
 274          (pom (and spos (move-marker (make-marker) (nth 3 spos)
 275                                      (get-file-buffer (nth 1 spos))))))
 276     (prog1 (org-id-get pom 'create)
 277       (move-marker pom nil))))
 278
 279 ;;;###autoload
 280 (defun org-id-get-with-outline-drilling (&optional targets)
 281   "Use an outline-cycling interface to retrieve the ID of an entry.
 282 This only finds entries in the current buffer, using `org-get-location'.
 283 It returns the ID of the entry.  If necessary, the ID is created."
 284   (let* ((spos (org-get-location (current-buffer) org-goto-help))
 285          (pom (and spos (move-marker (make-marker) (car spos)))))
 286     (prog1 (org-id-get pom 'create)
 287       (move-marker pom nil))))
 288
 289 ;;;###autoload
 290 (defun org-id-goto (id)
 291   "Switch to the buffer containing the entry with id ID.
 292 Move the cursor to that entry in that buffer."
 293   (interactive "sID: ")
 294   (let ((m (org-id-find id 'marker)))
 295     (unless m
 296       (error "Cannot find entry with ID \"%s\"" id))
 297     (org-pop-to-buffer-same-window (marker-buffer m))
 298     (goto-char m)
 299     (move-marker m nil)
 300     (org-show-context)))
 301
 302 ;;;###autoload
 303 (defun org-id-find (id &optional markerp)
 304   "Return the location of the entry with the id ID.
 305 The return value is a cons cell (file-name . position), or nil
 306 if there is no entry with that ID.
 307 With optional argument MARKERP, return the position as a new marker."
 308   (cond
 309    ((symbolp id) (setq id (symbol-name id)))
 310    ((numberp id) (setq id (number-to-string id))))
 311   (let ((file (org-id-find-id-file id))
 312         org-agenda-new-buffers where)
 313     (when file
 314       (setq where (org-id-find-id-in-file id file markerp)))
 315     (unless where
 316       (org-id-update-id-locations nil t)
 317       (setq file (org-id-find-id-file id))
 318       (when file
 319         (setq where (org-id-find-id-in-file id file markerp))))
 320     where))
 321
 322 ;;; Internal functions
 323
 324 ;; Creating new IDs
 325
 326 (defun org-id-new (&optional prefix)
 327   "Create a new globally unique ID.
 328
 329 An ID consists of two parts separated by a colon:
 330 - a prefix
 331 - a unique part that will be created according to `org-id-method'.
 332
 333 PREFIX can specify the prefix, the default is given by the variable
 334 `org-id-prefix'.  However, if PREFIX is the symbol `none', don't use any
 335 prefix even if `org-id-prefix' specifies one.
 336
 337 So a typical ID could look like \"Org:4nd91V40HI\"."
 338   (let* ((prefix (if (eq prefix 'none)
 339                      ""
 340                    (concat (or prefix org-id-prefix) ":")))
 341          unique)
 342     (if (equal prefix ":") (setq prefix ""))
 343     (cond
 344      ((memq org-id-method '(uuidgen uuid))
 345       (setq unique (org-trim (shell-command-to-string org-id-uuid-program)))
 346       (unless (org-uuidgen-p unique)
 347         (setq unique (org-id-uuid))))
 348      ((eq org-id-method 'org)
 349       (let* ((etime (org-id-reverse-string (org-id-time-to-b36)))
 350              (postfix (if org-id-include-domain
 351                           (progn
 352                             (require 'message)
 353                             (concat "@" (message-make-fqdn))))))
 354         (setq unique (concat etime postfix))))
 355      (t (error "Invalid `org-id-method'")))
 356     (concat prefix unique)))
 357
 358 (defun org-id-uuid ()
 359   "Return string with random (version 4) UUID."
 360   (let ((rnd (md5 (format "%s%s%s%s%s%s%s"
 361                           (random)
 362                           (current-time)
 363                           (user-uid)
 364                           (emacs-pid)
 365                           (user-full-name)
 366                           user-mail-address
 367                           (recent-keys)))))
 368     (format "%s-%s-4%s-%s%s-%s"
 369             (substring rnd 0 8)
 370             (substring rnd 8 12)
 371             (substring rnd 13 16)
 372             (format "%x"
 373                     (logior
 374                      #b10000000
 375                      (logand
 376                       #b10111111
 377                       (string-to-number
 378                        (substring rnd 16 18) 16))))
 379             (substring rnd 18 20)
 380             (substring rnd 20 32))))
 381
 382 (defun org-id-reverse-string (s)
 383   (mapconcat 'char-to-string (nreverse (string-to-list s)) ""))
 384
 385 (defun org-id-int-to-b36-one-digit (i)
 386   "Turn an integer between 0 and 61 into a single character 0..9, A..Z, a..z."
 387   (cond
 388    ((< i 10) (+ ?0 i))
 389    ((< i 36) (+ ?a i -10))
 390    (t (error "Larger that 35"))))
 391
 392 (defun org-id-b36-to-int-one-digit (i)
 393   "Turn a character 0..9, A..Z, a..z into a number 0..61.
 394 The input I may be a character, or a single-letter string."
 395   (and (stringp i) (setq i (string-to-char i)))
 396   (cond
 397    ((and (>= i ?0) (<= i ?9)) (- i ?0))
 398    ((and (>= i ?a) (<= i ?z)) (+ (- i ?a) 10))
 399    (t (error "Invalid b36 letter"))))
 400
 401 (defun org-id-int-to-b36 (i &optional length)
 402   "Convert an integer to a base-36 number represented as a string."
 403   (let ((s ""))
 404     (while (> i 0)
 405       (setq s (concat (char-to-string
 406                        (org-id-int-to-b36-one-digit (mod i 36))) s)
 407             i (/ i 36)))
 408     (setq length (max 1 (or length 1)))
 409     (if (< (length s) length)
 410         (setq s (concat (make-string (- length (length s)) ?0) s)))
 411     s))
 412
 413 (defun org-id-b36-to-int (s)
 414   "Convert a base-36 string into the corresponding integer."
 415   (let ((r 0))
 416     (mapc (lambda (i) (setq r (+ (* r 36) (org-id-b36-to-int-one-digit i))))
 417           s)
 418     r))
 419
 420 (defun org-id-time-to-b36 (&optional time)
 421   "Encode TIME as a 10-digit string.
 422 This string holds the time to micro-second accuracy, and can be decoded
 423 using `org-id-decode'."
 424   (setq time (or time (current-time)))
 425   (concat (org-id-int-to-b36 (nth 0 time) 4)
 426           (org-id-int-to-b36 (nth 1 time) 4)
 427           (org-id-int-to-b36 (or (nth 2 time) 0) 4)))
 428
 429 (defun org-id-decode (id)
 430   "Split ID into the prefix and the time value that was used to create it.
 431 The return value is (prefix . time) where PREFIX is nil or a string,
 432 and time is the usual three-integer representation of time."
 433   (let (prefix time parts)
 434     (setq parts (org-split-string id ":"))
 435     (if (= 2 (length parts))
 436         (setq prefix (car parts) time (nth 1 parts))
 437       (setq prefix nil time (nth 0 parts)))
 438     (setq time (org-id-reverse-string time))
 439     (setq time (list (org-id-b36-to-int (substring time 0 4))
 440                      (org-id-b36-to-int (substring time 4 8))
 441                      (org-id-b36-to-int (substring time 8 12))))
 442     (cons prefix time)))
 443
 444 ;; Storing ID locations (files)
 445
 446 (defun org-id-update-id-locations (&optional files silent)
 447   "Scan relevant files for IDs.
 448 Store the relation between files and corresponding IDs.
 449 This will scan all agenda files, all associated archives, and all
 450 files currently mentioned in `org-id-locations'.
 451 When FILES is given, scan these files instead.
 452 When CHECK is given, prepare detailed information about duplicate IDs."
 453   (interactive)
 454   (if (not org-id-track-globally)
 455       (error "Please turn on `org-id-track-globally' if you want to track IDs")
 456     (let* ((org-id-search-archives
 457             (or org-id-search-archives
 458                 (and (symbolp org-id-extra-files)
 459                      (symbol-value org-id-extra-files)
 460                      (member 'agenda-archives org-id-extra-files))))
 461            (files
 462             (or files
 463                 (append
 464                  ;; Agenda files and all associated archives
 465                  (org-agenda-files t org-id-search-archives)
 466                  ;; Explicit extra files
 467                  (if (symbolp org-id-extra-files)
 468                      (symbol-value org-id-extra-files)
 469                    org-id-extra-files)
 470                  ;; Files associated with live org-mode buffers
 471                  (delq nil
 472                        (mapcar (lambda (b)
 473                                  (with-current-buffer b
 474                                    (and (derived-mode-p 'org-mode) (buffer-file-name))))
 475                                (buffer-list)))
 476                  ;; All files known to have IDs
 477                  org-id-files)))
 478            org-agenda-new-buffers
 479            file nfiles tfile ids reg found id seen (ndup 0))
 480       (when (member 'agenda-archives files)
 481         (setq files (delq 'agenda-archives (copy-sequence files))))
 482       (setq nfiles (length files))
 483       (while (setq file (pop files))
 484         (unless silent
 485           (message "Finding ID locations (%d/%d files): %s"
 486                    (- nfiles (length files)) nfiles file))
 487         (setq tfile (file-truename file))
 488         (when (and (file-exists-p file) (not (member tfile seen)))
 489           (push tfile seen)
 490           (setq ids nil)
 491           (with-current-buffer (org-get-agenda-file-buffer file)
 492             (save-excursion
 493               (save-restriction
 494                 (widen)
 495                 (goto-char (point-min))
 496                 (while (re-search-forward "^[ \t]*:ID:[ \t]+\\(\\S-+\\)[ \t]*$"
 497                                           nil t)
 498                   (setq id (org-match-string-no-properties 1))
 499                   (if (member id found)
 500                       (progn
 501                         (message "Duplicate ID \"%s\", also in file %s"
 502                                  id (or (car (delq
 503                                               nil
 504                                               (mapcar
 505                                                (lambda (x)
 506                                                  (if (member id (cdr x))
 507                                                      (car x)))
 508                                                reg)))
 509                                         (buffer-file-name)))
 510                         (when (= ndup 0)
 511                           (ding)
 512                           (sit-for 2))
 513                         (setq ndup (1+ ndup)))
 514                     (push id found)
 515                     (push id ids)))
 516                 (push (cons (abbreviate-file-name file) ids) reg))))))
 517       (org-release-buffers org-agenda-new-buffers)
 518       (setq org-agenda-new-buffers nil)
 519       (setq org-id-locations reg)
 520       (setq org-id-files (mapcar 'car org-id-locations))
 521       (org-id-locations-save) ;; this function can also handle the alist form
 522       ;; now convert to a hash
 523       (setq org-id-locations (org-id-alist-to-hash org-id-locations))
 524       (if (> ndup 0)
 525           (message "WARNING: %d duplicate IDs found, check *Messages* buffer" ndup)
 526         (message "%d unique files scanned for IDs" (length org-id-files)))
 527       org-id-locations)))
 528
 529 (defun org-id-locations-save ()
 530   "Save `org-id-locations' in `org-id-locations-file'."
 531   (when (and org-id-track-globally org-id-locations)
 532     (let ((out (if (hash-table-p org-id-locations)
 533                    (org-id-hash-to-alist org-id-locations)
 534                  org-id-locations)))
 535       (with-temp-file org-id-locations-file
 536         (print out (current-buffer))))))
 537
 538 (defun org-id-locations-load ()
 539   "Read the data from `org-id-locations-file'."
 540   (setq org-id-locations nil)
 541   (when org-id-track-globally
 542     (with-temp-buffer
 543       (condition-case nil
 544           (progn
 545             (insert-file-contents-literally org-id-locations-file)
 546             (goto-char (point-min))
 547             (setq org-id-locations (read (current-buffer))))
 548         (error
 549          (message "Could not read org-id-values from %s.  Setting it to nil."
 550                   org-id-locations-file))))
 551     (setq org-id-files (mapcar 'car org-id-locations))
 552     (setq org-id-locations (org-id-alist-to-hash org-id-locations))))
 553
 554 (defun org-id-add-location (id file)
 555   "Add the ID with location FILE to the database of ID locations."
 556   ;; Only if global tracking is on, and when the buffer has a file
 557   (when (and org-id-track-globally id file)
 558     (unless org-id-locations (org-id-locations-load))
 559     (puthash id (abbreviate-file-name file) org-id-locations)
 560     (add-to-list 'org-id-files (abbreviate-file-name file))))
 561
 562 (unless noninteractive
 563   (add-hook 'kill-emacs-hook 'org-id-locations-save))
 564
 565 (defun org-id-hash-to-alist (hash)
 566   "Turn an org-id hash into an alist, so that it can be written to a file."
 567   (let (res x)
 568     (maphash
 569      (lambda (k v)
 570        (if (setq x (member v res))
 571            (setcdr x (cons k (cdr x)))
 572          (push (list v k) res)))
 573      hash)
 574     res))
 575
 576 (defun org-id-alist-to-hash (list)
 577   "Turn an org-id location list into a hash table."
 578   (let ((res (make-hash-table
 579               :test 'equal
 580               :size (apply '+ (mapcar 'length list))))
 581         f)
 582     (mapc
 583      (lambda (x)
 584        (setq f (car x))
 585        (mapc (lambda (i) (puthash i f res)) (cdr x)))
 586      list)
 587     res))
 588
 589 (defun org-id-paste-tracker (txt &optional buffer-or-file)
 590   "Update any IDs in TXT and assign BUFFER-OR-FILE to them."
 591   (when org-id-track-globally
 592     (save-match-data
 593       (setq buffer-or-file (or buffer-or-file (current-buffer)))
 594       (when (bufferp buffer-or-file)
 595         (setq buffer-or-file (or (buffer-base-buffer buffer-or-file)
 596                                  buffer-or-file))
 597         (setq buffer-or-file (buffer-file-name buffer-or-file)))
 598       (when buffer-or-file
 599         (let ((fname (abbreviate-file-name buffer-or-file))
 600               (s 0))
 601           (while (string-match "^[ \t]*:ID:[ \t]+\\([^ \t\n\r]+\\)" txt s)
 602             (setq s (match-end 0))
 603             (org-id-add-location (match-string 1 txt) fname)))))))
 604
 605 ;; Finding entries with specified id
 606
 607 ;;;###autoload
 608 (defun org-id-find-id-file (id)
 609   "Query the id database for the file in which this ID is located."
 610   (unless org-id-locations (org-id-locations-load))
 611   (or (and org-id-locations
 612            (hash-table-p org-id-locations)
 613            (gethash id org-id-locations))
 614       ;; ball back on current buffer
 615       (buffer-file-name (or (buffer-base-buffer (current-buffer))
 616                             (current-buffer)))))
 617
 618 (defun org-id-find-id-in-file (id file &optional markerp)
 619   "Return the position of the entry ID in FILE.
 620 If that files does not exist, or if it does not contain this ID,
 621 return nil.
 622 The position is returned as a cons cell (file-name . position).  With
 623 optional argument MARKERP, return the position as a new marker."
 624   (let (org-agenda-new-buffers buf pos)
 625     (cond
 626      ((not file) nil)
 627      ((not (file-exists-p file)) nil)
 628      (t (with-current-buffer (setq buf (org-get-agenda-file-buffer file))
 629           (setq pos (org-find-entry-with-id id))
 630           (when pos
 631             (if markerp
 632                 (move-marker (make-marker) pos buf)
 633               (cons file pos))))))))
 634
 635 ;; id link type
 636
 637 ;; Calling the following function is hard-coded into `org-store-link',
 638 ;; so we do have to add it to `org-store-link-functions'.
 639
 640 ;;;###autoload
 641 (defun org-id-store-link ()
 642   "Store a link to the current entry, using its ID."
 643   (interactive)
 644   (when (and (buffer-file-name (buffer-base-buffer)) (derived-mode-p 'org-mode))
 645     (let* ((link (concat "id:" (org-id-get-create)))
 646            (case-fold-search nil)
 647            (desc (save-excursion
 648                    (org-back-to-heading t)
 649                    (or (and (looking-at org-complex-heading-regexp)
 650                             (if (match-end 4)
 651                                 (match-string 4)
 652                               (match-string 0)))
 653                        link))))
 654       (org-store-link-props :link link :description desc :type "id")
 655       link)))
 656
 657 (defun org-id-open (id)
 658   "Go to the entry with id ID."
 659   (org-mark-ring-push)
 660   (let ((m (org-id-find id 'marker))
 661         cmd)
 662     (unless m
 663       (error "Cannot find entry with ID \"%s\"" id))
 664     ;; Use a buffer-switching command in analogy to finding files
 665     (setq cmd
 666           (or
 667            (cdr
 668             (assq
 669              (cdr (assq 'file org-link-frame-setup))
 670              '((find-file . switch-to-buffer)
 671                (find-file-other-window . switch-to-buffer-other-window)
 672                (find-file-other-frame . switch-to-buffer-other-frame))))
 673            'switch-to-buffer-other-window))
 674     (if (not (equal (current-buffer) (marker-buffer m)))
 675         (funcall cmd (marker-buffer m)))
 676     (goto-char m)
 677     (move-marker m nil)
 678     (org-show-context)))
 679
 680 (org-add-link-type "id" 'org-id-open)
 681
 682 (provide 'org-id)
 683
 684 ;;; org-id.el ends here