]> code.delx.au - gnu-emacs/blob - configure.in
delx.au / code / gnu-emacs / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
*** empty log message ***
[gnu-emacs] / configure.in
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999 Free Software Foundation, Inc.
7 dnl
8 dnl This file is part of GNU Emacs.
9 dnl
10 dnl GNU Emacs is free software; you can redistribute it and/or modify
11 dnl it under the terms of the GNU General Public License as published by
12 dnl the Free Software Foundation; either version 2, or (at your option)
13 dnl any later version.
14 dnl
15 dnl GNU Emacs is distributed in the hope that it will be useful,
16 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 dnl GNU General Public License for more details.
19 dnl
20 dnl You should have received a copy of the GNU General Public License
21 dnl along with GNU Emacs; see the file COPYING. If not, write to the
22 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
23 dnl Boston, MA 02111-1307, USA.
24
25 AC_PREREQ(2.8)dnl
26 AC_INIT(src/lisp.h)
27 AC_CONFIG_HEADER(src/config.h:src/config.in)
28
29 lispdir='${datadir}/emacs/${version}/lisp'
30 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
31 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
32 lisppath='${locallisppath}:${lispdir}'
33 etcdir='${datadir}/emacs/${version}/etc'
34 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
35 docdir='${datadir}/emacs/${version}/etc'
36
37 AC_ARG_WITH(gcc,
38 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
39 AC_ARG_WITH(pop,
40 [ --without-pop don't support POP mail retrieval with movemail],
41 [if test "$withval" = yes; then
42 AC_DEFINE(MAIL_USE_POP)
43 else :
44 fi],
45 AC_DEFINE(MAIL_USE_POP))
46 AC_ARG_WITH(kerberos,
47 [ --with-kerberos support Kerberos-authenticated POP],
48 [AC_DEFINE(KERBEROS)])
49 AC_ARG_WITH(kerberos5,
50 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
51 [if test "${with_kerberos5+set}" = set; then
52 if test "${with_kerberos+set}" != set; then
53 with_kerberos=yes
54 AC_DEFINE(KERBEROS)
55 fi
56 fi
57 AC_DEFINE(KERBEROS5)])
58 AC_ARG_WITH(hesiod,
59 [ --with-hesiod support Hesiod to get the POP server host],
60 [AC_DEFINE(HESIOD)])
61 dnl This should be the last --with option, because --with-x is
62 dnl added later on when we find the path of X, and it's best to
63 dnl keep them together visually.
64 AC_ARG_WITH(x-toolkit,
65 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif/no)],
66 [ case "${withval}" in
67 y | ye | yes ) val=athena ;;
68 n | no ) val=no ;;
69 l | lu | luc | luci | lucid ) val=lucid ;;
70 a | at | ath | athe | athen | athena ) val=athena ;;
71 m | mo | mot | moti | motif ) val=motif ;;
72 dnl These don't currently work.
73 dnl o | op | ope | open | open- | open-l | open-lo \
74 dnl | open-loo | open-look ) val=open-look ;;
75 * )
76 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
77 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
78 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
79 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
80 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
81 ;;
82 esac
83 with_x_toolkit=$val
84 ])
85 AC_ARG_WITH(xpm,
86 [ --with-xpm use -lXpm for displaying XPM images])
87 AC_ARG_WITH(jpeg,
88 [ --with-jpeg use -ljpeg for displaying JPEG images])
89 AC_ARG_WITH(tiff,
90 [ --with-tiff use -ltiff for displaying TIFF images])
91 AC_ARG_WITH(gif,
92 [ --with-gif use -lungif for displaying GIF images])
93 AC_ARG_WITH(png,
94 [ --with-png use -lpng for displaying PNG images])
95 AC_ARG_WITH(toolkit-scroll-bars,
96 [ --without-toolkit-scroll-bars don't use Motif or Xaw3d scroll bars])
97
98 #### Make srcdir absolute, if it isn't already. It's important to
99 #### avoid running the path through pwd unnecessary, since pwd can
100 #### give you automounter prefixes, which can go away. We do all this
101 #### so Emacs can find its files when run uninstalled.
102 case "${srcdir}" in
103 /* ) ;;
104 . )
105 ## We may be able to use the $PWD environment variable to make this
106 ## absolute. But sometimes PWD is inaccurate.
107 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
108 unset CDPATH
109 if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`" ;
110 then
111 srcdir="$PWD"
112 else
113 srcdir="`(cd ${srcdir}; pwd)`"
114 fi
115 ;;
116 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
117 esac
118
119 #### Check if the source directory already has a configured system in it.
120 if test `pwd` != `(cd ${srcdir} && pwd)` \
121 && test -f "${srcdir}/src/config.h" ; then
122 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
123 as a build directory right now; it has been configured in its own
124 right. To configure in another directory as well, you MUST
125 use GNU make. If you do not have GNU make, then you must
126 now do \`make distclean' in ${srcdir},
127 and then run $0 again.])
128
129 changequote(, )dnl
130 extrasub='/^VPATH[ ]*=/c\
131 changequote([, ])dnl
132 vpath %.c $(srcdir)\
133 vpath %.h $(srcdir)\
134 vpath %.y $(srcdir)\
135 vpath %.l $(srcdir)\
136 vpath %.s $(srcdir)\
137 vpath %.in $(srcdir)\
138 vpath %.texi $(srcdir)'
139 fi
140
141 #### Given the configuration name, set machfile and opsysfile to the
142 #### names of the m/*.h and s/*.h files we should use.
143
144 ### Canonicalize the configuration name.
145
146 AC_CANONICAL_HOST
147 canonical=$host
148 configuration=$host_alias
149
150 changequote(, )dnl
151
152 ### If you add support for a new configuration, add code to this
153 ### switch statement to recognize your configuration name and select
154 ### the appropriate operating system and machine description files.
155
156 ### You would hope that you could choose an m/*.h file pretty much
157 ### based on the machine portion of the configuration name, and an s-
158 ### file based on the operating system portion. However, it turns out
159 ### that each m/*.h file is pretty manufacturer-specific - for
160 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
161 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
162 ### machines. So we basically have to have a special case for each
163 ### configuration name.
164 ###
165 ### As far as handling version numbers on operating systems is
166 ### concerned, make sure things will fail in a fixable way. If
167 ### /etc/MACHINES doesn't say anything about version numbers, be
168 ### prepared to handle anything reasonably. If version numbers
169 ### matter, be sure /etc/MACHINES says something about it.
170 ###
171 ### Eric Raymond says we should accept strings like "sysvr4" to mean
172 ### "System V Release 4"; he writes, "The old convention encouraged
173 ### confusion between `system' and `release' levels'."
174
175 machine='' opsys='' unported=no
176 case "${canonical}" in
177
178 ## NetBSD ports
179 *-*-netbsd* )
180 opsys=netbsd
181 case "${canonical}" in
182 alpha*-*-netbsd*) machine=alpha ;;
183 i[3456]86-*-netbsd*) machine=intel386 ;;
184 m68k-*-netbsd*)
185 # This is somewhat bogus.
186 machine=hp9000s300 ;;
187 powerpc-apple-netbsd*) machine=macppc ;;
188 mips-*-netbsd*) machine=pmax ;;
189 ns32k-*-netbsd*) machine=ns32000 ;;
190 sparc-*-netbsd*) machine=sparc ;;
191 vax-*-netbsd*) machine=vax ;;
192 esac
193 ;;
194
195 ## OpenBSD ports
196 *-*-openbsd* )
197 opsys=openbsd
198 case "${canonical}" in
199 alpha*-*-openbsd*) machine=alpha ;;
200 i386-*-openbsd*) machine=intel386 ;;
201 m68k-*-openbsd*) machine=hp9000s300 ;;
202 mipsel-*-openbsd*) machine=pmax ;;
203 ns32k-*-openbsd*) machine=ns32000 ;;
204 sparc-*-openbsd*) machine=sparc ;;
205 vax-*-openbsd*) machine=vax ;;
206 esac
207 ;;
208
209 ## Acorn RISCiX:
210 arm-acorn-riscix1.1* )
211 machine=acorn opsys=riscix1-1
212 ;;
213 arm-acorn-riscix1.2* | arm-acorn-riscix )
214 ## This name is riscix12 instead of riscix1.2
215 ## to avoid a file name conflict on MSDOS.
216 machine=acorn opsys=riscix12
217 ;;
218
219 ## BSDI ports
220 *-*-bsdi* )
221 opsys=bsdi
222 case "${canonical}" in
223 i[345]86-*-bsdi*) machine=intel386 ;;
224 sparc-*-bsdi*) machine=sparc ;;
225 powerpc-*-bsdi*) machine=powerpc ;;
226 esac
227 case "${canonical}" in
228 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
229 *-*-bsdi2.0* ) opsys=bsdos2 ;;
230 *-*-bsdi2* ) opsys=bsdos2-1 ;;
231 *-*-bsdi3* ) opsys=bsdos3 ;;
232 *-*-bsdi4* ) opsys=bsdos4 ;;
233 esac
234 ;;
235
236 ## Alliant machines
237 ## Strictly speaking, we need the version of the alliant operating
238 ## system to choose the right machine file, but currently the
239 ## configuration name doesn't tell us enough to choose the right
240 ## one; we need to give alliants their own operating system name to
241 ## do this right. When someone cares, they can help us.
242 fx80-alliant-* )
243 machine=alliant4 opsys=bsd4-2
244 ;;
245 i860-alliant-* )
246 machine=alliant-2800 opsys=bsd4-3
247 ;;
248
249 ## Alpha (DEC) machines.
250 alpha*-dec-osf* )
251 machine=alpha opsys=osf1
252 # This is needed to find X11R6.1 libraries for certain tests.
253 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
254 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
255 ;;
256
257 alpha*-*-linux-gnu* )
258 machine=alpha opsys=gnu-linux
259 ;;
260
261 arm*-*-linux-gnu* )
262 machine=arm opsys=gnu-linux
263 ;;
264
265 ppc-*-linux | \
266 powerpc-*-linux* )
267 machine=powerpc opsys=gnu-linux
268 ;;
269
270 ## Altos 3068
271 m68*-altos-sysv* )
272 machine=altos opsys=usg5-2
273 ;;
274
275 ## Amdahl UTS
276 580-amdahl-sysv* )
277 machine=amdahl opsys=usg5-2-2
278 ;;
279
280 ## Apollo, Domain/OS
281 m68*-apollo-* )
282 machine=apollo opsys=bsd4-3
283 ;;
284
285 ## AT&T 3b2, 3b5, 3b15, 3b20
286 we32k-att-sysv* )
287 machine=att3b opsys=usg5-2-2
288 ;;
289
290 ## AT&T 3b1 - The Mighty Unix PC!
291 m68*-att-sysv* )
292 machine=7300 opsys=usg5-2-2
293 ;;
294
295 ## Bull dpx20
296 rs6000-bull-bosx* )
297 machine=ibmrs6000 opsys=aix3-2
298 ;;
299
300 ## Bull dpx2
301 m68*-bull-sysv3* )
302 machine=dpx2 opsys=usg5-3
303 ;;
304
305 ## Bull sps7
306 m68*-bull-sysv2* )
307 machine=sps7 opsys=usg5-2
308 ;;
309
310 ## CCI 5/32, 6/32 -- see "Tahoe".
311
312 ## Celerity
313 ## I don't know what configuration name to use for this; config.sub
314 ## doesn't seem to know anything about it. Hey, Celerity users, get
315 ## in touch with us!
316 celerity-celerity-bsd* )
317 machine=celerity opsys=bsd4-2
318 ;;
319
320 ## Clipper
321 ## What operating systems does this chip run that Emacs has been
322 ## tested on?
323 clipper-* )
324 machine=clipper
325 ## We'll use the catch-all code at the bottom to guess the
326 ## operating system.
327 ;;
328
329 ## Convex
330 *-convex-bsd* | *-convex-convexos* )
331 machine=convex opsys=bsd4-3
332 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
333 NON_GNU_CPP="cc -E -P"
334 ;;
335
336 ## Cubix QBx/386
337 i[3456]86-cubix-sysv* )
338 machine=intel386 opsys=usg5-3
339 ;;
340
341 ## Cydra 5
342 cydra*-cydrome-sysv* )
343 machine=cydra5 opsys=usg5-3
344 ;;
345
346 ## Data General AViiON Machines
347 ## DG changed naming conventions with the release of 5.4.4.10, they
348 ## dropped the initial 5.4 but left the intervening R. Because of the
349 ## R this shouldn't conflict with older versions of the OS (which I
350 ## think were named like dgux4.*). In addition, DG new AViiONs series
351 ## uses either Motorola M88k or Intel Pentium CPUs.
352 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
353 machine=aviion opsys=dgux4
354 ;;
355 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
356 ## This name is dgux5-4-3 instead of dgux5-4r3
357 ## to avoid a file name conflict on MSDOS.
358 machine=aviion opsys=dgux5-4-3
359 ;;
360 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
361 machine=aviion opsys=dgux5-4r2
362 ;;
363 m88k-dg-dgux* )
364 machine=aviion opsys=dgux
365 ;;
366
367 ## Data General AViiON Intel (x86) Machines
368 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
369 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
370 i[345]86-dg-dguxR4* )
371 machine=aviion-intel opsys=dgux4
372 ;;
373
374 ## DECstations
375 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
376 machine=pmax opsys=bsd4-2
377 ;;
378 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
379 machine=pmax opsys=bsd4-3
380 ;;
381 mips-dec-ultrix* )
382 machine=pmax opsys=ultrix4-3
383 ;;
384 mips-dec-osf* )
385 machine=pmax opsys=osf1
386 ;;
387 mips-dec-mach_bsd4.3* )
388 machine=pmax opsys=mach-bsd4-3
389 ;;
390
391 ## Motorola Delta machines
392 m68k-motorola-sysv* | m68000-motorola-sysv* )
393 machine=delta opsys=usg5-3
394 if test -z "`type gnucc | grep 'not found'`"
395 then
396 if test -s /etc/167config
397 then CC="gnucc -m68040"
398 else CC="gnucc -m68881"
399 fi
400 else
401 if test -z "`type gcc | grep 'not found'`"
402 then CC=gcc
403 else CC=cc
404 fi
405 fi
406 ;;
407 m88k-motorola-sysv4* )
408 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
409 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
410 # I hope there are not other 4.0 versions for this machine
411 # which really need usg5-4 instead.
412 machine=delta88k opsys=usg5-4-2
413 ;;
414 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
415 machine=delta88k opsys=usg5-3
416 ;;
417
418 ## Dual machines
419 m68*-dual-sysv* )
420 machine=dual opsys=usg5-2
421 ;;
422 m68*-dual-uniplus* )
423 machine=dual opsys=unipl5-2
424 ;;
425
426 ## Elxsi 6400
427 elxsi-elxsi-sysv* )
428 machine=elxsi opsys=usg5-2
429 ;;
430
431 ## Encore machines
432 ns16k-encore-bsd* )
433 machine=ns16000 opsys=umax
434 ;;
435
436 ## The GEC 93 - apparently, this port isn't really finished yet.
437
438 ## Gould Power Node and NP1
439 pn-gould-bsd4.2* )
440 machine=gould opsys=bsd4-2
441 ;;
442 pn-gould-bsd4.3* )
443 machine=gould opsys=bsd4-3
444 ;;
445 np1-gould-bsd* )
446 machine=gould-np1 opsys=bsd4-3
447 ;;
448
449 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
450 ## as far as Emacs is concerned).
451 m88k-harris-cxux* )
452 # Build needs to be different on 7.0 and later releases
453 case "`uname -r`" in
454 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
455 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
456 esac
457 NON_GNU_CPP="/lib/cpp"
458 ;;
459 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
460 m68k-harris-cxux* )
461 machine=nh3000 opsys=cxux
462 ;;
463 ## Harris power pc NightHawk running Power UNIX (Series 6000)
464 powerpc-harris-powerunix )
465 machine=nh6000 opsys=powerunix
466 NON_GNU_CPP="cc -Xo -E -P"
467 ;;
468 ## SR2001/SR2201 running HI-UX/MPP
469 hppa1.1-hitachi-hiuxmpp* )
470 machine=sr2k opsys=hiuxmpp
471 ;;
472 ## Honeywell XPS100
473 xps*-honeywell-sysv* )
474 machine=xps100 opsys=usg5-2
475 ;;
476
477 ## HP 9000 series 200 or 300
478 m68*-hp-bsd* )
479 machine=hp9000s300 opsys=bsd4-3
480 ;;
481 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
482 m68*-hp-hpux* )
483 case "`uname -r`" in
484 ## Someone's system reports A.B8.05 for this.
485 ## I wonder what other possibilities there are.
486 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
487 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
488 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
489 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
490 *) machine=hp9000s300 opsys=hpux ;;
491 esac
492 ;;
493
494 ## HP 9000 series 700 and 800, running HP/UX
495 hppa*-hp-hpux7* )
496 machine=hp800 opsys=hpux
497 ;;
498 hppa*-hp-hpux8* )
499 machine=hp800 opsys=hpux8
500 ;;
501 hppa*-hp-hpux9shr* )
502 machine=hp800 opsys=hpux9shr
503 ;;
504 hppa*-hp-hpux9* )
505 machine=hp800 opsys=hpux9
506 ;;
507 hppa*-hp-hpux1[0-9]* )
508 machine=hp800 opsys=hpux10
509 ;;
510
511 ## HP 9000 series 700 and 800, running HP/UX
512 hppa*-hp-hpux* )
513 ## Cross-compilation? Nah!
514 case "`uname -r`" in
515 ## Someone's system reports A.B8.05 for this.
516 ## I wonder what other possibilities there are.
517 *.B8.* ) machine=hp800 opsys=hpux8 ;;
518 *.08.* ) machine=hp800 opsys=hpux8 ;;
519 *.09.* ) machine=hp800 opsys=hpux9 ;;
520 *) machine=hp800 opsys=hpux10 ;;
521 esac
522 ;;
523 hppa*-*-nextstep* )
524 machine=hp800 opsys=nextstep
525 ;;
526
527 ## Orion machines
528 orion-orion-bsd* )
529 machine=orion opsys=bsd4-2
530 ;;
531 clipper-orion-bsd* )
532 machine=orion105 opsys=bsd4-2
533 ;;
534
535 ## IBM machines
536 i[3456]86-ibm-aix1.1* )
537 machine=ibmps2-aix opsys=usg5-2-2
538 ;;
539 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
540 machine=ibmps2-aix opsys=usg5-3
541 ;;
542 i370-ibm-aix*)
543 machine=ibm370aix opsys=usg5-3
544 ;;
545 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
546 machine=ibmrs6000 opsys=aix3-1
547 ;;
548 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
549 machine=ibmrs6000 opsys=aix3-2-5
550 ;;
551 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
552 machine=ibmrs6000 opsys=aix4-1
553 ;;
554 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
555 machine=ibmrs6000 opsys=aix4-2
556 ;;
557 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
558 machine=ibmrs6000 opsys=aix4
559 ;;
560 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
561 machine=ibmrs6000 opsys=aix4-1
562 ;;
563 rs6000-ibm-aix* | powerpc-ibm-aix* )
564 machine=ibmrs6000 opsys=aix3-2
565 ;;
566 romp-ibm-bsd4.3* )
567 machine=ibmrt opsys=bsd4-3
568 ;;
569 romp-ibm-bsd4.2* )
570 machine=ibmrt opsys=bsd4-2
571 ;;
572 romp-ibm-aos4.3* )
573 machine=ibmrt opsys=bsd4-3
574 ;;
575 romp-ibm-aos4.2* )
576 machine=ibmrt opsys=bsd4-2
577 ;;
578 romp-ibm-aos* )
579 machine=ibmrt opsys=bsd4-3
580 ;;
581 romp-ibm-bsd* )
582 machine=ibmrt opsys=bsd4-3
583 ;;
584 romp-ibm-aix* )
585 machine=ibmrt-aix opsys=usg5-2-2
586 ;;
587
588 ## Integrated Solutions `Optimum V'
589 m68*-isi-bsd4.2* )
590 machine=isi-ov opsys=bsd4-2
591 ;;
592 m68*-isi-bsd4.3* )
593 machine=isi-ov opsys=bsd4-3
594 ;;
595
596 ## Intel 386 machines where we do care about the manufacturer
597 i[3456]86-intsys-sysv* )
598 machine=is386 opsys=usg5-2-2
599 ;;
600
601 ## Prime EXL
602 i[3456]86-prime-sysv* )
603 machine=i386 opsys=usg5-3
604 ;;
605
606 ## Sequent Symmetry running Dynix
607 i[3456]86-sequent-bsd* )
608 machine=symmetry opsys=bsd4-3
609 ;;
610
611 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
612 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
613 machine=sequent-ptx opsys=ptx4
614 NON_GNU_CPP=/lib/cpp
615 ;;
616
617 ## Sequent Symmetry running DYNIX/ptx
618 ## Use the old cpp rather than the newer ANSI one.
619 i[3456]86-sequent-ptx* )
620 machine=sequent-ptx opsys=ptx
621 NON_GNU_CPP="/lib/cpp"
622 ;;
623
624 ## ncr machine running svr4.3.
625 i[3456]86-ncr-sysv4.3 )
626 machine=ncr386 opsys=usg5-4-3
627 ;;
628
629 ## Unspecified sysv on an ncr machine defaults to svr4.2.
630 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
631 i[3456]86-ncr-sysv* )
632 machine=ncr386 opsys=usg5-4-2
633 ;;
634
635 ## Intel Paragon OSF/1
636 i860-intel-osf1* )
637 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
638 ;;
639
640 ## Intel 860
641 i860-*-sysv4* )
642 machine=i860 opsys=usg5-4
643 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
644 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
645 ;;
646
647 ## Masscomp machines
648 m68*-masscomp-rtu* )
649 machine=masscomp opsys=rtu
650 ;;
651
652 ## Megatest machines
653 m68*-megatest-bsd* )
654 machine=mega68 opsys=bsd4-2
655 ;;
656
657 ## Workstations sold by MIPS
658 ## This is not necessarily all workstations using the MIPS processor -
659 ## Irises are produced by SGI, and DECstations by DEC.
660
661 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
662 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
663 ## it gives for choosing between the alternatives seems to be "Use
664 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
665 ## the BSD world." I'll assume that these are instructions for
666 ## handling two odd situations, and that every other situation
667 ## should use mips.h and usg5-2-2, they being listed first.
668 mips-mips-usg* )
669 machine=mips4
670 ## Fall through to the general code at the bottom to decide on the OS.
671 ;;
672 mips-mips-riscos4* )
673 machine=mips4 opsys=bsd4-3
674 NON_GNU_CC="cc -systype bsd43"
675 NON_GNU_CPP="cc -systype bsd43 -E"
676 ;;
677 mips-mips-riscos5* )
678 machine=mips4 opsys=riscos5
679 NON_GNU_CC="cc -systype bsd43"
680 NON_GNU_CPP="cc -systype bsd43 -E"
681 ;;
682 mips-mips-bsd* )
683 machine=mips opsys=bsd4-3
684 ;;
685 mips-mips-* )
686 machine=mips opsys=usg5-2-2
687 ;;
688
689 ## NeXT
690 m68*-next-* | m68k-*-nextstep* )
691 machine=m68k opsys=nextstep
692 ;;
693
694 ## The complete machine from National Semiconductor
695 ns32k-ns-genix* )
696 machine=ns32000 opsys=usg5-2
697 ;;
698
699 ## NCR machines
700 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
701 machine=tower32 opsys=usg5-2-2
702 ;;
703 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
704 machine=tower32v3 opsys=usg5-3
705 ;;
706
707 ## NEC EWS4800
708 mips-nec-sysv4*)
709 machine=ews4800 opsys=ux4800
710 ;;
711
712 ## Nixdorf Targon 31
713 m68*-nixdorf-sysv* )
714 machine=targon31 opsys=usg5-2-2
715 ;;
716
717 ## Nu (TI or LMI)
718 m68*-nu-sysv* )
719 machine=nu opsys=usg5-2
720 ;;
721
722 ## Plexus
723 m68*-plexus-sysv* )
724 machine=plexus opsys=usg5-2
725 ;;
726
727 ## PowerPC reference platform
728 powerpcle-*-solaris2* )
729 machine=prep
730 opsys=sol2-5
731 ;;
732
733 ## Pyramid machines
734 ## I don't really have any idea what sort of processor the Pyramid has,
735 ## so I'm assuming it is its own architecture.
736 pyramid-pyramid-bsd* )
737 machine=pyramid opsys=bsd4-2
738 ;;
739
740 ## Sequent Balance
741 ns32k-sequent-bsd4.2* )
742 machine=sequent opsys=bsd4-2
743 ;;
744 ns32k-sequent-bsd4.3* )
745 machine=sequent opsys=bsd4-3
746 ;;
747
748 ## Siemens Nixdorf
749 mips-siemens-sysv* | mips-sni-sysv*)
750 machine=mips-siemens opsys=usg5-4
751 NON_GNU_CC=/usr/ccs/bin/cc
752 NON_GNU_CPP=/usr/ccs/lib/cpp
753 ;;
754
755 ## Silicon Graphics machines
756 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
757 m68*-sgi-iris3.5* )
758 machine=irist opsys=iris3-5
759 ;;
760 m68*-sgi-iris3.6* | m68*-sgi-iris*)
761 machine=irist opsys=iris3-6
762 ;;
763 ## Iris 4D
764 mips-sgi-irix3* )
765 machine=iris4d opsys=irix3-3
766 ;;
767 mips-sgi-irix4* )
768 machine=iris4d opsys=irix4-0
769 ;;
770 mips-sgi-irix6.5 )
771 machine=iris4d opsys=irix6-5
772 # Without defining _LANGUAGE_C, things get masked out in the headers
773 # so that, for instance, grepping for `free' in stdlib.h fails and
774 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
775 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
776 NON_GCC_TEST_OPTIONS="-n32 -G0 -D_LANGUAGE_C"
777 ;;
778 mips-sgi-irix6* )
779 machine=iris4d opsys=irix6-0
780 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
781 # but presumably it does no harm.
782 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
783 NON_GCC_TEST_OPTIONS=-32
784 ;;
785 mips-sgi-irix5.[01]* )
786 machine=iris4d opsys=irix5-0
787 ;;
788 mips-sgi-irix5* | mips-sgi-irix* )
789 machine=iris4d opsys=irix5-2
790 ;;
791
792 ## SONY machines
793 m68*-sony-bsd4.2* )
794 machine=news opsys=bsd4-2
795 ;;
796 m68*-sony-bsd4.3* )
797 machine=news opsys=bsd4-3
798 ;;
799 m68*-sony-newsos3* | m68*-sony-news3*)
800 machine=news opsys=bsd4-3
801 ;;
802 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
803 machine=news-risc opsys=bsd4-3
804 ;;
805 mips-sony-newsos6* )
806 machine=news-r6 opsys=newsos6
807 ;;
808 mips-sony-news* )
809 machine=news-risc opsys=newsos5
810 ;;
811
812 ## Stride
813 m68*-stride-sysv* )
814 machine=stride opsys=usg5-2
815 ;;
816
817 ## Suns
818 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
819 machine=sparc opsys=gnu-linux
820 ;;
821
822 *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
823 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
824 | rs6000-*-solaris2*)
825 case "${canonical}" in
826 m68*-sunos1* ) machine=sun1 ;;
827 m68*-sunos2* ) machine=sun2 ;;
828 m68* ) machine=sun3 ;;
829 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
830 i[3456]86-*-* ) machine=intel386 ;;
831 powerpcle* ) machine=powerpcle ;;
832 powerpc* | rs6000* ) machine=ibmrs6000 ;;
833 sparc* ) machine=sparc ;;
834 * ) unported=yes ;;
835 esac
836 case "${canonical}" in
837 ## The Sun386 didn't get past 4.0.
838 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
839 *-sunos4.0* ) opsys=sunos4-0 ;;
840 *-sunos4.1.[3-9]*noshare )
841 ## This name is sunos413 instead of sunos4-1-3
842 ## to avoid a file name conflict on MSDOS.
843 opsys=sunos413
844 NON_GNU_CPP=/usr/lib/cpp
845 NON_GCC_TEST_OPTIONS=-Bstatic
846 GCC_TEST_OPTIONS=-static
847 ;;
848 *-sunos4.1.[3-9]* | *-sunos4shr*)
849 opsys=sunos4shr
850 NON_GNU_CPP=/usr/lib/cpp
851 ;;
852 *-sunos4* | *-sunos )
853 opsys=sunos4-1
854 NON_GCC_TEST_OPTIONS=-Bstatic
855 GCC_TEST_OPTIONS=-static
856 ;;
857 *-sunos5.3* | *-solaris2.3* )
858 opsys=sol2-3
859 NON_GNU_CPP=/usr/ccs/lib/cpp
860 ;;
861 *-sunos5.4* | *-solaris2.4* )
862 opsys=sol2-4
863 NON_GNU_CPP=/usr/ccs/lib/cpp
864 RANLIB="ar -ts"
865 ;;
866 *-sunos5.5* | *-solaris2.5* )
867 opsys=sol2-5
868 NON_GNU_CPP=/usr/ccs/lib/cpp
869 RANLIB="ar -ts"
870 ;;
871 *-sunos5* | *-solaris* )
872 opsys=sol2-5
873 NON_GNU_CPP=/usr/ccs/lib/cpp
874 ;;
875 * ) opsys=bsd4-2 ;;
876 esac
877 ## Watch out for a compiler that we know will not work.
878 case "${canonical}" in
879 *-solaris* | *-sunos5* )
880 if [ "x$CC" = x/usr/ucb/cc ]; then
881 ## /usr/ucb/cc doesn't work;
882 ## we should find some other compiler that does work.
883 unset CC
884 fi
885 ;;
886 *) ;;
887 esac
888 ;;
889 sparc-*-nextstep* )
890 machine=sparc opsys=nextstep
891 ;;
892
893 ## Tadpole 68k
894 m68*-tadpole-sysv* )
895 machine=tad68k opsys=usg5-3
896 ;;
897
898 ## Tahoe machines
899 tahoe-tahoe-bsd4.2* )
900 machine=tahoe opsys=bsd4-2
901 ;;
902 tahoe-tahoe-bsd4.3* )
903 machine=tahoe opsys=bsd4-3
904 ;;
905
906 ## Tandem Integrity S2
907 mips-tandem-sysv* )
908 machine=tandem-s2 opsys=usg5-3
909 ;;
910
911 ## Tektronix XD88
912 m88k-tektronix-sysv3* )
913 machine=tekxd88 opsys=usg5-3
914 ;;
915
916 ## Tektronix 16000 box (6130?)
917 ns16k-tektronix-bsd* )
918 machine=ns16000 opsys=bsd4-2
919 ;;
920 ## Tektronix 4300
921 ## src/m/tek4300.h hints that this is a m68k machine.
922 m68*-tektronix-bsd* )
923 machine=tek4300 opsys=bsd4-3
924 ;;
925
926 ## Titan P2 or P3
927 ## We seem to have lost the machine-description file titan.h!
928 titan-titan-sysv* )
929 machine=titan opsys=usg5-3
930 ;;
931
932 ## Ustation E30 (SS5E)
933 m68*-unisys-uniplus* )
934 machine=ustation opsystem=unipl5-2
935 ;;
936
937 ## Vaxen.
938 vax-dec-* )
939 machine=vax
940 case "${canonical}" in
941 *-bsd4.1* ) opsys=bsd4-1 ;;
942 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
943 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
944 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
945 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
946 *-vms* ) opsys=vms ;;
947 * ) unported=yes
948 esac
949 ;;
950
951 ## Whitechapel MG1
952 ns16k-whitechapel-* )
953 machine=mg1
954 ## We don't know what sort of OS runs on these; we'll let the
955 ## operating system guessing code below try.
956 ;;
957
958 ## Wicat
959 m68*-wicat-sysv* )
960 machine=wicat opsys=usg5-2
961 ;;
962
963 ## Intel 386 machines where we don't care about the manufacturer
964 i[3456]86-*-* )
965 machine=intel386
966 case "${canonical}" in
967 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
968 *-isc2.2* ) opsys=isc2-2 ;;
969 *-isc4.0* ) opsys=isc4-0 ;;
970 *-isc4.* ) opsys=isc4-1
971 GCC_TEST_OPTIONS=-posix
972 NON_GCC_TEST_OPTIONS=-Xp
973 ;;
974 *-isc* ) opsys=isc3-0 ;;
975 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
976 *-esix* ) opsys=esix ;;
977 *-xenix* ) opsys=xenix ;;
978 *-linux-gnu* ) opsys=gnu-linux ;;
979 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
980 *-sco3.2v5* ) opsys=sco5
981 NON_GNU_CPP=/lib/cpp
982 # Prevent -belf from being passed to $CPP.
983 # /lib/cpp does not accept it.
984 OVERRIDE_CPPFLAGS=" "
985 ;;
986 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
987 *-386bsd* ) opsys=386bsd ;;
988 *-freebsd* ) opsys=freebsd ;;
989 *-nextstep* ) opsys=nextstep ;;
990 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
991 esac
992 ;;
993
994 ## m68k Linux-based GNU system
995 m68k-*-linux-gnu* )
996 machine=m68k opsys=gnu-linux
997 ;;
998
999 ## Mips Linux-based GNU system
1000 mips-*-linux-gnu* )
1001 machine=mips opsys=gnu-linux
1002 ;;
1003
1004 ## UXP/DS
1005 sparc-fujitsu-sysv4* )
1006 machine=sparc opsys=uxpds
1007 NON_GNU_CPP=/usr/ccs/lib/cpp
1008 RANLIB="ar -ts"
1009 ;;
1010
1011 ## UXP/V
1012 f301-fujitsu-uxpv4.1)
1013 machine=f301 opsys=uxpv
1014 ;;
1015
1016 * )
1017 unported=yes
1018 ;;
1019 esac
1020
1021 ### If the code above didn't choose an operating system, just choose
1022 ### an operating system based on the configuration name. You really
1023 ### only want to use this when you have no idea what the right
1024 ### operating system is; if you know what operating systems a machine
1025 ### runs, it's cleaner to make it explicit in the case statement
1026 ### above.
1027 if test x"${opsys}" = x; then
1028 case "${canonical}" in
1029 *-gnu* ) opsys=gnu ;;
1030 *-bsd4.[01] ) opsys=bsd4-1 ;;
1031 *-bsd4.2 ) opsys=bsd4-2 ;;
1032 *-bsd4.3 ) opsys=bsd4-3 ;;
1033 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1034 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1035 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1036 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1037 *-sysv4.2uw* ) opsys=unixware ;;
1038 *-sysv4.1* | *-sysvr4.1* )
1039 NON_GNU_CPP=/usr/lib/cpp
1040 opsys=usg5-4 ;;
1041 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1042 if [ x$NON_GNU_CPP = x ]; then
1043 if [ -f /usr/ccs/lib/cpp ]; then
1044 NON_GNU_CPP=/usr/ccs/lib/cpp
1045 else
1046 NON_GNU_CPP=/lib/cpp
1047 fi
1048 fi
1049 opsys=usg5-4-2 ;;
1050 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1051 * )
1052 unported=yes
1053 ;;
1054 esac
1055 fi
1056
1057 if test "x$RANLIB" = x; then
1058 RANLIB=ranlib
1059 fi
1060
1061 changequote([, ])dnl
1062
1063 if test $unported = yes; then
1064 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1065 Check \`etc/MACHINES' for recognized configuration names.])
1066 fi
1067
1068 machfile="m/${machine}.h"
1069 opsysfile="s/${opsys}.h"
1070
1071
1072 #### Choose a compiler.
1073 test -n "$CC" && cc_specified=yes
1074
1075 # Save the value of CFLAGS that the user specified.
1076 SPECIFIED_CFLAGS="$CFLAGS"
1077
1078 case ${with_gcc} in
1079 "yes" ) CC="gcc" GCC=yes ;;
1080 "no" ) : ${CC=cc} ;;
1081 * ) AC_PROG_CC
1082 esac
1083
1084 # On Suns, sometimes $CPP names a directory.
1085 if test -n "$CPP" && test -d "$CPP"; then
1086 CPP=
1087 fi
1088
1089 #### Some systems specify a CPP to use unless we are using GCC.
1090 #### Now that we know whether we are using GCC, we can decide whether
1091 #### to use that one.
1092 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1093 then
1094 CPP="$NON_GNU_CPP"
1095 fi
1096
1097 #### Some systems specify a CC to use unless we are using GCC.
1098 #### Now that we know whether we are using GCC, we can decide whether
1099 #### to use that one.
1100 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1101 test x$cc_specified != xyes
1102 then
1103 CC="$NON_GNU_CC"
1104 fi
1105
1106 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1107 then
1108 CC="$CC $GCC_TEST_OPTIONS"
1109 fi
1110
1111 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1112 then
1113 CC="$CC $NON_GCC_TEST_OPTIONS"
1114 fi
1115
1116 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1117 then
1118 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1119 fi
1120
1121 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1122 then
1123 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1124 fi
1125
1126 #### Some other nice autoconf tests. If you add a test here which
1127 #### should make an entry in src/config.h, don't forget to add an
1128 #### #undef clause to src/config.h.in for autoconf to modify.
1129
1130 dnl checks for programs
1131 AC_PROG_LN_S
1132 AC_PROG_CPP
1133 AC_PROG_INSTALL
1134 AC_PROG_YACC
1135
1136 dnl checks for Unix variants
1137 AC_AIX
1138
1139 # Sound support for GNU/Linux and the free BSDs.
1140 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h)
1141
1142 dnl checks for header files
1143 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1144 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1145 termcap.h stdio_ext.h)
1146 AC_HEADER_STDC
1147 AC_HEADER_TIME
1148 AC_DECL_SYS_SIGLIST
1149
1150 dnl Some systems have utime.h but don't declare the struct anyplace.
1151 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1152 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1153 #include <sys/time.h>
1154 #include <time.h>
1155 #else
1156 #ifdef HAVE_SYS_TIME_H
1157 #include <sys/time.h>
1158 #else
1159 #include <time.h>
1160 #endif
1161 #endif
1162 #ifdef HAVE_UTIME_H
1163 #include <utime.h>
1164 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1165 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1166 if test $emacs_cv_struct_utimbuf = yes; then
1167 AC_DEFINE(HAVE_STRUCT_UTIMBUF)
1168 fi
1169
1170 dnl checks for typedefs
1171 AC_TYPE_SIGNAL
1172
1173 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1174 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1175 #include <sys/time.h>
1176 #include <time.h>
1177 #else
1178 #ifdef HAVE_SYS_TIME_H
1179 #include <sys/time.h>
1180 #else
1181 #include <time.h>
1182 #endif
1183 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1184 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1185 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1186 if test $emacs_cv_struct_timeval = yes; then
1187 AC_DEFINE(HAVE_TIMEVAL)
1188 fi
1189
1190 dnl checks for structure members
1191 AC_STRUCT_TM
1192 AC_STRUCT_TIMEZONE
1193 AC_CACHE_CHECK(for tm_gmtoff in struct tm, emacs_cv_tm_gmtoff,
1194 AC_TRY_LINK([#include <time.h>], [struct tm t; t.tm_gmtoff = 0],
1195 emacs_cv_tm_gmtoff=yes,
1196 emacs_cv_tm_gmtoff=no))
1197 if test $emacs_cv_tm_gmtoff = yes; then
1198 AC_DEFINE(HAVE_TM_GMTOFF)
1199 fi
1200
1201 dnl checks for compiler characteristics
1202 AC_C_CONST
1203
1204 dnl check for Make feature
1205 AC_PROG_MAKE_SET
1206
1207 dnl checks for operating system services
1208 AC_SYS_LONG_FILE_NAMES
1209
1210 #### Choose a window system.
1211
1212 AC_PATH_X
1213 if test "$no_x" = yes; then
1214 window_system=none
1215 else
1216 window_system=x11
1217 fi
1218
1219 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1220 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1221 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1222 x_default_search_path=""
1223 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1224 x_search_path="${x_library}/X11/%L/%T/%N%C%S:\
1225 ${x_library}/X11/%L/%T/%N%C%S:${x_libary}/X11/%l/%T/%N%C%S:\
1226 ${x_library}/X11/%T/%N%C%S:${x_library}/X11/%L/%T/%N%S:\
1227 ${x_library}/X11/%l/%T/%N%S:${x_library}/X11/%T/%N%S"
1228 if test x"${x_default_search_path}" = x; then
1229 x_default_search_path=${x_search_path}
1230 else
1231 x_default_search_path="${x_search_path}:${x_default_search_path}"
1232 fi
1233 done
1234 fi
1235 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1236 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1237 fi
1238
1239 if test x"${x_includes}" = x; then
1240 bitmapdir=/usr/include/X11/bitmaps
1241 else
1242 # accumulate include directories that have X11 bitmap subdirectories
1243 bmd_acc="dummyval"
1244 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1245 if test -d "${bmd}/X11/bitmaps"; then
1246 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1247 fi
1248 if test -d "${bmd}/bitmaps"; then
1249 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1250 fi
1251 done
1252 if test ${bmd_acc} != "dummyval"; then
1253 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1254 fi
1255 fi
1256
1257 case "${window_system}" in
1258 x11 )
1259 HAVE_X_WINDOWS=yes
1260 HAVE_X11=yes
1261 case "${with_x_toolkit}" in
1262 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1263 motif ) USE_X_TOOLKIT=MOTIF ;;
1264 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1265 no ) USE_X_TOOLKIT=none ;;
1266 dnl If user did not say whether to use a toolkit,
1267 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1268 * ) USE_X_TOOLKIT=maybe ;;
1269 esac
1270 ;;
1271 none )
1272 HAVE_X_WINDOWS=no
1273 HAVE_X11=no
1274 USE_X_TOOLKIT=none
1275 ;;
1276 esac
1277
1278 ### If we're using X11, we should use the X menu package.
1279 HAVE_MENUS=no
1280 case ${HAVE_X11} in
1281 yes ) HAVE_MENUS=yes ;;
1282 esac
1283
1284 if test "${opsys}" = "hpux9"; then
1285 case "${x_libraries}" in
1286 *X11R4* )
1287 opsysfile="s/hpux9-x11r4.h"
1288 ;;
1289 esac
1290 fi
1291
1292 if test "${opsys}" = "hpux9shr"; then
1293 case "${x_libraries}" in
1294 *X11R4* )
1295 opsysfile="s/hpux9shxr4.h"
1296 ;;
1297 esac
1298 fi
1299
1300 #### Extract some information from the operating system and machine files.
1301
1302 AC_CHECKING([the machine- and system-dependent files to find out
1303 - which libraries the lib-src programs will want, and
1304 - whether the GNU malloc routines are usable])
1305
1306 ### First figure out CFLAGS (which we use for running the compiler here)
1307 ### and REAL_CFLAGS (which we use for real compilation).
1308 ### The two are the same except on a few systems, where they are made
1309 ### different to work around various lossages. For example,
1310 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1311 ### as implying static linking.
1312
1313 ### If the CFLAGS env var is specified, we use that value
1314 ### instead of the default.
1315
1316 ### It's not important that this name contain the PID; you can't run
1317 ### two configures in the same directory and have anything work
1318 ### anyway.
1319 tempcname="conftest.c"
1320
1321 echo '
1322 #include "'${srcdir}'/src/'${opsysfile}'"
1323 #include "'${srcdir}'/src/'${machfile}'"
1324 #ifndef LIBS_MACHINE
1325 #define LIBS_MACHINE
1326 #endif
1327 #ifndef LIBS_SYSTEM
1328 #define LIBS_SYSTEM
1329 #endif
1330 #ifndef C_SWITCH_SYSTEM
1331 #define C_SWITCH_SYSTEM
1332 #endif
1333 #ifndef C_SWITCH_MACHINE
1334 #define C_SWITCH_MACHINE
1335 #endif
1336 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1337 configure___ c_switch_system=C_SWITCH_SYSTEM
1338 configure___ c_switch_machine=C_SWITCH_MACHINE
1339
1340 #ifndef LIB_X11_LIB
1341 #define LIB_X11_LIB -lX11
1342 #endif
1343
1344 #ifndef LIBX11_MACHINE
1345 #define LIBX11_MACHINE
1346 #endif
1347
1348 #ifndef LIBX11_SYSTEM
1349 #define LIBX11_SYSTEM
1350 #endif
1351 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1352
1353 #ifdef UNEXEC
1354 configure___ unexec=UNEXEC
1355 #else
1356 configure___ unexec=unexec.o
1357 #endif
1358
1359 #ifdef SYSTEM_MALLOC
1360 configure___ system_malloc=yes
1361 #else
1362 configure___ system_malloc=no
1363 #endif
1364
1365 #ifndef C_DEBUG_SWITCH
1366 #define C_DEBUG_SWITCH -g
1367 #endif
1368
1369 #ifndef C_OPTIMIZE_SWITCH
1370 #define C_OPTIMIZE_SWITCH -O
1371 #endif
1372
1373 #ifndef LD_SWITCH_MACHINE
1374 #define LD_SWITCH_MACHINE
1375 #endif
1376
1377 #ifndef LD_SWITCH_SYSTEM
1378 #define LD_SWITCH_SYSTEM
1379 #endif
1380
1381 #ifndef LD_SWITCH_X_SITE_AUX
1382 #define LD_SWITCH_X_SITE_AUX
1383 #endif
1384
1385 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1386 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1387
1388 #ifdef THIS_IS_CONFIGURE
1389
1390 /* Get the CFLAGS for tests in configure. */
1391 #ifdef __GNUC__
1392 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1393 #else
1394 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1395 #endif
1396
1397 #else /* not THIS_IS_CONFIGURE */
1398
1399 /* Get the CFLAGS for real compilation. */
1400 #ifdef __GNUC__
1401 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1402 #else
1403 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1404 #endif
1405
1406 #endif /* not THIS_IS_CONFIGURE */
1407 ' > ${tempcname}
1408
1409 # The value of CPP is a quoted variable reference, so we need to do this
1410 # to get its actual value...
1411 CPP=`eval "echo $CPP"`
1412 changequote(, )dnl
1413 eval `${CPP} -Isrc ${tempcname} \
1414 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1415 if test "x$SPECIFIED_CFLAGS" = x; then
1416 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1417 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1418 else
1419 REAL_CFLAGS="$CFLAGS"
1420 fi
1421 changequote([, ])dnl
1422 rm ${tempcname}
1423
1424 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1425
1426 ### Compute the unexec source name from the object name.
1427 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1428
1429 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1430 # Assume not, until told otherwise.
1431 GNU_MALLOC=yes
1432 doug_lea_malloc=yes
1433 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1434 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1435 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1436 emacs_cv_var___after_morecore_hook,
1437 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1438 emacs_cv_var___after_morecore_hook=yes,
1439 emacs_cv_var___after_morecore_hook=no))
1440 if test $emacs_cv_var___after_morecore_hook = no; then
1441 doug_lea_malloc=no
1442 fi
1443 if test "${system_malloc}" = "yes"; then
1444 GNU_MALLOC=no
1445 GNU_MALLOC_reason="
1446 (The GNU allocators don't work with this system configuration.)"
1447 fi
1448 if test "$doug_lea_malloc" = "yes" ; then
1449 if test "$GNU_MALLOC" = yes ; then
1450 GNU_MALLOC_reason="
1451 (Using Doug Lea's new malloc from the GNU C Library.)"
1452 fi
1453 AC_DEFINE(DOUG_LEA_MALLOC)
1454 fi
1455
1456 if test x"${REL_ALLOC}" = x; then
1457 REL_ALLOC=${GNU_MALLOC}
1458 fi
1459
1460 LISP_FLOAT_TYPE=yes
1461
1462
1463 #### Add the libraries to LIBS and check for some functions.
1464
1465 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1466 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1467 else
1468 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1469 fi
1470
1471 LIBS="$libsrc_libs $LIBS"
1472
1473 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1474 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1475 AC_CHECK_LIB(dnet, dnet_ntoa)
1476 dnl This causes -lresolv to get used in subsequent tests,
1477 dnl which causes failures on some systems such as HPUX 9.
1478 dnl AC_CHECK_LIB(resolv, gethostbyname)
1479
1480 dnl FIXME replace main with a function we actually want from this library.
1481 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1482
1483 AC_CHECK_LIB(pthreads, cma_open)
1484
1485 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1486 if test -d /usr/X386/include; then
1487 HAVE_XFREE386=yes
1488 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1489 else
1490 HAVE_XFREE386=no
1491 fi
1492 AC_MSG_RESULT($HAVE_XFREE386)
1493
1494 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1495 # for the tests that follow. We set it back to REAL_CFLAGS later on.
1496
1497 if test "${HAVE_X11}" = "yes"; then
1498 DEFS="$C_SWITCH_X_SITE $DEFS"
1499 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1500 LIBS="$LIBX $LIBS"
1501 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1502
1503 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1504 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1505 # but it's more convenient here to set LD_RUN_PATH
1506 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1507 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1508 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1509 export LD_RUN_PATH
1510 fi
1511
1512 if test "${opsys}" = "gnu-linux"; then
1513 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1514 AC_TRY_LINK([],
1515 [XOpenDisplay ("foo");],
1516 [xlinux_first_failure=no],
1517 [xlinux_first_failure=yes])
1518 if test "${xlinux_first_failure}" = "yes"; then
1519 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1520 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1521 OLD_CPPFLAGS="$CPPFLAGS"
1522 OLD_LIBS="$LIBS"
1523 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1524 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1525 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1526 LIBS="$LIBS -b i486-linuxaout"
1527 AC_TRY_LINK([],
1528 [XOpenDisplay ("foo");],
1529 [xlinux_second_failure=no],
1530 [xlinux_second_failure=yes])
1531 if test "${xlinux_second_failure}" = "yes"; then
1532 # If we get the same failure with -b, there is no use adding -b.
1533 # So take it out. This plays safe.
1534 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1535 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1536 CPPFLAGS="$OLD_CPPFLAGS"
1537 LIBS="$OLD_LIBS"
1538 AC_MSG_RESULT(no)
1539 else
1540 AC_MSG_RESULT(yes)
1541 fi
1542 else
1543 AC_MSG_RESULT(no)
1544 fi
1545 fi
1546
1547 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1548 XScreenNumberOfScreen XSetWMProtocols)
1549 fi
1550
1551 if test "${window_system}" = "x11"; then
1552 AC_MSG_CHECKING(X11 version 6)
1553 AC_CACHE_VAL(emacs_cv_x11_version_6,
1554 AC_TRY_LINK([#include <X11/Xlib.h>],
1555 [#if XlibSpecificationRelease < 6
1556 fail;
1557 #endif
1558 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no))
1559 if test $emacs_cv_x11_version_6 = yes; then
1560 AC_MSG_RESULT(6 or newer)
1561 AC_DEFINE(HAVE_X11R6)
1562 else
1563 AC_MSG_RESULT(before 6)
1564 fi
1565 fi
1566
1567 if test "${window_system}" = "x11"; then
1568 AC_MSG_CHECKING(X11 version 5)
1569 AC_CACHE_VAL(emacs_cv_x11_version_5,
1570 AC_TRY_LINK([#include <X11/Xlib.h>],
1571 [#if XlibSpecificationRelease < 5
1572 fail;
1573 #endif
1574 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no))
1575 if test $emacs_cv_x11_version_5 = yes; then
1576 AC_MSG_RESULT(5 or newer)
1577 HAVE_X11R5=yes
1578 AC_DEFINE(HAVE_X11R5)
1579 else
1580 HAVE_X11R5=no
1581 AC_MSG_RESULT(before 5)
1582 fi
1583 fi
1584
1585 dnl Do not put whitespace before the #include statements below.
1586 dnl Older compilers (eg sunos4 cc) choke on it.
1587 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1588 if test x"${HAVE_X11R5}" = xyes; then
1589 AC_MSG_CHECKING(X11 version 5 with Xaw)
1590 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1591 AC_TRY_LINK([
1592 #include <X11/Intrinsic.h>
1593 #include <X11/Xaw/Simple.h>],
1594 [],
1595 emacs_cv_x11_version_5_with_xaw=yes,
1596 emacs_cv_x11_version_5_with_xaw=no))
1597 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1598 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1599 USE_X_TOOLKIT=LUCID
1600 else
1601 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1602 USE_X_TOOLKIT=none
1603 fi
1604 else
1605 USE_X_TOOLKIT=none
1606 fi
1607 fi
1608
1609 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1610
1611 if test "${USE_X_TOOLKIT}" != "none"; then
1612 AC_MSG_CHECKING(X11 toolkit version)
1613 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1614 AC_TRY_LINK([#include <X11/Intrinsic.h>],
1615 [#if XtSpecificationRelease < 6
1616 fail;
1617 #endif
1618 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no))
1619 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1620 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1621 AC_MSG_RESULT(6 or newer)
1622 AC_DEFINE(HAVE_X11XTR6)
1623 else
1624 AC_MSG_RESULT(before 6)
1625 fi
1626
1627 dnl If using toolkit, check whether libXmu.a exists.
1628 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1629 OLDLIBS="$LIBS"
1630 if test x$HAVE_X11XTR6 = xyes; then
1631 LIBS="-lXt -lSM -lICE $LIBS"
1632 else
1633 LIBS="-lXt $LIBS"
1634 fi
1635 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1636 LIBS="$OLDLIBS"
1637 fi
1638
1639 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1640 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1641 AC_TRY_COMPILE([#include <Xm/Xm.h>],
1642 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1643 int x = 5;
1644 #else
1645 Motif version prior to 2.1.
1646 #endif],
1647 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no))
1648 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1649 if test $emacs_cv_motif_version_2_1 = yes; then
1650 AC_DEFINE(HAVE_MOTIF_2_1)
1651 AC_CHECK_LIB(Xp, XpCreateContext)
1652 fi
1653 fi
1654
1655 ### Is -lXaw3d available?
1656 HAVE_XAW3D=no
1657 if test "${HAVE_X11}" = "yes"; then
1658 if test "${USE_X_TOOLKIT}" != "none"; then
1659 old_c_flags="${CFLAGS}"
1660 CFLAGS="${LD_SWITCH_X_SITE}"
1661 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
1662 AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes, , -lX11))
1663 CFLAGS="${old_c_flags}"
1664
1665 if test "${HAVE_XAW3D}" = "yes"; then
1666 AC_DEFINE(HAVE_XAW3D)
1667 fi
1668 fi
1669 fi
1670
1671 dnl Use toolkit scroll bars if configured for X toolkit and either
1672 dnl using Motif or Xaw3d is available, and unless
1673 dnl --with-toolkit-scroll-bars=no was specified.
1674
1675 USE_TOOLKIT_SCROLL_BARS=no
1676 if test "${with_toolkit_scroll_bars}" != "no"; then
1677 if test "${USE_X_TOOLKIT}" != "none"; then
1678 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1679 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1680 HAVE_XAW3D=no
1681 USE_TOOLKIT_SCROLL_BARS=yes
1682 elif test "${HAVE_XAW3D}" = "yes"; then
1683 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1684 USE_TOOLKIT_SCROLL_BARS=yes
1685 fi
1686 fi
1687 fi
1688
1689 ### Use -lXpm if available, unless `--with-xpm=no'.
1690 HAVE_XPM=no
1691 if test "${HAVE_X11}" = "yes"; then
1692 if test "${with_xpm}" != "no"; then
1693 old_c_flags="${CFLAGS}"
1694 CFLAGS="${LD_SWITCH_X_SITE}"
1695 AC_CHECK_HEADER(X11/xpm.h,
1696 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
1697 CFLAGS="${old_c_flags}"
1698 fi
1699
1700 if test "${HAVE_XPM}" = "yes"; then
1701 AC_DEFINE(HAVE_XPM)
1702 fi
1703 fi
1704
1705 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1706 HAVE_JPEG=no
1707 if test "${HAVE_X11}" = "yes"; then
1708 if test "${with_jpeg}" != "no"; then
1709 old_c_flags="${CFLAGS}"
1710 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1711 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes, , -lX11)
1712 CFLAGS="${old_c_flags}"
1713 fi
1714
1715 if test "${HAVE_JPEG}" = "yes"; then
1716 AC_DEFINE(HAVE_JPEG)
1717 fi
1718 fi
1719
1720 ### Use -lpng if available, unless `--with-png=no'.
1721 HAVE_PNG=no
1722 if test "${HAVE_X11}" = "yes"; then
1723 if test "${with_png}" != "no"; then
1724 old_c_flags="${CFLAGS}"
1725 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1726 AC_CHECK_HEADER(png.h,
1727 AC_CHECK_LIB(png, png_set_expand, HAVE_PNG=yes, , -lX11 -lz -lm))
1728 CFLAGS="${old_c_flags}"
1729 fi
1730
1731 if test "${HAVE_PNG}" = "yes"; then
1732 AC_DEFINE(HAVE_PNG)
1733 fi
1734 fi
1735
1736 ### Use -ltiff if available, unless `--with-tiff=no'.
1737 HAVE_TIFF=no
1738 if test "${HAVE_X11}" = "yes"; then
1739 if test "${with_tiff}" != "no"; then
1740 old_c_flags="${CFLAGS}"
1741 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1742 AC_CHECK_HEADER(tiffio.h,
1743 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , -lX11 -lm))
1744 CFLAGS="${old_c_flags}"
1745 fi
1746
1747 if test "${HAVE_TIFF}" = "yes"; then
1748 AC_DEFINE(HAVE_TIFF)
1749 fi
1750 fi
1751
1752 ### Use -lgif if available, unless `--with-gif=no'.
1753 HAVE_GIF=no
1754 if test "${HAVE_X11}" = "yes"; then
1755 if test "${with_gif}" != "no"; then
1756 old_c_flags="${CFLAGS}"
1757 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1758 AC_CHECK_HEADER(gif_lib.h,
1759 AC_CHECK_LIB(ungif, DGifOpenFileName, HAVE_GIF=yes, , -lX11))
1760 CFLAGS="${old_c_flags}"
1761 fi
1762
1763 if test "${HAVE_GIF}" = "yes"; then
1764 AC_DEFINE(HAVE_GIF)
1765 fi
1766 fi
1767
1768 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1769 AC_CACHE_CHECK(whether netdb declares h_errno,
1770 emacs_cv_netdb_declares_h_errno,
1771 AC_TRY_LINK([#include <netdb.h>],
1772 [return h_errno;],
1773 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no))
1774 if test $emacs_cv_netdb_declares_h_errno = yes; then
1775 AC_DEFINE(HAVE_H_ERRNO)
1776 fi
1777
1778 AC_FUNC_ALLOCA
1779
1780 # fmod, logb, and frexp are found in -lm on most systems.
1781 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1782 AC_CHECK_LIB(m, sqrt)
1783
1784 # Check for mail-locking functions in a "mail" library
1785 AC_CHECK_LIB(mail, maillock)
1786 dnl Debian, at least:
1787 dnl AC_CHECK_LIB(lockfile, maillock, [AC_DEFINE(HAVE_LIBMAIL)])
1788 AC_CHECK_LIB(lockfile, maillock)
1789 # If we have the shared liblockfile, assume we must use it for mail
1790 # locking (e.g. Debian). If we couldn't link against liblockfile
1791 # (no liblockfile.a installed), ensure that we don't need to.
1792 if test "$ac_cv_lib_lockfile_maillock" = no; then
1793 dnl This works for files generally, not just executables.
1794 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
1795 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
1796 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
1797 if test $ac_cv_prog_liblockfile = yes; then
1798 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
1799 This probably means that movemail could lose mail.
1800 There may be a \`development' package to install containing liblockfile.])
1801 else AC_DEFINE(LIBMAIL, -llockfile)
1802 fi
1803 else :
1804 fi
1805 AC_CHECK_FUNCS(touchlock)
1806 AC_CHECK_HEADERS(maillock.h)
1807
1808 AC_CHECK_FUNCS(gettimeofday gethostname getdomainname dup2 \
1809 rename closedir mkdir rmdir sysinfo \
1810 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
1811 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
1812 utimes setrlimit setpgid getcwd shutdown strftime getaddrinfo \
1813 __fpending ftello getloadavg mblen mbrlen strsignal setitimer ualarm)
1814
1815 # Check this now, so that we will NOT find the above functions in ncurses.
1816 # That is because we have not set up to link ncurses in lib-src.
1817 # It's better to believe a function is not available
1818 # than to expect to find it in ncurses.
1819 AC_CHECK_LIB(ncurses, tparm)
1820
1821 # These tell us which Kerberos-related libraries to use.
1822 if test "${with_kerberos+set}" = set; then
1823 AC_CHECK_LIB(com_err, com_err)
1824 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
1825 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
1826 AC_CHECK_LIB(krb5, krb5_init_context)
1827 if test "${with_kerberos5+set}" != set; then
1828 AC_CHECK_LIB(des425, des_cbc_encrypt,,
1829 AC_CHECK_LIB(des, des_cbc_encrypt))
1830 AC_CHECK_LIB(krb4, krb_get_cred,,
1831 AC_CHECK_LIB(krb, krb_get_cred))
1832 fi
1833
1834 if test "${with_kerberos5+set}" = set; then
1835 AC_CHECK_HEADERS(krb5.h)
1836 else
1837 AC_CHECK_HEADERS(des.h,,
1838 AC_CHECK_HEADERS(kerberosIV/des.h,,
1839 AC_CHECK_HEADERS(kerberos/des.h)))
1840 AC_CHECK_HEADERS(krb.h,,
1841 AC_CHECK_HEADERS(kerberosIV/krb.h,,
1842 AC_CHECK_HEADERS(kerberos/krb.h)))
1843 fi
1844 AC_CHECK_HEADERS(com_err.h)
1845 fi
1846
1847 # Solaris requires -lintl if you want strerror (which calls dgettext)
1848 # to return localized messages.
1849 AC_CHECK_LIB(intl, dgettext)
1850
1851 AC_MSG_CHECKING(whether localtime caches TZ)
1852 AC_CACHE_VAL(emacs_cv_localtime_cache,
1853 [if test x$ac_cv_func_tzset = xyes; then
1854 AC_TRY_RUN([#include <time.h>
1855 extern char **environ;
1856 unset_TZ ()
1857 {
1858 char **from, **to;
1859 for (to = from = environ; (*to = *from); from++)
1860 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1861 to++;
1862 }
1863 char TZ_GMT0[] = "TZ=GMT0";
1864 char TZ_PST8[] = "TZ=PST8";
1865 main()
1866 {
1867 time_t now = time ((time_t *) 0);
1868 int hour_GMT0, hour_unset;
1869 if (putenv (TZ_GMT0) != 0)
1870 exit (1);
1871 hour_GMT0 = localtime (&now)->tm_hour;
1872 unset_TZ ();
1873 hour_unset = localtime (&now)->tm_hour;
1874 if (putenv (TZ_PST8) != 0)
1875 exit (1);
1876 if (localtime (&now)->tm_hour == hour_GMT0)
1877 exit (1);
1878 unset_TZ ();
1879 if (localtime (&now)->tm_hour != hour_unset)
1880 exit (1);
1881 exit (0);
1882 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
1883 [# If we have tzset, assume the worst when cross-compiling.
1884 emacs_cv_localtime_cache=yes])
1885 else
1886 # If we lack tzset, report that localtime does not cache TZ,
1887 # since we can't invalidate the cache if we don't have tzset.
1888 emacs_cv_localtime_cache=no
1889 fi])dnl
1890 AC_MSG_RESULT($emacs_cv_localtime_cache)
1891 if test $emacs_cv_localtime_cache = yes; then
1892 AC_DEFINE(LOCALTIME_CACHE)
1893 fi
1894
1895 if test "x$HAVE_TIMEVAL" = xyes; then
1896 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
1897 emacs_cv_gettimeofday_two_arguments,
1898 AC_TRY_LINK([
1899 #ifdef TIME_WITH_SYS_TIME
1900 #include <sys/time.h>
1901 #include <time.h>
1902 #else
1903 #ifdef HAVE_SYS_TIME_H
1904 #include <sys/time.h>
1905 #else
1906 #include <time.h>
1907 #endif
1908 #endif
1909 ],
1910 [
1911 struct timeval time;
1912 struct timezone dummy;
1913 gettimeofday (&time, &dummy);
1914 ],
1915 emacs_cv_gettimeofday_two_arguments=yes,
1916 emacs_cv_gettimeofday_two_arguments=no))
1917 if test $emacs_cv_gettimeofday_two_arguments = no; then
1918 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)
1919 fi
1920 fi
1921
1922 ok_so_far=yes
1923 AC_CHECK_FUNC(socket, , ok_so_far=no)
1924 if test $ok_so_far = yes; then
1925 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1926 fi
1927 if test $ok_so_far = yes; then
1928 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1929 fi
1930 if test $ok_so_far = yes; then
1931 AC_DEFINE(HAVE_INET_SOCKETS)
1932 fi
1933
1934 if test -f /usr/lpp/X11/bin/smt.exp; then
1935 AC_DEFINE(HAVE_AIX_SMT_EXP)
1936 fi
1937
1938 AC_MSG_CHECKING(whether system supports dynamic ptys)
1939 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
1940 AC_MSG_RESULT(yes)
1941 AC_DEFINE(HAVE_DEV_PTMX)
1942 else
1943 AC_MSG_RESULT(no)
1944 fi
1945
1946 # Set up the CFLAGS for real compilation, so we can substitute it.
1947 CFLAGS="$REAL_CFLAGS"
1948
1949 changequote(, )dnl
1950 #### Find out which version of Emacs this is.
1951 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
1952 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1953 changequote([, ])dnl
1954 if test x"${version}" = x; then
1955 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1956 fi
1957
1958 ### Specify what sort of things we'll be editing into Makefile and config.h.
1959 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1960 AC_SUBST(version)
1961 AC_SUBST(configuration)
1962 AC_SUBST(canonical)
1963 AC_SUBST(srcdir)
1964 AC_SUBST(prefix)
1965 AC_SUBST(exec_prefix)
1966 AC_SUBST(bindir)
1967 AC_SUBST(datadir)
1968 AC_SUBST(sharedstatedir)
1969 AC_SUBST(libexecdir)
1970 AC_SUBST(mandir)
1971 AC_SUBST(infodir)
1972 AC_SUBST(lispdir)
1973 AC_SUBST(locallisppath)
1974 AC_SUBST(lisppath)
1975 AC_SUBST(x_default_search_path)
1976 AC_SUBST(etcdir)
1977 AC_SUBST(archlibdir)
1978 AC_SUBST(docdir)
1979 AC_SUBST(bitmapdir)
1980 AC_SUBST(c_switch_system)
1981 AC_SUBST(c_switch_machine)
1982 AC_SUBST(LD_SWITCH_X_SITE)
1983 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1984 AC_SUBST(C_SWITCH_X_SITE)
1985 AC_SUBST(CFLAGS)
1986 AC_SUBST(X_TOOLKIT_TYPE)
1987 AC_SUBST(machfile)
1988 AC_SUBST(opsysfile)
1989 AC_SUBST(RANLIB)
1990
1991 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}")
1992 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
1993 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}")
1994 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1995 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1996 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1997 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE})
1998 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC})
1999
2000 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2001 AC_DEFINE(HAVE_X_WINDOWS)
2002 fi
2003 if test "${USE_X_TOOLKIT}" != "none" ; then
2004 AC_DEFINE(USE_X_TOOLKIT)
2005 fi
2006 if test "${HAVE_X11}" = "yes" ; then
2007 AC_DEFINE(HAVE_X11)
2008 fi
2009 if test "${HAVE_XFREE386}" = "yes" ; then
2010 AC_DEFINE(HAVE_XFREE386)
2011 fi
2012 if test "${HAVE_MENUS}" = "yes" ; then
2013 AC_DEFINE(HAVE_MENUS)
2014 fi
2015 if test "${GNU_MALLOC}" = "yes" ; then
2016 AC_DEFINE(GNU_MALLOC)
2017 fi
2018 if test "${REL_ALLOC}" = "yes" ; then
2019 AC_DEFINE(REL_ALLOC)
2020 fi
2021 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
2022 AC_DEFINE(LISP_FLOAT_TYPE)
2023 fi
2024
2025 #### Report on what we decided to do.
2026 echo "
2027 Configured for \`${canonical}'.
2028
2029 Where should the build process find the source code? ${srcdir}
2030 What operating system and machine description files should Emacs use?
2031 \`${opsysfile}' and \`${machfile}'
2032 What compiler should emacs be built with? ${CC} ${CFLAGS}
2033 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
2034 Should Emacs use the relocating allocator for buffers? ${REL_ALLOC}
2035 What window system should Emacs use? ${window_system}
2036 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
2037
2038 if test -n "${x_includes}"; then
2039 echo " Where do we find X Windows header files? ${x_includes}"
2040 else
2041 echo " Where do we find X Windows header files? Standard dirs"
2042 fi
2043 if test -n "${x_libraries}"; then
2044 echo " Where do we find X Windows libraries? ${x_libraries}"
2045 else
2046 echo " Where do we find X Windows libraries? Standard dirs"
2047 fi
2048
2049 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
2050 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
2051 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
2052 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
2053 echo " Does Emacs use -lungif? ${HAVE_GIF}"
2054 echo " Does Emacs use -lpng? ${HAVE_PNG}"
2055 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
2056 echo
2057
2058 # Remove any trailing slashes in these variables.
2059 changequote(, )dnl
2060 test "${prefix}" != NONE &&
2061 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2062 test "${exec_prefix}" != NONE &&
2063 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
2064 changequote([, ])dnl
2065
2066 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2067 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2068 leim/Makefile, [
2069
2070 ### Make the necessary directories, if they don't exist.
2071 for dir in etc lisp ; do
2072 test -d ${dir} || mkdir ${dir}
2073 done
2074
2075 # Build src/Makefile from ${srcdir}/src/Makefile.c
2076 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2077 # This must be done after src/config.h is built, since we rely on that file.
2078
2079 changequote(, )dnl The horror, the horror.
2080 # Now get this: Some word that is part of the ${srcdir} directory name
2081 # or the ${configuration} value might, just might, happen to be an
2082 # identifier like `sun4' or `i386' or something, and be predefined by
2083 # the C preprocessor to some helpful value like 1, or maybe the empty
2084 # string. Needless to say consequent macro substitutions are less
2085 # than conducive to the makefile finding the correct directory.
2086 undefs="`echo $top_srcdir $configuration $canonical |
2087 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
2088 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2089 `"
2090 changequote([, ])dnl
2091
2092 echo creating src/epaths.h
2093 make epaths-force
2094
2095 echo creating lib-src/Makefile
2096 ( cd lib-src
2097 rm -f junk.c junk1.c junk2.c
2098 sed -e '/start of cpp stuff/q' \
2099 < Makefile.c > junk1.c
2100 sed -e '1,/start of cpp stuff/d'\
2101 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
2102 < Makefile.c > junk.c
2103 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2104 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2105 cat junk1.c junk2.c > Makefile.new
2106 rm -f junk.c junk1.c junk2.c
2107 chmod 444 Makefile.new
2108 mv -f Makefile.new Makefile
2109 )
2110
2111 echo creating src/Makefile
2112 ( cd src
2113 rm -f junk.c junk1.c junk2.c
2114 sed -e '/start of cpp stuff/q' \
2115 < Makefile.c > junk1.c
2116 sed -e '1,/start of cpp stuff/d'\
2117 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
2118 < Makefile.c > junk.c
2119 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2120 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2121 cat junk1.c junk2.c > Makefile.new
2122 rm -f junk.c junk1.c junk2.c
2123 chmod 444 Makefile.new
2124 mv -f Makefile.new Makefile
2125 )
2126
2127 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
2128 echo creating src/.gdbinit
2129 echo source $top_srcdir/src/.gdbinit > src/.gdbinit
2130 fi
2131
2132 # This is how we know whether to re-run configure in certain cases.
2133 touch src/config.stamp
2134
2135 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])