code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.60)
  24
  25 m4_define(PA_MAJOR, [0])
  26 m4_define(PA_MINOR, [9])
  27 m4_define(PA_MICRO, [11])
  28
  29 AC_INIT([pulseaudio], PA_MAJOR.PA_MINOR.PA_MICRO,[mzchyfrnhqvb (at) 0pointer (dot) net])
  30 AC_CONFIG_SRCDIR([src/daemon/main.c])
  31 AC_CONFIG_HEADERS([config.h])
  32 AM_INIT_AUTOMAKE([foreign -Wall])
  33
  34 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  35 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  36
  37 AC_SUBST(PA_API_VERSION, 11)
  38 AC_SUBST(PA_PROTOCOL_VERSION, 13)
  39
  40 # The stable ABI for client applications, for the version info x:y:z
  41 # always will hold y=z
  42 AC_SUBST(LIBPULSE_VERSION_INFO, [5:0:5])
  43
  44 # A simplified, synchronous, ABI-stable interface for client
  45 # applications, for the version info x:y:z always will hold y=z
  46 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:1:0])
  47
  48 # The ABI-stable network browsing interface for client applications,
  49 # for the version info x:y:z always will hold y=z
  50 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  51
  52 # The ABI-stable GLib adapter for client applications, for the version
  53 # info x:y:z always will hold y=z
  54 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:3:0])
  55
  56 # An internally used, ABI-unstable library that contains the
  57 # PulseAudio core, SONAMEs are bumped on every release, version info
  58 # suffix will always be 0:0
  59 AC_SUBST(LIBPULSECORE_VERSION_INFO, [6:0:0])
  60
  61 AC_CANONICAL_HOST
  62
  63 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  64    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  65    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  66 fi
  67
  68 #### Platform hacks ####
  69
  70 case $host in
  71    *-*-solaris* )
  72       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  73       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  74       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  75       ;;
  76 esac
  77
  78 #### Checks for programs. ####
  79
  80 # mkdir -p
  81
  82 AC_PROG_MKDIR_P
  83
  84 # CC
  85
  86 AC_PROG_CC
  87 AM_PROG_CC_C_O
  88 AC_PROG_GCC_TRADITIONAL
  89 AC_GNU_SOURCE
  90
  91 # M4
  92
  93 AC_PATH_PROG([M4], [m4 gm4], [no])
  94 if test "x$M4" = xno ; then
  95    AC_MSG_ERROR([m4 missing])
  96 fi
  97
  98 # GCC flags
  99
 100 test_gcc_flag() {
 101     AC_LANG_CONFTEST([int main(int argc, char*argv[]) {}])
 102     $CC -c conftest.c $CFLAGS -o conftest.o > /dev/null 2> /dev/null
 103     ret=$?
 104     rm -f conftest.o
 105     return $ret
 106 }
 107
 108 # If using GCC specify some additional parameters
 109 if test "x$GCC" = "xyes" ; then
 110
 111     # We use gnu99 instead of c99 because many have interpreted the standard
 112     # in a way that int64_t isn't defined on non-64 bit platforms.
 113     DESIRED_FLAGS="-std=gnu99 -Wall -W -Wextra -pedantic -pipe -Wformat -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Winline -Wno-unused-parameter -ffast-math"
 114
 115     for flag in $DESIRED_FLAGS ; do
 116         AC_MSG_CHECKING([whether $CC accepts $flag])
 117         if test_gcc_flag $flag ; then
 118            CFLAGS="$CFLAGS $flag"
 119            AC_MSG_RESULT([yes])
 120         else
 121            AC_MSG_RESULT([no])
 122         fi
 123     done
 124 fi
 125
 126 # Native atomic operation support
 127 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 128     AC_HELP_STRING([--disable-atomic-arm-linux-helpers], [use inline asm or libatomic_ops instead]),
 129         [
 130             case "${enableval}" in
 131                 yes) atomic_arm_linux_helpers=yes ;;
 132                 no) atomic_arm_linux_helpers=no ;;
 133                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 134             esac
 135         ],
 136         [atomic_arm_linux_helpers=auto])
 137
 138 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 139     AC_HELP_STRING([--enable-atomic-arm-memory-barrier], [only really needed in SMP arm systems]),
 140         [
 141             case "${enableval}" in
 142                 yes) AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers]) ;;
 143                 no) ;;
 144                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 145             esac
 146         ],)
 147
 148 AC_MSG_CHECKING([target operating system])
 149 case $host in
 150         *-*-linux*)
 151             AC_MSG_RESULT([linux])
 152             pulse_target_os=linux
 153         ;;
 154         *)
 155             AC_MSG_RESULT([unknown])
 156             pulse_target_os=unknown
 157         ;;
 158 esac
 159
 160 # If everything else fails use libatomic_ops
 161 need_libatomic_ops=yes
 162
 163 AC_MSG_CHECKING([whether $CC knows __sync_bool_compare_and_swap()])
 164 AC_LANG_CONFTEST([int main() { int a = 4; __sync_bool_compare_and_swap(&a, 4, 5); }])
 165 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 166 ret=$?
 167 rm -f conftest.o conftest
 168 if test $ret -eq 0 ; then
 169     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 170     AC_MSG_RESULT([yes])
 171     need_libatomic_ops=no
 172 else
 173     AC_MSG_RESULT([no])
 174     # HW specific atomic ops stuff
 175     AC_MSG_CHECKING([architecture for native atomic operations])
 176     case $host_cpu in
 177         arm*)
 178             AC_MSG_RESULT([arm])
 179             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 180             # The Linux kernel helper functions have been there since 2.6.16. However
 181             # compile time checking for kernel version in cross compile environment
 182             # (which is usually the case for arm cpu) is tricky (or impossible).
 183             if test "x$pulse_target_os" = "xlinux" && test "x$atomic_arm_linux_helpers" != "xno"; then
 184                 AC_MSG_RESULT([yes])
 185                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 186                 need_libatomic_ops=no
 187             else
 188                AC_MSG_RESULT([no])
 189                AC_MSG_CHECKING([compiler support for arm inline asm atomic operations])
 190                AC_LANG_CONFTEST([[int main()
 191                {
 192                    volatile int a=0;
 193                    int o=0, n=1, r;
 194                    asm volatile ("ldrex %0, [%1]\n"
 195                                  "subs  %0, %0, %2\n"
 196                                  "strexeq %0, %3, [%1]\n"
 197                                  : "=&r" (r)
 198                                  : "r" (&a), "Ir" (o), "r" (n)
 199                                  : "cc");
 200                    return (a==1 ? 0 : -1);
 201                }]])
 202                $CC conftest.c $CFLAGS -o conftest > /dev/null 2>&1
 203                ret=$?
 204                rm -f conftest.o conftest
 205                if test $ret -eq 0 ; then
 206                    AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARMv6 instructions.])
 207                    AC_MSG_RESULT([yes])
 208                    need_libatomic_ops=no
 209                else
 210                    AC_MSG_RESULT([no])
 211                fi
 212            fi
 213         ;;
 214         *)
 215             AC_MSG_RESULT([unknown])
 216         ;;
 217     esac
 218 fi
 219
 220 AC_MSG_CHECKING([whether $CC knows __thread])
 221 AC_LANG_CONFTEST([static __thread int a = 6; int main() { a = 5; }])
 222 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 223 ret=$?
 224 rm -f conftest.o conftest
 225 if test $ret -eq 0 ; then
 226     AC_DEFINE([HAVE_TLS_BUILTIN], 1, [Have __thread().])
 227     AC_MSG_RESULT([yes])
 228 else
 229     AC_MSG_RESULT([no])
 230 fi
 231
 232 AC_MSG_CHECKING([whether $CC knows _Bool])
 233 AC_LANG_CONFTEST([int main() { _Bool b; }])
 234 $CC conftest.c $CFLAGS -o conftest > /dev/null 2> /dev/null
 235 ret=$?
 236 rm -f conftest.o conftest
 237 if test $ret -eq 0 ; then
 238     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 239     AC_MSG_RESULT([yes])
 240 else
 241     AC_MSG_RESULT([no])
 242 fi
 243
 244 #### libtool stuff ####
 245
 246 AC_LTDL_ENABLE_INSTALL
 247 AC_LIBLTDL_INSTALLABLE
 248 AC_LIBTOOL_DLOPEN
 249 AC_LIBTOOL_WIN32_DLL
 250 AC_PROG_LIBTOOL
 251 AC_SUBST(LTDLINCL)
 252 AC_SUBST(LIBLTDL)
 253 AC_CONFIG_SUBDIRS(libltdl)
 254
 255 old_LIBS=$LIBS
 256 LIBS="$LIBS $LIBLTDL"
 257 AC_CHECK_FUNCS([lt_dlmutex_register])
 258 LIBS=$old_LIBS
 259 AC_CHECK_TYPES([struct lt_user_dlloader, lt_dladvise], , , [#include <ltdl.h>])
 260
 261 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 262     AC_MSG_ERROR([[
 263
 264         *** Cannot find the libltdl development files.
 265         *** Maybe you need to install the libltdl-dev package.
 266         ]])
 267 fi
 268
 269 #### Determine build environment ####
 270
 271 os_is_win32=0
 272
 273 case "$host_os" in
 274         mingw*)
 275         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 276         os_is_win32=1
 277                 ;;
 278         esac
 279
 280 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 281
 282 ###################################
 283 #   Basic environment checks      #
 284 ###################################
 285
 286 #### Checks for header files. ####
 287
 288 # ISO
 289 AC_HEADER_STDC
 290
 291 # POSIX
 292 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 293     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 294     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 295     syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 296 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 297                  [#include <sys/types.h>
 298                   #if HAVE_NETINET_IN_H
 299                   # include <netinet/in.h>
 300                   #endif
 301                   #if HAVE_NETINET_IN_SYSTM_H
 302                   # include <netinet/in_systm.h>
 303                   #endif
 304                  ])
 305 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 306 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 307
 308 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 309 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 310
 311 # Linux
 312 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 313
 314 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 315
 316 AC_CHECK_HEADERS([sys/prctl.h])
 317
 318 # Solaris
 319 AC_CHECK_HEADERS([sys/filio.h])
 320
 321 # Windows
 322 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 323
 324 # Other
 325 AC_CHECK_HEADERS([sys/ioctl.h])
 326 AC_CHECK_HEADERS([byteswap.h])
 327 AC_CHECK_HEADERS([sys/syscall.h])
 328
 329 #### Typdefs, structures, etc. ####
 330
 331 AC_C_CONST
 332 AC_C_BIGENDIAN
 333 AC_TYPE_PID_T
 334 AC_TYPE_SIZE_T
 335 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 336     [Define ssize_t if it is not done by the standard libs.])])
 337 AC_TYPE_OFF_T
 338 AC_TYPE_SIGNAL
 339 AC_TYPE_UID_T
 340 AC_CHECK_DECLS(environ)
 341
 342 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 343 HAVE_SIGXCPU=1
 344 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 345 ], [HAVE_SIGXCPU=0])
 346 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 347
 348 # Solaris lacks this
 349 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 350     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 351         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 352
 353 #### POSIX threads ####
 354
 355 ACX_PTHREAD
 356
 357 #### Check for libs ####
 358
 359 # ISO
 360 AC_SEARCH_LIBS([pow], [m])
 361
 362 # POSIX
 363 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 364 AC_SEARCH_LIBS([dlopen], [dl])
 365 AC_SEARCH_LIBS([shm_open], [rt])
 366 AC_SEARCH_LIBS([inet_ntop], [nsl])
 367 AC_SEARCH_LIBS([timer_create], [rt])
 368
 369 # BSD
 370 AC_SEARCH_LIBS([connect], [socket])
 371
 372 # Non-standard
 373
 374 # This magic is needed so we do not needlessly add static libs to the win32
 375 # build, disabling its ability to make dlls.
 376 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 377
 378 AC_CHECK_LIB(gdbm, gdbm_open)
 379 AC_CHECK_HEADERS(gdbm.h)
 380
 381 #### Check for functions ####
 382
 383 # ISO
 384 AC_CHECK_FUNCS([lrintf strtof])
 385
 386 # POSIX
 387 AC_FUNC_FORK
 388 AC_FUNC_GETGROUPS
 389 AC_FUNC_SELECT_ARGTYPES
 390 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 391     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 392     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 393     sigaction sleep sysconf])
 394 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 395
 396 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 397
 398 # X/OPEN
 399 AC_CHECK_FUNCS([readlink])
 400
 401 # SUSv2
 402 AC_CHECK_FUNCS([ctime_r usleep])
 403
 404 # SUSv3
 405 AC_CHECK_FUNCS([strerror_r])
 406
 407 # BSD
 408 AC_CHECK_FUNCS([lstat])
 409
 410 # Non-standard
 411
 412 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 413
 414 AC_FUNC_ALLOCA
 415
 416 AC_MSG_CHECKING([for PTHREAD_PRIO_INHERIT])
 417 AC_LANG_CONFTEST([AC_LANG_SOURCE([[
 418 #include <pthread.h>
 419 int main() { int i = PTHREAD_PRIO_INHERIT; }]])])
 420 $PTHREAD_CC conftest.c $PTHREAD_CFLAGS $CFLAGS $PTHREAD_LIBS -o conftest > /dev/null 2> /dev/null
 421 ret=$?
 422 rm -f conftest.o conftest
 423
 424 if test $ret -eq 0 ; then
 425     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 426     AC_MSG_RESULT([yes])
 427 else
 428     AC_MSG_RESULT([no])
 429 fi
 430
 431 #### Large File-Support (LFS) ####
 432
 433 AC_SYS_LARGEFILE
 434
 435 # Check for open64 to know if the current system does have open64() and similar functions
 436 AC_CHECK_FUNCS([open64])
 437
 438 #### [lib]iconv ####
 439
 440 AM_ICONV
 441
 442 ###################################
 443 #      External libraries         #
 444 ###################################
 445
 446 #### X11 (optional) ####
 447
 448 HAVE_X11=0
 449
 450 # The macro tests the host, not the build target
 451 if test "x$os_is_win32" != "x1" ; then
 452     AC_PATH_XTRA
 453     test "x$no_x" != "xyes" && HAVE_X11=1
 454 fi
 455
 456 AC_SUBST(HAVE_X11)
 457 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 458 if test "x$HAVE_X11" = "x1" ; then
 459     AC_DEFINE([HAVE_X11], 1, [Have X11])
 460 fi
 461
 462 #### Capabilities (optional) ####
 463
 464 CAP_LIBS=''
 465
 466 AC_ARG_WITH(
 467         [caps],
 468         AC_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 469
 470 if test "x${with_caps}" != "xno"; then
 471     AC_SEARCH_LIBS([cap_init], [cap], [], [
 472                     if test "x${with_caps}" = "xyes" ; then
 473                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 474                     fi])
 475     AC_CHECK_HEADERS([sys/capability.h], [], [
 476                     if test "x${with_caps}" = "xyes" ; then
 477                         AC_MSG_ERROR([*** POSIX caps headers not found])
 478                     fi])
 479 fi
 480
 481 #### pkg-config ####
 482
 483 # Check for pkg-config manually first, as if its not installed the
 484 # PKG_PROG_PKG_CONFIG macro won't be defined.
 485 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 486
 487 if test x"$have_pkg_config" = "xno"; then
 488     AC_MSG_ERROR(pkg-config is required to install this program)
 489 fi
 490
 491 PKG_PROG_PKG_CONFIG
 492
 493 #### Sound file ####
 494
 495 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 496 AC_SUBST(LIBSNDFILE_CFLAGS)
 497 AC_SUBST(LIBSNDFILE_LIBS)
 498
 499 #### atomic-ops ###
 500
 501 AC_MSG_CHECKING([whether we need libatomic_ops])
 502 if test "x$need_libatomic_ops" = "xyes"; then
 503    AC_MSG_RESULT([yes])
 504    AC_CHECK_HEADERS([atomic_ops.h], [], [
 505    AC_MSG_ERROR([*** libatomic-ops headers not found])
 506    ])
 507
 508    # Win32 does not need the lib and breaks horribly if we try to include it
 509    if test "x$os_is_win32" != "x1" ; then
 510        LIBS="$LIBS -latomic_ops"
 511    fi
 512 else
 513    AC_MSG_RESULT([no])
 514 fi
 515
 516 #### Libsamplerate support (optional) ####
 517
 518 AC_ARG_ENABLE([samplerate],
 519     AC_HELP_STRING([--disable-samplerate], [Disable optional libsamplerate support]),
 520         [
 521             case "${enableval}" in
 522                 yes) samplerate=yes ;;
 523                 no) samplerate=no ;;
 524                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 525             esac
 526         ],
 527         [samplerate=auto])
 528
 529 if test "x${samplerate}" != xno ; then
 530     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 531         HAVE_LIBSAMPLERATE=1,
 532         [
 533             HAVE_LIBSAMPLERATE=0
 534             if test "x$samplerate" = xyes ; then
 535                 AC_MSG_ERROR([*** Libsamplerate not found])
 536             fi
 537         ])
 538 else
 539     HAVE_LIBSAMPLERATE=0
 540 fi
 541
 542 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 543    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 544 fi
 545
 546 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 547 AC_SUBST(LIBSAMPLERATE_LIBS)
 548 AC_SUBST(HAVE_LIBSAMPLERATE)
 549 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 550
 551 #### OSS support (optional) ####
 552
 553 AC_ARG_ENABLE([oss],
 554     AC_HELP_STRING([--disable-oss], [Disable optional OSS support]),
 555         [
 556             case "${enableval}" in
 557                 yes) oss=yes ;;
 558                 no) oss=no ;;
 559                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 560             esac
 561         ],
 562         [oss=auto])
 563
 564 if test "x${oss}" != xno ; then
 565     AC_CHECK_HEADERS([sys/soundcard.h],
 566         [
 567             HAVE_OSS=1
 568             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 569         ],
 570         [
 571             HAVE_OSS=0
 572             if test "x$oss" = xyes ; then
 573                 AC_MSG_ERROR([*** OSS support not found])
 574             fi
 575         ])
 576 else
 577     HAVE_OSS=0
 578 fi
 579
 580 AC_SUBST(HAVE_OSS)
 581 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 582
 583
 584 #### ALSA support (optional) ####
 585
 586 AC_ARG_ENABLE([alsa],
 587     AC_HELP_STRING([--disable-alsa], [Disable optional ALSA support]),
 588         [
 589             case "${enableval}" in
 590                 yes) alsa=yes ;;
 591                 no) alsa=no ;;
 592                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 593             esac
 594         ],
 595         [alsa=auto])
 596
 597 if test "x${alsa}" != xno ; then
 598     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.16 ],
 599         [
 600             HAVE_ALSA=1
 601             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 602         ],
 603         [
 604             HAVE_ALSA=0
 605             if test "x$alsa" = xyes ; then
 606                 AC_MSG_ERROR([*** ALSA support not found])
 607             fi
 608         ])
 609 else
 610     HAVE_ALSA=0
 611 fi
 612
 613 AC_SUBST(ASOUNDLIB_CFLAGS)
 614 AC_SUBST(ASOUNDLIB_LIBS)
 615 AC_SUBST(HAVE_ALSA)
 616 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 617
 618 #### Solaris audio support (optional) ####
 619
 620 AC_ARG_ENABLE([solaris],
 621     AC_HELP_STRING([--disable-solaris], [Disable optional Solaris audio support]),
 622         [
 623             case "${enableval}" in
 624                 yes) solaris=yes ;;
 625                 no) solaris=no ;;
 626                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 627             esac
 628         ],
 629         [solaris=auto])
 630
 631 if test "x${solaris}" != xno ; then
 632     AC_CHECK_HEADERS([sys/audio.h],
 633         [
 634             HAVE_SOLARIS=1
 635             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 636         ],
 637         [
 638             HAVE_SOLARIS=0
 639             if test "x$solaris" = xyes ; then
 640                 AC_MSG_ERROR([*** Solaris audio support not found])
 641             fi
 642         ])
 643 else
 644     HAVE_SOLARIS=0
 645 fi
 646
 647 AC_SUBST(HAVE_SOLARIS)
 648 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 649
 650 #### GLib 2 support (optional) ####
 651
 652 AC_ARG_ENABLE([glib2],
 653     AC_HELP_STRING([--disable-glib2], [Disable optional GLib 2 support]),
 654         [
 655             case "${enableval}" in
 656                 yes) glib2=yes ;;
 657                 no) glib2=no ;;
 658                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 659             esac
 660         ],
 661         [glib2=auto])
 662
 663 if test "x${glib2}" != xno ; then
 664     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 665         HAVE_GLIB20=1,
 666         [
 667             HAVE_GLIB20=0
 668             if test "x$glib2" = xyes ; then
 669                 AC_MSG_ERROR([*** GLib 2 support not found])
 670             fi
 671         ])
 672 else
 673     HAVE_GLIB20=0
 674 fi
 675
 676 AC_SUBST(GLIB20_CFLAGS)
 677 AC_SUBST(GLIB20_LIBS)
 678 AC_SUBST(HAVE_GLIB20)
 679 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 680
 681 #### GConf support (optional) ####
 682
 683 AC_ARG_ENABLE([gconf],
 684     AC_HELP_STRING([--disable-gconf], [Disable optional GConf support]),
 685         [
 686             case "${enableval}" in
 687                 yes) gconf=yes ;;
 688                 no) gconf=no ;;
 689                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 690             esac
 691         ],
 692         [glib=auto])
 693
 694 if test "x${gconf}" != xno ; then
 695     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 696         HAVE_GCONF=1,
 697         [
 698             HAVE_GCONF=0
 699             if test "x$gconf" = xyes ; then
 700                 AC_MSG_ERROR([*** GConf support not found])
 701             fi
 702         ])
 703 else
 704     HAVE_GCONF=0
 705 fi
 706
 707 AC_SUBST(GCONF_CFLAGS)
 708 AC_SUBST(GCONF_LIBS)
 709 AC_SUBST(HAVE_GCONF)
 710 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 711
 712 #### Avahi support (optional) ####
 713
 714 AC_ARG_ENABLE([avahi],
 715     AC_HELP_STRING([--disable-avahi], [Disable optional Avahi support]),
 716         [
 717             case "${enableval}" in
 718                 yes) avahi=yes ;;
 719                 no) avahi=no ;;
 720                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 721             esac
 722         ],
 723         [avahi=auto])
 724
 725 if test "x${avahi}" != xno ; then
 726     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 727         HAVE_AVAHI=1,
 728         [
 729                 HAVE_AVAHI=0
 730                 if test "x$avahi" = xyes ; then
 731                         AC_MSG_ERROR([*** Avahi support not found])
 732                 fi
 733         ])
 734 else
 735     HAVE_AVAHI=0
 736 fi
 737
 738 AC_SUBST(AVAHI_CFLAGS)
 739 AC_SUBST(AVAHI_LIBS)
 740 AC_SUBST(HAVE_AVAHI)
 741 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 742
 743 ### LIBOIL ####
 744
 745 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 746 AC_SUBST(LIBOIL_CFLAGS)
 747 AC_SUBST(LIBOIL_LIBS)
 748
 749 ### JACK (optional) ####
 750
 751 AC_ARG_ENABLE([jack],
 752     AC_HELP_STRING([--disable-jack], [Disable optional JACK support]),
 753         [
 754             case "${enableval}" in
 755                 yes) jack=yes ;;
 756                 no) jack=no ;;
 757                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 758             esac
 759         ],
 760         [jack=auto])
 761
 762 if test "x${jack}" != xno ; then
 763     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 764         HAVE_JACK=1,
 765         [
 766             HAVE_JACK=0
 767             if test "x$jack" = xyes ; then
 768                 AC_MSG_ERROR([*** JACK support not found])
 769             fi
 770         ])
 771 else
 772     HAVE_JACK=0
 773 fi
 774
 775 AC_SUBST(JACK_CFLAGS)
 776 AC_SUBST(JACK_LIBS)
 777 AC_SUBST(HAVE_JACK)
 778 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 779
 780 #### Async DNS support (optional) ####
 781
 782 AC_ARG_ENABLE([asyncns],
 783     AC_HELP_STRING([--disable-asyncns], [Disable optional Async DNS support]),
 784         [
 785             case "${enableval}" in
 786                 yes) asyncns=yes ;;
 787                 no) asyncns=no ;;
 788                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 789             esac
 790         ],
 791         [asyncns=auto])
 792
 793 if test "x${asyncns}" != xno ; then
 794     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 795         HAVE_LIBASYNCNS=1,
 796         [
 797             HAVE_LIBASYNCNS=0
 798             if test "x$asyncns" = xyes ; then
 799                 AC_MSG_ERROR([*** Async DNS support not found])
 800             fi
 801         ])
 802 else
 803     HAVE_LIBASYNCNS=0
 804 fi
 805
 806 AC_SUBST(LIBASYNCNS_CFLAGS)
 807 AC_SUBST(LIBASYNCNS_LIBS)
 808 AC_SUBST(HAVE_LIBASYNCNS)
 809 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 810
 811 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 812    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 813 fi
 814
 815 #### TCP wrappers (optional) ####
 816
 817 AC_ARG_ENABLE([tcpwrap],
 818     AC_HELP_STRING([--disable-tcpwrap], [Disable optional TCP wrappers support]),
 819         [
 820             case "${enableval}" in
 821                 yes) tcpwrap=yes ;;
 822                 no) tcpwrap=no ;;
 823                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 824             esac
 825         ],
 826         [tcpwrap=auto])
 827
 828 if test "x${tcpwrap}" != xno ; then
 829     ACX_LIBWRAP
 830     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 831         AC_MSG_ERROR([*** TCP wrappers support not found])
 832     fi
 833 else
 834     LIBWRAP_LIBS=
 835 fi
 836
 837 AC_SUBST(LIBWRAP_LIBS)
 838
 839 #### LIRC support (optional) ####
 840
 841 AC_ARG_ENABLE([lirc],
 842     AC_HELP_STRING([--disable-lirc], [Disable optional LIRC support]),
 843         [
 844             case "${enableval}" in
 845                 yes) lirc=yes ;;
 846                 no) lirc=no ;;
 847                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 848             esac
 849         ],
 850         [lirc=auto])
 851
 852 if test "x${lirc}" != xno ; then
 853     ACX_LIRC
 854     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 855         AC_MSG_ERROR([*** LIRC support not found])
 856     fi
 857 else
 858     HAVE_LIRC=0
 859 fi
 860
 861 AC_SUBST(LIRC_CFLAGS)
 862 AC_SUBST(LIRC_LIBS)
 863 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 864
 865 #### HAL support (optional) ####
 866
 867 AC_ARG_ENABLE([hal],
 868     AC_HELP_STRING([--disable-hal], [Disable optional HAL support]),
 869         [
 870             case "${enableval}" in
 871                 yes) hal=yes ;;
 872                 no) hal=no ;;
 873                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 874             esac
 875         ],
 876         [hal=auto])
 877 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 878     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 879         HAVE_HAL=1,
 880         [
 881             HAVE_HAL=0
 882             if test "x$hal" = xyes ; then
 883                 AC_MSG_ERROR([*** HAL support not found])
 884             fi
 885         ])
 886 else
 887     HAVE_HAL=0
 888 fi
 889
 890 AC_SUBST(HAL_CFLAGS)
 891 AC_SUBST(HAL_LIBS)
 892 AC_SUBST(HAVE_HAL)
 893 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 894
 895 #### BlueZ support (optional) ####
 896
 897 AC_ARG_ENABLE([bluez],
 898     AC_HELP_STRING([--disable-bluez], [Disable optional BlueZ support]),
 899         [
 900             case "${enableval}" in
 901                 yes) bluez=yes ;;
 902                 no) bluez=no ;;
 903                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 904             esac
 905         ],
 906         [bluez=auto])
 907 if test "x${bluez}" != xno ; then
 908     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 909         HAVE_BLUEZ=1,
 910         [
 911             HAVE_BLUEZ=0
 912             if test "x$bluez" = xyes ; then
 913                 AC_MSG_ERROR([*** BLUEZ support not found])
 914             fi
 915         ])
 916 else
 917     HAVE_BLUEZ=0
 918 fi
 919
 920 AC_SUBST(BLUEZ_CFLAGS)
 921 AC_SUBST(BLUEZ_LIBS)
 922 AC_SUBST(HAVE_BLUEZ)
 923 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 924
 925 #### D-Bus support (optional) ####
 926
 927 AC_ARG_ENABLE([dbus],
 928     AC_HELP_STRING([--disable-dbus], [Disable optional D-Bus support]),
 929         [
 930             case "${enableval}" in
 931                 yes) dbus=yes ;;
 932                 no) dbus=no ;;
 933                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 934             esac
 935         ],
 936         [dbus=auto])
 937
 938 if test "x$HAVE_HAL" = x1 ; then
 939    dbus=yes
 940 fi
 941
 942 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 943
 944     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 945         [
 946             HAVE_DBUS=1
 947             saved_LIBS="$LIBS"
 948             LIBS="$LIBS $DBUS_LIBS"
 949             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 950             LIBS="$saved_LIBS"
 951             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 952         ],
 953         [
 954             HAVE_DBUS=0
 955             if test "x$dbus" = xyes ; then
 956                 AC_MSG_ERROR([*** D-Bus support not found])
 957             fi
 958         ])
 959 else
 960     HAVE_DBUS=0
 961 fi
 962
 963 AC_SUBST(DBUS_CFLAGS)
 964 AC_SUBST(DBUS_LIBS)
 965 AC_SUBST(HAVE_DBUS)
 966 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 967
 968 #### PolicyKit support (optional) ####
 969
 970 AC_ARG_ENABLE([polkit],
 971     AC_HELP_STRING([--disable-polkit], [Disable optional PolicyKit support]),
 972         [
 973             case "${enableval}" in
 974                 yes) polkit=yes ;;
 975                 no) polkit=no ;;
 976                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
 977             esac
 978         ],
 979         [polkit=auto])
 980
 981 if test "x${polkit}" != xno ; then
 982
 983     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus >= 0.7 ],
 984         [
 985             HAVE_POLKIT=1
 986             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
 987             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
 988             AC_SUBST(policydir)
 989         ],
 990         [
 991             HAVE_POLKIT=0
 992             if test "x$polkit" = xyes ; then
 993                 AC_MSG_ERROR([*** PolicyKit support not found])
 994             fi
 995         ])
 996 else
 997     HAVE_POLKIT=0
 998 fi
 999
