code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004,
   8 dnl    2005, 2006, 2007, 2008, 2009, 2010
   9 dnl    Free Software Foundation, Inc.
  10 dnl
  11 dnl  This file is part of GNU Emacs.
  12 dnl
  13 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  14 dnl  it under the terms of the GNU General Public License as published by
  15 dnl  the Free Software Foundation, either version 3 of the License, or
  16 dnl  (at your option) any later version.
  17 dnl
  18 dnl  GNU Emacs is distributed in the hope that it will be useful,
  19 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 dnl  GNU General Public License for more details.
  22 dnl
  23 dnl  You should have received a copy of the GNU General Public License
  24 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 AC_PREREQ(2.65)
  27 AC_INIT(emacs, 24.0.50)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29 AC_CONFIG_SRCDIR(src/lisp.h)
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  41 '${datadir}/emacs/site-lisp'
  42 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  43 etcdir='${datadir}/emacs/${version}/etc'
  44 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  45 docdir='${datadir}/emacs/${version}/etc'
  46 gamedir='${localstatedir}/games/emacs'
  47
  48 gameuser=games
  49
  50 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  51 dnl Create a new --with option that defaults to being disabled.
  52 dnl NAME is the base name of the option.  The shell variable with_NAME
  53 dnl   will be set to either the user's value (if the option is
  54 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  55 dnl   option is not specified).  Note that the shell variable name is
  56 dnl   constructed as autoconf does, by replacing non-alphanumeric
  57 dnl   characters with "_".
  58 dnl HELP-STRING is the help text for the option.
  59 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  60   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  61     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  62 ])dnl
  63
  64 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  65 dnl Create a new --with option that defaults to being enabled.  NAME
  66 dnl   is the base name of the option.  The shell variable with_NAME
  67 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  68 dnl   'yes' (if the option is not specified).  Note that the shell
  69 dnl   variable name is constructed as autoconf does, by replacing
  70 dnl   non-alphanumeric characters with "_".
  71 dnl HELP-STRING is the help text for the option.
  72 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  73   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  74    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  75 ])dnl
  76
  77 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  78 if test "$with_pop" = yes; then
  79    AC_DEFINE(MAIL_USE_POP)
  80 fi
  81 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  82
  83 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  84 if test "$with_kerberos" != no; then
  85    AC_DEFINE(KERBEROS)
  86 fi
  87 AH_TEMPLATE(KERBEROS,
  88             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  89
  90 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  91 if test "${with_kerberos5}" != no; then
  92   if test "${with_kerberos}" = no; then
  93     with_kerberos=yes
  94     AC_DEFINE(KERBEROS)
  95   fi
  96   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  97 fi
  98
  99 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 100 dnl FIXME hesiod support may not be present, so it seems like an error
 101 dnl to define, or at least use, this unconditionally.
 102 if test "$with_hesiod" != no; then
 103   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 104 fi
 105
 106 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 107 if test "$with_mmdf" != no; then
 108    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 109 fi
 110
 111 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 112 if test "$with_mail_unlink" != no; then
 113    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 114 fi
 115
 116 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 117     [string giving default POP mail host])],
 118     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 119
 120 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 121
 122 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 123 if test "$with_sync_input" = yes; then
 124    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 125 fi
 126
 127 dnl FIXME currently it is not the last.
 128 dnl This should be the last --with option, because --with-x is
 129 dnl added later on when we find the path of X, and it's best to
 130 dnl keep them together visually.
 131 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 132  [use an X toolkit (KIT one of: yes or gtk, lucid or athena, motif, no)])],
 133 [         case "${withval}" in
 134             y | ye | yes )      val=gtk ;;
 135             n | no )            val=no  ;;
 136             l | lu | luc | luci | lucid )       val=lucid ;;
 137             a | at | ath | athe | athen | athena )      val=athena ;;
 138             m | mo | mot | moti | motif )       val=motif ;;
 139             g | gt | gtk  )     val=gtk ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
 143 `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 dnl _ON results in a '--without' option in the --help output, so
 150 dnl the help text should refer to "don't compile", etc.
 151 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 152 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 153 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 154 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 155 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 156 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 157
 158 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 159 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 160 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 161
 162 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 163 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 164 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 165 OPTION_DEFAULT_OFF([ns],[use nextstep (Cocoa or GNUstep) windowing system])
 166
 167 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 168 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 169 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 170 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 171
 172 ## For the times when you want to build Emacs but don't have
 173 ## a suitable makeinfo, and can live without the manuals.
 174 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 175 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 176
 177 AC_ARG_WITH([pkg-config-prog],dnl
 178 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 179                   [path to pkg-config for finding GTK and librsvg])])
 180 if test "X${with_pkg_config_prog}" != X; then
 181    if test "${with_pkg_config_prog}" != yes; then
 182       PKG_CONFIG="${with_pkg_config_prog}"
 183    fi
 184 fi
 185
 186 CRT_DIR=
 187 AC_ARG_WITH([crt-dir],dnl
 188 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 189 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 190 CRT_DIR="${with_crt_dir}"
 191
 192 AC_ARG_WITH([gnustep-conf],dnl
 193 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 194 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 195   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 196 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 197      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 198
 199 AC_ARG_ENABLE(ns-self-contained,
 200 [AS_HELP_STRING([--disable-ns-self-contained],
 201                 [disable self contained build under NeXTstep])],
 202    EN_NS_SELF_CONTAINED=$enableval,
 203    EN_NS_SELF_CONTAINED=yes)
 204
 205 AC_ARG_ENABLE(asserts,
 206 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 207       USE_XASSERTS=$enableval,
 208       USE_XASSERTS=no)
 209
 210 AC_ARG_ENABLE(maintainer-mode,
 211 [AS_HELP_STRING([--enable-maintainer-mode],
 212                 [enable make rules and dependencies not useful (and sometimes
 213                  confusing) to the casual installer])],
 214       USE_MAINTAINER_MODE=$enableval,
 215       USE_MAINTAINER_MODE=no)
 216 if test $USE_MAINTAINER_MODE = yes; then
 217   MAINT=
 218 else
 219   MAINT=#
 220 fi
 221 AC_SUBST(MAINT)
 222
 223 AC_ARG_ENABLE(locallisppath,
 224 [AS_HELP_STRING([--enable-locallisppath=PATH],
 225                 [directories Emacs should search for lisp files specific
 226                  to this site])],
 227 if test "${enableval}" = "no"; then
 228   locallisppath=
 229 elif test "${enableval}" != "yes"; then
 230   locallisppath=${enableval}
 231 fi)
 232
 233 AC_ARG_ENABLE(checking,
 234 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 235                 [enable expensive run-time checks.  With LIST,
 236                  enable only specific categories of checks.
 237                  Categories are: all,yes,no.
 238                  Flags are: stringbytes, stringoverrun, stringfreelist,
 239                  xmallocoverrun, conslist])],
 240 [ac_checking_flags="${enableval}"],[])
 241 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 242 for check in $ac_checking_flags
 243 do
 244         case $check in
 245         # these set all the flags to specific states
 246         yes)            ac_enable_checking=1 ;;
 247         no)             ac_enable_checking= ;
 248                         ac_gc_check_stringbytes= ;
 249                         ac_gc_check_string_overrun= ;
 250                         ac_gc_check_string_free_list= ;
 251                         ac_xmalloc_overrun= ;
 252                         ac_gc_check_cons_list= ;;
 253         all)            ac_enable_checking=1 ;
 254                         ac_gc_check_stringbytes=1 ;
 255                         ac_gc_check_string_overrun=1 ;
 256                         ac_gc_check_string_free_list=1 ;
 257                         ac_xmalloc_overrun=1 ;
 258                         ac_gc_check_cons_list=1 ;;
 259         # these enable particular checks
 260         stringbytes)    ac_gc_check_stringbytes=1 ;;
 261         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 262         stringfreelist) ac_gc_check_string_free_list=1 ;;
 263         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 264         conslist)       ac_gc_check_cons_list=1 ;;
 265         *)      AC_MSG_ERROR(unknown check category $check) ;;
 266         esac
 267 done
 268 IFS="$ac_save_IFS"
 269
 270 if test x$ac_enable_checking != x ; then
 271   AC_DEFINE(ENABLE_CHECKING, 1,
 272 [Enable expensive run-time checking of data types?])
 273 fi
 274 if test x$ac_gc_check_stringbytes != x ; then
 275   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 276 [Define this temporarily to hunt a bug.  If defined, the size of
 277    strings is redundantly recorded in sdata structures so that it can
 278    be compared to the sizes recorded in Lisp strings.])
 279 fi
 280 if test x$ac_gc_check_stringoverrun != x ; then
 281   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 282 [Define this to check for short string overrun.])
 283 fi
 284 if test x$ac_gc_check_string_free_list != x ; then
 285   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 286 [Define this to check the string free list.])
 287 fi
 288 if test x$ac_xmalloc_overrun != x ; then
 289   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 290 [Define this to check for malloc buffer overrun.])
 291 fi
 292 if test x$ac_gc_check_cons_list != x ; then
 293   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 294 [Define this to check for errors in cons list.])
 295 fi
 296
 297 AC_ARG_ENABLE(profiling,
 298 [AS_HELP_STRING([--enable-profiling],
 299                 [build emacs with profiling support.
 300                  This might not work on all platforms])],
 301 [ac_enable_profiling="${enableval}"],[])
 302 if test x$ac_enable_profiling != x ; then
 303    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 304    PROFILING_LDFLAGS="-pg"
 305 else
 306    PROFILING_CFLAGS=
 307    PROFILING_LDFLAGS=
 308 fi
 309
 310 AC_ARG_ENABLE(autodepend,
 311 [AS_HELP_STRING([--enable-autodepend],
 312                 [automatically generate dependencies to .h-files.
 313                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 314                  found])],
 315 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 316
 317 #### Make srcdir absolute, if it isn't already.  It's important to
 318 #### avoid running the path through pwd unnecessarily, since pwd can
 319 #### give you automounter prefixes, which can go away.  We do all this
 320 #### so Emacs can find its files when run uninstalled.
 321 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 322 unset CDPATH
 323 case "${srcdir}" in
 324   /* ) ;;
 325   . )
 326     ## We may be able to use the $PWD environment variable to make this
 327     ## absolute.  But sometimes PWD is inaccurate.
 328     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 329     ## but that tested only for a well-formed and valid PWD,
 330     ## it did not object when PWD was well-formed and valid but just wrong.
 331     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 332     then
 333       srcdir="$PWD"
 334     else
 335       srcdir="`(cd ${srcdir}; pwd)`"
 336     fi
 337   ;;
 338   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 339 esac
 340
 341 #### Check if the source directory already has a configured system in it.
 342 if test `pwd` != `(cd ${srcdir} && pwd)` \
 343    && test -f "${srcdir}/src/config.h" ; then
 344   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 345    as a build directory right now; it has been configured in its own
 346    right.  To configure in another directory as well, you MUST
 347    use GNU make.  If you do not have GNU make, then you must
 348    now do `make distclean' in ${srcdir},
 349    and then run $0 again.]])
 350 fi
 351
 352 #### Given the configuration name, set machfile and opsysfile to the
 353 #### names of the m/*.h and s/*.h files we should use.
 354
 355 ### Canonicalize the configuration name.
 356
 357 AC_CANONICAL_HOST
 358 canonical=$host
 359 configuration=${host_alias-${build_alias-$host}}
 360
 361 dnl This used to use changequote, but, apart from `changequote is evil'
 362 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 363 dnl the great gob of text.  Thus it's not processed for possible expansion.
 364 dnl Just make sure the brackets remain balanced.
 365 dnl
 366 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 367 dnl indicated by comments.
 368 dnl quotation begins
 369 [
 370
 371 ### If you add support for a new configuration, add code to this
 372 ### switch statement to recognize your configuration name and select
 373 ### the appropriate operating system and machine description files.
 374
 375 ### You would hope that you could choose an m/*.h file pretty much
 376 ### based on the machine portion of the configuration name, and an s/*.h
 377 ### file based on the operating system portion.  However, it turns out
 378 ### that each m/*.h file is pretty manufacturer-specific - for
 379 ### example mips.h is MIPS
 380 ### So we basically have to have a special case for each
 381 ### configuration name.
 382 ###
 383 ### As far as handling version numbers on operating systems is
 384 ### concerned, make sure things will fail in a fixable way.  If
 385 ### /etc/MACHINES doesn't say anything about version numbers, be
 386 ### prepared to handle anything reasonably.  If version numbers
 387 ### matter, be sure /etc/MACHINES says something about it.
 388
 389 machine='' opsys='' unported=no
 390 case "${canonical}" in
 391
 392   ## FreeBSD ports
 393   *-*-freebsd* )
 394     opsys=freebsd
 395     case "${canonical}" in
 396       alpha*)           machine=alpha ;;
 397       amd64-*|x86_64-*) machine=amdx86-64 ;;
 398       arm*)             machine=arm ;;
 399       ia64-*)           machine=ia64 ;;
 400       i[3456]86-*)      machine=intel386 ;;
 401       powerpc-*)        machine=macppc ;;
 402       sparc-*)          machine=sparc ;;
 403       sparc64-*)        machine=sparc ;;
 404     esac
 405   ;;
 406
 407   ## FreeBSD kernel + glibc based userland
 408   *-*-kfreebsd*gnu* )
 409     opsys=gnu-kfreebsd
 410     case "${canonical}" in
 411       alpha*)           machine=alpha ;;
 412       amd64-*|x86_64-*) machine=amdx86-64 ;;
 413       ia64-*)           machine=ia64 ;;
 414       i[3456]86-*)      machine=intel386 ;;
 415       powerpc-*)        machine=macppc ;;
 416       sparc-*)          machine=sparc ;;
 417       sparc64-*)        machine=sparc ;;
 418     esac
 419   ;;
 420
 421   ## NetBSD ports
 422   *-*-netbsd* )
 423     opsys=netbsd
 424     case "${canonical}" in
 425       alpha*)      machine=alpha ;;
 426       x86_64-*)    machine=amdx86-64 ;;
 427       arm-*)       machine=arm ;;
 428       hppa-*)      machine=hp800 ;;
 429       i[3456]86-*) machine=intel386 ;;
 430       m68k-*)      machine=m68k ;;
 431       powerpc-*)   machine=macppc ;;
 432       mips-*)      machine=mips ;;
 433       mipse[bl]-*) machine=mips ;;
 434       sparc*-)     machine=sparc ;;
 435       vax-*)       machine=vax ;;
 436     esac
 437   ;;
 438
 439   ## OpenBSD ports
 440   *-*-openbsd* )
 441     opsys=openbsd
 442     case "${canonical}" in
 443       alpha*)    machine=alpha ;;
 444       x86_64-*)  machine=amdx86-64 ;;
 445       arm-*)     machine=arm ;;
 446       hppa-*)    machine=hp800 ;;
 447       i386-*)    machine=intel386 ;;
 448       powerpc-*) machine=macppc ;;
 449       sparc*)    machine=sparc ;;
 450       vax-*)     machine=vax ;;
 451     esac
 452   ;;
 453
 454   alpha*-*-linux-gnu* )
 455     machine=alpha opsys=gnu-linux
 456   ;;
 457
 458   arm*-*-linux-gnu* )
 459     machine=arm opsys=gnu-linux
 460   ;;
 461
 462   ## Apple Darwin / Mac OS X
 463   *-apple-darwin* )
 464     case "${canonical}" in
 465       i[3456]86-* )  machine=intel386 ;;
 466       powerpc-* )    machine=macppc ;;
 467       x86_64-* )     machine=amdx86-64 ;;
 468       * )            unported=yes ;;
 469     esac
 470     opsys=darwin
 471     # Define CPP as follows to make autoconf work correctly.
 472     CPP="${CC-cc} -E -no-cpp-precomp"
 473     # Use fink packages if available.
 474     if test -d /sw/include && test -d /sw/lib; then
 475       GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 476       CPP="${CPP} ${GCC_TEST_OPTIONS}"
 477       NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 478     fi
 479   ;;
 480
 481   ## HP 9000 series 700 and 800, running HP/UX
 482   hppa*-hp-hpux10.2* )
 483     machine=hp800 opsys=hpux10-20
 484   ;;
 485   hppa*-hp-hpux1[1-9]* )
 486     machine=hp800 opsys=hpux11
 487     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 488   ;;
 489
 490   hppa*-*-linux-gnu* )
 491     machine=hp800 opsys=gnu-linux
 492   ;;
 493
 494   ## IBM machines
 495   s390-*-linux-gnu* )
 496     machine=ibms390 opsys=gnu-linux
 497   ;;
 498   s390x-*-linux-gnu* )
 499     machine=ibms390x opsys=gnu-linux
 500   ;;
 501   rs6000-ibm-aix4.[23]* )
 502     machine=ibmrs6000 opsys=aix4-2
 503   ;;
 504   powerpc-ibm-aix4.[23]*  )
 505     machine=ibmrs6000 opsys=aix4-2
 506   ;;
 507   rs6000-ibm-aix[56]* )
 508     machine=ibmrs6000 opsys=aix4-2
 509   ;;
 510   powerpc-ibm-aix[56]*  )
 511     machine=ibmrs6000 opsys=aix4-2
 512   ;;
 513
 514   ## Macintosh PowerPC
 515   powerpc*-*-linux-gnu* )
 516     machine=macppc opsys=gnu-linux
 517   ;;
 518
 519   ## Silicon Graphics machines
 520   ## Iris 4D
 521   mips-sgi-irix6.5 )
 522     machine=iris4d opsys=irix6-5
 523     # Without defining _LANGUAGE_C, things get masked out in the headers
 524     # so that, for instance, grepping for `free' in stdlib.h fails and
 525     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 526     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 527     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 528   ;;
 529
 530   ## Suns
 531   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 532     machine=sparc opsys=gnu-linux
 533   ;;
 534
 535   *-sun-solaris* \
 536     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 537     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 538     case "${canonical}" in
 539       i[3456]86-*-* )     machine=intel386 ;;
 540       amd64-*-*|x86_64-*-*)     machine=amdx86-64 ;;
 541       sparc* )          machine=sparc ;;
 542       * )               unported=yes ;;
 543     esac
 544     case "${canonical}" in
 545       *-sunos5.6* | *-solaris2.6* )
 546                 opsys=sol2-6
 547                 NON_GNU_CPP=/usr/ccs/lib/cpp
 548                 RANLIB="ar -ts"
 549                 ;;
 550       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 551                 opsys=sol2-6
 552                 emacs_check_sunpro_c=yes
 553                 NON_GNU_CPP=/usr/ccs/lib/cpp
 554                 ;;
 555       *-sunos5* | *-solaris* )
 556                 opsys=sol2-10
 557                 emacs_check_sunpro_c=yes
 558                 NON_GNU_CPP=/usr/ccs/lib/cpp
 559                 ;;
 560     esac
 561     ## Watch out for a compiler that we know will not work.
 562     case "${canonical}" in
 563      *-solaris* | *-sunos5* )
 564                 if [ "x$CC" = x/usr/ucb/cc ]; then
 565                   ## /usr/ucb/cc doesn't work;
 566                   ## we should find some other compiler that does work.
 567                   unset CC
 568                 fi
 569                 ;;
 570       *) ;;
 571     esac
 572   ;;
 573
 574   ## IA-64
 575   ia64*-*-linux* )
 576     machine=ia64 opsys=gnu-linux
 577   ;;
 578
 579   ## Intel 386 machines where we don't care about the manufacturer.
 580   i[3456]86-*-* )
 581     machine=intel386
 582     case "${canonical}" in
 583       *-cygwin )                opsys=cygwin ;;
 584       *-darwin* )               opsys=darwin
 585                                 CPP="${CC-cc} -E -no-cpp-precomp"
 586                                 ;;
 587       *-linux-gnu* )            opsys=gnu-linux ;;
 588       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 589       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 590       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
 591       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 592     esac
 593   ;;
 594
 595   ## m68k Linux-based GNU system
 596   m68k-*-linux-gnu* )
 597     machine=m68k opsys=gnu-linux
 598   ;;
 599
 600   ## Mips Linux-based GNU system
 601   mips-*-linux-gnu* | mipsel-*-linux-gnu* \
 602     | mips64-*-linux-gnu* | mips64el-*-linux-gnu* )
 603     machine=mips opsys=gnu-linux
 604   ;;
 605
 606   ## AMD x86-64 Linux-based GNU system
 607   x86_64-*-linux-gnu* )
 608     machine=amdx86-64 opsys=gnu-linux
 609   ;;
 610
 611   ## Tensilica Xtensa Linux-based GNU system
 612   xtensa*-*-linux-gnu* )
 613     machine=xtensa opsys=gnu-linux
 614     ;;
 615
 616   ## SuperH Linux-based GNU system
 617   sh[34]*-*-linux-gnu* )
 618     machine=sh3 opsys=gnu-linux
 619   ;;
 620
 621   * )
 622     unported=yes
 623   ;;
 624 esac
 625
 626 ### If the code above didn't choose an operating system, just choose
 627 ### an operating system based on the configuration name.  You really
 628 ### only want to use this when you have no idea what the right
 629 ### operating system is; if you know what operating systems a machine
 630 ### runs, it's cleaner to make it explicit in the case statement
 631 ### above.
 632 if test x"${opsys}" = x; then
 633   case "${canonical}" in
 634     *-gnu* )                            opsys=gnu ;;
 635     * )
 636       unported=yes
 637     ;;
 638   esac
 639 fi
 640
 641 ]
 642 dnl quotation ends
 643
 644 if test $unported = yes; then
 645   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 646 Check `etc/MACHINES' for recognized configuration names.])
 647 fi
 648
 649 machfile="m/${machine}.h"
 650 opsysfile="s/${opsys}.h"
 651
 652
 653 #### Choose a compiler.
 654 test -n "$CC" && cc_specified=yes
 655
 656 # Save the value of CFLAGS that the user specified.
 657 SPECIFIED_CFLAGS="$CFLAGS"
 658
 659 dnl Sets GCC=yes if using gcc.
 660 AC_PROG_CC
 661
 662 # On Suns, sometimes $CPP names a directory.
 663 if test -n "$CPP" && test -d "$CPP"; then
 664   CPP=
 665 fi
 666
 667 ## If not using gcc, and on Solaris, and no CPP specified, see if
 668 ## using a Sun compiler, which needs -Xs to prevent whitespace.
 669 if test x"$GCC" != xyes && test x"$emacs_check_sunpro_c" = xyes && \
 670  test x"$CPP" = x; then
 671   AC_MSG_CHECKING([whether we are using a Sun C compiler])
 672   AC_CACHE_VAL(emacs_cv_sunpro_c,
 673   [AC_TRY_LINK([],
 674 [#ifndef __SUNPRO_C
 675 fail;
 676 #endif
 677 ], emacs_cv_sunpro_c=yes, emacs_cv_sunpro_c=no)])
 678   AC_MSG_RESULT($emacs_cv_sunpro_c)
 679
 680   if test x"$emacs_cv_sunpro_c" = xyes; then
 681     NON_GNU_CPP="$CC -E -Xs"
 682   fi
 683 fi
 684
 685 #### Some systems specify a CPP to use unless we are using GCC.
 686 #### Now that we know whether we are using GCC, we can decide whether
 687 #### to use that one.
 688 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 689 then
 690   CPP="$NON_GNU_CPP"
 691 fi
 692
 693 #### Some systems specify a CC to use unless we are using GCC.
 694 #### Now that we know whether we are using GCC, we can decide whether
 695 #### to use that one.
 696 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 697   test x$cc_specified != xyes
 698 then
 699   CC="$NON_GNU_CC"
 700 fi
 701
 702 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 703 then
 704   CC="$CC $GCC_TEST_OPTIONS"
 705 fi
 706
 707 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 708 then
 709   CC="$CC $NON_GCC_TEST_OPTIONS"
 710 fi
 711
 712 dnl checks for Unix variants
 713 AC_USE_SYSTEM_EXTENSIONS
 714
 715 ### Use -Wno-pointer-sign if the compiler supports it
 716 AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
 717 SAVE_CFLAGS="$CFLAGS"
 718 CFLAGS="$CFLAGS -Wno-pointer-sign"
 719 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 720 if test $has_option = yes; then
 721    C_WARNINGS_SWITCH="-Wno-pointer-sign $C_WARNINGS_SWITCH"
 722 fi
 723 AC_MSG_RESULT($has_option)
 724 CFLAGS="$SAVE_CFLAGS"
 725 unset has_option
 726 unset SAVE_CFLAGS
 727
 728 ### Use -Wdeclaration-after-statement if the compiler supports it
 729 AC_MSG_CHECKING([whether gcc understands -Wdeclaration-after-statement])
 730 SAVE_CFLAGS="$CFLAGS"
 731 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 732 AC_TRY_COMPILE([], [], has_option=yes, has_option=no,)
 733 if test $has_option = yes; then
 734    C_WARNINGS_SWITCH="-Wdeclaration-after-statement $C_WARNINGS_SWITCH"
 735 fi
 736 AC_MSG_RESULT($has_option)
 737 CFLAGS="$SAVE_CFLAGS"
 738 unset has_option
 739 unset SAVE_CFLAGS
 740
 741 #### Some other nice autoconf tests.
 742
 743 dnl checks for programs
 744 AC_PROG_CPP
 745 AC_PROG_INSTALL
 746 if test "x$RANLIB" = x; then
 747   AC_PROG_RANLIB
 748 fi
 749
 750 ## Although we're running on an amd64 kernel, we're actually compiling for
 751 ## the x86 architecture.  The user should probably have provided an
 752 ## explicit --build to `configure', but if everything else than the kernel
 753 ## is running in i386 mode, we can help them out.
 754 if test "$machine" = "amdx86-64"; then
 755   AC_CHECK_DECL([i386])
 756   if test "$ac_cv_have_decl_i386" = "yes"; then
 757     canonical=`echo "$canonical" | sed -e 's/^amd64/i386/' -e 's/^x86_64/i386/'`
 758     machine=intel386
 759     machfile="m/${machine}.h"
 760   fi
 761 fi
 762
 763 AC_PATH_PROG(INSTALL_INFO, install-info)
 764 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
 765 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
 766 dnl Don't use GZIP, which is used by gzip for additional parameters.
 767 AC_PATH_PROG(GZIP_PROG, gzip)
 768
 769
 770 ## Need makeinfo >= 4.6 (?) to build the manuals.
 771 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 772 dnl By this stage, configure has already checked for egrep and set EGREP,
 773 dnl or exited with an error if no egrep was found.
 774 if test "$MAKEINFO" != "no" && \
 775   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[6-9]]|4\.[[1-5]][[0-9]]+)'`" = x; then
 776    MAKEINFO=no
 777 fi
 778
 779 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 780 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 781 ## therefore in the category of "special tools" not normally required, which
 782 ## configure does not have to check for (eg autoconf itself).
 783 ## In a Bazaar checkout on the other hand, the manuals are not included.
 784 ## So makeinfo is a requirement to build from Bazaar, and configure
 785 ## should test for it as it does for any other build requirement.
 786 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 787 ## with pre-built manuals, from a Bazaar checkout.
 788 if test "$MAKEINFO" = "no"; then
 789   if test "x${with_makeinfo}" = "xno"; then
 790     MAKEINFO=off
 791   elif test ! -e $srcdir/info/emacs; then
 792     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.6, and your
 793 source tree does not seem to have pre-built manuals in the `info' directory.
 794 Either install a suitable version of makeinfo, or re-run configure
 795 with the `--without-makeinfo' option to build without the manuals.] )
 796   fi
 797 fi
 798
 799 dnl Add our options to ac_link now, after it is set up.
 800
 801 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
 802 then
 803   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 804 fi
 805
 806 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
 807 then
 808   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 809 fi
 810
 811 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 812 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 813 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 814 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 815 dnl if not built to support GNU ld.
 816
 817 late_LDFLAGS=$LDFLAGS
 818 if test "$GCC" = yes; then
 819   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 820 else
 821   LDFLAGS="$LDFLAGS -znocombreloc"
 822 fi
 823
 824 AC_MSG_CHECKING([for -znocombreloc])
 825 AC_LINK_IFELSE([main(){return 0;}],
 826   [AC_MSG_RESULT(yes)],
 827   LDFLAGS=$late_LDFLAGS
 828   [AC_MSG_RESULT(no)])
 829
 830 #### Extract some information from the operating system and machine files.
 831
 832 AC_CHECKING([the machine- and system-dependent files to find out
 833  - which libraries the lib-src programs will want, and
 834  - whether the GNU malloc routines are usable])
 835
 836 ### First figure out CFLAGS (which we use for running the compiler here)
 837 ### and REAL_CFLAGS (which we use for real compilation).
 838 ### The two are the same except on a few systems, where they are made
 839 ### different to work around various lossages.  For example,
 840 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
 841 ### as implying static linking.
 842
 843 ### If the CFLAGS env var is specified, we use that value
 844 ### instead of the default.
 845
 846 ### It's not important that this name contain the PID; you can't run
 847 ### two configures in the same directory and have anything work
 848 ### anyway.
 849 tempcname="conftest.c"
 850
 851 echo '
 852 #include "'${srcdir}'/src/'${opsysfile}'"
 853 #include "'${srcdir}'/src/'${machfile}'"
 854
 855 configure___ LIBX=-lX11
 856
 857 #ifdef CANNOT_DUMP
 858 configure___ cannot_dump=yes
 859 #else
 860 configure___ cannot_dump=no
 861 #endif
 862
 863 #ifdef SYSTEM_MALLOC
 864 configure___ system_malloc=yes
 865 #else
 866 configure___ system_malloc=no
 867 #endif
 868
 869 #ifdef USE_MMAP_FOR_BUFFERS
 870 configure___ use_mmap_for_buffers=yes
 871 #else
 872 configure___ use_mmap_for_buffers=no
 873 #endif
 874
 875 #ifndef C_OPTIMIZE_SWITCH
 876 #ifdef __GNUC__
 877 #define C_OPTIMIZE_SWITCH -O2
 878 #else
 879 #define C_OPTIMIZE_SWITCH -O
 880 #endif
 881 #endif
 882
 883 #ifndef C_WARNINGS_SWITCH
 884 #define C_WARNINGS_SWITCH ${C_WARNINGS_SWITCH}
 885 #endif
 886
 887 #ifdef THIS_IS_CONFIGURE
 888
 889 /* Get the CFLAGS for tests in configure.  */
 890 #ifdef __GNUC__
 891 configure___ CFLAGS=-g C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
 892 #else
 893 configure___ CFLAGS='${SPECIFIED_CFLAGS}'
 894 #endif
 895
 896 #else /* not THIS_IS_CONFIGURE */
 897
 898 /* Get the CFLAGS for real compilation.  */
 899 #ifdef __GNUC__
 900 configure___ REAL_CFLAGS=-g C_OPTIMIZE_SWITCH C_WARNINGS_SWITCH ${PROFILING_CFLAGS} '${SPECIFIED_CFLAGS}'
 901 #else
 902 configure___ REAL_CFLAGS='${SPECIFIED_CFLAGS}'
 903 #endif
 904
 905 #endif /* not THIS_IS_CONFIGURE */
 906 ' > ${tempcname}
 907
 908 LDFLAGS="${LDFLAGS} ${PROFILING_LDFLAGS}"
 909
 910 # The value of CPP is a quoted variable reference, so we need to do this
 911 # to get its actual value...
 912 CPP=`eval "echo $CPP"`
 913 [eval `${CPP} -Isrc ${tempcname} \
 914        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 915 if test "x$SPECIFIED_CFLAGS" = x; then
 916   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
 917          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
 918 else
 919   REAL_CFLAGS="$CFLAGS"
 920 fi]
 921 rm ${tempcname}
 922
 923
 924 AC_SUBST(cannot_dump)
 925
 926 UNEXEC_OBJ=unexelf.o
 927 case "$opsys" in
 928   aix4-2)
 929    UNEXEC_OBJ=unexaix.o
 930    ;;
 931   cygwin)
 932    UNEXEC_OBJ=unexcw.o
 933    ;;
 934   darwin)
 935    UNEXEC_OBJ=unexmacosx.o
 936    ;;
 937   hpux10-20 | hpux11)
 938    UNEXEC_OBJ=unexhp9k800.o
 939    ;;
 940   sol2-10)
 941    # Use the Solaris dldump() function, called from unexsol.c, to dump
 942    # emacs, instead of the generic ELF dump code found in unexelf.c.
 943    # The resulting binary has a complete symbol table, and is better
 944    # for debugging and other observability tools (debuggers, pstack, etc).
 945    #
 946    # If you encounter a problem using dldump(), please consider sending
 947    # a message to the OpenSolaris tools-linking mailing list:
 948    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 949    #
 950    # It is likely that dldump() works with older Solaris too, but this has
 951    # not been tested, so for now this change is for Solaris 10 or newer.
 952    UNEXEC_OBJ=unexsol.o
 953    ;;
 954 esac
 955
 956 LD_SWITCH_SYSTEM=
 957 case "$opsys" in
 958   freebsd)
 959    ## Let `ld' find image libs and similar things in /usr/local/lib.
 960    ## The system compiler, GCC, has apparently been modified to not
 961    ## look there, contrary to what a stock GCC would do.
 962    LD_SWITCH_SYSTEM=-L/usr/local/lib
 963    ;;
 964
 965   gnu-linux)
 966    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 967    test "$machine" = "mips" && LD_SWITCH_SYSTEM="-G 0"
 968    ;;
 969
 970   netbsd)
 971    LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 972    ;;
 973
 974   openbsd)
 975    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 976    ## otherwise Emacs dumps core on elf systems.
 977    LD_SWITCH_SYSTEM="-Z"
 978    ;;
 979 esac
 980 AC_SUBST(LD_SWITCH_SYSTEM)
 981
 982 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 983
 984 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_AUX,
 985 ## which has not been defined yet.  When this was handled with cpp,
 986 ## it was expanded to null when configure sourced the s/*.h file.
 987 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 988 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 989 ## (or somesuch), but because it is supposed to go at the _front_
 990 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 991 ## Compare with the gnu-linux case below, which added to the end
 992 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 993 ## LD_SWITCH_SYSTEM_TEMACS.
 994 case "$opsys" in
 995   netbsd|openbsd)
 996    ## _AUX_RPATH is like _AUX, but uses -rpath instead of -R.
 997    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_AUX_RPATH) $LD_SWITCH_SYSTEM" ;;
 998 esac
 999
