code.delx.au - gnu-emacs/blob - lisp/tool-bar.el

   1 ;;; tool-bar.el --- setting up the tool bar
   2 ;;
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Dave Love <fx@gnu.org>
   7 ;; Keywords: mouse frames
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Provides `tool-bar-mode' to control display of the tool-bar and
  27 ;; bindings for the global tool bar with convenience functions
  28 ;; `tool-bar-add-item' and `tool-bar-add-item-from-menu'.
  29
  30 ;; The normal global binding for [tool-bar] (below) uses the value of
  31 ;; `tool-bar-map' as the actual keymap to define the tool bar.  Modes
  32 ;; may either bind items under the [tool-bar] prefix key of the local
  33 ;; map to add to the global bar or may set `tool-bar-map'
  34 ;; buffer-locally to override it.  (Some items are removed from the
  35 ;; global bar in modes which have `special' as their `mode-class'
  36 ;; property.)
  37
  38 ;; Todo: Somehow make tool bars easily customizable by the naive?
  39
  40 ;;; Code:
  41
  42 ;; The autoload cookie doesn't work when preloading.
  43 ;; Deleting it means invoking this command won't work
  44 ;; when you are on a tty.  I hope that won't cause too much trouble -- rms.
  45 (define-minor-mode tool-bar-mode
  46   "Toggle use of the tool bar.
  47 With numeric ARG, display the tool bar if and only if ARG is positive.
  48
  49 See `tool-bar-add-item' and `tool-bar-add-item-from-menu' for
  50 conveniently adding tool bar items."
  51   :init-value nil
  52   :global t
  53   :group 'mouse
  54   :group 'frames
  55   (if tool-bar-mode
  56       (progn
  57         (dolist (frame (frame-list))
  58           (if (display-graphic-p frame)
  59               (set-frame-parameter frame 'tool-bar-lines 1)))
  60         (tool-bar-setup))
  61     (modify-all-frames-parameters (list (cons 'tool-bar-lines 0)))))
  62
  63 ;;;###autoload
  64 ;; Used in the Show/Hide menu, to have the toggle reflect the current frame.
  65 (defun toggle-tool-bar-mode-from-frame (&optional arg)
  66   "Toggle tool bar on or off, based on the status of the current frame.
  67 See `tool-bar-mode' for more information."
  68   (interactive (list (or current-prefix-arg 'toggle)))
  69   (if (eq arg 'toggle)
  70       (tool-bar-mode (if (> (frame-parameter nil 'tool-bar-lines) 0) 0 1))
  71     (tool-bar-mode arg)))
  72
  73 ;;;###autoload
  74 ;; We want to pretend the toolbar by standard is on, as this will make
  75 ;; customize consider disabling the toolbar a customization, and save
  76 ;; that.  We could do this for real by setting :init-value above, but
  77 ;; that would turn on the toolbar in MS Windows where it is currently
  78 ;; useless, and it would overwrite disabling the tool bar from X
  79 ;; resources.  If anyone want to implement this in a cleaner way,
  80 ;; please do so.
  81 ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2002-02-21.
  82 (put 'tool-bar-mode 'standard-value '(t))
  83
  84 (defvar tool-bar-map (make-sparse-keymap)
  85   "Keymap for the tool bar.
  86 Define this locally to override the global tool bar.")
  87
  88 (global-set-key [tool-bar]
  89                 '(menu-item "tool bar" ignore
  90                             :filter tool-bar-make-keymap))
  91
  92 (declare-function image-mask-p "image.c" (spec &optional frame))
  93
  94 (defun tool-bar-make-keymap (&optional ignore)
  95   "Generate an actual keymap from `tool-bar-map'.
  96 Its main job is to figure out which images to use based on the display's
  97 color capability and based on the available image libraries."
  98   (mapcar (lambda (bind)
  99             (let (image-exp plist)
 100               (when (and (eq (car-safe (cdr-safe bind)) 'menu-item)
 101                          ;; For the format of menu-items, see node
 102                          ;; `Extended Menu Items' in the Elisp manual.
 103                          (setq plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 104                                              bind))
 105                          (setq image-exp (plist-get plist :image))
 106                          (consp image-exp)
 107                          (not (eq (car image-exp) 'image))
 108                          (fboundp (car image-exp)))
 109                 (if (not (display-images-p))
 110                     (setq bind nil)
 111                   (let ((image (eval image-exp)))
 112                     (unless (and image (image-mask-p image))
 113                       (setq image (append image '(:mask heuristic))))
 114                     (setq bind (copy-sequence bind)
 115                           plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 116                                         bind))
 117                     (plist-put plist :image image))))
 118               bind))
 119           tool-bar-map))
 120
 121 (defconst tool-bar-find-image-cache (make-hash-table :weakness t :test 'equal))
 122
 123 (defun tool-bar-find-image (specs)
 124   "Like `find-image' but with caching."
 125   (or (gethash specs tool-bar-find-image-cache)
 126       (puthash specs (find-image specs) tool-bar-find-image-cache)))
 127
 128 ;;;###autoload
 129 (defun tool-bar-add-item (icon def key &rest props)
 130   "Add an item to the tool bar.
 131 ICON names the image, DEF is the key definition and KEY is a symbol
 132 for the fake function key in the menu keymap.  Remaining arguments
 133 PROPS are additional items to add to the menu item specification.  See
 134 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 135
 136 ICON is the base name of a file containing the image to use.  The
 137 function will first try to use low-color/ICON.xpm if `display-color-cells'
 138 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 139 ICON.xbm, using `find-image'.
 140
 141 Use this function only to make bindings in the global value of `tool-bar-map'.
 142 To define items in any other map, use `tool-bar-local-item'."
 143   (apply 'tool-bar-local-item icon def key tool-bar-map props))
 144
 145 ;;;###autoload
 146 (defun tool-bar-local-item (icon def key map &rest props)
 147   "Add an item to the tool bar in map MAP.
 148 ICON names the image, DEF is the key definition and KEY is a symbol
 149 for the fake function key in the menu keymap.  Remaining arguments
 150 PROPS are additional items to add to the menu item specification.  See
 151 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 152
 153 ICON is the base name of a file containing the image to use.  The
 154 function will first try to use low-color/ICON.xpm if `display-color-cells'
 155 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 156 ICON.xbm, using `find-image'."
 157   (let* ((fg (face-attribute 'tool-bar :foreground))
 158          (bg (face-attribute 'tool-bar :background))
 159          (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
 160                         (if (eq bg 'unspecified) nil (list :background bg))))
 161          (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
 162          (xpm-lo-spec (if (> (display-color-cells) 256)
 163                           nil
 164                         (list :type 'xpm :file
 165                               (concat "low-color/" icon ".xpm"))))
 166          (pbm-spec (append (list :type 'pbm :file
 167                                  (concat icon ".pbm")) colors))
 168          (xbm-spec (append (list :type 'xbm :file
 169                                  (concat icon ".xbm")) colors))
 170          (image-exp `(tool-bar-find-image
 171                       (if (display-color-p)
 172                           ',(list xpm-lo-spec xpm-spec pbm-spec xbm-spec)
 173                         ',(list pbm-spec xbm-spec xpm-lo-spec xpm-spec)))))
 174
 175     (define-key-after map (vector key)
 176       `(menu-item ,(symbol-name key) ,def :image ,image-exp ,@props))))
 177
 178 ;;;###autoload
 179 (defun tool-bar-add-item-from-menu (command icon &optional map &rest props)
 180   "Define tool bar binding for COMMAND in keymap MAP using the given ICON.
 181 This makes a binding for COMMAND in `tool-bar-map', copying its
 182 binding from the menu bar in MAP (which defaults to `global-map'), but
 183 modifies the binding by adding an image specification for ICON.  It
 184 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 185 properties to add to the binding.
 186
 187 MAP must contain appropriate binding for `[menu-bar]' which holds a keymap.
 188
 189 Use this function only to make bindings in the global value of `tool-bar-map'.
 190 To define items in any other map, use `tool-bar-local-item-from-menu'."
 191   (apply 'tool-bar-local-item-from-menu command icon
 192          (default-value 'tool-bar-map) map props))
 193
 194 ;;;###autoload
 195 (defun tool-bar-local-item-from-menu (command icon in-map &optional from-map &rest props)
 196   "Define local tool bar binding for COMMAND using the given ICON.
 197 This makes a binding for COMMAND in IN-MAP, copying its binding from
 198 the menu bar in FROM-MAP (which defaults to `global-map'), but
 199 modifies the binding by adding an image specification for ICON.  It
 200 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 201 properties to add to the binding.
 202
 203 FROM-MAP must contain appropriate binding for `[menu-bar]' which
 204 holds a keymap."
 205   (unless from-map
 206     (setq from-map global-map))
 207   (let* ((menu-bar-map (lookup-key from-map [menu-bar]))
 208          (keys (where-is-internal command menu-bar-map))
 209          (fg (face-attribute 'tool-bar :foreground))
 210          (bg (face-attribute 'tool-bar :background))
 211          (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
 212                         (if (eq bg 'unspecified) nil (list :background bg))))
 213          (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
 214          (xpm-lo-spec (if (> (display-color-cells) 256)
 215                           nil
 216                         (list :type 'xpm :file
 217                               (concat "low-color/" icon ".xpm"))))
 218          (pbm-spec (append (list :type 'pbm :file
 219                                  (concat icon ".pbm")) colors))
 220          (xbm-spec (append (list :type 'xbm :file
 221                                  (concat icon ".xbm")) colors))
 222          (image-exp `(tool-bar-find-image
 223                       (if (display-color-p)
 224                           ',(list xpm-lo-spec xpm-spec pbm-spec xbm-spec)
 225                         ',(list pbm-spec xbm-spec xpm-lo-spec xpm-spec))))
 226          submap key)
 227     ;; We'll pick up the last valid entry in the list of keys if
 228     ;; there's more than one.
 229     (dolist (k keys)
 230       ;; We're looking for a binding of the command in a submap of
 231       ;; the menu bar map, so the key sequence must be two or more
 232       ;; long.
 233       (if (and (vectorp k)
 234                (> (length k) 1))
 235           (let ((m (lookup-key menu-bar-map (substring k 0 -1)))
 236                 ;; Last element in the bound key sequence:
 237                 (kk (aref k (1- (length k)))))
 238             (if (and (keymapp m)
 239                      (symbolp kk))
 240                 (setq submap m
 241                       key kk)))))
 242     (when (and (symbolp submap) (boundp submap))
 243       (setq submap (eval submap)))
 244     (let ((defn (assq key (cdr submap))))
 245       (if (eq (cadr defn) 'menu-item)
 246           (define-key-after in-map (vector key)
 247             (append (cdr defn) (list :image image-exp) props))
 248         (setq defn (cdr defn))
 249         (define-key-after in-map (vector key)
 250           (let ((rest (cdr defn)))
 251             ;; If the rest of the definition starts
 252             ;; with a list of menu cache info, get rid of that.
 253             (if (and (consp rest) (consp (car rest)))
 254                 (setq rest (cdr rest)))
 255             (append `(menu-item ,(car defn) ,rest)
 256                     (list :image image-exp) props)))))))
 257
 258 ;;; Set up some global items.  Additions/deletions up for grabs.
 259
 260 (defvar tool-bar-setup nil
 261   "Non-nil if the tool-bar has been set up by `tool-bar-setup'.")
 262
 263 (defun tool-bar-setup (&optional frame)
 264   (unless (or tool-bar-setup
 265               (null tool-bar-mode)
 266               ;; No-op if the initial frame is on a tty, deferring
 267               ;; action until called from x-create-frame-with-faces.
 268               ;; Tool-bar icons can depend on X settings, which are
 269               ;; initially unavailable in this case.
 270               (not (display-graphic-p frame)))
 271     (with-selected-frame (or frame (selected-frame))
 272       ;; People say it's bad to have EXIT on the tool bar, since users
 273       ;; might inadvertently click that button.
 274       ;;(tool-bar-add-item-from-menu 'save-buffers-kill-emacs "exit")
 275       (tool-bar-add-item-from-menu 'find-file "new")
 276       (tool-bar-add-item-from-menu 'menu-find-file-existing "open")
 277       (tool-bar-add-item-from-menu 'dired "diropen")
 278       (tool-bar-add-item-from-menu 'kill-this-buffer "close")
 279       (tool-bar-add-item-from-menu 'save-buffer "save" nil
 280                                    :visible '(or buffer-file-name
 281                                                  (not (eq 'special
 282                                                           (get major-mode
 283                                                                'mode-class)))))
 284       (tool-bar-add-item-from-menu 'write-file "saveas" nil
 285                                    :visible '(or buffer-file-name
 286                                                  (not (eq 'special
 287                                                           (get major-mode
 288                                                                'mode-class)))))
 289       (tool-bar-add-item-from-menu 'undo "undo" nil
 290                                    :visible '(not (eq 'special (get major-mode
 291                                                                     'mode-class))))
 292       (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [cut])
 293                                    "cut" nil
 294                                    :visible '(not (eq 'special (get major-mode
 295                                                                     'mode-class))))
 296       (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [copy])
 297                                    "copy")
 298       (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [paste])
 299                                    "paste" nil
 300                                    :visible '(not (eq 'special (get major-mode
 301                                                                     'mode-class))))
 302       (tool-bar-add-item-from-menu 'nonincremental-search-forward "search")
 303       ;;(tool-bar-add-item-from-menu 'ispell-buffer "spell")
 304
 305       ;; There's no icon appropriate for News and we need a command rather
 306       ;; than a lambda for Read Mail.
 307       ;;(tool-bar-add-item-from-menu 'compose-mail "mail/compose")
 308
 309       (tool-bar-add-item-from-menu 'print-buffer "print")
 310
 311       ;; tool-bar-add-item-from-menu itself operates on
 312       ;; (default-value 'tool-bar-map), but when we don't use that function,
 313       ;; we must explicitly operate on the default value.
 314
 315       (let ((tool-bar-map (default-value 'tool-bar-map)))
 316         (tool-bar-add-item "preferences" 'customize 'customize
 317                            :help "Edit preferences (customize)")
 318
 319         (tool-bar-add-item "help" (lambda ()
 320                                     (interactive)
 321                                     (popup-menu menu-bar-help-menu))
 322                            'help
 323                            :help "Pop up the Help menu"))
 324       (setq tool-bar-setup t))))
 325
 326
 327 (provide 'tool-bar)
 328 ;; arch-tag: 15f30f0a-d0d7-4d50-bbb7-f48fd0c8582f
 329 ;;; tool-bar.el ends here