code.delx.au - pulseaudio/blob - configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # This file is part of PulseAudio.
   5 #
   6 # Copyright 2004-2008 Lennart Poettering
   7 # Copyright 2006-2007 Pierre Ossman <ossman@cendio.se> for Cendio AB
   8 #
   9 # PulseAudio is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU Lesser General Public License as published by
  11 # the Free Software Foundation; either version 2 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # PulseAudio is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  17 # General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU Lesser General Public License
  20 # along with PulseAudio; if not, write to the Free Software Foundation,
  21 # Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA.
  22
  23 AC_PREREQ(2.62)
  24
  25 m4_define(PA_MAJOR, [0])
  26 m4_define(PA_MINOR, [9])
  27 m4_define(PA_MICRO, [13])
  28
  29 AC_INIT([pulseaudio],[PA_MAJOR.PA_MINOR.PA_MICRO],[mzchyfrnhqvb (at) 0pointer (dot) net])
  30 AC_CONFIG_SRCDIR([src/daemon/main.c])
  31 AC_CONFIG_MACRO_DIR([m4])
  32 AC_CONFIG_HEADERS([config.h])
  33 AM_INIT_AUTOMAKE([foreign 1.10 -Wall])
  34
  35 AC_SUBST(PA_MAJORMINOR, "PA_MAJOR.PA_MINOR")
  36 AC_SUBST(PACKAGE_URL, [http://pulseaudio.org/])
  37
  38 AC_SUBST(PA_API_VERSION, 12)
  39 AC_SUBST(PA_PROTOCOL_VERSION, 14)
  40
  41 # The stable ABI for client applications, for the version info x:y:z
  42 # always will hold y=z
  43 AC_SUBST(LIBPULSE_VERSION_INFO, [7:0:7])
  44
  45 # A simplified, synchronous, ABI-stable interface for client
  46 # applications, for the version info x:y:z always will hold y=z
  47 AC_SUBST(LIBPULSE_SIMPLE_VERSION_INFO, [0:2:0])
  48
  49 # The ABI-stable network browsing interface for client applications,
  50 # for the version info x:y:z always will hold y=z
  51 AC_SUBST(LIBPULSE_BROWSE_VERSION_INFO, [1:1:1])
  52
  53 # The ABI-stable GLib adapter for client applications, for the version
  54 # info x:y:z always will hold y=z
  55 AC_SUBST(LIBPULSE_MAINLOOP_GLIB_VERSION_INFO, [0:4:0])
  56
  57 # An internally used, ABI-unstable library that contains the
  58 # PulseAudio core, SONAMEs are bumped on every release, version info
  59 # suffix will always be 0:0
  60 AC_SUBST(LIBPULSECORE_VERSION_INFO, [8:0:0])
  61
  62 AC_CANONICAL_HOST
  63 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  64
  65 if type -p stow > /dev/null && test -d /usr/local/stow ; then
  66    AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  67    ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  68 fi
  69
  70 #### Platform hacks ####
  71
  72 case $host in
  73    *-*-solaris* )
  74       AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  75       AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
  76       AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
  77       ;;
  78 esac
  79
  80 #### Checks for programs. ####
  81
  82 # mkdir -p
  83
  84 AC_PROG_MKDIR_P
  85
  86 # CC
  87
  88 AC_PROG_CC
  89 AC_PROG_CC_C99
  90 AM_PROG_CC_C_O
  91 AC_PROG_GCC_TRADITIONAL
  92 AC_USE_SYSTEM_EXTENSIONS
  93
  94 # M4
  95
  96 AC_PATH_PROG([M4], [m4 gm4], [no])
  97 if test "x$M4" = xno ; then
  98    AC_MSG_ERROR([m4 missing])
  99 fi
 100
 101 dnl Compiler flags
 102 DESIRED_FLAGS="-Wall -W -Wextra -pedantic -pipe -Wno-long-long -Wvla -Wno-overlength-strings -Wconversion -Wundef -Wformat -Wlogical-op -Wpacked -Wformat-security -Wmissing-include-dirs -Wformat-nonliteral -Wold-style-definition -Wdeclaration-after-statement -Wfloat-equal -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wmissing-noreturn -Wshadow -Wendif-labels -Wpointer-arith -Wcast-align -Wwrite-strings -Wno-unused-parameter -ffast-math"
 103
 104 for flag in $DESIRED_FLAGS ; do
 105   CC_CHECK_CFLAGS([$flag], [CFLAGS="$CFLAGS $flag"])
 106 done
 107
 108 # Native atomic operation support
 109 AC_ARG_ENABLE([atomic-arm-linux-helpers],
 110     AS_HELP_STRING([--disable-atomic-arm-linux-helpers],[use inline asm or libatomic_ops instead]),
 111         [
 112             case "${enableval}" in
 113                 yes) atomic_arm_linux_helpers=yes ;;
 114                 no) atomic_arm_linux_helpers=no ;;
 115                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 116             esac
 117         ],
 118         [atomic_arm_linux_helpers=auto])
 119
 120 AC_ARG_ENABLE([atomic-arm-memory-barrier],
 121     AS_HELP_STRING([--enable-atomic-arm-memory-barrier],[only really needed in SMP arm systems]),
 122         [
 123             case "${enableval}" in
 124                 yes) AC_DEFINE_UNQUOTED(ATOMIC_ARM_MEMORY_BARRIER_ENABLED, 1, [Enable memory barriers]) ;;
 125                 no) ;;
 126                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-atomic-arm-linux-helpers) ;;
 127             esac
 128         ],)
 129
 130 AC_MSG_CHECKING([target operating system])
 131 case $host in
 132         *-*-linux*)
 133             AC_MSG_RESULT([linux])
 134             pulse_target_os=linux
 135         ;;
 136         *)
 137             AC_MSG_RESULT([unknown])
 138             pulse_target_os=unknown
 139         ;;
 140 esac
 141
 142 # If everything else fails use libatomic_ops
 143 need_libatomic_ops=yes
 144
 145 AC_CACHE_CHECK([whether $CC knows __sync_bool_compare_and_swap()],
 146   pulseaudio_cv_sync_bool_compare_and_swap,
 147   [AC_LINK_IFELSE(
 148      AC_LANG_PROGRAM([], [[int a = 4; __sync_bool_compare_and_swap(&a, 4, 5);]]),
 149      [pulseaudio_cv_sync_bool_compare_and_swap=yes],
 150      [pulseaudio_cv_sync_bool_compare_and_swap=no])
 151   ])
 152
 153 if test "$pulseaudio_cv_sync_bool_compare_and_swap" = "yes" ; then
 154     AC_DEFINE([HAVE_ATOMIC_BUILTINS], 1, [Have __sync_bool_compare_and_swap() and friends.])
 155     need_libatomic_ops=no
 156 else
 157     # HW specific atomic ops stuff
 158     AC_MSG_CHECKING([architecture for native atomic operations])
 159     case $host_cpu in
 160         arm*)
 161             AC_MSG_RESULT([arm])
 162             AC_MSG_CHECKING([whether we can use Linux kernel helpers])
 163             # The Linux kernel helper functions have been there since 2.6.16. However
 164             # compile time checking for kernel version in cross compile environment
 165             # (which is usually the case for arm cpu) is tricky (or impossible).
 166             if test "x$pulse_target_os" = "xlinux" && test "x$atomic_arm_linux_helpers" != "xno"; then
 167                 AC_MSG_RESULT([yes])
 168                 AC_DEFINE_UNQUOTED(ATOMIC_ARM_LINUX_HELPERS, 1, [special arm linux implementation])
 169                 need_libatomic_ops=no
 170             else
 171                AC_MSG_RESULT([no])
 172                AC_CACHE_CHECK([compiler support for arm inline asm atomic operations],
 173                  pulseaudio_cv_support_arm_atomic_ops,
 174                  [AC_COMPILE_IFELSE(
 175                     AC_LANG_PROGRAM([],
 176                       [[volatile int a=0;
 177                         int o=0, n=1, r;
 178                         asm volatile ("ldrex    %0, [%1]\n"
 179                                          "subs  %0, %0, %2\n"
 180                                          "strexeq %0, %3, [%1]\n"
 181                                          : "=&r" (r)
 182                                          : "r" (&a), "Ir" (o), "r" (n)
 183                                          : "cc");
 184                         return (a==1 ? 0 : -1);
 185                       ]]),
 186                     [pulseaudio_cv_support_arm_atomic_ops=yes],
 187                     [pulseaudio_cv_support_arm_atomic_ops=no])
 188                  ])
 189                AS_IF([test "$pulseaudio_cv_support_arm_atomic_ops" = "yes"], [
 190                    AC_DEFINE([ATOMIC_ARM_INLINE_ASM], 1, [Have ARMv6 instructions.])
 191                    need_libatomic_ops=no
 192                  ])
 193            fi
 194         ;;
 195         *)
 196             AC_MSG_RESULT([unknown])
 197         ;;
 198     esac
 199 fi
 200
 201 CC_CHECK_TLS
 202
 203 AC_CACHE_CHECK([whether $CC knows _Bool],
 204   pulseaudio_cv__Bool,
 205   [AC_COMPILE_IFELSE(
 206      AC_LANG_PROGRAM([], [[_Bool b;]]),
 207      [pulseaudio_cv__Bool=yes],
 208      [pulseaudio_cv__Bool=no])
 209   ])
 210
 211 AS_IF([test "$pulseaudio_cv__Bool" = "yes"], [
 212     AC_DEFINE([HAVE_STD_BOOL], 1, [Have _Bool.])
 213   ])
 214
 215 #### libtool stuff ####
 216
 217 AC_LTDL_ENABLE_INSTALL
 218 AC_LIBLTDL_INSTALLABLE
 219 AC_LIBTOOL_DLOPEN
 220 AC_LIBTOOL_WIN32_DLL
 221 AC_PROG_LIBTOOL
 222 AC_SUBST(LTDLINCL)
 223 AC_SUBST(LIBLTDL)
 224 AC_CONFIG_SUBDIRS(libltdl)
 225
 226 old_LIBS=$LIBS
 227 LIBS="$LIBS $LIBLTDL"
 228 AC_CHECK_FUNCS([lt_dlmutex_register])
 229 LIBS=$old_LIBS
 230 AC_CHECK_TYPES([struct lt_user_dlloader, lt_dladvise], , , [#include <ltdl.h>])
 231
 232 if test "x$enable_ltdl_install" = "xno" && test "x$ac_cv_lib_ltdl_lt_dlinit" = "xno" ; then
 233     AC_MSG_ERROR([[
 234
 235         *** Cannot find the libltdl development files.
 236         *** Maybe you need to install the libltdl-dev package.
 237         ]])
 238 fi
 239
 240 #### Determine build environment ####
 241
 242 os_is_win32=0
 243
 244 case "$host_os" in
 245         mingw*)
 246         AC_DEFINE([OS_IS_WIN32], 1, [Build target is Windows.])
 247         os_is_win32=1
 248                 ;;
 249         esac
 250
 251 AM_CONDITIONAL(OS_IS_WIN32, test "x$os_is_win32" = "x1")
 252
 253 ###################################
 254 #   Basic environment checks      #
 255 ###################################
 256
 257 #### Checks for header files. ####
 258
 259 # ISO
 260 AC_HEADER_STDC
 261
 262 # POSIX
 263 AC_CHECK_HEADERS([arpa/inet.h glob.h grp.h netdb.h netinet/in.h \
 264     netinet/in_systm.h netinet/tcp.h poll.h pwd.h sched.h \
 265     sys/mman.h sys/resource.h sys/select.h sys/socket.h sys/wait.h \
 266     syslog.h sys/dl.h dlfcn.h linux/sockios.h])
 267 AC_CHECK_HEADERS([netinet/ip.h], [], [],
 268                  [#include <sys/types.h>
 269                   #if HAVE_NETINET_IN_H
 270                   # include <netinet/in.h>
 271                   #endif
 272                   #if HAVE_NETINET_IN_SYSTM_H
 273                   # include <netinet/in_systm.h>
 274                   #endif
 275                  ])
 276 AC_CHECK_HEADERS([regex.h], [HAVE_REGEX=1], [HAVE_REGEX=0])
 277 AC_CHECK_HEADERS([sys/un.h], [HAVE_AF_UNIX=1], [HAVE_AF_UNIX=0])
 278
 279 AM_CONDITIONAL(HAVE_REGEX, test "x$HAVE_REGEX" = "x1")
 280 AM_CONDITIONAL(HAVE_AF_UNIX, test "x$HAVE_AF_UNIX" = "x1")
 281
 282 # Linux
 283 AC_CHECK_HEADERS([linux/input.h], [HAVE_EVDEV=1], [HAVE_EVDEV=0])
 284
 285 AM_CONDITIONAL([HAVE_EVDEV], [test "x$HAVE_EVDEV" = "x1"])
 286
 287 AC_CHECK_HEADERS([sys/prctl.h])
 288
 289 # Solaris
 290 AC_CHECK_HEADERS([sys/filio.h])
 291
 292 # Windows
 293 AC_CHECK_HEADERS([windows.h winsock2.h ws2tcpip.h])
 294
 295 # Other
 296 AC_CHECK_HEADERS([sys/ioctl.h])
 297 AC_CHECK_HEADERS([byteswap.h])
 298 AC_CHECK_HEADERS([sys/syscall.h])
 299 AC_CHECK_HEADERS([sys/eventfd.h])
 300 AC_CHECK_HEADERS([execinfo.h])
 301
 302 #### Typdefs, structures, etc. ####
 303
 304 AC_C_CONST
 305 AC_C_BIGENDIAN
 306 AC_TYPE_PID_T
 307 AC_TYPE_SIZE_T
 308 AC_CHECK_TYPES(ssize_t, , [AC_DEFINE([ssize_t], [signed long],
 309     [Define ssize_t if it is not done by the standard libs.])])
 310 AC_TYPE_OFF_T
 311 AC_TYPE_SIGNAL
 312 AC_TYPE_UID_T
 313 AC_CHECK_DECLS(environ)
 314
 315 AC_CHECK_DEFINE([SIGXCPU], [signal.h], [
 316 HAVE_SIGXCPU=1
 317 AC_DEFINE([HAVE_SIGXCPU], 1, [Have SIGXCPU?])
 318 ], [HAVE_SIGXCPU=0])
 319 AM_CONDITIONAL(HAVE_SIGXCPU, test "x$HAVE_SIGXCPU" = "x1")
 320
 321 # Solaris lacks this
 322 AC_CHECK_DEFINE([INADDR_NONE], [netinet/in.h], [],
 323     [AC_CHECK_DEFINE([INADDR_NONE], [winsock2.h], [],
 324         [AC_DEFINE([INADDR_NONE],  [0xffffffff], [Define INADDR_NONE if not found in <netinet/in.h>])])])
 325
 326 #### POSIX threads ####
 327
 328 ACX_PTHREAD
 329
 330 #### Check for libs ####
 331
 332 # ISO
 333 AC_SEARCH_LIBS([pow], [m])
 334
 335 # POSIX
 336 AC_SEARCH_LIBS([sched_setscheduler], [rt])
 337 AC_SEARCH_LIBS([dlopen], [dl])
 338 AC_SEARCH_LIBS([shm_open], [rt])
 339 AC_SEARCH_LIBS([inet_ntop], [nsl])
 340 AC_SEARCH_LIBS([timer_create], [rt])
 341
 342 # BSD
 343 AC_SEARCH_LIBS([connect], [socket])
 344
 345 # Non-standard
 346
 347 # This magic is needed so we do not needlessly add static libs to the win32
 348 # build, disabling its ability to make dlls.
 349 AC_CHECK_FUNCS([getopt_long], [], [AC_CHECK_LIB([iberty], [getopt_long])])
 350
 351 AC_CHECK_LIB(gdbm, gdbm_open)
 352 AC_CHECK_HEADERS(gdbm.h, [], [AC_MSG_ERROR([gdbm.h not found])])
 353
 354 #### Check for functions ####
 355
 356 # ISO
 357 AC_CHECK_FUNCS([lrintf strtof])
 358
 359 # POSIX
 360 AC_FUNC_FORK
 361 AC_FUNC_GETGROUPS
 362 AC_FUNC_SELECT_ARGTYPES
 363 AC_CHECK_FUNCS([chmod chown clock_gettime getaddrinfo getgrgid_r \
 364     getpwuid_r gettimeofday getuid inet_ntop inet_pton mlock nanosleep \
 365     pipe posix_fadvise posix_madvise posix_memalign setpgid setsid shm_open \
 366     sigaction sleep sysconf])
 367 AC_CHECK_FUNCS([mkfifo], [HAVE_MKFIFO=1], [HAVE_MKFIFO=0])
 368
 369 AM_CONDITIONAL(HAVE_MKFIFO, test "x$HAVE_MKFIFO" = "x1")
 370
 371 # X/OPEN
 372 AC_CHECK_FUNCS([readlink])
 373
 374 # SUSv2
 375 AC_CHECK_FUNCS([ctime_r usleep])
 376
 377 # SUSv3
 378 AC_CHECK_FUNCS([strerror_r])
 379
 380 # BSD
 381 AC_CHECK_FUNCS([lstat])
 382
 383 # Non-standard
 384
 385 AC_CHECK_FUNCS([setresuid setresgid setreuid setregid seteuid setegid ppoll strsignal sig2str strtof_l])
 386
 387 AC_FUNC_ALLOCA
 388
 389 AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 390   pulseaudio_cv_PTHREAD_PRIO_INHERIT,
 391   [save_CC=$CC; CC=$PTHREAD_CC
 392    save_CFLAGS=$CFLAGS; CFLAGS=$PTHREAD_CFLAGS
 393    save_LIBS=$LIBS; LIBS=$PTHREAD_LIBS
 394    AC_LINK_IFELSE(
 395      AC_LANG_PROGRAM(
 396        [[
 397          #include <pthread.h>
 398        ]],
 399        [[int i = PTHREAD_PRIO_INHERIT;]]),
 400      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=yes],
 401      [pulseaudio_cv_PTHREAD_PRIO_INHERIT=no])
 402    CC=$save_CC
 403    CFLAGS=$save_CFLAGS
 404    LIBS=$save_LIBS
 405   ])
 406
 407 AS_IF([test "$pulseaudio_cv_PTHREAD_PRIO_INHERIT" = "yes"], [
 408     AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], 1, [Have PTHREAD_PRIO_INHERIT.])
 409   ])
 410
 411 AC_DEFINE_UNQUOTED(PA_CFLAGS,"$CFLAGS", [The CFLAGS used during compilation])
 412
 413 #### Large File-Support (LFS) ####
 414
 415 AC_SYS_LARGEFILE
 416
 417 # Check for open64 to know if the current system does have open64() and similar functions
 418 AC_CHECK_FUNCS([open64])
 419
 420 #### [lib]iconv ####
 421
 422 AM_ICONV
 423
 424 IT_PROG_INTLTOOL([0.35.0])
 425 GETTEXT_PACKAGE=pulseaudio
 426 AC_SUBST([GETTEXT_PACKAGE])
 427 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext package])
 428 AM_GLIB_GNU_GETTEXT
 429
 430 pulselocaledir='${prefix}/${DATADIRNAME}/locale'
 431 AC_SUBST(pulselocaledir)
 432
 433 ###################################
 434 #      External libraries         #
 435 ###################################
 436
 437 #### X11 (optional) ####
 438
 439 HAVE_X11=0
 440
 441 # The macro tests the host, not the build target
 442 if test "x$os_is_win32" != "x1" ; then
 443     AC_PATH_XTRA
 444     test "x$no_x" != "xyes" && HAVE_X11=1
 445 fi
 446
 447 AC_SUBST(HAVE_X11)
 448 AM_CONDITIONAL(HAVE_X11, test "x$HAVE_X11" = "x1")
 449 if test "x$HAVE_X11" = "x1" ; then
 450     AC_DEFINE([HAVE_X11], 1, [Have X11])
 451 fi
 452
 453 #### Capabilities (optional) ####
 454
 455 CAP_LIBS=''
 456
 457 AC_ARG_WITH(
 458         [caps],
 459         AS_HELP_STRING([--without-caps],[Omit support for POSIX capabilities.]))
 460
 461 if test "x${with_caps}" != "xno"; then
 462     AC_SEARCH_LIBS([cap_init], [cap], [], [
 463                     if test "x${with_caps}" = "xyes" ; then
 464                         AC_MSG_ERROR([*** POSIX caps libraries not found])
 465                     fi])
 466     AC_CHECK_HEADERS([sys/capability.h], [], [
 467                     if test "x${with_caps}" = "xyes" ; then
 468                         AC_MSG_ERROR([*** POSIX caps headers not found])
 469                     fi])
 470 fi
 471
 472 #### Valgrind (optional) ####
 473
 474 AC_CHECK_HEADERS([valgrind/memcheck.h])
 475
 476 #### pkg-config ####
 477
 478 # Check for pkg-config manually first, as if its not installed the
 479 # PKG_PROG_PKG_CONFIG macro won't be defined.
 480 AC_CHECK_PROG(have_pkg_config, pkg-config, yes, no)
 481
 482 if test x"$have_pkg_config" = "xno"; then
 483     AC_MSG_ERROR(pkg-config is required to install this program)
 484 fi
 485
 486 PKG_PROG_PKG_CONFIG
 487
 488 #### Sound file ####
 489
 490 PKG_CHECK_MODULES(LIBSNDFILE, [ sndfile >= 1.0.10 ])
 491 AC_SUBST(LIBSNDFILE_CFLAGS)
 492 AC_SUBST(LIBSNDFILE_LIBS)
 493
 494 PKG_CHECK_MODULES(LIBSPEEX, [ speexdsp >= 1.2 ])
 495 AC_SUBST(LIBSPEEX_CFLAGS)
 496 AC_SUBST(LIBSPEEX_LIBS)
 497
 498 #### atomic-ops ###
 499
 500 AC_MSG_CHECKING([whether we need libatomic_ops])
 501 if test "x$need_libatomic_ops" = "xyes"; then
 502    AC_MSG_RESULT([yes])
 503    AC_CHECK_HEADERS([atomic_ops.h], [], [
 504    AC_MSG_ERROR([*** libatomic-ops headers not found])
 505    ])
 506
 507    # Win32 does not need the lib and breaks horribly if we try to include it
 508    if test "x$os_is_win32" != "x1" ; then
 509        LIBS="$LIBS -latomic_ops"
 510    fi
 511 else
 512    AC_MSG_RESULT([no])
 513 fi
 514
 515 #### Libsamplerate support (optional) ####
 516
 517 AC_ARG_ENABLE([samplerate],
 518     AS_HELP_STRING([--disable-samplerate],[Disable optional libsamplerate support]),
 519         [
 520             case "${enableval}" in
 521                 yes) samplerate=yes ;;
 522                 no) samplerate=no ;;
 523                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-samplerate) ;;
 524             esac
 525         ],
 526         [samplerate=auto])
 527
 528 if test "x${samplerate}" != xno ; then
 529     PKG_CHECK_MODULES(LIBSAMPLERATE, [ samplerate >= 0.1.0 ],
 530         HAVE_LIBSAMPLERATE=1,
 531         [
 532             HAVE_LIBSAMPLERATE=0
 533             if test "x$samplerate" = xyes ; then
 534                 AC_MSG_ERROR([*** Libsamplerate not found])
 535             fi
 536         ])
 537 else
 538     HAVE_LIBSAMPLERATE=0
 539 fi
 540
 541 if test "x${HAVE_LIBSAMPLERATE}" = x1 ; then
 542    AC_DEFINE([HAVE_LIBSAMPLERATE], 1, [Have libsamplerate?])
 543 fi
 544
 545 AC_SUBST(LIBSAMPLERATE_CFLAGS)
 546 AC_SUBST(LIBSAMPLERATE_LIBS)
 547 AC_SUBST(HAVE_LIBSAMPLERATE)
 548 AM_CONDITIONAL([HAVE_LIBSAMPLERATE], [test "x$HAVE_LIBSAMPLERATE" = x1])
 549
 550 #### OSS support (optional) ####
 551
 552 AC_ARG_ENABLE([oss],
 553     AS_HELP_STRING([--disable-oss],[Disable optional OSS support]),
 554         [
 555             case "${enableval}" in
 556                 yes) oss=yes ;;
 557                 no) oss=no ;;
 558                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-oss) ;;
 559             esac
 560         ],
 561         [oss=auto])
 562
 563 if test "x${oss}" != xno ; then
 564     AC_CHECK_HEADERS([sys/soundcard.h],
 565         [
 566             HAVE_OSS=1
 567             AC_DEFINE([HAVE_OSS], 1, [Have OSS?])
 568         ],
 569         [
 570             HAVE_OSS=0
 571             if test "x$oss" = xyes ; then
 572                 AC_MSG_ERROR([*** OSS support not found])
 573             fi
 574         ])
 575 else
 576     HAVE_OSS=0
 577 fi
 578
 579 AC_SUBST(HAVE_OSS)
 580 AM_CONDITIONAL([HAVE_OSS], [test "x$HAVE_OSS" = x1])
 581
 582
 583 #### ALSA support (optional) ####
 584
 585 AC_ARG_ENABLE([alsa],
 586     AS_HELP_STRING([--disable-alsa],[Disable optional ALSA support]),
 587         [
 588             case "${enableval}" in
 589                 yes) alsa=yes ;;
 590                 no) alsa=no ;;
 591                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-alsa) ;;
 592             esac
 593         ],
 594         [alsa=auto])
 595
 596 if test "x${alsa}" != xno ; then
 597     PKG_CHECK_MODULES(ASOUNDLIB, [ alsa >= 1.0.17 ],
 598         [
 599             HAVE_ALSA=1
 600             AC_DEFINE([HAVE_ALSA], 1, [Have ALSA?])
 601         ],
 602         [
 603             HAVE_ALSA=0
 604             if test "x$alsa" = xyes ; then
 605                 AC_MSG_ERROR([*** Needed alsa >= 1.0.17 support not found])
 606             fi
 607         ])
 608 else
 609     HAVE_ALSA=0
 610 fi
 611
 612 AC_SUBST(ASOUNDLIB_CFLAGS)
 613 AC_SUBST(ASOUNDLIB_LIBS)
 614 AC_SUBST(HAVE_ALSA)
 615 AM_CONDITIONAL([HAVE_ALSA], [test "x$HAVE_ALSA" = x1])
 616
 617 #### Solaris audio support (optional) ####
 618
 619 AC_ARG_ENABLE([solaris],
 620     AS_HELP_STRING([--disable-solaris],[Disable optional Solaris audio support]),
 621         [
 622             case "${enableval}" in
 623                 yes) solaris=yes ;;
 624                 no) solaris=no ;;
 625                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-solaris) ;;
 626             esac
 627         ],
 628         [solaris=auto])
 629
 630 if test "x${solaris}" != xno ; then
 631     AC_CHECK_HEADERS([sys/audio.h],
 632         [
 633             HAVE_SOLARIS=1
 634             AC_DEFINE([HAVE_SOLARIS], 1, [Have Solaris audio?])
 635         ],
 636         [
 637             HAVE_SOLARIS=0
 638             if test "x$solaris" = xyes ; then
 639                 AC_MSG_ERROR([*** Solaris audio support not found])
 640             fi
 641         ])
 642 else
 643     HAVE_SOLARIS=0
 644 fi
 645
 646 AC_SUBST(HAVE_SOLARIS)
 647 AM_CONDITIONAL([HAVE_SOLARIS], [test "x$HAVE_SOLARIS" = x1])
 648
 649 #### GLib 2 support (optional) ####
 650
 651 AC_ARG_ENABLE([glib2],
 652     AS_HELP_STRING([--disable-glib2],[Disable optional GLib 2 support]),
 653         [
 654             case "${enableval}" in
 655                 yes) glib2=yes ;;
 656                 no) glib2=no ;;
 657                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-glib2) ;;
 658             esac
 659         ],
 660         [glib2=auto])
 661
 662 if test "x${glib2}" != xno ; then
 663     PKG_CHECK_MODULES(GLIB20, [ glib-2.0 >= 2.4.0 ],
 664         HAVE_GLIB20=1,
 665         [
 666             HAVE_GLIB20=0
 667             if test "x$glib2" = xyes ; then
 668                 AC_MSG_ERROR([*** GLib 2 support not found])
 669             fi
 670         ])
 671 else
 672     HAVE_GLIB20=0
 673 fi
 674
 675 AC_SUBST(GLIB20_CFLAGS)
 676 AC_SUBST(GLIB20_LIBS)
 677 AC_SUBST(HAVE_GLIB20)
 678 AM_CONDITIONAL([HAVE_GLIB20], [test "x$HAVE_GLIB20" = x1])
 679
 680 #### GConf support (optional) ####
 681
 682 AC_ARG_ENABLE([gconf],
 683     AS_HELP_STRING([--disable-gconf],[Disable optional GConf support]),
 684         [
 685             case "${enableval}" in
 686                 yes) gconf=yes ;;
 687                 no) gconf=no ;;
 688                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-gconf) ;;
 689             esac
 690         ],
 691         [gconf=auto])
 692
 693 if test "x${gconf}" != xno ; then
 694     PKG_CHECK_MODULES(GCONF, [ gconf-2.0 >= 2.4.0 ],
 695         HAVE_GCONF=1,
 696         [
 697             HAVE_GCONF=0
 698             if test "x$gconf" = xyes ; then
 699                 AC_MSG_ERROR([*** GConf support not found])
 700             fi
 701         ])
 702 else
 703     HAVE_GCONF=0
 704 fi
 705
 706 AC_SUBST(GCONF_CFLAGS)
 707 AC_SUBST(GCONF_LIBS)
 708 AC_SUBST(HAVE_GCONF)
 709 AM_CONDITIONAL([HAVE_GCONF], [test "x$HAVE_GCONF" = x1])
 710
 711 #### Avahi support (optional) ####
 712
 713 AC_ARG_ENABLE([avahi],
 714     AS_HELP_STRING([--disable-avahi],[Disable optional Avahi support]),
 715         [
 716             case "${enableval}" in
 717                 yes) avahi=yes ;;
 718                 no) avahi=no ;;
 719                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-avahi) ;;
 720             esac
 721         ],
 722         [avahi=auto])
 723
 724 if test "x${avahi}" != xno ; then
 725     PKG_CHECK_MODULES(AVAHI, [ avahi-client >= 0.6.0 ],
 726         HAVE_AVAHI=1,
 727         [
 728                 HAVE_AVAHI=0
 729                 if test "x$avahi" = xyes ; then
 730                         AC_MSG_ERROR([*** Avahi support not found])
 731                 fi
 732         ])
 733 else
 734     HAVE_AVAHI=0
 735 fi
 736
 737 AC_SUBST(AVAHI_CFLAGS)
 738 AC_SUBST(AVAHI_LIBS)
 739 AC_SUBST(HAVE_AVAHI)
 740 AM_CONDITIONAL([HAVE_AVAHI], [test "x$HAVE_AVAHI" = x1])
 741
 742 ### LIBOIL ####
 743
 744 PKG_CHECK_MODULES(LIBOIL, [ liboil-0.3 >= 0.3.0 ])
 745 AC_SUBST(LIBOIL_CFLAGS)
 746 AC_SUBST(LIBOIL_LIBS)
 747
 748 ### JACK (optional) ####
 749
 750 AC_ARG_ENABLE([jack],
 751     AS_HELP_STRING([--disable-jack],[Disable optional JACK support]),
 752         [
 753             case "${enableval}" in
 754                 yes) jack=yes ;;
 755                 no) jack=no ;;
 756                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-jack) ;;
 757             esac
 758         ],
 759         [jack=auto])
 760
 761 if test "x${jack}" != xno ; then
 762     PKG_CHECK_MODULES(JACK, [ jack >= 0.100 ],
 763         HAVE_JACK=1,
 764         [
 765             HAVE_JACK=0
 766             if test "x$jack" = xyes ; then
 767                 AC_MSG_ERROR([*** JACK support not found])
 768             fi
 769         ])
 770 else
 771     HAVE_JACK=0
 772 fi
 773
 774 AC_SUBST(JACK_CFLAGS)
 775 AC_SUBST(JACK_LIBS)
 776 AC_SUBST(HAVE_JACK)
 777 AM_CONDITIONAL([HAVE_JACK], [test "x$HAVE_JACK" = x1])
 778
 779 #### Async DNS support (optional) ####
 780
 781 AC_ARG_ENABLE([asyncns],
 782     AS_HELP_STRING([--disable-asyncns],[Disable optional Async DNS support]),
 783         [
 784             case "${enableval}" in
 785                 yes) asyncns=yes ;;
 786                 no) asyncns=no ;;
 787                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-asyncns) ;;
 788             esac
 789         ],
 790         [asyncns=auto])
 791
 792 if test "x${asyncns}" != xno ; then
 793     PKG_CHECK_MODULES(LIBASYNCNS, [ libasyncns >= 0.1 ],
 794         HAVE_LIBASYNCNS=1,
 795         [
 796             HAVE_LIBASYNCNS=0
 797             if test "x$asyncns" = xyes ; then
 798                 AC_MSG_ERROR([*** Async DNS support not found])
 799             fi
 800         ])
 801 else
 802     HAVE_LIBASYNCNS=0
 803 fi
 804
 805 AC_SUBST(LIBASYNCNS_CFLAGS)
 806 AC_SUBST(LIBASYNCNS_LIBS)
 807 AC_SUBST(HAVE_LIBASYNCNS)
 808 AM_CONDITIONAL([HAVE_LIBASYNCNS], [test "x$HAVE_LIBASYNCNS" = x1])
 809
 810 if test "x$HAVE_LIBASYNCNS" != "x0" ; then
 811    AC_DEFINE([HAVE_LIBASYNCNS], 1, [Have libasyncns?])
 812 fi
 813
 814 #### TCP wrappers (optional) ####
 815
 816 AC_ARG_ENABLE([tcpwrap],
 817     AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 818         [
 819             case "${enableval}" in
 820                 yes) tcpwrap=yes ;;
 821                 no) tcpwrap=no ;;
 822                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 823             esac
 824         ],
 825         [tcpwrap=auto])
 826
 827 if test "x${tcpwrap}" != xno ; then
 828     ACX_LIBWRAP
 829     if test "x${LIBWRAP_LIBS}" = x && test "x$tcpwrap" = xyes ; then
 830         AC_MSG_ERROR([*** TCP wrappers support not found])
 831     fi
 832 else
 833     LIBWRAP_LIBS=
 834 fi
 835
 836 AC_SUBST(LIBWRAP_LIBS)
 837
 838 #### LIRC support (optional) ####
 839
 840 AC_ARG_ENABLE([lirc],
 841     AS_HELP_STRING([--disable-lirc],[Disable optional LIRC support]),
 842         [
 843             case "${enableval}" in
 844                 yes) lirc=yes ;;
 845                 no) lirc=no ;;
 846                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-lirc) ;;
 847             esac
 848         ],
 849         [lirc=auto])
 850
 851 if test "x${lirc}" != xno ; then
 852     ACX_LIRC
 853     if test "x${HAVE_LIRC}" = x0 && test "x$lirc" = xyes ; then
 854         AC_MSG_ERROR([*** LIRC support not found])
 855     fi
 856 else
 857     HAVE_LIRC=0
 858 fi
 859
 860 AC_SUBST(LIRC_CFLAGS)
 861 AC_SUBST(LIRC_LIBS)
 862 AM_CONDITIONAL([HAVE_LIRC], [test "x$HAVE_LIRC" = x1])
 863
 864 #### HAL support (optional) ####
 865
 866 AC_ARG_ENABLE([hal],
 867     AS_HELP_STRING([--disable-hal],[Disable optional HAL support]),
 868         [
 869             case "${enableval}" in
 870                 yes) hal=yes ;;
 871                 no) hal=no ;;
 872                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-hal) ;;
 873             esac
 874         ],
 875         [hal=auto])
 876 if test "x${hal}" != xno -a \( "x$HAVE_OSS" = "x1" -o "x$HAVE_ALSA" = "x1" \) ; then
 877     PKG_CHECK_MODULES(HAL, [ hal >= 0.5.7 ],
 878         HAVE_HAL=1,
 879         [
 880             HAVE_HAL=0
 881             if test "x$hal" = xyes ; then
 882                 AC_MSG_ERROR([*** HAL support not found])
 883             fi
 884         ])
 885 else
 886     HAVE_HAL=0
 887 fi
 888
 889 AC_SUBST(HAL_CFLAGS)
 890 AC_SUBST(HAL_LIBS)
 891 AC_SUBST(HAVE_HAL)
 892 AM_CONDITIONAL([HAVE_HAL], [test "x$HAVE_HAL" = x1])
 893
 894 #### BlueZ support (optional) ####
 895
 896 AC_ARG_ENABLE([bluez],
 897     AS_HELP_STRING([--disable-bluez],[Disable optional BlueZ support]),
 898         [
 899             case "${enableval}" in
 900                 yes) bluez=yes ;;
 901                 no) bluez=no ;;
 902                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-bluez) ;;
 903             esac
 904         ],
 905         [bluez=auto])
 906 if test "x${bluez}" != xno ; then
 907     PKG_CHECK_MODULES(BLUEZ, [ bluez >= 3.0 ],
 908         HAVE_BLUEZ=1,
 909         [
 910             HAVE_BLUEZ=0
 911             if test "x$bluez" = xyes ; then
 912                 AC_MSG_ERROR([*** BLUEZ support not found])
 913             fi
 914         ])
 915 else
 916     HAVE_BLUEZ=0
 917 fi
 918
 919 AC_SUBST(BLUEZ_CFLAGS)
 920 AC_SUBST(BLUEZ_LIBS)
 921 AC_SUBST(HAVE_BLUEZ)
 922 AM_CONDITIONAL([HAVE_BLUEZ], [test "x$HAVE_BLUEZ" = x1])
 923
 924 #### D-Bus support (optional) ####
 925
 926 AC_ARG_ENABLE([dbus],
 927     AS_HELP_STRING([--disable-dbus],[Disable optional D-Bus support]),
 928         [
 929             case "${enableval}" in
 930                 yes) dbus=yes ;;
 931                 no) dbus=no ;;
 932                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-dbus) ;;
 933             esac
 934         ],
 935         [dbus=auto])
 936
 937 if test "x$HAVE_HAL" = x1 ; then
 938    dbus=yes
 939 fi
 940
 941 if test "x${dbus}" != xno || test "x${bluez}" != xno || "x${hal}" != xno ; then
 942
 943     PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.0.0 ],
 944         [
 945             HAVE_DBUS=1
 946             saved_LIBS="$LIBS"
 947             LIBS="$LIBS $DBUS_LIBS"
 948             AC_CHECK_FUNCS(dbus_watch_get_unix_fd)
 949             LIBS="$saved_LIBS"
 950             AC_DEFINE([HAVE_DBUS], 1, [Have D-Bus.])
 951         ],
 952         [
 953             HAVE_DBUS=0
 954             if test "x$dbus" = xyes ; then
 955                 AC_MSG_ERROR([*** D-Bus support not found])
 956             fi
 957         ])
 958 else
 959     HAVE_DBUS=0
 960 fi
 961
 962 AC_SUBST(DBUS_CFLAGS)
 963 AC_SUBST(DBUS_LIBS)
 964 AC_SUBST(HAVE_DBUS)
 965 AM_CONDITIONAL([HAVE_DBUS], [test "x$HAVE_DBUS" = x1])
 966
 967 #### PolicyKit support (optional) ####
 968
 969 AC_ARG_ENABLE([polkit],
 970     AS_HELP_STRING([--disable-polkit],[Disable optional PolicyKit support]),
 971         [
 972             case "${enableval}" in
 973                 yes) polkit=yes ;;
 974                 no) polkit=no ;;
 975                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-polkit) ;;
 976             esac
 977         ],
 978         [polkit=auto])
 979
 980 if test "x${polkit}" != xno ; then
 981
 982     PKG_CHECK_MODULES(POLKIT, [ polkit-dbus >= 0.7 ],
 983         [
 984             HAVE_POLKIT=1
 985             AC_DEFINE([HAVE_POLKIT], 1, [Have PolicyKit])
 986             policydir=`pkg-config polkit-dbus --variable prefix`/share/PolicyKit/policy/
 987             AC_SUBST(policydir)
 988         ],
 989         [
 990             HAVE_POLKIT=0
 991             if test "x$polkit" = xyes ; then
 992                 AC_MSG_ERROR([*** PolicyKit support not found])
 993             fi
 994         ])
 995 else
 996     HAVE_POLKIT=0
 997 fi
 998
 999 AC_SUBST(POLKIT_CFLAGS)
