code.delx.au - gnu-emacs/blob - lisp/xml.el

   1 ;;; xml.el --- XML parser
   2
   3 ;; Copyright (C) 2000, 01, 03, 2004  Free Software Foundation, Inc.
   4
   5 ;; Author: Emmanuel Briot  <briot@gnat.com>
   6 ;; Maintainer: Mark A. Hershberger <mah@everybody.org>
   7 ;; Keywords: xml, data
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; This file contains a somewhat incomplete non-validating XML parser.  It
  29 ;; parses a file, and returns a list that can be used internally by
  30 ;; any other Lisp libraries.
  31
  32 ;;; FILE FORMAT
  33
  34 ;; The document type declaration may either be ignored or (optionally)
  35 ;; parsed, but currently the parsing will only accept element
  36 ;; declarations.  The XML file is assumed to be well-formed.  In case
  37 ;; of error, the parsing stops and the XML file is shown where the
  38 ;; parsing stopped.
  39 ;;
  40 ;; It also knows how to ignore comments and processing instructions.
  41 ;;
  42 ;; The XML file should have the following format:
  43 ;;    <node1 attr1="name1" attr2="name2" ...>value
  44 ;;       <node2 attr3="name3" attr4="name4">value2</node2>
  45 ;;       <node3 attr5="name5" attr6="name6">value3</node3>
  46 ;;    </node1>
  47 ;; Of course, the name of the nodes and attributes can be anything.  There can
  48 ;; be any number of attributes (or none), as well as any number of children
  49 ;; below the nodes.
  50 ;;
  51 ;; There can be only top level node, but with any number of children below.
  52
  53 ;;; LIST FORMAT
  54
  55 ;; The functions `xml-parse-file', `xml-parse-region' and
  56 ;; `xml-parse-tag' return a list with the following format:
  57 ;;
  58 ;;    xml-list   ::= (node node ...)
  59 ;;    node       ::= (qname attribute-list . child_node_list)
  60 ;;    child_node_list ::= child_node child_node ...
  61 ;;    child_node ::= node | string
  62 ;;    qname      ::= (:namespace-uri . "name") | "name"
  63 ;;    attribute_list ::= ((qname . "value") (qname . "value") ...)
  64 ;;                       | nil
  65 ;;    string     ::= "..."
  66 ;;
  67 ;; Some macros are provided to ease the parsing of this list.
  68 ;; Whitespace is preserved.  Fixme: There should be a tree-walker that
  69 ;; can remove it.
  70
  71 ;; TODO:
  72 ;;  * xml:base, xml:space support
  73 ;;  * more complete DOCTYPE parsing
  74 ;;  * pi support
  75
  76 ;;; Code:
  77
  78 ;; Note that {buffer-substring,match-string}-no-properties were
  79 ;; formerly used in several places, but that removes composition info.
  80
  81 ;;*******************************************************************
  82 ;;**
  83 ;;**  Macros to parse the list
  84 ;;**
  85 ;;*******************************************************************
  86
  87 (defvar xml-entity-alist
  88   '(("lt"   . "<")
  89     ("gt"   . ">")
  90     ("apos" . "'")
  91     ("quot" . "\"")
  92     ("amp"  . "&"))
  93   "The defined entities.  Entities are added to this when the DTD is parsed.")
  94
  95 (defvar xml-sub-parser nil
  96   "Dynamically set this to a non-nil value if you want to parse an XML fragment.")
  97
  98 (defvar xml-validating-parser nil
  99   "Set to non-nil to get validity checking.")
 100
 101 (defsubst xml-node-name (node)
 102   "Return the tag associated with NODE.
 103 Without namespace-aware parsing, the tag is a symbol.
 104
 105 With namespace-aware parsing, the tag is a cons of a string
 106 representing the uri of the namespace with the local name of the
 107 tag.  For example,
 108
 109     <foo>
 110
 111 would be represented by
 112
 113     '(\"\" . \"foo\")."
 114
 115   (car node))
 116
 117 (defsubst xml-node-attributes (node)
 118   "Return the list of attributes of NODE.
 119 The list can be nil."
 120   (nth 1 node))
 121
 122 (defsubst xml-node-children (node)
 123   "Return the list of children of NODE.
 124 This is a list of nodes, and it can be nil."
 125   (cddr node))
 126
 127 (defun xml-get-children (node child-name)
 128   "Return the children of NODE whose tag is CHILD-NAME.
 129 CHILD-NAME should match the value returned by `xml-node-name'."
 130   (let ((match ()))
 131     (dolist (child (xml-node-children node))
 132       (if (and (listp child)
 133                (equal (xml-node-name child) child-name))
 134           (push child match)))
 135     (nreverse match)))
 136
 137 (defun xml-get-attribute-or-nil (node attribute)
 138   "Get from NODE the value of ATTRIBUTE.
 139 Return nil if the attribute was not found.
 140
 141 See also `xml-get-attribute'."
 142   (cdr (assoc attribute (xml-node-attributes node))))
 143
 144 (defsubst xml-get-attribute (node attribute)
 145   "Get from NODE the value of ATTRIBUTE.
 146 An empty string is returned if the attribute was not found.
 147
 148 See also `xml-get-attribute-or-nil'."
 149   (or (xml-get-attribute-or-nil node attribute) ""))
 150
 151 ;;*******************************************************************
 152 ;;**
 153 ;;**  Creating the list
 154 ;;**
 155 ;;*******************************************************************
 156
 157 ;;;###autoload
 158 (defun xml-parse-file (file &optional parse-dtd parse-ns)
 159   "Parse the well-formed XML file FILE.
 160 If FILE is already visited, use its buffer and don't kill it.
 161 Returns the top node with all its children.
 162 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped.
 163 If PARSE-NS is non-nil, then QNAMES are expanded."
 164   (let ((keep))
 165     (if (get-file-buffer file)
 166         (progn
 167           (set-buffer (get-file-buffer file))
 168           (setq keep (point)))
 169       (let (auto-mode-alist)            ; no need for xml-mode
 170         (find-file file)))
 171
 172     (let ((xml (xml-parse-region (point-min)
 173                                  (point-max)
 174                                  (current-buffer)
 175                                  parse-dtd parse-ns)))
 176       (if keep
 177           (goto-char keep)
 178         (kill-buffer (current-buffer)))
 179       xml)))
 180
 181
 182 (let* ((start-chars (concat ":[:alpha:]_"))
 183        (name-chars  (concat "-[:digit:]." start-chars))
 184 ;;[3]           S          ::=          (#x20 | #x9 | #xD | #xA)+
 185        (whitespace  "[ \t\n\r]"))
 186 ;;[4] NameStartChar ::= ":" | [A-Z] | "_" | [a-z] | [#xC0-#xD6]
 187 ;;                      | [#xD8-#xF6] | [#xF8-#x2FF] | [#x370-#x37D] | [#x37F-#x1FFF]
 188 ;;                      | [#x200C-#x200D] | [#x2070-#x218F] | [#x2C00-#x2FEF] | [#x3001-#xD7FF]
 189 ;;                      | [#xF900-#xFDCF] | [#xFDF0-#xFFFD] | [#x10000-#xEFFFF]
 190   (defvar xml-name-start-char-re (concat "[" start-chars "]"))
 191 ;;[4a] NameChar ::= NameStartChar | "-" | "." | [0-9] | #xB7 | [#x0300-#x036F] | [#x203F-#x2040]
 192   (defvar xml-name-char-re       (concat "[" name-chars  "]"))
 193 ;;[5] Name     ::= NameStartChar (NameChar)*
 194   (defvar xml-name-re            (concat xml-name-start-char-re xml-name-char-re "*"))
 195 ;;[6] Names    ::= Name (#x20 Name)*
 196   (defvar xml-names-re           (concat xml-name-re "\\(?: " xml-name-re "\\)*"))
 197 ;;[7] Nmtoken ::= (NameChar)+
 198   (defvar xml-nmtoken-re         (concat xml-name-char-re "+"))
 199 ;;[8] Nmtokens ::= Nmtoken (#x20 Nmtoken)*
 200   (defvar xml-nmtokens-re        (concat xml-nmtoken-re "\\(?: " xml-name-re "\\)*"))
 201 ;;[66] CharRef ::= '&#' [0-9]+ ';' | '&#x' [0-9a-fA-F]+ ';'
 202   (defvar xml-char-ref-re        "\\(?:&#[0-9]+;\\|&#x[0-9a-fA-F]+;\\)")
 203 ;;[68] EntityRef   ::= '&' Name ';'
 204   (defvar xml-entity-ref         (concat "&" xml-name-re ";"))
 205 ;;[69] PEReference ::= '%' Name ';'
 206   (defvar xml-pe-reference-re    (concat "%" xml-name-re ";"))
 207 ;;[67] Reference   ::= EntityRef | CharRef
 208   (defvar xml-reference-re       (concat "\\(?:" xml-entity-ref "\\|" xml-char-ref-re "\\)"))
 209 ;;[9] EntityValue ::= '"' ([^%&"] | PEReference | Reference)* '"'
 210 ;;                 |  "'" ([^%&'] | PEReference | Reference)* "'"
 211   (defvar xml-entity-value-re    (concat "\\(?:\"\\(?:[^%&\"]\\|" xml-pe-reference-re
 212                                          "\\|" xml-reference-re "\\)*\"\\|'\\(?:[^%&']\\|"
 213                                          xml-pe-reference-re "\\|" xml-reference-re "\\)*'\\)")))
 214 ;;[75] ExternalID ::= 'SYSTEM' S SystemLiteral
 215 ;;                 | 'PUBLIC' S PubidLiteral S SystemLiteral
 216 ;;[76] NDataDecl ::=    S 'NDATA' S
 217 ;;[73] EntityDef  ::= EntityValue| (ExternalID NDataDecl?)
 218 ;;[71] GEDecl     ::= '<!ENTITY' S Name S EntityDef S? '>'
 219 ;;[74] PEDef      ::= EntityValue | ExternalID
 220 ;;[72] PEDecl     ::= '<!ENTITY' S '%' S Name S PEDef S? '>'
 221 ;;[70] EntityDecl ::= GEDecl | PEDecl
 222
 223 ;; Note that this is setup so that we can do whitespace-skipping with
 224 ;; `(skip-syntax-forward " ")', inter alia.  Previously this was slow
 225 ;; compared with `re-search-forward', but that has been fixed.  Also
 226 ;; note that the standard syntax table contains other characters with
 227 ;; whitespace syntax, like NBSP, but they are invalid in contexts in
 228 ;; which we might skip whitespace -- specifically, they're not
 229 ;; NameChars [XML 4].
 230
 231 (defvar xml-syntax-table
 232   (let ((table (make-syntax-table)))
 233     ;; Get space syntax correct per XML [3].
 234     (dotimes (c 31)
 235       (modify-syntax-entry c "." table)) ; all are space in standard table
 236     (dolist (c '(?\t ?\n ?\r))          ; these should be space
 237       (modify-syntax-entry c " " table))
 238     ;; For skipping attributes.
 239     (modify-syntax-entry ?\" "\"" table)
 240     (modify-syntax-entry ?' "\"" table)
 241     ;; Non-alnum name chars should be symbol constituents (`-' and `_'
 242     ;; are OK by default).
 243     (modify-syntax-entry ?. "_" table)
 244     (modify-syntax-entry ?: "_" table)
 245     ;; XML [89]
 246     (dolist (c '(#x00B7 #x02D0 #x02D1 #x0387 #x0640 #x0E46 #x0EC6 #x3005
 247                  #x3031 #x3032 #x3033 #x3034 #x3035 #x309D #x309E #x30FC
 248                  #x30FD #x30FE))
 249       (modify-syntax-entry (decode-char 'ucs c) "w" table))
 250     ;; Fixme: rest of [4]
 251     table)
 252   "Syntax table used by `xml-parse-region'.")
 253
 254 ;; XML [5]
 255 ;; Note that [:alpha:] matches all multibyte chars with word syntax.
 256 (eval-and-compile
 257   (defconst xml-name-regexp "[[:alpha:]_:][[:alnum:]._:-]*"))
 258
 259 ;; Fixme:  This needs re-writing to deal with the XML grammar properly, i.e.
 260 ;;   document    ::=    prolog element Misc*
 261 ;;   prolog    ::=    XMLDecl? Misc* (doctypedecl Misc*)?
 262
 263 ;;;###autoload
 264 (defun xml-parse-region (beg end &optional buffer parse-dtd parse-ns)
 265   "Parse the region from BEG to END in BUFFER.
 266 If BUFFER is nil, it defaults to the current buffer.
 267 Returns the XML list for the region, or raises an error if the region
 268 is not well-formed XML.
 269 If PARSE-DTD is non-nil, the DTD is parsed rather than skipped,
 270 and returned as the first element of the list.
 271 If PARSE-NS is non-nil, then QNAMES are expanded."
 272   (save-restriction
 273     (narrow-to-region beg end)
 274     ;; Use fixed syntax table to ensure regexp char classes and syntax
 275     ;; specs DTRT.
 276     (with-syntax-table (standard-syntax-table)
 277       (let ((case-fold-search nil)      ; XML is case-sensitive.
 278             xml result dtd)
 279         (save-excursion
 280           (if buffer
 281               (set-buffer buffer))
 282           (goto-char (point-min))
 283           (while (not (eobp))
 284             (if (search-forward "<" nil t)
 285                 (progn
 286                   (forward-char -1)
 287                   (setq result (xml-parse-tag parse-dtd parse-ns))
 288                   (if (and xml result (not xml-sub-parser))
 289                       ;;  translation of rule [1] of XML specifications
 290                       (error "XML: (Not Well-Formed) Only one root tag allowed")
 291                     (cond
 292                      ((null result))
 293                      ((and (listp (car result))
 294                            parse-dtd)
 295                       (setq dtd (car result))
 296                       (if (cdr result)  ; possible leading comment
 297                           (add-to-list 'xml (cdr result))))
 298                      (t
 299                       (add-to-list 'xml result)))))
 300               (goto-char (point-max))))
 301           (if parse-dtd
 302               (cons dtd (nreverse xml))
 303             (nreverse xml)))))))
 304
 305 (defun xml-maybe-do-ns (name default xml-ns)
 306   "Perform any namespace expansion.
 307 NAME is the name to perform the expansion on.
 308 DEFAULT is the default namespace.  XML-NS is a cons of namespace
 309 names to uris.  When namespace-aware parsing is off, then XML-NS
 310 is nil.
 311
 312 During namespace-aware parsing, any name without a namespace is
 313 put into the namespace identified by DEFAULT.  nil is used to
 314 specify that the name shouldn't be given a namespace."
 315   (if (consp xml-ns)
 316       (let* ((nsp (string-match ":" name))
 317              (lname (if nsp (substring name (match-end 0)) name))
 318              (prefix (if nsp (substring name 0 (match-beginning 0)) default))
 319              (special (and (string-equal lname "xmlns") (not prefix)))
 320              ;; Setting default to nil will insure that there is not
 321              ;; matching cons in xml-ns.  In which case we
 322              (ns (or (cdr (assoc (if special "xmlns" prefix)
 323                                  xml-ns))
 324                      "")))
 325         (cons ns (if special "" lname)))
 326     (intern name)))
 327
 328 (defun xml-parse-fragment (&optional parse-dtd parse-ns)
 329   "Parse xml-like fragments."
 330   (let ((xml-sub-parser t)
 331         children)
 332     (while (not (eobp))
 333       (let ((bit (xml-parse-tag
 334                   parse-dtd parse-ns)))
 335         (if children
 336             (setq children (append (list bit) children))
 337           (if (stringp bit)
 338               (setq children (list bit))
 339             (setq children bit)))))
 340     (reverse children)))
 341
 342 (defun xml-parse-tag (&optional parse-dtd parse-ns)
 343   "Parse the tag at point.
 344 If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
 345 returned as the first element in the list.
 346 If PARSE-NS is non-nil, then QNAMES are expanded.
 347 Returns one of:
 348  - a list : the matching node
 349  - nil    : the point is not looking at a tag.
 350  - a pair : the first element is the DTD, the second is the node."
 351   (let ((xml-validating-parser (or parse-dtd xml-validating-parser))
 352         (xml-ns (if (consp parse-ns)
 353                     parse-ns
 354                   (if parse-ns
 355                       (list
 356                        ;; Default for empty prefix is no namespace
 357                        (cons ""      "")
 358                        ;; "xml" namespace
 359                        (cons "xml"   "http://www.w3.org/XML/1998/namespace")
 360                        ;; We need to seed the xmlns namespace
 361                        (cons "xmlns" "http://www.w3.org/2000/xmlns/"))))))
 362     (cond
 363      ;; Processing instructions (like the <?xml version="1.0"?> tag at the
 364      ;; beginning of a document).
 365      ((looking-at "<\\?")
 366       (search-forward "?>")
 367       (skip-syntax-forward " ")
 368       (xml-parse-tag parse-dtd xml-ns))
 369      ;;  Character data (CDATA) sections, in which no tag should be interpreted
 370      ((looking-at "<!\\[CDATA\\[")
 371       (let ((pos (match-end 0)))
 372         (unless (search-forward "]]>" nil t)
 373           (error "XML: (Not Well Formed) CDATA section does not end anywhere in the document"))
 374         (buffer-substring pos (match-beginning 0))))
 375      ;;  DTD for the document
 376      ((looking-at "<!DOCTYPE")
 377       (let ((dtd (xml-parse-dtd parse-ns)))
 378         (skip-syntax-forward " ")
 379         (if xml-validating-parser
 380             (cons dtd (xml-parse-tag nil xml-ns))
 381           (xml-parse-tag nil xml-ns))))
 382      ;;  skip comments
 383      ((looking-at "<!--")
 384       (search-forward "-->")
 385       nil)
 386      ;;  end tag
 387      ((looking-at "</")
 388       '())
 389      ;;  opening tag
 390      ((looking-at "<\\([^/>[:space:]]+\\)")
 391       (goto-char (match-end 1))
 392
 393       ;; Parse this node
 394       (let* ((node-name (match-string 1))
 395              ;; Parse the attribute list.
 396              (attrs (xml-parse-attlist xml-ns))
 397              children pos)
 398
 399         ;; add the xmlns:* attrs to our cache
 400         (when (consp xml-ns)
 401           (dolist (attr attrs)
 402             (when (and (consp (car attr))
 403                        (equal "http://www.w3.org/2000/xmlns/"
 404                               (caar attr)))
 405               (push (cons (cdar attr) (cdr attr))
 406                     xml-ns))))
 407
 408         (setq children (list attrs (xml-maybe-do-ns node-name "" xml-ns)))
 409
 410         ;; is this an empty element ?
 411         (if (looking-at "/>")
 412             (progn
 413               (forward-char 2)
 414               (nreverse children))
 415
 416           ;; is this a valid start tag ?
 417           (if (eq (char-after) ?>)
 418               (progn
 419                 (forward-char 1)
 420                 ;;  Now check that we have the right end-tag. Note that this
 421                 ;;  one might contain spaces after the tag name
 422                 (let ((end (concat "</" node-name "\\s-*>")))
 423                   (while (not (looking-at end))
 424                     (cond
 425                      ((looking-at "</")
 426                       (error "XML: (Not Well-Formed) Invalid end tag (expecting %s) at pos %d"
 427                              node-name (point)))
 428                      ((= (char-after) ?<)
 429                       (let ((tag (xml-parse-tag nil xml-ns)))
 430                         (when tag
 431                           (push tag children))))
 432                      (t
 433                       (let ((expansion (xml-parse-string)))
 434                         (setq children
 435                               (if (stringp expansion)
 436                                   (if (stringp (car children))
 437                                       ;; The two strings were separated by a comment.
 438                                       (setq children (append (concat (car children) expansion)
 439                                                              (cdr children)))
 440                                     (setq children (append (list expansion) children)))
 441                                 (setq children (append expansion children))))))))
 442
 443                   (goto-char (match-end 0))
 444                   (nreverse children)))
 445             ;;  This was an invalid start tag (Expected ">", but didn't see it.)
 446             (error "XML: (Well-Formed) Couldn't parse tag: %s"
 447                    (buffer-substring (- (point) 10) (+ (point) 1)))))))
 448      (t ;; (Not one of PI, CDATA, Comment, End tag, or Start tag)
 449       (unless xml-sub-parser            ; Usually, we error out.
 450         (error "XML: (Well-Formed) Invalid character"))
 451
 452       ;; However, if we're parsing incrementally, then we need to deal
 453       ;; with stray CDATA.
 454       (xml-parse-string)))))
 455
 456 (defun xml-parse-string ()
 457   "Parse the next whatever.  Could be a string, or an element."
 458     (let* ((pos (point))
 459            (string (progn (if (search-forward "<" nil t)
 460                               (forward-char -1)
 461                             (goto-char (point-max)))
 462                           (buffer-substring pos (point)))))
 463       ;; Clean up the string.  As per XML specifications, the XML
 464       ;; processor should always pass the whole string to the
 465       ;; application.  But \r's should be replaced:
 466       ;; http://www.w3.org/TR/2000/REC-xml-20001006#sec-line-ends
 467       (setq pos 0)
 468       (while (string-match "\r\n?" string pos)
 469         (setq string (replace-match "\n" t t string))
 470         (setq pos (1+ (match-beginning 0))))
 471
 472       (xml-substitute-special string)))
 473
 474 (defun xml-parse-attlist (&optional xml-ns)
 475   "Return the attribute-list after point.
 476 Leave point at the first non-blank character after the tag."
 477   (let ((attlist ())
 478         end-pos name)
 479     (skip-syntax-forward " ")
 480     (while (looking-at (eval-when-compile
 481                          (concat "\\(" xml-name-regexp "\\)\\s-*=\\s-*")))
 482       (setq end-pos (match-end 0))
 483       (setq name (xml-maybe-do-ns (match-string 1) nil xml-ns))
 484       (goto-char end-pos)
 485
 486       ;; See also: http://www.w3.org/TR/2000/REC-xml-20001006#AVNormalize
 487
 488       ;; Do we have a string between quotes (or double-quotes),
 489       ;;  or a simple word ?
 490       (if (looking-at "\"\\([^\"]*\\)\"")
 491           (setq end-pos (match-end 0))
 492         (if (looking-at "'\\([^']*\\)'")
 493             (setq end-pos (match-end 0))
 494           (error "XML: (Not Well-Formed) Attribute values must be given between quotes")))
 495
 496       ;; Each attribute must be unique within a given element
 497       (if (assoc name attlist)
 498           (error "XML: (Not Well-Formed) Each attribute must be unique within an element"))
 499
 500       ;; Multiple whitespace characters should be replaced with a single one
 501       ;; in the attributes
 502       (let ((string (match-string 1))
 503             (pos 0))
 504         (replace-regexp-in-string "\\s-\\{2,\\}" " " string)
 505         (let ((expansion (xml-substitute-special string)))
 506           (unless (stringp expansion)
 507             ; We say this is the constraint.  It is acctually that
 508             ; external entities nor "<" can be in an attribute value.
 509             (error "XML: (Not Well-Formed) Entities in attributes cannot expand into elements"))
 510           (push (cons name expansion) attlist)))
 511
 512       (goto-char end-pos)
 513       (skip-syntax-forward " "))
 514     (nreverse attlist)))
 515
 516 ;;*******************************************************************
 517 ;;**
 518 ;;**  The DTD (document type declaration)
 519 ;;**  The following functions know how to skip or parse the DTD of
 520 ;;**  a document
 521 ;;**
 522 ;;*******************************************************************
 523
 524 ;; Fixme: This fails at least if the DTD contains conditional sections.
 525
 526 (defun xml-skip-dtd ()
 527   "Skip the DTD at point.
 528 This follows the rule [28] in the XML specifications."
 529   (let ((xml-validating-parser nil))
 530     (xml-parse-dtd)))
 531
 532 (defun xml-parse-dtd (&optional parse-ns)
 533   "Parse the DTD at point."
 534   (forward-char (eval-when-compile (length "<!DOCTYPE")))
 535   (skip-syntax-forward " ")
 536   (if (and (looking-at ">")
 537            xml-validating-parser)
 538       (error "XML: (Validity) Invalid DTD (expecting name of the document)"))
 539
 540   ;;  Get the name of the document
 541   (looking-at xml-name-regexp)
 542   (let ((dtd (list (match-string 0) 'dtd))
 543         type element end-pos)
 544     (goto-char (match-end 0))
 545
 546     (skip-syntax-forward " ")
 547     ;; XML [75]
 548     (cond ((looking-at "PUBLIC\\s-+")
 549            (goto-char (match-end 0))
 550            (unless (or (re-search-forward
 551                         "\\=\"\\([[:space:][:alnum:]-'()+,./:=?;!*#@$_%]*\\)\""
 552                         nil t)
 553                        (re-search-forward
 554                         "\\='\\([[:space:][:alnum:]-()+,./:=?;!*#@$_%]*\\)'"
 555                         nil t))
 556              (error "XML: Missing Public ID"))
 557            (let ((pubid (match-string 1)))
 558              (skip-syntax-forward " ")
 559              (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 560                          (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 561                (error "XML: Missing System ID"))
 562              (push (list pubid (match-string 1) 'public) dtd)))
 563           ((looking-at "SYSTEM\\s-+")
 564            (goto-char (match-end 0))
 565            (unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
 566                        (re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
 567              (error "XML: Missing System ID"))
 568            (push (list (match-string 1) 'system) dtd)))
 569     (skip-syntax-forward " ")
 570     (if (eq ?> (char-after))
 571         (forward-char)
 572       (if (not (eq (char-after) ?\[))
 573           (error "XML: Bad DTD")
 574         (forward-char)
 575         ;;  Parse the rest of the DTD
 576         ;;  Fixme: Deal with ATTLIST, NOTATION, PIs.
 577         (while (not (looking-at "\\s-*\\]"))
 578           (skip-syntax-forward " ")
 579           (cond
 580
 581            ;;  Translation of rule [45] of XML specifications
 582            ((looking-at
 583              "<!ELEMENT\\s-+\\([[:alnum:].%;]+\\)\\s-+\\([^>]+\\)>")
 584
 585             (setq element (match-string 1)
 586                   type    (match-string-no-properties 2))
 587             (setq end-pos (match-end 0))
 588
 589             ;;  Translation of rule [46] of XML specifications
 590             (cond
 591              ((string-match "^EMPTY[ \t\n\r]*$" type) ;; empty declaration
 592               (setq type 'empty))
 593              ((string-match "^ANY[ \t\n\r]*$" type) ;; any type of contents
 594               (setq type 'any))
 595              ((string-match "^(\\(.*\\))[ \t\n\r]*$" type) ;; children ([47])
 596               (setq type (xml-parse-elem-type (match-string 1 type))))
 597              ((string-match "^%[^;]+;[ \t\n\r]*$" type) ;; substitution
 598               nil)
 599              (t
 600               (if xml-validating-parser
 601                   (error "XML: (Validity) Invalid element type in the DTD"))))
 602
 603             ;;  rule [45]: the element declaration must be unique
 604             (if (and (assoc element dtd)
 605                      xml-validating-parser)
 606                 (error "XML: (Validity) Element declarations must be unique in a DTD (<%s>)"
 607                        element))
 608
 609             ;;  Store the element in the DTD
 610             (push (list element type) dtd)
 611             (goto-char end-pos))
 612            ((looking-at "<!--")
 613             (search-forward "-->"))
 614            ((looking-at (concat "<!ENTITY[ \t\n\r]*\\(" xml-name-re
 615                                 "\\)[ \t\n\r]*\\(" xml-entity-value-re
 616                                 "\\)[ \t\n\r]*>"))
 617             (let ((name  (buffer-substring (nth 2 (match-data))
 618                                            (nth 3 (match-data))))
 619                   (value (buffer-substring (+ (nth 4 (match-data)) 1)
 620                                            (- (nth 5 (match-data)) 1))))
 621               (goto-char (nth 1 (match-data)))
 622               (setq xml-entity-alist
 623                     (append xml-entity-alist
 624                             (list (cons name
 625                                         (with-temp-buffer
 626                                           (insert value)
 627                                           (goto-char (point-min))
 628                                           (xml-parse-fragment
 629                                            xml-validating-parser
 630                                            parse-ns))))))))
 631            ((or (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 632                                     "\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
 633                                     "\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
 634                 (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
 635                                     "\\)[ \t\n\r]+PUBLIC[ \t\n\r]+"
 636                                     "\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
 637                                     "\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'"
 638                                     "[ \t\n\r]+\\(\"[^\"]*\"\\|'[^']*'\\)"
 639                                     "[ \t\n\r]*>")))
 640             (let ((name  (buffer-substring (nth 2 (match-data))
 641                                            (nth 3 (match-data))))
 642                   (file  (buffer-substring (+ (nth 4 (match-data)) 1)
 643                                            (- (nth 5 (match-data)) 1))))
 644               (goto-char (nth 1 (match-data)))
 645               (setq xml-entity-alist
 646                     (append xml-entity-alist
 647                             (list (cons name (with-temp-buffer
 648                                                (insert-file-contents file)
 649                                                (goto-char (point-min))
 650                                                (xml-parse-fragment
 651                                                 xml-validating-parser
 652                                                 parse-ns))))))))
 653            (t
 654             (error "XML: (Validity) Invalid DTD item")))))
 655       (if (looking-at "\\s-*]>")
 656           (goto-char (nth 1 (match-data)))))
 657     (nreverse dtd)))
 658
 659 (defun xml-parse-elem-type (string)
 660   "Convert element type STRING into a Lisp structure."
 661
 662   (let (elem modifier)
 663     (if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
 664         (progn
 665           (setq elem     (match-string 1 string)
 666                 modifier (match-string 2 string))
 667           (if (string-match "|" elem)
 668               (setq elem (cons 'choice
 669                                (mapcar 'xml-parse-elem-type
 670                                        (split-string elem "|"))))
 671             (if (string-match "," elem)
 672                 (setq elem (cons 'seq
 673                                  (mapcar 'xml-parse-elem-type
 674                                          (split-string elem ",")))))))
 675       (if (string-match "[ \t\n\r]*\\([^+*?]+\\)\\([+*?]?\\)" string)
 676           (setq elem     (match-string 1 string)
 677                 modifier (match-string 2 string))))
 678
 679     (if (and (stringp elem) (string= elem "#PCDATA"))
 680         (setq elem 'pcdata))
 681
 682     (cond
 683      ((string= modifier "+")
 684       (list '+ elem))
 685      ((string= modifier "*")
 686       (list '* elem))
 687      ((string= modifier "?")
 688       (list '\? elem))
 689      (t
 690       elem))))
 691
 692 ;;*******************************************************************
 693 ;;**
 694 ;;**  Substituting special XML sequences
 695 ;;**
 696 ;;*******************************************************************
 697
 698 (defun xml-substitute-special (string)
 699   "Return STRING, after subsituting entity references."
 700   ;; This originally made repeated passes through the string from the
 701   ;; beginning, which isn't correct, since then either "&amp;amp;" or
 702   ;; "&#38;amp;" won't DTRT.
 703
 704   (let ((point 0)
 705         children end-point)
 706     (while (string-match "&\\([^;]+\\);" string point)
 707       (setq end-point (match-end 0))
 708       (let* ((this-part (match-string 1 string))
 709              (prev-part (substring string point (match-beginning 0)))
 710              (entity (assoc this-part xml-entity-alist))
 711              (expansion
 712               (cond ((string-match "#\\([0-9]+\\)" this-part)
 713                      (let ((c (decode-char
 714                                'ucs
 715                                (string-to-number (match-string 1 this-part)))))
 716                        (if c (string c))))
 717                     ((string-match "#x\\([[:xdigit:]]+\\)" this-part)
 718                      (let ((c (decode-char
 719                                'ucs
 720                                (string-to-number (match-string 1 this-part) 16))))
 721                        (if c (string c))))
 722                     (entity
 723                      (cdr entity))
 724                     (t
 725                      (if xml-validating-parser
 726                          (error "XML: (Validity) Undefined entity `%s'"
 727                                 (match-string 1 this-part)))))))
 728
 729         (cond ((null children)
 730                ;; FIXME: If we have an entity that expands into XML, this won't work.
 731                (setq children
 732                      (concat prev-part expansion)))
 733               ((stringp children)
 734                (if (stringp expansion)
 735                    (setq children (concat children prev-part expansion))
 736                  (setq children (list expansion (concat prev-part children)))))
 737               ((and (stringp expansion)
 738                     (stringp (car children)))
 739                (setcar children (concat prev-part expansion (car children))))
 740               ((stringp expansion)
 741                (setq children (append (concat prev-part expansion)
 742                                       children)))
 743               ((stringp (car children))
 744                (setcar children (concat (car children) prev-part))
 745                (setq children (append expansion children)))
 746               (t
 747                (setq children (list expansion
 748                                     prev-part
 749                                     children))))
 750         (setq point end-point)))
 751     (cond ((stringp children)
 752            (concat children (substring string point)))
 753           ((stringp (car (last children)))
 754            (concat (car (last children)) (substring string point)))
 755           ((null children)
 756            string)
 757           (t
 758            (concat (mapconcat 'identity
 759                               (nreverse children)
 760                               "")
 761                    (substring string point))))))
 762
 763 ;;*******************************************************************
 764 ;;**
 765 ;;**  Printing a tree.
 766 ;;**  This function is intended mainly for debugging purposes.
 767 ;;**
 768 ;;*******************************************************************
 769
 770 (defun xml-debug-print (xml &optional indent-string)
 771   "Outputs the XML in the current buffer.
 772 XML can be a tree or a list of nodes.
 773 The first line is indented with the optional INDENT-STRING."
 774   (setq indent-string (or indent-string ""))
 775   (dolist (node xml)
 776     (xml-debug-print-internal node indent-string)))
 777
 778 (defalias 'xml-print 'xml-debug-print)
 779
 780 (defun xml-debug-print-internal (xml indent-string)
 781   "Outputs the XML tree in the current buffer.
 782 The first line is indented with INDENT-STRING."
 783   (let ((tree xml)
 784         attlist)
 785     (insert indent-string ?< (symbol-name (xml-node-name tree)))
 786
 787     ;;  output the attribute list
 788     (setq attlist (xml-node-attributes tree))
 789     (while attlist
 790       (insert ?\  (symbol-name (caar attlist)) "=\"" (cdar attlist) ?\")
 791       (setq attlist (cdr attlist)))
 792
 793     (setq tree (xml-node-children tree))
 794
 795     (if (null tree)
 796         (insert ?/ ?>)
 797       (insert ?>)
 798
 799       ;;  output the children
 800       (dolist (node tree)
 801         (cond
 802          ((listp node)
 803           (insert ?\n)
 804           (xml-debug-print-internal node (concat indent-string "  ")))
 805          ((stringp node) (insert node))
 806          (t
 807           (error "Invalid XML tree"))))
 808
 809       (when (not (and (null (cdr tree))
 810                       (stringp (car tree))))
 811         (insert ?\n indent-string))
 812       (insert ?< ?/ (symbol-name (xml-node-name xml)) ?>))))
 813
 814 (provide 'xml)
 815
 816 ;; arch-tag: 5864b283-5a68-4b59-a20d-36a72b353b9b
 817 ;;; xml.el ends here