code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.63)
  24
  25 m4_define(PA_MAJOR, [0])
  26 m4_define(PA_MINOR, [9])
  27 m4_define(PA_MICRO, [15])
  28
  29 AC_INIT([pulseaudio],[PA_MAJOR.PA_MINOR.PA_MICRO],[mzchyfrnhqvb (at) 0pointer (dot) net])
  30 AC_CONFIG_SRCDIR([src/daemon/main.c])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_HEADERS([config.h])
  33 AM_INIT_AUTOMAKE([foreign 1.10 -Wall])
  34
  35 AC_SUBST(PA_MAJORMINOR, PA_MAJOR.PA_MINOR)
  36 AC_SUBST(PA_MAJORMINORMICRO, PA_MAJOR.PA_MINOR.PA_MICRO)
  37 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  38
  39 AC_SUBST(PA_API_VERSION, 12)
  40 AC_SUBST(PA_PROTOCOL_VERSION, 15)
  41
  42 # The stable ABI for client applications, for the version info x:y:z
  43 # always will hold y=z
  44 AC_SUBST(LIBPULSE_VERSION_INFO, [7:1:7])
  45
  46 # A simplified, synchronous, ABI-stable interface for client
  47 # applications, for the version info x:y:z always will hold y=z
  48 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:2:0])
  49
  50 # The ABI-stable network browsing interface for client applications,
  51 # for the version info x:y:z always will hold y=z
  52 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  53
  54 # The ABI-stable GLib adapter for client applications, for the version
  55 # info x:y:z always will hold y=z
  56 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
  57
  58 AC_CANONICAL_HOST
  59 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  60
  61 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  62    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  63    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  64 fi
  65
  66 #### Platform hacks ####
  67
  68 case $host in
  69    *-*-solaris* )
  70       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  71       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  72       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  73       ;;
  74 esac
  75
  76 #### Checks for programs. ####
  77
  78 # mkdir -p
  79
  80 AC_PROG_MKDIR_P
  81
  82 # CC
  83
  84 AC_PROG_CC
  85 AC_PROG_CC_C99
  86 AM_PROG_CC_C_O
  87 AC_PROG_GCC_TRADITIONAL
  88 AC_USE_SYSTEM_EXTENSIONS
  89
  90 # M4
  91
  92 AC_PATH_PROG([M4], [m4 gm4], [no])
  93 if test "x$M4" = xno ; then
  94    AC_MSG_ERROR([m4 missing])
  95 fi
  96
  97 dnl Compiler flags
  98 DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wno-long-long -Winline -Wvla -Wno-overlength-strings -Wunsafe-loop-optimizations -Wundef -Wformat=2 -Wlogical-op -Wsign-compare -Wpacked -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wpointer-arith -Winit-self -Wdeclaration-after-statement -Wfloat-equal -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-declarations -Wmissing-noreturn -Wshadow -Wendif-labels -Wcast-align -Wstrict-aliasing=2 -Wwrite-strings -Wno-unused-parameter -ffast-math -Wp,-D_FORTIFY_SOURCE=2 -fno-common -fdiagnostics-show-option"
  99
 100 for flag in $DESIRED_FLAGS ; do
 101   CC_CHECK_CFLAGS([$flag], [CFLAGS="$CFLAGS $flag"])
 102 done
 103
 104 # Native atomic operation support
 105 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 106     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]),
 107         [
 108             case "${enableval}" in
 109                 yes) atomic_arm_linux_helpers=yes ;;
 110                 no) atomic_arm_linux_helpers=no ;;
 111                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 112             esac
 113         ],
 114         [atomic_arm_linux_helpers=auto])
 115
 116 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 117     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]),
 118         [
 119             case "${enableval}" in
 120                 yes) AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers]) ;;
 121                 no) ;;
 122                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 123             esac
 124         ],)
 125
 126 AC_MSG_CHECKING([target operating system])
 127 case $host in
 128         *-*-linux*)
 129             AC_MSG_RESULT([linux])
 130             pulse_target_os=linux
 131         ;;
 132         *)
 133             AC_MSG_RESULT([unknown])
 134             pulse_target_os=unknown
 135         ;;
 136 esac
 137
 138 # If everything else fails use libatomic_ops
 139 need_libatomic_ops=yes
 140
 141 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 142   pulseaudio_cv_sync_bool_compare_and_swap,
 143   [AC_LINK_IFELSE(
 144      AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 145      [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 146      [pulseaudio_cv_sync_bool_compare_and_swap=no])
 147   ])
 148
 149 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 150     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 151     need_libatomic_ops=no
 152 else
 153     # HW specific atomic ops stuff
 154     AC_MSG_CHECKING([architecture for native atomic operations])
 155     case $host_cpu in
 156         arm*)
 157             AC_MSG_RESULT([arm])
 158             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 159             # The Linux kernel helper functions have been there since 2.6.16. However
 160             # compile time checking for kernel version in cross compile environment
 161             # (which is usually the case for arm cpu) is tricky (or impossible).
 162             if test "x$pulse_target_os" = "xlinux" && test "x$atomic_arm_linux_helpers" != "xno"; then
 163                 AC_MSG_RESULT([yes])
 164                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 165                 need_libatomic_ops=no
 166             else
 167                AC_MSG_RESULT([no])
 168                AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 169                  pulseaudio_cv_support_arm_atomic_ops,
 170                  [AC_COMPILE_IFELSE(
 171                     AC_LANG_PROGRAM([],
 172                       [[volatile int a=0;
 173                         int o=0, n=1, r;
 174                         asm volatile ("ldrex    %0, [%1]\n"
 175                                          "subs  %0, %0, %2\n"
 176                                          "strexeq %0, %3, [%1]\n"
 177                                          : "=&r" (r)
 178                                          : "r" (&a), "Ir" (o), "r" (n)
 179                                          : "cc");
 180                         return (a==1 ? 0 : -1);
 181                       ]]),
 182                     [pulseaudio_cv_support_arm_atomic_ops=yes],
 183                     [pulseaudio_cv_support_arm_atomic_ops=no])
 184                  ])
 185                AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 186                    AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARMv6 instructions.])
 187                    need_libatomic_ops=no
 188                  ])
 189            fi
 190         ;;
 191         *)
 192             AC_MSG_RESULT([unknown])
 193         ;;
 194     esac
 195 fi
 196
 197 CC_CHECK_TLS
 198
 199 AC_CACHE_CHECK([whether $CC knows _Bool],
 200   pulseaudio_cv__Bool,
 201   [AC_COMPILE_IFELSE(
 202      AC_LANG_PROGRAM([], [[_Bool b;]]),
 203      [pulseaudio_cv__Bool=yes],
 204      [pulseaudio_cv__Bool=no])
 205   ])
 206
 207 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], [
 208     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 209   ])
 210
 211 #### libtool stuff ####
 212 LT_PREREQ(2.2)
 213 LT_CONFIG_LTDL_DIR([libltdl])
 214 LT_INIT([dlopen win32-dll disable-static])
 215 LTDL_INIT([convenience recursive])
 216
 217 #### Determine build environment ####
 218
 219 os_is_win32=0
 220
 221 case "$host_os" in
 222         mingw*)
 223         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 224         os_is_win32=1
 225                 ;;
 226         esac
 227
 228 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 229
 230 ###################################
 231 #   Basic environment checks      #
 232 ###################################
 233
 234 #### Checks for header files. ####
 235
 236 # ISO
 237 AC_HEADER_STDC
 238
 239 # POSIX
 240 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 241     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 242     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 243     syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 244 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 245                  [#include <sys/types.h>
 246                   #if HAVE_NETINET_IN_H
 247                   # include <netinet/in.h>
 248                   #endif
 249                   #if HAVE_NETINET_IN_SYSTM_H
 250                   # include <netinet/in_systm.h>
 251                   #endif
 252                  ])
 253 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 254 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 255
 256 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 257 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 258
 259 # Linux
 260 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 261
 262 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 263
 264 AC_CHECK_HEADERS([sys/prctl.h])
 265
 266 # Solaris
 267 AC_CHECK_HEADERS([sys/filio.h])
 268
 269 # Windows
 270 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 271
 272 # Other
 273 AC_CHECK_HEADERS([sys/ioctl.h])
 274 AC_CHECK_HEADERS([byteswap.h])
 275 AC_CHECK_HEADERS([sys/syscall.h])
 276 AC_CHECK_HEADERS([sys/eventfd.h])
 277 AC_CHECK_HEADERS([execinfo.h])
 278
 279 #### Typdefs, structures, etc. ####
 280
 281 AC_C_CONST
 282 AC_C_BIGENDIAN
 283 AC_TYPE_PID_T
 284 AC_TYPE_SIZE_T
 285 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 286     [Define ssize_t if it is not done by the standard libs.])])
 287 AC_TYPE_OFF_T
 288
 289 AC_TYPE_UID_T
 290 AC_CHECK_DECLS(environ)
 291
 292 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 293 HAVE_SIGXCPU=1
 294 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 295 ], [HAVE_SIGXCPU=0])
 296 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 297
 298 # Solaris lacks this
 299 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 300     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 301         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 302
 303 #### POSIX threads ####
 304
 305 ACX_PTHREAD
 306
 307 #### Check for libs ####
 308
 309 # ISO
 310 AC_SEARCH_LIBS([pow], [m])
 311
 312 # POSIX
 313 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 314 AC_SEARCH_LIBS([dlopen], [dl])
 315 AC_SEARCH_LIBS([shm_open], [rt])
 316 AC_SEARCH_LIBS([inet_ntop], [nsl])
 317 AC_SEARCH_LIBS([timer_create], [rt])
 318
 319 # BSD
 320 AC_SEARCH_LIBS([connect], [socket])
 321
 322 # Non-standard
 323
 324 # This magic is needed so we do not needlessly add static libs to the win32
 325 # build, disabling its ability to make dlls.
 326 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 327
 328 AC_CHECK_LIB(gdbm, gdbm_open)
 329 AC_CHECK_HEADERS(gdbm.h, [], [AC_MSG_ERROR([gdbm.h not found])])
 330
 331 #### Check for functions ####
 332
 333 # ISO
 334 AC_CHECK_FUNCS([lrintf strtof])
 335
 336 # POSIX
 337 AC_FUNC_FORK
 338 AC_FUNC_GETGROUPS
 339 AC_FUNC_SELECT_ARGTYPES
 340 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 341     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 342     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 343     sigaction sleep sysconf])
 344 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 345
 346 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 347
 348 # X/OPEN
 349 AC_CHECK_FUNCS([readlink])
 350
 351 # SUSv2
 352 AC_CHECK_FUNCS([ctime_r usleep])
 353
 354 # SUSv3
 355 AC_CHECK_FUNCS([strerror_r])
 356
 357 # BSD
 358 AC_CHECK_FUNCS([lstat])
 359
 360 # Non-standard
 361
 362 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 363
 364 AC_FUNC_ALLOCA
 365
 366 AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 367   pulseaudio_cv_PTHREAD_PRIO_INHERIT,
 368   [save_CC=$CC; CC=$PTHREAD_CC
 369    save_CFLAGS=$CFLAGS; CFLAGS=$PTHREAD_CFLAGS
 370    save_LIBS=$LIBS; LIBS=$PTHREAD_LIBS
 371    AC_LINK_IFELSE(
 372      AC_LANG_PROGRAM(
 373        [[
 374          #include <pthread.h>
 375        ]],
 376        [[int i = PTHREAD_PRIO_INHERIT;]]),
 377      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=yes],
 378      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=no])
 379    CC=$save_CC
 380    CFLAGS=$save_CFLAGS
 381    LIBS=$save_LIBS
 382   ])
 383
 384 AS_IF([test "$pulseaudio_cv_PTHREAD_PRIO_INHERIT" = "yes"], [
 385     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 386   ])
 387
 388 AC_DEFINE_UNQUOTED(PA_CFLAGS,"$CFLAGS", [The CFLAGS used during compilation])
 389
 390 #### Large File-Support (LFS) ####
 391
 392 AC_SYS_LARGEFILE
 393
 394 # Check for open64 to know if the current system does have open64() and similar functions
 395 AC_CHECK_FUNCS([open64])
 396
 397 #### [lib]iconv ####
 398
 399 AM_ICONV
 400
 401 IT_PROG_INTLTOOL([0.35.0])
 402 GETTEXT_PACKAGE=pulseaudio
 403 AC_SUBST([GETTEXT_PACKAGE])
 404 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 405 AM_GLIB_GNU_GETTEXT
 406
 407 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 408 AC_SUBST(pulselocaledir)
 409
 410 ###################################
 411 #      External libraries         #
 412 ###################################
 413
 414 #### pkg-config ####
 415
 416 # Check for pkg-config manually first, as if its not installed the
 417 # PKG_PROG_PKG_CONFIG macro won't be defined.
 418 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 419
 420 if test x"$have_pkg_config" = "xno"; then
 421     AC_MSG_ERROR(pkg-config is required to install this program)
 422 fi
 423
 424 PKG_PROG_PKG_CONFIG
 425
 426 #### X11 (optional) ####
 427
 428 AC_ARG_ENABLE([x11],
 429     AS_HELP_STRING([--disable-x11],[Disable optional X11 support]),
 430         [
 431             case "${enableval}" in
 432                 yes) x11=yes ;;
 433                 no) x11=no ;;
 434                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-x11) ;;
 435             esac
 436         ],
 437         [x11=auto])
 438
 439 if test "x${x11}" != xno ; then
 440     PKG_CHECK_MODULES(X11, [ x11 ice sm ],
 441         HAVE_X11=1,
 442         [
 443             HAVE_X11=0
 444             if test "x$x11" = xyes ; then
 445                 AC_MSG_ERROR([*** X11 not found])
 446             fi
 447         ])
 448 else
 449     HAVE_X11=0
 450 fi
 451
 452 if test "x${HAVE_X11}" = x1 ; then
 453    AC_DEFINE([HAVE_X11], 1, [Have X11?])
 454 fi
 455
 456 AC_SUBST(X11_CFLAGS)
 457 AC_SUBST(X11_LIBS)
 458 AC_SUBST(HAVE_X11)
 459 AM_CONDITIONAL([HAVE_X11], [test "x$HAVE_X11" = x1])
 460
 461 #### Capabilities (optional) ####
 462
 463 CAP_LIBS=''
 464
 465 AC_ARG_WITH(
 466         [caps],
 467         AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 468
 469 if test "x${with_caps}" != "xno"; then
 470     AC_SEARCH_LIBS([cap_init], [cap], [], [
 471                     if test "x${with_caps}" = "xyes" ; then
 472                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 473                     fi])
 474     AC_CHECK_HEADERS([sys/capability.h], [], [
 475                     if test "x${with_caps}" = "xyes" ; then
 476                         AC_MSG_ERROR([*** POSIX caps headers not found])
 477                     fi])
 478 fi
 479
 480 #### Valgrind (optional) ####
 481
 482 AC_CHECK_HEADERS([valgrind/memcheck.h])
 483
 484 #### Sound file ####
 485
 486 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 487 AC_SUBST(LIBSNDFILE_CFLAGS)
 488 AC_SUBST(LIBSNDFILE_LIBS)
 489
 490 PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ])
 491 AC_SUBST(LIBSPEEX_CFLAGS)
 492 AC_SUBST(LIBSPEEX_LIBS)
 493
 494 #### atomic-ops ###
 495
 496 AC_MSG_CHECKING([whether we need libatomic_ops])
 497 if test "x$need_libatomic_ops" = "xyes"; then
 498    AC_MSG_RESULT([yes])
 499    AC_CHECK_HEADERS([atomic_ops.h], [], [
 500    AC_MSG_ERROR([*** libatomic-ops headers not found])
 501    ])
 502
 503    # Win32 does not need the lib and breaks horribly if we try to include it
 504    if test "x$os_is_win32" != "x1" ; then
 505        LIBS="$LIBS -latomic_ops"
 506    fi
 507 else
 508    AC_MSG_RESULT([no])
 509 fi
 510
 511 #### Libsamplerate support (optional) ####
 512
 513 AC_ARG_ENABLE([samplerate],
 514     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]),
 515         [
 516             case "${enableval}" in
 517                 yes) samplerate=yes ;;
 518                 no) samplerate=no ;;
 519                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 520             esac
 521         ],
 522         [samplerate=auto])
 523
 524 if test "x${samplerate}" != xno ; then
 525     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 526         HAVE_LIBSAMPLERATE=1,
 527         [
 528             HAVE_LIBSAMPLERATE=0
 529             if test "x$samplerate" = xyes ; then
 530                 AC_MSG_ERROR([*** Libsamplerate not found])
 531             fi
 532         ])
 533 else
 534     HAVE_LIBSAMPLERATE=0
 535 fi
 536
 537 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 538    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 539 fi
 540
 541 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 542 AC_SUBST(LIBSAMPLERATE_LIBS)
 543 AC_SUBST(HAVE_LIBSAMPLERATE)
 544 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 545
 546 #### OSS support (optional) ####
 547
 548 AC_ARG_ENABLE([oss],
 549     AS_HELP_STRING([--disable-oss],[Disable optional OSS support]),
 550         [
 551             case "${enableval}" in
 552                 yes) oss=yes ;;
 553                 no) oss=no ;;
 554                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 555             esac
 556         ],
 557         [oss=auto])
 558
 559 if test "x${oss}" != xno ; then
 560     AC_CHECK_HEADERS([sys/soundcard.h],
 561         [
 562             HAVE_OSS=1
 563             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 564         ],
 565         [
 566             HAVE_OSS=0
 567             if test "x$oss" = xyes ; then
 568                 AC_MSG_ERROR([*** OSS support not found])
 569             fi
 570         ])
 571 else
 572     HAVE_OSS=0
 573 fi
 574
 575 AC_SUBST(HAVE_OSS)
 576 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 577
 578
 579 #### ALSA support (optional) ####
 580
 581 AC_ARG_ENABLE([alsa],
 582     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]),
 583         [
 584             case "${enableval}" in
 585                 yes) alsa=yes ;;
 586                 no) alsa=no ;;
 587                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 588             esac
 589         ],
 590         [alsa=auto])
 591
 592 if test "x${alsa}" != xno ; then
 593     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.17 ],
 594         [
 595             HAVE_ALSA=1
 596             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 597         ],
 598         [
 599             HAVE_ALSA=0
 600             if test "x$alsa" = xyes ; then
 601                 AC_MSG_ERROR([*** Needed alsa >= 1.0.17 support not found])
 602             fi
 603         ])
 604 else
 605     HAVE_ALSA=0
 606 fi
 607
 608 AC_SUBST(ASOUNDLIB_CFLAGS)
 609 AC_SUBST(ASOUNDLIB_LIBS)
 610 AC_SUBST(HAVE_ALSA)
 611 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 612
 613 #### Solaris audio support (optional) ####
 614
 615 AC_ARG_ENABLE([solaris],
 616     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]),
 617         [
 618             case "${enableval}" in
 619                 yes) solaris=yes ;;
 620                 no) solaris=no ;;
 621                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 622             esac
 623         ],
 624         [solaris=auto])
 625
 626 if test "x${solaris}" != xno ; then
 627     AC_CHECK_HEADERS([sys/audio.h],
 628         [
 629             HAVE_SOLARIS=1
 630             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 631         ],
 632         [
 633             HAVE_SOLARIS=0
 634             if test "x$solaris" = xyes ; then
 635                 AC_MSG_ERROR([*** Solaris audio support not found])
 636             fi
 637         ])
 638 else
 639     HAVE_SOLARIS=0
 640 fi
 641
 642 AC_SUBST(HAVE_SOLARIS)
 643 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 644
 645 #### GLib 2 support (optional) ####
 646
 647 AC_ARG_ENABLE([glib2],
 648     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]),
 649         [
 650             case "${enableval}" in
 651                 yes) glib2=yes ;;
 652                 no) glib2=no ;;
 653                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 654             esac
 655         ],
 656         [glib2=auto])
 657
 658 if test "x${glib2}" != xno ; then
 659     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 660         HAVE_GLIB20=1,
 661         [
 662             HAVE_GLIB20=0
 663             if test "x$glib2" = xyes ; then
 664                 AC_MSG_ERROR([*** GLib 2 support not found])
 665             fi
 666         ])
 667 else
 668     HAVE_GLIB20=0
 669 fi
 670
 671 AC_SUBST(GLIB20_CFLAGS)
 672 AC_SUBST(GLIB20_LIBS)
 673 AC_SUBST(HAVE_GLIB20)
 674 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 675
 676 #### GConf support (optional) ####
 677
 678 AC_ARG_ENABLE([gconf],
 679     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]),
 680         [
 681             case "${enableval}" in
 682                 yes) gconf=yes ;;
 683                 no) gconf=no ;;
 684                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 685             esac
 686         ],
 687         [gconf=auto])
 688
 689 if test "x${gconf}" != xno ; then
 690     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 691         HAVE_GCONF=1,
 692         [
 693             HAVE_GCONF=0
 694             if test "x$gconf" = xyes ; then
 695                 AC_MSG_ERROR([*** GConf support not found])
 696             fi
 697         ])
 698 else
 699     HAVE_GCONF=0
 700 fi
 701
 702 AC_SUBST(GCONF_CFLAGS)
 703 AC_SUBST(GCONF_LIBS)
 704 AC_SUBST(HAVE_GCONF)
 705 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 706
 707 #### Avahi support (optional) ####
 708
 709 AC_ARG_ENABLE([avahi],
 710     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]),
 711         [
 712             case "${enableval}" in
 713                 yes) avahi=yes ;;
 714                 no) avahi=no ;;
 715                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 716             esac
 717         ],
 718         [avahi=auto])
 719
 720 if test "x${avahi}" != xno ; then
 721     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 722         HAVE_AVAHI=1,
 723         [
 724                 HAVE_AVAHI=0
 725                 if test "x$avahi" = xyes ; then
 726                         AC_MSG_ERROR([*** Avahi support not found])
 727                 fi
 728         ])
 729 else
 730     HAVE_AVAHI=0
 731 fi
 732
 733 AC_SUBST(AVAHI_CFLAGS)
 734 AC_SUBST(AVAHI_LIBS)
 735 AC_SUBST(HAVE_AVAHI)
 736 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 737
 738 ### LIBOIL ####
 739
 740 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 741 AC_SUBST(LIBOIL_CFLAGS)
 742 AC_SUBST(LIBOIL_LIBS)
 743
 744 ### JACK (optional) ####
 745
 746 AC_ARG_ENABLE([jack],
 747     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]),
 748         [
 749             case "${enableval}" in
 750                 yes) jack=yes ;;
 751                 no) jack=no ;;
 752                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 753             esac
 754         ],
 755         [jack=auto])
 756
 757 if test "x${jack}" != xno ; then
 758     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 759         HAVE_JACK=1,
 760         [
 761             HAVE_JACK=0
 762             if test "x$jack" = xyes ; then
 763                 AC_MSG_ERROR([*** JACK support not found])
 764             fi
 765         ])
 766 else
 767     HAVE_JACK=0
 768 fi
 769
 770 AC_SUBST(JACK_CFLAGS)
 771 AC_SUBST(JACK_LIBS)
 772 AC_SUBST(HAVE_JACK)
 773 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 774
 775 #### Async DNS support (optional) ####
 776
 777 AC_ARG_ENABLE([asyncns],
 778     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]),
 779         [
 780             case "${enableval}" in
 781                 yes) asyncns=yes ;;
 782                 no) asyncns=no ;;
 783                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 784             esac
 785         ],
 786         [asyncns=auto])
 787
 788 if test "x${asyncns}" != xno ; then
 789     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 790         HAVE_LIBASYNCNS=1,
 791         [
 792             HAVE_LIBASYNCNS=0
 793             if test "x$asyncns" = xyes ; then
 794                 AC_MSG_ERROR([*** Async DNS support not found])
 795             fi
 796         ])
 797 else
 798     HAVE_LIBASYNCNS=0
 799 fi
 800
 801 AC_SUBST(LIBASYNCNS_CFLAGS)
 802 AC_SUBST(LIBASYNCNS_LIBS)
 803 AC_SUBST(HAVE_LIBASYNCNS)
 804 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 805
 806 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 807    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 808 fi
 809
 810 #### TCP wrappers (optional) ####
 811
 812 AC_ARG_ENABLE([tcpwrap],
 813     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 814         [
 815             case "${enableval}" in
 816                 yes) tcpwrap=yes ;;
 817                 no) tcpwrap=no ;;
 818                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 819             esac
 820         ],
 821         [tcpwrap=auto])
 822
 823 if test "x${tcpwrap}" != xno ; then
 824     ACX_LIBWRAP
 825     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 826         AC_MSG_ERROR([*** TCP wrappers support not found])
 827     fi
 828 else
 829     LIBWRAP_LIBS=
 830 fi
 831
 832 AC_SUBST(LIBWRAP_LIBS)
 833
 834 #### LIRC support (optional) ####
 835
 836 AC_ARG_ENABLE([lirc],
 837     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]),
 838         [
 839             case "${enableval}" in
 840                 yes) lirc=yes ;;
 841                 no) lirc=no ;;
 842                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 843             esac
 844         ],
 845         [lirc=auto])
 846
 847 if test "x${lirc}" != xno ; then
 848     ACX_LIRC
 849     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 850         AC_MSG_ERROR([*** LIRC support not found])
 851     fi
 852 else
 853     HAVE_LIRC=0
 854 fi
 855
 856 AC_SUBST(LIRC_CFLAGS)
 857 AC_SUBST(LIRC_LIBS)
 858 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 859
 860 #### HAL support (optional) ####
 861
 862 AC_ARG_ENABLE([hal],
 863     AS_HELP_STRING([--disable-hal],[Disable optional HAL support]),
 864         [
 865             case "${enableval}" in
 866                 yes) hal=yes ;;
 867                 no) hal=no ;;
 868                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 869             esac
 870         ],
 871         [hal=auto])
 872 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 873     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 874         HAVE_HAL=1,
 875         [
 876             HAVE_HAL=0
 877             if test "x$hal" = xyes ; then
 878                 AC_MSG_ERROR([*** HAL support not found])
 879             fi
 880         ])
 881 else
 882     HAVE_HAL=0
 883 fi
 884
 885 AC_SUBST(HAL_CFLAGS)
 886 AC_SUBST(HAL_LIBS)
 887 AC_SUBST(HAVE_HAL)
 888 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 889
 890 #### BlueZ support (optional) ####
 891
 892 AC_ARG_ENABLE([bluez],
 893     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]),
 894         [
 895             case "${enableval}" in
 896                 yes) bluez=yes ;;
 897                 no) bluez=no ;;
 898                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 899             esac
 900         ],
 901         [bluez=auto])
 902 if test "x${bluez}" != xno ; then
 903     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 904         HAVE_BLUEZ=1,
 905         [
 906             HAVE_BLUEZ=0
 907             if test "x$bluez" = xyes ; then
 908                 AC_MSG_ERROR([*** BLUEZ support not found])
 909             fi
 910         ])
 911 else
 912     HAVE_BLUEZ=0
 913 fi
 914
 915 AC_SUBST(BLUEZ_CFLAGS)
 916 AC_SUBST(BLUEZ_LIBS)
 917 AC_SUBST(HAVE_BLUEZ)
 918 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 919
 920 #### D-Bus support (optional) ####
 921
 922 AC_ARG_ENABLE([dbus],
 923     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]),
 924         [
 925             case "${enableval}" in
 926                 yes) dbus=yes ;;
 927                 no) dbus=no ;;
 928                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 929             esac
 930         ],
 931         [dbus=auto])
 932
 933 if test "x$HAVE_HAL" = x1 ; then
 934    dbus=yes
 935 fi
 936
 937 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 938
 939     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 940         [
 941             HAVE_DBUS=1
 942             saved_LIBS="$LIBS"
 943             LIBS="$LIBS $DBUS_LIBS"
 944             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 945             LIBS="$saved_LIBS"
 946             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 947         ],
 948         [
 949             HAVE_DBUS=0
 950             if test "x$dbus" = xyes ; then
 951                 AC_MSG_ERROR([*** D-Bus support not found])
 952             fi
 953         ])
 954 else
 955     HAVE_DBUS=0
 956 fi
 957
 958 AC_SUBST(DBUS_CFLAGS)
 959 AC_SUBST(DBUS_LIBS)
 960 AC_SUBST(HAVE_DBUS)
 961 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 962
 963 #### PolicyKit support (optional) ####
 964
 965 AC_ARG_ENABLE([polkit],
 966     AS_HELP_STRING([--disable-polkit],[Disable optional PolicyKit support]),
 967         [
 968             case "${enableval}" in
 969                 yes) polkit=yes ;;
 970                 no) polkit=no ;;
 971                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
 972             esac
 973         ],
 974         [polkit=auto])
 975
 976 if test "x${polkit}" != xno ; then
 977
 978     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus >= 0.7 ],
 979         [
 980             HAVE_POLKIT=1
 981             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
 982             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
 983             AC_SUBST(policydir)
 984         ],
 985         [
 986             HAVE_POLKIT=0
 987             if test "x$polkit" = xyes ; then
 988                 AC_MSG_ERROR([*** PolicyKit support not found])
 989             fi
 990         ])
 991 else
 992     HAVE_POLKIT=0
 993 fi
 994
 995 AC_SUBST(POLKIT_CFLAGS)
 996 AC_SUBST(POLKIT_LIBS)
 997 AC_SUBST(HAVE_POLKIT)
 998 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
 999
