code.delx.au - gnu-emacs/blob - lisp/ielm.el

   1 ;;; ielm.el --- interaction mode for Emacs Lisp
   2
   3 ;; Copyright (C) 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: David Smith <maa036@lancaster.ac.uk>
   6 ;; Maintainer: FSF
   7 ;; Created: 25 Feb 1994
   8 ;; Keywords: lisp
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Provides a nice interface to evaluating Emacs Lisp expressions.
  30 ;; Input is handled by the comint package, and output is passed
  31 ;; through the pretty-printer.
  32
  33 ;; To install: copy this file to a directory in your load-path, and
  34 ;; add the following line to your .emacs file:
  35 ;;
  36 ;;   (autoload 'ielm "ielm" "Start an inferior Emacs Lisp session" t)
  37 ;;
  38 ;; For completion to work, the comint.el from Emacs 19.23 is
  39 ;; required.  If you do not have it, or if you are running Lemacs,
  40 ;; also add the following code to your .emacs:
  41 ;;
  42 ;;    (setq ielm-mode-hook
  43 ;;          '(lambda nil
  44 ;;               (define-key ielm-map "\t"
  45 ;;                  '(lambda nil (interactive) (or (ielm-tab)
  46 ;;                                                 (lisp-complete-symbol))))))
  47
  48 ;; To start: M-x ielm.  Type C-h m in the *ielm* buffer for more info.
  49
  50 ;; The latest version is available by WWW from
  51 ;;      http://mathssun5.lancs.ac.uk:2080/~maa036/elisp/dir.html
  52 ;; or by anonymous FTP from
  53 ;;      /anonymous@wingra.stat.wisc.edu:pub/src/emacs-lisp/ielm.el.gz
  54 ;; or from the author: David M. Smith <maa036@lancaster.ac.uk>
  55
  56 ;;; Code:
  57
  58 (require 'comint)
  59 (require 'pp)
  60
  61 ;;; User variables
  62
  63 (defgroup ielm nil
  64   "Interaction mode for Emacs Lisp."
  65   :group 'lisp)
  66
  67
  68 (defcustom ielm-noisy t
  69   "*If non-nil, IELM will beep on error."
  70   :type 'boolean
  71   :group 'ielm)
  72
  73 (defvar ielm-prompt "ELISP> "
  74   "Prompt used in IELM.")
  75
  76 (defcustom ielm-dynamic-return t
  77   "*Controls whether \\<ielm-map>\\[ielm-return] has intelligent behaviour in IELM.
  78 If non-nil, \\[ielm-return] evaluates input for complete sexps, or inserts a newline
  79 and indents for incomplete sexps.  If nil, always inserts newlines."
  80   :type 'boolean
  81   :group 'ielm)
  82
  83 (defcustom ielm-dynamic-multiline-inputs t
  84   "*Force multiline inputs to start from column zero?
  85 If non-nil, after entering the first line of an incomplete sexp, a newline
  86 will be inserted after the prompt, moving the input to the next line.
  87 This gives more frame width for large indented sexps, and allows functions
  88 such as `edebug-defun' to work with such inputs."
  89   :type 'boolean
  90   :group 'ielm)
  91
  92 (defcustom ielm-mode-hook nil
  93   "*Hooks to be run when IELM (`inferior-emacs-lisp-mode') is started."
  94   :type 'hook
  95   :group 'ielm)
  96
  97 ;;; System variables
  98
  99 (defvar ielm-working-buffer nil
 100   "Buffer in which IELM sexps will be evaluated.
 101 This variable is buffer-local.")
 102
 103 (defvar ielm-header
 104   "*** Welcome to IELM ***  Type (describe-mode) for help.\n"
 105   "Message to display when IELM is started.")
 106
 107 (defvar ielm-map nil)
 108 (if ielm-map nil
 109   (if (string-match "Lucid" emacs-version)
 110       ;; Lemacs
 111       (progn
 112         (setq ielm-map (make-sparse-keymap))
 113         (set-keymap-parent ielm-map comint-mode-map))
 114     ;; FSF
 115     (setq ielm-map (cons 'keymap comint-mode-map)))
 116   (define-key ielm-map "\t" 'comint-dynamic-complete)
 117   (define-key ielm-map "\C-m" 'ielm-return)
 118   (define-key ielm-map "\C-j" 'ielm-send-input)
 119   (define-key ielm-map "\e\C-x" 'eval-defun)         ; for consistency with
 120   (define-key ielm-map "\e\t" 'lisp-complete-symbol) ; lisp-interaction-mode
 121   ;; These bindings are from shared-lisp-mode-map -- can you inherit
 122   ;; from more than one keymap??
 123   (define-key ielm-map "\e\C-q" 'indent-sexp)
 124   (define-key ielm-map "\177" 'backward-delete-char-untabify)
 125   ;; Some convenience bindings for setting the working buffer
 126   (define-key ielm-map "\C-c\C-b" 'ielm-change-working-buffer)
 127   (define-key ielm-map "\C-c\C-f" 'ielm-display-working-buffer)
 128   (define-key ielm-map "\C-c\C-v" 'ielm-print-working-buffer))
 129
 130 (defvar ielm-font-lock-keywords
 131   (list
 132    (cons (concat "^" (regexp-quote ielm-prompt)) 'font-lock-keyword-face)
 133    '("\\(^\\*\\*\\*[^*]+\\*\\*\\*\\)\\(.*$\\)"
 134      (1 font-lock-comment-face)
 135      (2 font-lock-constant-face)))
 136   "Additional expressions to highlight in ielm buffers.")
 137
 138 ;;; Completion stuff
 139
 140 (defun ielm-tab nil
 141   "Possibly indent the current line as lisp code."
 142   (interactive)
 143   (if (or (eq (preceding-char) ?\n)
 144           (eq (char-syntax (preceding-char)) ? ))
 145       (progn
 146         (ielm-indent-line)
 147         t)))
 148
 149 (defun ielm-complete-symbol nil
 150   "Complete the lisp symbol before point."
 151   ;; A wrapper for lisp-complete symbol that returns non-nil if
 152   ;; completion has occurred
 153   (let* ((btick (buffer-modified-tick))
 154          (cbuffer (get-buffer "*Completions*"))
 155          (ctick (and cbuffer (buffer-modified-tick cbuffer))))
 156     (lisp-complete-symbol)
 157      ;; completion has occurred if:
 158     (or
 159      ;; the buffer has been modified
 160      (not (= btick (buffer-modified-tick)))
 161      ;; a completions buffer has been modified or created
 162      (if cbuffer
 163          (not (= ctick (buffer-modified-tick cbuffer)))
 164        (get-buffer "*Completions*")))))
 165
 166 (defun ielm-complete-filename nil
 167   "Dynamically complete filename before point, if in a string."
 168   (if (nth 3 (parse-partial-sexp comint-last-input-start (point)))
 169       (comint-dynamic-complete-filename)))
 170
 171 (defun ielm-indent-line nil
 172   "Indent the current line as Lisp code if it is not a prompt line."
 173   (if (save-excursion
 174         (beginning-of-line)
 175         (looking-at comint-prompt-regexp)) nil
 176     (lisp-indent-line)))
 177
 178 ;;; Working buffer manipulation
 179
 180 (defun ielm-print-working-buffer nil
 181   "Print the current IELM working buffer's name in the echo area."
 182   (interactive)
 183   (message "The current working buffer is: %s" (buffer-name ielm-working-buffer)))
 184
 185 (defun ielm-display-working-buffer nil
 186   "Display the current IELM working buffer.
 187 Don't forget that selecting that buffer will change its value of `point'
 188 to its value of `window-point'!"
 189   (interactive)
 190   (display-buffer ielm-working-buffer)
 191   (ielm-print-working-buffer))
 192
 193 (defun ielm-change-working-buffer (buf)
 194   "Change the current IELM working buffer to BUF.
 195 This is the buffer in which all sexps entered at the IELM prompt are
 196 evaluated.  You can achieve the same effect with a call to
 197 `set-buffer' at the IELM prompt."
 198   (interactive "bSet working buffer to: ")
 199   (setq ielm-working-buffer (or (get-buffer buf) (error "No such buffer")))
 200   (ielm-print-working-buffer))
 201
 202 ;;; Other bindings
 203
 204 (defun ielm-return nil
 205   "Newline and indent, or evaluate the sexp before the prompt.
 206 Complete sexps are evaluated; for incomplete sexps inserts a newline
 207 and indents.  If however `ielm-dynamic-return' is nil, this always
 208 simply inserts a newline."
 209   (interactive)
 210   (if ielm-dynamic-return
 211       (let ((state
 212              (save-excursion
 213                (end-of-line)
 214                (parse-partial-sexp (ielm-pm)
 215                                    (point)))))
 216         (if (and (< (car state) 1) (not (nth 3 state)))
 217             (ielm-send-input)
 218           (if (and ielm-dynamic-multiline-inputs
 219                    (save-excursion
 220                      (beginning-of-line)
 221                      (looking-at comint-prompt-regexp)))
 222               (save-excursion
 223                 (goto-char (ielm-pm))
 224                 (newline 1)))
 225           (newline-and-indent)))
 226     (newline)))
 227
 228 (defvar ielm-input)
 229
 230 (defun ielm-input-sender (proc input)
 231   ;; Just sets the variable ielm-input, which is in the scope of
 232   ;; `ielm-send-input's call.
 233   (setq ielm-input input))
 234
 235 (defun ielm-send-input nil
 236   "Evaluate the Emacs Lisp expression after the prompt."
 237   (interactive)
 238   (let ((buf (current-buffer))
 239         ielm-input)                     ; set by ielm-input-sender
 240     (comint-send-input)                 ; update history, markers etc.
 241     (ielm-eval-input ielm-input)))
 242
 243 ;;; Utility functions
 244
 245 (defun ielm-is-whitespace (string)
 246   "Return non-nil if STRING is all whitespace."
 247   (or (string= string "") (string-match "\\`[ \t\n]+\\'" string)))
 248
 249 (defun ielm-format-errors (errlist)
 250   (let ((result ""))
 251     (while errlist
 252       (setq result (concat result (prin1-to-string (car errlist)) ", "))
 253       (setq errlist (cdr errlist)))
 254     (substring result 0 -2)))
 255
 256
 257 (defun ielm-format-error (err)
 258   ;; Return a string form of the error ERR.
 259   (format "%s%s"
 260           (or (get (car err) 'error-message) "Peculiar error")
 261           (if (cdr err)
 262               (format ": %s" (ielm-format-errors (cdr err)))
 263             "")))
 264
 265 ;;; Evaluation
 266
 267 (defun ielm-eval-input (ielm-string)
 268   "Evaluate the Lisp expression IELM-STRING, and pretty-print the result."
 269   ;; This is the function that actually `sends' the input to the
 270   ;; `inferior Lisp process'. All comint-send-input does is works out
 271   ;; what that input is.  What this function does is evaluates that
 272   ;; input and produces `output' which gets inserted into the buffer,
 273   ;; along with a new prompt.  A better way of doing this might have
 274   ;; been to actually send the output to the `cat' process, and write
 275   ;; this as in output filter that converted sexps in the output
 276   ;; stream to their evaluated value.  But that would have involved
 277   ;; more process coordination than I was happy to deal with.
 278   ;;
 279   ;; NOTE: all temporary variables in this function will be in scope
 280   ;; during the eval, and so need to have non-clashing names.
 281   (let (ielm-form                       ; form to evaluate
 282         ielm-pos                        ; End posn of parse in string
 283         ielm-result                     ; Result, or error message
 284         ielm-error-type                 ; string, nil if no error
 285         (ielm-output    "")             ; result to display
 286         (ielm-wbuf ielm-working-buffer) ; current buffer after evaluation
 287         (ielm-pmark (ielm-pm)))
 288     (if (not (ielm-is-whitespace ielm-string))
 289         (progn
 290           (condition-case err
 291               (let (rout)
 292                 (setq rout (read-from-string ielm-string))
 293                 (setq ielm-form (car rout))
 294                 (setq ielm-pos (cdr rout)))
 295             (error (setq ielm-result (ielm-format-error err))
 296                    (setq ielm-error-type "Read error")))
 297           (if ielm-error-type nil
 298             ;; Make sure working buffer has not been killed
 299             (if (not (buffer-name ielm-working-buffer))
 300                 (setq ielm-result "Working buffer has been killed"
 301                       ielm-error-type "IELM Error"
 302                       ielm-wbuf (current-buffer))
 303               (if (ielm-is-whitespace (substring ielm-string ielm-pos))
 304                   ;; need this awful let convolution to work around
 305                   ;; an Emacs bug involving local vbls and let binding
 306                   (let ((*save *)
 307                         (**save **)
 308                         (***save ***))
 309                     (save-excursion
 310                       (set-buffer ielm-working-buffer)
 311                       (condition-case err
 312                           (let ((* *save)
 313                                 (** **save)
 314                                 (*** ***save)
 315                                 (ielm-obuf (current-buffer)))
 316                             (setq ielm-result (eval ielm-form))
 317                             (setq ielm-wbuf (current-buffer))
 318                             ;; The eval may have changed current-buffer;
 319                             ;; need to set it back here to avoid a bug
 320                             ;; in let.  Don't want to use save-excursion
 321                             ;; because we want to allow changes in point.
 322                             (set-buffer ielm-obuf))
 323                         (error (setq ielm-result (ielm-format-error err))
 324                                (setq ielm-error-type "Eval error"))
 325                         (quit (setq ielm-result "Quit during evaluation")
 326                               (setq ielm-error-type "Eval error")))))
 327                 (setq ielm-error-type "IELM error")
 328                 (setq ielm-result "More than one sexp in input"))))
 329
 330           ;; If the eval changed the current buffer, mention it here
 331           (if (eq ielm-wbuf ielm-working-buffer) nil
 332             (message "current buffer is now: %s" ielm-wbuf)
 333             (setq ielm-working-buffer ielm-wbuf))
 334
 335           (goto-char ielm-pmark)
 336           (if (not ielm-error-type)
 337               (condition-case err
 338                   ;; Self-referential objects cause loops in the printer, so
 339                   ;; trap quits here. May as well do errors, too
 340                   (setq ielm-output (concat ielm-output (pp-to-string ielm-result)))
 341                 (error (setq ielm-error-type "IELM Error")
 342                        (setq ielm-result  "Error during pretty-printing (bug in pp)"))
 343                 (quit  (setq ielm-error-type "IELM Error")
 344                        (setq ielm-result "Quit during pretty-printing"))))
 345           (if ielm-error-type
 346               (progn
 347                 (if ielm-noisy (ding))
 348                 (setq ielm-output (concat ielm-output "*** " ielm-error-type " ***  "))
 349                 (setq ielm-output (concat ielm-output ielm-result)))
 350             ;; There was no error, so shift the ::: values
 351             (setq ::: ::)
 352             (setq :: :)
 353             (setq : ielm-result))
 354           (setq ielm-output (concat ielm-output "\n"))))
 355     (setq ielm-output (concat ielm-output ielm-prompt))
 356     (comint-output-filter (ielm-process) ielm-output)))
 357
 358 ;;; Process and marker utilities
 359
 360 (defun ielm-process nil
 361   ;; Return the current buffer's process.
 362   (get-buffer-process (current-buffer)))
 363
 364 (defun ielm-pm nil
 365   ;; Return the process mark of the current buffer.
 366   (process-mark (get-buffer-process (current-buffer))))
 367
 368 (defun ielm-set-pm (pos)
 369   ;; Set the process mark in the current buffer to POS.
 370   (set-marker (process-mark (get-buffer-process (current-buffer))) pos))
 371
 372 ;;; Major mode
 373
 374 (put 'inferior-emacs-lisp-mode 'mode-class 'special)
 375
 376 (defun inferior-emacs-lisp-mode nil
 377   "Major mode for interactively evaluating Emacs Lisp expressions.
 378 Uses the interface provided by `comint-mode' (which see).
 379
 380 * \\<ielm-map>\\[ielm-send-input] evaluates the sexp following the prompt. There must be at most
 381   one top-level sexp per prompt.
 382
 383 * \\[ielm-return] inserts a newline and indents, or evaluates a
 384   complete expression (but see variable `ielm-dynamic-return').
 385   Inputs longer than one line are moved to the line following the
 386   prompt (but see variable `ielm-dynamic-multiline-inputs').
 387
 388 * \\[comint-dynamic-complete] completes Lisp symbols (or filenames, within strings),
 389   or indents the line if there is nothing to complete.
 390
 391 During evaluations, the values of the variables `*', `**', and `***'
 392 are the results of the previous, second previous and third previous
 393 evaluations respectively.
 394
 395 The current working buffer may be changed (with a call to
 396 `set-buffer', or with \\[ielm-change-working-buffer]), and its value
 397 is preserved between successive evaluations.  In this way, expressions
 398 may be evaluated in a different buffer than the *ielm* buffer.
 399 Display the name of the working buffer with \\[ielm-print-working-buffer],
 400 or the buffer itself with \\[ielm-display-working-buffer].
 401
 402 Expressions evaluated by IELM are not subject to `debug-on-quit' or
 403 `debug-on-error'.
 404
 405 The behaviour of IELM may be customised with the following variables:
 406 * To stop beeping on error, set `ielm-noisy' to nil
 407 * If you don't like the prompt, you can change it by setting `ielm-prompt'.
 408 * Set `ielm-dynamic-return' to nil for bindings like `lisp-interaction-mode'
 409 * Entry to this mode runs `comint-mode-hook' and `ielm-mode-hook'
 410  (in that order).
 411
 412 Customised bindings may be defined in `ielm-map', which currently contains:
 413 \\{ielm-map}"
 414   (interactive)
 415   (comint-mode)
 416   (setq comint-prompt-regexp (concat "^" (regexp-quote ielm-prompt)))
 417   (make-local-variable 'paragraph-start)
 418   (setq paragraph-start comint-prompt-regexp)
 419   (setq comint-input-sender 'ielm-input-sender)
 420   (setq comint-process-echoes nil)
 421   (setq comint-dynamic-complete-functions
 422         '(ielm-tab comint-replace-by-expanded-history ielm-complete-filename ielm-complete-symbol))
 423   (setq comint-get-old-input 'ielm-get-old-input)
 424   (make-local-variable 'comint-completion-addsuffix)
 425   (setq comint-completion-addsuffix
 426         (cons (char-to-string directory-sep-char) ""))
 427
 428   (setq major-mode 'inferior-emacs-lisp-mode)
 429   (setq mode-name "IELM")
 430   (use-local-map ielm-map)
 431   (set-syntax-table emacs-lisp-mode-syntax-table)
 432
 433   (make-local-variable 'indent-line-function)
 434   (make-local-variable 'ielm-working-buffer)
 435   (setq ielm-working-buffer (current-buffer))
 436   (setq indent-line-function 'ielm-indent-line)
 437   (make-local-variable 'fill-paragraph-function)
 438   (setq fill-paragraph-function 'lisp-fill-paragraph)
 439
 440   ;; Value holders
 441   (setq * nil)
 442   (make-local-variable '*)
 443   (setq ** nil)
 444   (make-local-variable '**)
 445   (setq *** nil)
 446   (make-local-variable '***)
 447
 448   ;; font-lock support
 449   (make-local-variable 'font-lock-defaults)
 450   (setq font-lock-defaults
 451         '(ielm-font-lock-keywords nil nil ((?: . "w") (?- . "w") (?* . "w"))))
 452
 453   ;; A dummy process to keep comint happy. It will never get any input
 454   (if (comint-check-proc (current-buffer)) nil
 455     (start-process "ielm" (current-buffer) "cat")
 456     (process-kill-without-query (ielm-process))
 457     (goto-char (point-max))
 458     ;; Add a silly header
 459     (insert ielm-header)
 460     (ielm-set-pm (point-max))
 461     (comint-output-filter (ielm-process) ielm-prompt)
 462     (set-marker comint-last-input-start (ielm-pm))
 463     (set-process-filter (get-buffer-process (current-buffer)) 'comint-output-filter))
 464   (run-hooks 'ielm-mode-hook))
 465
 466 (defun ielm-get-old-input nil
 467   ;; Return the previous input surrounding point
 468   (save-excursion
 469     (beginning-of-line)
 470     (if (looking-at comint-prompt-regexp) nil
 471       (re-search-backward comint-prompt-regexp))
 472     (comint-skip-prompt)
 473     (buffer-substring (point) (progn (forward-sexp 1) (point)))))
 474
 475 ;;; User command
 476
 477 ;;;###autoload (add-hook 'same-window-buffer-names "*ielm*")
 478
 479 ;;;###autoload
 480 (defun ielm nil
 481   "Interactively evaluate Emacs Lisp expressions.
 482 Switches to the buffer `*ielm*', or creates it if it does not exist."
 483   (interactive)
 484   (if (comint-check-proc "*ielm*")
 485       nil
 486     (save-excursion
 487       (set-buffer (get-buffer-create "*ielm*"))
 488       (inferior-emacs-lisp-mode)))
 489   (pop-to-buffer "*ielm*"))
 490
 491 (provide 'ielm)
 492
 493 ;;; ielm.el ends here