1000 AC_SUBST(POLKIT_LIBS)
1001 AC_SUBST(HAVE_POLKIT)
1002 AM_CONDITIONAL([HAVE_POLKIT], [test "x$HAVE_POLKIT" = x1])
1003
1004 #### OpenSSL support (optional) ####
1005
1006 AC_ARG_ENABLE([openssl],
1007     AC_HELP_STRING([--disable-openssl], [Disable OpenSSL support (used for Airtunes/RAOP)]),
1008         [
1009             case "${enableval}" in
1010                 yes) openssl=yes ;;
1011                 no) openssl=no ;;
1012                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-openssl) ;;
1013             esac
1014         ],
1015         [openssl=auto])
1016
1017 if test "x${openssl}" != xno ; then
1018
1019     PKG_CHECK_MODULES(OPENSSL, [ openssl > 0.9 ],
1020         [
1021             HAVE_OPENSSL=1
1022             AC_DEFINE([HAVE_OPENSSL], 1, [Have OpenSSL])
1023         ],
1024         [
1025             HAVE_OPENSSL=0
1026             if test "x$openssl" = xyes ; then
1027                 AC_MSG_ERROR([*** OpenSSL support not found])
1028             fi
1029         ])
1030 else
1031     HAVE_OPENSSL=0
1032 fi
1033
1034 AC_SUBST(OPENSSL_CFLAGS)
1035 AC_SUBST(OPENSSL_LIBS)
1036 AC_SUBST(HAVE_OPENSSL)
1037 AM_CONDITIONAL([HAVE_OPENSSL], [test "x$HAVE_OPENSSL" = x1])
1038
1039 ### Build and Install man pages ###
1040 AC_ARG_ENABLE(manpages,
1041         AS_HELP_STRING([--disable-manpages],[Disable building and installation of man pages]),
1042 [case "${enableval}" in
1043   yes) manpages=yes ;;
1044   no)  manpages=no ;;
1045   *) AC_MSG_ERROR([bad value ${enableval} for --disable-manpages]) ;;
1046 esac],[manpages=yes])
1047
1048 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$manpages" = xyes])
1049
1050 #### PulseAudio system group & user  #####
1051
1052 AC_ARG_WITH(system_user, AS_HELP_STRING([--with-system-user=<user>],[User for running the PulseAudio daemon as a system-wide instance (pulse)]))
1053 if test -z "$with_system_user" ; then
1054     PA_SYSTEM_USER=pulse
1055 else
1056     PA_SYSTEM_USER=$with_system_user
1057 fi
1058 AC_SUBST(PA_SYSTEM_USER)
1059 AC_DEFINE_UNQUOTED(PA_SYSTEM_USER,"$PA_SYSTEM_USER", [User for running the PulseAudio system daemon])
1060
1061 AC_ARG_WITH(system_group,AS_HELP_STRING([--with-system-group=<group>],[Group for running the PulseAudio daemon as a system-wide instance (pulse)]))
1062 if test -z "$with_system_group" ; then
1063     PA_SYSTEM_GROUP=pulse
1064 else
1065     PA_SYSTEM_GROUP=$with_system_group
1066 fi
1067 AC_SUBST(PA_SYSTEM_GROUP)
1068 AC_DEFINE_UNQUOTED(PA_SYSTEM_GROUP,"$PA_SYSTEM_GROUP", [Group for the PulseAudio system daemon])
1069
1070 AC_ARG_WITH(realtime_group,AS_HELP_STRING([--with-realtime-group=<group>],[Group for users that are allowed to start the PulseAudio daemon with realtime scheduling (realtime)]))
1071 if test -z "$with_realtime_group" ; then
1072     PA_REALTIME_GROUP=pulse-rt
1073 else
1074     PA_REALTIME_GROUP=$with_realtime_group
1075 fi
1076 AC_SUBST(PA_REALTIME_GROUP)
1077 AC_DEFINE_UNQUOTED(PA_REALTIME_GROUP,"$PA_REALTIME_GROUP", [Realtime group])
1078
1079 AC_ARG_WITH(access_group,AS_HELP_STRING([--with-access-group=<group>],[Group which is allowed access to a system-wide PulseAudio daemon (pulse-access)]))
1080 if test -z "$with_access_group" ; then
1081     PA_ACCESS_GROUP=pulse-access
1082 else
1083     PA_ACCESS_GROUP=$with_access_group
1084 fi
1085 AC_SUBST(PA_ACCESS_GROUP)
1086 AC_DEFINE_UNQUOTED(PA_ACCESS_GROUP,"$PA_ACCESS_GROUP", [Access group])
1087
1088 AC_ARG_ENABLE(
1089         per_user_esound_socket,
1090         AS_HELP_STRING([--disable-per-user-esound-socket], [Use global esound socket directory /tmp/.esd/socket.]),
1091         [
1092             case "${enableval}" in
1093                 yes) per_user_esound_socket=1 ;;
1094                 no) per_user_esound_socket=0 ;;
1095                 *) AC_MSG_ERROR(bad value ${enableval} for --disable-per-user-esound-socket) ;;
1096             esac
1097         ],
1098         [per_user_esound_socket=1])
1099
1100 if test "x$per_user_esound_socket" = "x1"; then
1101    AC_DEFINE([USE_PER_USER_ESOUND_SOCKET], [1], [Define this if you want per-user esound socket directories])
1102 fi
1103
1104 #### PulseAudio system runtime dir ####
1105 PA_SYSTEM_RUNTIME_PATH="${localstatedir}/run/pulse"
1106 AC_SUBST(PA_SYSTEM_RUNTIME_PATH)
1107 PA_SYSTEM_CONFIG_PATH="${localstatedir}/lib/pulse"
1108 AC_SUBST(PA_SYSTEM_CONFIG_PATH)
1109 PA_SYSTEM_STATE_PATH="${localstatedir}/lib/pulse"
1110 AC_SUBST(PA_SYSTEM_STATE_PATH)
1111
1112 ###################################
1113 #            Output               #
1114 ###################################
1115
1116 AC_ARG_ENABLE(
1117         [static-bins],
1118         AS_HELP_STRING([--enable-static-bins],[Statically link executables.]),
1119         [STATIC_BINS=1], [STATIC_BINS=0])
1120 AM_CONDITIONAL([STATIC_BINS], [test "x$STATIC_BINS" = "x1"])
1121
1122 AC_ARG_WITH(
1123         [preopen-mods],
1124         AS_HELP_STRING([--with-preopen-mods],[Modules to preopen in daemon (default: all).]),
1125         [PREOPEN_MODS=$withval], [PREOPEN_MODS="all"])
1126 AM_CONDITIONAL([PREOPEN_MODS], [test "x$PREOPEN_MODS" != "xall"])
1127 if test "x$PREOPEN_MODS" != "xall" ; then
1128     tmpLIBS=""
1129     for mod in $PREOPEN_MODS; do
1130         tmpLIBS="$tmpLIBS module-$mod.la"
1131     done
1132     PREOPEN_MODS="$tmpLIBS"
1133     AC_SUBST(PREOPEN_MODS)
1134 fi
1135
1136 AC_ARG_WITH(
1137         [module-dir],
1138         AS_HELP_STRING([--with-module-dir],[Directory where to install the modules to (defaults to ${libdir}/pulse-${PA_MAJORMINOR}/modules/]),
1139         [modlibexecdir=$withval], [modlibexecdir="${libdir}/pulse-${PA_MAJORMINOR}/modules/"])
1140
1141 AC_SUBST(modlibexecdir)
1142
1143 AC_ARG_ENABLE(
1144         [force-preopen],
1145         AS_HELP_STRING([--enable-force-preopen],[Preopen modules, even when dlopen() is supported.]),
1146         [FORCE_PREOPEN=1], [FORCE_PREOPEN=0])
1147 AM_CONDITIONAL([FORCE_PREOPEN], [test "x$FORCE_PREOPEN" = "x1"])
1148
1149 AC_CONFIG_FILES([
1150 Makefile
1151 src/Makefile
1152 man/Makefile
1153 libpulse.pc
1154 libpulse-simple.pc
1155 libpulse-browse.pc
1156 libpulse-mainloop-glib.pc
1157 doxygen/Makefile
1158 doxygen/doxygen.conf
1159 src/pulse/version.h
1160 po/Makefile.in
1161 ])
1162 AC_OUTPUT
1163
1164 # ==========================================================================
1165 ENABLE_X11=no
1166 if test "x$HAVE_X11" = "x1" ; then
1167    ENABLE_X11=yes
1168 fi
1169
1170 ENABLE_OSS=no
1171 if test "x$HAVE_OSS" = "x1" ; then
1172    ENABLE_OSS=yes
1173 fi
1174
1175 ENABLE_ALSA=no
1176 if test "x$HAVE_ALSA" = "x1" ; then
1177    ENABLE_ALSA=yes
1178 fi
1179
1180 ENABLE_SOLARIS=no
1181 if test "x$HAVE_SOLARIS" = "x1" ; then
1182    ENABLE_SOLARIS=yes
1183 fi
1184
1185 ENABLE_GLIB20=no
1186 if test "x$HAVE_GLIB20" = "x1" ; then
1187    ENABLE_GLIB20=yes
1188 fi
1189
1190 ENABLE_GCONF=no
1191 if test "x$HAVE_GCONF" = "x1" ; then
1192    ENABLE_GCONF=yes
1193 fi
1194
1195 ENABLE_AVAHI=no
1196 if test "x$HAVE_AVAHI" = "x1" ; then
1197    ENABLE_AVAHI=yes
1198 fi
1199
1200 ENABLE_JACK=no
1201 if test "x$HAVE_JACK" = "x1" ; then
1202    ENABLE_JACK=yes
1203 fi
1204
1205 ENABLE_LIBASYNCNS=no
1206 if test "x$HAVE_LIBASYNCNS" = "x1" ; then
1207    ENABLE_LIBASYNCNS=yes
1208 fi
1209
1210 ENABLE_LIRC=no
1211 if test "x$HAVE_LIRC" = "x1" ; then
1212    ENABLE_LIRC=yes
1213 fi
1214
1215 ENABLE_HAL=no
1216 if test "x$HAVE_HAL" = "x1" ; then
1217    ENABLE_HAL=yes
1218 fi
1219
1220 ENABLE_TCPWRAP=no
1221 if test "x${LIBWRAP_LIBS}" != x ; then
1222    ENABLE_TCPWRAP=yes
1223 fi
1224
1225 ENABLE_LIBSAMPLERATE=no
1226 if test "x${HAVE_LIBSAMPLERATE}" = "x1" ; then
1227    ENABLE_LIBSAMPLERATE=yes
1228 fi
1229
1230 ENABLE_BLUEZ=no
1231 if test "x${HAVE_BLUEZ}" = "x1" ; then
1232    ENABLE_BLUEZ=yes
1233 fi
1234
1235 ENABLE_POLKIT=no
1236 if test "x${HAVE_POLKIT}" = "x1" ; then
1237    ENABLE_POLKIT=yes
1238 fi
1239
1240 ENABLE_OPENSSL=no
1241 if test "x${HAVE_OPENSSL}" = "x1" ; then
1242    ENABLE_OPENSSL=yes
1243 fi
1244
1245 ENABLE_PER_USER_ESOUND_SOCKET=no
1246 if test "x$per_user_esound_socket" = "x1" ; then
1247    ENABLE_PER_USER_ESOUND_SOCKET=yes
1248 fi
1249
1250 echo "
1251  ---{ $PACKAGE_NAME $VERSION }---
1252
1253     prefix:                        ${prefix}
1254     sysconfdir:                    ${sysconfdir}
1255     localstatedir:                 ${localstatedir}
1256     System Runtime Path:           ${PA_SYSTEM_RUNTIME_PATH}
1257     System State Path:             ${PA_SYSTEM_STATE_PATH}
1258     System Config Path:            ${PA_SYSTEM_CONFIG_PATH}
1259     Compiler:                      ${CC}
1260     CFLAGS:                        ${CFLAGS}
1261     Have X11:                      ${ENABLE_X11}
1262     Enable OSS:                    ${ENABLE_OSS}
1263     Enable Alsa:                   ${ENABLE_ALSA}
1264     Enable Solaris:                ${ENABLE_SOLARIS}
1265     Enable GLib 2.0:               ${ENABLE_GLIB20}
1266     Enable GConf:                  ${ENABLE_GCONF}
1267     Enable Avahi:                  ${ENABLE_AVAHI}
1268     Enable Jack:                   ${ENABLE_JACK}
1269     Enable Async DNS:              ${ENABLE_LIBASYNCNS}
1270     Enable LIRC:                   ${ENABLE_LIRC}
1271     Enable HAL:                    ${ENABLE_HAL}
1272     Enable BlueZ:                  ${ENABLE_BLUEZ}
1273     Enable TCP Wrappers:           ${ENABLE_TCPWRAP}
1274     Enable libsamplerate:          ${ENABLE_LIBSAMPLERATE}
1275     Enable PolicyKit:              ${ENABLE_POLKIT}
1276     Enable OpenSSL (for Airtunes): ${ENABLE_OPENSSL}
1277     System User:                   ${PA_SYSTEM_USER}
1278     System Group:                  ${PA_SYSTEM_GROUP}
1279     Realtime Group:                ${PA_REALTIME_GROUP}
1280     Access Group:                  ${PA_ACCESS_GROUP}
1281     Enable per-user EsounD socket: ${ENABLE_PER_USER_ESOUND_SOCKET}
1282 "