1000 #### OpenSSL support (optional) ####
1001
1002 AC_ARG_ENABLE([openssl],
1003     AS_HELP_STRING([--disable-openssl],[Disable OpenSSL support (used for Airtunes/RAOP)]),
1004         [
1005             case "${enableval}" in
1006                 yes) openssl=yes ;;
1007                 no) openssl=no ;;
1008                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-openssl) ;;
1009             esac
1010         ],
1011         [openssl=auto])
1012
1013 if test "x${openssl}" != xno ; then
1014
1015     PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ],
1016         [
1017             HAVE_OPENSSL=1
1018             AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL])
1019         ],
1020         [
1021             HAVE_OPENSSL=0
1022             if test "x$openssl" = xyes ; then
1023                 AC_MSG_ERROR([*** OpenSSL support not found])
1024             fi
1025         ])
1026 else
1027     HAVE_OPENSSL=0
1028 fi
1029
1030 AC_SUBST(OPENSSL_CFLAGS)
1031 AC_SUBST(OPENSSL_LIBS)
1032 AC_SUBST(HAVE_OPENSSL)
1033 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1034
1035 ### Build and Install man pages ###
1036 AC_ARG_ENABLE(manpages,
1037         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
1038 [case "${enableval}" in
1039   yes) manpages=yes ;;
1040   no)  manpages=no ;;
1041   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
1042 esac],[manpages=yes])
1043
1044 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1045
1046 #### PulseAudio system group & user  #####
1047
1048 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1049 if test -z "$with_system_user" ; then
1050     PA_SYSTEM_USER=pulse
1051 else
1052     PA_SYSTEM_USER=$with_system_user
1053 fi
1054 AC_SUBST(PA_SYSTEM_USER)
1055 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1056
1057 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1058 if test -z "$with_system_group" ; then
1059     PA_SYSTEM_GROUP=pulse
1060 else
1061     PA_SYSTEM_GROUP=$with_system_group
1062 fi
1063 AC_SUBST(PA_SYSTEM_GROUP)
1064 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1065
1066 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
1067 if test -z "$with_realtime_group" ; then
1068     PA_REALTIME_GROUP=pulse-rt
1069 else
1070     PA_REALTIME_GROUP=$with_realtime_group
1071 fi
1072 AC_SUBST(PA_REALTIME_GROUP)
1073 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
1074
1075 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1076 if test -z "$with_access_group" ; then
1077     PA_ACCESS_GROUP=pulse-access
1078 else
1079     PA_ACCESS_GROUP=$with_access_group
1080 fi
1081 AC_SUBST(PA_ACCESS_GROUP)
1082 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1083
1084 AC_ARG_ENABLE(
1085         per_user_esound_socket,
1086         AS_HELP_STRING([--disable-per-user-esound-socket], [Use global esound socket directory /tmp/.esd/socket.]),
1087         [
1088             case "${enableval}" in
1089                 yes) per_user_esound_socket=1 ;;
1090                 no) per_user_esound_socket=0 ;;
1091                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-per-user-esound-socket) ;;
1092             esac
1093         ],
1094         [per_user_esound_socket=1])
1095
1096 if test "x$per_user_esound_socket" = "x1"; then
1097    AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1098 fi
1099
1100 #### PulseAudio system runtime dir ####
1101 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1102 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1103 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1104 AC_SUBST(PA_SYSTEM_CONFIG_PATH)
1105 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1106 AC_SUBST(PA_SYSTEM_STATE_PATH)
1107
1108 ###################################
1109 #            Output               #
1110 ###################################
1111
1112 AC_ARG_ENABLE(
1113         [static-bins],
1114         AS_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1115         [STATIC_BINS=1], [STATIC_BINS=0])
1116 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1117
1118 AC_ARG_WITH(
1119         [preopen-mods],
1120         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1121         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1122 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1123 if test "x$PREOPEN_MODS" != "xall" ; then
1124     tmpLIBS=""
1125     for mod in $PREOPEN_MODS; do
1126         tmpLIBS="$tmpLIBS module-$mod.la"
1127     done
1128     PREOPEN_MODS="$tmpLIBS"
1129     AC_SUBST(PREOPEN_MODS)
1130 fi
1131
1132 AC_ARG_WITH(
1133         [module-dir],
1134         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINORMICRO}/modules/]),
1135         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINORMICRO}/modules/"])
1136
1137 AC_SUBST(modlibexecdir)
1138
1139 AC_ARG_ENABLE(
1140         [force-preopen],
1141         AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1142         [FORCE_PREOPEN=$enableval], [FORCE_PREOPEN=no])
1143 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "xyes"])
1144
1145 AC_CONFIG_FILES([
1146 Makefile
1147 libltdl/Makefile
1148 src/Makefile
1149 man/Makefile
1150 libpulse.pc
1151 libpulse-simple.pc
1152 libpulse-browse.pc
1153 libpulse-mainloop-glib.pc
1154 doxygen/Makefile
1155 doxygen/doxygen.conf
1156 src/pulse/version.h
1157 po/Makefile.in
1158 ])
1159 AC_OUTPUT
1160
1161 # ==========================================================================
1162 ENABLE_X11=no
1163 if test "x$HAVE_X11" = "x1" ; then
1164    ENABLE_X11=yes
1165 fi
1166
1167 ENABLE_OSS=no
1168 if test "x$HAVE_OSS" = "x1" ; then
1169    ENABLE_OSS=yes
1170 fi
1171
1172 ENABLE_ALSA=no
1173 if test "x$HAVE_ALSA" = "x1" ; then
1174    ENABLE_ALSA=yes
1175 fi
1176
1177 ENABLE_SOLARIS=no
1178 if test "x$HAVE_SOLARIS" = "x1" ; then
1179    ENABLE_SOLARIS=yes
1180 fi
1181
1182 ENABLE_GLIB20=no
1183 if test "x$HAVE_GLIB20" = "x1" ; then
1184    ENABLE_GLIB20=yes
1185 fi
1186
1187 ENABLE_GCONF=no
1188 if test "x$HAVE_GCONF" = "x1" ; then
1189    ENABLE_GCONF=yes
1190 fi
1191
1192 ENABLE_AVAHI=no
1193 if test "x$HAVE_AVAHI" = "x1" ; then
1194    ENABLE_AVAHI=yes
1195 fi
1196
1197 ENABLE_JACK=no
1198 if test "x$HAVE_JACK" = "x1" ; then
1199    ENABLE_JACK=yes
1200 fi
1201
1202 ENABLE_LIBASYNCNS=no
1203 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1204    ENABLE_LIBASYNCNS=yes
1205 fi
1206
1207 ENABLE_LIRC=no
1208 if test "x$HAVE_LIRC" = "x1" ; then
1209    ENABLE_LIRC=yes
1210 fi
1211
1212 ENABLE_HAL=no
1213 if test "x$HAVE_HAL" = "x1" ; then
1214    ENABLE_HAL=yes
1215 fi
1216
1217 ENABLE_TCPWRAP=no
1218 if test "x${LIBWRAP_LIBS}" != x ; then
1219    ENABLE_TCPWRAP=yes
1220 fi
1221
1222 ENABLE_LIBSAMPLERATE=no
1223 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1224    ENABLE_LIBSAMPLERATE=yes
1225 fi
1226
1227 ENABLE_BLUEZ=no
1228 if test "x${HAVE_BLUEZ}" = "x1" ; then
1229    ENABLE_BLUEZ=yes
1230 fi
1231
1232 ENABLE_POLKIT=no
1233 if test "x${HAVE_POLKIT}" = "x1" ; then
1234    ENABLE_POLKIT=yes
1235 fi
1236
1237 ENABLE_OPENSSL=no
1238 if test "x${HAVE_OPENSSL}" = "x1" ; then
1239    ENABLE_OPENSSL=yes
1240 fi
1241
1242 ENABLE_PER_USER_ESOUND_SOCKET=no
1243 if test "x$per_user_esound_socket" = "x1" ; then
1244    ENABLE_PER_USER_ESOUND_SOCKET=yes
1245 fi
1246
1247 echo "
1248  ---{ $PACKAGE_NAME $VERSION }---
1249
1250     prefix:                        ${prefix}
1251     sysconfdir:                    ${sysconfdir}
1252     localstatedir:                 ${localstatedir}
1253     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1254     System State Path:             ${PA_SYSTEM_STATE_PATH}
1255     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1256     Compiler:                      ${CC}
1257     CFLAGS:                        ${CFLAGS}
1258
1259     Have X11:                      ${ENABLE_X11}
1260     Enable OSS:                    ${ENABLE_OSS}
1261     Enable Alsa:                   ${ENABLE_ALSA}
1262     Enable Solaris:                ${ENABLE_SOLARIS}
1263     Enable GLib 2.0:               ${ENABLE_GLIB20}
1264     Enable GConf:                  ${ENABLE_GCONF}
1265     Enable Avahi:                  ${ENABLE_AVAHI}
1266     Enable Jack:                   ${ENABLE_JACK}
1267     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1268     Enable LIRC:                   ${ENABLE_LIRC}
1269     Enable HAL:                    ${ENABLE_HAL}
1270     Enable BlueZ:                  ${ENABLE_BLUEZ}
1271     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1272     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1273     Enable PolicyKit:              ${ENABLE_POLKIT}
1274     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1275
1276     System User:                   ${PA_SYSTEM_USER}
1277     System Group:                  ${PA_SYSTEM_GROUP}
1278     Realtime Group:                ${PA_REALTIME_GROUP}
1279     Access Group:                  ${PA_ACCESS_GROUP}
1280     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1281     Force preopen:                 ${FORCE_PREOPEN}
1282     Preopened modules:             ${PREOPEN_MODS}
1283 "