code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006
   7 dnl  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 2, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 dnl  Boston, MA 02110-1301, USA.
  25
  26 AC_PREREQ(2.54)dnl
  27 AC_INIT(src/lisp.h)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 lispdir='${datadir}/emacs/${version}/lisp'
  35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  36 '${datadir}/emacs/site-lisp'
  37 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  38 etcdir='${datadir}/emacs/${version}/etc'
  39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  40 docdir='${datadir}/emacs/${version}/etc'
  41 gamedir='${localstatedir}/games/emacs'
  42
  43 gameuser=games
  44
  45 AC_ARG_WITH(gcc,
  46 [  --without-gcc           don't use GCC to compile Emacs if GCC is found])
  47 AC_ARG_WITH(pop,
  48 [  --without-pop           don't support POP mail retrieval with movemail],
  49 [if test "$withval" = yes; then
  50    AC_DEFINE(MAIL_USE_POP)
  51 else :
  52 fi],
  53 AC_DEFINE(MAIL_USE_POP))
  54 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  55 AC_ARG_WITH(kerberos,
  56 [  --with-kerberos         support Kerberos-authenticated POP],
  57 [AC_DEFINE(KERBEROS)])
  58 AH_TEMPLATE(KERBEROS,
  59             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  60 AC_ARG_WITH(kerberos5,
  61 [  --with-kerberos5        support Kerberos version 5 authenticated POP],
  62 [if test "${with_kerberos5+set}" = set; then
  63   if test "${with_kerberos+set}" != set; then
  64     with_kerberos=yes
  65     AC_DEFINE(KERBEROS)
  66   fi
  67 fi
  68 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
  69 AC_ARG_WITH(hesiod,
  70 [  --with-hesiod           support Hesiod to get the POP server host],
  71 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
  72
  73 AC_ARG_WITH(sound,
  74 [  --without-sound         don't compile with sound support])
  75
  76 dnl This should be the last --with option, because --with-x is
  77 dnl added later on when we find the path of X, and it's best to
  78 dnl keep them together visually.
  79 AC_ARG_WITH(x-toolkit,
  80 [  --with-x-toolkit=KIT    use an X toolkit
  81                               (KIT = yes/lucid/athena/motif/gtk/no)],
  82 [         case "${withval}" in
  83             y | ye | yes )      val=athena ;;
  84             n | no )            val=no  ;;
  85             l | lu | luc | luci | lucid )       val=lucid ;;
  86             a | at | ath | athe | athen | athena )      val=athena ;;
  87             m | mo | mot | moti | motif )       val=motif ;;
  88             g | gt | gtk  )     val=gtk ;;
  89 dnl These don't currently work.
  90 dnl         o | op | ope | open | open- | open-l | open-lo \
  91 dnl             | open-loo | open-look )        val=open-look ;;
  92             * )
  93 dnl AC_MSG_ERROR([the `--with-x-toolkit' option is supposed to have a value
  94 dnl which is `yes', `no', `lucid', `athena', `motif' or `open-look'.])
  95 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid\;
  96 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
  97 Currently, `yes', `athena' and `lucid' are synonyms.])
  98             ;;
  99           esac
 100           with_x_toolkit=$val
 101 ])
 102 AC_ARG_WITH(xpm,
 103 [  --with-xpm              use -lXpm for displaying XPM images])
 104 AC_ARG_WITH(jpeg,
 105 [  --with-jpeg             use -ljpeg for displaying JPEG images])
 106 AC_ARG_WITH(tiff,
 107 [  --with-tiff             use -ltiff for displaying TIFF images])
 108 AC_ARG_WITH(gif,
 109 [  --with-gif              use -lungif for displaying GIF images])
 110 AC_ARG_WITH(png,
 111 [  --with-png              use -lpng for displaying PNG images])
 112 AC_ARG_WITH(gtk,
 113 [  --with-gtk              use GTK (same as --with-x-toolkit=gtk)])
 114 AC_ARG_WITH(pkg-config-prog,
 115 [  --with-pkg-config-prog  Path to pkg-config to use for finding GTK])
 116 AC_ARG_WITH(toolkit-scroll-bars,
 117 [  --without-toolkit-scroll-bars
 118                           don't use Motif or Xaw3d scroll bars])
 119 AC_ARG_WITH(xim,
 120 [  --without-xim           don't use X11 XIM])
 121 AC_ARG_WITH(carbon,
 122 [  --without-carbon        don't use Carbon GUI on Mac OS X])
 123 AC_ARG_ENABLE(carbon-app,
 124 [[  --enable-carbon-app[=DIR]  [DIR=/Application]
 125                           specify install directory for Emacs.app on Mac OS X]],
 126 [ carbon_appdir_x=${enableval}])
 127
 128 AC_ARG_ENABLE(asserts,
 129 [  --enable-asserts        compile code with asserts enabled],
 130       USE_XASSERTS=$enableval,
 131       USE_XASSERTS=no)
 132
 133 AC_ARG_ENABLE(maintainer-mode,
 134 [  --enable-maintainer-mode enable make rules and dependencies not useful
 135                           (and sometimes confusing) to the casual installer],
 136       USE_MAINTAINER_MODE=$enableval,
 137       USE_MAINTAINER_MODE=no)
 138 if test $USE_MAINTAINER_MODE = yes; then
 139   MAINT=
 140 else
 141   MAINT=#
 142 fi
 143 AC_SUBST(MAINT)
 144
 145 AC_ARG_ENABLE(locallisppath,
 146 [  --enable-locallisppath=PATH
 147                           directories Emacs should search for lisp files
 148                           specific to this site],
 149 if test "${enableval}" = "no"; then
 150   locallisppath=
 151 elif test "${enableval}" != "yes"; then
 152   locallisppath=${enableval}
 153 fi)
 154
 155 #### Make srcdir absolute, if it isn't already.  It's important to
 156 #### avoid running the path through pwd unnecessarily, since pwd can
 157 #### give you automounter prefixes, which can go away.  We do all this
 158 #### so Emacs can find its files when run uninstalled.
 159 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 160 unset CDPATH
 161 case "${srcdir}" in
 162   /* ) ;;
 163   . )
 164     ## We may be able to use the $PWD environment variable to make this
 165     ## absolute.  But sometimes PWD is inaccurate.
 166     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 167     ## but that tested only for a well-formed and valid PWD,
 168     ## it did not object when PWD was well-formed and valid but just wrong.
 169     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 170     then
 171       srcdir="$PWD"
 172     else
 173       srcdir="`(cd ${srcdir}; pwd)`"
 174     fi
 175   ;;
 176   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 177 esac
 178
 179 #### Check if the source directory already has a configured system in it.
 180 if test `pwd` != `(cd ${srcdir} && pwd)` \
 181    && test -f "${srcdir}/src/config.h" ; then
 182   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 183    as a build directory right now; it has been configured in its own
 184    right.  To configure in another directory as well, you MUST
 185    use GNU make.  If you do not have GNU make, then you must
 186    now do `make distclean' in ${srcdir},
 187    and then run $0 again.]])
 188 fi
 189
 190 #### Given the configuration name, set machfile and opsysfile to the
 191 #### names of the m/*.h and s/*.h files we should use.
 192
 193 ### Canonicalize the configuration name.
 194
 195 AC_CANONICAL_HOST
 196 canonical=$host
 197 configuration=${host_alias-$host}
 198
 199 dnl This used to use changequote, but, apart from `changequote is evil'
 200 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 201 dnl the great gob of text.  Thus it's not processed for possible expansion.
 202 dnl Just make sure the brackets remain balanced.
 203 dnl
 204 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 205 dnl indicated by comments.
 206 dnl quotation begins
 207 [
 208
 209 ### If you add support for a new configuration, add code to this
 210 ### switch statement to recognize your configuration name and select
 211 ### the appropriate operating system and machine description files.
 212
 213 ### You would hope that you could choose an m/*.h file pretty much
 214 ### based on the machine portion of the configuration name, and an s-
 215 ### file based on the operating system portion.  However, it turns out
 216 ### that each m/*.h file is pretty manufacturer-specific - for
 217 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 218 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 219 ### machines.  So we basically have to have a special case for each
 220 ### configuration name.
 221 ###
 222 ### As far as handling version numbers on operating systems is
 223 ### concerned, make sure things will fail in a fixable way.  If
 224 ### /etc/MACHINES doesn't say anything about version numbers, be
 225 ### prepared to handle anything reasonably.  If version numbers
 226 ### matter, be sure /etc/MACHINES says something about it.
 227 ###
 228 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 229 ### "System V Release 4"; he writes, "The old convention encouraged
 230 ### confusion between `system' and `release' levels'."
 231
 232 machine='' opsys='' unported=no
 233 case "${canonical}" in
 234
 235   ## FreeBSD ports
 236   *-*-freebsd* )
 237     opsys=freebsd
 238     case "${canonical}" in
 239       alpha*-*-freebsd*)        machine=alpha ;;
 240       ia64-*-freebsd*)          machine=ia64 ;;
 241       sparc64-*-freebsd*)       machine=sparc ;;
 242       powerpc-*-freebsd*)       machine=macppc ;;
 243       i[3456]86-*-freebsd*)     machine=intel386 ;;
 244       amd64-*-freebsd*|x86_64-*-freebsd*) machine=amdx86-64 ;;
 245     esac
 246   ;;
 247
 248   ## NetBSD ports
 249   *-*-netbsd* )
 250     opsys=netbsd
 251     if test -f /usr/lib/crti.o; then]
 252 dnl The close and open brackets here are because this section is quoted --
 253 dnl see the `changequote' comment above.
 254       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 255 [   fi
 256
 257     case "${canonical}" in
 258       alpha*-*-netbsd*) machine=alpha ;;
 259       i[3456]86-*-netbsd*) machine=intel386 ;;
 260       m68k-*-netbsd*)
 261                         # This is somewhat bogus.
 262                         machine=hp9000s300 ;;
 263       powerpc-apple-netbsd*) machine=macppc ;;
 264       mips-*-netbsd*)   machine=pmax ;;
 265       mipsel-*-netbsd*) machine=pmax ;;
 266       mipseb-*-netbsd*) machine=pmax ;;
 267       ns32k-*-netbsd*)  machine=ns32000 ;;
 268       powerpc-*-netbsd*) machine=macppc ;;
 269       sparc*-*-netbsd*) machine=sparc ;;
 270       vax-*-netbsd*)    machine=vax ;;
 271       arm-*-netbsd*)    machine=arm ;;
 272     esac
 273   ;;
 274
 275   ## OpenBSD ports
 276   *-*-openbsd* )
 277     opsys=openbsd
 278     case "${canonical}" in
 279       alpha*-*-openbsd*)        machine=alpha ;;
 280       i386-*-openbsd*)  machine=intel386 ;;
 281       x86_64-*-openbsd*)    machine=amdx86-64 ;;
 282       m68k-*-openbsd*)  machine=hp9000s300 ;;
 283       mipsel-*-openbsd*) machine=pmax ;;
 284       ns32k-*-openbsd*) machine=ns32000 ;;
 285       sparc-*-openbsd*) machine=sparc ;;
 286       vax-*-openbsd*)   machine=vax ;;
 287     esac
 288   ;;
 289
 290   ## LynxOS ports
 291   *-*-lynxos* )
 292     opsys=lynxos
 293     case "${canonical}" in
 294       i[3456]86-*-lynxos*) machine=intel386 ;;
 295       powerpc-*-lynxos*) machine=powerpc ;;
 296     esac
 297   ;;
 298
 299   ## Acorn RISCiX:
 300   arm-acorn-riscix1.1* )
 301     machine=acorn opsys=riscix1-1
 302   ;;
 303   arm-acorn-riscix1.2* | arm-acorn-riscix )
 304     ## This name is riscix12 instead of riscix1.2
 305     ## to avoid a file name conflict on MSDOS.
 306     machine=acorn opsys=riscix12
 307   ;;
 308
 309   ## BSDI ports
 310   *-*-bsdi* )
 311     opsys=bsdi
 312     case "${canonical}" in
 313       i[345]86-*-bsdi*) machine=intel386 ;;
 314       sparc-*-bsdi*)  machine=sparc ;;
 315       powerpc-*-bsdi*)  machine=macppc ;;
 316     esac
 317     case "${canonical}" in
 318       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 319       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 320       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 321       *-*-bsdi3* )              opsys=bsdos3 ;;
 322       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 323     esac
 324   ;;
 325
 326   ## Alliant machines
 327   ## Strictly speaking, we need the version of the alliant operating
 328   ## system to choose the right machine file, but currently the
 329   ## configuration name doesn't tell us enough to choose the right
 330   ## one; we need to give alliants their own operating system name to
 331   ## do this right.  When someone cares, they can help us.
 332   fx80-alliant-* )
 333     machine=alliant4 opsys=bsd4-2
 334   ;;
 335   i860-alliant-* )
 336     machine=alliant-2800 opsys=bsd4-3
 337   ;;
 338
 339   ## Alpha (DEC) machines.
 340   alpha*-dec-osf* )
 341     machine=alpha opsys=osf1
 342     # This is needed to find X11R6.1 libraries for certain tests.
 343     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 344     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 345     # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
 346     # due to non-traditional preprocessing with the current compiler
 347     # defaults.  OSF 4 can also have that compiler version, and there
 348     # seems always to have been a usable /usr/bin/cpp.
 349     NON_GNU_CPP=/usr/bin/cpp
 350     case "${canonical}" in
 351     alpha*-dec-osf[5-9]*)
 352       opsys=osf5-0 ;;
 353     esac
 354   ;;
 355
 356   alpha*-*-linux-gnu* )
 357     machine=alpha opsys=gnu-linux
 358   ;;
 359
 360   arm*-*-linux-gnu* )
 361     machine=arm opsys=gnu-linux
 362   ;;
 363
 364   ## Altos 3068
 365   m68*-altos-sysv* )
 366     machine=altos opsys=usg5-2
 367   ;;
 368
 369   ## Amdahl UTS
 370   580-amdahl-sysv* )
 371     machine=amdahl opsys=usg5-2-2
 372   ;;
 373
 374   ## Apollo, Domain/OS
 375   m68*-apollo-* )
 376     machine=apollo opsys=bsd4-3
 377   ;;
 378
 379   ## AT&T 3b2, 3b5, 3b15, 3b20
 380   we32k-att-sysv* )
 381     machine=att3b opsys=usg5-2-2
 382   ;;
 383
 384   ## AT&T 3b1 - The Mighty Unix PC!
 385   m68*-att-sysv* )
 386     machine=7300 opsys=usg5-2-2
 387   ;;
 388
 389   ## Bull dpx20
 390   rs6000-bull-bosx* )
 391     machine=ibmrs6000 opsys=aix3-2
 392   ;;
 393
 394   ## Bull dpx2
 395   m68*-bull-sysv3* )
 396     machine=dpx2 opsys=usg5-3
 397   ;;
 398
 399   ## Bull sps7
 400   m68*-bull-sysv2* )
 401     machine=sps7 opsys=usg5-2
 402   ;;
 403
 404   ## CCI 5/32, 6/32 -- see "Tahoe".
 405
 406   ## Celerity
 407   ## I don't know what configuration name to use for this; config.sub
 408   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 409   ## in touch with us!
 410   celerity-celerity-bsd* )
 411     machine=celerity opsys=bsd4-2
 412   ;;
 413
 414   ## Clipper
 415   ## What operating systems does this chip run that Emacs has been
 416   ## tested on?
 417   clipper-* )
 418     machine=clipper
 419     ## We'll use the catch-all code at the bottom to guess the
 420     ## operating system.
 421   ;;
 422
 423   ## Compaq Nonstop
 424   mips-compaq-nonstopux* )
 425     machine=nonstopux opsys=nonstopux
 426     ;;
 427
 428   ## Convex
 429   *-convex-bsd* | *-convex-convexos* )
 430     machine=convex opsys=bsd4-3
 431     ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
 432     NON_GNU_CPP="cc -E -P"
 433   ;;
 434
 435   ## Cubix QBx/386
 436   i[3456]86-cubix-sysv* )
 437     machine=intel386 opsys=usg5-3
 438   ;;
 439
 440   ## Cydra 5
 441   cydra*-cydrome-sysv* )
 442     machine=cydra5 opsys=usg5-3
 443   ;;
 444
 445   ## Data General AViiON Machines
 446   ## DG changed naming conventions with the release of 5.4.4.10, they
 447   ## dropped the initial 5.4 but left the intervening R.  Because of the
 448   ## R this shouldn't conflict with older versions of the OS (which I
 449   ## think were named like dgux4.*). In addition, DG new AViiONs series
 450   ## uses either Motorola M88k or Intel Pentium CPUs.
 451   m88k-dg-dguxR4.* | m88k-dg-dgux4* )
 452     machine=aviion opsys=dgux4
 453   ;;
 454   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 455     ## This name is dgux5-4-3 instead of dgux5-4r3
 456     ## to avoid a file name conflict on MSDOS.
 457     machine=aviion opsys=dgux5-4-3
 458   ;;
 459   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 460     machine=aviion opsys=dgux5-4r2
 461   ;;
 462   m88k-dg-dgux* )
 463     machine=aviion opsys=dgux
 464   ;;
 465
 466   ## Data General AViiON Intel (x86) Machines
 467   ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
 468   ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
 469   i[345]86-dg-dguxR4* )
 470     machine=aviion-intel opsys=dgux4
 471   ;;
 472
 473   ## DECstations
 474   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 475     machine=pmax opsys=bsd4-2
 476   ;;
 477   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 478     machine=pmax opsys=bsd4-3
 479   ;;
 480   mips-dec-ultrix* )
 481     machine=pmax opsys=ultrix4-3
 482   ;;
 483   mips-dec-osf* )
 484     machine=pmax opsys=osf1
 485   ;;
 486   mips-dec-mach_bsd4.3* )
 487     machine=pmax opsys=mach-bsd4-3
 488   ;;
 489
 490   ## Motorola Delta machines
 491   m68k-motorola-sysv* | m68000-motorola-sysv* )
 492     machine=delta opsys=usg5-3
 493     if test -z "`type gnucc | grep 'not found'`"
 494     then
 495       if test -s /etc/167config
 496       then CC="gnucc -m68040"
 497       else CC="gnucc -m68881"
 498       fi
 499     else
 500       if test -z "`type gcc | grep 'not found'`"
 501       then CC=gcc
 502       else CC=cc
 503       fi
 504     fi
 505   ;;
 506   m88k-motorola-sysv4* )
 507     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 508     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 509     # I hope there are not other 4.0 versions for this machine
 510     # which really need usg5-4 instead.
 511     machine=delta88k opsys=usg5-4-2
 512   ;;
 513   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 514     machine=delta88k opsys=usg5-3
 515   ;;
 516
 517   ## Dual machines
 518   m68*-dual-sysv* )
 519     machine=dual opsys=usg5-2
 520   ;;
 521   m68*-dual-uniplus* )
 522     machine=dual opsys=unipl5-2
 523   ;;
 524
 525   ## Elxsi 6400
 526   elxsi-elxsi-sysv* )
 527     machine=elxsi opsys=usg5-2
 528   ;;
 529
 530   ## Encore machines
 531   ns16k-encore-bsd* )
 532     machine=ns16000 opsys=umax
 533   ;;
 534
 535   ## The GEC 63 - apparently, this port isn't really finished yet.
 536   #  I'm sure we finished off the last of the machines, though.  -- fx
 537
 538   ## Gould Power Node and NP1
 539   pn-gould-bsd4.2* )
 540     machine=gould opsys=bsd4-2
 541   ;;
 542   pn-gould-bsd4.3* )
 543     machine=gould opsys=bsd4-3
 544   ;;
 545   np1-gould-bsd* )
 546     machine=gould-np1 opsys=bsd4-3
 547   ;;
 548
 549   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 550   ## as far as Emacs is concerned).
 551   m88k-harris-cxux* )
 552     # Build needs to be different on 7.0 and later releases
 553     case "`uname -r`" in
 554        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 555        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 556     esac
 557     NON_GNU_CPP="/lib/cpp"
 558   ;;
 559   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 560   m68k-harris-cxux* )
 561     machine=nh3000 opsys=cxux
 562   ;;
 563   ## Harris power pc NightHawk running Power UNIX (Series 6000)
 564   powerpc-harris-powerunix )
 565     machine=nh6000 opsys=powerunix
 566     NON_GNU_CPP="cc -Xo -E -P"
 567   ;;
 568   ## SR2001/SR2201 running HI-UX/MPP
 569   hppa1.1-hitachi-hiuxmpp* )
 570     machine=sr2k opsys=hiuxmpp
 571   ;;
 572   hppa1.1-hitachi-hiuxwe2* )
 573     machine=sr2k opsys=hiuxwe2
 574   ;;
 575   ## Honeywell XPS100
 576   xps*-honeywell-sysv* )
 577     machine=xps100 opsys=usg5-2
 578   ;;
 579
 580   ## HP 9000 series 200 or 300
 581   m68*-hp-bsd* )
 582     machine=hp9000s300 opsys=bsd4-3
 583   ;;
 584   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 585   m68*-hp-hpux* )
 586     case "`uname -r`" in
 587       ## Someone's system reports A.B8.05 for this.
 588       ## I wonder what other possibilities there are.
 589       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 590       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 591       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 592       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 593       *) machine=hp9000s300 opsys=hpux ;;
 594     esac
 595   ;;
 596
 597   ## HP 9000 series 700 and 800, running HP/UX
 598   hppa*-hp-hpux7* )
 599     machine=hp800 opsys=hpux
 600   ;;
 601   hppa*-hp-hpux8* )
 602     machine=hp800 opsys=hpux8
 603   ;;
 604   hppa*-hp-hpux9shr* )
 605     machine=hp800 opsys=hpux9shr
 606   ;;
 607   hppa*-hp-hpux9* )
 608     machine=hp800 opsys=hpux9
 609   ;;
 610   hppa*-hp-hpux10.2* )
 611     machine=hp800 opsys=hpux10-20
 612   ;;
 613   hppa*-hp-hpux10* )
 614     machine=hp800 opsys=hpux10
 615   ;;
 616   hppa*-hp-hpux1[1-9]* )
 617     machine=hp800 opsys=hpux11
 618     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 619   ;;
 620
 621   hppa*-*-linux-gnu* )
 622     machine=hp800 opsys=gnu-linux
 623   ;;
 624
 625   ## HP 9000 series 700 and 800, running HP/UX
 626   hppa*-hp-hpux* )
 627     ## Cross-compilation?  Nah!
 628     case "`uname -r`" in
 629       ## Someone's system reports A.B8.05 for this.
 630       ## I wonder what other possibilities there are.
 631       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 632       *.08.* ) machine=hp800 opsys=hpux8 ;;
 633       *.09.* ) machine=hp800 opsys=hpux9 ;;
 634       *) machine=hp800 opsys=hpux10 ;;
 635     esac
 636   ;;
 637   hppa*-*-nextstep* )
 638     machine=hp800 opsys=nextstep
 639   ;;
 640
 641   ## Orion machines
 642   orion-orion-bsd* )
 643     machine=orion opsys=bsd4-2
 644   ;;
 645   clipper-orion-bsd* )
 646     machine=orion105 opsys=bsd4-2
 647   ;;
 648
 649   ## IBM machines
 650   i[3456]86-ibm-aix1.1* )
 651     machine=ibmps2-aix opsys=usg5-2-2
 652   ;;
 653   i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
 654     machine=ibmps2-aix opsys=usg5-3
 655   ;;
 656   i370-ibm-aix*)
 657     machine=ibm370aix opsys=usg5-3
 658   ;;
 659   s390-*-linux-gnu* )
 660     machine=ibms390 opsys=gnu-linux
 661   ;;
 662   s390x-*-linux-gnu* )
 663     machine=ibms390x opsys=gnu-linux
 664   ;;
 665   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 666     machine=ibmrs6000 opsys=aix3-1
 667   ;;
 668   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 669     machine=ibmrs6000 opsys=aix3-2-5
 670   ;;
 671   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 672     machine=ibmrs6000 opsys=aix4-1
 673   ;;
 674   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 675     machine=ibmrs6000 opsys=aix4-2
 676   ;;
 677   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 678     machine=ibmrs6000 opsys=aix4-2
 679   ;;
 680   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 681     machine=ibmrs6000 opsys=aix4
 682   ;;
 683   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 684     machine=ibmrs6000 opsys=aix4-1
 685   ;;
 686   rs6000-ibm-aix* | powerpc-ibm-aix* )
 687     machine=ibmrs6000 opsys=aix3-2
 688   ;;
 689   romp-ibm-bsd4.3* )
 690     machine=ibmrt opsys=bsd4-3
 691   ;;
 692   romp-ibm-bsd4.2* )
 693     machine=ibmrt opsys=bsd4-2
 694   ;;
 695   romp-ibm-aos4.3* )
 696     machine=ibmrt opsys=bsd4-3
 697   ;;
 698   romp-ibm-aos4.2* )
 699     machine=ibmrt opsys=bsd4-2
 700   ;;
 701   romp-ibm-aos* )
 702     machine=ibmrt opsys=bsd4-3
 703   ;;
 704   romp-ibm-bsd* )
 705     machine=ibmrt opsys=bsd4-3
 706   ;;
 707   romp-ibm-aix* )
 708     machine=ibmrt-aix opsys=usg5-2-2
 709   ;;
 710
 711   ## Integrated Solutions `Optimum V'
 712   m68*-isi-bsd4.2* )
 713     machine=isi-ov opsys=bsd4-2
 714   ;;
 715   m68*-isi-bsd4.3* )
 716     machine=isi-ov opsys=bsd4-3
 717   ;;
 718
 719   ## Intel 386 machines where we do care about the manufacturer
 720   i[3456]86-intsys-sysv* )
 721     machine=is386 opsys=usg5-2-2
 722   ;;
 723
 724   ## Prime EXL
 725   i[3456]86-prime-sysv* )
 726     machine=i386 opsys=usg5-3
 727   ;;
 728
 729   ## Sequent Symmetry running Dynix
 730   i[3456]86-sequent-bsd* )
 731     machine=symmetry opsys=bsd4-3
 732   ;;
 733
 734   ## Sequent Symmetry running ptx 4, which is a modified SVR4.
 735   i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
 736     machine=sequent-ptx opsys=ptx4
 737     NON_GNU_CPP=/lib/cpp
 738   ;;
 739
 740   ## Sequent Symmetry running DYNIX/ptx
 741   ## Use the old cpp rather than the newer ANSI one.
 742   i[3456]86-sequent-ptx* )
 743     machine=sequent-ptx opsys=ptx
 744     NON_GNU_CPP="/lib/cpp"
 745   ;;
 746
 747   ## ncr machine running svr4.3.
 748   i[3456]86-ncr-sysv4.3 )
 749     machine=ncr386 opsys=usg5-4-3
 750   ;;
 751
 752   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 753   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 754   i[3456]86-ncr-sysv* )
 755     machine=ncr386 opsys=usg5-4-2
 756   ;;
 757
 758   ## Intel Paragon OSF/1
 759   i860-intel-osf1* )
 760     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 761   ;;
 762
 763   ## Intel 860
 764   i860-*-sysv4* )
 765     machine=i860 opsys=usg5-4
 766     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 767     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 768   ;;
 769
 770   ## Macintosh PowerPC
 771   powerpc*-*-linux-gnu* )
 772     machine=macppc opsys=gnu-linux
 773   ;;
 774
 775   ## Masscomp machines
 776   m68*-masscomp-rtu* )
 777     machine=masscomp opsys=rtu
 778   ;;
 779
 780   ## Megatest machines
 781   m68*-megatest-bsd* )
 782     machine=mega68 opsys=bsd4-2
 783   ;;
 784
 785   ## Workstations sold by MIPS
 786   ## This is not necessarily all workstations using the MIPS processor -
 787   ## Irises are produced by SGI, and DECstations by DEC.
 788
 789   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 790   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 791   ## it gives for choosing between the alternatives seems to be "Use
 792   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 793   ## the BSD world."  I'll assume that these are instructions for
 794   ## handling two odd situations, and that every other situation
 795   ## should use mips.h and usg5-2-2, they being listed first.
 796   mips-mips-usg* )
 797     machine=mips4
 798     ## Fall through to the general code at the bottom to decide on the OS.
 799   ;;
 800   mips-mips-riscos4* )
 801     machine=mips4 opsys=bsd4-3
 802     NON_GNU_CC="cc -systype bsd43"
 803     NON_GNU_CPP="cc -systype bsd43 -E"
 804   ;;
 805   mips-mips-riscos5* )
 806     machine=mips4 opsys=riscos5
 807     NON_GNU_CC="cc -systype bsd43"
 808     NON_GNU_CPP="cc -systype bsd43 -E"
 809   ;;
 810   mips-mips-bsd* )
 811     machine=mips opsys=bsd4-3
 812   ;;
 813   mips-mips-* )
 814     machine=mips opsys=usg5-2-2
 815   ;;
 816
 817   ## NeXT
 818   m68*-next-* | m68k-*-nextstep* )
 819     machine=m68k opsys=nextstep
 820   ;;
 821
 822   ## The complete machine from National Semiconductor
 823   ns32k-ns-genix* )
 824     machine=ns32000 opsys=usg5-2
 825   ;;
 826
 827   ## NCR machines
 828   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 829     machine=tower32 opsys=usg5-2-2
 830   ;;
 831   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 832     machine=tower32v3 opsys=usg5-3
 833   ;;
 834
 835   ## NEC EWS4800
 836   mips-nec-sysv4*)
 837   machine=ews4800 opsys=ux4800
 838   ;;
 839
 840   ## Nixdorf Targon 31
 841   m68*-nixdorf-sysv* )
 842     machine=targon31 opsys=usg5-2-2
 843   ;;
 844
 845   ## Nu (TI or LMI)
 846   m68*-nu-sysv* )
 847     machine=nu opsys=usg5-2
 848   ;;
 849
 850   ## Plexus
 851   m68*-plexus-sysv* )
 852     machine=plexus opsys=usg5-2
 853   ;;
 854
 855   ## Pyramid machines
 856   ## I don't really have any idea what sort of processor the Pyramid has,
 857   ## so I'm assuming it is its own architecture.
 858   pyramid-pyramid-bsd* )
 859     machine=pyramid opsys=bsd4-2
 860   ;;
 861
 862   ## Sequent Balance
 863   ns32k-sequent-bsd4.2* )
 864     machine=sequent opsys=bsd4-2
 865   ;;
 866   ns32k-sequent-bsd4.3* )
 867     machine=sequent opsys=bsd4-3
 868   ;;
 869
 870   ## Siemens Nixdorf
 871   mips-siemens-sysv* | mips-sni-sysv*)
 872     machine=mips-siemens opsys=usg5-4
 873     NON_GNU_CC=/usr/ccs/bin/cc
 874     NON_GNU_CPP=/usr/ccs/lib/cpp
 875   ;;
 876
 877   ## Silicon Graphics machines
 878   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 879   m68*-sgi-iris3.5* )
 880     machine=irist opsys=iris3-5
 881   ;;
 882   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 883     machine=irist opsys=iris3-6
 884   ;;
 885   ## Iris 4D
 886   mips-sgi-irix3* )
 887     machine=iris4d opsys=irix3-3
 888   ;;
 889   mips-sgi-irix4* )
 890     machine=iris4d opsys=irix4-0
 891   ;;
 892   mips-sgi-irix6.5 )
 893     machine=iris4d opsys=irix6-5
 894     # Without defining _LANGUAGE_C, things get masked out in the headers
 895     # so that, for instance, grepping for `free' in stdlib.h fails and
 896     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 897     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 898     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 899   ;;
 900   mips-sgi-irix6* )
 901     machine=iris4d opsys=irix6-0
 902     # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
 903     # but presumably it does no harm.
 904     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 905     # -32 probably isn't necessary in later v.6s -- anyone know which?
 906     NON_GCC_TEST_OPTIONS=-32
 907   ;;
 908   mips-sgi-irix5.[01]* )
 909     machine=iris4d opsys=irix5-0
 910   ;;
 911   mips-sgi-irix5* | mips-sgi-irix* )
 912     machine=iris4d opsys=irix5-2
 913   ;;
 914
 915   ## SONY machines
 916   m68*-sony-bsd4.2* )
 917     machine=news opsys=bsd4-2
 918   ;;
 919   m68*-sony-bsd4.3* )
 920     machine=news opsys=bsd4-3
 921   ;;
 922   m68*-sony-newsos3* | m68*-sony-news3*)
 923     machine=news opsys=bsd4-3
 924   ;;
 925   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 926     machine=news-risc opsys=bsd4-3
 927   ;;
 928   mips-sony-newsos6* )
 929     machine=news-r6 opsys=newsos6
 930   ;;
 931   mips-sony-news* )
 932     machine=news-risc opsys=newsos5
 933   ;;
 934
 935   ## Stride
 936   m68*-stride-sysv* )
 937     machine=stride opsys=usg5-2
 938   ;;
 939
 940   ## Suns
 941   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 942     machine=sparc opsys=gnu-linux
 943   ;;
 944
 945   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 946     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 947     | rs6000-*-solaris2*)
 948     case "${canonical}" in
 949       m68*-sunos1* )    machine=sun1 ;;
 950       m68*-sunos2* )    machine=sun2 ;;
 951       m68* )            machine=sun3 ;;
 952       i[3456]86-sun-sunos[34]* )        machine=sun386 ;;
 953       i[3456]86-*-* )     machine=intel386 ;;
 954       powerpcle* )      machine=powerpcle ;;
 955       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 956       sparc* )          machine=sparc ;;
 957       * )               unported=yes ;;
 958     esac
 959     case "${canonical}" in
 960       ## The Sun386 didn't get past 4.0.
 961       i[3456]86-*-sunos4          ) opsys=sunos4-0 ;;
 962       *-sunos4.0*         ) opsys=sunos4-0 ;;
 963       *-sunos4.1.[3-9]*noshare )
 964                 ## This name is sunos413 instead of sunos4-1-3
 965                 ## to avoid a file name conflict on MSDOS.
 966                 opsys=sunos413
 967                 NON_GNU_CPP=/usr/lib/cpp
 968                 NON_GCC_TEST_OPTIONS=-Bstatic
 969                 GCC_TEST_OPTIONS=-static
 970                 ;;
 971       *-sunos4.1.[3-9]* | *-sunos4shr*)
 972                 opsys=sunos4shr
 973                 NON_GNU_CPP=/usr/lib/cpp
 974                 ;;
 975       *-sunos4* | *-sunos )
 976                 opsys=sunos4-1
 977                 NON_GCC_TEST_OPTIONS=-Bstatic
 978                 GCC_TEST_OPTIONS=-static
 979                 ;;
 980       *-sunos5.3* | *-solaris2.3* )
 981                 opsys=sol2-3
 982                 NON_GNU_CPP=/usr/ccs/lib/cpp
 983                 ;;
 984       *-sunos5.4* | *-solaris2.4* )
 985                 opsys=sol2-4
 986                 NON_GNU_CPP=/usr/ccs/lib/cpp
 987                 RANLIB="ar -ts"
 988                 ;;
 989       *-sunos5.5* | *-solaris2.5* )
 990                 opsys=sol2-5
 991                 NON_GNU_CPP=/usr/ccs/lib/cpp
 992                 RANLIB="ar -ts"
 993                 ;;
 994       *-sunos5.6* | *-solaris2.6* )
 995                 opsys=sol2-6
 996                 NON_GNU_CPP=/usr/ccs/lib/cpp
 997                 RANLIB="ar -ts"
 998                 ;;
 999       *-sunos5* | *-solaris* )
