code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/derived.el

   1 ;;; derived.el --- allow inheritance of major modes
   2 ;; (formerly mode-clone.el)
   3
   4 ;; Copyright (C) 1993, 1994, 1999, 2003 Free Software Foundation, Inc.
   5
   6 ;; Author: David Megginson (dmeggins@aix1.uottawa.ca)
   7 ;; Maintainer: FSF
   8 ;; Keywords: extensions
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  25 ;; Boston, MA 02110-1301, USA.
  26 \f
  27 ;;; Commentary:
  28
  29 ;; GNU Emacs is already, in a sense, object oriented -- each object
  30 ;; (buffer) belongs to a class (major mode), and that class defines
  31 ;; the relationship between messages (input events) and methods
  32 ;; (commands) by means of a keymap.
  33 ;;
  34 ;; The only thing missing is a good scheme of inheritance.  It is
  35 ;; possible to simulate a single level of inheritance with generous
  36 ;; use of hooks and a bit of work -- sgml-mode, for example, also runs
  37 ;; the hooks for text-mode, and keymaps can inherit from other keymaps
  38 ;; -- but generally, each major mode ends up reinventing the wheel.
  39 ;; Ideally, someone should redesign all of Emacs's major modes to
  40 ;; follow a more conventional object-oriented system: when defining a
  41 ;; new major mode, the user should need only to name the existing mode
  42 ;; it is most similar to, then list the (few) differences.
  43 ;;
  44 ;; In the mean time, this package offers most of the advantages of
  45 ;; full inheritance with the existing major modes.  The macro
  46 ;; `define-derived-mode' allows the user to make a variant of an existing
  47 ;; major mode, with its own keymap.  The new mode will inherit the key
  48 ;; bindings of its parent, and will, in fact, run its parent first
  49 ;; every time it is called.  For example, the commands
  50 ;;
  51 ;;  (define-derived-mode hypertext-mode text-mode "Hypertext"
  52 ;;    "Major mode for hypertext.\n\n\\{hypertext-mode-map}"
  53 ;;    (setq case-fold-search nil))
  54 ;;
  55 ;;  (define-key hypertext-mode-map [down-mouse-3] 'do-hyper-link)
  56 ;;
  57 ;; will create a function `hypertext-mode' with its own (sparse)
  58 ;; keymap `hypertext-mode-map.'  The command M-x hypertext-mode will
  59 ;; perform the following actions:
  60 ;;
  61 ;; - run the command (text-mode) to get its default setup
  62 ;; - replace the current keymap with 'hypertext-mode-map,' which will
  63 ;;   inherit from 'text-mode-map'.
  64 ;; - replace the current syntax table with
  65 ;;   'hypertext-mode-syntax-table', which will borrow its defaults
  66 ;;   from the current text-mode-syntax-table.
  67 ;; - replace the current abbrev table with
  68 ;;   'hypertext-mode-abbrev-table', which will borrow its defaults
  69 ;;   from the current text-mode-abbrev table
  70 ;; - change the mode line to read "Hypertext"
  71 ;; - assign the value 'hypertext-mode' to the 'major-mode' variable
  72 ;; - run the body of commands provided in the macro -- in this case,
  73 ;;   set the local variable `case-fold-search' to nil.
  74 ;;
  75 ;; The advantages of this system are threefold.  First, text mode is
  76 ;; untouched -- if you had added the new keystroke to `text-mode-map,'
  77 ;; possibly using hooks, you would have added it to all text buffers
  78 ;; -- here, it appears only in hypertext buffers, where it makes
  79 ;; sense.  Second, it is possible to build even further, and make
  80 ;; a derived mode from a derived mode.  The commands
  81 ;;
  82 ;;   (define-derived-mode html-mode hypertext-mode "HTML")
  83 ;;   [various key definitions]
  84 ;;
  85 ;; will add a new major mode for HTML with very little fuss.
  86 ;;
  87 ;; Note also the function `derived-mode-p' which can tell if the current
  88 ;; mode derives from another.  In a hypertext-mode, buffer, for example,
  89 ;; (derived-mode-p 'text-mode) would return non-nil.  This should always
  90 ;; be used in place of (eq major-mode 'text-mode).
  91 \f
  92 ;;; Code:
  93
  94 (eval-when-compile (require 'cl))
  95
  96 ;;; PRIVATE: defsubst must be defined before they are first used
  97
  98 (defsubst derived-mode-hook-name (mode)
  99   "Construct the mode hook name based on mode name MODE."
 100   (intern (concat (symbol-name mode) "-hook")))
 101
 102 (defsubst derived-mode-map-name (mode)
 103   "Construct a map name based on a MODE name."
 104   (intern (concat (symbol-name mode) "-map")))
 105
 106 (defsubst derived-mode-syntax-table-name (mode)
 107   "Construct a syntax-table name based on a MODE name."
 108   (intern (concat (symbol-name mode) "-syntax-table")))
 109
 110 (defsubst derived-mode-abbrev-table-name (mode)
 111   "Construct an abbrev-table name based on a MODE name."
 112   (intern (concat (symbol-name mode) "-abbrev-table")))
 113
 114 ;; PUBLIC: define a new major mode which inherits from an existing one.
 115
 116 ;;;###autoload
 117 (defmacro define-derived-mode (child parent name &optional docstring &rest body)
 118   "Create a new mode as a variant of an existing mode.
 119
 120 The arguments to this command are as follow:
 121
 122 CHILD:     the name of the command for the derived mode.
 123 PARENT:    the name of the command for the parent mode (e.g. `text-mode')
 124            or nil if there is no parent.
 125 NAME:      a string which will appear in the status line (e.g. \"Hypertext\")
 126 DOCSTRING: an optional documentation string--if you do not supply one,
 127            the function will attempt to invent something useful.
 128 BODY:      forms to execute just before running the
 129            hooks for the new mode.  Do not use `interactive' here.
 130
 131 BODY can start with a bunch of keyword arguments.  The following keyword
 132   arguments are currently understood:
 133 :group GROUP
 134         Declare the customization group that corresponds to this mode.
 135         The command `customize-mode' uses this.
 136 :syntax-table TABLE
 137         Use TABLE instead of the default.
 138         A nil value means to simply use the same syntax-table as the parent.
 139 :abbrev-table TABLE
 140         Use TABLE instead of the default.
 141         A nil value means to simply use the same abbrev-table as the parent.
 142
 143 Here is how you could define LaTeX-Thesis mode as a variant of LaTeX mode:
 144
 145   (define-derived-mode LaTeX-thesis-mode LaTeX-mode \"LaTeX-Thesis\")
 146
 147 You could then make new key bindings for `LaTeX-thesis-mode-map'
 148 without changing regular LaTeX mode.  In this example, BODY is empty,
 149 and DOCSTRING is generated by default.
 150
 151 On a more complicated level, the following command uses `sgml-mode' as
 152 the parent, and then sets the variable `case-fold-search' to nil:
 153
 154   (define-derived-mode article-mode sgml-mode \"Article\"
 155     \"Major mode for editing technical articles.\"
 156     (setq case-fold-search nil))
 157
 158 Note that if the documentation string had been left out, it would have
 159 been generated automatically, with a reference to the keymap.
 160
 161 The new mode runs the hook constructed by the function
 162 `derived-mode-hook-name'.
 163
 164 See Info node `(elisp)Derived Modes' for more details."
 165   (declare (debug (&define name symbolp sexp [&optional stringp]
 166                            [&rest keywordp sexp] def-body)))
 167
 168   (when (and docstring (not (stringp docstring)))
 169     ;; Some trickiness, since what appears to be the docstring may really be
 170     ;; the first element of the body.
 171     (push docstring body)
 172     (setq docstring nil))
 173
 174   (when (eq parent 'fundamental-mode) (setq parent nil))
 175
 176   (let ((map (derived-mode-map-name child))
 177         (syntax (derived-mode-syntax-table-name child))
 178         (abbrev (derived-mode-abbrev-table-name child))
 179         (declare-abbrev t)
 180         (declare-syntax t)
 181         (hook (derived-mode-hook-name child))
 182         (group nil))
 183
 184     ;; Process the keyword args.
 185     (while (keywordp (car body))
 186       (case (pop body)
 187         (:group (setq group (pop body)))
 188         (:abbrev-table (setq abbrev (pop body)) (setq declare-abbrev nil))
 189         (:syntax-table (setq syntax (pop body)) (setq declare-syntax nil))
 190         (t (pop body))))
 191
 192     (setq docstring (derived-mode-make-docstring
 193                      parent child docstring syntax abbrev))
 194
 195     `(progn
 196        (defvar ,hook nil ,(format "Hook run when entering %s mode." name))
 197        (defvar ,map (make-sparse-keymap))
 198        ,(if declare-syntax
 199             `(defvar ,syntax (make-syntax-table)))
 200        ,(if declare-abbrev
 201             `(defvar ,abbrev
 202                (progn (define-abbrev-table ',abbrev nil) ,abbrev)))
 203        (put ',child 'derived-mode-parent ',parent)
 204        ,(if group `(put ',child 'custom-mode-group ,group))
 205
 206        (defun ,child ()
 207          ,docstring
 208          (interactive)
 209                                         ; Run the parent.
 210          (delay-mode-hooks
 211
 212           (,(or parent 'kill-all-local-variables))
 213                                         ; Identify the child mode.
 214           (setq major-mode (quote ,child))
 215           (setq mode-name ,name)
 216                                         ; Identify special modes.
 217           ,(when parent
 218              `(progn
 219                 (if (get (quote ,parent) 'mode-class)
 220                     (put (quote ,child) 'mode-class
 221                          (get (quote ,parent) 'mode-class)))
 222                                         ; Set up maps and tables.
 223                 (unless (keymap-parent ,map)
 224                   ;; It would probably be better to set the keymap's parent
 225                   ;; at the toplevel rather than inside the mode function,
 226                   ;; but this is not easy for at least the following reasons:
 227                   ;; - the parent (and its keymap) may not yet be loaded.
 228                   ;; - the parent's keymap name may be called something else
 229                   ;;   than <parent>-mode-map.
 230                   (set-keymap-parent ,map (current-local-map)))
 231                 ,(when declare-syntax
 232                    `(let ((parent (char-table-parent ,syntax)))
 233                       (unless (and parent
 234                                    (not (eq parent (standard-syntax-table))))
 235                         (set-char-table-parent ,syntax (syntax-table)))))))
 236
 237           (use-local-map ,map)
 238           ,(when syntax `(set-syntax-table ,syntax))
 239           ,(when abbrev `(setq local-abbrev-table ,abbrev))
 240                                         ; Splice in the body (if any).
 241           ,@body
 242           )
 243          ;; Run the hooks, if any.
 244          ;; Make the generated code work in older Emacs versions
 245          ;; that do not yet have run-mode-hooks.
 246          (if (fboundp 'run-mode-hooks)
 247              (run-mode-hooks ',hook)
 248            (run-hooks ',hook))))))
 249
 250 ;; PUBLIC: find the ultimate class of a derived mode.
 251
 252 (defun derived-mode-class (mode)
 253   "Find the class of a major MODE.
 254 A mode's class is the first ancestor which is NOT a derived mode.
 255 Use the `derived-mode-parent' property of the symbol to trace backwards.
 256 Since major-modes might all derive from `fundamental-mode', this function
 257 is not very useful."
 258   (while (get mode 'derived-mode-parent)
 259     (setq mode (get mode 'derived-mode-parent)))
 260   mode)
 261 (make-obsolete 'derived-mode-class 'derived-mode-p "22.1")
 262
 263 \f
 264 ;;; PRIVATE
 265
 266 (defun derived-mode-make-docstring (parent child &optional
 267                                            docstring syntax abbrev)
 268   "Construct a docstring for a new mode if none is provided."
 269
 270   (let ((map (derived-mode-map-name child))
 271         (hook (derived-mode-hook-name child)))
 272
 273     (unless (stringp docstring)
 274       ;; Use a default docstring.
 275       (setq docstring
 276             (if (null parent)
 277                 (format "Major-mode.
 278 Uses keymap `%s', abbrev table `%s' and syntax-table `%s'." map abbrev syntax)
 279               (format "Major mode derived from `%s' by `define-derived-mode'.
 280 It inherits all of the parent's attributes, but has its own keymap,
 281 abbrev table and syntax table:
 282
 283   `%s', `%s' and `%s'
 284
 285 which more-or-less shadow %s's corresponding tables."
 286                       parent map abbrev syntax parent))))
 287
 288     (unless (string-match (regexp-quote (symbol-name hook)) docstring)
 289       ;; Make sure the docstring mentions the mode's hook.
 290       (setq docstring
 291             (concat docstring
 292                     (if (null parent)
 293                         "\n\nThis mode "
 294                       (concat
 295                        "\n\nIn addition to any hooks its parent mode "
 296                        (if (string-match (regexp-quote (format "`%s'" parent))
 297                                          docstring) nil
 298                          (format "`%s' " parent))
 299                        "might have run,\nthis mode "))
 300                     (format "runs the hook `%s'" hook)
 301                     ", as the final step\nduring initialization.")))
 302
 303     (unless (string-match "\\\\[{[]" docstring)
 304       ;; And don't forget to put the mode's keymap.
 305       (setq docstring (concat docstring "\n\n\\{" (symbol-name map) "}")))
 306
 307     docstring))
 308
 309 \f
 310 ;;; OBSOLETE
 311 ;; The functions below are only provided for backward compatibility with
 312 ;; code byte-compiled with versions of derived.el prior to Emacs-21.
 313
 314 (defsubst derived-mode-setup-function-name (mode)
 315   "Construct a setup-function name based on a MODE name."
 316   (intern (concat (symbol-name mode) "-setup")))
 317
 318 \f
 319 ;; Utility functions for defining a derived mode.
 320
 321 ;;;###autoload
 322 (defun derived-mode-init-mode-variables (mode)
 323   "Initialize variables for a new MODE.
 324 Right now, if they don't already exist, set up a blank keymap, an
 325 empty syntax table, and an empty abbrev table -- these will be merged
 326 the first time the mode is used."
 327
 328   (if (boundp (derived-mode-map-name mode))
 329       t
 330     (eval `(defvar ,(derived-mode-map-name mode)
 331                (make-sparse-keymap)
 332                ,(format "Keymap for %s." mode)))
 333     (put (derived-mode-map-name mode) 'derived-mode-unmerged t))
 334
 335   (if (boundp (derived-mode-syntax-table-name mode))
 336       t
 337     (eval `(defvar ,(derived-mode-syntax-table-name mode)
 338              ;; Make a syntax table which doesn't specify anything
 339              ;; for any char.  Valid data will be merged in by
 340              ;; derived-mode-merge-syntax-tables.
 341              (make-char-table 'syntax-table nil)
 342              ,(format "Syntax table for %s." mode)))
 343     (put (derived-mode-syntax-table-name mode) 'derived-mode-unmerged t))
 344
 345   (if (boundp (derived-mode-abbrev-table-name mode))
 346       t
 347     (eval `(defvar ,(derived-mode-abbrev-table-name mode)
 348              (progn
 349                (define-abbrev-table (derived-mode-abbrev-table-name mode) nil)
 350                (make-abbrev-table))
 351              ,(format "Abbrev table for %s." mode)))))
 352 \f
 353 ;; Utility functions for running a derived mode.
 354
 355 (defun derived-mode-set-keymap (mode)
 356   "Set the keymap of the new MODE, maybe merging with the parent."
 357   (let* ((map-name (derived-mode-map-name mode))
 358          (new-map (eval map-name))
 359          (old-map (current-local-map)))
 360     (and old-map
 361          (get map-name 'derived-mode-unmerged)
 362          (derived-mode-merge-keymaps old-map new-map))
 363     (put map-name 'derived-mode-unmerged nil)
 364     (use-local-map new-map)))
 365
 366 (defun derived-mode-set-syntax-table (mode)
 367   "Set the syntax table of the new MODE, maybe merging with the parent."
 368   (let* ((table-name (derived-mode-syntax-table-name mode))
 369          (old-table (syntax-table))
 370          (new-table (eval table-name)))
 371     (if (get table-name 'derived-mode-unmerged)
 372         (derived-mode-merge-syntax-tables old-table new-table))
 373     (put table-name 'derived-mode-unmerged nil)
 374     (set-syntax-table new-table)))
 375
 376 (defun derived-mode-set-abbrev-table (mode)
 377   "Set the abbrev table for MODE if it exists.
 378 Always merge its parent into it, since the merge is non-destructive."
 379   (let* ((table-name (derived-mode-abbrev-table-name mode))
 380          (old-table local-abbrev-table)
 381          (new-table (eval table-name)))
 382     (derived-mode-merge-abbrev-tables old-table new-table)
 383     (setq local-abbrev-table new-table)))
 384
 385 ;;;(defun derived-mode-run-setup-function (mode)
 386 ;;;  "Run the setup function if it exists."
 387
 388 ;;;  (let ((fname (derived-mode-setup-function-name mode)))
 389 ;;;    (if (fboundp fname)
 390 ;;;     (funcall fname))))
 391
 392 (defun derived-mode-run-hooks (mode)
 393   "Run the mode hook for MODE."
 394   (let ((hooks-name (derived-mode-hook-name mode)))
 395     (if (boundp hooks-name)
 396         (run-hooks hooks-name))))
 397
 398 ;; Functions to merge maps and tables.
 399
 400 (defun derived-mode-merge-keymaps (old new)
 401   "Merge an OLD keymap into a NEW one.
 402 The old keymap is set to be the last cdr of the new one, so that there will
 403 be automatic inheritance."
 404   ;; ?? Can this just use `set-keymap-parent'?
 405   (let ((tail new))
 406     ;; Scan the NEW map for prefix keys.
 407     (while (consp tail)
 408       (and (consp (car tail))
 409            (let* ((key (vector (car (car tail))))
 410                   (subnew (lookup-key new key))
 411                   (subold (lookup-key old key)))
 412              ;; If KEY is a prefix key in both OLD and NEW, merge them.
 413              (and (keymapp subnew) (keymapp subold)
 414                   (derived-mode-merge-keymaps subold subnew))))
 415       (and (vectorp (car tail))
 416            ;; Search a vector of ASCII char bindings for prefix keys.
 417            (let ((i (1- (length (car tail)))))
 418              (while (>= i 0)
 419                (let* ((key (vector i))
 420                       (subnew (lookup-key new key))
 421                       (subold (lookup-key old key)))
 422                  ;; If KEY is a prefix key in both OLD and NEW, merge them.
 423                  (and (keymapp subnew) (keymapp subold)
 424                       (derived-mode-merge-keymaps subold subnew)))
 425                (setq i (1- i)))))
 426       (setq tail (cdr tail))))
 427   (setcdr (nthcdr (1- (length new)) new) old))
 428
 429 (defun derived-mode-merge-syntax-tables (old new)
 430   "Merge an OLD syntax table into a NEW one.
 431 Where the new table already has an entry, nothing is copied from the old one."
 432   (set-char-table-parent new old))
 433
 434 ;; Merge an old abbrev table into a new one.
 435 ;; This function requires internal knowledge of how abbrev tables work,
 436 ;; presuming that they are obarrays with the abbrev as the symbol, the expansion
 437 ;; as the value of the symbol, and the hook as the function definition.
 438 (defun derived-mode-merge-abbrev-tables (old new)
 439   (if old
 440       (mapatoms
 441        (lambda (symbol)
 442          (or (intern-soft (symbol-name symbol) new)
 443              (define-abbrev new (symbol-name symbol)
 444                (symbol-value symbol) (symbol-function symbol))))
 445        old)))
 446
 447 (provide 'derived)
 448
 449 ;; arch-tag: 630be248-47d1-4f02-afa0-8207de0ebea0
 450 ;;; derived.el ends here