code.delx.au - gnu-emacs/blob - lisp/loadhist.el

   1 ;;; loadhist.el --- lisp functions for working with feature groups
   2
   3 ;; Copyright (C) 1995, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   6 ;; Version: 1.0
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions exploit the load-history system variable.
  29 ;; Entry points include `unload-feature', `symbol-file', and
  30 ;; `feature-file', documented in the Emacs Lisp manual.
  31
  32 ;;; Code:
  33
  34 (defun feature-symbols (feature)
  35   "Return the file and list of symbols associated with a given FEATURE."
  36    (catch 'foundit
  37      (mapcar
  38       (function (lambda (x)
  39                   (if (member (cons 'provide feature) (cdr x))
  40                       (throw 'foundit x))))
  41       load-history)
  42      nil))
  43
  44 (defun feature-file (feature)
  45   "Return the file name from which a given FEATURE was loaded.
  46 Actually, return the load argument, if any; this is sometimes the name of a
  47 Lisp file without an extension.  If the feature came from an eval-buffer on
  48 a buffer with no associated file, or an eval-region, return nil."
  49   (if (not (featurep feature))
  50       (error "%s is not a currently loaded feature" (symbol-name feature))
  51     (car (feature-symbols feature))))
  52
  53 (defun file-provides (file)
  54   "Return the list of features provided by FILE."
  55   (let ((symbols (cdr (assoc file load-history))) (provides nil))
  56     (mapcar
  57      (function (lambda (x)
  58                  (if (and (consp x) (eq (car x) 'provide))
  59                      (setq provides (cons (cdr x) provides)))))
  60      symbols)
  61     provides
  62     ))
  63
  64 (defun file-requires (file)
  65   "Return the list of features required by FILE."
  66   (let ((symbols (cdr (assoc file load-history))) (requires nil))
  67     (mapcar
  68      (function (lambda (x)
  69                  (if (and (consp x) (eq (car x) 'require))
  70                      (setq requires (cons (cdr x) requires)))))
  71      symbols)
  72     requires
  73     ))
  74
  75 (defun file-set-intersect (p q)
  76   ;; Return the set intersection of two lists
  77   (let ((ret nil))
  78     (mapcar
  79      (function (lambda (x) (if (memq x q) (setq ret (cons x ret)))))
  80      p)
  81     ret
  82     ))
  83
  84 (defun file-dependents (file)
  85   "Return the list of loaded libraries that depend on FILE.
  86 This can include FILE itself."
  87   (let ((provides (file-provides file)) (dependents nil))
  88     (mapcar
  89      (function (lambda (x)
  90                  (if (file-set-intersect provides (file-requires (car x)))
  91                      (setq dependents (cons (car x) dependents)))))
  92      load-history)
  93     dependents
  94     ))
  95
  96 (defun read-feature (prompt)
  97   "Read a feature name \(string\) from the minibuffer.
  98 Prompt with PROMPT and completing from `features', and
  99 return the feature \(symbol\)."
 100   (intern (completing-read prompt
 101                            (mapcar (function (lambda (feature)
 102                                                (list (symbol-name feature))))
 103                                    features)
 104                            nil t)))
 105
 106 (defvar loadhist-hook-functions
 107   '(after-change-function after-change-functions
 108 after-insert-file-functions auto-fill-function before-change-function
 109 before-change-functions blink-paren-function
 110 buffer-access-fontify-functions command-line-functions
 111 comment-indent-function kill-buffer-query-functions
 112 kill-emacs-query-functions lisp-indent-function
 113 redisplay-end-trigger-functions temp-buffer-show-function
 114 window-scroll-functions window-size-change-functions
 115 write-region-annotate-functions)
 116   "A list of special hooks from the `Standard Hooks' node of the Lisp manual.
 117
 118 These are symbols with hook-type values whose names don't end in
 119 `-hook' or `-hooks', from which `unload-feature' tries to remove
 120 pertinent symbols.")
 121
 122 ;;;###autoload
 123 (defun unload-feature (feature &optional force)
 124   "Unload the library that provided FEATURE, restoring all its autoloads.
 125 If the feature is required by any other loaded code, and optional FORCE
 126 is nil, raise an error."
 127   (interactive (list (read-feature "Feature: ")))
 128   (if (not (featurep feature))
 129       (error "%s is not a currently loaded feature" (symbol-name feature)))
 130   (if (not force)
 131       (let* ((file (feature-file feature))
 132              (dependents (delete file (copy-sequence (file-dependents file)))))
 133         (if dependents
 134             (error "Loaded libraries %s depend on %s"
 135                    (prin1-to-string dependents) file))))
 136   (let* ((flist (feature-symbols feature))
 137          (file (car flist))
 138          (unload-hook (intern-soft (concat (symbol-name feature)
 139                                            "-unload-hook"))))
 140     ;; Try to avoid losing badly when hooks installed in critical
 141     ;; places go away.  (Some packages install things on
 142     ;; `kill-buffer-hook', `activate-menubar-hook' and the like.)
 143     ;; First off, provide a clean way for package `foo' to arrange
 144     ;; this by defining `foo-unload-hook'.
 145     (if unload-hook
 146         (run-hooks unload-hook)
 147       ;; Otherwise, do our best.  Look through the obarray for symbols
 148       ;; which seem to be hook variables or special hook functions and
 149       ;; remove anything from them which matches the feature-symbols
 150       ;; about to get zapped.  Obviously this won't get anonymous
 151       ;; functions which the package might just have installed, and
 152       ;; there might be other important state, but this tactic
 153       ;; normally works.
 154       (mapatoms
 155        (lambda (x)
 156          (if (or (and (boundp x)        ; Random hooks.
 157                       (consp (symbol-value x))
 158                       (string-match "-hooks?\\'" (symbol-name x)))
 159                  (and (fboundp x)       ; Known abnormal hooks etc.
 160                       (memq x loadhist-hook-functions)))
 161              (mapcar (lambda (y) (remove-hook x y))
 162                      (cdr flist))))))
 163     (mapcar
 164      (lambda (x)
 165        (cond ((stringp x) nil)
 166              ((consp x)
 167               ;; Remove any feature names that this file provided.
 168               (if (eq (car x) 'provide)
 169                   (setq features (delq (cdr x) features))))
 170              ((boundp x) (makunbound x))
 171              ((fboundp x)
 172               (fmakunbound x)
 173               (let ((aload (get x 'autoload)))
 174                 (if aload (fset x (cons 'autoload aload)))))))
 175      (cdr flist))
 176     ;; Delete the load-history element for this file.
 177     (let ((elt (assoc file load-history)))
 178       (setq load-history (delq elt load-history)))))
 179
 180 (provide 'loadhist)
 181
 182 ;;; loadhist.el ends here