code.delx.au - gnu-emacs/blob - lisp/gud.el

   1 ;;; gud.el --- Grand Unified Debugger mode for running GDB and other debuggers
   2
   3 ;; Author: Eric S. Raymond <esr@snark.thyrsus.com>
   4 ;; Maintainer: FSF
   5 ;; Keywords: unix, tools
   6
   7 ;; Copyright (C) 1992, 93, 94, 95, 96, 1998, 2000 Free Software Foundation, Inc.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; The ancestral gdb.el was by W. Schelter <wfs@rascal.ics.utexas.edu>
  29 ;; It was later rewritten by rms.  Some ideas were due to Masanobu.
  30 ;; Grand Unification (sdb/dbx support) by Eric S. Raymond <esr@thyrsus.com>
  31 ;; The overloading code was then rewritten by Barry Warsaw <bwarsaw@cen.com>,
  32 ;; who also hacked the mode to use comint.el.  Shane Hartman <shane@spr.com>
  33 ;; added support for xdb (HPUX debugger).  Rick Sladkey <jrs@world.std.com>
  34 ;; wrote the GDB command completion code.  Dave Love <d.love@dl.ac.uk>
  35 ;; added the IRIX kluge, re-implemented the Mips-ish variant and added
  36 ;; a menu. Brian D. Carlstrom <bdc@ai.mit.edu> combined the IRIX kluge with
  37 ;; the gud-xdb-directories hack producing gud-dbx-directories.  Derek L. Davies
  38 ;; <ddavies@world.std.com> added support for jdb (Java debugger.)
  39
  40 ;;; Code:
  41
  42 (require 'comint)
  43 (require 'etags)
  44
  45 ;; ======================================================================
  46 ;; GUD commands must be visible in C buffers visited by GUD
  47
  48 (defgroup gud nil
  49   "Grand Unified Debugger mode for gdb and other debuggers under Emacs.
  50 Supported debuggers include gdb, sdb, dbx, xdb, perldb, pdb (Python), and jdb."
  51   :group 'unix
  52   :group 'tools)
  53
  54
  55 (defcustom gud-key-prefix "\C-x\C-a"
  56   "Prefix of all GUD commands valid in C buffers."
  57   :type 'string
  58   :group 'gud)
  59
  60 (global-set-key (concat gud-key-prefix "\C-l") 'gud-refresh)
  61 (define-key ctl-x-map " " 'gud-break)   ;; backward compatibility hack
  62
  63 (defvar gud-marker-filter nil)
  64 (put 'gud-marker-filter 'permanent-local t)
  65 (defvar gud-find-file nil)
  66 (put 'gud-find-file 'permanent-local t)
  67
  68 (defun gud-marker-filter (&rest args)
  69   (apply gud-marker-filter args))
  70
  71 (defvar gud-minor-mode nil)
  72 (put 'gud-minor-mode 'permanent-local t)
  73
  74 (defun gud-symbol (sym &optional soft minor-mode)
  75   "Return the symbol used for SYM in MINOR-MODE.
  76 MINOR-MODE defaults to `gud-minor-mode.
  77 The symbol returned is `gud-<MINOR-MODE>-<SYM>'.
  78 If SOFT is non-nil, returns nil if the symbol doesn't already exist."
  79   (unless (or minor-mode gud-minor-mode) (error "Gud internal error"))
  80   (funcall (if soft 'intern-soft 'intern)
  81            (format "gud-%s-%s" (or minor-mode gud-minor-mode) sym)))
  82
  83 (defun gud-val (sym &optional minor-mode)
  84   "Return the value of `gud-symbol' SYM.  Default to nil."
  85   (let ((sym (gud-symbol sym t minor-mode)))
  86     (if (boundp sym) (symbol-value sym))))
  87
  88 (defun gud-find-file (file)
  89   ;; Don't get confused by double slashes in the name that comes from GDB.
  90   (while (string-match "//+" file)
  91     (setq file (replace-match "/" t t file)))
  92   (let ((minor-mode gud-minor-mode)
  93         (buf (funcall gud-find-file file)))
  94     (when buf
  95       ;; Copy `gud-minor-mode' to the found buffer to turn on the menu.
  96       (with-current-buffer buf
  97         (set (make-local-variable 'gud-minor-mode) minor-mode))
  98       buf)))
  99
 100 (easy-mmode-defmap gud-menu-map
 101   '(([refresh]  "Refresh" . gud-refresh)
 102     ([remove]   "Remove Breakpoint" . gud-remove)
 103     ([tbreak]   menu-item "Temporary Breakpoint" gud-tbreak
 104                         :enable (memq gud-minor-mode '(gdb sdb xdb)))
 105     ([break]    "Set Breakpoint" . gud-break)
 106     ([up]       menu-item "Up Stack" gud-up
 107                         :enable (memq gud-minor-mode '(gdb dbx xdb jdb)))
 108     ([down]     menu-item "Down Stack" gud-down
 109                         :enable (memq gud-minor-mode '(gdb dbx xdb jdb)))
 110     ([print]    "Print Expression" . gud-print)
 111     ([finish]   menu-item "Finish Function" gud-finish
 112                         :enable (memq gud-minor-mode '(gdb xdb jdb)))
 113     ([stepi]    "Step Instruction" . gud-stepi)
 114     ([step]     "Step Line" . gud-step)
 115     ([next]     "Next Line" . gud-next)
 116     ([cont]     "Continue" . gud-cont))
 117   "Menu for `gud-mode'."
 118   :name "Gud")
 119
 120 (easy-mmode-defmap gud-minor-mode-map
 121   `(([menu-bar debug] . ("Gud" . ,gud-menu-map)))
 122   "Map used in visited files.")
 123
 124 (let ((m (assq 'gud-minor-mode minor-mode-map-alist)))
 125   (if m (setcdr m gud-minor-mode-map)
 126     (push (cons 'gud-minor-mode gud-minor-mode-map) minor-mode-map-alist)))
 127
 128 (defvar gud-mode-map
 129   ;; Will inherit from comint-mode via define-derived-mode.
 130   (make-sparse-keymap)
 131   "`gud-mode' keymap.")
 132 \f
 133 ;; ======================================================================
 134 ;; command definition
 135
 136 ;; This macro is used below to define some basic debugger interface commands.
 137 ;; Of course you may use `gud-def' with any other debugger command, including
 138 ;; user defined ones.
 139
 140 ;; A macro call like (gud-def FUNC NAME KEY DOC) expands to a form
 141 ;; which defines FUNC to send the command NAME to the debugger, gives
 142 ;; it the docstring DOC, and binds that function to KEY in the GUD
 143 ;; major mode.  The function is also bound in the global keymap with the
 144 ;; GUD prefix.
 145
 146 (defmacro gud-def (func cmd key &optional doc)
 147   "Define FUNC to be a command sending STR and bound to KEY, with
 148 optional doc string DOC.  Certain %-escapes in the string arguments
 149 are interpreted specially if present.  These are:
 150
 151   %f    name (without directory) of current source file.
 152   %F    name (without directory or extension) of current source file.
 153   %d    directory of current source file.
 154   %l    number of current source line
 155   %e    text of the C lvalue or function-call expression surrounding point.
 156   %a    text of the hexadecimal address surrounding point
 157   %p    prefix argument to the command (if any) as a number
 158
 159   The `current' source file is the file of the current buffer (if
 160 we're in a C file) or the source file current at the last break or
 161 step (if we're in the GUD buffer).
 162   The `current' line is that of the current buffer (if we're in a
 163 source file) or the source line number at the last break or step (if
 164 we're in the GUD buffer)."
 165   (list 'progn
 166         (list 'defun func '(arg)
 167               (or doc "")
 168               '(interactive "p")
 169               (list 'gud-call cmd 'arg))
 170         (if key
 171             (list 'define-key
 172                   '(current-local-map)
 173                   (concat "\C-c" key)
 174                   (list 'quote func)))
 175         (if key
 176             (list 'global-set-key
 177                   (list 'concat 'gud-key-prefix key)
 178                   (list 'quote func)))))
 179
 180 ;; Where gud-display-frame should put the debugging arrow; a cons of
 181 ;; (filename . line-number).  This is set by the marker-filter, which scans
 182 ;; the debugger's output for indications of the current program counter.
 183 (defvar gud-last-frame nil)
 184
 185 ;; Used by gud-refresh, which should cause gud-display-frame to redisplay
 186 ;; the last frame, even if it's been called before and gud-last-frame has
 187 ;; been set to nil.
 188 (defvar gud-last-last-frame nil)
 189
 190 ;; All debugger-specific information is collected here.
 191 ;; Here's how it works, in case you ever need to add a debugger to the mode.
 192 ;;
 193 ;; Each entry must define the following at startup:
 194 ;;
 195 ;;<name>
 196 ;; comint-prompt-regexp
 197 ;; gud-<name>-massage-args
 198 ;; gud-<name>-marker-filter
 199 ;; gud-<name>-find-file
 200 ;;
 201 ;; The job of the massage-args method is to modify the given list of
 202 ;; debugger arguments before running the debugger.
 203 ;;
 204 ;; The job of the marker-filter method is to detect file/line markers in
 205 ;; strings and set the global gud-last-frame to indicate what display
 206 ;; action (if any) should be triggered by the marker.  Note that only
 207 ;; whatever the method *returns* is displayed in the buffer; thus, you
 208 ;; can filter the debugger's output, interpreting some and passing on
 209 ;; the rest.
 210 ;;
 211 ;; The job of the find-file method is to visit and return the buffer indicated
 212 ;; by the car of gud-tag-frame.  This may be a file name, a tag name, or
 213 ;; something else.
 214 \f
 215 ;; ======================================================================
 216 ;; speedbar support functions and variables.
 217 (eval-when-compile (require 'speedbar))
 218
 219 (defvar gud-last-speedbar-buffer nil
 220   "The last GUD buffer used.")
 221
 222 (defvar gud-last-speedbar-stackframe nil
 223   "Description of the currently displayed GUD stack.
 224 t means that there is no stack, and we are in display-file mode.")
 225
 226 (defvar gud-speedbar-key-map nil
 227   "Keymap used when in the buffers display mode.")
 228
 229 (defun gud-install-speedbar-variables ()
 230   "Install those variables used by speedbar to enhance gud/gdb."
 231   (if gud-speedbar-key-map
 232       nil
 233     (setq gud-speedbar-key-map (speedbar-make-specialized-keymap))
 234
 235     (define-key gud-speedbar-key-map "j" 'speedbar-edit-line)
 236     (define-key gud-speedbar-key-map "e" 'speedbar-edit-line)
 237     (define-key gud-speedbar-key-map "\C-m" 'speedbar-edit-line)))
 238
 239 (defvar gud-speedbar-menu-items
 240   ;; Note to self.  Add expand, and turn off items when not available.
 241   '(["Jump to stack frame" speedbar-edit-line t])
 242   "Additional menu items to add to the speedbar frame.")
 243
 244 ;; Make sure our special speedbar mode is loaded
 245 (if (featurep 'speedbar)
 246     (gud-install-speedbar-variables)
 247   (add-hook 'speedbar-load-hook 'gud-install-speedbar-variables))
 248
 249 (defun gud-speedbar-buttons (buffer)
 250   "Create a speedbar display based on the current state of GUD.
 251 If the GUD BUFFER is not running a supported debugger, then turn
 252 off the specialized speedbar mode."
 253   (if (and (save-excursion (goto-char (point-min))
 254                            (looking-at "Current Stack"))
 255            (equal gud-last-last-frame gud-last-speedbar-stackframe))
 256       nil
 257     (setq gud-last-speedbar-buffer buffer)
 258     (let* ((ff (save-excursion (set-buffer buffer) gud-find-file))
 259            ;;(lf (save-excursion (set-buffer buffer) gud-last-last-frame))
 260            (frames
 261             (cond ((eq ff 'gud-gdb-find-file)
 262                    (gud-gdb-get-stackframe buffer)
 263                    )
 264                   ;; Add more debuggers here!
 265                   (t
 266                    (speedbar-remove-localized-speedbar-support buffer)
 267                    nil))))
 268       (erase-buffer)
 269       (if (not frames)
 270           (insert "No Stack frames\n")
 271         (insert "Current Stack:\n"))
 272       (while frames
 273         (insert (nth 1 (car frames)) ":\n")
 274         (if (= (length (car frames)) 2)
 275             (progn
 276 ;             (speedbar-insert-button "[?]"
 277 ;                                     'speedbar-button-face
 278 ;                                     nil nil nil t)
 279               (speedbar-insert-button (car (car frames))
 280                                       'speedbar-directory-face
 281                                       nil nil nil t))
 282 ;         (speedbar-insert-button "[+]"
 283 ;                                 'speedbar-button-face
 284 ;                                 'speedbar-highlight-face
 285 ;                                 'gud-gdb-get-scope-data
 286 ;                                 (car frames) t)
 287           (speedbar-insert-button (car (car frames))
 288                                   'speedbar-file-face
 289                                   'speedbar-highlight-face
 290                                   (cond ((eq ff 'gud-gdb-find-file)
 291                                          'gud-gdb-goto-stackframe)
 292                                         (t (error "Should never be here")))
 293                                   (car frames) t))
 294         (setq frames (cdr frames)))
 295 ;      (let ((selected-frame
 296 ;            (cond ((eq ff 'gud-gdb-find-file)
 297 ;                   (gud-gdb-selected-frame-info buffer))
 298 ;                  (t (error "Should never be here"))))))
 299       )
 300     (setq gud-last-speedbar-stackframe gud-last-last-frame)))
 301
 302 \f
 303 ;; ======================================================================
 304 ;; gdb functions
 305
 306 ;;; History of argument lists passed to gdb.
 307 (defvar gud-gdb-history nil)
 308
 309 (defun gud-gdb-massage-args (file args)
 310   (cons "-fullname" args))
 311
 312 (defvar gud-gdb-marker-regexp
 313   ;; This used to use path-separator instead of ":";
 314   ;; however, we found that on both Windows 32 and MSDOS
 315   ;; a colon is correct here.
 316   (concat "\032\032\\(.:?[^" ":" "\n]*\\)" ":"
 317           "\\([0-9]*\\)" ":" ".*\n"))
 318
 319 ;; There's no guarantee that Emacs will hand the filter the entire
 320 ;; marker at once; it could be broken up across several strings.  We
 321 ;; might even receive a big chunk with several markers in it.  If we
 322 ;; receive a chunk of text which looks like it might contain the
 323 ;; beginning of a marker, we save it here between calls to the
 324 ;; filter.
 325 (defvar gud-marker-acc "")
 326 (make-variable-buffer-local 'gud-marker-acc)
 327
 328 (defun gud-gdb-marker-filter (string)
 329   (setq gud-marker-acc (concat gud-marker-acc string))
 330   (let ((output ""))
 331
 332     ;; Process all the complete markers in this chunk.
 333     (while (string-match gud-gdb-marker-regexp gud-marker-acc)
 334       (setq
 335
 336        ;; Extract the frame position from the marker.
 337        gud-last-frame
 338        (cons (substring gud-marker-acc (match-beginning 1) (match-end 1))
 339              (string-to-int (substring gud-marker-acc
 340                                        (match-beginning 2)
 341                                        (match-end 2))))
 342
 343        ;; Append any text before the marker to the output we're going
 344        ;; to return - we don't include the marker in this text.
 345        output (concat output
 346                       (substring gud-marker-acc 0 (match-beginning 0)))
 347
 348        ;; Set the accumulator to the remaining text.
 349        gud-marker-acc (substring gud-marker-acc (match-end 0))))
 350
 351     ;; Does the remaining text look like it might end with the
 352     ;; beginning of another marker?  If it does, then keep it in
 353     ;; gud-marker-acc until we receive the rest of it.  Since we
 354     ;; know the full marker regexp above failed, it's pretty simple to
 355     ;; test for marker starts.
 356     (if (string-match "\032.*\\'" gud-marker-acc)
 357         (progn
 358           ;; Everything before the potential marker start can be output.
 359           (setq output (concat output (substring gud-marker-acc
 360                                                  0 (match-beginning 0))))
 361
 362           ;; Everything after, we save, to combine with later input.
 363           (setq gud-marker-acc
 364                 (substring gud-marker-acc (match-beginning 0))))
 365
 366       (setq output (concat output gud-marker-acc)
 367             gud-marker-acc ""))
 368
 369     output))
 370
 371 (defun gud-gdb-find-file (f)
 372   (find-file-noselect f 'nowarn))
 373
 374 (easy-mmode-defmap gud-minibuffer-local-map
 375   '(("\C-i" . comint-dynamic-complete-filename))
 376   "Keymap for minibuffer prompting of gud startup command."
 377   :inherit minibuffer-local-map)
 378
 379 (defun gud-query-cmdline (minor-mode &optional init)
 380   (let* ((hist-sym (gud-symbol 'history nil minor-mode))
 381          (cmd-name (gud-val 'command-name minor-mode)))
 382     (unless (boundp hist-sym) (set hist-sym nil))
 383     (read-from-minibuffer
 384      (format "Run %s (like this): " minor-mode)
 385      (or (car-safe (symbol-value hist-sym))
 386          (concat (or cmd-name (symbol-name minor-mode)) " " init))
 387      gud-minibuffer-local-map nil
 388      hist-sym)))
 389
 390 ;;;###autoload
 391 (defun gdb (command-line)
 392   "Run gdb on program FILE in buffer *gud-FILE*.
 393 The directory containing FILE becomes the initial working directory
 394 and source-file directory for your debugger."
 395   (interactive (list (gud-query-cmdline 'gdb)))
 396
 397   (gud-common-init command-line 'gud-gdb-massage-args
 398                    'gud-gdb-marker-filter 'gud-gdb-find-file)
 399   (set (make-local-variable 'gud-minor-mode) 'gdb)
 400
 401   (gud-def gud-break  "break %f:%l"  "\C-b" "Set breakpoint at current line.")
 402   (gud-def gud-tbreak "tbreak %f:%l" "\C-t" "Set temporary breakpoint at current line.")
 403   (gud-def gud-remove "clear %f:%l"  "\C-d" "Remove breakpoint at current line")
 404   (gud-def gud-step   "step %p"      "\C-s" "Step one source line with display.")
 405   (gud-def gud-stepi  "stepi %p"     "\C-i" "Step one instruction with display.")
 406   (gud-def gud-next   "next %p"      "\C-n" "Step one line (skip functions).")
 407   (gud-def gud-cont   "cont"         "\C-r" "Continue with display.")
 408   (gud-def gud-finish "finish"       "\C-f" "Finish executing current function.")
 409   (gud-def gud-jump   "tbreak %f:%l\njump %f:%l" "\C-j" "Relocate execution address to line at point in source buffer.")
 410
 411   (gud-def gud-up     "up %p"        "<" "Up N stack frames (numeric arg).")
 412   (gud-def gud-down   "down %p"      ">" "Down N stack frames (numeric arg).")
 413   (gud-def gud-print  "print %e"     "\C-p" "Evaluate C expression at point.")
 414
 415   (local-set-key "\C-i" 'gud-gdb-complete-command)
 416   (local-set-key [menu-bar debug tbreak] '("Temporary Breakpoint" . gud-tbreak))
 417   (local-set-key [menu-bar debug finish] '("Finish Function" . gud-finish))
 418   (local-set-key [menu-bar debug up] '("Up Stack" . gud-up))
 419   (local-set-key [menu-bar debug down] '("Down Stack" . gud-down))
 420   (setq comint-prompt-regexp "^(.*gdb[+]?) *")
 421   (setq paragraph-start comint-prompt-regexp)
 422   (run-hooks 'gdb-mode-hook)
 423   )
 424
 425 ;; One of the nice features of GDB is its impressive support for
 426 ;; context-sensitive command completion.  We preserve that feature
 427 ;; in the GUD buffer by using a GDB command designed just for Emacs.
 428
 429 ;; The completion process filter indicates when it is finished.
 430 (defvar gud-gdb-complete-in-progress)
 431
 432 ;; Since output may arrive in fragments we accumulate partials strings here.
 433 (defvar gud-gdb-complete-string)
 434
 435 ;; We need to know how much of the completion to chop off.
 436 (defvar gud-gdb-complete-break)
 437
 438 ;; The completion list is constructed by the process filter.
 439 (defvar gud-gdb-complete-list)
 440
 441 (defvar gud-comint-buffer nil)
 442
 443 (defun gud-gdb-complete-command ()
 444   "Perform completion on the GDB command preceding point.
 445 This is implemented using the GDB `complete' command which isn't
 446 available with older versions of GDB."
 447   (interactive)
 448   (let* ((end (point))
 449          (command (buffer-substring (comint-line-beginning-position) end))
 450          command-word)
 451     ;; Find the word break.  This match will always succeed.
 452     (string-match "\\(\\`\\| \\)\\([^ ]*\\)\\'" command)
 453     (setq gud-gdb-complete-break (match-beginning 2)
 454           command-word (substring command gud-gdb-complete-break))
 455     ;; Temporarily install our filter function.
 456     (let ((gud-marker-filter 'gud-gdb-complete-filter))
 457       ;; Issue the command to GDB.
 458       (gud-basic-call (concat "complete " command))
 459       (setq gud-gdb-complete-in-progress t
 460             gud-gdb-complete-string nil
 461             gud-gdb-complete-list nil)
 462       ;; Slurp the output.
 463       (while gud-gdb-complete-in-progress
 464         (accept-process-output (get-buffer-process gud-comint-buffer))))
 465     ;; Protect against old versions of GDB.
 466     (and gud-gdb-complete-list
 467          (string-match "^Undefined command: \"complete\""
 468                        (car gud-gdb-complete-list))
 469          (error "This version of GDB doesn't support the `complete' command"))
 470     ;; Sort the list like readline.
 471     (setq gud-gdb-complete-list
 472           (sort gud-gdb-complete-list (function string-lessp)))
 473     ;; Remove duplicates.
 474     (let ((first gud-gdb-complete-list)
 475           (second (cdr gud-gdb-complete-list)))
 476       (while second
 477         (if (string-equal (car first) (car second))
 478             (setcdr first (setq second (cdr second)))
 479           (setq first second
 480                 second (cdr second)))))
 481     ;; Add a trailing single quote if there is a unique completion
 482     ;; and it contains an odd number of unquoted single quotes.
 483     (and (= (length gud-gdb-complete-list) 1)
 484          (let ((str (car gud-gdb-complete-list))
 485                (pos 0)
 486                (count 0))
 487            (while (string-match "\\([^'\\]\\|\\\\'\\)*'" str pos)
 488              (setq count (1+ count)
 489                    pos (match-end 0)))
 490            (and (= (mod count 2) 1)
 491                 (setq gud-gdb-complete-list (list (concat str "'"))))))
 492     ;; Let comint handle the rest.
 493     (comint-dynamic-simple-complete command-word gud-gdb-complete-list)))
 494
 495 ;; The completion process filter is installed temporarily to slurp the
 496 ;; output of GDB up to the next prompt and build the completion list.
 497 (defun gud-gdb-complete-filter (string)
 498   (setq string (concat gud-gdb-complete-string string))
 499   (while (string-match "\n" string)
 500     (setq gud-gdb-complete-list
 501           (cons (substring string gud-gdb-complete-break (match-beginning 0))
 502                 gud-gdb-complete-list))
 503     (setq string (substring string (match-end 0))))
 504   (if (string-match comint-prompt-regexp string)
 505       (progn
 506         (setq gud-gdb-complete-in-progress nil)
 507         string)
 508     (progn
 509       (setq gud-gdb-complete-string string)
 510       "")))
 511
 512 ;; gdb speedbar functions
 513
 514 (defun gud-gdb-goto-stackframe (text token indent)
 515   "Goto the stackframe described by TEXT, TOKEN, and INDENT."
 516   (speedbar-with-attached-buffer
 517    (gud-basic-call (concat "frame " (nth 1 token)))
 518    (sit-for 1)))
 519
 520 (defvar gud-gdb-fetched-stack-frame nil
 521   "Stack frames we are fetching from GDB.")
 522
 523 (defvar gud-gdb-fetched-stack-frame-list nil
 524   "List of stack frames we are fetching from GDB.")
 525
 526 ;(defun gud-gdb-get-scope-data (text token indent)
 527 ;  ;; checkdoc-params: (indent)
 528 ;  "Fetch data associated with a stack frame, and expand/contract it.
 529 ;Data to do this is retrieved from TEXT and TOKEN."
 530 ;  (let ((args nil) (scope nil))
 531 ;    (gud-gdb-run-command-fetch-lines "info args")
 532 ;
 533 ;    (gud-gdb-run-command-fetch-lines "info local")
 534 ;
 535 ;    ))
 536
 537 (defun gud-gdb-get-stackframe (buffer)
 538   "Extract the current stack frame out of the GUD GDB BUFFER."
 539   (let ((newlst nil)
 540         (gud-gdb-fetched-stack-frame-list nil))
 541     (gud-gdb-run-command-fetch-lines "backtrace" buffer)
 542     (if (and (car gud-gdb-fetched-stack-frame-list)
 543              (string-match "No stack" (car gud-gdb-fetched-stack-frame-list)))
 544         ;; Go into some other mode???
 545         nil
 546       (while gud-gdb-fetched-stack-frame-list
 547         (let ((e (car gud-gdb-fetched-stack-frame-list))
 548               (name nil) (num nil))
 549           (if (not (or
 550                     (string-match "^#\\([0-9]+\\) +[0-9a-fx]+ in \\([:0-9a-zA-Z_]+\\) (" e)
 551                     (string-match "^#\\([0-9]+\\) +\\([:0-9a-zA-Z_]+\\) (" e)))
 552               (if (not (string-match
 553                         "at \\([-0-9a-zA-Z_.]+\\):\\([0-9]+\\)$" e))
 554                   nil
 555                 (setcar newlst
 556                         (list (nth 0 (car newlst))
 557                               (nth 1 (car newlst))
 558                               (match-string 1 e)
 559                               (match-string 2 e))))
 560             (setq num (match-string 1 e)
 561                   name (match-string 2 e))
 562             (setq newlst
 563                   (cons
 564                    (if (string-match
 565                         "at \\([-0-9a-zA-Z_.]+\\):\\([0-9]+\\)$" e)
 566                        (list name num (match-string 1 e)
 567                              (match-string 2 e))
 568                      (list name num))
 569                    newlst))))
 570         (setq gud-gdb-fetched-stack-frame-list
 571               (cdr gud-gdb-fetched-stack-frame-list)))
 572       (nreverse newlst))))
 573
 574 ;(defun gud-gdb-selected-frame-info (buffer)
 575 ;  "Learn GDB information for the currently selected stack frame in BUFFER."
 576 ;  )
 577
 578 (defun gud-gdb-run-command-fetch-lines (command buffer)
 579   "Run COMMAND, and return when `gud-gdb-fetched-stack-frame-list' is full.
 580 BUFFER is the GUD buffer in which to run the command."
 581   (save-excursion
 582     (set-buffer buffer)
 583     (if (save-excursion
 584           (goto-char (point-max))
 585           (forward-line 0)
 586           (not (looking-at comint-prompt-regexp)))
 587         nil
 588       ;; Much of this copied from GDB complete, but I'm grabbing the stack
 589       ;; frame instead.
 590       (let ((gud-marker-filter 'gud-gdb-speedbar-stack-filter))
 591         ;; Issue the command to GDB.
 592         (gud-basic-call command)
 593         (setq gud-gdb-complete-in-progress t ;; use this flag for our purposes.
 594               gud-gdb-complete-string nil
 595               gud-gdb-complete-list nil)
 596         ;; Slurp the output.
 597         (while gud-gdb-complete-in-progress
 598           (accept-process-output (get-buffer-process gud-comint-buffer)))
 599         (setq gud-gdb-fetched-stack-frame nil
 600               gud-gdb-fetched-stack-frame-list
 601               (nreverse gud-gdb-fetched-stack-frame-list))))))
 602
 603 (defun gud-gdb-speedbar-stack-filter (string)
 604   ;; checkdoc-params: (string)
 605   "Filter used to read in the current GDB stack."
 606   (setq string (concat gud-gdb-fetched-stack-frame string))
 607   (while (string-match "\n" string)
 608     (setq gud-gdb-fetched-stack-frame-list
 609           (cons (substring string 0 (match-beginning 0))
 610                 gud-gdb-fetched-stack-frame-list))
 611     (setq string (substring string (match-end 0))))
 612   (if (string-match comint-prompt-regexp string)
 613       (progn
 614         (setq gud-gdb-complete-in-progress nil)
 615         string)
 616     (progn
 617       (setq gud-gdb-complete-string string)
 618       "")))
 619
 620 \f
 621 ;; ======================================================================
 622 ;; sdb functions
 623
 624 ;;; History of argument lists passed to sdb.
 625 (defvar gud-sdb-history nil)
 626
 627 (defvar gud-sdb-needs-tags (not (file-exists-p "/var"))
 628   "If nil, we're on a System V Release 4 and don't need the tags hack.")
 629
 630 (defvar gud-sdb-lastfile nil)
 631
 632 (defun gud-sdb-massage-args (file args) args)
 633
 634 (defun gud-sdb-marker-filter (string)
 635   (setq gud-marker-acc
 636         (if gud-marker-acc (concat gud-marker-acc string) string))
 637   (let (start)
 638     ;; Process all complete markers in this chunk
 639     (while
 640         (cond
 641          ;; System V Release 3.2 uses this format
 642          ((string-match "\\(^\\|\n\\)\\*?\\(0x\\w* in \\)?\\([^:\n]*\\):\\([0-9]*\\):.*\n"
 643                         gud-marker-acc start)
 644           (setq gud-last-frame
 645                 (cons
 646                  (substring gud-marker-acc (match-beginning 3) (match-end 3))
 647                  (string-to-int
 648                   (substring gud-marker-acc (match-beginning 4) (match-end 4))))))
 649          ;; System V Release 4.0 quite often clumps two lines together
 650          ((string-match "^\\(BREAKPOINT\\|STEPPED\\) process [0-9]+ function [^ ]+ in \\(.+\\)\n\\([0-9]+\\):"
 651                         gud-marker-acc start)
 652           (setq gud-sdb-lastfile
 653                 (substring gud-marker-acc (match-beginning 2) (match-end 2)))
 654           (setq gud-last-frame
 655                 (cons
 656                  gud-sdb-lastfile
 657                  (string-to-int
 658                   (substring gud-marker-acc (match-beginning 3) (match-end 3))))))
 659          ;; System V Release 4.0
 660          ((string-match "^\\(BREAKPOINT\\|STEPPED\\) process [0-9]+ function [^ ]+ in \\(.+\\)\n"
 661                         gud-marker-acc start)
 662           (setq gud-sdb-lastfile
 663                 (substring gud-marker-acc (match-beginning 2) (match-end 2))))
 664          ((and gud-sdb-lastfile (string-match "^\\([0-9]+\\):"
 665                                               gud-marker-acc start))
 666                (setq gud-last-frame
 667                      (cons
 668                       gud-sdb-lastfile
 669                       (string-to-int
 670                        (substring gud-marker-acc (match-beginning 1) (match-end 1))))))
 671          (t
 672           (setq gud-sdb-lastfile nil)))
 673       (setq start (match-end 0)))
 674
 675     ;; Search for the last incomplete line in this chunk
 676     (while (string-match "\n" gud-marker-acc start)
 677       (setq start (match-end 0)))
 678
 679     ;; If we have an incomplete line, store it in gud-marker-acc.
 680     (setq gud-marker-acc (substring gud-marker-acc (or start 0))))
 681   string)
 682
 683 (defun gud-sdb-find-file (f)
 684   (if gud-sdb-needs-tags (find-tag-noselect f) (find-file-noselect f)))
 685
 686 ;;;###autoload
 687 (defun sdb (command-line)
 688   "Run sdb on program FILE in buffer *gud-FILE*.
 689 The directory containing FILE becomes the initial working directory
 690 and source-file directory for your debugger."
 691   (interactive (list (gud-query-cmdline 'sdb)))
 692
 693   (if (and gud-sdb-needs-tags
 694            (not (and (boundp 'tags-file-name)
 695                      (stringp tags-file-name)
 696                      (file-exists-p tags-file-name))))
 697       (error "The sdb support requires a valid tags table to work"))
 698
 699   (gud-common-init command-line 'gud-sdb-massage-args
 700                    'gud-sdb-marker-filter 'gud-sdb-find-file)
 701   (set (make-local-variable 'gud-minor-mode) 'sdb)
 702
 703   (gud-def gud-break  "%l b" "\C-b"   "Set breakpoint at current line.")
 704   (gud-def gud-tbreak "%l c" "\C-t"   "Set temporary breakpoint at current line.")
 705   (gud-def gud-remove "%l d" "\C-d"   "Remove breakpoint at current line")
 706   (gud-def gud-step   "s %p" "\C-s"   "Step one source line with display.")
 707   (gud-def gud-stepi  "i %p" "\C-i"   "Step one instruction with display.")
 708   (gud-def gud-next   "S %p" "\C-n"   "Step one line (skip functions).")
 709   (gud-def gud-cont   "c"    "\C-r"   "Continue with display.")
 710   (gud-def gud-print  "%e/"  "\C-p"   "Evaluate C expression at point.")
 711
 712   (setq comint-prompt-regexp  "\\(^\\|\n\\)\\*")
 713   (setq paragraph-start comint-prompt-regexp)
 714   (local-set-key [menu-bar debug tbreak]
 715     '("Temporary Breakpoint" . gud-tbreak))
 716   (run-hooks 'sdb-mode-hook)
 717   )
 718 \f
 719 ;; ======================================================================
 720 ;; dbx functions
 721
 722 ;;; History of argument lists passed to dbx.
 723 (defvar gud-dbx-history nil)
 724
 725 (defcustom gud-dbx-directories nil
 726   "*A list of directories that dbx should search for source code.
 727 If nil, only source files in the program directory
 728 will be known to dbx.
 729
 730 The file names should be absolute, or relative to the directory
 731 containing the executable being debugged."
 732   :type '(choice (const :tag "Current Directory" nil)
 733                  (repeat :value ("")
 734                          directory))
 735   :group 'gud)
 736
 737 (defun gud-dbx-massage-args (file args)
 738   (nconc (let ((directories gud-dbx-directories)
 739                (result nil))
 740            (while directories
 741              (setq result (cons (car directories) (cons "-I" result)))
 742              (setq directories (cdr directories)))
 743            (nreverse result))
 744          args))
 745
 746 (defun gud-dbx-file-name (f)
 747   "Transform a relative file name to an absolute file name, for dbx."
 748   (let ((result nil))
 749     (if (file-exists-p f)
 750         (setq result (expand-file-name f))
 751       (let ((directories gud-dbx-directories))
 752         (while directories
 753           (let ((path (concat (car directories) "/" f)))
 754             (if (file-exists-p path)
 755                 (setq result (expand-file-name path)
 756                       directories nil)))
 757           (setq directories (cdr directories)))))
 758     result))
 759
 760 (defun gud-dbx-marker-filter (string)
 761   (setq gud-marker-acc (if gud-marker-acc (concat gud-marker-acc string) string))
 762
 763   (let (start)
 764     ;; Process all complete markers in this chunk.
 765     (while (or (string-match
 766                 "stopped in .* at line \\([0-9]*\\) in file \"\\([^\"]*\\)\""
 767                 gud-marker-acc start)
 768                (string-match
 769                 "signal .* in .* at line \\([0-9]*\\) in file \"\\([^\"]*\\)\""
 770                 gud-marker-acc start))
 771       (setq gud-last-frame
 772             (cons
 773              (substring gud-marker-acc (match-beginning 2) (match-end 2))
 774              (string-to-int
 775               (substring gud-marker-acc (match-beginning 1) (match-end 1))))
 776             start (match-end 0)))
 777
 778     ;; Search for the last incomplete line in this chunk
 779     (while (string-match "\n" gud-marker-acc start)
 780       (setq start (match-end 0)))
 781
 782     ;; If the incomplete line APPEARS to begin with another marker, keep it
 783     ;; in the accumulator.  Otherwise, clear the accumulator to avoid an
 784     ;; unnecessary concat during the next call.
 785     (setq gud-marker-acc
 786           (if (string-match "\\(stopped\\|signal\\)" gud-marker-acc start)
 787               (substring gud-marker-acc (match-beginning 0))
 788             nil)))
 789   string)
 790
 791 ;; Functions for Mips-style dbx.  Given the option `-emacs', documented in
 792 ;; OSF1, not necessarily elsewhere, it produces markers similar to gdb's.
 793 (defvar gud-mips-p
 794   (or (string-match "^mips-[^-]*-ultrix" system-configuration)
 795       ;; We haven't tested gud on this system:
 796       (string-match "^mips-[^-]*-riscos" system-configuration)
 797       ;; It's documented on OSF/1.3
 798       (string-match "^mips-[^-]*-osf1" system-configuration)
 799       (string-match "^alpha[^-]*-[^-]*-osf" system-configuration))
 800   "Non-nil to assume the MIPS/OSF dbx conventions (argument `-emacs').")
 801
 802 (defun gud-mipsdbx-massage-args (file args)
 803   (cons "-emacs" args))
 804
 805 ;; This is just like the gdb one except for the regexps since we need to cope
 806 ;; with an optional breakpoint number in [] before the ^Z^Z
 807 (defun gud-mipsdbx-marker-filter (string)
 808   (setq gud-marker-acc (concat gud-marker-acc string))
 809   (let ((output ""))
 810
 811     ;; Process all the complete markers in this chunk.
 812     (while (string-match
 813             ;; This is like th gdb marker but with an optional
 814             ;; leading break point number like `[1] '
 815             "[][ 0-9]*\032\032\\([^:\n]*\\):\\([0-9]*\\):.*\n"
 816             gud-marker-acc)
 817       (setq
 818
 819        ;; Extract the frame position from the marker.
 820        gud-last-frame
 821        (cons (substring gud-marker-acc (match-beginning 1) (match-end 1))
 822              (string-to-int (substring gud-marker-acc
 823                                        (match-beginning 2)
 824                                        (match-end 2))))
 825
 826        ;; Append any text before the marker to the output we're going
 827        ;; to return - we don't include the marker in this text.
 828        output (concat output
 829                       (substring gud-marker-acc 0 (match-beginning 0)))
 830
 831        ;; Set the accumulator to the remaining text.
 832        gud-marker-acc (substring gud-marker-acc (match-end 0))))
 833
 834     ;; Does the remaining text look like it might end with the
 835     ;; beginning of another marker?  If it does, then keep it in
 836     ;; gud-marker-acc until we receive the rest of it.  Since we
 837     ;; know the full marker regexp above failed, it's pretty simple to
 838     ;; test for marker starts.
 839     (if (string-match "[][ 0-9]*\032.*\\'" gud-marker-acc)
 840         (progn
 841           ;; Everything before the potential marker start can be output.
 842           (setq output (concat output (substring gud-marker-acc
 843                                                  0 (match-beginning 0))))
 844
 845           ;; Everything after, we save, to combine with later input.
 846           (setq gud-marker-acc
 847                 (substring gud-marker-acc (match-beginning 0))))
 848
 849       (setq output (concat output gud-marker-acc)
 850             gud-marker-acc ""))
 851
 852     output))
 853
 854 ;; The dbx in IRIX is a pain.  It doesn't print the file name when
 855 ;; stopping at a breakpoint (but you do get it from the `up' and
 856 ;; `down' commands...).  The only way to extract the information seems
 857 ;; to be with a `file' command, although the current line number is
 858 ;; available in $curline.  Thus we have to look for output which
 859 ;; appears to indicate a breakpoint.  Then we prod the dbx sub-process
 860 ;; to output the information we want with a combination of the
 861 ;; `printf' and `file' commands as a pseudo marker which we can
 862 ;; recognise next time through the marker-filter.  This would be like
 863 ;; the gdb marker but you can't get the file name without a newline...
 864 ;; Note that gud-remove won't work since Irix dbx expects a breakpoint
 865 ;; number rather than a line number etc.  Maybe this could be made to
 866 ;; work by listing all the breakpoints and picking the one(s) with the
 867 ;; correct line number, but life's too short.
 868 ;;   d.love@dl.ac.uk (Dave Love) can be blamed for this
 869
 870 (defvar gud-irix-p
 871   (and (string-match "^mips-[^-]*-irix" system-configuration)
 872        (not (string-match "irix[6-9]\\.[1-9]" system-configuration)))
 873   "Non-nil to assume the interface appropriate for IRIX dbx.
 874 This works in IRIX 4, 5 and 6, but `gud-dbx-use-stopformat-p' provides
 875 a better solution in 6.1 upwards.")
 876 (defvar gud-dbx-use-stopformat-p
 877   (string-match "irix[6-9]\\.[1-9]" system-configuration)
 878   "Non-nil to use the dbx feature present at least from Irix 6.1
 879   whereby $stopformat=1 produces an output format compatiable with
 880   `gud-dbx-marker-filter'.")
 881 ;; [Irix dbx seems to be a moving target.  The dbx output changed
 882 ;; subtly sometime between OS v4.0.5 and v5.2 so that, for instance,
 883 ;; the output from `up' is no longer spotted by gud (and it's probably
 884 ;; not distinctive enough to try to match it -- use C-<, C->
 885 ;; exclusively) .  For 5.3 and 6.0, the $curline variable changed to
 886 ;; `long long'(why?!), so the printf stuff needed changing.  The line
 887 ;; number was cast to `long' as a compromise between the new `long
 888 ;; long' and the original `int'.  This is reported not to work in 6.2,
 889 ;; so it's changed back to int -- don't make your sources too long.
 890 ;; From Irix6.1 (but not 6.0?) dbx supports an undocumented feature
 891 ;; whereby `set $stopformat=1' reportedly produces output compatible
 892 ;; with `gud-dbx-marker-filter', which we prefer.
 893
 894 ;; The process filter is also somewhat
 895 ;; unreliable, sometimes not spotting the markers; I don't know
 896 ;; whether there's anything that can be done about that.  It would be
 897 ;; much better if SGI could be persuaded to (re?)instate the MIPS
 898 ;; -emacs flag for gdb-like output (which ought to be possible as most
 899 ;; of the communication I've had over it has been from sgi.com).]
 900
 901 ;; this filter is influenced by the xdb one rather than the gdb one
 902 (defun gud-irixdbx-marker-filter (string)
 903   (let (result (case-fold-search nil))
 904     (if (or (string-match comint-prompt-regexp string)
 905             (string-match ".*\012" string))
 906         (setq result (concat gud-marker-acc string)
 907               gud-marker-acc "")
 908       (setq gud-marker-acc (concat gud-marker-acc string)))
 909     (if result
 910         (cond
 911          ;; look for breakpoint or signal indication e.g.:
 912          ;; [2] Process  1267 (pplot) stopped at [params:338 ,0x400ec0]
 913          ;; Process  1281 (pplot) stopped at [params:339 ,0x400ec8]
 914          ;; Process  1270 (pplot) Floating point exception [._read._read:16 ,0x452188]
 915          ((string-match
 916            "^\\(\\[[0-9]+] \\)?Process +[0-9]+ ([^)]*) [^[]+\\[[^]\n]*]\n"
 917            result)
 918           ;; prod dbx into printing out the line number and file
 919           ;; name in a form we can grok as below
 920           (process-send-string (get-buffer-process gud-comint-buffer)
 921                                "printf \"\032\032%1d:\",(int)$curline;file\n"))
 922          ;; look for result of, say, "up" e.g.:
 923          ;; .pplot.pplot(0x800) ["src/pplot.f":261, 0x400c7c]
 924          ;; (this will also catch one of the lines printed by "where")
 925          ((string-match
 926            "^[^ ][^[]*\\[\"\\([^\"]+\\)\":\\([0-9]+\\), [^]]+]\n"
 927            result)
 928           (let ((file (substring result (match-beginning 1)
 929                                  (match-end 1))))
 930             (if (file-exists-p file)
 931                 (setq gud-last-frame
 932                       (cons
 933                        (substring
 934                         result (match-beginning 1) (match-end 1))
 935                        (string-to-int
 936                         (substring
 937                          result (match-beginning 2) (match-end 2)))))))
 938           result)
 939          ((string-match                 ; kluged-up marker as above
 940            "\032\032\\([0-9]*\\):\\(.*\\)\n" result)
 941           (let ((file (gud-dbx-file-name
 942                        (substring result (match-beginning 2) (match-end 2)))))
 943             (if (and file (file-exists-p file))
 944                 (setq gud-last-frame
 945                       (cons
 946                        file
 947                        (string-to-int
 948                         (substring
 949                          result (match-beginning 1) (match-end 1)))))))
 950           (setq result (substring result 0 (match-beginning 0))))))
 951     (or result "")))
 952
 953 (defvar gud-dgux-p (string-match "-dgux" system-configuration)
 954   "Non-nil means to assume the interface approriate for DG/UX dbx.
 955 This was tested using R4.11.")
 956
 957 ;; There are a couple of differences between DG's dbx output and normal
 958 ;; dbx output which make it nontrivial to integrate this into the
 959 ;; standard dbx-marker-filter (mainly, there are a different number of
 960 ;; backreferences).  The markers look like:
 961 ;;
 962 ;;     (0) Stopped at line 10, routine main(argc=1, argv=0xeffff0e0), file t.c
 963 ;;
 964 ;; from breakpoints (the `(0)' there isn't constant, it's the breakpoint
 965 ;; number), and
 966 ;;
 967 ;;     Stopped at line 13, routine main(argc=1, argv=0xeffff0e0), file t.c
 968 ;;
 969 ;; from signals and
 970 ;;
 971 ;;     Frame 21, line 974, routine command_loop(), file keyboard.c
 972 ;;
 973 ;; from up/down/where.
 974
 975 (defun gud-dguxdbx-marker-filter (string)
 976   (setq gud-marker-acc (if gud-marker-acc
 977                            (concat gud-marker-acc string)
 978                          string))
 979   (let ((re (concat "^\\(\\(([0-9]+) \\)?Stopped at\\|Frame [0-9]+,\\)"
 980                     " line \\([0-9]+\\), routine .*, file \\([^ \t\n]+\\)"))
 981         start)
 982     ;; Process all complete markers in this chunk.
 983     (while (string-match re gud-marker-acc start)
 984       (setq gud-last-frame
 985             (cons
 986              (substring gud-marker-acc (match-beginning 4) (match-end 4))
 987              (string-to-int (substring gud-marker-acc
 988                                        (match-beginning 3) (match-end 3))))
 989             start (match-end 0)))
 990
 991     ;; Search for the last incomplete line in this chunk
 992     (while (string-match "\n" gud-marker-acc start)
 993       (setq start (match-end 0)))
 994
 995     ;; If the incomplete line APPEARS to begin with another marker, keep it
 996     ;; in the accumulator.  Otherwise, clear the accumulator to avoid an
 997     ;; unnecessary concat during the next call.
 998     (setq gud-marker-acc
 999           (if (string-match "Stopped\\|Frame" gud-marker-acc start)
1000               (substring gud-marker-acc (match-beginning 0))
1001             nil)))
1002   string)
1003
1004 (defun gud-dbx-find-file (f)
1005   (save-excursion
1006     (let ((realf (gud-dbx-file-name f)))
1007       (if realf
1008           (find-file-noselect realf)))))
1009
1010 ;;;###autoload
1011 (defun dbx (command-line)
1012   "Run dbx on program FILE in buffer *gud-FILE*.
1013 The directory containing FILE becomes the initial working directory
1014 and source-file directory for your debugger."
1015   (interactive (list (gud-query-cmdline 'dbx)))
1016
1017   (cond
1018    (gud-mips-p
1019     (gud-common-init command-line 'gud-mipsdbx-massage-args
1020                      'gud-mipsdbx-marker-filter 'gud-dbx-find-file))
1021    (gud-irix-p
1022     (gud-common-init command-line 'gud-dbx-massage-args
1023                      'gud-irixdbx-marker-filter 'gud-dbx-find-file))
1024    (gud-dgux-p
1025     (gud-common-init command-line 'gud-dbx-massage-args
1026                      'gud-dguxdbx-marker-filter 'gud-dbx-find-file))
1027    (t
1028     (gud-common-init command-line 'gud-dbx-massage-args
1029                      'gud-dbx-marker-filter 'gud-dbx-find-file)))
1030
1031   (set (make-local-variable 'gud-minor-mode) 'dbx)
1032
1033   (cond
1034    (gud-mips-p
1035     (gud-def gud-up     "up %p"         "<" "Up (numeric arg) stack frames.")
1036     (gud-def gud-down   "down %p" ">" "Down (numeric arg) stack frames.")
1037     (gud-def gud-break "stop at \"%f\":%l"
1038                                   "\C-b" "Set breakpoint at current line.")
1039     (gud-def gud-finish "return"  "\C-f" "Finish executing current function."))
1040    (gud-irix-p
1041     (gud-def gud-break "stop at \"%d%f\":%l"
1042                                   "\C-b" "Set breakpoint at current line.")
1043     (gud-def gud-finish "return"  "\C-f" "Finish executing current function.")
1044     (gud-def gud-up     "up %p; printf \"\032\032%1d:\",(int)$curline;file\n"
1045              "<" "Up (numeric arg) stack frames.")
1046     (gud-def gud-down "down %p; printf \"\032\032%1d:\",(int)$curline;file\n"
1047              ">" "Down (numeric arg) stack frames.")
1048     ;; Make dbx give out the source location info that we need.
1049     (process-send-string (get-buffer-process gud-comint-buffer)
1050                          "printf \"\032\032%1d:\",(int)$curline;file\n"))
1051    (t
1052     (gud-def gud-up     "up %p"         "<" "Up (numeric arg) stack frames.")
1053     (gud-def gud-down   "down %p" ">" "Down (numeric arg) stack frames.")
1054     (gud-def gud-break "file \"%d%f\"\nstop at %l"
1055                                   "\C-b" "Set breakpoint at current line.")
1056     (if gud-dbx-use-stopformat-p
1057         (process-send-string (get-buffer-process gud-comint-buffer)
1058                              "set $stopformat=1\n"))))
1059
1060   (gud-def gud-remove "clear %l"  "\C-d" "Remove breakpoint at current line")
1061   (gud-def gud-step   "step %p"   "\C-s" "Step one line with display.")
1062   (gud-def gud-stepi  "stepi %p"  "\C-i" "Step one instruction with display.")
1063   (gud-def gud-next   "next %p"   "\C-n" "Step one line (skip functions).")
1064   (gud-def gud-cont   "cont"      "\C-r" "Continue with display.")
1065   (gud-def gud-print  "print %e"  "\C-p" "Evaluate C expression at point.")
1066
1067   (setq comint-prompt-regexp  "^[^)\n]*dbx) *")
1068   (setq paragraph-start comint-prompt-regexp)
1069   (local-set-key [menu-bar debug up] '("Up Stack" . gud-up))
1070   (local-set-key [menu-bar debug down] '("Down Stack" . gud-down))
1071   (run-hooks 'dbx-mode-hook)
1072   )
1073 \f
1074 ;; ======================================================================
1075 ;; xdb (HP PARISC debugger) functions
1076
1077 ;;; History of argument lists passed to xdb.
1078 (defvar gud-xdb-history nil)
1079
1080 (defcustom gud-xdb-directories nil
1081   "*A list of directories that xdb should search for source code.
1082 If nil, only source files in the program directory
1083 will be known to xdb.
1084
1085 The file names should be absolute, or relative to the directory
1086 containing the executable being debugged."
1087   :type '(choice (const :tag "Current Directory" nil)
1088                  (repeat :value ("")
1089                          directory))
1090   :group 'gud)
1091
1092 (defun gud-xdb-massage-args (file args)
1093   (nconc (let ((directories gud-xdb-directories)
1094                (result nil))
1095            (while directories
1096              (setq result (cons (car directories) (cons "-d" result)))
1097              (setq directories (cdr directories)))
1098            (nreverse result))
1099          args))
1100
1101 (defun gud-xdb-file-name (f)
1102   "Transform a relative pathname to a full pathname in xdb mode"
1103   (let ((result nil))
1104     (if (file-exists-p f)
1105         (setq result (expand-file-name f))
1106       (let ((directories gud-xdb-directories))
1107         (while directories
1108           (let ((path (concat (car directories) "/" f)))
1109             (if (file-exists-p path)
1110                 (setq result (expand-file-name path)
1111                       directories nil)))
1112           (setq directories (cdr directories)))))
1113     result))
1114
1115 ;; xdb does not print the lines all at once, so we have to accumulate them
1116 (defun gud-xdb-marker-filter (string)
1117   (let (result)
1118     (if (or (string-match comint-prompt-regexp string)
1119             (string-match ".*\012" string))
1120         (setq result (concat gud-marker-acc string)
1121               gud-marker-acc "")
1122       (setq gud-marker-acc (concat gud-marker-acc string)))
1123     (if result
1124         (if (or (string-match "\\([^\n \t:]+\\): [^:]+: \\([0-9]+\\)[: ]"
1125                               result)
1126                 (string-match "[^: \t]+:[ \t]+\\([^:]+\\): [^:]+: \\([0-9]+\\):"
1127                               result))
1128             (let ((line (string-to-int
1129                          (substring result (match-beginning 2) (match-end 2))))
1130                   (file (gud-xdb-file-name
1131                          (substring result (match-beginning 1) (match-end 1)))))
1132               (if file
1133                   (setq gud-last-frame (cons file line))))))
1134     (or result "")))
1135
1136 (defun gud-xdb-find-file (f)
1137   (save-excursion
1138     (let ((realf (gud-xdb-file-name f)))
1139       (if realf
1140           (find-file-noselect realf)))))
1141
1142 ;;;###autoload
1143 (defun xdb (command-line)
1144   "Run xdb on program FILE in buffer *gud-FILE*.
1145 The directory containing FILE becomes the initial working directory
1146 and source-file directory for your debugger.
1147
1148 You can set the variable 'gud-xdb-directories' to a list of program source
1149 directories if your program contains sources from more than one directory."
1150   (interactive (list (gud-query-cmdline 'xdb)))
1151
1152   (gud-common-init command-line 'gud-xdb-massage-args
1153                    'gud-xdb-marker-filter 'gud-xdb-find-file)
1154   (set (make-local-variable 'gud-minor-mode) 'xdb)
1155
1156   (gud-def gud-break  "b %f:%l"    "\C-b" "Set breakpoint at current line.")
1157   (gud-def gud-tbreak "b %f:%l\\t" "\C-t"
1158            "Set temporary breakpoint at current line.")
1159   (gud-def gud-remove "db"         "\C-d" "Remove breakpoint at current line")
1160   (gud-def gud-step   "s %p"       "\C-s" "Step one line with display.")
1161   (gud-def gud-next   "S %p"       "\C-n" "Step one line (skip functions).")
1162   (gud-def gud-cont   "c"          "\C-r" "Continue with display.")
1163   (gud-def gud-up     "up %p"      "<"    "Up (numeric arg) stack frames.")
1164   (gud-def gud-down   "down %p"    ">"    "Down (numeric arg) stack frames.")
1165   (gud-def gud-finish "bu\\t"      "\C-f" "Finish executing current function.")
1166   (gud-def gud-print  "p %e"       "\C-p" "Evaluate C expression at point.")
1167
1168   (setq comint-prompt-regexp  "^>")
1169   (setq paragraph-start comint-prompt-regexp)
1170   (local-set-key [menu-bar debug tbreak] '("Temporary Breakpoint" . gud-tbreak))
1171   (local-set-key [menu-bar debug finish] '("Finish Function" . gud-finish))
1172   (local-set-key [menu-bar debug up] '("Up Stack" . gud-up))
1173   (local-set-key [menu-bar debug down] '("Down Stack" . gud-down))
1174   (run-hooks 'xdb-mode-hook))
1175 \f
1176 ;; ======================================================================
1177 ;; perldb functions
1178
1179 ;;; History of argument lists passed to perldb.
1180 (defvar gud-perldb-history nil)
1181
1182 ;; Convert a command line as would be typed normally to run a script
1183 ;; into one that invokes an Emacs-enabled debugging session.
1184 ;; "-d" in inserted as the first switch, and "-emacs" is inserted where
1185 ;; it will be $ARGV[0] (see perl5db.pl).
1186 (defun gud-perldb-massage-args (file args)
1187   (let* ((new-args (list "-d"))
1188          (seen-e nil)
1189          (shift (lambda ()
1190                   (setq new-args (cons (car args) new-args))
1191                   (setq args (cdr args)))))
1192
1193     ;; Pass all switches and -e scripts through.
1194     (while (and args
1195                 (string-match "^-" (car args))
1196                 (not (equal "-" (car args)))
1197                 (not (equal "--" (car args))))
1198       (when (equal "-e" (car args))
1199         ;; -e goes with the next arg, so shift one extra.
1200         (or (funcall shift)
1201             ;; -e as the last arg is an error in Perl.
1202             (error "No code specified for -e"))
1203         (setq seen-e t))
1204       (funcall shift))
1205
1206     (unless seen-e
1207       (if (or (not args)
1208               (string-match "^-" (car args)))
1209           (error "Can't use stdin as the script to debug"))
1210       ;; This is the program name.
1211       (funcall shift))
1212
1213     ;; If -e specified, make sure there is a -- so -emacs is not taken
1214     ;; as -e macs.
1215     (if (and args (equal "--" (car args)))
1216         (funcall shift)
1217       (and seen-e (push "--" new-args)))
1218
1219     (push "-emacs" new-args)
1220     (while args
1221       (funcall shift))
1222
1223     (nreverse new-args)))
1224
1225 ;; There's no guarantee that Emacs will hand the filter the entire
1226 ;; marker at once; it could be broken up across several strings.  We
1227 ;; might even receive a big chunk with several markers in it.  If we
1228 ;; receive a chunk of text which looks like it might contain the
1229 ;; beginning of a marker, we save it here between calls to the
1230 ;; filter.
1231 (defun gud-perldb-marker-filter (string)
1232   (setq gud-marker-acc (concat gud-marker-acc string))
1233   (let ((output ""))
1234
1235     ;; Process all the complete markers in this chunk.
1236     (while (string-match "\032\032\\(\\([a-zA-Z]:\\)?[^:\n]*\\):\\([0-9]*\\):.*\n"
1237                          gud-marker-acc)
1238       (setq
1239
1240        ;; Extract the frame position from the marker.
1241        gud-last-frame
1242        (cons (substring gud-marker-acc (match-beginning 1) (match-end 1))
1243              (string-to-int (substring gud-marker-acc
1244                                        (match-beginning 3)
1245                                        (match-end 3))))
1246
1247        ;; Append any text before the marker to the output we're going
1248        ;; to return - we don't include the marker in this text.
1249        output (concat output
1250                       (substring gud-marker-acc 0 (match-beginning 0)))
1251
1252        ;; Set the accumulator to the remaining text.
1253        gud-marker-acc (substring gud-marker-acc (match-end 0))))
1254
1255     ;; Does the remaining text look like it might end with the
1256     ;; beginning of another marker?  If it does, then keep it in
1257     ;; gud-marker-acc until we receive the rest of it.  Since we
1258     ;; know the full marker regexp above failed, it's pretty simple to
1259     ;; test for marker starts.
1260     (if (string-match "\032.*\\'" gud-marker-acc)
1261         (progn
1262           ;; Everything before the potential marker start can be output.
1263           (setq output (concat output (substring gud-marker-acc
1264                                                  0 (match-beginning 0))))
1265
1266           ;; Everything after, we save, to combine with later input.
1267           (setq gud-marker-acc
1268                 (substring gud-marker-acc (match-beginning 0))))
1269
1270       (setq output (concat output gud-marker-acc)
1271             gud-marker-acc ""))
1272
1273     output))
1274
1275 (defun gud-perldb-find-file (f)
1276   (find-file-noselect f))
1277
1278 (defcustom gud-perldb-command-name "perl"
1279   "File name for executing Perl."
1280   :type 'string
1281   :group 'gud)
1282
1283 ;;;###autoload
1284 (defun perldb (command-line)
1285   "Run perldb on program FILE in buffer *gud-FILE*.
1286 The directory containing FILE becomes the initial working directory
1287 and source-file directory for your debugger."
1288   (interactive
1289    (list (gud-query-cmdline 'perldb
1290                             (concat (or (buffer-file-name) "-e 0") " "))))
1291
1292   (gud-common-init command-line 'gud-perldb-massage-args
1293                    'gud-perldb-marker-filter 'gud-perldb-find-file)
1294   (set (make-local-variable 'gud-minor-mode) 'perldb)
1295
1296   (gud-def gud-break  "b %l"         "\C-b" "Set breakpoint at current line.")
1297   (gud-def gud-remove "d %l"         "\C-d" "Remove breakpoint at current line")
1298   (gud-def gud-step   "s"            "\C-s" "Step one source line with display.")
1299   (gud-def gud-next   "n"            "\C-n" "Step one line (skip functions).")
1300   (gud-def gud-cont   "c"            "\C-r" "Continue with display.")
1301 ;  (gud-def gud-finish "finish"       "\C-f" "Finish executing current function.")
1302 ;  (gud-def gud-up     "up %p"        "<" "Up N stack frames (numeric arg).")
1303 ;  (gud-def gud-down   "down %p"      ">" "Down N stack frames (numeric arg).")
1304   (gud-def gud-print  "%e"           "\C-p" "Evaluate perl expression at point.")
1305
1306   (setq comint-prompt-regexp "^  DB<+[0-9]+>+ ")
1307   (setq paragraph-start comint-prompt-regexp)
1308   (run-hooks 'perldb-mode-hook))
1309 \f
1310 ;; ======================================================================
1311 ;; pdb (Python debugger) functions
1312
1313 ;;; History of argument lists passed to pdb.
1314 (defvar gud-pdb-history nil)
1315
1316 (defun gud-pdb-massage-args (file args)
1317   args)
1318
1319 ;; Last group is for return value, e.g. "> test.py(2)foo()->None"
1320 ;; Either file or function name may be omitted: "> <string>(0)?()"
1321 (defvar gud-pdb-marker-regexp
1322   "^> \\([-a-zA-Z0-9_/.]*\\|<string>\\)(\\([0-9]+\\))\\([a-zA-Z0-9_]*\\|\\?\\)()\\(->[^\n]*\\)?\n")
1323 (defvar gud-pdb-marker-regexp-file-group 1)
1324 (defvar gud-pdb-marker-regexp-line-group 2)
1325 (defvar gud-pdb-marker-regexp-fnname-group 3)
1326
1327 (defvar gud-pdb-marker-regexp-start "^> ")
1328
1329 ;; There's no guarantee that Emacs will hand the filter the entire
1330 ;; marker at once; it could be broken up across several strings.  We
1331 ;; might even receive a big chunk with several markers in it.  If we
1332 ;; receive a chunk of text which looks like it might contain the
1333 ;; beginning of a marker, we save it here between calls to the
1334 ;; filter.
1335 (defun gud-pdb-marker-filter (string)
1336   (setq gud-marker-acc (concat gud-marker-acc string))
1337   (let ((output ""))
1338
1339     ;; Process all the complete markers in this chunk.
1340     (while (string-match gud-pdb-marker-regexp gud-marker-acc)
1341       (setq
1342
1343        ;; Extract the frame position from the marker.
1344        gud-last-frame
1345        (let ((file (match-string gud-pdb-marker-regexp-file-group
1346                                  gud-marker-acc))
1347              (line (string-to-int
1348                     (match-string gud-pdb-marker-regexp-line-group
1349                                   gud-marker-acc))))
1350          (if (string-equal file "<string>")
1351              gud-last-frame
1352            (cons file line)))
1353
1354        ;; Output everything instead of the below
1355        output (concat output (substring gud-marker-acc 0 (match-end 0)))
1356 ;;        ;; Append any text before the marker to the output we're going
1357 ;;        ;; to return - we don't include the marker in this text.
1358 ;;        output (concat output
1359 ;;                    (substring gud-marker-acc 0 (match-beginning 0)))
1360
1361        ;; Set the accumulator to the remaining text.
1362        gud-marker-acc (substring gud-marker-acc (match-end 0))))
1363
1364     ;; Does the remaining text look like it might end with the
1365     ;; beginning of another marker?  If it does, then keep it in
1366     ;; gud-marker-acc until we receive the rest of it.  Since we
1367     ;; know the full marker regexp above failed, it's pretty simple to
1368     ;; test for marker starts.
1369     (if (string-match gud-pdb-marker-regexp-start gud-marker-acc)
1370         (progn
1371           ;; Everything before the potential marker start can be output.
1372           (setq output (concat output (substring gud-marker-acc
1373                                                  0 (match-beginning 0))))
1374
1375           ;; Everything after, we save, to combine with later input.
1376           (setq gud-marker-acc
1377                 (substring gud-marker-acc (match-beginning 0))))
1378
1379       (setq output (concat output gud-marker-acc)
1380             gud-marker-acc ""))
1381
1382     output))
1383
1384 (defun gud-pdb-find-file (f)
1385   (find-file-noselect f))
1386
1387 (defcustom gud-pdb-command-name "pdb"
1388   "File name for executing the Python debugger.
1389 This should be an executable on your path, or an absolute file name."
1390   :type 'string
1391   :group 'gud)
1392
1393 ;;;###autoload
1394 (defun pdb (command-line)
1395   "Run pdb on program FILE in buffer `*gud-FILE*'.
1396 The directory containing FILE becomes the initial working directory
1397 and source-file directory for your debugger."
1398   (interactive
1399    (list (gud-query-cmdline 'pdb)))
1400
1401   (gud-common-init command-line 'gud-pdb-massage-args
1402                    'gud-pdb-marker-filter 'gud-pdb-find-file)
1403   (set (make-local-variable 'gud-minor-mode) 'pdb)
1404
1405   (gud-def gud-break  "break %l"     "\C-b" "Set breakpoint at current line.")
1406   (gud-def gud-remove "clear %l"     "\C-d" "Remove breakpoint at current line")
1407   (gud-def gud-step   "step"         "\C-s" "Step one source line with display.")
1408   (gud-def gud-next   "next"         "\C-n" "Step one line (skip functions).")
1409   (gud-def gud-cont   "continue"     "\C-r" "Continue with display.")
1410   (gud-def gud-finish "return"       "\C-f" "Finish executing current function.")
1411   (gud-def gud-up     "up"           "<" "Up one stack frame.")
1412   (gud-def gud-down   "down"         ">" "Down one stack frame.")
1413   (gud-def gud-print  "p %e"         "\C-p" "Evaluate Python expression at point.")
1414   ;; Is this right?
1415   (gud-def gud-statement "! %e"      "\C-e" "Execute Python statement at point.")
1416
1417   (local-set-key [menu-bar debug finish] '("Finish Function" . gud-finish))
1418   (local-set-key [menu-bar debug up] '("Up Stack" . gud-up))
1419   (local-set-key [menu-bar debug down] '("Down Stack" . gud-down))
1420   ;; (setq comint-prompt-regexp "^(.*pdb[+]?) *")
1421   (setq comint-prompt-regexp "^(Pdb) *")
1422   (setq paragraph-start comint-prompt-regexp)
1423   (run-hooks 'pdb-mode-hook))
1424 \f
1425 ;; ======================================================================
1426 ;;
1427 ;; JDB support.
1428 ;;
1429 ;; AUTHOR:      Derek Davies <ddavies@world.std.com>
1430 ;;              Zoltan Kemenczy <zoltan@ieee.org;zkemenczy@rim.net>
1431 ;;
1432 ;; CREATED:     Sun Feb 22 10:46:38 1998 Derek Davies.
1433 ;; UPDATED:     Nov 11, 2001 Zoltan Kemenczy
1434 ;;
1435 ;; INVOCATION NOTES:
1436 ;;
1437 ;; You invoke jdb-mode with:
1438 ;;
1439 ;;    M-x jdb <enter>
1440 ;;
1441 ;; It responds with:
1442 ;;
1443 ;;    Run jdb (like this): jdb
1444 ;;
1445 ;; type any jdb switches followed by the name of the class you'd like to debug.
1446 ;; Supply a fully qualfied classname (these do not have the ".class" extension)
1447 ;; for the name of the class to debug (e.g. "COM.the-kind.ddavies.CoolClass").
1448 ;; See the known problems section below for restrictions when specifying jdb
1449 ;; command line switches (search forward for '-classpath').
1450 ;;
1451 ;; You should see something like the following:
1452 ;;
1453 ;;    Current directory is ~/src/java/hello/
1454 ;;    Initializing jdb...
1455 ;;    0xed2f6628:class(hello)
1456 ;;    >
1457 ;;
1458 ;; To set an initial breakpoint try:
1459 ;;
1460 ;;    > stop in hello.main
1461 ;;    Breakpoint set in hello.main
1462 ;;    >
1463 ;;
1464 ;; To execute the program type:
1465 ;;
1466 ;;    > run
1467 ;;    run hello
1468 ;;
1469 ;;    Breakpoint hit: running ...
1470 ;;    hello.main (hello:12)
1471 ;;
1472 ;; Type M-n to step over the current line and M-s to step into it.  That,
1473 ;; along with the JDB 'help' command should get you started.  The 'quit'
1474 ;; JDB command will get out out of the debugger.  There is some truly
1475 ;; pathetic JDB documentation available at:
1476 ;;
1477 ;;     http://java.sun.com/products/jdk/1.1/debugging/
1478 ;;
1479 ;; KNOWN PROBLEMS AND FIXME's:
1480 ;;
1481 ;; Not sure what happens with inner classes ... haven't tried them.
1482 ;;
1483 ;; Does not grok UNICODE id's.  Only ASCII id's are supported.
1484 ;;
1485 ;; You must not put whitespace between "-classpath" and the path to
1486 ;; search for java classes even though it is required when invoking jdb
1487 ;; from the command line.  See gud-jdb-massage-args for details.
1488 ;;
1489 ;; Note: The following applies only if `gud-jdb-use-classpath' is nil;
1490 ;; refer to the documentation of `gud-jdb-use-classpath' and
1491 ;; `gud-jdb-classpath' variables for information on using the classpath
1492 ;; for locating java source files.
1493 ;;
1494 ;; If any of the source files in the directories listed in
1495 ;; gud-jdb-directories won't parse you'll have problems.  Make sure
1496 ;; every file ending in ".java" in these directories parses without error.
1497 ;;
1498 ;; All the .java files in the directories in gud-jdb-directories are
1499 ;; syntactically analyzed each time gud jdb is invoked.  It would be
1500 ;; nice to keep as much information as possible between runs.  It would
1501 ;; be really nice to analyze the files only as neccessary (when the
1502 ;; source needs to be displayed.)  I'm not sure to what extent the former
1503 ;; can be accomplished and I'm not sure the latter can be done at all
1504 ;; since I don't know of any general way to tell which .class files are
1505 ;; defined by which .java file without analyzing all the .java files.
1506 ;; If anyone knows why JavaSoft didn't put the source file names in
1507 ;; debuggable .class files please clue me in so I find something else
1508 ;; to be spiteful and bitter about.
1509 ;;
1510 ;; ======================================================================
1511 ;; gud jdb variables and functions
1512
1513 (defcustom gud-jdb-command-name "jdb"
1514   "Command that executes the Java debugger."
1515   :type 'string
1516   :group 'gud)
1517
1518 (defcustom gud-jdb-use-classpath t
1519   "If non-nil, search for Java source files in classpath directories.
1520 The list of directories to search is the value of `gud-jdb-classpath'.
1521 The file pathname is obtained by converting the fully qualified
1522 class information output by jdb to a relative pathname and appending
1523 it to `gud-jdb-classpath' element by element until a match is found.
1524
1525 This method has a significant jdb startup time reduction advantage
1526 since it does not require the scanning of all `gud-jdb-directories'
1527 and parsing all Java files for class information.
1528
1529 Set to nil to use `gud-jdb-directories' to scan java sources for
1530 class information on jdb startup (original method)."
1531   :type 'boolean
1532   :group 'gud)
1533
1534 (defvar gud-jdb-classpath nil
1535  "Java/jdb classpath directories list.
1536 If `gud-jdb-use-classpath' is non-nil, gud-jdb derives the `gud-jdb-classpath'
1537 list automatically using the following methods in sequence
1538 (with subsequent successful steps overriding the results of previous
1539 steps):
1540
1541 1) Read the CLASSPATH environment variable,
1542 2) Read any \"-classpath\" argument used to run jdb,
1543    or detected in jdb output (e.g. if jdb is run by a script
1544    that echoes the actual jdb command before starting jdb)
1545 3) Send a \"classpath\" command to jdb and scan jdb output for
1546    classpath information if jdb is invoked with an \"-attach\" (to
1547    an already running VM) argument (This case typically does not
1548    have a \"-classpath\" command line argument - that is provided
1549    to the VM when it is started).
1550
1551 Note that method 3 cannot be used with oldjdb (or Java 1 jdb) since
1552 those debuggers do not support the classpath command. Use 1) or 2).")
1553
1554 (defvar gud-marker-acc-max-length 4000
1555   "Maximum number of debugger output characters to keep.
1556 This variable limits the size of `gud-marker-acc' which holds
1557 the most recent debugger output history while searching for
1558 source file information.")
1559
1560 (defvar gud-jdb-history nil
1561 "History of argument lists passed to jdb.")
1562
1563
1564 ;; List of Java source file directories.
1565 (defvar gud-jdb-directories (list ".")
1566   "*A list of directories that gud jdb should search for source code.
1567 The file names should be absolute, or relative to the current
1568 directory.
1569
1570 The set of .java files residing in the directories listed are
1571 syntactically analyzed to determine the classes they define and the
1572 packages in which these classes belong.  In this way gud jdb maps the
1573 package-qualified class names output by the jdb debugger to the source
1574 file from which the class originated.  This allows gud mode to keep
1575 the source code display in sync with the debugging session.")
1576
1577 (defvar gud-jdb-source-files nil
1578 "List of the java source files for this debugging session.")
1579
1580 ;; Association list of fully qualified class names (package + class name)
1581 ;; and their source files.
1582 (defvar gud-jdb-class-source-alist nil
1583 "Association list of fully qualified class names and source files.")
1584
1585 ;; This is used to hold a source file during analysis.
1586 (defvar gud-jdb-analysis-buffer nil)
1587
1588 (defvar gud-jdb-classpath-string nil
1589 "Holds temporary classpath values.")
1590
1591 (defun gud-jdb-build-source-files-list (path extn)
1592 "Return a list of java source files.
1593 PATH gives the directories in which to search for files with
1594 extension EXTN.  Normally EXTN is given as the regular expression
1595  \"\\.java$\" ."
1596   (apply 'nconc (mapcar (lambda (d)
1597                           (when (file-directory-p d)
1598                             (directory-files d t extn nil)))
1599                         path)))
1600
1601 ;; Move point past whitespace.
1602 (defun gud-jdb-skip-whitespace ()
1603   (skip-chars-forward " \n\r\t\014"))
1604
1605 ;; Move point past a "// <eol>" type of comment.
1606 (defun gud-jdb-skip-single-line-comment ()
1607   (end-of-line))
1608
1609 ;; Move point past a "/* */" or "/** */" type of comment.
1610 (defun gud-jdb-skip-traditional-or-documentation-comment ()
1611   (forward-char 2)
1612   (catch 'break
1613     (while (not (eobp))
1614       (if (eq (following-char) ?*)
1615           (progn
1616             (forward-char)
1617             (if (not (eobp))
1618                 (if (eq (following-char) ?/)
1619                     (progn
1620                       (forward-char)
1621                       (throw 'break nil)))))
1622         (forward-char)))))
1623
1624 ;; Move point past any number of consecutive whitespace chars and/or comments.
1625 (defun gud-jdb-skip-whitespace-and-comments ()
1626   (gud-jdb-skip-whitespace)
1627   (catch 'done
1628     (while t
1629       (cond
1630        ((looking-at "//")
1631         (gud-jdb-skip-single-line-comment)
1632         (gud-jdb-skip-whitespace))
1633        ((looking-at "/\\*")
1634         (gud-jdb-skip-traditional-or-documentation-comment)
1635         (gud-jdb-skip-whitespace))
1636        (t (throw 'done nil))))))
1637
1638 ;; Move point past things that are id-like.  The intent is to skip regular
1639 ;; id's, such as class or interface names as well as package and interface
1640 ;; names.
1641 (defun gud-jdb-skip-id-ish-thing ()
1642   (skip-chars-forward "^ /\n\r\t\014,;{"))
1643
1644 ;; Move point past a string literal.
1645 (defun gud-jdb-skip-string-literal ()
1646   (forward-char)
1647   (while (not (cond
1648                ((eq (following-char) ?\\)
1649                 (forward-char))
1650                ((eq (following-char) ?\042))))
1651     (forward-char))
1652   (forward-char))
1653
1654 ;; Move point past a character literal.
1655 (defun gud-jdb-skip-character-literal ()
1656   (forward-char)
1657   (while
1658       (progn
1659         (if (eq (following-char) ?\\)
1660             (forward-char 2))
1661         (not (eq (following-char) ?\')))
1662     (forward-char))
1663   (forward-char))
1664
1665 ;; Move point past the following block.  There may be (legal) cruft before
1666 ;; the block's opening brace.  There must be a block or it's the end of life
1667 ;; in petticoat junction.
1668 (defun gud-jdb-skip-block ()
1669
1670   ;; Find the begining of the block.
1671   (while
1672       (not (eq (following-char) ?{))
1673
1674     ;; Skip any constructs that can harbor literal block delimiter
1675     ;; characters and/or the delimiters for the constructs themselves.
1676     (cond
1677      ((looking-at "//")
1678       (gud-jdb-skip-single-line-comment))
1679      ((looking-at "/\\*")
1680       (gud-jdb-skip-traditional-or-documentation-comment))
1681      ((eq (following-char) ?\042)
1682       (gud-jdb-skip-string-literal))
1683      ((eq (following-char) ?\')
1684       (gud-jdb-skip-character-literal))
1685      (t (forward-char))))
1686
1687   ;; Now at the begining of the block.
1688   (forward-char)
1689
1690   ;; Skip over the body of the block as well as the final brace.
1691   (let ((open-level 1))
1692     (while (not (eq open-level 0))
1693       (cond
1694        ((looking-at "//")
1695         (gud-jdb-skip-single-line-comment))
1696        ((looking-at "/\\*")
1697         (gud-jdb-skip-traditional-or-documentation-comment))
1698        ((eq (following-char) ?\042)
1699         (gud-jdb-skip-string-literal))
1700        ((eq (following-char) ?\')
1701         (gud-jdb-skip-character-literal))
1702        ((eq (following-char) ?{)
1703         (setq open-level (+ open-level 1))
1704         (forward-char))
1705        ((eq (following-char) ?})
1706         (setq open-level (- open-level 1))
1707         (forward-char))
1708        (t (forward-char))))))
1709
1710 ;; Find the package and class definitions in Java source file FILE.  Assumes
1711 ;; that FILE contains a legal Java program.  BUF is a scratch buffer used
1712 ;; to hold the source during analysis.
1713 (defun gud-jdb-analyze-source (buf file)
1714   (let ((l nil))
1715     (set-buffer buf)
1716     (insert-file-contents file nil nil nil t)
1717     (goto-char 0)
1718     (catch 'abort
1719       (let ((p ""))
1720         (while (progn
1721                  (gud-jdb-skip-whitespace)
1722                  (not (eobp)))
1723           (cond
1724
1725            ;; Any number of semi's following a block is legal.  Move point
1726            ;; past them.  Note that comments and whitespace may be
1727            ;; interspersed as well.
1728            ((eq (following-char) ?\073)
1729             (forward-char))
1730
1731            ;; Move point past a single line comment.
1732            ((looking-at "//")
1733             (gud-jdb-skip-single-line-comment))
1734
1735            ;; Move point past a traditional or documentation comment.
1736            ((looking-at "/\\*")
1737             (gud-jdb-skip-traditional-or-documentation-comment))
1738
1739            ;; Move point past a package statement, but save the PackageName.
1740            ((looking-at "package")
1741             (forward-char 7)
1742             (gud-jdb-skip-whitespace-and-comments)
1743             (let ((s (point)))
1744               (gud-jdb-skip-id-ish-thing)
1745               (setq p (concat (buffer-substring s (point)) "."))
1746               (gud-jdb-skip-whitespace-and-comments)
1747               (if (eq (following-char) ?\073)
1748                   (forward-char))))
1749
1750            ;; Move point past an import statement.
1751            ((looking-at "import")
1752             (forward-char 6)
1753             (gud-jdb-skip-whitespace-and-comments)
1754             (gud-jdb-skip-id-ish-thing)
1755             (gud-jdb-skip-whitespace-and-comments)
1756             (if (eq (following-char) ?\073)
1757                 (forward-char)))
1758
1759            ;; Move point past the various kinds of ClassModifiers.
1760            ((looking-at "public")
1761             (forward-char 6))
1762            ((looking-at "abstract")
1763             (forward-char 8))
1764            ((looking-at "final")
1765             (forward-char 5))
1766
1767            ;; Move point past a ClassDeclaraction, but save the class
1768            ;; Identifier.
1769            ((looking-at "class")
1770             (forward-char 5)
1771             (gud-jdb-skip-whitespace-and-comments)
1772             (let ((s (point)))
1773               (gud-jdb-skip-id-ish-thing)
1774               (setq
1775                l (nconc l (list (concat p (buffer-substring s (point)))))))
1776             (gud-jdb-skip-block))
1777
1778            ;; Move point past an interface statement.
1779            ((looking-at "interface")
1780             (forward-char 9)
1781             (gud-jdb-skip-block))
1782
1783            ;; Anything else means the input is invalid.
1784            (t
1785             (message (format "Error parsing file %s." file))
1786             (throw 'abort nil))))))
1787     l))
1788
1789 (defun gud-jdb-build-class-source-alist-for-file (file)
1790   (mapcar
1791    (lambda (c)
1792      (cons c file))
1793    (gud-jdb-analyze-source gud-jdb-analysis-buffer file)))
1794
1795 ;; Return an alist of fully qualified classes and the source files
1796 ;; holding their definitions.  SOURCES holds a list of all the source
1797 ;; files to examine.
1798 (defun gud-jdb-build-class-source-alist (sources)
1799   (setq gud-jdb-analysis-buffer (get-buffer-create " *gud-jdb-scratch*"))
1800   (prog1
1801       (apply
1802        'nconc
1803        (mapcar
1804         'gud-jdb-build-class-source-alist-for-file
1805         sources))
1806     (kill-buffer gud-jdb-analysis-buffer)
1807     (setq gud-jdb-analysis-buffer nil)))
1808
1809 ;; Change what was given in the minibuffer to something that can be used to
1810 ;; invoke the debugger.
1811 (defun gud-jdb-massage-args (file args)
1812   ;; The jdb executable must have whitespace between "-classpath" and
1813   ;; its value while gud-common-init expects all switch values to
1814   ;; follow the switch keyword without intervening whitespace.  We
1815   ;; require that when the user enters the "-classpath" switch in the
1816   ;; EMACS minibuffer that they do so without the intervening
1817   ;; whitespace.  This function adds it back (it's called after
1818   ;; gud-common-init).  There are more switches like this (for
1819   ;; instance "-host" and "-password") but I don't care about them
1820   ;; yet.
1821   (if args
1822       (let (massaged-args user-error)
1823
1824         (while
1825             (and args
1826                  (not (string-match "-classpath\\(.+\\)" (car args)))
1827                  (not (setq user-error
1828                             (string-match "-classpath$" (car args)))))
1829           (setq massaged-args (append massaged-args (list (car args))))
1830           (setq args (cdr args)))
1831
1832         ;; By this point the current directory is all screwed up.  Maybe we
1833         ;; could fix things and re-invoke gud-common-init, but for now I think
1834         ;; issueing the error is good enough.
1835         (if user-error
1836             (progn
1837               (kill-buffer (current-buffer))
1838               (error "Error: Omit whitespace between '-classpath' and its value")))
1839
1840         (if args
1841             (setq massaged-args
1842                   (append
1843                    massaged-args
1844                    (list "-classpath")
1845                    (list
1846                     (setq gud-jdb-classpath-string
1847                           (substring
1848                            (car args)
1849                            (match-beginning 1) (match-end 1))))
1850                    (cdr args)))
1851           massaged-args))))
1852
1853 ;; Search for an association with P, a fully qualified class name, in
1854 ;; gud-jdb-class-source-alist.  The asssociation gives the fully
1855 ;; qualified file name of the source file which produced the class.
1856 (defun gud-jdb-find-source-file (p)
1857   (cdr (assoc p gud-jdb-class-source-alist)))
1858
1859 ;; Note: Reset to this value every time a prompt is seen
1860 (defvar gud-jdb-lowest-stack-level 999)
1861
1862 (defun gud-jdb-find-source-using-classpath (p)
1863 "Find source file corresponding to fully qualified class p.
1864 Convert p from jdb's output, converted to a pathname
1865 relative to a classpath directory."
1866   (save-match-data
1867     (let
1868       (;; Replace dots with slashes and append ".java" to generate file
1869        ;; name relative to classpath
1870        (filename
1871         (concat
1872          (mapconcat (lambda (x) x)
1873                     (split-string
1874                      ;; Eliminate any subclass references in the class
1875                      ;; name string. These start with a "$"
1876                      ((lambda (x)
1877                         (if (string-match "$.*" x)
1878                             (replace-match "" t t x) p))
1879                       p)
1880                      "\\.") "/")
1881          ".java"))
1882        (cplist gud-jdb-classpath)
1883        found-file)
1884     (while (and cplist
1885                 (not (setq found-file
1886                            (file-readable-p
1887                             (concat (car cplist) "/" filename)))))
1888       (setq cplist (cdr cplist)))
1889     (if found-file (concat (car cplist) "/" filename)))))
1890
1891 (defun gud-jdb-find-source (string)
1892 "Alias for function used to locate source files.
1893 Set to `gud-jdb-find-source-using-classpath' or `gud-jdb-find-source-file'
1894 during jdb initialization depending on the value of
1895 `gud-jdb-use-classpath'."
1896 nil)
1897
1898 (defun gud-jdb-parse-classpath-string (string)
1899 "Parse the classpath list and convert each item to an absolute pathname."
1900   (mapcar 'file-truename (split-string string
1901         (concat "[ \t\n\r,\"" path-separator "]+"))))
1902
1903 ;; See comentary for other debugger's marker filters - there you will find
1904 ;; important notes about STRING.
1905 (defun gud-jdb-marker-filter (string)
1906
1907   ;; Build up the accumulator.
1908   (setq gud-marker-acc
1909         (if gud-marker-acc
1910             (concat gud-marker-acc string)
1911           string))
1912
1913   ;; Look for classpath information until gud-jdb-classpath-string is found
1914   (if (and gud-jdb-use-classpath
1915            (not gud-jdb-classpath-string)
1916            (or (string-match "classpath:[ \t[]+\\([^]]+\\)" gud-marker-acc)
1917                (string-match "-classpath[ \t\"]+\\([^ \"]+\\)" gud-marker-acc)))
1918       (setq gud-jdb-classpath
1919             (gud-jdb-parse-classpath-string
1920                     (setq gud-jdb-classpath-string
1921                           (substring gud-marker-acc
1922                                (match-beginning 1) (match-end 1))))))
1923
1924   ;; We process STRING from left to right.  Each time through the
1925   ;; following loop we process at most one marker. After we've found a
1926   ;; marker, delete gud-marker-acc up to and including the match
1927   (let (file-found)
1928     ;; Process each complete marker in the input.
1929     (while
1930
1931         ;; Do we see a marker?
1932         (string-match
1933          ;; jdb puts out a string of the following form when it
1934          ;; hits a breakpoint:
1935          ;;
1936          ;;     <fully-qualified-class><method> (<class>:<line-number>)
1937          ;;
1938          ;; <fully-qualified-class>'s are composed of Java ID's
1939          ;; separated by periods.  <method> and <class> are
1940          ;; also Java ID's.  <method> begins with a period and
1941          ;; may contain less-than and greater-than (constructors,
1942          ;; for instance, are called <init> in the symbol table.)
1943          ;; Java ID's begin with a letter followed by letters
1944          ;; and/or digits.  The set of letters includes underscore
1945          ;; and dollar sign.
1946          ;;
1947          ;; The first group matches <fully-qualified-class>,
1948          ;; the second group matches <class> and the third group
1949          ;; matches <line-number>.  We don't care about using
1950          ;; <method> so we don't "group" it.
1951          ;;
1952          ;; FIXME: Java ID's are UNICODE strings, this matches ASCII
1953          ;; ID's only.
1954          "\\(\[[0-9]+\] \\)*\\([a-zA-Z0-9.$_]+\\)\\.[a-zA-Z0-9$_<>(),]+ \
1955 \\(([a-zA-Z0-9.$_]+:\\|line=\\)\\([0-9]+\\)"
1956          gud-marker-acc)
1957
1958       ;; A good marker is one that:
1959       ;; 1) does not have a "[n] " prefix (not part of a stack backtrace)
1960       ;; 2) does have an "[n] " prefix and n is the lowest prefix seen
1961       ;;    since the last prompt
1962       ;; Figure out the line on which to position the debugging arrow.
1963       ;; Return the info as a cons of the form:
1964       ;;
1965       ;;     (<file-name> . <line-number>) .
1966       (if (if (match-beginning 1)
1967               (let (n)
1968                 (setq n (string-to-int (substring
1969                                         gud-marker-acc
1970                                         (1+ (match-beginning 1))
1971                                         (- (match-end 1) 2))))
1972                 (if (< n gud-jdb-lowest-stack-level)
1973                     (progn (setq gud-jdb-lowest-stack-level n) t)))
1974             t)
1975           (if (setq file-found
1976                     (gud-jdb-find-source
1977                      (substring gud-marker-acc
1978                                 (match-beginning 2)
1979                                 (match-end 2))))
1980               (setq gud-last-frame
1981                     (cons file-found
1982                           (string-to-int
1983                            (substring gud-marker-acc
1984                                       (match-beginning 4)
1985                                       (match-end 4)))))
1986             (message "Could not find source file.")))
1987
1988       ;; Set the accumulator to the remaining text.
1989       (setq gud-marker-acc (substring gud-marker-acc (match-end 0))))
1990
1991     (if (string-match comint-prompt-regexp gud-marker-acc)
1992         (setq gud-jdb-lowest-stack-level 999)))
1993
1994   ;; Do not allow gud-marker-acc to grow without bound. If the source
1995   ;; file information is not within the last 3/4
1996   ;; gud-marker-acc-max-length characters, well,...
1997   (if (> (length gud-marker-acc) gud-marker-acc-max-length)
1998       (setq gud-marker-acc
1999             (substring gud-marker-acc
2000                        (- (/ (* gud-marker-acc-max-length 3) 4)))))
2001
2002   ;; We don't filter any debugger output so just return what we were given.
2003   string)
2004
2005 (defun gud-jdb-find-file (f)
2006   (and (file-readable-p f)
2007        (find-file-noselect f)))
2008
2009 ;;;###autoload
2010 (defun jdb (command-line)
2011   "Run jdb with command line COMMAND-LINE in a buffer.
2012 The buffer is named \"*gud*\" if no initial class is given or
2013 \"*gud-<initial-class-basename>*\" if there is.  If the \"-classpath\"
2014 switch is given, omit all whitespace between it and its value.
2015
2016 See `gud-jdb-use-classpath' and `gud-jdb-classpath' documentation for
2017 information on how jdb accesses source files. Alternatively (if
2018 `gud-jdb-use-classpath' is nil), see `gud-jdb-directories' for the
2019 original source file access method.
2020
2021 For general information about commands available to control jdb from
2022 gud, see `gud-mode'."
2023   (interactive
2024    (list (gud-query-cmdline 'jdb)))
2025
2026   ;; Set gud-jdb-classpath from the CLASSPATH environment variable,
2027   ;; if CLASSPATH is set.
2028   (setq gud-jdb-classpath-string (getenv "CLASSPATH"))
2029   (if gud-jdb-classpath-string
2030       (setq gud-jdb-classpath
2031             (gud-jdb-parse-classpath-string gud-jdb-classpath-string)))
2032   (setq gud-jdb-classpath-string nil)   ; prepare for next
2033
2034   (gud-common-init command-line 'gud-jdb-massage-args
2035                    'gud-jdb-marker-filter 'gud-jdb-find-file)
2036   (set (make-local-variable 'gud-minor-mode) 'jdb)
2037
2038   ;; If a -classpath option was provided, set gud-jdb-classpath
2039   (if gud-jdb-classpath-string
2040       (setq gud-jdb-classpath
2041             (gud-jdb-parse-classpath-string gud-jdb-classpath-string)))
2042   (setq gud-jdb-classpath-string nil)   ; prepare for next
2043
2044   (gud-def gud-break  "stop at %c:%l" "\C-b" "Set breakpoint at current line.")
2045   (gud-def gud-remove "clear %c:%l"   "\C-d" "Remove breakpoint at current line")
2046   (gud-def gud-step   "step"          "\C-s" "Step one source line with display.")
2047   (gud-def gud-next   "next"          "\C-n" "Step one line (skip functions).")
2048   (gud-def gud-cont   "cont"          "\C-r" "Continue with display.")
2049   (gud-def gud-finish "step up"       "\C-f" "Continue until current method returns.")
2050   (gud-def gud-up     "up\C-Mwhere"   "<"    "Up one stack frame.")
2051   (gud-def gud-down   "down\C-Mwhere" ">"    "Up one stack frame.")
2052   (local-set-key [menu-bar debug finish] '("Finish Function" . gud-finish))
2053   (local-set-key [menu-bar debug up] '("Up Stack" . gud-up))
2054   (local-set-key [menu-bar debug down] '("Down Stack" . gud-down))
2055
2056   (setq comint-prompt-regexp "^> \\|^[^ ]+\\[[0-9]+\\] ")
2057   (setq paragraph-start comint-prompt-regexp)
2058   (run-hooks 'jdb-mode-hook)
2059
2060   (if gud-jdb-use-classpath
2061       ;; Get the classpath information from the debugger (this is much
2062       ;; faster) and does not need the constant updating of
2063       ;; gud-jdb-directories
2064       (progn
2065         (if (string-match "-attach" command-line)
2066             (gud-call "classpath"))
2067         (fset 'gud-jdb-find-source
2068               'gud-jdb-find-source-using-classpath))
2069
2070     ;; Else create and bind the class/source association list as well
2071     ;; as the source file list.
2072     (setq gud-jdb-class-source-alist
2073           (gud-jdb-build-class-source-alist
2074            (setq gud-jdb-source-files
2075                  (gud-jdb-build-source-files-list gud-jdb-directories
2076                                                   "\\.java$"))))
2077     (fset 'gud-jdb-find-source 'gud-jdb-find-source-file)))
2078 \f
2079
2080 ;;
2081 ;; End of debugger-specific information
2082 ;;
2083
2084 \f
2085 ;;; When we send a command to the debugger via gud-call, it's annoying
2086 ;;; to see the command and the new prompt inserted into the debugger's
2087 ;;; buffer; we have other ways of knowing the command has completed.
2088 ;;;
2089 ;;; If the buffer looks like this:
2090 ;;; --------------------
2091 ;;; (gdb) set args foo bar
2092 ;;; (gdb) -!-
2093 ;;; --------------------
2094 ;;; (the -!- marks the location of point), and we type `C-x SPC' in a
2095 ;;; source file to set a breakpoint, we want the buffer to end up like
2096 ;;; this:
2097 ;;; --------------------
2098 ;;; (gdb) set args foo bar
2099 ;;; Breakpoint 1 at 0x92: file make-docfile.c, line 49.
2100 ;;; (gdb) -!-
2101 ;;; --------------------
2102 ;;; Essentially, the old prompt is deleted, and the command's output
2103 ;;; and the new prompt take its place.
2104 ;;;
2105 ;;; Not echoing the command is easy enough; you send it directly using
2106 ;;; process-send-string, and it never enters the buffer.  However,
2107 ;;; getting rid of the old prompt is trickier; you don't want to do it
2108 ;;; when you send the command, since that will result in an annoying
2109 ;;; flicker as the prompt is deleted, redisplay occurs while Emacs
2110 ;;; waits for a response from the debugger, and the new prompt is
2111 ;;; inserted.  Instead, we'll wait until we actually get some output
2112 ;;; from the subprocess before we delete the prompt.  If the command
2113 ;;; produced no output other than a new prompt, that prompt will most
2114 ;;; likely be in the first chunk of output received, so we will delete
2115 ;;; the prompt and then replace it with an identical one.  If the
2116 ;;; command produces output, the prompt is moving anyway, so the
2117 ;;; flicker won't be annoying.
2118 ;;;
2119 ;;; So - when we want to delete the prompt upon receipt of the next
2120 ;;; chunk of debugger output, we position gud-delete-prompt-marker at
2121 ;;; the start of the prompt; the process filter will notice this, and
2122 ;;; delete all text between it and the process output marker.  If
2123 ;;; gud-delete-prompt-marker points nowhere, we leave the current
2124 ;;; prompt alone.
2125 (defvar gud-delete-prompt-marker nil)
2126
2127 \f
2128 (put 'gud-mode 'mode-class 'special)
2129
2130 (define-derived-mode gud-mode comint-mode "Debugger"
2131   "Major mode for interacting with an inferior debugger process.
2132
2133    You start it up with one of the commands M-x gdb, M-x sdb, M-x dbx,
2134 M-x perldb, M-x xdb, or M-x jdb.  Each entry point finishes by executing a
2135 hook; `gdb-mode-hook', `sdb-mode-hook', `dbx-mode-hook',
2136 `perldb-mode-hook', `xdb-mode-hook', or `jdb-mode-hook' respectively.
2137
2138 After startup, the following commands are available in both the GUD
2139 interaction buffer and any source buffer GUD visits due to a breakpoint stop
2140 or step operation:
2141
2142 \\[gud-break] sets a breakpoint at the current file and line.  In the
2143 GUD buffer, the current file and line are those of the last breakpoint or
2144 step.  In a source buffer, they are the buffer's file and current line.
2145
2146 \\[gud-remove] removes breakpoints on the current file and line.
2147
2148 \\[gud-refresh] displays in the source window the last line referred to
2149 in the gud buffer.
2150
2151 \\[gud-step], \\[gud-next], and \\[gud-stepi] do a step-one-line,
2152 step-one-line (not entering function calls), and step-one-instruction
2153 and then update the source window with the current file and position.
2154 \\[gud-cont] continues execution.
2155
2156 \\[gud-print] tries to find the largest C lvalue or function-call expression
2157 around point, and sends it to the debugger for value display.
2158
2159 The above commands are common to all supported debuggers except xdb which
2160 does not support stepping instructions.
2161
2162 Under gdb, sdb and xdb, \\[gud-tbreak] behaves exactly like \\[gud-break],
2163 except that the breakpoint is temporary; that is, it is removed when
2164 execution stops on it.
2165
2166 Under gdb, dbx, and xdb, \\[gud-up] pops up through an enclosing stack
2167 frame.  \\[gud-down] drops back down through one.
2168
2169 If you are using gdb or xdb, \\[gud-finish] runs execution to the return from
2170 the current function and stops.
2171
2172 All the keystrokes above are accessible in the GUD buffer
2173 with the prefix C-c, and in all buffers through the prefix C-x C-a.
2174
2175 All pre-defined functions for which the concept make sense repeat
2176 themselves the appropriate number of times if you give a prefix
2177 argument.
2178
2179 You may use the `gud-def' macro in the initialization hook to define other
2180 commands.
2181
2182 Other commands for interacting with the debugger process are inherited from
2183 comint mode, which see."
2184   (setq mode-line-process '(":%s"))
2185   (define-key (current-local-map) "\C-c\C-l" 'gud-refresh)
2186   (set (make-local-variable 'gud-last-frame) nil)
2187   (make-local-variable 'comint-prompt-regexp)
2188   ;; Don't put repeated commands in command history many times.
2189   (set (make-local-variable 'comint-input-ignoredups) t)
2190   (make-local-variable 'paragraph-start)
2191   (set (make-local-variable 'gud-delete-prompt-marker) (make-marker)))
2192
2193 ;; Cause our buffers to be displayed, by default,
2194 ;; in the selected window.
2195 ;;;###autoload (add-hook 'same-window-regexps "\\*gud-.*\\*\\(\\|<[0-9]+>\\)")
2196
2197 (defcustom gud-chdir-before-run t
2198   "Non-nil if GUD should `cd' to the debugged executable."
2199   :group 'gud
2200   :type 'boolean)
2201
2202 ;; Perform initializations common to all debuggers.
2203 ;; The first arg is the specified command line,
2204 ;; which starts with the program to debug.
2205 ;; The other three args specify the values to use
2206 ;; for local variables in the debugger buffer.
2207 (defun gud-common-init (command-line massage-args marker-filter &optional find-file)
2208   (let* ((words (split-string command-line))
2209          (program (car words))
2210          ;; Extract the file name from WORDS
2211          ;; and put t in its place.
2212          ;; Later on we will put the modified file name arg back there.
2213          (file-word (let ((w (cdr words)))
2214                       (while (and w (= ?- (aref (car w) 0)))
2215                         (setq w (cdr w)))
2216                       (and w
2217                            (prog1 (car w)
2218                              (setcar w t)))))
2219          (file-subst
2220           (and file-word (substitute-in-file-name file-word)))
2221          (args (cdr words))
2222          ;; If a directory was specified, expand the file name.
2223          ;; Otherwise, don't expand it, so GDB can use the PATH.
2224          ;; A file name without directory is literally valid
2225          ;; only if the file exists in ., and in that case,
2226          ;; omitting the expansion here has no visible effect.
2227          (file (and file-word
2228                     (if (file-name-directory file-subst)
2229                         (expand-file-name file-subst)
2230                       file-subst)))
2231          (filepart (and file-word (concat "-" (file-name-nondirectory file)))))
2232     (pop-to-buffer (concat "*gud" filepart "*"))
2233     ;; Set default-directory to the file's directory.
2234     (and file-word
2235          gud-chdir-before-run
2236          ;; Don't set default-directory if no directory was specified.
2237          ;; In that case, either the file is found in the current directory,
2238          ;; in which case this setq is a no-op,
2239          ;; or it is found by searching PATH,
2240          ;; in which case we don't know what directory it was found in.
2241          (file-name-directory file)
2242          (setq default-directory (file-name-directory file)))
2243     (or (bolp) (newline))
2244     (insert "Current directory is " default-directory "\n")
2245     ;; Put the substituted and expanded file name back in its place.
2246     (let ((w args))
2247       (while (and w (not (eq (car w) t)))
2248         (setq w (cdr w)))
2249       (if w
2250           (setcar w file)))
2251     (apply 'make-comint (concat "gud" filepart) program nil
2252            (funcall massage-args file args)))
2253   ;; Since comint clobbered the mode, we don't set it until now.
2254   (gud-mode)
2255   (make-local-variable 'gud-marker-filter)
2256   (setq gud-marker-filter marker-filter)
2257   (if find-file (set (make-local-variable 'gud-find-file) find-file))
2258
2259   (set-process-filter (get-buffer-process (current-buffer)) 'gud-filter)
2260   (set-process-sentinel (get-buffer-process (current-buffer)) 'gud-sentinel)
2261   (gud-set-buffer))
2262
2263 (defun gud-set-buffer ()
2264   (when (eq major-mode 'gud-mode)
2265     (setq gud-comint-buffer (current-buffer))))
2266
2267 (defvar gud-filter-defer-flag nil
2268   "Non-nil means don't process anything from the debugger right now.
2269 It is saved for when this flag is not set.")
2270
2271 (defvar gud-filter-pending-text nil
2272   "Non-nil means this is text that has been saved for later in `gud-filter'.")
2273
2274 ;; These functions are responsible for inserting output from your debugger
2275 ;; into the buffer.  The hard work is done by the method that is
2276 ;; the value of gud-marker-filter.
2277
2278 (defun gud-filter (proc string)
2279   ;; Here's where the actual buffer insertion is done
2280   (let (output process-window)
2281     (if (buffer-name (process-buffer proc))
2282         (if gud-filter-defer-flag
2283             ;; If we can't process any text now,
2284             ;; save it for later.
2285             (setq gud-filter-pending-text
2286                   (concat (or gud-filter-pending-text "") string))
2287
2288           ;; If we have to ask a question during the processing,
2289           ;; defer any additional text that comes from the debugger
2290           ;; during that time.
2291           (let ((gud-filter-defer-flag t))
2292             ;; Process now any text we previously saved up.
2293             (if gud-filter-pending-text
2294                 (setq string (concat gud-filter-pending-text string)
2295                       gud-filter-pending-text nil))
2296
2297             (with-current-buffer (process-buffer proc)
2298               ;; If we have been so requested, delete the debugger prompt.
2299               (save-restriction
2300                 (widen)
2301                 (if (marker-buffer gud-delete-prompt-marker)
2302                     (progn
2303                       (delete-region (process-mark proc)
2304                                      gud-delete-prompt-marker)
2305                       (set-marker gud-delete-prompt-marker nil)))
2306                 ;; Save the process output, checking for source file markers.
2307                 (setq output (gud-marker-filter string))
2308                 ;; Check for a filename-and-line number.
2309                 ;; Don't display the specified file
2310                 ;; unless (1) point is at or after the position where output appears
2311                 ;; and (2) this buffer is on the screen.
2312                 (setq process-window
2313                       (and gud-last-frame
2314                            (>= (point) (process-mark proc))
2315                            (get-buffer-window (current-buffer)))))
2316
2317               ;; Let the comint filter do the actual insertion.
2318               ;; That lets us inherit various comint features.
2319               (comint-output-filter proc output))
2320
2321             ;; Put the arrow on the source line.
2322             ;; This must be outside of the save-excursion
2323             ;; in case the source file is our current buffer.
2324             (if process-window
2325                 (save-selected-window
2326                   (select-window process-window)
2327                   (gud-display-frame))
2328               ;; We have to be in the proper buffer, (process-buffer proc),
2329               ;; but not in a save-excursion, because that would restore point.
2330               (let ((old-buf (current-buffer)))
2331                 (set-buffer (process-buffer proc))
2332                 (unwind-protect
2333                     (gud-display-frame)
2334                   (set-buffer old-buf)))))
2335
2336           ;; If we deferred text that arrived during this processing,
2337           ;; handle it now.
2338           (if gud-filter-pending-text
2339               (gud-filter proc ""))))))
2340
2341 (defun gud-sentinel (proc msg)
2342   (cond ((null (buffer-name (process-buffer proc)))
2343          ;; buffer killed
2344          ;; Stop displaying an arrow in a source file.
2345          (setq overlay-arrow-position nil)
2346          (set-process-buffer proc nil))
2347         ((memq (process-status proc) '(signal exit))
2348          ;; Stop displaying an arrow in a source file.
2349          (setq overlay-arrow-position nil)
2350          (let* ((obuf (current-buffer)))
2351            ;; save-excursion isn't the right thing if
2352            ;;  process-buffer is current-buffer
2353            (unwind-protect
2354                (progn
2355                  ;; Write something in *compilation* and hack its mode line,
2356                  (set-buffer (process-buffer proc))
2357                  ;; Fix the mode line.
2358                  (setq mode-line-process
2359                        (concat ":"
2360                                (symbol-name (process-status proc))))
2361                  (force-mode-line-update)
2362                  (if (eobp)
2363                      (insert ?\n mode-name " " msg)
2364                    (save-excursion
2365                      (goto-char (point-max))
2366                      (insert ?\n mode-name " " msg)))
2367                  ;; If buffer and mode line will show that the process
2368                  ;; is dead, we can delete it now.  Otherwise it
2369                  ;; will stay around until M-x list-processes.
2370                  (delete-process proc))
2371              ;; Restore old buffer, but don't restore old point
2372              ;; if obuf is the gud buffer.
2373              (set-buffer obuf))))))
2374
2375 (defun gud-display-frame ()
2376   "Find and obey the last filename-and-line marker from the debugger.
2377 Obeying it means displaying in another window the specified file and line."
2378   (interactive)
2379   (if gud-last-frame
2380    (progn
2381      (gud-set-buffer)
2382      (gud-display-line (car gud-last-frame) (cdr gud-last-frame))
2383      (setq gud-last-last-frame gud-last-frame
2384            gud-last-frame nil))))
2385
2386 ;; Make sure the file named TRUE-FILE is in a buffer that appears on the screen
2387 ;; and that its line LINE is visible.
2388 ;; Put the overlay-arrow on the line LINE in that buffer.
2389 ;; Most of the trickiness in here comes from wanting to preserve the current
2390 ;; region-restriction if that's possible.  We use an explicit display-buffer
2391 ;; to get around the fact that this is called inside a save-excursion.
2392
2393 (defun gud-display-line (true-file line)
2394   (let* ((last-nonmenu-event t)  ; Prevent use of dialog box for questions.
2395          (buffer
2396           (save-excursion
2397             (or (eq (current-buffer) gud-comint-buffer)
2398                 (set-buffer gud-comint-buffer))
2399             (gud-find-file true-file)))
2400          (window (and buffer (or (get-buffer-window buffer)
2401                                  (display-buffer buffer))))
2402          (pos))
2403     (if buffer
2404         (progn
2405           (save-excursion
2406             (set-buffer buffer)
2407             (save-restriction
2408               (widen)
2409               (goto-line line)
2410               (setq pos (point))
2411               (setq overlay-arrow-string "=>")
2412               (or overlay-arrow-position
2413                   (setq overlay-arrow-position (make-marker)))
2414               (set-marker overlay-arrow-position (point) (current-buffer)))
2415             (cond ((or (< pos (point-min)) (> pos (point-max)))
2416                    (widen)
2417                    (goto-char pos))))
2418           (set-window-point window overlay-arrow-position)))))
2419
2420 ;;; The gud-call function must do the right thing whether its invoking
2421 ;;; keystroke is from the GUD buffer itself (via major-mode binding)
2422 ;;; or a C buffer.  In the former case, we want to supply data from
2423 ;;; gud-last-frame.  Here's how we do it:
2424
2425 (defun gud-format-command (str arg)
2426   (let ((insource (not (eq (current-buffer) gud-comint-buffer)))
2427         (frame (or gud-last-frame gud-last-last-frame))
2428         result)
2429     (while (and str (string-match "\\([^%]*\\)%\\([adeflpc]\\)" str))
2430       (let ((key (string-to-char (substring str (match-beginning 2))))
2431             subst)
2432         (cond
2433          ((eq key ?f)
2434           (setq subst (file-name-nondirectory (if insource
2435                                                   (buffer-file-name)
2436                                                 (car frame)))))
2437          ((eq key ?F)
2438           (setq subst (file-name-sans-extension
2439                        (file-name-nondirectory (if insource
2440                                                    (buffer-file-name)
2441                                                  (car frame))))))
2442          ((eq key ?d)
2443           (setq subst (file-name-directory (if insource
2444                                                (buffer-file-name)
2445                                              (car frame)))))
2446          ((eq key ?l)
2447           (setq subst (int-to-string
2448                        (if insource
2449                            (save-restriction
2450                              (widen)
2451                              (+ (count-lines 1 (point))
2452                                 (if (bolp) 1 0)))
2453                          (cdr frame)))))
2454          ((eq key ?e)
2455           (setq subst (gud-find-c-expr)))
2456          ((eq key ?a)
2457           (setq subst (gud-read-address)))
2458          ((eq key ?c)
2459           (setq subst (gud-find-class (if insource
2460                                           (buffer-file-name)
2461                                         (car frame)))))
2462          ((eq key ?p)
2463           (setq subst (if arg (int-to-string arg)))))
2464         (setq result (concat result (match-string 1 str) subst)))
2465       (setq str (substring str (match-end 2))))
2466     ;; There might be text left in STR when the loop ends.
2467     (concat result str)))
2468
2469 (defun gud-read-address ()
2470   "Return a string containing the core-address found in the buffer at point."
2471   (save-excursion
2472     (let ((pt (point)) found begin)
2473       (setq found (if (search-backward "0x" (- pt 7) t) (point)))
2474       (cond
2475        (found (forward-char 2)
2476               (buffer-substring found
2477                                 (progn (re-search-forward "[^0-9a-f]")
2478                                        (forward-char -1)
2479                                        (point))))
2480        (t (setq begin (progn (re-search-backward "[^0-9]")
2481                              (forward-char 1)
2482                              (point)))
2483           (forward-char 1)
2484           (re-search-forward "[^0-9]")
2485           (forward-char -1)
2486           (buffer-substring begin (point)))))))
2487
2488 (defun gud-call (fmt &optional arg)
2489   (let ((msg (gud-format-command fmt arg)))
2490     (message "Command: %s" msg)
2491     (sit-for 0)
2492     (gud-basic-call msg)))
2493
2494 (defun gud-basic-call (command)
2495   "Invoke the debugger COMMAND displaying source in other window."
2496   (interactive)
2497   (gud-set-buffer)
2498   (let ((command (concat command "\n"))
2499         (proc (get-buffer-process gud-comint-buffer)))
2500     (or proc (error "Current buffer has no process"))
2501     ;; Arrange for the current prompt to get deleted.
2502     (save-excursion
2503       (set-buffer gud-comint-buffer)
2504       (save-restriction
2505         (widen)
2506         (goto-char (process-mark proc))
2507         (forward-line 0)
2508         (if (looking-at comint-prompt-regexp)
2509             (set-marker gud-delete-prompt-marker (point)))))
2510     (process-send-string proc command)))
2511
2512 (defun gud-refresh (&optional arg)
2513   "Fix up a possibly garbled display, and redraw the arrow."
2514   (interactive "P")
2515   (or gud-last-frame (setq gud-last-frame gud-last-last-frame))
2516   (gud-display-frame)
2517   (recenter arg))
2518 \f
2519 ;;; Code for parsing expressions out of C code.  The single entry point is
2520 ;;; find-c-expr, which tries to return an lvalue expression from around point.
2521 ;;;
2522 ;;; The rest of this file is a hacked version of gdbsrc.el by
2523 ;;; Debby Ayers <ayers@asc.slb.com>,
2524 ;;; Rich Schaefer <schaefer@asc.slb.com> Schlumberger, Austin, Tx.
2525
2526 (defun gud-find-c-expr ()
2527   "Returns the C expr that surrounds point."
2528   (interactive)
2529   (save-excursion
2530     (let (p expr test-expr)
2531       (setq p (point))
2532       (setq expr (gud-innermost-expr))
2533       (setq test-expr (gud-prev-expr))
2534       (while (and test-expr (gud-expr-compound test-expr expr))
2535         (let ((prev-expr expr))
2536           (setq expr (cons (car test-expr) (cdr expr)))
2537           (goto-char (car expr))
2538           (setq test-expr (gud-prev-expr))
2539           ;; If we just pasted on the condition of an if or while,
2540           ;; throw it away again.
2541           (if (member (buffer-substring (car test-expr) (cdr test-expr))
2542                       '("if" "while" "for"))
2543               (setq test-expr nil
2544                     expr prev-expr))))
2545       (goto-char p)
2546       (setq test-expr (gud-next-expr))
2547       (while (gud-expr-compound expr test-expr)
2548         (setq expr (cons (car expr) (cdr test-expr)))
2549         (setq test-expr (gud-next-expr)))
2550       (buffer-substring (car expr) (cdr expr)))))
2551
2552 (defun gud-innermost-expr ()
2553   "Returns the smallest expr that point is in; move point to beginning of it.
2554 The expr is represented as a cons cell, where the car specifies the point in
2555 the current buffer that marks the beginning of the expr and the cdr specifies
2556 the character after the end of the expr."
2557   (let ((p (point)) begin end)
2558     (gud-backward-sexp)
2559     (setq begin (point))
2560     (gud-forward-sexp)
2561     (setq end (point))
2562     (if (>= p end)
2563         (progn
2564          (setq begin p)
2565          (goto-char p)
2566          (gud-forward-sexp)
2567          (setq end (point)))
2568       )
2569     (goto-char begin)
2570     (cons begin end)))
2571
2572 (defun gud-backward-sexp ()
2573   "Version of `backward-sexp' that catches errors."
2574   (condition-case nil
2575       (backward-sexp)
2576     (error t)))
2577
2578 (defun gud-forward-sexp ()
2579   "Version of `forward-sexp' that catches errors."
2580   (condition-case nil
2581      (forward-sexp)
2582     (error t)))
2583
2584 (defun gud-prev-expr ()
2585   "Returns the previous expr, point is set to beginning of that expr.
2586 The expr is represented as a cons cell, where the car specifies the point in
2587 the current buffer that marks the beginning of the expr and the cdr specifies
2588 the character after the end of the expr"
2589   (let ((begin) (end))
2590     (gud-backward-sexp)
2591     (setq begin (point))
2592     (gud-forward-sexp)
2593     (setq end (point))
2594     (goto-char begin)
2595     (cons begin end)))
2596
2597 (defun gud-next-expr ()
2598   "Returns the following expr, point is set to beginning of that expr.
2599 The expr is represented as a cons cell, where the car specifies the point in
2600 the current buffer that marks the beginning of the expr and the cdr specifies
2601 the character after the end of the expr."
2602   (let ((begin) (end))
2603     (gud-forward-sexp)
2604     (gud-forward-sexp)
2605     (setq end (point))
2606     (gud-backward-sexp)
2607     (setq begin (point))
2608     (cons begin end)))
2609
2610 (defun gud-expr-compound-sep (span-start span-end)
2611   "Scan from SPAN-START to SPAN-END for punctuation characters.
2612 If `->' is found, return `?.'.  If `.' is found, return `?.'.
2613 If any other punctuation is found, return `??'.
2614 If no punctuation is found, return `? '."
2615   (let ((result ?\ )
2616         (syntax))
2617     (while (< span-start span-end)
2618       (setq syntax (char-syntax (char-after span-start)))
2619       (cond
2620        ((= syntax ?\ ) t)
2621        ((= syntax ?.) (setq syntax (char-after span-start))
2622         (cond
2623          ((= syntax ?.) (setq result ?.))
2624          ((and (= syntax ?-) (= (char-after (+ span-start 1)) ?>))
2625           (setq result ?.)
2626           (setq span-start (+ span-start 1)))
2627          (t (setq span-start span-end)
2628             (setq result ??)))))
2629       (setq span-start (+ span-start 1)))
2630     result))
2631
2632 (defun gud-expr-compound (first second)
2633   "Non-nil if concatenating FIRST and SECOND makes a single C expression.
2634 The two exprs are represented as a cons cells, where the car
2635 specifies the point in the current buffer that marks the beginning of the
2636 expr and the cdr specifies the character after the end of the expr.
2637 Link exprs of the form:
2638       Expr -> Expr
2639       Expr . Expr
2640       Expr (Expr)
2641       Expr [Expr]
2642       (Expr) Expr
2643       [Expr] Expr"
2644   (let ((span-start (cdr first))
2645         (span-end (car second))
2646         (syntax))
2647     (setq syntax (gud-expr-compound-sep span-start span-end))
2648     (cond
2649      ((= (car first) (car second)) nil)
2650      ((= (cdr first) (cdr second)) nil)
2651      ((= syntax ?.) t)
2652      ((= syntax ?\ )
2653          (setq span-start (char-after (- span-start 1)))
2654          (setq span-end (char-after span-end))
2655          (cond
2656           ((= span-start ?)) t)
2657           ((= span-start ?]) t)
2658           ((= span-end ?() t)
2659           ((= span-end ?[) t)
2660           (t nil)))
2661      (t nil))))
2662
2663 (defun gud-find-class (f)
2664   "Find fully qualified class corresponding to file F.
2665 This function uses the `gud-jdb-classpath' list to derive a file
2666 pathname relative to its classpath directory. The values in
2667 `gud-jdb-classpath' are assumed to have been converted to absolute
2668 pathname standards using file-truename."
2669   ;; Convert f to a standard representation and remove suffix
2670   (setq f (file-name-sans-extension (file-truename f)))
2671   (if gud-jdb-classpath
2672       (save-match-data
2673         (let ((cplist gud-jdb-classpath)
2674               class-found)
2675           ;; Search through classpath list for an entry that is
2676           ;; contained in f
2677           (while (and cplist (not class-found))
2678             (if (string-match (car cplist) f)
2679                 (setq class-found
2680                       (mapconcat (lambda(x) x)
2681                                  (split-string
2682                                    (substring f (+ (match-end 0) 1))
2683                                   "/") ".")))
2684             (setq cplist (cdr cplist)))
2685           (if (not class-found)
2686              (message "gud-find-class: class for file %s not found!" f))
2687           class-found))
2688     (message "gud-find-class: classpath information not available!")))
2689
2690 (provide 'gud)
2691
2692 ;;; gud.el ends here