code.delx.au - gnu-emacs/blob - lisp/faces.el

   1 ;;; faces.el --- Lisp interface to the c "face" structure
   2
   3 ;; Copyright (C) 1992, 1993 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  19 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  20
  21 ;;; Commentary:
  22
  23 ;; Mostly derived from Lucid.
  24
  25 ;;; Code:
  26
  27 \f
  28 ;;;; Functions for manipulating face vectors.
  29
  30 ;;; A face vector is a vector of the form:
  31 ;;;    [face ID FONT FOREGROUND BACKGROUND BACKGROUND-PIXMAP UNDERLINE]
  32
  33 ;;; Type checkers.
  34 (defsubst internal-facep (x)
  35   (and (vectorp x) (= (length x) 8) (eq (aref x 0) 'face)))
  36
  37 (defmacro internal-check-face (face)
  38   (` (while (not (internal-facep (, face)))
  39        (setq (, face) (signal 'wrong-type-argument (list 'internal-facep (, face)))))))
  40
  41 ;;; Accessors.
  42 (defsubst face-name (face)
  43   "Return the name of face FACE."
  44   (aref (internal-get-face face) 1))
  45
  46 (defsubst face-id (face)
  47   "Return the internal ID number of face FACE."
  48   (aref (internal-get-face face) 2))
  49
  50 (defsubst face-font (face &optional frame)
  51   "Return the font name of face FACE, or nil if it is unspecified.
  52 If the optional argument FRAME is given, report on face FACE in that frame.
  53 If FRAME is t, report on the defaults for face FACE (for new frames).
  54   The font default for a face is either nil, or a list
  55   of the form (bold), (italic) or (bold italic).
  56 If FRAME is omitted or nil, use the selected frame."
  57   (aref (internal-get-face face frame) 3))
  58
  59 (defsubst face-foreground (face &optional frame)
  60   "Return the foreground color name of face FACE, or nil if unspecified.
  61 If the optional argument FRAME is given, report on face FACE in that frame.
  62 If FRAME is t, report on the defaults for face FACE (for new frames).
  63 If FRAME is omitted or nil, use the selected frame."
  64   (aref (internal-get-face face frame) 4))
  65
  66 (defsubst face-background (face &optional frame)
  67   "Return the background color name of face FACE, or nil if unspecified.
  68 If the optional argument FRAME is given, report on face FACE in that frame.
  69 If FRAME is t, report on the defaults for face FACE (for new frames).
  70 If FRAME is omitted or nil, use the selected frame."
  71   (aref (internal-get-face face frame) 5))
  72
  73 ;;(defsubst face-background-pixmap (face &optional frame)
  74 ;; "Return the background pixmap name of face FACE, or nil if unspecified.
  75 ;;If the optional argument FRAME is given, report on face FACE in that frame.
  76 ;;Otherwise report on the defaults for face FACE (for new frames)."
  77 ;; (aref (internal-get-face face frame) 6))
  78
  79 (defsubst face-underline-p (face &optional frame)
  80  "Return t if face FACE is underlined.
  81 If the optional argument FRAME is given, report on face FACE in that frame.
  82 If FRAME is t, report on the defaults for face FACE (for new frames).
  83 If FRAME is omitted or nil, use the selected frame."
  84  (aref (internal-get-face face frame) 7))
  85
  86 \f
  87 ;;; Mutators.
  88
  89 (defsubst set-face-font (face font &optional frame)
  90   "Change the font of face FACE to FONT (a string).
  91 If the optional FRAME argument is provided, change only
  92 in that frame; otherwise change each frame."
  93   (interactive (internal-face-interactive "font"))
  94   (if (stringp font) (setq font (x-resolve-font-name font face frame)))
  95   (internal-set-face-1 face 'font font 3 frame))
  96
  97 (defsubst set-face-foreground (face color &optional frame)
  98   "Change the foreground color of face FACE to COLOR (a string).
  99 If the optional FRAME argument is provided, change only
 100 in that frame; otherwise change each frame."
 101   (interactive (internal-face-interactive "foreground"))
 102   (internal-set-face-1 face 'foreground color 4 frame))
 103
 104 (defsubst set-face-background (face color &optional frame)
 105   "Change the background color of face FACE to COLOR (a string).
 106 If the optional FRAME argument is provided, change only
 107 in that frame; otherwise change each frame."
 108   (interactive (internal-face-interactive "background"))
 109   (internal-set-face-1 face 'background color 5 frame))
 110
 111 ;;(defsubst set-face-background-pixmap (face name &optional frame)
 112 ;;  "Change the background pixmap of face FACE to PIXMAP.
 113 ;;PIXMAP should be a string, the name of a file of pixmap data.
 114 ;;The directories listed in the `x-bitmap-file-path' variable are searched.
 115
 116 ;;Alternatively, PIXMAP may be a list of the form (WIDTH HEIGHT DATA)
 117 ;;where WIDTH and HEIGHT are the size in pixels,
 118 ;;and DATA is a string, containing the raw bits of the bitmap.
 119
 120 ;;If the optional FRAME argument is provided, change only
 121 ;;in that frame; otherwise change each frame."
 122 ;;  (interactive (internal-face-interactive "background-pixmap"))
 123 ;;  (internal-set-face-1 face 'background-pixmap name 6 frame))
 124
 125 (defsubst set-face-underline-p (face underline-p &optional frame)
 126   "Specify whether face FACE is underlined.  (Yes if UNDERLINE-P is non-nil.)
 127 If the optional FRAME argument is provided, change only
 128 in that frame; otherwise change each frame."
 129   (interactive (internal-face-interactive "underline-p" "underlined"))
 130   (internal-set-face-1 face 'underline underline-p 7 frame))
 131
 132 \f
 133 ;;;; Associating face names (symbols) with their face vectors.
 134
 135 (defvar global-face-data nil
 136   "Internal data for face support functions.  Not for external use.
 137 This is an alist associating face names with the default values for
 138 their parameters.  Newly created frames get their data from here.")
 139
 140 (defun face-list ()
 141   "Returns a list of all defined face names."
 142   (mapcar 'car global-face-data))
 143
 144 (defun internal-find-face (name &optional frame)
 145   "Retrieve the face named NAME.  Return nil if there is no such face.
 146 If the optional argument FRAME is given, this gets the face NAME for
 147 that frame; otherwise, it uses the selected frame.
 148 If FRAME is the symbol t, then the global, non-frame face is returned.
 149 If NAME is already a face, it is simply returned."
 150   (if (and (eq frame t) (not (symbolp name)))
 151       (setq name (face-name name)))
 152   (if (symbolp name)
 153       (cdr (assq name
 154                  (if (eq frame t)
 155                      global-face-data
 156                    (frame-face-alist (or frame (selected-frame))))))
 157     (internal-check-face name)
 158     name))
 159
 160 (defun internal-get-face (name &optional frame)
 161   "Retrieve the face named NAME; error if there is none.
 162 If the optional argument FRAME is given, this gets the face NAME for
 163 that frame; otherwise, it uses the selected frame.
 164 If FRAME is the symbol t, then the global, non-frame face is returned.
 165 If NAME is already a face, it is simply returned."
 166   (or (internal-find-face name frame)
 167       (internal-check-face name)))
 168
 169
 170 (defun internal-set-face-1 (face name value index frame)
 171   (let ((inhibit-quit t))
 172     (if (null frame)
 173         (let ((frames (frame-list)))
 174           (while frames
 175             (internal-set-face-1 (face-name face) name value index (car frames))
 176             (setq frames (cdr frames)))
 177           (aset (internal-get-face (if (symbolp face) face (face-name face)) t)
 178                 index value)
 179           value)
 180       (or (eq frame t)
 181           (set-face-attribute-internal (face-id face) name value frame))
 182       (aset (internal-get-face face frame) index value))))
 183
 184
 185 (defun read-face-name (prompt)
 186   (let (face)
 187     (while (= (length face) 0)
 188       (setq face (completing-read prompt
 189                                   (mapcar '(lambda (x) (list (symbol-name x)))
 190                                           (face-list))
 191                                   nil t)))
 192     (intern face)))
 193
 194 (defun internal-face-interactive (what &optional bool)
 195   (let* ((fn (intern (concat "face-" what)))
 196          (prompt (concat "Set " what " of face"))
 197          (face (read-face-name (concat prompt ": ")))
 198          (default (if (fboundp fn)
 199                       (or (funcall fn face (selected-frame))
 200                           (funcall fn 'default (selected-frame)))))
 201          (value (if bool
 202                     (y-or-n-p (concat "Should face " (symbol-name face)
 203                                       " be " bool "? "))
 204                   (read-string (concat prompt " " (symbol-name face) " to: ")
 205                                default))))
 206     (list face (if (equal value "") nil value))))
 207
 208
 209
 210 (defun make-face (name)
 211   "Define a new FACE on all frames.
 212 You can modify the font, color, etc of this face with the set-face- functions.
 213 If the face already exists, it is unmodified."
 214   (interactive "SMake face: ")
 215   (or (internal-find-face name)
 216       (let ((face (make-vector 8 nil)))
 217         (aset face 0 'face)
 218         (aset face 1 name)
 219         (let* ((frames (frame-list))
 220                (inhibit-quit t)
 221                (id (internal-next-face-id)))
 222           (make-face-internal id)
 223           (aset face 2 id)
 224           (while frames
 225             (set-frame-face-alist (car frames)
 226                                   (cons (cons name (copy-sequence face))
 227                                         (frame-face-alist (car frames))))
 228             (setq frames (cdr frames)))
 229           (setq global-face-data (cons (cons name face) global-face-data)))
 230         ;; when making a face after frames already exist
 231         (if (eq window-system 'x)
 232             (make-face-x-resource-internal face))
 233         face)))
 234
 235 ;; Fill in a face by default based on X resources, for all existing frames.
 236 ;; This has to be done when a new face is made.
 237 (defun make-face-x-resource-internal (face &optional frame set-anyway)
 238   (cond ((null frame)
 239          (let ((frames (frame-list)))
 240            (while frames
 241              (make-face-x-resource-internal (face-name face)
 242                                             (car frames) set-anyway)
 243              (setq frames (cdr frames)))))
 244         (t
 245          (setq face (internal-get-face (face-name face) frame))
 246          ;;
 247          ;; These are things like "attributeForeground" instead of simply
 248          ;; "foreground" because people tend to do things like "*foreground",
 249          ;; which would cause all faces to be fully qualified, making faces
 250          ;; inherit attributes in a non-useful way.  So we've made them slightly
 251          ;; less obvious to specify in order to make them work correctly in
 252          ;; more random environments.
 253          ;;
 254          ;; I think these should be called "face.faceForeground" instead of
 255          ;; "face.attributeForeground", but they're the way they are for
 256          ;; hysterical reasons.
 257          ;;
 258          (let* ((name (symbol-name (face-name face)))
 259                 (fn  (or (x-get-resource (concat name ".attributeFont")
 260                                          "Face.AttributeFont")
 261                          (and set-anyway (face-font face))))
 262                 (fg  (or (x-get-resource (concat name ".attributeForeground")
 263                                          "Face.AttributeForeground")
 264                          (and set-anyway (face-foreground face))))
 265                 (bg  (or (x-get-resource (concat name ".attributeBackground")
 266                                          "Face.AttributeBackground")
 267                          (and set-anyway (face-background face))))
 268 ;;              (bgp (or (x-get-resource (concat name ".attributeBackgroundPixmap")
 269 ;;                                       "Face.AttributeBackgroundPixmap")
 270 ;;                       (and set-anyway (face-background-pixmap face))))
 271                 (ulp (or (x-get-resource (concat name ".attributeUnderline")
 272                                          "Face.AttributeUnderline")
 273                          (and set-anyway (face-underline-p face))))
 274                 )
 275            (if fn
 276                (condition-case ()
 277                    (set-face-font face fn frame)
 278                  (error (message "font `%s' not found for face `%s'" fn name))))
 279            (if fg
 280                (condition-case ()
 281                    (set-face-foreground face fg frame)
 282                  (error (message "color `%s' not allocated for face `%s'" fg name))))
 283            (if bg
 284                (condition-case ()
 285                    (set-face-background face bg frame)
 286                  (error (message "color `%s' not allocated for face `%s'" bg name))))
 287 ;;         (if bgp
 288 ;;             (condition-case ()
 289 ;;                 (set-face-background-pixmap face bgp frame)
 290 ;;               (error (message "pixmap `%s' not found for face `%s'" bgp name))))
 291            (if (or ulp set-anyway)
 292                (set-face-underline-p face ulp frame))
 293            )))
 294   face)
 295
 296 (defun copy-face (old-face new-name &optional frame new-frame)
 297   "Define a face just like OLD-FACE, with name NEW-NAME.
 298 If NEW-NAME already exists as a face, it is modified to be like OLD-FACE.
 299 If the optional argument FRAME is given, this applies only to that frame.
 300 Otherwise it applies to each frame separately.
 301 If the optional fourth argument NEW-FRAME is given,
 302 copy the information from face OLD-FACE on frame FRAME
 303 to face NEW-NAME on frame NEW-FRAME."
 304   (or new-frame (setq new-frame frame))
 305   (setq old-face (internal-get-face old-face frame))
 306   (let* ((inhibit-quit t)
 307          (new-face (or (internal-find-face new-name new-frame)
 308                        (make-face new-name))))
 309     (if (null frame)
 310         (let ((frames (frame-list)))
 311           (while frames
 312             (copy-face old-face new-name (car frames))
 313             (setq frames (cdr frames)))
 314           (copy-face old-face new-name t))
 315       (set-face-font new-face (face-font old-face frame) new-frame)
 316       (set-face-foreground new-face (face-foreground old-face frame) new-frame)
 317       (set-face-background new-face (face-background old-face frame) new-frame)
 318 ;;;      (set-face-background-pixmap
 319 ;;;       new-face (face-background-pixmap old-face frame) new-frame)
 320       (set-face-underline-p new-face (face-underline-p old-face frame)
 321                             new-frame))
 322     new-face))
 323
 324 (defun face-equal (face1 face2 &optional frame)
 325   "True if the faces FACE1 and FACE2 display in the same way."
 326   (setq face1 (internal-get-face face1 frame)
 327         face2 (internal-get-face face2 frame))
 328   (and (equal (face-foreground face1 frame) (face-foreground face2 frame))
 329        (equal (face-background face1 frame) (face-background face2 frame))
 330        (equal (face-font face1 frame) (face-font face2 frame))
 331 ;;       (equal (face-background-pixmap face1 frame)
 332 ;;            (face-background-pixmap face2 frame))
 333        ))
 334
 335 (defun face-differs-from-default-p (face &optional frame)
 336   "True if face FACE displays differently from the default face, on FRAME.
 337 A face is considered to be ``the same'' as the default face if it is
 338 actually specified in the same way (equivalent fonts, etc) or if it is
 339 fully unspecified, and thus inherits the attributes of any face it
 340 is displayed on top of."
 341   (let ((default (internal-get-face 'default frame)))
 342     (setq face (internal-get-face face frame))
 343     (not (and (or (equal (face-foreground default frame)
 344                          (face-foreground face frame))
 345                   (null (face-foreground face frame)))
 346               (or (equal (face-background default frame)
 347                          (face-background face frame))
 348                   (null (face-background face frame)))
 349               (or (equal (face-font default frame) (face-font face frame))
 350                   (null (face-font face frame)))
 351 ;;;           (or (equal (face-background-pixmap default frame)
 352 ;;;                      (face-background-pixmap face frame))
 353 ;;;               (null (face-background-pixmap face frame)))
 354               (equal (face-underline-p default frame)
 355                      (face-underline-p face frame))
 356               ))))
 357
 358
 359 (defun invert-face (face &optional frame)
 360   "Swap the foreground and background colors of face FACE.
 361 If the face doesn't specify both foreground and background, then
 362 set its foreground and background to the default background and foreground."
 363   (interactive (list (read-face-name "Invert face: ")))
 364   (setq face (internal-get-face face frame))
 365   (let ((fg (face-foreground face frame))
 366         (bg (face-background face frame)))
 367     (if (or fg bg)
 368         (progn
 369           (set-face-foreground face bg frame)
 370           (set-face-background face fg frame))
 371       (set-face-foreground face (or (face-background 'default frame)
 372                                     (cdr (assq 'background-color (frame-parameters frame))))
 373                            frame)
 374       (set-face-background face (or (face-foreground 'default frame)
 375                                     (cdr (assq 'foreground-color (frame-parameters frame))))
 376                            frame)))
 377   face)
 378
 379
 380 (defun internal-try-face-font (face font &optional frame)
 381   "Like set-face-font, but returns nil on failure instead of an error."
 382   (condition-case ()
 383       (set-face-font face font frame)
 384     (error nil)))
 385 \f
 386 ;; Manipulating font names.
 387
 388 (defconst x-font-regexp nil)
 389 (defconst x-font-regexp-head nil)
 390 (defconst x-font-regexp-weight nil)
 391 (defconst x-font-regexp-slant nil)
 392
 393 ;;; Regexps matching font names in "Host Portable Character Representation."
 394 ;;;
 395 (let ((-                "[-?]")
 396       (foundry          "[^-]+")
 397       (family           "[^-]+")
 398       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
 399 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
 400       (weight\?         "\\([^-]*\\)")                                  ; 1
 401       (slant            "\\([ior]\\)")                                  ; 2
 402 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
 403       (slant\?          "\\([^-]?\\)")                                  ; 2
 404 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
 405       (swidth           "\\([^-]*\\)")                                  ; 3
 406 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
 407       (adstyle          "[^-]*")                                        ; 4
 408       (pixelsize        "[0-9]+")
 409       (pointsize        "[0-9][0-9]+")
 410       (resx             "[0-9][0-9]+")
 411       (resy             "[0-9][0-9]+")
 412       (spacing          "[cmp?*]")
 413       (avgwidth         "[0-9]+")
 414       (registry         "[^-]+")
 415       (encoding         "[^-]+")
 416       )
 417   (setq x-font-regexp
 418         (concat "\\`\\*?[-?*]"
 419                 foundry - family - weight\? - slant\? - swidth - adstyle -
 420                 pixelsize - pointsize - resx - resy - spacing - registry -
 421                 encoding "[-?*]\\*?\\'"
 422                 ))
 423   (setq x-font-regexp-head
 424         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
 425                 "\\([-*?]\\|\\'\\)"))
 426   (setq x-font-regexp-slant (concat - slant -))
 427   (setq x-font-regexp-weight (concat - weight -))
 428   nil)
 429
 430 (defun x-resolve-font-name (pattern &optional face frame)
 431   "Return a font name matching PATTERN.
 432 All wildcards in PATTERN become substantiated.
 433 If PATTERN is nil, return the name of the frame's base font, which never
 434 contains wildcards.
 435 Given optional arguments FACE and FRAME, try to return a font which is
 436 also the same size as FACE on FRAME."
 437   (or (symbolp face)
 438       (setq face (face-name face)))
 439   (and (eq frame t)
 440        (setq frame nil))
 441   (if pattern
 442       (let ((fonts (x-list-fonts pattern face frame)))
 443         (or fonts
 444             (if face
 445                 (error "No fonts matching pattern are the same size as `%s'"
 446                        face)
 447               (error "No fonts match `%s'" pattern)))
 448         (car fonts))
 449     (cdr (assq 'font (frame-parameters (selected-frame))))))
 450
 451 (defun x-frob-font-weight (font which)
 452   (if (or (string-match x-font-regexp font)
 453           (string-match x-font-regexp-head font)
 454           (string-match x-font-regexp-weight font))
 455       (concat (substring font 0 (match-beginning 1)) which
 456               (substring font (match-end 1)))
 457     nil))
 458
 459 (defun x-frob-font-slant (font which)
 460   (cond ((or (string-match x-font-regexp font)
 461              (string-match x-font-regexp-head font))
 462          (concat (substring font 0 (match-beginning 2)) which
 463                  (substring font (match-end 2))))
 464         ((string-match x-font-regexp-slant font)
 465          (concat (substring font 0 (match-beginning 1)) which
 466                  (substring font (match-end 1))))
 467         (t nil)))
 468
 469
 470 (defun x-make-font-bold (font)
 471   "Given an X font specification, make a bold version of it.
 472 If that can't be done, return nil."
 473   (x-frob-font-weight font "bold"))
 474
 475 (defun x-make-font-demibold (font)
 476   "Given an X font specification, make a demibold version of it.
 477 If that can't be done, return nil."
 478   (x-frob-font-weight font "demibold"))
 479
 480 (defun x-make-font-unbold (font)
 481   "Given an X font specification, make a non-bold version of it.
 482 If that can't be done, return nil."
 483   (x-frob-font-weight font "medium"))
 484
 485 (defun x-make-font-italic (font)
 486   "Given an X font specification, make an italic version of it.
 487 If that can't be done, return nil."
 488   (x-frob-font-slant font "i"))
 489
 490 (defun x-make-font-oblique (font) ; you say tomayto...
 491   "Given an X font specification, make an oblique version of it.
 492 If that can't be done, return nil."
 493   (x-frob-font-slant font "o"))
 494
 495 (defun x-make-font-unitalic (font)
 496   "Given an X font specification, make a non-italic version of it.
 497 If that can't be done, return nil."
 498   (x-frob-font-slant font "r"))
 499 \f
 500 ;;; non-X-specific interface
 501
 502 (defun make-face-bold (face &optional frame noerror)
 503   "Make the font of the given face be bold, if possible.
 504 If NOERROR is non-nil, return nil on failure."
 505   (interactive (list (read-face-name "Make which face bold: ")))
 506   (if (eq frame t)
 507       (set-face-font face (if (memq 'italic (face-font face t))
 508                               '(bold italic) '(bold))
 509                      t)
 510     (let ((ofont (face-font face frame))
 511           font f2)
 512       (if (null frame)
 513           (let ((frames (frame-list)))
 514             ;; Make this face bold in global-face-data.
 515             (make-face-bold face t noerror)
 516             ;; Make this face bold in each frame.
 517             (while frames
 518               (make-face-bold face (car frames) noerror)
 519               (setq frames (cdr frames))))
 520         (setq face (internal-get-face face frame))
 521         (setq font (or (face-font face frame)
 522                        (face-font face t)))
 523         (if (listp font)
 524             (setq font nil))
 525         (setq font (or font
 526                        (face-font 'default frame)
 527                        (cdr (assq 'font (frame-parameters frame)))))
 528         (make-face-bold-internal face frame))
 529       (or (not (equal ofont (face-font face)))
 530           (and (not noerror)
 531                (error "No bold version of %S" font))))))
 532
 533 (defun make-face-bold-internal (face frame)
 534   (or (and (setq f2 (x-make-font-bold font))
 535            (internal-try-face-font face f2 frame))
 536       (and (setq f2 (x-make-font-demibold font))
 537            (internal-try-face-font face f2 frame))))
 538
 539 (defun make-face-italic (face &optional frame noerror)
 540   "Make the font of the given face be italic, if possible.
 541 If NOERROR is non-nil, return nil on failure."
 542   (interactive (list (read-face-name "Make which face italic: ")))
 543   (if (eq frame t)
 544       (set-face-font face (if (memq 'bold (face-font face t))
 545                               '(bold italic) '(italic))
 546                      t)
 547     (let ((ofont (face-font face frame))
 548           font f2)
 549       (if (null frame)
 550           (let ((frames (frame-list)))
 551             ;; Make this face italic in global-face-data.
 552             (make-face-italic face t noerror)
 553             ;; Make this face italic in each frame.
 554             (while frames
 555               (make-face-italic face (car frames) noerror)
 556               (setq frames (cdr frames))))
 557         (setq face (internal-get-face face frame))
 558         (setq font (or (face-font face frame)
 559                        (face-font face t)))
 560         (if (listp font)
 561             (setq font nil))
 562         (setq font (or font
 563                        (face-font 'default frame)
 564                        (cdr (assq 'font (frame-parameters frame)))))
 565         (make-face-italic-internal face frame))
 566       (or (not (equal ofont (face-font face)))
 567           (and (not noerror)
 568                (error "No italic version of %S" font))))))
 569
 570 (defun make-face-italic-internal (face frame)
 571   (or (and (setq f2 (x-make-font-italic font))
 572            (internal-try-face-font face f2 frame))
 573       (and (setq f2 (x-make-font-oblique font))
 574            (internal-try-face-font face f2 frame))))
 575
 576 (defun make-face-bold-italic (face &optional frame noerror)
 577   "Make the font of the given face be bold and italic, if possible.
 578 If NOERROR is non-nil, return nil on failure."
 579   (interactive (list (read-face-name "Make which face bold-italic: ")))
 580   (if (eq frame t)
 581       (set-face-font face '(bold italic) t)
 582     (let ((ofont (face-font face frame))
 583           font)
 584       (if (null frame)
 585           (let ((frames (frame-list)))
 586             ;; Make this face bold-italic in global-face-data.
 587             (make-face-bold-italic face t noerror)
 588             ;; Make this face bold in each frame.
 589             (while frames
 590               (make-face-bold-italic face (car frames) noerror)
 591               (setq frames (cdr frames))))
 592         (setq face (internal-get-face face frame))
 593         (setq font (or (face-font face frame)
 594                        (face-font face t)))
 595         (if (listp font)
 596             (setq font nil))
 597         (setq font (or font
 598                        (face-font 'default frame)
 599                        (cdr (assq 'font (frame-parameters frame)))))
 600         (make-face-bold-italic-internal face frame))
 601       (or (not (equal ofont (face-font face)))
 602           (and (not noerror)
 603                (error "No bold italic version of %S" font))))))
 604
 605 (defun make-face-bold-italic-internal (face frame)
 606   (let (f2 f3)
 607     (or (and (setq f2 (x-make-font-italic font))
 608              (not (equal font f2))
 609              (setq f3 (x-make-font-bold f2))
 610              (not (equal f2 f3))
 611              (internal-try-face-font face f3 frame))
 612         (and (setq f2 (x-make-font-oblique font))
 613              (not (equal font f2))
 614              (setq f3 (x-make-font-bold f2))
 615              (not (equal f2 f3))
 616              (internal-try-face-font face f3 frame))
 617         (and (setq f2 (x-make-font-italic font))
 618              (not (equal font f2))
 619              (setq f3 (x-make-font-demibold f2))
 620              (not (equal f2 f3))
 621              (internal-try-face-font face f3 frame))
 622         (and (setq f2 (x-make-font-oblique font))
 623              (not (equal font f2))
 624              (setq f3 (x-make-font-demibold f2))
 625              (not (equal f2 f3))
 626              (internal-try-face-font face f3 frame)))))
 627
 628 (defun make-face-unbold (face &optional frame noerror)
 629   "Make the font of the given face be non-bold, if possible.
 630 If NOERROR is non-nil, return nil on failure."
 631   (interactive (list (read-face-name "Make which face non-bold: ")))
 632   (if (eq frame t)
 633       (set-face-font face (if (memq 'italic (face-font face t))
 634                               '(italic) nil)
 635                      t)
 636     (let ((ofont (face-font face frame))
 637           font font1)
 638       (if (null frame)
 639           (let ((frames (frame-list)))
 640             ;; Make this face unbold in global-face-data.
 641             (make-face-unbold face t noerror)
 642             ;; Make this face unbold in each frame.
 643             (while frames
 644               (make-face-unbold face (car frames) noerror)
 645               (setq frames (cdr frames))))
 646         (setq face (internal-get-face face frame))
 647         (setq font1 (or (face-font face frame)
 648                         (face-font face t)))
 649         (if (listp font1)
 650             (setq font1 nil))
 651         (setq font1 (or font1
 652                         (face-font 'default frame)
 653                         (cdr (assq 'font (frame-parameters frame)))))
 654         (setq font (x-make-font-unbold font1))
 655         (if font (internal-try-face-font face font frame)))
 656       (or (not (equal ofont (face-font face)))
 657           (and (not noerror)
 658                (error "No unbold version of %S" font1))))))
 659
 660 (defun make-face-unitalic (face &optional frame noerror)
 661   "Make the font of the given face be non-italic, if possible.
 662 If NOERROR is non-nil, return nil on failure."
 663   (interactive (list (read-face-name "Make which face non-italic: ")))
 664   (if (eq frame t)
 665       (set-face-font face (if (memq 'bold (face-font face t))
 666                               '(bold) nil)
 667                      t)
 668     (let ((ofont (face-font face frame))
 669           font font1)
 670       (if (null frame)
 671           (let ((frames (frame-list)))
 672             ;; Make this face unitalic in global-face-data.
 673             (make-face-unitalic face t noerror)
 674             ;; Make this face unitalic in each frame.
 675             (while frames
 676               (make-face-unitalic face (car frames) noerror)
 677               (setq frames (cdr frames))))
 678         (setq face (internal-get-face face frame))
 679         (setq font1 (or (face-font face frame)
 680                         (face-font face t)))
 681         (if (listp font1)
 682             (setq font1 nil))
 683         (setq font1 (or font1
 684                         (face-font 'default frame)
 685                         (cdr (assq 'font (frame-parameters frame)))))
 686         (setq font (x-make-font-unitalic font1))
 687         (if font (internal-try-face-font face font frame)))
 688       (or (not (equal ofont (face-font face)))
 689           (and (not noerror)
 690                (error "No unitalic version of %S" font1))))))
 691 \f
 692 (defvar list-faces-sample-text
 693   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 694   "*Text string to display as the sample text for `list-faces-display'.")
 695
 696 ;; The name list-faces would be more consistent, but let's avoid a conflict
 697 ;; with Lucid, which uses that name differently.
 698 (defun list-faces-display ()
 699   "List all faces, using the same sample text in each.
 700 The sample text is a string that comes from the variable
 701 `list-faces-sample-text'.
 702
 703 It is possible to give a particular face name different appearances in
 704 different frames.  This command shows the appearance in the
 705 selected frame."
 706   (interactive)
 707   (let ((faces (sort (face-list) (function string-lessp)))
 708         (face nil)
 709         (frame (selected-frame))
 710         disp-frame window)
 711     (with-output-to-temp-buffer "*Faces*"
 712       (save-excursion
 713         (set-buffer standard-output)
 714         (setq truncate-lines t)
 715         (while faces
 716           (setq face (car faces))
 717           (setq faces (cdr faces))
 718           (insert (format "%25s " (symbol-name face)))
 719           (let ((beg (point)))
 720             (insert list-faces-sample-text)
 721             (insert "\n")
 722             (put-text-property beg (1- (point)) 'face face)))
 723         (goto-char (point-min))))
 724     ;; If the *Faces* buffer appears in a different frame,
 725     ;; copy all the face definitions from FRAME,
 726     ;; so that the display will reflect the frame that was selected.
 727     (setq window (get-buffer-window (get-buffer "*Faces*") t))
 728     (setq disp-frame (if window (window-frame window)
 729                        (car (frame-list))))
 730     (or (eq frame disp-frame)
 731         (let ((faces (face-list)))
 732           (while faces
 733             (copy-face (car faces) (car faces) frame disp-frame)
 734             (setq faces (cdr faces)))))))
 735 \f
 736 ;;; Make the default and modeline faces; the C code knows these as
 737 ;;; faces 0 and 1, respectively, so they must be the first two faces
 738 ;;; made.
 739 (defun face-initialize ()
 740   (make-face 'default)
 741   (make-face 'modeline)
 742   (make-face 'highlight)
 743   ;;
 744   ;; These aren't really special in any way, but they're nice to have around.
 745   ;; The X-specific code is clever at them.
 746   ;;
 747   (make-face 'bold)
 748   (make-face 'italic)
 749   (make-face 'bold-italic)
 750   (make-face 'region)
 751   (make-face 'secondary-selection)
 752   (make-face 'underline)
 753
 754   (setq region-face (face-id 'region))
 755
 756   ;; Set up the faces of all existing X Window frames.
 757   (let ((frames (frame-list)))
 758     (while frames
 759       (if (eq (framep (car frames)) 'x)
 760           (x-initialize-frame-faces (car frames)))
 761       (setq frames (cdr frames)))))
 762
 763 \f
 764 ;;; This really belongs in setting a frame's own font.
 765 ;;;     ;;
 766 ;;;     ;; No font specified in the resource database; try to cope.
 767 ;;;     ;;
 768 ;;;     (internal-try-face-font default "-*-courier-medium-r-*-*-*-120-*-*-*-*-iso8859-*"
 769 ;;;                          frame)
 770 ;;;     (internal-try-face-font default "-*-courier-*-r-*-*-*-120-*-*-*-*-iso8859-*"
 771 ;;;                          frame)
 772 ;;;     (internal-try-face-font default "-*-*-medium-r-*-*-*-120-*-*-m-*-iso8859-*" frame)
 773 ;;;     (internal-try-face-font default "-*-*-medium-r-*-*-*-120-*-*-c-*-iso8859-*" frame)
 774 ;;;     (internal-try-face-font default "-*-*-*-r-*-*-*-120-*-*-m-*-iso8859-*" frame)
 775 ;;;     (internal-try-face-font default "-*-*-*-r-*-*-*-120-*-*-c-*-iso8859-*" frame)
 776 ;;;     (internal-try-face-font default "-*-*-*-r-*-*-*-120-*-*-*-*-iso8859-*" frame)
 777
 778
 779 ;;; This is called from make-screen-initial-faces to make sure that the
 780 ;;; "default" and "modeline" faces for this screen have enough attributes
 781 ;;; specified for emacs to be able to display anything on it.  This had
 782 ;;; better not signal an error.
 783 ;;;
 784 (defun x-initialize-frame-faces (frame)
 785   (or (face-differs-from-default-p 'bold frame)
 786       (make-face-bold 'bold frame t)
 787       ;; if default font is bold, then make the `bold' face be unbold.
 788       (make-face-unbold 'bold frame t)
 789       ;; otherwise the luser specified one of the bogus font names
 790       (internal-x-complain-about-font 'bold frame)
 791       )
 792
 793   (or (face-differs-from-default-p 'italic frame)
 794       (make-face-italic 'italic frame t)
 795       (progn
 796         (make-face-bold 'italic frame t)
 797         (internal-x-complain-about-font 'italic frame))
 798       )
 799
 800   (or (face-differs-from-default-p 'bold-italic frame)
 801       (make-face-bold-italic 'bold-italic frame t)
 802       ;; if we couldn't get a bold-italic version, try just bold.
 803       (make-face-bold 'bold-italic frame t)
 804       ;; if we couldn't get bold or bold-italic, then that's probably because
 805       ;; the default font is bold, so make the `bold-italic' face be unbold.
 806       (and (make-face-unbold 'bold-italic frame t)
 807            (make-face-italic 'bold-italic frame t))
 808       ;; if that didn't work, try italic (can this ever happen? what the hell.)
 809       (progn
 810         (make-face-italic 'bold-italic frame t)
 811         ;; then bitch and moan.
 812         (internal-x-complain-about-font 'bold-italic frame))
 813       )
 814
 815   (or (face-differs-from-default-p 'highlight frame)
 816       (if (or (not (x-display-color-p))
 817               (= (x-display-planes) 1))
 818           (invert-face 'highlight frame)
 819         (condition-case ()
 820             (condition-case ()
 821                 (set-face-background 'highlight "darkseagreen2" frame)
 822               (error (set-face-background 'highlight "green" frame)))
 823 ;;;         (set-face-background-pixmap 'highlight "gray1" frame)
 824           (error (invert-face 'highlight frame)))))
 825
 826   (or (face-differs-from-default-p 'region frame)
 827       (if (= (x-display-planes) 1)
 828           (invert-face 'region frame)
 829         (condition-case ()
 830             (set-face-background 'region "gray" frame)
 831           (error (invert-face 'region frame)))))
 832
 833   (or (face-differs-from-default-p 'modeline frame)
 834       (invert-face 'modeline frame))
 835
 836   (or (face-differs-from-default-p 'underline frame)
 837       (set-face-underline-p 'underline t frame))
 838
 839   (or (face-differs-from-default-p 'secondary-selection frame)
 840       (if (or (not (x-display-color-p))
 841               (= (x-display-planes) 1))
 842           (invert-face 'secondary-selection frame)
 843         (condition-case ()
 844             (condition-case ()
 845                 ;; some older X servers don't have this one.
 846                 (set-face-background 'secondary-selection "paleturquoise"
 847                                      frame)
 848               (error
 849                (set-face-background 'secondary-selection "green" frame)))
 850 ;;;         (set-face-background-pixmap 'secondary-selection "gray1" frame)
 851           (error (invert-face 'secondary-selection frame)))))
 852   )
 853
 854 (defun internal-x-complain-about-font (face frame)
 855 ;;; It's annoying to bother the user about this,
 856 ;;; since it happens under normal circumstances.
 857 ;;;  (message "No %s version of %S"
 858 ;;;        face
 859 ;;;        (or (face-font face frame)
 860 ;;;            (face-font face t)
 861 ;;;            (face-font 'default frame)
 862 ;;;            (cdr (assq 'font (frame-parameters frame)))))
 863 ;;;  (sit-for 1)
 864   )
 865 \f
 866 ;; Like x-create-frame but also set up the faces.
 867
 868 (defun x-create-frame-with-faces (&optional parameters)
 869   (if (null global-face-data)
 870       (x-create-frame parameters)
 871     (let* ((frame (x-create-frame parameters))
 872            (faces (copy-alist global-face-data))
 873            (rest faces))
 874       (set-frame-face-alist frame faces)
 875
 876       (if (cdr (or (assq 'reverse parameters)
 877                    (assq 'reverse default-frame-alist)
 878                    (cons nil
 879                          (member (x-get-resource "reverseVideo" "ReverseVideo")
 880                                  '("on" "true")))))
 881           (let ((params (frame-parameters frame)))
 882             (modify-frame-parameters
 883              frame
 884              (list (cons 'foreground-color (cdr (assq 'background-color params)))
 885                    (cons 'background-color (cdr (assq 'foreground-color params)))
 886                    (cons 'mouse-color (cdr (assq 'background-color params)))
 887                    (cons 'cursor-color (cdr (assq 'background-color params)))
 888                    (cons 'border-color (cdr (assq 'background-color params)))))))
 889
 890       ;; Copy the vectors that represent the faces.
 891       ;; Also fill them in from X resources.
 892       (while rest
 893         (setcdr (car rest) (copy-sequence (cdr (car rest))))
 894         (if (listp (face-font (cdr (car rest))))
 895             (let ((bold (memq 'bold (face-font (cdr (car rest)))))
 896                   (italic (memq 'italic (face-font (cdr (car rest))))))
 897               (if (and bold italic)
 898                   (make-face-bold-italic (car (car rest)) frame)
 899                 (if bold
 900                     (make-face-bold (car (car rest)) frame)
 901                   (if italic
 902                       (make-face-italic (car (car rest)) frame))))))
 903         (make-face-x-resource-internal (cdr (car rest)) frame t)
 904         (setq rest (cdr rest)))
 905
 906       (x-initialize-frame-faces frame)
 907
 908       frame)))
 909
 910 ;; If we are already using x-window frames, initialize faces for them.
 911 (if (eq (framep (selected-frame)) 'x)
 912     (face-initialize))
 913
 914 (provide 'faces)
 915
 916 ;;; faces.el ends here