code.delx.au - gnu-emacs/blob - lisp/rsz-mini.el

   1 ;;; rsz-mini.el --- dynamically resize minibuffer to display entire contents
   2
   3 ;; Copyright (C) 1990, 1993, 1994, 1995 Free Software Foundation, Inc.
   4
   5 ;; Author: Noah Friedman <friedman@prep.ai.mit.edu>
   6 ;;         Roland McGrath <roland@prep.ai.mit.edu>
   7 ;; Maintainer: friedman@prep.ai.mit.edu
   8 ;; Keywords: minibuffer, window, frame, display
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; This package allows the entire contents (or as much as possible) of the
  30 ;; minibuffer to be visible at once when typing.  As the end of a line is
  31 ;; reached, the minibuffer will resize itself.  When the user is done
  32 ;; typing, the minibuffer will return to its original size.
  33
  34 ;; In window systems where it is possible to have a frame in which the
  35 ;; minibuffer is the only window, the frame itself can be resized.  In
  36 ;; Emacs 19.22 and earlier, the frame may not be properly returned to
  37 ;; its original size after it ceases to be active because
  38 ;; `minibuffer-exit-hook' didn't exist until version 19.23.
  39 ;;
  40 ;; Prior to Emacs 19.26, minibuffer-exit-hook wasn't called after exiting
  41 ;; from the minibuffer by hitting the quit char.  That meant that the
  42 ;; frame size restoration function wasn't being called in that case.  In
  43 ;; 19.26 or later, minibuffer-exit-hook should be called anyway.
  44
  45 ;; Note that the minibuffer and echo area are not the same!  They simply
  46 ;; happen to occupy roughly the same place on the frame.  Messages put in
  47 ;; the echo area will not cause any resizing by this package.
  48
  49 ;; This package is considered a minor mode but it doesn't put anything in
  50 ;; minor-mode-alist because this mode is specific to the minibuffer, which
  51 ;; has no mode line.
  52
  53 ;; To enable or disable this mode, use M-x resize-minibuffer-mode.
  54
  55 ;;; Code:
  56
  57 \f
  58 (defgroup resize-minibuffer nil
  59   "Dynamically resize minibuffer to display entire contents"
  60   :group 'frames)
  61
  62
  63 ;;;###autoload
  64 (defcustom resize-minibuffer-mode nil
  65   "*If non-`nil', resize the minibuffer so its entire contents are visible."
  66   :type 'boolean
  67   :group 'resize-minibuffer)
  68
  69 ;;;###autoload
  70 (defcustom resize-minibuffer-window-max-height nil
  71   "*Maximum size the minibuffer window is allowed to become.
  72 If less than 1 or not a number, the limit is the height of the frame in
  73 which the active minibuffer window resides."
  74   :type '(choice (const nil) integer)
  75   :group 'resize-minibuffer)
  76
  77 ;;;###autoload
  78 (defcustom resize-minibuffer-window-exactly t
  79   "*Allow making minibuffer exactly the size to display all its contents.
  80 If `nil', the minibuffer window can temporarily increase in size but
  81 never get smaller while it is active.  Any other value allows exact
  82 resizing."
  83   :type 'boolean
  84   :group 'resize-minibuffer)
  85
  86 ;;;###autoload
  87 (defcustom resize-minibuffer-frame nil
  88   "*Allow changing the frame height of minibuffer frames.
  89 If non-`nil' and the active minibuffer is the sole window in its frame,
  90 allow changing the frame height."
  91   :type 'boolean
  92   :group 'resize-minibuffer)
  93
  94 ;;;###autoload
  95 (defcustom resize-minibuffer-frame-max-height nil
  96   "*Maximum size the minibuffer frame is allowed to become.
  97 If less than 1 or not a number, there is no limit.")
  98
  99 ;;;###autoload
 100 (defcustom resize-minibuffer-frame-exactly t
 101   "*Allow making minibuffer frame exactly the size to display all its contents.
 102 If `nil', the minibuffer frame can temporarily increase in size but
 103 never get smaller while it is active.  Any other value allows exact
 104 resizing."
 105   :type 'boolean
 106   :group 'resize-minibuffer)
 107
 108 ;; Variable used to store the height of the minibuffer frame
 109 ;; on entry, so it can be restored on exit.  It is made local before it is
 110 ;; modified.  Do not use it yourself.
 111 (defvar resize-minibuffer-frame-original-height nil)
 112
 113 \f
 114 ;;;###autoload
 115 (defun resize-minibuffer-mode (&optional prefix)
 116   "Enable or disable resize-minibuffer mode.
 117 A negative prefix argument disables this mode.  A positive argument or
 118 argument of 0 enables it.
 119
 120 When this minor mode is enabled, the minibuffer is dynamically resized to
 121 contain the entire region of text put in it as you type.
 122
 123 The variable `resize-minibuffer-mode' is set to t or nil depending on
 124 whether this mode is active or not.
 125
 126 The maximum height to which the minibuffer can grow is controlled by the
 127 variable `resize-minibuffer-window-max-height'.
 128
 129 The variable `resize-minibuffer-window-exactly' determines whether the
 130 minibuffer window should ever be shrunk to make it no larger than needed to
 131 display its contents.
 132
 133 When using a window system, it is possible for a minibuffer to be the sole
 134 window in a frame.  Since that window is already its maximum size, the only
 135 way to make more text visible at once is to increase the size of the frame.
 136 The variable `resize-minibuffer-frame' controls whether this should be
 137 done.  The variables `resize-minibuffer-frame-max-height' and
 138 `resize-minibuffer-frame-exactly' are analogous to their window
 139 counterparts."
 140   (interactive "p")
 141   (or prefix (setq prefix 0))
 142   (cond
 143    ((>= prefix 0)
 144     (setq resize-minibuffer-mode t))
 145    (t
 146     (setq resize-minibuffer-mode nil))))
 147
 148 (defun resize-minibuffer-setup ()
 149   (cond
 150    (resize-minibuffer-mode
 151     (cond
 152      ((and window-system
 153            (eq 'only (cdr (assq 'minibuffer (frame-parameters)))))
 154       ;; Checking for resize-minibuffer-frame is done outside the cond
 155       ;; predicate because that should always be t if this is a minibuffer
 156       ;; frame; it just shouldn't do anything if this flag is nil.
 157       (and resize-minibuffer-frame
 158            (progn
 159              ;; Can't trust the height stored in minibuffer-frame-alist
 160              ;; since the frame can be resized by the window manager and
 161              ;; that variable isn't updated.
 162              (make-local-variable 'resize-minibuffer-frame-original-height)
 163              (setq resize-minibuffer-frame-original-height (frame-height))
 164
 165              (make-local-hook 'post-command-hook)
 166              (add-hook 'post-command-hook 'resize-minibuffer-frame 'append t)
 167
 168              (make-local-hook 'minibuffer-exit-hook)
 169              (add-hook 'minibuffer-exit-hook 'resize-minibuffer-frame-restore
 170                        nil t)
 171
 172              (resize-minibuffer-frame))))
 173      (t
 174       (make-local-variable 'post-command-hook)
 175       ;; Copy this because add-hook modifies the list structure.
 176       (setq post-command-hook (copy-sequence post-command-hook))
 177       (add-hook 'post-command-hook 'resize-minibuffer-window 'append)
 178
 179       (make-local-variable 'minibuffer-exit-hook)
 180       (add-hook 'minibuffer-exit-hook 'resize-minibuffer-window-restore)
 181
 182       (resize-minibuffer-window))))))
 183
 184 (defun resize-minibuffer-count-window-lines (&optional start end)
 185   "Return number of window lines occupied by text in region.
 186 The number of window lines may be greater than the number of actual lines
 187 in the buffer if any wrap on the display due to their length.
 188
 189 Optional arguments START and END default to point-min and point-max,
 190 respectively."
 191   (or start (setq start (point-min)))
 192   (or end   (setq end   (point-max)))
 193   (if (= start end)
 194       0
 195     (save-excursion
 196       (save-restriction
 197         (widen)
 198         (narrow-to-region start end)
 199         (goto-char start)
 200         (vertical-motion (buffer-size))))))
 201
 202 \f
 203 ;; Resize the minibuffer window to contain the minibuffer's contents.
 204 (defun resize-minibuffer-window ()
 205   (and (eq (selected-window) (minibuffer-window))
 206        (let ((height (window-height))
 207              (lines (1+ (resize-minibuffer-count-window-lines))))
 208          (and (numberp resize-minibuffer-window-max-height)
 209               (> resize-minibuffer-window-max-height 0)
 210               (setq lines (min lines resize-minibuffer-window-max-height)))
 211          (or (if resize-minibuffer-window-exactly
 212                  (= lines height)
 213                (<= lines height))
 214              (enlarge-window (- lines height))))))
 215
 216 ;; This resizes the minibuffer back to one line as soon as it is exited
 217 ;; (e.g. when the user hits RET).  This way, subsequent messages put in the
 218 ;; echo area aren't cluttered with leftover minibuffer text.
 219 ;; It should be called by minibuffer-exit-hook.
 220 ;;
 221 ;; Note that because it calls sit-for to force a screen update, strange
 222 ;; things may happen in the minibuffer, such as unexpanded partial
 223 ;; completions by complete.el showing their completion.
 224 ;; If this bothers you, just redefine this function to do nothing, in, say,
 225 ;; your after-load-alist.  Perhaps there should be an option variable,
 226 ;; but I don't know if there's really any demand for it.
 227 ;; (Clobbering this definition is harmless because eventually emacs restores
 228 ;; its idea of the minibuffer window size when the minibuffer isn't in use
 229 ;; anyway; this is just a kludge because of the timing for that update).
 230 (defun resize-minibuffer-window-restore ()
 231   (cond
 232    ((not (eq (minibuffer-window) (selected-window))))
 233    ((> (window-height) 1)
 234     (enlarge-window (- 1 (window-height)))
 235     (sit-for 0))))
 236
 237 \f
 238 ;; Resize the minibuffer frame to contain the minibuffer's contents.
 239 ;; The minibuffer frame must be the current frame.
 240 (defun resize-minibuffer-frame ()
 241   (let ((height (frame-height))
 242         (lines (1+ (resize-minibuffer-count-window-lines))))
 243     (and (numberp resize-minibuffer-frame-max-height)
 244          (> resize-minibuffer-frame-max-height 0)
 245          (setq lines (min lines resize-minibuffer-frame-max-height)))
 246     (cond
 247      ((> lines height)
 248       (set-frame-size (window-frame (minibuffer-window)) (frame-width) lines))
 249      ((and resize-minibuffer-frame-exactly
 250            (> height resize-minibuffer-frame-original-height)
 251            (< lines height))
 252       (set-frame-size (window-frame (minibuffer-window))
 253                       (frame-width) lines)))))
 254
 255 ;; Restore the original height of the frame.
 256 ;; resize-minibuffer-frame-original-height is set in
 257 ;; resize-minibuffer-setup.
 258 (defun resize-minibuffer-frame-restore ()
 259   (set-frame-size (window-frame (minibuffer-window))
 260                   (frame-width)
 261                   resize-minibuffer-frame-original-height))
 262
 263 \f
 264 (provide 'rsz-mini)
 265
 266 (add-hook 'minibuffer-setup-hook 'resize-minibuffer-setup)
 267 (resize-minibuffer-mode)
 268
 269 ;; rsz-mini.el ends here