code.delx.au - gnu-emacs/blob - lisp/eshell/em-ls.el

   1 ;;; em-ls.el --- implementation of ls in Lisp
   2
   3 ;; Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008  Free Software Foundation, Inc.
   5
   6 ;; Author: John Wiegley <johnw@gnu.org>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Most of the command switches recognized by GNU's ls utility are
  26 ;; supported ([(fileutils)ls invocation]).
  27
  28 ;;; Code:
  29
  30 (eval-when-compile
  31   (require 'cl)
  32   (require 'eshell))
  33 (require 'esh-util)
  34 (require 'esh-opt)
  35
  36 ;;;###autoload
  37 (eshell-defgroup eshell-ls nil
  38   "This module implements the \"ls\" utility fully in Lisp.  If it is
  39 passed any unrecognized command switches, it will revert to the
  40 operating system's version.  This version of \"ls\" uses text
  41 properties to colorize its output based on the setting of
  42 `eshell-ls-use-colors'."
  43   :tag "Implementation of `ls' in Lisp"
  44   :group 'eshell-module)
  45
  46 ;;; User Variables:
  47
  48 (defvar eshell-ls-orig-insert-directory
  49   (symbol-function 'insert-directory)
  50   "Preserve the original definition of `insert-directory'.")
  51
  52 (defcustom eshell-ls-unload-hook
  53   (list
  54    (function
  55     (lambda ()
  56       (fset 'insert-directory eshell-ls-orig-insert-directory))))
  57   "*When unloading `eshell-ls', restore the definition of `insert-directory'."
  58   :type 'hook
  59   :group 'eshell-ls)
  60
  61 (defcustom eshell-ls-initial-args nil
  62   "*If non-nil, this list of args is included before any call to `ls'.
  63 This is useful for enabling human-readable format (-h), for example."
  64   :type '(repeat :tag "Arguments" string)
  65   :group 'eshell-ls)
  66
  67 (defcustom eshell-ls-dired-initial-args nil
  68   "*If non-nil, args is included before any call to `ls' in Dired.
  69 This is useful for enabling human-readable format (-h), for example."
  70   :type '(repeat :tag "Arguments" string)
  71   :group 'eshell-ls)
  72
  73 (defcustom eshell-ls-use-in-dired nil
  74   "*If non-nil, use `eshell-ls' to read directories in Dired."
  75   :set (lambda (symbol value)
  76          (if value
  77              (unless (and (boundp 'eshell-ls-use-in-dired)
  78                           eshell-ls-use-in-dired)
  79                (fset 'insert-directory 'eshell-ls-insert-directory))
  80            (when (and (boundp 'eshell-ls-insert-directory)
  81                       eshell-ls-use-in-dired)
  82              (fset 'insert-directory eshell-ls-orig-insert-directory)))
  83          (setq eshell-ls-use-in-dired value))
  84   :type 'boolean
  85   :require 'em-ls
  86   :group 'eshell-ls)
  87
  88 (defcustom eshell-ls-default-blocksize 1024
  89   "*The default blocksize to use when display file sizes with -s."
  90   :type 'integer
  91   :group 'eshell-ls)
  92
  93 (defcustom eshell-ls-exclude-regexp nil
  94   "*Unless -a is specified, files matching this regexp will not be shown."
  95   :type '(choice regexp (const nil))
  96   :group 'eshell-ls)
  97
  98 (defcustom eshell-ls-exclude-hidden t
  99   "*Unless -a is specified, files beginning with . will not be shown.
 100 Using this boolean, instead of `eshell-ls-exclude-regexp', is both
 101 faster and conserves more memory."
 102   :type 'boolean
 103   :group 'eshell-ls)
 104
 105 (defcustom eshell-ls-use-colors t
 106   "*If non-nil, use colors in file listings."
 107   :type 'boolean
 108   :group 'eshell-ls)
 109
 110 (defface eshell-ls-directory
 111   '((((class color) (background light)) (:foreground "Blue" :weight bold))
 112     (((class color) (background dark)) (:foreground "SkyBlue" :weight bold))
 113     (t (:weight bold)))
 114   "*The face used for highlight directories."
 115   :group 'eshell-ls)
 116 ;; backward-compatibility alias
 117 (put 'eshell-ls-directory-face 'face-alias 'eshell-ls-directory)
 118
 119 (defface eshell-ls-symlink
 120   '((((class color) (background light)) (:foreground "Dark Cyan" :weight bold))
 121     (((class color) (background dark)) (:foreground "Cyan" :weight bold)))
 122   "*The face used for highlight symbolic links."
 123   :group 'eshell-ls)
 124 ;; backward-compatibility alias
 125 (put 'eshell-ls-symlink-face 'face-alias 'eshell-ls-symlink)
 126
 127 (defface eshell-ls-executable
 128   '((((class color) (background light)) (:foreground "ForestGreen" :weight bold))
 129     (((class color) (background dark)) (:foreground "Green" :weight bold)))
 130   "*The face used for highlighting executables (not directories, though)."
 131   :group 'eshell-ls)
 132 ;; backward-compatibility alias
 133 (put 'eshell-ls-executable-face 'face-alias 'eshell-ls-executable)
 134
 135 (defface eshell-ls-readonly
 136   '((((class color) (background light)) (:foreground "Brown"))
 137     (((class color) (background dark)) (:foreground "Pink")))
 138   "*The face used for highlighting read-only files."
 139   :group 'eshell-ls)
 140 ;; backward-compatibility alias
 141 (put 'eshell-ls-readonly-face 'face-alias 'eshell-ls-readonly)
 142
 143 (defface eshell-ls-unreadable
 144   '((((class color) (background light)) (:foreground "Grey30"))
 145     (((class color) (background dark)) (:foreground "DarkGrey")))
 146   "*The face used for highlighting unreadable files."
 147   :group 'eshell-ls)
 148 ;; backward-compatibility alias
 149 (put 'eshell-ls-unreadable-face 'face-alias 'eshell-ls-unreadable)
 150
 151 (defface eshell-ls-special
 152   '((((class color) (background light)) (:foreground "Magenta" :weight bold))
 153     (((class color) (background dark)) (:foreground "Magenta" :weight bold)))
 154   "*The face used for highlighting non-regular files."
 155   :group 'eshell-ls)
 156 ;; backward-compatibility alias
 157 (put 'eshell-ls-special-face 'face-alias 'eshell-ls-special)
 158
 159 (defface eshell-ls-missing
 160   '((((class color) (background light)) (:foreground "Red" :weight bold))
 161     (((class color) (background dark)) (:foreground "Red" :weight bold)))
 162   "*The face used for highlighting non-existent file names."
 163   :group 'eshell-ls)
 164 ;; backward-compatibility alias
 165 (put 'eshell-ls-missing-face 'face-alias 'eshell-ls-missing)
 166
 167 (defcustom eshell-ls-archive-regexp
 168   (concat "\\.\\(t\\(a[rz]\\|gz\\)\\|arj\\|lzh\\|"
 169           "zip\\|[zZ]\\|gz\\|bz2\\|deb\\|rpm\\)\\'")
 170   "*A regular expression that matches names of file archives.
 171 This typically includes both traditional archives and compressed
 172 files."
 173   :type 'regexp
 174   :group 'eshell-ls)
 175
 176 (defface eshell-ls-archive
 177   '((((class color) (background light)) (:foreground "Orchid" :weight bold))
 178     (((class color) (background dark)) (:foreground "Orchid" :weight bold)))
 179   "*The face used for highlighting archived and compressed file names."
 180   :group 'eshell-ls)
 181 ;; backward-compatibility alias
 182 (put 'eshell-ls-archive-face 'face-alias 'eshell-ls-archive)
 183
 184 (defcustom eshell-ls-backup-regexp
 185   "\\(\\`\\.?#\\|\\(\\.bak\\|~\\)\\'\\)"
 186   "*A regular expression that matches names of backup files."
 187   :type 'regexp
 188   :group 'eshell-ls)
 189
 190 (defface eshell-ls-backup
 191   '((((class color) (background light)) (:foreground "OrangeRed"))
 192     (((class color) (background dark)) (:foreground "LightSalmon")))
 193   "*The face used for highlighting backup file names."
 194   :group 'eshell-ls)
 195 ;; backward-compatibility alias
 196 (put 'eshell-ls-backup-face 'face-alias 'eshell-ls-backup)
 197
 198 (defcustom eshell-ls-product-regexp
 199   "\\.\\(elc\\|o\\(bj\\)?\\|a\\|lib\\|res\\)\\'"
 200   "*A regular expression that matches names of product files.
 201 Products are files that get generated from a source file, and hence
 202 ought to be recreatable if they are deleted."
 203   :type 'regexp
 204   :group 'eshell-ls)
 205
 206 (defface eshell-ls-product
 207   '((((class color) (background light)) (:foreground "OrangeRed"))
 208     (((class color) (background dark)) (:foreground "LightSalmon")))
 209   "*The face used for highlighting files that are build products."
 210   :group 'eshell-ls)
 211 ;; backward-compatibility alias
 212 (put 'eshell-ls-product-face 'face-alias 'eshell-ls-product)
 213
 214 (defcustom eshell-ls-clutter-regexp
 215   "\\(^texput\\.log\\|^core\\)\\'"
 216   "*A regular expression that matches names of junk files.
 217 These are mainly files that get created for various reasons, but don't
 218 really need to stick around for very long."
 219   :type 'regexp
 220   :group 'eshell-ls)
 221
 222 (defface eshell-ls-clutter
 223   '((((class color) (background light)) (:foreground "OrangeRed" :weight bold))
 224     (((class color) (background dark)) (:foreground "OrangeRed" :weight bold)))
 225   "*The face used for highlighting junk file names."
 226   :group 'eshell-ls)
 227 ;; backward-compatibility alias
 228 (put 'eshell-ls-clutter-face 'face-alias 'eshell-ls-clutter)
 229
 230 (defsubst eshell-ls-filetype-p (attrs type)
 231   "Test whether ATTRS specifies a directory."
 232   (if (nth 8 attrs)
 233       (eq (aref (nth 8 attrs) 0) type)))
 234
 235 (defmacro eshell-ls-applicable (attrs index func file)
 236   "Test whether, for ATTRS, the user UID can do what corresponds to INDEX.
 237 This is really just for efficiency, to avoid having to stat the file
 238 yet again."
 239   `(if (numberp (nth 2 ,attrs))
 240        (if (= (user-uid) (nth 2 ,attrs))
 241            (not (eq (aref (nth 8 ,attrs) ,index) ?-))
 242          (,(eval func) ,file))
 243      (not (eq (aref (nth 8 ,attrs)
 244                     (+ ,index (if (member (nth 2 ,attrs)
 245                                           (eshell-current-ange-uids))
 246                                   0 6)))
 247               ?-))))
 248
 249 (defcustom eshell-ls-highlight-alist nil
 250   "*This alist correlates test functions to color.
 251 The format of the members of this alist is
 252
 253   (TEST-SEXP . FACE)
 254
 255 If TEST-SEXP evals to non-nil, that face will be used to highlight the
 256 name of the file.  The first match wins.  `file' and `attrs' are in
 257 scope during the evaluation of TEST-SEXP."
 258   :type '(repeat (cons function face))
 259   :group 'eshell-ls)
 260
 261 ;;; Functions:
 262
 263 (defun eshell-ls-insert-directory
 264   (file switches &optional wildcard full-directory-p)
 265   "Insert directory listing for FILE, formatted according to SWITCHES.
 266 Leaves point after the inserted text.
 267 SWITCHES may be a string of options, or a list of strings.
 268 Optional third arg WILDCARD means treat FILE as shell wildcard.
 269 Optional fourth arg FULL-DIRECTORY-P means file is a directory and
 270 switches do not contain `d', so that a full listing is expected.
 271
 272 This version of the function uses `eshell/ls'.  If any of the switches
 273 passed are not recognized, the operating system's version will be used
 274 instead."
 275   (let ((handler (find-file-name-handler file 'insert-directory)))
 276     (if handler
 277         (funcall handler 'insert-directory file switches
 278                  wildcard full-directory-p)
 279       (if (stringp switches)
 280           (setq switches (split-string switches)))
 281       (let (eshell-current-handles
 282             eshell-current-subjob-p
 283             font-lock-mode)
 284         ;; use the fancy highlighting in `eshell-ls' rather than font-lock
 285         (when (and eshell-ls-use-colors
 286                    (featurep 'font-lock))
 287           (font-lock-mode -1)
 288           (setq font-lock-defaults nil)
 289           (if (boundp 'font-lock-buffers)
 290               (set 'font-lock-buffers
 291                    (delq (current-buffer)
 292                          (symbol-value 'font-lock-buffers)))))
 293         (let ((insert-func 'insert)
 294               (error-func 'insert)
 295               (flush-func 'ignore)
 296               eshell-ls-dired-initial-args)
 297           (eshell-do-ls (append switches (list file))))))))
 298
 299 (defsubst eshell/ls (&rest args)
 300   "An alias version of `eshell-do-ls'."
 301   (let ((insert-func 'eshell-buffered-print)
 302         (error-func 'eshell-error)
 303         (flush-func 'eshell-flush))
 304     (eshell-do-ls args)))
 305
 306 (put 'eshell/ls 'eshell-no-numeric-conversions t)
 307
 308 (defvar block-size)
 309 (defvar dereference-links)
 310 (defvar dir-literal)
 311 (defvar error-func)
 312 (defvar flush-func)
 313 (defvar human-readable)
 314 (defvar ignore-pattern)
 315 (defvar insert-func)
 316 (defvar listing-style)
 317 (defvar numeric-uid-gid)
 318 (defvar reverse-list)
 319 (defvar show-all)
 320 (defvar show-recursive)
 321 (defvar show-size)
 322 (defvar sort-method)
 323 (defvar ange-cache)
 324 (defvar dired-flag)
 325
 326 (defun eshell-do-ls (&rest args)
 327   "Implementation of \"ls\" in Lisp, passing ARGS."
 328   (funcall flush-func -1)
 329   ;; process the command arguments, and begin listing files
 330   (eshell-eval-using-options
 331    "ls" (if eshell-ls-initial-args
 332             (list eshell-ls-initial-args args)
 333           args)
 334    `((?a "all" nil show-all
 335          "show all files in directory")
 336      (?c nil by-ctime sort-method
 337          "sort by last status change time")
 338      (?d "directory" nil dir-literal
 339          "list directory entries instead of contents")
 340      (?k "kilobytes" 1024 block-size
 341          "using 1024 as the block size")
 342      (?h "human-readable" 1024 human-readable
 343          "print sizes in human readable format")
 344      (?H "si" 1000 human-readable
 345          "likewise, but use powers of 1000 not 1024")
 346      (?I "ignore" t ignore-pattern
 347          "do not list implied entries matching pattern")
 348      (?l nil long-listing listing-style
 349          "use a long listing format")
 350      (?n "numeric-uid-gid" nil numeric-uid-gid
 351          "list numeric UIDs and GIDs instead of names")
 352      (?r "reverse" nil reverse-list
 353          "reverse order while sorting")
 354      (?s "size" nil show-size
 355          "print size of each file, in blocks")
 356      (?t nil by-mtime sort-method
 357          "sort by modification time")
 358      (?u nil by-atime sort-method
 359          "sort by last access time")
 360      (?x nil by-lines listing-style
 361          "list entries by lines instead of by columns")
 362      (?C nil by-columns listing-style
 363          "list entries by columns")
 364      (?L "deference" nil dereference-links
 365          "list entries pointed to by symbolic links")
 366      (?R "recursive" nil show-recursive
 367          "list subdirectories recursively")
 368      (?S nil by-size sort-method
 369          "sort by file size")
 370      (?U nil unsorted sort-method
 371          "do not sort; list entries in directory order")
 372      (?X nil by-extension sort-method
 373          "sort alphabetically by entry extension")
 374      (?1 nil single-column listing-style
 375          "list one file per line")
 376      (nil "dired" nil dired-flag
 377           "Here for compatibility with GNU ls.")
 378      (nil "help" nil nil
 379           "show this usage display")
 380      :external "ls"
 381      :usage "[OPTION]... [FILE]...
 382 List information about the FILEs (the current directory by default).
 383 Sort entries alphabetically across.")
 384    ;; setup some defaults, based on what the user selected
 385    (unless block-size
 386      (setq block-size eshell-ls-default-blocksize))
 387    (unless listing-style
 388      (setq listing-style 'by-columns))
 389    (unless args
 390      (setq args (list ".")))
 391    (let ((eshell-ls-exclude-regexp eshell-ls-exclude-regexp) ange-cache)
 392      (when ignore-pattern
 393        (unless (eshell-using-module 'eshell-glob)
 394          (error (concat "-I option requires that `eshell-glob'"
 395                         " be a member of `eshell-modules-list'")))
 396        (set-text-properties 0 (length ignore-pattern) nil ignore-pattern)
 397        (setq eshell-ls-exclude-regexp
 398              (if eshell-ls-exclude-regexp
 399                  (concat "\\(" eshell-ls-exclude-regexp "\\|"
 400                          (eshell-glob-regexp ignore-pattern) "\\)")
 401                (eshell-glob-regexp ignore-pattern))))
 402      ;; list the files!
 403      (eshell-ls-entries
 404       (mapcar (function
 405                (lambda (arg)
 406                  (cons (if (and (eshell-under-windows-p)
 407                                 (file-name-absolute-p arg))
 408                            (expand-file-name arg)
 409                          arg)
 410                        (eshell-file-attributes arg))))
 411               args)
 412       t (expand-file-name default-directory)))
 413    (funcall flush-func)))
 414
 415 (defsubst eshell-ls-printable-size (filesize &optional by-blocksize)
 416   "Return a printable FILESIZE."
 417   (eshell-printable-size filesize human-readable
 418                          (and by-blocksize block-size)
 419                          eshell-ls-use-colors))
 420
 421 (defsubst eshell-ls-size-string (attrs size-width)
 422   "Return the size string for ATTRS length, using SIZE-WIDTH."
 423   (let* ((str (eshell-ls-printable-size (nth 7 attrs) t))
 424          (len (length str)))
 425     (if (< len size-width)
 426         (concat (make-string (- size-width len) ? ) str)
 427       str)))
 428
 429 (defun eshell-ls-annotate (fileinfo)
 430   "Given a FILEINFO object, return a resolved, decorated FILEINFO.
 431 This means resolving any symbolic links, determining what face the
 432 name should be displayed as, etc.  Think of it as cooking a FILEINFO."
 433   (if (not (and (stringp (cadr fileinfo))
 434                 (or dereference-links
 435                     (eq listing-style 'long-listing))))
 436       (setcar fileinfo (eshell-ls-decorated-name fileinfo))
 437     (let (dir attr)
 438       (unless (file-name-absolute-p (cadr fileinfo))
 439         (setq dir (file-truename
 440                    (file-name-directory
 441                     (expand-file-name (car fileinfo))))))
 442       (setq attr
 443             (eshell-file-attributes
 444              (let ((target (if dir
 445                                (expand-file-name (cadr fileinfo) dir)
 446                              (cadr fileinfo))))
 447                (if dereference-links
 448                    (file-truename target)
 449                  target))))
 450       (if (or dereference-links
 451               (string-match "^\\.\\.?$" (car fileinfo)))
 452           (progn
 453             (setcdr fileinfo attr)
 454             (setcar fileinfo (eshell-ls-decorated-name fileinfo)))
 455         (assert (eq listing-style 'long-listing))
 456         (setcar fileinfo
 457                 (concat (eshell-ls-decorated-name fileinfo) " -> "
 458                         (eshell-ls-decorated-name
 459                          (cons (cadr fileinfo) attr)))))))
 460   fileinfo)
 461
 462 (defun eshell-ls-file (fileinfo &optional size-width copy-fileinfo)
 463   "Output FILE in long format.
 464 FILE may be a string, or a cons cell whose car is the filename and
 465 whose cdr is the list of file attributes."
 466   (if (not (cdr fileinfo))
 467       (funcall error-func (format "%s: No such file or directory\n"
 468                                   (car fileinfo)))
 469     (setq fileinfo
 470           (eshell-ls-annotate (if copy-fileinfo
 471                                   (cons (car fileinfo)
 472                                         (cdr fileinfo))
 473                                 fileinfo)))
 474     (let ((file (car fileinfo))
 475           (attrs (cdr fileinfo)))
 476       (if (not (eq listing-style 'long-listing))
 477           (if show-size
 478               (funcall insert-func (eshell-ls-size-string attrs size-width)
 479                        " " file "\n")
 480             (funcall insert-func file "\n"))
 481         (let ((line
 482                (concat
 483                 (if show-size
 484                     (concat (eshell-ls-size-string attrs size-width) " "))
 485                 (format
 486                  "%s%4d %-8s %-8s "
 487                  (or (nth 8 attrs) "??????????")
 488                  (or (nth 1 attrs) 0)
 489                  (or (let ((user (nth 2 attrs)))
 490                        (and (not numeric-uid-gid)
 491                             user
 492                             (eshell-substring
 493                              (if (numberp user)
 494                                  (user-login-name user)
 495                                user) 8)))
 496                      (nth 2 attrs)
 497                      "")
 498                  (or (let ((group (nth 3 attrs)))
 499                        (and (not numeric-uid-gid)
 500                             group
 501                             (eshell-substring
 502                              (if (numberp group)
 503                                  (eshell-group-name group)
 504                                group) 8)))
 505                      (nth 3 attrs)
 506                      ""))
 507                 (let* ((str (eshell-ls-printable-size (nth 7 attrs)))
 508                        (len (length str)))
 509                   (if (< len (or size-width 4))
 510                       (concat (make-string (- (or size-width 4) len) ? ) str)
 511                     str))
 512                 " " (format-time-string
 513                      (concat
 514                       "%b %e "
 515                       (if (= (nth 5 (decode-time (current-time)))
 516                              (nth 5 (decode-time
 517                                      (nth (cond
 518                                            ((eq sort-method 'by-atime) 4)
 519                                            ((eq sort-method 'by-ctime) 6)
 520                                            (t 5)) attrs))))
 521                           "%H:%M"
 522                         " %Y")) (nth (cond
 523                         ((eq sort-method 'by-atime) 4)
 524                         ((eq sort-method 'by-ctime) 6)
 525                         (t 5)) attrs)) " ")))
 526           (funcall insert-func line file "\n"))))))
 527
 528 (defun eshell-ls-dir (dirinfo &optional insert-name root-dir size-width)
 529   "Output the entries in DIRINFO.
 530 If INSERT-NAME is non-nil, the name of DIRINFO will be output.  If
 531 ROOT-DIR is also non-nil, and a directory name, DIRINFO will be output
 532 relative to that directory."
 533   (let ((dir (car dirinfo)))
 534     (if (not (cdr dirinfo))
 535         (funcall error-func (format "%s: No such file or directory\n" dir))
 536       (if dir-literal
 537           (eshell-ls-file dirinfo size-width)
 538         (if insert-name
 539             (funcall insert-func
 540                      (eshell-ls-decorated-name
 541                       (cons (concat
 542                              (if root-dir
 543                                  (file-relative-name dir root-dir)
 544                                (expand-file-name dir)))
 545                             (cdr dirinfo))) ":\n"))
 546         (let ((entries (eshell-directory-files-and-attributes
 547                         dir nil (and (not show-all)
 548                                      eshell-ls-exclude-hidden
 549                                      "\\`[^.]") t)))
 550           (when (and (not show-all) eshell-ls-exclude-regexp)
 551             (while (and entries (string-match eshell-ls-exclude-regexp
 552                                               (caar entries)))
 553               (setq entries (cdr entries)))
 554             (let ((e entries))
 555               (while (cdr e)
 556                 (if (string-match eshell-ls-exclude-regexp (car (cadr e)))
 557                     (setcdr e (cddr e))
 558                   (setq e (cdr e))))))
 559           (when (or (eq listing-style 'long-listing) show-size)
 560             (let ((total 0.0))
 561               (setq size-width 0)
 562               (eshell-for e entries
 563                 (if (nth 7 (cdr e))
 564                     (setq total (+ total (nth 7 (cdr e)))
 565                           size-width
 566                           (max size-width
 567                                (length (eshell-ls-printable-size
 568                                         (nth 7 (cdr e)) t))))))
 569               (funcall insert-func "total "
 570                        (eshell-ls-printable-size total t) "\n")))
 571           (let ((default-directory (expand-file-name dir)))
 572             (if show-recursive
 573                 (eshell-ls-entries
 574                  (let ((e entries) (good-entries (list t)))
 575                    (while e
 576                      (unless (let ((len (length (caar e))))
 577                                (and (eq (aref (caar e) 0) ?.)
 578                                     (or (= len 1)
 579                                         (and (= len 2)
 580                                              (eq (aref (caar e) 1) ?.)))))
 581                        (nconc good-entries (list (car e))))
 582                      (setq e (cdr e)))
 583                    (cdr good-entries))
 584                  nil root-dir)
 585               (eshell-ls-files (eshell-ls-sort-entries entries)
 586                                size-width))))))))
 587
 588 (defsubst eshell-ls-compare-entries (l r inx func)
 589   "Compare the time of two files, L and R, the attribute indexed by INX."
 590   (let ((lt (nth inx (cdr l)))
 591         (rt (nth inx (cdr r))))
 592     (if (equal lt rt)
 593         (string-lessp (directory-file-name (car l))
 594                       (directory-file-name (car r)))
 595       (funcall func rt lt))))
 596
 597 (defun eshell-ls-sort-entries (entries)
 598   "Sort the given ENTRIES, which may be files, directories or both.
 599 In Eshell's implementation of ls, ENTRIES is always reversed."
 600   (if (eq sort-method 'unsorted)
 601       (nreverse entries)
 602     (sort entries
 603           (function
 604            (lambda (l r)
 605              (let ((result
 606                     (cond
 607                      ((eq sort-method 'by-atime)
 608                       (eshell-ls-compare-entries l r 4 'eshell-time-less-p))
 609                      ((eq sort-method 'by-mtime)
 610                       (eshell-ls-compare-entries l r 5 'eshell-time-less-p))
 611                      ((eq sort-method 'by-ctime)
 612                       (eshell-ls-compare-entries l r 6 'eshell-time-less-p))
 613                      ((eq sort-method 'by-size)
 614                       (eshell-ls-compare-entries l r 7 '<))
 615                      ((eq sort-method 'by-extension)
 616                       (let ((lx (file-name-extension
 617                                  (directory-file-name (car l))))
 618                             (rx (file-name-extension
 619                                  (directory-file-name (car r)))))
 620                         (cond
 621                          ((or (and (not lx) (not rx))
 622                               (equal lx rx))
 623                           (string-lessp (directory-file-name (car l))
 624                                         (directory-file-name (car r))))
 625                          ((not lx) t)
 626                          ((not rx) nil)
 627                          (t
 628                           (string-lessp lx rx)))))
 629                      (t
 630                       (string-lessp (directory-file-name (car l))
 631                                     (directory-file-name (car r)))))))
 632                (if reverse-list
 633                    (not result)
 634                  result)))))))
 635
 636 (defun eshell-ls-files (files &optional size-width copy-fileinfo)
 637   "Output a list of FILES.
 638 Each member of FILES is either a string or a cons cell of the form
 639 \(FILE .  ATTRS)."
 640   ;; Mimic behavior of coreutils ls, which lists a single file per
 641   ;; line when output is not a tty.  Exceptions: if -x was supplied,
 642   ;; or if we are the _last_ command in a pipeline.
 643   ;; FIXME Not really the same since not testing output destination.
 644   (if (or (and eshell-in-pipeline-p
 645                (not (eq eshell-in-pipeline-p 'last))
 646                (not (eq listing-style 'by-lines)))
 647           (memq listing-style '(long-listing single-column)))
 648       (eshell-for file files
 649         (if file
 650             (eshell-ls-file file size-width copy-fileinfo)))
 651     (let ((f files)
 652           last-f
 653           display-files
 654           ignore)
 655       (while f
 656         (if (cdar f)
 657             (setq last-f f
 658                   f (cdr f))
 659           (unless ignore
 660             (funcall error-func
 661                      (format "%s: No such file or directory\n" (caar f))))
 662           (if (eq f files)
 663               (setq files (cdr files)
 664                     f files)
 665             (if (not (cdr f))
 666                 (progn
 667                   (setcdr last-f nil)
 668                   (setq f nil))
 669               (setcar f (cadr f))
 670               (setcdr f (cddr f))))))
 671       (if (not show-size)
 672           (setq display-files (mapcar 'eshell-ls-annotate files))
 673         (eshell-for file files
 674           (let* ((str (eshell-ls-printable-size (nth 7 (cdr file)) t))
 675                  (len (length str)))
 676             (if (< len size-width)
 677                 (setq str (concat (make-string (- size-width len) ? ) str)))
 678             (setq file (eshell-ls-annotate file)
 679                   display-files (cons (cons (concat str " " (car file))
 680                                             (cdr file))
 681                                       display-files))))
 682         (setq display-files (nreverse display-files)))
 683       (let* ((col-vals
 684               (if (eq listing-style 'by-columns)
 685                   (eshell-ls-find-column-lengths display-files)
 686                 (assert (eq listing-style 'by-lines))
 687                 (eshell-ls-find-column-widths display-files)))
 688              (col-widths (car col-vals))
 689              (display-files (cdr col-vals))
 690              (columns (length col-widths))
 691              (col-index 1)
 692              need-return)
 693         (eshell-for file display-files
 694           (let ((name
 695                  (if (car file)
 696                      (if show-size
 697                          (concat (substring (car file) 0 size-width)
 698                                  (eshell-ls-decorated-name
 699                                   (cons (substring (car file) size-width)
 700                                         (cdr file))))
 701                        (eshell-ls-decorated-name file))
 702                    "")))
 703             (if (< col-index columns)
 704                 (setq need-return
 705                       (concat need-return name
 706                               (make-string
 707                                (max 0 (- (aref col-widths
 708                                                (1- col-index))
 709                                          (length name))) ? ))
 710                       col-index (1+ col-index))
 711               (funcall insert-func need-return name "\n")
 712               (setq col-index 1 need-return nil))))
 713         (if need-return
 714             (funcall insert-func need-return "\n"))))))
 715
 716 (defun eshell-ls-entries (entries &optional separate root-dir)
 717   "Output PATH's directory ENTRIES, formatted according to OPTIONS.
 718 Each member of ENTRIES may either be a string or a cons cell, the car
 719 of which is the file name, and the cdr of which is the list of
 720 attributes.
 721 If SEPARATE is non-nil, directories name will be entirely separated
 722 from the filenames.  This is the normal behavior, except when doing a
 723 recursive listing.
 724 ROOT-DIR, if non-nil, specifies the root directory of the listing, to
 725 which non-absolute directory names will be made relative if ever they
 726 need to be printed."
 727   (let (dirs files show-names need-return (size-width 0))
 728     (eshell-for entry entries
 729       (if (and (not dir-literal)
 730                (or (eshell-ls-filetype-p (cdr entry) ?d)
 731                    (and (eshell-ls-filetype-p (cdr entry) ?l)
 732                         (file-directory-p (car entry)))))
 733           (progn
 734             (unless separate
 735               (setq files (cons entry files)
 736                     size-width
 737                     (if show-size
 738                         (max size-width
 739                              (length (eshell-ls-printable-size
 740                                       (nth 7 (cdr entry)) t))))))
 741             (setq dirs (cons entry dirs)))
 742         (setq files (cons entry files)
 743               size-width
 744               (if show-size
 745                   (max size-width
 746                        (length (eshell-ls-printable-size
 747                                 (nth 7 (cdr entry)) t)))))))
 748     (when files
 749       (eshell-ls-files (eshell-ls-sort-entries files)
 750                        size-width show-recursive)
 751       (setq need-return t))
 752     (setq show-names (or show-recursive
 753                          (> (+ (length files) (length dirs)) 1)))
 754     (eshell-for dir (eshell-ls-sort-entries dirs)
 755       (if (and need-return (not dir-literal))
 756           (funcall insert-func "\n"))
 757       (eshell-ls-dir dir show-names
 758                      (unless (file-name-absolute-p (car dir)) root-dir)
 759                      size-width)
 760       (setq need-return t))))
 761
 762 (defun eshell-ls-find-column-widths (files)
 763   "Find the best fitting column widths for FILES.
 764 It will be returned as a vector, whose length is the number of columns
 765 to use, and each member of which is the width of that column
 766 \(including spacing)."
 767   (let* ((numcols 0)
 768          (width 0)
 769          (widths
 770           (mapcar
 771            (function
 772             (lambda (file)
 773               (+ 2 (length (car file)))))
 774            files))
 775          ;; must account for the added space...
 776          (max-width (+ (window-width) 2))
 777          (best-width 0)
 778          col-widths)
 779
 780     ;; determine the largest number of columns in the first row
 781     (let ((w widths))
 782       (while (and w (< width max-width))
 783         (setq width (+ width (car w))
 784               numcols (1+ numcols)
 785               w (cdr w))))
 786
 787     ;; refine it based on the following rows
 788     (while (> numcols 0)
 789       (let ((i 0)
 790             (colw (make-vector numcols 0))
 791             (w widths))
 792         (while w
 793           (if (= i numcols)
 794               (setq i 0))
 795           (aset colw i (max (aref colw i) (car w)))
 796           (setq w (cdr w) i (1+ i)))
 797         (setq i 0 width 0)
 798         (while (< i numcols)
 799           (setq width (+ width (aref colw i))
 800                 i (1+ i)))
 801         (if (and (< width max-width)
 802                  (> width best-width))
 803             (setq col-widths colw
 804                   best-width width)))
 805       (setq numcols (1- numcols)))
 806
 807     (cons (or col-widths (vector max-width)) files)))
 808
 809 (defun eshell-ls-find-column-lengths (files)
 810   "Find the best fitting column lengths for FILES.
 811 It will be returned as a vector, whose length is the number of columns
 812 to use, and each member of which is the width of that column
 813 \(including spacing)."
 814   (let* ((numcols 1)
 815          (width 0)
 816          (widths
 817           (mapcar
 818            (function
 819             (lambda (file)
 820               (+ 2 (length (car file)))))
 821            files))
 822          (max-width (+ (window-width) 2))
 823          col-widths
 824          colw)
 825
 826     ;; refine it based on the following rows
 827     (while numcols
 828       (let* ((rows (ceiling (/ (length widths)
 829                                (float numcols))))
 830              (w widths)
 831              (len (* rows numcols))
 832              (index 0)
 833              (i 0))
 834         (setq width 0)
 835         (unless (or (= rows 0)
 836                     (<= (/ (length widths) (float rows))
 837                         (float (1- numcols))))
 838           (setq colw (make-vector numcols 0))
 839           (while (> len 0)
 840             (if (= i numcols)
 841                 (setq i 0 index (1+ index)))
 842             (aset colw i
 843                   (max (aref colw i)
 844                        (or (nth (+ (* i rows) index) w) 0)))
 845             (setq len (1- len) i (1+ i)))
 846           (setq i 0)
 847           (while (< i numcols)
 848             (setq width (+ width (aref colw i))
 849                   i (1+ i))))
 850         (if (>= width max-width)
 851             (setq numcols nil)
 852           (if colw
 853               (setq col-widths colw))
 854           (if (>= numcols (length widths))
 855               (setq numcols nil)
 856             (setq numcols (1+ numcols))))))
 857
 858     (if (not col-widths)
 859         (cons (vector max-width) files)
 860       (setq numcols (length col-widths))
 861       (let* ((rows (ceiling (/ (length widths)
 862                                (float numcols))))
 863              (len (* rows numcols))
 864              (newfiles (make-list len nil))
 865              (index 0)
 866              (i 0)
 867              (j 0))
 868         (while (< j len)
 869           (if (= i numcols)
 870               (setq i 0 index (1+ index)))
 871           (setcar (nthcdr j newfiles)
 872                   (nth (+ (* i rows) index) files))
 873           (setq j (1+ j) i (1+ i)))
 874         (cons col-widths newfiles)))))
 875
 876 (defun eshell-ls-decorated-name (file)
 877   "Return FILE, possibly decorated."
 878   (if eshell-ls-use-colors
 879       (let ((face
 880              (cond
 881               ((not (cdr file))
 882                'eshell-ls-missing)
 883
 884               ((stringp (cadr file))
 885                'eshell-ls-symlink)
 886
 887               ((eq (cadr file) t)
 888                'eshell-ls-directory)
 889
 890               ((not (eshell-ls-filetype-p (cdr file) ?-))
 891                'eshell-ls-special)
 892
 893               ((and (/= (user-uid) 0) ; root can execute anything
 894                     (eshell-ls-applicable (cdr file) 3
 895                                           'file-executable-p (car file)))
 896                'eshell-ls-executable)
 897
 898               ((not (eshell-ls-applicable (cdr file) 1
 899                                           'file-readable-p (car file)))
 900                'eshell-ls-unreadable)
 901
 902               ((string-match eshell-ls-archive-regexp (car file))
 903                'eshell-ls-archive)
 904
 905               ((string-match eshell-ls-backup-regexp (car file))
 906                'eshell-ls-backup)
 907
 908               ((string-match eshell-ls-product-regexp (car file))
 909                'eshell-ls-product)
 910
 911               ((string-match eshell-ls-clutter-regexp (car file))
 912                'eshell-ls-clutter)
 913
 914               ((not (eshell-ls-applicable (cdr file) 2
 915                                           'file-writable-p (car file)))
 916                'eshell-ls-readonly)
 917               (eshell-ls-highlight-alist
 918                (let ((tests eshell-ls-highlight-alist)
 919                      value)
 920                  (while tests
 921                    (if (funcall (caar tests) (car file) (cdr file))
 922                        (setq value (cdar tests) tests nil)
 923                      (setq tests (cdr tests))))
 924                  value)))))
 925         (if face
 926             (add-text-properties 0 (length (car file))
 927                                  (list 'face face)
 928                                  (car file)))))
 929   (car file))
 930
 931 (provide 'em-ls)
 932
 933 ;; Local Variables:
 934 ;; generated-autoload-file: "esh-groups.el"
 935 ;; End:
 936
 937 ;; arch-tag: 9295181c-0cb2-499c-999b-89f5359842cb
 938 ;;; em-ls.el ends here