code.delx.au - gnu-emacs/blob - lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Introduction:
  30 ;;
  31 ;; Whenever a file that Emacs is editing has been changed by another
  32 ;; program the user normally has to execute the command `revert-buffer'
  33 ;; to load the new content of the file into Emacs.
  34 ;;
  35 ;; This package contains two minor modes: Global Auto-Revert Mode and
  36 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  37 ;; whenever the corresponding files have been changed on disk.
  38 ;;
  39 ;; Auto-Revert Mode can be activated for individual buffers.
  40 ;; Global Auto-Revert Mode applies to all file buffers.
  41 ;;
  42 ;; Both modes operate by checking the time stamp of all files at
  43 ;; intervals of `auto-revert-interval'.  The default is every five
  44 ;; seconds.  The check is aborted whenever the user actually uses
  45 ;; Emacs.  You should never even notice that this package is active
  46 ;; (except that your buffers will be reverted, of course).
  47
  48 ;; Usage:
  49 ;;
  50 ;; Go to the appropriate buffer and press:
  51 ;;   M-x auto-revert-mode RET
  52 ;;
  53 ;; To activate Global Auto-Revert Mode, press:
  54 ;;   M-x global-auto-revert-mode RET
  55 ;;
  56 ;; To activate Global Auto-Revert Mode every time Emacs is started
  57 ;; customise the option `global-auto-revert-mode' or the following
  58 ;; line could be added to your ~/.emacs:
  59 ;;   (global-auto-revert-mode 1)
  60 ;;
  61 ;; The function `turn-on-auto-revert-mode' could be added to any major
  62 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  63 ;; mode.  For example, the following line will activate Auto-Revert
  64 ;; Mode in all C mode buffers:
  65 ;;
  66 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  67
  68 ;;; Code:
  69
  70 ;; Dependencies:
  71
  72 (require 'timer)
  73 (eval-when-compile (require 'cl))
  74
  75
  76 ;; Custom Group:
  77 ;;
  78 ;; The two modes will be placed next to Auto Save Mode under the
  79 ;; Files group under Emacs.
  80
  81 (defgroup auto-revert nil
  82   "Revert individual buffers when files on disk change.
  83
  84 Auto-Revert Mode can be activated for individual buffer.
  85 Global Auto-Revert Mode applies to all buffers."
  86   :group 'files
  87   :group 'convenience)
  88
  89
  90 ;; Variables:
  91
  92 ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
  93 ;;;###autoload
  94 (defvar auto-revert-mode nil
  95   "*Non-nil when Auto-Revert Mode is active.
  96 Never set this variable directly, use the command `auto-revert-mode' instead.")
  97 (put 'auto-revert-mode 'permanent-local t)
  98
  99 (defcustom auto-revert-interval 5
 100   "Time, in seconds, between Auto-Revert Mode file checks.
 101 Setting this variable has no effect on buffers that are already in
 102 auto-revert-mode; it only affects buffers that are put into
 103 auto-revert-mode afterwards."
 104   :group 'auto-revert
 105   :type 'integer)
 106
 107 (defcustom auto-revert-stop-on-user-input t
 108   "When non-nil Auto-Revert Mode stops checking files on user input."
 109   :group 'auto-revert
 110   :type 'boolean)
 111
 112 (defcustom auto-revert-verbose t
 113   "When nil, Auto-Revert Mode will not generate any messages.
 114
 115 Currently, messages are generated when the mode is activated or
 116 deactivated, and whenever a file is reverted."
 117   :group 'auto-revert
 118   :type 'boolean)
 119
 120 (defcustom auto-revert-mode-text " ARev"
 121   "String to display in the mode line when Auto-Revert Mode is active.
 122
 123 \(When the string is not empty, make sure that it has a leading space.)"
 124   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 125   :group 'auto-revert
 126   :type 'string)
 127
 128 (defcustom auto-revert-mode-hook nil
 129   "Functions to run when Auto-Revert Mode is activated."
 130   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 131   :group 'auto-revert
 132   :type 'hook)
 133
 134 (defcustom global-auto-revert-mode-text ""
 135   "String to display when Global Auto-Revert Mode is active.
 136
 137 The default is nothing since when this mode is active this text doesn't
 138 vary over time, or between buffers.  Hence mode line text
 139 would only waste precious space."
 140   :group 'auto-revert
 141   :type 'string)
 142
 143 (defcustom global-auto-revert-mode-hook nil
 144   "Hook called when Global Auto-Revert Mode is activated."
 145   :group 'auto-revert
 146   :type 'hook)
 147
 148 (defcustom global-auto-revert-non-file-buffers nil
 149   "When nil only file buffers are reverted by Global Auto-Revert Mode.
 150
 151 When non-nil, both file buffers and buffers with a custom
 152 `revert-buffer-function' are reverted by Global Auto-Revert Mode.
 153
 154 Use this option with care since it could lead to excessive reverts."
 155   :group 'auto-revert
 156   :type 'boolean)
 157
 158 (defcustom global-auto-revert-ignore-modes '()
 159   "List of major modes Global Auto-Revert Mode should not check."
 160   :group 'auto-revert
 161   :type '(repeat sexp))
 162
 163 (defcustom auto-revert-load-hook nil
 164   "Functions to run when Auto-Revert Mode is first loaded."
 165   :tag "Load Hook"
 166   :group 'auto-revert
 167   :type 'hook)
 168
 169 (defvar global-auto-revert-ignore-buffer nil
 170   "*When non-nil, Global Auto-Revert Mode will not revert this buffer.
 171
 172 This variable becomes buffer local when set in any fashion.")
 173 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 174
 175
 176 ;; Internal variables:
 177
 178 (defvar auto-revert-buffer-list '()
 179   "List of buffers in Auto-Revert Mode.
 180
 181 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 182 buffers to this list.
 183
 184 The timer function `auto-revert-buffers' is responsible for purging
 185 the list of old buffers.")
 186
 187 (defvar auto-revert-timer nil
 188   "Timer used by Auto-Revert Mode.")
 189
 190 (defvar auto-revert-remaining-buffers '()
 191   "Buffers not checked when user input stopped execution.")
 192
 193
 194 ;; Functions:
 195
 196 ;;;###autoload
 197 (define-minor-mode auto-revert-mode
 198   "Toggle reverting buffer when file on disk changes.
 199
 200 With arg, turn Auto Revert mode on if and only if arg is positive.
 201 This is a minor mode that affects only the current buffer.
 202 Use `global-auto-revert-mode' to automatically revert all buffers."
 203   nil auto-revert-mode-text nil
 204   (if auto-revert-mode
 205       (if (not (memq (current-buffer) auto-revert-buffer-list))
 206           (push (current-buffer) auto-revert-buffer-list))
 207     (setq auto-revert-buffer-list
 208           (delq (current-buffer) auto-revert-buffer-list)))
 209   (auto-revert-set-timer)
 210   (when auto-revert-mode
 211     (auto-revert-buffers)))
 212
 213
 214 ;;;###autoload
 215 (defun turn-on-auto-revert-mode ()
 216   "Turn on Auto-Revert Mode.
 217
 218 This function is designed to be added to hooks, for example:
 219   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 220   (auto-revert-mode 1))
 221
 222
 223 ;;;###autoload
 224 (define-minor-mode global-auto-revert-mode
 225   "Revert any buffer when file on disk change.
 226
 227 With arg, turn Auto Revert mode on globally if and only if arg is positive.
 228 This is a minor mode that affects all buffers.
 229 Use `auto-revert-mode' to revert a particular buffer."
 230   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 231   (auto-revert-set-timer)
 232   (when global-auto-revert-mode
 233     (auto-revert-buffers)))
 234
 235
 236 (defun auto-revert-set-timer ()
 237   "Restart or cancel the timer."
 238   (if (timerp auto-revert-timer)
 239       (cancel-timer auto-revert-timer))
 240   (setq auto-revert-timer
 241         (if (or global-auto-revert-mode auto-revert-buffer-list)
 242             (run-with-timer auto-revert-interval
 243                             auto-revert-interval
 244                             'auto-revert-buffers)
 245           nil)))
 246
 247 (defun auto-revert-active-p ()
 248   "Check if auto-revert is active (in current buffer or globally)."
 249   (or auto-revert-mode
 250       (and
 251        global-auto-revert-mode
 252        (not global-auto-revert-ignore-buffer)
 253        (not (memq major-mode
 254                   global-auto-revert-ignore-modes)))))
 255
 256 (defun auto-revert-list-diff (a b)
 257   "Check if strings in list A differ from list B."
 258   (when (and a b)
 259     (setq a (sort a 'string-lessp))
 260     (setq b (sort b 'string-lessp))
 261     (let (elt1 elt2)
 262       (catch 'break
 263         (while (and (setq elt1 (and a (pop a)))
 264                     (setq elt2 (and b (pop b))))
 265           (if (not (string= elt1 elt2))
 266               (throw 'break t)))))))
 267
 268 (defun auto-revert-dired-file-list ()
 269   "Return list of dired files."
 270   (let (list)
 271     (save-excursion
 272       (goto-char (point-min))
 273       (while (not (eobp))
 274         (if (setq file (dired-get-filename t t))
 275             (push file list))
 276         (forward-line 1)))
 277     list))
 278
 279 (defun auto-revert-dired-changed-p ()
 280   "Check if dired buffer has changed."
 281   (when (and (stringp dired-directory)
 282              ;;   Exclude remote buffers, would be too slow for user
 283              ;;   modem, timeouts, network lag ... all is possible
 284              (not (string-match "@" dired-directory))
 285              (file-directory-p dired-directory))
 286     (let ((files (directory-files dired-directory))
 287           (dired (auto-revert-dired-file-list)))
 288       (or (not (eq (length files) (length dired)))
 289           (auto-revert-list-diff files dired)))))
 290
 291 (defun auto-revert-buffer-p ()
 292   "Check if current buffer should be reverted."
 293   ;;  Always include dired buffers to list. It would be too expensive
 294   ;;  to test the "revert" status here each time timer launches.
 295   (or (eq major-mode 'dired-mode)
 296       (and (not (buffer-modified-p))
 297            (if (buffer-file-name)
 298                (and (file-readable-p (buffer-file-name))
 299                     (not (verify-visited-file-modtime buf)))
 300              (and revert-buffer-function
 301                   (or (and global-auto-revert-mode
 302                            global-auto-revert-non-file-buffers)
 303                       auto-revert-mode))))))
 304
 305 (defun auto-revert-handler ()
 306   "Revert current buffer."
 307   (let (done)
 308     (cond
 309      ((eq major-mode 'dired-mode)
 310       ;;  Dired includes revert-buffer-function
 311       (when (and revert-buffer-function
 312                  (auto-revert-dired-changed-p))
 313         (setq done t)
 314         (revert-buffer t t t)))
 315      ((or (buffer-file-name)
 316           revert-buffer-function)
 317       (setq done t)
 318       (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)))
 319     (if (and done
 320              auto-revert-verbose)
 321         (message "Reverting buffer `%s'." (buffer-name)))))
 322
 323 (defun auto-revert-buffers ()
 324   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 325
 326 Should `global-auto-revert-mode' be active all file buffers are checked.
 327
 328 Should `auto-revert-mode' be active in some buffers, those buffers
 329 are checked.
 330
 331 Non-file buffers that have a custom `revert-buffer-function' are
 332 reverted either when Auto-Revert Mode is active in that buffer, or
 333 when the variable `global-auto-revert-non-file-buffers' is non-nil
 334 and Global Auto-Revert Mode is active.
 335
 336 This function stops whenever there is user input.  The buffers not
 337 checked are stored in the variable `auto-revert-remaining-buffers'.
 338
 339 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 340 are checked first the next time this function is called.
 341
 342 This function is also responsible for removing buffers no longer in
 343 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 344 the timer when no buffers need to be checked."
 345   (let ((bufs (if global-auto-revert-mode
 346                   (buffer-list)
 347                 auto-revert-buffer-list))
 348         (remaining '())
 349         (new '()))
 350     ;; Partition `bufs' into two halves depending on whether or not
 351     ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 352     ;; halves are then re-joined with the "remaining" buffers at the
 353     ;; head of the list.
 354     (dolist (buf auto-revert-remaining-buffers)
 355       (if (memq buf bufs)
 356           (push buf remaining)))
 357     (dolist (buf bufs)
 358       (if (not (memq buf remaining))
 359           (push buf new)))
 360     (setq bufs (nreverse (nconc new remaining)))
 361     (while (and bufs
 362                 (not (and auto-revert-stop-on-user-input
 363                           (input-pending-p))))
 364       (let ((buf (car bufs)))
 365         (if (buffer-name buf)           ; Buffer still alive?
 366             (with-current-buffer buf
 367               ;; Test if someone has turned off Auto-Revert Mode in a
 368               ;; non-standard way, for example by changing major mode.
 369               (if (and (not auto-revert-mode)
 370                        (memq buf auto-revert-buffer-list))
 371                   (setq auto-revert-buffer-list
 372                         (delq buf auto-revert-buffer-list)))
 373               (when (and (auto-revert-active-p)
 374                          (auto-revert-buffer-p))
 375                 (auto-revert-handler)
 376                 ;; `preserve-modes' avoids changing the (minor) modes.  But we
 377                 ;; do want to reset the mode for VC, so we do it explicitly.
 378                 (vc-find-file-hook)))
 379           ;; Remove dead buffer from `auto-revert-buffer-list'.
 380           (setq auto-revert-buffer-list
 381                 (delq buf auto-revert-buffer-list))))
 382       (setq bufs (cdr bufs)))
 383     (setq auto-revert-remaining-buffers bufs)
 384     ;; Check if we should cancel the timer.
 385     (when (and (not global-auto-revert-mode)
 386                (null auto-revert-buffer-list))
 387       (cancel-timer auto-revert-timer)
 388       (setq auto-revert-timer nil))))
 389
 390
 391 ;; The end:
 392 (provide 'autorevert)
 393
 394 (run-hooks 'auto-revert-load-hook)
 395
 396 ;;; arch-tag: f6bcb07b-4841-477e-9e44-b18678e58876
 397 ;;; autorevert.el ends here