code.delx.au - gnu-emacs/blob - lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Gerd Moellmann <gerd@acm.org>
   7 ;; Keywords: help c mouse tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl)) ; for case macro
  31
  32 \f
  33 ;;; Customizable settings
  34
  35 (defgroup tooltip nil
  36   "Customization group for the `tooltip' package."
  37   :group 'help
  38   :group 'gud
  39   :group 'mouse
  40   :group 'tools
  41   :version "21.1"
  42   :tag "Tool Tips")
  43
  44 (defcustom tooltip-delay 0.7
  45   "Seconds to wait before displaying a tooltip the first time."
  46   :tag "Delay"
  47   :type 'number
  48   :group 'tooltip)
  49
  50 (defcustom tooltip-short-delay 0.1
  51   "Seconds to wait between subsequent tooltips on different items."
  52   :tag "Short delay"
  53   :type 'number
  54   :group 'tooltip)
  55
  56 (defcustom tooltip-recent-seconds 1
  57   "Display tooltips if changing tip items within this many seconds.
  58 Do so after `tooltip-short-delay'."
  59   :tag "Recent seconds"
  60   :type 'number
  61   :group 'tooltip)
  62
  63 (defcustom tooltip-hide-delay 10
  64   "Hide tooltips automatically after this many seconds."
  65   :tag "Hide delay"
  66   :type 'number
  67   :group 'tooltip)
  68
  69 (defcustom tooltip-x-offset nil
  70   "X offset, in pixels, for the display of tooltips.
  71 The offset is relative to the position of the mouse.  It must
  72 be chosen so that the tooltip window doesn't contain the mouse
  73 when it pops up.  If the value is nil, the default offset is 5
  74 pixels.
  75
  76 If `tooltip-frame-parameters' includes the `left' parameter,
  77 the value of `tooltip-x-offset' is ignored."
  78   :tag "X offset"
  79   :type '(choice (const :tag "Default" nil)
  80                  (integer :tag "Offset" :value 1))
  81   :group 'tooltip)
  82
  83 (defcustom tooltip-y-offset nil
  84   "Y offset, in pixels, for the display of tooltips.
  85 The offset is relative to the position of the mouse.  It must
  86 be chosen so that the tooltip window doesn't contain the mouse
  87 when it pops up.  If the value is nil, the default offset is -10
  88 pixels.
  89
  90 If `tooltip-frame-parameters' includes the `top' parameter,
  91 the value of `tooltip-y-offset' is ignored."
  92   :tag "Y offset"
  93   :type '(choice (const :tag "Default" nil)
  94                  (integer :tag "Offset" :value 1))
  95   :group 'tooltip)
  96
  97 (defcustom tooltip-frame-parameters
  98   '((name . "tooltip")
  99     (internal-border-width . 5)
 100     (border-width . 1))
 101   "Frame parameters used for tooltips.
 102
 103 If `left' or `top' parameters are included, they specify the absolute
 104 position to pop up the tooltip."
 105   :type 'sexp
 106   :tag "Frame Parameters"
 107   :group 'tooltip)
 108
 109 (defface tooltip
 110   '((((class color))
 111      :background "lightyellow"
 112      :foreground "black"
 113      :inherit variable-pitch)
 114     (t
 115      :inherit variable-pitch))
 116   "Face for tooltips."
 117   :group 'tooltip)
 118
 119 (defcustom tooltip-gud-tips-p nil
 120   "*Non-nil means show tooltips in GUD sessions."
 121   :type 'boolean
 122   :tag "GUD"
 123   :group 'tooltip)
 124
 125 (defcustom tooltip-gud-modes '(gud-mode c-mode c++-mode fortran-mode)
 126   "List of modes for which to enable GUD tips."
 127   :type 'sexp
 128   :tag "GUD modes"
 129   :group 'tooltip)
 130
 131 (defcustom tooltip-gud-display
 132   '((eq (tooltip-event-buffer tooltip-gud-event)
 133         (marker-buffer gud-overlay-arrow-position)))
 134   "List of forms determining where GUD tooltips are displayed.
 135
 136 Forms in the list are combined with AND.  The default is to display
 137 only tooltips in the buffer containing the overlay arrow."
 138   :type 'sexp
 139   :tag "GUD buffers predicate"
 140   :group 'tooltip)
 141
 142 (defcustom tooltip-use-echo-area nil
 143   "Use the echo area instead of tooltip frames.
 144 This is only relevant GUD display, since otherwise it is equivalent to
 145 turning off Tooltip mode."
 146   :type 'boolean
 147   :tag "Use echo area"
 148   :group 'tooltip)
 149
 150 \f
 151 ;;; Variables that are not customizable.
 152
 153 (defvar tooltip-hook nil
 154   "Functions to call to display tooltips.
 155 Each function is called with one argument EVENT which is a copy of
 156 the last mouse movement event that occurred.")
 157
 158 (defvar tooltip-timeout-id nil
 159   "The id of the timeout started when Emacs becomes idle.")
 160
 161 (defvar tooltip-last-mouse-motion-event nil
 162   "A copy of the last mouse motion event seen.")
 163
 164 (defvar tooltip-hide-time nil
 165   "Time when the last tooltip was hidden.")
 166
 167 \f
 168 ;;; Event accessors
 169
 170 (defun tooltip-event-buffer (event)
 171   "Return the buffer over which event EVENT occurred.
 172 This might return nil if the event did not occur over a buffer."
 173   (let ((window (posn-window (event-end event))))
 174     (and window (window-buffer window))))
 175
 176 \f
 177 ;;; Switching tooltips on/off
 178
 179 ;; We don't set track-mouse globally because this is a big redisplay
 180 ;; problem in buffers having a pre-command-hook or such installed,
 181 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
 182 ;; set-buffer prevents redisplay optimizations, so every mouse motion
 183 ;; would be accompanied by a full redisplay.
 184
 185 ;;;###autoload
 186 (define-minor-mode tooltip-mode
 187   "Toggle Tooltip display.
 188 With ARG, turn tooltip mode on if and only if ARG is positive."
 189   :global t
 190   ;; If you change the :init-value below, you also need to change the
 191   ;; corresponding code in startup.el.
 192   :init-value (not (or noninteractive
 193                        emacs-quick-startup
 194                        (not (display-graphic-p))
 195                        (not (fboundp 'x-show-tip))))
 196   :group 'tooltip
 197   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
 198     (error "Sorry, tooltips are not yet available on this system"))
 199   (let ((hook-fn (if tooltip-mode 'add-hook 'remove-hook)))
 200     (funcall hook-fn 'change-major-mode-hook 'tooltip-change-major-mode)
 201     (tooltip-activate-mouse-motions-if-enabled)
 202     (funcall hook-fn 'pre-command-hook 'tooltip-hide)
 203     (funcall hook-fn 'tooltip-hook 'tooltip-gud-tips)
 204     (funcall hook-fn 'tooltip-hook 'tooltip-help-tips)
 205     (setq show-help-function (if tooltip-mode 'tooltip-show-help-function nil))
 206     ;; `ignore' is the default binding for mouse movements.
 207     (define-key global-map [mouse-movement]
 208       (if tooltip-mode 'tooltip-mouse-motion 'ignore))))
 209
 210 \f
 211 ;;; Timeout for tooltip display
 212
 213 (defun tooltip-delay ()
 214   "Return the delay in seconds for the next tooltip."
 215   (let ((delay tooltip-delay)
 216         (now (float-time)))
 217     (when (and tooltip-hide-time
 218                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 219       (setq delay tooltip-short-delay))
 220     delay))
 221
 222 (defun tooltip-cancel-delayed-tip ()
 223   "Disable the tooltip timeout."
 224   (when tooltip-timeout-id
 225     (disable-timeout tooltip-timeout-id)
 226     (setq tooltip-timeout-id nil)))
 227
 228 (defun tooltip-start-delayed-tip ()
 229   "Add a one-shot timeout to call function tooltip-timeout."
 230   (setq tooltip-timeout-id
 231         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 232
 233 (defun tooltip-timeout (object)
 234   "Function called when timer with id tooltip-timeout-id fires."
 235   (run-hook-with-args-until-success 'tooltip-hook
 236                                     tooltip-last-mouse-motion-event))
 237
 238 \f
 239 ;;; Reacting on mouse movements
 240
 241 (defun tooltip-change-major-mode ()
 242   "Function added to `change-major-mode-hook' when tooltip mode is on."
 243   (add-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled))
 244
 245 (defun tooltip-activate-mouse-motions-if-enabled ()
 246   "Reconsider for all buffers whether mouse motion events are desired."
 247   (remove-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled)
 248   (dolist (buffer (buffer-list))
 249     (save-excursion
 250       (set-buffer buffer)
 251       (if (and tooltip-mode
 252                tooltip-gud-tips-p
 253                (memq major-mode tooltip-gud-modes))
 254           (tooltip-activate-mouse-motions t)
 255         (tooltip-activate-mouse-motions nil)))))
 256
 257 (defvar tooltip-mouse-motions-active nil
 258   "Locally t in a buffer if tooltip processing of mouse motion is enabled.")
 259
 260 (defun tooltip-activate-mouse-motions (activatep)
 261   "Activate/deactivate mouse motion events for the current buffer.
 262 ACTIVATEP non-nil means activate mouse motion events."
 263   (if activatep
 264       (progn
 265         (make-local-variable 'tooltip-mouse-motions-active)
 266         (setq tooltip-mouse-motions-active t)
 267         (make-local-variable 'track-mouse)
 268         (setq track-mouse t))
 269     (when tooltip-mouse-motions-active
 270       (kill-local-variable 'tooltip-mouse-motions-active)
 271       (kill-local-variable 'track-mouse))))
 272
 273 (defun tooltip-mouse-motion (event)
 274   "Command handler for mouse movement events in `global-map'."
 275   (interactive "e")
 276   (tooltip-hide)
 277   (when (car (mouse-pixel-position))
 278     (setq tooltip-last-mouse-motion-event (copy-sequence event))
 279     (tooltip-start-delayed-tip)))
 280
 281 \f
 282 ;;; Displaying tips
 283
 284 (defun tooltip-set-param (alist key value)
 285   "Change the value of KEY in alist ALIST to VALUE.
 286 If there's no association for KEY in ALIST, add one, otherwise
 287 change the existing association.  Value is the resulting alist."
 288   (let ((param (assq key alist)))
 289     (if (consp param)
 290         (setcdr param value)
 291       (push (cons key value) alist))
 292     alist))
 293
 294 (defun tooltip-show (text)
 295   "Show a tooltip window displaying TEXT.
 296
 297 Text larger than `x-max-tooltip-size' (which see) is clipped.
 298
 299 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 300 parameters, they determine the x and y position where the tooltip
 301 is displayed.  Otherwise, the tooltip pops at offsets specified by
 302 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 303 position."
 304   (if tooltip-use-echo-area
 305       (message "%s" text)
 306     (condition-case error
 307         (let ((params (copy-sequence tooltip-frame-parameters))
 308               (fg (face-attribute 'tooltip :foreground))
 309               (bg (face-attribute 'tooltip :background)))
 310           (when (stringp fg)
 311             (setq params (tooltip-set-param params 'foreground-color fg))
 312             (setq params (tooltip-set-param params 'border-color fg)))
 313           (when (stringp bg)
 314             (setq params (tooltip-set-param params 'background-color bg)))
 315           (x-show-tip (propertize text 'face 'tooltip)
 316                       (selected-frame)
 317                       params
 318                       tooltip-hide-delay
 319                       tooltip-x-offset
 320                       tooltip-y-offset))
 321       (error
 322        (message "Error while displaying tooltip: %s" error)
 323        (sit-for 1)
 324        (message "%s" text)))))
 325
 326 (defun tooltip-hide (&optional ignored-arg)
 327   "Hide a tooltip, if one is displayed.
 328 Value is non-nil if tooltip was open."
 329   (tooltip-cancel-delayed-tip)
 330   (when (x-hide-tip)
 331     (setq tooltip-hide-time (float-time))))
 332
 333 \f
 334 ;;; Debugger-related functions
 335
 336 (defun tooltip-identifier-from-point (point)
 337   "Extract the identifier at POINT, if any.
 338 Value is nil if no identifier exists at point.  Identifier extraction
 339 is based on the current syntax table."
 340   (save-excursion
 341     (goto-char point)
 342     (let ((start (progn (skip-syntax-backward "w_") (point))))
 343       (unless (looking-at "[0-9]")
 344         (skip-syntax-forward "w_")
 345         (when (> (point) start)
 346           (buffer-substring start (point)))))))
 347
 348 (defmacro tooltip-region-active-p ()
 349   "Value is non-nil if the region is currently active."
 350   (if (string-match "^GNU" (emacs-version))
 351       `(and transient-mark-mode mark-active)
 352     `(region-active-p)))
 353
 354 (defun tooltip-expr-to-print (event)
 355   "Return an expression that should be printed for EVENT.
 356 If a region is active and the mouse is inside the region, print
 357 the region.  Otherwise, figure out the identifier around the point
 358 where the mouse is."
 359   (save-excursion
 360     (set-buffer (tooltip-event-buffer event))
 361     (let ((point (posn-point (event-end event))))
 362       (if (tooltip-region-active-p)
 363           (when (and (<= (region-beginning) point) (<= point (region-end)))
 364             (buffer-substring (region-beginning) (region-end)))
 365         (tooltip-identifier-from-point point)))))
 366
 367 (defun tooltip-process-prompt-regexp (process)
 368   "Return regexp matching the prompt of PROCESS at the end of a string.
 369 The prompt is taken from the value of COMINT-PROMPT-REGEXP in the buffer
 370 of PROCESS."
 371   (let ((prompt-regexp (save-excursion
 372                          (set-buffer (process-buffer process))
 373                          comint-prompt-regexp)))
 374     ;; Most start with `^' but the one for `sdb' cannot be easily
 375     ;; stripped.  Code the prompt for `sdb' fixed here.
 376     (if (= (aref prompt-regexp 0) ?^)
 377         (setq prompt-regexp (substring prompt-regexp 1))
 378       (setq prompt-regexp "\\*"))
 379     (concat "\n*" prompt-regexp "$")))
 380
 381 (defun tooltip-strip-prompt (process output)
 382   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 383   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 384     (save-match-data
 385       (when (string-match prompt-regexp output)
 386         (setq output (substring output 0 (match-beginning 0)))))
 387     output))
 388
 389 \f
 390 ;;; Tips for `gud'
 391
 392 (defvar tooltip-gud-original-filter nil
 393   "Process filter to restore after GUD output has been received.")
 394
 395 (defvar tooltip-gud-dereference nil
 396   "Non-nil means print expressions with a `*' in front of them.
 397 For C this would dereference a pointer expression.")
 398
 399 (defvar tooltip-gud-event nil
 400   "The mouse movement event that led to a tooltip display.
 401 This event can be examined by forms in TOOLTIP-GUD-DISPLAY.")
 402
 403 (defun tooltip-gud-toggle-dereference ()
 404   "Toggle whether tooltips should show `* expr' or `expr'."
 405   (interactive)
 406   (setq tooltip-gud-dereference (not tooltip-gud-dereference))
 407   (when (interactive-p)
 408     (message "Dereferencing is now %s."
 409              (if tooltip-gud-dereference "on" "off"))))
 410
 411 ; This will only display data that comes in one chunk.
 412 ; Larger arrays (say 400 elements) are displayed in
 413 ; the tootip incompletely and spill over into the gud buffer.
 414 ; Switching the process-filter creates timing problems and
 415 ; it may be difficult to do better. gdba in gdb-ui.el
 416 ; gets round this problem.
 417 (defun tooltip-gud-process-output (process output)
 418   "Process debugger output and show it in a tooltip window."
 419   (set-process-filter process tooltip-gud-original-filter)
 420   (tooltip-show (tooltip-strip-prompt process output)))
 421
 422 (defun tooltip-gud-print-command (expr)
 423   "Return a suitable command to print the expression EXPR.
 424 If TOOLTIP-GUD-DEREFERENCE is t, also prepend a `*' to EXPR."
 425   (when tooltip-gud-dereference
 426     (setq expr (concat "*" expr)))
 427   (case gud-minor-mode
 428     ((gdb gdba) (concat "server print " expr))
 429     (dbx (concat "print " expr))
 430     (xdb (concat "p " expr))
 431     (sdb (concat expr "/"))
 432     (perldb expr)))
 433
 434 (defun tooltip-gud-tips (event)
 435   "Show tip for identifier or selection under the mouse.
 436 The mouse must either point at an identifier or inside a selected
 437 region for the tip window to be shown.  If tooltip-gud-dereference is t,
 438 add a `*' in front of the printed expression.
 439
 440 This function must return nil if it doesn't handle EVENT."
 441   (let (process)
 442     (when (and (eventp event)
 443                tooltip-gud-tips-p
 444                (boundp 'gud-comint-buffer)
 445                (setq process (get-buffer-process gud-comint-buffer))
 446                (posn-point (event-end event))
 447                (progn (setq tooltip-gud-event event)
 448                       (eval (cons 'and tooltip-gud-display))))
 449       (let ((expr (tooltip-expr-to-print event)))
 450         (when expr
 451           (let ((cmd (tooltip-gud-print-command expr)))
 452             (unless (null cmd)         ; CMD can be nil if unknown debugger
 453               (case gud-minor-mode
 454                     (gdba (gdb-enqueue-input
 455                            (list  (concat cmd "\n") 'gdb-tooltip-print)))
 456                     (t
 457                      (setq tooltip-gud-original-filter (process-filter process))
 458                        (set-process-filter process 'tooltip-gud-process-output)
 459                        (gud-basic-call cmd)))
 460                     expr)))))))
 461
 462 (defun gdb-tooltip-print ()
 463   (tooltip-show
 464    (with-current-buffer (gdb-get-buffer 'gdb-partial-output-buffer)
 465      (let ((string (buffer-string)))
 466        ;; remove newline for tooltip-use-echo-area
 467        (substring string 0 (- (length string) 1))))))
 468
 469 \f
 470 ;;; Tooltip help.
 471
 472 (defvar tooltip-help-message nil
 473   "The last help message received via `tooltip-show-help-function'.")
 474
 475 (defun tooltip-show-help-function (msg)
 476   "Function installed as `show-help-function'.
 477 MSG is either a help string to display, or nil to cancel the display."
 478   (let ((previous-help tooltip-help-message))
 479     (setq tooltip-help-message msg)
 480     (cond ((null msg)
 481            ;; Cancel display.  This also cancels a delayed tip, if
 482            ;; there is one.
 483            (tooltip-hide))
 484           ((equal previous-help msg)
 485            ;; Same help as before (but possibly the mouse has moved).
 486            ;; Keep what we have.
 487            )
 488           (t
 489            ;; A different help.  Remove a previous tooltip, and
 490            ;; display a new one, with some delay.
 491            (tooltip-hide)
 492            (tooltip-start-delayed-tip)))))
 493
 494 (defun tooltip-help-tips (event)
 495   "Hook function to display a help tooltip.
 496 This is installed on the hook `tooltip-hook', which is run when
 497 the timer with ID `tooltip-timeout-id' fires.
 498 Value is non-nil if this function handled the tip."
 499   (when (stringp tooltip-help-message)
 500     (tooltip-show tooltip-help-message)
 501     t))
 502
 503 (provide 'tooltip)
 504
 505 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 506 ;;; tooltip.el ends here