]> code.delx.au - gnu-emacs/blob - configure.in
delx.au / code / gnu-emacs / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
Lowercase the first letter in the header.
[gnu-emacs] / configure.in
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002
7 dnl Free Software Foundation, Inc.
8 dnl
9 dnl This file is part of GNU Emacs.
10 dnl
11 dnl GNU Emacs is free software; you can redistribute it and/or modify
12 dnl it under the terms of the GNU General Public License as published by
13 dnl the Free Software Foundation; either version 2, or (at your option)
14 dnl any later version.
15 dnl
16 dnl GNU Emacs is distributed in the hope that it will be useful,
17 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
18 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
19 dnl GNU General Public License for more details.
20 dnl
21 dnl You should have received a copy of the GNU General Public License
22 dnl along with GNU Emacs; see the file COPYING. If not, write to the
23 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
24 dnl Boston, MA 02111-1307, USA.
25
26 AC_PREREQ(2.51)dnl
27 AC_INIT(src/lisp.h)
28 AC_CONFIG_HEADER(src/config.h:src/config.in)
29
30 dnl Support for --program-prefix, --program-suffix and
31 dnl --program-transform-name options
32 AC_ARG_PROGRAM
33
34 lispdir='${datadir}/emacs/${version}/lisp'
35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
36 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
37 lisppath='${locallisppath}:${lispdir}'
38 etcdir='${datadir}/emacs/${version}/etc'
39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
40 docdir='${datadir}/emacs/${version}/etc'
41 gamedir=yes
42
43 AC_ARG_WITH(game-dir,
44 [ --with-game-dir use a shared game directory if possible],
45 [
46 gamedir="$withval"
47 ])
48 if test "$gamedir" = yes; then
49 gamedir="${localstatedir}/games/emacs"
50 fi
51 eval tgamedir=\"$gamedir\"
52 if test "$gamedir" != no; then
53 AC_DEFINE_UNQUOTED(HAVE_SHARED_GAME_DIR, "$tgamedir",
54 [Define to the name of the shared game directory.])
55 fi
56
57 gameuser=games
58 AC_ARG_WITH(game-user,
59 [ --with-game-user use specified user for game directory],
60 [gameuser="$withval"])
61
62 AC_ARG_WITH(gcc,
63 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
64 AC_ARG_WITH(pop,
65 [ --without-pop don't support POP mail retrieval with movemail],
66 [if test "$withval" = yes; then
67 AC_DEFINE(MAIL_USE_POP)
68 else :
69 fi],
70 AC_DEFINE(MAIL_USE_POP))
71 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
72 AC_ARG_WITH(kerberos,
73 [ --with-kerberos support Kerberos-authenticated POP],
74 [AC_DEFINE(KERBEROS)])
75 AH_TEMPLATE(KERBEROS,
76 [Define to support Kerberos-authenticated POP mail retrieval.])dnl
77 AC_ARG_WITH(kerberos5,
78 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
79 [if test "${with_kerberos5+set}" = set; then
80 if test "${with_kerberos+set}" != set; then
81 with_kerberos=yes
82 AC_DEFINE(KERBEROS)
83 fi
84 fi
85 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
86 AC_ARG_WITH(hesiod,
87 [ --with-hesiod support Hesiod to get the POP server host],
88 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
89
90 AC_ARG_WITH(sound,
91 [ --without-sound don't compile with sound support])
92
93 dnl This should be the last --with option, because --with-x is
94 dnl added later on when we find the path of X, and it's best to
95 dnl keep them together visually.
96 AC_ARG_WITH(x-toolkit,
97 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif/no)],
98 [ case "${withval}" in
99 y | ye | yes ) val=athena ;;
100 n | no ) val=no ;;
101 l | lu | luc | luci | lucid ) val=lucid ;;
102 a | at | ath | athe | athen | athena ) val=athena ;;
103 m | mo | mot | moti | motif ) val=motif ;;
104 dnl These don't currently work.
105 dnl o | op | ope | open | open- | open-l | open-lo \
106 dnl | open-loo | open-look ) val=open-look ;;
107 * )
108 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
109 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
110 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
111 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
112 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
113 ;;
114 esac
115 with_x_toolkit=$val
116 ])
117 AC_ARG_WITH(xpm,
118 [ --with-xpm use -lXpm for displaying XPM images])
119 AC_ARG_WITH(jpeg,
120 [ --with-jpeg use -ljpeg for displaying JPEG images])
121 AC_ARG_WITH(tiff,
122 [ --with-tiff use -ltiff for displaying TIFF images])
123 AC_ARG_WITH(gif,
124 [ --with-gif use -lungif for displaying GIF images])
125 AC_ARG_WITH(png,
126 [ --with-png use -lpng for displaying PNG images])
127 AC_ARG_WITH(toolkit-scroll-bars,
128 [ --without-toolkit-scroll-bars
129 don't use Motif or Xaw3d scroll bars])
130 AC_ARG_WITH(xim,
131 [ --without-xim don't use X11 XIM])
132 AC_ARG_WITH(carbon,
133 [ --without-carbon don't use Carbon GUI on Mac OS X])
134
135 #### Make srcdir absolute, if it isn't already. It's important to
136 #### avoid running the path through pwd unnecessarily, since pwd can
137 #### give you automounter prefixes, which can go away. We do all this
138 #### so Emacs can find its files when run uninstalled.
139 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
140 unset CDPATH
141 case "${srcdir}" in
142 /* ) ;;
143 . )
144 ## We may be able to use the $PWD environment variable to make this
145 ## absolute. But sometimes PWD is inaccurate.
146 ## Note: we used to use ${PWD} at the end instead of `pwd`,
147 ## but that tested only for a well-formed and valid PWD,
148 ## it did not object when PWD was well-formed and valid but just wrong.
149 if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`" ;
150 then
151 srcdir="$PWD"
152 else
153 srcdir="`(cd ${srcdir}; pwd)`"
154 fi
155 ;;
156 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
157 esac
158
159 #### Check if the source directory already has a configured system in it.
160 if test `pwd` != `(cd ${srcdir} && pwd)` \
161 && test -f "${srcdir}/src/config.h" ; then
162 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
163 as a build directory right now; it has been configured in its own
164 right. To configure in another directory as well, you MUST
165 use GNU make. If you do not have GNU make, then you must
166 now do \`make distclean' in ${srcdir},
167 and then run $0 again.])
168
169 changequote(, )dnl
170 extrasub='/^VPATH[ ]*=/c\
171 changequote([, ])dnl
172 vpath %.c $(srcdir)\
173 vpath %.h $(srcdir)\
174 vpath %.y $(srcdir)\
175 vpath %.l $(srcdir)\
176 vpath %.s $(srcdir)\
177 vpath %.in $(srcdir)\
178 vpath %.texi $(srcdir)'
179 fi
180
181 #### Given the configuration name, set machfile and opsysfile to the
182 #### names of the m/*.h and s/*.h files we should use.
183
184 ### Canonicalize the configuration name.
185
186 AC_CANONICAL_HOST
187 canonical=$host
188 configuration=${host_alias-$host}
189
190 changequote(, )dnl
191
192 ### If you add support for a new configuration, add code to this
193 ### switch statement to recognize your configuration name and select
194 ### the appropriate operating system and machine description files.
195
196 ### You would hope that you could choose an m/*.h file pretty much
197 ### based on the machine portion of the configuration name, and an s-
198 ### file based on the operating system portion. However, it turns out
199 ### that each m/*.h file is pretty manufacturer-specific - for
200 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
201 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
202 ### machines. So we basically have to have a special case for each
203 ### configuration name.
204 ###
205 ### As far as handling version numbers on operating systems is
206 ### concerned, make sure things will fail in a fixable way. If
207 ### /etc/MACHINES doesn't say anything about version numbers, be
208 ### prepared to handle anything reasonably. If version numbers
209 ### matter, be sure /etc/MACHINES says something about it.
210 ###
211 ### Eric Raymond says we should accept strings like "sysvr4" to mean
212 ### "System V Release 4"; he writes, "The old convention encouraged
213 ### confusion between `system' and `release' levels'."
214
215 machine='' opsys='' unported=no
216 case "${canonical}" in
217
218 ## FreeBSD ports
219 *-*-freebsd* )
220 opsys=freebsd
221 case "${canonical}" in
222 alpha*-*-freebsd*) machine=alpha ;;
223 i[3456]86-*-freebsd*) machine=intel386 ;;
224 esac
225 ;;
226
227 ## NetBSD ports
228 *-*-netbsd* )
229 opsys=netbsd
230 case "${canonical}" in
231 alpha*-*-netbsd*) machine=alpha ;;
232 i[3456]86-*-netbsd*) machine=intel386 ;;
233 m68k-*-netbsd*)
234 # This is somewhat bogus.
235 machine=hp9000s300 ;;
236 powerpc-apple-netbsd*) machine=macppc ;;
237 mips-*-netbsd*) machine=pmax ;;
238 mipsel-*-netbsd*) machine=pmax ;;
239 ns32k-*-netbsd*) machine=ns32000 ;;
240 powerpc-*-netbsd*) machine=macppc ;;
241 sparc*-*-netbsd*) machine=sparc ;;
242 vax-*-netbsd*) machine=vax ;;
243 arm-*-netbsd*) machine=arm ;;
244 esac
245 ;;
246
247 ## OpenBSD ports
248 *-*-openbsd* )
249 opsys=openbsd
250 case "${canonical}" in
251 alpha*-*-openbsd*) machine=alpha ;;
252 i386-*-openbsd*) machine=intel386 ;;
253 m68k-*-openbsd*) machine=hp9000s300 ;;
254 mipsel-*-openbsd*) machine=pmax ;;
255 ns32k-*-openbsd*) machine=ns32000 ;;
256 sparc-*-openbsd*) machine=sparc ;;
257 vax-*-openbsd*) machine=vax ;;
258 esac
259 ;;
260
261 ## Acorn RISCiX:
262 arm-acorn-riscix1.1* )
263 machine=acorn opsys=riscix1-1
264 ;;
265 arm-acorn-riscix1.2* | arm-acorn-riscix )
266 ## This name is riscix12 instead of riscix1.2
267 ## to avoid a file name conflict on MSDOS.
268 machine=acorn opsys=riscix12
269 ;;
270
271 ## BSDI ports
272 *-*-bsdi* )
273 opsys=bsdi
274 case "${canonical}" in
275 i[345]86-*-bsdi*) machine=intel386 ;;
276 sparc-*-bsdi*) machine=sparc ;;
277 powerpc-*-bsdi*) machine=macppc ;;
278 esac
279 case "${canonical}" in
280 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
281 *-*-bsdi2.0* ) opsys=bsdos2 ;;
282 *-*-bsdi2* ) opsys=bsdos2-1 ;;
283 *-*-bsdi3* ) opsys=bsdos3 ;;
284 *-*-bsdi[45]* ) opsys=bsdos4 ;;
285 esac
286 ;;
287
288 ## Alliant machines
289 ## Strictly speaking, we need the version of the alliant operating
290 ## system to choose the right machine file, but currently the
291 ## configuration name doesn't tell us enough to choose the right
292 ## one; we need to give alliants their own operating system name to
293 ## do this right. When someone cares, they can help us.
294 fx80-alliant-* )
295 machine=alliant4 opsys=bsd4-2
296 ;;
297 i860-alliant-* )
298 machine=alliant-2800 opsys=bsd4-3
299 ;;
300
301 ## Alpha (DEC) machines.
302 alpha*-dec-osf* )
303 machine=alpha opsys=osf1
304 # This is needed to find X11R6.1 libraries for certain tests.
305 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
306 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
307 # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
308 # due to non-traditional preprocessing with the current compiler
309 # defaults. OSF 4 can also have that compiler version, and there
310 # seems always to have been a usable /usr/bin/cpp.
311 NON_GNU_CPP=/usr/bin/cpp
312 case "${canonical}" in
313 alpha*-dec-osf[5-9]*)
314 opsys=osf5-0 ;;
315 esac
316 ;;
317
318 alpha*-*-linux-gnu* )
319 machine=alpha opsys=gnu-linux
320 ;;
321
322 arm*-*-linux-gnu* )
323 machine=arm opsys=gnu-linux
324 ;;
325
326 ppc-*-linux | \
327 powerpc-*-linux* )
328 machine=macppc opsys=gnu-linux
329 ;;
330
331 ## Altos 3068
332 m68*-altos-sysv* )
333 machine=altos opsys=usg5-2
334 ;;
335
336 ## Amdahl UTS
337 580-amdahl-sysv* )
338 machine=amdahl opsys=usg5-2-2
339 ;;
340
341 ## Apollo, Domain/OS
342 m68*-apollo-* )
343 machine=apollo opsys=bsd4-3
344 ;;
345
346 ## AT&T 3b2, 3b5, 3b15, 3b20
347 we32k-att-sysv* )
348 machine=att3b opsys=usg5-2-2
349 ;;
350
351 ## AT&T 3b1 - The Mighty Unix PC!
352 m68*-att-sysv* )
353 machine=7300 opsys=usg5-2-2
354 ;;
355
356 ## Bull dpx20
357 rs6000-bull-bosx* )
358 machine=ibmrs6000 opsys=aix3-2
359 ;;
360
361 ## Bull dpx2
362 m68*-bull-sysv3* )
363 machine=dpx2 opsys=usg5-3
364 ;;
365
366 ## Bull sps7
367 m68*-bull-sysv2* )
368 machine=sps7 opsys=usg5-2
369 ;;
370
371 ## CCI 5/32, 6/32 -- see "Tahoe".
372
373 ## Celerity
374 ## I don't know what configuration name to use for this; config.sub
375 ## doesn't seem to know anything about it. Hey, Celerity users, get
376 ## in touch with us!
377 celerity-celerity-bsd* )
378 machine=celerity opsys=bsd4-2
379 ;;
380
381 ## Clipper
382 ## What operating systems does this chip run that Emacs has been
383 ## tested on?
384 clipper-* )
385 machine=clipper
386 ## We'll use the catch-all code at the bottom to guess the
387 ## operating system.
388 ;;
389
390 ## Compaq Nonstop
391 mips-compaq-nonstopux* )
392 machine=nonstopux opsys=nonstopux
393 ;;
394
395 ## Convex
396 *-convex-bsd* | *-convex-convexos* )
397 machine=convex opsys=bsd4-3
398 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
399 NON_GNU_CPP="cc -E -P"
400 ;;
401
402 ## Cubix QBx/386
403 i[3456]86-cubix-sysv* )
404 machine=intel386 opsys=usg5-3
405 ;;
406
407 ## Cydra 5
408 cydra*-cydrome-sysv* )
409 machine=cydra5 opsys=usg5-3
410 ;;
411
412 ## Data General AViiON Machines
413 ## DG changed naming conventions with the release of 5.4.4.10, they
414 ## dropped the initial 5.4 but left the intervening R. Because of the
415 ## R this shouldn't conflict with older versions of the OS (which I
416 ## think were named like dgux4.*). In addition, DG new AViiONs series
417 ## uses either Motorola M88k or Intel Pentium CPUs.
418 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
419 machine=aviion opsys=dgux4
420 ;;
421 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
422 ## This name is dgux5-4-3 instead of dgux5-4r3
423 ## to avoid a file name conflict on MSDOS.
424 machine=aviion opsys=dgux5-4-3
425 ;;
426 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
427 machine=aviion opsys=dgux5-4r2
428 ;;
429 m88k-dg-dgux* )
430 machine=aviion opsys=dgux
431 ;;
432
433 ## Data General AViiON Intel (x86) Machines
434 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
435 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
436 i[345]86-dg-dguxR4* )
437 machine=aviion-intel opsys=dgux4
438 ;;
439
440 ## DECstations
441 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
442 machine=pmax opsys=bsd4-2
443 ;;
444 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
445 machine=pmax opsys=bsd4-3
446 ;;
447 mips-dec-ultrix* )
448 machine=pmax opsys=ultrix4-3
449 ;;
450 mips-dec-osf* )
451 machine=pmax opsys=osf1
452 ;;
453 mips-dec-mach_bsd4.3* )
454 machine=pmax opsys=mach-bsd4-3
455 ;;
456
457 ## Motorola Delta machines
458 m68k-motorola-sysv* | m68000-motorola-sysv* )
459 machine=delta opsys=usg5-3
460 if test -z "`type gnucc | grep 'not found'`"
461 then
462 if test -s /etc/167config
463 then CC="gnucc -m68040"
464 else CC="gnucc -m68881"
465 fi
466 else
467 if test -z "`type gcc | grep 'not found'`"
468 then CC=gcc
469 else CC=cc
470 fi
471 fi
472 ;;
473 m88k-motorola-sysv4* )
474 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
475 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
476 # I hope there are not other 4.0 versions for this machine
477 # which really need usg5-4 instead.
478 machine=delta88k opsys=usg5-4-2
479 ;;
480 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
481 machine=delta88k opsys=usg5-3
482 ;;
483
484 ## Dual machines
485 m68*-dual-sysv* )
486 machine=dual opsys=usg5-2
487 ;;
488 m68*-dual-uniplus* )
489 machine=dual opsys=unipl5-2
490 ;;
491
492 ## Elxsi 6400
493 elxsi-elxsi-sysv* )
494 machine=elxsi opsys=usg5-2
495 ;;
496
497 ## Encore machines
498 ns16k-encore-bsd* )
499 machine=ns16000 opsys=umax
500 ;;
501
502 ## The GEC 63 - apparently, this port isn't really finished yet.
503 # I'm sure we finished off the last of the machines, though. -- fx
504
505 ## Gould Power Node and NP1
506 pn-gould-bsd4.2* )
507 machine=gould opsys=bsd4-2
508 ;;
509 pn-gould-bsd4.3* )
510 machine=gould opsys=bsd4-3
511 ;;
512 np1-gould-bsd* )
513 machine=gould-np1 opsys=bsd4-3
514 ;;
515
516 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
517 ## as far as Emacs is concerned).
518 m88k-harris-cxux* )
519 # Build needs to be different on 7.0 and later releases
520 case "`uname -r`" in
521 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
522 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
523 esac
524 NON_GNU_CPP="/lib/cpp"
525 ;;
526 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
527 m68k-harris-cxux* )
528 machine=nh3000 opsys=cxux
529 ;;
530 ## Harris power pc NightHawk running Power UNIX (Series 6000)
531 powerpc-harris-powerunix )
532 machine=nh6000 opsys=powerunix
533 NON_GNU_CPP="cc -Xo -E -P"
534 ;;
535 ## SR2001/SR2201 running HI-UX/MPP
536 hppa1.1-hitachi-hiuxmpp* )
537 machine=sr2k opsys=hiuxmpp
538 ;;
539 hppa1.1-hitachi-hiuxwe2* )
540 machine=sr2k opsys=hiuxwe2
541 ;;
542 ## Honeywell XPS100
543 xps*-honeywell-sysv* )
544 machine=xps100 opsys=usg5-2
545 ;;
546
547 ## HP 9000 series 200 or 300
548 m68*-hp-bsd* )
549 machine=hp9000s300 opsys=bsd4-3
550 ;;
551 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
552 m68*-hp-hpux* )
553 case "`uname -r`" in
554 ## Someone's system reports A.B8.05 for this.
555 ## I wonder what other possibilities there are.
556 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
557 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
558 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
559 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
560 *) machine=hp9000s300 opsys=hpux ;;
561 esac
562 ;;
563
564 ## HP 9000 series 700 and 800, running HP/UX
565 hppa*-hp-hpux7* )
566 machine=hp800 opsys=hpux
567 ;;
568 hppa*-hp-hpux8* )
569 machine=hp800 opsys=hpux8
570 ;;
571 hppa*-hp-hpux9shr* )
572 machine=hp800 opsys=hpux9shr
573 ;;
574 hppa*-hp-hpux9* )
575 machine=hp800 opsys=hpux9
576 ;;
577 hppa*-hp-hpux10* )
578 machine=hp800 opsys=hpux10
579 ;;
580 hppa*-hp-hpux1[1-9]* )
581 machine=hp800 opsys=hpux11
582 ;;
583
584 hppa*-*-linux-gnu* )
585 machine=hp800 opsys=gnu-linux
586 ;;
587
588 ## HP 9000 series 700 and 800, running HP/UX
589 hppa*-hp-hpux* )
590 ## Cross-compilation? Nah!
591 case "`uname -r`" in
592 ## Someone's system reports A.B8.05 for this.
593 ## I wonder what other possibilities there are.
594 *.B8.* ) machine=hp800 opsys=hpux8 ;;
595 *.08.* ) machine=hp800 opsys=hpux8 ;;
596 *.09.* ) machine=hp800 opsys=hpux9 ;;
597 *) machine=hp800 opsys=hpux10 ;;
598 esac
599 ;;
600 hppa*-*-nextstep* )
601 machine=hp800 opsys=nextstep
602 ;;
603
604 ## Orion machines
605 orion-orion-bsd* )
606 machine=orion opsys=bsd4-2
607 ;;
608 clipper-orion-bsd* )
609 machine=orion105 opsys=bsd4-2
610 ;;
611
612 ## IBM machines
613 i[3456]86-ibm-aix1.1* )
614 machine=ibmps2-aix opsys=usg5-2-2
615 ;;
616 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
617 machine=ibmps2-aix opsys=usg5-3
618 ;;
619 i370-ibm-aix*)
620 machine=ibm370aix opsys=usg5-3
621 ;;
622 s390-*-linux-gnu)
623 machine=ibms390 opsys=gnu-linux
624 ;;
625 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
626 machine=ibmrs6000 opsys=aix3-1
627 ;;
628 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
629 machine=ibmrs6000 opsys=aix3-2-5
630 ;;
631 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
632 machine=ibmrs6000 opsys=aix4-1
633 ;;
634 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
635 machine=ibmrs6000 opsys=aix4-2
636 ;;
637 rs6000-ibm-aix5.1* | powerpc-ibm-aix5.1* )
638 machine=ibmrs6000 opsys=aix4-2
639 ;;
640 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
641 machine=ibmrs6000 opsys=aix4
642 ;;
643 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
644 machine=ibmrs6000 opsys=aix4-1
645 ;;
646 rs6000-ibm-aix* | powerpc-ibm-aix* )
647 machine=ibmrs6000 opsys=aix3-2
648 ;;
649 romp-ibm-bsd4.3* )
650 machine=ibmrt opsys=bsd4-3
651 ;;
652 romp-ibm-bsd4.2* )
653 machine=ibmrt opsys=bsd4-2
654 ;;
655 romp-ibm-aos4.3* )
656 machine=ibmrt opsys=bsd4-3
657 ;;
658 romp-ibm-aos4.2* )
659 machine=ibmrt opsys=bsd4-2
660 ;;
661 romp-ibm-aos* )
662 machine=ibmrt opsys=bsd4-3
663 ;;
664 romp-ibm-bsd* )
665 machine=ibmrt opsys=bsd4-3
666 ;;
667 romp-ibm-aix* )
668 machine=ibmrt-aix opsys=usg5-2-2
669 ;;
670
671 ## Integrated Solutions `Optimum V'
672 m68*-isi-bsd4.2* )
673 machine=isi-ov opsys=bsd4-2
674 ;;
675 m68*-isi-bsd4.3* )
676 machine=isi-ov opsys=bsd4-3
677 ;;
678
679 ## Intel 386 machines where we do care about the manufacturer
680 i[3456]86-intsys-sysv* )
681 machine=is386 opsys=usg5-2-2
682 ;;
683
684 ## Prime EXL
685 i[3456]86-prime-sysv* )
686 machine=i386 opsys=usg5-3
687 ;;
688
689 ## Sequent Symmetry running Dynix
690 i[3456]86-sequent-bsd* )
691 machine=symmetry opsys=bsd4-3
692 ;;
693
694 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
695 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
696 machine=sequent-ptx opsys=ptx4
697 NON_GNU_CPP=/lib/cpp
698 ;;
699
700 ## Sequent Symmetry running DYNIX/ptx
701 ## Use the old cpp rather than the newer ANSI one.
702 i[3456]86-sequent-ptx* )
703 machine=sequent-ptx opsys=ptx
704 NON_GNU_CPP="/lib/cpp"
705 ;;
706
707 ## ncr machine running svr4.3.
708 i[3456]86-ncr-sysv4.3 )
709 machine=ncr386 opsys=usg5-4-3
710 ;;
711
712 ## Unspecified sysv on an ncr machine defaults to svr4.2.
713 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
714 i[3456]86-ncr-sysv* )
715 machine=ncr386 opsys=usg5-4-2
716 ;;
717
718 ## Intel Paragon OSF/1
719 i860-intel-osf1* )
720 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
721 ;;
722
723 ## Intel 860
724 i860-*-sysv4* )
725 machine=i860 opsys=usg5-4
726 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
727 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
728 ;;
729
730 ## Macintosh PowerPC
731 powerpc*-*-linux-gnu* )
732 machine=macppc opsys=gnu-linux
733 ;;
734
735 ## Masscomp machines
736 m68*-masscomp-rtu* )
737 machine=masscomp opsys=rtu
738 ;;
739
740 ## Megatest machines
741 m68*-megatest-bsd* )
742 machine=mega68 opsys=bsd4-2
743 ;;
744
745 ## Workstations sold by MIPS
746 ## This is not necessarily all workstations using the MIPS processor -
747 ## Irises are produced by SGI, and DECstations by DEC.
748
749 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
750 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
751 ## it gives for choosing between the alternatives seems to be "Use
752 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
753 ## the BSD world." I'll assume that these are instructions for
754 ## handling two odd situations, and that every other situation
755 ## should use mips.h and usg5-2-2, they being listed first.
756 mips-mips-usg* )
757 machine=mips4
758 ## Fall through to the general code at the bottom to decide on the OS.
759 ;;
760 mips-mips-riscos4* )
761 machine=mips4 opsys=bsd4-3
762 NON_GNU_CC="cc -systype bsd43"
763 NON_GNU_CPP="cc -systype bsd43 -E"
764 ;;
765 mips-mips-riscos5* )
766 machine=mips4 opsys=riscos5
767 NON_GNU_CC="cc -systype bsd43"
768 NON_GNU_CPP="cc -systype bsd43 -E"
769 ;;
770 mips-mips-bsd* )
771 machine=mips opsys=bsd4-3
772 ;;
773 mips-mips-* )
774 machine=mips opsys=usg5-2-2
775 ;;
776
777 ## NeXT
778 m68*-next-* | m68k-*-nextstep* )
779 machine=m68k opsys=nextstep
780 ;;
781
782 ## The complete machine from National Semiconductor
783 ns32k-ns-genix* )
784 machine=ns32000 opsys=usg5-2
785 ;;
786
787 ## NCR machines
788 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
789 machine=tower32 opsys=usg5-2-2
790 ;;
791 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
792 machine=tower32v3 opsys=usg5-3
793 ;;
794
795 ## NEC EWS4800
796 mips-nec-sysv4*)
797 machine=ews4800 opsys=ux4800
798 ;;
799
800 ## Nixdorf Targon 31
801 m68*-nixdorf-sysv* )
802 machine=targon31 opsys=usg5-2-2
803 ;;
804
805 ## Nu (TI or LMI)
806 m68*-nu-sysv* )
807 machine=nu opsys=usg5-2
808 ;;
809
810 ## Plexus
811 m68*-plexus-sysv* )
812 machine=plexus opsys=usg5-2
813 ;;
814
815 ## PowerPC reference platform
816 powerpcle-*-solaris2* )
817 machine=prep
818 opsys=sol2-5
819 ;;
820
821 ## Pyramid machines
822 ## I don't really have any idea what sort of processor the Pyramid has,
823 ## so I'm assuming it is its own architecture.
824 pyramid-pyramid-bsd* )
825 machine=pyramid opsys=bsd4-2
826 ;;
827
828 ## Sequent Balance
829 ns32k-sequent-bsd4.2* )
830 machine=sequent opsys=bsd4-2
831 ;;
832 ns32k-sequent-bsd4.3* )
833 machine=sequent opsys=bsd4-3
834 ;;
835
836 ## Siemens Nixdorf
837 mips-siemens-sysv* | mips-sni-sysv*)
838 machine=mips-siemens opsys=usg5-4
839 NON_GNU_CC=/usr/ccs/bin/cc
840 NON_GNU_CPP=/usr/ccs/lib/cpp
841 ;;
842
843 ## Silicon Graphics machines
844 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
845 m68*-sgi-iris3.5* )
846 machine=irist opsys=iris3-5
847 ;;
848 m68*-sgi-iris3.6* | m68*-sgi-iris*)
849 machine=irist opsys=iris3-6
850 ;;
851 ## Iris 4D
852 mips-sgi-irix3* )
853 machine=iris4d opsys=irix3-3
854 ;;
855 mips-sgi-irix4* )
856 machine=iris4d opsys=irix4-0
857 ;;
858 mips-sgi-irix6.5 )
859 machine=iris4d opsys=irix6-5
860 # Without defining _LANGUAGE_C, things get masked out in the headers
861 # so that, for instance, grepping for `free' in stdlib.h fails and
862 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
863 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
864 NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
865 ;;
866 mips-sgi-irix6* )
867 machine=iris4d opsys=irix6-0
868 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
869 # but presumably it does no harm.
870 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
871 # -32 probably isn't necessary in later v.6s -- anyone know which?
872 NON_GCC_TEST_OPTIONS=-32
873 ;;
874 mips-sgi-irix5.[01]* )
875 machine=iris4d opsys=irix5-0
876 ;;
877 mips-sgi-irix5* | mips-sgi-irix* )
878 machine=iris4d opsys=irix5-2
879 ;;
880
881 ## SONY machines
882 m68*-sony-bsd4.2* )
883 machine=news opsys=bsd4-2
884 ;;
885 m68*-sony-bsd4.3* )
886 machine=news opsys=bsd4-3
887 ;;
888 m68*-sony-newsos3* | m68*-sony-news3*)
889 machine=news opsys=bsd4-3
890 ;;
891 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
892 machine=news-risc opsys=bsd4-3
893 ;;
894 mips-sony-newsos6* )
895 machine=news-r6 opsys=newsos6
896 ;;
897 mips-sony-news* )
898 machine=news-risc opsys=newsos5
899 ;;
900
901 ## Stride
902 m68*-stride-sysv* )
903 machine=stride opsys=usg5-2
904 ;;
905
906 ## Suns
907 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
908 machine=sparc opsys=gnu-linux
909 ;;
910
911 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
912 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
913 | rs6000-*-solaris2*)
914 case "${canonical}" in
915 m68*-sunos1* ) machine=sun1 ;;
916 m68*-sunos2* ) machine=sun2 ;;
917 m68* ) machine=sun3 ;;
918 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
919 i[3456]86-*-* ) machine=intel386 ;;
920 powerpcle* ) machine=powerpcle ;;
921 powerpc* | rs6000* ) machine=ibmrs6000 ;;
922 sparc* ) machine=sparc ;;
923 * ) unported=yes ;;
924 esac
925 case "${canonical}" in
926 ## The Sun386 didn't get past 4.0.
927 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
928 *-sunos4.0* ) opsys=sunos4-0 ;;
929 *-sunos4.1.[3-9]*noshare )
930 ## This name is sunos413 instead of sunos4-1-3
931 ## to avoid a file name conflict on MSDOS.
932 opsys=sunos413
933 NON_GNU_CPP=/usr/lib/cpp
934 NON_GCC_TEST_OPTIONS=-Bstatic
935 GCC_TEST_OPTIONS=-static
936 ;;
937 *-sunos4.1.[3-9]* | *-sunos4shr*)
938 opsys=sunos4shr
939 NON_GNU_CPP=/usr/lib/cpp
940 ;;
941 *-sunos4* | *-sunos )
942 opsys=sunos4-1
943 NON_GCC_TEST_OPTIONS=-Bstatic
944 GCC_TEST_OPTIONS=-static
945 ;;
946 *-sunos5.3* | *-solaris2.3* )
947 opsys=sol2-3
948 NON_GNU_CPP=/usr/ccs/lib/cpp
949 ;;
950 *-sunos5.4* | *-solaris2.4* )
951 opsys=sol2-4
952 NON_GNU_CPP=/usr/ccs/lib/cpp
953 RANLIB="ar -ts"
954 ;;
955 *-sunos5.5* | *-solaris2.5* )
956 opsys=sol2-5
957 NON_GNU_CPP=/usr/ccs/lib/cpp
958 RANLIB="ar -ts"
959 ;;
960 *-sunos5* | *-solaris* )
961 opsys=sol2-5
962 NON_GNU_CPP=/usr/ccs/lib/cpp
963 ;;
964 * ) opsys=bsd4-2 ;;
965 esac
966 ## Watch out for a compiler that we know will not work.
967 case "${canonical}" in
968 *-solaris* | *-sunos5* )
969 if [ "x$CC" = x/usr/ucb/cc ]; then
970 ## /usr/ucb/cc doesn't work;
971 ## we should find some other compiler that does work.
972 unset CC
973 fi
974 ;;
975 *) ;;
976 esac
977 ;;
978 sparc-*-nextstep* )
979 machine=sparc opsys=nextstep
980 ;;
981
982 ## Tadpole 68k
983 m68*-tadpole-sysv* )
984 machine=tad68k opsys=usg5-3
985 ;;
986
987 ## Tahoe machines
988 tahoe-tahoe-bsd4.2* )
989 machine=tahoe opsys=bsd4-2
990 ;;
991 tahoe-tahoe-bsd4.3* )
992 machine=tahoe opsys=bsd4-3
993 ;;
994
995 ## Tandem Integrity S2
996 mips-tandem-sysv* )
997 machine=tandem-s2 opsys=usg5-3
998 ;;
999
1000 ## Tektronix XD88
1001 m88k-tektronix-sysv3* )
1002 machine=tekxd88 opsys=usg5-3
1003 ;;
1004
1005 ## Tektronix 16000 box (6130?)
1006 ns16k-tektronix-bsd* )
1007 machine=ns16000 opsys=bsd4-2
1008 ;;
1009 ## Tektronix 4300
1010 ## src/m/tek4300.h hints that this is a m68k machine.
1011 m68*-tektronix-bsd* )
1012 machine=tek4300 opsys=bsd4-3
1013 ;;
1014
1015 ## Titan P2 or P3
1016 ## We seem to have lost the machine-description file titan.h!
1017 titan-titan-sysv* )
1018 machine=titan opsys=usg5-3
1019 ;;
1020
1021 ## Ustation E30 (SS5E)
1022 m68*-unisys-uniplus* )
1023 machine=ustation opsystem=unipl5-2
1024 ;;
1025
1026 ## Vaxen.
1027 vax-dec-* )
1028 machine=vax
1029 case "${canonical}" in
1030 *-bsd4.1* ) opsys=bsd4-1 ;;
1031 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
1032 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
1033 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
1034 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
1035 *-vms* ) opsys=vms ;;
1036 * ) unported=yes
1037 esac
1038 ;;
1039
1040 ## Whitechapel MG1
1041 ns16k-whitechapel-* )
1042 machine=mg1
1043 ## We don't know what sort of OS runs on these; we'll let the
1044 ## operating system guessing code below try.
1045 ;;
1046
1047 ## Wicat
1048 m68*-wicat-sysv* )
1049 machine=wicat opsys=usg5-2
1050 ;;
1051
1052 ## IA-64
1053 ia64*-*-linux* )
1054 machine=ia64 opsys=gnu-linux
1055 ;;
1056
1057 ## Intel 386 machines where we don't care about the manufacturer
1058 i[3456]86-*-* )
1059 machine=intel386
1060 case "${canonical}" in
1061 *-lynxos* ) opsys=lynxos ;;
1062 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1063 *-isc2.2* ) opsys=isc2-2 ;;
1064 *-isc4.0* ) opsys=isc4-0 ;;
1065 *-isc4.* ) opsys=isc4-1
1066 GCC_TEST_OPTIONS=-posix
1067 NON_GCC_TEST_OPTIONS=-Xp
1068 ;;
1069 *-isc* ) opsys=isc3-0 ;;
1070 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1071 *-esix* ) opsys=esix ;;
1072 *-xenix* ) opsys=xenix ;;
1073 *-linux-gnu* ) opsys=gnu-linux ;;
1074 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
1075 *-sco3.2v5* ) opsys=sco5
1076 NON_GNU_CPP=/lib/cpp
1077 # Prevent -belf from being passed to $CPP.
1078 # /lib/cpp does not accept it.
1079 OVERRIDE_CPPFLAGS=" "
1080 ;;
1081 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1082 *-386bsd* ) opsys=386bsd ;;
1083 *-nextstep* ) opsys=nextstep ;;
1084 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1085 esac
1086 ;;
1087
1088 ## m68k Linux-based GNU system
1089 m68k-*-linux-gnu* )
1090 machine=m68k opsys=gnu-linux
1091 ;;
1092
1093 ## Mips Linux-based GNU system
1094 mips-*-linux-gnu* )
1095 machine=mips opsys=gnu-linux
1096 ;;
1097
1098 ## UXP/DS
1099 sparc-fujitsu-sysv4* )
1100 machine=sparc opsys=uxpds
1101 NON_GNU_CPP=/usr/ccs/lib/cpp
1102 RANLIB="ar -ts"
1103 ;;
1104
1105 ## UXP/V
1106 f301-fujitsu-uxpv4.1)
1107 machine=f301 opsys=uxpv
1108 ;;
1109
1110 ## Darwin / Mac OS X
1111 powerpc-apple-darwin* )
1112 machine=powermac opsys=darwin
1113 # Define CPP as follows to make autoconf work correctly.
1114 CPP="cc -E -traditional-cpp"
1115 ;;
1116
1117 * )
1118 unported=yes
1119 ;;
1120 esac
1121
1122 ### If the code above didn't choose an operating system, just choose
1123 ### an operating system based on the configuration name. You really
1124 ### only want to use this when you have no idea what the right
1125 ### operating system is; if you know what operating systems a machine
1126 ### runs, it's cleaner to make it explicit in the case statement
1127 ### above.
1128 if test x"${opsys}" = x; then
1129 case "${canonical}" in
1130 *-gnu* ) opsys=gnu ;;
1131 *-bsd4.[01] ) opsys=bsd4-1 ;;
1132 *-bsd4.2 ) opsys=bsd4-2 ;;
1133 *-bsd4.3 ) opsys=bsd4-3 ;;
1134 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1135 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1136 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1137 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1138 *-sysv4.2uw* ) opsys=unixware ;;
1139 *-sysv4.1* | *-sysvr4.1* )
1140 NON_GNU_CPP=/usr/lib/cpp
1141 opsys=usg5-4 ;;
1142 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1143 if [ x$NON_GNU_CPP = x ]; then
1144 if [ -f /usr/ccs/lib/cpp ]; then
1145 NON_GNU_CPP=/usr/ccs/lib/cpp
1146 else
1147 NON_GNU_CPP=/lib/cpp
1148 fi
1149 fi
1150 opsys=usg5-4-2 ;;
1151 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1152 * )
1153 unported=yes
1154 ;;
1155 esac
1156 fi
1157
1158 changequote([, ])dnl
1159
1160 if test $unported = yes; then
1161 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1162 Check \`etc/MACHINES' for recognized configuration names.])
1163 fi
1164
1165 machfile="m/${machine}.h"
1166 opsysfile="s/${opsys}.h"
1167
1168
1169 #### Choose a compiler.
1170 test -n "$CC" && cc_specified=yes
1171
1172 # Save the value of CFLAGS that the user specified.
1173 SPECIFIED_CFLAGS="$CFLAGS"
1174
1175 case ${with_gcc} in
1176 "yes" ) CC="gcc" GCC=yes ;;
1177 "no" ) : ${CC=cc} ;;
1178 * )
1179 esac
1180 AC_PROG_CC
1181
1182 # On Suns, sometimes $CPP names a directory.
1183 if test -n "$CPP" && test -d "$CPP"; then
1184 CPP=
1185 fi
1186
1187 #### Some systems specify a CPP to use unless we are using GCC.
1188 #### Now that we know whether we are using GCC, we can decide whether
1189 #### to use that one.
1190 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1191 then
1192 CPP="$NON_GNU_CPP"
1193 fi
1194
1195 #### Some systems specify a CC to use unless we are using GCC.
1196 #### Now that we know whether we are using GCC, we can decide whether
1197 #### to use that one.
1198 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1199 test x$cc_specified != xyes
1200 then
1201 CC="$NON_GNU_CC"
1202 fi
1203
1204 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1205 then
1206 CC="$CC $GCC_TEST_OPTIONS"
1207 fi
1208
1209 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1210 then
1211 CC="$CC $NON_GCC_TEST_OPTIONS"
1212 fi
1213
1214 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1215 then
1216 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1217 fi
1218
1219 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1220 then
1221 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1222 fi
1223
1224 #### Some other nice autoconf tests. If you add a test here which
1225 #### should make an entry in src/config.h, don't forget to add an
1226 #### #undef clause to src/config.h.in for autoconf to modify.
1227
1228 dnl checks for programs
1229 AC_PROG_LN_S
1230 AC_PROG_CPP
1231 AC_PROG_INSTALL
1232 AC_PROG_YACC
1233 if test "x$RANLIB" = x; then
1234 AC_PROG_RANLIB
1235 fi
1236
1237 dnl checks for Unix variants
1238 AC_AIX
1239
1240 #### Extract some information from the operating system and machine files.
1241
1242 AC_CHECKING([the machine- and system-dependent files to find out
1243 - which libraries the lib-src programs will want, and
1244 - whether the GNU malloc routines are usable])
1245
1246 ### First figure out CFLAGS (which we use for running the compiler here)
1247 ### and REAL_CFLAGS (which we use for real compilation).
1248 ### The two are the same except on a few systems, where they are made
1249 ### different to work around various lossages. For example,
1250 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1251 ### as implying static linking.
1252
1253 ### If the CFLAGS env var is specified, we use that value
1254 ### instead of the default.
1255
1256 ### It's not important that this name contain the PID; you can't run
1257 ### two configures in the same directory and have anything work
1258 ### anyway.
1259 tempcname="conftest.c"
1260
1261 echo '
1262 #include "'${srcdir}'/src/'${opsysfile}'"
1263 #include "'${srcdir}'/src/'${machfile}'"
1264 #ifndef LIBS_MACHINE
1265 #define LIBS_MACHINE
1266 #endif
1267 #ifndef LIBS_SYSTEM
1268 #define LIBS_SYSTEM
1269 #endif
1270 #ifndef C_SWITCH_SYSTEM
1271 #define C_SWITCH_SYSTEM
1272 #endif
1273 #ifndef C_SWITCH_MACHINE
1274 #define C_SWITCH_MACHINE
1275 #endif
1276 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1277 configure___ c_switch_system=C_SWITCH_SYSTEM
1278 configure___ c_switch_machine=C_SWITCH_MACHINE
1279
1280 #ifndef LIB_X11_LIB
1281 #define LIB_X11_LIB -lX11
1282 #endif
1283
1284 #ifndef LIBX11_MACHINE
1285 #define LIBX11_MACHINE
1286 #endif
1287
1288 #ifndef LIBX11_SYSTEM
1289 #define LIBX11_SYSTEM
1290 #endif
1291 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1292
1293 #ifdef UNEXEC
1294 configure___ unexec=UNEXEC
1295 #else
1296 configure___ unexec=unexec.o
1297 #endif
1298
1299 #ifdef SYSTEM_MALLOC
1300 configure___ system_malloc=yes
1301 #else
1302 configure___ system_malloc=no
1303 #endif
1304
1305 #ifdef USE_MMAP_FOR_BUFFERS
1306 configure___ use_mmap_for_buffers=yes
1307 #else
1308 configure___ use_mmap_for_buffers=no
1309 #endif
1310
1311 #ifndef C_DEBUG_SWITCH
1312 #define C_DEBUG_SWITCH -g
1313 #endif
1314
1315 #ifndef C_OPTIMIZE_SWITCH
1316 #ifdef __GNUC__
1317 #define C_OPTIMIZE_SWITCH -O2
1318 #else
1319 #define C_OPTIMIZE_SWITCH -O
1320 #endif
1321 #endif
1322
1323 #ifndef LD_SWITCH_MACHINE
1324 #define LD_SWITCH_MACHINE
1325 #endif
1326
1327 #ifndef LD_SWITCH_SYSTEM
1328 #define LD_SWITCH_SYSTEM
1329 #endif
1330
1331 #ifndef LD_SWITCH_X_SITE_AUX
1332 #define LD_SWITCH_X_SITE_AUX
1333 #endif
1334
1335 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1336 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1337
1338 #ifdef THIS_IS_CONFIGURE
1339
1340 /* Get the CFLAGS for tests in configure. */
1341 #ifdef __GNUC__
1342 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1343 #else
1344 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1345 #endif
1346
1347 #else /* not THIS_IS_CONFIGURE */
1348
1349 /* Get the CFLAGS for real compilation. */
1350 #ifdef __GNUC__
1351 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1352 #else
1353 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1354 #endif
1355
1356 #endif /* not THIS_IS_CONFIGURE */
1357 ' > ${tempcname}
1358
1359 # The value of CPP is a quoted variable reference, so we need to do this
1360 # to get its actual value...
1361 CPP=`eval "echo $CPP"`
1362 changequote(, )dnl
1363 eval `${CPP} -Isrc ${tempcname} \
1364 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1365 if test "x$SPECIFIED_CFLAGS" = x; then
1366 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1367 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1368 else
1369 REAL_CFLAGS="$CFLAGS"
1370 fi
1371 changequote([, ])dnl
1372 rm ${tempcname}
1373
1374 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1375
1376 ### Make sure subsequent tests use flags consistent with the build flags.
1377
1378 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1379 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1380 else
1381 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1382 fi
1383
1384 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1385 AC_SYS_LARGEFILE
1386
1387 if test "${with_sound}" != "no"; then
1388 # Sound support for GNU/Linux and the free BSDs.
1389 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1390 # Emulation library used on NetBSD.
1391 AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1392 AC_SUBST(LIBSOUND)
1393 fi
1394
1395 dnl checks for header files
1396 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1397 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1398 termcap.h stdio_ext.h fcntl.h term.h strings.h coff.h)
1399 AC_HEADER_STDC
1400 AC_HEADER_TIME
1401 AC_DECL_SYS_SIGLIST
1402 AC_HEADER_SYS_WAIT
1403
1404 dnl Some systems have utime.h but don't declare the struct anyplace.
1405 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1406 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1407 #include <sys/time.h>
1408 #include <time.h>
1409 #else
1410 #ifdef HAVE_SYS_TIME_H
1411 #include <sys/time.h>
1412 #else
1413 #include <time.h>
1414 #endif
1415 #endif
1416 #ifdef HAVE_UTIME_H
1417 #include <utime.h>
1418 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1419 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1420 if test $emacs_cv_struct_utimbuf = yes; then
1421 AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1422 fi
1423
1424 dnl checks for typedefs
1425 AC_TYPE_SIGNAL
1426
1427 dnl Check for speed_t typedef.
1428 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1429 AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1430 emacs_cv_speed_t=yes, emacs_cv_speed_t=no))
1431 if test $emacs_cv_speed_t = yes; then
1432 AC_DEFINE(HAVE_SPEED_T, 1, [Define to 1 if `speed_t' is declared by <termios.h>.])
1433 fi
1434
1435 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1436 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1437 #include <sys/time.h>
1438 #include <time.h>
1439 #else
1440 #ifdef HAVE_SYS_TIME_H
1441 #include <sys/time.h>
1442 #else
1443 #include <time.h>
1444 #endif
1445 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1446 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1447 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1448 if test $emacs_cv_struct_timeval = yes; then
1449 AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1450 fi
1451
1452 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1453 AC_TRY_COMPILE([#include <math.h>],
1454 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1455 emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1456 HAVE_EXCEPTION=$emacs_cv_struct_exception
1457 if test $emacs_cv_struct_exception != yes; then
1458 AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1459 fi
1460
1461 dnl checks for structure members
1462 AC_STRUCT_TM
1463 AC_STRUCT_TIMEZONE
1464 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1465 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1466 [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1467 [#include <time.h>])
1468
1469 dnl checks for compiler characteristics
1470
1471 dnl Testing __STDC__ to determine prototype support isn't good enough.
1472 dnl DEC C, for instance, doesn't define it with default options, and
1473 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1474 dnl and void *.
1475 AC_C_PROTOTYPES
1476 AC_C_VOLATILE
1477 AC_C_CONST
1478 dnl This isn't useful because we can't turn on use of `inline' unless
1479 dnl the compiler groks `extern inline'.
1480 dnl AC_C_INLINE
1481 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1482 [AC_TRY_COMPILE(, [void * foo;],
1483 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1484 if test $emacs_cv_void_star = yes; then
1485 AC_DEFINE(POINTER_TYPE, void)
1486 else
1487 AC_DEFINE(POINTER_TYPE, char)
1488 fi
1489 AH_TEMPLATE(POINTER_TYPE,
1490 [Define as `void' if your compiler accepts `void *'; otherwise
1491 define as `char'.])dnl
1492
1493 dnl check for Make feature
1494 AC_PROG_MAKE_SET
1495
1496 dnl checks for operating system services
1497 AC_SYS_LONG_FILE_NAMES
1498
1499 #### Choose a window system.
1500
1501 AC_PATH_X
1502 if test "$no_x" = yes; then
1503 window_system=none
1504 else
1505 window_system=x11
1506 fi
1507
1508 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1509 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1510 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1511 x_default_search_path=""
1512 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1513 x_search_path="\
1514 ${x_library}/X11/%L/%T/%N%C%S:\
1515 ${x_library}/X11/%l/%T/%N%C%S:\
1516 ${x_library}/X11/%T/%N%C%S:\
1517 ${x_library}/X11/%L/%T/%N%S:\
1518 ${x_library}/X11/%l/%T/%N%S:\
1519 ${x_library}/X11/%T/%N%S"
1520 if test x"${x_default_search_path}" = x; then
1521 x_default_search_path=${x_search_path}
1522 else
1523 x_default_search_path="${x_search_path}:${x_default_search_path}"
1524 fi
1525 done
1526 fi
1527 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1528 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1529 fi
1530
1531 if test x"${x_includes}" = x; then
1532 bitmapdir=/usr/include/X11/bitmaps
1533 else
1534 # accumulate include directories that have X11 bitmap subdirectories
1535 bmd_acc="dummyval"
1536 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1537 if test -d "${bmd}/X11/bitmaps"; then
1538 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1539 fi
1540 if test -d "${bmd}/bitmaps"; then
1541 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1542 fi
1543 done
1544 if test ${bmd_acc} != "dummyval"; then
1545 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1546 fi
1547 fi
1548
1549 case "${window_system}" in
1550 x11 )
1551 HAVE_X_WINDOWS=yes
1552 HAVE_X11=yes
1553 case "${with_x_toolkit}" in
1554 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1555 motif ) USE_X_TOOLKIT=MOTIF ;;
1556 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1557 no ) USE_X_TOOLKIT=none ;;
1558 dnl If user did not say whether to use a toolkit,
1559 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1560 * ) USE_X_TOOLKIT=maybe ;;
1561 esac
1562 ;;
1563 none )
1564 HAVE_X_WINDOWS=no
1565 HAVE_X11=no
1566 USE_X_TOOLKIT=none
1567 ;;
1568 esac
1569
1570 ### If we're using X11, we should use the X menu package.
1571 HAVE_MENUS=no
1572 case ${HAVE_X11} in
1573 yes ) HAVE_MENUS=yes ;;
1574 esac
1575
1576 if test "${opsys}" = "hpux9"; then
1577 case "${x_libraries}" in
1578 *X11R4* )
1579 opsysfile="s/hpux9-x11r4.h"
1580 ;;
1581 esac
1582 fi
1583
1584 if test "${opsys}" = "hpux9shr"; then
1585 case "${x_libraries}" in
1586 *X11R4* )
1587 opsysfile="s/hpux9shxr4.h"
1588 ;;
1589 esac
1590 fi
1591
1592 ### Compute the unexec source name from the object name.
1593 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1594
1595 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1596 # Assume not, until told otherwise.
1597 GNU_MALLOC=yes
1598 doug_lea_malloc=yes
1599 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1600 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1601 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1602 emacs_cv_var___after_morecore_hook,
1603 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1604 emacs_cv_var___after_morecore_hook=yes,
1605 emacs_cv_var___after_morecore_hook=no)])
1606 if test $emacs_cv_var___after_morecore_hook = no; then
1607 doug_lea_malloc=no
1608 fi
1609 if test "${system_malloc}" = "yes"; then
1610 GNU_MALLOC=no
1611 GNU_MALLOC_reason="
1612 (The GNU allocators don't work with this system configuration.)"
1613 fi
1614 if test "$doug_lea_malloc" = "yes" ; then
1615 if test "$GNU_MALLOC" = yes ; then
1616 GNU_MALLOC_reason="
1617 (Using Doug Lea's new malloc from the GNU C Library.)"
1618 fi
1619 AC_DEFINE(DOUG_LEA_MALLOC, 1,
1620 [Define to 1 if you are using the GNU C Library.])
1621 fi
1622
1623 if test x"${REL_ALLOC}" = x; then
1624 REL_ALLOC=${GNU_MALLOC}
1625 fi
1626
1627 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1628 dnl the system configuration file (s/*.h) to turn the use of mmap
1629 dnl in the relocating allocator on.
1630
1631 AC_FUNC_MMAP
1632 if test $use_mmap_for_buffers = yes; then
1633 REL_ALLOC=no
1634 fi
1635
1636 LIBS="$libsrc_libs $LIBS"
1637
1638 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1639 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1640 AC_CHECK_LIB(dnet, dnet_ntoa)
1641 dnl This causes -lresolv to get used in subsequent tests,
1642 dnl which causes failures on some systems such as HPUX 9.
1643 dnl AC_CHECK_LIB(resolv, gethostbyname)
1644
1645 dnl FIXME replace main with a function we actually want from this library.
1646 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1647
1648 AC_CHECK_LIB(pthreads, cma_open)
1649
1650 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1651 if test -d /usr/X386/include; then
1652 HAVE_XFREE386=yes
1653 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1654 else
1655 HAVE_XFREE386=no
1656 fi
1657 AC_MSG_RESULT($HAVE_XFREE386)
1658
1659 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1660 # for the tests that follow. We set it back to REAL_CFLAGS later on.
1661
1662 REAL_CPPFLAGS="$CPPFLAGS"
1663
1664 if test "${HAVE_X11}" = "yes"; then
1665 DEFS="$C_SWITCH_X_SITE $DEFS"
1666 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1667 LIBS="$LIBX $LIBS"
1668 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1669 CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1670
1671 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1672 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1673 # but it's more convenient here to set LD_RUN_PATH
1674 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1675 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1676 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1677 export LD_RUN_PATH
1678 fi
1679
1680 if test "${opsys}" = "gnu-linux"; then
1681 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1682 AC_TRY_LINK([],
1683 [XOpenDisplay ("foo");],
1684 [xlinux_first_failure=no],
1685 [xlinux_first_failure=yes])
1686 if test "${xlinux_first_failure}" = "yes"; then
1687 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1688 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1689 OLD_CPPFLAGS="$CPPFLAGS"
1690 OLD_LIBS="$LIBS"
1691 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1692 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1693 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1694 LIBS="$LIBS -b i486-linuxaout"
1695 AC_TRY_LINK([],
1696 [XOpenDisplay ("foo");],
1697 [xlinux_second_failure=no],
1698 [xlinux_second_failure=yes])
1699 if test "${xlinux_second_failure}" = "yes"; then
1700 # If we get the same failure with -b, there is no use adding -b.
1701 # So take it out. This plays safe.
1702 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1703 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1704 CPPFLAGS="$OLD_CPPFLAGS"
1705 LIBS="$OLD_LIBS"
1706 AC_MSG_RESULT(no)
1707 else
1708 AC_MSG_RESULT(yes)
1709 fi
1710 else
1711 AC_MSG_RESULT(no)
1712 fi
1713 fi
1714
1715 # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1716 # header files included from there.
1717 AC_MSG_CHECKING(for Xkb)
1718 AC_TRY_LINK([#include <X11/Xlib.h>
1719 #include <X11/XKBlib.h>],
1720 [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1721 emacs_xkb=yes, emacs_xkb=no)
1722 AC_MSG_RESULT($emacs_xkb)
1723 if test $emacs_xkb = yes; then
1724 AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1725 fi
1726
1727 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1728 XScreenNumberOfScreen XSetWMProtocols)
1729 fi
1730
1731 if test "${window_system}" = "x11"; then
1732 AC_MSG_CHECKING(X11 version 6)
1733 AC_CACHE_VAL(emacs_cv_x11_version_6,
1734 [AC_TRY_LINK([#include <X11/Xlib.h>],
1735 [#if XlibSpecificationRelease < 6
1736 fail;
1737 #endif
1738 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1739 if test $emacs_cv_x11_version_6 = yes; then
1740 AC_MSG_RESULT(6 or newer)
1741 AC_DEFINE(HAVE_X11R6, 1,
1742 [Define to 1 if you have the X11R6 or newer version of Xlib.])
1743 else
1744 AC_MSG_RESULT(before 6)
1745 fi
1746 fi
1747
1748 if test "${window_system}" = "x11"; then
1749 AC_MSG_CHECKING(X11 version 5)
1750 AC_CACHE_VAL(emacs_cv_x11_version_5,
1751 [AC_TRY_LINK([#include <X11/Xlib.h>],
1752 [#if XlibSpecificationRelease < 5
1753 fail;
1754 #endif
1755 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
1756 if test $emacs_cv_x11_version_5 = yes; then
1757 AC_MSG_RESULT(5 or newer)
1758 HAVE_X11R5=yes
1759 AC_DEFINE(HAVE_X11R5, 1,
1760 [Define to 1 if you have the X11R5 or newer version of Xlib.])
1761 else
1762 HAVE_X11R5=no
1763 AC_MSG_RESULT(before 5)
1764 fi
1765 fi
1766
1767 dnl Do not put whitespace before the #include statements below.
1768 dnl Older compilers (eg sunos4 cc) choke on it.
1769 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1770 if test x"${HAVE_X11R5}" = xyes; then
1771 AC_MSG_CHECKING(X11 version 5 with Xaw)
1772 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1773 [AC_TRY_LINK([
1774 #include <X11/Intrinsic.h>
1775 #include <X11/Xaw/Simple.h>],
1776 [],
1777 emacs_cv_x11_version_5_with_xaw=yes,
1778 emacs_cv_x11_version_5_with_xaw=no)])
1779 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1780 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1781 USE_X_TOOLKIT=LUCID
1782 else
1783 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1784 USE_X_TOOLKIT=none
1785 fi
1786 else
1787 USE_X_TOOLKIT=none
1788 fi
1789 fi
1790
1791 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1792
1793 if test "${USE_X_TOOLKIT}" != "none"; then
1794 AC_MSG_CHECKING(X11 toolkit version)
1795 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1796 [AC_TRY_LINK([#include <X11/Intrinsic.h>],
1797 [#if XtSpecificationRelease < 6
1798 fail;
1799 #endif
1800 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
1801 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1802 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1803 AC_MSG_RESULT(6 or newer)
1804 AC_DEFINE(HAVE_X11XTR6, 1,
1805 [Define to 1 if you have the X11R6 or newer version of Xt.])
1806 else
1807 AC_MSG_RESULT(before 6)
1808 fi
1809
1810 dnl If using toolkit, check whether libXmu.a exists.
1811 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1812 OLDLIBS="$LIBS"
1813 if test x$HAVE_X11XTR6 = xyes; then
1814 LIBS="-lXt -lSM -lICE $LIBS"
1815 else
1816 LIBS="-lXt $LIBS"
1817 fi
1818 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1819 test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
1820 fi
1821
1822 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
1823 if test "${HAVE_X11}" = "yes"; then
1824 if test "${USE_X_TOOLKIT}" != "none"; then
1825 AC_CHECK_LIB(Xext, XShapeQueryExtension)
1826 fi
1827 fi
1828
1829 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1830 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1831 [AC_TRY_COMPILE([#include <Xm/Xm.h>],
1832 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1833 int x = 5;
1834 #else
1835 Motif version prior to 2.1.
1836 #endif],
1837 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
1838 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1839 if test $emacs_cv_motif_version_2_1 = yes; then
1840 HAVE_LIBXP=no
1841 AC_DEFINE(HAVE_MOTIF_2_1, 1,
1842 [Define to 1 if you have Motif 2.1 or newer.])
1843 AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
1844 if test ${HAVE_LIBXP} = yes; then
1845 AC_DEFINE(HAVE_LIBXP, 1,
1846 [Define to 1 if you have the Xp library (-lXp).])
1847 fi
1848 fi
1849 fi
1850
1851 ### Is -lXaw3d available?
1852 HAVE_XAW3D=no
1853 if test "${HAVE_X11}" = "yes"; then
1854 if test "${USE_X_TOOLKIT}" != "none"; then
1855 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
1856 AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes))
1857 if test "${HAVE_XAW3D}" = "yes"; then
1858 AC_DEFINE(HAVE_XAW3D, 1,
1859 [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1860 fi
1861 fi
1862 fi
1863
1864 dnl Use toolkit scroll bars if configured for X toolkit and either
1865 dnl using Motif or Xaw3d is available, and unless
1866 dnl --with-toolkit-scroll-bars=no was specified.
1867
1868 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
1869 [Define to 1 if we should use toolkit scroll bars.])dnl
1870 USE_TOOLKIT_SCROLL_BARS=no
1871 if test "${with_toolkit_scroll_bars}" != "no"; then
1872 if test "${USE_X_TOOLKIT}" != "none"; then
1873 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1874 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1875 HAVE_XAW3D=no
1876 USE_TOOLKIT_SCROLL_BARS=yes
1877 elif test "${HAVE_XAW3D}" = "yes"; then
1878 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1879 USE_TOOLKIT_SCROLL_BARS=yes
1880 fi
1881 fi
1882 fi
1883
1884 dnl Don't use X11 input methods if user specifies he doesn't want it
1885 dnl with `--with-xim=no'.
1886
1887 if test "${with_xim}" != "no"; then
1888 AC_DEFINE(USE_XIM, 1,
1889 [Define to 1 if we should use XIM, if it is available.])
1890 fi
1891
1892 ### Use -lXpm if available, unless `--with-xpm=no'.
1893 HAVE_XPM=no
1894 if test "${HAVE_X11}" = "yes"; then
1895 if test "${with_xpm}" != "no"; then
1896 AC_CHECK_HEADER(X11/xpm.h,
1897 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
1898 if test "${HAVE_XPM}" = "yes"; then
1899 AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
1900 AC_EGREP_CPP(no_return_alloc_pixels,
1901 [#include "X11/xpm.h"
1902 #ifndef XpmReturnAllocPixels
1903 no_return_alloc_pixels
1904 #endif
1905 ], HAVE_XPM=no, HAVE_XPM=yes)
1906
1907 if test "${HAVE_XPM}" = "yes"; then
1908 AC_MSG_RESULT(yes)
1909 else
1910 AC_MSG_RESULT(no)
1911 fi
1912 fi
1913 fi
1914
1915 if test "${HAVE_XPM}" = "yes"; then
1916 AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
1917 fi
1918 fi
1919
1920 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1921 HAVE_JPEG=no
1922 if test "${HAVE_X11}" = "yes"; then
1923 if test "${with_jpeg}" != "no"; then
1924 dnl Checking for jpeglib.h can lose becsue of a redefinition of
1925 dnl HAVE_STDLIB_H.
1926 AC_CHECK_HEADER(jerror.h,
1927 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
1928 fi
1929
1930 AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
1931 if test "${HAVE_JPEG}" = "yes"; then
1932 AC_DEFINE(HAVE_JPEG)
1933 AC_EGREP_CPP(
1934 changequote({, })dnl avoid leadingspace on the next line
1935 {version= *(6[2-9]|[7-9][0-9])},
1936 changequote([, ])dnl
1937 [#include <jpeglib.h>
1938 version=JPEG_LIB_VERSION
1939 ],
1940 AC_DEFINE(HAVE_JPEG),
1941 [AC_MSG_WARN([libjpeg found, but not version 6b or later])
1942 HAVE_JPEG=no])
1943 fi
1944 fi
1945
1946 ### Use -lpng if available, unless `--with-png=no'.
1947 HAVE_PNG=no
1948 if test "${HAVE_X11}" = "yes"; then
1949 if test "${with_png}" != "no"; then
1950 AC_CHECK_HEADER(png.h,
1951 AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm))
1952 fi
1953
1954 if test "${HAVE_PNG}" = "yes"; then
1955 AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
1956 fi
1957 fi
1958
1959 ### Use -ltiff if available, unless `--with-tiff=no'.
1960 HAVE_TIFF=no
1961 if test "${HAVE_X11}" = "yes"; then
1962 if test "${with_tiff}" != "no"; then
1963 AC_CHECK_HEADER(tiffio.h,
1964 tifflibs="-lz -lm"
1965 # At least one tiff package requires the jpeg library.
1966 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1967 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
1968 fi
1969
1970 if test "${HAVE_TIFF}" = "yes"; then
1971 AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
1972 fi
1973 fi
1974
1975 ### Use -lgif if available, unless `--with-gif=no'.
1976 HAVE_GIF=no
1977 if test "${HAVE_X11}" = "yes"; then
1978 if test "${with_gif}" != "no"; then
1979 AC_CHECK_HEADER(gif_lib.h,
1980 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
1981 # Earlier versions can crash Emacs.
1982 AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
1983 fi
1984
1985 if test "${HAVE_GIF}" = "yes"; then
1986 AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
1987 fi
1988 fi
1989
1990 ### Use Mac OS X Carbon API to implement GUI.
1991 HAVE_CARBON=no
1992 if test "${with_carbon}" != "no"; then
1993 AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1994 fi
1995
1996 if test "${HAVE_CARBON}" = "yes"; then
1997 AC_DEFINE(HAVE_CARBON)
1998 fi
1999
2000 ### Use session management (-lSM -lICE) if available
2001 HAVE_X_SM=no
2002 if test "${HAVE_X11}" = "yes"; then
2003 AC_CHECK_HEADER(X11/SM/SMlib.h,
2004 AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, -lICE))
2005
2006 if test "${HAVE_X_SM}" = "yes"; then
2007 AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2008 case "$LIBS" in
2009 *-lSM*) ;;
2010 *) LIBS="-lSM -lICE $LIBS" ;;
2011 esac
2012 fi
2013 fi
2014
2015 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2016 AC_CACHE_CHECK(whether netdb declares h_errno,
2017 emacs_cv_netdb_declares_h_errno,
2018 [AC_TRY_LINK([#include <netdb.h>],
2019 [return h_errno;],
2020 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2021 if test $emacs_cv_netdb_declares_h_errno = yes; then
2022 AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2023 fi
2024
2025 AC_FUNC_ALLOCA
2026
2027 # fmod, logb, and frexp are found in -lm on most systems.
2028 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2029 AC_CHECK_LIB(m, sqrt)
2030
2031 # Check for mail-locking functions in a "mail" library
2032 AC_CHECK_LIB(mail, maillock)
2033 dnl Debian, at least:
2034 dnl AC_CHECK_LIB(lockfile, maillock, [AC_DEFINE(HAVE_LIBMAIL)])
2035 AC_CHECK_LIB(lockfile, maillock)
2036 # If we have the shared liblockfile, assume we must use it for mail
2037 # locking (e.g. Debian). If we couldn't link against liblockfile
2038 # (no liblockfile.a installed), ensure that we don't need to.
2039 if test "$ac_cv_lib_lockfile_maillock" = no; then
2040 dnl This works for files generally, not just executables.
2041 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
2042 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2043 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2044 if test $ac_cv_prog_liblockfile = yes; then
2045 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2046 This probably means that movemail could lose mail.
2047 There may be a \`development' package to install containing liblockfile.])
2048 else AC_DEFINE(LIBMAIL, -llockfile, [Define to -llockfile if it is usable.])
2049 fi
2050 else :
2051 fi
2052 AC_CHECK_FUNCS(touchlock)
2053 AC_CHECK_HEADERS(maillock.h)
2054
2055 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2056 rename closedir mkdir rmdir sysinfo \
2057 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2058 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2059 utimes setrlimit setpgid getcwd getwd shutdown strftime getaddrinfo \
2060 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2061 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2062 gai_strerror mkstemp getline getdelim)
2063
2064 AC_CHECK_HEADERS(sys/un.h)
2065
2066 AC_FUNC_MKTIME
2067 if test "$ac_cv_func_working_mktime" = no; then
2068 AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2069 fi
2070
2071 AC_FUNC_GETLOADAVG
2072
2073 AC_FUNC_FSEEKO
2074
2075 # UNIX98 PTYs.
2076 AC_CHECK_FUNCS(grantpt)
2077
2078 # PTY-related GNU extensions.
2079 AC_CHECK_FUNCS(getpt)
2080
2081 # Check this now, so that we will NOT find the above functions in ncurses.
2082 # That is because we have not set up to link ncurses in lib-src.
2083 # It's better to believe a function is not available
2084 # than to expect to find it in ncurses.
2085 AC_CHECK_LIB(ncurses, tparm)
2086
2087 # Do we need the Hesiod library to provide the support routines?
2088 if test "$with_hesiod" = yes ; then
2089 # Don't set $LIBS here -- see comments above.
2090 resolv=no
2091 AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2092 [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2093 [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2094 if test "$resolv" = yes ; then
2095 RESOLVLIB=-lresolv
2096 AC_DEFINE(HAVE_LIBRESOLV, 1,
2097 [Define to 1 if you have the resolv library (-lresolv).])
2098 else
2099 RESOLVLIB=
2100 fi
2101 AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2102 AC_DEFINE(HAVE_LIBHESIOD, 1,
2103 [Define to 1 if you have the hesiod library (-lhesiod).]),
2104 :, $RESOLVLIB)])
2105 fi
2106
2107 # These tell us which Kerberos-related libraries to use.
2108 if test "${with_kerberos+set}" = set; then
2109 AC_CHECK_LIB(com_err, com_err)
2110 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2111 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2112 AC_CHECK_LIB(krb5, krb5_init_context)
2113 if test "${with_kerberos5+set}" != set; then
2114 AC_CHECK_LIB(des425, des_cbc_encrypt,,
2115 AC_CHECK_LIB(des, des_cbc_encrypt))
2116 AC_CHECK_LIB(krb4, krb_get_cred,,
2117 AC_CHECK_LIB(krb, krb_get_cred))
2118 fi
2119
2120 if test "${with_kerberos5+set}" = set; then
2121 AC_CHECK_HEADERS(krb5.h)
2122 else
2123 AC_CHECK_HEADERS(des.h,,
2124 [AC_CHECK_HEADERS(kerberosIV/des.h,,
2125 [AC_CHECK_HEADERS(kerberos/des.h)])])
2126 AC_CHECK_HEADERS(krb.h,,
2127 [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2128 [AC_CHECK_HEADERS(kerberos/krb.h)])])
2129 fi
2130 AC_CHECK_HEADERS(com_err.h)
2131 fi
2132
2133 # Solaris requires -lintl if you want strerror (which calls dgettext)
2134 # to return localized messages.
2135 AC_CHECK_LIB(intl, dgettext)
2136
2137 AC_MSG_CHECKING(whether localtime caches TZ)
2138 AC_CACHE_VAL(emacs_cv_localtime_cache,
2139 [if test x$ac_cv_func_tzset = xyes; then
2140 AC_TRY_RUN([#include <time.h>
2141 extern char **environ;
2142 unset_TZ ()
2143 {
2144 char **from, **to;
2145 for (to = from = environ; (*to = *from); from++)
2146 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2147 to++;
2148 }
2149 char TZ_GMT0[] = "TZ=GMT0";
2150 char TZ_PST8[] = "TZ=PST8";
2151 main()
2152 {
2153 time_t now = time ((time_t *) 0);
2154 int hour_GMT0, hour_unset;
2155 if (putenv (TZ_GMT0) != 0)
2156 exit (1);
2157 hour_GMT0 = localtime (&now)->tm_hour;
2158 unset_TZ ();
2159 hour_unset = localtime (&now)->tm_hour;
2160 if (putenv (TZ_PST8) != 0)
2161 exit (1);
2162 if (localtime (&now)->tm_hour == hour_GMT0)
2163 exit (1);
2164 unset_TZ ();
2165 if (localtime (&now)->tm_hour != hour_unset)
2166 exit (1);
2167 exit (0);
2168 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2169 [# If we have tzset, assume the worst when cross-compiling.
2170 emacs_cv_localtime_cache=yes])
2171 else
2172 # If we lack tzset, report that localtime does not cache TZ,
2173 # since we can't invalidate the cache if we don't have tzset.
2174 emacs_cv_localtime_cache=no
2175 fi])dnl
2176 AC_MSG_RESULT($emacs_cv_localtime_cache)
2177 if test $emacs_cv_localtime_cache = yes; then
2178 AC_DEFINE(LOCALTIME_CACHE, 1,
2179 [Define to 1 if localtime caches TZ.])
2180 fi
2181
2182 if test "x$HAVE_TIMEVAL" = xyes; then
2183 AC_CHECK_FUNCS(gettimeofday)
2184 if test $ac_cv_func_gettimeofday = yes; then
2185 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2186 emacs_cv_gettimeofday_two_arguments,
2187 [AC_TRY_COMPILE([
2188 #ifdef TIME_WITH_SYS_TIME
2189 #include <sys/time.h>
2190 #include <time.h>
2191 #else
2192 #ifdef HAVE_SYS_TIME_H
2193 #include <sys/time.h>
2194 #else
2195 #include <time.h>
2196 #endif
2197 #endif],
2198 [struct timeval time;
2199 gettimeofday (&time, 0);],
2200 emacs_cv_gettimeofday_two_arguments=yes,
2201 emacs_cv_gettimeofday_two_arguments=no)])
2202 if test $emacs_cv_gettimeofday_two_arguments = no; then
2203 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2204 [Define to 1 if gettimeofday accepts only one argument.])
2205 fi
2206 fi
2207 fi
2208
2209 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2210 if test "$ac_cv_func_gettimeofday" = yes; then
2211 AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2212 [AC_TRY_COMPILE([#include <sys/time.h>],
2213 [struct timezone tz;],
2214 dnl It may be that we can't call gettimeofday with a non-null pointer,
2215 dnl even though we have struct timezone (e.g. HPUX). In that case
2216 dnl we'll lie about struct timezone.
2217 [AC_TRY_RUN([
2218 #ifdef TIME_WITH_SYS_TIME
2219 #include <sys/time.h>
2220 #include <time.h>
2221 #else
2222 #ifdef HAVE_SYS_TIME_H
2223 #include <sys/time.h>
2224 #else
2225 #include <time.h>
2226 #endif
2227 #endif
2228 main () {
2229 struct timeval time;
2230 struct timezone dummy;
2231 exit (gettimeofday (&time, &dummy));
2232 }],
2233 emacs_cv_struct_timezone=yes,
2234 emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2235 emacs_cv_struct_timezone=no)])
2236 fi
2237
2238 ok_so_far=yes
2239 AC_CHECK_FUNC(socket, , ok_so_far=no)
2240 if test $ok_so_far = yes; then
2241 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2242 fi
2243 if test $ok_so_far = yes; then
2244 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2245 fi
2246 if test $ok_so_far = yes; then
2247 AC_DEFINE(HAVE_INET_SOCKETS, 1,
2248 [Define to 1 if you have inet sockets.])
2249 fi
2250
2251 if test -f /usr/lpp/X11/bin/smt.exp; then
2252 AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2253 [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2254 fi
2255
2256 AC_MSG_CHECKING(whether system supports dynamic ptys)
2257 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2258 AC_MSG_RESULT(yes)
2259 AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2260 else
2261 AC_MSG_RESULT(no)
2262 fi
2263
2264 AC_FUNC_FORK
2265
2266 # Fixme: This should be replaced when we have autoconf 2.14.
2267 AC_SIZE_T
2268
2269 # Set up the CFLAGS for real compilation, so we can substitute it.
2270 CFLAGS="$REAL_CFLAGS"
2271 CPPFLAGS="$REAL_CPPFLAGS"
2272
2273 changequote(, )dnl
2274 #### Find out which version of Emacs this is.
2275 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2276 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
2277 changequote([, ])dnl
2278 if test x"${version}" = x; then
2279 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
2280 fi
2281
2282 ### Specify what sort of things we'll be editing into Makefile and config.h.
2283 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2284 AC_SUBST(version)
2285 AC_SUBST(configuration)
2286 AC_SUBST(canonical)
2287 AC_SUBST(srcdir)
2288 AC_SUBST(prefix)
2289 AC_SUBST(exec_prefix)
2290 AC_SUBST(bindir)
2291 AC_SUBST(datadir)
2292 AC_SUBST(sharedstatedir)
2293 AC_SUBST(libexecdir)
2294 AC_SUBST(mandir)
2295 AC_SUBST(infodir)
2296 AC_SUBST(lispdir)
2297 AC_SUBST(locallisppath)
2298 AC_SUBST(lisppath)
2299 AC_SUBST(x_default_search_path)
2300 AC_SUBST(etcdir)
2301 AC_SUBST(archlibdir)
2302 AC_SUBST(docdir)
2303 AC_SUBST(bitmapdir)
2304 AC_SUBST(gamedir)
2305 AC_SUBST(gameuser)
2306 AC_SUBST(c_switch_system)
2307 AC_SUBST(c_switch_machine)
2308 AC_SUBST(LD_SWITCH_X_SITE)
2309 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2310 AC_SUBST(C_SWITCH_X_SITE)
2311 AC_SUBST(CFLAGS)
2312 AC_SUBST(X_TOOLKIT_TYPE)
2313 AC_SUBST(machfile)
2314 AC_SUBST(opsysfile)
2315 AC_SUBST(GETLOADAVG_LIBS)
2316
2317 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}",
2318 [Define to the canonical Emacs configuration name.])
2319 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2320 [Define to the options passed to configure.])
2321 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}",
2322 [Define to the used machine dependent file.])
2323 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2324 [Define to the used os dependent file.])
2325 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2326 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2327 may need to deal with X Windows. For instance, if you've defined
2328 HAVE_X_WINDOWS above and your X libraries aren't in a place that
2329 your loader can find on its own, you might want to add "-L/..." or
2330 something similar.])
2331 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2332 [Define LD_SWITCH_X_SITE_AUX with an -R option
2333 in case it's needed (for Solaris, for example).])
2334 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE},
2335 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2336 may need to deal with X Windows. For instance, if you've defined
2337 HAVE_X_WINDOWS above and your X include files aren't in a place
2338 that your compiler can find on its own, you might want to add
2339 "-I/..." or something similar.])
2340 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC},
2341 [Define to the unexec source file name.])
2342
2343 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2344 AC_DEFINE(HAVE_X_WINDOWS, 1,
2345 [Define to 1 if you want to use the X window system.])
2346 fi
2347 if test "${USE_X_TOOLKIT}" != "none" ; then
2348 AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2349 fi
2350 if test "${HAVE_X11}" = "yes" ; then
2351 AC_DEFINE(HAVE_X11, 1,
2352 [Define to 1 if you want to use version 11 of X windows.
2353 Otherwise, Emacs expects to use version 10.])
2354 fi
2355 if test "${HAVE_XFREE386}" = "yes" ; then
2356 AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2357 fi
2358 if test "${HAVE_MENUS}" = "yes" ; then
2359 AC_DEFINE(HAVE_MENUS, 1,
2360 [Define to 1 if you have mouse menus.
2361 (This is automatic if you use X, but the option to specify it remains.)
2362 It is also defined with other window systems that support xmenu.c.])
2363 fi
2364 if test "${GNU_MALLOC}" = "yes" ; then
2365 AC_DEFINE(GNU_MALLOC, 1,
2366 [Define to 1 if you want to use the GNU memory allocator.])
2367 fi
2368 if test "${REL_ALLOC}" = "yes" ; then
2369 AC_DEFINE(REL_ALLOC, 1,
2370 [Define REL_ALLOC if you want to use the relocating allocator for
2371 buffer space.])
2372 fi
2373
2374 AC_CHECK_HEADERS(nlist.h, [AC_DEFINE(NLIST_STRUCT, 1,
2375 [Define to 1 if you have <nlist.h>.])])
2376
2377 AH_TOP([/* GNU Emacs site configuration template file. -*- C -*-
2378 Copyright (C) 1988, 1993, 1994, 1999, 2000 Free Software Foundation, Inc.
2379
2380 This file is part of GNU Emacs.
2381
2382 GNU Emacs is free software; you can redistribute it and/or modify
2383 it under the terms of the GNU General Public License as published by
2384 the Free Software Foundation; either version 2, or (at your option)
2385 any later version.
2386
2387 GNU Emacs is distributed in the hope that it will be useful,
2388 but WITHOUT ANY WARRANTY; without even the implied warranty of
2389 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
2390 GNU General Public License for more details.
2391
2392 You should have received a copy of the GNU General Public License
2393 along with GNU Emacs; see the file COPYING. If not, write to the
2394 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
2395 Boston, MA 02111-1307, USA. */
2396
2397
2398 /* No code in Emacs #includes config.h twice, but some of the code
2399 intended to work with other packages as well (like gmalloc.c)
2400 think they can include it as many times as they like. */
2401 #ifndef EMACS_CONFIG_H
2402 #define EMACS_CONFIG_H
2403 ])dnl
2404
2405 AH_BOTTOM([
2406 /* If we're using any sort of window system, define some consequences. */
2407 #ifdef HAVE_X_WINDOWS
2408 #define HAVE_WINDOW_SYSTEM
2409 #define MULTI_KBOARD
2410 #define HAVE_MOUSE
2411 #endif
2412
2413 /* Define USER_FULL_NAME to return a string
2414 that is the user's full name.
2415 It can assume that the variable `pw'
2416 points to the password file entry for this user.
2417
2418 At some sites, the pw_gecos field contains
2419 the user's full name. If neither this nor any other
2420 field contains the right thing, use pw_name,
2421 giving the user's login name, since that is better than nothing. */
2422 #define USER_FULL_NAME pw->pw_gecos
2423
2424 /* Define AMPERSAND_FULL_NAME if you use the convention
2425 that & in the full name stands for the login id. */
2426 /* Turned on June 1996 supposing nobody will mind it. */
2427 #define AMPERSAND_FULL_NAME
2428
2429 /* Define HAVE_SOUND if we have sound support. We know it works
2430 and compiles only on the specified platforms. For others,
2431 it probably doesn't make sense to try. */
2432
2433 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2434 #ifdef HAVE_MACHINE_SOUNDCARD_H
2435 #define HAVE_SOUND 1
2436 #endif
2437 #ifdef HAVE_SYS_SOUNDCARD_H
2438 #define HAVE_SOUND 1
2439 #endif
2440 #ifdef HAVE_SOUNDCARD_H
2441 #define HAVE_SOUND 1
2442 #endif
2443 #endif /* __FreeBSD__ || __NetBSD__ || __linux__ */
2444
2445 /* If using GNU, then support inline function declarations. */
2446 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2447 generally, because even if non-gcc compilers accept `inline', they
2448 may reject `extern inline'. */
2449 #ifdef __GNUC__
2450 #define INLINE __inline__
2451 #else
2452 #define INLINE
2453 #endif
2454
2455 /* Include the os and machine dependent files. */
2456 #include config_opsysfile
2457 #include config_machfile
2458
2459 /* Load in the conversion definitions if this system
2460 needs them and the source file being compiled has not
2461 said to inhibit this. There should be no need for you
2462 to alter these lines. */
2463
2464 #ifdef SHORTNAMES
2465 #ifndef NO_SHORTNAMES
2466 #include "../shortnames/remap.h"
2467 #endif /* not NO_SHORTNAMES */
2468 #endif /* SHORTNAMES */
2469
2470 /* If no remapping takes place, static variables cannot be dumped as
2471 pure, so don't worry about the `static' keyword. */
2472 #ifdef NO_REMAP
2473 #undef static
2474 #endif
2475
2476 /* Define `subprocesses' should be defined if you want to
2477 have code for asynchronous subprocesses
2478 (as used in M-x compile and M-x shell).
2479 These do not work for some USG systems yet;
2480 for the ones where they work, the s/SYSTEM.h file defines this flag. */
2481
2482 #ifndef VMS
2483 #ifndef USG
2484 /* #define subprocesses */
2485 #endif
2486 #endif
2487
2488 /* SIGTYPE is the macro we actually use. */
2489 #ifndef SIGTYPE
2490 #define SIGTYPE RETSIGTYPE
2491 #endif
2492
2493 #ifdef emacs /* Don't do this for lib-src. */
2494 /* Tell regex.c to use a type compatible with Emacs. */
2495 #define RE_TRANSLATE_TYPE Lisp_Object
2496 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2497 #define RE_TRANSLATE_P(TBL) (XFASTINT (TBL) != 0)
2498 #endif
2499
2500 /* Avoid link-time collision with system mktime if we will use our own. */
2501 #if ! HAVE_MKTIME || BROKEN_MKTIME
2502 #define mktime emacs_mktime
2503 #endif
2504
2505 /* The rest of the code currently tests the CPP symbol BSTRING.
2506 Override any claims made by the system-description files.
2507 Note that on some SCO version it is possible to have bcopy and not bcmp. */
2508 #undef BSTRING
2509 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2510 #define BSTRING
2511 #endif
2512
2513 /* Some of the files of Emacs which are intended for use with other
2514 programs assume that if you have a config.h file, you must declare
2515 the type of getenv.
2516
2517 This declaration shouldn't appear when alloca.s or Makefile.in
2518 includes config.h. */
2519 #ifndef NOT_C_CODE
2520 extern char *getenv ();
2521 #endif
2522
2523 #endif /* EMACS_CONFIG_H */
2524
2525 /* These default definitions are good for almost all machines.
2526 The exceptions override them in m/MACHINE.h. */
2527
2528 #ifndef BITS_PER_CHAR
2529 #define BITS_PER_CHAR 8
2530 #endif
2531
2532 #ifndef BITS_PER_SHORT
2533 #define BITS_PER_SHORT 16
2534 #endif
2535
2536 /* Note that lisp.h uses this in a preprocessor conditional, so it
2537 would not work to use sizeof. That being so, we do all of them
2538 without sizeof, for uniformity's sake. */
2539 #ifndef BITS_PER_INT
2540 #define BITS_PER_INT 32
2541 #endif
2542
2543 #ifndef BITS_PER_LONG
2544 #ifdef _LP64
2545 #define BITS_PER_LONG 64
2546 #else
2547 #define BITS_PER_LONG 32
2548 #endif
2549 #endif
2550
2551 /* Define if the compiler supports function prototypes. It may do so
2552 but not define __STDC__ (e.g. DEC C by default) or may define it as
2553 zero. */
2554 #undef PROTOTYPES
2555 /* For mktime.c: */
2556 #ifndef __P
2557 # if defined PROTOTYPES
2558 # define __P(args) args
2559 # else
2560 # define __P(args) ()
2561 # endif /* GCC. */
2562 #endif /* __P */
2563
2564
2565 /* Don't include "string.h" or <stdlib.h> in non-C code. */
2566 #ifndef NOT_C_CODE
2567 #ifdef HAVE_STRING_H
2568 #include "string.h"
2569 #endif
2570 #ifdef HAVE_STDLIB_H
2571 #include <stdlib.h>
2572 #endif
2573 #endif
2574
2575 /* Define HAVE_X_I18N if we have usable i18n support. */
2576
2577 #ifdef HAVE_X11R6
2578 #define HAVE_X_I18N
2579 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
2580 #define HAVE_X_I18N
2581 #endif
2582
2583 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support. */
2584
2585 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
2586 #define HAVE_X11R6_XIM
2587 #endif
2588
2589 /* Should we enable expensive run-time checking of data types? */
2590 #undef ENABLE_CHECKING
2591
2592 #if defined __GNUC__ && (__GNUC__ > 2 \
2593 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
2594 #define NO_RETURN __attribute__ ((__noreturn__))
2595 #else
2596 #define NO_RETURN /* nothing */
2597 #endif
2598 ])dnl
2599
2600 #### Report on what we decided to do.
2601 echo "
2602 Configured for \`${canonical}'.
2603
2604 Where should the build process find the source code? ${srcdir}
2605 What operating system and machine description files should Emacs use?
2606 \`${opsysfile}' and \`${machfile}'
2607 What compiler should emacs be built with? ${CC} ${CFLAGS}
2608 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
2609 Should Emacs use a relocating allocator for buffers? ${REL_ALLOC}
2610 Should Emacs use mmap(2) for buffer allocation? $use_mmap_for_buffers
2611 What window system should Emacs use? ${window_system}
2612 What toolkit should Emacs use? ${USE_X_TOOLKIT}
2613 Should Emacs use a shared game state directory? ${gamedir}"
2614
2615 if test -n "${x_includes}"; then
2616 echo " Where do we find X Windows header files? ${x_includes}"
2617 else
2618 echo " Where do we find X Windows header files? Standard dirs"
2619 fi
2620 if test -n "${x_libraries}"; then
2621 echo " Where do we find X Windows libraries? ${x_libraries}"
2622 else
2623 echo " Where do we find X Windows libraries? Standard dirs"
2624 fi
2625
2626 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
2627 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
2628 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
2629 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
2630 echo " Does Emacs use -lungif? ${HAVE_GIF}"
2631 echo " Does Emacs use -lpng? ${HAVE_PNG}"
2632 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
2633 echo
2634
2635 # Remove any trailing slashes in these variables.
2636 changequote(, )dnl
2637 test "${prefix}" != NONE &&
2638 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2639 test "${exec_prefix}" != NONE &&
2640 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
2641 changequote([, ])dnl
2642
2643 ## Check if the C preprocessor will convert `..' to `. .'. If so, set
2644 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
2645 ## from Makefile.c can correctly provide the arg `-traditional' to the
2646 ## C preprocessor.
2647
2648 AC_EGREP_CPP(yes..yes,
2649 [yes..yes],
2650 CPP_NEED_TRADITIONAL=no,
2651 CPP_NEED_TRADITIONAL=yes)
2652
2653 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2654 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2655 lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
2656
2657 ### Make the necessary directories, if they don't exist.
2658 for dir in etc lisp ; do
2659 test -d ${dir} || mkdir ${dir}
2660 done
2661
2662 # Build src/Makefile from ${srcdir}/src/Makefile.c
2663 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2664 # This must be done after src/config.h is built, since we rely on that file.
2665
2666 changequote(, )dnl The horror, the horror.
2667 # Now get this: Some word that is part of the ${srcdir} directory name
2668 # or the ${configuration} value might, just might, happen to be an
2669 # identifier like `sun4' or `i386' or something, and be predefined by
2670 # the C preprocessor to some helpful value like 1, or maybe the empty
2671 # string. Needless to say consequent macro substitutions are less
2672 # than conducive to the makefile finding the correct directory.
2673 undefs="`echo $top_srcdir $configuration $canonical |
2674 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
2675 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2676 `"
2677 changequote([, ])dnl
2678
2679 echo creating src/epaths.h
2680 ${MAKE-make} epaths-force
2681
2682 # As of 2000-11-19, newest development versions of GNU cpp preprocess
2683 # `..' to `. .' unless invoked with -traditional
2684
2685 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
2686 CPPFLAGS="$CPPFLAGS -traditional"
2687 fi
2688
2689 echo creating lib-src/Makefile
2690 ( cd lib-src
2691 rm -f junk.c junk1.c junk2.c
2692 sed -e '/start of cpp stuff/q' \
2693 < Makefile.c > junk1.c
2694 sed -e '1,/start of cpp stuff/d'\
2695 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2696 < Makefile.c > junk.c
2697 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2698 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2699 cat junk1.c junk2.c > Makefile.new
2700 rm -f junk.c junk1.c junk2.c
2701 chmod 444 Makefile.new
2702 mv -f Makefile.new Makefile
2703 )
2704
2705 echo creating src/Makefile
2706 ( cd src
2707 rm -f junk.c junk1.c junk2.c
2708 sed -e '/start of cpp stuff/q' \
2709 < Makefile.c > junk1.c
2710 sed -e '1,/start of cpp stuff/d'\
2711 -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
2712 < Makefile.c > junk.c
2713 $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
2714 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2715 cat junk1.c junk2.c > Makefile.new
2716 rm -f junk.c junk1.c junk2.c
2717 chmod 444 Makefile.new
2718 mv -f Makefile.new Makefile
2719 )
2720
2721 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
2722 echo creating src/.gdbinit
2723 echo source $srcdir/src/.gdbinit > src/.gdbinit
2724 fi
2725
2726 # This is how we know whether to re-run configure in certain cases.
2727 touch src/config.stamp
2728
2729 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
2730