1000 AC_SUBST(POLKIT_CFLAGS)
1001 AC_SUBST(POLKIT_LIBS)
1002 AC_SUBST(HAVE_POLKIT)
1003 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
1004
1005 ### Build and Install man pages ###
1006 AC_ARG_ENABLE(manpages,
1007         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
1008 [case "${enableval}" in
1009   yes) manpages=yes ;;
1010   no)  manpages=no ;;
1011   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
1012 esac],[manpages=yes])
1013
1014 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1015
1016 #### PulseAudio system group & user  #####
1017
1018 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1019 if test -z "$with_system_user" ; then
1020     PA_SYSTEM_USER=pulse
1021 else
1022     PA_SYSTEM_USER=$with_system_user
1023 fi
1024 AC_SUBST(PA_SYSTEM_USER)
1025 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1026
1027 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1028 if test -z "$with_system_group" ; then
1029     PA_SYSTEM_GROUP=pulse
1030 else
1031     PA_SYSTEM_GROUP=$with_system_group
1032 fi
1033 AC_SUBST(PA_SYSTEM_GROUP)
1034 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1035
1036 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
1037 if test -z "$with_realtime_group" ; then
1038     PA_REALTIME_GROUP=pulse-rt
1039 else
1040     PA_REALTIME_GROUP=$with_realtime_group
1041 fi
1042 AC_SUBST(PA_REALTIME_GROUP)
1043 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
1044
1045 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1046 if test -z "$with_access_group" ; then
1047     PA_ACCESS_GROUP=pulse-access
1048 else
1049     PA_ACCESS_GROUP=$with_access_group
1050 fi
1051 AC_SUBST(PA_ACCESS_GROUP)
1052 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1053
1054 AC_ARG_ENABLE(
1055         per_user_esound_socket,
1056         AS_HELP_STRING([--disable-per-user-esound-socket], [Use global esound socket directory /tmp/.esd/socket.]),
1057         [
1058             case "${enableval}" in
1059                 yes) per_user_esound_socket=1 ;;
1060                 no) per_user_esound_socket=0 ;;
1061                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-per-user-esound-socket) ;;
1062             esac
1063         ],
1064         [per_user_esound_socket=1])
1065
1066 if test "x$per_user_esound_socket" = "x1"; then
1067    AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1068 fi
1069
1070 #### PulseAudio system runtime dir ####
1071 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1072 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1073 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1074 AC_SUBST(PA_SYSTEM_CONFIG_PATH)
1075 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1076 AC_SUBST(PA_SYSTEM_STATE_PATH)
1077
1078 ###################################
1079 #            Output               #
1080 ###################################
1081
1082 AC_ARG_ENABLE(
1083         [static-bins],
1084         AC_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1085         [STATIC_BINS=1], [STATIC_BINS=0])
1086 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1087
1088 AC_ARG_WITH(
1089         [preopen-mods],
1090         AC_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1091         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1092 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1093 if test "x$PREOPEN_MODS" != "xall" ; then
1094     tmpLIBS=""
1095     for mod in $PREOPEN_MODS; do
1096         tmpLIBS="$tmpLIBS module-$mod.la"
1097     done
1098     PREOPEN_MODS="$tmpLIBS"
1099     AC_SUBST(PREOPEN_MODS)
1100 fi
1101
1102 AC_ARG_WITH(
1103         [module-dir],
1104         AC_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
1105         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
1106
1107 AC_SUBST(modlibexecdir)
1108
1109 AC_ARG_ENABLE(
1110         [force-preopen],
1111         AC_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1112         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
1113 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
1114
1115 AC_CONFIG_FILES([
1116 Makefile
1117 src/Makefile
1118 man/Makefile
1119 libpulse.pc
1120 libpulse-simple.pc
1121 libpulse-browse.pc
1122 libpulse-mainloop-glib.pc
1123 doxygen/Makefile
1124 doxygen/doxygen.conf
1125 src/pulse/version.h
1126 ])
1127 AC_OUTPUT
1128
1129 # ==========================================================================
1130 ENABLE_X11=no
1131 if test "x$HAVE_X11" = "x1" ; then
1132    ENABLE_X11=yes
1133 fi
1134
1135 ENABLE_OSS=no
1136 if test "x$HAVE_OSS" = "x1" ; then
1137    ENABLE_OSS=yes
1138 fi
1139
1140 ENABLE_ALSA=no
1141 if test "x$HAVE_ALSA" = "x1" ; then
1142    ENABLE_ALSA=yes
1143 fi
1144
1145 ENABLE_SOLARIS=no
1146 if test "x$HAVE_SOLARIS" = "x1" ; then
1147    ENABLE_SOLARIS=yes
1148 fi
1149
1150 ENABLE_GLIB20=no
1151 if test "x$HAVE_GLIB20" = "x1" ; then
1152    ENABLE_GLIB20=yes
1153 fi
1154
1155 ENABLE_GCONF=no
1156 if test "x$HAVE_GCONF" = "x1" ; then
1157    ENABLE_GCONF=yes
1158 fi
1159
1160 ENABLE_AVAHI=no
1161 if test "x$HAVE_AVAHI" = "x1" ; then
1162    ENABLE_AVAHI=yes
1163 fi
1164
1165 ENABLE_JACK=no
1166 if test "x$HAVE_JACK" = "x1" ; then
1167    ENABLE_JACK=yes
1168 fi
1169
1170 ENABLE_LIBASYNCNS=no
1171 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1172    ENABLE_LIBASYNCNS=yes
1173 fi
1174
1175 ENABLE_LIRC=no
1176 if test "x$HAVE_LIRC" = "x1" ; then
1177    ENABLE_LIRC=yes
1178 fi
1179
1180 ENABLE_HAL=no
1181 if test "x$HAVE_HAL" = "x1" ; then
1182    ENABLE_HAL=yes
1183 fi
1184
1185 ENABLE_TCPWRAP=no
1186 if test "x${LIBWRAP_LIBS}" != x ; then
1187    ENABLE_TCPWRAP=yes
1188 fi
1189
1190 ENABLE_LIBSAMPLERATE=no
1191 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1192    ENABLE_LIBSAMPLERATE=yes
1193 fi
1194
1195 ENABLE_BLUEZ=no
1196 if test "x${HAVE_BLUEZ}" = "x1" ; then
1197    ENABLE_BLUEZ=yes
1198 fi
1199
1200 ENABLE_POLKIT=no
1201 if test "x${HAVE_POLKIT}" = "x1" ; then
1202    ENABLE_POLKIT=yes
1203 fi
1204
1205 ENABLE_PER_USER_ESOUND_SOCKET=no
1206 if test "x$per_user_esound_socket" = "x1" ; then
1207    ENABLE_PER_USER_ESOUND_SOCKET=yes
1208 fi
1209
1210 echo "
1211  ---{ $PACKAGE_NAME $VERSION }---
1212
1213     prefix:                        ${prefix}
1214     sysconfdir:                    ${sysconfdir}
1215     localstatedir:                 ${localstatedir}
1216     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1217     System State Path:             ${PA_SYSTEM_STATE_PATH}
1218     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1219     Compiler:                      ${CC}
1220     CFLAGS:                        ${CFLAGS}
1221     Have X11:                      ${ENABLE_X11}
1222     Enable OSS:                    ${ENABLE_OSS}
1223     Enable Alsa:                   ${ENABLE_ALSA}
1224     Enable Solaris:                ${ENABLE_SOLARIS}
1225     Enable GLib 2.0:               ${ENABLE_GLIB20}
1226     Enable GConf:                  ${ENABLE_GCONF}
1227     Enable Avahi:                  ${ENABLE_AVAHI}
1228     Enable Jack:                   ${ENABLE_JACK}
1229     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1230     Enable LIRC:                   ${ENABLE_LIRC}
1231     Enable HAL:                    ${ENABLE_HAL}
1232     Enable BlueZ:                  ${ENABLE_BLUEZ}
1233     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1234     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1235     Enable PolicyKit:              ${ENABLE_POLKIT}
1236     System User:                   ${PA_SYSTEM_USER}
1237     System Group:                  ${PA_SYSTEM_GROUP}
1238     Realtime Group:                ${PA_REALTIME_GROUP}
1239     Access Group:                  ${PA_ACCESS_GROUP}
1240     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1241 "