code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2013 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.3.50)
  26
  27 dnl This is the documented way to record the args passed to configure,
  28 dnl rather than $ac_configure_args.
  29 emacs_config_options="$@"
  30 ## Add some environment variables, if they were passed via the environment
  31 ## rather than on the command-line.
  32 for var in CFLAGS CPPFLAGS LDFLAGS; do
  33     case "$emacs_config_options" in
  34       *$var=*) continue ;;
  35     esac
  36     eval val="\$${var}"
  37     test x"$val" = x && continue
  38     emacs_config_options="${emacs_config_options}${emacs_config_options:+ }$var=\"$val\""
  39 done
  40
  41 AC_CONFIG_HEADER(src/config.h:src/config.in)
  42 AC_CONFIG_SRCDIR(src/lisp.h)
  43 AC_CONFIG_AUX_DIR(build-aux)
  44 dnl Fairly arbitrary, older versions might work too.
  45 AM_INIT_AUTOMAKE(1.11)
  46
  47 dnl Support for --program-prefix, --program-suffix and
  48 dnl --program-transform-name options
  49 AC_ARG_PROGRAM
  50
  51 dnl It is important that variables on the RHS not be expanded here,
  52 dnl hence the single quotes.  This is per the GNU coding standards, see
  53 dnl (autoconf) Installation Directory Variables
  54 dnl See also epaths.h below.
  55 lispdir='${datadir}/emacs/${version}/lisp'
  56 leimdir='${datadir}/emacs/${version}/leim'
  57 standardlisppath='${lispdir}:${leimdir}'
  58 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  59 '${datadir}/emacs/site-lisp'
  60 lisppath='${locallisppath}:${standardlisppath}'
  61 etcdir='${datadir}/emacs/${version}/etc'
  62 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  63 docdir='${datadir}/emacs/${version}/etc'
  64 gamedir='${localstatedir}/games/emacs'
  65
  66 dnl Special option to disable the most of other options.
  67 AC_ARG_WITH(all,
  68 [AS_HELP_STRING([--without-all],
  69                 [omit almost all features and build
  70                 small executable with minimal dependencies])],
  71   with_features=$withval,
  72   with_features=yes)
  73
  74 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  75 dnl Create a new --with option that defaults to being disabled.
  76 dnl NAME is the base name of the option.  The shell variable with_NAME
  77 dnl   will be set to either the user's value (if the option is
  78 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  79 dnl   option is not specified).  Note that the shell variable name is
  80 dnl   constructed as autoconf does, by replacing non-alphanumeric
  81 dnl   characters with "_".
  82 dnl HELP-STRING is the help text for the option.
  83 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  84   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  85     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  86 ])dnl
  87
  88 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  89 dnl Create a new --with option that defaults to $with_features.
  90 dnl NAME is the base name of the option.  The shell variable with_NAME
  91 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  92 dnl   'yes' (if the option is not specified).  Note that the shell
  93 dnl   variable name is constructed as autoconf does, by replacing
  94 dnl   non-alphanumeric characters with "_".
  95 dnl HELP-STRING is the help text for the option.
  96 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  97   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  98    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
  99 ])dnl
 100
 101 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 102 if test "$with_pop" = yes; then
 103    AC_DEFINE(MAIL_USE_POP)
 104 fi
 105 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 106
 107 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 108 if test "$with_kerberos" != no; then
 109    AC_DEFINE(KERBEROS)
 110 fi
 111 AH_TEMPLATE(KERBEROS,
 112             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 113
 114 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 115 if test "${with_kerberos5}" != no; then
 116   if test "${with_kerberos}" = no; then
 117     with_kerberos=yes
 118     AC_DEFINE(KERBEROS)
 119   fi
 120   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 121 fi
 122
 123 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 124 dnl FIXME hesiod support may not be present, so it seems like an error
 125 dnl to define, or at least use, this unconditionally.
 126 if test "$with_hesiod" != no; then
 127   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 128 fi
 129
 130 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 131 if test "$with_mmdf" != no; then
 132    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 133 fi
 134
 135 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 136 if test "$with_mail_unlink" != no; then
 137    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 138 fi
 139
 140 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 141     [string giving default POP mail host])],
 142     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 143
 144 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 145
 146 dnl FIXME currently it is not the last.
 147 dnl This should be the last --with option, because --with-x is
 148 dnl added later on when we find the file name of X, and it's best to
 149 dnl keep them together visually.
 150 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 151  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 152 [         case "${withval}" in
 153             y | ye | yes )      val=gtk ;;
 154             n | no )            val=no  ;;
 155             l | lu | luc | luci | lucid )       val=lucid ;;
 156             a | at | ath | athe | athen | athena )      val=athena ;;
 157             m | mo | mot | moti | motif )       val=motif ;;
 158             g | gt | gtk  )     val=gtk ;;
 159             gtk2  )     val=gtk2 ;;
 160             gtk3  )     val=gtk3 ;;
 161             * )
 162 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 163 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk',
 164 `gtk2' or `gtk3'.  `yes' and `gtk' are synonyms.
 165 `athena' and `lucid' are synonyms.])
 166             ;;
 167           esac
 168           with_x_toolkit=$val
 169 ])
 170
 171 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 172 if test "$with_wide_int" = yes; then
 173   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 174 fi
 175
 176 dnl _ON results in a '--without' option in the --help output, so
 177 dnl the help text should refer to "don't compile", etc.
 178 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 179 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 180 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 181 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 182 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 183 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 184 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 185 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 186
 187 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 188 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 189 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 190
 191 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 192 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 193 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 194 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 195 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 196
 197 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 198 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 199 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 200 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 201 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 202 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 203
 204 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 205  [use a file notification library (LIB one of: yes, gfile, inotify, w32, no)])],
 206  [ case "${withval}" in
 207     y | ye | yes )      val=yes ;;
 208     n | no )            val=no  ;;
 209     g | gf | gfi | gfil | gfile )       val=gfile ;;
 210     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 211     w | w3 | w32 )      val=w32 ;;
 212     * ) AC_MSG_ERROR([`--with-file-notification=$withval' is invalid;
 213 this option's value should be `yes', `no', `gfile', `inotify' or `w32'.
 214 `yes' is a synonym for `w32' on MS-Windows, and for `gfile' otherwise.])
 215     ;;
 216    esac
 217    with_file_notification=$val
 218  ],
 219  [with_file_notification=$with_features])
 220
 221 ## For the times when you want to build Emacs but don't have
 222 ## a suitable makeinfo, and can live without the manuals.
 223 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 224 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 225
 226 ## Makefile.in needs the cache file name.
 227 AC_SUBST(cache_file)
 228
 229 ## This is an option because I do not know if all info/man support
 230 ## compressed files, nor how to test if they do so.
 231 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 232 if test $with_compress_info = yes; then
 233    GZIP_INFO=yes
 234 else
 235    GZIP_INFO=
 236 fi
 237 AC_SUBST(GZIP_INFO)
 238
 239 AC_ARG_WITH([pkg-config-prog],dnl
 240 [AS_HELP_STRING([--with-pkg-config-prog=FILENAME],
 241                   [file name of pkg-config for finding GTK and librsvg])])
 242 if test "X${with_pkg_config_prog}" != X; then
 243    if test "${with_pkg_config_prog}" != yes; then
 244       PKG_CONFIG="${with_pkg_config_prog}"
 245    fi
 246 fi
 247
 248 AC_ARG_WITH(gameuser,dnl
 249 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 250 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 251   && gameuser="${with_gameuser}"
 252 test "X$gameuser" = X && gameuser=games
 253
 254 AC_ARG_WITH([gnustep-conf],dnl
 255 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 256    [name of GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 257 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 258   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 259 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 260      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 261
 262 AC_ARG_ENABLE(ns-self-contained,
 263 [AS_HELP_STRING([--disable-ns-self-contained],
 264                 [disable self contained build under NeXTstep])],
 265    EN_NS_SELF_CONTAINED=$enableval,
 266    EN_NS_SELF_CONTAINED=yes)
 267
 268 AC_ARG_ENABLE(locallisppath,
 269 [AS_HELP_STRING([--enable-locallisppath=PATH],
 270                 [directories Emacs should search for lisp files specific
 271                  to this site])],
 272 if test "${enableval}" = "no"; then
 273   locallisppath=
 274 elif test "${enableval}" != "yes"; then
 275   locallisppath=${enableval}
 276 fi)
 277
 278 AC_ARG_ENABLE(checking,
 279 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 280                 [enable expensive run-time checks.  With LIST,
 281                  enable only specific categories of checks.
 282                  Categories are: all,yes,no.
 283                  Flags are: stringbytes, stringoverrun, stringfreelist,
 284                  xmallocoverrun, conslist, glyphs])],
 285 [ac_checking_flags="${enableval}"],[])
 286 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 287 for check in $ac_checking_flags
 288 do
 289         case $check in
 290         # these set all the flags to specific states
 291         yes)            ac_enable_checking=1 ;;
 292         no)             ac_enable_checking= ;
 293                         ac_gc_check_stringbytes= ;
 294                         ac_gc_check_string_overrun= ;
 295                         ac_gc_check_string_free_list= ;
 296                         ac_xmalloc_overrun= ;
 297                         ac_gc_check_cons_list= ;
 298                         ac_glyphs_debug= ;;
 299         all)            ac_enable_checking=1 ;
 300                         ac_gc_check_stringbytes=1 ;
 301                         ac_gc_check_string_overrun=1 ;
 302                         ac_gc_check_string_free_list=1 ;
 303                         ac_xmalloc_overrun=1 ;
 304                         ac_gc_check_cons_list=1 ;
 305                         ac_glyphs_debug=1 ;;
 306         # these enable particular checks
 307         stringbytes)    ac_gc_check_stringbytes=1 ;;
 308         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 309         stringfreelist) ac_gc_check_string_free_list=1 ;;
 310         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 311         conslist)       ac_gc_check_cons_list=1 ;;
 312         glyphs)         ac_glyphs_debug=1 ;;
 313         *)      AC_MSG_ERROR(unknown check category $check) ;;
 314         esac
 315 done
 316 IFS="$ac_save_IFS"
 317
 318 if test x$ac_enable_checking != x ; then
 319   AC_DEFINE(ENABLE_CHECKING, 1,
 320 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 321 fi
 322 if test x$ac_gc_check_stringbytes != x ; then
 323   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 324 [Define this temporarily to hunt a bug.  If defined, the size of
 325    strings is redundantly recorded in sdata structures so that it can
 326    be compared to the sizes recorded in Lisp strings.])
 327 fi
 328 if test x$ac_gc_check_string_overrun != x ; then
 329   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 330 [Define this to check for short string overrun.])
 331 fi
 332 if test x$ac_gc_check_string_free_list != x ; then
 333   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 334 [Define this to check the string free list.])
 335 fi
 336 if test x$ac_xmalloc_overrun != x ; then
 337   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 338 [Define this to check for malloc buffer overrun.])
 339 fi
 340 if test x$ac_gc_check_cons_list != x ; then
 341   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 342 [Define this to check for errors in cons list.])
 343 fi
 344 if test x$ac_glyphs_debug != x ; then
 345   AC_DEFINE(GLYPH_DEBUG, 1,
 346 [Define this to enable glyphs debugging code.])
 347 fi
 348
 349 AC_ARG_ENABLE(check-lisp-object-type,
 350 [AS_HELP_STRING([--enable-check-lisp-object-type],
 351                 [enable compile time checks for the Lisp_Object data type.
 352                 This is useful for development for catching certain types of bugs.])],
 353 if test "${enableval}" != "no"; then
 354    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 355    [Define this to enable compile time checks for the Lisp_Object data type.])
 356 fi)
 357
 358
 359 dnl The name of this option is unfortunate.  It predates, and has no
 360 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 361 dnl Actually, it stops it working.
 362 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 363 AC_ARG_ENABLE(profiling,
 364 [AS_HELP_STRING([--enable-profiling],
 365                 [build emacs with low-level, gprof profiling support.
 366                 Mainly useful for debugging Emacs itself.  May not work on
 367                 all platforms.  Stops profiler.el working.])],
 368 [ac_enable_profiling="${enableval}"],[])
 369 if test x$ac_enable_profiling != x ; then
 370    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 371 else
 372    PROFILING_CFLAGS=
 373 fi
 374 AC_SUBST(PROFILING_CFLAGS)
 375
 376 AC_ARG_ENABLE(autodepend,
 377 [AS_HELP_STRING([--enable-autodepend],
 378                 [automatically generate dependencies to .h-files.
 379                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 380                  found])],
 381 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 382
 383 AC_ARG_ENABLE(gtk-deprecation-warnings,
 384 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 385                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 386 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 387
 388 #### Make srcdir absolute, if it isn't already.  It's important to
 389 #### avoid running the file name through pwd unnecessarily, since pwd can
 390 #### give you automounter prefixes, which can go away.  We do all this
 391 #### so Emacs can find its files when run uninstalled.
 392 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 393 unset CDPATH
 394 case "${srcdir}" in
 395   [[\\/]]* | ?:[[\\/]]*) ;;
 396   . )
 397     ## We may be able to use the $PWD environment variable to make this
 398     ## absolute.  But sometimes PWD is inaccurate.
 399     ## Note: we used to use $PWD at the end instead of `pwd`,
 400     ## but that tested only for a well-formed and valid PWD,
 401     ## it did not object when PWD was well-formed and valid but just wrong.
 402     if test ".$PWD" != "." && test ".`(cd "$PWD" ; sh -c pwd)`" = ".`pwd`"  ;
 403     then
 404       srcdir="$PWD"
 405     else
 406       srcdir=`(cd "$srcdir"; pwd)`
 407     fi
 408   ;;
 409   *  ) srcdir=`(cd "$srcdir"; pwd)` ;;
 410 esac
 411
 412 ### Canonicalize the configuration name.
 413
 414 AC_CANONICAL_HOST
 415 canonical=$host
 416 configuration=${host_alias-${build_alias-$host}}
 417
 418 dnl This used to use changequote, but, apart from `changequote is evil'
 419 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 420 dnl the great gob of text.  Thus it's not processed for possible expansion.
 421 dnl Just make sure the brackets remain balanced.
 422 dnl
 423 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 424 dnl indicated by comments.
 425 dnl quotation begins
 426 [
 427
 428 ### If you add support for a new configuration, add code to this
 429 ### switch statement to recognize your configuration name and select
 430 ### the appropriate operating system file.
 431
 432 ### You would hope that you could choose an s/*.h
 433 ### file based on the operating system portion.  However, it turns out
 434 ### that each s/*.h file is pretty manufacturer-specific.
 435 ### So we basically have to have a special case for each
 436 ### configuration name.
 437 ###
 438 ### As far as handling version numbers on operating systems is
 439 ### concerned, make sure things will fail in a fixable way.  If
 440 ### /etc/MACHINES doesn't say anything about version numbers, be
 441 ### prepared to handle anything reasonably.  If version numbers
 442 ### matter, be sure /etc/MACHINES says something about it.
 443
 444 opsys='' unported=no
 445 case "${canonical}" in
 446
 447   ## GNU/Linux and similar ports
 448   *-*-linux* )
 449     opsys=gnu-linux
 450   ;;
 451
 452   ## FreeBSD ports
 453   *-*-freebsd* )
 454     opsys=freebsd
 455   ;;
 456
 457   ## DragonFly ports
 458   *-*-dragonfly* )
 459     opsys=dragonfly
 460   ;;
 461
 462   ## FreeBSD kernel + glibc based userland
 463   *-*-kfreebsd*gnu* )
 464     opsys=gnu-kfreebsd
 465   ;;
 466
 467   ## NetBSD ports
 468   *-*-netbsd* )
 469     opsys=netbsd
 470   ;;
 471
 472   ## OpenBSD ports
 473   *-*-openbsd* )
 474     opsys=openbsd
 475   ;;
 476
 477   ## Apple Darwin / Mac OS X
 478   *-apple-darwin* )
 479     case "${canonical}" in
 480       i[3456]86-* )  ;;
 481       powerpc-* )    ;;
 482       x86_64-* )     ;;
 483       * )            unported=yes ;;
 484     esac
 485     opsys=darwin
 486     ## Use fink packages if available.
 487     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 488 ##    if test -d /sw/include && test -d /sw/lib; then
 489 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 490 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 491 ##    fi
 492   ;;
 493
 494   ## Cygwin ports
 495   *-*-cygwin )
 496     opsys=cygwin
 497   ;;
 498
 499   ## HP 9000 series 700 and 800, running HP/UX
 500   hppa*-hp-hpux10.2* )
 501     opsys=hpux10-20
 502   ;;
 503   hppa*-hp-hpux1[1-9]* )
 504     opsys=hpux11
 505     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 506   ;;
 507
 508   ## IBM machines
 509   rs6000-ibm-aix4.[23]* )
 510     opsys=aix4-2
 511   ;;
 512   powerpc-ibm-aix4.[23]*  )
 513     opsys=aix4-2
 514   ;;
 515   rs6000-ibm-aix[56]* )
 516     opsys=aix4-2
 517   ;;
 518   powerpc-ibm-aix[56]*  )
 519     opsys=aix4-2
 520   ;;
 521
 522   ## Silicon Graphics machines
 523   ## Iris 4D
 524   mips-sgi-irix6.5 )
 525     opsys=irix6-5
 526     # Without defining _LANGUAGE_C, things get masked out in the headers
 527     # so that, for instance, grepping for `free' in stdlib.h fails and
 528     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 529     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 530   ;;
 531
 532   ## Suns
 533   *-sun-solaris* \
 534     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 535     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 536     case "${canonical}" in
 537       i[3456]86-*-* )   ;;
 538       amd64-*-*|x86_64-*-*) ;;
 539       sparc* )          ;;
 540       * )               unported=yes ;;
 541     esac
 542     case "${canonical}" in
 543       *-sunos5.6* | *-solaris2.6* )
 544                 opsys=sol2-6
 545                 RANLIB="ar -ts"
 546                 ;;
 547       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 548                 opsys=sol2-6
 549                 emacs_check_sunpro_c=yes
 550                 ;;
 551       *-sunos5* | *-solaris* )
 552                 opsys=sol2-10
 553                 emacs_check_sunpro_c=yes
 554                 ;;
 555     esac
 556     ## Watch out for a compiler that we know will not work.
 557     case "${canonical}" in
 558      *-solaris* | *-sunos5* )
 559                 if [ "x$CC" = x/usr/ucb/cc ]; then
 560                   ## /usr/ucb/cc doesn't work;
 561                   ## we should find some other compiler that does work.
 562                   unset CC
 563                 fi
 564                 ;;
 565       *) ;;
 566     esac
 567   ;;
 568
 569   ## Intel 386 machines where we don't care about the manufacturer.
 570   i[3456]86-*-* )
 571     case "${canonical}" in
 572       *-darwin* )               opsys=darwin ;;
 573       *-mingw32 )
 574                 opsys=mingw32
 575                 # MinGW overrides and adds some system headers in nt/inc.
 576                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 577                 ;;
 578       *-sysv4.2uw* )            opsys=unixware ;;
 579       *-sysv5uw* )              opsys=unixware ;;
 580       *-sysv5OpenUNIX* )        opsys=unixware ;;
 581       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 582     esac
 583   ;;
 584
 585   * )
 586     unported=yes
 587   ;;
 588 esac
 589
 590 ### If the code above didn't choose an operating system, just choose
 591 ### an operating system based on the configuration name.  You really
 592 ### only want to use this when you have no idea what the right
 593 ### operating system is; if you know what operating systems a machine
 594 ### runs, it's cleaner to make it explicit in the case statement
 595 ### above.
 596 if test x"${opsys}" = x; then
 597   case "${canonical}" in
 598     *-gnu* )                            opsys=gnu ;;
 599     * )
 600       unported=yes
 601     ;;
 602   esac
 603 fi
 604
 605 ]
 606 dnl quotation ends
 607
 608 if test $unported = yes; then
 609   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 610 Check `etc/MACHINES' for recognized configuration names.])
 611 fi
 612
 613
 614 #### Choose a compiler.
 615
 616 dnl Sets GCC=yes if using gcc.
 617 AC_PROG_CC
 618 AM_PROG_CC_C_O
 619
 620 if test x$GCC = xyes; then
 621   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 622 else
 623   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 624 fi
 625
 626 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 627 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 628 dnl that clash with MinGW.
 629 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 630
 631 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 632 # as we don't use them.
 633 AC_DEFUN([gl_FCNTL_O_FLAGS])
 634 # Avoid gnulib's threadlib module, as we do threads our own way.
 635 AC_DEFUN([gl_THREADLIB])
 636
 637 # Initialize gnulib right after choosing the compiler.
 638 dnl Amongst other things, this sets AR and ARFLAGS.
 639 gl_EARLY
 640
 641 if test "$ac_test_CFLAGS" != set; then
 642   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 643   # if -g3 works and the user does not specify CFLAGS.
 644   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 645   case $CFLAGS in
 646     '-g')
 647       emacs_g3_CFLAGS='-g3';;
 648     '-g -O2')
 649       emacs_g3_CFLAGS='-g3 -O2';;
 650     *)
 651       emacs_g3_CFLAGS='';;
 652   esac
 653   if test -n "$emacs_g3_CFLAGS"; then
 654     emacs_save_CFLAGS=$CFLAGS
 655     CFLAGS=$emacs_g3_CFLAGS
 656     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 657       [emacs_cv_prog_cc_g3],
 658       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 659          [emacs_cv_prog_cc_g3=yes],
 660          [emacs_cv_prog_cc_g3=no])])
 661     if test $emacs_cv_prog_cc_g3 != yes; then
 662       CFLAGS=$emacs_save_CFLAGS
 663     fi
 664     if test $opsys = mingw32; then
 665       CFLAGS="$CFLAGS -gdwarf-2"
 666     fi
 667   fi
 668
 669   case $CFLAGS in
 670     *-O*) ;;
 671     *)
 672       # No optimization flag was inferred for this non-GCC compiler.
 673       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 674       emacs_save_CFLAGS=$CFLAGS
 675       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 676       CFLAGS=${CFLAGS}-O
 677       AC_CACHE_CHECK([whether $CC accepts -O],
 678         [emacs_cv_prog_cc_o],
 679         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 680            [emacs_cv_prog_cc_o=yes],
 681            [emacs_cv_prog_cc_o=no])])
 682       if test $emacs_cv_prog_cc_o != yes; then
 683         CFLAGS=$emacs_save_CFLAGS
 684       fi ;;
 685   esac
 686 fi
 687
 688 AC_ARG_ENABLE([gcc-warnings],
 689   [AS_HELP_STRING([--enable-gcc-warnings],
 690                   [turn on lots of GCC warnings/errors. This is intended for
 691                    developers, and may generate false alarms when used
 692                    with older or non-GNU development tools.])],
 693   [case $enableval in
 694      yes|no) ;;
 695      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 696    esac
 697    gl_gcc_warnings=$enableval],
 698   [gl_gcc_warnings=no]
 699 )
 700
 701 AC_ARG_ENABLE(link-time-optimization,
 702 [AS_HELP_STRING([--enable-link-time-optimization],
 703                 [build emacs with link-time optimization.
 704                  This is supported only for GCC since 4.5.0.])],
 705 if test "${enableval}" != "no"; then
 706    AC_MSG_CHECKING([whether link-time optimization is supported])
 707    ac_lto_supported=no
 708    if test x$GCC = xyes; then
 709       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
 710       if test x$CPUS != x; then
 711          LTO="-flto=$CPUS"
 712       else
 713          LTO="-flto"
 714       fi
 715       old_CFLAGS=$CFLAGS
 716       CFLAGS="$CFLAGS $LTO"
 717       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
 718         [ac_lto_supported=yes], [ac_lto_supported=no])
 719       CFLAGS="$old_CFLAGS"
 720    fi
 721    AC_MSG_RESULT([$ac_lto_supported])
 722    if test "$ac_lto_supported" = "yes"; then
 723       CFLAGS="$CFLAGS $LTO"
 724    fi
 725 fi)
 726
 727 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 728 # ------------------------------------------------
 729 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 730 # Otherwise, run RUN-IF-NOT-FOUND.
 731 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 732   [AC_PREPROC_IFELSE(
 733     [AC_LANG_PROGRAM(
 734       [[
 735 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 736 /* ok */
 737 #else
 738 # error "your version of gcc is older than $1.$2"
 739 #endif
 740       ]]),
 741     ], [$3], [$4])
 742   ]
 743 )
 744
 745 # When compiling with GCC, prefer -isystem to -I when including system
 746 # include files, to avoid generating useless diagnostics for the files.
 747 if test "$gl_gcc_warnings" != yes; then
 748   isystem='-I'
 749 else
 750   isystem='-isystem '
 751
 752   # This, $nw, is the list of warnings we disable.
 753   nw=
 754
 755   case $with_x_toolkit in
 756     lucid | athena | motif)
 757        # Old toolkits mishandle 'const'.
 758        nw="$nw -Wwrite-strings"
 759        ;;
 760     *)
 761        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 762        ;;
 763   esac
 764   AC_SUBST([WERROR_CFLAGS])
 765
 766   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 767   nw="$nw -Woverlength-strings"     # Not a problem these days
 768   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 769   nw="$nw -Wformat-nonliteral"      # we do this a lot
 770   nw="$nw -Wvla"                    # warnings in gettext.h
 771   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 772   nw="$nw -Wswitch-default"         # Too many warnings for now
 773   nw="$nw -Winline"                 # OK to ignore 'inline'
 774   nw="$nw -Wjump-misses-init"       # We sometimes safely jump over init.
 775   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 776                                     # signed overflow has undefined behavior
 777   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 778   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 779   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 780
 781   # Emacs doesn't care about shadowing; see
 782   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 783   nw="$nw -Wshadow"
 784
 785   # Emacs's use of alloca inhibits protecting the stack.
 786   nw="$nw -Wstack-protector"
 787
 788   # The following line should be removable at some point.
 789   nw="$nw -Wsuggest-attribute=pure"
 790
 791   # clang is unduly picky about some things.
 792   AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 793     [AC_COMPILE_IFELSE(
 794        [AC_LANG_PROGRAM([[
 795             #ifndef __clang__
 796               #error "not clang"
 797             #endif
 798           ]])],
 799        [emacs_cv_clang=yes],
 800        [emacs_cv_clang=no])])
 801   if test $emacs_cv_clang = yes; then
 802     nw="$nw -Wcast-align"
 803   fi
 804
 805   gl_MANYWARN_ALL_GCC([ws])
 806   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 807   for w in $ws; do
 808     gl_WARN_ADD([$w])
 809   done
 810   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 811   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 812   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 813   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 814   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 815   gl_WARN_ADD([-Wno-format-nonliteral])
 816
 817   # In spite of excluding -Wlogical-op above, it is enabled, as of
 818   # gcc 4.5.0 20090517.
 819   gl_WARN_ADD([-Wno-logical-op])
 820
 821   # More things that clang is unduly picky about.
 822   if test $emacs_cv_clang = yes; then
 823     gl_WARN_ADD([-Wno-format-extra-args])
 824     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 825     gl_WARN_ADD([-Wno-unused-command-line-argument])
 826     gl_WARN_ADD([-Wno-unused-value])
 827   fi
 828
 829   gl_WARN_ADD([-fdiagnostics-show-option])
 830   gl_WARN_ADD([-funit-at-a-time])
 831
 832   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 833   AH_VERBATIM([FORTIFY_SOURCE],
 834   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 835       without upsetting glibc 2.15+. */
 836    #if !defined _FORTIFY_SOURCE && defined __OPTIMIZE__ && __OPTIMIZE__
 837    # define _FORTIFY_SOURCE 2
 838    #endif
 839   ])
 840   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 841
 842   # We use a slightly smaller set of warning options for lib/.
 843   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 844   nw=
 845   nw="$nw -Wunused-macros"
 846
 847   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 848   AC_SUBST([GNULIB_WARN_CFLAGS])
 849 fi
 850
 851
 852
 853 dnl Some other nice autoconf tests.
 854 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 855 dnl AC_PROG_INSTALL
 856 dnl AC_PROG_MKDIR_P
 857 dnl if test "x$RANLIB" = x; then
 858 dnl   AC_PROG_RANLIB
 859 dnl fi
 860
 861
 862 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
 863 dnl can be made to directories.  This is not relevant for our usage, and
 864 dnl excludes some cases that work fine for us.  Eg MS Windows or files
 865 dnl hosted on AFS, both examples where simple links work, but links to
 866 dnl directories fail.  We use a cut-down version instead.
 867 dnl AC_PROG_LN_S
 868
 869 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
 870 rm -f conf$$ conf$$.file
 871
 872 LN_S_FILEONLY='cp -p'
 873
 874 if (echo >conf$$.file) 2>/dev/null; then
 875   if ln -s conf$$.file conf$$ 2>/dev/null; then
 876     LN_S_FILEONLY='ln -s'
 877   elif ln conf$$.file conf$$ 2>/dev/null; then
 878     LN_S_FILEONLY=ln
 879   fi
 880 fi
 881
 882 rm -f conf$$ conf$$.file
 883
 884 if test "$LN_S_FILEONLY" = "ln -s"; then
 885    AC_MSG_RESULT([yes])
 886 else
 887    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
 888 fi
 889
 890 AC_SUBST(LN_S_FILEONLY)
 891
 892
 893 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
 894 dnl doesn't support links to directories, as in "ln file dir".  But that
 895 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
 896 dnl executables at "make install" time.
 897 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
 898 dnl for more details.
 899 if test "$opsys" = "mingw32"; then
 900   LN_S="ln"
 901 fi
 902
 903 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 904   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 905 dnl Don't use GZIP, which is used by gzip for additional parameters.
 906 AC_PATH_PROG(GZIP_PROG, gzip)
 907
 908 if test $opsys = gnu-linux; then
 909   AC_PATH_PROG(PAXCTL, paxctl,,
 910     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 911   if test "X$PAXCTL" != X; then
 912     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
 913     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 914       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
 915       else AC_MSG_RESULT(no); PAXCTL=""; fi])
 916   fi
 917 fi
 918
 919 ## Need makeinfo >= 4.7 (?) to build the manuals.
 920 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 921 dnl By this stage, configure has already checked for egrep and set EGREP,
 922 dnl or exited with an error if no egrep was found.
 923 if test "$MAKEINFO" != "no"; then
 924   case `
 925     $MAKEINFO --version 2> /dev/null |
 926     $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'
 927   ` in
 928     '') MAKEINFO=no;;
 929   esac
 930 fi
 931
 932 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 933 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 934 ## therefore in the category of "special tools" not normally required, which
 935 ## configure does not have to check for (eg autoconf itself).
 936 ## In a Bazaar checkout on the other hand, the manuals are not included.
 937 ## So makeinfo is a requirement to build from Bazaar, and configure
 938 ## should test for it as it does for any other build requirement.
 939 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 940 ## with pre-built manuals, from a Bazaar checkout.
 941 HAVE_MAKEINFO=yes
 942
 943 if test "$MAKEINFO" = "no"; then
 944   MAKEINFO=makeinfo
 945   if test "x${with_makeinfo}" = "xno"; then
 946     HAVE_MAKEINFO=no
 947   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
 948     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 949 source tree does not seem to have pre-built manuals in the `info' directory.
 950 Either install a suitable version of makeinfo, or re-run configure
 951 with the `--without-makeinfo' option to build without the manuals.] )
 952   fi
 953 fi
 954 AC_SUBST(HAVE_MAKEINFO)
 955
 956 dnl Just so that there is only a single place we need to edit.
 957 INFO_EXT=.info
 958 INFO_OPTS=--no-split
 959 AC_SUBST(INFO_EXT)
 960 AC_SUBST(INFO_OPTS)
 961
 962 dnl Add our options to ac_link now, after it is set up.
 963
 964 if test x$GCC = xyes; then
 965   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 966     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 967 else
 968   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 969     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 970 fi
 971
 972 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 973 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 974 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 975 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 976 dnl if not built to support GNU ld.
 977
 978 late_LDFLAGS=$LDFLAGS
 979 if test x$GCC = xyes; then
 980   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 981 else
 982   LDFLAGS="$LDFLAGS -znocombreloc"
 983 fi
 984
 985 AC_MSG_CHECKING([for -znocombreloc])
 986 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 987   [AC_MSG_RESULT(yes)],
 988   LDFLAGS=$late_LDFLAGS
 989   [AC_MSG_RESULT(no)])
 990
 991
 992 dnl The function dump-emacs will not be defined and temacs will do
 993 dnl (load "loadup") automatically unless told otherwise.
 994 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 995 case "$opsys" in
 996   your-opsys-here) CANNOT_DUMP=yes ;;
 997 esac
 998
 999 test "$CANNOT_DUMP" = "yes" && \
1000   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1001
1002 AC_SUBST(CANNOT_DUMP)
1003
1004
1005 UNEXEC_OBJ=unexelf.o
1006 case "$opsys" in
1007   # MSDOS uses unexcoff.o
1008   aix4-2)
1009    UNEXEC_OBJ=unexaix.o
1010    ;;
1011   cygwin)
1012    UNEXEC_OBJ=unexcw.o
1013    ;;
1014   darwin)
1015    UNEXEC_OBJ=unexmacosx.o
1016    ;;
1017   hpux10-20 | hpux11)
1018    UNEXEC_OBJ=unexhp9k800.o
1019    ;;
1020   mingw32)
1021    UNEXEC_OBJ=unexw32.o
1022    ;;
1023   sol2-10)
1024    # Use the Solaris dldump() function, called from unexsol.c, to dump
1025    # emacs, instead of the generic ELF dump code found in unexelf.c.
1026    # The resulting binary has a complete symbol table, and is better
1027    # for debugging and other observability tools (debuggers, pstack, etc).
1028    #
1029    # If you encounter a problem using dldump(), please consider sending
1030    # a message to the OpenSolaris tools-linking mailing list:
1031    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1032    #
1033    # It is likely that dldump() works with older Solaris too, but this has
1034    # not been tested, so for now this change is for Solaris 10 or newer.
1035    UNEXEC_OBJ=unexsol.o
1036    ;;
1037 esac
1038
1039 LD_SWITCH_SYSTEM=
1040 case "$opsys" in
1041   freebsd|dragonfly)
1042    ## Let `ld' find image libs and similar things in /usr/local/lib.
1043    ## The system compiler, GCC, has apparently been modified to not
1044    ## look there, contrary to what a stock GCC would do.
1045 ### It's not our place to do this.  See bug#10313#17.
1046 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1047       :
1048    ;;
1049
1050   gnu-linux)
1051    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1052    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1053    ;;
1054
1055   netbsd)
1056 ### It's not our place to do this.  See bug#10313#17.
1057 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1058       :
1059    ;;
1060
1061   openbsd)
1062    ## Han Boetes <han@boetes.org> says this is necessary,
1063    ## otherwise Emacs dumps core on elf systems.
1064    LD_SWITCH_SYSTEM="-Z"
1065    ;;
1066 esac
1067 AC_SUBST(LD_SWITCH_SYSTEM)
1068
1069 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1070
1071 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1072 ## which has not been defined yet.  When this was handled with cpp,
1073 ## it was expanded to null when configure sourced the s/*.h file.
1074 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1075 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1076 ## (or somesuch), but because it is supposed to go at the _front_
1077 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1078 ## Compare with the gnu-linux case below, which added to the end
1079 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1080 ## LD_SWITCH_SYSTEM_TEMACS.
1081 case "$opsys" in
1082   netbsd|openbsd)
1083    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1084 esac
1085
1086
1087 C_SWITCH_MACHINE=
1088 case $canonical in
1089  alpha*)
1090   AC_CHECK_DECL([__ELF__])
1091   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1092     ## With ELF, make sure that all common symbols get allocated to in the
1093     ## data section.  Otherwise, the dump of temacs may miss variables in
1094     ## the shared library that have been initialized.  For example, with
1095     ## GNU libc, __malloc_initialized would normally be resolved to the
1096     ## shared library's .bss section, which is fatal.
1097     if test "x$GCC" = "xyes"; then
1098       C_SWITCH_MACHINE="-fno-common"
1099     else
1100       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
1101     fi
1102   else
1103     UNEXEC_OBJ=unexalpha.o
1104   fi
1105   ;;
1106 esac
1107 AC_SUBST(C_SWITCH_MACHINE)
1108
1109 AC_SUBST(UNEXEC_OBJ)
1110
1111 C_SWITCH_SYSTEM=
1112 ## Some programs in src produce warnings saying certain subprograms
1113 ## are too complex and need a MAXMEM value greater than 2000 for
1114 ## additional optimization.  --nils@exp-math.uni-essen.de
1115 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1116   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1117 test "$opsys" = "mingw32" && C_SWITCH_SYSTEM="-mtune=pentium4"
1118 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1119 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1120 AC_SUBST(C_SWITCH_SYSTEM)
1121
1122
1123 LIBS_SYSTEM=
1124 case "$opsys" in
1125   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1126   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1127
1128   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1129
1130   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1131
1132   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1133
1134   ## Motif needs -lgen.
1135   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1136 esac
1137
1138 AC_SUBST(LIBS_SYSTEM)
1139
1140 ### Make sure subsequent tests use flags consistent with the build flags.
1141
1142 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1143   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1144 else
1145   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1146 fi
1147
1148 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
1149 AC_DEFUN([AC_TYPE_SIZE_T])
1150 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1151 AC_DEFUN([AC_TYPE_UID_T])
1152
1153
1154 LIB_MATH=-lm
1155 dnl Current possibilities handled by sed (aix4-2 -> aix,
1156 dnl gnu-linux -> gnu/linux, etc.):
1157 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
1158 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1159 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1160
1161 case $opsys in
1162   cygwin )
1163     LIB_MATH=
1164     ;;
1165   darwin )
1166     ## Adding -lm confuses the dynamic linker, so omit it.
1167     LIB_MATH=
1168     ;;
1169   freebsd | dragonfly )
1170     SYSTEM_TYPE=berkeley-unix
1171     ;;
1172   gnu-linux | gnu-kfreebsd )
1173     ;;
1174   hpux10-20 | hpux11 )
1175     ;;
1176   mingw32 )
1177     LIB_MATH=
1178     SYSTEM_TYPE=windows-nt
1179     ;;
1180   dnl NB this may be adjusted below.
1181   netbsd | openbsd )
1182     SYSTEM_TYPE=berkeley-unix
1183     ;;
1184
1185   sol2* | unixware )
1186     SYSTEM_TYPE=usg-unix-v
1187     ;;
1188
1189 esac
1190
1191 AC_SUBST(LIB_MATH)
1192 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1193   [The type of system you are compiling for; sets `system-type'.])
1194
1195
1196 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1197 pre_PKG_CONFIG_LIBS=$LIBS
1198
1199 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1200
1201 dnl This function definition taken from Gnome 2.0
1202 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1203 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1204 dnl also defines GSTUFF_PKG_ERRORS on error
1205 AC_DEFUN([PKG_CHECK_MODULES], [
1206   succeeded=no
1207
1208   if test "$PKG_CONFIG" = "no" ; then
1209      ifelse([$4], , [AC_MSG_ERROR([
1210       *** The pkg-config script could not be found. Make sure it is in your path, or give the full name of pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1211   else
1212      PKG_CONFIG_MIN_VERSION=0.9.0
1213      if "$PKG_CONFIG" --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1214         AC_MSG_CHECKING(for $2)
1215
1216         if "$PKG_CONFIG" --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1217            $1_CFLAGS=`"$PKG_CONFIG" --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1218            $1_LIBS=`"$PKG_CONFIG" --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1219             edit_cflags="
1220               s,///*,/,g
1221               s/^/ /
1222               s/ -I/ $isystem/g
1223               s/^ //
1224             "
1225             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1226             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1227             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1228             succeeded=yes
1229         else
1230             AC_MSG_RESULT(no)
1231             $1_CFLAGS=""
1232             $1_LIBS=""
1233             ## If we have a custom action on failure, don't print errors, but
1234             ## do set a variable so people can do so.  Do it in a subshell
1235             ## to capture any diagnostics in invoking pkg-config.
1236             $1_PKG_ERRORS=`("$PKG_CONFIG" --print-errors "$2") 2>&1`
1237             ifelse([$4], ,echo "$$1_PKG_ERRORS",)
1238         fi
1239
1240         AC_SUBST($1_CFLAGS)
1241         AC_SUBST($1_LIBS)
1242      else
1243         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1244         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1245      fi
1246   fi
1247
1248   if test $succeeded = yes; then
1249      ifelse([$3], , :, [$3])
1250   else
1251      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1252   fi
1253 ])
1254
1255 if test "${with_sound}" != "no"; then
1256   # Sound support for GNU/Linux, the free BSDs, and MinGW.
1257   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h,
1258     have_sound_header=yes, [], [
1259     #ifdef __MINGW32__
1260     #define WIN32_LEAN_AND_MEAN
1261     #include <windows.h>
1262     #endif
1263     ])
1264   # Emulation library used on NetBSD.
1265   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1266   AC_SUBST(LIBSOUND)
1267
1268   ALSA_REQUIRED=1.0.0
1269   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1270   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1271   if test $HAVE_ALSA = yes; then
1272     SAVE_CFLAGS="$CFLAGS"
1273     SAVE_LIBS="$LIBS"
1274     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1275     LIBS="$ALSA_LIBS $LIBS"
1276     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1277                     emacs_alsa_normal=yes,
1278                     emacs_alsa_normal=no)
1279     if test "$emacs_alsa_normal" != yes; then
1280       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1281                      [[snd_lib_error_set_handler (0);]])],
1282                      emacs_alsa_subdir=yes,
1283                      emacs_alsa_subdir=no)
1284       if test "$emacs_alsa_subdir" != yes; then
1285         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1286       fi
1287       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1288     fi
1289
1290     CFLAGS="$SAVE_CFLAGS"
1291     LIBS="$SAVE_LIBS"
1292     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1293     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1294     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1295   fi
1296
1297   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1298   dnl compiles only on the specified platforms.  For others, it
1299   dnl probably doesn't make sense to try.
1300   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1301      case "$opsys" in
1302        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1303        gnu-linux|freebsd|netbsd|mingw32)
1304          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1305          ;;
1306      esac
1307   fi
1308
1309   AC_SUBST(CFLAGS_SOUND)
1310 fi
1311
1312 dnl checks for header files
1313 AC_CHECK_HEADERS_ONCE(
1314   linux/version.h sys/systeminfo.h
1315   coff.h pty.h
1316   sys/resource.h
1317   sys/utsname.h pwd.h utmp.h util.h)
1318
1319 AC_MSG_CHECKING(if personality LINUX32 can be set)
1320 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1321                emacs_cv_personality_linux32=yes,
1322                emacs_cv_personality_linux32=no)
1323 AC_MSG_RESULT($emacs_cv_personality_linux32)
1324
1325 if test $emacs_cv_personality_linux32 = yes; then
1326   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1327             [Define to 1 if personality LINUX32 can be set.])
1328 fi
1329
1330 dnl On Solaris 8 there's a compilation warning for term.h because
1331 dnl it doesn't define `bool'.
1332 AC_CHECK_HEADERS(term.h, , , -)
1333 AC_HEADER_TIME
1334 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1335                                       ]])
1336 if test $ac_cv_have_decl_sys_siglist != yes; then
1337   # For Tru64, at least:
1338   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1339                                           ]])
1340   if test $ac_cv_have_decl___sys_siglist = yes; then
1341     AC_DEFINE(sys_siglist, __sys_siglist,
1342               [Define to any substitute for sys_siglist.])
1343   fi
1344 fi
1345 AC_HEADER_SYS_WAIT
1346
1347 dnl Check for speed_t typedef.
1348 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1349   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1350     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1351 if test $emacs_cv_speed_t = yes; then
1352   AC_DEFINE(HAVE_SPEED_T, 1,
1353            [Define to 1 if `speed_t' is declared by <termios.h>.])
1354 fi
1355
1356 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1357 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1358 #if HAVE_SYS_SOCKET_H
1359 #include <sys/socket.h>
1360 #endif])
1361 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1362 #if HAVE_SYS_SOCKET_H
1363 #include <sys/socket.h>
1364 #endif])
1365 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1366 #if HAVE_SYS_SOCKET_H
1367 #include <sys/socket.h>
1368 #endif])
1369
1370 dnl checks for structure members
1371 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1372                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1373                   struct ifreq.ifr_addr,
1374                   struct ifreq.ifr_addr.sa_len], , ,
1375                  [AC_INCLUDES_DEFAULT
1376 #if HAVE_SYS_SOCKET_H
1377 #include <sys/socket.h>
1378 #endif
1379 #if HAVE_NET_IF_H
1380 #include <net/if.h>
1381 #endif])
1382
1383 dnl Check for endianness.
1384 dnl AC_C_BIGENDIAN is done by gnulib.
1385
1386 dnl check for Make feature
1387 dnl AC_PROG_MAKE_SET is done by Automake.
1388
1389 DEPFLAGS=
1390 MKDEPDIR=":"
1391 deps_frag=deps.mk
1392 dnl check for GNU Make if we have GCC and autodepend is on.
1393 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1394    AC_MSG_CHECKING([whether we are using GNU Make])
1395    HAVE_GNU_MAKE=no
1396    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1397    if test "x$testval" != x; then
1398       HAVE_GNU_MAKE=yes
1399    else
1400       ac_enable_autodepend=no
1401    fi
1402    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1403    if test $HAVE_GNU_MAKE = yes; then
1404       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1405       SAVE_CFLAGS="$CFLAGS"
1406       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1407       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1408       CFLAGS="$SAVE_CFLAGS"
1409       test -f deps.d || ac_enable_autodepend=no
1410       rm -rf deps.d
1411       AC_MSG_RESULT([$ac_enable_autodepend])
1412    fi
1413    if test $ac_enable_autodepend = yes; then
1414       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1415       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1416       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1417       deps_frag=autodeps.mk
1418    fi
1419 fi
1420 deps_frag=$srcdir/src/$deps_frag
1421 AC_SUBST(MKDEPDIR)
1422 AC_SUBST(DEPFLAGS)
1423 AC_SUBST_FILE(deps_frag)
1424
1425
1426 lisp_frag=$srcdir/src/lisp.mk
1427 AC_SUBST_FILE(lisp_frag)
1428
1429
1430 dnl checks for operating system services
1431 AC_SYS_LONG_FILE_NAMES
1432
1433 #### Choose a window system.
1434
1435 ## We leave window_system equal to none if
1436 ## we end up building without one.  Any new window system should
1437 ## set window_system to an appropriate value and add objects to
1438 ## window-system-specific substs.
1439
1440 window_system=none
1441 AC_PATH_X
1442 if test "$no_x" != yes; then
1443   window_system=x11
1444 fi
1445
1446 LD_SWITCH_X_SITE_RPATH=
1447 if test "${x_libraries}" != NONE; then
1448   if test -n "${x_libraries}"; then
1449     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1450     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1451   fi
1452   x_default_search_path=""
1453   x_search_path=${x_libraries}
1454   if test -z "${x_search_path}"; then
1455     x_search_path=/usr/lib
1456   fi
1457   for x_library in `echo ${x_search_path}: | \
1458                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1459     x_search_path="\
1460 ${x_library}/X11/%L/%T/%N%C%S:\
1461 ${x_library}/X11/%l/%T/%N%C%S:\
1462 ${x_library}/X11/%T/%N%C%S:\
1463 ${x_library}/X11/%L/%T/%N%S:\
1464 ${x_library}/X11/%l/%T/%N%S:\
1465 ${x_library}/X11/%T/%N%S"
1466     if test x"${x_default_search_path}" = x; then
1467       x_default_search_path=${x_search_path}
1468     else
1469       x_default_search_path="${x_search_path}:${x_default_search_path}"
1470     fi
1471   done
1472 fi
1473 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1474
1475 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1476   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1477 fi
1478
1479 if test x"${x_includes}" = x; then
1480   bitmapdir=/usr/include/X11/bitmaps
1481 else
1482   # accumulate include directories that have X11 bitmap subdirectories
1483   bmd_acc="dummyval"
1484   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1485     if test -d "${bmd}/X11/bitmaps"; then
1486       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1487     fi
1488     if test -d "${bmd}/bitmaps"; then
1489       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1490     fi
1491   done
1492   if test ${bmd_acc} != "dummyval"; then
1493     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1494   fi
1495 fi
1496
1497 HAVE_NS=no
1498 NS_IMPL_COCOA=no
1499 NS_IMPL_GNUSTEP=no
1500 tmp_CPPFLAGS="$CPPFLAGS"
1501 tmp_CFLAGS="$CFLAGS"
1502 CPPFLAGS="$CPPFLAGS -x objective-c"
1503 CFLAGS="$CFLAGS -x objective-c"
1504 GNU_OBJC_CFLAGS=
1505 LIBS_GNUSTEP=
1506 if test "${with_ns}" != no; then
1507   if test "${opsys}" = darwin; then
1508      NS_IMPL_COCOA=yes
1509      ns_appdir=`pwd`/nextstep/Emacs.app
1510      ns_appbindir=${ns_appdir}/Contents/MacOS
1511      ns_appresdir=${ns_appdir}/Contents/Resources
1512      ns_appsrc=Cocoa/Emacs.base
1513   elif test -f $GNUSTEP_CONFIG_FILE; then
1514      NS_IMPL_GNUSTEP=yes
1515      ns_appdir=`pwd`/nextstep/Emacs.app
1516      ns_appbindir=${ns_appdir}
1517      ns_appresdir=${ns_appdir}/Resources
1518      ns_appsrc=GNUstep/Emacs.base
1519      dnl FIXME sourcing this several times in subshells seems inefficient.
1520      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1521      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1522      dnl I seemed to need these as well with GNUstep-startup 0.25.
1523      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1524      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1525      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1526        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1527      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1528        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1529      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1530      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1531      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1532      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1533      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1534      dnl If they had chosen to either define it or not, we could have
1535      dnl just used AC_CHECK_DECL here.
1536      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1537        emacs_cv_objc_exceptions,
1538 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1539 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1540 1;
1541 #else
1542 fail;
1543 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1544      if test $emacs_cv_objc_exceptions = yes; then
1545        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1546        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1547          [Define if GNUstep uses ObjC exceptions.])
1548        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1549      fi
1550   fi
1551
1552   dnl This is only used while we test the NS headers, it gets reset below.
1553   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1554
1555   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1556                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1557   files are missing or cannot be compiled.])])
1558
1559   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1560                                      [
1561 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1562 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1040
1563  ; /* OK */
1564 #else
1565 #error "OSX 10.4 or newer required"
1566 #endif
1567 #endif
1568                     ])],
1569                     ns_osx_have_104=yes,
1570                     ns_osx_have_104=no)
1571   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1572                                      [NSInteger i;])],
1573                     ns_have_nsinteger=yes,
1574                     ns_have_nsinteger=no)
1575   if test $ns_osx_have_104 = no; then
1576      AC_MSG_ERROR([`OSX 10.4 or newer is required']);
1577   fi
1578   if test $ns_have_nsinteger = yes; then
1579     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1580   fi
1581 fi
1582
1583 AC_SUBST(LIBS_GNUSTEP)
1584
1585 INSTALL_ARCH_INDEP_EXTRA=install-etc
1586 ns_self_contained=no
1587 NS_OBJ=
1588 NS_OBJC_OBJ=
1589 if test "${HAVE_NS}" = yes; then
1590   if test "$with_toolkit_scroll_bars" = "no"; then
1591     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1592   fi
1593
1594   window_system=nextstep
1595   # set up packaging dirs
1596   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1597      ns_self_contained=yes
1598      prefix=${ns_appresdir}
1599      exec_prefix=${ns_appbindir}
1600      dnl This one isn't really used, only archlibdir is.
1601      libexecdir="\${ns_appbindir}/libexec"
1602      archlibdir="\${ns_appbindir}/libexec"
1603      docdir="\${ns_appresdir}/etc"
1604      etcdir="\${ns_appresdir}/etc"
1605      dnl FIXME maybe set datarootdir instead.
1606      dnl That would also get applications, icons, man.
1607      infodir="\${ns_appresdir}/info"
1608      mandir="\${ns_appresdir}/man"
1609      lispdir="\${ns_appresdir}/lisp"
1610      leimdir="\${ns_appresdir}/leim"
1611      INSTALL_ARCH_INDEP_EXTRA=
1612   fi
1613   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1614 fi
1615 CFLAGS="$tmp_CFLAGS"
1616 CPPFLAGS="$tmp_CPPFLAGS"
1617 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1618 AC_SUBST(ns_self_contained)
1619 AC_SUBST(NS_OBJ)
1620 AC_SUBST(NS_OBJC_OBJ)
1621
1622 HAVE_W32=no
1623 W32_OBJ=
1624 W32_LIBS=
1625 EMACSRES=
1626 CLIENTRES=
1627 CLIENTW=
1628 W32_RES_LINK=
1629 EMACS_MANIFEST=
1630 if test "${with_w32}" != no; then
1631   case "${opsys}" in
1632     cygwin)
1633       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1634              [AC_MSG_ERROR([`--with-w32' was specified, but windows.h
1635                    cannot be found.])])
1636     ;;
1637     mingw32)
1638     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1639     ;;
1640     *)
1641       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1642     ;;
1643   esac
1644 fi
1645
1646 if test "${opsys}" = "mingw32"; then
1647   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1648   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1649      #include <windows.h>
1650      #include <usp10.h>]],
1651    [[void test(PIMAGE_NT_HEADERS pHeader)
1652      {PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader);}]])],
1653    [emacs_cv_w32api=yes
1654     HAVE_W32=yes],
1655    emacs_cv_w32api=no)
1656   AC_MSG_RESULT($emacs_cv_w32api)
1657   if test "${emacs_cv_w32api}" = "no"; then
1658     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1659   fi
1660 fi
1661
1662 FIRSTFILE_OBJ=
1663 NTDIR=
1664 LIBS_ECLIENT=
1665 LIB_WSOCK32=
1666 NTLIB=
1667 CM_OBJ="cm.o"
1668 XARGS_LIMIT=
1669 if test "${HAVE_W32}" = "yes"; then
1670   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1671   AC_CHECK_TOOL(WINDRES, [windres],
1672                 [AC_MSG_ERROR([No resource compiler found.])])
1673   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1674   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1675   EMACSRES="emacs.res"
1676   case "$canonical" in
1677     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1678     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1679   esac
1680   if test "${opsys}" = "cygwin"; then
1681     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1682     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1683     # Tell the linker that emacs.res is an object (which we compile from
1684     # the rc file), not a linker script.
1685     W32_RES_LINK="-Wl,emacs.res"
1686   else
1687     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1688     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1689     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1690     W32_RES_LINK="\$(EMACSRES)"
1691     CLIENTRES="emacsclient.res"
1692     CLIENTW="emacsclientw\$(EXEEXT)"
1693     FIRSTFILE_OBJ=firstfile.o
1694     NTDIR=nt
1695     CM_OBJ=
1696     LIBS_ECLIENT="-lcomctl32"
1697     LIB_WSOCK32="-lwsock32"
1698     NTLIB="ntlib.$ac_objext"
1699     XARGS_LIMIT="-s 10000"
1700   fi
1701 fi
1702 AC_SUBST(W32_OBJ)
1703 AC_SUBST(W32_LIBS)
1704 AC_SUBST(EMACSRES)
1705 AC_SUBST(EMACS_MANIFEST)
1706 AC_SUBST(CLIENTRES)
1707 AC_SUBST(CLIENTW)
1708 AC_SUBST(W32_RES_LINK)
1709 AC_SUBST(FIRSTFILE_OBJ)
1710 AC_SUBST(NTDIR)
1711 AC_SUBST(CM_OBJ)
1712 AC_SUBST(LIBS_ECLIENT)
1713 AC_SUBST(LIB_WSOCK32)
1714 AC_SUBST(NTLIB)
1715 AC_SUBST(XARGS_LIMIT)
1716
1717 if test "${HAVE_W32}" = "yes"; then
1718   window_system=w32
1719   with_xft=no
1720 fi
1721
1722 ## $window_system is now set to the window system we will
1723 ## ultimately use.
1724
1725 term_header=
1726 HAVE_X_WINDOWS=no
1727 HAVE_X11=no
1728 USE_X_TOOLKIT=none
1729
1730 case "${window_system}" in
1731   x11 )
1732     HAVE_X_WINDOWS=yes
1733     HAVE_X11=yes
1734     term_header=xterm.h
1735     case "${with_x_toolkit}" in
1736       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1737       motif ) USE_X_TOOLKIT=MOTIF ;;
1738       gtk ) with_gtk=yes
1739             term_header=gtkutil.h
1740 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1741 dnl USE_X_TOOLKIT is set.
1742             USE_X_TOOLKIT=none ;;
1743       gtk2 ) with_gtk2=yes
1744              term_header=gtkutil.h
1745              USE_X_TOOLKIT=none ;;
1746       gtk3 ) with_gtk3=yes
1747              term_header=gtkutil.h
1748              USE_X_TOOLKIT=none ;;
1749       no ) USE_X_TOOLKIT=none ;;
1750 dnl If user did not say whether to use a toolkit, make this decision later:
1751 dnl use the toolkit if we have gtk, or X11R5 or newer.
1752       * ) USE_X_TOOLKIT=maybe ;;
1753     esac
1754   ;;
1755   nextstep )
1756     term_header=nsterm.h
1757   ;;
1758   w32 )
1759     term_header=w32term.h
1760   ;;
1761 esac
1762
1763 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1764    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1765    if test "$HAVE_XSERVER" = true ||
1766       test -n "$DISPLAY" ||
1767       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1768         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1769 were found.  You should install the relevant development files for X
1770 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1771 sure you have development files for image handling, i.e.
1772 tiff, gif, jpeg, png and xpm.
1773 If you are sure you want Emacs compiled without X window support, pass
1774   --without-x
1775 to configure.])
1776    fi
1777 fi
1778
1779 ### If we're using X11, we should use the X menu package.
1780 HAVE_MENUS=no
1781 case ${HAVE_X11} in
1782   yes ) HAVE_MENUS=yes ;;
1783 esac
1784
1785 # Does the opsystem file prohibit the use of the GNU malloc?
1786 # Assume not, until told otherwise.
1787 GNU_MALLOC=yes
1788
1789 AC_CACHE_CHECK(
1790   [whether malloc is Doug Lea style],
1791   [emacs_cv_var_doug_lea_malloc],
1792   [AC_LINK_IFELSE(
1793      [AC_LANG_PROGRAM(
1794         [[#include <malloc.h>
1795           static void hook (void) {}]],
1796         [[malloc_set_state (malloc_get_state ());
1797           __after_morecore_hook = hook;
1798           __malloc_initialize_hook = hook;]])],
1799      [emacs_cv_var_doug_lea_malloc=yes],
1800      [emacs_cv_var_doug_lea_malloc=no])])
1801 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1802
1803
1804 dnl See comments in aix4-2.h about maybe using system malloc there.
1805 system_malloc=no
1806 case "$opsys" in
1807   ## darwin ld insists on the use of malloc routines in the System framework.
1808   darwin|sol2-10) system_malloc=yes ;;
1809 esac
1810
1811 if test "${system_malloc}" = "yes"; then
1812   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1813   GNU_MALLOC=no
1814   GNU_MALLOC_reason="
1815     (The GNU allocators don't work with this system configuration.)"
1816   GMALLOC_OBJ=
1817   VMLIMIT_OBJ=
1818 else
1819   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1820   VMLIMIT_OBJ=vm-limit.o
1821
1822   AC_CHECK_HEADERS([sys/vlimit.h])
1823   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
1824     [AC_LINK_IFELSE(
1825        [AC_LANG_PROGRAM(
1826          [[extern char data_start[]; char ch;]],
1827          [[return data_start < &ch;]])],
1828        [emacs_cv_data_start=yes],
1829        [emacs_cv_data_start=no])])
1830   if test $emacs_cv_data_start = yes; then
1831     AC_DEFINE([HAVE_DATA_START], 1,
1832       [Define to 1 if data_start is the address of the start
1833        of the main data segment.])
1834   fi
1835 fi
1836 AC_SUBST(GMALLOC_OBJ)
1837 AC_SUBST(VMLIMIT_OBJ)
1838
1839 if test "$doug_lea_malloc" = "yes" ; then
1840   if test "$GNU_MALLOC" = yes ; then
1841     GNU_MALLOC_reason="
1842       (Using Doug Lea's new malloc from the GNU C Library.)"
1843   fi
1844   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1845             [Define to 1 if you are using the GNU C Library.])
1846
1847   ## Use mmap directly for allocating larger buffers.
1848   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1849   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1850   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1851   case "$opsys" in
1852     gnu*) REL_ALLOC=no ;;
1853   esac
1854 fi
1855
1856 if test x"${REL_ALLOC}" = x; then
1857   REL_ALLOC=${GNU_MALLOC}
1858 fi
1859
1860 use_mmap_for_buffers=no
1861 case "$opsys" in
1862   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1863 esac
1864
1865 AC_FUNC_MMAP
1866 if test $use_mmap_for_buffers = yes; then
1867   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1868   REL_ALLOC=no
1869 fi
1870
1871 LIBS="$LIBS_SYSTEM $LIBS"
1872
1873 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1874 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1875 AC_CHECK_LIB(dnet, dnet_ntoa)
1876 dnl This causes -lresolv to get used in subsequent tests,
1877 dnl which causes failures on some systems such as HPUX 9.
1878 dnl AC_CHECK_LIB(resolv, gethostbyname)
1879
1880 dnl FIXME replace main with a function we actually want from this library.
1881 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1882
1883 dnl Check if pthreads is available.
1884 LIB_PTHREAD=
1885 AC_CHECK_HEADERS_ONCE(pthread.h)
1886 if test "$ac_cv_header_pthread_h"; then
1887   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1888   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1889   dnl testing for pthread_self if Emacs uses gmalloc.c.
1890   if test "$GMALLOC_OBJ" = gmalloc.o; then
1891     emacs_pthread_function=pthread_atfork
1892   else
1893     emacs_pthread_function=pthread_self
1894   fi
1895   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1896 fi
1897 if test "$HAVE_PTHREAD" = yes; then
1898   case "${canonical}" in
1899     *-hpux*) ;;
1900     *) LIB_PTHREAD="-lpthread"
1901        LIBS="$LIB_PTHREAD $LIBS" ;;
1902   esac
1903   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1904 fi
1905 AC_SUBST([LIB_PTHREAD])
1906
1907 AC_CHECK_LIB(pthreads, cma_open)
1908
1909 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1910 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1911 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1912 ## added to LIBS in configure would never contain the pthreads part,
1913 ## but the value used in Makefiles might.  FIXME?
1914 ##
1915 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1916 ## be harmless on older versions of X where it happens to exist.
1917 test "$opsys" = "aix4-2" && \
1918   test $ac_cv_lib_pthreads_cma_open = yes && \
1919   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1920
1921 dnl Check for need for bigtoc support on IBM AIX
1922
1923 case ${host_os} in
1924 aix*)
1925   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1926     case $GCC in
1927     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1928     *) gdb_cv_bigtoc=-bbigtoc ;;
1929     esac
1930
1931     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1932     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1933   ])
1934   ;;
1935 esac
1936
1937 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1938 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1939 # REAL_CPPFLAGS later on.
1940
1941 REAL_CFLAGS="$CFLAGS"
1942 REAL_CPPFLAGS="$CPPFLAGS"
1943
1944 if test "${HAVE_X11}" = "yes"; then
1945   DEFS="$C_SWITCH_X_SITE $DEFS"
1946   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1947   LIBS="-lX11 $LIBS"
1948   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1949   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1950
1951   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1952   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1953   # but it's more convenient here to set LD_RUN_PATH since this
1954   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1955   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1956     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1957     export LD_RUN_PATH
1958   fi
1959
1960   if test "${opsys}" = "gnu-linux"; then
1961     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1962     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1963      [[XOpenDisplay ("foo");]])],
1964      [xgnu_linux_first_failure=no],
1965      [xgnu_linux_first_failure=yes])
1966     if test "${xgnu_linux_first_failure}" = "yes"; then
1967       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1968       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1969       OLD_CPPFLAGS="$CPPFLAGS"
1970       OLD_LIBS="$LIBS"
1971       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1972       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1973       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1974       LIBS="$LIBS -b i486-linuxaout"
1975       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1976        [[XOpenDisplay ("foo");]])],
1977        [xgnu_linux_second_failure=no],
1978        [xgnu_linux_second_failure=yes])
1979       if test "${xgnu_linux_second_failure}" = "yes"; then
1980         # If we get the same failure with -b, there is no use adding -b.
1981         # So take it out.  This plays safe.
1982         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1983         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1984         CPPFLAGS="$OLD_CPPFLAGS"
1985         LIBS="$OLD_LIBS"
1986         AC_MSG_RESULT(no)
1987       else
1988         AC_MSG_RESULT(yes)
1989       fi
1990     else
1991       AC_MSG_RESULT(no)
1992     fi
1993   fi
1994
1995   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1996   # header files included from there.
1997   AC_MSG_CHECKING(for Xkb)
1998   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1999 #include <X11/XKBlib.h>]],
2000         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2001         emacs_xkb=yes, emacs_xkb=no)
2002   AC_MSG_RESULT($emacs_xkb)
2003   if test $emacs_xkb = yes; then
2004     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2005   fi
2006
2007   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2008 XScreenNumberOfScreen)
2009 fi
2010
2011 if test "${window_system}" = "x11"; then
2012   AC_MSG_CHECKING(X11 version 6)
2013   AC_CACHE_VAL(emacs_cv_x11_version_6,
2014   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2015 [[#if XlibSpecificationRelease < 6
2016 fail;
2017 #endif
2018 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2019   if test $emacs_cv_x11_version_6 = yes; then
2020     AC_MSG_RESULT(6 or newer)
2021     AC_DEFINE(HAVE_X11R6, 1,
2022               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2023     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2024     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2025     ## XIM support.
2026     case "$opsys" in
2027       sol2-*) : ;;
2028       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2029            [Define if you have usable X11R6-style XIM support.])
2030          ;;
2031     esac
2032   else
2033     AC_MSG_RESULT(before 6)
2034   fi
2035 fi
2036
2037
2038 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
2039 HAVE_RSVG=no
2040 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2041   if test "${with_rsvg}" != "no"; then
2042     RSVG_REQUIRED=2.11.0
2043     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2044
2045     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
2046     AC_SUBST(RSVG_CFLAGS)
2047     AC_SUBST(RSVG_LIBS)
2048
2049     if test $HAVE_RSVG = yes; then
2050       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2051       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2052       LIBS="$RSVG_LIBS $LIBS"
2053     fi
2054   fi
2055 fi
2056
2057 HAVE_IMAGEMAGICK=no
2058 if test "${HAVE_X11}" = "yes"; then
2059   if test "${with_imagemagick}" != "no"; then
2060     ## 6.2.8 is the earliest version known to work, but earlier versions
2061     ## might work - let us know if you find one.
2062     ## 6.0.7 does not work.  See bug#7955.
2063     ## 6.8.2 makes Emacs crash; see Bug#13867.
2064     IMAGEMAGICK_MODULE="Wand >= 6.2.8 Wand != 6.8.2"
2065     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
2066     AC_SUBST(IMAGEMAGICK_CFLAGS)
2067     AC_SUBST(IMAGEMAGICK_LIBS)
2068
2069     if test $HAVE_IMAGEMAGICK = yes; then
2070       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2071       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2072       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2073       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
2074     fi
2075   fi
2076 fi
2077
2078
2079 HAVE_GTK=no
2080 GTK_OBJ=
2081 check_gtk2=no
2082 gtk3_pkg_errors=
2083 if test "${opsys}" != "mingw32"; then
2084   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2085     GLIB_REQUIRED=2.28
2086     GTK_REQUIRED=3.0
2087     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2088
2089     dnl Checks for libraries.
2090     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2091     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2092        AC_MSG_ERROR($GTK_PKG_ERRORS)
2093     fi
2094     if test "$pkg_check_gtk" = "yes"; then
2095        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2096        GTK_OBJ=emacsgtkfixed.o
2097        term_header=gtkutil.h
2098        USE_GTK_TOOLKIT="GTK3"
2099        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2100           GTK_CFLAGS="$GTK_CFLAGS -DGDK_DISABLE_DEPRECATION_WARNINGS"
2101           GTK_CFLAGS="$GTK_CFLAGS -DGLIB_DISABLE_DEPRECATION_WARNINGS"
2102        fi
2103     else
2104        check_gtk2=yes
2105        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2106     fi
2107   fi
2108
2109   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2110     GLIB_REQUIRED=2.10
2111     GTK_REQUIRED=2.10
2112     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2113
2114     dnl Checks for libraries.
2115     PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
2116     if test "$pkg_check_gtk" = "no" &&
2117        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2118     then
2119       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2120     fi
2121     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2122   fi
2123 fi
2124
2125 if test x"$pkg_check_gtk" = xyes; then
2126
2127   AC_SUBST(GTK_CFLAGS)
2128   AC_SUBST(GTK_LIBS)
2129   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2130   CFLAGS="$CFLAGS $GTK_CFLAGS"
2131   LIBS="$GTK_LIBS $LIBS"
2132   dnl Try to compile a simple GTK program.
2133   GTK_COMPILES=no
2134   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
2135   if test "${GTK_COMPILES}" != "yes"; then
2136     if test "$USE_X_TOOLKIT" != "maybe"; then
2137       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2138     fi
2139   else
2140     HAVE_GTK=yes
2141     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2142     GTK_OBJ="gtkutil.o $GTK_OBJ"
2143     USE_X_TOOLKIT=none
2144     if "$PKG_CONFIG" --atleast-version=2.10 gtk+-2.0; then
2145       :
2146     else
2147       AC_MSG_WARN([[Your version of Gtk+ will have problems with
2148        closing open displays.  This is no problem if you just use
2149        one display, but if you use more than one and close one of them
2150        Emacs may crash.]])
2151       sleep 3
2152     fi
2153   fi
2154
2155 fi
2156 AC_SUBST(GTK_OBJ)
2157
2158
2159 if test "${HAVE_GTK}" = "yes"; then
2160
2161   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2162   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2163   if test "$with_toolkit_scroll_bars" != no; then
2164     with_toolkit_scroll_bars=yes
2165   fi
2166
2167   dnl  Check if we have the old file selection dialog declared and
2168   dnl  in the link library.  In 2.x it may be in the library,
2169   dnl  but not declared if deprecated featured has been selected out.
2170   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2171   HAVE_GTK_FILE_SELECTION=no
2172   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2173                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2174 #include <gtk/gtk.h>])
2175   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2176     AC_CHECK_FUNCS(gtk_file_selection_new)
2177   fi
2178
2179   dnl Same as above for gtk_handle_box.
2180   HAVE_GTK_HANDLE_BOX=no
2181   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2182                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2183 #include <gtk/gtk.h>])
2184   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2185     AC_CHECK_FUNCS(gtk_handle_box_new)
2186   fi
2187
2188   dnl Same as above for gtk_tearoff_menu_item.
2189   HAVE_GTK_TEAROFF_MENU_ITEM=no
2190   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2191                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2192 #include <gtk/gtk.h>])
2193   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2194     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2195   fi
2196
2197   dnl Check for functions introduced in 2.14 and later.
2198   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2199                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2200                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2201                  gtk_orientable_set_orientation \
2202                  gtk_window_set_has_resize_grip)
2203
2204  term_header=gtkutil.h
2205 fi
2206
2207 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2208 dnl other platforms.
2209 HAVE_DBUS=no
2210 DBUS_OBJ=
2211 if test "${with_dbus}" = "yes"; then
2212    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
2213    if test "$HAVE_DBUS" = yes; then
2214      LIBS="$LIBS $DBUS_LIBS"
2215      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2216      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2217      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2218      dnl D-Bus 1.5.12.
2219      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2220                     dbus_type_is_valid \
2221                     dbus_validate_bus_name \
2222                     dbus_validate_path \
2223                     dbus_validate_interface \
2224                     dbus_validate_member)
2225      DBUS_OBJ=dbusbind.o
2226    fi
2227 fi
2228 AC_SUBST(DBUS_OBJ)
2229
2230 dnl GSettings has been tested under GNU/Linux only.
2231 HAVE_GSETTINGS=no
2232 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2233    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
2234    if test "$HAVE_GSETTINGS" = "yes"; then
2235       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2236       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2237       SETTINGS_LIBS="$GSETTINGS_LIBS"
2238    fi
2239 fi
2240
2241 dnl GConf has been tested under GNU/Linux only.
2242 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2243 HAVE_GCONF=no
2244 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2245    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
2246    if test "$HAVE_GCONF" = yes; then
2247       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2248       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2249       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2250       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2251    fi
2252 fi
2253
2254 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2255     PKG_CHECK_MODULES(GOBJECT, gobject-2.0 >= 2.0, HAVE_GOBJECT=yes, HAVE_GOBJECT=no)
2256     if test "$HAVE_GOBJECT" = "yes"; then
2257        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2258        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2259     fi
2260     SAVE_CFLAGS="$CFLAGS"
2261     SAVE_LIBS="$LIBS"
2262     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2263     LIBS="$SETTINGS_LIBS $LIBS"
2264     AC_CHECK_FUNCS([g_type_init])
2265     CFLAGS="$SAVE_CFLAGS"
2266     LIBS="$SAVE_LIBS"
2267 fi
2268 AC_SUBST(SETTINGS_CFLAGS)
2269 AC_SUBST(SETTINGS_LIBS)
2270
2271
2272 dnl SELinux is available for GNU/Linux only.
2273 HAVE_LIBSELINUX=no
2274 LIBSELINUX_LIBS=
2275 if test "${with_selinux}" = "yes"; then
2276    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2277    if test "$HAVE_LIBSELINUX" = yes; then
2278       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2279       LIBSELINUX_LIBS=-lselinux
2280    fi
2281 fi
2282 AC_SUBST(LIBSELINUX_LIBS)
2283
2284 HAVE_GNUTLS=no
2285 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2286 if test "${with_gnutls}" = "yes" ; then
2287   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2288   if test "${HAVE_GNUTLS}" = "yes"; then
2289     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2290   fi
2291
2292   OLD_CFLAGS=$CFLAGS
2293   OLD_LIBS=$LIBS
2294   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2295   LIBS="$LIBGNUTLS_LIBS $LIBS"
2296   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2297
2298   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2299     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2300   fi
2301
2302   # Windows loads GnuTLS dynamically
2303   if test "${opsys}" = "mingw32"; then
2304     CFLAGS=$OLD_CFLAGS
2305     LIBS=$OLD_LIBS
2306     LIBGNUTLS_LIBS=
2307   fi
2308 fi
2309
2310 AC_SUBST(LIBGNUTLS_LIBS)
2311 AC_SUBST(LIBGNUTLS_CFLAGS)
2312
2313 NOTIFY_OBJ=
2314 NOTIFY_SUMMARY=no
2315
2316 dnl Set defaults of $with_file_notification.
2317 if test "${with_file_notification}" = "yes"; then
2318    if test "${opsys}" = "mingw32"; then
2319       with_file_notification=w32
2320    else
2321       if test "${with_ns}" != yes; then
2322         with_file_notification=gfile
2323       fi
2324    fi
2325 fi
2326
2327 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2328 dnl has been added in glib 2.24.  It has been tested under
2329 dnl GNU/Linux only.  We take precedence over inotify, but this makes
2330 dnl only sense when glib has been compiled with inotify support.  How
2331 dnl to check?
2332 if test "${with_file_notification}" = "gfile"; then
2333    PKG_CHECK_MODULES(GFILENOTIFY, gio-2.0 >= 2.24, HAVE_GFILENOTIFY=yes, HAVE_GFILENOTIFY=no)
2334    if test "$HAVE_GFILENOTIFY" = "yes"; then
2335       AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2336       NOTIFY_OBJ=gfilenotify.o
2337       NOTIFY_SUMMARY="yes -lgio (gfile)"
2338    fi
2339 fi
2340 dnl inotify is only available on GNU/Linux.
2341 if test "${with_file_notification}" = "inotify"; then
2342    AC_CHECK_HEADER(sys/inotify.h)
2343    if test "$ac_cv_header_sys_inotify_h" = yes ; then
2344        AC_CHECK_FUNC(inotify_init1)
2345        if test "$ac_cv_func_inotify_init1" = yes; then
2346            AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2347            NOTIFY_OBJ=inotify.o
2348            NOTIFY_SUMMARY="yes -lglibc (inotify)"
2349         fi
2350   fi
2351 fi
2352 dnl MS Windows native file monitor is available for mingw32 only.
2353 if test "${with_file_notification}" = "w32"; then
2354    AC_CHECK_HEADER(windows.h)
2355    if test "$ac_cv_header_windows_h" = yes ; then
2356       AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2357       NOTIFY_OBJ=w32notify.o
2358       NOTIFY_SUMMARY="yes (w32)"
2359    fi
2360 fi
2361 if test -n "$NOTIFY_OBJ"; then
2362    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2363 fi
2364 AC_SUBST(NOTIFY_OBJ)
2365 AC_SUBST(GFILENOTIFY_CFLAGS)
2366 AC_SUBST(GFILENOTIFY_LIBS)
2367
2368 dnl Do not put whitespace before the #include statements below.
2369 dnl Older compilers (eg sunos4 cc) choke on it.
2370 HAVE_XAW3D=no
2371 LUCID_LIBW=
2372 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2373   if test "$with_xaw3d" != no; then
2374     AC_CACHE_VAL(emacs_cv_xaw3d,
2375     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2376 #include <X11/Intrinsic.h>
2377 #include <X11/Xaw3d/Simple.h>]],
2378       [[]])],
2379       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2380                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2381       emacs_cv_xaw3d=no)])
2382   else
2383     emacs_cv_xaw3d=no
2384   fi
2385   if test $emacs_cv_xaw3d = yes; then
2386     AC_MSG_CHECKING(for xaw3d)
2387     AC_MSG_RESULT([yes; using Lucid toolkit])
2388     USE_X_TOOLKIT=LUCID
2389     HAVE_XAW3D=yes
2390     LUCID_LIBW=-lXaw3d
2391     AC_DEFINE(HAVE_XAW3D, 1,
2392               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2393   else
2394     AC_MSG_CHECKING(for xaw3d)
2395     AC_MSG_RESULT(no)
2396     AC_MSG_CHECKING(for libXaw)
2397     AC_CACHE_VAL(emacs_cv_xaw,
2398     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2399 #include <X11/Intrinsic.h>
2400 #include <X11/Xaw/Simple.h>]],
2401       [[]])],
2402       emacs_cv_xaw=yes,
2403       emacs_cv_xaw=no)])
2404     if test $emacs_cv_xaw = yes; then
2405       AC_MSG_RESULT([yes; using Lucid toolkit])
2406       USE_X_TOOLKIT=LUCID
2407       LUCID_LIBW=-lXaw
2408     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2409       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2410     else
2411       AC_MSG_ERROR([No X toolkit could be found.
2412 If you are sure you want Emacs compiled without an X toolkit, pass
2413   --with-x-toolkit=no
2414 to configure.  Otherwise, install the development libraries for the toolkit
2415 that you want to use (e.g. Gtk+) and re-run configure.])
2416     fi
2417   fi
2418 fi
2419
2420 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2421
2422 LIBXTR6=
2423 if test "${USE_X_TOOLKIT}" != "none"; then
2424   AC_MSG_CHECKING(X11 toolkit version)
2425   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2426   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2427 [[#if XtSpecificationRelease < 6
2428 fail;
2429 #endif
2430 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2431   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2432   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2433     AC_MSG_RESULT(6 or newer)
2434     AC_DEFINE(HAVE_X11XTR6, 1,
2435               [Define to 1 if you have the X11R6 or newer version of Xt.])
2436     LIBXTR6="-lSM -lICE"
2437     case "$opsys" in
2438       ## Use libw.a along with X11R6 Xt.
2439       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2440     esac
2441   else
2442     AC_MSG_RESULT(before 6)
2443   fi
2444
2445 dnl If using toolkit, check whether libXmu.a exists.
2446 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2447   OLDLIBS="$LIBS"
2448   if test x$HAVE_X11XTR6 = xyes; then
2449     LIBS="-lXt -lSM -lICE $LIBS"
2450   else
2451     LIBS="-lXt $LIBS"
2452   fi
2453   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2454   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2455   dnl ac_cv_lib_Xmu_XmuConvertStandardSelection is also referenced below.
2456 fi
2457 AC_SUBST(LIBXTR6)
2458
2459 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2460 dnl Why not just test for libxmu in the normal way?
2461 LIBXMU=-lXmu
2462 case $opsys in
2463   ## These systems don't supply Xmu.
2464   hpux* | aix4-2 )
2465     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2466     ;;
2467   mingw32 )
2468     LIBXMU=
2469     ;;
2470 esac
2471 AC_SUBST(LIBXMU)
2472
2473 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2474 if test "${HAVE_X11}" = "yes"; then
2475   if test "${USE_X_TOOLKIT}" != "none"; then
2476     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2477   fi
2478 fi
2479
2480 LIBXP=
2481 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2482   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2483   if test -d /usr/include/openmotif; then
2484     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2485     emacs_cv_openmotif=yes
2486     case "$canonical" in
2487       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2488       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2489       ;;
2490       *)
2491       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2492     esac
2493   else
2494     emacs_cv_openmotif=no
2495   fi
2496   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2497   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2498     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2499 int x = 5;
2500 #else
2501 Motif version prior to 2.1.
2502 #endif]])],
2503     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2504   if test $emacs_cv_motif_version_2_1 = yes; then
2505     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2506     if test x$emacs_cv_openmotif = xyes; then
2507       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2508     fi
2509   else
2510     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2511     # We put this in CFLAGS temporarily to precede other -I options
2512     # that might be in CFLAGS temporarily.
2513     # We put this in CPPFLAGS where it precedes the other -I options.
2514     OLD_CPPFLAGS=$CPPFLAGS
2515     OLD_CFLAGS=$CFLAGS
2516     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2517     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2518     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2519       [[int x = 5;]])],
2520       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2521     if test $emacs_cv_lesstif = yes; then
2522       # Make sure this -I option remains in CPPFLAGS after it is set
2523       # back to REAL_CPPFLAGS.
2524       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2525       # have those other -I options anyway.  Ultimately, having this
2526       # directory ultimately in CPPFLAGS will be enough.
2527       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2528       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2529     else
2530       CFLAGS=$OLD_CFLAGS
2531       CPPFLAGS=$OLD_CPPFLAGS
2532     fi
2533   fi
2534   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2535     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2536 fi
2537
2538 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2539 dnl using Motif or Xaw3d is available, and unless
2540 dnl --with-toolkit-scroll-bars=no was specified.
2541
2542 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2543             [Define to 1 if we should use toolkit scroll bars.])dnl
2544 USE_TOOLKIT_SCROLL_BARS=no
2545 if test "${with_toolkit_scroll_bars}" != "no"; then
2546   if test "${USE_X_TOOLKIT}" != "none"; then
2547     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2548       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2549       HAVE_XAW3D=no
2550       USE_TOOLKIT_SCROLL_BARS=yes
2551     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2552       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2553       USE_TOOLKIT_SCROLL_BARS=yes
2554     fi
2555   elif test "${HAVE_GTK}" = "yes"; then
2556     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2557     USE_TOOLKIT_SCROLL_BARS=yes
2558   elif test "${HAVE_NS}" = "yes"; then
2559     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2560     USE_TOOLKIT_SCROLL_BARS=yes
2561   elif test "${HAVE_W32}" = "yes"; then
2562     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2563     USE_TOOLKIT_SCROLL_BARS=yes
2564   fi
2565 fi
2566
2567 dnl See if XIM is available.
2568 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2569           #include <X11/Xlib.h>
2570           #include <X11/Xresource.h>]],
2571          [[XIMProc  callback;]])],
2572          [HAVE_XIM=yes
2573          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2574          HAVE_XIM=no)
2575
2576 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2577
2578 if test "${with_xim}" != "no"; then
2579   AC_DEFINE(USE_XIM, 1,
2580             [Define to 1 if we should use XIM, if it is available.])
2581 fi
2582
2583
2584 if test "${HAVE_XIM}" != "no"; then
2585   late_CFLAGS=$CFLAGS
2586   if test "$GCC" = yes; then
2587     CFLAGS="$CFLAGS --pedantic-errors"
2588   fi
2589   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2590 #include <X11/Xlib.h>
2591 #include <X11/Xresource.h>]],
2592 [[Display *display;
2593 XrmDatabase db;
2594 char *res_name;
2595 char *res_class;
2596 XIMProc  callback;
2597 XPointer *client_data;
2598 #ifndef __GNUC__
2599 /* If we're not using GCC, it's probably not XFree86, and this is
2600    probably right, but we can't use something like --pedantic-errors.  */
2601 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2602                                            char*, XIMProc, XPointer*);
2603 #endif
2604 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2605    client_data);]])],
2606     [emacs_cv_arg6_star=yes])
2607   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2608          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2609 either XPointer or XPointer*.])dnl
2610   if test "$emacs_cv_arg6_star" = yes; then
2611     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2612   else
2613     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2614   fi
2615   CFLAGS=$late_CFLAGS
2616 fi
2617
2618 ### Start of font-backend (under any platform) section.
2619 # (nothing here yet -- this is a placeholder)
2620 ### End of font-backend (under any platform) section.
2621
2622 ### Start of font-backend (under X11) section.
2623 if test "${HAVE_X11}" = "yes"; then
2624    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2625
2626    ## Use -lXft if available, unless `--with-xft=no'.
2627    HAVE_XFT=maybe
2628     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2629       with_xft="no";
2630     fi
2631     if test "x${with_xft}" != "xno"; then
2632
2633       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2634       ## Because xftfont.c uses XRenderQueryExtension, we also
2635       ## need to link to -lXrender.
2636       HAVE_XRENDER=no
2637       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2638       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2639         OLD_CPPFLAGS="$CPPFLAGS"
2640         OLD_CFLAGS="$CFLAGS"
2641         OLD_LIBS="$LIBS"
2642         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2643         CFLAGS="$CFLAGS $XFT_CFLAGS"
2644         XFT_LIBS="-lXrender $XFT_LIBS"
2645         LIBS="$XFT_LIBS $LIBS"
2646         AC_CHECK_HEADER(X11/Xft/Xft.h,
2647           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
2648           [[#include <X11/X.h>]])
2649
2650         if test "${HAVE_XFT}" = "yes"; then
2651           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2652             AC_SUBST(XFT_LIBS)
2653           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2654         else
2655           CPPFLAGS="$OLD_CPPFLAGS"
2656           CFLAGS="$OLD_CFLAGS"
2657           LIBS="$OLD_LIBS"
2658         fi                        # "${HAVE_XFT}" = "yes"
2659       fi                          # "$HAVE_XFT" != no
2660     fi                            # "x${with_xft}" != "xno"
2661
2662     ## We used to allow building with FreeType and without Xft.
2663     ## However, the ftx font backend driver is not in good shape.
2664     if test "$HAVE_XFT" != "yes"; then
2665        dnl For the "Does Emacs use" message at the end.
2666        HAVE_XFT=no
2667        HAVE_FREETYPE=no
2668     else
2669        dnl Strict linkers fail with
2670        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2671        dnl if -lfreetype is not specified.
2672        dnl The following is needed to set FREETYPE_LIBS.
2673        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2674                          HAVE_FREETYPE=no)
2675
2676        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2677     fi
2678
2679     HAVE_LIBOTF=no
2680     if test "${HAVE_FREETYPE}" = "yes"; then
2681       AC_DEFINE(HAVE_FREETYPE, 1,
2682                 [Define to 1 if using the freetype and fontconfig libraries.])
2683       if test "${with_libotf}" != "no"; then
2684         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2685                           HAVE_LIBOTF=no)
2686         if test "$HAVE_LIBOTF" = "yes"; then
2687           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2688           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2689                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2690                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2691           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2692             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2693                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2694           fi
2695         fi
2696       fi
2697     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2698     dnl Does the new font backend require it, or can it work without it?
2699     fi
2700
2701     HAVE_M17N_FLT=no
2702     if test "${HAVE_LIBOTF}" = yes; then
2703       if test "${with_m17n_flt}" != "no"; then
2704         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2705         if test "$HAVE_M17N_FLT" = "yes"; then
2706           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2707         fi
2708       fi
2709     fi
2710 else
2711     HAVE_XFT=no
2712     HAVE_FREETYPE=no
2713     HAVE_LIBOTF=no
2714     HAVE_M17N_FLT=no
2715 fi
2716
2717 ### End of font-backend (under X11) section.
2718
2719 AC_SUBST(FREETYPE_CFLAGS)
2720 AC_SUBST(FREETYPE_LIBS)
2721 AC_SUBST(FONTCONFIG_CFLAGS)
2722 AC_SUBST(FONTCONFIG_LIBS)
2723 AC_SUBST(LIBOTF_CFLAGS)
2724 AC_SUBST(LIBOTF_LIBS)
2725 AC_SUBST(M17N_FLT_CFLAGS)
2726 AC_SUBST(M17N_FLT_LIBS)
2727
2728 ### Use -lXpm if available, unless `--with-xpm=no'.
2729 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
2730 HAVE_XPM=no
2731 LIBXPM=
2732 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
2733   if test "${with_xpm}" != "no"; then
2734     SAVE_CPPFLAGS="$CPPFLAGS"
2735     SAVE_LDFLAGS="$LDFLAGS"
2736     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
2737     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
2738     AC_CHECK_HEADER(X11/xpm.h,
2739       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
2740     if test "${HAVE_XPM}" = "yes"; then
2741       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2742       AC_EGREP_CPP(no_return_alloc_pixels,
2743       [#include "X11/xpm.h"
2744 #ifndef XpmReturnAllocPixels
2745 no_return_alloc_pixels
2746 #endif
2747       ], HAVE_XPM=no, HAVE_XPM=yes)
2748
2749       if test "${HAVE_XPM}" = "yes"; then
2750         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
2751         AC_MSG_RESULT(yes)
2752       else
2753         AC_MSG_RESULT(no)
2754         CPPFLAGS="$SAVE_CPPFLAGS"
2755         LDFLAGS="$SAVE_LDFLAGS"
2756       fi
2757     fi
2758   fi
2759
2760   if test "${HAVE_XPM}" = "yes"; then
2761     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2762     LIBXPM=-lXpm
2763   fi
2764 fi
2765
2766 if test "${HAVE_X11}" = "yes"; then
2767   if test "${with_xpm}" != "no"; then
2768     AC_CHECK_HEADER(X11/xpm.h,
2769       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2770     if test "${HAVE_XPM}" = "yes"; then
2771       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2772       AC_EGREP_CPP(no_return_alloc_pixels,
2773       [#include "X11/xpm.h"
2774 #ifndef XpmReturnAllocPixels
2775 no_return_alloc_pixels
2776 #endif
2777       ], HAVE_XPM=no, HAVE_XPM=yes)
2778
2779       if test "${HAVE_XPM}" = "yes"; then
2780         AC_MSG_RESULT(yes)
2781       else
2782         AC_MSG_RESULT(no)
2783       fi
2784     fi
2785   fi
2786
2787   if test "${HAVE_XPM}" = "yes"; then
2788     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2789     LIBXPM=-lXpm
2790   fi
2791 fi
2792
2793 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
2794 ### slightly different requirements wrt image libraries (it doesn't
2795 ### use -lXpm because it loads the xpm shared library dynamically at
2796 ### run time).
2797 if test "${opsys}" = "mingw32"; then
2798   if test "${with_xpm}" != "no"; then
2799     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
2800 #define FOR_MSW 1])
2801   fi
2802
2803   if test "${HAVE_XPM}" = "yes"; then
2804     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2805   fi
2806 fi
2807
2808 AC_SUBST(LIBXPM)
2809
2810 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2811 ### mingw32 doesn't use -ljpeg, since it loads the library dynamically.
2812 HAVE_JPEG=no
2813 LIBJPEG=
2814 if test "${opsys}" = "mingw32"; then
2815   if test "${with_jpeg}" != "no"; then
2816     dnl Checking for jpeglib.h can lose because of a redefinition of
2817     dnl HAVE_STDLIB_H.
2818     AC_CHECK_HEADER(jerror.h, HAVE_JPEG=yes, HAVE_JPEG=no)
2819   fi
2820   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2821   if test "${HAVE_JPEG}" = "yes"; then
2822     AC_DEFINE(HAVE_JPEG)
2823     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2824         [#include <jpeglib.h>
2825          version=JPEG_LIB_VERSION
2826 ],
2827         [AC_DEFINE(HAVE_JPEG)],
2828         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2829         HAVE_JPEG=no])
2830   fi
2831 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2832   if test "${with_jpeg}" != "no"; then
2833     dnl Checking for jpeglib.h can lose because of a redefinition of
2834     dnl  HAVE_STDLIB_H.
2835     AC_CHECK_HEADER(jerror.h,
2836       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2837   fi
2838
2839   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2840   if test "${HAVE_JPEG}" = "yes"; then
2841     AC_DEFINE(HAVE_JPEG)
2842     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2843         [#include <jpeglib.h>
2844          version=JPEG_LIB_VERSION
2845 ],
2846         [AC_DEFINE(HAVE_JPEG)],
2847         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2848         HAVE_JPEG=no])
2849   fi
2850   if test "${HAVE_JPEG}" = "yes"; then
2851     LIBJPEG=-ljpeg
2852   fi
2853 fi
2854 AC_SUBST(LIBJPEG)
2855
2856 ### Use -lpng if available, unless `--with-png=no'.
2857 ### mingw32 doesn't use -lpng, since it loads the library dynamically.
2858 HAVE_PNG=no
2859 LIBPNG=
2860 if test "${opsys}" = "mingw32"; then
2861   if test "${with_png}" != "no"; then
2862     AC_CHECK_HEADER(png.h, HAVE_PNG=yes, HAVE_PNG=no)
2863   fi
2864   if test "${HAVE_PNG}" = "yes"; then
2865     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2866
2867     AC_CHECK_DECL(png_longjmp,
2868       [],
2869       [AC_DEFINE(PNG_DEPSTRUCT, [],
2870          [Define to empty to suppress deprecation warnings when building
2871           with --enable-gcc-warnings and with libpng versions before 1.5,
2872           which lack png_longjmp.])],
2873       [[#ifdef HAVE_LIBPNG_PNG_H
2874         # include <libpng/png.h>
2875         #else
2876         # include <png.h>
2877         #endif
2878       ]])
2879   fi
2880 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2881   if test "${with_png}" != "no"; then
2882     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2883     # in /usr/include/libpng.
2884     AC_CHECK_HEADERS(png.h libpng/png.h, break)
2885     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2886       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2887     fi
2888   fi
2889
2890   if test "${HAVE_PNG}" = "yes"; then
2891     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2892     LIBPNG="-lpng -lz -lm"
2893
2894     AC_CHECK_DECL(png_longjmp,
2895       [],
2896       [AC_DEFINE(PNG_DEPSTRUCT, [],
2897          [Define to empty to suppress deprecation warnings when building
2898           with --enable-gcc-warnings and with libpng versions before 1.5,
2899           which lack png_longjmp.])],
2900       [[#ifdef HAVE_LIBPNG_PNG_H
2901         # include <libpng/png.h>
2902         #else
2903         # include <png.h>
2904         #endif
2905       ]])
2906   fi
2907 fi
2908 AC_SUBST(LIBPNG)
2909
2910 ### Use -ltiff if available, unless `--with-tiff=no'.
2911 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
2912 HAVE_TIFF=no
2913 LIBTIFF=
2914 if test "${opsys}" = "mingw32"; then
2915   if test "${with_tiff}" != "no"; then
2916     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
2917   fi
2918   if test "${HAVE_TIFF}" = "yes"; then
2919     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2920   fi
2921 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
2922   if test "${with_tiff}" != "no"; then
2923     AC_CHECK_HEADER(tiffio.h,
2924       [tifflibs="-lz -lm"
2925       # At least one tiff package requires the jpeg library.
2926       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2927       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2928   fi
2929
2930   if test "${HAVE_TIFF}" = "yes"; then
2931     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2932     dnl FIXME -lz -lm, as per libpng?
2933     LIBTIFF=-ltiff
2934   fi
2935 fi
2936 AC_SUBST(LIBTIFF)
2937
2938 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2939 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
2940 HAVE_GIF=no
2941 LIBGIF=
2942 if test "${opsys}" = "mingw32"; then
2943   if test "${with_gif}" != "no"; then
2944     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
2945   fi
2946   if test "${HAVE_GIF}" = "yes"; then
2947     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2948   fi
2949 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
2950         || test "${HAVE_W32}" = "yes"; then
2951   AC_CHECK_HEADER(gif_lib.h,
2952 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2953 # Earlier versions can crash Emacs.
2954     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2955
2956   if test "$HAVE_GIF" = yes; then
2957     LIBGIF=-lgif
2958   elif test "$HAVE_GIF" = maybe; then
2959 # If gif_lib.h but no libgif, try libungif.
2960     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2961     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2962   fi
2963
2964   if test "${HAVE_GIF}" = "yes"; then
2965     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2966   fi
2967 fi
2968 AC_SUBST(LIBGIF)
2969
2970 dnl Check for required libraries.
2971 if test "${HAVE_X11}" = "yes"; then
2972   MISSING=""
2973   WITH_NO=""
2974   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2975     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2976   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2977     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2978   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2979     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2980   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2981     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2982   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2983     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2984
2985   if test "X${MISSING}" != X; then
2986     AC_MSG_ERROR([The following required libraries were not found:
2987     $MISSING
2988 Maybe some development libraries/packages are missing?
2989 If you don't want to link with them give
2990     $WITH_NO
2991 as options to configure])
2992   fi
2993 fi
2994
2995 ### Use -lgpm if available, unless `--with-gpm=no'.
2996 HAVE_GPM=no
2997 LIBGPM=
2998 if test "${with_gpm}" != "no"; then
2999   AC_CHECK_HEADER(gpm.h,
3000     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3001
3002   if test "${HAVE_GPM}" = "yes"; then
3003     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3004     LIBGPM=-lgpm
3005   fi
3006 fi
3007 AC_SUBST(LIBGPM)
3008
3009 dnl Check for malloc/malloc.h on darwin
3010 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3011
3012 GNUSTEP_CFLAGS=
3013 ### Use NeXTstep API to implement GUI.
3014 if test "${HAVE_NS}" = "yes"; then
3015   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3016   if test "${NS_IMPL_COCOA}" = "yes"; then
3017     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3018   fi
3019   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3020     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3021     # See also .m.o rule in Makefile.in */
3022     # FIXME: are all these flags really needed?  Document here why.  */
3023     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3024     ## Extra CFLAGS applied to src/*.m files.
3025     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3026   fi
3027   # We also have mouse menus.
3028   HAVE_MENUS=yes
3029   OTHER_FILES=ns-app
3030 fi
3031
3032 if test "${HAVE_W32}" = "yes"; then
3033   HAVE_MENUS=yes
3034 fi
3035
3036 ### Use session management (-lSM -lICE) if available
3037 HAVE_X_SM=no
3038 LIBXSM=
3039 if test "${HAVE_X11}" = "yes"; then
3040   AC_CHECK_HEADER(X11/SM/SMlib.h,
3041     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3042
3043   if test "${HAVE_X_SM}" = "yes"; then
3044     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3045     LIBXSM="-lSM -lICE"
3046     case "$LIBS" in
3047       *-lSM*) ;;
3048       *)      LIBS="$LIBXSM $LIBS" ;;
3049     esac
3050   fi
3051 fi
3052 AC_SUBST(LIBXSM)
3053
3054 ### Use XRandr (-lXrandr) if available
3055 HAVE_XRANDR=no
3056 if test "${HAVE_X11}" = "yes"; then
3057   XRANDR_REQUIRED=1.2.2
3058   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3059   PKG_CHECK_MODULES(XRANDR, $XRANDR_MODULES, HAVE_XRANDR=yes, HAVE_XRANDR=no)
3060   if test $HAVE_XRANDR = no; then
3061     # Test old way in case pkg-config doesn't have it (older machines).
3062     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3063       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)])
3064     if test $HAVE_XRANDR = yes; then
3065       XRANDR_LIBS=-lXrandr
3066       AC_SUBST(XRANDR_LIBS)
3067     fi
3068   fi
3069   if test $HAVE_XRANDR = yes; then
3070     SAVE_CFLAGS="$CFLAGS"
3071     SAVE_LIBS="$LIBS"
3072     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3073     LIBS="$XRANDR_LIBS $LIBS"
3074     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3075     CFLAGS="$SAVE_CFLAGS"
3076     LIBS="$SAVE_LIBS"
3077
3078     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3079   fi
3080 fi
3081
3082 ### Use Xinerama (-lXinerama) if available
3083 HAVE_XINERAMA=no
3084 if test "${HAVE_X11}" = "yes"; then
3085   XINERAMA_REQUIRED=1.0.2
3086   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3087   PKG_CHECK_MODULES(XINERAMA, $XINERAMA_MODULES, HAVE_XINERAMA=yes,
3088                     HAVE_XINERAMA=no)
3089   if test $HAVE_XINERAMA = no; then
3090     # Test old way in case pkg-config doesn't have it (older machines).
3091     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3092       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3093     if test $HAVE_XINERAMA = yes; then
3094       XINERAMA_LIBS=-lXinerama
3095       AC_SUBST(XINERAMA_LIBS)
3096     fi
3097   fi
3098   if test $HAVE_XINERAMA = yes; then
3099     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3100   fi
3101 fi
3102
3103
3104 ### Use libxml (-lxml2) if available
3105 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3106 HAVE_LIBXML2=no
3107 if test "${with_xml2}" != "no"; then
3108   ### I'm not sure what the version number should be, so I just guessed.
3109   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3110   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3111   if test "${HAVE_LIBXML2}" != "yes" -a "$opsys" = "darwin"; then
3112     SAVE_CPPFLAGS="$CPPFLAGS"
3113     CPPFLAGS="$CPPFLAGS -I/usr/include/libxml2"
3114     AC_CHECK_HEADER(libxml/HTMLparser.h,
3115       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3116                      [#include <libxml/HTMLparser.h>])])
3117     CPPFLAGS="$SAVE_CPPFLAGS"
3118     if test "${HAVE_LIBXML2}" = "yes"; then
3119       LIBXML2_LIBS="-lxml2"
3120       LIBXML2_CFLAGS="-I/usr/include/libxml2"
3121     fi
3122   fi
3123   if test "${HAVE_LIBXML2}" = "yes"; then
3124     if test "${opsys}" != "mingw32"; then
3125       LIBS="$LIBXML2_LIBS $LIBS"
3126       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
3127     else
3128       LIBXML2_LIBS=""
3129     fi
3130     if test "${HAVE_LIBXML2}" = "yes"; then
3131       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3132     else
3133       LIBXML2_LIBS=""
3134       LIBXML2_CFLAGS=""
3135     fi
3136   fi
3137 fi
3138 AC_SUBST(LIBXML2_LIBS)
3139 AC_SUBST(LIBXML2_CFLAGS)
3140
3141 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3142 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3143 if test "${opsys}" = "mingw32"; then
3144   emacs_cv_netdb_declares_h_errno=yes
3145 fi
3146 AC_CACHE_CHECK(whether netdb declares h_errno,
3147                emacs_cv_netdb_declares_h_errno,
3148 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3149   [[return h_errno;]])],
3150   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3151 if test $emacs_cv_netdb_declares_h_errno = yes; then
3152   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3153 fi
3154
3155 # sqrt and other floating-point functions such as fmod and frexp
3156 # are found in -lm on most systems, but mingw32 doesn't use -lm.
3157 if test "${opsys}" != "mingw32"; then
3158   AC_CHECK_LIB(m, sqrt)
3159 fi
3160
3161 # Check for mail-locking functions in a "mail" library.  Probably this should
3162 # have the same check as for liblockfile below.
3163 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3164 if test $have_mail = yes; then
3165   LIBS_MAIL=-lmail
3166   LIBS="$LIBS_MAIL $LIBS"
3167   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
3168 else
3169   LIBS_MAIL=
3170 fi
3171 dnl Debian, at least:
3172 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3173 if test $have_lockfile = yes; then
3174    LIBS_MAIL=-llockfile
3175    LIBS="$LIBS_MAIL $LIBS"
3176    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
3177 else
3178 # If we have the shared liblockfile, assume we must use it for mail
3179 # locking (e.g. Debian).  If we couldn't link against liblockfile
3180 # (no liblockfile.a installed), ensure that we don't need to.
3181   dnl This works for files generally, not just executables.
3182   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3183   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3184                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3185   if test $ac_cv_prog_liblockfile = yes; then
3186     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3187 This probably means that movemail could lose mail.
3188 There may be a `development' package to install containing liblockfile.])
3189   fi
3190 fi
3191 AC_CHECK_HEADERS_ONCE(maillock.h)
3192 AC_SUBST(LIBS_MAIL)
3193
3194 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3195 ## interlock access to the mail spool.  The alternative is a lock file named
3196 ## /usr/spool/mail/$USER.lock.
3197 mail_lock=no
3198 case "$opsys" in
3199   aix4-2) mail_lock="lockf" ;;
3200
3201   gnu|freebsd|dragonfly|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
3202
3203   ## On GNU/Linux systems, both methods are used by various mail programs.
3204   ## I assume most people are using newer mailers that have heard of flock.
3205   ## Change this if you need to.
3206   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
3207   ## configure gets the right answers, and that means *NOT* using flock.
3208   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3209   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
3210   ## Debian maintainer hasn't provided a clean fix for Emacs.
3211   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
3212   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3213   ## correct logic.  -- fx
3214   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3215   ## liblockfile is a Free Software replacement for libmail, used on
3216   ## Debian systems and elsewhere. -rfr.
3217   gnu-*)
3218     mail_lock="flock"
3219     if test $have_mail = yes || test $have_lockfile = yes; then
3220       test $ac_cv_header_maillock_h = yes && mail_lock=no
3221     fi
3222     ;;
3223
3224   mingw32)
3225     mail_lock="none-needed" ;;
3226 esac
3227
3228 BLESSMAIL_TARGET=
3229 case "$mail_lock" in
3230   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3231
3232   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3233
3234   none-needed) ;;
3235
3236   *) BLESSMAIL_TARGET="need-blessmail" ;;
3237 esac
3238 AC_SUBST(BLESSMAIL_TARGET)
3239
3240
3241 AC_CHECK_FUNCS(gethostname \
3242 getrusage get_current_dir_name \
3243 lrand48 \
3244 select getpagesize setlocale \
3245 utimes getrlimit setrlimit shutdown getaddrinfo \
3246 strsignal setitimer \
3247 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3248 gai_strerror mkstemp getline getdelim sync \
3249 difftime posix_memalign \
3250 getpwent endpwent getgrent endgrent \
3251 touchlock \
3252 cfmakeraw cfsetspeed copysign __executable_start log2)
3253
3254 ## Eric Backus <ericb@lsid.hp.com> says, HP-UX 9.x on HP 700 machines
3255 ## has a broken `rint' in some library versions including math library
3256 ## version number A.09.05.
3257 ## You can fix the math library by installing patch number PHSS_4630.
3258 ## But we can fix it more reliably for Emacs by just not using rint.
3259 ## We also skip HAVE_RANDOM - see comments in src/conf_post.h.
3260 case $opsys in
3261    hpux*) : ;;
3262    *) AC_CHECK_FUNCS(random rint) ;;
3263 esac
3264
3265 dnl Cannot use AC_CHECK_FUNCS
3266 AC_CACHE_CHECK([for __builtin_unwind_init],
3267                emacs_cv_func___builtin_unwind_init,
3268 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3269                 emacs_cv_func___builtin_unwind_init=yes,
3270                 emacs_cv_func___builtin_unwind_init=no)])
3271 if test $emacs_cv_func___builtin_unwind_init = yes; then
3272   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3273             [Define to 1 if you have the `__builtin_unwind_init' function.])
3274 fi
3275
3276 AC_CHECK_HEADERS_ONCE(sys/un.h)
3277
3278 AC_FUNC_FSEEKO
3279
3280 # UNIX98 PTYs.
3281 AC_CHECK_FUNCS(grantpt)
3282
3283 # PTY-related GNU extensions.
3284 AC_CHECK_FUNCS(getpt posix_openpt)
3285
3286 # Check this now, so that we will NOT find the above functions in ncurses.
3287 # That is because we have not set up to link ncurses in lib-src.
3288 # It's better to believe a function is not available
3289 # than to expect to find it in ncurses.
3290 # Also we need tputs and friends to be able to build at all.
3291 AC_MSG_CHECKING([for library containing tputs])
3292 # Run a test program that contains a call to tputs, a call that is
3293 # never executed.  This tests whether a pre-'main' dynamic linker
3294 # works with the library.  It's too much trouble to actually call
3295 # tputs in the test program, due to portability hassles.  When
3296 # cross-compiling, assume the test program will run if it links.
3297 AC_DEFUN([tputs_link_source], [
3298   AC_LANG_SOURCE(
3299      [[extern void tputs (const char *, int, int (*)(int));
3300        int main (int argc, char **argv)
3301        {
3302           if (argc == 10000)
3303             tputs (argv[0], 0, 0);
3304           return 0;
3305        }]])
3306 ])
3307 if test "${opsys}" = "mingw32"; then
3308   msg='none required'
3309 else
3310   # Maybe curses should be tried earlier?
3311   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3312   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3313     OLIBS=$LIBS
3314     if test -z "$tputs_library"; then
3315       LIBS_TERMCAP=
3316       msg='none required'
3317     else
3318       LIBS_TERMCAP=-l$tputs_library
3319       msg=$LIBS_TERMCAP
3320       LIBS="$LIBS_TERMCAP $LIBS"
3321     fi
3322     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3323       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3324     LIBS=$OLIBS
3325     if test "X$msg" != Xno; then
3326       break
3327     fi
3328   done
3329 fi
3330 AC_MSG_RESULT([$msg])
3331 if test "X$msg" = Xno; then
3332   AC_MSG_ERROR([The required function `tputs' was not found in any library.
3333 The following libraries were tried (in order):
3334   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3335 Please try installing whichever of these libraries is most appropriate
3336 for your system, together with its header files.
3337 For example, a libncurses-dev(el) or similar package.])
3338 fi
3339
3340 ## Use termcap instead of terminfo?
3341 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3342 TERMINFO=yes
3343 ## FIXME?  In the cases below where we unconditionally set
3344 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3345 ## if that was found above to have tputs.
3346 ## Should we use the gnu* logic everywhere?
3347 case "$opsys" in
3348   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3349   ##  The ncurses library has been moved out of the System framework in
3350   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3351   ##  option to use it.
3352   darwin) LIBS_TERMCAP="-lncurses" ;;
3353
3354   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3355
3356   freebsd)
3357     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3358     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3359     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3360 [[#if __FreeBSD_version < 400000
3361 fail;
3362 #endif
3363 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3364
3365     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3366
3367     if test $emacs_cv_freebsd_terminfo = yes; then
3368       LIBS_TERMCAP="-lncurses"
3369     else
3370       TERMINFO=no
3371       LIBS_TERMCAP="-ltermcap"
3372     fi
3373     ;;
3374
3375   mingw32)
3376     TERMINFO=no
3377     LIBS_TERMCAP=
3378     ;;
3379
3380   netbsd)
3381     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3382       TERMINFO=no
3383       LIBS_TERMCAP="-ltermcap"
3384     fi
3385     ;;
3386
3387   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3388
3389   ## hpux: Make sure we get select from libc rather than from libcurses
3390   ##  because libcurses on HPUX 10.10 has a broken version of select.
3391   ##  We used to use -lc -lcurses, but this may be cleaner.
3392   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3393   # set that way, now it uses the default).  Isn't this a contradiction?
3394   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3395
3396 esac
3397
3398 TERMCAP_OBJ=tparam.o
3399 if test $TERMINFO = yes; then
3400   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3401   TERMCAP_OBJ=terminfo.o
3402 fi
3403 AC_SUBST(LIBS_TERMCAP)
3404 AC_SUBST(TERMCAP_OBJ)
3405
3406
3407 # Do we have res_init, for detecting changes in /etc/resolv.conf?
3408 # On Darwin, res_init appears not to be useful: see bug#562 and
3409 # http://lists.gnu.org/archive/html/emacs-devel/2007-11/msg01467.html
3410 resolv=no
3411
3412 if test $opsys != darwin; then
3413
3414   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3415 #include <arpa/nameser.h>
3416 #include <resolv.h>]],
3417     [[return res_init();]])],
3418     have_res_init=yes, have_res_init=no)
3419   if test "$have_res_init" = no; then
3420     OLIBS="$LIBS"
3421     LIBS="$LIBS -lresolv"
3422     AC_MSG_CHECKING(for res_init with -lresolv)
3423     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
3424 #include <arpa/nameser.h>
3425 #include <resolv.h>]],
3426       [[return res_init();]])],
3427       have_res_init=yes, have_res_init=no)
3428     AC_MSG_RESULT($have_res_init)
3429     if test "$have_res_init" = yes ; then
3430       resolv=yes
3431     fi
3432     LIBS="$OLIBS"
3433   fi
3434
3435   if test "$have_res_init" = yes; then
3436     AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
3437   fi
3438 fi                              dnl !darwin
3439
3440 # Do we need the Hesiod library to provide the support routines?
3441 dnl FIXME?  Should we be skipping this on Darwin too?
3442 LIBHESIOD=
3443 if test "$with_hesiod" != no ; then
3444   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3445   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
3446      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
3447                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
3448   if test "$resolv" = yes ; then
3449     RESOLVLIB=-lresolv
3450   else
3451     RESOLVLIB=
3452   fi
3453   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
3454         hesiod=yes, :, $RESOLVLIB)])
3455
3456   if test x"$hesiod" = xyes; then
3457     AC_DEFINE(HAVE_LIBHESIOD, 1,
3458               [Define to 1 if you have the hesiod library (-lhesiod).])
3459     LIBHESIOD=-lhesiod
3460   fi
3461 fi
3462 AC_SUBST(LIBHESIOD)
3463
3464 # Do we need libresolv (due to res_init or Hesiod)?
3465 if test "$resolv" = yes && test $opsys != darwin; then
3466   AC_DEFINE(HAVE_LIBRESOLV, 1,
3467             [Define to 1 if you have the resolv library (-lresolv).])
3468   LIBRESOLV=-lresolv
3469 else
3470   LIBRESOLV=
3471 fi
3472 AC_SUBST(LIBRESOLV)
3473
3474 # These tell us which Kerberos-related libraries to use.
3475 COM_ERRLIB=
3476 CRYPTOLIB=
3477 KRB5LIB=
3478 DESLIB=
3479 KRB4LIB=
3480
3481 if test "${with_kerberos}" != no; then
3482   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
3483   if test $have_com_err = yes; then
3484     COM_ERRLIB=-lcom_err
3485     LIBS="$COM_ERRLIB $LIBS"
3486     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
3487   fi
3488   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
3489   if test $have_crypto = yes; then
3490     CRYPTOLIB=-lcrypto
3491     LIBS="$CRYPTOLIB $LIBS"
3492     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
3493   fi
3494   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
3495   if test $have_k5crypto = yes; then
3496     CRYPTOLIB=-lk5crypto
3497     LIBS="$CRYPTOLIB $LIBS"
3498     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
3499   fi
3500   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
3501   if test $have_krb5=yes; then
3502     KRB5LIB=-lkrb5
3503     LIBS="$KRB5LIB $LIBS"
3504     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
3505   fi
3506   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
3507   if test "${with_kerberos5}" = no; then
3508     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
3509     if test $have_des425 = yes; then
3510       DESLIB=-ldes425
3511       LIBS="$DESLIB $LIBS"
3512       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
3513     else
3514       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
3515       if test $have_des = yes; then
3516         DESLIB=-ldes
3517         LIBS="$DESLIB $LIBS"
3518         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
3519       fi
3520     fi
3521     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
3522     if test $have_krb4 = yes; then
3523       KRB4LIB=-lkrb4
3524       LIBS="$KRB4LIB $LIBS"
3525       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
3526     else
3527       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
3528       if test $have_krb = yes; then
3529         KRB4LIB=-lkrb
3530         LIBS="$KRB4LIB $LIBS"
3531         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
3532       fi
3533     fi
3534   fi
3535
3536   if test "${with_kerberos5}" != no; then
3537     AC_CHECK_HEADERS(krb5.h,
3538       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
3539                         [#include <krb5.h>])])
3540   else
3541     AC_CHECK_HEADERS(des.h,,
3542                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
3543                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
3544     AC_CHECK_HEADERS(krb.h,,
3545                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
3546                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
3547   fi
3548   AC_CHECK_HEADERS(com_err.h)
3549 fi
3550
3551 AC_SUBST(COM_ERRLIB)
3552 AC_SUBST(CRYPTOLIB)
3553 AC_SUBST(KRB5LIB)
3554 AC_SUBST(DESLIB)
3555 AC_SUBST(KRB4LIB)
3556
3557 AC_CHECK_FUNCS_ONCE(tzset)
3558 AC_MSG_CHECKING(whether localtime caches TZ)
3559 AC_CACHE_VAL(emacs_cv_localtime_cache,
3560 [if test x$ac_cv_func_tzset = xyes; then
3561 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
3562 char TZ_GMT0[] = "TZ=GMT0";
3563 char TZ_PST8[] = "TZ=PST8";
3564 main()
3565 {
3566   time_t now = time ((time_t *) 0);
3567   int hour_GMT0, hour_unset;
3568   if (putenv (TZ_GMT0) != 0)
3569     exit (1);
3570   hour_GMT0 = localtime (&now)->tm_hour;
3571   unsetenv("TZ");
3572   hour_unset = localtime (&now)->tm_hour;
3573   if (putenv (TZ_PST8) != 0)
3574     exit (1);
3575   if (localtime (&now)->tm_hour == hour_GMT0)
3576     exit (1);
3577   unsetenv("TZ");
3578   if (localtime (&now)->tm_hour != hour_unset)
3579     exit (1);
3580   exit (0);
3581 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
3582 [# If we have tzset, assume the worst when cross-compiling.
3583 emacs_cv_localtime_cache=yes])
3584 else
3585         # If we lack tzset, report that localtime does not cache TZ,
3586         # since we can't invalidate the cache if we don't have tzset.
3587         emacs_cv_localtime_cache=no
3588 fi])dnl
3589 AC_MSG_RESULT($emacs_cv_localtime_cache)
3590 if test $emacs_cv_localtime_cache = yes; then
3591   AC_DEFINE(LOCALTIME_CACHE, 1,
3592             [Define to 1 if localtime caches TZ.])
3593 fi
3594
3595 ok_so_far=yes
3596 AC_CHECK_FUNC(socket, , ok_so_far=no)
3597 if test $ok_so_far = yes; then
3598   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
3599 fi
3600 if test $ok_so_far = yes; then
3601   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3602 fi
3603 if test $ok_so_far = yes; then
3604 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3605   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3606             [Define to 1 if you have inet sockets.])
3607 fi
3608
3609 if test -f /usr/lpp/X11/bin/smt.exp; then
3610   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3611             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3612 fi
3613
3614 AC_MSG_CHECKING(whether system supports dynamic ptys)
3615 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3616   AC_MSG_RESULT(yes)
3617   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3618 else
3619   AC_MSG_RESULT(no)
3620 fi
3621
3622 dnl Check for a Solaris 2.4 vfork bug that Autoconf misses (through 2.69).
3623 dnl This can be removed once we assume Autoconf 2.70.
3624 case $canonical in
3625   *-solaris2.4 | *-solaris2.4.*)
3626     dnl Disable the Autoconf-generated vfork test.
3627     : ${ac_cv_func_vfork_works=no};;
3628 esac
3629
3630 AC_FUNC_FORK
3631
3632 AC_CHECK_FUNCS(snprintf)
3633
3634 dnl Check this late.  It depends on what other libraries (lrsvg, Gtk+ etc)
3635 dnl Emacs uses.
3636 XGSELOBJ=
3637 AC_MSG_CHECKING([whether GLib is linked in])
3638 AC_LINK_IFELSE([AC_LANG_PROGRAM(
3639         [[#include <glib.h>
3640         ]],
3641         [[g_print ("Hello world");]])],
3642      [links_glib=yes],
3643      [links_glib=no])
3644 AC_MSG_RESULT([$links_glib])
3645 if test "${links_glib}" = "yes"; then
3646   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
3647   if test "$HAVE_NS" = no;then
3648     XGSELOBJ=xgselect.o
3649   fi
3650 fi
3651 AC_SUBST(XGSELOBJ)
3652
3653 dnl Adapted from Haible's version.
3654 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3655   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3656     [[char* cs = nl_langinfo(CODESET);]])],
3657     emacs_cv_langinfo_codeset=yes,
3658     emacs_cv_langinfo_codeset=no)
3659   ])
3660 if test $emacs_cv_langinfo_codeset = yes; then
3661   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3662     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3663 fi
3664
3665 AC_TYPE_MBSTATE_T
3666
3667 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3668   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3669                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3670 if test "$emacs_cv_c_restrict_arr" = yes; then
3671   AC_DEFINE(__restrict_arr, __restrict,
3672     [Define to compiler's equivalent of C99 restrict keyword in array
3673      declarations.  Define as empty for no equivalent.])
3674 fi
3675
3676 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3677 dnl how the tty code is related to POSIX and/or other versions of termios.
3678 dnl The following looks like a useful start.
3679 dnl
3680 dnl AC_SYS_POSIX_TERMIOS
3681 dnl if test $ac_cv_sys_posix_termios = yes; then
3682 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3683 dnl                                and macros for terminal control.])
3684 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3685 dnl fi
3686
3687 dnl Turned on June 1996 supposing nobody will mind it.
3688 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
3689 if test "${opsys}" != "mingw32"; then
3690    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
3691      in the full name stands for the login id.])
3692 fi
3693
3694 dnl Every platform that uses configure supports this.
3695 dnl There is a create-lockfiles option you can
3696 dnl customize if you do not want the lock files to be written.
3697 dnl So it is not clear that this #define still needs to exist.
3698 AC_DEFINE(CLASH_DETECTION, 1, [Define if you want lock files to be written,
3699   so that Emacs can tell instantly when you try to modify a file that
3700   someone else has modified in his/her Emacs.])
3701
3702 dnl Everybody supports this, except MS.
3703 dnl Seems like the kind of thing we should be testing for, though.
3704 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
3705 if test "${opsys}" != "mingw32"; then
3706   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
3707 fi
3708
3709 dnl Everybody supports this, except MS-DOS.
3710 dnl Seems like the kind of thing we should be testing for, though.
3711 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
3712 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
3713   4.2-compatible sockets.])
3714
3715 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
3716
3717 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
3718   a null file, or a data sink.])
3719 if test "${opsys}" = "mingw32"; then
3720   AC_DEFINE(NULL_DEVICE, ["NUL:"])
3721 else
3722   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
3723 fi
3724
3725 AH_TEMPLATE(SEPCHAR, [Character that separates PATH elements.])
3726 if test "${opsys}" = "mingw32"; then
3727   AC_DEFINE(SEPCHAR, [';'])
3728 else
3729   AC_DEFINE(SEPCHAR, [':'])
3730 fi
3731
3732 dnl Everybody supports this, except MS-DOS.
3733 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
3734
3735 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
3736
3737
3738 AC_DEFINE(DIRECTORY_SEP, ['/'],
3739   [Character that separates directories in a file name.])
3740
3741 AH_TEMPLATE(DEVICE_SEP, [Character that separates a device in a file name.])
3742 if test "${opsys}" = "mingw32"; then
3743   dnl Only used on MS platforms.
3744   AC_DEFINE(DEVICE_SEP, ':')
3745   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == DEVICE_SEP)],
3746     [Returns true if character is a device separator.])
3747
3748   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
3749     [Returns true if character is a directory separator.])
3750
3751   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
3752     [Returns true if character is any form of separator.])
3753 else
3754   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
3755     [Returns true if character is a device separator.])
3756
3757   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
3758     [Returns true if character is a directory separator.])
3759
3760   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
3761     [Returns true if character is any form of separator.])
3762 fi
3763
3764 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
3765
3766 case $opsys in
3767   aix4-2)
3768     dnl Unfortunately without libXmu we cannot support EditRes.
3769     if test x$ac_cv_lib_Xmu_XmuConvertStandardSelection != xyes; then
3770       AC_DEFINE(NO_EDITRES, 1)
3771     fi
3772     ;;
3773
3774   hpux*)
3775     dnl Assar Westerlund <assar@sics.se> says this is necessary for
3776     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
3777     AC_DEFINE(NO_EDITRES, 1)
3778     ;;
3779 esac
3780
3781
3782 case $opsys in
3783   irix6-5 | sol2* | unixware )
3784     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
3785     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
3786     dnl need the constant to dimension an array.  So wire in the appropriate
3787     dnl value here.
3788     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
3789     ;;
3790 esac
3791
3792 emacs_broken_SIGIO=no
3793
3794 case $opsys in
3795   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3796   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3797   hpux* | irix6-5 | openbsd | sol2* | unixware )
3798     emacs_broken_SIGIO=yes
3799     ;;
3800
3801   aix4-2)
3802     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
3803     dnl the way this system works, libc functions that return malloced
3804     dnl memory use the libc malloc implementation. Calling xfree or
3805     dnl xrealloc on the results of such functions results in a crash.
3806     dnl
3807     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
3808     dnl but that does not currently work on this system.
3809     dnl
3810     dnl It is possible to completely override the malloc implementation on
3811     dnl AIX, but that involves putting the malloc functions in a shared
3812     dnl library and setting the MALLOCTYPE environment variable to point to
3813     dnl that shared library.
3814     dnl
3815     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
3816     dnl to avoid a crash just use the Emacs implementation for that function.
3817     dnl
3818     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
3819     dnl of this file, so that we do not check for get_current_dir_name
3820     dnl on AIX.  But that might be fragile if something else ends
3821     dnl up testing for get_current_dir_name as a dependency.
3822     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
3823       get_current_dir_name should not be used.])
3824     ;;
3825
3826   freebsd)
3827     dnl Circumvent a bug in FreeBSD.  In the following sequence of
3828     dnl writes/reads on a PTY, read(2) returns bogus data:
3829     dnl
3830     dnl write(2)  1022 bytes
3831     dnl write(2)   954 bytes, get EAGAIN
3832     dnl read(2)   1024 bytes in process_read_output
3833     dnl read(2)     11 bytes in process_read_output
3834     dnl
3835     dnl That is, read(2) returns more bytes than have ever been written
3836     dnl successfully.  The 1033 bytes read are the 1022 bytes written
3837     dnl successfully after processing (for example with CRs added if the
3838     dnl terminal is set up that way which it is here).  The same bytes will
3839     dnl be seen again in a later read(2), without the CRs.
3840     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
3841       work around an issue when reading from a PTY.])
3842     ;;
3843 esac
3844
3845 case $opsys in
3846   gnu-* | sol2-10 )
3847     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3848     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3849   ;;
3850 esac
3851
3852 case $opsys in
3853   darwin | dragonfly | freebsd | netbsd | openbsd )
3854     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
3855       close a pty to make it a controlling terminal (it is already a
3856       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
3857   ;;
3858 esac
3859
3860 dnl FIXME Surely we can test for this rather than hard-code it.
3861 case $opsys in
3862   netbsd | openbsd) sound_device="/dev/audio" ;;
3863   *) sound_device="/dev/dsp" ;;
3864 esac
3865
3866 dnl Used in sound.c
3867 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
3868   [Name of the default sound device.])
3869
3870
3871 dnl Emacs can read input using SIGIO and buffering characters itself,
3872 dnl or using CBREAK mode and making C-g cause SIGINT.
3873 dnl The choice is controlled by the variable interrupt_input.
3874 dnl
3875 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
3876 dnl
3877 dnl Emacs uses the presence of the USABLE_SIGIO macro
3878 dnl to indicate whether or not signal-driven I/O is possible.  It uses
3879 dnl INTERRUPT_INPUT to decide whether to use it by default.
3880 dnl
3881 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
3882 dnl CBREAK mode has two disadvantages
3883 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
3884 dnl I hear that in system V this problem does not exist.
3885 dnl 2) Control-G causes output to be discarded.
3886 dnl I do not know whether this can be fixed in system V.
3887 dnl
3888 dnl Another method of doing input is planned but not implemented.
3889 dnl It would have Emacs fork off a separate process
3890 dnl to read the input and send it to the true Emacs process
3891 dnl through a pipe.
3892 case $opsys in
3893   darwin | gnu-linux | gnu-kfreebsd )
3894     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
3895   ;;
3896 esac
3897
3898
3899 dnl If the system's imake configuration file defines `NeedWidePrototypes'
3900 dnl as `NO', we must define NARROWPROTO manually.  Such a define is
3901 dnl generated in the Makefile generated by `xmkmf'.  If we don't define
3902 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
3903 dnl taking float or double parameters.
3904 case $opsys in
3905   cygwin|gnu|gnu-linux|gnu-kfreebsd|irix6-5|freebsd|netbsd|openbsd)
3906     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
3907       file defines `NeedWidePrototypes' as `NO'.])
3908   ;;
3909 esac
3910
3911
3912 dnl Used in process.c, this must be a loop, even if it only runs once.
3913 dnl (Except on SGI; see below.  Take that, clarity and consistency!)
3914 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
3915 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
3916 dnl trying suffixes 0-16.
3917 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
3918   first PTY, if PTYs are supported.])
3919 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
3920 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
3921   end of a PTY, if non-standard.])
3922 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
3923   end of a PTY, if non-standard.])
3924
3925 case $opsys in
3926   aix4-2 )
3927     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
3928     dnl You allocate a pty by opening /dev/ptc to get the master side.
3929     dnl To get the name of the slave side, you just ttyname() the master side.
3930     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
3931     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
3932     ;;
3933
3934   cygwin )
3935     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3936     dnl multi-line AC_DEFINEs are hard. :(
3937     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (0)])
3938     AC_DEFINE(PTY_NAME_SPRINTF, [])
3939     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3940     ;;
3941
3942   dnl FIXME?  Maybe use same as freebsd - see bug#12040.
3943   darwin )
3944     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3945     dnl Not used, because PTY_ITERATION is defined.
3946     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3947     dnl Note that openpty may fork via grantpt on Mac OS X 10.4/Darwin 8.
3948     dnl But we don't have to block SIGCHLD because it is blocked in the
3949     dnl implementation of grantpt.
3950     AC_DEFINE(PTY_OPEN, [ do { int slave; if (openpty (&fd, &slave, pty_name, NULL, NULL) == -1) fd = -1; else emacs_close (slave); } while (0)])
3951     AC_DEFINE(PTY_NAME_SPRINTF, [])
3952     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
3953     ;;
3954
3955   gnu | openbsd )
3956     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3957     ;;
3958
3959   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd )
3960     dnl if HAVE_GRANTPT
3961     if test "x$ac_cv_func_grantpt" = xyes; then
3962       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
3963       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
3964       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
3965       dnl to prevent sigchld_handler from intercepting the child's death.
3966       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
3967       dnl if HAVE_POSIX_OPENPT
3968       if test "x$ac_cv_func_posix_openpt" = xyes; then
3969         AC_DEFINE(PTY_OPEN, [fd = posix_openpt (O_RDWR | O_NOCTTY)])
3970         AC_DEFINE(PTY_NAME_SPRINTF, [])
3971       dnl if HAVE_GETPT
3972       elif test "x$ac_cv_func_getpt" = xyes; then
3973         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
3974         AC_DEFINE(PTY_NAME_SPRINTF, [])
3975       else
3976         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
3977       fi
3978     else
3979       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3980     fi
3981     ;;
3982
3983   hpux*)
3984     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
3985     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
3986     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
3987     ;;
3988
3989   irix6-5 )
3990     dnl It looks like this cannot be right, because it is not a loop.
3991     dnl However, process.c actually does this:
3992     dnl # ifndef __sgi
3993     dnl   continue;
3994     dnl # else
3995     dnl   return -1;
3996     dnl # endif
3997     dnl which presumably makes it OK, since irix == sgi (?).
3998     dnl FIXME it seems like this special treatment is unnecessary?
3999     dnl Why can't irix use a single-trip loop like eg cygwin?
4000     AC_DEFINE(PTY_ITERATION, [])
4001     dnl Not used, because PTY_ITERATION is defined.
4002     AC_DEFINE(FIRST_PTY_LETTER, ['q'])
4003     AC_DEFINE(PTY_OPEN, [ { struct sigaction ocstat, cstat; struct stat stb; char * name; sigemptyset(&cstat.sa_mask); cstat.sa_handler = SIG_DFL; cstat.sa_flags = 0; sigaction(SIGCHLD, &cstat, &ocstat); name = _getpty (&fd, O_RDWR | O_NDELAY, 0600, 0); sigaction(SIGCHLD, &ocstat, (struct sigaction *)0); if (name == 0) return -1; if (fd < 0) return -1; if (fstat (fd, &stb) < 0) return -1; strcpy (pty_name, name); }])
4004     dnl No need to get the pty name at all.
4005     AC_DEFINE(PTY_NAME_SPRINTF, [])
4006     dnl No need to use sprintf to get the tty name--we get that from _getpty.
4007     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4008     ;;
4009
4010   sol2* )
4011     dnl On SysVr4, grantpt(3) forks a subprocess, so keep sigchld_handler()
4012     dnl from intercepting that death.  If any child but grantpt's should die
4013     dnl within, it should be caught after sigrelse(2).
4014     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
4015     ;;
4016
4017   unixware )
4018     dnl Comments are as per sol2*.
4019     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, sizeof pty_name, "%s", ptyname); }])
4020     ;;
4021 esac
4022
4023
4024 case $opsys in
4025   sol2* | unixware )
4026     dnl This change means that we don't loop through allocate_pty too
4027     dnl many times in the (rare) event of a failure.
4028     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4029     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4030     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4031     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (xforkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (xforkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (xforkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4032     ;;
4033 esac
4034
4035
4036 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4037 "typing" a signal character on the pty.])
4038
4039 case $opsys in
4040   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4041   dnl thomas@mathematik.uni-bremen.de says this is needed for IRIX.
4042   aix4-2 | cygwin | gnu | irix6-5 | dragonfly | freebsd | netbsd | openbsd | darwin )
4043     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4044     ;;
4045
4046   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4047   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4048   gnu-linux | gnu-kfreebsd )
4049
4050     AC_MSG_CHECKING([for signals via characters])
4051     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4052 #include <linux/version.h>
4053 #if LINUX_VERSION_CODE < 0x20400
4054 # error "Linux version too old"
4055 #endif
4056       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4057
4058     AC_MSG_RESULT([$emacs_signals_via_chars])
4059     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4060     ;;
4061 esac
4062
4063
4064 dnl Used in lisp.h, emacs.c, vm-limit.c
4065 dnl NEWS.18 describes this as "a number which contains
4066 dnl the high bits to be inclusive or'ed with pointers that are unpacked."
4067 AH_TEMPLATE(DATA_SEG_BITS, [Extra bits to be or'd in with any pointers
4068 stored in a Lisp_Object.])
4069 dnl if Emacs uses fewer than 32 bits for the value field of a LISP_OBJECT.
4070
4071 case $opsys in
4072   aix*)
4073     dnl This works with 32-bit executables; Emacs doesn't support 64-bit.
4074     AC_DEFINE(DATA_SEG_BITS, [0x20000000])
4075     ;;
4076   hpux*)
4077     dnl The data segment on this machine always starts at address 0x40000000.
4078     AC_DEFINE(DATA_SEG_BITS, [0x40000000])
4079     ;;
4080   irix6-5)
4081     AC_DEFINE(DATA_SEG_BITS, [0x10000000])
4082     ;;
4083 esac
4084
4085
4086 AH_TEMPLATE(TAB3, [Undocumented.])
4087
4088 case $opsys in
4089   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4090
4091   gnu | dragonfly | freebsd | netbsd | openbsd )
4092     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4093     AC_DEFINE(TAB3, OXTABS)
4094     ;;
4095
4096   gnu-linux | gnu-kfreebsd )
4097     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4098 #ifndef __ia64__
4099 # error "not ia64"
4100 #endif
4101       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4102         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (0)],
4103         [Mark a secondary stack, like the register stack on the ia64.]), [])
4104     ;;
4105
4106   hpux*)
4107     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4108       run_time_remap; for HPUX.])
4109     ;;
4110 esac
4111
4112
4113 dnl This won't be used automatically yet.  We also need to know, at least,
4114 dnl that the stack is continuous.
4115 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4116   registers relevant for conservative garbage collection in the jmp_buf.])
4117
4118
4119 case $opsys in
4120   dnl Not all the architectures are tested, but there are Debian packages
4121   dnl for SCM and/or Guile on them, so the technique must work.  See also
4122   dnl comments in alloc.c concerning setjmp and gcc.
4123   dnl Fixme: it's probably safe to just use the GCC conditional below.
4124   gnu-linux | gnu-kfreebsd )
4125     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4126 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4127   || defined __alpha__ || defined __mips__ || defined __s390__ \
4128   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4129   || defined __ia64__ || defined __sh__
4130 /* ok */
4131 #else
4132 # error "setjmp not known to work on this arch"
4133 #endif
4134     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4135     ;;
4136 esac
4137
4138
4139 if test x$GCC = xyes; then
4140    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4141    AC_DEFINE(GC_SETJMP_WORKS, 1)
4142 else
4143   case $opsys in
4144     dnl irix: Tested on Irix 6.5.  SCM worked on earlier versions.
4145     dragonfly | freebsd | netbsd | openbsd | irix6-5 | sol2* )
4146       AC_DEFINE(GC_SETJMP_WORKS, 1)
4147       ;;
4148   esac
4149 fi                              dnl GCC?
4150
4151 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4152 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4153   [AC_LINK_IFELSE(
4154      [AC_LANG_PROGRAM(
4155        [[#include <setjmp.h>
4156          #ifdef __MINGW32__
4157          # define _longjmp longjmp
4158          #endif
4159        ]],
4160        [[jmp_buf j;
4161          if (! _setjmp (j))
4162            _longjmp (j, 1);]])],
4163      [emacs_cv_func__setjmp=yes],
4164      [emacs_cv_func__setjmp=no])])
4165 if test $emacs_cv_func__setjmp = yes; then
4166   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4167 else
4168   AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4169     [AC_LINK_IFELSE(
4170        [AC_LANG_PROGRAM(
4171          [[#include <setjmp.h>
4172          ]],
4173          [[sigjmp_buf j;
4174            if (! sigsetjmp (j, 1))
4175              siglongjmp (j, 1);]])],
4176        [emacs_cv_func_sigsetjmp=yes],
4177        [emacs_cv_func_sigsetjmp=no])])
4178   if test $emacs_cv_func_sigsetjmp = yes; then
4179     AC_DEFINE([HAVE_SIGSETJMP], 1,
4180       [Define to 1 if sigsetjmp and siglongjmp work.
4181        The value of this symbol is irrelevant if HAVE__SETJMP is defined.])
4182   fi
4183 fi
4184
4185 case $opsys in
4186   sol2* | unixware )
4187     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4188     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4189     dnl and this is all we need.
4190     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4191     ;;
4192 esac
4193
4194
4195 case $opsys in
4196   hpux* | sol2* )
4197     dnl Used in xfaces.c.
4198     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4199       some systems, where it requires time.h.])
4200     ;;
4201 esac
4202
4203
4204 dnl Define symbols to identify the version of Unix this is.
4205 dnl Define all the symbols that apply correctly.
4206 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4207 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4208 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4209 AH_TEMPLATE(USG5, [Define if the system is compatible with System V.])
4210 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4211
4212 case $opsys in
4213   aix4-2)
4214     AC_DEFINE(USG, [])
4215     AC_DEFINE(USG5, [])
4216     dnl This symbol should be defined on AIX Version 3  ???????
4217     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4218 #ifndef _AIX
4219 # error "_AIX not defined"
4220 #endif
4221     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4222     ;;
4223
4224   cygwin)
4225     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4226     ;;
4227
4228   darwin)
4229     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4230     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4231     dnl distinguish OS X from pure Darwin.
4232     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4233     ;;
4234
4235   gnu-linux | gnu-kfreebsd )
4236     AC_DEFINE(USG, [])
4237     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4238     ;;
4239
4240   hpux*)
4241     AC_DEFINE(USG, [])
4242     AC_DEFINE(USG5, [])
4243     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4244     ;;
4245
4246   irix6-5)
4247     AC_DEFINE(USG, [])
4248     AC_DEFINE(USG5, [])
4249     AC_DEFINE(USG5_4, [])
4250     AC_DEFINE(IRIX6_5, [], [Define if the system is IRIX.])
4251     ;;
4252
4253   mingw32)
4254     AC_DEFINE(DOS_NT, [])
4255     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4256     if test "x$ac_enable_checking" != "x" ; then
4257       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4258     fi
4259     ;;
4260
4261   sol2*)
4262     AC_DEFINE(USG, [])
4263     AC_DEFINE(USG5, [])
4264     AC_DEFINE(USG5_4, [])
4265     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4266     ;;
4267
4268   unixware)
4269     AC_DEFINE(USG, [])
4270     AC_DEFINE(USG5, [])
4271     AC_DEFINE(USG5_4, [])
4272     ;;
4273 esac
4274
4275 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4276   [case $opsys in
4277      aix4-2)
4278        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4279        emacs_cv_usable_FIONREAD=no
4280        ;;
4281
4282      mingw32)
4283        emacs_cv_usable_FIONREAD=yes
4284        ;;
4285
4286      *)
4287        AC_COMPILE_IFELSE(
4288          [AC_LANG_PROGRAM([[#include <sys/types.h>
4289                             #include <sys/ioctl.h>
4290                             #ifdef USG5_4
4291                             # include <sys/filio.h>
4292                             #endif
4293                           ]],
4294                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4295          [emacs_cv_usable_FIONREAD=yes],
4296          [emacs_cv_usable_FIONREAD=no])
4297        ;;
4298    esac])
4299 if test $emacs_cv_usable_FIONREAD = yes; then
4300   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4301
4302   if test $emacs_broken_SIGIO = no; then
4303     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4304       [AC_COMPILE_IFELSE(
4305          [AC_LANG_PROGRAM([[#include <fcntl.h>
4306                             #include <signal.h>
4307                           ]],
4308                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4309          [emacs_cv_usable_SIGIO=yes],
4310          [emacs_cv_usable_SIGIO=no])],
4311       [emacs_cv_usable_SIGIO=yes],
4312       [emacs_cv_usable_SIGIO=no])
4313     if test $emacs_cv_usable_SIGIO = yes; then
4314       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4315     fi
4316   fi
4317 fi
4318
4319
4320 case $opsys in
4321   dnl Emacs supplies its own malloc, but glib (part of Gtk+) calls
4322   dnl memalign and on Cygwin, that becomes the Cygwin-supplied memalign.
4323   dnl As malloc is not the Cygwin malloc, the Cygwin memalign always
4324   dnl returns ENOSYS.  A workaround is to set G_SLICE=always-malloc. */
4325   cygwin)
4326     AC_DEFINE(G_SLICE_ALWAYS_MALLOC, 1, [Define to set the
4327       G_SLICE environment variable to "always-malloc" at startup, if
4328       using GTK.])
4329     ;;
4330
4331   hpux11)
4332     dnl It works to open the pty's tty in the parent (Emacs), then
4333     dnl close and reopen it in the child.
4334     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4335       works to open a pty's tty in the parent process, then close and
4336       reopen it in the child.])
4337     ;;
4338
4339   irix6-5)
4340     AC_DEFINE(PREFER_VSUSP, 1, [Define if process_send_signal should
4341       use VSUSP instead of VSWTCH.])
4342     ;;
4343
4344   sol2-10)
4345     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4346       on Solaris.])
4347     ;;
4348 esac
4349
4350 # Set up the CFLAGS for real compilation, so we can substitute it.
4351 CFLAGS="$REAL_CFLAGS"
4352 CPPFLAGS="$REAL_CPPFLAGS"
4353
4354 ## Hack to detect a buggy GCC version.
4355 if test "x$GCC" = xyes \
4356    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
4357    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
4358    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
4359    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
4360 fi
4361
4362 version=$PACKAGE_VERSION
4363
4364 copyright="Copyright (C) 2013 Free Software Foundation, Inc."
4365 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4366   [Short copyright string for this version of Emacs.])
4367 AC_SUBST(copyright)
4368
4369 ### Specify what sort of things we'll be editing into Makefile and config.h.
4370 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4371 AC_SUBST(version)
4372 AC_SUBST(configuration)
4373 ## Unused?
4374 AC_SUBST(canonical)
4375 AC_SUBST(srcdir)
4376 AC_SUBST(prefix)
4377 AC_SUBST(exec_prefix)
4378 AC_SUBST(bindir)
4379 AC_SUBST(datadir)
4380 AC_SUBST(sharedstatedir)
4381 AC_SUBST(libexecdir)
4382 AC_SUBST(mandir)
4383 AC_SUBST(infodir)
4384 AC_SUBST(lispdir)
4385 AC_SUBST(leimdir)
4386 AC_SUBST(standardlisppath)
4387 AC_SUBST(locallisppath)
4388 AC_SUBST(lisppath)
4389 AC_SUBST(x_default_search_path)
4390 AC_SUBST(etcdir)
4391 AC_SUBST(archlibdir)
4392 AC_SUBST(docdir)
4393 AC_SUBST(bitmapdir)
4394 AC_SUBST(gamedir)
4395 AC_SUBST(gameuser)
4396 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4397 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4398 ## end of LIBX_BASE, but nothing ever set it.
4399 AC_SUBST(LD_SWITCH_X_SITE)
4400 AC_SUBST(C_SWITCH_X_SITE)
4401 AC_SUBST(GNUSTEP_CFLAGS)
4402 AC_SUBST(CFLAGS)
4403 ## Used in lwlib/Makefile.in.
4404 AC_SUBST(X_TOOLKIT_TYPE)
4405 AC_SUBST(ns_appdir)
4406 AC_SUBST(ns_appbindir)
4407 AC_SUBST(ns_appresdir)
4408 AC_SUBST(ns_appsrc)
4409 AC_SUBST(GNU_OBJC_CFLAGS)
4410 AC_SUBST(OTHER_FILES)
4411
4412 if test -n "${term_header}"; then
4413     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4414         [Define to the header for the built-in window system.])
4415 fi
4416
4417 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4418                    [Define to the canonical Emacs configuration name.])
4419 dnl Replace any embedded " characters (bug#13274).
4420 emacs_config_options=`echo "$emacs_config_options " | sed -e 's/--no-create //' -e 's/--no-recursion //' -e 's/ *$//' -e "s/\"/'/g"`
4421 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4422                    [Define to the options passed to configure.])
4423 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4424   define this to include extra configuration information.])
4425
4426 case $opsys in
4427   mingw32)
4428     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4429     ;;
4430 esac
4431
4432 XMENU_OBJ=
4433 XOBJ=
4434 FONT_OBJ=
4435 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4436   AC_DEFINE(HAVE_X_WINDOWS, 1,
4437             [Define to 1 if you want to use the X window system.])
4438   XMENU_OBJ=xmenu.o
4439   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4440   FONT_OBJ=xfont.o
4441   if test "$HAVE_XFT" = "yes"; then
4442     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4443   elif test "$HAVE_FREETYPE" = "yes"; then
4444     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4445   fi
4446   AC_SUBST(FONT_OBJ)
4447 fi
4448 AC_SUBST(XMENU_OBJ)
4449 AC_SUBST(XOBJ)
4450 AC_SUBST(FONT_OBJ)
4451
4452 WIDGET_OBJ=
4453 MOTIF_LIBW=
4454 if test "${USE_X_TOOLKIT}" != "none" ; then
4455   WIDGET_OBJ=widget.o
4456   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4457   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4458     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4459   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4460     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4461     MOTIF_LIBW=-lXm
4462     case "$opsys" in
4463       gnu-linux)
4464         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4465         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4466         ;;
4467
4468       unixware)
4469         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4470         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4471         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4472         ;;
4473
4474       aix4-2)
4475         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4476         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4477         ;;
4478     esac
4479     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4480   fi
4481 fi
4482 AC_SUBST(WIDGET_OBJ)
4483
4484 TOOLKIT_LIBW=
4485 case "$USE_X_TOOLKIT" in
4486   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4487   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4488   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4489 esac
4490 AC_SUBST(TOOLKIT_LIBW)
4491
4492 if test "${opsys}" != "mingw32"; then
4493   if test "$USE_X_TOOLKIT" = "none"; then
4494     LIBXT_OTHER="\$(LIBXSM)"
4495     OLDXMENU_TARGET="really-oldXMenu"
4496   else
4497     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4498     OLDXMENU_TARGET="really-lwlib"
4499   fi
4500 fi
4501 AC_SUBST(LIBXT_OTHER)
4502
4503 ## The X Menu stuff is present in the X10 distribution, but missing
4504 ## from X11.  If we have X10, just use the installed library;
4505 ## otherwise, use our own copy.
4506 if test "${HAVE_X11}" = "yes" ; then
4507   AC_DEFINE(HAVE_X11, 1,
4508             [Define to 1 if you want to use version 11 of X windows.
4509              Otherwise, Emacs expects to use version 10.])
4510
4511   if test "$USE_X_TOOLKIT" = "none"; then
4512     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
4513   else
4514     OLDXMENU="\${lwlibdir}/liblw.a"
4515   fi
4516   LIBXMENU="\$(OLDXMENU)"
4517   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4518   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
4519 else
4520   ## For a syntactically valid Makefile; not actually used for anything.
4521   ## See comments in src/Makefile.in.
4522   OLDXMENU=nothing
4523   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
4524   if test "${HAVE_X_WINDOWS}" = "yes"; then
4525     LIBXMENU="-lXMenu"
4526   else
4527     LIBXMENU=
4528   fi
4529   LIBX_OTHER=
4530   OLDXMENU_DEPS=
4531 fi
4532
4533 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
4534   OLDXMENU_TARGET=
4535   OLDXMENU=nothing
4536   LIBXMENU=
4537   OLDXMENU_DEPS=
4538 fi
4539
4540 AC_SUBST(OLDXMENU_TARGET)
4541 AC_SUBST(OLDXMENU)
4542 AC_SUBST(LIBXMENU)
4543 AC_SUBST(LIBX_OTHER)
4544 AC_SUBST(OLDXMENU_DEPS)
4545
4546 if test "${HAVE_MENUS}" = "yes" ; then
4547   AC_DEFINE(HAVE_MENUS, 1,
4548             [Define to 1 if you have mouse menus.
4549              (This is automatic if you use X, but the option to specify it remains.)
4550              It is also defined with other window systems that support xmenu.c.])
4551 fi
4552
4553 if test "${GNU_MALLOC}" = "yes" ; then
4554   AC_DEFINE(GNU_MALLOC, 1,
4555             [Define to 1 if you want to use the GNU memory allocator.])
4556 fi
4557
4558 RALLOC_OBJ=
4559 if test "${REL_ALLOC}" = "yes" ; then
4560   AC_DEFINE(REL_ALLOC, 1,
4561             [Define REL_ALLOC if you want to use the relocating allocator for
4562              buffer space.])
4563
4564   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4565 fi
4566 AC_SUBST(RALLOC_OBJ)
4567
4568 if test "$opsys" = "cygwin"; then
4569   CYGWIN_OBJ="sheap.o cygw32.o"
4570   ## Cygwin differs because of its unexec().
4571   PRE_ALLOC_OBJ=
4572   POST_ALLOC_OBJ=lastfile.o
4573 elif test "$opsys" = "mingw32"; then
4574   CYGWIN_OBJ=
4575   PRE_ALLOC_OBJ=
4576   POST_ALLOC_OBJ=lastfile.o
4577 else
4578   CYGWIN_OBJ=
4579   PRE_ALLOC_OBJ=lastfile.o
4580   POST_ALLOC_OBJ=
4581 fi
4582 AC_SUBST(CYGWIN_OBJ)
4583 AC_SUBST(PRE_ALLOC_OBJ)
4584 AC_SUBST(POST_ALLOC_OBJ)
4585
4586 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
4587 # it temporarily reverts them to their pre-pkg-config values,
4588 # because gnulib needs to work with both src (which uses the
4589 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
4590 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
4591 # and it therefore needs to run in an environment where LIBS does not
4592 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
4593 # for some package unrelated to lib-src.
4594 SAVE_CFLAGS=$CFLAGS
4595 SAVE_LIBS=$LIBS
4596 CFLAGS=$pre_PKG_CONFIG_CFLAGS
4597 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
4598 gl_ASSERT_NO_GNULIB_POSIXCHECK
4599 gl_ASSERT_NO_GNULIB_TESTS
4600 gl_INIT
4601 CFLAGS=$SAVE_CFLAGS
4602 LIBS=$SAVE_LIBS
4603
4604 if test "${opsys}" = "mingw32"; then
4605   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I $srcdir/nt/inc"
4606   # Remove unneeded switches from the value of CC that goes to Makefiles
4607   CC=`echo $CC | sed -e "s,$GCC_TEST_OPTIONS,,"`
4608 fi
4609
4610 case "$opsys" in
4611   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
4612
4613   darwin)
4614    ## The -headerpad option tells ld (see man page) to leave room at the
4615    ## end of the header for adding load commands.  Needed for dumping.
4616    ## 0x690 is the total size of 30 segment load commands (at 56
4617    ## each); under Cocoa 31 commands are required.
4618    if test "$HAVE_NS" = "yes"; then
4619      libs_nsgui="-framework AppKit"
4620      if test "$NS_IMPL_COCOA" = "yes"; then
4621         libs_nsgui="$libs_nsgui -framework IOKit"
4622      fi
4623      headerpad_extra=6C8
4624    else
4625      libs_nsgui=
4626      headerpad_extra=690
4627    fi
4628    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
4629
4630    ## This is here because src/Makefile.in did some extra fiddling around
4631    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
4632    ## LD_SWITCH_SYSTEM_TEMACS instead,
4633    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
4634      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
4635    ;;
4636
4637   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
4638   ## find X at run-time.
4639   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
4640   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
4641   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
4642   ## had different values in configure (in ac_link) and src/Makefile.in.
4643   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
4644   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
4645
4646   mingw32)
4647    ## MinGW64 does not prepend an underscore to symbols, so we must
4648    ## pass a different -entry switch to linker.  FIXME: It is better
4649    ## to make the entry points the same by changing unexw32.c.
4650    case "$canonical" in
4651      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,_start -Wl,-Map,./temacs.map" ;;
4652      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
4653    esac
4654    ;;
4655
4656   openbsd) LD_SWITCH_SYSTEM_TEMACS='-nopie' ;;
4657
4658   *) LD_SWITCH_SYSTEM_TEMACS= ;;
4659 esac
4660
4661 if test x$ac_enable_profiling != x ; then
4662   case $opsys in
4663     *freebsd | gnu-linux) ;;
4664     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
4665   esac
4666 fi
4667
4668 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
4669
4670 ## MinGW-specific post-link processing of temacs.
4671 TEMACS_POST_LINK=":"
4672 ADDSECTION=
4673 EMACS_HEAPSIZE=
4674 if test "${opsys}" = "mingw32"; then
4675   TEMACS_POST_LINK="\$(MINGW_TEMACS_POST_LINK)"
4676   ADDSECTION="../nt/addsection\$(EXEEXT)"
4677   ## Preload heap size of temacs.exe in MB.
4678   case "$canonical" in
4679     x86_64-*-*) EMACS_HEAPSIZE=42 ;;
4680     *) EMACS_HEAPSIZE=27 ;;
4681   esac
4682 fi
4683
4684 AC_SUBST(ADDSECTION)
4685 AC_SUBST(TEMACS_POST_LINK)
4686 AC_SUBST(EMACS_HEAPSIZE)
4687
4688 ## Common for all window systems
4689 if test "$window_system" != "none"; then
4690   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
4691   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
4692 fi
4693
4694 AC_SUBST(WINDOW_SYSTEM_OBJ)
4695
4696 AH_TOP([/* GNU Emacs site configuration template file.
4697
4698 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2013
4699   Free Software Foundation, Inc.
4700
4701 This file is part of GNU Emacs.
4702
4703 GNU Emacs is free software: you can redistribute it and/or modify
4704 it under the terms of the GNU General Public License as published by
4705 the Free Software Foundation, either version 3 of the License, or
4706 (at your option) any later version.
4707
4708 GNU Emacs is distributed in the hope that it will be useful,
4709 but WITHOUT ANY WARRANTY; without even the implied warranty of
4710 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
4711 GNU General Public License for more details.
4712
4713 You should have received a copy of the GNU General Public License
4714 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
4715
4716
4717 /* No code in Emacs #includes config.h twice, but some bits of code
4718    intended to work with other packages as well (like gmalloc.c)
4719    think they can include it as many times as they like.  */
4720 #ifndef EMACS_CONFIG_H
4721 #define EMACS_CONFIG_H
4722 ])dnl
4723
4724 AH_BOTTOM([#include <conf_post.h>
4725
4726 #endif /* EMACS_CONFIG_H */
4727
4728 /*
4729 Local Variables:
4730 mode: c
4731 End:
4732 */
4733 ])dnl
4734
4735 #### Report on what we decided to do.
4736 #### Report GTK as a toolkit, even if it doesn't use Xt.
4737 #### It makes printing result more understandable as using GTK sets
4738 #### toolkit_scroll_bars to yes by default.
4739 if test "${HAVE_GTK}" = "yes"; then
4740   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
4741 fi
4742
4743 if test $USE_ACL -ne 0; then
4744   acl_summary="yes $LIB_ACL"
4745 else
4746   acl_summary=no
4747 fi
4748
4749 echo "
4750 Configured for \`${canonical}'.
4751
4752   Where should the build process find the source code?    ${srcdir}
4753   What compiler should emacs be built with?               ${CC} ${CFLAGS}
4754   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
4755   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
4756   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
4757   What window system should Emacs use?                    ${window_system}
4758   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
4759
4760 if test -n "${x_includes}"; then
4761 echo "  Where do we find X Windows header files?                ${x_includes}"
4762 else
4763 echo "  Where do we find X Windows header files?                Standard dirs"
4764 fi
4765 if test -n "${x_libraries}"; then
4766 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
4767 else
4768 echo "  Where do we find X Windows libraries?                   Standard dirs"
4769 fi
4770
4771 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
4772 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
4773 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
4774 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
4775 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
4776 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
4777 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
4778 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
4779
4780 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
4781 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
4782 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
4783 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
4784 echo "  Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}"
4785 echo "  Does Emacs use access control lists?                    ${acl_summary}"
4786 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
4787 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
4788 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
4789
4790 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
4791 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
4792 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
4793 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
4794
4795 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
4796 echo
4797
4798 if test -n "${EMACSDATA}"; then
4799    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
4800 fi
4801 if test -n "${EMACSDOC}"; then
4802    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
4803 fi
4804
4805 echo
4806
4807 if test "$HAVE_NS" = "yes"; then
4808    echo
4809    echo "You must run \"${MAKE-make} install\" in order to test the built application.
4810 The installed application will go to nextstep/Emacs.app and can be
4811 run or moved from there."
4812    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
4813       echo "The application will be fully self-contained."
4814     else
4815       echo "The lisp resources for the application will be installed under ${prefix}.
4816 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
4817 to run if these resources are not installed."
4818    fi
4819    echo
4820 fi
4821
4822 if test "${opsys}" = "cygwin"; then
4823   case `uname -r` in
4824     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
4825            echo
4826            ;;
4827   esac
4828 fi
4829
4830 # Remove any trailing slashes in these variables.
4831 [test "${prefix}" != NONE &&
4832   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
4833 test "${exec_prefix}" != NONE &&
4834   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
4835
4836 if test "$HAVE_NS" = "yes"; then
4837   if test "$NS_IMPL_GNUSTEP" = yes; then
4838     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
4839       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
4840   else
4841     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
4842       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
4843   fi
4844 fi
4845
4846 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
4847 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
4848 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
4849 dnl (else you get "no `Makefile.am' found for any configure output").
4850 dnl This will work, but you get a config.status that is not quite right
4851 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
4852 dnl That doesn't have any obvious consequences for Emacs, but on the whole
4853 dnl it seems better to just live with the duplication.
4854 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
4855
4856 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
4857        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
4858        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
4859        leim/Makefile nextstep/Makefile nt/Makefile])
4860
4861 dnl test/ is not present in release tarfiles.
4862 opt_makefile=test/automated/Makefile
4863
4864 if test -f "$srcdir/$opt_makefile.in"; then
4865   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4866   dnl Again, it's best not to use a variable.  Though you can add
4867   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
4868   AC_CONFIG_FILES([test/automated/Makefile])
4869 fi
4870
4871
4872 dnl admin/ may or may not be present.
4873 opt_makefile=admin/unidata/Makefile
4874
4875 if test -f "$srcdir/$opt_makefile.in"; then
4876   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
4877   AC_CONFIG_FILES([admin/unidata/Makefile])
4878 fi
4879
4880
4881 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
4882
4883 AC_SUBST(SUBDIR_MAKEFILES_IN)
4884
4885 dnl Make the necessary directories, if they don't exist.
4886 AC_CONFIG_COMMANDS([mkdirs], [
4887 for dir in etc lisp ; do
4888   test -d ${dir} || mkdir ${dir}
4889 done
4890 ])
4891
4892 dnl You might wonder (I did) why epaths.h is generated by running make,
4893 dnl rather than just letting configure generate it from epaths.in.
4894 dnl One reason is that the various paths are not fully expanded (see above);
4895 dnl eg gamedir=${prefix}/var/games/emacs.
4896 dnl Secondly, the GNU Coding standards require that one should be able
4897 dnl to run `make prefix=/some/where/else' and override the values set
4898 dnl by configure.  This also explains the `move-if-change' test and
4899 dnl the use of force in the `epaths-force' rule in Makefile.in.
4900 AC_CONFIG_COMMANDS([epaths], [
4901 echo creating src/epaths.h
4902 if test "${opsys}" = "mingw32"; then
4903   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
4904 else
4905   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
4906 fi
4907 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
4908
4909 AC_CONFIG_COMMANDS([gdbinit], [
4910 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
4911   echo creating src/.gdbinit
4912   echo "source $srcdir/src/.gdbinit" > src/.gdbinit
4913 fi
4914 ])
4915
4916 AC_OUTPUT