1000
1001 C_SWITCH_MACHINE=
1002 if test "$machine" = "alpha"; then
1003   AC_CHECK_DECL([__ELF__])
1004   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1005     ## With ELF, make sure that all common symbols get allocated to in the
1006     ## data section.  Otherwise, the dump of temacs may miss variables in
1007     ## the shared library that have been initialized.  For example, with
1008     ## GNU libc, __malloc_initialized would normally be resolved to the
1009     ## shared library's .bss section, which is fatal.
1010     if test "x$GCC" = "xyes"; then
1011       C_SWITCH_MACHINE="-fno-common"
1012     else
1013       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
1014     fi
1015   else
1016     UNEXEC_OBJ=unexalpha.o
1017   fi
1018 fi
1019 AC_SUBST(C_SWITCH_MACHINE)
1020
1021 AC_SUBST(UNEXEC_OBJ)
1022
1023 C_SWITCH_SYSTEM=
1024 ## Some programs in src produce warnings saying certain subprograms
1025 ## are too complex and need a MAXMEM value greater than 2000 for
1026 ## additional optimization.  --nils@exp-math.uni-essen.de
1027 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1028   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1029 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1030 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1031 AC_SUBST(C_SWITCH_SYSTEM)
1032
1033
1034 LIBS_SYSTEM=
1035 case "$opsys" in
1036   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1037   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1038
1039   freebsd) LIBS_SYSTEM="-lutil" ;;
1040
1041   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1042
1043   sol2*) LIBS_SYSTEM="-lsocket -lnsl -lkstat" ;;
1044
1045   ## Motif needs -lgen.
1046   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1047 esac
1048 AC_SUBST(LIBS_SYSTEM)
1049
1050
1051 ### Make sure subsequent tests use flags consistent with the build flags.
1052
1053 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1054   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1055 else
1056   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1057 fi
1058
1059 dnl For AC_FUNC_GETLOADAVG, at least:
1060 AC_CONFIG_LIBOBJ_DIR(src)
1061
1062 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1063 AC_SYS_LARGEFILE
1064
1065
1066 ## If user specified a crt-dir, use that unconditionally.
1067 if test "X$CRT_DIR" = "X"; then
1068
1069   case "$canonical" in
1070     x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1071     ## On x86-64 and s390x GNU/Linux distributions, the standard library
1072     ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1073     ## For anything else (eg /usr/lib32), it is up the user to specify
1074     ## the location (bug#5655).
1075     ## Test for crtn.o, not just the directory, because sometimes the
1076     ## directory exists but does not have the relevant files (bug#1287).
1077     ## FIXME better to test for binary compatibility somehow.
1078     test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1079     ;;
1080
1081     powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1082   esac
1083
1084   case "$opsys" in
1085     hpux10-20) CRT_DIR=/lib ;;
1086   esac
1087
1088   ## Default is /usr/lib.
1089   test "X$CRT_DIR" = "X" && CRT_DIR=/usr/lib
1090
1091 else
1092
1093   ## Some platforms don't use any of these files, so it is not
1094   ## appropriate to put this test outside the if block.
1095   test -e $CRT_DIR/crtn.o || test -e $CRT_DIR/crt0.o || \
1096     AC_MSG_ERROR([crt*.o not found in specified location.])
1097
1098 fi
1099
1100 AC_SUBST(CRT_DIR)
1101
1102 LIB_MATH=-lm
1103 LIB_STANDARD=
1104 START_FILES=
1105
1106 case $opsys in
1107   cygwin )
1108     LIB_MATH=
1109     START_FILES='ecrt0.o'
1110     ;;
1111   darwin )
1112     ## Adding -lm confuses the dynamic linker, so omit it.
1113     LIB_MATH=
1114     START_FILES='pre-crt0.o'
1115     ;;
1116   freebsd )
1117     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1118     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1119     ;;
1120   gnu-linux | gnu-kfreebsd )
1121     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
1122     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
1123     ;;
1124   hpux10-20 | hpux11 )
1125     LIB_STANDARD=-lc
1126     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
1127     ;;
1128   netbsd | openbsd )
1129     if test -f $CRT_DIR/crti.o; then
1130         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1131         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1132     else
1133         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
1134         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
1135     fi
1136     ;;
1137 esac
1138
1139 AC_SUBST(LIB_MATH)
1140 AC_SUBST(START_FILES)
1141
1142 dnl This function definition taken from Gnome 2.0
1143 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1144 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1145 dnl also defines GSTUFF_PKG_ERRORS on error
1146 AC_DEFUN([PKG_CHECK_MODULES], [
1147   succeeded=no
1148
1149   AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1150
1151   if test "$PKG_CONFIG" = "no" ; then
1152      ifelse([$4], , [AC_MSG_ERROR([
1153       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1154   else
1155      PKG_CONFIG_MIN_VERSION=0.9.0
1156      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1157         AC_MSG_CHECKING(for $2)
1158
1159         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD; then
1160             AC_MSG_RESULT(yes)
1161             succeeded=yes
1162
1163             AC_MSG_CHECKING($1_CFLAGS)
1164             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"|sed -e 's,///*,/,g'`
1165             AC_MSG_RESULT($$1_CFLAGS)
1166
1167             AC_MSG_CHECKING($1_LIBS)
1168             $1_LIBS=`$PKG_CONFIG --libs "$2"|sed -e 's,///*,/,g'`
1169             AC_MSG_RESULT($$1_LIBS)
1170         else
1171             AC_MSG_RESULT(no)
1172             $1_CFLAGS=""
1173             $1_LIBS=""
1174             ## If we have a custom action on failure, don't print errors, but
1175             ## do set a variable so people can do so.
1176             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1177             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1178         fi
1179
1180         AC_SUBST($1_CFLAGS)
1181         AC_SUBST($1_LIBS)
1182      else
1183         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1184         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1185      fi
1186   fi
1187
1188   if test $succeeded = yes; then
1189      ifelse([$3], , :, [$3])
1190   else
1191      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1192   fi
1193 ])
1194
1195
1196 if test "${with_sound}" != "no"; then
1197   # Sound support for GNU/Linux and the free BSDs.
1198   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1199   # Emulation library used on NetBSD.
1200   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1201   AC_SUBST(LIBSOUND)
1202
1203   ALSA_REQUIRED=1.0.0
1204   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1205   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1206   if test $HAVE_ALSA = yes; then
1207     SAVE_CFLAGS="$CFLAGS"
1208     SAVE_LDFLAGS="$LDFLAGS"
1209     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1210     LDFLAGS="$ALSA_LIBS $LDFLAGS"
1211     AC_TRY_COMPILE([#include <asoundlib.h>], [snd_lib_error_set_handler (0);],
1212                     emacs_alsa_normal=yes,
1213                     emacs_alsa_normal=no)
1214     if test "$emacs_alsa_normal" != yes; then
1215       AC_TRY_COMPILE([#include <alsa/asoundlib.h>],
1216                      [snd_lib_error_set_handler (0);],
1217                      emacs_alsa_subdir=yes,
1218                      emacs_alsa_subdir=no)
1219       if test "$emacs_alsa_subdir" != yes; then
1220         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1221       fi
1222       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1223     fi
1224
1225     CFLAGS="$SAVE_CFLAGS"
1226     LDFLAGS="$SAVE_LDFLAGS"
1227     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1228     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1229     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1230   fi
1231   AC_SUBST(CFLAGS_SOUND)
1232 fi
1233
1234 dnl checks for header files
1235 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1236   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1237   stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1238   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1239   sys/utsname.h pwd.h utmp.h)
1240
1241 AC_MSG_CHECKING(if personality LINUX32 can be set)
1242 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1243                emacs_cv_personality_linux32=yes,
1244                emacs_cv_personality_linux32=no)
1245 AC_MSG_RESULT($emacs_cv_personality_linux32)
1246
1247 if test $emacs_cv_personality_linux32 = yes; then
1248   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1249             [Define to 1 if personality LINUX32 can be set.])
1250 fi
1251
1252 dnl On Solaris 8 there's a compilation warning for term.h because
1253 dnl it doesn't define `bool'.
1254 AC_CHECK_HEADERS(term.h, , , -)
1255 AC_HEADER_STDC
1256 AC_HEADER_TIME
1257 AC_CHECK_DECLS([sys_siglist])
1258 if test $ac_cv_have_decl_sys_siglist != yes; then
1259   # For Tru64, at least:
1260   AC_CHECK_DECLS([__sys_siglist])
1261   if test $ac_cv_have_decl___sys_siglist = yes; then
1262     AC_DEFINE(sys_siglist, __sys_siglist,
1263               [Define to any substitute for sys_siglist.])
1264   fi
1265 fi
1266 AC_HEADER_SYS_WAIT
1267
1268 dnl Some systems have utime.h but don't declare the struct anyplace.
1269 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1270 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1271 #include <sys/time.h>
1272 #include <time.h>
1273 #else
1274 #ifdef HAVE_SYS_TIME_H
1275 #include <sys/time.h>
1276 #else
1277 #include <time.h>
1278 #endif
1279 #endif
1280 #ifdef HAVE_UTIME_H
1281 #include <utime.h>
1282 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1283   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1284 if test $emacs_cv_struct_utimbuf = yes; then
1285   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1286 fi
1287
1288 dnl checks for typedefs
1289 AC_TYPE_SIGNAL
1290
1291 dnl Check for speed_t typedef.
1292 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1293   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1294     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1295 if test $emacs_cv_speed_t = yes; then
1296   AC_DEFINE(HAVE_SPEED_T, 1,
1297            [Define to 1 if `speed_t' is declared by <termios.h>.])
1298 fi
1299
1300 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1301 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1302 #include <sys/time.h>
1303 #include <time.h>
1304 #else
1305 #ifdef HAVE_SYS_TIME_H
1306 #include <sys/time.h>
1307 #else
1308 #include <time.h>
1309 #endif
1310 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1311   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1312 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1313 if test $emacs_cv_struct_timeval = yes; then
1314   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1315 fi
1316
1317 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1318 AC_TRY_COMPILE([#include <math.h>],
1319 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1320   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1321 HAVE_EXCEPTION=$emacs_cv_struct_exception
1322 if test $emacs_cv_struct_exception != yes; then
1323   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1324 fi
1325
1326 AC_CHECK_HEADERS(sys/socket.h)
1327 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1328 #if HAVE_SYS_SOCKET_H
1329 #include <sys/socket.h>
1330 #endif])
1331
1332 dnl checks for structure members
1333 AC_STRUCT_TM
1334 AC_STRUCT_TIMEZONE
1335 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1336                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1337                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1338                 [#include <time.h>])
1339 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1340                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1341                   struct ifreq.ifr_addr], , ,
1342                  [AC_INCLUDES_DEFAULT
1343 #if HAVE_SYS_SOCKET_H
1344 #include <sys/socket.h>
1345 #endif
1346 #if HAVE_NET_IF_H
1347 #include <net/if.h>
1348 #endif])
1349
1350 dnl checks for compiler characteristics
1351
1352 dnl Testing __STDC__ to determine prototype support isn't good enough.
1353 dnl DEC C, for instance, doesn't define it with default options, and
1354 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1355 dnl and void *.
1356 AC_C_PROTOTYPES
1357 AC_C_VOLATILE
1358 AC_C_CONST
1359 dnl This isn't useful because we can't turn on use of `inline' unless
1360 dnl the compiler groks `extern inline'.
1361 dnl AC_C_INLINE
1362 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1363   [AC_TRY_COMPILE(, [void * foo;],
1364                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1365 if test $emacs_cv_void_star = yes; then
1366   AC_DEFINE(POINTER_TYPE, void)
1367 else
1368   AC_DEFINE(POINTER_TYPE, char)
1369 fi
1370 AH_TEMPLATE(POINTER_TYPE,
1371             [Define as `void' if your compiler accepts `void *'; otherwise
1372              define as `char'.])dnl
1373
1374
1375
1376 dnl This could be used for targets which can have both byte sexes.
1377 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1378 dnl AC_C_BIGENDIAN
1379
1380 dnl check for Make feature
1381 AC_PROG_MAKE_SET
1382
1383 DEPFLAGS=
1384 MKDEPDIR=":"
1385 deps_frag=deps.mk
1386 dnl check for GNU Make if we have GCC and autodepend is on.
1387 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1388    AC_MSG_CHECKING([whether we are using GNU Make])
1389    HAVE_GNU_MAKE=no
1390    testval=`make --version 2>/dev/null | grep 'GNU Make'`
1391    if test "x$testval" != x; then
1392       HAVE_GNU_MAKE=yes
1393    else
1394       ac_enable_autodepend=no
1395    fi
1396    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1397    if test $HAVE_GNU_MAKE = yes; then
1398       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1399       SAVE_CFLAGS="$CFLAGS"
1400       CFLAGS="$CFLAGS -MMD -MF deps.d"
1401       AC_TRY_COMPILE([], [], , ac_enable_autodepend=no)
1402       CFLAGS="$SAVE_CFLAGS"
1403       test -f deps.d || ac_enable_autodepend=no
1404       rm -rf deps.d
1405       AC_MSG_RESULT([$ac_enable_autodepend])
1406    fi
1407    if test $ac_enable_autodepend = yes; then
1408       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d'
1409       ## In parallel builds, another make might create depdir between
1410       ## the first test and mkdir, so stick another test on the end.
1411       ## Or use mkinstalldirs?  mkdir -p is not portable.
1412       MKDEPDIR='test -d ${DEPDIR} || mkdir ${DEPDIR} || test -d ${DEPDIR}'
1413       deps_frag=autodeps.mk
1414    fi
1415 fi
1416 deps_frag=$srcdir/src/$deps_frag
1417 AC_SUBST(MKDEPDIR)
1418 AC_SUBST(DEPFLAGS)
1419 AC_SUBST_FILE(deps_frag)
1420
1421
1422 dnl checks for operating system services
1423 AC_SYS_LONG_FILE_NAMES
1424
1425 #### Choose a window system.
1426
1427 AC_PATH_X
1428 if test "$no_x" = yes; then
1429   window_system=none
1430 else
1431   window_system=x11
1432 fi
1433
1434 ## Workaround for bug in autoconf <= 2.62.
1435 ## http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01551.html
1436 ## No need to do anything special for these standard directories.
1437 if test -n "${x_libraries}" && test x"${x_libraries}" != xNONE; then
1438
1439    x_libraries=`echo :${x_libraries}: | sed -e 's|:/usr/lib64:|:|g' -e 's|:/lib64:|:|g' -e 's|^:||' -e 's|:$||'`
1440
1441 fi
1442
1443 LD_SWITCH_X_SITE_AUX=
1444 LD_SWITCH_X_SITE_AUX_RPATH=
1445 if test "${x_libraries}" != NONE; then
1446   if test -n "${x_libraries}"; then
1447     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1448     LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1449     LD_SWITCH_X_SITE_AUX_RPATH=`echo ${LD_SWITCH_X_SITE_AUX} | sed -e 's/-R/-Wl,-rpath,/'`
1450   fi
1451   x_default_search_path=""
1452   x_search_path=${x_libraries}
1453   if test -z "${x_search_path}"; then
1454     x_search_path=/usr/lib
1455   fi
1456   for x_library in `echo ${x_search_path}: | \
1457                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1458     x_search_path="\
1459 ${x_library}/X11/%L/%T/%N%C%S:\
1460 ${x_library}/X11/%l/%T/%N%C%S:\
1461 ${x_library}/X11/%T/%N%C%S:\
1462 ${x_library}/X11/%L/%T/%N%S:\
1463 ${x_library}/X11/%l/%T/%N%S:\
1464 ${x_library}/X11/%T/%N%S"
1465     if test x"${x_default_search_path}" = x; then
1466       x_default_search_path=${x_search_path}
1467     else
1468       x_default_search_path="${x_search_path}:${x_default_search_path}"
1469     fi
1470   done
1471 fi
1472 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1473 AC_SUBST(LD_SWITCH_X_SITE_AUX_RPATH)
1474
1475 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1476   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1477 fi
1478
1479 if test x"${x_includes}" = x; then
1480   bitmapdir=/usr/include/X11/bitmaps
1481 else
1482   # accumulate include directories that have X11 bitmap subdirectories
1483   bmd_acc="dummyval"
1484   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1485     if test -d "${bmd}/X11/bitmaps"; then
1486       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1487     fi
1488     if test -d "${bmd}/bitmaps"; then
1489       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1490     fi
1491   done
1492   if test ${bmd_acc} != "dummyval"; then
1493     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1494   fi
1495 fi
1496
1497 HAVE_NS=no
1498 NS_IMPL_COCOA=no
1499 NS_IMPL_GNUSTEP=no
1500 tmp_CPPFLAGS="$CPPFLAGS"
1501 tmp_CFLAGS="$CFLAGS"
1502 CPPFLAGS="$CPPFLAGS -x objective-c"
1503 CFLAGS="$CFLAGS -x objective-c"
1504 TEMACS_LDFLAGS2="\${LDFLAGS}"
1505 dnl I don't think it's especially important, but src/Makefile.in
1506 dnl (now the only user of ns_appdir) used to go to the trouble of adding a
1507 dnl trailing "/" to it, so now we do it here.
1508 if test "${with_ns}" != no; then
1509   if test "${opsys}" = darwin; then
1510      NS_IMPL_COCOA=yes
1511      ns_appdir=`pwd`/nextstep/Emacs.app/
1512      ns_appbindir=${ns_appdir}Contents/MacOS/
1513      ns_appresdir=${ns_appdir}Contents/Resources
1514      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1515   elif test -f $GNUSTEP_CONFIG_FILE; then
1516      NS_IMPL_GNUSTEP=yes
1517      ns_appdir=`pwd`/nextstep/Emacs.app/
1518      ns_appbindir=${ns_appdir}
1519      ns_appresdir=${ns_appdir}Resources
1520      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1521      dnl FIXME sourcing this several times in subshells seems inefficient.
1522      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1523      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1524      dnl I seemed to need these as well with GNUstep-startup 0.25.
1525      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1526      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1527      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1528        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1529      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1530        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1531      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1532      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1533      REAL_CFLAGS="$REAL_CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1534      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1535      LIB_STANDARD=
1536      START_FILES=
1537      TEMACS_LDFLAGS2=
1538   fi
1539   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1540                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1541   files are missing or cannot be compiled.])])
1542   NS_HAVE_NSINTEGER=yes
1543   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1544                                      [NSInteger i;])],
1545                     ns_have_nsinteger=yes,
1546                     ns_have_nsinteger=no)
1547   if test $ns_have_nsinteger = no; then
1548     NS_HAVE_NSINTEGER=no
1549   fi
1550 fi
1551 AC_SUBST(TEMACS_LDFLAGS2)
1552
1553 ns_frag=/dev/null
1554 NS_OBJ=
1555 NS_SUPPORT=
1556 if test "${HAVE_NS}" = yes; then
1557   window_system=nextstep
1558   with_xft=no
1559   # set up packaging dirs
1560   exec_prefix=${ns_appbindir}
1561   libexecdir=${ns_appbindir}/libexec
1562   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1563      prefix=${ns_appresdir}
1564   fi
1565   ns_frag=$srcdir/src/ns.mk
1566   NS_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o fontset.o fringe.o image.o"
1567   NS_SUPPORT="\${lispsource}emacs-lisp/easymenu.elc \${lispsource}term/ns-win.elc"
1568 fi
1569 CFLAGS="$tmp_CFLAGS"
1570 CPPFLAGS="$tmp_CPPFLAGS"
1571 AC_SUBST(NS_OBJ)
1572 AC_SUBST(NS_SUPPORT)
1573 AC_SUBST(LIB_STANDARD)
1574 AC_SUBST_FILE(ns_frag)
1575
1576 case "${window_system}" in
1577   x11 )
1578     HAVE_X_WINDOWS=yes
1579     HAVE_X11=yes
1580     case "${with_x_toolkit}" in
1581       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1582       motif ) USE_X_TOOLKIT=MOTIF ;;
1583       gtk ) with_gtk=yes
1584 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1585 dnl USE_X_TOOLKIT is set.
1586             USE_X_TOOLKIT=none ;;
1587       no ) USE_X_TOOLKIT=none ;;
1588 dnl If user did not say whether to use a toolkit, make this decision later:
1589 dnl use the toolkit if we have gtk, or X11R5 or newer.
1590       * ) USE_X_TOOLKIT=maybe ;;
1591     esac
1592   ;;
1593   nextstep | none )
1594     HAVE_X_WINDOWS=no
1595     HAVE_X11=no
1596     USE_X_TOOLKIT=none
1597   ;;
1598 esac
1599
1600 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1601    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1602    if test "$HAVE_XSERVER" = true ||
1603       test -n "$DISPLAY" ||
1604       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1605         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1606 were found.  You should install the relevant development files for X
1607 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1608 sure you have development files for image handling, i.e.
1609 tiff, gif, jpeg, png and xpm.
1610 If you are sure you want Emacs compiled without X window support, pass
1611   --without-x
1612 to configure.])
1613    fi
1614 fi
1615
1616 ### If we're using X11, we should use the X menu package.
1617 HAVE_MENUS=no
1618 case ${HAVE_X11} in
1619   yes ) HAVE_MENUS=yes ;;
1620 esac
1621
1622 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1623 # Assume not, until told otherwise.
1624 GNU_MALLOC=yes
1625 doug_lea_malloc=yes
1626 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1627 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1628 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1629                emacs_cv_var___after_morecore_hook,
1630 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1631   emacs_cv_var___after_morecore_hook=yes,
1632   emacs_cv_var___after_morecore_hook=no)])
1633 if test $emacs_cv_var___after_morecore_hook = no; then
1634   doug_lea_malloc=no
1635 fi
1636
1637 if test "${system_malloc}" = "yes"; then
1638   GNU_MALLOC=no
1639   GNU_MALLOC_reason="
1640     (The GNU allocators don't work with this system configuration.)"
1641   GMALLOC_OBJ=
1642   VMLIMIT_OBJ=
1643 else
1644   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1645   VMLIMIT_OBJ=vm-limit.o
1646 fi
1647 AC_SUBST(GMALLOC_OBJ)
1648 AC_SUBST(VMLIMIT_OBJ)
1649
1650 if test "$doug_lea_malloc" = "yes" ; then
1651   if test "$GNU_MALLOC" = yes ; then
1652     GNU_MALLOC_reason="
1653       (Using Doug Lea's new malloc from the GNU C Library.)"
1654   fi
1655   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1656             [Define to 1 if you are using the GNU C Library.])
1657
1658   ## Use mmap directly for allocating larger buffers.
1659   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1660   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1661   ## Does the AC_FUNC_MMAP test below make this check unecessary?
1662   case "$opsys" in
1663     gnu*) REL_ALLOC=no ;;
1664   esac
1665 fi
1666
1667 if test x"${REL_ALLOC}" = x; then
1668   REL_ALLOC=${GNU_MALLOC}
1669 fi
1670
1671 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1672 dnl the system configuration file (s/*.h) to turn the use of mmap
1673 dnl in the relocating allocator on.
1674
1675 AC_FUNC_MMAP
1676 if test $use_mmap_for_buffers = yes; then
1677   REL_ALLOC=no
1678 fi
1679
1680 LIBS="$LIBS_SYSTEM $LIBS"
1681
1682 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1683 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1684 AC_CHECK_LIB(dnet, dnet_ntoa)
1685 dnl This causes -lresolv to get used in subsequent tests,
1686 dnl which causes failures on some systems such as HPUX 9.
1687 dnl AC_CHECK_LIB(resolv, gethostbyname)
1688
1689 dnl FIXME replace main with a function we actually want from this library.
1690 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1691
1692 AC_CHECK_LIB(pthreads, cma_open)
1693
1694 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1695 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1696 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1697 ## added to LIBS in configure would never contain the pthreads part,
1698 ## but the value used in Makefiles might.  FIXME?
1699 ##
1700 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1701 ## be harmless on older versions of X where it happens to exist.
1702 test "$opsys" = "aix4-2" && \
1703   test $ac_cv_lib_pthreads_cma_open = yes && \
1704   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1705
1706 dnl Check for need for bigtoc support on IBM AIX
1707
1708 case ${host_os} in
1709 aix*)
1710   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1711     case $GCC in
1712     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1713     *) gdb_cv_bigtoc=-bbigtoc ;;
1714     esac
1715
1716     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1717     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1718   ])
1719   ;;
1720 esac
1721
1722 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1723 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1724 # REAL_CPPFLAGS later on.
1725
1726 REAL_CPPFLAGS="$CPPFLAGS"
1727
1728 if test "${HAVE_X11}" = "yes"; then
1729   DEFS="$C_SWITCH_X_SITE $DEFS"
1730   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1731   LIBS="$LIBX $LIBS"
1732   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1733   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1734
1735   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1736   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1737   # but it's more convenient here to set LD_RUN_PATH
1738   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1739   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1740     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1741     export LD_RUN_PATH
1742   fi
1743
1744   if test "${opsys}" = "gnu-linux"; then
1745     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1746     AC_TRY_LINK([],
1747      [XOpenDisplay ("foo");],
1748      [xlinux_first_failure=no],
1749      [xlinux_first_failure=yes])
1750     if test "${xlinux_first_failure}" = "yes"; then
1751       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1752       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1753       OLD_CPPFLAGS="$CPPFLAGS"
1754       OLD_LIBS="$LIBS"
1755       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1756       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1757       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1758       LIBS="$LIBS -b i486-linuxaout"
1759       AC_TRY_LINK([],
1760        [XOpenDisplay ("foo");],
1761        [xlinux_second_failure=no],
1762        [xlinux_second_failure=yes])
1763       if test "${xlinux_second_failure}" = "yes"; then
1764         # If we get the same failure with -b, there is no use adding -b.
1765         # So take it out.  This plays safe.
1766         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1767         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1768         CPPFLAGS="$OLD_CPPFLAGS"
1769         LIBS="$OLD_LIBS"
1770         AC_MSG_RESULT(no)
1771       else
1772         AC_MSG_RESULT(yes)
1773       fi
1774     else
1775       AC_MSG_RESULT(no)
1776     fi
1777   fi
1778
1779   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1780   # header files included from there.
1781   AC_MSG_CHECKING(for Xkb)
1782   AC_TRY_LINK([#include <X11/Xlib.h>
1783 #include <X11/XKBlib.h>],
1784         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1785         emacs_xkb=yes, emacs_xkb=no)
1786   AC_MSG_RESULT($emacs_xkb)
1787   if test $emacs_xkb = yes; then
1788     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1789   fi
1790
1791   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1792 XScreenNumberOfScreen XSetWMProtocols)
1793 fi
1794
1795 if test "${window_system}" = "x11"; then
1796   AC_MSG_CHECKING(X11 version 6)
1797   AC_CACHE_VAL(emacs_cv_x11_version_6,
1798   [AC_TRY_LINK([#include <X11/Xlib.h>],
1799 [#if XlibSpecificationRelease < 6
1800 fail;
1801 #endif
1802 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1803   if test $emacs_cv_x11_version_6 = yes; then
1804     AC_MSG_RESULT(6 or newer)
1805     AC_DEFINE(HAVE_X11R6, 1,
1806               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1807   else
1808     AC_MSG_RESULT(before 6)
1809   fi
1810 fi
1811
1812
1813 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1814 HAVE_RSVG=no
1815 if test "${HAVE_X11}" = "yes" || test "${NS_IMPL_GNUSTEP}" = "yes"; then
1816   if test "${with_rsvg}" != "no"; then
1817     RSVG_REQUIRED=2.11.0
1818     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1819
1820     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, :, :)
1821     AC_SUBST(RSVG_CFLAGS)
1822     AC_SUBST(RSVG_LIBS)
1823
1824     if test ".${RSVG_CFLAGS}" != "."; then
1825       HAVE_RSVG=yes
1826       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1827       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1828       LIBS="$RSVG_LIBS $LIBS"
1829     fi
1830   fi
1831 fi
1832
1833
1834 HAVE_GTK=no
1835 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1836   GLIB_REQUIRED=2.6
1837   GTK_REQUIRED=2.6
1838   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1839
1840   dnl Checks for libraries.
1841   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1842   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1843      AC_MSG_ERROR($GTK_PKG_ERRORS)
1844   fi
1845 fi
1846
1847
1848 GTK_OBJ=
1849 if test x"$pkg_check_gtk" = xyes; then
1850
1851   AC_SUBST(GTK_CFLAGS)
1852   AC_SUBST(GTK_LIBS)
1853   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1854   CFLAGS="$CFLAGS $GTK_CFLAGS"
1855   LIBS="$GTK_LIBS $LIBS"
1856   dnl Try to compile a simple GTK program.
1857   GTK_COMPILES=no
1858   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1859   if test "${GTK_COMPILES}" != "yes"; then
1860     if test "$USE_X_TOOLKIT" != "maybe"; then
1861       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1862     fi
1863   else
1864     HAVE_GTK=yes
1865     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1866     GTK_OBJ=gtkutil.o
1867     USE_X_TOOLKIT=none
1868     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1869       :
1870     else
1871       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1872        closing open displays.  This is no problem if you just use
1873        one display, but if you use more than one and close one of them
1874        Emacs may crash.]])
1875       sleep 3
1876     fi
1877   fi
1878
1879 fi
1880 AC_SUBST(GTK_OBJ)
1881
1882
1883 if test "${HAVE_GTK}" = "yes"; then
1884
1885   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1886   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1887   if test "$with_toolkit_scroll_bars" != no; then
1888     with_toolkit_scroll_bars=yes
1889   fi
1890
1891   dnl  Check if we can use multiple displays with this GTK version.
1892   dnl  If gdk_display_open exists, assume all others are there also.
1893   HAVE_GTK_MULTIDISPLAY=no
1894   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1895   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1896     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1897               [Define to 1 if GTK can handle more than one display.])
1898   fi
1899
1900   dnl  Check if we have the old file selection dialog declared and
1901   dnl  in the link library.  In 2.x it may be in the library,
1902   dnl  but not declared if deprecated featured has been selected out.
1903   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1904   HAVE_GTK_FILE_SELECTION=no
1905   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1906                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1907 #include <gtk/gtk.h>])
1908   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1909     AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes,
1910                    HAVE_GTK_FILE_SELECTION=no)
1911   fi
1912
1913   dnl  Check if we have the new file chooser dialog
1914   HAVE_GTK_FILE_CHOOSER=no
1915   AC_CHECK_DECL(GTK_TYPE_FILE_CHOOSER, HAVE_GTK_FILE_CHOOSER=yes,
1916                 HAVE_GTK_FILE_CHOOSER=no, [AC_INCLUDES_DEFAULT
1917 #include <gtk/gtk.h>])
1918   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1919     AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes,
1920                    HAVE_GTK_FILE_CHOOSER=no)
1921   fi
1922
1923   if test "$HAVE_GTK_FILE_SELECTION" = yes \
1924      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
1925     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
1926               [Define to 1 if GTK has both file selection and chooser dialog.])
1927   fi
1928
1929   dnl Check if pthreads are available.  Emacs only needs this when using
1930   dnl gtk_file_chooser under Gnome.
1931   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
1932     HAVE_GTK_AND_PTHREAD=no
1933     AC_CHECK_HEADERS(pthread.h)
1934     if test "$ac_cv_header_pthread_h"; then
1935       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
1936     fi
1937     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
1938       case "${canonical}" in
1939         *-hpux*) ;;
1940         *) GTK_LIBS="$GTK_LIBS -lpthread" ;;
1941       esac
1942       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
1943                [Define to 1 if you have GTK and pthread (-lpthread).])
1944     fi
1945   fi
1946 fi
1947
1948 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1949 dnl other platforms.  Support for higher D-Bus versions than 1.0 is
1950 dnl also not configured.
1951 HAVE_DBUS=no
1952 DBUS_OBJ=
1953 if test "${with_dbus}" = "yes"; then
1954    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1955    if test "$HAVE_DBUS" = yes; then
1956      LIBS="$LIBS $DBUS_LIBS"
1957      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1958      AC_CHECK_FUNCS([dbus_watch_get_unix_fd])
1959      DBUS_OBJ=dbusbind.o
1960    fi
1961 fi
1962 AC_SUBST(DBUS_OBJ)
1963
1964 dnl GConf has been tested under GNU/Linux only.
1965 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1966 HAVE_GCONF=no
1967 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1968    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1969    if test "$HAVE_GCONF" = yes; then
1970       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1971    fi
1972 fi
1973
1974 dnl SELinux is available for GNU/Linux only.
1975 HAVE_LIBSELINUX=no
1976 LIBSELINUX_LIBS=
1977 if test "${with_selinux}" = "yes"; then
1978    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1979    if test "$HAVE_LIBSELINUX" = yes; then
1980       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1981       LIBSELINUX_LIBS=-lselinux
1982    fi
1983 fi
1984 AC_SUBST(LIBSELINUX_LIBS)
1985
1986 dnl Do not put whitespace before the #include statements below.
1987 dnl Older compilers (eg sunos4 cc) choke on it.
1988 HAVE_XAW3D=no
1989 LUCID_LIBW=
1990 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
1991   if test "$with_xaw3d" != no; then
1992     AC_MSG_CHECKING(for xaw3d)
1993     AC_CACHE_VAL(emacs_cv_xaw3d,
1994     [AC_TRY_LINK([
1995 #include <X11/Intrinsic.h>
1996 #include <X11/Xaw3d/Simple.h>],
1997       [],
1998       emacs_cv_xaw3d=yes,
1999       emacs_cv_xaw3d=no)])
2000   else
2001     emacs_cv_xaw3d=no
2002   fi
2003   if test $emacs_cv_xaw3d = yes; then
2004     AC_MSG_RESULT([yes; using Lucid toolkit])
2005     USE_X_TOOLKIT=LUCID
2006     HAVE_XAW3D=yes
2007     LUCID_LIBW=-lXaw3d
2008     AC_DEFINE(HAVE_XAW3D, 1,
2009               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2010   else
2011     AC_MSG_RESULT(no)
2012     AC_MSG_CHECKING(for libXaw)
2013     AC_CACHE_VAL(emacs_cv_xaw,
2014     [AC_TRY_LINK([
2015 #include <X11/Intrinsic.h>
2016 #include <X11/Xaw/Simple.h>],
2017       [],
2018       emacs_cv_xaw=yes,
2019       emacs_cv_xaw=no)])
2020     if test $emacs_cv_xaw = yes; then
2021       AC_MSG_RESULT([yes; using Lucid toolkit])
2022       USE_X_TOOLKIT=LUCID
2023       LUCID_LIBW=-lXaw
2024     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2025       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2026     else
2027       AC_MSG_RESULT([no; do not use toolkit by default])
2028       USE_X_TOOLKIT=none
2029     fi
2030   fi
2031 fi
2032
2033 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2034
2035 LIBXTR6=
2036 if test "${USE_X_TOOLKIT}" != "none"; then
2037   AC_MSG_CHECKING(X11 toolkit version)
2038   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2039   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2040 [#if XtSpecificationRelease < 6
2041 fail;
2042 #endif
2043 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2044   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2045   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2046     AC_MSG_RESULT(6 or newer)
2047     AC_DEFINE(HAVE_X11XTR6, 1,
2048               [Define to 1 if you have the X11R6 or newer version of Xt.])
2049     LIBXTR6="-lSM -lICE"
2050     case "$opsys" in
2051       ## Use libw.a along with X11R6 Xt.
2052       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2053     esac
2054   else
2055     AC_MSG_RESULT(before 6)
2056   fi
2057
2058 dnl If using toolkit, check whether libXmu.a exists.
2059 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2060   OLDLIBS="$LIBS"
2061   if test x$HAVE_X11XTR6 = xyes; then
2062     LIBS="-lXt -lSM -lICE $LIBS"
2063   else
2064     LIBS="-lXt $LIBS"
2065   fi
2066   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2067   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2068 fi
2069 AC_SUBST(LIBXTR6)
2070
2071 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2072 dnl Why not just test for libxmu in the normal way?
2073 LIBXMU=-lXmu
2074 case "$machine" in
2075   ## These machines don't supply Xmu.
2076   hpux* | aix4-2 )
2077     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2078     ;;
2079 esac
2080 AC_SUBST(LIBXMU)
2081
2082 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2083 if test "${HAVE_X11}" = "yes"; then
2084   if test "${USE_X_TOOLKIT}" != "none"; then
2085     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2086   fi
2087 fi
2088
2089 LIBXP=
2090 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2091   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2092   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2093     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2094 int x = 5;
2095 #else
2096 Motif version prior to 2.1.
2097 #endif],
2098     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2099   if test $emacs_cv_motif_version_2_1 = yes; then
2100     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2101   else
2102     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2103     # We put this in CFLAGS temporarily to precede other -I options
2104     # that might be in CFLAGS temporarily.
2105     # We put this in CPPFLAGS where it precedes the other -I options.
2106     OLD_CPPFLAGS=$CPPFLAGS
2107     OLD_CFLAGS=$CFLAGS
2108     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2109     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2110     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2111       [int x = 5;],
2112       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2113     if test $emacs_cv_lesstif = yes; then
2114       # Make sure this -I option remains in CPPFLAGS after it is set
2115       # back to REAL_CPPFLAGS.
2116       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2117       # have those other -I options anyway.  Ultimately, having this
2118       # directory ultimately in CPPFLAGS will be enough.
2119       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2120       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2121     else
2122       CFLAGS=$OLD_CFLAGS
2123       CPPFLAGS=$OLD_CPPFLAGS
2124     fi
2125   fi
2126 fi
2127
2128 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2129 dnl using Motif or Xaw3d is available, and unless
2130 dnl --with-toolkit-scroll-bars=no was specified.
2131
2132 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2133             [Define to 1 if we should use toolkit scroll bars.])dnl
2134 USE_TOOLKIT_SCROLL_BARS=no
2135 if test "${with_toolkit_scroll_bars}" != "no"; then
2136   if test "${USE_X_TOOLKIT}" != "none"; then
2137     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2138       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2139       HAVE_XAW3D=no
2140       USE_TOOLKIT_SCROLL_BARS=yes
2141     elif test "${HAVE_XAW3D}" = "yes"; then
2142       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2143       USE_TOOLKIT_SCROLL_BARS=yes
2144     fi
2145   elif test "${HAVE_GTK}" = "yes"; then
2146     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2147     USE_TOOLKIT_SCROLL_BARS=yes
2148   elif test "${HAVE_NS}" = "yes"; then
2149     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2150     USE_TOOLKIT_SCROLL_BARS=yes
2151   fi
2152 fi
2153
2154 dnl See if XIM is available.
2155 AC_TRY_COMPILE([
2156           #include <X11/Xlib.h>
2157           #include <X11/Xresource.h>],
2158          [XIMProc  callback;],
2159          [HAVE_XIM=yes
2160          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2161          HAVE_XIM=no)
2162
2163 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2164
2165 if test "${with_xim}" != "no"; then
2166   AC_DEFINE(USE_XIM, 1,
2167             [Define to 1 if we should use XIM, if it is available.])
2168 fi
2169
2170
2171 if test "${HAVE_XIM}" != "no"; then
2172   late_CFLAGS=$CFLAGS
2173   if test "$GCC" = yes; then
2174     CFLAGS="$CFLAGS --pedantic-errors"
2175   fi
2176   AC_TRY_COMPILE([
2177 #include <X11/Xlib.h>
2178 #include <X11/Xresource.h>],
2179 [Display *display;
2180 XrmDatabase db;
2181 char *res_name;
2182 char *res_class;
2183 XIMProc  callback;
2184 XPointer *client_data;
2185 #ifndef __GNUC__
2186 /* If we're not using GCC, it's probably not XFree86, and this is
2187    probably right, but we can't use something like --pedantic-errors.  */
2188 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2189                                            char*, XIMProc, XPointer*);
2190 #endif
2191 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2192    client_data);],
2193     [emacs_cv_arg6_star=yes])
2194   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2195          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2196 either XPointer or XPointer*.])dnl
2197   if test "$emacs_cv_arg6_star" = yes; then
2198     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2199   else
2200     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2201   fi
2202   CFLAGS=$late_CFLAGS
2203 fi
2204
2205 ### Start of font-backend (under any platform) section.
2206 # (nothing here yet -- this is a placeholder)
2207 ### End of font-backend (under any platform) section.
2208
2209 ### Start of font-backend (under X11) section.
2210 if test "${HAVE_X11}" = "yes"; then
2211    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2212
2213    ## Use -lXft if available, unless `--with-xft=no'.
2214    HAVE_XFT=maybe
2215     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2216       with_xft="no";
2217     fi
2218     if test "x${with_xft}" != "xno"; then
2219
2220       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2221       ## Because xftfont.c uses XRenderQueryExtension, we also
2222       ## need to link to -lXrender.
2223       HAVE_XRENDER=no
2224       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2225       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2226         OLD_CPPFLAGS="$CPPFLAGS"
2227         OLD_CFLAGS="$CFLAGS"
2228         OLD_LIBS="$LIBS"
2229         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2230         CFLAGS="$CFLAGS $XFT_CFLAGS"
2231         XFT_LIBS="-lXrender $XFT_LIBS"
2232         LIBS="$XFT_LIBS $LIBS"
2233         AC_CHECK_HEADER(X11/Xft/Xft.h,
2234           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2235
2236         if test "${HAVE_XFT}" = "yes"; then
2237           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2238             AC_SUBST(XFT_LIBS)
2239           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2240         else
2241           CPPFLAGS="$OLD_CPPFLAGS"
2242           CFLAGS="$OLD_CFLAGS"
2243           LIBS="$OLD_LIBS"
2244         fi                        # "${HAVE_XFT}" = "yes"
2245       fi                          # "$HAVE_XFT" != no
2246     fi                            # "x${with_xft}" != "xno"
2247
2248     dnl For the "Does Emacs use" message at the end.
2249     if test "$HAVE_XFT" != "yes"; then
2250        HAVE_XFT=no
2251     fi
2252
2253
2254     HAVE_FREETYPE=no
2255     ## We used to allow building with FreeType and without Xft.
2256     ## However, the ftx font backend driver is not in good shape.
2257     if test "${HAVE_XFT}" = "yes"; then
2258       dnl As we use Xft, we anyway use freetype.
2259       dnl There's no need for additional CFLAGS and LIBS.
2260       HAVE_FREETYPE=yes
2261       FONTCONFIG_CFLAGS=
2262       FONTCONFIG_LIBS=
2263     fi
2264
2265     HAVE_LIBOTF=no
2266     if test "${HAVE_FREETYPE}" = "yes"; then
2267       AC_DEFINE(HAVE_FREETYPE, 1,
2268                 [Define to 1 if using the freetype and fontconfig libraries.])
2269       if test "${with_libotf}" != "no"; then
2270         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2271                           HAVE_LIBOTF=no)
2272         if test "$HAVE_LIBOTF" = "yes"; then
2273           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2274           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2275                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2276                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2277           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2278             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2279                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2280           fi
2281         fi
2282       fi
2283     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2284     dnl Does the new font backend require it, or can it work without it?
2285     fi
2286
2287     HAVE_M17N_FLT=no
2288     if test "${HAVE_LIBOTF}" = yes; then
2289       if test "${with_m17n_flt}" != "no"; then
2290         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2291         if test "$HAVE_M17N_FLT" = "yes"; then
2292           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2293         fi
2294       fi
2295     fi
2296 else
2297     HAVE_XFT=no
2298     HAVE_FREETYPE=no
2299     HAVE_LIBOTF=no
2300     HAVE_M17N_FLT=no
2301 fi
2302
2303 ### End of font-backend (under X11) section.
2304
2305 AC_SUBST(FREETYPE_CFLAGS)
2306 AC_SUBST(FREETYPE_LIBS)
2307 AC_SUBST(FONTCONFIG_CFLAGS)
2308 AC_SUBST(FONTCONFIG_LIBS)
2309 AC_SUBST(LIBOTF_CFLAGS)
2310 AC_SUBST(LIBOTF_LIBS)
2311 AC_SUBST(M17N_FLT_CFLAGS)
2312 AC_SUBST(M17N_FLT_LIBS)
2313
2314 ### Use -lXpm if available, unless `--with-xpm=no'.
2315 HAVE_XPM=no
2316 LIBXPM=
2317 if test "${HAVE_X11}" = "yes"; then
2318   if test "${with_xpm}" != "no"; then
2319     AC_CHECK_HEADER(X11/xpm.h,
2320       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2321     if test "${HAVE_XPM}" = "yes"; then
2322       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2323       AC_EGREP_CPP(no_return_alloc_pixels,
2324       [#include "X11/xpm.h"
2325 #ifndef XpmReturnAllocPixels
2326 no_return_alloc_pixels
2327 #endif
2328       ], HAVE_XPM=no, HAVE_XPM=yes)
2329
2330       if test "${HAVE_XPM}" = "yes"; then
2331         AC_MSG_RESULT(yes)
2332       else
2333         AC_MSG_RESULT(no)
2334       fi
2335     fi
2336   fi
2337
2338   if test "${HAVE_XPM}" = "yes"; then
2339     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2340     LIBXPM=-lXpm
2341   fi
2342 fi
2343 AC_SUBST(LIBXPM)
2344
2345 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2346 HAVE_JPEG=no
2347 LIBJPEG=
2348 if test "${HAVE_X11}" = "yes"; then
2349   if test "${with_jpeg}" != "no"; then
2350     dnl Checking for jpeglib.h can lose because of a redefinition of
2351     dnl  HAVE_STDLIB_H.
2352     AC_CHECK_HEADER(jerror.h,
2353       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2354   fi
2355
2356   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2357   if test "${HAVE_JPEG}" = "yes"; then
2358     AC_DEFINE(HAVE_JPEG)
2359     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2360         [#include <jpeglib.h>
2361          version=JPEG_LIB_VERSION
2362 ],
2363         [AC_DEFINE(HAVE_JPEG)],
2364         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2365         HAVE_JPEG=no])
2366   fi
2367   if test "${HAVE_JPEG}" = "yes"; then
2368     LIBJPEG=-ljpeg
2369   fi
2370 fi
2371 AC_SUBST(LIBJPEG)
2372
2373 ### Use -lpng if available, unless `--with-png=no'.
2374 HAVE_PNG=no
2375 LIBPNG=
2376 if test "${HAVE_X11}" = "yes"; then
2377   if test "${with_png}" != "no"; then
2378     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2379     # in /usr/include/libpng.
2380     AC_CHECK_HEADERS(png.h libpng/png.h)
2381     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2382       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2383     fi
2384   fi
2385
2386   if test "${HAVE_PNG}" = "yes"; then
2387     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2388     LIBPNG="-lpng -lz -lm"
2389   fi
2390 fi
2391 AC_SUBST(LIBPNG)
2392
2393 ### Use -ltiff if available, unless `--with-tiff=no'.
2394 HAVE_TIFF=no
2395 LIBTIFF=
2396 if test "${HAVE_X11}" = "yes"; then
2397   if test "${with_tiff}" != "no"; then
2398     AC_CHECK_HEADER(tiffio.h,
2399       [tifflibs="-lz -lm"
2400       # At least one tiff package requires the jpeg library.
2401       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2402       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2403   fi
2404
2405   if test "${HAVE_TIFF}" = "yes"; then
2406     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2407     dnl FIXME -lz -lm, as per libpng?
2408     LIBTIFF=-ltiff
2409   fi
2410 fi
2411 AC_SUBST(LIBTIFF)
2412
2413 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2414 HAVE_GIF=no
2415 LIBGIF=
2416 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2417   AC_CHECK_HEADER(gif_lib.h,
2418 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2419 # Earlier versions can crash Emacs.
2420     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2421
2422   if test "$HAVE_GIF" = yes; then
2423     LIBGIF=-lgif
2424   elif test "$HAVE_GIF" = maybe; then
2425 # If gif_lib.h but no libgif, try libungif.
2426     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2427     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2428   fi
2429
2430   if test "${HAVE_GIF}" = "yes"; then
2431     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2432   fi
2433 fi
2434 AC_SUBST(LIBGIF)
2435
2436 dnl Check for required libraries.
2437 if test "${HAVE_X11}" = "yes"; then
2438   MISSING=""
2439   WITH_NO=""
2440   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2441     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2442   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2443     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2444   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2445     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2446   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2447     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2448   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2449     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2450
2451   if test "X${MISSING}" != X; then
2452     AC_MSG_ERROR([The following required libraries were not found:
2453     $MISSING
2454 Maybe some development libraries/packages are missing?
2455 If you don't want to link with them give
2456     $WITH_NO
2457 as options to configure])
2458   fi
2459 fi
2460
2461 ### Use -lgpm if available, unless `--with-gpm=no'.
2462 HAVE_GPM=no
2463 LIBGPM=
2464 MOUSE_SUPPORT=
2465 if test "${with_gpm}" != "no"; then
2466   AC_CHECK_HEADER(gpm.h,
2467     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2468
2469   if test "${HAVE_GPM}" = "yes"; then
2470     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2471     LIBGPM=-lgpm
2472     ## May be reset below.
2473     MOUSE_SUPPORT="\$(GPM_MOUSE_SUPPORT)"
2474   fi
2475 fi
2476 AC_SUBST(LIBGPM)
2477
2478 dnl Check for malloc/malloc.h on darwin
2479 AC_CHECK_HEADER(malloc/malloc.h, [AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.])])
2480
2481 C_SWITCH_X_SYSTEM=
2482 ### Use NeXTstep API to implement GUI.
2483 if test "${HAVE_NS}" = "yes"; then
2484   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2485   if test "${NS_IMPL_COCOA}" = "yes"; then
2486     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2487     GNU_OBJC_CFLAGS=
2488   fi
2489   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2490     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2491     # See also .m.o rule in Makefile.in */
2492     # FIXME: are all these flags really needed?  Document here why.  */
2493     C_SWITCH_X_SYSTEM="-D_REENTRANT -fPIC -fno-strict-aliasing"
2494     GNU_OBJC_CFLAGS="-fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2495   fi
2496   if test "${NS_HAVE_NSINTEGER}" = "yes"; then
2497     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
2498   fi
2499   # We also have mouse menus.
2500   HAVE_MENUS=yes
2501   OTHER_FILES=ns-app
2502 fi
2503
2504
2505 ### Use session management (-lSM -lICE) if available
2506 HAVE_X_SM=no
2507 LIBXSM=
2508 if test "${HAVE_X11}" = "yes"; then
2509   AC_CHECK_HEADER(X11/SM/SMlib.h,
2510     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2511
2512   if test "${HAVE_X_SM}" = "yes"; then
2513     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2514     LIBXSM="-lSM -lICE"
2515     case "$LIBS" in
2516       *-lSM*) ;;
2517       *)      LIBS="$LIBXSM $LIBS" ;;
2518     esac
2519   fi
2520 fi
2521 AC_SUBST(LIBXSM)
2522
2523 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2524 AC_CACHE_CHECK(whether netdb declares h_errno,
2525                emacs_cv_netdb_declares_h_errno,
2526 [AC_TRY_LINK([#include <netdb.h>],
2527   [return h_errno;],
2528   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2529 if test $emacs_cv_netdb_declares_h_errno = yes; then
2530   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2531 fi
2532
2533 AC_FUNC_ALLOCA
2534
2535 dnl src/alloca.c has been removed.  Could also check if $ALLOCA is set?
2536 dnl FIXME is there an autoconf test that does the right thing, without
2537 dnl needing to call A_M_E afterwards?
2538 if test x"$ac_cv_func_alloca_works" != xyes; then
2539    AC_MSG_ERROR( [a system implementation of alloca is required] )
2540 fi
2541
2542 # fmod, logb, and frexp are found in -lm on most systems.
2543 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2544 AC_CHECK_LIB(m, sqrt)
2545
2546 # Check for mail-locking functions in a "mail" library.  Probably this should
2547 # have the same check as for liblockfile below.
2548 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2549 if test $have_mail = yes; then
2550   LIBS_MAIL=-lmail
2551   LIBS="$LIBS_MAIL $LIBS"
2552   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2553 else
2554   LIBS_MAIL=
2555 fi
2556 dnl Debian, at least:
2557 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2558 if test $have_lockfile = yes; then
2559    LIBS_MAIL=-llockfile
2560    LIBS="$LIBS_MAIL $LIBS"
2561    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2562 else
2563 # If we have the shared liblockfile, assume we must use it for mail
2564 # locking (e.g. Debian).  If we couldn't link against liblockfile
2565 # (no liblockfile.a installed), ensure that we don't need to.
2566   dnl This works for files generally, not just executables.
2567   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2568   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2569                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2570   if test $ac_cv_prog_liblockfile = yes; then
2571     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2572 This probably means that movemail could lose mail.
2573 There may be a `development' package to install containing liblockfile.])
2574   fi
2575 fi
2576 AC_CHECK_FUNCS(touchlock)
2577 AC_CHECK_HEADERS(maillock.h)
2578 AC_SUBST(LIBS_MAIL)
2579
2580 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2581 ## interlock access to the mail spool.  The alternative is a lock file named
2582 ## /usr/spool/mail/$USER.lock.
2583 mail_lock=no
2584 case "$opsys" in
2585   aix4-2) mail_lock="lockf" ;;
2586
2587   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2588
2589   ## On GNU/Linux systems, both methods are used by various mail programs.
2590   ## I assume most people are using newer mailers that have heard of flock.
2591   ## Change this if you need to.
2592   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2593   ## configure gets the right answers, and that means *NOT* using flock.
2594   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2595   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2596   ## Debian maintainer hasn't provided a clean fix for Emacs.
2597   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2598   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2599   ## correct logic.  -- fx
2600   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2601   ## liblockfile is a Free Software replacement for libmail, used on
2602   ## Debian systems and elsewhere. -rfr.
2603   gnu-*)
2604     mail_lock="flock"
2605     if test $have_mail = yes || test $have_lockfile = yes; then
2606       test $ac_cv_header_maillock_h = yes && mail_lock=no
2607     fi
2608     ;;
2609 esac
2610
2611 BLESSMAIL_TARGET=
2612 case "$mail_lock" in
2613   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2614
2615   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2616
2617   *) BLESSMAIL_TARGET="need-blessmail" ;;
2618 esac
2619 AC_SUBST(BLESSMAIL_TARGET)
2620
2621
2622 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2623 rename closedir mkdir rmdir sysinfo getrusage get_current_dir_name \
2624 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime setsid \
2625 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2626 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2627 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2628 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2629 gai_strerror mkstemp getline getdelim mremap memmove fsync sync bzero \
2630 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign \
2631 cfmakeraw cfsetspeed isnan copysign)
2632
2633 AC_CHECK_HEADERS(sys/un.h)
2634
2635 AC_FUNC_MKTIME
2636 if test "$ac_cv_func_working_mktime" = no; then
2637   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2638 fi
2639
2640 AC_FUNC_GETLOADAVG
2641
2642 AC_FUNC_FSEEKO
2643
2644 # Configure getopt.
2645 m4_include([m4/getopt.m4])
2646 gl_GETOPT_IFELSE([
2647   gl_GETOPT_SUBSTITUTE_HEADER
2648   gl_PREREQ_GETOPT
2649   GETOPTOBJS='getopt.o getopt1.o'
2650 ])
2651 AC_SUBST(GETOPTOBJS)
2652
2653 AC_FUNC_GETPGRP
2654
2655 AC_FUNC_STRFTIME
2656
2657 # UNIX98 PTYs.
2658 AC_CHECK_FUNCS(grantpt)
2659
2660 # PTY-related GNU extensions.
2661 AC_CHECK_FUNCS(getpt)
2662
2663 # Check this now, so that we will NOT find the above functions in ncurses.
2664 # That is because we have not set up to link ncurses in lib-src.
2665 # It's better to believe a function is not available
2666 # than to expect to find it in ncurses.
2667 # Also we need tputs and friends to be able to build at all.
2668 have_tputs_et_al=true
2669 AC_SEARCH_LIBS(tputs, [ncurses terminfo termcap], , have_tputs_et_al=false)
2670 if test "$have_tputs_et_al" != true; then
2671   AC_MSG_ERROR([I couldn't find termcap functions (tputs and friends).
2672 Maybe some development libraries/packages are missing?  Try installing
2673 libncurses-dev(el), libterminfo-dev(el) or similar.])
2674 fi
2675 # Must define this when any termcap library is found.
2676 AC_DEFINE(HAVE_LIBNCURSES, 1,
2677           [Define to 1 if you have the `ncurses' library (-lncurses).])
2678 ## FIXME This was the cpp logic, but I am not sure it is right.
2679 ## The above test has not necessarily found libncurses.
2680 HAVE_LIBNCURSES=yes
2681
2682 ## Use terminfo instead of termcap?
2683 ## Note only system files NOT using terminfo are:
2684 ## freebsd < 40000, ms-w32, msdos, netbsd < 599002500, and
2685 ## darwin|gnu without ncurses.
2686 TERMINFO=no
2687 LIBS_TERMCAP=
2688 case "$opsys" in
2689   ## cygwin: Fewer environment variables to go wrong, more terminal types.
2690   ## hpux10-20: Use the system provided termcap(3) library.
2691   ## openbsd: David Mazieres <dm@reeducation-labor.lcs.mit.edu> says this
2692   ##  is necessary.  Otherwise Emacs dumps core when run -nw.
2693   aix4-2|cygwin|hpux*|irix6-5|openbsd|sol2*|unixware) TERMINFO=yes ;;
2694
2695   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2696   ##  The ncurses library has been moved out of the System framework in
2697   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2698   ##  option to use it.
2699   darwin|gnu*)
2700     ## (HAVE_LIBNCURSES was not always true, but is since 2010-03-18.)
2701     if test "x$HAVE_LIBNCURSES" = "xyes"; then
2702       TERMINFO=yes
2703       LIBS_TERMCAP="-lncurses"
2704     fi
2705     ;;
2706
2707   freebsd)
2708     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2709     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2710     [AC_TRY_LINK([#include <osreldate.h>],
2711 [#if __FreeBSD_version < 400000
2712 fail;
2713 #endif
2714 ], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2715
2716     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2717
2718     if test $emacs_cv_freebsd_terminfo = yes; then
2719       TERMINFO=yes
2720       LIBS_TERMCAP="-lncurses"
2721     else
2722       LIBS_TERMCAP="-ltermcap"
2723     fi
2724     ;;
2725
2726   netbsd)
2727     if test $ac_cv_search_tputs = -lterminfo; then
2728       TERMINFO=yes
2729       LIBS_TERMCAP="-lterminfo"
2730     else
2731       LIBS_TERMCAP="-ltermcap"
2732     fi
2733     ;;
2734
2735 esac
2736
2737 case "$opsys" in
2738   ## hpux: Make sure we get select from libc rather than from libcurses
2739   ##  because libcurses on HPUX 10.10 has a broken version of select.
2740   ##  We used to use -lc -lcurses, but this may be cleaner.
2741   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2742
2743   openbsd) LIBS_TERMCAP="-lncurses" ;;
2744
2745   ## Must use system termcap, if we use any termcap.  It does special things.
2746   sol2*) test "$TERMINFO" != yes && LIBS_TERMCAP="-ltermcap" ;;
2747 esac
2748
2749 TERMCAP_OBJ=tparam.o
2750 if test $TERMINFO = yes; then
2751   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2752
2753   ## Default used to be -ltermcap.  Add a case above if need something else.
2754   test "x$LIBS_TERMCAP" = "x" && LIBS_TERMCAP="-lcurses"
2755
2756   TERMCAP_OBJ=terminfo.o
2757 fi
2758 AC_SUBST(LIBS_TERMCAP)
2759 AC_SUBST(TERMCAP_OBJ)
2760
2761
2762 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2763 resolv=no
2764 AC_TRY_LINK([#include <netinet/in.h>
2765 #include <arpa/nameser.h>
2766 #include <resolv.h>],
2767     [return res_init();],
2768     have_res_init=yes, have_res_init=no)
2769 if test "$have_res_init" = no; then
2770   OLIBS="$LIBS"
2771   LIBS="$LIBS -lresolv"
2772   AC_MSG_CHECKING(for res_init with -lresolv)
2773   AC_TRY_LINK([#include <netinet/in.h>
2774 #include <arpa/nameser.h>
2775 #include <resolv.h>],
2776     [return res_init();],
2777     have_res_init=yes, have_res_init=no)
2778   AC_MSG_RESULT($have_res_init)
2779   if test "$have_res_init" = yes ; then
2780     resolv=yes
2781   fi
2782   LIBS="$OLIBS"
2783 fi
2784
2785 if test "$have_res_init" = yes; then
2786   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2787 fi
2788
2789 # Do we need the Hesiod library to provide the support routines?
2790 LIBHESIOD=
2791 if test "$with_hesiod" != no ; then
2792   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2793   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2794      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2795                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2796   if test "$resolv" = yes ; then
2797     RESOLVLIB=-lresolv
2798   else
2799     RESOLVLIB=
2800   fi
2801   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2802         hesiod=yes, :, $RESOLVLIB)])
2803
2804   if test x"$hesiod" = xyes; then
2805     AC_DEFINE(HAVE_LIBHESIOD, 1,
2806               [Define to 1 if you have the hesiod library (-lhesiod).])
2807     LIBHESIOD=-lhesiod
2808   fi
2809 fi
2810 AC_SUBST(LIBHESIOD)
2811
2812 # Do we need libresolv (due to res_init or Hesiod)?
2813 if test "$resolv" = yes ; then
2814   AC_DEFINE(HAVE_LIBRESOLV, 1,
2815             [Define to 1 if you have the resolv library (-lresolv).])
2816   LIBRESOLV=-lresolv
2817 else
2818   LIBRESOLV=
2819 fi
2820 AC_SUBST(LIBRESOLV)
2821
2822 # These tell us which Kerberos-related libraries to use.
2823 COM_ERRLIB=
2824 CRYPTOLIB=
2825 KRB5LIB=
2826 DESLIB=
2827 KRB4LIB=
2828
2829 if test "${with_kerberos}" != no; then
2830   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2831   if test $have_com_err = yes; then
2832     COM_ERRLIB=-lcom_err
2833     LIBS="$COM_ERRLIB $LIBS"
2834     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2835   fi
2836   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2837   if test $have_crypto = yes; then
2838     CRYPTOLIB=-lcrypto
2839     LIBS="$CRYPTOLIB $LIBS"
2840     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2841   fi
2842   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2843   if test $have_k5crypto = yes; then
2844     CRYPTOLIB=-lk5crypto
2845     LIBS="$CRYPTOLIB $LIBS"
2846     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2847   fi
2848   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2849   if test $have_krb5=yes; then
2850     KRB5LIB=-lkrb5
2851     LIBS="$KRB5LIB $LIBS"
2852     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2853   fi
2854   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2855   if test "${with_kerberos5}" = no; then
2856     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2857     if test $have_des425 = yes; then
2858       DESLIB=-ldes425
2859       LIBS="$DESLIB $LIBS"
2860       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2861     else
2862       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2863       if test $have_des = yes; then
2864         DESLIB=-ldes
2865         LIBS="$DESLIB $LIBS"
2866         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2867       fi
2868     fi
2869     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2870     if test $have_krb4 = yes; then
2871       KRB4LIB=-lkrb4
2872       LIBS="$KRB4LIB $LIBS"
2873       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2874     else
2875       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2876       if test $have_krb = yes; then
2877         KRB4LIB=-lkrb
2878         LIBS="$KRB4LIB $LIBS"
2879         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2880       fi
2881     fi
2882   fi
2883
2884   if test "${with_kerberos5}" != no; then
2885     AC_CHECK_HEADERS(krb5.h,
2886       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2887                         [#include <krb5.h>])])
2888   else
2889     AC_CHECK_HEADERS(des.h,,
2890                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2891                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2892     AC_CHECK_HEADERS(krb.h,,
2893                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2894                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2895   fi
2896   AC_CHECK_HEADERS(com_err.h)
2897 fi
2898
2899 AC_SUBST(COM_ERRLIB)
2900 AC_SUBST(CRYPTOLIB)
2901 AC_SUBST(KRB5LIB)
2902 AC_SUBST(DESLIB)
2903 AC_SUBST(KRB4LIB)
2904
2905 # Solaris requires -lintl if you want strerror (which calls dgettext)
2906 # to return localized messages.
2907 AC_CHECK_LIB(intl, dgettext)
2908
2909 AC_MSG_CHECKING(whether localtime caches TZ)
2910 AC_CACHE_VAL(emacs_cv_localtime_cache,
2911 [if test x$ac_cv_func_tzset = xyes; then
2912 AC_TRY_RUN([#include <time.h>
2913 extern char **environ;
2914 unset_TZ ()
2915 {
2916   char **from, **to;
2917   for (to = from = environ; (*to = *from); from++)
2918     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2919       to++;
2920 }
2921 char TZ_GMT0[] = "TZ=GMT0";
2922 char TZ_PST8[] = "TZ=PST8";
2923 main()
2924 {
2925   time_t now = time ((time_t *) 0);
2926   int hour_GMT0, hour_unset;
2927   if (putenv (TZ_GMT0) != 0)
2928     exit (1);
2929   hour_GMT0 = localtime (&now)->tm_hour;
2930   unset_TZ ();
2931   hour_unset = localtime (&now)->tm_hour;
2932   if (putenv (TZ_PST8) != 0)
2933     exit (1);
2934   if (localtime (&now)->tm_hour == hour_GMT0)
2935     exit (1);
2936   unset_TZ ();
2937   if (localtime (&now)->tm_hour != hour_unset)
2938     exit (1);
2939   exit (0);
2940 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2941 [# If we have tzset, assume the worst when cross-compiling.
2942 emacs_cv_localtime_cache=yes])
2943 else
2944         # If we lack tzset, report that localtime does not cache TZ,
2945         # since we can't invalidate the cache if we don't have tzset.
2946         emacs_cv_localtime_cache=no
2947 fi])dnl
2948 AC_MSG_RESULT($emacs_cv_localtime_cache)
2949 if test $emacs_cv_localtime_cache = yes; then
2950   AC_DEFINE(LOCALTIME_CACHE, 1,
2951             [Define to 1 if localtime caches TZ.])
2952 fi
2953
2954 if test "x$HAVE_TIMEVAL" = xyes; then
2955   AC_CHECK_FUNCS(gettimeofday)
2956   if test $ac_cv_func_gettimeofday = yes; then
2957     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2958                    emacs_cv_gettimeofday_two_arguments,
2959     [AC_TRY_COMPILE([
2960 #ifdef TIME_WITH_SYS_TIME
2961 #include <sys/time.h>
2962 #include <time.h>
2963 #else
2964 #ifdef HAVE_SYS_TIME_H
2965 #include <sys/time.h>
2966 #else
2967 #include <time.h>
2968 #endif
2969 #endif],
2970       [struct timeval time;
2971        gettimeofday (&time, 0);],
2972       emacs_cv_gettimeofday_two_arguments=yes,
2973       emacs_cv_gettimeofday_two_arguments=no)])
2974     if test $emacs_cv_gettimeofday_two_arguments = no; then
2975       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2976                 [Define to 1 if gettimeofday accepts only one argument.])
2977     fi
2978   fi
2979 fi
2980
2981 ok_so_far=yes
2982 AC_CHECK_FUNC(socket, , ok_so_far=no)
2983 if test $ok_so_far = yes; then
2984   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2985 fi
2986 if test $ok_so_far = yes; then
2987   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2988 fi
2989 if test $ok_so_far = yes; then
2990 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2991   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2992             [Define to 1 if you have inet sockets.])
2993 fi
2994
2995 AC_CHECK_HEADERS(sys/ioctl.h)
2996
2997 if test -f /usr/lpp/X11/bin/smt.exp; then
2998   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2999             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3000 fi
3001
3002 AC_MSG_CHECKING(whether system supports dynamic ptys)
3003 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3004   AC_MSG_RESULT(yes)
3005   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3006 else
3007   AC_MSG_RESULT(no)
3008 fi
3009
3010 AC_FUNC_FORK
3011
3012 dnl Adapted from Haible's version.
3013 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3014   [AC_TRY_LINK([#include <langinfo.h>],
3015     [char* cs = nl_langinfo(CODESET);],
3016     emacs_cv_langinfo_codeset=yes,
3017     emacs_cv_langinfo_codeset=no)
3018   ])
3019 if test $emacs_cv_langinfo_codeset = yes; then
3020   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3021     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3022 fi
3023
3024 AC_CHECK_TYPES(size_t)
3025
3026 AC_TYPE_MBSTATE_T
3027
3028 dnl Restrict could probably be used effectively other than in regex.c.
3029 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
3030   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
3031                   emacs_cv_c_restrict=yes,
3032                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
3033                                   emacs_cv_c_restrict=__restrict,
3034                                   emacs_cv_c_restrict=no)])])
3035 case "$emacs_cv_c_restrict" in
3036   yes) emacs_restrict=restrict;;
3037   no) emacs_restrict="";;
3038   *) emacs_restrict="$emacs_cv_c_restrict";;
3039 esac
3040 if test "$emacs_restrict" != __restrict; then
3041   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
3042     [Define to compiler's equivalent of C99 restrict keyword.
3043      Don't define if equivalent is `__restrict'.])
3044 fi
3045
3046 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3047   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
3048                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3049 if test "$emacs_cv_c_restrict_arr" = yes; then
3050   AC_DEFINE(__restrict_arr, __restrict,
3051     [Define to compiler's equivalent of C99 restrict keyword in array
3052      declarations.  Define as empty for no equivalent.])
3053 fi
3054
3055 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3056 dnl how the tty code is related to POSIX and/or other versions of termios.
3057 dnl The following looks like a useful start.
3058 dnl
3059 dnl AC_SYS_POSIX_TERMIOS
3060 dnl if test $ac_cv_sys_posix_termios = yes; then
3061 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3062 dnl                                and macros for terminal control.])
3063 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3064 dnl fi
3065
3066 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
3067
3068 # Set up the CFLAGS for real compilation, so we can substitute it.
3069 CFLAGS="$REAL_CFLAGS"
3070 CPPFLAGS="$REAL_CPPFLAGS"
3071
3072 ## Hack to detect a buggy GCC version.
3073 if test "x$GCC" = xyes \
3074    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3075    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3076    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3077    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3078 fi
3079
3080 #### Find out which version of Emacs this is.
3081 [version=`grep 'const char emacs_version' ${srcdir}/src/emacs.c \
3082          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
3083 if test x"${version}" = x; then
3084   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/src/emacs.c'.])
3085 fi
3086 if test x"${version}" != x"$PACKAGE_VERSION"; then
3087   AC_MSG_WARN([version mismatch between `${srcdir}/configure.in' and `${srcdir}/src/emacs.c'.])
3088 fi
3089
3090 ### Specify what sort of things we'll be editing into Makefile and config.h.
3091 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3092 AC_SUBST(version)
3093 AC_SUBST(configuration)
3094 ## Unused?
3095 AC_SUBST(canonical)
3096 AC_SUBST(srcdir)
3097 AC_SUBST(prefix)
3098 AC_SUBST(exec_prefix)
3099 AC_SUBST(bindir)
3100 AC_SUBST(datadir)
3101 AC_SUBST(sharedstatedir)
3102 AC_SUBST(libexecdir)
3103 AC_SUBST(mandir)
3104 AC_SUBST(infodir)
3105 AC_SUBST(lispdir)
3106 AC_SUBST(locallisppath)
3107 AC_SUBST(lisppath)
3108 AC_SUBST(x_default_search_path)
3109 AC_SUBST(etcdir)
3110 AC_SUBST(archlibdir)
3111 AC_SUBST(docdir)
3112 AC_SUBST(bitmapdir)
3113 AC_SUBST(gamedir)
3114 AC_SUBST(gameuser)
3115 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3116 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3117 ## end of LIBX_BASE, but nothing ever set it.
3118 AC_SUBST(LD_SWITCH_X_SITE)
3119 AC_SUBST(C_SWITCH_X_SITE)
3120 AC_SUBST(C_SWITCH_X_SYSTEM)
3121 AC_SUBST(CFLAGS)
3122 ## Used in lwlib/Makefile.in.
3123 AC_SUBST(X_TOOLKIT_TYPE)
3124 AC_SUBST(machfile)
3125 AC_SUBST(opsysfile)
3126 AC_SUBST(GETLOADAVG_LIBS)
3127 AC_SUBST(ns_appdir)
3128 AC_SUBST(ns_appbindir)
3129 AC_SUBST(ns_appresdir)
3130 AC_SUBST(ns_appsrc)
3131 AC_SUBST(GNU_OBJC_CFLAGS)
3132 AC_SUBST(OTHER_FILES)
3133
3134 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3135                    [Define to the canonical Emacs configuration name.])
3136 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3137                    [Define to the options passed to configure.])
3138 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
3139                    [Define to the used machine dependent file.])
3140 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3141                    [Define to the used os dependent file.])
3142
3143 XMENU_OBJ=
3144 XOBJ=
3145 FONT_OBJ=
3146 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3147   AC_DEFINE(HAVE_X_WINDOWS, 1,
3148             [Define to 1 if you want to use the X window system.])
3149   XMENU_OBJ=xmenu.o
3150   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3151   FONT_OBJ=xfont.o
3152   if test "$HAVE_XFT" = "yes"; then
3153     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3154   elif test "$HAVE_FREETYPE" = "yes"; then
3155     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3156   fi
3157   AC_SUBST(FONT_OBJ)
3158 fi
3159 AC_SUBST(XMENU_OBJ)
3160 AC_SUBST(XOBJ)
3161 AC_SUBST(FONT_OBJ)
3162
3163 WIDGET_OBJ=
3164 MOTIF_LIBW=
3165 if test "${USE_X_TOOLKIT}" != "none" ; then
3166   WIDGET_OBJ=widget.o
3167   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3168   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3169     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3170   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3171     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3172     MOTIF_LIBW=-lXm
3173     case "$opsys" in
3174       gnu-linux)
3175         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3176         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3177         ;;
3178
3179       unixware)
3180         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3181         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3182         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3183         ;;
3184
3185       aix4-2)
3186         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3187         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3188         ;;
3189     esac
3190     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3191   fi
3192 fi
3193 AC_SUBST(WIDGET_OBJ)
3194
3195 TOOLKIT_LIBW=
3196 case "$USE_X_TOOLKIT" in
3197   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3198   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3199   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3200 esac
3201 AC_SUBST(TOOLKIT_LIBW)
3202
3203 if test "$USE_X_TOOLKIT" = "none"; then
3204   LIBXT_OTHER="\$(LIBXSM)"
3205   OLDXMENU_TARGET="really-oldXMenu"
3206 else
3207   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3208   OLDXMENU_TARGET="really-lwlib"
3209 fi
3210 AC_SUBST(LIBXT_OTHER)
3211
3212 ## The X Menu stuff is present in the X10 distribution, but missing
3213 ## from X11.  If we have X10, just use the installed library;
3214 ## otherwise, use our own copy.
3215 if test "${HAVE_X11}" = "yes" ; then
3216   AC_DEFINE(HAVE_X11, 1,
3217             [Define to 1 if you want to use version 11 of X windows.
3218              Otherwise, Emacs expects to use version 10.])
3219
3220   if test "$USE_X_TOOLKIT" = "none"; then
3221     OLDXMENU="\${oldXMenudir}libXMenu11.a"
3222   else
3223     OLDXMENU="\${lwlibdir}liblw.a"
3224   fi
3225   LIBXMENU="\$(OLDXMENU)"
3226   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3227   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3228 else
3229   ## For a syntactically valid Makefile; not actually used for anything.
3230   ## See comments in src/Makefile.in.
3231   OLDXMENU=nothing
3232   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3233   if test "${HAVE_X_WINDOWS}" = "yes"; then
3234     LIBXMENU="-lXMenu"
3235   else
3236     LIBXMENU=
3237   fi
3238   LIBX_OTHER=
3239   OLDXMENU_DEPS=
3240 fi
3241
3242 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3243   OLDXMENU_TARGET=
3244   OLDXMENU=nothing
3245   LIBXMENU=
3246   OLDXMENU_DEPS=
3247 fi
3248
3249 AC_SUBST(OLDXMENU_TARGET)
3250 AC_SUBST(OLDXMENU)
3251 AC_SUBST(LIBXMENU)
3252 AC_SUBST(LIBX_OTHER)
3253 AC_SUBST(OLDXMENU_DEPS)
3254
3255 if test "${HAVE_MENUS}" = "yes" ; then
3256   AC_DEFINE(HAVE_MENUS, 1,
3257             [Define to 1 if you have mouse menus.
3258              (This is automatic if you use X, but the option to specify it remains.)
3259              It is also defined with other window systems that support xmenu.c.])
3260 fi
3261
3262 if test "${GNU_MALLOC}" = "yes" ; then
3263   AC_DEFINE(GNU_MALLOC, 1,
3264             [Define to 1 if you want to use the GNU memory allocator.])
3265 fi
3266
3267 RALLOC_OBJ=
3268 if test "${REL_ALLOC}" = "yes" ; then
3269   AC_DEFINE(REL_ALLOC, 1,
3270             [Define REL_ALLOC if you want to use the relocating allocator for
3271              buffer space.])
3272
3273   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3274 fi
3275 AC_SUBST(RALLOC_OBJ)
3276
3277 if test "$opsys" = "cygwin"; then
3278   CYGWIN_OBJ="sheap.o"
3279   ## Cygwin differs because of its unexec().
3280   PRE_ALLOC_OBJ=
3281   POST_ALLOC_OBJ=lastfile.o
3282 else
3283   CYGWIN_OBJ=
3284   PRE_ALLOC_OBJ=lastfile.o
3285   POST_ALLOC_OBJ=
3286 fi
3287 AC_SUBST(CYGWIN_OBJ)
3288 AC_SUBST(PRE_ALLOC_OBJ)
3289 AC_SUBST(POST_ALLOC_OBJ)
3290
3291
3292 case "$opsys" in
3293   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3294
3295   darwin)
3296    ## The -headerpad option tells ld (see man page) to leave room at the
3297    ## end of the header for adding load commands.  Needed for dumping.
3298    ## 0x690 is the total size of 30 segment load commands (at 56
3299    ## each); under Cocoa 31 commands are required.
3300    if test "$HAVE_NS" = "yes"; then
3301      libs_nsgui="-framework AppKit"
3302      headerpad_extra=6C8
3303    else
3304      libs_nsgui=
3305      headerpad_extra=690
3306    fi
3307    LD_SWITCH_SYSTEM_TEMACS="-prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3308
3309    ## This is here because src/Makefile.in did some extra fiddling around
3310    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3311    ##   #ifndef LD_SWITCH_SYSTEM
3312    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3313    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3314    ## not using gcc, darwin system not on an alpha (ie darwin, since
3315    ## darwin + alpha does not occur).
3316    ## Because this was done in src/Makefile.in, the resulting part of
3317    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3318    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3319    ## rather than LD_SWITCH_SYSTEM.
3320    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3321      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3322    ;;
3323
3324   ## LD_SWITCH_X_SITE_AUX is a -R option saying where to find X at run-time.
3325   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at
3326   ## the point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_AUX
3327   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3328   ## had different values in configure (in ac_link) and src/Makefile.in.
3329   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3330   gnu-linux) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_AUX)" ;;
3331
3332   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3333 esac
3334
3335 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3336   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3337 fi
3338
3339 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3340
3341
3342 LINKER=
3343 ORDINARY_LINK=
3344 case "$opsys" in
3345   ## gnu: GNU needs its own crt0.
3346   aix4-2|darwin|gnu|usg5-4|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3347
3348   cygwin) LINKER="\$(CC)" ;;
3349
3350   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3351   ## library search parth, i.e. it won't search /usr/lib for libc and
3352   ## friends.  Using -nostartfiles instead avoids this problem, and
3353   ## will also work on earlier NetBSD releases.
3354   netbsd|openbsd) LINKER="\$(CC) -nostartfiles" ;;
3355
3356   ## macpcc: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3357   ##   MkLinux/LinuxPPC needs this.
3358   ## ibms390x only supports opsys = gnu-linux so it can be added here.
3359   gnu-*)
3360     case "$machine" in
3361       macppc|ibms390x) LINKER="\$(CC) -nostdlib" ;;
3362     esac
3363     ;;
3364 esac
3365
3366
3367 PRE_EDIT_LDFLAGS=
3368 POST_EDIT_LDFLAGS=
3369 if test "x$ORDINARY_LINK" = "xyes"; then
3370
3371   LINKER="\$(CC)"
3372   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3373
3374 ## The system files defining neither ORDINARY_LINK nor LINKER are:
3375 ## (bsd-common), freebsd, gnu-* not on macppc|ibms390x, hpux*.
3376 elif test "x$GCC" = "xyes" && test "x$LINKER" = "x"; then
3377
3378   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3379   ## places that are difficult to figure out at make time.  Fortunately,
3380   ## these same versions allow you to pass arbitrary flags on to the
3381   ## linker, so there is no reason not to use it as a linker.
3382   ##
3383   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3384   ## searching for libraries in its internal directories, so we have to
3385   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3386   LINKER="\$(CC) -nostdlib"
3387   ## GCC passes any argument prefixed with -Xlinker directly to the linker.
3388   ## See prefix-args.c for an explanation of why we do not do this with the
3389   ## shell''s ``for'' construct.  Note that sane people do not have '.' in
3390   ## their paths, so we must use ./prefix-args.
3391   ## TODO either make prefix-args check ORDINARY_LINK internally,
3392   ## or remove it altogether (bug#6184), removing the need for this hack.
3393   PRE_EDIT_LDFLAGS='`./prefix-args -Xlinker'
3394   POST_EDIT_LDFLAGS='`'
3395 fi
3396 AC_SUBST(PRE_EDIT_LDFLAGS)
3397 AC_SUBST(POST_EDIT_LDFLAGS)
3398
3399 test "x$LINKER" = "x" && LINKER=ld
3400 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3401 test "$NS_IMPL_GNUSTEP" = "yes" && LINKER="\$(CC) -rdynamic"
3402
3403 AC_SUBST(LINKER)
3404
3405
3406 ## FIXME? The logic here is not precisely the same as that above.
3407 ## There is no check here for a pre-defined LINKER.
3408 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3409 LIB_GCC=
3410 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3411
3412   case "$opsys" in
3413     ## cygwin: don't link against static libgcc.
3414     cygwin|freebsd|netbsd|openbsd) LIB_GCC= ;;
3415
3416     gnu-*)
3417       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3418       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3419       ## Note that m/arm.h never bothered to undefine LIB_GCC first.
3420       if test "$machine" = "arm"; then
3421         LIB_GCC="-lgcc_s"
3422       else
3423         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3424         ## immediately undefine it again and redefine it to empty.
3425         ## Was the C_SWITCH_X_SITE part really necessary?
3426 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3427         LIB_GCC=
3428       fi
3429       ;;
3430
3431     ## Ask GCC where to find libgcc.a.
3432     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3433   esac
3434 fi                              dnl if $GCC
3435 AC_SUBST(LIB_GCC)
3436
3437
3438 TOOLTIP_SUPPORT=
3439 WINDOW_SUPPORT=
3440 ## If we're using X11/GNUstep, define some consequences.
3441 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3442   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3443   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3444   MOUSE_SUPPORT="\$(REAL_MOUSE_SUPPORT)"
3445   TOOLTIP_SUPPORT="\${lispsource}mouse.elc"
3446
3447   WINDOW_SUPPORT="\$(BASE_WINDOW_SUPPORT)"
3448   test "$HAVE_X_WINDOWS" = "yes" && \
3449     WINDOW_SUPPORT="$WINDOW_SUPPORT \$(X_WINDOW_SUPPORT)"
3450
3451 fi
3452 AC_SUBST(MOUSE_SUPPORT)
3453 AC_SUBST(TOOLTIP_SUPPORT)
3454 AC_SUBST(WINDOW_SUPPORT)
3455
3456
3457 AH_TOP([/* GNU Emacs site configuration template file.
3458    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2001, 2002, 2004, 2005,
3459      2006, 2007, 2008, 2009, 2010  Free Software Foundation, Inc.
3460
3461 This file is part of GNU Emacs.
3462
3463 GNU Emacs is free software: you can redistribute it and/or modify
3464 it under the terms of the GNU General Public License as published by
3465 the Free Software Foundation, either version 3 of the License, or
3466 (at your option) any later version.
3467
3468 GNU Emacs is distributed in the hope that it will be useful,
3469 but WITHOUT ANY WARRANTY; without even the implied warranty of
3470 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3471 GNU General Public License for more details.
3472
3473 You should have received a copy of the GNU General Public License
3474 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3475
3476
3477 /* No code in Emacs #includes config.h twice, but some bits of code
3478    intended to work with other packages as well (like gmalloc.c)
3479    think they can include it as many times as they like.  */
3480 #ifndef EMACS_CONFIG_H
3481 #define EMACS_CONFIG_H
3482 ])dnl
3483
3484 AH_BOTTOM([
3485 /* Define AMPERSAND_FULL_NAME if you use the convention
3486    that & in the full name stands for the login id.  */
3487 /* Turned on June 1996 supposing nobody will mind it.  */
3488 #define AMPERSAND_FULL_NAME
3489
3490 /* Define HAVE_SOUND if we have sound support.  We know it works
3491    and compiles only on the specified platforms.   For others,
3492    it probably doesn't make sense to try.  */
3493
3494 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
3495 #ifdef HAVE_MACHINE_SOUNDCARD_H
3496 #define HAVE_SOUND 1
3497 #endif
3498 #ifdef HAVE_SYS_SOUNDCARD_H
3499 #define HAVE_SOUND 1
3500 #endif
3501 #ifdef HAVE_SOUNDCARD_H
3502 #define HAVE_SOUND 1
3503 #endif
3504 #ifdef HAVE_ALSA
3505 #define HAVE_SOUND 1
3506 #endif
3507 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
3508
3509 /* If using GNU, then support inline function declarations.  */
3510 /* Don't try to switch on inline handling as detected by AC_C_INLINE
3511    generally, because even if non-gcc compilers accept `inline', they
3512    may reject `extern inline'.  */
3513 #if defined (__GNUC__) && defined (OPTIMIZE)
3514 #define INLINE __inline__
3515 #else
3516 #define INLINE
3517 #endif
3518
3519 /* `subprocesses' should be defined if you want to
3520    have code for asynchronous subprocesses
3521    (as used in M-x compile and M-x shell).
3522    Only MSDOS does not support this (it overrides
3523    this in its config_opsysfile below).  */
3524
3525 #define subprocesses
3526
3527 /* Include the os and machine dependent files.  */
3528 #include config_opsysfile
3529 #include config_machfile
3530
3531 /* Set up some defines, C and LD flags for NeXTstep interface on GNUstep.
3532   (There is probably a better place to do this, but right now the Cocoa
3533    side does this in s/darwin.h and we cannot
3534    parallel this exactly since GNUstep is multi-OS.  */
3535 #ifdef HAVE_NS
3536 # ifdef NS_IMPL_GNUSTEP
3537 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3538 SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.  */
3539 #  define SYSTEM_PURESIZE_EXTRA 30000
3540 # endif /* NS_IMPL_GNUSTEP */
3541 #endif /* HAVE_NS */
3542
3543 /* SIGTYPE is the macro we actually use.  */
3544 #ifndef SIGTYPE
3545 #define SIGTYPE RETSIGTYPE
3546 #endif
3547
3548 #ifdef emacs /* Don't do this for lib-src.  */
3549 /* Tell regex.c to use a type compatible with Emacs.  */
3550 #define RE_TRANSLATE_TYPE Lisp_Object
3551 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3552 #ifdef make_number
3553 /* If make_number is a macro, use it.  */
3554 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3555 #else
3556 /* If make_number is a function, avoid it.  */
3557 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3558 #endif
3559 #endif
3560
3561 /* Avoid link-time collision with system mktime if we will use our own.  */
3562 #if ! HAVE_MKTIME || BROKEN_MKTIME
3563 #define mktime emacs_mktime
3564 #endif
3565
3566 #define my_strftime nstrftime   /* for strftime.c */
3567
3568 /* Some of the files of Emacs which are intended for use with other
3569    programs assume that if you have a config.h file, you must declare
3570    the type of getenv.  */
3571 extern char *getenv ();
3572
3573 /* These default definitions are good for almost all machines.
3574    The exceptions override them in m/MACHINE.h.  */
3575
3576 #ifndef BITS_PER_CHAR
3577 #define BITS_PER_CHAR 8
3578 #endif
3579
3580 #ifndef BITS_PER_SHORT
3581 #define BITS_PER_SHORT 16
3582 #endif
3583
3584 /* Note that lisp.h uses this in a preprocessor conditional, so it
3585    would not work to use sizeof.  That being so, we do all of them
3586    without sizeof, for uniformity's sake.  */
3587 #ifndef BITS_PER_INT
3588 #define BITS_PER_INT 32
3589 #endif
3590
3591 #ifndef BITS_PER_LONG
3592 #ifdef _LP64
3593 #define BITS_PER_LONG 64
3594 #else
3595 #define BITS_PER_LONG 32
3596 #endif
3597 #endif
3598
3599 /* Define if the compiler supports function prototypes.  It may do so
3600    but not define __STDC__ (e.g. DEC C by default) or may define it as
3601    zero.  */
3602 #undef PROTOTYPES
3603 /* For mktime.c:  */
3604 #ifndef __P
3605 # if defined PROTOTYPES
3606 #  define __P(args) args
3607 # else
3608 #  define __P(args) ()
3609 # endif  /* GCC.  */
3610 #endif /* __P */
3611
3612 #ifdef HAVE_STRING_H
3613 #include <string.h>
3614 #endif
3615
3616 #ifdef HAVE_STRINGS_H
3617 #include <strings.h>  /* May be needed for bcopy & al.  */
3618 #endif
3619
3620 #ifdef HAVE_STDLIB_H
3621 #include <stdlib.h>
3622 #endif
3623
3624 #ifdef HAVE_ALLOCA_H
3625 # include <alloca.h>
3626 #elif defined __GNUC__
3627 # define alloca __builtin_alloca
3628 #elif defined _AIX
3629 # define alloca __alloca
3630 #else
3631 # include <stddef.h>
3632 # ifdef  __cplusplus
3633 extern "C"
3634 # endif
3635 void *alloca (size_t);
3636 #endif
3637
3638 #ifndef HAVE_SIZE_T
3639 typedef unsigned size_t;
3640 #endif
3641
3642 /* Define HAVE_X_I18N if we have usable i18n support.  */
3643
3644 #ifdef HAVE_X11R6
3645 #define HAVE_X_I18N
3646 #endif
3647
3648 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3649
3650 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3651 #define HAVE_X11R6_XIM
3652 #endif
3653
3654 #if defined __GNUC__ && (__GNUC__ > 2 \
3655                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3656 #define NO_RETURN       __attribute__ ((__noreturn__))
3657 #else
3658 #define NO_RETURN       /* nothing */
3659 #endif
3660
3661 /* These won't be used automatically yet.  We also need to know, at least,
3662    that the stack is continuous.  */
3663 #ifdef __GNUC__
3664 #  ifndef GC_SETJMP_WORKS
3665   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3666 #    define GC_SETJMP_WORKS 1
3667 #  endif
3668 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3669 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3670 #  endif
3671 #endif
3672
3673 #ifndef HAVE_BCOPY
3674 #define bcopy(a,b,s) memcpy (b,a,s)
3675 #endif
3676 #ifndef HAVE_BZERO
3677 #define bzero(a,s) memset (a,0,s)
3678 #endif
3679 #ifndef HAVE_BCMP
3680 #define BCMP memcmp
3681 #endif
3682
3683 #endif /* EMACS_CONFIG_H */
3684
3685 /*
3686 Local Variables:
3687 mode: c
3688 End:
3689 */
3690 ])dnl
3691
3692 #### Report on what we decided to do.
3693 #### Report GTK as a toolkit, even if it doesn't use Xt.
3694 #### It makes printing result more understandable as using GTK sets
3695 #### toolkit_scroll_bars to yes by default.
3696 if test "${HAVE_GTK}" = "yes"; then
3697   USE_X_TOOLKIT=GTK
3698 fi
3699
3700 echo "
3701 Configured for \`${canonical}'.
3702
3703   Where should the build process find the source code?    ${srcdir}
3704   What operating system and machine description files should Emacs use?
3705         \`${opsysfile}' and \`${machfile}'
3706   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3707   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3708   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3709   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3710   What window system should Emacs use?                    ${window_system}
3711   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3712
3713 if test -n "${x_includes}"; then
3714 echo "  Where do we find X Windows header files?                ${x_includes}"
3715 else
3716 echo "  Where do we find X Windows header files?                Standard dirs"
3717 fi
3718 if test -n "${x_libraries}"; then
3719 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3720 else
3721 echo "  Where do we find X Windows libraries?                   Standard dirs"
3722 fi
3723
3724 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3725 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3726 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3727 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3728 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3729 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3730 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3731 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3732 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3733 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3734 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3735
3736 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3737 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3738 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3739 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3740
3741 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3742 echo
3743
3744 if test $USE_XASSERTS = yes; then
3745    echo "  Compiling with asserts turned on."
3746    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3747 fi
3748
3749 echo
3750
3751 if test "$HAVE_NS" = "yes"; then
3752    echo
3753    echo "You must run \"make install\" in order to test the built application.
3754 The installed application will go to nextstep/Emacs.app and can be
3755 run or moved from there."
3756    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3757       echo "The application will be fully self-contained."
3758     else
3759       echo "The lisp resources for the application will be installed under ${prefix}.
3760 You may need to run \"make install\" with sudo.  The application will fail
3761 to run if these resources are not installed."
3762    fi
3763    echo
3764 fi
3765
3766 if test "$HAVE_DBUS" = yes && test "${opsys}" != "gnu-linux"; then
3767   echo "D-Bus integration has been tested for GNU/Linux only."
3768   echo
3769 fi
3770
3771
3772 # Remove any trailing slashes in these variables.
3773 [test "${prefix}" != NONE &&
3774   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3775 test "${exec_prefix}" != NONE &&
3776   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3777
3778 dnl You might wonder (I did) why epaths.h is generated by running make,
3779 dnl rather than just letting configure generate it from epaths.in.
3780 dnl One reason is that the various paths are not fully expanded (see above);
3781 dnl eg gamedir=${prefix}/var/games/emacs.
3782 dnl Secondly, the GNU Coding standards require that one should be able
3783 dnl to run `make prefix=/some/where/else' and override the values set
3784 dnl by configure.  This also explains the `move-if-change' test and
3785 dnl the use of force in the `epaths-force' rule in Makefile.in.
3786 AC_OUTPUT(Makefile lib-src/Makefile oldXMenu/Makefile \
3787         doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3788         doc/lispref/Makefile src/Makefile \
3789         lwlib/Makefile lisp/Makefile leim/Makefile, [
3790
3791 ### Make the necessary directories, if they don't exist.
3792 for dir in etc lisp ; do
3793   test -d ${dir} || mkdir ${dir}
3794 done
3795
3796 echo creating src/epaths.h
3797 ${MAKE-make} epaths-force
3798
3799 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3800   echo creating src/.gdbinit
3801   echo source $srcdir/src/.gdbinit > src/.gdbinit
3802 fi
3803
3804 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPPFLAGS="$CPPFLAGS"])
3805
3806 m4_if(dnl       Do not change this comment
3807    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3808 )dnl