1000                 opsys=sol2-6
1001                 NON_GNU_CPP=/usr/ccs/lib/cpp
1002                 ;;
1003       *                   ) opsys=bsd4-2   ;;
1004     esac
1005     ## Watch out for a compiler that we know will not work.
1006     case "${canonical}" in
1007      *-solaris* | *-sunos5* )
1008                 if [ "x$CC" = x/usr/ucb/cc ]; then
1009                   ## /usr/ucb/cc doesn't work;
1010                   ## we should find some other compiler that does work.
1011                   unset CC
1012                 fi
1013                 ;;
1014       *) ;;
1015     esac
1016   ;;
1017   sparc-*-nextstep* )
1018     machine=sparc opsys=nextstep
1019   ;;
1020
1021   ## Tadpole 68k
1022   m68*-tadpole-sysv* )
1023     machine=tad68k opsys=usg5-3
1024   ;;
1025
1026   ## Tahoe machines
1027   tahoe-tahoe-bsd4.2* )
1028     machine=tahoe opsys=bsd4-2
1029   ;;
1030   tahoe-tahoe-bsd4.3* )
1031     machine=tahoe opsys=bsd4-3
1032   ;;
1033
1034   ## Tandem Integrity S2
1035   mips-tandem-sysv* )
1036     machine=tandem-s2 opsys=usg5-3
1037   ;;
1038
1039   ## Tektronix XD88
1040   m88k-tektronix-sysv3* )
1041   machine=tekxd88 opsys=usg5-3
1042   ;;
1043
1044   ## Tektronix 16000 box (6130?)
1045   ns16k-tektronix-bsd* )
1046     machine=ns16000 opsys=bsd4-2
1047   ;;
1048   ## Tektronix 4300
1049   ## src/m/tek4300.h hints that this is a m68k machine.
1050   m68*-tektronix-bsd* )
1051     machine=tek4300 opsys=bsd4-3
1052   ;;
1053
1054   ## Titan P2 or P3
1055   ## We seem to have lost the machine-description file titan.h!
1056   titan-titan-sysv* )
1057     machine=titan opsys=usg5-3
1058   ;;
1059
1060   ## Ustation E30 (SS5E)
1061   m68*-unisys-uniplus* )
1062     machine=ustation opsystem=unipl5-2
1063   ;;
1064
1065   ## Vaxen.
1066   vax-dec-* )
1067     machine=vax
1068     case "${canonical}" in
1069       *-bsd4.1* )                                       opsys=bsd4-1 ;;
1070       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
1071       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
1072       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
1073       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
1074       *-vms* )                                          opsys=vms ;;
1075       * )                                               unported=yes
1076     esac
1077   ;;
1078
1079   ## Whitechapel MG1
1080   ns16k-whitechapel-* )
1081     machine=mg1
1082     ## We don't know what sort of OS runs on these; we'll let the
1083     ## operating system guessing code below try.
1084   ;;
1085
1086   ## Wicat
1087   m68*-wicat-sysv* )
1088     machine=wicat opsys=usg5-2
1089   ;;
1090
1091   ## IA-64
1092   ia64*-*-linux* )
1093     machine=ia64 opsys=gnu-linux
1094   ;;
1095
1096   ## Intel 386 machines where we don't care about the manufacturer
1097   i[3456]86-*-* )
1098     machine=intel386
1099     case "${canonical}" in
1100       *-cygwin )                opsys=cygwin ;;
1101       *-darwin* )               opsys=darwin
1102                                 CPP="${CC-cc} -E -no-cpp-precomp"
1103                                 ;;
1104       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1105       *-isc2.2* )               opsys=isc2-2 ;;
1106       *-isc4.0* )               opsys=isc4-0 ;;
1107       *-isc4.* )                opsys=isc4-1
1108                                 GCC_TEST_OPTIONS=-posix
1109                                 NON_GCC_TEST_OPTIONS=-Xp
1110                                 ;;
1111       *-isc* )                  opsys=isc3-0 ;;
1112       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1113       *-esix* )                 opsys=esix ;;
1114       *-xenix* )                opsys=xenix ;;
1115       *-linux-gnu* )            opsys=gnu-linux ;;
1116       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
1117       *-sco3.2v5* )             opsys=sco5
1118                                 NON_GNU_CPP=/lib/cpp
1119                                 # Prevent -belf from being passed to $CPP.
1120                                 # /lib/cpp does not accept it.
1121                                 OVERRIDE_CPPFLAGS=" "
1122                                 ;;
1123       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1124       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1125       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1126       *-386bsd* )               opsys=386bsd ;;
1127       *-nextstep* )             opsys=nextstep ;;
1128       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1129     esac
1130   ;;
1131
1132   ## m68k Linux-based GNU system
1133   m68k-*-linux-gnu* )
1134     machine=m68k opsys=gnu-linux
1135   ;;
1136
1137   ## Mips Linux-based GNU system
1138   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
1139     machine=mips opsys=gnu-linux
1140   ;;
1141
1142   ## UXP/DS
1143   sparc-fujitsu-sysv4* )
1144     machine=sparc opsys=uxpds
1145     NON_GNU_CPP=/usr/ccs/lib/cpp
1146     RANLIB="ar -ts"
1147   ;;
1148
1149   ## UXP/V
1150   f301-fujitsu-uxpv4.1)
1151     machine=f301 opsys=uxpv
1152   ;;
1153
1154   ## Darwin / Mac OS X
1155   powerpc-apple-darwin* )
1156     machine=powermac opsys=darwin
1157     # Define CPP as follows to make autoconf work correctly.
1158     CPP="${CC-cc} -E -no-cpp-precomp"
1159     # Use fink packages if available.
1160     if test -d /sw/include && test -d /sw/lib; then
1161         GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
1162         CPP="${CPP} ${GCC_TEST_OPTIONS}"
1163         NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
1164     fi
1165   ;;
1166
1167   ## AMD x86-64 Linux-based GNU system
1168   x86_64-*-linux-gnu* )
1169     machine=amdx86-64 opsys=gnu-linux
1170   ;;
1171
1172   * )
1173     unported=yes
1174   ;;
1175 esac
1176
1177 ### If the code above didn't choose an operating system, just choose
1178 ### an operating system based on the configuration name.  You really
1179 ### only want to use this when you have no idea what the right
1180 ### operating system is; if you know what operating systems a machine
1181 ### runs, it's cleaner to make it explicit in the case statement
1182 ### above.
1183 if test x"${opsys}" = x; then
1184   case "${canonical}" in
1185     *-gnu* )                            opsys=gnu ;;
1186     *-bsd4.[01] )                       opsys=bsd4-1 ;;
1187     *-bsd4.2 )                          opsys=bsd4-2 ;;
1188     *-bsd4.3 )                          opsys=bsd4-3 ;;
1189     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
1190     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
1191     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
1192     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
1193     *-sysv4.2uw* )                      opsys=unixware ;;
1194     *-sysv5uw* )                        opsys=unixware ;;
1195     *-sysv5OpenUNIX* )                  opsys=unixware ;;
1196     *-sysv4.1* | *-sysvr4.1* )
1197         NON_GNU_CPP=/usr/lib/cpp
1198         opsys=usg5-4 ;;
1199     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1200         if [ x$NON_GNU_CPP = x ]; then
1201           if [ -f /usr/ccs/lib/cpp ]; then
1202             NON_GNU_CPP=/usr/ccs/lib/cpp
1203           else
1204             NON_GNU_CPP=/lib/cpp
1205           fi
1206         fi
1207         opsys=usg5-4-2 ;;
1208     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
1209     * )
1210       unported=yes
1211     ;;
1212   esac
1213 fi
1214
1215 ]
1216 dnl quotation ends
1217
1218 if test $unported = yes; then
1219   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
1220 Check `etc/MACHINES' for recognized configuration names.])
1221 fi
1222
1223 machfile="m/${machine}.h"
1224 opsysfile="s/${opsys}.h"
1225
1226
1227 #### Choose a compiler.
1228 test -n "$CC" && cc_specified=yes
1229
1230 # Save the value of CFLAGS that the user specified.
1231 SPECIFIED_CFLAGS="$CFLAGS"
1232
1233 case ${with_gcc} in
1234   "yes" ) CC="gcc" GCC=yes ;;
1235   "no"  ) : ${CC=cc} ;;
1236   * )
1237 esac
1238 AC_PROG_CC
1239
1240 # On Suns, sometimes $CPP names a directory.
1241 if test -n "$CPP" && test -d "$CPP"; then
1242   CPP=
1243 fi
1244
1245 #### Some systems specify a CPP to use unless we are using GCC.
1246 #### Now that we know whether we are using GCC, we can decide whether
1247 #### to use that one.
1248 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1249 then
1250   CPP="$NON_GNU_CPP"
1251 fi
1252
1253 #### Some systems specify a CC to use unless we are using GCC.
1254 #### Now that we know whether we are using GCC, we can decide whether
1255 #### to use that one.
1256 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1257   test x$cc_specified != xyes
1258 then
1259   CC="$NON_GNU_CC"
1260 fi
1261
1262 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1263 then
1264   CC="$CC $GCC_TEST_OPTIONS"
1265 fi
1266
1267 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1268 then
1269   CC="$CC $NON_GCC_TEST_OPTIONS"
1270 fi
1271
1272 dnl checks for Unix variants
1273 AC_AIX
1274 AC_GNU_SOURCE
1275
1276 ### Use -Wno-pointer-sign if the compiler supports it
1277 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
1278 SAVE_CFLAGS="$CFLAGS"
1279 CFLAGS="$CFLAGS -Wno-pointer-sign"
1280 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
1281 if test $has_option = yes; then
1282    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
1283 fi
1284 AC_MSG_RESULT($has_option)
1285 CFLAGS="$SAVE_CFLAGS"
1286 unset has_option
1287 unset SAVE_CFLAGS
1288
1289 #### Some other nice autoconf tests.
1290
1291 dnl checks for programs
1292 AC_PROG_LN_S
1293 AC_PROG_CPP
1294 AC_PROG_INSTALL
1295 if test "x$RANLIB" = x; then
1296   AC_PROG_RANLIB
1297 fi
1298 AC_PATH_PROG(INSTALL_INFO, install-info)
1299 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
1300 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
1301 dnl Don't use GZIP, which is used by gzip for additional parameters.
1302 AC_PATH_PROG(GZIP_PROG, gzip)
1303
1304 dnl Add our options to ac_link now, after it is set up.
1305
1306 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1307 then
1308   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1309 fi
1310
1311 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1312 then
1313   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1314 fi
1315
1316 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1317 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1318 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1319 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1320 dnl if not built to support GNU ld.
1321
1322 late_LDFLAGS=$LDFLAGS
1323 if test "$GCC" = yes; then
1324   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
1325 else
1326   LDFLAGS="$LDFLAGS -znocombreloc"
1327 fi
1328
1329 AC_MSG_CHECKING([for -znocombreloc])
1330 AC_LINK_IFELSE([main(){return 0;}],
1331   [AC_MSG_RESULT(yes)],
1332   LDFLAGS=$late_LDFLAGS
1333   [AC_MSG_RESULT(no)])
1334
1335 #### Extract some information from the operating system and machine files.
1336
1337 AC_CHECKING([the machine- and system-dependent files to find out
1338  - which libraries the lib-src programs will want, and
1339  - whether the GNU malloc routines are usable])
1340
1341 ### First figure out CFLAGS (which we use for running the compiler here)
1342 ### and REAL_CFLAGS (which we use for real compilation).
1343 ### The two are the same except on a few systems, where they are made
1344 ### different to work around various lossages.  For example,
1345 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1346 ### as implying static linking.
1347
1348 ### If the CFLAGS env var is specified, we use that value
1349 ### instead of the default.
1350
1351 ### It's not important that this name contain the PID; you can't run
1352 ### two configures in the same directory and have anything work
1353 ### anyway.
1354 tempcname="conftest.c"
1355
1356 echo '
1357 #include "'${srcdir}'/src/'${opsysfile}'"
1358 #include "'${srcdir}'/src/'${machfile}'"
1359 #ifndef LIBS_MACHINE
1360 #define LIBS_MACHINE
1361 #endif
1362 #ifndef LIBS_SYSTEM
1363 #define LIBS_SYSTEM
1364 #endif
1365 #ifndef C_SWITCH_SYSTEM
1366 #define C_SWITCH_SYSTEM
1367 #endif
1368 #ifndef C_SWITCH_MACHINE
1369 #define C_SWITCH_MACHINE
1370 #endif
1371 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1372 configure___ c_switch_system=C_SWITCH_SYSTEM
1373 configure___ c_switch_machine=C_SWITCH_MACHINE
1374
1375 #ifndef LIB_X11_LIB
1376 #define LIB_X11_LIB -lX11
1377 #endif
1378
1379 #ifndef LIBX11_MACHINE
1380 #define LIBX11_MACHINE
1381 #endif
1382
1383 #ifndef LIBX11_SYSTEM
1384 #define LIBX11_SYSTEM
1385 #endif
1386 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1387
1388 #ifdef UNEXEC
1389 configure___ unexec=UNEXEC
1390 #else
1391 configure___ unexec=unexec.o
1392 #endif
1393
1394 #ifdef SYSTEM_MALLOC
1395 configure___ system_malloc=yes
1396 #else
1397 configure___ system_malloc=no
1398 #endif
1399
1400 #ifdef USE_MMAP_FOR_BUFFERS
1401 configure___ use_mmap_for_buffers=yes
1402 #else
1403 configure___ use_mmap_for_buffers=no
1404 #endif
1405
1406 #ifndef C_DEBUG_SWITCH
1407 #define C_DEBUG_SWITCH -g
1408 #endif
1409
1410 #ifndef C_OPTIMIZE_SWITCH
1411 #ifdef __GNUC__
1412 #define C_OPTIMIZE_SWITCH -O2
1413 #else
1414 #define C_OPTIMIZE_SWITCH -O
1415 #endif
1416 #endif
1417
1418 #ifndef C_WARNINGS_SWITCH
1419 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
1420 #endif
1421
1422 #ifndef LD_SWITCH_MACHINE
1423 #define LD_SWITCH_MACHINE
1424 #endif
1425
1426 #ifndef LD_SWITCH_SYSTEM
1427 #define LD_SWITCH_SYSTEM
1428 #endif
1429
1430 #ifndef LD_SWITCH_X_SITE_AUX
1431 #define LD_SWITCH_X_SITE_AUX
1432 #endif
1433
1434 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1435 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1436
1437 #ifdef THIS_IS_CONFIGURE
1438
1439 /* Get the CFLAGS for tests in configure.  */
1440 #ifdef __GNUC__
1441 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1442 #else
1443 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1444 #endif
1445
1446 #else /* not THIS_IS_CONFIGURE */
1447
1448 /* Get the CFLAGS for real compilation.  */
1449 #ifdef __GNUC__
1450 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH '${SPECIFIED_CFLAGS}'
1451 #else
1452 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1453 #endif
1454
1455 #endif /* not THIS_IS_CONFIGURE */
1456 ' > ${tempcname}
1457
1458 # The value of CPP is a quoted variable reference, so we need to do this
1459 # to get its actual value...
1460 CPP=`eval "echo $CPP"`
1461 [eval `${CPP} -Isrc ${tempcname} \
1462        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1463 if test "x$SPECIFIED_CFLAGS" = x; then
1464   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1465          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1466 else
1467   REAL_CFLAGS="$CFLAGS"
1468 fi]
1469 rm ${tempcname}
1470
1471 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1472
1473 ### Make sure subsequent tests use flags consistent with the build flags.
1474
1475 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1476   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1477 else
1478   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1479 fi
1480
1481 dnl For AC_FUNC_GETLOADAVG, at least:
1482 AC_CONFIG_LIBOBJ_DIR(src)
1483
1484 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1485 AC_SYS_LARGEFILE
1486
1487
1488 ### The standard library on x86-64 GNU/Linux distributions can
1489 ### be located in either /usr/lib64 or /usr/lib.
1490 case "${canonical}" in
1491   x86_64-*-linux-gnu* )
1492     if test -d /usr/lib64; then
1493       AC_DEFINE(HAVE_X86_64_LIB64_DIR, 1,
1494         [Define to 1 if the file /usr/lib64 exists.])
1495 fi
1496 esac
1497
1498 dnl This function defintion taken from Gnome 2.0
1499 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1500 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1501 dnl also defines GSTUFF_PKG_ERRORS on error
1502 AC_DEFUN([PKG_CHECK_MODULES], [
1503   succeeded=no
1504
1505   if test -z "$PKG_CONFIG"; then
1506     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1507   fi
1508
1509   if test "$PKG_CONFIG" = "no" ; then
1510      ifelse([$4], , [AC_MSG_ERROR([
1511       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1512   else
1513      PKG_CONFIG_MIN_VERSION=0.9.0
1514      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1515         AC_MSG_CHECKING(for $2)
1516
1517         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1518             AC_MSG_RESULT(yes)
1519             succeeded=yes
1520
1521             AC_MSG_CHECKING($1_CFLAGS)
1522             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1523             AC_MSG_RESULT($$1_CFLAGS)
1524
1525             AC_MSG_CHECKING($1_LIBS)
1526             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1527             AC_MSG_RESULT($$1_LIBS)
1528         else
1529             AC_MSG_RESULT(no)
1530             $1_CFLAGS=""
1531             $1_LIBS=""
1532             ## If we have a custom action on failure, don't print errors, but
1533             ## do set a variable so people can do so.
1534             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1535             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1536         fi
1537
1538         AC_SUBST($1_CFLAGS)
1539         AC_SUBST($1_LIBS)
1540      else
1541         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1542         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1543      fi
1544   fi
1545
1546   if test $succeeded = yes; then
1547      ifelse([$3], , :, [$3])
1548   else
1549      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1550   fi
1551 ])
1552
1553
1554 if test "${with_sound}" != "no"; then
1555   # Sound support for GNU/Linux and the free BSDs.
1556   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1557   # Emulation library used on NetBSD.
1558   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1559   AC_SUBST(LIBSOUND)
1560
1561   ALSA_REQUIRED=1.0.0
1562   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1563   dnl Check if --with-pkg-config-prog has been given.
1564   if test "X${with_pkg_config_prog}" != X; then
1565     PKG_CONFIG="${with_pkg_config_prog}"
1566   fi
1567   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1568   if test $HAVE_ALSA = yes; then
1569     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1570     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1571     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1572   fi
1573   AC_SUBST(CFLAGS_SOUND)
1574 fi
1575
1576 dnl checks for header files
1577 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1578   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1579   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1580   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1581   sys/utsname.h pwd.h)
1582
1583 AC_MSG_CHECKING(if personality LINUX32 can be set)
1584 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1585                emacs_cv_personality_linux32=yes,
1586                emacs_cv_personality_linux32=no)
1587 AC_MSG_RESULT($emacs_cv_personality_linux32)
1588
1589 if test $emacs_cv_personality_linux32 = yes; then
1590   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1591             [Define to 1 if personality LINUX32 can be set.])
1592 fi
1593
1594 dnl On Solaris 8 there's a compilation warning for term.h because
1595 dnl it doesn't define `bool'.
1596 AC_CHECK_HEADERS(term.h, , , -)
1597 AC_HEADER_STDC
1598 AC_HEADER_TIME
1599 AC_CHECK_DECLS([sys_siglist])
1600 if test $ac_cv_have_decl_sys_siglist != yes; then
1601   # For Tru64, at least:
1602   AC_CHECK_DECLS([__sys_siglist])
1603   if test $ac_cv_have_decl___sys_siglist = yes; then
1604     AC_DEFINE(sys_siglist, __sys_siglist,
1605               [Define to any substitute for sys_siglist.])
1606   fi
1607 fi
1608 AC_HEADER_SYS_WAIT
1609
1610 dnl Some systems have utime.h but don't declare the struct anyplace.
1611 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1612 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1613 #include <sys/time.h>
1614 #include <time.h>
1615 #else
1616 #ifdef HAVE_SYS_TIME_H
1617 #include <sys/time.h>
1618 #else
1619 #include <time.h>
1620 #endif
1621 #endif
1622 #ifdef HAVE_UTIME_H
1623 #include <utime.h>
1624 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1625   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1626 if test $emacs_cv_struct_utimbuf = yes; then
1627   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1628 fi
1629
1630 dnl checks for typedefs
1631 AC_TYPE_SIGNAL
1632
1633 dnl Check for speed_t typedef.
1634 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1635   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1636     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1637 if test $emacs_cv_speed_t = yes; then
1638   AC_DEFINE(HAVE_SPEED_T, 1,
1639            [Define to 1 if `speed_t' is declared by <termios.h>.])
1640 fi
1641
1642 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1643 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1644 #include <sys/time.h>
1645 #include <time.h>
1646 #else
1647 #ifdef HAVE_SYS_TIME_H
1648 #include <sys/time.h>
1649 #else
1650 #include <time.h>
1651 #endif
1652 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1653   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1654 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1655 if test $emacs_cv_struct_timeval = yes; then
1656   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1657 fi
1658
1659 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1660 AC_TRY_COMPILE([#include <math.h>],
1661 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1662   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1663 HAVE_EXCEPTION=$emacs_cv_struct_exception
1664 if test $emacs_cv_struct_exception != yes; then
1665   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1666 fi
1667
1668 AC_CHECK_HEADERS(sys/socket.h)
1669 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1670 #if HAVE_SYS_SOCKET_H
1671 #include <sys/socket.h>
1672 #endif])
1673
1674 dnl checks for structure members
1675 AC_STRUCT_TM
1676 AC_STRUCT_TIMEZONE
1677 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1678                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1679                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1680                 [#include <time.h>])
1681 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1682                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1683                   struct ifreq.ifr_addr], , ,
1684                  [AC_INCLUDES_DEFAULT
1685 #if HAVE_SYS_SOCKET_H
1686 #include <sys/socket.h>
1687 #endif
1688 #if HAVE_NET_IF_H
1689 #include <net/if.h>
1690 #endif])
1691
1692 dnl checks for compiler characteristics
1693
1694 dnl Testing __STDC__ to determine prototype support isn't good enough.
1695 dnl DEC C, for instance, doesn't define it with default options, and
1696 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1697 dnl and void *.
1698 AC_C_PROTOTYPES
1699 AC_C_VOLATILE
1700 AC_C_CONST
1701 dnl This isn't useful because we can't turn on use of `inline' unless
1702 dnl the compiler groks `extern inline'.
1703 dnl AC_C_INLINE
1704 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1705   [AC_TRY_COMPILE(, [void * foo;],
1706                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1707 if test $emacs_cv_void_star = yes; then
1708   AC_DEFINE(POINTER_TYPE, void)
1709 else
1710   AC_DEFINE(POINTER_TYPE, char)
1711 fi
1712 AH_TEMPLATE(POINTER_TYPE,
1713             [Define as `void' if your compiler accepts `void *'; otherwise
1714              define as `char'.])dnl
1715
1716
1717
1718 dnl This could be used for targets which can have both byte sexes.
1719 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1720 dnl AC_C_BIGENDIAN
1721
1722 dnl check for Make feature
1723 AC_PROG_MAKE_SET
1724
1725 dnl checks for operating system services
1726 AC_SYS_LONG_FILE_NAMES
1727
1728 #### Choose a window system.
1729
1730 AC_PATH_X
1731 if test "$no_x" = yes; then
1732   window_system=none
1733 else
1734   window_system=x11
1735 fi
1736
1737 if test "${x_libraries}" != NONE; then
1738   if test -n "${x_libraries}"; then
1739     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1740     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1741   fi
1742   x_default_search_path=""
1743   x_search_path=${x_libraries}
1744   if test -z "${x_search_path}"; then
1745     x_search_path=/usr/lib
1746   fi
1747   for x_library in `echo ${x_search_path}: | \
1748                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1749     x_search_path="\
1750 ${x_library}/X11/%L/%T/%N%C%S:\
1751 ${x_library}/X11/%l/%T/%N%C%S:\
1752 ${x_library}/X11/%T/%N%C%S:\
1753 ${x_library}/X11/%L/%T/%N%S:\
1754 ${x_library}/X11/%l/%T/%N%S:\
1755 ${x_library}/X11/%T/%N%S"
1756     if test x"${x_default_search_path}" = x; then
1757       x_default_search_path=${x_search_path}
1758     else
1759       x_default_search_path="${x_search_path}:${x_default_search_path}"
1760     fi
1761   done
1762 fi
1763 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1764   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1765 fi
1766
1767 if test x"${x_includes}" = x; then
1768   bitmapdir=/usr/include/X11/bitmaps
1769 else
1770   # accumulate include directories that have X11 bitmap subdirectories
1771   bmd_acc="dummyval"
1772   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1773     if test -d "${bmd}/X11/bitmaps"; then
1774       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1775     fi
1776     if test -d "${bmd}/bitmaps"; then
1777       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1778     fi
1779   done
1780   if test ${bmd_acc} != "dummyval"; then
1781     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1782   fi
1783 fi
1784
1785 HAVE_CARBON=no
1786 if test "${with_carbon}" != no; then
1787   AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1788 fi
1789 if test "${window_system}" = x11 && test "${HAVE_CARBON}" = yes; then
1790   if test "${with_carbon+set}" != set \
1791      && test "${carbon_appdir_x+set}" != set; then
1792     for var in with_x with_x_toolkit with_gtk with_xim \
1793                with_xpm with_jpeg with_tiff with_gif with_png; do
1794       if eval test \"\${$var+set}\" = set; then
1795         HAVE_CARBON=no
1796         break
1797       fi
1798     done
1799   fi
1800 fi
1801 if test "${HAVE_CARBON}" = yes; then
1802   window_system=mac
1803 fi
1804
1805 case "${window_system}" in
1806   x11 )
1807     HAVE_X_WINDOWS=yes
1808     HAVE_X11=yes
1809     case "${with_x_toolkit}" in
1810       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1811       motif ) USE_X_TOOLKIT=MOTIF ;;
1812 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1813       gtk ) with_gtk=yes
1814 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1815 dnl USE_X_TOOLKIT is set.
1816             USE_X_TOOLKIT=none ;;
1817       no ) USE_X_TOOLKIT=none ;;
1818 dnl If user did not say whether to use a toolkit,
1819 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1820       * ) USE_X_TOOLKIT=maybe ;;
1821     esac
1822   ;;
1823   mac | none )
1824     HAVE_X_WINDOWS=no
1825     HAVE_X11=no
1826     USE_X_TOOLKIT=none
1827   ;;
1828 esac
1829
1830 ### If we're using X11, we should use the X menu package.
1831 HAVE_MENUS=no
1832 case ${HAVE_X11} in
1833   yes ) HAVE_MENUS=yes ;;
1834 esac
1835
1836 if test "${opsys}" = "hpux9"; then
1837   case "${x_libraries}" in
1838     *X11R4* )
1839       opsysfile="s/hpux9-x11r4.h"
1840       ;;
1841   esac
1842 fi
1843
1844 if test "${opsys}" = "hpux9shr"; then
1845   case "${x_libraries}" in
1846     *X11R4* )
1847       opsysfile="s/hpux9shxr4.h"
1848       ;;
1849   esac
1850 fi
1851
1852 ### Compute the unexec source name from the object name.
1853 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1854
1855 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1856 # Assume not, until told otherwise.
1857 GNU_MALLOC=yes
1858 doug_lea_malloc=yes
1859 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1860 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1861 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1862                emacs_cv_var___after_morecore_hook,
1863 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1864   emacs_cv_var___after_morecore_hook=yes,
1865   emacs_cv_var___after_morecore_hook=no)])
1866 if test $emacs_cv_var___after_morecore_hook = no; then
1867   doug_lea_malloc=no
1868 fi
1869 if test "${system_malloc}" = "yes"; then
1870   GNU_MALLOC=no
1871   GNU_MALLOC_reason="
1872     (The GNU allocators don't work with this system configuration.)"
1873 fi
1874 if test "$doug_lea_malloc" = "yes" ; then
1875   if test "$GNU_MALLOC" = yes ; then
1876     GNU_MALLOC_reason="
1877       (Using Doug Lea's new malloc from the GNU C Library.)"
1878   fi
1879   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1880             [Define to 1 if you are using the GNU C Library.])
1881 fi
1882
1883 if test x"${REL_ALLOC}" = x; then
1884   REL_ALLOC=${GNU_MALLOC}
1885 fi
1886
1887 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1888 dnl the system configuration file (s/*.h) to turn the use of mmap
1889 dnl in the relocating allocator on.
1890
1891 AC_FUNC_MMAP
1892 if test $use_mmap_for_buffers = yes; then
1893   REL_ALLOC=no
1894 fi
1895
1896 LIBS="$libsrc_libs $LIBS"
1897
1898 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1899 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1900 AC_CHECK_LIB(dnet, dnet_ntoa)
1901 dnl This causes -lresolv to get used in subsequent tests,
1902 dnl which causes failures on some systems such as HPUX 9.
1903 dnl AC_CHECK_LIB(resolv, gethostbyname)
1904
1905 dnl FIXME replace main with a function we actually want from this library.
1906 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1907
1908 AC_CHECK_LIB(pthreads, cma_open)
1909
1910 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1911 if test -d /usr/X386/include; then
1912   HAVE_XFREE386=yes
1913   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1914 else
1915   HAVE_XFREE386=no
1916 fi
1917 AC_MSG_RESULT($HAVE_XFREE386)
1918
1919 dnl Check for need for bigtoc support on IBM AIX
1920
1921 case ${host_os} in
1922 aix*)
1923   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1924     case $GCC in
1925     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1926     *) gdb_cv_bigtoc=-bbigtoc ;;
1927     esac
1928
1929     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1930     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1931   ])
1932   ;;
1933 esac
1934
1935 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1936 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1937 # REAL_CPPFLAGS later on.
1938
1939 REAL_CPPFLAGS="$CPPFLAGS"
1940
1941 if test "${HAVE_X11}" = "yes"; then
1942   DEFS="$C_SWITCH_X_SITE $DEFS"
1943   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1944   LIBS="$LIBX $LIBS"
1945   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1946   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1947
1948   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1949   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1950   # but it's more convenient here to set LD_RUN_PATH
1951   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1952   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1953     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1954     export LD_RUN_PATH
1955   fi
1956
1957   if test "${opsys}" = "gnu-linux"; then
1958     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1959     AC_TRY_LINK([],
1960      [XOpenDisplay ("foo");],
1961      [xlinux_first_failure=no],
1962      [xlinux_first_failure=yes])
1963     if test "${xlinux_first_failure}" = "yes"; then
1964       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1965       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1966       OLD_CPPFLAGS="$CPPFLAGS"
1967       OLD_LIBS="$LIBS"
1968       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1969       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1970       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1971       LIBS="$LIBS -b i486-linuxaout"
1972       AC_TRY_LINK([],
1973        [XOpenDisplay ("foo");],
1974        [xlinux_second_failure=no],
1975        [xlinux_second_failure=yes])
1976       if test "${xlinux_second_failure}" = "yes"; then
1977         # If we get the same failure with -b, there is no use adding -b.
1978         # So take it out.  This plays safe.
1979         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1980         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1981         CPPFLAGS="$OLD_CPPFLAGS"
1982         LIBS="$OLD_LIBS"
1983         AC_MSG_RESULT(no)
1984       else
1985         AC_MSG_RESULT(yes)
1986       fi
1987     else
1988       AC_MSG_RESULT(no)
1989     fi
1990   fi
1991
1992   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1993   # header files included from there.
1994   AC_MSG_CHECKING(for Xkb)
1995   AC_TRY_LINK([#include <X11/Xlib.h>
1996 #include <X11/XKBlib.h>],
1997         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1998         emacs_xkb=yes, emacs_xkb=no)
1999   AC_MSG_RESULT($emacs_xkb)
2000   if test $emacs_xkb = yes; then
2001     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
2002   fi
2003
2004   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2005 XScreenNumberOfScreen XSetWMProtocols)
2006 fi
2007
2008 if test "${window_system}" = "x11"; then
2009   AC_MSG_CHECKING(X11 version 6)
2010   AC_CACHE_VAL(emacs_cv_x11_version_6,
2011   [AC_TRY_LINK([#include <X11/Xlib.h>],
2012 [#if XlibSpecificationRelease < 6
2013 fail;
2014 #endif
2015 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2016   if test $emacs_cv_x11_version_6 = yes; then
2017     AC_MSG_RESULT(6 or newer)
2018     AC_DEFINE(HAVE_X11R6, 1,
2019               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2020   else
2021     AC_MSG_RESULT(before 6)
2022   fi
2023 fi
2024
2025 if test "${window_system}" = "x11"; then
2026   AC_MSG_CHECKING(X11 version 5)
2027   AC_CACHE_VAL(emacs_cv_x11_version_5,
2028   [AC_TRY_LINK([#include <X11/Xlib.h>],
2029 [#if XlibSpecificationRelease < 5
2030 fail;
2031 #endif
2032 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
2033   if test $emacs_cv_x11_version_5 = yes; then
2034     AC_MSG_RESULT(5 or newer)
2035     HAVE_X11R5=yes
2036     AC_DEFINE(HAVE_X11R5, 1,
2037               [Define to 1 if you have the X11R5 or newer version of Xlib.])
2038   else
2039     HAVE_X11R5=no
2040     AC_MSG_RESULT(before 5)
2041   fi
2042 fi
2043
2044 HAVE_GTK=no
2045 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk"; then
2046   if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
2047     AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
2048   fi
2049   GLIB_REQUIRED=2.4
2050   GTK_REQUIRED=2.4
2051   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2052
2053   dnl Check if --with-pkg-config-prog has been given.
2054   if test "X${with_pkg_config_prog}" != X; then
2055     PKG_CONFIG="${with_pkg_config_prog}"
2056   fi
2057   dnl Checks for libraries.
2058   PKG_CHECK_MODULES(GTK, $GTK_MODULES)
2059   AC_SUBST(GTK_CFLAGS)
2060   AC_SUBST(GTK_LIBS)
2061   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2062   CFLAGS="$CFLAGS $GTK_CFLAGS"
2063   LIBS="$GTK_LIBS $LIBS"
2064   HAVE_GTK=yes
2065   AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
2066   USE_X_TOOLKIT=none
2067
2068   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2069   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2070   if test "$with_toolkit_scroll_bars" != no; then
2071     with_toolkit_scroll_bars=yes
2072   fi
2073
2074   dnl  Check if we can use multiple displays with this GTK version.
2075   dnl  If gdk_display_open exists, assume all others are there also.
2076   HAVE_GTK_MULTIDISPLAY=no
2077   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
2078   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
2079     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
2080               [Define to 1 if GTK can handle more than one display.])
2081   fi
2082   dnl  Check if we have the old file selection dialog.
2083   dnl  If gdk_display_open exists, assume all others are there also.
2084   HAVE_GTK_FILE_SELECTION=no
2085   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
2086
2087   dnl  Check if we have the new file chooser dialog
2088   dnl  If gdk_display_open exists, assume all others are there also.
2089   HAVE_GTK_FILE_CHOOSER=no
2090   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
2091
2092   if test "$HAVE_GTK_FILE_SELECTION" = yes \
2093      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
2094     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
2095               [Define to 1 if GTK has both file selection and chooser dialog.])
2096   fi
2097
2098   dnl Check if pthreads are available.  Emacs only needs this when using
2099   dnl gtk_file_chooser under Gnome.
2100   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
2101     HAVE_GTK_AND_PTHREAD=no
2102     AC_CHECK_HEADERS(pthread.h)
2103     if test "$ac_cv_header_pthread_h"; then
2104       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
2105     fi
2106     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
2107       GTK_LIBS="$GTK_LIBS -lpthread"
2108       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
2109                [Define to 1 if you have GTK and pthread (-lpthread).])
2110     fi
2111   fi
2112 fi
2113
2114 dnl Do not put whitespace before the #include statements below.
2115 dnl Older compilers (eg sunos4 cc) choke on it.
2116 if test x"${USE_X_TOOLKIT}" = xmaybe; then
2117   if test x"${HAVE_X11R5}" = xyes; then
2118     AC_MSG_CHECKING(X11 version 5 with Xaw)
2119     AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
2120     [AC_TRY_LINK([
2121 #include <X11/Intrinsic.h>
2122 #include <X11/Xaw/Simple.h>],
2123       [],
2124       emacs_cv_x11_version_5_with_xaw=yes,
2125       emacs_cv_x11_version_5_with_xaw=no)])
2126     if test $emacs_cv_x11_version_5_with_xaw = yes; then
2127       AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
2128       USE_X_TOOLKIT=LUCID
2129     else
2130       AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
2131       USE_X_TOOLKIT=none
2132     fi
2133   else
2134     USE_X_TOOLKIT=none
2135   fi
2136 fi
2137
2138 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2139
2140 if test "${USE_X_TOOLKIT}" != "none"; then
2141   AC_MSG_CHECKING(X11 toolkit version)
2142   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2143   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2144 [#if XtSpecificationRelease < 6
2145 fail;
2146 #endif
2147 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2148   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2149   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2150     AC_MSG_RESULT(6 or newer)
2151     AC_DEFINE(HAVE_X11XTR6, 1,
2152               [Define to 1 if you have the X11R6 or newer version of Xt.])
2153   else
2154     AC_MSG_RESULT(before 6)
2155   fi
2156
2157 dnl If using toolkit, check whether libXmu.a exists.
2158 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2159   OLDLIBS="$LIBS"
2160   if test x$HAVE_X11XTR6 = xyes; then
2161     LIBS="-lXt -lSM -lICE $LIBS"
2162   else
2163     LIBS="-lXt $LIBS"
2164   fi
2165   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2166   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2167 fi
2168
2169 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2170 if test "${HAVE_X11}" = "yes"; then
2171   if test "${USE_X_TOOLKIT}" != "none"; then
2172     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2173   fi
2174 fi
2175
2176 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2177   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2178   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2179     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2180 int x = 5;
2181 #else
2182 Motif version prior to 2.1.
2183 #endif],
2184     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2185   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
2186   if test $emacs_cv_motif_version_2_1 = yes; then
2187     HAVE_LIBXP=no
2188     AC_DEFINE(HAVE_MOTIF_2_1, 1,
2189               [Define to 1 if you have Motif 2.1 or newer.])
2190     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
2191     if test ${HAVE_LIBXP} = yes; then
2192       AC_DEFINE(HAVE_LIBXP, 1,
2193                 [Define to 1 if you have the Xp library (-lXp).])
2194     fi
2195   else
2196     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2197     # We put this in CFLAGS temporarily to precede other -I options
2198     # that might be in CFLAGS temporarily.
2199     # We put this in CPPFLAGS where it precedes the other -I options.
2200     OLD_CPPFLAGS=$CPPFLAGS
2201     OLD_CFLAGS=$CFLAGS
2202     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2203     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2204     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2205       [int x = 5;],
2206       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2207     if test $emacs_cv_lesstif = yes; then
2208       # Make sure this -I option remains in CPPFLAGS after it is set
2209       # back to REAL_CPPFLAGS.
2210       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2211       # have those other -I options anyway.  Ultimately, having this
2212       # directory ultimately in CPPFLAGS will be enough.
2213       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2214       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2215     else
2216       CFLAGS=$OLD_CFLAGS
2217       CPPFLAGS=$OLD_CPPFLAGS
2218     fi
2219   fi
2220 fi
2221
2222 ### Is -lXaw3d available?
2223 HAVE_XAW3D=no
2224 if test "${HAVE_X11}" = "yes"; then
2225   if test "${USE_X_TOOLKIT}" != "none" && test "${with_toolkit_scroll_bars}" != "no"; then
2226     dnl Fixme: determine what Scrollbar.h needs to avoid compilation
2227     dnl errors from the test without the `-'.
2228     AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
2229         [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes)], , -)
2230     if test "${HAVE_XAW3D}" = "yes"; then
2231         AC_DEFINE(HAVE_XAW3D, 1,
2232                   [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2233     fi
2234   fi
2235 fi
2236
2237 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2238 dnl using Motif or Xaw3d is available, and unless
2239 dnl --with-toolkit-scroll-bars=no was specified.
2240
2241 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2242             [Define to 1 if we should use toolkit scroll bars.])dnl
2243 USE_TOOLKIT_SCROLL_BARS=no
2244 if test "${with_toolkit_scroll_bars}" != "no"; then
2245   if test "${USE_X_TOOLKIT}" != "none"; then
2246     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2247       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2248       HAVE_XAW3D=no
2249       USE_TOOLKIT_SCROLL_BARS=yes
2250     elif test "${HAVE_XAW3D}" = "yes"; then
2251       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2252       USE_TOOLKIT_SCROLL_BARS=yes
2253     fi
2254   elif test "${HAVE_GTK}" = "yes"; then
2255     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2256     USE_TOOLKIT_SCROLL_BARS=yes
2257   elif test "${HAVE_CARBON}" = "yes"; then
2258     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2259     USE_TOOLKIT_SCROLL_BARS=yes
2260   fi
2261 fi
2262
2263 dnl See if XIM is available.
2264 AC_TRY_COMPILE([
2265           #include <X11/Xlib.h>
2266           #include <X11/Xresource.h>],
2267          [XIMProc  callback;],
2268          HAVE_XIM=yes
2269          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available]),
2270          HAVE_XIM=no)
2271
2272 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2273
2274 if test "${with_xim}" != "no"; then
2275   AC_DEFINE(USE_XIM, 1,
2276             [Define to 1 if we should use XIM, if it is available.])
2277 fi
2278
2279
2280 if test "${HAVE_XIM}" != "no"; then
2281   late_CFLAGS=$CFLAGS
2282   if test "$GCC" = yes; then
2283     CFLAGS="$CFLAGS --pedantic-errors"
2284   fi
2285   AC_TRY_COMPILE([
2286 #include <X11/Xlib.h>
2287 #include <X11/Xresource.h>],
2288 [Display *display;
2289 XrmDatabase db;
2290 char *res_name;
2291 char *res_class;
2292 XIMProc  callback;
2293 XPointer *client_data;
2294 #ifndef __GNUC__
2295 /* If we're not using GCC, it's probably not XFree86, and this is
2296    probably right, but we can't use something like --pedantic-errors.  */
2297 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2298                                            char*, XIMProc, XPointer*);
2299 #endif
2300 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2301    client_data);],
2302     [emacs_cv_arg6_star=yes])
2303   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2304          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2305 either XPointer or XPointer*.])dnl
2306   if test "$emacs_cv_arg6_star" = yes; then
2307     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2308   else
2309     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2310   fi
2311   CFLAGS=$late_CFLAGS
2312 fi
2313
2314 ### Use -lXpm if available, unless `--with-xpm=no'.
2315 HAVE_XPM=no
2316 if test "${HAVE_X11}" = "yes"; then
2317   if test "${with_xpm}" != "no"; then
2318     AC_CHECK_HEADER(X11/xpm.h,
2319       AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
2320     if test "${HAVE_XPM}" = "yes"; then
2321       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2322       AC_EGREP_CPP(no_return_alloc_pixels,
2323       [#include "X11/xpm.h"
2324 #ifndef XpmReturnAllocPixels
2325 no_return_alloc_pixels
2326 #endif
2327       ], HAVE_XPM=no, HAVE_XPM=yes)
2328
2329       if test "${HAVE_XPM}" = "yes"; then
2330         AC_MSG_RESULT(yes)
2331       else
2332         AC_MSG_RESULT(no)
2333       fi
2334     fi
2335   fi
2336
2337   if test "${HAVE_XPM}" = "yes"; then
2338     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2339   fi
2340 fi
2341
2342 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2343 HAVE_JPEG=no
2344 if test "${HAVE_X11}" = "yes"; then
2345   if test "${with_jpeg}" != "no"; then
2346     dnl Checking for jpeglib.h can lose because of a redefinition of
2347     dnl  HAVE_STDLIB_H.
2348     AC_CHECK_HEADER(jerror.h,
2349       AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
2350   fi
2351
2352   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2353   if test "${HAVE_JPEG}" = "yes"; then
2354     AC_DEFINE(HAVE_JPEG)
2355     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2356         [#include <jpeglib.h>
2357          version=JPEG_LIB_VERSION
2358 ],
2359         AC_DEFINE(HAVE_JPEG),
2360         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2361         HAVE_JPEG=no])
2362   fi
2363 fi
2364
2365 ### Use -lpng if available, unless `--with-png=no'.
2366 HAVE_PNG=no
2367 if test "${HAVE_X11}" = "yes"; then
2368   if test "${with_png}" != "no"; then
2369     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2370     # in /usr/include/libpng.
2371     AC_CHECK_HEADERS(png.h libpng/png.h)
2372     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2373       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2374     fi
2375   fi
2376
2377   if test "${HAVE_PNG}" = "yes"; then
2378     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2379   fi
2380 fi
2381
2382 ### Use -ltiff if available, unless `--with-tiff=no'.
2383 HAVE_TIFF=no
2384 if test "${HAVE_X11}" = "yes"; then
2385   if test "${with_tiff}" != "no"; then
2386     AC_CHECK_HEADER(tiffio.h,
2387       tifflibs="-lz -lm"
2388       # At least one tiff package requires the jpeg library.
2389       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2390       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
2391   fi
2392
2393   if test "${HAVE_TIFF}" = "yes"; then
2394     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2395   fi
2396 fi
2397
2398 ### Use -lgif if available, unless `--with-gif=no'.
2399 HAVE_GIF=no
2400 if test "${HAVE_X11}" = "yes"; then
2401   if test "${with_gif}" != "no"; then
2402     AC_CHECK_HEADER(gif_lib.h,
2403 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2404 # Earlier versions can crash Emacs.
2405       AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
2406   fi
2407
2408   if test "${HAVE_GIF}" = "yes"; then
2409     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
2410   fi
2411 fi
2412
2413 dnl Check for malloc/malloc.h on darwin
2414 AC_CHECK_HEADER(malloc/malloc.h, AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.]))
2415
2416 ### Use Mac OS X Carbon API to implement GUI.
2417 if test "${HAVE_CARBON}" = "yes"; then
2418   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2419   ## Specify the install directory
2420   carbon_appdir=
2421   if test "${carbon_appdir_x}" != ""; then
2422     case ${carbon_appdir_x} in
2423       y | ye | yes)  carbon_appdir=/Applications ;;
2424       * ) carbon_appdir=${carbon_appdir_x} ;;
2425     esac
2426   fi
2427   # We also have mouse menus.
2428   HAVE_MENUS=yes
2429 fi
2430
2431 ### Use session management (-lSM -lICE) if available
2432 HAVE_X_SM=no
2433 if test "${HAVE_X11}" = "yes"; then
2434   AC_CHECK_HEADER(X11/SM/SMlib.h,
2435     AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE))
2436
2437   if test "${HAVE_X_SM}" = "yes"; then
2438     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2439     case "$LIBS" in
2440       *-lSM*) ;;
2441       *)      LIBS="-lSM -lICE $LIBS" ;;
2442     esac
2443   fi
2444 fi
2445
2446 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2447 AC_CACHE_CHECK(whether netdb declares h_errno,
2448                emacs_cv_netdb_declares_h_errno,
2449 [AC_TRY_LINK([#include <netdb.h>],
2450   [return h_errno;],
2451   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2452 if test $emacs_cv_netdb_declares_h_errno = yes; then
2453   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2454 fi
2455
2456 AC_FUNC_ALLOCA
2457
2458 # fmod, logb, and frexp are found in -lm on most systems.
2459 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2460 AC_CHECK_LIB(m, sqrt)
2461
2462 # Check for mail-locking functions in a "mail" library.  Probably this should
2463 # have the same check as for liblockfile below.
2464 AC_CHECK_LIB(mail, maillock)
2465 dnl Debian, at least:
2466 AC_CHECK_LIB(lockfile, maillock)
2467 # If we have the shared liblockfile, assume we must use it for mail
2468 # locking (e.g. Debian).  If we couldn't link against liblockfile
2469 # (no liblockfile.a installed), ensure that we don't need to.
2470 if test "$ac_cv_lib_lockfile_maillock" = no; then
2471   dnl This works for files generally, not just executables.
2472   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2473   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2474                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2475   if test $ac_cv_prog_liblockfile = yes; then
2476     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2477 This probably means that movemail could lose mail.
2478 There may be a `development' package to install containing liblockfile.])
2479   else :
2480   fi
2481 fi
2482 AC_CHECK_FUNCS(touchlock)
2483 AC_CHECK_HEADERS(maillock.h)
2484
2485 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2486 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2487 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2488 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2489 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2490 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2491 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2492 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2493 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2494
2495 AC_CHECK_HEADERS(sys/un.h)
2496
2497 AC_FUNC_MKTIME
2498 if test "$ac_cv_func_working_mktime" = no; then
2499   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2500 fi
2501
2502 AC_FUNC_GETLOADAVG
2503
2504 AC_FUNC_FSEEKO
2505
2506 # Configure getopt.
2507 m4_include([m4/getopt.m4])
2508 gl_GETOPT_IFELSE([
2509   gl_GETOPT_SUBSTITUTE_HEADER
2510   gl_PREREQ_GETOPT
2511   GETOPTOBJS='getopt.o getopt1.o'
2512 ])
2513 AC_SUBST(GETOPTOBJS)
2514
2515 AC_FUNC_GETPGRP
2516
2517 AC_FUNC_STRFTIME
2518
2519 # UNIX98 PTYs.
2520 AC_CHECK_FUNCS(grantpt)
2521
2522 # PTY-related GNU extensions.
2523 AC_CHECK_FUNCS(getpt)
2524
2525 # Check this now, so that we will NOT find the above functions in ncurses.
2526 # That is because we have not set up to link ncurses in lib-src.
2527 # It's better to believe a function is not available
2528 # than to expect to find it in ncurses.
2529 AC_CHECK_LIB(ncurses, tparm)
2530
2531 # Do we need the Hesiod library to provide the support routines?
2532 if test "$with_hesiod" = yes ; then
2533   # Don't set $LIBS here -- see comments above.
2534   resolv=no
2535   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2536      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2537                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2538   if test "$resolv" = yes ; then
2539     RESOLVLIB=-lresolv
2540     AC_DEFINE(HAVE_LIBRESOLV, 1,
2541               [Define to 1 if you have the resolv library (-lresolv).])
2542   else
2543     RESOLVLIB=
2544   fi
2545   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2546         AC_DEFINE(HAVE_LIBHESIOD, 1,
2547                   [Define to 1 if you have the hesiod library (-lhesiod).]),
2548         :, $RESOLVLIB)])
2549 fi
2550
2551 # These tell us which Kerberos-related libraries to use.
2552 if test "${with_kerberos+set}" = set; then
2553   AC_CHECK_LIB(com_err, com_err)
2554   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2555   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2556   AC_CHECK_LIB(krb5, krb5_init_context)
2557   if test "${with_kerberos5+set}" != set; then
2558     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2559                  AC_CHECK_LIB(des, des_cbc_encrypt))
2560     AC_CHECK_LIB(krb4, krb_get_cred,,
2561                  AC_CHECK_LIB(krb, krb_get_cred))
2562   fi
2563
2564   if test "${with_kerberos5+set}" = set; then
2565     AC_CHECK_HEADERS(krb5.h)
2566   else
2567     AC_CHECK_HEADERS(des.h,,
2568                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2569                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2570     AC_CHECK_HEADERS(krb.h,,
2571                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2572                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2573   fi
2574   AC_CHECK_HEADERS(com_err.h)
2575 fi
2576
2577 # Solaris requires -lintl if you want strerror (which calls dgettext)
2578 # to return localized messages.
2579 AC_CHECK_LIB(intl, dgettext)
2580
2581 AC_MSG_CHECKING(whether localtime caches TZ)
2582 AC_CACHE_VAL(emacs_cv_localtime_cache,
2583 [if test x$ac_cv_func_tzset = xyes; then
2584 AC_TRY_RUN([#include <time.h>
2585 extern char **environ;
2586 unset_TZ ()
2587 {
2588   char **from, **to;
2589   for (to = from = environ; (*to = *from); from++)
2590     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2591       to++;
2592 }
2593 char TZ_GMT0[] = "TZ=GMT0";
2594 char TZ_PST8[] = "TZ=PST8";
2595 main()
2596 {
2597   time_t now = time ((time_t *) 0);
2598   int hour_GMT0, hour_unset;
2599   if (putenv (TZ_GMT0) != 0)
2600     exit (1);
2601   hour_GMT0 = localtime (&now)->tm_hour;
2602   unset_TZ ();
2603   hour_unset = localtime (&now)->tm_hour;
2604   if (putenv (TZ_PST8) != 0)
2605     exit (1);
2606   if (localtime (&now)->tm_hour == hour_GMT0)
2607     exit (1);
2608   unset_TZ ();
2609   if (localtime (&now)->tm_hour != hour_unset)
2610     exit (1);
2611   exit (0);
2612 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2613 [# If we have tzset, assume the worst when cross-compiling.
2614 emacs_cv_localtime_cache=yes])
2615 else
2616         # If we lack tzset, report that localtime does not cache TZ,
2617         # since we can't invalidate the cache if we don't have tzset.
2618         emacs_cv_localtime_cache=no
2619 fi])dnl
2620 AC_MSG_RESULT($emacs_cv_localtime_cache)
2621 if test $emacs_cv_localtime_cache = yes; then
2622   AC_DEFINE(LOCALTIME_CACHE, 1,
2623             [Define to 1 if localtime caches TZ.])
2624 fi
2625
2626 if test "x$HAVE_TIMEVAL" = xyes; then
2627   AC_CHECK_FUNCS(gettimeofday)
2628   if test $ac_cv_func_gettimeofday = yes; then
2629     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2630                    emacs_cv_gettimeofday_two_arguments,
2631     [AC_TRY_COMPILE([
2632 #ifdef TIME_WITH_SYS_TIME
2633 #include <sys/time.h>
2634 #include <time.h>
2635 #else
2636 #ifdef HAVE_SYS_TIME_H
2637 #include <sys/time.h>
2638 #else
2639 #include <time.h>
2640 #endif
2641 #endif],
2642       [struct timeval time;
2643        gettimeofday (&time, 0);],
2644       emacs_cv_gettimeofday_two_arguments=yes,
2645       emacs_cv_gettimeofday_two_arguments=no)])
2646     if test $emacs_cv_gettimeofday_two_arguments = no; then
2647       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2648                 [Define to 1 if gettimeofday accepts only one argument.])
2649     fi
2650   fi
2651 fi
2652
2653 # This defines (or not) HAVE_TZNAME and HAVE_TM_ZONE.
2654 AC_STRUCT_TIMEZONE
2655
2656 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2657 if test "$ac_cv_func_gettimeofday" = yes; then
2658   AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2659     [AC_TRY_COMPILE([#include <sys/time.h>],
2660     [struct timezone tz;],
2661     dnl It may be that we can't call gettimeofday with a non-null pointer,
2662     dnl even though we have struct timezone (e.g. HPUX).  In that case
2663     dnl we'll lie about struct timezone.
2664     [AC_TRY_RUN([
2665 #ifdef TIME_WITH_SYS_TIME
2666 #include <sys/time.h>
2667 #include <time.h>
2668 #else
2669 #ifdef HAVE_SYS_TIME_H
2670 #include <sys/time.h>
2671 #else
2672 #include <time.h>
2673 #endif
2674 #endif
2675 main () {
2676   struct timeval time;
2677   struct timezone dummy;
2678   exit (gettimeofday (&time, &dummy));
2679 }],
2680       emacs_cv_struct_timezone=yes,
2681       emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2682     emacs_cv_struct_timezone=no)])
2683 fi
2684
2685 ok_so_far=yes
2686 AC_CHECK_FUNC(socket, , ok_so_far=no)
2687 if test $ok_so_far = yes; then
2688   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2689 fi
2690 if test $ok_so_far = yes; then
2691   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2692 fi
2693 if test $ok_so_far = yes; then
2694 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2695   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2696             [Define to 1 if you have inet sockets.])
2697 fi
2698
2699 AC_CHECK_HEADERS(sys/ioctl.h)
2700
2701 if test -f /usr/lpp/X11/bin/smt.exp; then
2702   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2703             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2704 fi
2705
2706 AC_MSG_CHECKING(whether system supports dynamic ptys)
2707 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2708   AC_MSG_RESULT(yes)
2709   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2710 else
2711   AC_MSG_RESULT(no)
2712 fi
2713
2714 AC_FUNC_FORK
2715
2716 dnl Adapted from Haible's version.
2717 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2718   [AC_TRY_LINK([#include <langinfo.h>],
2719     [char* cs = nl_langinfo(CODESET);],
2720     emacs_cv_langinfo_codeset=yes,
2721     emacs_cv_langinfo_codeset=no)
2722   ])
2723 if test $emacs_cv_langinfo_codeset = yes; then
2724   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2725     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2726 fi
2727
2728 AC_CHECK_TYPES(size_t)
2729
2730 AC_TYPE_MBSTATE_T
2731
2732 dnl Restrict could probably be used effectively other than in regex.c.
2733 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2734   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2735                   emacs_cv_c_restrict=yes,
2736                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2737                                   emacs_cv_c_restrict=__restrict,
2738                                   emacs_cv_c_restrict=no)])])
2739 case "$emacs_cv_c_restrict" in
2740   yes) emacs_restrict=restrict;;
2741   no) emacs_restrict="";;
2742   *) emacs_restrict="$emacs_cv_c_restrict";;
2743 esac
2744 if test "$emacs_restrict" != __restrict; then
2745   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2746     [Define to compiler's equivalent of C99 restrict keyword.
2747      Don't define if equivalent is `__restrict'.])
2748 fi
2749
2750 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2751   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2752                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2753 if test "$emacs_cv_c_restrict_arr" = yes; then
2754   AC_DEFINE(__restrict_arr, __restrict,
2755     [Define to compiler's equivalent of C99 restrict keyword in array
2756      declarations.  Define as empty for no equivalent.])
2757 fi
2758
2759 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2760 dnl how the tty code is related to POSIX and/or other versions of termios.
2761 dnl The following looks like a useful start.
2762 dnl
2763 dnl AC_SYS_POSIX_TERMIOS
2764 dnl if test $ac_cv_sys_posix_termios = yes; then
2765 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2766 dnl                                and macros for terminal control.])
2767 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2768 dnl fi
2769
2770 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2771
2772 # Set up the CFLAGS for real compilation, so we can substitute it.
2773 CFLAGS="$REAL_CFLAGS"
2774 CPPFLAGS="$REAL_CPPFLAGS"
2775
2776 #### Find out which version of Emacs this is.
2777 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2778          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2779 if test x"${version}" = x; then
2780   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2781 fi
2782
2783 ### Specify what sort of things we'll be editing into Makefile and config.h.
2784 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2785 AC_SUBST(version)
2786 AC_SUBST(configuration)
2787 AC_SUBST(canonical)
2788 AC_SUBST(srcdir)
2789 AC_SUBST(prefix)
2790 AC_SUBST(exec_prefix)
2791 AC_SUBST(bindir)
2792 AC_SUBST(datadir)
2793 AC_SUBST(sharedstatedir)
2794 AC_SUBST(libexecdir)
2795 AC_SUBST(mandir)
2796 AC_SUBST(infodir)
2797 AC_SUBST(lispdir)
2798 AC_SUBST(locallisppath)
2799 AC_SUBST(lisppath)
2800 AC_SUBST(x_default_search_path)
2801 AC_SUBST(etcdir)
2802 AC_SUBST(archlibdir)
2803 AC_SUBST(docdir)
2804 AC_SUBST(bitmapdir)
2805 AC_SUBST(gamedir)
2806 AC_SUBST(gameuser)
2807 AC_SUBST(c_switch_system)
2808 AC_SUBST(c_switch_machine)
2809 AC_SUBST(LD_SWITCH_X_SITE)
2810 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2811 AC_SUBST(C_SWITCH_X_SITE)
2812 AC_SUBST(CFLAGS)
2813 AC_SUBST(X_TOOLKIT_TYPE)
2814 AC_SUBST(machfile)
2815 AC_SUBST(opsysfile)
2816 AC_SUBST(GETLOADAVG_LIBS)
2817 AC_SUBST(carbon_appdir)
2818
2819 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2820                    [Define to the canonical Emacs configuration name.])
2821 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2822                    [Define to the options passed to configure.])
2823 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2824                    [Define to the used machine dependent file.])
2825 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2826                    [Define to the used os dependent file.])
2827 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2828 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2829  may need to deal with X Windows.  For instance, if you've defined
2830  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2831  your loader can find on its own, you might want to add "-L/..." or
2832  something similar.])
2833 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2834                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2835                     in case it's needed (for Solaris, for example).])
2836 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2837 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2838  may need to deal with X Windows.  For instance, if you've defined
2839  HAVE_X_WINDOWS above and your X include files aren't in a place
2840  that your compiler can find on its own, you might want to add
2841  "-I/..." or something similar.])
2842 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2843                    [Define to the unexec source file name.])
2844
2845 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2846   AC_DEFINE(HAVE_X_WINDOWS, 1,
2847             [Define to 1 if you want to use the X window system.])
2848 fi
2849 if test "${USE_X_TOOLKIT}" != "none" ; then
2850   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2851 fi
2852 if test "${HAVE_X11}" = "yes" ; then
2853   AC_DEFINE(HAVE_X11, 1,
2854             [Define to 1 if you want to use version 11 of X windows.
2855              Otherwise, Emacs expects to use version 10.])
2856 fi
2857 if test "${HAVE_XFREE386}" = "yes" ; then
2858   AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2859 fi
2860 if test "${HAVE_MENUS}" = "yes" ; then
2861   AC_DEFINE(HAVE_MENUS, 1,
2862             [Define to 1 if you have mouse menus.
2863              (This is automatic if you use X, but the option to specify it remains.)
2864              It is also defined with other window systems that support xmenu.c.])
2865 fi
2866 if test "${GNU_MALLOC}" = "yes" ; then
2867   AC_DEFINE(GNU_MALLOC, 1,
2868             [Define to 1 if you want to use the GNU memory allocator.])
2869 fi
2870 if test "${REL_ALLOC}" = "yes" ; then
2871   AC_DEFINE(REL_ALLOC, 1,
2872             [Define REL_ALLOC if you want to use the relocating allocator for
2873              buffer space.])
2874 fi
2875
2876 AH_TOP([/* GNU Emacs site configuration template file.
2877    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005, 2006
2878              Free Software Foundation, Inc.
2879
2880 This file is part of GNU Emacs.
2881
2882 GNU Emacs is free software; you can redistribute it and/or modify
2883 it under the terms of the GNU General Public License as published by
2884 the Free Software Foundation; either version 2, or (at your option)
2885 any later version.
2886
2887 GNU Emacs is distributed in the hope that it will be useful,
2888 but WITHOUT ANY WARRANTY; without even the implied warranty of
2889 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2890 GNU General Public License for more details.
2891
2892 You should have received a copy of the GNU General Public License
2893 along with GNU Emacs; see the file COPYING.  If not, write to the
2894 Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
2895 Boston, MA 02110-1301, USA.  */
2896
2897
2898 /* No code in Emacs #includes config.h twice, but some bits of code
2899    intended to work with other packages as well (like gmalloc.c)
2900    think they can include it as many times as they like.  */
2901 #ifndef EMACS_CONFIG_H
2902 #define EMACS_CONFIG_H
2903 ])dnl
2904
2905 AH_BOTTOM([
2906 /* If we're using any sort of window system, define some consequences.  */
2907 #ifdef HAVE_X_WINDOWS
2908 #define HAVE_WINDOW_SYSTEM
2909 #define MULTI_KBOARD
2910 #define HAVE_MOUSE
2911 #endif
2912
2913 /* If we're using the Carbon API on Mac OS X, define a few more
2914    variables as well.  */
2915 #ifdef HAVE_CARBON
2916 #define HAVE_WINDOW_SYSTEM
2917 #define HAVE_MOUSE
2918 #endif
2919
2920 /* Define USER_FULL_NAME to return a string
2921    that is the user's full name.
2922    It can assume that the variable `pw'
2923    points to the password file entry for this user.
2924
2925    At some sites, the pw_gecos field contains
2926    the user's full name.  If neither this nor any other
2927    field contains the right thing, use pw_name,
2928    giving the user's login name, since that is better than nothing.  */
2929 #define USER_FULL_NAME pw->pw_gecos
2930
2931 /* Define AMPERSAND_FULL_NAME if you use the convention
2932    that & in the full name stands for the login id.  */
2933 /* Turned on June 1996 supposing nobody will mind it.  */
2934 #define AMPERSAND_FULL_NAME
2935
2936 /* We have blockinput.h.  */
2937 #define DO_BLOCK_INPUT
2938
2939 /* Define HAVE_SOUND if we have sound support.  We know it works
2940    and compiles only on the specified platforms.   For others,
2941    it probably doesn't make sense to try.  */
2942
2943 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2944 #ifdef HAVE_MACHINE_SOUNDCARD_H
2945 #define HAVE_SOUND 1
2946 #endif
2947 #ifdef HAVE_SYS_SOUNDCARD_H
2948 #define HAVE_SOUND 1
2949 #endif
2950 #ifdef HAVE_SOUNDCARD_H
2951 #define HAVE_SOUND 1
2952 #endif
2953 #ifdef HAVE_ALSA
2954 #define HAVE_SOUND 1
2955 #endif
2956 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2957
2958 /* If using GNU, then support inline function declarations. */
2959 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2960    generally, because even if non-gcc compilers accept `inline', they
2961    may reject `extern inline'.  */
2962 #if defined (__GNUC__) && defined (OPTIMIZE)
2963 #define INLINE __inline__
2964 #else
2965 #define INLINE
2966 #endif
2967
2968 /* Include the os and machine dependent files.  */
2969 #include config_opsysfile
2970 #include config_machfile
2971
2972 /* Load in the conversion definitions if this system
2973    needs them and the source file being compiled has not
2974    said to inhibit this.  There should be no need for you
2975    to alter these lines.  */
2976
2977 #ifdef SHORTNAMES
2978 #ifndef NO_SHORTNAMES
2979 #include "../shortnames/remap.h"
2980 #endif /* not NO_SHORTNAMES */
2981 #endif /* SHORTNAMES */
2982
2983 /* If no remapping takes place, static variables cannot be dumped as
2984    pure, so don't worry about the `static' keyword. */
2985 #ifdef NO_REMAP
2986 #undef static
2987 #endif
2988
2989 /* Define `subprocesses' should be defined if you want to
2990    have code for asynchronous subprocesses
2991    (as used in M-x compile and M-x shell).
2992    These do not work for some USG systems yet;
2993    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2994
2995 #ifndef VMS
2996 #ifndef USG
2997 /* #define subprocesses */
2998 #endif
2999 #endif
3000
3001 /* SIGTYPE is the macro we actually use.  */
3002 #ifndef SIGTYPE
3003 #define SIGTYPE RETSIGTYPE
3004 #endif
3005
3006 #ifdef emacs /* Don't do this for lib-src.  */
3007 /* Tell regex.c to use a type compatible with Emacs.  */
3008 #define RE_TRANSLATE_TYPE Lisp_Object
3009 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3010 #ifdef make_number
3011 /* If make_number is a macro, use it.  */
3012 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3013 #else
3014 /* If make_number is a function, avoid it.  */
3015 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3016 #endif
3017 #endif
3018
3019 /* Avoid link-time collision with system mktime if we will use our own.  */
3020 #if ! HAVE_MKTIME || BROKEN_MKTIME
3021 #define mktime emacs_mktime
3022 #endif
3023
3024 #define my_strftime nstrftime   /* for strftime.c */
3025
3026 /* The rest of the code currently tests the CPP symbol BSTRING.
3027    Override any claims made by the system-description files.
3028    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
3029 #undef BSTRING
3030 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
3031 #define BSTRING
3032 #endif
3033
3034 /* Some of the files of Emacs which are intended for use with other
3035    programs assume that if you have a config.h file, you must declare
3036    the type of getenv.
3037
3038    This declaration shouldn't appear when alloca.s or Makefile.in
3039    includes config.h.  */
3040 #ifndef NOT_C_CODE
3041 extern char *getenv ();
3042 #endif
3043
3044 /* These default definitions are good for almost all machines.
3045    The exceptions override them in m/MACHINE.h.  */
3046
3047 #ifndef BITS_PER_CHAR
3048 #define BITS_PER_CHAR 8
3049 #endif
3050
3051 #ifndef BITS_PER_SHORT
3052 #define BITS_PER_SHORT 16
3053 #endif
3054
3055 /* Note that lisp.h uses this in a preprocessor conditional, so it
3056    would not work to use sizeof.  That being so, we do all of them
3057    without sizeof, for uniformity's sake.  */
3058 #ifndef BITS_PER_INT
3059 #define BITS_PER_INT 32
3060 #endif
3061
3062 #ifndef BITS_PER_LONG
3063 #ifdef _LP64
3064 #define BITS_PER_LONG 64
3065 #else
3066 #define BITS_PER_LONG 32
3067 #endif
3068 #endif
3069
3070 /* Define if the compiler supports function prototypes.  It may do so
3071    but not define __STDC__ (e.g. DEC C by default) or may define it as
3072    zero.  */
3073 #undef PROTOTYPES
3074 /* For mktime.c:  */
3075 #ifndef __P
3076 # if defined PROTOTYPES
3077 #  define __P(args) args
3078 # else
3079 #  define __P(args) ()
3080 # endif  /* GCC.  */
3081 #endif /* __P */
3082
3083 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
3084 #ifndef NOT_C_CODE
3085 #ifdef HAVE_STRING_H
3086 #include "string.h"
3087 #endif
3088 #ifdef HAVE_STRINGS_H
3089 #include "strings.h"  /* May be needed for bcopy & al. */
3090 #endif
3091 #ifdef HAVE_STDLIB_H
3092 #include <stdlib.h>
3093 #endif
3094 #ifndef __GNUC__
3095 # ifdef HAVE_ALLOCA_H
3096 #  include <alloca.h>
3097 # else /* AIX files deal with #pragma.  */
3098 #  ifndef alloca /* predefined by HP cc +Olibcalls */
3099 char *alloca ();
3100 #  endif
3101 # endif /* HAVE_ALLOCA_H */
3102 #endif /* __GNUC__ */
3103 #ifndef HAVE_SIZE_T
3104 typedef unsigned size_t;
3105 #endif
3106 #endif /* NOT_C_CODE */
3107
3108 /* Define HAVE_X_I18N if we have usable i18n support.  */
3109
3110 #ifdef HAVE_X11R6
3111 #define HAVE_X_I18N
3112 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
3113 #define HAVE_X_I18N
3114 #endif
3115
3116 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3117
3118 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3119 #define HAVE_X11R6_XIM
3120 #endif
3121
3122 /* Should we enable expensive run-time checking of data types?  */
3123 #undef ENABLE_CHECKING
3124
3125 #if defined __GNUC__ && (__GNUC__ > 2 \
3126                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3127 #define NO_RETURN       __attribute__ ((__noreturn__))
3128 #else
3129 #define NO_RETURN       /* nothing */
3130 #endif
3131
3132 /* These won't be used automatically yet.  We also need to know, at least,
3133    that the stack is continuous.  */
3134 #ifdef __GNUC__
3135 #  ifndef GC_SETJMP_WORKS
3136   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3137      see NON_SAVING_SETJMP in the target descriptions.  */
3138   /* Exceptions (see NON_SAVING_SETJMP in target description) are ns32k,
3139      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3140      Fixme: Deal with ns32k, SVR3.  */
3141 #    define GC_SETJMP_WORKS 1
3142 #  endif
3143 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3144 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3145 #  endif
3146 #endif
3147
3148 #ifndef HAVE_BCOPY
3149 #define bcopy(a,b,s) memcpy (b,a,s)
3150 #endif
3151 #ifndef HAVE_BZERO
3152 #define bzero(a,s) memset (a,0,s)
3153 #endif
3154 #ifndef HAVE_BCMP
3155 #define BCMP memcmp
3156 #endif
3157
3158 #endif /* EMACS_CONFIG_H */
3159
3160 /*
3161 Local Variables:
3162 mode: c
3163 End:
3164 */
3165 ])dnl
3166
3167 #### Report on what we decided to do.
3168 #### Report GTK as a toolkit, even if it doesn't use Xt.
3169 #### It makes printing result more understandable as using GTK sets
3170 #### toolkit_scroll_bars to yes by default.
3171 if test "${HAVE_GTK}" = "yes"; then
3172   USE_X_TOOLKIT=GTK
3173 fi
3174
3175 echo "
3176 Configured for \`${canonical}'.
3177
3178   Where should the build process find the source code?    ${srcdir}
3179   What operating system and machine description files should Emacs use?
3180         \`${opsysfile}' and \`${machfile}'
3181   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3182   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3183   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3184   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3185   What window system should Emacs use?                    ${window_system}
3186   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3187
3188 if test -n "${x_includes}"; then
3189 echo "  Where do we find X Windows header files?                ${x_includes}"
3190 else
3191 echo "  Where do we find X Windows header files?                Standard dirs"
3192 fi
3193 if test -n "${x_libraries}"; then
3194 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3195 else
3196 echo "  Where do we find X Windows libraries?                   Standard dirs"
3197 fi
3198
3199 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3200 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3201 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3202 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3203 echo "  Does Emacs use -lungif?                                 ${HAVE_GIF}"
3204 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3205 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3206 echo
3207
3208 if test $USE_XASSERTS = yes; then
3209    echo "  Compiling with asserts turned on."
3210    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3211    echo
3212 fi
3213
3214
3215
3216 # Remove any trailing slashes in these variables.
3217 [test "${prefix}" != NONE &&
3218   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3219 test "${exec_prefix}" != NONE &&
3220   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3221
3222 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3223 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3224 ## from Makefile.c can correctly provide the arg `-traditional' to the
3225 ## C preprocessor.
3226
3227 AC_EGREP_CPP(yes..yes,
3228         [yes..yes],
3229         CPP_NEED_TRADITIONAL=no,
3230         CPP_NEED_TRADITIONAL=yes)
3231
3232 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3233         man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
3234         lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
3235
3236 ### Make the necessary directories, if they don't exist.
3237 for dir in etc lisp ; do
3238   test -d ${dir} || mkdir ${dir}
3239 done
3240
3241 # Build src/Makefile from ${srcdir}/src/Makefile.c
3242 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3243 # This must be done after src/config.h is built, since we rely on that file.
3244
3245 # Now get this: Some word that is part of the ${srcdir} directory name
3246 # or the ${configuration} value might, just might, happen to be an
3247 # identifier like `sun4' or `i386' or something, and be predefined by
3248 # the C preprocessor to some helpful value like 1, or maybe the empty
3249 # string.  Needless to say consequent macro substitutions are less
3250 # than conducive to the makefile finding the correct directory.
3251 [undefs="`echo $top_srcdir $configuration $canonical |
3252 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3253     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3254 `"]
3255
3256 echo creating src/epaths.h
3257 ${MAKE-make} epaths-force
3258
3259 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3260 # `..' to `. .'  unless invoked with -traditional
3261
3262 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3263   CPPFLAGS="$CPPFLAGS -traditional"
3264 fi
3265
3266 echo creating lib-src/Makefile
3267 ( cd lib-src
3268   rm -f junk.c junk1.c junk2.c
3269   sed -e '/start of cpp stuff/q' \
3270       < Makefile.c > junk1.c
3271   sed -e '1,/start of cpp stuff/d'\
3272       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3273       < Makefile.c > junk.c
3274   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3275       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3276   cat junk1.c junk2.c > Makefile.new
3277   rm -f junk.c junk1.c junk2.c
3278   chmod 444 Makefile.new
3279   mv -f Makefile.new Makefile
3280 )
3281
3282 echo creating src/Makefile
3283 ( cd src
3284   rm -f junk.c junk1.c junk2.c
3285   sed -e '/start of cpp stuff/q' \
3286       < Makefile.c > junk1.c
3287   sed -e '1,/start of cpp stuff/d'\
3288       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3289       < Makefile.c > junk.c
3290   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3291       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3292   cat junk1.c junk2.c > Makefile.new
3293   rm -f junk.c junk1.c junk2.c
3294   chmod 444 Makefile.new
3295   mv -f Makefile.new Makefile
3296 )
3297
3298 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3299   echo creating src/.gdbinit
3300   echo source $srcdir/src/.gdbinit > src/.gdbinit
3301 fi
3302
3303 # This is how we know whether to re-run configure in certain cases.
3304 touch src/config.stamp
3305
3306 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3307
3308 m4_if(dnl       Do not change this comment
3309    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3310 )dnl