code.delx.au - gnu-emacs-elpa/blob - swiper.el

   1 ;;; swiper.el --- Isearch with an overview. Oh, man! -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 2015  Free Software Foundation, Inc.
   4
   5 ;; Author: Oleh Krehel <ohwoeowho@gmail.com>
   6 ;; URL: https://github.com/abo-abo/swiper
   7 ;; Version: 0.7.0
   8 ;; Package-Requires: ((emacs "24.1"))
   9 ;; Keywords: matching
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; This file is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 3, or (at your option)
  16 ;; any later version.
  17
  18 ;; This program is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; For a full copy of the GNU General Public License
  24 ;; see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27 ;;
  28 ;; This package gives an overview of the current regex search
  29 ;; candidates.  The search regex can be split into groups with a
  30 ;; space.  Each group is highlighted with a different face.
  31 ;;
  32 ;; It can double as a quick `regex-builder', although only single
  33 ;; lines will be matched.
  34 ;;
  35 ;; It also provides `ivy-mode': a global minor mode that uses the
  36 ;; matching back end of `swiper' for all matching on your system,
  37 ;; including file matching. You can use it in place of `ido-mode'
  38 ;; (can't have both on at once).
  39
  40 ;;; Code:
  41 (require 'ivy)
  42
  43 (defgroup swiper nil
  44   "`isearch' with an overview."
  45   :group 'matching
  46   :prefix "swiper-")
  47
  48 (defface swiper-match-face-1
  49   '((t (:inherit isearch-lazy-highlight-face)))
  50   "The background face for `swiper' matches.")
  51
  52 (defface swiper-match-face-2
  53   '((t (:inherit isearch)))
  54   "Face for `swiper' matches modulo 1.")
  55
  56 (defface swiper-match-face-3
  57   '((t (:inherit match)))
  58   "Face for `swiper' matches modulo 2.")
  59
  60 (defface swiper-match-face-4
  61   '((t (:inherit isearch-fail)))
  62   "Face for `swiper' matches modulo 3.")
  63
  64 (define-obsolete-face-alias 'swiper-minibuffer-match-face-1
  65     'ivy-minibuffer-match-face-1 "0.6.0")
  66
  67 (define-obsolete-face-alias 'swiper-minibuffer-match-face-2
  68     'ivy-minibuffer-match-face-2 "0.6.0")
  69
  70 (define-obsolete-face-alias 'swiper-minibuffer-match-face-3
  71     'ivy-minibuffer-match-face-3 "0.6.0")
  72
  73 (define-obsolete-face-alias 'swiper-minibuffer-match-face-4
  74     'ivy-minibuffer-match-face-4 "0.6.0")
  75
  76 (defface swiper-line-face
  77   '((t (:inherit highlight)))
  78   "Face for current `swiper' line.")
  79
  80 (defcustom swiper-faces '(swiper-match-face-1
  81                           swiper-match-face-2
  82                           swiper-match-face-3
  83                           swiper-match-face-4)
  84   "List of `swiper' faces for group matches.")
  85
  86 (defcustom swiper-min-highlight 2
  87   "Only highlight matches for regexps at least this long."
  88   :type 'integer)
  89
  90 (defvar swiper-map
  91   (let ((map (make-sparse-keymap)))
  92     (define-key map (kbd "M-q") 'swiper-query-replace)
  93     (define-key map (kbd "C-l") 'swiper-recenter-top-bottom)
  94     (define-key map (kbd "C-'") 'swiper-avy)
  95     (define-key map (kbd "C-7") 'swiper-mc)
  96     (define-key map (kbd "C-c C-f") 'swiper-toggle-face-matching)
  97     map)
  98   "Keymap for swiper.")
  99
 100 (defun swiper-query-replace ()
 101   "Start `query-replace' with string to replace from last search string."
 102   (interactive)
 103   (if (null (window-minibuffer-p))
 104       (user-error "Should only be called in the minibuffer through `swiper-map'")
 105     (let* ((enable-recursive-minibuffers t)
 106            (from (ivy--regex ivy-text))
 107            (to (query-replace-read-to from "Query replace" t)))
 108       (swiper--cleanup)
 109       (ivy-exit-with-action
 110        (lambda (_)
 111          (with-ivy-window
 112            (move-beginning-of-line 1)
 113            (perform-replace from to
 114                             t t nil)))))))
 115
 116 (defvar avy-background)
 117 (defvar avy-all-windows)
 118 (defvar avy-style)
 119 (defvar avy-keys)
 120 (declare-function avy--regex-candidates "ext:avy")
 121 (declare-function avy--process "ext:avy")
 122 (declare-function avy--overlay-post "ext:avy")
 123 (declare-function avy-action-goto "ext:avy")
 124 (declare-function avy--done "ext:avy")
 125 (declare-function avy--make-backgrounds "ext:avy")
 126 (declare-function avy-window-list "ext:avy")
 127 (declare-function avy-read "ext:avy")
 128 (declare-function avy-read-de-bruijn "ext:avy")
 129 (declare-function avy-tree "ext:avy")
 130 (declare-function avy-push-mark "ext:avy")
 131 (declare-function avy--remove-leading-chars "ext:avy")
 132
 133 ;;;###autoload
 134 (defun swiper-avy ()
 135   "Jump to one of the current swiper candidates."
 136   (interactive)
 137   (unless (string= ivy-text "")
 138     (let* ((avy-all-windows nil)
 139            (candidates (append
 140                         (with-ivy-window
 141                           (avy--regex-candidates
 142                            (ivy--regex ivy-text)))
 143                         (save-excursion
 144                           (save-restriction
 145                             (narrow-to-region (window-start) (window-end))
 146                             (goto-char (point-min))
 147                             (forward-line)
 148                             (let ((cands))
 149                               (while (< (point) (point-max))
 150                                 (push (cons (1+ (point))
 151                                             (selected-window))
 152                                       cands)
 153                                 (forward-line))
 154                               cands)))))
 155            (candidate (unwind-protect
 156                            (prog2
 157                                (avy--make-backgrounds
 158                                 (append (avy-window-list)
 159                                         (list (ivy-state-window ivy-last))))
 160                                (if (eq avy-style 'de-bruijn)
 161                                    (avy-read-de-bruijn
 162                                     candidates avy-keys)
 163                                  (avy-read (avy-tree candidates avy-keys)
 164                                            #'avy--overlay-post
 165                                            #'avy--remove-leading-chars))
 166                              (avy-push-mark))
 167                         (avy--done))))
 168       (if (window-minibuffer-p (cdr candidate))
 169           (progn
 170             (ivy-set-index (- (line-number-at-pos (car candidate)) 2))
 171             (ivy--exhibit)
 172             (ivy-done)
 173             (ivy-call))
 174         (ivy-quit-and-run
 175          (avy-action-goto (caar candidate)))))))
 176
 177 (declare-function mc/create-fake-cursor-at-point "ext:multiple-cursors-core")
 178 (declare-function multiple-cursors-mode "ext:multiple-cursors-core")
 179
 180 ;;;###autoload
 181 (defun swiper-mc ()
 182   (interactive)
 183   (unless (require 'multiple-cursors nil t)
 184     (error "multiple-cursors isn't installed"))
 185   (let ((cands (nreverse ivy--old-cands)))
 186     (unless (string= ivy-text "")
 187       (ivy-exit-with-action
 188        (lambda (_)
 189          (let (cand)
 190            (while (setq cand (pop cands))
 191              (swiper--action cand)
 192              (when cands
 193                (mc/create-fake-cursor-at-point))))
 194          (multiple-cursors-mode 1))))))
 195
 196 (defun swiper-recenter-top-bottom (&optional arg)
 197   "Call (`recenter-top-bottom' ARG)."
 198   (interactive "P")
 199   (with-ivy-window
 200     (recenter-top-bottom arg)))
 201
 202 (defvar swiper-font-lock-exclude
 203   '(package-menu-mode
 204     gnus-summary-mode
 205     gnus-article-mode
 206     gnus-group-mode
 207     emms-playlist-mode
 208     emms-stream-mode
 209     erc-mode
 210     org-agenda-mode
 211     dired-mode
 212     jabber-chat-mode
 213     elfeed-search-mode
 214     elfeed-show-mode
 215     fundamental-mode
 216     Man-mode
 217     woman-mode
 218     mu4e-view-mode
 219     mu4e-headers-mode
 220     help-mode
 221     debbugs-gnu-mode
 222     occur-mode
 223     occur-edit-mode
 224     bongo-mode
 225     bongo-library-mode
 226     bongo-playlist-mode
 227     eww-mode
 228     twittering-mode
 229     vc-dir-mode
 230     rcirc-mode
 231     sauron-mode
 232     w3m-mode)
 233   "List of major-modes that are incompatible with font-lock-ensure.")
 234
 235 (defun swiper-font-lock-ensure-p ()
 236   "Return non-nil if we should font-lock-ensure."
 237   (or (derived-mode-p 'magit-mode)
 238               (bound-and-true-p magit-blame-mode)
 239               (memq major-mode swiper-font-lock-exclude)))
 240
 241 (defun swiper-font-lock-ensure ()
 242   "Ensure the entired buffer is highlighted."
 243   (unless (swiper-font-lock-ensure-p)
 244     (unless (> (buffer-size) 100000)
 245       (if (fboundp 'font-lock-ensure)
 246           (font-lock-ensure)
 247         (with-no-warnings (font-lock-fontify-buffer))))))
 248
 249 (defvar swiper--format-spec ""
 250   "Store the current candidates format spec.")
 251
 252 (defvar swiper--width nil
 253   "Store the number of digits needed for the longest line nubmer.")
 254
 255 (defvar swiper-use-visual-line nil
 256   "When non-nil, use `line-move' instead of `forward-line'.")
 257
 258 (declare-function outline-show-all "outline")
 259
 260 (defun swiper--candidates (&optional numbers-width)
 261   "Return a list of this buffer lines.
 262
 263 NUMBERS-WIDTH, when specified, is used for width spec of line
 264 numbers; replaces calculating the width from buffer line count."
 265   (if (and visual-line-mode
 266            ;; super-slow otherwise
 267            (< (buffer-size) 20000))
 268       (progn
 269         (when (eq major-mode 'org-mode)
 270           (require 'outline)
 271           (if (fboundp 'outline-show-all)
 272               (outline-show-all)
 273             (with-no-warnings
 274               (show-all))))
 275         (setq swiper-use-visual-line t))
 276     (setq swiper-use-visual-line nil))
 277   (let ((n-lines (count-lines (point-min) (point-max))))
 278     (unless (zerop n-lines)
 279       (setq swiper--width (or numbers-width
 280                               (1+ (floor (log n-lines 10)))))
 281       (setq swiper--format-spec
 282             (format "%%-%dd " swiper--width))
 283       (let ((line-number 0)
 284             (advancer (if swiper-use-visual-line
 285                           (lambda (arg) (line-move arg t))
 286                         #'forward-line))
 287             candidates)
 288         (save-excursion
 289           (goto-char (point-min))
 290           (swiper-font-lock-ensure)
 291           (while (< (point) (point-max))
 292             (let ((str (concat
 293                         " "
 294                         (replace-regexp-in-string
 295                          "\t" "    "
 296                          (if swiper-use-visual-line
 297                              (buffer-substring
 298                               (save-excursion
 299                                 (beginning-of-visual-line)
 300                                 (point))
 301                               (save-excursion
 302                                 (end-of-visual-line)
 303                                 (point)))
 304                            (buffer-substring
 305                             (point)
 306                             (line-end-position)))))))
 307               (when (eq major-mode 'twittering-mode)
 308                 (remove-text-properties 0 (length str) '(field) str))
 309               (put-text-property 0 1 'display
 310                                  (format swiper--format-spec
 311                                          (cl-incf line-number))
 312                                  str)
 313               (push str candidates))
 314             (funcall advancer 1))
 315           (nreverse candidates))))))
 316
 317 (defvar swiper--opoint 1
 318   "The point when `swiper' starts.")
 319
 320 ;;;###autoload
 321 (defun swiper (&optional initial-input)
 322   "`isearch' with an overview.
 323 When non-nil, INITIAL-INPUT is the initial search pattern."
 324   (interactive)
 325   (swiper--ivy initial-input))
 326
 327 (defun swiper-occur ()
 328   "Generate a custom occur buffer for `swiper'."
 329   (ivy-occur-grep-mode)
 330   (font-lock-mode -1)
 331   (let* ((fname (propertize
 332                  (with-ivy-window
 333                    (file-name-nondirectory
 334                     (buffer-file-name)))
 335                  'face
 336                  'compilation-info))
 337          (cands (mapcar
 338                  (lambda (s)
 339                    (format "%s:%s:%s"
 340                            fname
 341                            (propertize
 342                             (string-trim-right
 343                              (get-text-property 0 'display s))
 344                             'face 'compilation-line-number)
 345                            (substring s 1)))
 346                  ivy--old-cands)))
 347     (insert (format "-*- mode:grep; default-directory: %S -*-\n\n\n"
 348                     default-directory))
 349     (insert (format "%d candidates:\n" (length cands)))
 350     (ivy--occur-insert-lines
 351      (mapcar
 352       (lambda (cand) (concat "./" cand))
 353       cands))))
 354
 355 (ivy-set-occur 'swiper 'swiper-occur)
 356
 357 (declare-function evil-jumper--set-jump "ext:evil-jumper")
 358
 359 (defvar swiper--current-line nil)
 360 (defvar swiper--current-match-start nil)
 361
 362 (defun swiper--init ()
 363   "Perform initialization common to both completion methods."
 364   (setq swiper--current-line nil)
 365   (setq swiper--current-match-start nil)
 366   (setq swiper--opoint (point))
 367   (when (bound-and-true-p evil-jumper-mode)
 368     (evil-jumper--set-jump)))
 369
 370 (defun swiper--re-builder (str)
 371   "Transform STR into a swiper regex.
 372 This is the regex used in the minibuffer where candidates have
 373 line numbers. For the buffer, use `ivy--regex' instead."
 374   (replace-regexp-in-string
 375    "\t" "    "
 376    (cond
 377      ((equal str "")
 378       "")
 379      ((equal str "^")
 380       (setq ivy--subexps 0)
 381       ".")
 382      ((string-match "^\\^" str)
 383       (setq ivy--old-re "")
 384       (let ((re (ivy--regex-plus (substring str 1))))
 385         (if (zerop ivy--subexps)
 386             (prog1 (format "^ ?\\(%s\\)" re)
 387               (setq ivy--subexps 1))
 388           (format "^ %s" re))))
 389      (t
 390       (ivy--regex-plus str)))))
 391
 392 (defvar swiper-history nil
 393   "History for `swiper'.")
 394
 395 (defvar swiper-invocation-face nil
 396   "The face at the point of invocation of `swiper'.")
 397
 398 (defun swiper--ivy (&optional initial-input)
 399   "`isearch' with an overview using `ivy'.
 400 When non-nil, INITIAL-INPUT is the initial search pattern."
 401   (interactive)
 402   (swiper--init)
 403   (setq swiper-invocation-face
 404         (plist-get (text-properties-at (point)) 'face))
 405   (let ((candidates (swiper--candidates))
 406         (preselect
 407          (if swiper-use-visual-line
 408              (count-screen-lines
 409               (point-min)
 410               (save-excursion (beginning-of-visual-line) (point)))
 411            (1- (line-number-at-pos))))
 412         (minibuffer-allow-text-properties t)
 413         res)
 414     (unwind-protect
 415          (and
 416           (setq res
 417                 (ivy-read
 418                  "Swiper: "
 419                  candidates
 420                  :initial-input initial-input
 421                  :keymap swiper-map
 422                  :preselect preselect
 423                  :require-match t
 424                  :update-fn #'swiper--update-input-ivy
 425                  :unwind #'swiper--cleanup
 426                  :action #'swiper--action
 427                  :re-builder #'swiper--re-builder
 428                  :history 'swiper-history
 429                  :caller 'swiper))
 430           (point))
 431       (unless res
 432         (goto-char swiper--opoint)))))
 433
 434 (defun swiper-toggle-face-matching ()
 435   "Toggle matching only the candidates with `swiper-invocation-face'."
 436   (interactive)
 437   (setf (ivy-state-matcher ivy-last)
 438         (if (ivy-state-matcher ivy-last)
 439             nil
 440           #'swiper--face-matcher))
 441   (setq ivy--old-re nil))
 442
 443 (defun swiper--face-matcher (regexp candidates)
 444   "Return REGEXP-matching CANDIDATES.
 445 Matched candidates should have `swiper-invocation-face'."
 446   (cl-remove-if-not
 447    (lambda (x)
 448      (and
 449       (string-match regexp x)
 450       (let ((s (match-string 0 x))
 451             (i 0))
 452         (while (and (< i (length s))
 453                     (text-property-any
 454                      i (1+ i)
 455                      'face swiper-invocation-face
 456                      s))
 457           (cl-incf i))
 458         (eq i (length s)))))
 459    candidates))
 460
 461 (defun swiper--ensure-visible ()
 462   "Remove overlays hiding point."
 463   (let ((overlays (overlays-at (point)))
 464         ov expose)
 465     (while (setq ov (pop overlays))
 466       (if (and (invisible-p (overlay-get ov 'invisible))
 467                (setq expose (overlay-get ov 'isearch-open-invisible)))
 468           (funcall expose ov)))))
 469
 470 (defvar swiper--overlays nil
 471   "Store overlays.")
 472
 473 (defun swiper--cleanup ()
 474   "Clean up the overlays."
 475   (while swiper--overlays
 476     (delete-overlay (pop swiper--overlays)))
 477   (save-excursion
 478     (goto-char (point-min))
 479     (isearch-clean-overlays)))
 480
 481 (defun swiper--update-input-ivy ()
 482   "Called when `ivy' input is updated."
 483   (with-ivy-window
 484     (swiper--cleanup)
 485     (when (> (length ivy--current) 0)
 486       (let* ((re (funcall ivy--regex-function ivy-text))
 487              (re (if (stringp re) re (caar re)))
 488              (str (get-text-property 0 'display ivy--current))
 489              (num (if (string-match "^[0-9]+" str)
 490                       (string-to-number (match-string 0 str))
 491                     0)))
 492         (unless (eq this-command 'ivy-yank-word)
 493           (when (cl-plusp num)
 494             (unless (if swiper--current-line
 495                         (eq swiper--current-line num)
 496                       (eq (line-number-at-pos) num))
 497               (goto-char (point-min))
 498               (if swiper-use-visual-line
 499                   (line-move (1- num))
 500                 (forward-line (1- num))))
 501             (if (and (equal ivy-text "")
 502                      (>= swiper--opoint (line-beginning-position))
 503                      (<= swiper--opoint (line-end-position)))
 504                 (goto-char swiper--opoint)
 505               (if (eq swiper--current-line num)
 506                   (when swiper--current-match-start
 507                     (goto-char swiper--current-match-start))
 508                 (setq swiper--current-line num))
 509               (when (re-search-forward re (line-end-position) t)
 510                 (setq swiper--current-match-start (match-beginning 0))))
 511             (isearch-range-invisible (line-beginning-position)
 512                                      (line-end-position))
 513             (unless (and (>= (point) (window-start))
 514                          (<= (point) (window-end (ivy-state-window ivy-last) t)))
 515               (recenter))))
 516         (swiper--add-overlays re)))))
 517
 518 (defun swiper--add-overlays (re &optional beg end wnd)
 519   "Add overlays for RE regexp in visible part of the current buffer.
 520 BEG and END, when specified, are the point bounds.
 521 WND, when specified is the window."
 522   (setq wnd (or wnd (ivy-state-window ivy-last)))
 523   (let ((ov (if visual-line-mode
 524                 (make-overlay
 525                  (save-excursion
 526                    (beginning-of-visual-line)
 527                    (point))
 528                  (save-excursion
 529                    (end-of-visual-line)
 530                    (point)))
 531               (make-overlay
 532                (line-beginning-position)
 533                (1+ (line-end-position))))))
 534     (overlay-put ov 'face 'swiper-line-face)
 535     (overlay-put ov 'window wnd)
 536     (push ov swiper--overlays)
 537     (let* ((wh (window-height))
 538            (beg (or beg (save-excursion
 539                           (forward-line (- wh))
 540                           (point))))
 541            (end (or end (save-excursion
 542                           (forward-line wh)
 543                           (point)))))
 544       (when (>= (length re) swiper-min-highlight)
 545         (save-excursion
 546           (goto-char beg)
 547           ;; RE can become an invalid regexp
 548           (while (and (ignore-errors (re-search-forward re end t))
 549                       (> (- (match-end 0) (match-beginning 0)) 0))
 550             (let ((i 0))
 551               (while (<= i ivy--subexps)
 552                 (when (match-beginning i)
 553                   (let ((overlay (make-overlay (match-beginning i)
 554                                                (match-end i)))
 555                         (face
 556                          (cond ((zerop ivy--subexps)
 557                                 (cadr swiper-faces))
 558                                ((zerop i)
 559                                 (car swiper-faces))
 560                                (t
 561                                 (nth (1+ (mod (+ i 2) (1- (length swiper-faces))))
 562                                      swiper-faces)))))
 563                     (push overlay swiper--overlays)
 564                     (overlay-put overlay 'face face)
 565                     (overlay-put overlay 'window wnd)
 566                     (overlay-put overlay 'priority i)))
 567                 (cl-incf i)))))))))
 568
 569 (defun swiper--action (x)
 570   "Goto line X."
 571   (let ((ln (1- (read (if (memq this-command '(ivy-occur-press))
 572                           (when (string-match ":\\([0-9]+\\):.*\\'" x)
 573                             (match-string-no-properties 1 x))
 574                         (get-text-property 0 'display x)))))
 575         (re (ivy--regex ivy-text)))
 576     (if (null x)
 577         (user-error "No candidates")
 578       (with-ivy-window
 579         (unless (equal (current-buffer)
 580                        (ivy-state-buffer ivy-last))
 581           (switch-to-buffer (ivy-state-buffer ivy-last)))
 582         (goto-char (point-min))
 583         (funcall (if swiper-use-visual-line
 584                      #'line-move
 585                    #'forward-line)
 586                  ln)
 587         (re-search-forward re (line-end-position) t)
 588         (swiper--ensure-visible)
 589         (when (/= (point) swiper--opoint)
 590           (unless (and transient-mark-mode mark-active)
 591             (when (eq ivy-exit 'done)
 592               (push-mark swiper--opoint t)
 593               (message "Mark saved where search started"))))
 594         (add-to-history
 595          'regexp-search-ring
 596          re
 597          regexp-search-ring-max)))))
 598
 599 ;; (define-key isearch-mode-map (kbd "C-o") 'swiper-from-isearch)
 600 (defun swiper-from-isearch ()
 601   "Invoke `swiper' from isearch."
 602   (interactive)
 603   (let ((query (if isearch-regexp
 604                    isearch-string
 605                  (regexp-quote isearch-string))))
 606     (isearch-exit)
 607     (swiper query)))
 608
 609 (defvar swiper-multi-buffers nil
 610   "Store the current list of buffers.")
 611
 612 (defvar swiper-multi-candidates nil
 613   "Store the list of candidates for `swiper-multi'.")
 614
 615 (defun swiper-multi-prompt ()
 616   (format "Buffers (%s): "
 617           (mapconcat #'identity swiper-multi-buffers ", ")))
 618
 619 (defun swiper-multi ()
 620   "Select one or more buffers.
 621 Run `swiper' for those buffers."
 622   (interactive)
 623   (setq swiper-multi-buffers nil)
 624   (ivy-read (swiper-multi-prompt)
 625             'internal-complete-buffer
 626             :action 'swiper-multi-action-1)
 627   (ivy-read "Swiper: " swiper-multi-candidates
 628             :action 'swiper-multi-action-2
 629             :unwind #'swiper--cleanup
 630             :caller 'swiper-multi))
 631
 632 (defun swiper-all ()
 633   "Run `swiper' for all opened buffers."
 634   (interactive)
 635   (ivy-read "Swiper: " (swiper--multi-candidates
 636                         (cl-remove-if-not
 637                          #'buffer-file-name
 638                          (buffer-list)))
 639             :action 'swiper-multi-action-2
 640             :unwind #'swiper--cleanup
 641             :caller 'swiper-multi))
 642
 643 (defun swiper--multi-candidates (buffers)
 644   (let* ((ww (window-width))
 645          (res nil)
 646          (column-2 (apply #'max
 647                           (mapcar
 648                            (lambda (b)
 649                              (length (buffer-name b)))
 650                            buffers)))
 651          (column-1 (- ww 4 column-2 1)))
 652     (dolist (buf buffers)
 653       (with-current-buffer buf
 654         (setq res
 655               (append
 656                (mapcar
 657                 (lambda (s)
 658                   (setq s (concat (ivy--truncate-string s column-1) " "))
 659                   (let ((len (length s)))
 660                     (put-text-property
 661                      (1- len) len 'display
 662                      (concat
 663                       (make-string
 664                        (- ww (string-width s) (length (buffer-name)) 3)
 665                        ?\ )
 666                       (buffer-name))
 667                      s)
 668                     s))
 669                 (swiper--candidates 4))
 670                res))
 671         nil))
 672     res))
 673
 674 (defun swiper-multi-action-1 (x)
 675   (if (member x swiper-multi-buffers)
 676       (progn
 677         (setq swiper-multi-buffers (delete x swiper-multi-buffers)))
 678     (unless (equal x "")
 679       (setq swiper-multi-buffers (append swiper-multi-buffers (list x)))))
 680   (let ((prompt (swiper-multi-prompt)))
 681     (setf (ivy-state-prompt ivy-last) prompt)
 682     (setq ivy--prompt (concat "%-4d " prompt)))
 683   (cond ((memq this-command '(ivy-done
 684                               ivy-alt-done
 685                               ivy-immediate-done))
 686          (setq swiper-multi-candidates
 687                (swiper--multi-candidates
 688                 (mapcar #'get-buffer swiper-multi-buffers))))
 689         ((eq this-command 'ivy-call)
 690          (delete-minibuffer-contents))))
 691
 692 (defun swiper-multi-action-2 (x)
 693   (let ((buf-space (get-text-property (1- (length x)) 'display x)))
 694     (with-ivy-window
 695       (when (string-match "\\` *\\([^ ]+\\)\\'" buf-space)
 696         (switch-to-buffer (match-string 1 buf-space))
 697         (goto-char (point-min))
 698         (forward-line (1- (read (get-text-property 0 'display x))))
 699         (re-search-forward
 700          (ivy--regex ivy-text)
 701          (line-end-position) t)
 702         (unless (eq ivy-exit 'done)
 703           (swiper--cleanup)
 704           (swiper--add-overlays (ivy--regex ivy-text)))))))
 705
 706 (provide 'swiper)
 707
 708 ;;; swiper.el ends here