code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             gtk3  )     val=gtk3 ;;
 141             * )
 142 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 143 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 144 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 145             ;;
 146           esac
 147           with_x_toolkit=$val
 148 ])
 149
 150 dnl _ON results in a '--without' option in the --help output, so
 151 dnl the help text should refer to "don't compile", etc.
 152 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 153 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 154 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 155 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 156 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 157 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 158
 159 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 160 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 161 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 162
 163 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 164 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 165 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 166 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 167
 168 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 169 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 170 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 171 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 172
 173 ## For the times when you want to build Emacs but don't have
 174 ## a suitable makeinfo, and can live without the manuals.
 175 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 176 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 177
 178 ## This is an option because I do not know if all info/man support
 179 ## compressed files, nor how to test if they do so.
 180 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 181 if test $with_compress_info = yes; then
 182    GZIP_INFO=yes
 183 else
 184    GZIP_INFO=
 185 fi
 186 AC_SUBST(GZIP_INFO)
 187
 188 AC_ARG_WITH([pkg-config-prog],dnl
 189 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 190                   [path to pkg-config for finding GTK and librsvg])])
 191 if test "X${with_pkg_config_prog}" != X; then
 192    if test "${with_pkg_config_prog}" != yes; then
 193       PKG_CONFIG="${with_pkg_config_prog}"
 194    fi
 195 fi
 196
 197 CRT_DIR=
 198 AC_ARG_WITH([crt-dir],dnl
 199 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 200 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 201 CRT_DIR="${with_crt_dir}"
 202
 203 AC_ARG_WITH([gnustep-conf],dnl
 204 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 205 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 206   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 207 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 208      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 209
 210 AC_ARG_ENABLE(ns-self-contained,
 211 [AS_HELP_STRING([--disable-ns-self-contained],
 212                 [disable self contained build under NeXTstep])],
 213    EN_NS_SELF_CONTAINED=$enableval,
 214    EN_NS_SELF_CONTAINED=yes)
 215
 216 AC_ARG_ENABLE(asserts,
 217 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 218       USE_XASSERTS=$enableval,
 219       USE_XASSERTS=no)
 220
 221 AC_ARG_ENABLE(maintainer-mode,
 222 [AS_HELP_STRING([--enable-maintainer-mode],
 223                 [enable make rules and dependencies not useful (and sometimes
 224                  confusing) to the casual installer])],
 225       USE_MAINTAINER_MODE=$enableval,
 226       USE_MAINTAINER_MODE=no)
 227 if test $USE_MAINTAINER_MODE = yes; then
 228   MAINT=
 229 else
 230   MAINT=#
 231 fi
 232 AC_SUBST(MAINT)
 233
 234 AC_ARG_ENABLE(locallisppath,
 235 [AS_HELP_STRING([--enable-locallisppath=PATH],
 236                 [directories Emacs should search for lisp files specific
 237                  to this site])],
 238 if test "${enableval}" = "no"; then
 239   locallisppath=
 240 elif test "${enableval}" != "yes"; then
 241   locallisppath=${enableval}
 242 fi)
 243
 244 AC_ARG_ENABLE(checking,
 245 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 246                 [enable expensive run-time checks.  With LIST,
 247                  enable only specific categories of checks.
 248                  Categories are: all,yes,no.
 249                  Flags are: stringbytes, stringoverrun, stringfreelist,
 250                  xmallocoverrun, conslist])],
 251 [ac_checking_flags="${enableval}"],[])
 252 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 253 for check in $ac_checking_flags
 254 do
 255         case $check in
 256         # these set all the flags to specific states
 257         yes)            ac_enable_checking=1 ;;
 258         no)             ac_enable_checking= ;
 259                         ac_gc_check_stringbytes= ;
 260                         ac_gc_check_string_overrun= ;
 261                         ac_gc_check_string_free_list= ;
 262                         ac_xmalloc_overrun= ;
 263                         ac_gc_check_cons_list= ;;
 264         all)            ac_enable_checking=1 ;
 265                         ac_gc_check_stringbytes=1 ;
 266                         ac_gc_check_string_overrun=1 ;
 267                         ac_gc_check_string_free_list=1 ;
 268                         ac_xmalloc_overrun=1 ;
 269                         ac_gc_check_cons_list=1 ;;
 270         # these enable particular checks
 271         stringbytes)    ac_gc_check_stringbytes=1 ;;
 272         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 273         stringfreelist) ac_gc_check_string_free_list=1 ;;
 274         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 275         conslist)       ac_gc_check_cons_list=1 ;;
 276         *)      AC_MSG_ERROR(unknown check category $check) ;;
 277         esac
 278 done
 279 IFS="$ac_save_IFS"
 280
 281 if test x$ac_enable_checking != x ; then
 282   AC_DEFINE(ENABLE_CHECKING, 1,
 283 [Enable expensive run-time checking of data types?])
 284 fi
 285 if test x$ac_gc_check_stringbytes != x ; then
 286   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 287 [Define this temporarily to hunt a bug.  If defined, the size of
 288    strings is redundantly recorded in sdata structures so that it can
 289    be compared to the sizes recorded in Lisp strings.])
 290 fi
 291 if test x$ac_gc_check_stringoverrun != x ; then
 292   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 293 [Define this to check for short string overrun.])
 294 fi
 295 if test x$ac_gc_check_string_free_list != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 297 [Define this to check the string free list.])
 298 fi
 299 if test x$ac_xmalloc_overrun != x ; then
 300   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 301 [Define this to check for malloc buffer overrun.])
 302 fi
 303 if test x$ac_gc_check_cons_list != x ; then
 304   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 305 [Define this to check for errors in cons list.])
 306 fi
 307
 308 AC_ARG_ENABLE(profiling,
 309 [AS_HELP_STRING([--enable-profiling],
 310                 [build emacs with profiling support.
 311                  This might not work on all platforms])],
 312 [ac_enable_profiling="${enableval}"],[])
 313 if test x$ac_enable_profiling != x ; then
 314    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 315    PROFILING_LDFLAGS="-pg"
 316 else
 317    PROFILING_CFLAGS=
 318    PROFILING_LDFLAGS=
 319 fi
 320
 321 AC_ARG_ENABLE(autodepend,
 322 [AS_HELP_STRING([--enable-autodepend],
 323                 [automatically generate dependencies to .h-files.
 324                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 325                  found])],
 326 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 327
 328 #### Make srcdir absolute, if it isn't already.  It's important to
 329 #### avoid running the path through pwd unnecessarily, since pwd can
 330 #### give you automounter prefixes, which can go away.  We do all this
 331 #### so Emacs can find its files when run uninstalled.
 332 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 333 unset CDPATH
 334 case "${srcdir}" in
 335   /* ) ;;
 336   . )
 337     ## We may be able to use the $PWD environment variable to make this
 338     ## absolute.  But sometimes PWD is inaccurate.
 339     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 340     ## but that tested only for a well-formed and valid PWD,
 341     ## it did not object when PWD was well-formed and valid but just wrong.
 342     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 343     then
 344       srcdir="$PWD"
 345     else
 346       srcdir="`(cd ${srcdir}; pwd)`"
 347     fi
 348   ;;
 349   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 350 esac
 351
 352 #### Check if the source directory already has a configured system in it.
 353 if test `pwd` != `(cd ${srcdir} && pwd)` \
 354    && test -f "${srcdir}/src/config.h" ; then
 355   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 356    as a build directory right now; it has been configured in its own
 357    right.  To configure in another directory as well, you MUST
 358    use GNU make.  If you do not have GNU make, then you must
 359    now do `make distclean' in ${srcdir},
 360    and then run $0 again.]])
 361 fi
 362
 363 #### Given the configuration name, set machfile and opsysfile to the
 364 #### names of the m/*.h and s/*.h files we should use.
 365
 366 ### Canonicalize the configuration name.
 367
 368 AC_CANONICAL_HOST
 369 canonical=$host
 370 configuration=${host_alias-${build_alias-$host}}
 371
 372 dnl This used to use changequote, but, apart from `changequote is evil'
 373 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 374 dnl the great gob of text.  Thus it's not processed for possible expansion.
 375 dnl Just make sure the brackets remain balanced.
 376 dnl
 377 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 378 dnl indicated by comments.
 379 dnl quotation begins
 380 [
 381
 382 ### If you add support for a new configuration, add code to this
 383 ### switch statement to recognize your configuration name and select
 384 ### the appropriate operating system and machine description files.
 385
 386 ### You would hope that you could choose an m/*.h file pretty much
 387 ### based on the machine portion of the configuration name, and an s/*.h
 388 ### file based on the operating system portion.  However, it turns out
 389 ### that each m/*.h file is pretty manufacturer-specific - for
 390 ### example mips.h is MIPS
 391 ### So we basically have to have a special case for each
 392 ### configuration name.
 393 ###
 394 ### As far as handling version numbers on operating systems is
 395 ### concerned, make sure things will fail in a fixable way.  If
 396 ### /etc/MACHINES doesn't say anything about version numbers, be
 397 ### prepared to handle anything reasonably.  If version numbers
 398 ### matter, be sure /etc/MACHINES says something about it.
 399
 400 machine='' opsys='' unported=no
 401 case "${canonical}" in
 402
 403   ## FreeBSD ports
 404   *-*-freebsd* )
 405     opsys=freebsd
 406     case "${canonical}" in
 407       alpha*)           machine=alpha ;;
 408       amd64-*|x86_64-*) machine=amdx86-64 ;;
 409       arm*)             machine=arm ;;
 410       ia64-*)           machine=ia64 ;;
 411       i[3456]86-*)      machine=intel386 ;;
 412       powerpc-*)        machine=macppc ;;
 413       sparc-*)          machine=sparc ;;
 414       sparc64-*)        machine=sparc ;;
 415     esac
 416   ;;
 417
 418   ## FreeBSD kernel + glibc based userland
 419   *-*-kfreebsd*gnu* )
 420     opsys=gnu-kfreebsd
 421     case "${canonical}" in
 422       alpha*)           machine=alpha ;;
 423       amd64-*|x86_64-*) machine=amdx86-64 ;;
 424       ia64-*)           machine=ia64 ;;
 425       i[3456]86-*)      machine=intel386 ;;
 426       powerpc-*)        machine=macppc ;;
 427       sparc-*)          machine=sparc ;;
 428       sparc64-*)        machine=sparc ;;
 429     esac
 430   ;;
 431
 432   ## NetBSD ports
 433   *-*-netbsd* )
 434     opsys=netbsd
 435     case "${canonical}" in
 436       alpha*)      machine=alpha ;;
 437       x86_64-*)    machine=amdx86-64 ;;
 438       arm-*)       machine=arm ;;
 439       hppa-*)      machine=hp800 ;;
 440       i[3456]86-*) machine=intel386 ;;
 441       m68k-*)      machine=m68k ;;
 442       powerpc-*)   machine=macppc ;;
 443       mips-*)      machine=mips ;;
 444       mipse[bl]-*) machine=mips ;;
 445       sparc*-)     machine=sparc ;;
 446       vax-*)       machine=vax ;;
 447     esac
 448   ;;
 449
 450   ## OpenBSD ports
 451   *-*-openbsd* )
 452     opsys=openbsd
 453     case "${canonical}" in
 454       alpha*)    machine=alpha ;;
 455       x86_64-*)  machine=amdx86-64 ;;
 456       arm-*)     machine=arm ;;
 457       hppa-*)    machine=hp800 ;;
 458       i386-*)    machine=intel386 ;;
 459       powerpc-*) machine=macppc ;;
 460       sparc*)    machine=sparc ;;
 461       vax-*)     machine=vax ;;
 462     esac
 463   ;;
 464
 465   alpha*-*-linux-gnu* )
 466     machine=alpha opsys=gnu-linux
 467   ;;
 468
 469   arm*-*-linux-gnu* )
 470     machine=arm opsys=gnu-linux
 471   ;;
 472
 473   ## Apple Darwin / Mac OS X
 474   *-apple-darwin* )
 475     case "${canonical}" in
 476       i[3456]86-* )  machine=intel386 ;;
 477       powerpc-* )    machine=macppc ;;
 478       x86_64-* )     machine=amdx86-64 ;;
 479       * )            unported=yes ;;
 480     esac
 481     opsys=darwin
 482     # Define CPP as follows to make autoconf work correctly.
 483     CPP="${CC-cc} -E -no-cpp-precomp"
 484     # Use fink packages if available.
 485     if test -d /sw/include && test -d /sw/lib; then
 486       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 487       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 488       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 489     fi
 490   ;;
 491
 492   ## HP 9000 series 700 and 800, running HP/UX
 493   hppa*-hp-hpux10.2* )
 494     machine=hp800 opsys=hpux10-20
 495   ;;
 496   hppa*-hp-hpux1[1-9]* )
 497     machine=hp800 opsys=hpux11
 498     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 499   ;;
 500
 501   hppa*-*-linux-gnu* )
 502     machine=hp800 opsys=gnu-linux
 503   ;;
 504
 505   ## IBM machines
 506   s390-*-linux-gnu* )
 507     machine=ibms390 opsys=gnu-linux
 508   ;;
 509   s390x-*-linux-gnu* )
 510     machine=ibms390x opsys=gnu-linux
 511   ;;
 512   rs6000-ibm-aix4.[23]* )
 513     machine=ibmrs6000 opsys=aix4-2
 514   ;;
 515   powerpc-ibm-aix4.[23]*  )
 516     machine=ibmrs6000 opsys=aix4-2
 517   ;;
 518   rs6000-ibm-aix[56]* )
 519     machine=ibmrs6000 opsys=aix4-2
 520   ;;
 521   powerpc-ibm-aix[56]*  )
 522     machine=ibmrs6000 opsys=aix4-2
 523   ;;
 524
 525   ## Macintosh PowerPC
 526   powerpc*-*-linux-gnu* )
 527     machine=macppc opsys=gnu-linux
 528   ;;
 529
 530   ## Silicon Graphics machines
 531   ## Iris 4D
 532   mips-sgi-irix6.5 )
 533     machine=iris4d opsys=irix6-5
 534     # Without defining _LANGUAGE_C, things get masked out in the headers
 535     # so that, for instance, grepping for `free' in stdlib.h fails and
 536     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 537     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 538     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 539   ;;
 540
 541   ## Suns
 542   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 543     machine=sparc opsys=gnu-linux
 544   ;;
 545
 546   *-sun-solaris* \
 547     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 548     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 549     case "${canonical}" in
 550       i[3456]86-*-* )     machine=intel386 ;;
 551       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 552       sparc* )          machine=sparc ;;
 553       * )               unported=yes ;;
 554     esac
 555     case "${canonical}" in
 556       *-sunos5.6* | *-solaris2.6* )
 557                 opsys=sol2-6
 558                 NON_GNU_CPP=/usr/ccs/lib/cpp
 559                 RANLIB="ar -ts"
 560                 ;;
 561       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 562                 opsys=sol2-6
 563                 emacs_check_sunpro_c=yes
 564                 NON_GNU_CPP=/usr/ccs/lib/cpp
 565                 ;;
 566       *-sunos5* | *-solaris* )
 567                 opsys=sol2-10
 568                 emacs_check_sunpro_c=yes
 569                 NON_GNU_CPP=/usr/ccs/lib/cpp
 570                 ;;
 571     esac
 572     ## Watch out for a compiler that we know will not work.
 573     case "${canonical}" in
 574      *-solaris* | *-sunos5* )
 575                 if [ "x$CC" = x/usr/ucb/cc ]; then
 576                   ## /usr/ucb/cc doesn't work;
 577                   ## we should find some other compiler that does work.
 578                   unset CC
 579                 fi
 580                 ;;
 581       *) ;;
 582     esac
 583   ;;
 584
 585   ## IA-64
 586   ia64*-*-linux* )
 587     machine=ia64 opsys=gnu-linux
 588   ;;
 589
 590   ## Intel 386 machines where we don't care about the manufacturer.
 591   i[3456]86-*-* )
 592     machine=intel386
 593     case "${canonical}" in
 594       *-cygwin )                opsys=cygwin ;;
 595       *-darwin* )               opsys=darwin
 596                                 CPP="${CC-cc} -E -no-cpp-precomp"
 597                                 ;;
 598       *-linux-gnu* )            opsys=gnu-linux ;;
 599       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 600       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 601       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 602       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 603     esac
 604   ;;
 605
 606   ## m68k Linux-based GNU system
 607   m68k-*-linux-gnu* )
 608     machine=m68k opsys=gnu-linux
 609   ;;
 610
 611   ## Mips Linux-based GNU system
 612   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 613     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 614     machine=mips opsys=gnu-linux
 615   ;;
 616
 617   ## AMD x86-64 Linux-based GNU system
 618   x86_64-*-linux-gnu* )
 619     machine=amdx86-64 opsys=gnu-linux
 620   ;;
 621
 622   ## Tensilica Xtensa Linux-based GNU system
 623   xtensa*-*-linux-gnu* )
 624     machine=xtensa opsys=gnu-linux
 625     ;;
 626
 627   ## SuperH Linux-based GNU system
 628   sh[34]*-*-linux-gnu* )
 629     machine=sh3 opsys=gnu-linux
 630   ;;
 631
 632   * )
 633     unported=yes
 634   ;;
 635 esac
 636
 637 ### If the code above didn't choose an operating system, just choose
 638 ### an operating system based on the configuration name.  You really
 639 ### only want to use this when you have no idea what the right
 640 ### operating system is; if you know what operating systems a machine
 641 ### runs, it's cleaner to make it explicit in the case statement
 642 ### above.
 643 if test x"${opsys}" = x; then
 644   case "${canonical}" in
 645     *-gnu* )                            opsys=gnu ;;
 646     * )
 647       unported=yes
 648     ;;
 649   esac
 650 fi
 651
 652 ]
 653 dnl quotation ends
 654
 655 if test $unported = yes; then
 656   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 657 Check `etc/MACHINES' for recognized configuration names.])
 658 fi
 659
 660 machfile="m/${machine}.h"
 661 opsysfile="s/${opsys}.h"
 662
 663
 664 #### Choose a compiler.
 665 test -n "$CC" && cc_specified=yes
 666
 667 # Save the value of CFLAGS that the user specified.
 668 SPECIFIED_CFLAGS="$CFLAGS"
 669
 670 dnl Sets GCC=yes if using gcc.
 671 AC_PROG_CC
 672
 673 # On Suns, sometimes $CPP names a directory.
 674 if test -n "$CPP" && test -d "$CPP"; then
 675   CPP=
 676 fi
 677
 678 ## If not using gcc, and on Solaris, and no CPP specified, see if
 679 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 680 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 681  test x"$CPP" = x; then
 682   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 683   AC_CACHE_VAL(emacs_cv_sunpro_c,
 684   [AC_TRY_LINK([],
 685 [#ifndef __SUNPRO_C
 686 fail;
 687 #endif
 688 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 689   AC_MSG_RESULT($emacs_cv_sunpro_c)
 690
 691   if test x"$emacs_cv_sunpro_c" = xyes; then
 692     NON_GNU_CPP="$CC -E -Xs"
 693   fi
 694 fi
 695
 696 #### Some systems specify a CPP to use unless we are using GCC.
 697 #### Now that we know whether we are using GCC, we can decide whether
 698 #### to use that one.
 699 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 700 then
 701   CPP="$NON_GNU_CPP"
 702 fi
 703
 704 #### Some systems specify a CC to use unless we are using GCC.
 705 #### Now that we know whether we are using GCC, we can decide whether
 706 #### to use that one.
 707 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 708   test x$cc_specified != xyes
 709 then
 710   CC="$NON_GNU_CC"
 711 fi
 712
 713 if test x$GCC = xyes; then
 714   C_OPTIMIZE_SWITCH=-O2
 715   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 716 else
 717   dnl FIXME? unused.
 718   C_OPTIMIZE_SWITCH=-O
 719   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 720 fi
 721
 722 dnl checks for Unix variants
 723 AC_USE_SYSTEM_EXTENSIONS
 724
 725 ### Use -Wno-pointer-sign if the compiler supports it
 726 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 727 SAVE_CFLAGS="$CFLAGS"
 728 CFLAGS="$CFLAGS -Wno-pointer-sign"
 729 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 730 if test $has_option = yes; then
 731    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 732 fi
 733 AC_MSG_RESULT($has_option)
 734 CFLAGS="$SAVE_CFLAGS"
 735 unset has_option
 736 unset SAVE_CFLAGS
 737
 738 ### Use -Wdeclaration-after-statement if the compiler supports it
 739 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 740 SAVE_CFLAGS="$CFLAGS"
 741 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 742 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 743 if test $has_option = yes; then
 744    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 745 fi
 746 AC_MSG_RESULT($has_option)
 747 CFLAGS="$SAVE_CFLAGS"
 748 unset has_option
 749 unset SAVE_CFLAGS
 750
 751 #### Some other nice autoconf tests.
 752
 753 dnl checks for programs
 754 AC_PROG_CPP
 755 AC_PROG_INSTALL
 756 if test "x$RANLIB" = x; then
 757   AC_PROG_RANLIB
 758 fi
 759
 760 ## Although we're running on an amd64 kernel, we're actually compiling for
 761 ## the x86 architecture.  The user should probably have provided an
 762 ## explicit --build to `configure', but if everything else than the kernel
 763 ## is running in i386 mode, we can help them out.
 764 if test "$machine" = "amdx86-64"; then
 765   AC_CHECK_DECL([i386])
 766   if test "$ac_cv_have_decl_i386" = "yes"; then
 767     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 768     machine=intel386
 769     machfile="m/${machine}.h"
 770   fi
 771 fi
 772
 773 AC_PATH_PROG(INSTALL_INFO, install-info)
 774 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 775 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 776 dnl Don't use GZIP, which is used by gzip for additional parameters.
 777 AC_PATH_PROG(GZIP_PROG, gzip)
 778
 779
 780 ## Need makeinfo >= 4.6 (?) to build the manuals.
 781 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 782 dnl By this stage, configure has already checked for egrep and set EGREP,
 783 dnl or exited with an error if no egrep was found.
 784 if test "$MAKEINFO" != "no" && \
 785   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 786    MAKEINFO=no
 787 fi
 788
 789 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 790 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 791 ## therefore in the category of "special tools" not normally required, which
 792 ## configure does not have to check for (eg autoconf itself).
 793 ## In a Bazaar checkout on the other hand, the manuals are not included.
 794 ## So makeinfo is a requirement to build from Bazaar, and configure
 795 ## should test for it as it does for any other build requirement.
 796 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 797 ## with pre-built manuals, from a Bazaar checkout.
 798 if test "$MAKEINFO" = "no"; then
 799   if test "x${with_makeinfo}" = "xno"; then
 800     MAKEINFO=off
 801   elif test ! -e $srcdir/info/emacs; then
 802     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 803 source tree does not seem to have pre-built manuals in the `info' directory.
 804 Either install a suitable version of makeinfo, or re-run configure
 805 with the `--without-makeinfo' option to build without the manuals.] )
 806   fi
 807 fi
 808
 809 dnl Add our options to ac_link now, after it is set up.
 810
 811 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 812 then
 813   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 814 fi
 815
 816 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 817 then
 818   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 819 fi
 820
 821 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 822 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 823 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 824 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 825 dnl if not built to support GNU ld.
 826
 827 late_LDFLAGS=$LDFLAGS
 828 if test "$GCC" = yes; then
 829   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 830 else
 831   LDFLAGS="$LDFLAGS -znocombreloc"
 832 fi
 833
 834 AC_MSG_CHECKING([for -znocombreloc])
 835 AC_LINK_IFELSE([main(){return 0;}],
 836   [AC_MSG_RESULT(yes)],
 837   LDFLAGS=$late_LDFLAGS
 838   [AC_MSG_RESULT(no)])
 839
 840 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 841
 842
 843 # The value of CPP is a quoted variable reference, so we need to do this
 844 # to get its actual value...
 845 CPP=`eval "echo $CPP"`
 846
 847
 848 ### First figure out CFLAGS (which we use for running the compiler here)
 849 ### and REAL_CFLAGS (which we use for real compilation).
 850 ### The two are the same except when using GCC where we might use
 851 ### extra warning and profiling flags.
 852
 853 ### If the CFLAGS env var is specified, we use that value
 854 ### instead of the default.
 855
 856 dnl Note AC_PROG_CC sets CFLAGS to -g -O2 for gcc anyway.
 857 if test "x$SPECIFIED_CFLAGS" = x; then
 858   CFLAGS="-g $C_OPTIMIZE_SWITCH"
 859   if test x$GCC = xyes; then
 860     REAL_CFLAGS="$CFLAGS $C_WARNINGS_SWITCH $PROFILING_CFLAGS"
 861   else
 862     REAL_CFLAGS="$CFLAGS"
 863   fi
 864 else
 865   REAL_CFLAGS="$CFLAGS"
 866 fi
 867
 868
 869 dnl Not used by any currently supported platform.
 870 dnl The function dump-emacs will not be defined and temacs will do
 871 dnl (load "loadup") automatically unless told otherwise.
 872 CANNOT_DUMP=no
 873 case "$opsys" in
 874   your-opsys-here)
 875    CANNOT_DUMP=yes
 876    AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 877   ;;
 878 esac
 879 AC_SUBST(CANNOT_DUMP)
 880
 881
 882 UNEXEC_OBJ=unexelf.o
 883 case "$opsys" in
 884   aix4-2)
 885    UNEXEC_OBJ=unexaix.o
 886    ;;
 887   cygwin)
 888    UNEXEC_OBJ=unexcw.o
 889    ;;
 890   darwin)
 891    UNEXEC_OBJ=unexmacosx.o
 892    ;;
 893   hpux10-20 | hpux11)
 894    UNEXEC_OBJ=unexhp9k800.o
 895    ;;
 896   sol2-10)
 897    # Use the Solaris dldump() function, called from unexsol.c, to dump
 898    # emacs, instead of the generic ELF dump code found in unexelf.c.
 899    # The resulting binary has a complete symbol table, and is better
 900    # for debugging and other observability tools (debuggers, pstack, etc).
 901    #
 902    # If you encounter a problem using dldump(), please consider sending
 903    # a message to the OpenSolaris tools-linking mailing list:
 904    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 905    #
 906    # It is likely that dldump() works with older Solaris too, but this has
 907    # not been tested, so for now this change is for Solaris 10 or newer.
 908    UNEXEC_OBJ=unexsol.o
 909    ;;
 910 esac
 911
 912 LD_SWITCH_SYSTEM=
 913 case "$opsys" in
 914   freebsd)
 915    ## Let `ld' find image libs and similar things in /usr/local/lib.
 916    ## The system compiler, GCC, has apparently been modified to not
 917    ## look there, contrary to what a stock GCC would do.
 918    LD_SWITCH_SYSTEM=-L/usr/local/lib
 919    ;;
 920
 921   gnu-linux)
 922    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 923    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 924    ;;
 925
 926   netbsd)
 927    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 928    ;;
 929
 930   openbsd)
 931    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 932    ## otherwise Emacs dumps core on elf systems.
 933    LD_SWITCH_SYSTEM="-Z"
 934    ;;
 935 esac
 936 AC_SUBST(LD_SWITCH_SYSTEM)
 937
 938 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 939
 940 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 941 ## which has not been defined yet.  When this was handled with cpp,
 942 ## it was expanded to null when configure sourced the s/*.h file.
 943 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 944 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 945 ## (or somesuch), but because it is supposed to go at the _front_
 946 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 947 ## Compare with the gnu-linux case below, which added to the end
 948 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 949 ## LD_SWITCH_SYSTEM_TEMACS.
 950 case "$opsys" in
 951   netbsd|openbsd)
 952    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 953    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 954 esac
 955
 956
 957 C_SWITCH_MACHINE=
 958 if test "$machine" = "alpha"; then
 959   AC_CHECK_DECL([__ELF__])
 960   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 961     ## With ELF, make sure that all common symbols get allocated to in the
 962     ## data section.  Otherwise, the dump of temacs may miss variables in
 963     ## the shared library that have been initialized.  For example, with
 964     ## GNU libc, __malloc_initialized would normally be resolved to the
 965     ## shared library's .bss section, which is fatal.
 966     if test "x$GCC" = "xyes"; then
 967       C_SWITCH_MACHINE="-fno-common"
 968     else
 969       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 970     fi
 971   else
 972     UNEXEC_OBJ=unexalpha.o
 973   fi
 974 fi
 975 AC_SUBST(C_SWITCH_MACHINE)
 976
 977 AC_SUBST(UNEXEC_OBJ)
 978
 979 C_SWITCH_SYSTEM=
 980 ## Some programs in src produce warnings saying certain subprograms
 981 ## are too complex and need a MAXMEM value greater than 2000 for
 982 ## additional optimization.  --nils@exp-math.uni-essen.de
 983 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 984   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 985 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 986 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 987 AC_SUBST(C_SWITCH_SYSTEM)
 988
 989
 990 LIBS_SYSTEM=
 991 case "$opsys" in
 992   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 993   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 994
 995   freebsd) LIBS_SYSTEM="-lutil" ;;
 996
 997   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 998
 999   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1000
1001   ## Motif needs -lgen.
1002   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1003 esac
1004 AC_SUBST(LIBS_SYSTEM)
1005
1006
1007 ### Make sure subsequent tests use flags consistent with the build flags.
1008
1009 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1010   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1011 else
1012   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1013 fi
1014
1015 dnl For AC_FUNC_GETLOADAVG, at least:
1016 AC_CONFIG_LIBOBJ_DIR(src)
1017
1018 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1019 AC_SYS_LARGEFILE
1020
1021
1022 ## If user specified a crt-dir, use that unconditionally.
1023 if test "X$CRT_DIR" = "X"; then
1024
1025   case "$canonical" in
1026     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1027     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1028     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1029     ## For anything else (eg /usr/lib32), it is up the user to specify
1030     ## the location (bug#5655).
1031     ## Test for crtn.o, not just the directory, because sometimes the
1032     ## directory exists but does not have the relevant files (bug#1287).
1033     ## FIXME better to test for binary compatibility somehow.
1034     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1035     ;;
1036
1037     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1038   esac
1039
1040   case "$opsys" in
1041     hpux10-20) CRT_DIR=/lib ;;
1042   esac
1043
1044   ## Default is /usr/lib.
1045   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1046
1047 else
1048
1049   ## Some platforms don't use any of these files, so it is not
1050   ## appropriate to put this test outside the if block.
1051   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1052     AC_MSG_ERROR([crt*.o not found in specified location.])
1053
1054 fi
1055
1056 AC_SUBST(CRT_DIR)
1057
1058 LIB_MATH=-lm
1059 LIB_STANDARD=
1060 START_FILES=
1061
1062 case $opsys in
1063   cygwin )
1064     LIB_MATH=
1065     START_FILES='ecrt0.o'
1066     ;;
1067   darwin )
1068     ## Adding -lm confuses the dynamic linker, so omit it.
1069     LIB_MATH=
1070     START_FILES='pre-crt0.o'
1071     ;;
1072   freebsd )
1073     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1074     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1075     ;;
1076   gnu-linux | gnu-kfreebsd )
1077     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1078     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1079     ;;
1080   hpux10-20 | hpux11 )
1081     LIB_STANDARD=-lc
1082     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1083     ;;
1084   netbsd | openbsd )
1085     if test -f $CRT_DIR/crti.o; then
1086         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1087         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1088     else
1089         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1090         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1091     fi
1092     ;;
1093 esac
1094
1095 AC_SUBST(LIB_MATH)
1096 AC_SUBST(START_FILES)
1097
1098 dnl This function definition taken from Gnome 2.0
1099 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1100 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1101 dnl also defines GSTUFF_PKG_ERRORS on error
1102 AC_DEFUN([PKG_CHECK_MODULES], [
1103   succeeded=no
1104
1105   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1106
1107   if test "$PKG_CONFIG" = "no" ; then
1108      ifelse([$4], , [AC_MSG_ERROR([
1109       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1110   else
1111      PKG_CONFIG_MIN_VERSION=0.9.0
1112      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1113         AC_MSG_CHECKING(for $2)
1114
1115         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1116             AC_MSG_RESULT(yes)
1117             succeeded=yes
1118
1119             AC_MSG_CHECKING($1_CFLAGS)
1120             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1121             AC_MSG_RESULT($$1_CFLAGS)
1122
1123             AC_MSG_CHECKING($1_LIBS)
1124             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1125             AC_MSG_RESULT($$1_LIBS)
1126         else
1127             AC_MSG_RESULT(no)
1128             $1_CFLAGS=""
1129             $1_LIBS=""
1130             ## If we have a custom action on failure, don't print errors, but
1131             ## do set a variable so people can do so.
1132             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1133             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1134         fi
1135
1136         AC_SUBST($1_CFLAGS)
1137         AC_SUBST($1_LIBS)
1138      else
1139         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1140         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1141      fi
1142   fi
1143
1144   if test $succeeded = yes; then
1145      ifelse([$3], , :, [$3])
1146   else
1147      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1148   fi
1149 ])
1150
1151
1152 if test "${with_sound}" != "no"; then
1153   # Sound support for GNU/Linux and the free BSDs.
1154   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1155     have_sound_header=yes)
1156   # Emulation library used on NetBSD.
1157   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1158   AC_SUBST(LIBSOUND)
1159
1160   ALSA_REQUIRED=1.0.0
1161   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1162   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1163   if test $HAVE_ALSA = yes; then
1164     SAVE_CFLAGS="$CFLAGS"
1165     SAVE_LDFLAGS="$LDFLAGS"
1166     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1167     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1168     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1169                     emacs_alsa_normal=yes,
1170                     emacs_alsa_normal=no)
1171     if test "$emacs_alsa_normal" != yes; then
1172       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1173                      [snd_lib_error_set_handler (0);],
1174                      emacs_alsa_subdir=yes,
1175                      emacs_alsa_subdir=no)
1176       if test "$emacs_alsa_subdir" != yes; then
1177         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1178       fi
1179       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1180     fi
1181
1182     CFLAGS="$SAVE_CFLAGS"
1183     LDFLAGS="$SAVE_LDFLAGS"
1184     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1185     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1186     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1187   fi
1188
1189   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1190   dnl compiles only on the specified platforms.  For others, it
1191   dnl probably doesn't make sense to try.
1192   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1193      case "$opsys" in
1194        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1195        gnu-linux|freebsd|netbsd)
1196          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1197          ;;
1198      esac
1199   fi
1200
1201   AC_SUBST(CFLAGS_SOUND)
1202 fi
1203
1204 dnl checks for header files
1205 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1206   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1207   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1208   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1209   sys/utsname.h pwd.h utmp.h)
1210
1211 AC_MSG_CHECKING(if personality LINUX32 can be set)
1212 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1213                emacs_cv_personality_linux32=yes,
1214                emacs_cv_personality_linux32=no)
1215 AC_MSG_RESULT($emacs_cv_personality_linux32)
1216
1217 if test $emacs_cv_personality_linux32 = yes; then
1218   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1219             [Define to 1 if personality LINUX32 can be set.])
1220 fi
1221
1222 dnl On Solaris 8 there's a compilation warning for term.h because
1223 dnl it doesn't define `bool'.
1224 AC_CHECK_HEADERS(term.h, , , -)
1225 AC_HEADER_STDC
1226 AC_HEADER_TIME
1227 AC_CHECK_DECLS([sys_siglist])
1228 if test $ac_cv_have_decl_sys_siglist != yes; then
1229   # For Tru64, at least:
1230   AC_CHECK_DECLS([__sys_siglist])
1231   if test $ac_cv_have_decl___sys_siglist = yes; then
1232     AC_DEFINE(sys_siglist, __sys_siglist,
1233               [Define to any substitute for sys_siglist.])
1234   fi
1235 fi
1236 AC_HEADER_SYS_WAIT
1237
1238 dnl Some systems have utime.h but don't declare the struct anyplace.
1239 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1240 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1241 #include <sys/time.h>
1242 #include <time.h>
1243 #else
1244 #ifdef HAVE_SYS_TIME_H
1245 #include <sys/time.h>
1246 #else
1247 #include <time.h>
1248 #endif
1249 #endif
1250 #ifdef HAVE_UTIME_H
1251 #include <utime.h>
1252 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1253   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1254 if test $emacs_cv_struct_utimbuf = yes; then
1255   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1256 fi
1257
1258 dnl checks for typedefs
1259 AC_TYPE_SIGNAL
1260
1261 dnl Check for speed_t typedef.
1262 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1263   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1264     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1265 if test $emacs_cv_speed_t = yes; then
1266   AC_DEFINE(HAVE_SPEED_T, 1,
1267            [Define to 1 if `speed_t' is declared by <termios.h>.])
1268 fi
1269
1270 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1271 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1272 #include <sys/time.h>
1273 #include <time.h>
1274 #else
1275 #ifdef HAVE_SYS_TIME_H
1276 #include <sys/time.h>
1277 #else
1278 #include <time.h>
1279 #endif
1280 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1281   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1282 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1283 if test $emacs_cv_struct_timeval = yes; then
1284   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1285 fi
1286
1287 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1288 AC_TRY_COMPILE([#include <math.h>],
1289 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1290   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1291 HAVE_EXCEPTION=$emacs_cv_struct_exception
1292 if test $emacs_cv_struct_exception != yes; then
1293   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1294 fi
1295
1296 AC_CHECK_HEADERS(sys/socket.h)
1297 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1298 #if HAVE_SYS_SOCKET_H
1299 #include <sys/socket.h>
1300 #endif])
1301
1302 dnl checks for structure members
1303 AC_STRUCT_TM
1304 AC_STRUCT_TIMEZONE
1305 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1306                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1307                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1308                 [#include <time.h>])
1309 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1310                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1311                   struct ifreq.ifr_addr], , ,
1312                  [AC_INCLUDES_DEFAULT
1313 #if HAVE_SYS_SOCKET_H
1314 #include <sys/socket.h>
1315 #endif
1316 #if HAVE_NET_IF_H
1317 #include <net/if.h>
1318 #endif])
1319
1320 dnl checks for compiler characteristics
1321
1322 dnl Testing __STDC__ to determine prototype support isn't good enough.
1323 dnl DEC C, for instance, doesn't define it with default options, and
1324 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1325 dnl and void *.
1326 AC_C_PROTOTYPES
1327 AC_C_VOLATILE
1328 AC_C_CONST
1329 dnl This isn't useful because we can't turn on use of `inline' unless
1330 dnl the compiler groks `extern inline'.
1331 dnl AC_C_INLINE
1332 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1333   [AC_TRY_COMPILE(, [void * foo;],
1334                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1335 if test $emacs_cv_void_star = yes; then
1336   AC_DEFINE(POINTER_TYPE, void)
1337 else
1338   AC_DEFINE(POINTER_TYPE, char)
1339 fi
1340 AH_TEMPLATE(POINTER_TYPE,
1341             [Define as `void' if your compiler accepts `void *'; otherwise
1342              define as `char'.])dnl
1343
1344
1345
1346 dnl This could be used for targets which can have both byte sexes.
1347 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1348 dnl AC_C_BIGENDIAN
1349
1350 dnl check for Make feature
1351 AC_PROG_MAKE_SET
1352
1353 DEPFLAGS=
1354 MKDEPDIR=":"
1355 deps_frag=deps.mk
1356 dnl check for GNU Make if we have GCC and autodepend is on.
1357 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1358    AC_MSG_CHECKING([whether we are using GNU Make])
1359    HAVE_GNU_MAKE=no
1360    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1361    if test "x$testval" != x; then
1362       HAVE_GNU_MAKE=yes
1363    else
1364       ac_enable_autodepend=no
1365    fi
1366    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1367    if test $HAVE_GNU_MAKE = yes; then
1368       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1369       SAVE_CFLAGS="$CFLAGS"
1370       CFLAGS="$CFLAGS -MMD -MF deps.d"
1371       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1372       CFLAGS="$SAVE_CFLAGS"
1373       test -f deps.d || ac_enable_autodepend=no
1374       rm -rf deps.d
1375       AC_MSG_RESULT([$ac_enable_autodepend])
1376    fi
1377    if test $ac_enable_autodepend = yes; then
1378       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1379       ## In parallel builds, another make might create depdir between
1380       ## the first test and mkdir, so stick another test on the end.
1381       ## Or use mkinstalldirs?  mkdir -p is not portable.
1382       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1383       deps_frag=autodeps.mk
1384    fi
1385 fi
1386 deps_frag=$srcdir/src/$deps_frag
1387 AC_SUBST(MKDEPDIR)
1388 AC_SUBST(DEPFLAGS)
1389 AC_SUBST_FILE(deps_frag)
1390
1391
1392 dnl checks for operating system services
1393 AC_SYS_LONG_FILE_NAMES
1394
1395 #### Choose a window system.
1396
1397 AC_PATH_X
1398 if test "$no_x" = yes; then
1399   window_system=none
1400 else
1401   window_system=x11
1402 fi
1403
1404 ## Workaround for bug in autoconf <= 2.62.
1405 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1406 ## No need to do anything special for these standard directories.
1407 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1408
1409    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1410
1411 fi
1412
1413 LD_SWITCH_X_SITE_AUX=
1414 LD_SWITCH_X_SITE_AUX_RPATH=
1415 if test "${x_libraries}" != NONE; then
1416   if test -n "${x_libraries}"; then
1417     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1418     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1419     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1420   fi
1421   x_default_search_path=""
1422   x_search_path=${x_libraries}
1423   if test -z "${x_search_path}"; then
1424     x_search_path=/usr/lib
1425   fi
1426   for x_library in `echo ${x_search_path}: | \
1427                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1428     x_search_path="\
1429 ${x_library}/X11/%L/%T/%N%C%S:\
1430 ${x_library}/X11/%l/%T/%N%C%S:\
1431 ${x_library}/X11/%T/%N%C%S:\
1432 ${x_library}/X11/%L/%T/%N%S:\
1433 ${x_library}/X11/%l/%T/%N%S:\
1434 ${x_library}/X11/%T/%N%S"
1435     if test x"${x_default_search_path}" = x; then
1436       x_default_search_path=${x_search_path}
1437     else
1438       x_default_search_path="${x_search_path}:${x_default_search_path}"
1439     fi
1440   done
1441 fi
1442 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1443 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1444
1445 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1446   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1447 fi
1448
1449 if test x"${x_includes}" = x; then
1450   bitmapdir=/usr/include/X11/bitmaps
1451 else
1452   # accumulate include directories that have X11 bitmap subdirectories
1453   bmd_acc="dummyval"
1454   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1455     if test -d "${bmd}/X11/bitmaps"; then
1456       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1457     fi
1458     if test -d "${bmd}/bitmaps"; then
1459       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1460     fi
1461   done
1462   if test ${bmd_acc} != "dummyval"; then
1463     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1464   fi
1465 fi
1466
1467 HAVE_NS=no
1468 NS_IMPL_COCOA=no
1469 NS_IMPL_GNUSTEP=no
1470 tmp_CPPFLAGS="$CPPFLAGS"
1471 tmp_CFLAGS="$CFLAGS"
1472 CPPFLAGS="$CPPFLAGS -x objective-c"
1473 CFLAGS="$CFLAGS -x objective-c"
1474 TEMACS_LDFLAGS2="\${LDFLAGS}"
1475 dnl I don't think it's especially important, but src/Makefile.in
1476 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1477 dnl trailing "/" to it, so now we do it here.
1478 if test "${with_ns}" != no; then
1479   if test "${opsys}" = darwin; then
1480      NS_IMPL_COCOA=yes
1481      ns_appdir=`pwd`/nextstep/Emacs.app/
1482      ns_appbindir=${ns_appdir}Contents/MacOS/
1483      ns_appresdir=${ns_appdir}Contents/Resources
1484      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1485   elif test -f $GNUSTEP_CONFIG_FILE; then
1486      NS_IMPL_GNUSTEP=yes
1487      ns_appdir=`pwd`/nextstep/Emacs.app/
1488      ns_appbindir=${ns_appdir}
1489      ns_appresdir=${ns_appdir}Resources
1490      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1491      dnl FIXME sourcing this several times in subshells seems inefficient.
1492      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1493      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1494      dnl I seemed to need these as well with GNUstep-startup 0.25.
1495      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1496      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1497      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1498        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1499      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1500        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1501      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1502      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1503      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1504      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1505      LIB_STANDARD=
1506      START_FILES=
1507      TEMACS_LDFLAGS2=
1508   fi
1509   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1510                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1511   files are missing or cannot be compiled.])])
1512   NS_HAVE_NSINTEGER=yes
1513   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1514                                      [NSInteger i;])],
1515                     ns_have_nsinteger=yes,
1516                     ns_have_nsinteger=no)
1517   if test $ns_have_nsinteger = no; then
1518     NS_HAVE_NSINTEGER=no
1519   fi
1520 fi
1521 AC_SUBST(TEMACS_LDFLAGS2)
1522
1523 ns_frag=/dev/null
1524 NS_OBJ=
1525 NS_SUPPORT=
1526 if test "${HAVE_NS}" = yes; then
1527   window_system=nextstep
1528   with_xft=no
1529   # set up packaging dirs
1530   exec_prefix=${ns_appbindir}
1531   libexecdir=${ns_appbindir}/libexec
1532   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1533      prefix=${ns_appresdir}
1534   fi
1535   ns_frag=$srcdir/src/ns.mk
1536   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1537   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1538 fi
1539 CFLAGS="$tmp_CFLAGS"
1540 CPPFLAGS="$tmp_CPPFLAGS"
1541 AC_SUBST(NS_OBJ)
1542 AC_SUBST(NS_SUPPORT)
1543 AC_SUBST(LIB_STANDARD)
1544 AC_SUBST_FILE(ns_frag)
1545
1546 case "${window_system}" in
1547   x11 )
1548     HAVE_X_WINDOWS=yes
1549     HAVE_X11=yes
1550     case "${with_x_toolkit}" in
1551       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1552       motif ) USE_X_TOOLKIT=MOTIF ;;
1553       gtk ) with_gtk=yes
1554 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1555 dnl USE_X_TOOLKIT is set.
1556             USE_X_TOOLKIT=none ;;
1557       gtk3 ) with_gtk3=yes
1558              USE_X_TOOLKIT=none ;;
1559       no ) USE_X_TOOLKIT=none ;;
1560 dnl If user did not say whether to use a toolkit, make this decision later:
1561 dnl use the toolkit if we have gtk, or X11R5 or newer.
1562       * ) USE_X_TOOLKIT=maybe ;;
1563     esac
1564   ;;
1565   nextstep | none )
1566     HAVE_X_WINDOWS=no
1567     HAVE_X11=no
1568     USE_X_TOOLKIT=none
1569   ;;
1570 esac
1571
1572 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1573    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1574    if test "$HAVE_XSERVER" = true ||
1575       test -n "$DISPLAY" ||
1576       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1577         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1578 were found.  You should install the relevant development files for X
1579 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1580 sure you have development files for image handling, i.e.
1581 tiff, gif, jpeg, png and xpm.
1582 If you are sure you want Emacs compiled without X window support, pass
1583   --without-x
1584 to configure.])
1585    fi
1586 fi
1587
1588 ### If we're using X11, we should use the X menu package.
1589 HAVE_MENUS=no
1590 case ${HAVE_X11} in
1591   yes ) HAVE_MENUS=yes ;;
1592 esac
1593
1594 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1595 # Assume not, until told otherwise.
1596 GNU_MALLOC=yes
1597 doug_lea_malloc=yes
1598 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1599 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1600 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1601                emacs_cv_var___after_morecore_hook,
1602 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1603   emacs_cv_var___after_morecore_hook=yes,
1604   emacs_cv_var___after_morecore_hook=no)])
1605 if test $emacs_cv_var___after_morecore_hook = no; then
1606   doug_lea_malloc=no
1607 fi
1608
1609
1610 dnl See comments in aix4-2.h about maybe using system malloc there.
1611 system_malloc=no
1612 case "$opsys" in
1613   ## darwin ld insists on the use of malloc routines in the System framework.
1614   darwin|sol2-10) system_malloc=yes ;;
1615 esac
1616
1617 if test "${system_malloc}" = "yes"; then
1618   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1619   GNU_MALLOC=no
1620   GNU_MALLOC_reason="
1621     (The GNU allocators don't work with this system configuration.)"
1622   GMALLOC_OBJ=
1623   VMLIMIT_OBJ=
1624 else
1625   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1626   VMLIMIT_OBJ=vm-limit.o
1627 fi
1628 AC_SUBST(GMALLOC_OBJ)
1629 AC_SUBST(VMLIMIT_OBJ)
1630
1631 if test "$doug_lea_malloc" = "yes" ; then
1632   if test "$GNU_MALLOC" = yes ; then
1633     GNU_MALLOC_reason="
1634       (Using Doug Lea's new malloc from the GNU C Library.)"
1635   fi
1636   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1637             [Define to 1 if you are using the GNU C Library.])
1638
1639   ## Use mmap directly for allocating larger buffers.
1640   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1641   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1642   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1643   case "$opsys" in
1644     gnu*) REL_ALLOC=no ;;
1645   esac
1646 fi
1647
1648 if test x"${REL_ALLOC}" = x; then
1649   REL_ALLOC=${GNU_MALLOC}
1650 fi
1651
1652 use_mmap_for_buffers=no
1653 case "$opsys" in
1654   freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1655 esac
1656
1657 AC_FUNC_MMAP
1658 if test $use_mmap_for_buffers = yes; then
1659   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1660   REL_ALLOC=no
1661 fi
1662
1663 LIBS="$LIBS_SYSTEM $LIBS"
1664
1665 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1666 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1667 AC_CHECK_LIB(dnet, dnet_ntoa)
1668 dnl This causes -lresolv to get used in subsequent tests,
1669 dnl which causes failures on some systems such as HPUX 9.
1670 dnl AC_CHECK_LIB(resolv, gethostbyname)
1671
1672 dnl FIXME replace main with a function we actually want from this library.
1673 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1674
1675 AC_CHECK_LIB(pthreads, cma_open)
1676
1677 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1678 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1679 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1680 ## added to LIBS in configure would never contain the pthreads part,
1681 ## but the value used in Makefiles might.  FIXME?
1682 ##
1683 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1684 ## be harmless on older versions of X where it happens to exist.
1685 test "$opsys" = "aix4-2" && \
1686   test $ac_cv_lib_pthreads_cma_open = yes && \
1687   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1688
1689 dnl Check for need for bigtoc support on IBM AIX
1690
1691 case ${host_os} in
1692 aix*)
1693   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1694     case $GCC in
1695     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1696     *) gdb_cv_bigtoc=-bbigtoc ;;
1697     esac
1698
1699     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1700     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1701   ])
1702   ;;
1703 esac
1704
1705 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1706 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1707 # REAL_CPPFLAGS later on.
1708
1709 REAL_CPPFLAGS="$CPPFLAGS"
1710
1711 if test "${HAVE_X11}" = "yes"; then
1712   DEFS="$C_SWITCH_X_SITE $DEFS"
1713   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1714   LIBS="-lX11 $LIBS"
1715   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1716   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1717
1718   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1719   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1720   # but it's more convenient here to set LD_RUN_PATH
1721   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1722   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1723     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1724     export LD_RUN_PATH
1725   fi
1726
1727   if test "${opsys}" = "gnu-linux"; then
1728     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1729     AC_TRY_LINK([],
1730      [XOpenDisplay ("foo");],
1731      [xlinux_first_failure=no],
1732      [xlinux_first_failure=yes])
1733     if test "${xlinux_first_failure}" = "yes"; then
1734       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1735       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1736       OLD_CPPFLAGS="$CPPFLAGS"
1737       OLD_LIBS="$LIBS"
1738       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1739       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1740       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1741       LIBS="$LIBS -b i486-linuxaout"
1742       AC_TRY_LINK([],
1743        [XOpenDisplay ("foo");],
1744        [xlinux_second_failure=no],
1745        [xlinux_second_failure=yes])
1746       if test "${xlinux_second_failure}" = "yes"; then
1747         # If we get the same failure with -b, there is no use adding -b.
1748         # So take it out.  This plays safe.
1749         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1750         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1751         CPPFLAGS="$OLD_CPPFLAGS"
1752         LIBS="$OLD_LIBS"
1753         AC_MSG_RESULT(no)
1754       else
1755         AC_MSG_RESULT(yes)
1756       fi
1757     else
1758       AC_MSG_RESULT(no)
1759     fi
1760   fi
1761
1762   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1763   # header files included from there.
1764   AC_MSG_CHECKING(for Xkb)
1765   AC_TRY_LINK([#include <X11/Xlib.h>
1766 #include <X11/XKBlib.h>],
1767         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1768         emacs_xkb=yes, emacs_xkb=no)
1769   AC_MSG_RESULT($emacs_xkb)
1770   if test $emacs_xkb = yes; then
1771     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1772   fi
1773
1774   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1775 XScreenNumberOfScreen XSetWMProtocols)
1776 fi
1777
1778 if test "${window_system}" = "x11"; then
1779   AC_MSG_CHECKING(X11 version 6)
1780   AC_CACHE_VAL(emacs_cv_x11_version_6,
1781   [AC_TRY_LINK([#include <X11/Xlib.h>],
1782 [#if XlibSpecificationRelease < 6
1783 fail;
1784 #endif
1785 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1786   if test $emacs_cv_x11_version_6 = yes; then
1787     AC_MSG_RESULT(6 or newer)
1788     AC_DEFINE(HAVE_X11R6, 1,
1789               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1790     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1791     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1792     ## XIM support.
1793     case "$opsys" in
1794       sol2-*) : ;;
1795       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1796            [Define if you have usable X11R6-style XIM support.])
1797          ;;
1798     esac
1799   else
1800     AC_MSG_RESULT(before 6)
1801   fi
1802 fi
1803
1804
1805 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1806 HAVE_RSVG=no
1807 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1808   if test "${with_rsvg}" != "no"; then
1809     RSVG_REQUIRED=2.11.0
1810     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1811
1812     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1813     AC_SUBST(RSVG_CFLAGS)
1814     AC_SUBST(RSVG_LIBS)
1815
1816     if test ".${RSVG_CFLAGS}" != "."; then
1817       HAVE_RSVG=yes
1818       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1819       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1820       LIBS="$RSVG_LIBS $LIBS"
1821     fi
1822   fi
1823 fi
1824
1825
1826 HAVE_GTK=no
1827 if test "${with_gtk3}" = "yes"; then
1828   GLIB_REQUIRED=2.6
1829   GTK_REQUIRED=2.90
1830   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1831
1832   dnl Checks for libraries.
1833   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1834   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1835      AC_MSG_ERROR($GTK_PKG_ERRORS)
1836   fi
1837 fi
1838
1839 if test "$pkg_check_gtk" != "yes"; then
1840   HAVE_GTK=no
1841 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1842   GLIB_REQUIRED=2.6
1843   GTK_REQUIRED=2.6
1844   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1845
1846   dnl Checks for libraries.
1847   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1848   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1849      AC_MSG_ERROR($GTK_PKG_ERRORS)
1850   fi
1851 fi
1852 fi
1853
1854 GTK_OBJ=
1855 if test x"$pkg_check_gtk" = xyes; then
1856
1857   AC_SUBST(GTK_CFLAGS)
1858   AC_SUBST(GTK_LIBS)
1859   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1860   CFLAGS="$CFLAGS $GTK_CFLAGS"
1861   LIBS="$GTK_LIBS $LIBS"
1862   dnl Try to compile a simple GTK program.
1863   GTK_COMPILES=no
1864   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1865   if test "${GTK_COMPILES}" != "yes"; then
1866     if test "$USE_X_TOOLKIT" != "maybe"; then
1867       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1868     fi
1869   else
1870     HAVE_GTK=yes
1871     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1872     GTK_OBJ=gtkutil.o
1873     USE_X_TOOLKIT=none
1874     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1875       :
1876     else
1877       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1878        closing open displays.  This is no problem if you just use
1879        one display, but if you use more than one and close one of them
1880        Emacs may crash.]])
1881       sleep 3
1882     fi
1883   fi
1884
1885 fi
1886 AC_SUBST(GTK_OBJ)
1887
1888
1889 if test "${HAVE_GTK}" = "yes"; then
1890
1891   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1892   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1893   if test "$with_toolkit_scroll_bars" != no; then
1894     with_toolkit_scroll_bars=yes
1895   fi
1896
1897   dnl  Check if we have the old file selection dialog declared and
1898   dnl  in the link library.  In 2.x it may be in the library,
1899   dnl  but not declared if deprecated featured has been selected out.
1900   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1901   HAVE_GTK_FILE_SELECTION=no
1902   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1903                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1904 #include <gtk/gtk.h>])
1905   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1906     AC_CHECK_FUNCS(gtk_file_selection_new)
1907   fi
1908
1909   dnl Check if pthreads are available.  Emacs only needs this when using
1910   dnl gtk_file_chooser under Gnome.
1911     HAVE_GTK_AND_PTHREAD=no
1912     AC_CHECK_HEADERS(pthread.h)
1913     if test "$ac_cv_header_pthread_h"; then
1914       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1915     fi
1916     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1917       case "${canonical}" in
1918         *-hpux*) ;;
1919         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1920       esac
1921       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1922                [Define to 1 if you have GTK and pthread (-lpthread).])
1923     fi
1924
1925   dnl Check for functions introduced in 2.14 and later.
1926   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1927                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1928                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1929                  gtk_orientable_set_orientation)
1930
1931 fi
1932
1933 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1934 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1935 dnl also not configured.
1936 HAVE_DBUS=no
1937 DBUS_OBJ=
1938 if test "${with_dbus}" = "yes"; then
1939    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1940    if test "$HAVE_DBUS" = yes; then
1941      LIBS="$LIBS $DBUS_LIBS"
1942      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1943      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1944      DBUS_OBJ=dbusbind.o
1945    fi
1946 fi
1947 AC_SUBST(DBUS_OBJ)
1948
1949 dnl GConf has been tested under GNU/Linux only.
1950 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1951 HAVE_GCONF=no
1952 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1953    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1954    if test "$HAVE_GCONF" = yes; then
1955       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1956    fi
1957 fi
1958
1959 dnl SELinux is available for GNU/Linux only.
1960 HAVE_LIBSELINUX=no
1961 LIBSELINUX_LIBS=
1962 if test "${with_selinux}" = "yes"; then
1963    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1964    if test "$HAVE_LIBSELINUX" = yes; then
1965       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1966       LIBSELINUX_LIBS=-lselinux
1967    fi
1968 fi
1969 AC_SUBST(LIBSELINUX_LIBS)
1970
1971 dnl Do not put whitespace before the #include statements below.
1972 dnl Older compilers (eg sunos4 cc) choke on it.
1973 HAVE_XAW3D=no
1974 LUCID_LIBW=
1975 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1976   if test "$with_xaw3d" != no; then
1977     AC_MSG_CHECKING(for xaw3d)
1978     AC_CACHE_VAL(emacs_cv_xaw3d,
1979     [AC_TRY_LINK([
1980 #include <X11/Intrinsic.h>
1981 #include <X11/Xaw3d/Simple.h>],
1982       [],
1983       emacs_cv_xaw3d=yes,
1984       emacs_cv_xaw3d=no)])
1985   else
1986     emacs_cv_xaw3d=no
1987   fi
1988   if test $emacs_cv_xaw3d = yes; then
1989     AC_MSG_RESULT([yes; using Lucid toolkit])
1990     USE_X_TOOLKIT=LUCID
1991     HAVE_XAW3D=yes
1992     LUCID_LIBW=-lXaw3d
1993     AC_DEFINE(HAVE_XAW3D, 1,
1994               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
1995   else
1996     AC_MSG_RESULT(no)
1997     AC_MSG_CHECKING(for libXaw)
1998     AC_CACHE_VAL(emacs_cv_xaw,
1999     [AC_TRY_LINK([
2000 #include <X11/Intrinsic.h>
2001 #include <X11/Xaw/Simple.h>],
2002       [],
2003       emacs_cv_xaw=yes,
2004       emacs_cv_xaw=no)])
2005     if test $emacs_cv_xaw = yes; then
2006       AC_MSG_RESULT([yes; using Lucid toolkit])
2007       USE_X_TOOLKIT=LUCID
2008       LUCID_LIBW=-lXaw
2009     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2010       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2011     else
2012       AC_MSG_RESULT([no; do not use toolkit by default])
2013       USE_X_TOOLKIT=none
2014     fi
2015   fi
2016 fi
2017
2018 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2019
2020 LIBXTR6=
2021 if test "${USE_X_TOOLKIT}" != "none"; then
2022   AC_MSG_CHECKING(X11 toolkit version)
2023   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2024   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2025 [#if XtSpecificationRelease < 6
2026 fail;
2027 #endif
2028 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2029   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2030   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2031     AC_MSG_RESULT(6 or newer)
2032     AC_DEFINE(HAVE_X11XTR6, 1,
2033               [Define to 1 if you have the X11R6 or newer version of Xt.])
2034     LIBXTR6="-lSM -lICE"
2035     case "$opsys" in
2036       ## Use libw.a along with X11R6 Xt.
2037       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2038     esac
2039   else
2040     AC_MSG_RESULT(before 6)
2041   fi
2042
2043 dnl If using toolkit, check whether libXmu.a exists.
2044 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2045   OLDLIBS="$LIBS"
2046   if test x$HAVE_X11XTR6 = xyes; then
2047     LIBS="-lXt -lSM -lICE $LIBS"
2048   else
2049     LIBS="-lXt $LIBS"
2050   fi
2051   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2052   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2053 fi
2054 AC_SUBST(LIBXTR6)
2055
2056 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2057 dnl Why not just test for libxmu in the normal way?
2058 LIBXMU=-lXmu
2059 case "$machine" in
2060   ## These machines don't supply Xmu.
2061   hpux* | aix4-2 )
2062     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2063     ;;
2064 esac
2065 AC_SUBST(LIBXMU)
2066
2067 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2068 if test "${HAVE_X11}" = "yes"; then
2069   if test "${USE_X_TOOLKIT}" != "none"; then
2070     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2071   fi
2072 fi
2073
2074 LIBXP=
2075 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2076   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2077   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2078     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2079 int x = 5;
2080 #else
2081 Motif version prior to 2.1.
2082 #endif],
2083     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2084   if test $emacs_cv_motif_version_2_1 = yes; then
2085     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2086   else
2087     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2088     # We put this in CFLAGS temporarily to precede other -I options
2089     # that might be in CFLAGS temporarily.
2090     # We put this in CPPFLAGS where it precedes the other -I options.
2091     OLD_CPPFLAGS=$CPPFLAGS
2092     OLD_CFLAGS=$CFLAGS
2093     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2094     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2095     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2096       [int x = 5;],
2097       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2098     if test $emacs_cv_lesstif = yes; then
2099       # Make sure this -I option remains in CPPFLAGS after it is set
2100       # back to REAL_CPPFLAGS.
2101       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2102       # have those other -I options anyway.  Ultimately, having this
2103       # directory ultimately in CPPFLAGS will be enough.
2104       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2105       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2106     else
2107       CFLAGS=$OLD_CFLAGS
2108       CPPFLAGS=$OLD_CPPFLAGS
2109     fi
2110   fi
2111 fi
2112
2113 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2114 dnl using Motif or Xaw3d is available, and unless
2115 dnl --with-toolkit-scroll-bars=no was specified.
2116
2117 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2118             [Define to 1 if we should use toolkit scroll bars.])dnl
2119 USE_TOOLKIT_SCROLL_BARS=no
2120 if test "${with_toolkit_scroll_bars}" != "no"; then
2121   if test "${USE_X_TOOLKIT}" != "none"; then
2122     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2123       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2124       HAVE_XAW3D=no
2125       USE_TOOLKIT_SCROLL_BARS=yes
2126     elif test "${HAVE_XAW3D}" = "yes"; then
2127       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2128       USE_TOOLKIT_SCROLL_BARS=yes
2129     fi
2130   elif test "${HAVE_GTK}" = "yes"; then
2131     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2132     USE_TOOLKIT_SCROLL_BARS=yes
2133   elif test "${HAVE_NS}" = "yes"; then
2134     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2135     USE_TOOLKIT_SCROLL_BARS=yes
2136   fi
2137 fi
2138
2139 dnl See if XIM is available.
2140 AC_TRY_COMPILE([
2141           #include <X11/Xlib.h>
2142           #include <X11/Xresource.h>],
2143          [XIMProc  callback;],
2144          [HAVE_XIM=yes
2145          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2146          HAVE_XIM=no)
2147
2148 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2149
2150 if test "${with_xim}" != "no"; then
2151   AC_DEFINE(USE_XIM, 1,
2152             [Define to 1 if we should use XIM, if it is available.])
2153 fi
2154
2155
2156 if test "${HAVE_XIM}" != "no"; then
2157   late_CFLAGS=$CFLAGS
2158   if test "$GCC" = yes; then
2159     CFLAGS="$CFLAGS --pedantic-errors"
2160   fi
2161   AC_TRY_COMPILE([
2162 #include <X11/Xlib.h>
2163 #include <X11/Xresource.h>],
2164 [Display *display;
2165 XrmDatabase db;
2166 char *res_name;
2167 char *res_class;
2168 XIMProc  callback;
2169 XPointer *client_data;
2170 #ifndef __GNUC__
2171 /* If we're not using GCC, it's probably not XFree86, and this is
2172    probably right, but we can't use something like --pedantic-errors.  */
2173 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2174                                            char*, XIMProc, XPointer*);
2175 #endif
2176 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2177    client_data);],
2178     [emacs_cv_arg6_star=yes])
2179   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2180          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2181 either XPointer or XPointer*.])dnl
2182   if test "$emacs_cv_arg6_star" = yes; then
2183     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2184   else
2185     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2186   fi
2187   CFLAGS=$late_CFLAGS
2188 fi
2189
2190 ### Start of font-backend (under any platform) section.
2191 # (nothing here yet -- this is a placeholder)
2192 ### End of font-backend (under any platform) section.
2193
2194 ### Start of font-backend (under X11) section.
2195 if test "${HAVE_X11}" = "yes"; then
2196    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2197
2198    ## Use -lXft if available, unless `--with-xft=no'.
2199    HAVE_XFT=maybe
2200     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2201       with_xft="no";
2202     fi
2203     if test "x${with_xft}" != "xno"; then
2204
2205       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2206       ## Because xftfont.c uses XRenderQueryExtension, we also
2207       ## need to link to -lXrender.
2208       HAVE_XRENDER=no
2209       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2210       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2211         OLD_CPPFLAGS="$CPPFLAGS"
2212         OLD_CFLAGS="$CFLAGS"
2213         OLD_LIBS="$LIBS"
2214         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2215         CFLAGS="$CFLAGS $XFT_CFLAGS"
2216         XFT_LIBS="-lXrender $XFT_LIBS"
2217         LIBS="$XFT_LIBS $LIBS"
2218         AC_CHECK_HEADER(X11/Xft/Xft.h,
2219           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2220
2221         if test "${HAVE_XFT}" = "yes"; then
2222           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2223             AC_SUBST(XFT_LIBS)
2224           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2225         else
2226           CPPFLAGS="$OLD_CPPFLAGS"
2227           CFLAGS="$OLD_CFLAGS"
2228           LIBS="$OLD_LIBS"
2229         fi                        # "${HAVE_XFT}" = "yes"
2230       fi                          # "$HAVE_XFT" != no
2231     fi                            # "x${with_xft}" != "xno"
2232
2233     dnl For the "Does Emacs use" message at the end.
2234     if test "$HAVE_XFT" != "yes"; then
2235        HAVE_XFT=no
2236     fi
2237
2238
2239     HAVE_FREETYPE=no
2240     ## We used to allow building with FreeType and without Xft.
2241     ## However, the ftx font backend driver is not in good shape.
2242     if test "${HAVE_XFT}" = "yes"; then
2243       dnl As we use Xft, we anyway use freetype.
2244       dnl There's no need for additional CFLAGS and LIBS.
2245       HAVE_FREETYPE=yes
2246       FONTCONFIG_CFLAGS=
2247       FONTCONFIG_LIBS=
2248     fi
2249
2250     HAVE_LIBOTF=no
2251     if test "${HAVE_FREETYPE}" = "yes"; then
2252       AC_DEFINE(HAVE_FREETYPE, 1,
2253                 [Define to 1 if using the freetype and fontconfig libraries.])
2254       if test "${with_libotf}" != "no"; then
2255         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2256                           HAVE_LIBOTF=no)
2257         if test "$HAVE_LIBOTF" = "yes"; then
2258           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2259           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2260                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2261                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2262           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2263             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2264                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2265           fi
2266         fi
2267       fi
2268     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2269     dnl Does the new font backend require it, or can it work without it?
2270     fi
2271
2272     HAVE_M17N_FLT=no
2273     if test "${HAVE_LIBOTF}" = yes; then
2274       if test "${with_m17n_flt}" != "no"; then
2275         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2276         if test "$HAVE_M17N_FLT" = "yes"; then
2277           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2278         fi
2279       fi
2280     fi
2281 else
2282     HAVE_XFT=no
2283     HAVE_FREETYPE=no
2284     HAVE_LIBOTF=no
2285     HAVE_M17N_FLT=no
2286 fi
2287
2288 ### End of font-backend (under X11) section.
2289
2290 AC_SUBST(FREETYPE_CFLAGS)
2291 AC_SUBST(FREETYPE_LIBS)
2292 AC_SUBST(FONTCONFIG_CFLAGS)
2293 AC_SUBST(FONTCONFIG_LIBS)
2294 AC_SUBST(LIBOTF_CFLAGS)
2295 AC_SUBST(LIBOTF_LIBS)
2296 AC_SUBST(M17N_FLT_CFLAGS)
2297 AC_SUBST(M17N_FLT_LIBS)
2298
2299 ### Use -lXpm if available, unless `--with-xpm=no'.
2300 HAVE_XPM=no
2301 LIBXPM=
2302 if test "${HAVE_X11}" = "yes"; then
2303   if test "${with_xpm}" != "no"; then
2304     AC_CHECK_HEADER(X11/xpm.h,
2305       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2306     if test "${HAVE_XPM}" = "yes"; then
2307       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2308       AC_EGREP_CPP(no_return_alloc_pixels,
2309       [#include "X11/xpm.h"
2310 #ifndef XpmReturnAllocPixels
2311 no_return_alloc_pixels
2312 #endif
2313       ], HAVE_XPM=no, HAVE_XPM=yes)
2314
2315       if test "${HAVE_XPM}" = "yes"; then
2316         AC_MSG_RESULT(yes)
2317       else
2318         AC_MSG_RESULT(no)
2319       fi
2320     fi
2321   fi
2322
2323   if test "${HAVE_XPM}" = "yes"; then
2324     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2325     LIBXPM=-lXpm
2326   fi
2327 fi
2328 AC_SUBST(LIBXPM)
2329
2330 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2331 HAVE_JPEG=no
2332 LIBJPEG=
2333 if test "${HAVE_X11}" = "yes"; then
2334   if test "${with_jpeg}" != "no"; then
2335     dnl Checking for jpeglib.h can lose because of a redefinition of
2336     dnl  HAVE_STDLIB_H.
2337     AC_CHECK_HEADER(jerror.h,
2338       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2339   fi
2340
2341   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2342   if test "${HAVE_JPEG}" = "yes"; then
2343     AC_DEFINE(HAVE_JPEG)
2344     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2345         [#include <jpeglib.h>
2346          version=JPEG_LIB_VERSION
2347 ],
2348         [AC_DEFINE(HAVE_JPEG)],
2349         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2350         HAVE_JPEG=no])
2351   fi
2352   if test "${HAVE_JPEG}" = "yes"; then
2353     LIBJPEG=-ljpeg
2354   fi
2355 fi
2356 AC_SUBST(LIBJPEG)
2357
2358 ### Use -lpng if available, unless `--with-png=no'.
2359 HAVE_PNG=no
2360 LIBPNG=
2361 if test "${HAVE_X11}" = "yes"; then
2362   if test "${with_png}" != "no"; then
2363     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2364     # in /usr/include/libpng.
2365     AC_CHECK_HEADERS(png.h libpng/png.h)
2366     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2367       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2368     fi
2369   fi
2370
2371   if test "${HAVE_PNG}" = "yes"; then
2372     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2373     LIBPNG="-lpng -lz -lm"
2374   fi
2375 fi
2376 AC_SUBST(LIBPNG)
2377
2378 ### Use -ltiff if available, unless `--with-tiff=no'.
2379 HAVE_TIFF=no
2380 LIBTIFF=
2381 if test "${HAVE_X11}" = "yes"; then
2382   if test "${with_tiff}" != "no"; then
2383     AC_CHECK_HEADER(tiffio.h,
2384       [tifflibs="-lz -lm"
2385       # At least one tiff package requires the jpeg library.
2386       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2387       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2388   fi
2389
2390   if test "${HAVE_TIFF}" = "yes"; then
2391     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2392     dnl FIXME -lz -lm, as per libpng?
2393     LIBTIFF=-ltiff
2394   fi
2395 fi
2396 AC_SUBST(LIBTIFF)
2397
2398 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2399 HAVE_GIF=no
2400 LIBGIF=
2401 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2402   AC_CHECK_HEADER(gif_lib.h,
2403 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2404 # Earlier versions can crash Emacs.
2405     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2406
2407   if test "$HAVE_GIF" = yes; then
2408     LIBGIF=-lgif
2409   elif test "$HAVE_GIF" = maybe; then
2410 # If gif_lib.h but no libgif, try libungif.
2411     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2412     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2413   fi
2414
2415   if test "${HAVE_GIF}" = "yes"; then
2416     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2417   fi
2418 fi
2419 AC_SUBST(LIBGIF)
2420
2421 dnl Check for required libraries.
2422 if test "${HAVE_X11}" = "yes"; then
2423   MISSING=""
2424   WITH_NO=""
2425   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2426     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2427   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2428     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2429   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2430     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2431   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2432     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2433   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2434     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2435
2436   if test "X${MISSING}" != X; then
2437     AC_MSG_ERROR([The following required libraries were not found:
2438     $MISSING
2439 Maybe some development libraries/packages are missing?
2440 If you don't want to link with them give
2441     $WITH_NO
2442 as options to configure])
2443   fi
2444 fi
2445
2446 ### Use -lgpm if available, unless `--with-gpm=no'.
2447 HAVE_GPM=no
2448 LIBGPM=
2449 MOUSE_SUPPORT=
2450 if test "${with_gpm}" != "no"; then
2451   AC_CHECK_HEADER(gpm.h,
2452     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2453
2454   if test "${HAVE_GPM}" = "yes"; then
2455     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2456     LIBGPM=-lgpm
2457     ## May be reset below.
2458     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2459   fi
2460 fi
2461 AC_SUBST(LIBGPM)
2462
2463 dnl Check for malloc/malloc.h on darwin
2464 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2465
2466 C_SWITCH_X_SYSTEM=
2467 ### Use NeXTstep API to implement GUI.
2468 if test "${HAVE_NS}" = "yes"; then
2469   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2470   if test "${NS_IMPL_COCOA}" = "yes"; then
2471     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2472     GNU_OBJC_CFLAGS=
2473   fi
2474   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2475     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2476     # See also .m.o rule in Makefile.in */
2477     # FIXME: are all these flags really needed?  Document here why.  */
2478     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2479     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2480   fi
2481   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2482     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2483   fi
2484   # We also have mouse menus.
2485   HAVE_MENUS=yes
2486   OTHER_FILES=ns-app
2487 fi
2488
2489
2490 ### Use session management (-lSM -lICE) if available
2491 HAVE_X_SM=no
2492 LIBXSM=
2493 if test "${HAVE_X11}" = "yes"; then
2494   AC_CHECK_HEADER(X11/SM/SMlib.h,
2495     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2496
2497   if test "${HAVE_X_SM}" = "yes"; then
2498     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2499     LIBXSM="-lSM -lICE"
2500     case "$LIBS" in
2501       *-lSM*) ;;
2502       *)      LIBS="$LIBXSM $LIBS" ;;
2503     esac
2504   fi
2505 fi
2506 AC_SUBST(LIBXSM)
2507
2508 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2509 AC_CACHE_CHECK(whether netdb declares h_errno,
2510                emacs_cv_netdb_declares_h_errno,
2511 [AC_TRY_LINK([#include <netdb.h>],
2512   [return h_errno;],
2513   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2514 if test $emacs_cv_netdb_declares_h_errno = yes; then
2515   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2516 fi
2517
2518 AC_FUNC_ALLOCA
2519
2520 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2521 dnl FIXME is there an autoconf test that does the right thing, without
2522 dnl needing to call A_M_E afterwards?
2523 if test x"$ac_cv_func_alloca_works" != xyes; then
2524    AC_MSG_ERROR( [a system implementation of alloca is required] )
2525 fi
2526
2527 # fmod, logb, and frexp are found in -lm on most systems.
2528 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2529 AC_CHECK_LIB(m, sqrt)
2530
2531 # Check for mail-locking functions in a "mail" library.  Probably this should
2532 # have the same check as for liblockfile below.
2533 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2534 if test $have_mail = yes; then
2535   LIBS_MAIL=-lmail
2536   LIBS="$LIBS_MAIL $LIBS"
2537   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2538 else
2539   LIBS_MAIL=
2540 fi
2541 dnl Debian, at least:
2542 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2543 if test $have_lockfile = yes; then
2544    LIBS_MAIL=-llockfile
2545    LIBS="$LIBS_MAIL $LIBS"
2546    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2547 else
2548 # If we have the shared liblockfile, assume we must use it for mail
2549 # locking (e.g. Debian).  If we couldn't link against liblockfile
2550 # (no liblockfile.a installed), ensure that we don't need to.
2551   dnl This works for files generally, not just executables.
2552   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2553   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2554                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2555   if test $ac_cv_prog_liblockfile = yes; then
2556     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2557 This probably means that movemail could lose mail.
2558 There may be a `development' package to install containing liblockfile.])
2559   fi
2560 fi
2561 AC_CHECK_FUNCS(touchlock)
2562 AC_CHECK_HEADERS(maillock.h)
2563 AC_SUBST(LIBS_MAIL)
2564
2565 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2566 ## interlock access to the mail spool.  The alternative is a lock file named
2567 ## /usr/spool/mail/$USER.lock.
2568 mail_lock=no
2569 case "$opsys" in
2570   aix4-2) mail_lock="lockf" ;;
2571
2572   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2573
2574   ## On GNU/Linux systems, both methods are used by various mail programs.
2575   ## I assume most people are using newer mailers that have heard of flock.
2576   ## Change this if you need to.
2577   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2578   ## configure gets the right answers, and that means *NOT* using flock.
2579   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2580   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2581   ## Debian maintainer hasn't provided a clean fix for Emacs.
2582   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2583   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2584   ## correct logic.  -- fx
2585   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2586   ## liblockfile is a Free Software replacement for libmail, used on
2587   ## Debian systems and elsewhere. -rfr.
2588   gnu-*)
2589     mail_lock="flock"
2590     if test $have_mail = yes || test $have_lockfile = yes; then
2591       test $ac_cv_header_maillock_h = yes && mail_lock=no
2592     fi
2593     ;;
2594 esac
2595
2596 BLESSMAIL_TARGET=
2597 case "$mail_lock" in
2598   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2599
2600   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2601
2602   *) BLESSMAIL_TARGET="need-blessmail" ;;
2603 esac
2604 AC_SUBST(BLESSMAIL_TARGET)
2605
2606
2607 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2608 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2609 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2610 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2611 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2612 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2613 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2614 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2615 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2616 cfmakeraw cfsetspeed isnan copysign)
2617
2618 AC_CHECK_HEADERS(sys/un.h)
2619
2620 AC_FUNC_MKTIME
2621 if test "$ac_cv_func_working_mktime" = no; then
2622   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2623 fi
2624
2625 AC_FUNC_GETLOADAVG
2626
2627 AC_FUNC_FSEEKO
2628
2629 # Configure getopt.
2630 m4_include([m4/getopt.m4])
2631 gl_GETOPT_IFELSE([
2632   gl_GETOPT_SUBSTITUTE_HEADER
2633   gl_PREREQ_GETOPT
2634   GETOPTOBJS='getopt.o getopt1.o'
2635 ])
2636 AC_SUBST(GETOPTOBJS)
2637
2638 AC_FUNC_GETPGRP
2639
2640 AC_FUNC_STRFTIME
2641
2642 # UNIX98 PTYs.
2643 AC_CHECK_FUNCS(grantpt)
2644
2645 # PTY-related GNU extensions.
2646 AC_CHECK_FUNCS(getpt)
2647
2648 # Check this now, so that we will NOT find the above functions in ncurses.
2649 # That is because we have not set up to link ncurses in lib-src.
2650 # It's better to believe a function is not available
2651 # than to expect to find it in ncurses.
2652 # Also we need tputs and friends to be able to build at all.
2653 have_tputs_et_al=true
2654 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2655 if test "$have_tputs_et_al" != true; then
2656   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2657 Maybe some development libraries/packages are missing?  Try installing
2658 libncurses-dev(el), libterminfo-dev(el) or similar.])
2659 fi
2660 # Must define this when any termcap library is found.
2661 AC_DEFINE(HAVE_LIBNCURSES, 1,
2662           [Define to 1 if you have the `ncurses' library (-lncurses).])
2663 ## FIXME This was the cpp logic, but I am not sure it is right.
2664 ## The above test has not necessarily found libncurses.
2665 HAVE_LIBNCURSES=yes
2666
2667 ## Use terminfo instead of termcap?
2668 ## Note only system files NOT using terminfo are:
2669 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2670 ## darwin|gnu without ncurses.
2671 TERMINFO=no
2672 LIBS_TERMCAP=
2673 case "$opsys" in
2674   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2675   ## hpux10-20: Use the system provided termcap(3) library.
2676   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2677   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2678   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2679
2680   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2681   ##  The ncurses library has been moved out of the System framework in
2682   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2683   ##  option to use it.
2684   darwin|gnu*)
2685     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2686     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2687       TERMINFO=yes
2688       LIBS_TERMCAP="-lncurses"
2689     fi
2690     ;;
2691
2692   freebsd)
2693     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2694     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2695     [AC_TRY_LINK([#include <osreldate.h>],
2696 [#if __FreeBSD_version < 400000
2697 fail;
2698 #endif
2699 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2700
2701     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2702
2703     if test $emacs_cv_freebsd_terminfo = yes; then
2704       TERMINFO=yes
2705       LIBS_TERMCAP="-lncurses"
2706     else
2707       LIBS_TERMCAP="-ltermcap"
2708     fi
2709     ;;
2710
2711   netbsd)
2712     if test $ac_cv_search_tputs = -lterminfo; then
2713       TERMINFO=yes
2714       LIBS_TERMCAP="-lterminfo"
2715     else
2716       LIBS_TERMCAP="-ltermcap"
2717     fi
2718     ;;
2719
2720 esac
2721
2722 case "$opsys" in
2723   ## hpux: Make sure we get select from libc rather than from libcurses
2724   ##  because libcurses on HPUX 10.10 has a broken version of select.
2725   ##  We used to use -lc -lcurses, but this may be cleaner.
2726   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2727
2728   openbsd) LIBS_TERMCAP="-lncurses" ;;
2729
2730   ## Must use system termcap, if we use any termcap.  It does special things.
2731   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2732 esac
2733
2734 TERMCAP_OBJ=tparam.o
2735 if test $TERMINFO = yes; then
2736   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2737
2738   ## Default used to be -ltermcap.  Add a case above if need something else.
2739   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2740
2741   TERMCAP_OBJ=terminfo.o
2742 fi
2743 AC_SUBST(LIBS_TERMCAP)
2744 AC_SUBST(TERMCAP_OBJ)
2745
2746
2747 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2748 resolv=no
2749 AC_TRY_LINK([#include <netinet/in.h>
2750 #include <arpa/nameser.h>
2751 #include <resolv.h>],
2752     [return res_init();],
2753     have_res_init=yes, have_res_init=no)
2754 if test "$have_res_init" = no; then
2755   OLIBS="$LIBS"
2756   LIBS="$LIBS -lresolv"
2757   AC_MSG_CHECKING(for res_init with -lresolv)
2758   AC_TRY_LINK([#include <netinet/in.h>
2759 #include <arpa/nameser.h>
2760 #include <resolv.h>],
2761     [return res_init();],
2762     have_res_init=yes, have_res_init=no)
2763   AC_MSG_RESULT($have_res_init)
2764   if test "$have_res_init" = yes ; then
2765     resolv=yes
2766   fi
2767   LIBS="$OLIBS"
2768 fi
2769
2770 if test "$have_res_init" = yes; then
2771   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2772 fi
2773
2774 # Do we need the Hesiod library to provide the support routines?
2775 LIBHESIOD=
2776 if test "$with_hesiod" != no ; then
2777   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2778   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2779      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2780                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2781   if test "$resolv" = yes ; then
2782     RESOLVLIB=-lresolv
2783   else
2784     RESOLVLIB=
2785   fi
2786   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2787         hesiod=yes, :, $RESOLVLIB)])
2788
2789   if test x"$hesiod" = xyes; then
2790     AC_DEFINE(HAVE_LIBHESIOD, 1,
2791               [Define to 1 if you have the hesiod library (-lhesiod).])
2792     LIBHESIOD=-lhesiod
2793   fi
2794 fi
2795 AC_SUBST(LIBHESIOD)
2796
2797 # Do we need libresolv (due to res_init or Hesiod)?
2798 if test "$resolv" = yes ; then
2799   AC_DEFINE(HAVE_LIBRESOLV, 1,
2800             [Define to 1 if you have the resolv library (-lresolv).])
2801   LIBRESOLV=-lresolv
2802 else
2803   LIBRESOLV=
2804 fi
2805 AC_SUBST(LIBRESOLV)
2806
2807 # These tell us which Kerberos-related libraries to use.
2808 COM_ERRLIB=
2809 CRYPTOLIB=
2810 KRB5LIB=
2811 DESLIB=
2812 KRB4LIB=
2813
2814 if test "${with_kerberos}" != no; then
2815   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2816   if test $have_com_err = yes; then
2817     COM_ERRLIB=-lcom_err
2818     LIBS="$COM_ERRLIB $LIBS"
2819     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2820   fi
2821   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2822   if test $have_crypto = yes; then
2823     CRYPTOLIB=-lcrypto
2824     LIBS="$CRYPTOLIB $LIBS"
2825     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2826   fi
2827   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2828   if test $have_k5crypto = yes; then
2829     CRYPTOLIB=-lk5crypto
2830     LIBS="$CRYPTOLIB $LIBS"
2831     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2832   fi
2833   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2834   if test $have_krb5=yes; then
2835     KRB5LIB=-lkrb5
2836     LIBS="$KRB5LIB $LIBS"
2837     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2838   fi
2839   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2840   if test "${with_kerberos5}" = no; then
2841     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2842     if test $have_des425 = yes; then
2843       DESLIB=-ldes425
2844       LIBS="$DESLIB $LIBS"
2845       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2846     else
2847       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2848       if test $have_des = yes; then
2849         DESLIB=-ldes
2850         LIBS="$DESLIB $LIBS"
2851         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2852       fi
2853     fi
2854     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2855     if test $have_krb4 = yes; then
2856       KRB4LIB=-lkrb4
2857       LIBS="$KRB4LIB $LIBS"
2858       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2859     else
2860       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2861       if test $have_krb = yes; then
2862         KRB4LIB=-lkrb
2863         LIBS="$KRB4LIB $LIBS"
2864         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2865       fi
2866     fi
2867   fi
2868
2869   if test "${with_kerberos5}" != no; then
2870     AC_CHECK_HEADERS(krb5.h,
2871       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2872                         [#include <krb5.h>])])
2873   else
2874     AC_CHECK_HEADERS(des.h,,
2875                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2876                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2877     AC_CHECK_HEADERS(krb.h,,
2878                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2879                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2880   fi
2881   AC_CHECK_HEADERS(com_err.h)
2882 fi
2883
2884 AC_SUBST(COM_ERRLIB)
2885 AC_SUBST(CRYPTOLIB)
2886 AC_SUBST(KRB5LIB)
2887 AC_SUBST(DESLIB)
2888 AC_SUBST(KRB4LIB)
2889
2890 # Solaris requires -lintl if you want strerror (which calls dgettext)
2891 # to return localized messages.
2892 AC_CHECK_LIB(intl, dgettext)
2893
2894 AC_MSG_CHECKING(whether localtime caches TZ)
2895 AC_CACHE_VAL(emacs_cv_localtime_cache,
2896 [if test x$ac_cv_func_tzset = xyes; then
2897 AC_TRY_RUN([#include <time.h>
2898 extern char **environ;
2899 unset_TZ ()
2900 {
2901   char **from, **to;
2902   for (to = from = environ; (*to = *from); from++)
2903     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2904       to++;
2905 }
2906 char TZ_GMT0[] = "TZ=GMT0";
2907 char TZ_PST8[] = "TZ=PST8";
2908 main()
2909 {
2910   time_t now = time ((time_t *) 0);
2911   int hour_GMT0, hour_unset;
2912   if (putenv (TZ_GMT0) != 0)
2913     exit (1);
2914   hour_GMT0 = localtime (&now)->tm_hour;
2915   unset_TZ ();
2916   hour_unset = localtime (&now)->tm_hour;
2917   if (putenv (TZ_PST8) != 0)
2918     exit (1);
2919   if (localtime (&now)->tm_hour == hour_GMT0)
2920     exit (1);
2921   unset_TZ ();
2922   if (localtime (&now)->tm_hour != hour_unset)
2923     exit (1);
2924   exit (0);
2925 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2926 [# If we have tzset, assume the worst when cross-compiling.
2927 emacs_cv_localtime_cache=yes])
2928 else
2929         # If we lack tzset, report that localtime does not cache TZ,
2930         # since we can't invalidate the cache if we don't have tzset.
2931         emacs_cv_localtime_cache=no
2932 fi])dnl
2933 AC_MSG_RESULT($emacs_cv_localtime_cache)
2934 if test $emacs_cv_localtime_cache = yes; then
2935   AC_DEFINE(LOCALTIME_CACHE, 1,
2936             [Define to 1 if localtime caches TZ.])
2937 fi
2938
2939 if test "x$HAVE_TIMEVAL" = xyes; then
2940   AC_CHECK_FUNCS(gettimeofday)
2941   if test $ac_cv_func_gettimeofday = yes; then
2942     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2943                    emacs_cv_gettimeofday_two_arguments,
2944     [AC_TRY_COMPILE([
2945 #ifdef TIME_WITH_SYS_TIME
2946 #include <sys/time.h>
2947 #include <time.h>
2948 #else
2949 #ifdef HAVE_SYS_TIME_H
2950 #include <sys/time.h>
2951 #else
2952 #include <time.h>
2953 #endif
2954 #endif],
2955       [struct timeval time;
2956        gettimeofday (&time, 0);],
2957       emacs_cv_gettimeofday_two_arguments=yes,
2958       emacs_cv_gettimeofday_two_arguments=no)])
2959     if test $emacs_cv_gettimeofday_two_arguments = no; then
2960       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2961                 [Define to 1 if gettimeofday accepts only one argument.])
2962     fi
2963   fi
2964 fi
2965
2966 ok_so_far=yes
2967 AC_CHECK_FUNC(socket, , ok_so_far=no)
2968 if test $ok_so_far = yes; then
2969   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2970 fi
2971 if test $ok_so_far = yes; then
2972   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2973 fi
2974 if test $ok_so_far = yes; then
2975 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2976   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2977             [Define to 1 if you have inet sockets.])
2978 fi
2979
2980 AC_CHECK_HEADERS(sys/ioctl.h)
2981
2982 if test -f /usr/lpp/X11/bin/smt.exp; then
2983   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2984             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2985 fi
2986
2987 AC_MSG_CHECKING(whether system supports dynamic ptys)
2988 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2989   AC_MSG_RESULT(yes)
2990   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2991 else
2992   AC_MSG_RESULT(no)
2993 fi
2994
2995 AC_FUNC_FORK
2996
2997 dnl Adapted from Haible's version.
2998 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2999   [AC_TRY_LINK([#include <langinfo.h>],
3000     [char* cs = nl_langinfo(CODESET);],
3001     emacs_cv_langinfo_codeset=yes,
3002     emacs_cv_langinfo_codeset=no)
3003   ])
3004 if test $emacs_cv_langinfo_codeset = yes; then
3005   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3006     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3007 fi
3008
3009 AC_CHECK_TYPES(size_t)
3010
3011 AC_TYPE_MBSTATE_T
3012
3013 dnl Restrict could probably be used effectively other than in regex.c.
3014 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3015   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3016                   emacs_cv_c_restrict=yes,
3017                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3018                                   emacs_cv_c_restrict=__restrict,
3019                                   emacs_cv_c_restrict=no)])])
3020 case "$emacs_cv_c_restrict" in
3021   yes) emacs_restrict=restrict;;
3022   no) emacs_restrict="";;
3023   *) emacs_restrict="$emacs_cv_c_restrict";;
3024 esac
3025 if test "$emacs_restrict" != __restrict; then
3026   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3027     [Define to compiler's equivalent of C99 restrict keyword.
3028      Don't define if equivalent is `__restrict'.])
3029 fi
3030
3031 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3032   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3033                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3034 if test "$emacs_cv_c_restrict_arr" = yes; then
3035   AC_DEFINE(__restrict_arr, __restrict,
3036     [Define to compiler's equivalent of C99 restrict keyword in array
3037      declarations.  Define as empty for no equivalent.])
3038 fi
3039
3040 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3041 dnl how the tty code is related to POSIX and/or other versions of termios.
3042 dnl The following looks like a useful start.
3043 dnl
3044 dnl AC_SYS_POSIX_TERMIOS
3045 dnl if test $ac_cv_sys_posix_termios = yes; then
3046 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3047 dnl                                and macros for terminal control.])
3048 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3049 dnl fi
3050
3051 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3052
3053 # Set up the CFLAGS for real compilation, so we can substitute it.
3054 CFLAGS="$REAL_CFLAGS"
3055 CPPFLAGS="$REAL_CPPFLAGS"
3056
3057 ## Hack to detect a buggy GCC version.
3058 if test "x$GCC" = xyes \
3059    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3060    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3061    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3062    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3063 fi
3064
3065 #### Find out which version of Emacs this is.
3066 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3067          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3068 if test x"${version}" = x; then
3069   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3070 fi
3071 if test x"${version}" != x"$PACKAGE_VERSION"; then
3072   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3073 fi
3074
3075 ### Specify what sort of things we'll be editing into Makefile and config.h.
3076 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3077 AC_SUBST(version)
3078 AC_SUBST(configuration)
3079 ## Unused?
3080 AC_SUBST(canonical)
3081 AC_SUBST(srcdir)
3082 AC_SUBST(prefix)
3083 AC_SUBST(exec_prefix)
3084 AC_SUBST(bindir)
3085 AC_SUBST(datadir)
3086 AC_SUBST(sharedstatedir)
3087 AC_SUBST(libexecdir)
3088 AC_SUBST(mandir)
3089 AC_SUBST(infodir)
3090 AC_SUBST(lispdir)
3091 AC_SUBST(locallisppath)
3092 AC_SUBST(lisppath)
3093 AC_SUBST(x_default_search_path)
3094 AC_SUBST(etcdir)
3095 AC_SUBST(archlibdir)
3096 AC_SUBST(docdir)
3097 AC_SUBST(bitmapdir)
3098 AC_SUBST(gamedir)
3099 AC_SUBST(gameuser)
3100 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3101 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3102 ## end of LIBX_BASE, but nothing ever set it.
3103 AC_SUBST(LD_SWITCH_X_SITE)
3104 AC_SUBST(C_SWITCH_X_SITE)
3105 AC_SUBST(C_SWITCH_X_SYSTEM)
3106 AC_SUBST(CFLAGS)
3107 ## Used in lwlib/Makefile.in.
3108 AC_SUBST(X_TOOLKIT_TYPE)
3109 AC_SUBST(machfile)
3110 AC_SUBST(opsysfile)
3111 AC_SUBST(GETLOADAVG_LIBS)
3112 AC_SUBST(ns_appdir)
3113 AC_SUBST(ns_appbindir)
3114 AC_SUBST(ns_appresdir)
3115 AC_SUBST(ns_appsrc)
3116 AC_SUBST(GNU_OBJC_CFLAGS)
3117 AC_SUBST(OTHER_FILES)
3118
3119 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3120                    [Define to the canonical Emacs configuration name.])
3121 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3122                    [Define to the options passed to configure.])
3123 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3124                    [Define to the used machine dependent file.])
3125 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3126                    [Define to the used os dependent file.])
3127
3128 XMENU_OBJ=
3129 XOBJ=
3130 FONT_OBJ=
3131 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3132   AC_DEFINE(HAVE_X_WINDOWS, 1,
3133             [Define to 1 if you want to use the X window system.])
3134   XMENU_OBJ=xmenu.o
3135   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3136   FONT_OBJ=xfont.o
3137   if test "$HAVE_XFT" = "yes"; then
3138     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3139   elif test "$HAVE_FREETYPE" = "yes"; then
3140     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3141   fi
3142   AC_SUBST(FONT_OBJ)
3143 fi
3144 AC_SUBST(XMENU_OBJ)
3145 AC_SUBST(XOBJ)
3146 AC_SUBST(FONT_OBJ)
3147
3148 WIDGET_OBJ=
3149 MOTIF_LIBW=
3150 if test "${USE_X_TOOLKIT}" != "none" ; then
3151   WIDGET_OBJ=widget.o
3152   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3153   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3154     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3155   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3156     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3157     MOTIF_LIBW=-lXm
3158     case "$opsys" in
3159       gnu-linux)
3160         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3161         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3162         ;;
3163
3164       unixware)
3165         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3166         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3167         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3168         ;;
3169
3170       aix4-2)
3171         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3172         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3173         ;;
3174     esac
3175     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3176   fi
3177 fi
3178 AC_SUBST(WIDGET_OBJ)
3179
3180 TOOLKIT_LIBW=
3181 case "$USE_X_TOOLKIT" in
3182   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3183   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3184   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3185 esac
3186 AC_SUBST(TOOLKIT_LIBW)
3187
3188 if test "$USE_X_TOOLKIT" = "none"; then
3189   LIBXT_OTHER="\$(LIBXSM)"
3190   OLDXMENU_TARGET="really-oldXMenu"
3191 else
3192   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3193   OLDXMENU_TARGET="really-lwlib"
3194 fi
3195 AC_SUBST(LIBXT_OTHER)
3196
3197 ## The X Menu stuff is present in the X10 distribution, but missing
3198 ## from X11.  If we have X10, just use the installed library;
3199 ## otherwise, use our own copy.
3200 if test "${HAVE_X11}" = "yes" ; then
3201   AC_DEFINE(HAVE_X11, 1,
3202             [Define to 1 if you want to use version 11 of X windows.
3203              Otherwise, Emacs expects to use version 10.])
3204
3205   if test "$USE_X_TOOLKIT" = "none"; then
3206     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3207   else
3208     OLDXMENU="\${lwlibdir}liblw.a"
3209   fi
3210   LIBXMENU="\$(OLDXMENU)"
3211   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3212   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3213 else
3214   ## For a syntactically valid Makefile; not actually used for anything.
3215   ## See comments in src/Makefile.in.
3216   OLDXMENU=nothing
3217   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3218   if test "${HAVE_X_WINDOWS}" = "yes"; then
3219     LIBXMENU="-lXMenu"
3220   else
3221     LIBXMENU=
3222   fi
3223   LIBX_OTHER=
3224   OLDXMENU_DEPS=
3225 fi
3226
3227 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3228   OLDXMENU_TARGET=
3229   OLDXMENU=nothing
3230   LIBXMENU=
3231   OLDXMENU_DEPS=
3232 fi
3233
3234 AC_SUBST(OLDXMENU_TARGET)
3235 AC_SUBST(OLDXMENU)
3236 AC_SUBST(LIBXMENU)
3237 AC_SUBST(LIBX_OTHER)
3238 AC_SUBST(OLDXMENU_DEPS)
3239
3240 if test "${HAVE_MENUS}" = "yes" ; then
3241   AC_DEFINE(HAVE_MENUS, 1,
3242             [Define to 1 if you have mouse menus.
3243              (This is automatic if you use X, but the option to specify it remains.)
3244              It is also defined with other window systems that support xmenu.c.])
3245 fi
3246
3247 if test "${GNU_MALLOC}" = "yes" ; then
3248   AC_DEFINE(GNU_MALLOC, 1,
3249             [Define to 1 if you want to use the GNU memory allocator.])
3250 fi
3251
3252 RALLOC_OBJ=
3253 if test "${REL_ALLOC}" = "yes" ; then
3254   AC_DEFINE(REL_ALLOC, 1,
3255             [Define REL_ALLOC if you want to use the relocating allocator for
3256              buffer space.])
3257
3258   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3259 fi
3260 AC_SUBST(RALLOC_OBJ)
3261
3262 if test "$opsys" = "cygwin"; then
3263   CYGWIN_OBJ="sheap.o"
3264   ## Cygwin differs because of its unexec().
3265   PRE_ALLOC_OBJ=
3266   POST_ALLOC_OBJ=lastfile.o
3267 else
3268   CYGWIN_OBJ=
3269   PRE_ALLOC_OBJ=lastfile.o
3270   POST_ALLOC_OBJ=
3271 fi
3272 AC_SUBST(CYGWIN_OBJ)
3273 AC_SUBST(PRE_ALLOC_OBJ)
3274 AC_SUBST(POST_ALLOC_OBJ)
3275
3276
3277 case "$opsys" in
3278   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3279
3280   darwin)
3281    ## The -headerpad option tells ld (see man page) to leave room at the
3282    ## end of the header for adding load commands.  Needed for dumping.
3283    ## 0x690 is the total size of 30 segment load commands (at 56
3284    ## each); under Cocoa 31 commands are required.
3285    if test "$HAVE_NS" = "yes"; then
3286      libs_nsgui="-framework AppKit"
3287      headerpad_extra=6C8
3288    else
3289      libs_nsgui=
3290      headerpad_extra=690
3291    fi
3292    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3293
3294    ## This is here because src/Makefile.in did some extra fiddling around
3295    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3296    ##   #ifndef LD_SWITCH_SYSTEM
3297    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3298    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3299    ## not using gcc, darwin system not on an alpha (ie darwin, since
3300    ## darwin + alpha does not occur).
3301    ## Because this was done in src/Makefile.in, the resulting part of
3302    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3303    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3304    ## rather than LD_SWITCH_SYSTEM.
3305    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3306      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3307    ;;
3308
3309   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3310   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3311   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3312   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3313   ## had different values in configure (in ac_link) and src/Makefile.in.
3314   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3315   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3316
3317   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3318 esac
3319
3320 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3321   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3322 fi
3323
3324 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3325
3326
3327 LINKER=
3328 ORDINARY_LINK=
3329 case "$opsys" in
3330   ## gnu: GNU needs its own crt0.
3331   aix4-2|darwin|gnu|usg5-4|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3332
3333   cygwin) LINKER="\$(CC)" ;;
3334
3335   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3336   ## library search parth, i.e. it won't search /usr/lib for libc and
3337   ## friends.  Using -nostartfiles instead avoids this problem, and
3338   ## will also work on earlier NetBSD releases.
3339   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3340
3341   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3342   ##   MkLinux/LinuxPPC needs this.
3343   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3344   gnu-*)
3345     case "$machine" in
3346       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3347     esac
3348     ;;
3349 esac
3350
3351
3352 PRE_EDIT_LDFLAGS=
3353 POST_EDIT_LDFLAGS=
3354 if test "x$ORDINARY_LINK" = "xyes"; then
3355
3356   LINKER="\$(CC)"
3357   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3358
3359 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3360 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3361 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3362
3363   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3364   ## places that are difficult to figure out at make time.  Fortunately,
3365   ## these same versions allow you to pass arbitrary flags on to the
3366   ## linker, so there is no reason not to use it as a linker.
3367   ##
3368   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3369   ## searching for libraries in its internal directories, so we have to
3370   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3371   LINKER="\$(CC) -nostdlib"
3372   ## GCC passes any argument prefixed with -Xlinker directly to the linker.
3373   ## See prefix-args.c for an explanation of why we do not do this with the
3374   ## shell''s ``for'' construct.  Note that sane people do not have '.' in
3375   ## their paths, so we must use ./prefix-args.
3376   ## TODO either make prefix-args check ORDINARY_LINK internally,
3377   ## or remove it altogether (bug#6184), removing the need for this hack.
3378   PRE_EDIT_LDFLAGS='`./prefix-args -Xlinker'
3379   POST_EDIT_LDFLAGS='`'
3380 fi
3381 AC_SUBST(PRE_EDIT_LDFLAGS)
3382 AC_SUBST(POST_EDIT_LDFLAGS)
3383
3384 test "x$LINKER" = "x" && LINKER=ld
3385 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3386 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3387
3388 AC_SUBST(LINKER)
3389
3390
3391 ## FIXME? The logic here is not precisely the same as that above.
3392 ## There is no check here for a pre-defined LINKER.
3393 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3394 LIB_GCC=
3395 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3396
3397   case "$opsys" in
3398     ## cygwin: don't link against static libgcc.
3399     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3400
3401     gnu-*)
3402       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3403       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3404       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3405       if test "$machine" = "arm"; then
3406         LIB_GCC="-lgcc_s"
3407       else
3408         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3409         ## immediately undefine it again and redefine it to empty.
3410         ## Was the C_SWITCH_X_SITE part really necessary?
3411 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3412         LIB_GCC=
3413       fi
3414       ;;
3415
3416     ## Ask GCC where to find libgcc.a.
3417     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3418   esac
3419 fi                              dnl if $GCC
3420 AC_SUBST(LIB_GCC)
3421
3422
3423 TOOLTIP_SUPPORT=
3424 WINDOW_SUPPORT=
3425 ## If we're using X11/GNUstep, define some consequences.
3426 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3427   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3428   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3429   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3430   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3431
3432   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3433   test "$HAVE_X_WINDOWS" = "yes" && \
3434     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3435
3436 fi
3437 AC_SUBST(MOUSE_SUPPORT)
3438 AC_SUBST(TOOLTIP_SUPPORT)
3439 AC_SUBST(WINDOW_SUPPORT)
3440
3441
3442 AH_TOP([/* GNU Emacs site configuration template file.
3443    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3444      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3445
3446 This file is part of GNU Emacs.
3447
3448 GNU Emacs is free software: you can redistribute it and/or modify
3449 it under the terms of the GNU General Public License as published by
3450 the Free Software Foundation, either version 3 of the License, or
3451 (at your option) any later version.
3452
3453 GNU Emacs is distributed in the hope that it will be useful,
3454 but WITHOUT ANY WARRANTY; without even the implied warranty of
3455 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3456 GNU General Public License for more details.
3457
3458 You should have received a copy of the GNU General Public License
3459 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3460
3461
3462 /* No code in Emacs #includes config.h twice, but some bits of code
3463    intended to work with other packages as well (like gmalloc.c)
3464    think they can include it as many times as they like.  */
3465 #ifndef EMACS_CONFIG_H
3466 #define EMACS_CONFIG_H
3467 ])dnl
3468
3469 AH_BOTTOM([
3470 /* Define AMPERSAND_FULL_NAME if you use the convention
3471    that & in the full name stands for the login id.  */
3472 /* Turned on June 1996 supposing nobody will mind it.  */
3473 #define AMPERSAND_FULL_NAME
3474
3475 /* If using GNU, then support inline function declarations.  */
3476 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3477    generally, because even if non-gcc compilers accept `inline', they
3478    may reject `extern inline'.  */
3479 #if defined (__GNUC__) && defined (OPTIMIZE)
3480 #define INLINE __inline__
3481 #else
3482 #define INLINE
3483 #endif
3484
3485 /* `subprocesses' should be defined if you want to
3486    have code for asynchronous subprocesses
3487    (as used in M-x compile and M-x shell).
3488    Only MSDOS does not support this (it overrides
3489    this in its config_opsysfile below).  */
3490
3491 #define subprocesses
3492
3493 /* Include the os and machine dependent files.  */
3494 #include config_opsysfile
3495 #include config_machfile
3496
3497 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3498   (There is probably a better place to do this, but right now the Cocoa
3499    side does this in s/darwin.h and we cannot
3500    parallel this exactly since GNUstep is multi-OS.  */
3501 #ifdef HAVE_NS
3502 # ifdef NS_IMPL_GNUSTEP
3503 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3504 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3505 #  define SYSTEM_PURESIZE_EXTRA 30000
3506 # endif /* NS_IMPL_GNUSTEP */
3507 #endif /* HAVE_NS */
3508
3509 /* SIGTYPE is the macro we actually use.  */
3510 #ifndef SIGTYPE
3511 #define SIGTYPE RETSIGTYPE
3512 #endif
3513
3514 #ifdef emacs /* Don't do this for lib-src.  */
3515 /* Tell regex.c to use a type compatible with Emacs.  */
3516 #define RE_TRANSLATE_TYPE Lisp_Object
3517 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3518 #ifdef make_number
3519 /* If make_number is a macro, use it.  */
3520 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3521 #else
3522 /* If make_number is a function, avoid it.  */
3523 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3524 #endif
3525 #endif
3526
3527 /* Avoid link-time collision with system mktime if we will use our own.  */
3528 #if ! HAVE_MKTIME || BROKEN_MKTIME
3529 #define mktime emacs_mktime
3530 #endif
3531
3532 #define my_strftime nstrftime   /* for strftime.c */
3533
3534 /* Some of the files of Emacs which are intended for use with other
3535    programs assume that if you have a config.h file, you must declare
3536    the type of getenv.  */
3537 extern char *getenv ();
3538
3539 /* These default definitions are good for almost all machines.
3540    The exceptions override them in m/MACHINE.h.  */
3541
3542 #ifndef BITS_PER_CHAR
3543 #define BITS_PER_CHAR 8
3544 #endif
3545
3546 #ifndef BITS_PER_SHORT
3547 #define BITS_PER_SHORT 16
3548 #endif
3549
3550 /* Note that lisp.h uses this in a preprocessor conditional, so it
3551    would not work to use sizeof.  That being so, we do all of them
3552    without sizeof, for uniformity's sake.  */
3553 #ifndef BITS_PER_INT
3554 #define BITS_PER_INT 32
3555 #endif
3556
3557 #ifndef BITS_PER_LONG
3558 #ifdef _LP64
3559 #define BITS_PER_LONG 64
3560 #else
3561 #define BITS_PER_LONG 32
3562 #endif
3563 #endif
3564
3565 /* Define if the compiler supports function prototypes.  It may do so but
3566    not define __STDC__ (e.g. DEC C by default) or may define it as zero.  */
3567 #undef PROTOTYPES
3568 /* For mktime.c:  */
3569 #ifndef __P
3570 # if defined PROTOTYPES
3571 #  define __P(args) args
3572 # else
3573 #  define __P(args) ()
3574 # endif  /* GCC.  */
3575 #endif /* __P */
3576
3577 #ifdef HAVE_STRING_H
3578 #include <string.h>
3579 #endif
3580
3581 #ifdef HAVE_STRINGS_H
3582 #include <strings.h>  /* May be needed for bcopy & al.  */
3583 #endif
3584
3585 #ifdef HAVE_STDLIB_H
3586 #include <stdlib.h>
3587 #endif
3588
3589 #ifdef HAVE_ALLOCA_H
3590 # include <alloca.h>
3591 #elif defined __GNUC__
3592 # define alloca __builtin_alloca
3593 #elif defined _AIX
3594 # define alloca __alloca
3595 #else
3596 # include <stddef.h>
3597 # ifdef  __cplusplus
3598 extern "C"
3599 # endif
3600 void *alloca (size_t);
3601 #endif
3602
3603 #ifndef HAVE_SIZE_T
3604 typedef unsigned size_t;
3605 #endif
3606
3607 #if defined __GNUC__ && (__GNUC__ > 2 \
3608                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3609 #define NO_RETURN       __attribute__ ((__noreturn__))
3610 #else
3611 #define NO_RETURN       /* nothing */
3612 #endif
3613
3614 /* These won't be used automatically yet.  We also need to know, at least,
3615    that the stack is continuous.  */
3616 #ifdef __GNUC__
3617 #  ifndef GC_SETJMP_WORKS
3618   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3619 #    define GC_SETJMP_WORKS 1
3620 #  endif
3621 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3622 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3623 #  endif
3624 #endif
3625
3626 #ifndef HAVE_BCOPY
3627 #define bcopy(a,b,s) memcpy (b,a,s)
3628 #endif
3629 #ifndef HAVE_BZERO
3630 #define bzero(a,s) memset (a,0,s)
3631 #endif
3632 #ifndef HAVE_BCMP
3633 #define BCMP memcmp
3634 #endif
3635
3636 #endif /* EMACS_CONFIG_H */
3637
3638 /*
3639 Local Variables:
3640 mode: c
3641 End:
3642 */
3643 ])dnl
3644
3645 #### Report on what we decided to do.
3646 #### Report GTK as a toolkit, even if it doesn't use Xt.
3647 #### It makes printing result more understandable as using GTK sets
3648 #### toolkit_scroll_bars to yes by default.
3649 if test "${HAVE_GTK}" = "yes"; then
3650   USE_X_TOOLKIT=GTK
3651 fi
3652
3653 echo "
3654 Configured for \`${canonical}'.
3655
3656   Where should the build process find the source code?    ${srcdir}
3657   What operating system and machine description files should Emacs use?
3658         \`${opsysfile}' and \`${machfile}'
3659   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3660   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3661   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3662   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3663   What window system should Emacs use?                    ${window_system}
3664   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3665
3666 if test -n "${x_includes}"; then
3667 echo "  Where do we find X Windows header files?                ${x_includes}"
3668 else
3669 echo "  Where do we find X Windows header files?                Standard dirs"
3670 fi
3671 if test -n "${x_libraries}"; then
3672 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3673 else
3674 echo "  Where do we find X Windows libraries?                   Standard dirs"
3675 fi
3676
3677 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3678 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3679 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3680 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3681 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3682 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3683 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3684 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3685 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3686 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3687 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3688
3689 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3690 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3691 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3692 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3693
3694 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3695 echo
3696
3697 if test $USE_XASSERTS = yes; then
3698    echo "  Compiling with asserts turned on."
3699    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3700 fi
3701
3702 echo
3703
3704 if test "$HAVE_NS" = "yes"; then
3705    echo
3706    echo "You must run \"make install\" in order to test the built application.
3707 The installed application will go to nextstep/Emacs.app and can be
3708 run or moved from there."
3709    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3710       echo "The application will be fully self-contained."
3711     else
3712       echo "The lisp resources for the application will be installed under ${prefix}.
3713 You may need to run \"make install\" with sudo.  The application will fail
3714 to run if these resources are not installed."
3715    fi
3716    echo
3717 fi
3718
3719 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3720   echo "D-Bus integration has been tested for GNU/Linux only."
3721   echo
3722 fi
3723
3724
3725 # Remove any trailing slashes in these variables.
3726 [test "${prefix}" != NONE &&
3727   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3728 test "${exec_prefix}" != NONE &&
3729   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3730
3731 dnl You might wonder (I did) why epaths.h is generated by running make,
3732 dnl rather than just letting configure generate it from epaths.in.
3733 dnl One reason is that the various paths are not fully expanded (see above);
3734 dnl eg gamedir=${prefix}/var/games/emacs.
3735 dnl Secondly, the GNU Coding standards require that one should be able
3736 dnl to run `make prefix=/some/where/else' and override the values set
3737 dnl by configure.  This also explains the `move-if-change' test and
3738 dnl the use of force in the `epaths-force' rule in Makefile.in.
3739 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3740         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3741         doc/lispref/Makefile src/Makefile \
3742         lwlib/Makefile lisp/Makefile leim/Makefile, [
3743
3744 ### Make the necessary directories, if they don't exist.
3745 for dir in etc lisp ; do
3746   test -d ${dir} || mkdir ${dir}
3747 done
3748
3749 echo creating src/epaths.h
3750 ${MAKE-make} epaths-force
3751
3752 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3753   echo creating src/.gdbinit
3754   echo source $srcdir/src/.gdbinit > src/.gdbinit
3755 fi
3756
3757 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3758
3759 m4_if(dnl       Do not change this comment
3760    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3761 )dnl